libjava/classpath/m4/ac_prog_java_works.m4

   1 dnl Available from the GNU Autoconf Macro Archive at:
   2 dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_prog_java_works.html
   3 dnl
   4 AC_DEFUN([AC_PROG_JAVA_WORKS], [
   5 AC_CHECK_PROG(uudecode, uudecode$EXEEXT, yes)
   6 if test x$uudecode = xyes; then
   7 AC_CACHE_CHECK([if uudecode can decode base 64 file], ac_cv_prog_uudecode_base64, [
   8 dnl /**
   9 dnl  * Test.java: used to test if java compiler works.
  10 dnl  */
  11 dnl public class Test
  12 dnl {
  13 dnl
  14 dnl public static void
  15 dnl main( String[] argv )
  16 dnl {
  17 dnl     System.exit (0);
  18 dnl }
  19 dnl
  20 dnl }
  21 cat << \EOF > Test.uue
  22 begin-base64 644 Test.class
  23 yv66vgADAC0AFQcAAgEABFRlc3QHAAQBABBqYXZhL2xhbmcvT2JqZWN0AQAE
  24 bWFpbgEAFihbTGphdmEvbGFuZy9TdHJpbmc7KVYBAARDb2RlAQAPTGluZU51
  25 bWJlclRhYmxlDAAKAAsBAARleGl0AQAEKEkpVgoADQAJBwAOAQAQamF2YS9s
  26 YW5nL1N5c3RlbQEABjxpbml0PgEAAygpVgwADwAQCgADABEBAApTb3VyY2VG
  27 aWxlAQAJVGVzdC5qYXZhACEAAQADAAAAAAACAAkABQAGAAEABwAAACEAAQAB
  28 AAAABQO4AAyxAAAAAQAIAAAACgACAAAACgAEAAsAAQAPABAAAQAHAAAAIQAB
  29 AAEAAAAFKrcAErEAAAABAAgAAAAKAAIAAAAEAAQABAABABMAAAACABQ=
  30 ====
  31 EOF
  32 if uudecode$EXEEXT Test.uue; then
  33         ac_cv_prog_uudecode_base64=yes
  34 else
  35         echo "configure: __oline__: uudecode had trouble decoding base 64 file 'Test.uue'" >&AC_FD_CC
  36         echo "configure: failed file was:" >&AC_FD_CC
  37         cat Test.uue >&AC_FD_CC
  38         ac_cv_prog_uudecode_base64=no
  39 fi
  40 rm -f Test.uue])
  41 fi
  42 if test x$ac_cv_prog_uudecode_base64 != xyes; then
  43         rm -f Test.class
  44         AC_MSG_WARN([I have to compile Test.class from scratch])
  45         if test x$ac_cv_prog_javac_works = xno; then
  46                 AC_MSG_ERROR([Cannot compile java source. $JAVAC does not work properly])
  47         fi
  48         if test x$ac_cv_prog_javac_works = x; then
  49                 AC_PROG_JAVAC
  50         fi
  51 fi
  52 AC_CACHE_CHECK(if $JAVA works, ac_cv_prog_java_works, [
  53 JAVA_TEST=Test.java
  54 CLASS_TEST=Test.class
  55 TEST=Test
  56 changequote(, )dnl
  57 cat << \EOF > $JAVA_TEST
  58 /* [#]line __oline__ "configure" */
  59 public class Test {
  60 public static void main (String args[]) {
  61         System.exit (0);
  62 } }
  63 EOF
  64 changequote([, ])dnl
  65 if test x$ac_cv_prog_uudecode_base64 != xyes; then
  66         if AC_TRY_COMMAND($JAVAC $JAVACFLAGS $JAVA_TEST) && test -s $CLASS_TEST; then
  67                 :
  68         else
  69           echo "configure: failed program was:" >&AC_FD_CC
  70           cat $JAVA_TEST >&AC_FD_CC
  71           AC_MSG_ERROR(The Java compiler $JAVAC failed (see config.log, check the CLASSPATH?))
  72         fi
  73 fi
  74 if AC_TRY_COMMAND(CLASSPATH=.:$CLASSPATH $JAVA $JAVAFLAGS $TEST) >/dev/null 2>&1; then
  75   ac_cv_prog_java_works=yes
  76 else
  77   echo "configure: failed program was:" >&AC_FD_CC
  78   cat $JAVA_TEST >&AC_FD_CC
  79   AC_MSG_ERROR(The Java VM $JAVA failed (see config.log, check the CLASSPATH?))
  80 fi
  81 rm -fr $JAVA_TEST $CLASS_TEST Test.uue
  82 ])
  83 AC_PROVIDE([$0])dnl
  84 ]
  85 )
  86 dnl Available from the GNU Autoconf Macro Archive at:
  87 dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_try_compile_java.html
  88 dnl
  89 AC_DEFUN([AC_TRY_COMPILE_JAVA],[
  90 AC_REQUIRE([AC_PROG_JAVAC])dnl
  91 cat << \EOF > Test.java
  92 /* [#]line __oline__ "configure" */
  93 ifelse([$1], , , [import $1;])
  94 public class Test {
  95 [$2]
  96 }
  97 EOF
  98 if AC_TRY_COMMAND($JAVAC $JAVACFLAGS Test.java) && test -s Test.class
  99 then
 100 dnl Don't remove the temporary files here, so they can be examined.
 101   ifelse([$3], , :, [$3])
 102 else
 103   echo "configure: failed program was:" >&AC_FD_CC
 104   cat Test.java >&AC_FD_CC
 105 ifelse([$4], , , [  rm -fr Test*
 106   $4
 107 ])dnl
 108 fi
 109 rm -fr Test*])