libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 146
 147 # Only use libltdl for non-newlib builds.
 148 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 149    AC_LIBLTDL_CONVENIENCE
 150    AC_LIBTOOL_DLOPEN
 151    DIRLTDL=libltdl
 152    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 153    # Sigh.  Libtool's macro doesn't do the right thing.
 154    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 155    # FIXME: this is a hack.
 156    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 157    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 158 fi
 159 AC_SUBST(INCLTDL)
 160 AC_SUBST(LIBLTDL)
 161 AC_SUBST(DIRLTDL)
 162 AC_PROG_LIBTOOL
 163 AM_PROG_GCJ
 164 AM_PROG_CC_C_O
 165 AC_CONFIG_SUBDIRS(libltdl)
 166
 167 # The -no-testsuite modules omit the test subdir.
 168 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 169
 170 # Should the runtime set system properties by examining the
 171 # environment variable GCJ_PROPERTIES?
 172 AC_ARG_ENABLE(getenv-properties,
 173   AS_HELP_STRING([--disable-getenv-properties],
 174                  [don't set system properties from GCJ_PROPERTIES]))
 175
 176 # Whether GCJ_PROPERTIES is used depends on the target.
 177 if test -z "$enable_getenv_properties"; then
 178    enable_getenv_properties=${enable_getenv_properties_default-yes}
 179 fi
 180 if test "$enable_getenv_properties" = no; then
 181    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 182      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 183 fi
 184
 185 # Whether we should use arguments to main()
 186 if test -z "$enable_main_args"; then
 187    enable_main_args=${enable_main_args_default-yes}
 188 fi
 189 if test "$enable_main_args" = no; then
 190    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 191 fi
 192
 193
 194 # Should we use hashtable-based synchronization?
 195 # Currently works only for Linux X86/ia64
 196 # Typically faster and more space-efficient
 197 AC_ARG_ENABLE(hash-synchronization,
 198   AS_HELP_STRING([--enable-hash-synchronization],
 199                  [use global hash table for monitor locks]))
 200
 201 if test -z "$enable_hash_synchronization"; then
 202    enable_hash_synchronization=$enable_hash_synchronization_default
 203 fi
 204
 205 # Do we allow intermodule optimizations (i.e. compiling many files at once)?
 206 AC_ARG_ENABLE(libgcj-multifile,
 207   AS_HELP_STRING([--enable-libgcj-multifile]
 208                  [allow compilation of several files at once]),
 209 [case "${enableval}" in
 210   yes) enable_libgcj_multifile=yes ;;
 211   no)  enable_libgcj_multifile=no ;;
 212   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libgcj-multifile) ;;
 213 esac],[enable_libgcj_multifile=no])
 214 AM_CONDITIONAL(ONESTEP, test "$enable_libgcj_multifile" = yes)
 215
 216 # What is the native OS API for MinGW?
 217 AC_ARG_WITH(win32-nlsapi,
 218   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 219                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 220 [case "${withval}" in
 221   ansi) with_win32_nlsapi=ansi ;;
 222   unicows) with_win32_nlsapi=unicows ;;
 223   unicode) with_win32_nlsapi=unicode ;;
 224   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 225 esac],[with_win32_nlsapi=ansi])
 226
 227 case "${with_win32_nlsapi}" in
 228   unicows | unicode)
 229     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 230       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 231     ;;
 232 esac
 233
 234 # configure.host sets slow_pthread_self if the synchronization code should
 235 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 236 if test "${slow_pthread_self}" = "yes"; then
 237   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 238     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 239 fi
 240
 241
 242 # See if the user has requested runtime debugging.
 243 LIBGCJDEBUG="false"
 244 AC_SUBST(LIBGCJDEBUG)
 245 AC_ARG_ENABLE(libgcj-debug,
 246   AS_HELP_STRING([--enable-libgcj-debug],
 247                  [enable runtime debugging code]),
 248   [if test "$enable_libgcj_debug" = yes; then
 249     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 250     LIBGCJDEBUG="true"
 251   fi])
 252
 253 # Check for gc debugging.  This option is handled both here and in the GC.
 254 AC_ARG_ENABLE(gc-debug,
 255    AS_HELP_STRING([--enable-gc-debug],
 256                   [include full support for pointer backtracing etc.]),
 257 [ if test "$enable_gc_debug" = "yes"; then
 258     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 259               [Define if we want to use debug calls into the garbage collector.])
 260   fi])
 261
 262 # See if the user has the interpreter included.
 263 AC_ARG_ENABLE(interpreter,
 264   AS_HELP_STRING([--enable-interpreter],
 265                  [enable interpreter]),
 266   [if test "$enable_interpreter" = yes; then
 267     # This can also be set in configure.host.
 268     libgcj_interpreter=yes
 269   elif test "$enable_interpreter" = no; then
 270     libgcj_interpreter=no
 271   fi])
 272
 273 if test "$libgcj_interpreter" = yes; then
 274    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 275 fi
 276 INTERPRETER="$libgcj_interpreter"
 277 AC_SUBST(INTERPRETER)
 278
 279 AC_MSG_CHECKING([for exception model to use])
 280 AC_LANG_PUSH(C++)
 281 AC_ARG_ENABLE(sjlj-exceptions,
 282   AS_HELP_STRING([--enable-sjlj-exceptions],
 283                  [force use of builtin_setjmp for exceptions]),
 284 [:],
 285 [dnl Botheration.  Now we've got to detect the exception model.
 286 dnl Link tests against libgcc.a are problematic since -- at least
 287 dnl as of this writing -- we've not been given proper -L bits for
 288 dnl single-tree newlib and libgloss.
 289 dnl
 290 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 291 dnl conftest files before we got a change to grep them first.
 292 cat > conftest.$ac_ext << EOF
 293 [#]line __oline__ "configure"
 294 struct S { ~S(); };
 295 void bar();
 296 void foo()
 297 {
 298   S s;
 299   bar();
 300 }
 301 EOF
 302 old_CXXFLAGS="$CXXFLAGS"
 303 CXXFLAGS=-S
 304 if AC_TRY_EVAL(ac_compile); then
 305   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 306     enable_sjlj_exceptions=yes
 307   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 308     enable_sjlj_exceptions=no
 309   fi
 310 fi
 311 CXXFLAGS="$old_CXXFLAGS"
 312 rm -f conftest*])
 313 if test x$enable_sjlj_exceptions = xyes; then
 314   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 315         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 316   ac_exception_model_name=sjlj
 317 elif test x$enable_sjlj_exceptions = xno; then
 318   ac_exception_model_name="call frame"
 319 else
 320   AC_MSG_ERROR([unable to detect exception model])
 321 fi
 322 AC_LANG_POP(C++)
 323 AC_MSG_RESULT($ac_exception_model_name)
 324
 325 # If we are non using SJLJ exceptions, and this host does not have support
 326 # for unwinding from a signal handler, enable checked dereferences and divides.
 327 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 328   CHECKREFSPEC=-fcheck-references
 329   DIVIDESPEC=-fuse-divide-subroutine
 330   EXCEPTIONSPEC=
 331 fi
 332
 333 # See if the user wants to disable java.net.  This is the mildly
 334 # ugly way that we admit that target-side configuration sucks.
 335 AC_ARG_ENABLE(java-net,
 336   AS_HELP_STRING([--disable-java-net],
 337                  [disable java.net]))
 338
 339 # Whether java.net is built by default can depend on the target.
 340 if test -z "$enable_java_net"; then
 341    enable_java_net=${enable_java_net_default-yes}
 342 fi
 343 if test "$enable_java_net" = no; then
 344    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 345 fi
 346
 347 # See if the user wants to configure without libffi.  Some
 348 # architectures don't support it, and default values are set in
 349 # configure.host.
 350 AC_ARG_WITH(libffi,
 351   AS_HELP_STRING([--without-libffi],
 352                  [don't use libffi]),
 353   [:],
 354   [with_libffi=${with_libffi_default-yes}])
 355
 356 LIBFFI=
 357 LIBFFIINCS=
 358 if test "$with_libffi" != no; then
 359    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 360    LIBFFI=../libffi/libffi_convenience.la
 361    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 362 fi
 363 AC_SUBST(LIBFFI)
 364 AC_SUBST(LIBFFIINCS)
 365
 366 # See if the user wants to disable JVMPI support.
 367 AC_ARG_ENABLE(jvmpi,
 368   AS_HELP_STRING([--disable-jvmpi],
 369                  [disable JVMPI support]))
 370
 371 if test "$enable_jvmpi" != no; then
 372     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 373 fi
 374
 375 # If the target is an eCos system, use the appropriate eCos
 376 # I/O routines.
 377 # FIXME: this should not be a local option but a global target
 378 # system; at present there is no eCos target.
 379 TARGET_ECOS=${PROCESS-"no"}
 380 AC_ARG_WITH(ecos,
 381 [  --with-ecos             enable runtime eCos target support],
 382 TARGET_ECOS="$with_ecos"
 383 )
 384
 385 supply_backtrace=no
 386
 387 PLATFORM_INNER_NAT_HDRS=
 388 case "$TARGET_ECOS" in
 389    no) case "$host" in
 390       *mingw*)
 391             PLATFORM=Win32
 392             PLATFORMNET=Win32
 393             PLATFORMH=win32.h
 394         CHECK_FOR_BROKEN_MINGW_LD
 395       ;;
 396       *)
 397             PLATFORM=Posix
 398             PLATFORMNET=Posix
 399             PLATFORMH=posix.h
 400             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 401       ;;
 402       esac
 403       ;;
 404    *)
 405       PLATFORM=Ecos
 406       PLATFORMNET=NoNet
 407       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 408       PLATFORMH=posix.h
 409       ;;
 410 esac
 411 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 412 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 413
 414 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 415                                       [Define if you have int32_t and uint32_t.]))
 416 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 417                                         [Define if you have int32_t and uint32_t.]))
 418 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 419                                           [Define if you have u_int32_t]))
 420 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 421                                            [Define if you have u_int32_t]))
 422
 423 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 424 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix)
 425 AM_CONDITIONAL(USING_ECOS_PLATFORM, test "$PLATFORM" = Ecos)
 426
 427 case "$host" in
 428   *-darwin*) DARWIN_CRT=true ;;
 429   *) DARWIN_CRT=false ;;
 430 esac
 431 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 432
 433 # These may not be defined in a non-ANS conformant embedded system.
 434 # FIXME: Should these case a runtime exception in that case?
 435 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 436                                   [Define is you have 'mktime' in <time.h>]))
 437 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 438                                   [Define is you have 'localtime' in <time.h>]))
 439
 440 # Create the subdirectory for natFile.cc, or the attempt
 441 # to create the link will fail.
 442 test -d java || mkdir java
 443 test -d java/io || mkdir java/io
 444 test -d gnu || mkdir gnu
 445 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 446
 447 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 448 test -d java/lang || mkdir java/lang
 449 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 450 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 451
 452 # Likewise for natInetAddress.cc and natNetworkInterface.cc.
 453 test -d java/net || mkdir java/net
 454 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 455 AC_CONFIG_LINKS(java/net/natNetworkInterface.cc:java/net/natNetworkInterface${PLATFORMNET}.cc)
 456
 457 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 458 test -d gnu/java || mkdir gnu/java
 459 test -d gnu/java/net || mkdir gnu/java/net
 460 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 461 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 462
 463 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 464 test -d gnu/java/nio || mkdir gnu/java/nio
 465 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 466 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 467 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 468 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 469
 470 case "${host}" in
 471     *mingw*)
 472       SYSTEMSPEC="-lgdi32 -lws2_32"
 473       if test "${with_win32_nlsapi}" = "unicows"; then
 474         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 475       fi
 476     ;;
 477     *)
 478       SYSTEMSPEC=
 479     ;;
 480 esac
 481 AC_SUBST(SYSTEMSPEC)
 482
 483 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 484 AC_SUBST(LIBGCJTESTSPEC)
 485
 486 AC_ARG_WITH(system-zlib,
 487   AS_HELP_STRING([--with-system-zlib],
 488                  [use installed libz]))
 489 ZLIBSPEC=
 490 AC_SUBST(ZLIBSPEC)
 491 ZLIBTESTSPEC=
 492 AC_SUBST(ZLIBTESTSPEC)
 493
 494 AC_PATH_XTRA
 495
 496 # Determine which AWT peer libraries to build
 497 AC_ARG_ENABLE(java-awt,
 498   AS_HELP_STRING([--enable-java-awt],
 499                  [list of AWT peer implementations to be built]))
 500
 501 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 502 use_xlib_awt=""
 503 use_gtk_awt=""
 504 # The default toolkit to use is the first one specified.
 505 TOOLKIT=
 506 AC_SUBST(TOOLKIT)
 507
 508 for peer in $peerlibs ; do
 509   case $peer in
 510     xlib)
 511       if test "$no_x" = yes; then
 512         echo "*** xlib peers requested but no X library available" 1>&2
 513         exit 1
 514       else
 515         use_xlib_awt="yes"
 516         if test -z "$TOOLKIT"; then
 517            TOOLKIT=gnu.awt.xlib.XToolkit
 518         fi
 519       fi
 520       ;;
 521     gtk)
 522       if test "$no_x" = yes; then
 523          echo "*** xlib peers requested but no X library available" 1>&2
 524          exit 1
 525       else
 526          use_gtk_awt=yes
 527          if test -z "$TOOLKIT"; then
 528             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 529          fi
 530          test -d jniinclude || mkdir jniinclude
 531       fi
 532       ;;
 533     no)
 534       use_xlib_awt=
 535       use_gtk_awt=
 536       break
 537       ;;
 538     *)
 539       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 540       exit 1
 541   esac
 542 done
 543
 544 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 545 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 546
 547 # determine whether to enable the cairo GTK Graphics2D backend
 548 AC_ARG_ENABLE(gtk-cairo,
 549   AS_HELP_STRING([--enable-gtk-cairo],
 550                  [build the cairo Graphics2D implementation on GTK]))
 551 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 552 if test "x${enable_gtk_cairo}" = xyes
 553 then
 554         PKG_CHECK_MODULES(CAIRO, cairo)
 555         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 556 fi
 557 AC_SUBST(CAIRO_LIBS)
 558 AC_SUBST(CAIRO_CFLAGS)
 559 AC_SUBST(PANGOFT2_LIBS)
 560 AC_SUBST(PANGOFT2_CFLAGS)
 561
 562 # FIXME: this should be _libs on some hosts.
 563 libsubdir=.libs
 564
 565 # Allow the GC to be disabled.  Can be useful when debugging.
 566 AC_MSG_CHECKING([for garbage collector to use])
 567 AC_ARG_ENABLE(java-gc,
 568   AS_HELP_STRING([--enable-java-gc=TYPE],
 569                  [choose garbage collector (default is boehm)]),
 570   [GC=$enableval],
 571   [GC=boehm])
 572 GCLIBS=
 573 GCINCS=
 574 GCDEPS=
 575 GCSPEC=
 576 JC1GCSPEC=
 577 GCTESTSPEC=
 578 case "$GC" in
 579  boehm)
 580     AC_MSG_RESULT(boehm)
 581     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 582     JC1GCSPEC='-fuse-boehm-gc'
 583     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 584     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 585     GCOBJS=boehm.lo
 586     GCHDR=boehm-gc.h
 587     # The POSIX thread support needs to know this.
 588     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 589     ;;
 590  no)
 591     AC_MSG_RESULT(none)
 592     GCHDR=no-gc.h
 593     ;;
 594  *)
 595     AC_MSG_ERROR([unrecognized collector "$GC"])
 596     ;;
 597 esac
 598 AC_SUBST(GCLIBS)
 599 AC_SUBST(GCINCS)
 600 AC_SUBST(GCDEPS)
 601 AC_SUBST(GCSPEC)
 602 AC_SUBST(JC1GCSPEC)
 603 AC_SUBST(GCTESTSPEC)
 604 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 605 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 606 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 607
 608
 609 AC_MSG_CHECKING([for thread model used by GCC])
 610 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 611 AC_MSG_RESULT([$THREADS])
 612
 613 case "$THREADS" in
 614  no | none | single)
 615     THREADS=none
 616     ;;
 617  posix | posix95 | pthreads)
 618     THREADS=posix
 619     case "$host" in
 620      *-*-linux*)
 621         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 622         ;;
 623     esac
 624     ;;
 625  win32)
 626     ;;
 627  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 628     AC_MSG_ERROR(thread package $THREADS not yet supported)
 629     ;;
 630  *)
 631     AC_MSG_ERROR($THREADS is an unknown thread package)
 632     ;;
 633 esac
 634
 635 THREADCXXFLAGS=
 636 THREADLDFLAGS=
 637 THREADLIBS=
 638 THREADINCS=
 639 THREADDEPS=
 640 THREADH=
 641 THREADSPEC=
 642 case "$THREADS" in
 643  posix)
 644     case "$host" in
 645      *-*-cygwin*)
 646         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 647         ;;
 648      *-*-freebsd[[1234]]*)
 649         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 650         # merely adds pthread_* functions) but it does have a -pthread switch
 651         # which is required at link-time to select -lc_r *instead* of -lc.
 652         THREADLDFLAGS=-pthread
 653         # Don't set THREADSPEC here as might be expected since -pthread is
 654         # not processed when found within a spec file, it must come from
 655         # the command line.  For now, the user must provide the -pthread
 656         # switch to link code compiled with gcj.  In future, consider adding
 657         # support for weak references to pthread_* functions ala gthr.h API.
 658         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 659         ;;
 660      *-*-freebsd*)
 661         # FreeBSD 5 implements a model much closer to other modern UNIX
 662         # which support threads.  However, it still does not support
 663         # -lpthread.
 664         THREADLDFLAGS=-pthread
 665         THREADSPEC=-lc_r
 666         ;;
 667      alpha*-dec-osf*)
 668         THREADCXXFLAGS=-pthread
 669         # boehm-gc needs some functions from librt, so link that too.
 670         THREADLIBS='-lpthread -lrt'
 671         THREADSPEC='-lpthread -lrt'
 672         ;;
 673      *)
 674         THREADLIBS=-lpthread
 675         THREADSPEC=-lpthread
 676         ;;
 677     esac
 678     THREADH=posix-threads.h
 679     # MIT pthreads doesn't seem to have the mutexattr functions.
 680     # But for now we don't check for it.  We just assume you aren't
 681     # using MIT pthreads.
 682     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 683
 684     # If we're using the Boehm GC, then we happen to know that it
 685     # defines _REENTRANT, so we don't bother.  Eww.
 686     if test "$GC" != boehm; then
 687        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 688     fi
 689     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 690     ;;
 691
 692  win32)
 693     THREADH=win32-threads.h
 694     ;;
 695
 696  none)
 697     THREADH=no-threads.h
 698     ;;
 699 esac
 700 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 701 AC_SUBST(THREADLIBS)
 702 AC_SUBST(THREADINCS)
 703 AC_SUBST(THREADDEPS)
 704 AC_SUBST(THREADSPEC)
 705 AC_SUBST(THREADLDFLAGS)
 706 AC_SUBST(THREADCXXFLAGS)
 707 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 708 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 709 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 710
 711 if test -d sysdep; then true; else mkdir sysdep; fi
 712 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 713
 714 HASH_SYNC_SPEC=
 715 # Hash synchronization is only useful with posix threads right now.
 716 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 717    HASH_SYNC_SPEC=-fhash-synchronization
 718    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 719 fi
 720 AC_SUBST(HASH_SYNC_SPEC)
 721
 722
 723 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 724
 725 # We're in the tree with gcc, and need to include some of its headers.
 726 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 727
 728 TL_AC_GCC_VERSION([$srcdir/..])
 729
 730 # Figure out where generated headers like libgcj-config.h get installed.
 731 tool_include_dir='$(libdir)/gcc/$(target_noncanonical)/'${gcc_version}/include
 732 AC_SUBST(tool_include_dir)
 733
 734 if test "x${with_newlib}" = "xyes"; then
 735    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 736    # may not work correctly, because the compiler may not be able to
 737    # link executables.
 738
 739    # We assume newlib.  This lets us hard-code the functions we know
 740    # we'll have.
 741    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 742    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 743    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 744    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 745    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 746    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 747    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 748    # This is only for POSIX threads.
 749    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 750    # We also assume we are using gcc, which provides alloca.
 751    AC_DEFINE(HAVE_ALLOCA)
 752
 753    # Assume we do not have getuid and friends.
 754    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 755    PLATFORMNET=NoNet
 756 else
 757    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 758                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 759                    access stat mkdir rename rmdir unlink realpath utime chmod \
 760                    nl_langinfo setlocale \
 761                    inet_pton uname inet_ntoa \
 762                    fork execvp pipe sigaction ftruncate])
 763    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 764    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 765    AC_CHECK_FUNC(backtrace, [
 766      case "$host" in
 767        ia64-*-linux*)
 768          # Has broken backtrace()
 769          ;;
 770        mips*-*-linux*)
 771          # Has broken backtrace(), but we supply our own.
 772          if test -d sysdep; then true; else mkdir -p sysdep; fi
 773          supply_backtrace=yes
 774          AC_DEFINE(HAVE_BACKTRACE, 1,
 775            [Define if your platform has a working backtrace() function.])
 776          ;;
 777        *)
 778          AC_DEFINE(HAVE_BACKTRACE, 1,
 779            [Define if your platform has a working backtrace() function.])
 780          ;;
 781      esac
 782    ], [
 783      case "$host" in
 784        *mingw*)
 785          # Has backtrace() defined in libgcj itself
 786          AC_DEFINE(HAVE_BACKTRACE, 1,
 787            [Define if your platform has a working backtrace() function.])
 788          ;;
 789      esac
 790    ])
 791
 792    AC_CHECK_LIB(dl, dladdr, [
 793      if test "x${disable_dladdr}" = "xyes"; then
 794        #Broken dladdr().
 795        true
 796      else
 797        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 798      fi
 799    ])
 800    if test x"$build" = x"$host"; then
 801      AC_CHECK_FILES(/proc/self/exe, [
 802        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 803    else
 804      case $host in
 805      *-linux*)
 806        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 807        ;;
 808      esac
 809    fi
 810
 811    AM_ICONV
 812    AM_LC_MESSAGES
 813    AC_STRUCT_TIMEZONE
 814
 815    AC_CHECK_FUNCS(gethostbyname_r, [
 816      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 817        [Define if you have the 'gethostbyname_r' function.])
 818      # There are two different kinds of gethostbyname_r.
 819      # We look for the one that returns `int'.
 820      # Hopefully this check is robust enough.
 821      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 822        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 823
 824      case " $GCINCS " in
 825      *" -D_REENTRANT "*) ;;
 826      *)
 827         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 828         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 829         [libjava_cv_gethostbyname_r_needs_reentrant],
 830         [ AC_LANG_PUSH(C++)
 831           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 832             [[gethostbyname_r("", 0, 0);]])],
 833             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 834                 CPPFLAGS_SAVE="$CPPFLAGS"
 835                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 836                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 837                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 838                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 839                 CPPFLAGS="$CPPFLAGS_SAVE"
 840           ])
 841           AC_LANG_POP(C++)
 842         ])
 843         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 844           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 845         fi
 846      ;;
 847      esac
 848
 849      AC_CACHE_CHECK([for struct hostent_data],
 850         [libjava_cv_struct_hostent_data], [dnl
 851         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 852 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 853 # define _REENTRANT 1
 854 #endif
 855 #include <netdb.h>]], [[struct hostent_data data;]])],
 856           [libjava_cv_struct_hostent_data=yes],
 857           [libjava_cv_struct_hostent_data=no])])
 858      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 859        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 860          [Define if struct hostent_data is defined in netdb.h])
 861      fi
 862    ])
 863
 864    # FIXME: libjava source code expects to find a prototype for
 865    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 866    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 867    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 868    # linkage check is enough, yet C++ code requires proper prototypes.)
 869    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 870    AC_CHECK_FUNCS(gethostbyaddr_r, [
 871      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 872        [Define if you have the 'gethostbyaddr_r' function.])
 873      # There are two different kinds of gethostbyaddr_r.
 874      # We look for the one that returns `int'.
 875      # Hopefully this check is robust enough.
 876      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 877        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 878          [Define if gethostbyaddr_r returns 'int'.])])])])
 879
 880    AC_CHECK_FUNCS(gethostname, [
 881      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 882        [Define if you have the 'gethostname' function.])
 883      AC_EGREP_HEADER(gethostname, unistd.h, [
 884        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 885          [Define if gethostname is declared in <unistd.h>.])])])
 886
 887    AC_CHECK_FUNCS(usleep, [
 888      AC_EGREP_HEADER(usleep, unistd.h, [
 889        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 890           [Define if usleep is declared in <unistd.h>.])])])
 891
 892    # Look for these functions in the thread library, but only bother
 893    # if using POSIX threads.
 894    if test "$THREADS" = posix; then
 895       save_LIBS="$LIBS"
 896       LIBS="$LIBS $THREADLIBS"
 897       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 898       # E.g., Solaris.
 899       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 900
 901       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 902       # Solaris 7 the name librt is preferred.
 903       AC_CHECK_FUNCS(sched_yield, , [
 904         AC_CHECK_LIB(rt, sched_yield, [
 905           AC_DEFINE(HAVE_SCHED_YIELD)
 906           THREADLIBS="$THREADLIBS -lrt"
 907           THREADSPEC="$THREADSPEC -lrt"], [
 908           AC_CHECK_LIB(posix4, sched_yield, [
 909             AC_DEFINE(HAVE_SCHED_YIELD)
 910             THREADLIBS="$THREADLIBS -lposix4"
 911             THREADSPEC="$THREADSPEC -lposix4"])])])
 912       LIBS="$save_LIBS"
 913
 914       # We can save a little space at runtime if the mutex has m_count
 915       # or __m_count.  This is a nice hack for Linux.
 916       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 917           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 918         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 919              [Define if pthread_mutex_t has m_count member.]), [
 920         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 921             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 922           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 923             [Define if pthread_mutex_t has __m_count member.]))])
 924    fi
 925
 926    # We require a way to get the time.
 927    time_found=no
 928    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 929    if test "$time_found" = no; then
 930       AC_MSG_ERROR([no function found to get the time])
 931    fi
 932
 933    AC_CHECK_FUNCS(memmove)
 934
 935    # We require memcpy.
 936    memcpy_found=no
 937    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 938    if test "$memcpy_found" = no; then
 939       AC_MSG_ERROR([memcpy is required])
 940    fi
 941
 942    AC_CHECK_LIB(dl, dlopen, [
 943        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 944
 945    # Some library-finding code we stole from Tcl.
 946    #--------------------------------------------------------------------
 947    #    Check for the existence of the -lsocket and -lnsl libraries.
 948    #    The order here is important, so that they end up in the right
 949    #    order in the command line generated by make.  Here are some
 950    #    special considerations:
 951    #    1. Use "connect" and "accept" to check for -lsocket, and
 952    #       "gethostbyname" to check for -lnsl.
 953    #    2. Use each function name only once:  can't redo a check because
 954    #       autoconf caches the results of the last check and won't redo it.
 955    #    3. Use -lnsl and -lsocket only if they supply procedures that
 956    #       aren't already present in the normal libraries.  This is because
 957    #       IRIX 5.2 has libraries, but they aren't needed and they're
 958    #       bogus:  they goof up name resolution if used.
 959    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 960    #       To get around this problem, check for both libraries together
 961    #       if -lsocket doesn't work by itself.
 962    #--------------------------------------------------------------------
 963
 964    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 965     [gcj_cv_lib_sockets=
 966      gcj_checkBoth=0
 967      unset ac_cv_func_connect
 968      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 969      if test "$gcj_checkSocket" = 1; then
 970          unset ac_cv_func_connect
 971          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 972                       gcj_checkBoth=1)
 973      fi
 974      if test "$gcj_checkBoth" = 1; then
 975          gcj_oldLibs=$LIBS
 976          LIBS="$LIBS -lsocket -lnsl"
 977          unset ac_cv_func_accept
 978          AC_CHECK_FUNC(accept,
 979                        [gcj_checkNsl=0
 980                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 981          unset ac_cv_func_accept
 982          LIBS=$gcj_oldLibs
 983      fi
 984      unset ac_cv_func_gethostbyname
 985      gcj_oldLibs=$LIBS
 986      LIBS="$LIBS $gcj_cv_lib_sockets"
 987      AC_CHECK_FUNC(gethostbyname, ,
 988                    [AC_CHECK_LIB(nsl, main,
 989                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 990      unset ac_cv_func_gethostbyname
 991      LIBS=$gcj_oldLIBS
 992    ])
 993    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 994
 995    if test "$with_system_zlib" = yes; then
 996       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
 997    fi
 998
 999    # Test for Gtk stuff, if asked for.
1000    if test "$use_gtk_awt" = yes; then
1001       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1002       AC_SUBST(GTK_CFLAGS)
1003       AC_SUBST(GTK_LIBS)
1004
1005       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1006       AC_SUBST(GLIB_CFLAGS)
1007       AC_SUBST(GLIB_LIBS)
1008
1009       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1010       AC_SUBST(LIBART_CFLAGS)
1011       AC_SUBST(LIBART_LIBS)
1012
1013       # We require the XTest Extension to support java.awt.Robot.
1014       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1015                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1016                    [${X_LIBS}])
1017    fi
1018
1019    # On Solaris, and maybe other architectures, the Boehm collector
1020    # requires -ldl.
1021    if test "$GC" = boehm; then
1022       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1023    fi
1024 fi
1025 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1026
1027 if test -z "${with_multisubdir}"; then
1028    builddotdot=.
1029 else
1030    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1031 fi
1032
1033 NATIVE=yes
1034
1035 # Which gcj do we use?
1036 which_gcj=default
1037 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
1038 if test -n "${with_cross_host}"; then
1039   # We are being configured with a cross compiler. We can't
1040   # use ac_exeext, because that is for the target platform.
1041   NATIVE=no
1042   cross_host_exeext=
1043   case "${with_cross_host}" in
1044      *mingw* | *cygwin*)
1045          cross_host_exeext=.exe
1046      ;;
1047   esac
1048   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1049      if test x"$build_noncanonical" = x"$with_cross_host"; then
1050         # Ordinary cross (host!=target and host=build)
1051         which_gcj=built
1052      else
1053         # Canadian cross (host!=target and host!=build)
1054         which_gcj=cross
1055      fi
1056   else
1057      which_gcj=cross
1058   fi
1059 else
1060   # We are being configured with a native or crossed-native compiler
1061   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1062      if test x"$build" = x"$host"; then
1063         # True native build (host=target and host=build)
1064         which_gcj=built
1065      else
1066         # Crossed-native build (host=target and host!=build)
1067         which_gcj=cross
1068      fi
1069   else
1070      which_gcj=path
1071   fi
1072 fi
1073 case "${which_gcj}" in
1074    built)
1075       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1076       GCJH='$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
1077       ZIP='$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
1078    ;;
1079    cross)
1080       if test "x${with_newlib}" = "xyes"; then
1081          # FIXME (comment): Why is this needed?
1082          GCC_UNWIND_INCLUDE=
1083          GCJ="${target_noncanonical}-gcj"
1084       else
1085          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1086       fi
1087       ZIP=jar
1088       GCJH='$(target_noncanonical)-gcjh'
1089    ;;
1090    path)
1091       GCJ="gcj -B`${PWDCMD-pwd}`/"
1092       ## In this case, gcj is found outside the build tree.  However, zip is
1093       ## found in the build tree.
1094       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1095       GCJH=gcjh
1096    ;;
1097 esac
1098
1099 AC_SUBST(GCJH)
1100 AC_SUBST(ZIP)
1101
1102 # Create it, so that compile/link tests don't fail
1103 test -f libgcj.spec || touch libgcj.spec
1104
1105 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1106 case $build in
1107     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1108     *)         CLASSPATH_SEPARATOR=':' ;;
1109 esac
1110 AC_SUBST(CLASSPATH_SEPARATOR)
1111
1112 # We must search the source tree for java.lang, since we still don't
1113 # have libgcj.jar nor java/lang/*.class
1114 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1115 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1116
1117 # Since some classes depend on this one, we need its source available
1118 # before we can do any GCJ compilation test :-(
1119 if test ! -f gnu/classpath/Configuration.java; then
1120   test -d gnu || mkdir gnu
1121   test -d gnu/classpath || mkdir gnu/classpath
1122   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1123       -e 's,@TOOLKIT@,$TOOLKIT,' \
1124         < $srcdir/gnu/classpath/Configuration.java.in \
1125         > gnu/classpath/Configuration.java
1126   # We do not want to redirect the output of the grep below to /dev/null,
1127   # but we add /dev/null to the input list so that grep will print the
1128   # filename of Configuration.java in case it finds any matches.
1129   if grep @ gnu/classpath/Configuration.java /dev/null; then
1130     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1131   fi
1132 fi
1133
1134 LT_AC_PROG_GCJ
1135
1136 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1137
1138 AC_COMPILE_CHECK_SIZEOF(void *)
1139
1140 AC_C_BIGENDIAN_CROSS
1141
1142 ZLIBS=
1143 SYS_ZLIBS=
1144 ZINCS=
1145
1146 if test -z "$ZLIBSPEC"; then
1147    # Use zlib from the GCC tree.
1148    ZINCS='-I$(top_srcdir)/../zlib'
1149    ZLIBS=../zlib/libzgcj_convenience.la
1150 else
1151    # System's zlib.
1152    SYS_ZLIBS="$ZLIBSPEC"
1153 fi
1154 AC_SUBST(ZLIBS)
1155 AC_SUBST(SYS_ZLIBS)
1156 AC_SUBST(ZINCS)
1157 AC_SUBST(DIVIDESPEC)
1158 AC_SUBST(CHECKREFSPEC)
1159 AC_SUBST(EXCEPTIONSPEC)
1160 AC_SUBST(IEEESPEC)
1161
1162 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1163 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1164 AC_SUBST(GCC_UNWIND_INCLUDE)
1165
1166 # Process the option "--enable-version-specific-runtime-libs"
1167 # Calculate toolexeclibdir
1168 case ${version_specific_libs} in
1169   yes)
1170     # Need the gcc compiler version to know where to install libraries
1171     # and header files if --enable-version-specific-runtime-libs option
1172     # is selected.
1173     includedir='${libdir}/gcc/${target_noncanonical}/'$gcc_version/include/
1174     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1175     toolexecmainlibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1176     toolexeclibdir=$toolexecmainlibdir
1177     ;;
1178   no)
1179     if test -n "$with_cross_host" &&
1180        test x"$with_cross_host" != x"no"; then
1181       # Install a library built with a cross compiler in tooldir, not libdir.
1182       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1183       toolexecmainlibdir='$(toolexecdir)/lib'
1184     else
1185       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1186       toolexecmainlibdir='$(libdir)'
1187     fi
1188     multi_os_directory=`$CC -print-multi-os-directory`
1189     case $multi_os_directory in
1190       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1191       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1192     esac
1193     ;;
1194 esac
1195 AC_SUBST(toolexecdir)
1196 AC_SUBST(toolexecmainlibdir)
1197 AC_SUBST(toolexeclibdir)
1198
1199 # Determine gcj version number.
1200 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1201 GCJVERSION=$gcjversion
1202 AC_SUBST(GCJVERSION)
1203 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1204
1205 TL_AC_GXX_INCLUDE_DIR
1206
1207 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1208 # On that system, sys/ioctl.h will not include sys/filio.h unless
1209 # BSD_COMP is defined; just including sys/filio.h is simpler.
1210 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1211 # for now.  If you change this, you also must update natFile.cc.
1212 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1213                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1214                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1215                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1216                   dirent.h])
1217 AC_CHECK_HEADERS(inttypes.h, [
1218     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1219     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1220 ])
1221 AC_HEADER_SYS_WAIT
1222
1223 AC_CHECK_TYPE([ssize_t], [int])
1224
1225 AC_MSG_CHECKING([for in_addr_t])
1226 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1227 #if STDC_HEADERS
1228 #include <stdlib.h>
1229 #include <stddef.h>
1230 #endif
1231 #if HAVE_NETINET_IN_H
1232 #include <netinet/in.h>
1233 #endif]], [[in_addr_t foo;]])],
1234   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1235      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1236    AC_MSG_RESULT(yes)],
1237   [AC_MSG_RESULT(no)])
1238
1239 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1240 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1241   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1242      [Define if struct ip_mreq is defined in netinet/in.h.])
1243    AC_MSG_RESULT(yes)],
1244   [AC_MSG_RESULT(no)])
1245
1246 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1247 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1248   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1249      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1250    AC_MSG_RESULT(yes)],
1251   [AC_MSG_RESULT(no)])
1252
1253 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1254 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1255   [AC_DEFINE(HAVE_INET6, 1,
1256      [Define if inet6 structures are defined in netinet/in.h.])
1257    AC_MSG_RESULT(yes)],
1258   [AC_MSG_RESULT(no)])
1259
1260 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1261 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1262 #include <sys/types.h>
1263 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1264   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1265    AC_MSG_RESULT(yes)],
1266   [AC_MSG_RESULT(no)])
1267
1268 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1269 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1270   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1271    AC_MSG_RESULT(yes)],
1272   [AC_MSG_RESULT(no)
1273    AC_MSG_CHECKING([for global timezone variable])
1274    dnl FIXME: we don't want a link check here because that won't work
1275    dnl when cross-compiling.  So instead we make an assumption that
1276    dnl the header file will mention timezone if it exists.
1277    dnl Don't find the win32 function timezone
1278    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1279      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1280       AC_MSG_RESULT(yes)],
1281      [AC_MSG_RESULT(no)
1282        AC_MSG_CHECKING([for global _timezone variable])
1283        dnl FIXME: As above, don't want link check
1284        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1285          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1286             [Define if your platform has the global _timezone variable.])
1287           AC_MSG_RESULT(yes)],
1288           [AC_MSG_RESULT(no)])])])
1289
1290 AC_FUNC_ALLOCA
1291 AC_FUNC_MMAP
1292
1293 AC_CHECK_PROGS(PERL, perl, false)
1294
1295 SYSDEP_SOURCES=
1296 SIGNAL_HANDLER_AUX=
1297
1298 case "${host}" in
1299  i?86-*-linux*)
1300     SIGNAL_HANDLER=include/i386-signal.h
1301     ;;
1302  sparc*-sun-solaris*)
1303     SIGNAL_HANDLER=include/sparc-signal.h
1304     ;;
1305 # ia64-*)
1306 #    SYSDEP_SOURCES=sysdep/ia64.c
1307 #    test -d sysdep || mkdir sysdep
1308 #    ;;
1309  hppa*-*-linux*)
1310     SIGNAL_HANDLER=include/pa-signal.h
1311     ;;
1312  ia64-*-linux*)
1313     SIGNAL_HANDLER=include/dwarf2-signal.h
1314     ;;
1315  powerpc*-*-linux*)
1316     SIGNAL_HANDLER=include/powerpc-signal.h
1317     ;;
1318  alpha*-*-linux*)
1319     SIGNAL_HANDLER=include/dwarf2-signal.h
1320     ;;
1321  s390*-*-linux*)
1322     SIGNAL_HANDLER=include/s390-signal.h
1323     ;;
1324  x86_64*-*-linux*)
1325     SIGNAL_HANDLER=include/x86_64-signal.h
1326     SIGNAL_HANDLER_AUX=include/i386-signal.h
1327     ;;
1328  sparc*-*-linux*)
1329     SIGNAL_HANDLER=include/dwarf2-signal.h
1330     ;;
1331  sh*-*-linux*)
1332     SIGNAL_HANDLER=include/sh-signal.h
1333     ;;
1334  *mingw*)
1335     SIGNAL_HANDLER=include/win32-signal.h
1336     ;;
1337  mips*-*-linux*)
1338     SIGNAL_HANDLER=include/mips-signal.h
1339     ;;
1340  *-*-darwin*)
1341     SIGNAL_HANDLER=include/darwin-signal.h
1342     ;;
1343  *)
1344     SIGNAL_HANDLER=include/default-signal.h
1345     ;;
1346 esac
1347
1348 # If we're using sjlj exceptions, forget what we just learned.
1349 if test "$enable_sjlj_exceptions" = yes; then
1350    SIGNAL_HANDLER=include/default-signal.h
1351    SIGNAL_HANDLER_AUX=
1352 fi
1353
1354 # Define here any compiler flags that you need in order to make backtrace() work.
1355 BACKTRACESPEC=
1356 case "${host}" in
1357  x86_64*-*-linux*|i?86-*)
1358     BACKTRACESPEC=-fno-omit-frame-pointer
1359     ;;
1360 esac
1361 AC_SUBST(BACKTRACESPEC)
1362
1363 AC_SUBST(SYSDEP_SOURCES)
1364
1365 if test -z "$SIGNAL_HANDLER_AUX"; then
1366   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1367 fi
1368
1369 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1370                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1371
1372 if test "${multilib}" = "yes"; then
1373   multilib_arg="--enable-multilib"
1374 else
1375   multilib_arg=
1376 fi
1377
1378
1379
1380 here=`${PWDCMD-pwd}`
1381 AC_SUBST(here)
1382
1383 # We get this from the environment.
1384 AC_SUBST(GCJFLAGS)
1385
1386 AC_CONFIG_FILES([
1387 Makefile
1388 libgcj.pc
1389 libgcj.spec
1390 libgcj-test.spec
1391 gnu/classpath/Configuration.java
1392 gcj/Makefile
1393 include/Makefile
1394 testsuite/Makefile
1395 external/Makefile
1396 external/sax/Makefile
1397 external/w3c_dom/Makefile
1398 ])
1399
1400 AC_CONFIG_COMMANDS([default],
1401 [# Only add multilib support code if we just rebuilt top-level Makefile.
1402 case " $CONFIG_FILES " in
1403  *" Makefile "*)
1404    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1405    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1406    ;;
1407 esac
1408 ],
1409 srcdir=${srcdir}
1410 host=${host}
1411 target=${target}
1412 with_multisubdir=${with_multisubdir}
1413 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1414 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1415 libgcj_basedir=${libgcj_basedir}
1416 CC="${CC}"
1417 CXX="${CXX}"
1418 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1419 )
1420
1421 AC_OUTPUT