libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(pexecute.c)
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory])
   9 AC_ARG_WITH(cross-host,
  10 [  --with-cross-host=HOST           Configuring with a cross compiler])
  11 AC_ARG_WITH(newlib,
  12 [  --with-newlib                    Configuring with newlib])
  13
  14 if test "${srcdir}" = "."; then
  15   if test -z "${with_target_subdir}"; then
  16     libiberty_topdir="${srcdir}/.."
  17   else
  18     if test "${with_target_subdir}" != "."; then
  19       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  20     else
  21       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  22     fi
  23   fi
  24 else
  25   libiberty_topdir="${srcdir}/.."
  26 fi
  27 AC_CONFIG_AUX_DIR($libiberty_topdir)
  28
  29 AC_CANONICAL_HOST
  30
  31 dnl When we start using automake:
  32 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  33
  34 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 LIB_AC_PROG_CC
  40
  41 AC_ISC_POSIX
  42 AC_C_CONST
  43 AC_C_INLINE
  44
  45 dnl When we start using libtool:
  46 dnl Default to a non shared library.  This may be overridden by the
  47 dnl configure option --enable-shared.
  48 dnl AM_DISABLE_SHARED
  49
  50 dnl When we start using libtool:
  51 dnl AM_PROG_LIBTOOL
  52
  53 dnl When we start using automake:
  54 dnl AM_CONFIG_HEADER(config.h:config.in)
  55 AC_CONFIG_HEADER(config.h:config.in)
  56
  57 dnl When we start using automake:
  58 dnl AM_MAINTAINER_MODE
  59 dnl AC_EXEEXT
  60
  61 dnl When we start using automake:
  62 dnl AM_PROG_INSTALL
  63 AC_PROG_INSTALL
  64
  65 . ${srcdir}/config.table
  66 host_makefile_frag=${frag}
  67 AC_SUBST_FILE(host_makefile_frag)
  68
  69 # It's OK to check for header files.  Although the compiler may not be
  70 # able to link anything, it had better be able to at least compile
  71 # something.
  72 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h)
  73 AC_HEADER_SYS_WAIT
  74 AC_HEADER_TIME
  75
  76 libiberty_AC_DECLARE_ERRNO
  77
  78 # This is the list of functions which libiberty will provide if they
  79 # are not available on the host.
  80
  81 funcs="asprintf"
  82 funcs="$funcs atexit"
  83 funcs="$funcs basename"
  84 funcs="$funcs bcmp"
  85 funcs="$funcs bcopy"
  86 funcs="$funcs bsearch"
  87 funcs="$funcs bzero"
  88 funcs="$funcs calloc"
  89 funcs="$funcs clock"
  90 funcs="$funcs ffs"
  91 funcs="$funcs getcwd"
  92 funcs="$funcs getpagesize"
  93 funcs="$funcs index"
  94 funcs="$funcs insque"
  95 funcs="$funcs memchr"
  96 funcs="$funcs memcmp"
  97 funcs="$funcs memcpy"
  98 funcs="$funcs memmove"
  99 funcs="$funcs memset"
 100 funcs="$funcs mkstemps"
 101 funcs="$funcs putenv"
 102 funcs="$funcs random"
 103 funcs="$funcs rename"
 104 funcs="$funcs rindex"
 105 funcs="$funcs setenv"
 106 funcs="$funcs sigsetmask"
 107 funcs="$funcs strcasecmp"
 108 funcs="$funcs strchr"
 109 funcs="$funcs strdup"
 110 funcs="$funcs strncasecmp"
 111 funcs="$funcs strrchr"
 112 funcs="$funcs strstr"
 113 funcs="$funcs strtod"
 114 funcs="$funcs strtol"
 115 funcs="$funcs strtoul"
 116 funcs="$funcs tmpnam"
 117 funcs="$funcs vasprintf"
 118 funcs="$funcs vfprintf"
 119 funcs="$funcs vprintf"
 120 funcs="$funcs vsprintf"
 121 funcs="$funcs waitpid"
 122
 123 # Also in the old function.def file: alloca, vfork, getopt.
 124
 125 vars="sys_errlist sys_nerr sys_siglist"
 126
 127 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 128
 129 # These are neither executed nor required, but they help keep
 130 # autoheader happy without adding a bunch of text to acconfig.h.
 131 if test "x" = "y"; then
 132   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock)
 133   AC_CHECK_FUNCS(getcwd getpagesize index insque mkstemps memchr memcmp memcpy)
 134   AC_CHECK_FUNCS(memmove memset putenv random rename rindex sigsetmask)
 135   AC_CHECK_FUNCS(strcasecmp setenv strchr strdup strncasecmp strrchr strstr)
 136   AC_CHECK_FUNCS(strtod strtol strtoul tmpnam vasprintf vfprintf vprintf)
 137   AC_CHECK_FUNCS(vsprintf waitpid getrusage on_exit psignal strerror strsignal)
 138   AC_CHECK_FUNCS(sysconf times sbrk gettimeofday ffs)
 139   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 140   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 141   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 142 fi
 143
 144 # For each of these functions, if the host does not provide the
 145 # function we want to put FN.o in LIBOBJS, and if the host does
 146 # provide the function, we want to define HAVE_FN in config.h.
 147
 148 setobjs=
 149 CHECK=
 150 if test -n "${with_target_subdir}"; then
 151
 152   # We are being configured as a target library.  AC_REPLACE_FUNCS
 153   # may not work correctly, because the compiler may not be able to
 154   # link executables.  Note that we may still be being configured
 155   # native.
 156
 157   # If we are being configured for newlib, we know which functions
 158   # newlib provide and which ones we will be expected to provide.
 159
 160   if test "x${with_newlib}" = "xyes"; then
 161     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 162
 163     for f in $funcs; do
 164       case "$f" in
 165         asprintf | basename | insque | random | strdup | vasprintf)
 166           ;;
 167         *)
 168           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 169           AC_DEFINE_UNQUOTED($n)
 170           ;;
 171       esac
 172     done
 173
 174     # newlib doesnt provide any of the variables in $vars, so we
 175     # dont have to check them here.
 176
 177     # Of the functions in $checkfuncs, newlib only has strerror.
 178     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 179
 180     setobjs=yes
 181
 182   fi
 183
 184 else
 185
 186    # Not a target library, so we set things up to run the test suite.
 187    CHECK=check-cplus-dem
 188
 189 fi
 190
 191 AC_SUBST(CHECK)
 192
 193 case "${host}" in
 194   *-*-cygwin*)
 195     AC_DEFINE(HAVE_SYS_ERRLIST)
 196     AC_DEFINE(HAVE_SYS_NERR)
 197     ;;
 198 esac
 199
 200 if test -z "${setobjs}"; then
 201   case "${host}" in
 202
 203   *-*-vxworks*)
 204     # Handle VxWorks configuration specially, since on VxWorks the
 205     # libraries are actually on the target board, not in the file
 206     # system.
 207     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 208     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 209     for f in $funcs; do
 210       case "$f" in
 211         basename | getpagesize | insque | random | strcasecmp)
 212           ;;
 213         strncasecmp | strdup | vfork | waitpid | vasprintf)
 214           ;;
 215         *)
 216           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 217           AC_DEFINE_UNQUOTED($n)
 218           ;;
 219       esac
 220     done
 221
 222     # VxWorks doesn't provide any of the variables in $vars, so we
 223     # don't have to check them here.
 224
 225     # Of the functions in $checkfuncs, VxWorks only has strerror.
 226     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 227
 228     setobjs=yes
 229     ;;
 230
 231   esac
 232 fi
 233
 234 if test -z "${setobjs}"; then
 235
 236   case "${host}" in
 237
 238   *-*-cygwin*)
 239     # The Cygwin library actually uses a couple of files from
 240     # libiberty when it is built.  If we are building a native
 241     # Cygwin, and we run the tests, we will appear to have these
 242     # files.  However, when we go on to build winsup, we will wind up
 243     # with a library which does not have the files, since they should
 244     # have come from libiberty.
 245
 246     # We handle this by removing the functions the winsup library
 247     # provides from our shell variables, so that they appear to be
 248     # missing.
 249
 250     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 251
 252     if test -n "${with_target_subdir}"
 253     then
 254       funcs="`echo $funcs | sed -e 's/random//'`"
 255       LIBOBJS="$LIBOBJS random.o"
 256       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 257       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 258     fi
 259     ;;
 260
 261   *-*-mingw32*)
 262     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 263     # macros, so the test below won't find them.
 264     libiberty_cv_var_sys_nerr=yes
 265     libiberty_cv_var_sys_errlist=yes
 266     ;;
 267
 268   *-*-uwin*)
 269     # Under some versions of uwin, vfork is notoriously buggy and the test
 270     # can hang configure; on other versions, vfork exists just as a stub.
 271     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 272     ac_cv_func_vfork_works=no
 273     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 274     # macros (actually, these are imported from a DLL, but the end effect
 275     # is the same), so the test below won't find them.
 276     libiberty_cv_var_sys_nerr=yes
 277     libiberty_cv_var_sys_errlist=yes
 278     ;;
 279
 280   esac
 281
 282   # We haven't set the list of objects yet.  Use the standard autoconf
 283   # tests.  This will only work if the compiler works.
 284   AC_PROG_CC_WORKS
 285   AC_REPLACE_FUNCS($funcs)
 286   libiberty_AC_FUNC_C_ALLOCA
 287   AC_FUNC_VFORK
 288   if test $ac_cv_func_vfork_works = no; then
 289     LIBOBJS="$LIBOBJS vfork.o"
 290   fi
 291   for v in $vars; do
 292     AC_MSG_CHECKING([for $v])
 293     AC_CACHE_VAL(libiberty_cv_var_$v,
 294       [AC_TRY_LINK([int *p;], [extern int $v; p = &$v;],
 295                    [eval "libiberty_cv_var_$v=yes"],
 296                    [eval "libiberty_cv_var_$v=no"])])
 297     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 298       AC_MSG_RESULT(yes)
 299       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 300       AC_DEFINE_UNQUOTED($n)
 301     else
 302       AC_MSG_RESULT(no)
 303     fi
 304   done
 305   AC_CHECK_FUNCS($checkfuncs)
 306 fi
 307
 308 libiberty_AC_FUNC_STRNCMP
 309
 310 # Install a library built with a cross compiler in $(tooldir) rather
 311 # than $(libdir).
 312 if test -z "${with_cross_host}"; then
 313   INSTALL_DEST=libdir
 314 else
 315   INSTALL_DEST=tooldir
 316 fi
 317 AC_SUBST(INSTALL_DEST)
 318
 319 # We need multilib support, but only if configuring for the target.
 320 AC_OUTPUT(Makefile testsuite/Makefile,
 321 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 322 if test -n "$CONFIG_FILES"; then
 323   if test -n "${with_target_subdir}"; then
 324     # FIXME: We shouldn't need to set ac_file
 325     ac_file=Makefile
 326     . ${libiberty_topdir}/config-ml.in
 327   fi
 328 fi],
 329 srcdir=${srcdir}
 330 host=${host}
 331 target=${target}
 332 with_target_subdir=${with_target_subdir}
 333 with_multisubdir=${with_multisubdir}
 334 ac_configure_args="--enable-multilib ${ac_configure_args}"
 335 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 336 libiberty_topdir=${libiberty_topdir}
 337 )