libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.12.1)
   4 AC_INIT(pexecute.c)
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory])
   9 AC_ARG_WITH(cross-host,
  10 [  --with-cross-host=HOST           Configuring with a cross compiler])
  11 AC_ARG_WITH(newlib,
  12 [  --with-newlib                    Configuring with newlib])
  13
  14 if test "${srcdir}" = "."; then
  15   if test -z "${with_target_subdir}"; then
  16     libiberty_topdir="${srcdir}/.."
  17   else
  18     if test "${with_target_subdir}" != "."; then
  19       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  20     else
  21       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  22     fi
  23   fi
  24 else
  25   libiberty_topdir="${srcdir}/.."
  26 fi
  27 AC_CONFIG_AUX_DIR($libiberty_topdir)
  28
  29 AC_CANONICAL_HOST
  30
  31 dnl When we start using automake:
  32 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  33
  34 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  40 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  41 # are probably using a cross compiler, which will not be able to fully
  42 # link an executable.  This should really be fixed in autoconf
  43 # itself.
  44
  45 AC_DEFUN(LIB_AC_PROG_CC,
  46 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  47 AC_PROVIDE([AC_PROG_CC])
  48 AC_CHECK_PROG(CC, gcc, gcc)
  49 if test -z "$CC"; then
  50   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  51   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  52 fi
  53
  54 AC_PROG_CC_GNU
  55
  56 if test $ac_cv_prog_gcc = yes; then
  57   GCC=yes
  58 dnl Check whether -g works, even if CFLAGS is set, in case the package
  59 dnl plays around with CFLAGS (such as to build both debugging and
  60 dnl normal versions of a library), tasteless as that idea is.
  61   ac_test_CFLAGS="${CFLAGS+set}"
  62   ac_save_CFLAGS="$CFLAGS"
  63   CFLAGS=
  64   AC_PROG_CC_G
  65   if test "$ac_test_CFLAGS" = set; then
  66     CFLAGS="$ac_save_CFLAGS"
  67   elif test $ac_cv_prog_cc_g = yes; then
  68     CFLAGS="-g -O2"
  69   else
  70     CFLAGS="-O2"
  71   fi
  72 else
  73   GCC=
  74   test "${CFLAGS+set}" = set || CFLAGS="-g"
  75 fi
  76 ])
  77
  78 LIB_AC_PROG_CC
  79
  80 AC_ISC_POSIX
  81
  82 dnl When we start using libtool:
  83 dnl Default to a non shared library.  This may be overridden by the
  84 dnl configure option --enable-shared.
  85 dnl AM_DISABLE_SHARED
  86
  87 dnl When we start using libtool:
  88 dnl AM_PROG_LIBTOOL
  89
  90 dnl When we start using automake:
  91 dnl AM_CONFIG_HEADER(config.h:config.in)
  92 AC_CONFIG_HEADER(config.h:config.in)
  93
  94 dnl When we start using automake:
  95 dnl AM_MAINTAINER_MODE
  96 dnl AC_EXEEXT
  97
  98 dnl When we start using automake:
  99 dnl AM_PROG_INSTALL
 100 AC_PROG_INSTALL
 101
 102 . ${srcdir}/config.table
 103 host_makefile_frag=${frag}
 104 AC_SUBST_FILE(host_makefile_frag)
 105
 106 # It's OK to check for header files.  Although the compiler may not be
 107 # able to link anything, it had better be able to at least compile
 108 # something.
 109 AC_CHECK_HEADERS(sys/file.h sys/param.h stdlib.h string.h unistd.h strings.h sys/time.h)
 110 AC_HEADER_SYS_WAIT
 111
 112 # This is the list of functions which libiberty will provide if they
 113 # are not available on the host.
 114
 115 funcs="asprintf"
 116 funcs="$funcs atexit"
 117 funcs="$funcs basename"
 118 funcs="$funcs bcmp"
 119 funcs="$funcs bcopy"
 120 funcs="$funcs bzero"
 121 funcs="$funcs calloc"
 122 funcs="$funcs clock"
 123 funcs="$funcs getcwd"
 124 funcs="$funcs getpagesize"
 125 funcs="$funcs index"
 126 funcs="$funcs insque"
 127 funcs="$funcs memchr"
 128 funcs="$funcs memcmp"
 129 funcs="$funcs memcpy"
 130 funcs="$funcs memmove"
 131 funcs="$funcs memset"
 132 funcs="$funcs mkstemps"
 133 funcs="$funcs random"
 134 funcs="$funcs rename"
 135 funcs="$funcs rindex"
 136 funcs="$funcs sigsetmask"
 137 funcs="$funcs strcasecmp"
 138 funcs="$funcs strchr"
 139 funcs="$funcs strdup"
 140 funcs="$funcs strncasecmp"
 141 funcs="$funcs strrchr"
 142 funcs="$funcs strstr"
 143 funcs="$funcs strtod"
 144 funcs="$funcs strtol"
 145 funcs="$funcs strtoul"
 146 funcs="$funcs tmpnam"
 147 funcs="$funcs vasprintf"
 148 funcs="$funcs vfprintf"
 149 funcs="$funcs vprintf"
 150 funcs="$funcs vsprintf"
 151 funcs="$funcs waitpid"
 152
 153 # Also in the old function.def file: alloca, vfork, getopt.
 154
 155 vars="sys_errlist sys_nerr sys_siglist"
 156
 157 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times"
 158
 159 # These are neither executed nor required, but they help keep
 160 # autoheader happy without adding a bunch of text to acconfig.h.
 161 if test "x" = "y"; then
 162   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bzero calloc clock getcwd)
 163   AC_CHECK_FUNCS(getpagesize index insque mkstemps memchr memcmp memcpy memmove)
 164   AC_CHECK_FUNCS(memset random rename rindex sigsetmask strcasecmp)
 165   AC_CHECK_FUNCS(strchr strdup strncasecmp strrchr strstr strtod strtol)
 166   AC_CHECK_FUNCS(strtoul tmpnam vasprintf vfprintf vprintf vsprintf waitpid)
 167   AC_DEFINE(HAVE_SYS_ERRLIST)
 168   AC_DEFINE(HAVE_SYS_NERR)
 169   AC_DEFINE(HAVE_SYS_SIGLIST)
 170   AC_CHECK_FUNCS(getrusage on_exit psignal strerror strsignal sysconf times)
 171 fi
 172
 173 # For each of these functions, if the host does not provide the
 174 # function we want to put FN.o in LIBOBJS, and if the host does
 175 # provide the function, we want to define HAVE_FN in config.h.  Also,
 176 # if the host does not provide alloca, we set ALLOCA to alloca.o
 177
 178 setobjs=
 179 CHECK=
 180 if test -n "${with_target_subdir}"; then
 181
 182   # We are being configured as a target library.  AC_REPLACE_FUNCS
 183   # may not work correctly, because the compiler may not be able to
 184   # link executables.  Note that we may still be being configured
 185   # native.
 186
 187   # If we are being configured for newlib, we know which functions
 188   # newlib provide and which ones we will be expected to provide.
 189
 190   if test "x${with_newlib}" = "xyes"; then
 191     ALLOCA="alloca.o"
 192     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 193
 194     for f in $funcs; do
 195       case "$f" in
 196         asprintf | basename | insque | random | strdup | vasprintf)
 197           ;;
 198         *)
 199           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 200           AC_DEFINE_UNQUOTED($n)
 201           ;;
 202       esac
 203     done
 204
 205     # newlib doesnt provide any of the variables in $vars, so we
 206     # dont have to check them here.
 207
 208     # Of the functions in $checkfuncs, newlib only has strerror.
 209     AC_DEFINE(HAVE_STRERROR)
 210
 211     setobjs=yes
 212
 213   fi
 214
 215 else
 216
 217    # Not a target library, so we set things up to run the test suite.
 218    CHECK=check-cplus-dem
 219
 220 fi
 221
 222 AC_SUBST(CHECK)
 223
 224 if test -z "${setobjs}"; then
 225   case "${host}" in
 226
 227   *-*-vxworks*)
 228     # Handle VxWorks configuration specially, since on VxWorks the
 229     # libraries are actually on the target board, not in the file
 230     # system.
 231     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 232     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 233     for f in $funcs; do
 234       case "$f" in
 235         basename | getpagesize | insque | random | strcasecmp)
 236           ;;
 237         strncasecmp | strdup | vfork | waitpid | vasprintf)
 238           ;;
 239         *)
 240           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 241           AC_DEFINE_UNQUOTED($n)
 242           ;;
 243       esac
 244     done
 245
 246     # VxWorks doesn't provide any of the variables in $vars, so we
 247     # don't have to check them here.
 248
 249     # Of the functions in $checkfuncs, VxWorks only has strerror.
 250     AC_DEFINE(HAVE_STRERROR)
 251
 252     setobjs=yes
 253     ;;
 254
 255   esac
 256 fi
 257
 258 if test -z "${setobjs}"; then
 259
 260   case "${host}" in
 261
 262   *-*-cygwin*)
 263     # The Cygwin library actually uses a couple of files from
 264     # libiberty when it is built.  If we are building a native
 265     # Cygwin, and we run the tests, we will appear to have these
 266     # files.  However, when we go on to build winsup, we will wind up
 267     # with a library which does not have the files, since they should
 268     # have come from libiberty.
 269
 270     # We handle this by removing the functions the winsup library
 271     # provides from our shell variables, so that they appear to be
 272     # missing.
 273
 274     funcs="`echo $funcs | sed -e 's/random//'`"
 275     LIBOBJS="$LIBOBJS random.o"
 276     vars="`echo $vars | sed -e 's/sys_siglist//'`"
 277     checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 278     ;;
 279
 280   *-*-mingw32*)
 281     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 282     # macros, so the test below won't find them.
 283     vars="`echo $vars | sed -e 's/sys_nerr//' -e 's/sys_errlist//'`"
 284     AC_DEFINE(HAVE_SYS_NERR)
 285     AC_DEFINE(HAVE_SYS_ERRLIST)
 286     ;;
 287
 288   *-*-uwin*)
 289     # Under some versions of uwin, vfork is notoriously buggy and the test
 290     # can hang configure; on other versions, vfork exists just as a stub.
 291     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 292     ac_cv_func_vfork_works=no
 293     ;;
 294
 295   esac
 296
 297   # We haven't set the list of objects yet.  Use the standard autoconf
 298   # tests.  This will only work if the compiler works.
 299   AC_PROG_CC_WORKS
 300   AC_REPLACE_FUNCS($funcs)
 301   AC_FUNC_ALLOCA
 302   AC_FUNC_VFORK
 303   if test $ac_cv_func_vfork_works = no; then
 304     LIBOBJS="$LIBOBJS vfork.o"
 305   fi
 306   for v in $vars; do
 307     AC_MSG_CHECKING([for $v])
 308     AC_CACHE_VAL(libiberty_cv_var_$v,
 309       [AC_TRY_LINK([int *p;], [extern int $v; p = &$v;],
 310                    [eval "libiberty_cv_var_$v=yes"],
 311                    [eval "libiberty_cv_var_$v=no"])])
 312     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 313       AC_MSG_RESULT(yes)
 314       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 315       AC_DEFINE_UNQUOTED($n)
 316     else
 317       AC_MSG_RESULT(no)
 318     fi
 319   done
 320   AC_CHECK_FUNCS($checkfuncs)
 321 fi
 322
 323 # Install a library built with a cross compiler in $(tooldir) rather
 324 # than $(libdir).
 325 if test -z "${with_cross_host}"; then
 326   INSTALL_DEST=libdir
 327 else
 328   INSTALL_DEST=tooldir
 329 fi
 330 AC_SUBST(INSTALL_DEST)
 331
 332 # We need multilib support, but only if configuring for the target.
 333 AC_OUTPUT(Makefile testsuite/Makefile,
 334 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 335 if test -n "$CONFIG_FILES"; then
 336   if test -n "${with_target_subdir}"; then
 337     # FIXME: We shouldn't need to set ac_file
 338     ac_file=Makefile
 339     . ${libiberty_topdir}/config-ml.in
 340   fi
 341 fi],
 342 srcdir=${srcdir}
 343 host=${host}
 344 target=${target}
 345 with_target_subdir=${with_target_subdir}
 346 with_multisubdir=${with_multisubdir}
 347 ac_configure_args="--enable-multilib ${ac_configure_args}"
 348 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 349 libiberty_topdir=${libiberty_topdir}
 350 )