libgui/configure.in

   1 dnl Process this file with autoconf to produce configure.
   2
   3 AC_INIT(src/subcommand.h)
   4 AM_INIT_AUTOMAKE(libgui, 0.0)
   5 AM_CONFIG_HEADER(config.h)
   6 AM_MAINTAINER_MODE
   7 AC_CANONICAL_HOST
   8 AC_PROG_CC
   9 AC_EXEEXT
  10 AC_OBJEXT
  11 AC_ARG_ENABLE(install-libgui, \
  12   [  --enable-install-libgui Install libgui.a and library header files])
  13 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
  14 AM_CONDITIONAL(INSTALL_LIBGUI, test x$enable_install_libgui = xyes)
  15 AC_CHECK_TOOL(RANLIB, ranlib, :)
  16 AC_CHECK_TOOL(AR, ar, :)
  17
  18 AC_FUNC_ALLOCA
  19 AC_HAVE_HEADERS(stddef.h stdlib.h getopt.h unistd.h fcntl.h sys/file.h sys/wait.h string.h strings.h)
  20 AC_CHECK_FUNCS(raise)
  21
  22 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support],
  23 [case "${enableval}" in
  24   yes) ide=yes ;;
  25   no)  ide=no ;;
  26   *)   AC_MSG_ERROR(bad value ${enableval} for enable-ide option) ;;
  27 esac],
  28 [ide=no])
  29 AM_CONDITIONAL(IDE_ENABLED, test x$ide = xyes)
  30 if test x$ide = xyes; then
  31   AC_DEFINE(IDE_ENABLED)
  32 fi
  33
  34 # If we have random, assume we have srandom.  If we have drand48,
  35 # assume we have srand48.  If we have rand, assume we have srand.
  36 AC_CHECK_FUNCS(random drand48 rand, break)
  37
  38 dnl Tcl ensures that strncasecmp is provided everywhere.  But in some
  39 dnl situations we might need to declare it.  We check for that case
  40 dnl here.
  41 AC_EGREP_CPP(strncasecmp, [#include <string.h>],
  42   AC_DEFINE(HAVE_STRNCASECMP_DECL))
  43
  44 # Tcl8.1 requires writable strings for gcc
  45
  46 if test "$GCC" = "yes"; then
  47    LIBGUI_CFLAGS=-fwritable-strings
  48 else
  49    LIBGUI_CFLAGS=
  50 fi
  51
  52 AC_CACHE_CHECK([for cygwin32], ide_cv_os_cygwin32,
  53 [AC_EGREP_CPP(lose, [
  54 #ifdef __CYGWIN32__
  55 lose
  56 #endif],[ide_cv_os_cygwin32=yes],[ide_cv_os_cygwin32=no])])
  57 ac_win_build="no"
  58 if test x$ide_cv_os_cygwin32 = xyes; then
  59   ac_win_build="yes"
  60 fi
  61
  62 tmp="`cd $srcdir/library; pwd`"
  63 if test x"$ac_cv_prog_CC" = xcl ; then
  64   tmp2="`cygpath --windows $tmp`"
  65   LIBGUI_LIBRARY_DIR="`echo $tmp2 | sed -e s#\\\\\\\\#/#g`"
  66 else
  67   LIBGUI_LIBRARY_DIR=$tmp
  68 fi
  69 AC_SUBST(LIBGUI_LIBRARY_DIR)
  70
  71 # Find the init.tcl file.
  72
  73 AC_MSG_CHECKING(for init.tcl)
  74 AC_CACHE_VAL(ac_cv_c_tcl_libdir,[
  75 dnl currently, only check the source tree
  76 if test -f $srcdir/../tcl/library/init.tcl ; then
  77   ac_cv_c_tcl_libdir=`cd $srcdir/../tcl/library; pwd`
  78 elif test -f $srcdir/../tcl8.1/library/init.tcl; then
  79   ac_cv_c_tcl_libdir=`cd $srcdir/../tcl8.1/library; pwd`
  80 fi
  81 ])
  82 AC_MSG_RESULT(${ac_cv_c_tcl_libdir})
  83
  84 if test x"$ac_cv_prog_CC" = xcl; then
  85   tmp2="`cygpath --windows $ac_cv_c_tcl_libdir`"
  86   TCL_LIBRARY="`echo $tmp2 | sed -e s#\\\\\\\\#/#g`"
  87 else
  88   TCL_LIBRARY=$ac_cv_c_tcl_libdir
  89 fi
  90 AC_SUBST(TCL_LIBRARY)
  91
  92 # Check for Tcl and Tk.
  93 CYG_AC_PATH_TCLCONFIG
  94 CYG_AC_LOAD_TCLCONFIG
  95 CYG_AC_PATH_TKCONFIG
  96 CYG_AC_LOAD_TKCONFIG
  97 CYG_AC_PATH_TCLH
  98 # FIXME: consider only doing this if --with-x given.
  99 CYG_AC_PATH_TKH
 100 CYG_AC_PATH_ITCLCONFIG
 101 CYG_AC_LOAD_ITCLCONFIG
 102
 103 case ${host} in
 104 *cygwin*)
 105         touch ac$$.c
 106         if ${CC} -c -mwin32 ac$$.c >/dev/null 2>&1; then
 107             case "$LIBGUI_CFLAGS" in
 108                 *-mwin32*) ;;
 109                 *) LIBGUI_CFLAGS="-mwin32 $LIBGUI_CFLAGS" ;;
 110             esac
 111         fi
 112         rm -f ac$$.o ac$$.c
 113         ;;
 114 *)
 115         ;;
 116 esac
 117
 118 AC_SUBST(LIBGUI_CFLAGS)
 119 AC_SUBST(TCL_DEFS)
 120 AC_SUBST(TK_DEFS)
 121 AC_SUBST(TCLHDIR)
 122 AC_SUBST(TKHDIR)
 123 AC_SUBST(TK_XINCLUDES)
 124 AC_SUBST(TCL_LIBS)
 125 AC_SUBST(TK_BUILD_LIB_SPEC)
 126 AC_SUBST(TCL_BUILD_LIB_SPEC)
 127 AC_SUBST(TK_LIBS)
 128
 129 AM_CONDITIONAL(TCL_SHARED, test x$TCL_SHARED_BUILD = x1)
 130
 131 AC_SUBST(RPATH_ENVVAR)
 132
 133 AC_OUTPUT([Makefile library/Makefile src/Makefile])
 134
 135
 136