libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_ENABLE(java-maintainer-mode,
  81         AS_HELP_STRING([--enable-java-maintainer-mode],
  82         [allow rebuilding of .class and .h files]))
  83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
  99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 100 save_CXXFLAGS="$CXXFLAGS"
 101 CXXFLAGS="$CXXFLAGS -fno-builtin"
 102 AC_PROG_CC
 103 AC_PROG_CXX
 104 CXXFLAGS="$save_CXXFLAGS"
 105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 106 AC_SUBST(CFLAGS)
 107 AC_SUBST(CXXFLAGS)
 108 AC_SUBST(LDFLAGS)
 109
 110 AM_INIT_AUTOMAKE([1.9.0])
 111
 112 AC_CHECK_TOOL(AS, as)
 113 AC_CHECK_TOOL(LD, ld)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116 AC_PROG_AWK
 117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 118 AC_PATH_PROG([ZIP], [zip], no)
 119 AC_PATH_PROG([UNZIP], [unzip], unzip)
 120
 121 # We need a jar that supports -@.  This is a GNU extension.
 122 if test "$JAR" != no; then
 123    rm -f config-test.jar
 124    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 125    if test -f config-test.jar; then
 126      rm -f config-test.jar
 127    else
 128      JAR=no
 129    fi
 130 fi
 131
 132 # Prefer the jar we found, but fall back to our jar script.
 133 if test "$JAR" = no; then
 134   if test "$ZIP" = no; then
 135     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 136   else
 137     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 138     JAR=`pwd`/scripts/jar
 139   fi
 140 fi
 141
 142 AC_PROG_INSTALL
 143
 144 AM_MAINTAINER_MODE
 145
 146 AC_EXEEXT
 147
 148 # configure.host sets the following important variables
 149 #       libgcj_cflags    - host specific C compiler flags
 150 #       libgcj_cxxflags  - host specific C++ compiler flags
 151 #       libgcj_javaflags - host specific Java compiler flags
 152
 153 libgcj_cflags=
 154 libgcj_cxxflags=
 155 libgcj_javaflags=
 156
 157 . ${srcdir}/configure.host
 158
 159 ACX_PROG_LD_GNU_SYMBOLIC
 160 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 161 if test -z "$libgcj_ld_symbolic"; then
 162   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 163 fi
 164
 165 LIBGCJ_CFLAGS="${libgcj_cflags}"
 166 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 167 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 168 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 169 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 170 AC_SUBST(LIBGCJ_CFLAGS)
 171 AC_SUBST(LIBGCJ_CXXFLAGS)
 172 AC_SUBST(LIBGCJ_JAVAFLAGS)
 173 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 174 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 175
 176 # Only use libltdl for non-newlib builds.
 177 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 178    AC_LTDL_SHLIBPATH
 179 fi
 180
 181 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 182
 183 # See if the user has requested runtime debugging.
 184 LIBGCJDEBUG="disable"
 185 AC_SUBST(LIBGCJDEBUG)
 186 AC_ARG_ENABLE(libgcj-debug,
 187   AS_HELP_STRING([--enable-libgcj-debug],
 188                  [enable runtime debugging code]),
 189   [if test "$enable_libgcj_debug" = yes; then
 190     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 191     LIBGCJDEBUG="enable"
 192   fi])
 193
 194 AC_ARG_WITH([escher],
 195          AS_HELP_STRING([--with-escher=ABS.PATH],
 196                         [specify path to escher dir or JAR for X peers]))
 197 case "$with_escher" in
 198 "")
 199         use_escher=false
 200         ;;
 201 "no")
 202         use_escher=false
 203         ;;
 204 "yes")
 205         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 206         ;;
 207 *)
 208         use_escher=true
 209         ;;
 210 esac
 211
 212 # Determine which AWT peer libraries to build
 213 AC_ARG_ENABLE(java-awt,
 214   AS_HELP_STRING([--enable-java-awt],
 215                  [list of AWT peer implementations to be built]))
 216
 217 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 218 use_xlib_awt=""
 219 use_gtk_awt=""
 220 use_qt_awt=""
 221 use_x_awt=""
 222 # The default toolkit to use is the first one specified.
 223 TOOLKIT=
 224 AC_SUBST(TOOLKIT)
 225
 226 for peer in $peerlibs ; do
 227   case $peer in
 228     xlib)
 229       if test "$no_x" = yes; then
 230         echo "*** xlib peers requested but no X library available" 1>&2
 231         exit 1
 232       else
 233         use_xlib_awt="yes"
 234         if test -z "$TOOLKIT"; then
 235            TOOLKIT=gnu.awt.xlib.XToolkit
 236         fi
 237       fi
 238       ;;
 239     gtk)
 240       if test "$no_x" = yes; then
 241          echo "*** gtk peers requested but no X library available" 1>&2
 242          exit 1
 243       else
 244          use_gtk_awt=yes
 245          if test -z "$TOOLKIT"; then
 246             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 247          fi
 248       fi
 249       ;;
 250     qt)
 251       if test "$no_x" = yes; then
 252          # Perhaps we should admit the possibility of embedded Qt.
 253          echo "*** Qt peers requested but no X library available" 1>&2
 254          exit 1
 255       else
 256          use_qt_awt=yes
 257          if test -z "$TOOLKIT"; then
 258             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 259          fi
 260       fi
 261       ;;
 262     x)
 263       use_x_awt=yes
 264       if test -z "$TOOLKIT"; then
 265          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 266       fi
 267       ;;
 268     no)
 269       use_xlib_awt=
 270       use_gtk_awt=
 271       use_qt_awt=
 272       use_x_awt=
 273       break
 274       ;;
 275     *)
 276       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 277       exit 1
 278   esac
 279 done
 280
 281 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 282 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 283
 284 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 285
 286 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 287
 288 # Create standard.omit based on decisions we just made.
 289 cp $srcdir/standard.omit.in standard.omit
 290 if test "$use_xlib_awt" != yes; then
 291    echo gnu/awt/xlib >> standard.omit
 292    echo gnu/gcj/xlib >> standard.omit
 293 fi
 294 if test "$use_x_awt" != yes; then
 295    echo gnu/java/awt/peer/x >> standard.omit
 296 fi
 297
 298 # Tools that need to be compiled against classpath's tools classes
 299 : > vm-tools-packages
 300 for package in gnu/gcj/tools/gc_analyze ; do
 301     echo $package >> standard.omit
 302     echo $package >> vm-tools-packages
 303 done
 304
 305 if test -z "${with_multisubdir}"; then
 306    builddotdot=.
 307 else
 308    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 309 fi
 310
 311 NATIVE=yes
 312
 313 # Which gcj and host gcj (for ecjx) do we use?
 314 which_gcj=default
 315 host_exeext=${ac_exeext}
 316 GCJ_FOR_ECJX=
 317 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 318 if test -n "${with_cross_host}"; then
 319   # We are being configured with a cross compiler. We can't
 320   # use ac_exeext, because that is for the target platform.
 321   NATIVE=no
 322   cross_host_exeext=
 323   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 324   case "${with_cross_host}" in
 325      *mingw* | *cygwin*)
 326          cross_host_exeext=.exe
 327      ;;
 328   esac
 329   host_exeext=${cross_host_exeext}
 330   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 331      if test x"$build_noncanonical" = x"$with_cross_host"; then
 332         # Ordinary cross (host!=target and host=build)
 333         which_gcj=built
 334      else
 335         # Canadian cross (host!=target and host!=build)
 336         which_gcj=cross
 337      fi
 338   else
 339      which_gcj=cross
 340   fi
 341 else
 342   # We are being configured with a native or crossed-native compiler
 343   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 344      if test x"$build" = x"$host"; then
 345         # True native build (host=target and host=build)
 346         which_gcj=built
 347      else
 348         # Crossed-native build (host=target and host!=build)
 349         which_gcj=cross
 350      fi
 351   else
 352      which_gcj=path
 353   fi
 354 fi
 355 case "${which_gcj}" in
 356    built)
 357       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 358       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 359    ;;
 360    cross)
 361       if test "x${with_newlib}" = "xyes"; then
 362          # FIXME (comment): Why is this needed?
 363          GCC_UNWIND_INCLUDE=
 364          GCJ="${target_noncanonical}-gcj"
 365       else
 366          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 367       fi
 368       GCJH='$(target_noncanonical)-gcjh'
 369    ;;
 370    path)
 371       GCJ="gcj -B`${PWDCMD-pwd}`/"
 372       GCJH=gcjh
 373    ;;
 374 esac
 375
 376 AC_SUBST(GCJ_FOR_ECJX)
 377 AC_SUBST(GCJH)
 378 AC_SUBST(host_exeext)
 379
 380 # Create it, so that compile/link tests don't fail
 381 test -f libgcj.spec || touch libgcj.spec
 382
 383
 384
 385 # Set up to configure Classpath.
 386 # FIXME: no supported way to pass args in autoconf.
 387 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 388 # Disable tool wrappers to avoid ltdl.h configure check.
 389 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 390 ac_configure_args="$ac_configure_args --disable-load-library"
 391 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 392 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 393 dir1=`cd $srcdir && pwd`
 394 dir2=`pwd`
 395 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 396 ac_configure_args="$ac_configure_args --disable-core-jni"
 397 dnl FIXME?
 398 ac_configure_args="$ac_configure_args --disable-examples"
 399 ac_configure_args="$ac_configure_args --with-glibj=build"
 400 if test "$plugin_enabled" != yes; then
 401   ac_configure_args="$ac_configure_args --disable-plugin"
 402 fi
 403 if test "$gconf_enabled" != yes; then
 404   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 405   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 406 fi
 407 if test "$use_gtk_awt" != yes; then
 408   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 409 fi
 410 if test "$use_qt_awt" != yes; then
 411   ac_configure_args="$ac_configure_args --disable-qt-peer"
 412 else
 413   # We need this as qt is disabled by default in classpath.
 414   ac_configure_args="$ac_configure_args --enable-qt-peer"
 415 fi
 416 if test "$use_x_awt" != yes; then
 417   ac_configure_args="$ac_configure_args --without-escher"
 418 else
 419   # We need this as escher is disabled by default in classpath.
 420   if test "$use_escher" != true; then
 421     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 422   else
 423     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 424   fi
 425 fi
 426 # -Werror causes unavoidable problems in code using alsa.
 427 ac_configure_args="$ac_configure_args --disable-Werror"
 428 dnl --with-gcj=$GCJ
 429 dnl --with-javah=$GCJH
 430 dnl gjdoc?
 431 dnl gtk-cairo -- just export here...
 432 dnl --enable-regen-headers?
 433
 434 # Only use libltdl for non-newlib builds.
 435 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 436    AC_LIBLTDL_CONVENIENCE
 437    AC_LIBTOOL_DLOPEN
 438    DIRLTDL=libltdl
 439    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 440    # Sigh.  Libtool's macro doesn't do the right thing.
 441    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 442    # FIXME: this is a hack.
 443    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 444    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 445 fi
 446 AC_SUBST(INCLTDL)
 447 AC_SUBST(LIBLTDL)
 448 AC_SUBST(DIRLTDL)
 449 AC_PROG_LIBTOOL
 450 AM_PROG_GCJ
 451 AM_PROG_CC_C_O
 452
 453 AC_CONFIG_SUBDIRS(classpath libltdl)
 454
 455 # The -no-testsuite modules omit the test subdir.
 456 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 457
 458 # Should the runtime set system properties by examining the
 459 # environment variable GCJ_PROPERTIES?
 460 AC_ARG_ENABLE(getenv-properties,
 461   AS_HELP_STRING([--disable-getenv-properties],
 462                  [don't set system properties from GCJ_PROPERTIES]))
 463
 464 # Whether GCJ_PROPERTIES is used depends on the target.
 465 if test -z "$enable_getenv_properties"; then
 466    enable_getenv_properties=${enable_getenv_properties_default-yes}
 467 fi
 468 if test "$enable_getenv_properties" = no; then
 469    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 470      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 471 fi
 472
 473 # Whether we should use arguments to main()
 474 if test -z "$enable_main_args"; then
 475    enable_main_args=${enable_main_args_default-yes}
 476 fi
 477 if test "$enable_main_args" = no; then
 478    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 479 fi
 480
 481
 482 # Should we use hashtable-based synchronization?
 483 # Currently works only for Linux X86/ia64
 484 # Typically faster and more space-efficient
 485 AC_ARG_ENABLE(hash-synchronization,
 486   AS_HELP_STRING([--enable-hash-synchronization],
 487                  [use global hash table for monitor locks]))
 488
 489 if test -z "$enable_hash_synchronization"; then
 490    enable_hash_synchronization=$enable_hash_synchronization_default
 491 fi
 492
 493
 494 install_ecj_jar=no
 495 ECJ_BUILD_JAR=
 496 ECJ_JAR=
 497 AC_ARG_WITH(ecj-jar,
 498         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 499         [ECJ_JAR=$withval],
 500         [if test -f $multi_basedir/ecj.jar; then
 501            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 502            ECJ_JAR='$(jardir)/ecj.jar'
 503            install_ecj_jar=yes
 504          fi])
 505 AC_SUBST(ECJ_BUILD_JAR)
 506 AC_SUBST(ECJ_JAR)
 507 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 508 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 509
 510 AC_ARG_WITH(java-home,
 511   AS_HELP_STRING([--with-java-home=DIRECTORY],
 512                  [value of java.home system property]),
 513                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 514 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 515 AC_SUBST(JAVA_HOME)
 516
 517 # What is the native OS API for MinGW?
 518 AC_ARG_WITH(win32-nlsapi,
 519   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 520                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 521 [case "${withval}" in
 522   ansi) with_win32_nlsapi=ansi ;;
 523   unicows) with_win32_nlsapi=unicows ;;
 524   unicode) with_win32_nlsapi=unicode ;;
 525   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 526 esac],[with_win32_nlsapi=ansi])
 527
 528 case "${with_win32_nlsapi}" in
 529   unicows | unicode)
 530     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 531       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 532     ;;
 533 esac
 534
 535 # configure.host sets slow_pthread_self if the synchronization code should
 536 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 537 if test "${slow_pthread_self}" = "yes"; then
 538   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 539     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 540 fi
 541
 542 # Check for gc debugging.  This option is handled both here and in the GC.
 543 AC_ARG_ENABLE(gc-debug,
 544    AS_HELP_STRING([--enable-gc-debug],
 545                   [include full support for pointer backtracing etc.]),
 546 [ if test "$enable_gc_debug" = "yes"; then
 547     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 548               [Define if we want to use debug calls into the garbage collector.])
 549   fi])
 550
 551 # See if the user has the interpreter included.
 552 AC_ARG_ENABLE(interpreter,
 553   AS_HELP_STRING([--enable-interpreter],
 554                  [enable interpreter]),
 555   [if test "$enable_interpreter" = yes; then
 556     # This can also be set in configure.host.
 557     libgcj_interpreter=yes
 558   elif test "$enable_interpreter" = no; then
 559     libgcj_interpreter=no
 560   fi])
 561
 562 if test "$libgcj_interpreter" = yes; then
 563    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 564 fi
 565 INTERPRETER="$libgcj_interpreter"
 566 AC_SUBST(INTERPRETER)
 567 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 568
 569 AC_MSG_CHECKING([for exception model to use])
 570 AC_LANG_PUSH(C++)
 571 AC_ARG_ENABLE(sjlj-exceptions,
 572   AS_HELP_STRING([--enable-sjlj-exceptions],
 573                  [force use of builtin_setjmp for exceptions]),
 574 [:],
 575 [dnl Botheration.  Now we've got to detect the exception model.
 576 dnl Link tests against libgcc.a are problematic since -- at least
 577 dnl as of this writing -- we've not been given proper -L bits for
 578 dnl single-tree newlib and libgloss.
 579 dnl
 580 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 581 dnl conftest files before we got a change to grep them first.
 582 cat > conftest.$ac_ext << EOF
 583 [#]line __oline__ "configure"
 584 struct S { ~S(); };
 585 void bar();
 586 void foo()
 587 {
 588   S s;
 589   bar();
 590 }
 591 EOF
 592 old_CXXFLAGS="$CXXFLAGS"
 593 CXXFLAGS=-S
 594 if AC_TRY_EVAL(ac_compile); then
 595   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 596     enable_sjlj_exceptions=yes
 597   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 598     enable_sjlj_exceptions=no
 599   fi
 600 fi
 601 CXXFLAGS="$old_CXXFLAGS"
 602 rm -f conftest*])
 603 if test x$enable_sjlj_exceptions = xyes; then
 604   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 605         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 606   ac_exception_model_name=sjlj
 607 elif test x$enable_sjlj_exceptions = xno; then
 608   ac_exception_model_name="call frame"
 609 else
 610   AC_MSG_ERROR([unable to detect exception model])
 611 fi
 612 AC_LANG_POP(C++)
 613 AC_MSG_RESULT($ac_exception_model_name)
 614
 615 # If we are non using SJLJ exceptions, and this host does not have support
 616 # for unwinding from a signal handler, enable checked dereferences and divides.
 617 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 618   CHECKREFSPEC=-fcheck-references
 619   DIVIDESPEC=-fuse-divide-subroutine
 620   EXCEPTIONSPEC=
 621 fi
 622
 623 # See if the user wants to disable java.net.  This is the mildly
 624 # ugly way that we admit that target-side configuration sucks.
 625 AC_ARG_ENABLE(java-net,
 626   AS_HELP_STRING([--disable-java-net],
 627                  [disable java.net]))
 628
 629 # Whether java.net is built by default can depend on the target.
 630 if test -z "$enable_java_net"; then
 631    enable_java_net=${enable_java_net_default-yes}
 632 fi
 633 if test "$enable_java_net" = no; then
 634    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 635 fi
 636
 637 # See if the user wants to configure without libffi.  Some
 638 # architectures don't support it, and default values are set in
 639 # configure.host.
 640 AC_ARG_WITH(libffi,
 641   AS_HELP_STRING([--without-libffi],
 642                  [don't use libffi]),
 643   [:],
 644   [with_libffi=${with_libffi_default-yes}])
 645
 646 LIBFFI=
 647 LIBFFIINCS=
 648 if test "$with_libffi" != no; then
 649    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 650    LIBFFI=../libffi/libffi_convenience.la
 651    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 652 fi
 653 AC_SUBST(LIBFFI)
 654 AC_SUBST(LIBFFIINCS)
 655
 656 # See if the user wants to disable JVMPI support.
 657 AC_ARG_ENABLE(jvmpi,
 658   AS_HELP_STRING([--disable-jvmpi],
 659                  [disable JVMPI support]))
 660
 661 if test "$enable_jvmpi" != no; then
 662     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 663 fi
 664
 665 # If the target is an eCos system, use the appropriate eCos
 666 # I/O routines.
 667 # FIXME: this should not be a local option but a global target
 668 # system; at present there is no eCos target.
 669 TARGET_ECOS=${PROCESS-"no"}
 670 AC_ARG_WITH(ecos,
 671 [  --with-ecos             enable runtime eCos target support],
 672 TARGET_ECOS="$with_ecos"
 673 )
 674
 675 case "$TARGET_ECOS" in
 676    no) case "$host" in
 677       *mingw*)
 678             PLATFORM=Win32
 679             PLATFORMNET=Win32
 680             PLATFORMH=win32.h
 681         CHECK_FOR_BROKEN_MINGW_LD
 682       ;;
 683       *)
 684             PLATFORM=Posix
 685             PLATFORMNET=Posix
 686             PLATFORMH=posix.h
 687       ;;
 688       esac
 689       ;;
 690    *)
 691       PLATFORM=Ecos
 692       PLATFORMNET=NoNet
 693       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 694       PLATFORMH=posix.h
 695       ;;
 696 esac
 697 AC_SUBST(PLATFORM)
 698 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 699
 700 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 701                                       [Define if you have int32_t and uint32_t.]))
 702 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 703                                         [Define if you have int32_t and uint32_t.]))
 704 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 705                                           [Define if you have u_int32_t]))
 706 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 707                                            [Define if you have u_int32_t]))
 708
 709 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 710 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 711
 712 case "$host" in
 713   *-darwin*) DARWIN_CRT=true ;;
 714   *) DARWIN_CRT=false ;;
 715 esac
 716 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 717
 718 # This may not be defined in a non-ANS conformant embedded system.
 719 # FIXME: Should these case a runtime exception in that case?
 720 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 721                                   [Define is you have 'localtime' in <time.h>]))
 722
 723 # Create the subdirectory for natFile.cc, or the attempt
 724 # to create the link will fail.
 725 test -d java || mkdir java
 726 test -d java/io || mkdir java/io
 727 test -d gnu || mkdir gnu
 728 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 729
 730 # Likewise for natConcreteProcess.cc.
 731 test -d java/lang || mkdir java/lang
 732 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 733
 734 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 735 test -d java/net || mkdir java/net
 736 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 737 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 738
 739 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 740 test -d gnu/java || mkdir gnu/java
 741 test -d gnu/java/net || mkdir gnu/java/net
 742 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 743 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 744
 745 # Likewise for natVMPipe.cc and natVMSelector.cc.
 746 test -d gnu/java/nio || mkdir gnu/java/nio
 747 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 748 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 749
 750 # Likewise for natFileChannelImpl.cc
 751 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 752 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 753
 754 case "${host}" in
 755     *mingw*)
 756       SYSTEMSPEC="-lgdi32 -lws2_32"
 757       if test "${with_win32_nlsapi}" = "unicows"; then
 758         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 759       fi
 760     ;;
 761     *)
 762       SYSTEMSPEC=
 763     ;;
 764 esac
 765 AC_SUBST(SYSTEMSPEC)
 766
 767 AC_ARG_WITH(system-zlib,
 768   AS_HELP_STRING([--with-system-zlib],
 769                  [use installed libz]))
 770 ZLIBSPEC=
 771 AC_SUBST(ZLIBSPEC)
 772 ZLIBTESTSPEC=
 773 AC_SUBST(ZLIBTESTSPEC)
 774
 775 AC_PATH_XTRA
 776
 777 # FIXME: this should be _libs on some hosts.
 778 libsubdir=.libs
 779
 780 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 781
 782 LIBSTDCXXSPEC=
 783 # extra LD Flags which are required for targets
 784 case "${host}" in
 785 *-*-darwin[[0-7]].*)
 786     # For now we have to disable it on darwin[8-9] because it slows down
 787     # the linking phase. A possible bug in ld?
 788     # on Darwin -single_module speeds up loading of the dynamic libraries.
 789     extra_ldflags_libjava=-Wl,-single_module
 790     ;;
 791 *-*-darwin[[9]]*)
 792     extra_gij_ldflags=-Wl,-allow_stack_execute
 793     ;;
 794 arm*linux*eabi)
 795     # Some of the ARM unwinder code is actually in libstdc++.  We
 796     # could in principle replicate it in libgcj, but it's better to
 797     # have a dependency on libstdc++.
 798     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 799     LIBSTDCXXSPEC=-lstdc++
 800     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 801     ;;
 802 esac
 803 AC_SUBST(extra_ldflags_libjava)
 804 AC_SUBST(extra_gij_ldflags)
 805 AC_SUBST(extra_ldflags)
 806 AC_SUBST(LIBSTDCXXSPEC)
 807
 808 AC_SUBST(LIBGCJTESTSPEC)
 809
 810 # Allow the GC to be disabled.  Can be useful when debugging.
 811 AC_MSG_CHECKING([for garbage collector to use])
 812 AC_ARG_ENABLE(java-gc,
 813   AS_HELP_STRING([--enable-java-gc=TYPE],
 814                  [choose garbage collector (default is boehm)]),
 815   [GC=$enableval],
 816   [GC=boehm])
 817 GCLIBS=
 818 GCINCS=
 819 GCDEPS=
 820 GCSPEC=
 821 JC1GCSPEC=
 822 GCTESTSPEC=
 823 case "$GC" in
 824  boehm)
 825     AC_MSG_RESULT(boehm)
 826     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 827     JC1GCSPEC='-fuse-boehm-gc'
 828     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 829     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 830     GCOBJS=boehm.lo
 831     GCHDR=boehm-gc.h
 832     # The POSIX thread support needs to know this.
 833     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 834     ;;
 835  no)
 836     AC_MSG_RESULT(none)
 837     GCHDR=no-gc.h
 838     ;;
 839  *)
 840     AC_MSG_ERROR([unrecognized collector "$GC"])
 841     ;;
 842 esac
 843 AC_SUBST(GCLIBS)
 844 AC_SUBST(GCINCS)
 845 AC_SUBST(GCDEPS)
 846 AC_SUBST(GCSPEC)
 847 AC_SUBST(JC1GCSPEC)
 848 AC_SUBST(GCTESTSPEC)
 849 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 850 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 851 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 852
 853
 854 AC_MSG_CHECKING([for thread model used by GCC])
 855 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 856 AC_MSG_RESULT([$THREADS])
 857
 858 case "$THREADS" in
 859  no | none | single)
 860     THREADS=none
 861     ;;
 862  posix | posix95 | pthreads)
 863     THREADS=posix
 864     case "$host" in
 865      *-*-linux*)
 866         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 867         ;;
 868     esac
 869     ;;
 870  win32)
 871     ;;
 872  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 873     AC_MSG_ERROR(thread package $THREADS not yet supported)
 874     ;;
 875  *)
 876     AC_MSG_ERROR($THREADS is an unknown thread package)
 877     ;;
 878 esac
 879
 880 THREADCXXFLAGS=
 881 THREADLDFLAGS=
 882 THREADLIBS=
 883 THREADINCS=
 884 THREADDEPS=
 885 THREADH=
 886 THREADSPEC=
 887 THREADSTARTFILESPEC=
 888 case "$THREADS" in
 889  posix)
 890     case "$host" in
 891      *-*-cygwin*)
 892         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 893         ;;
 894      *-*-freebsd[[1234]]*)
 895         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 896         # merely adds pthread_* functions) but it does have a -pthread switch
 897         # which is required at link-time to select -lc_r *instead* of -lc.
 898         THREADLDFLAGS=-pthread
 899         # Don't set THREADSPEC here as might be expected since -pthread is
 900         # not processed when found within a spec file, it must come from
 901         # the command line.  For now, the user must provide the -pthread
 902         # switch to link code compiled with gcj.  In future, consider adding
 903         # support for weak references to pthread_* functions ala gthr.h API.
 904         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 905         ;;
 906      *-*-freebsd*)
 907         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 908         # systems which support threads and -lpthread.
 909         THREADLDFLAGS=-pthread
 910         THREADSPEC=-lpthread
 911         ;;
 912      alpha*-dec-osf* | hppa*-hp-hpux*)
 913         THREADCXXFLAGS=-pthread
 914         # boehm-gc needs some functions from librt, so link that too.
 915         THREADLIBS='-lpthread -lrt'
 916         THREADSPEC='-lpthread -lrt'
 917         ;;
 918      *)
 919         THREADLIBS=-lpthread
 920         THREADSPEC=-lpthread
 921         ;;
 922     esac
 923     THREADH=posix-threads.h
 924     # MIT pthreads doesn't seem to have the mutexattr functions.
 925     # But for now we don't check for it.  We just assume you aren't
 926     # using MIT pthreads.
 927     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 928
 929     # If we're using the Boehm GC, then we happen to know that it
 930     # defines _REENTRANT, so we don't bother.  Eww.
 931     if test "$GC" != boehm; then
 932        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 933     fi
 934     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 935     ;;
 936
 937  win32)
 938     THREADH=win32-threads.h
 939     THREADCXXFLAGS=-mthreads
 940     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 941     # But we do not want the executables created to be dependent on
 942     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 943     # exception handling contexts.  The following kludge achieves this effect
 944     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 945     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 946     # A workaround is to explicitly use -mthreads while linking Java programs.
 947     # See PR libgcj/28263.
 948     #
 949     # FIXME: In Java we are able to detect thread death at the end of
 950     # Thread.run() so we should be able to clean up the exception handling
 951     # contexts ourselves.
 952     THREADSTARTFILESPEC='crtmt%O%s'
 953     ;;
 954
 955  none)
 956     THREADH=no-threads.h
 957     ;;
 958 esac
 959 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 960 AC_SUBST(THREADLIBS)
 961 AC_SUBST(THREADINCS)
 962 AC_SUBST(THREADDEPS)
 963 AC_SUBST(THREADSPEC)
 964 AC_SUBST(THREADSTARTFILESPEC)
 965 AC_SUBST(THREADLDFLAGS)
 966 AC_SUBST(THREADCXXFLAGS)
 967 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 968 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 969 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 970 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 971
 972 if test -d sysdep; then true; else mkdir sysdep; fi
 973 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 974 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 975 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 976
 977 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 978 if test "$use_libgcj_bc" = yes; then
 979   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 980 fi
 981 AC_SUBST(LIBGCJ_SPEC)
 982
 983 HASH_SYNC_SPEC=
 984 # Hash synchronization is only useful with posix threads right now.
 985 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 986    HASH_SYNC_SPEC=-fhash-synchronization
 987    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 988 fi
 989 AC_SUBST(HASH_SYNC_SPEC)
 990
 991 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 992
 993 # We're in the tree with gcc, and need to include some of its headers.
 994 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
 995
 996 if test "x${with_newlib}" = "xyes"; then
 997    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 998    # may not work correctly, because the compiler may not be able to
 999    # link executables.
1000
1001    # We assume newlib.  This lets us hard-code the functions we know
1002    # we'll have.
1003    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1004    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1005    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1006    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1007    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1008    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1009    # This is only for POSIX threads.
1010    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1011
1012    # Assume we do not have getuid and friends.
1013    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1014    PLATFORMNET=NoNet
1015 else
1016    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1017                    localtime_r readdir_r getpwuid_r getcwd \
1018                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1019                    nl_langinfo setlocale \
1020                    inet_pton uname inet_ntoa \
1021                    getrlimit sigaction ftruncate mmap \
1022                    getifaddrs])
1023    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1024    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1025    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1026    AC_CHECK_LIB(dl, dladdr, [
1027        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1028        AC_CHECK_LIB(dld, dladdr, [
1029        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1030
1031    if test x"$cross_compiling" = x"no"; then
1032      AC_CHECK_FILES(/proc/self/exe, [
1033        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1034      AC_CHECK_FILES(/proc/self/maps, [
1035        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1036          [Define if you have /proc/self/maps])])
1037    else
1038      case $host in
1039      *-linux*)
1040        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1041        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1042        ;;
1043      esac
1044    fi
1045
1046    AM_ICONV
1047    AM_LC_MESSAGES
1048    AC_STRUCT_TIMEZONE
1049
1050    AC_CHECK_FUNCS(gethostbyname_r, [
1051      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1052        [Define if you have the 'gethostbyname_r' function.])
1053      # There are two different kinds of gethostbyname_r.
1054      # We look for the one that returns `int'.
1055      # Hopefully this check is robust enough.
1056      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1057        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1058
1059      case " $GCINCS " in
1060      *" -D_REENTRANT "*) ;;
1061      *)
1062         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1063         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1064         [libjava_cv_gethostbyname_r_needs_reentrant],
1065         [ AC_LANG_PUSH(C++)
1066           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1067             [[gethostbyname_r("", 0, 0);]])],
1068             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1069                 CPPFLAGS_SAVE="$CPPFLAGS"
1070                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1071                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1072                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1073                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1074                 CPPFLAGS="$CPPFLAGS_SAVE"
1075           ])
1076           AC_LANG_POP(C++)
1077         ])
1078         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1079           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1080         fi
1081      ;;
1082      esac
1083
1084      AC_CACHE_CHECK([for struct hostent_data],
1085         [libjava_cv_struct_hostent_data], [dnl
1086         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1087 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1088 # define _REENTRANT 1
1089 #endif
1090 #include <netdb.h>]], [[struct hostent_data data;]])],
1091           [libjava_cv_struct_hostent_data=yes],
1092           [libjava_cv_struct_hostent_data=no])])
1093      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1094        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1095          [Define if struct hostent_data is defined in netdb.h])
1096      fi
1097    ])
1098
1099    # FIXME: libjava source code expects to find a prototype for
1100    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1101    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1102    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1103    # linkage check is enough, yet C++ code requires proper prototypes.)
1104    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1105    AC_CHECK_FUNCS(gethostbyaddr_r, [
1106      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1107        [Define if you have the 'gethostbyaddr_r' function.])
1108      # There are two different kinds of gethostbyaddr_r.
1109      # We look for the one that returns `int'.
1110      # Hopefully this check is robust enough.
1111      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1112        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1113          [Define if gethostbyaddr_r returns 'int'.])])])])
1114
1115    AC_CHECK_FUNCS(gethostname, [
1116      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1117        [Define if you have the 'gethostname' function.])
1118      AC_EGREP_HEADER(gethostname, unistd.h, [
1119        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1120          [Define if gethostname is declared in <unistd.h>.])])])
1121
1122    AC_CHECK_FUNCS(usleep, [
1123      AC_EGREP_HEADER(usleep, unistd.h, [
1124        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1125           [Define if usleep is declared in <unistd.h>.])])])
1126
1127    # Look for these functions in the thread library, but only bother
1128    # if using POSIX threads.
1129    if test "$THREADS" = posix; then
1130       save_LIBS="$LIBS"
1131       LIBS="$LIBS $THREADLIBS"
1132
1133       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1134       # Solaris 7 the name librt is preferred.
1135       AC_CHECK_FUNCS(sched_yield, , [
1136         AC_CHECK_LIB(rt, sched_yield, [
1137           AC_DEFINE(HAVE_SCHED_YIELD)
1138           THREADLIBS="$THREADLIBS -lrt"
1139           THREADSPEC="$THREADSPEC -lrt"], [
1140           AC_CHECK_LIB(posix4, sched_yield, [
1141             AC_DEFINE(HAVE_SCHED_YIELD)
1142             THREADLIBS="$THREADLIBS -lposix4"
1143             THREADSPEC="$THREADSPEC -lposix4"])])])
1144
1145       AC_CHECK_LIB(rt, clock_gettime, [
1146          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1147          case "$THREADSPEC" in
1148            *-lrt*) ;;
1149            *)
1150              THREADSPEC="$THREADSPEC -lrt"
1151              THREADLIBS="$THREADLIBS -lrt"
1152              ;;
1153          esac])
1154
1155       LIBS="$save_LIBS"
1156
1157       # We can save a little space at runtime if the mutex has m_count
1158       # or __m_count.  This is a nice hack for Linux.
1159       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1160           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1161         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1162              [Define if pthread_mutex_t has m_count member.]), [
1163         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1164             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1165           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1166             [Define if pthread_mutex_t has __m_count member.]))])
1167    fi
1168
1169    # We require a way to get the time.
1170    time_found=no
1171    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1172    if test "$time_found" = no; then
1173       AC_MSG_ERROR([no function found to get the time])
1174    fi
1175
1176    AC_CHECK_FUNCS(memmove)
1177
1178    # We require memcpy.
1179    memcpy_found=no
1180    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1181    if test "$memcpy_found" = no; then
1182       AC_MSG_ERROR([memcpy is required])
1183    fi
1184    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1185    AC_CHECK_LIB(dl, dlopen, [
1186        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1187        AC_CHECK_LIB(dld, dlopen, [
1188        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1189
1190    # Some library-finding code we stole from Tcl.
1191    #--------------------------------------------------------------------
1192    #    Check for the existence of the -lsocket and -lnsl libraries.
1193    #    The order here is important, so that they end up in the right
1194    #    order in the command line generated by make.  Here are some
1195    #    special considerations:
1196    #    1. Use "connect" and "accept" to check for -lsocket, and
1197    #       "gethostbyname" to check for -lnsl.
1198    #    2. Use each function name only once:  can't redo a check because
1199    #       autoconf caches the results of the last check and won't redo it.
1200    #    3. Use -lnsl and -lsocket only if they supply procedures that
1201    #       aren't already present in the normal libraries.  This is because
1202    #       IRIX 5.2 has libraries, but they aren't needed and they're
1203    #       bogus:  they goof up name resolution if used.
1204    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1205    #       To get around this problem, check for both libraries together
1206    #       if -lsocket doesn't work by itself.
1207    #--------------------------------------------------------------------
1208
1209    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1210     [gcj_cv_lib_sockets=
1211      gcj_checkBoth=0
1212      unset ac_cv_func_connect
1213      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1214      if test "$gcj_checkSocket" = 1; then
1215          unset ac_cv_func_connect
1216          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1217                       gcj_checkBoth=1)
1218      fi
1219      if test "$gcj_checkBoth" = 1; then
1220          gcj_oldLibs=$LIBS
1221          LIBS="$LIBS -lsocket -lnsl"
1222          unset ac_cv_func_accept
1223          AC_CHECK_FUNC(accept,
1224                        [gcj_checkNsl=0
1225                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1226          unset ac_cv_func_accept
1227          LIBS=$gcj_oldLibs
1228      fi
1229      unset ac_cv_func_gethostbyname
1230      gcj_oldLibs=$LIBS
1231      LIBS="$LIBS $gcj_cv_lib_sockets"
1232      AC_CHECK_FUNC(gethostbyname, ,
1233                    [AC_CHECK_LIB(nsl, main,
1234                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1235      unset ac_cv_func_gethostbyname
1236      LIBS=$gcj_oldLIBS
1237    ])
1238    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1239
1240    if test "$with_system_zlib" = yes; then
1241       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1242    fi
1243
1244    # Test for Gtk stuff, if asked for.
1245    if test "$use_gtk_awt" = yes; then
1246       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1247       AC_SUBST(GTK_CFLAGS)
1248       AC_SUBST(GTK_LIBS)
1249
1250       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1251       AC_SUBST(GLIB_CFLAGS)
1252       AC_SUBST(GLIB_LIBS)
1253
1254       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1255       AC_SUBST(LIBART_CFLAGS)
1256       AC_SUBST(LIBART_LIBS)
1257
1258       # We require the XTest Extension to support java.awt.Robot.
1259       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1260                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1261                    [${X_LIBS}])
1262    fi
1263
1264    # On Solaris, and maybe other architectures, the Boehm collector
1265    # requires -ldl.
1266    if test "$GC" = boehm; then
1267       case "${host}" in
1268           mips-sgi-irix6*)
1269             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1270             # libgcj.spec is used, so override here
1271             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1272           ;;
1273           *)
1274             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1275           ;;
1276       esac
1277    fi
1278 fi
1279
1280 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1281 case $build in
1282     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1283     *)         CLASSPATH_SEPARATOR=':' ;;
1284 esac
1285 AC_SUBST(CLASSPATH_SEPARATOR)
1286
1287 # We must search the source tree for java.lang, since we still don't
1288 # have libgcj.jar nor java/lang/*.class
1289 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1290 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1291
1292 # Since some classes depend on this one, we need its source available
1293 # before we can do any GCJ compilation test :-(
1294 if test ! -f gnu/classpath/Configuration.java; then
1295   test -d gnu || mkdir gnu
1296   test -d gnu/classpath || mkdir gnu/classpath
1297   # Note that it is not crucial that all the values here be correct.
1298   sed -e "s,@prefix@,$prefix," \
1299       -e "s,@VERSION@,$VERSION," \
1300       -e "s,@LIBDEBUG@,false," \
1301       -e "s,@INIT_LOAD_LIBRARY@,false," \
1302       -e "s,@@,$LIBGCJDEBUG," \
1303       -e "s,@default_toolkit@,$TOOLKIT," \
1304       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1305       -e "s,@GTK_CAIRO_ENABLED@,false," \
1306       -e "s,@ECJ_JAR@,," \
1307         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1308         > gnu/classpath/Configuration.java
1309   # We do not want to redirect the output of the grep below to /dev/null,
1310   # but we add /dev/null to the input list so that grep will print the
1311   # filename of Configuration.java in case it finds any matches.
1312   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1313     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1314   fi
1315 fi
1316
1317 LT_AC_PROG_GCJ
1318
1319 # Now remove it.
1320 rm -f gnu/classpath/Configuration.java
1321
1322 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1323
1324 AC_CHECK_SIZEOF(void *)
1325
1326 AC_C_BIGENDIAN
1327
1328 ZLIBS=
1329 SYS_ZLIBS=
1330 ZINCS=
1331
1332 if test -z "$ZLIBSPEC"; then
1333    # Use zlib from the GCC tree.
1334    ZINCS='-I$(top_srcdir)/../zlib'
1335    ZLIBS=../zlib/libzgcj_convenience.la
1336 else
1337    # System's zlib.
1338    SYS_ZLIBS="$ZLIBSPEC"
1339 fi
1340 AC_SUBST(ZLIBS)
1341 AC_SUBST(SYS_ZLIBS)
1342 AC_SUBST(ZINCS)
1343 AC_SUBST(DIVIDESPEC)
1344 AC_SUBST(CHECKREFSPEC)
1345 AC_SUBST(EXCEPTIONSPEC)
1346 AC_SUBST(BACKTRACESPEC)
1347 AC_SUBST(IEEESPEC)
1348
1349 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1350 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1351 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1352 AC_SUBST(GCC_UNWIND_INCLUDE)
1353
1354 # Process the option "--enable-version-specific-runtime-libs"
1355 # Calculate toolexeclibdir
1356 case ${version_specific_libs} in
1357   yes)
1358     # Need the gcc compiler version to know where to install libraries
1359     # and header files if --enable-version-specific-runtime-libs option
1360     # is selected.
1361     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1362     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1363     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1364     toolexeclibdir=$toolexecmainlibdir
1365     ;;
1366   no)
1367     if test -n "$with_cross_host" &&
1368        test x"$with_cross_host" != x"no"; then
1369       # Install a library built with a cross compiler in tooldir, not libdir.
1370       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1371       toolexecmainlibdir='$(toolexecdir)/lib'
1372     else
1373       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1374       toolexecmainlibdir='$(libdir)'
1375     fi
1376     multi_os_directory=`$CC -print-multi-os-directory`
1377     case $multi_os_directory in
1378       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1379       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1380     esac
1381     ;;
1382 esac
1383 AC_SUBST(toolexecdir)
1384 AC_SUBST(toolexecmainlibdir)
1385 AC_SUBST(toolexeclibdir)
1386
1387 # Determine gcj and libgcj version number.
1388 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1389 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1390 GCJVERSION=$gcjversion
1391 AC_SUBST(GCJVERSION)
1392 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1393
1394 # Determine where the standard .db file and GNU Classpath JNI
1395 # libraries are found.
1396 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1397 multi_os_directory=`$CC -print-multi-os-directory`
1398 case $multi_os_directory in
1399   .)
1400    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1401    ;;
1402   *)
1403    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1404    ;;
1405 esac
1406 AC_SUBST(dbexecdir)
1407
1408 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1409 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1410
1411 TL_AC_GXX_INCLUDE_DIR
1412
1413 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1414 # On that system, sys/ioctl.h will not include sys/filio.h unless
1415 # BSD_COMP is defined; just including sys/filio.h is simpler.
1416 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1417 # for now.  If you change this, you also must update natFile.cc.
1418 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1419                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1420                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1421                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1422                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1423 AC_CHECK_HEADERS(inttypes.h, [
1424     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1425     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1426 ])
1427
1428 AC_CHECK_TYPE([ssize_t], [int])
1429 AC_CHECK_TYPE([magic_t], [
1430     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1431 #ifdef HAVE_MAGIC_H
1432 #include <magic.h>
1433 #endif])
1434
1435 AC_MSG_CHECKING([for in_addr_t])
1436 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1437 #if STDC_HEADERS
1438 #include <stdlib.h>
1439 #include <stddef.h>
1440 #endif
1441 #if HAVE_NETINET_IN_H
1442 #include <netinet/in.h>
1443 #endif]], [[in_addr_t foo;]])],
1444   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1445      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1446    AC_MSG_RESULT(yes)],
1447   [AC_MSG_RESULT(no)])
1448
1449 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1450 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1451   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1452      [Define if struct ip_mreq is defined in netinet/in.h.])
1453    AC_MSG_RESULT(yes)],
1454   [AC_MSG_RESULT(no)])
1455
1456 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1457 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1458   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1459      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1460    AC_MSG_RESULT(yes)],
1461   [AC_MSG_RESULT(no)])
1462
1463 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1464 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1465   [AC_DEFINE(HAVE_INET6, 1,
1466      [Define if inet6 structures are defined in netinet/in.h.])
1467    AC_MSG_RESULT(yes)],
1468   [AC_MSG_RESULT(no)])
1469
1470 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1471 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1472 #include <sys/types.h>
1473 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1474   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1475    AC_MSG_RESULT(yes)],
1476   [AC_MSG_RESULT(no)])
1477
1478 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1479 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1480   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1481    AC_MSG_RESULT(yes)],
1482   [AC_MSG_RESULT(no)
1483    AC_MSG_CHECKING([for global timezone variable])
1484    dnl FIXME: we don't want a link check here because that won't work
1485    dnl when cross-compiling.  So instead we make an assumption that
1486    dnl the header file will mention timezone if it exists.
1487    dnl Don't find the win32 function timezone
1488    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1489      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1490       AC_MSG_RESULT(yes)],
1491      [AC_MSG_RESULT(no)
1492        AC_MSG_CHECKING([for global _timezone variable])
1493        dnl FIXME: As above, don't want link check
1494        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1495          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1496             [Define if your platform has the global _timezone variable.])
1497           AC_MSG_RESULT(yes)],
1498           [AC_MSG_RESULT(no)])])])
1499
1500 AC_CHECK_PROGS(PERL, perl, false)
1501
1502 SYSDEP_SOURCES=
1503 SIGNAL_HANDLER_AUX=
1504
1505 case "${host}" in
1506  i?86-*-linux*)
1507     SIGNAL_HANDLER=include/i386-signal.h
1508     ;;
1509  sparc*-sun-solaris*)
1510     SIGNAL_HANDLER=include/sparc-signal.h
1511     ;;
1512 # ia64-*)
1513 #    SYSDEP_SOURCES=sysdep/ia64.c
1514 #    test -d sysdep || mkdir sysdep
1515 #    ;;
1516  hppa*-*-linux*)
1517     SIGNAL_HANDLER=include/pa-signal.h
1518     ;;
1519  hppa*-hp-hpux*)
1520     SIGNAL_HANDLER=include/hppa-signal.h
1521     ;;
1522  ia64-*-linux*)
1523     SIGNAL_HANDLER=include/dwarf2-signal.h
1524     ;;
1525  powerpc*-*-linux*)
1526     SIGNAL_HANDLER=include/powerpc-signal.h
1527     ;;
1528  alpha*-*-linux*)
1529     SIGNAL_HANDLER=include/dwarf2-signal.h
1530     ;;
1531  s390*-*-linux*)
1532     SIGNAL_HANDLER=include/s390-signal.h
1533     ;;
1534  x86_64*-*-linux*)
1535     SIGNAL_HANDLER=include/x86_64-signal.h
1536     SIGNAL_HANDLER_AUX=include/i386-signal.h
1537     ;;
1538  sparc*-*-linux*)
1539     SIGNAL_HANDLER=include/dwarf2-signal.h
1540     ;;
1541  sh*-*-linux*)
1542     SIGNAL_HANDLER=include/sh-signal.h
1543     ;;
1544  *mingw*)
1545     SIGNAL_HANDLER=include/win32-signal.h
1546     ;;
1547  mips*-*-linux*)
1548     SIGNAL_HANDLER=include/mips-signal.h
1549     ;;
1550  m68*-*-linux*)
1551     SIGNAL_HANDLER=include/dwarf2-signal.h
1552     ;;
1553  powerpc*-*-darwin* | i?86-*-darwin9* | x86_64-*-darwin9*)
1554     SIGNAL_HANDLER=include/darwin-signal.h
1555     ;;
1556  *)
1557     SIGNAL_HANDLER=include/default-signal.h
1558     ;;
1559 esac
1560
1561 # If we're using sjlj exceptions, forget what we just learned.
1562 if test "$enable_sjlj_exceptions" = yes; then
1563    SIGNAL_HANDLER=include/default-signal.h
1564    SIGNAL_HANDLER_AUX=
1565 fi
1566
1567 AC_SUBST(SYSDEP_SOURCES)
1568
1569 if test -z "$SIGNAL_HANDLER_AUX"; then
1570   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1571 fi
1572
1573 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1574                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1575
1576 if test "${multilib}" = "yes"; then
1577   multilib_arg="--enable-multilib"
1578 else
1579   multilib_arg=
1580 fi
1581
1582 # See if we support thread-local storage.
1583 GCC_CHECK_TLS
1584
1585 # For _Unwind_GetIPInfo.
1586 GCC_CHECK_UNWIND_GETIPINFO
1587
1588 # See if linker supports anonymous version scripts.
1589 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1590   [libjava_cv_anon_version_script],
1591   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1592    libjava_cv_anon_version_script=no
1593    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1594    echo '{ global: globalsymb*; local: *; };' > conftest.map
1595    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1596                [libjava_cv_anon_version_script=yes], [])
1597    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1598   ])
1599 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1600
1601 # Check if linker supports static linking on a per library basis
1602 LD_START_STATIC_SPEC=
1603 LD_FINISH_STATIC_SPEC=
1604 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1605   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1606     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1607     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1608   fi
1609 fi
1610 AC_SUBST(LD_START_STATIC_SPEC)
1611 AC_SUBST(LD_FINISH_STATIC_SPEC)
1612
1613 here=`${PWDCMD-pwd}`
1614 AC_SUBST(here)
1615
1616 # We get this from the environment.
1617 AC_SUBST(GCJFLAGS)
1618
1619 AC_CONFIG_FILES([
1620 Makefile
1621 libgcj.pc
1622 libgcj.spec
1623 libgcj-test.spec
1624 gcj/Makefile
1625 include/Makefile
1626 testsuite/Makefile
1627 ])
1628
1629 if test ${multilib} = yes; then
1630   multilib_arg="--enable-multilib"
1631 else
1632   multilib_arg=
1633 fi
1634
1635 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1636 AC_OUTPUT