libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 # Only use libltdl for non-newlib builds.
 146 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 147    AC_LTDL_SHLIBPATH
 148 fi
 149
 150 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 151
 152 # See if the user has requested runtime debugging.
 153 LIBGCJDEBUG="disable"
 154 AC_SUBST(LIBGCJDEBUG)
 155 AC_ARG_ENABLE(libgcj-debug,
 156   AS_HELP_STRING([--enable-libgcj-debug],
 157                  [enable runtime debugging code]),
 158   [if test "$enable_libgcj_debug" = yes; then
 159     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 160     LIBGCJDEBUG="enable"
 161   fi])
 162
 163 # Determine which AWT peer libraries to build
 164 AC_ARG_ENABLE(java-awt,
 165   AS_HELP_STRING([--enable-java-awt],
 166                  [list of AWT peer implementations to be built]))
 167
 168 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 169 use_xlib_awt=""
 170 use_gtk_awt=""
 171 use_qt_awt=""
 172 # The default toolkit to use is the first one specified.
 173 TOOLKIT=
 174 AC_SUBST(TOOLKIT)
 175
 176 for peer in $peerlibs ; do
 177   case $peer in
 178     xlib)
 179       if test "$no_x" = yes; then
 180         echo "*** xlib peers requested but no X library available" 1>&2
 181         exit 1
 182       else
 183         use_xlib_awt="yes"
 184         if test -z "$TOOLKIT"; then
 185            TOOLKIT=gnu.awt.xlib.XToolkit
 186         fi
 187       fi
 188       ;;
 189     gtk)
 190       if test "$no_x" = yes; then
 191          echo "*** gtk peers requested but no X library available" 1>&2
 192          exit 1
 193       else
 194          use_gtk_awt=yes
 195          if test -z "$TOOLKIT"; then
 196             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 197          fi
 198       fi
 199       ;;
 200     qt)
 201       if test "$no_x" = yes; then
 202          # Perhaps we should admit the possibility of embedded Qt.
 203          echo "*** Qt peers requested but no X library available" 1>&2
 204          exit 1
 205       else
 206          use_qt_awt=yes
 207          if test -z "$TOOLKIT"; then
 208             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 209          fi
 210       fi
 211       ;;
 212     no)
 213       use_xlib_awt=
 214       use_gtk_awt=
 215       use_qt_awt=
 216       break
 217       ;;
 218     *)
 219       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 220       exit 1
 221   esac
 222 done
 223
 224 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 225 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 226 AM_CONDITIONAL(QT_AWT, test "$use_qt_awt" = yes)
 227
 228 # Create standard.omit based on decisions we just made.
 229 cp $srcdir/standard.omit.in standard.omit
 230 if test "$use_xlib_awt" != yes; then
 231    echo gnu/awt/xlib >> standard.omit
 232    echo gnu/gcj/xlib >> standard.omit
 233 fi
 234 if test "$use_gtk_awt" != yes; then
 235    echo gnu/java/awt/peer/gtk >> standard.omit
 236 fi
 237 if test "$use_qt_awt" != yes; then
 238    echo gnu/java/awt/peer/qt >> standard.omit
 239 fi
 240
 241 if test -z "${with_multisubdir}"; then
 242    builddotdot=.
 243 else
 244    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 245 fi
 246
 247 NATIVE=yes
 248
 249 # Which gcj do we use?
 250 which_gcj=default
 251 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 252 if test -n "${with_cross_host}"; then
 253   # We are being configured with a cross compiler. We can't
 254   # use ac_exeext, because that is for the target platform.
 255   NATIVE=no
 256   cross_host_exeext=
 257   case "${with_cross_host}" in
 258      *mingw* | *cygwin*)
 259          cross_host_exeext=.exe
 260      ;;
 261   esac
 262   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 263      if test x"$build_noncanonical" = x"$with_cross_host"; then
 264         # Ordinary cross (host!=target and host=build)
 265         which_gcj=built
 266      else
 267         # Canadian cross (host!=target and host!=build)
 268         which_gcj=cross
 269      fi
 270   else
 271      which_gcj=cross
 272   fi
 273 else
 274   # We are being configured with a native or crossed-native compiler
 275   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 276      if test x"$build" = x"$host"; then
 277         # True native build (host=target and host=build)
 278         which_gcj=built
 279      else
 280         # Crossed-native build (host=target and host!=build)
 281         which_gcj=cross
 282      fi
 283   else
 284      which_gcj=path
 285   fi
 286 fi
 287 case "${which_gcj}" in
 288    built)
 289       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 290       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 291       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
 292    ;;
 293    cross)
 294       if test "x${with_newlib}" = "xyes"; then
 295          # FIXME (comment): Why is this needed?
 296          GCC_UNWIND_INCLUDE=
 297          GCJ="${target_noncanonical}-gcj"
 298       else
 299          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 300       fi
 301       ZIP='$(target_noncanonical)-fastjar'
 302       GCJH='$(target_noncanonical)-gcjh'
 303    ;;
 304    path)
 305       GCJ="gcj -B`${PWDCMD-pwd}`/"
 306       ## In this case, gcj is found outside the build tree.  However, zip is
 307       ## found in the build tree.
 308       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
 309       GCJH=gcjh
 310    ;;
 311 esac
 312
 313 AC_SUBST(GCJH)
 314 AC_SUBST(ZIP)
 315
 316 # Create it, so that compile/link tests don't fail
 317 test -f libgcj.spec || touch libgcj.spec
 318
 319
 320
 321 # Set up to configure Classpath.
 322 # FIXME: no supported way to pass args in autoconf.
 323 ac_configure_args="$ac_configure_args --disable-load-library"
 324 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 325 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 326 dir1=`cd $srcdir && pwd`
 327 dir2=`pwd`
 328 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 329 ac_configure_args="$ac_configure_args --disable-core-jni"
 330 dnl FIXME?
 331 ac_configure_args="$ac_configure_args --disable-examples"
 332 ac_configure_args="$ac_configure_args --with-glibj=build"
 333 if test "$use_gtk_awt" != yes; then
 334   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 335 fi
 336 if test "$use_qt_awt" != yes; then
 337   ac_configure_args="$ac_configure_args --disable-qt-peer"
 338 else
 339   # We need this as qt is disabled by default in classpath.
 340   ac_configure_args="$ac_configure_args --enable-qt-peer"
 341 fi
 342 dnl --with-gcj=$GCJ
 343 dnl --with-javah=$GCJH
 344 dnl gjdoc?
 345 dnl gtk-cairo -- just export here...
 346 dnl --enable-regen-headers?
 347
 348 # Only use libltdl for non-newlib builds.
 349 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 350    AC_LIBLTDL_CONVENIENCE
 351    AC_LIBTOOL_DLOPEN
 352    DIRLTDL=libltdl
 353    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 354    # Sigh.  Libtool's macro doesn't do the right thing.
 355    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 356    # FIXME: this is a hack.
 357    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 358    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 359 fi
 360 AC_SUBST(INCLTDL)
 361 AC_SUBST(LIBLTDL)
 362 AC_SUBST(DIRLTDL)
 363 AC_PROG_LIBTOOL
 364 AM_PROG_GCJ
 365 AM_PROG_CC_C_O
 366
 367 AC_CONFIG_SUBDIRS(classpath libltdl)
 368
 369 # The -no-testsuite modules omit the test subdir.
 370 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 371
 372 # Should the runtime set system properties by examining the
 373 # environment variable GCJ_PROPERTIES?
 374 AC_ARG_ENABLE(getenv-properties,
 375   AS_HELP_STRING([--disable-getenv-properties],
 376                  [don't set system properties from GCJ_PROPERTIES]))
 377
 378 # Whether GCJ_PROPERTIES is used depends on the target.
 379 if test -z "$enable_getenv_properties"; then
 380    enable_getenv_properties=${enable_getenv_properties_default-yes}
 381 fi
 382 if test "$enable_getenv_properties" = no; then
 383    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 384      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 385 fi
 386
 387 # Whether we should use arguments to main()
 388 if test -z "$enable_main_args"; then
 389    enable_main_args=${enable_main_args_default-yes}
 390 fi
 391 if test "$enable_main_args" = no; then
 392    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 393 fi
 394
 395
 396 # Should we use hashtable-based synchronization?
 397 # Currently works only for Linux X86/ia64
 398 # Typically faster and more space-efficient
 399 AC_ARG_ENABLE(hash-synchronization,
 400   AS_HELP_STRING([--enable-hash-synchronization],
 401                  [use global hash table for monitor locks]))
 402
 403 if test -z "$enable_hash_synchronization"; then
 404    enable_hash_synchronization=$enable_hash_synchronization_default
 405 fi
 406
 407 AC_ARG_WITH(java-home,
 408   AS_HELP_STRING([--with-java-home=DIRECTORY],
 409                  [value of java.home system property]),
 410                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 411 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 412 AC_SUBST(JAVA_HOME)
 413
 414 # What is the native OS API for MinGW?
 415 AC_ARG_WITH(win32-nlsapi,
 416   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 417                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 418 [case "${withval}" in
 419   ansi) with_win32_nlsapi=ansi ;;
 420   unicows) with_win32_nlsapi=unicows ;;
 421   unicode) with_win32_nlsapi=unicode ;;
 422   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 423 esac],[with_win32_nlsapi=ansi])
 424
 425 case "${with_win32_nlsapi}" in
 426   unicows | unicode)
 427     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 428       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 429     ;;
 430 esac
 431
 432 # configure.host sets slow_pthread_self if the synchronization code should
 433 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 434 if test "${slow_pthread_self}" = "yes"; then
 435   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 436     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 437 fi
 438
 439 # Check for gc debugging.  This option is handled both here and in the GC.
 440 AC_ARG_ENABLE(gc-debug,
 441    AS_HELP_STRING([--enable-gc-debug],
 442                   [include full support for pointer backtracing etc.]),
 443 [ if test "$enable_gc_debug" = "yes"; then
 444     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 445               [Define if we want to use debug calls into the garbage collector.])
 446   fi])
 447
 448 # See if the user has the interpreter included.
 449 AC_ARG_ENABLE(interpreter,
 450   AS_HELP_STRING([--enable-interpreter],
 451                  [enable interpreter]),
 452   [if test "$enable_interpreter" = yes; then
 453     # This can also be set in configure.host.
 454     libgcj_interpreter=yes
 455   elif test "$enable_interpreter" = no; then
 456     libgcj_interpreter=no
 457   fi])
 458
 459 if test "$libgcj_interpreter" = yes; then
 460    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 461 fi
 462 INTERPRETER="$libgcj_interpreter"
 463 AC_SUBST(INTERPRETER)
 464
 465 AC_MSG_CHECKING([for exception model to use])
 466 AC_LANG_PUSH(C++)
 467 AC_ARG_ENABLE(sjlj-exceptions,
 468   AS_HELP_STRING([--enable-sjlj-exceptions],
 469                  [force use of builtin_setjmp for exceptions]),
 470 [:],
 471 [dnl Botheration.  Now we've got to detect the exception model.
 472 dnl Link tests against libgcc.a are problematic since -- at least
 473 dnl as of this writing -- we've not been given proper -L bits for
 474 dnl single-tree newlib and libgloss.
 475 dnl
 476 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 477 dnl conftest files before we got a change to grep them first.
 478 cat > conftest.$ac_ext << EOF
 479 [#]line __oline__ "configure"
 480 struct S { ~S(); };
 481 void bar();
 482 void foo()
 483 {
 484   S s;
 485   bar();
 486 }
 487 EOF
 488 old_CXXFLAGS="$CXXFLAGS"
 489 CXXFLAGS=-S
 490 if AC_TRY_EVAL(ac_compile); then
 491   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 492     enable_sjlj_exceptions=yes
 493   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 494     enable_sjlj_exceptions=no
 495   fi
 496 fi
 497 CXXFLAGS="$old_CXXFLAGS"
 498 rm -f conftest*])
 499 if test x$enable_sjlj_exceptions = xyes; then
 500   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 501         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 502   ac_exception_model_name=sjlj
 503 elif test x$enable_sjlj_exceptions = xno; then
 504   ac_exception_model_name="call frame"
 505 else
 506   AC_MSG_ERROR([unable to detect exception model])
 507 fi
 508 AC_LANG_POP(C++)
 509 AC_MSG_RESULT($ac_exception_model_name)
 510
 511 # If we are non using SJLJ exceptions, and this host does not have support
 512 # for unwinding from a signal handler, enable checked dereferences and divides.
 513 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 514   CHECKREFSPEC=-fcheck-references
 515   DIVIDESPEC=-fuse-divide-subroutine
 516   EXCEPTIONSPEC=
 517 fi
 518
 519 # See if the user wants to disable java.net.  This is the mildly
 520 # ugly way that we admit that target-side configuration sucks.
 521 AC_ARG_ENABLE(java-net,
 522   AS_HELP_STRING([--disable-java-net],
 523                  [disable java.net]))
 524
 525 # Whether java.net is built by default can depend on the target.
 526 if test -z "$enable_java_net"; then
 527    enable_java_net=${enable_java_net_default-yes}
 528 fi
 529 if test "$enable_java_net" = no; then
 530    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 531 fi
 532
 533 # See if the user wants to configure without libffi.  Some
 534 # architectures don't support it, and default values are set in
 535 # configure.host.
 536 AC_ARG_WITH(libffi,
 537   AS_HELP_STRING([--without-libffi],
 538                  [don't use libffi]),
 539   [:],
 540   [with_libffi=${with_libffi_default-yes}])
 541
 542 LIBFFI=
 543 LIBFFIINCS=
 544 if test "$with_libffi" != no; then
 545    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 546    LIBFFI=../libffi/libffi_convenience.la
 547    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 548 fi
 549 AC_SUBST(LIBFFI)
 550 AC_SUBST(LIBFFIINCS)
 551
 552 # See if the user wants to disable JVMPI support.
 553 AC_ARG_ENABLE(jvmpi,
 554   AS_HELP_STRING([--disable-jvmpi],
 555                  [disable JVMPI support]))
 556
 557 if test "$enable_jvmpi" != no; then
 558     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 559 fi
 560
 561 # If the target is an eCos system, use the appropriate eCos
 562 # I/O routines.
 563 # FIXME: this should not be a local option but a global target
 564 # system; at present there is no eCos target.
 565 TARGET_ECOS=${PROCESS-"no"}
 566 AC_ARG_WITH(ecos,
 567 [  --with-ecos             enable runtime eCos target support],
 568 TARGET_ECOS="$with_ecos"
 569 )
 570
 571 supply_backtrace=no
 572
 573 PLATFORM_INNER_NAT_HDRS=
 574 case "$TARGET_ECOS" in
 575    no) case "$host" in
 576       *mingw*)
 577             PLATFORM=Win32
 578             PLATFORMNET=Win32
 579             PLATFORMH=win32.h
 580         CHECK_FOR_BROKEN_MINGW_LD
 581       ;;
 582       *)
 583             PLATFORM=Posix
 584             PLATFORMNET=Posix
 585             PLATFORMH=posix.h
 586             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 587       ;;
 588       esac
 589       ;;
 590    *)
 591       PLATFORM=Ecos
 592       PLATFORMNET=NoNet
 593       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 594       PLATFORMH=posix.h
 595       ;;
 596 esac
 597 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 598 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 599
 600 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 601                                       [Define if you have int32_t and uint32_t.]))
 602 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 603                                         [Define if you have int32_t and uint32_t.]))
 604 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 605                                           [Define if you have u_int32_t]))
 606 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 607                                            [Define if you have u_int32_t]))
 608
 609 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 610 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 611
 612 case "$host" in
 613   *-darwin*) DARWIN_CRT=true ;;
 614   *) DARWIN_CRT=false ;;
 615 esac
 616 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 617
 618 # These may not be defined in a non-ANS conformant embedded system.
 619 # FIXME: Should these case a runtime exception in that case?
 620 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 621                                   [Define is you have 'mktime' in <time.h>]))
 622 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 623                                   [Define is you have 'localtime' in <time.h>]))
 624
 625 # Create the subdirectory for natFile.cc, or the attempt
 626 # to create the link will fail.
 627 test -d java || mkdir java
 628 test -d java/io || mkdir java/io
 629 test -d gnu || mkdir gnu
 630 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 631
 632 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 633 test -d java/lang || mkdir java/lang
 634 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 635 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 636
 637 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 638 test -d java/net || mkdir java/net
 639 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 640 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 641
 642 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 643 test -d gnu/java || mkdir gnu/java
 644 test -d gnu/java/net || mkdir gnu/java/net
 645 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 646 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 647
 648 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 649 test -d gnu/java/nio || mkdir gnu/java/nio
 650 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 651 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 652 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 653 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 654
 655 case "${host}" in
 656     *mingw*)
 657       SYSTEMSPEC="-lgdi32 -lws2_32"
 658       if test "${with_win32_nlsapi}" = "unicows"; then
 659         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 660       fi
 661     ;;
 662     *)
 663       SYSTEMSPEC=
 664     ;;
 665 esac
 666 AC_SUBST(SYSTEMSPEC)
 667
 668 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 669 AC_SUBST(LIBGCJTESTSPEC)
 670
 671 AC_ARG_WITH(system-zlib,
 672   AS_HELP_STRING([--with-system-zlib],
 673                  [use installed libz]))
 674 ZLIBSPEC=
 675 AC_SUBST(ZLIBSPEC)
 676 ZLIBTESTSPEC=
 677 AC_SUBST(ZLIBTESTSPEC)
 678
 679 AC_PATH_XTRA
 680
 681 # determine whether to enable the cairo GTK Graphics2D backend
 682 AC_ARG_ENABLE(gtk-cairo,
 683   AS_HELP_STRING([--enable-gtk-cairo],
 684                  [build the cairo Graphics2D implementation on GTK]))
 685 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 686 if test "x${enable_gtk_cairo}" = xyes
 687 then
 688         PKG_CHECK_MODULES(CAIRO, cairo)
 689         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 690 fi
 691 AC_SUBST(CAIRO_LIBS)
 692 AC_SUBST(CAIRO_CFLAGS)
 693 AC_SUBST(PANGOFT2_LIBS)
 694 AC_SUBST(PANGOFT2_CFLAGS)
 695
 696 # FIXME: this should be _libs on some hosts.
 697 libsubdir=.libs
 698
 699 # extra LD Flags which are required for targets
 700 case "${host}" in
 701 *-*-darwin[[0-7]].*)
 702     # For now we have to disable it on darwin[8-9] because it slows down
 703     # the linking phase. A possible bug in ld?
 704     # on Darwin -single_module speeds up loading of the dynamic libraries.
 705     extra_ldflags_libjava=-Wl,-single_module
 706     ;;
 707 esac
 708 AC_SUBST(extra_ldflags_libjava)
 709
 710 # Allow the GC to be disabled.  Can be useful when debugging.
 711 AC_MSG_CHECKING([for garbage collector to use])
 712 AC_ARG_ENABLE(java-gc,
 713   AS_HELP_STRING([--enable-java-gc=TYPE],
 714                  [choose garbage collector (default is boehm)]),
 715   [GC=$enableval],
 716   [GC=boehm])
 717 GCLIBS=
 718 GCINCS=
 719 GCDEPS=
 720 GCSPEC=
 721 JC1GCSPEC=
 722 GCTESTSPEC=
 723 case "$GC" in
 724  boehm)
 725     AC_MSG_RESULT(boehm)
 726     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 727     JC1GCSPEC='-fuse-boehm-gc'
 728     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 729     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 730     GCOBJS=boehm.lo
 731     GCHDR=boehm-gc.h
 732     # The POSIX thread support needs to know this.
 733     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 734     ;;
 735  no)
 736     AC_MSG_RESULT(none)
 737     GCHDR=no-gc.h
 738     ;;
 739  *)
 740     AC_MSG_ERROR([unrecognized collector "$GC"])
 741     ;;
 742 esac
 743 AC_SUBST(GCLIBS)
 744 AC_SUBST(GCINCS)
 745 AC_SUBST(GCDEPS)
 746 AC_SUBST(GCSPEC)
 747 AC_SUBST(JC1GCSPEC)
 748 AC_SUBST(GCTESTSPEC)
 749 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 750 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 751 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 752
 753
 754 AC_MSG_CHECKING([for thread model used by GCC])
 755 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 756 AC_MSG_RESULT([$THREADS])
 757
 758 case "$THREADS" in
 759  no | none | single)
 760     THREADS=none
 761     ;;
 762  posix | posix95 | pthreads)
 763     THREADS=posix
 764     case "$host" in
 765      *-*-linux*)
 766         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 767         ;;
 768     esac
 769     ;;
 770  win32)
 771     ;;
 772  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 773     AC_MSG_ERROR(thread package $THREADS not yet supported)
 774     ;;
 775  *)
 776     AC_MSG_ERROR($THREADS is an unknown thread package)
 777     ;;
 778 esac
 779
 780 THREADCXXFLAGS=
 781 THREADLDFLAGS=
 782 THREADLIBS=
 783 THREADINCS=
 784 THREADDEPS=
 785 THREADH=
 786 THREADSPEC=
 787 case "$THREADS" in
 788  posix)
 789     case "$host" in
 790      *-*-cygwin*)
 791         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 792         ;;
 793      *-*-freebsd[[1234]]*)
 794         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 795         # merely adds pthread_* functions) but it does have a -pthread switch
 796         # which is required at link-time to select -lc_r *instead* of -lc.
 797         THREADLDFLAGS=-pthread
 798         # Don't set THREADSPEC here as might be expected since -pthread is
 799         # not processed when found within a spec file, it must come from
 800         # the command line.  For now, the user must provide the -pthread
 801         # switch to link code compiled with gcj.  In future, consider adding
 802         # support for weak references to pthread_* functions ala gthr.h API.
 803         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 804         ;;
 805      *-*-freebsd*)
 806         # FreeBSD 5 implements a model much closer to other modern UNIX
 807         # which support threads.  However, it still does not support
 808         # -lpthread.
 809         THREADLDFLAGS=-pthread
 810         THREADSPEC=-lc_r
 811         ;;
 812      alpha*-dec-osf*)
 813         THREADCXXFLAGS=-pthread
 814         # boehm-gc needs some functions from librt, so link that too.
 815         THREADLIBS='-lpthread -lrt'
 816         THREADSPEC='-lpthread -lrt'
 817         ;;
 818      *)
 819         THREADLIBS=-lpthread
 820         THREADSPEC=-lpthread
 821         ;;
 822     esac
 823     THREADH=posix-threads.h
 824     # MIT pthreads doesn't seem to have the mutexattr functions.
 825     # But for now we don't check for it.  We just assume you aren't
 826     # using MIT pthreads.
 827     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 828
 829     # If we're using the Boehm GC, then we happen to know that it
 830     # defines _REENTRANT, so we don't bother.  Eww.
 831     if test "$GC" != boehm; then
 832        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 833     fi
 834     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 835     ;;
 836
 837  win32)
 838     THREADH=win32-threads.h
 839     ;;
 840
 841  none)
 842     THREADH=no-threads.h
 843     ;;
 844 esac
 845 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 846 AC_SUBST(THREADLIBS)
 847 AC_SUBST(THREADINCS)
 848 AC_SUBST(THREADDEPS)
 849 AC_SUBST(THREADSPEC)
 850 AC_SUBST(THREADLDFLAGS)
 851 AC_SUBST(THREADCXXFLAGS)
 852 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 853 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 854 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 855
 856 if test -d sysdep; then true; else mkdir sysdep; fi
 857 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 858 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 859 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 860
 861 HASH_SYNC_SPEC=
 862 # Hash synchronization is only useful with posix threads right now.
 863 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 864    HASH_SYNC_SPEC=-fhash-synchronization
 865    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 866 fi
 867 AC_SUBST(HASH_SYNC_SPEC)
 868
 869 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 870
 871 # We're in the tree with gcc, and need to include some of its headers.
 872 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 873
 874 if test "x${with_newlib}" = "xyes"; then
 875    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 876    # may not work correctly, because the compiler may not be able to
 877    # link executables.
 878
 879    # We assume newlib.  This lets us hard-code the functions we know
 880    # we'll have.
 881    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 882    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 883    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 884    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 885    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 886    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 887    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 888    # This is only for POSIX threads.
 889    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 890    # We also assume we are using gcc, which provides alloca.
 891    AC_DEFINE(HAVE_ALLOCA)
 892
 893    # Assume we do not have getuid and friends.
 894    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 895    PLATFORMNET=NoNet
 896 else
 897    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 898                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 899                    access stat mkdir rename rmdir unlink realpath utime chmod \
 900                    nl_langinfo setlocale \
 901                    inet_pton uname inet_ntoa \
 902                    fork execvp pipe sigaction ftruncate])
 903    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 904    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 905    AC_CHECK_FUNC(backtrace, [
 906      case "$host" in
 907        ia64-*-linux*)
 908          # Has broken backtrace()
 909          ;;
 910        mips*-*-linux*)
 911          # Has broken backtrace(), but we supply our own.
 912          if test -d sysdep; then true; else mkdir -p sysdep; fi
 913          supply_backtrace=yes
 914          AC_DEFINE(HAVE_BACKTRACE, 1,
 915            [Define if your platform has a working backtrace() function.])
 916          ;;
 917        *)
 918          AC_DEFINE(HAVE_BACKTRACE, 1,
 919            [Define if your platform has a working backtrace() function.])
 920          ;;
 921      esac
 922    ], [
 923      case "$host" in
 924        *mingw*)
 925          # Has backtrace() defined in libgcj itself
 926          AC_DEFINE(HAVE_BACKTRACE, 1,
 927            [Define if your platform has a working backtrace() function.])
 928          ;;
 929      esac
 930    ])
 931
 932    AC_CHECK_LIB(dl, dladdr, [
 933      if test "x${disable_dladdr}" = "xyes"; then
 934        #Broken dladdr().
 935        true
 936      else
 937        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 938      fi
 939    ])
 940    if test x"$build" = x"$host"; then
 941      AC_CHECK_FILES(/proc/self/exe, [
 942        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 943    else
 944      case $host in
 945      *-linux*)
 946        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 947        ;;
 948      esac
 949    fi
 950
 951    AM_ICONV
 952    AM_LC_MESSAGES
 953    AC_STRUCT_TIMEZONE
 954
 955    AC_CHECK_FUNCS(gethostbyname_r, [
 956      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 957        [Define if you have the 'gethostbyname_r' function.])
 958      # There are two different kinds of gethostbyname_r.
 959      # We look for the one that returns `int'.
 960      # Hopefully this check is robust enough.
 961      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 962        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 963
 964      case " $GCINCS " in
 965      *" -D_REENTRANT "*) ;;
 966      *)
 967         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 968         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 969         [libjava_cv_gethostbyname_r_needs_reentrant],
 970         [ AC_LANG_PUSH(C++)
 971           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 972             [[gethostbyname_r("", 0, 0);]])],
 973             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 974                 CPPFLAGS_SAVE="$CPPFLAGS"
 975                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 976                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 977                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 978                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 979                 CPPFLAGS="$CPPFLAGS_SAVE"
 980           ])
 981           AC_LANG_POP(C++)
 982         ])
 983         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 984           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 985         fi
 986      ;;
 987      esac
 988
 989      AC_CACHE_CHECK([for struct hostent_data],
 990         [libjava_cv_struct_hostent_data], [dnl
 991         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 992 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 993 # define _REENTRANT 1
 994 #endif
 995 #include <netdb.h>]], [[struct hostent_data data;]])],
 996           [libjava_cv_struct_hostent_data=yes],
 997           [libjava_cv_struct_hostent_data=no])])
 998      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 999        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1000          [Define if struct hostent_data is defined in netdb.h])
1001      fi
1002    ])
1003
1004    # FIXME: libjava source code expects to find a prototype for
1005    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1006    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1007    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1008    # linkage check is enough, yet C++ code requires proper prototypes.)
1009    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1010    AC_CHECK_FUNCS(gethostbyaddr_r, [
1011      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1012        [Define if you have the 'gethostbyaddr_r' function.])
1013      # There are two different kinds of gethostbyaddr_r.
1014      # We look for the one that returns `int'.
1015      # Hopefully this check is robust enough.
1016      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1017        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1018          [Define if gethostbyaddr_r returns 'int'.])])])])
1019
1020    AC_CHECK_FUNCS(gethostname, [
1021      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1022        [Define if you have the 'gethostname' function.])
1023      AC_EGREP_HEADER(gethostname, unistd.h, [
1024        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1025          [Define if gethostname is declared in <unistd.h>.])])])
1026
1027    AC_CHECK_FUNCS(usleep, [
1028      AC_EGREP_HEADER(usleep, unistd.h, [
1029        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1030           [Define if usleep is declared in <unistd.h>.])])])
1031
1032    # Look for these functions in the thread library, but only bother
1033    # if using POSIX threads.
1034    if test "$THREADS" = posix; then
1035       save_LIBS="$LIBS"
1036       LIBS="$LIBS $THREADLIBS"
1037       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1038       # E.g., Solaris.
1039       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1040
1041       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1042       # Solaris 7 the name librt is preferred.
1043       AC_CHECK_FUNCS(sched_yield, , [
1044         AC_CHECK_LIB(rt, sched_yield, [
1045           AC_DEFINE(HAVE_SCHED_YIELD)
1046           THREADLIBS="$THREADLIBS -lrt"
1047           THREADSPEC="$THREADSPEC -lrt"], [
1048           AC_CHECK_LIB(posix4, sched_yield, [
1049             AC_DEFINE(HAVE_SCHED_YIELD)
1050             THREADLIBS="$THREADLIBS -lposix4"
1051             THREADSPEC="$THREADSPEC -lposix4"])])])
1052       LIBS="$save_LIBS"
1053
1054       # We can save a little space at runtime if the mutex has m_count
1055       # or __m_count.  This is a nice hack for Linux.
1056       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1057           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1058         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1059              [Define if pthread_mutex_t has m_count member.]), [
1060         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1061             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1062           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1063             [Define if pthread_mutex_t has __m_count member.]))])
1064    fi
1065
1066    # We require a way to get the time.
1067    time_found=no
1068    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1069    if test "$time_found" = no; then
1070       AC_MSG_ERROR([no function found to get the time])
1071    fi
1072
1073    AC_CHECK_FUNCS(memmove)
1074
1075    # We require memcpy.
1076    memcpy_found=no
1077    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1078    if test "$memcpy_found" = no; then
1079       AC_MSG_ERROR([memcpy is required])
1080    fi
1081
1082    AC_CHECK_LIB(dl, dlopen, [
1083        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
1084
1085    # Some library-finding code we stole from Tcl.
1086    #--------------------------------------------------------------------
1087    #    Check for the existence of the -lsocket and -lnsl libraries.
1088    #    The order here is important, so that they end up in the right
1089    #    order in the command line generated by make.  Here are some
1090    #    special considerations:
1091    #    1. Use "connect" and "accept" to check for -lsocket, and
1092    #       "gethostbyname" to check for -lnsl.
1093    #    2. Use each function name only once:  can't redo a check because
1094    #       autoconf caches the results of the last check and won't redo it.
1095    #    3. Use -lnsl and -lsocket only if they supply procedures that
1096    #       aren't already present in the normal libraries.  This is because
1097    #       IRIX 5.2 has libraries, but they aren't needed and they're
1098    #       bogus:  they goof up name resolution if used.
1099    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1100    #       To get around this problem, check for both libraries together
1101    #       if -lsocket doesn't work by itself.
1102    #--------------------------------------------------------------------
1103
1104    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1105     [gcj_cv_lib_sockets=
1106      gcj_checkBoth=0
1107      unset ac_cv_func_connect
1108      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1109      if test "$gcj_checkSocket" = 1; then
1110          unset ac_cv_func_connect
1111          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1112                       gcj_checkBoth=1)
1113      fi
1114      if test "$gcj_checkBoth" = 1; then
1115          gcj_oldLibs=$LIBS
1116          LIBS="$LIBS -lsocket -lnsl"
1117          unset ac_cv_func_accept
1118          AC_CHECK_FUNC(accept,
1119                        [gcj_checkNsl=0
1120                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1121          unset ac_cv_func_accept
1122          LIBS=$gcj_oldLibs
1123      fi
1124      unset ac_cv_func_gethostbyname
1125      gcj_oldLibs=$LIBS
1126      LIBS="$LIBS $gcj_cv_lib_sockets"
1127      AC_CHECK_FUNC(gethostbyname, ,
1128                    [AC_CHECK_LIB(nsl, main,
1129                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1130      unset ac_cv_func_gethostbyname
1131      LIBS=$gcj_oldLIBS
1132    ])
1133    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1134
1135    if test "$with_system_zlib" = yes; then
1136       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1137    fi
1138
1139    # Test for Gtk stuff, if asked for.
1140    if test "$use_gtk_awt" = yes; then
1141       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1142       AC_SUBST(GTK_CFLAGS)
1143       AC_SUBST(GTK_LIBS)
1144
1145       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1146       AC_SUBST(GLIB_CFLAGS)
1147       AC_SUBST(GLIB_LIBS)
1148
1149       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1150       AC_SUBST(LIBART_CFLAGS)
1151       AC_SUBST(LIBART_LIBS)
1152
1153       # We require the XTest Extension to support java.awt.Robot.
1154       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1155                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1156                    [${X_LIBS}])
1157    fi
1158
1159    # On Solaris, and maybe other architectures, the Boehm collector
1160    # requires -ldl.
1161    if test "$GC" = boehm; then
1162       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1163    fi
1164 fi
1165 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1166
1167 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1168 case $build in
1169     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1170     *)         CLASSPATH_SEPARATOR=':' ;;
1171 esac
1172 AC_SUBST(CLASSPATH_SEPARATOR)
1173
1174 # We must search the source tree for java.lang, since we still don't
1175 # have libgcj.jar nor java/lang/*.class
1176 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1177 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1178
1179 # Since some classes depend on this one, we need its source available
1180 # before we can do any GCJ compilation test :-(
1181 if test ! -f gnu/classpath/Configuration.java; then
1182   test -d gnu || mkdir gnu
1183   test -d gnu/classpath || mkdir gnu/classpath
1184   # Note that it is not crucial that all the values here be correct.
1185   sed -e "s,@prefix@,$prefix," \
1186       -e "s,@VERSION@,$VERSION," \
1187       -e "s,@LIBDEBUG@,false," \
1188       -e "s,@INIT_LOAD_LIBRARY@,false," \
1189       -e "s,@@,$LIBGCJDEBUG," \
1190       -e "s,@default_toolkit@,$TOOLKIT," \
1191       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1192       -e "s,@GTK_CAIRO_ENABLED@,false," \
1193         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1194         > gnu/classpath/Configuration.java
1195   # We do not want to redirect the output of the grep below to /dev/null,
1196   # but we add /dev/null to the input list so that grep will print the
1197   # filename of Configuration.java in case it finds any matches.
1198   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1199     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1200   fi
1201 fi
1202
1203 LT_AC_PROG_GCJ
1204
1205 # Now remove it.
1206 rm -f gnu/classpath/Configuration.java
1207
1208 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1209
1210 AC_CHECK_SIZEOF(void *)
1211
1212 AC_C_BIGENDIAN
1213
1214 ZLIBS=
1215 SYS_ZLIBS=
1216 ZINCS=
1217
1218 if test -z "$ZLIBSPEC"; then
1219    # Use zlib from the GCC tree.
1220    ZINCS='-I$(top_srcdir)/../zlib'
1221    ZLIBS=../zlib/libzgcj_convenience.la
1222 else
1223    # System's zlib.
1224    SYS_ZLIBS="$ZLIBSPEC"
1225 fi
1226 AC_SUBST(ZLIBS)
1227 AC_SUBST(SYS_ZLIBS)
1228 AC_SUBST(ZINCS)
1229 AC_SUBST(DIVIDESPEC)
1230 AC_SUBST(CHECKREFSPEC)
1231 AC_SUBST(EXCEPTIONSPEC)
1232 AC_SUBST(BACKTRACESPEC)
1233 AC_SUBST(IEEESPEC)
1234
1235 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1236 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1237 AC_SUBST(GCC_UNWIND_INCLUDE)
1238
1239 # Process the option "--enable-version-specific-runtime-libs"
1240 # Calculate toolexeclibdir
1241 case ${version_specific_libs} in
1242   yes)
1243     # Need the gcc compiler version to know where to install libraries
1244     # and header files if --enable-version-specific-runtime-libs option
1245     # is selected.
1246     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1247     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1248     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1249     toolexeclibdir=$toolexecmainlibdir
1250     ;;
1251   no)
1252     if test -n "$with_cross_host" &&
1253        test x"$with_cross_host" != x"no"; then
1254       # Install a library built with a cross compiler in tooldir, not libdir.
1255       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1256       toolexecmainlibdir='$(toolexecdir)/lib'
1257     else
1258       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1259       toolexecmainlibdir='$(libdir)'
1260     fi
1261     multi_os_directory=`$CC -print-multi-os-directory`
1262     case $multi_os_directory in
1263       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1264       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1265     esac
1266     ;;
1267 esac
1268 AC_SUBST(toolexecdir)
1269 AC_SUBST(toolexecmainlibdir)
1270 AC_SUBST(toolexeclibdir)
1271
1272 # Determine gcj version number.
1273 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1274 GCJVERSION=$gcjversion
1275 AC_SUBST(GCJVERSION)
1276 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1277
1278 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1279 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1280
1281 TL_AC_GXX_INCLUDE_DIR
1282
1283 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1284 # On that system, sys/ioctl.h will not include sys/filio.h unless
1285 # BSD_COMP is defined; just including sys/filio.h is simpler.
1286 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1287 # for now.  If you change this, you also must update natFile.cc.
1288 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1289                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1290                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1291                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1292                   dirent.h])
1293 AC_CHECK_HEADERS(inttypes.h, [
1294     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1295     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1296 ])
1297 AC_HEADER_SYS_WAIT
1298
1299 AC_CHECK_TYPE([ssize_t], [int])
1300
1301 AC_MSG_CHECKING([for in_addr_t])
1302 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1303 #if STDC_HEADERS
1304 #include <stdlib.h>
1305 #include <stddef.h>
1306 #endif
1307 #if HAVE_NETINET_IN_H
1308 #include <netinet/in.h>
1309 #endif]], [[in_addr_t foo;]])],
1310   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1311      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1312    AC_MSG_RESULT(yes)],
1313   [AC_MSG_RESULT(no)])
1314
1315 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1316 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1317   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1318      [Define if struct ip_mreq is defined in netinet/in.h.])
1319    AC_MSG_RESULT(yes)],
1320   [AC_MSG_RESULT(no)])
1321
1322 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1323 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1324   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1325      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1326    AC_MSG_RESULT(yes)],
1327   [AC_MSG_RESULT(no)])
1328
1329 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1330 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1331   [AC_DEFINE(HAVE_INET6, 1,
1332      [Define if inet6 structures are defined in netinet/in.h.])
1333    AC_MSG_RESULT(yes)],
1334   [AC_MSG_RESULT(no)])
1335
1336 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1337 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1338 #include <sys/types.h>
1339 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1340   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1341    AC_MSG_RESULT(yes)],
1342   [AC_MSG_RESULT(no)])
1343
1344 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1345 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1346   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1347    AC_MSG_RESULT(yes)],
1348   [AC_MSG_RESULT(no)
1349    AC_MSG_CHECKING([for global timezone variable])
1350    dnl FIXME: we don't want a link check here because that won't work
1351    dnl when cross-compiling.  So instead we make an assumption that
1352    dnl the header file will mention timezone if it exists.
1353    dnl Don't find the win32 function timezone
1354    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1355      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1356       AC_MSG_RESULT(yes)],
1357      [AC_MSG_RESULT(no)
1358        AC_MSG_CHECKING([for global _timezone variable])
1359        dnl FIXME: As above, don't want link check
1360        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1361          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1362             [Define if your platform has the global _timezone variable.])
1363           AC_MSG_RESULT(yes)],
1364           [AC_MSG_RESULT(no)])])])
1365
1366 AC_FUNC_ALLOCA
1367 AC_FUNC_MMAP
1368
1369 AC_CHECK_PROGS(PERL, perl, false)
1370
1371 SYSDEP_SOURCES=
1372 SIGNAL_HANDLER_AUX=
1373
1374 case "${host}" in
1375  i?86-*-linux*)
1376     SIGNAL_HANDLER=include/i386-signal.h
1377     ;;
1378  sparc*-sun-solaris*)
1379     SIGNAL_HANDLER=include/sparc-signal.h
1380     ;;
1381 # ia64-*)
1382 #    SYSDEP_SOURCES=sysdep/ia64.c
1383 #    test -d sysdep || mkdir sysdep
1384 #    ;;
1385  hppa*-*-linux*)
1386     SIGNAL_HANDLER=include/pa-signal.h
1387     ;;
1388  ia64-*-linux*)
1389     SIGNAL_HANDLER=include/dwarf2-signal.h
1390     ;;
1391  powerpc*-*-linux*)
1392     SIGNAL_HANDLER=include/powerpc-signal.h
1393     ;;
1394  alpha*-*-linux*)
1395     SIGNAL_HANDLER=include/dwarf2-signal.h
1396     ;;
1397  s390*-*-linux*)
1398     SIGNAL_HANDLER=include/s390-signal.h
1399     ;;
1400  x86_64*-*-linux*)
1401     SIGNAL_HANDLER=include/x86_64-signal.h
1402     SIGNAL_HANDLER_AUX=include/i386-signal.h
1403     ;;
1404  sparc*-*-linux*)
1405     SIGNAL_HANDLER=include/dwarf2-signal.h
1406     ;;
1407  sh*-*-linux*)
1408     SIGNAL_HANDLER=include/sh-signal.h
1409     ;;
1410  *mingw*)
1411     SIGNAL_HANDLER=include/win32-signal.h
1412     ;;
1413  mips*-*-linux*)
1414     SIGNAL_HANDLER=include/mips-signal.h
1415     ;;
1416  *-*-darwin*)
1417     SIGNAL_HANDLER=include/darwin-signal.h
1418     ;;
1419  *)
1420     SIGNAL_HANDLER=include/default-signal.h
1421     ;;
1422 esac
1423
1424 # If we're using sjlj exceptions, forget what we just learned.
1425 if test "$enable_sjlj_exceptions" = yes; then
1426    SIGNAL_HANDLER=include/default-signal.h
1427    SIGNAL_HANDLER_AUX=
1428 fi
1429
1430 AC_SUBST(SYSDEP_SOURCES)
1431
1432 if test -z "$SIGNAL_HANDLER_AUX"; then
1433   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1434 fi
1435
1436 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1437                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1438
1439 if test "${multilib}" = "yes"; then
1440   multilib_arg="--enable-multilib"
1441 else
1442   multilib_arg=
1443 fi
1444
1445 # See if we support thread-local storage.
1446 GCC_CHECK_TLS
1447
1448
1449 here=`${PWDCMD-pwd}`
1450 AC_SUBST(here)
1451
1452 # We get this from the environment.
1453 AC_SUBST(GCJFLAGS)
1454
1455 AC_CONFIG_FILES([
1456 Makefile
1457 libgcj.pc
1458 libgcj.spec
1459 libgcj-test.spec
1460 gcj/Makefile
1461 include/Makefile
1462 testsuite/Makefile
1463 ])
1464
1465 AC_CONFIG_COMMANDS([default],
1466 [# Only add multilib support code if we just rebuilt top-level Makefile.
1467 case " $CONFIG_FILES " in
1468  *" Makefile "*)
1469    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1470    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1471    ;;
1472 esac
1473 for ac_multi_file in $CONFIG_FILES; do
1474   case $ac_multi_file in
1475   */Makefile)
1476     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1477   esac
1478 done
1479 ],
1480 srcdir=${srcdir}
1481 host=${host}
1482 target=${target}
1483 with_multisubdir=${with_multisubdir}
1484 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1485 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1486 libgcj_basedir=${libgcj_basedir}
1487 CC="${CC}"
1488 CXX="${CXX}"
1489 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1490 )
1491
1492 AC_OUTPUT