libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 GCC_NO_EXECUTABLES
 113 AC_PROG_CC
 114 AC_PROG_CPP_WERROR
 115
 116 AC_PROG_LIBTOOL
 117
 118 if test x$GCC = xyes; then
 119   ac_libiberty_warn_cflags='-W -Wall -Wtraditional -pedantic'
 120 fi
 121 AC_SUBST(ac_libiberty_warn_cflags)
 122
 123 AC_C_CONST
 124 AC_C_INLINE
 125 AC_C_BIGENDIAN_CROSS
 126
 127 dnl When we start using libtool:
 128 dnl Default to a non shared library.  This may be overridden by the
 129 dnl configure option --enable-shared.
 130 dnl AM_DISABLE_SHARED
 131
 132 dnl When we start using libtool:
 133 dnl AM_PROG_LIBTOOL
 134
 135 dnl When we start using automake:
 136 dnl AM_CONFIG_HEADER(config.h:config.in)
 137 AC_CONFIG_HEADER(config.h:config.in)
 138
 139 dnl When we start using automake:
 140 dnl AM_MAINTAINER_MODE
 141 dnl AC_EXEEXT
 142
 143 dnl When we start using automake:
 144 dnl AM_PROG_INSTALL
 145 AC_PROG_INSTALL
 146
 147 . ${srcdir}/config.table
 148 host_makefile_frag=${frag}
 149 AC_SUBST_FILE(host_makefile_frag)
 150
 151 # It's OK to check for header files.  Although the compiler may not be
 152 # able to link anything, it had better be able to at least compile
 153 # something.
 154 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h)
 155 AC_HEADER_SYS_WAIT
 156 AC_HEADER_TIME
 157
 158 libiberty_AC_DECLARE_ERRNO
 159
 160 # Determine the size of an int for struct fibnode.
 161 AC_CHECK_SIZEOF([int])
 162
 163 AC_CHECK_TYPE(uintptr_t, unsigned long)
 164
 165 # Look for a 64-bit type.
 166 AC_MSG_CHECKING([for a 64-bit type])
 167 AC_CACHE_VAL(liberty_cv_uint64,
 168 [AC_TRY_COMPILE(
 169 [#ifdef HAVE_STDINT_H
 170 #include <stdint.h>
 171 #endif],
 172 [extern uint64_t foo;],
 173 liberty_cv_uint64=uint64_t,
 174 [AC_TRY_COMPILE(
 175 [#ifdef HAVE_LIMITS_H
 176 #include <limits.h>
 177 #endif
 178 #ifndef CHAR_BIT
 179 #define CHAR_BIT 8
 180 #endif],
 181 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 182 liberty_cv_uint64="unsigned long",
 183 [AC_TRY_COMPILE(
 184 [#ifdef HAVE_LIMITS_H
 185 #include <limits.h>
 186 #endif
 187 #ifndef CHAR_BIT
 188 #define CHAR_BIT 8
 189 #endif],
 190 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 191 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 192 AC_MSG_RESULT($liberty_cv_uint64)
 193 if test "$liberty_cv_uint64" != none; then
 194   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 195                      [Define to an unsigned 64-bit type available in the compiler.])
 196 fi
 197
 198 # Given the above check, we always have uintptr_t or a fallback
 199 # definition.  So define HAVE_UINTPTR_T in case any imported code
 200 # relies on it.
 201 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 202
 203 AC_TYPE_PID_T
 204
 205 # This is the list of functions which libiberty will provide if they
 206 # are not available on the host.
 207
 208 funcs="asprintf"
 209 funcs="$funcs atexit"
 210 funcs="$funcs basename"
 211 funcs="$funcs bcmp"
 212 funcs="$funcs bcopy"
 213 funcs="$funcs bsearch"
 214 funcs="$funcs bzero"
 215 funcs="$funcs calloc"
 216 funcs="$funcs clock"
 217 funcs="$funcs ffs"
 218 funcs="$funcs getcwd"
 219 funcs="$funcs getpagesize"
 220 funcs="$funcs index"
 221 funcs="$funcs insque"
 222 funcs="$funcs memchr"
 223 funcs="$funcs memcmp"
 224 funcs="$funcs memcpy"
 225 funcs="$funcs memmove"
 226 funcs="$funcs mempcpy"
 227 funcs="$funcs memset"
 228 funcs="$funcs mkstemps"
 229 funcs="$funcs putenv"
 230 funcs="$funcs random"
 231 funcs="$funcs rename"
 232 funcs="$funcs rindex"
 233 funcs="$funcs setenv"
 234 funcs="$funcs snprintf"
 235 funcs="$funcs sigsetmask"
 236 funcs="$funcs stpcpy"
 237 funcs="$funcs stpncpy"
 238 funcs="$funcs strcasecmp"
 239 funcs="$funcs strchr"
 240 funcs="$funcs strdup"
 241 funcs="$funcs strncasecmp"
 242 funcs="$funcs strrchr"
 243 funcs="$funcs strstr"
 244 funcs="$funcs strtod"
 245 funcs="$funcs strtol"
 246 funcs="$funcs strtoul"
 247 funcs="$funcs tmpnam"
 248 funcs="$funcs vasprintf"
 249 funcs="$funcs vfprintf"
 250 funcs="$funcs vprintf"
 251 funcs="$funcs vsnprintf"
 252 funcs="$funcs vsprintf"
 253 funcs="$funcs waitpid"
 254
 255 # Also in the old function.def file: alloca, vfork, getopt.
 256
 257 vars="sys_errlist sys_nerr sys_siglist"
 258
 259 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 260 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 261 checkfuncs="$checkfuncs getsysinfo table sysctl"
 262
 263 # These are neither executed nor required, but they help keep
 264 # autoheader happy without adding a bunch of text to acconfig.h.
 265 if test "x" = "y"; then
 266   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \
 267   getcwd getpagesize index insque mkstemps memchr memcmp memcpy \
 268   memmove mempcpy memset putenv random rename rindex sigsetmask \
 269   strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strrchr strstr \
 270   strtod strtol strtoul tmpnam vasprintf vfprintf vprintf \
 271   vsprintf waitpid getrusage on_exit psignal strerror strsignal \
 272   sysconf times sbrk gettimeofday ffs snprintf vsnprintf \
 273   pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl \
 274   realpath canonicalize_file_name)
 275   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 276   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 277   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 278 fi
 279
 280 # For each of these functions, if the host does not provide the
 281 # function we want to put FN.o in LIBOBJS, and if the host does
 282 # provide the function, we want to define HAVE_FN in config.h.
 283
 284 setobjs=
 285 CHECK=
 286 target_header_dir=
 287 if test -n "${with_target_subdir}"; then
 288
 289   # We are being configured as a target library.  AC_REPLACE_FUNCS
 290   # may not work correctly, because the compiler may not be able to
 291   # link executables.  Note that we may still be being configured
 292   # native.
 293
 294   # If we are being configured for newlib, we know which functions
 295   # newlib provide and which ones we will be expected to provide.
 296
 297   if test "x${with_newlib}" = "xyes"; then
 298     AC_LIBOBJ([asprintf])
 299     AC_LIBOBJ([basename])
 300     AC_LIBOBJ([insque])
 301     AC_LIBOBJ([random])
 302     AC_LIBOBJ([strdup])
 303     AC_LIBOBJ([vasprintf])
 304
 305     for f in $funcs; do
 306       case "$f" in
 307         asprintf | basename | insque | random | strdup | vasprintf)
 308           ;;
 309         *)
 310           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 311           AC_DEFINE_UNQUOTED($n)
 312           ;;
 313       esac
 314     done
 315
 316     # newlib doesnt provide any of the variables in $vars, so we
 317     # dont have to check them here.
 318
 319     # Of the functions in $checkfuncs, newlib only has strerror.
 320     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 321
 322     setobjs=yes
 323
 324   fi
 325
 326   # We may wish to install the target headers somewhere.
 327   AC_ARG_ENABLE(install-libiberty,
 328   [  --enable-install-libiberty       Install headers for end users],
 329   enable_install_libiberty=$enableval,
 330   enable_install_libiberty=no)dnl
 331
 332   # Option parsed, now set things appropriately.
 333   case x"$enable_install_libiberty" in
 334     xyes|x)
 335       target_header_dir=libiberty
 336       ;;
 337     xno)
 338       target_header_dir=
 339       ;;
 340     *)
 341       # This could be sanity-checked in various ways...
 342       target_header_dir="${enable_install_libiberty}"
 343       ;;
 344   esac
 345
 346
 347 else
 348
 349    # Not a target library, so we set things up to run the test suite.
 350    CHECK=check-cplus-dem
 351
 352 fi
 353
 354 AC_SUBST(CHECK)
 355 AC_SUBST(target_header_dir)
 356
 357 case "${host}" in
 358   *-*-cygwin* | *-*-mingw*)
 359     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 360     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 361     ;;
 362 esac
 363
 364 if test -z "${setobjs}"; then
 365   case "${host}" in
 366
 367   *-*-vxworks*)
 368     # Handle VxWorks configuration specially, since on VxWorks the
 369     # libraries are actually on the target board, not in the file
 370     # system.
 371     AC_LIBOBJ([basename])
 372     AC_LIBOBJ([getpagesize])
 373     AC_LIBOBJ([insque])
 374     AC_LIBOBJ([random])
 375     AC_LIBOBJ([strcasecmp])
 376     AC_LIBOBJ([strncasecmp])
 377     AC_LIBOBJ([strdup])
 378     AC_LIBOBJ([vfork])
 379     AC_LIBOBJ([waitpid])
 380     AC_LIBOBJ([vasprintf])
 381     for f in $funcs; do
 382       case "$f" in
 383         basename | getpagesize | insque | random | strcasecmp)
 384           ;;
 385         strncasecmp | strdup | vfork | waitpid | vasprintf)
 386           ;;
 387         *)
 388           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 389           AC_DEFINE_UNQUOTED($n)
 390           ;;
 391       esac
 392     done
 393
 394     # VxWorks doesn't provide any of the variables in $vars, so we
 395     # don't have to check them here.
 396
 397     # Of the functions in $checkfuncs, VxWorks only has strerror.
 398     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 399
 400     setobjs=yes
 401     ;;
 402
 403   esac
 404 fi
 405
 406 if test -z "${setobjs}"; then
 407
 408   case "${host}" in
 409
 410   *-*-cygwin*)
 411     # The Cygwin library actually uses a couple of files from
 412     # libiberty when it is built.  If we are building a native
 413     # Cygwin, and we run the tests, we will appear to have these
 414     # files.  However, when we go on to build winsup, we will wind up
 415     # with a library which does not have the files, since they should
 416     # have come from libiberty.
 417
 418     # We handle this by removing the functions the winsup library
 419     # provides from our shell variables, so that they appear to be
 420     # missing.
 421
 422     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 423
 424     if test -n "${with_target_subdir}"
 425     then
 426       funcs="`echo $funcs | sed -e 's/random//'`"
 427       AC_LIBOBJ([random])
 428       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 429       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 430     fi
 431     ;;
 432
 433   *-*-mingw32*)
 434     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 435     # macros, so the test below won't find them.
 436     libiberty_cv_var_sys_nerr=yes
 437     libiberty_cv_var_sys_errlist=yes
 438     ;;
 439
 440   *-*-uwin*)
 441     # Under some versions of uwin, vfork is notoriously buggy and the test
 442     # can hang configure; on other versions, vfork exists just as a stub.
 443     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 444     ac_cv_func_vfork_works=no
 445     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 446     # macros (actually, these are imported from a DLL, but the end effect
 447     # is the same), so the test below won't find them.
 448     libiberty_cv_var_sys_nerr=yes
 449     libiberty_cv_var_sys_errlist=yes
 450     ;;
 451
 452   *-*-*vms*)
 453     # Under VMS, vfork works very different than on Unix. The standard test
 454     # won't work, and it isn't easily adaptable. It makes more sense to
 455     # just force it.
 456     ac_cv_func_vfork_works=yes
 457     ;;
 458
 459   esac
 460
 461   # We haven't set the list of objects yet.  Use the standard autoconf
 462   # tests.  This will only work if the compiler works.
 463   AC_ISC_POSIX
 464   AC_REPLACE_FUNCS($funcs)
 465   libiberty_AC_FUNC_C_ALLOCA
 466   AC_FUNC_FORK
 467   if test $ac_cv_func_vfork_works = no; then
 468     AC_LIBOBJ([vfork])
 469   fi
 470   # We only need _doprnt if we might use it to implement v*printf.
 471   if test $ac_cv_func_vprintf != yes \
 472      || test $ac_cv_func_vfprintf != yes \
 473      || test $ac_cv_func_vsprintf != yes; then
 474     AC_REPLACE_FUNCS(_doprnt)
 475   else
 476     AC_CHECK_FUNCS(_doprnt)
 477   fi
 478
 479   for v in $vars; do
 480     AC_MSG_CHECKING([for $v])
 481     AC_CACHE_VAL(libiberty_cv_var_$v,
 482       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 483                       [eval "libiberty_cv_var_$v=yes"],
 484                       [eval "libiberty_cv_var_$v=no"])])
 485     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 486       AC_MSG_RESULT(yes)
 487       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 488       AC_DEFINE_UNQUOTED($n)
 489     else
 490       AC_MSG_RESULT(no)
 491     fi
 492   done
 493
 494   # special check for _system_configuration because AIX <4.3.2 do not
 495   # contain the `physmem' member.
 496   AC_MSG_CHECKING([for external symbol _system_configuration])
 497   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 498                         [[double x = _system_configuration.physmem;]])],
 499     [AC_MSG_RESULT([yes])
 500     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 501               [Define if you have the _system_configuration variable.])],
 502     [AC_MSG_RESULT([no])])
 503
 504   AC_CHECK_FUNCS($checkfuncs)
 505   libiberty_NEED_DECLARATION(canonicalize_file_name)
 506 fi
 507
 508 # Figure out which version of pexecute to use.
 509 case "${host}" in
 510      *-*-mingw* | *-*-winnt*)   pex=./pex-win32  ;;
 511      *-*-msdosdjgpp*)           pex=./pex-djgpp  ;;
 512      *-*-msdos*)                pex=./pex-msdos  ;;
 513      *-*-os2-emx*)              pex=./pex-os2    ;;
 514      *)                         pex=./pex-unix   ;;
 515 esac
 516 pexecute=${pex}.o
 517 ltpexecute=${pex}.lo
 518 AC_SUBST(pexecute)
 519 AC_SUBST(ltpexecute)
 520
 521 libiberty_AC_FUNC_STRNCMP
 522
 523 # Install a library built with a cross compiler in $(tooldir) rather
 524 # than $(libdir).
 525 if test -z "${with_cross_host}"; then
 526   INSTALL_DEST=libdir
 527 else
 528   INSTALL_DEST=tooldir
 529 fi
 530 AC_SUBST(INSTALL_DEST)
 531
 532 # We need multilib support, but only if configuring for the target.
 533 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 534 AC_CONFIG_COMMANDS([default],
 535   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 536 if test -n "$CONFIG_FILES"; then
 537   if test -n "${with_target_subdir}"; then
 538     # FIXME: We shouldn't need to set ac_file
 539     ac_file=Makefile
 540     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 541     . ${libiberty_topdir}/config-ml.in
 542   fi
 543 fi]],
 544 [[srcdir=${srcdir}
 545 host=${host}
 546 target=${target}
 547 with_target_subdir=${with_target_subdir}
 548 with_multisubdir=${with_multisubdir}
 549 ac_configure_args="--enable-multilib ${ac_configure_args}"
 550 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 551 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 552 libiberty_topdir=${libiberty_topdir}
 553 ]])
 554 AC_OUTPUT