libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 AC_MSG_CHECKING([for --enable-linux-futex])
  19 LIBGOMP_ENABLE(linux-futex, default, ,
  20   [Use the Linux futex system call],
  21   permit yes|no|default)
  22 AC_MSG_RESULT($enable_linux_futex)
  23
  24 # We would like our source tree to be readonly. However when releases or
  25 # pre-releases are generated, the flex/bison generated files as well as the
  26 # various formats of manuals need to be included along with the rest of the
  27 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  28 # just that.
  29 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  30 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  31    [put copies of generated files in source dir intended for creating source
  32     tarballs for users without texinfo bison or flex.],
  33    permit yes|no)
  34 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  35 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  36
  37
  38 # -------
  39 # -------
  40
  41 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  42 #
  43 # You will slowly go insane if you do not grok the following fact:  when
  44 # building this library, the top-level /target/ becomes the library's /host/.
  45 #
  46 # configure then causes --target to default to --host, exactly like any
  47 # other package using autoconf.  Therefore, 'target' and 'host' will
  48 # always be the same.  This makes sense both for native and cross compilers
  49 # just think about it for a little while.  :-)
  50 #
  51 # Also, if this library is being configured as part of a cross compiler, the
  52 # top-level configure script will pass the "real" host as $with_cross_host.
  53 #
  54 # Do not delete or change the following two lines.  For why, see
  55 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  56 AC_CANONICAL_SYSTEM
  57 target_alias=${target_alias-$host_alias}
  58
  59 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  60 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  61 #  1.9.0:  minimum required version
  62 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  63 #              of other PACKAGE_* variables will, however, and there's nothing
  64 #              we can do about that; they come from AC_INIT).
  65 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  66 #            file in the top srcdir, etc, etc), so stop complaining.
  67 #  -Wall:  turns on all automake warnings...
  68 #  -Wno-portability:  ...except this one, since GNU make is required.
  69 #  -Wno-override: ... and this one, since we do want this in testsuite.
  70 AM_INIT_AUTOMAKE([1.9.0 foreign -Wall -Wno-portability -Wno-override])
  71 AM_ENABLE_MULTILIB(, ..)
  72
  73 # Calculate toolexeclibdir
  74 # Also toolexecdir, though it's only used in toolexeclibdir
  75 case ${enable_version_specific_runtime_libs} in
  76   yes)
  77     # Need the gcc compiler version to know where to install libraries
  78     # and header files if --enable-version-specific-runtime-libs option
  79     # is selected.
  80     toolexecdir='$(libdir)/gcc/$(target_alias)'
  81     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  82     ;;
  83   no)
  84     if test -n "$with_cross_host" &&
  85        test x"$with_cross_host" != x"no"; then
  86       # Install a library built with a cross compiler in tooldir, not libdir.
  87       toolexecdir='$(exec_prefix)/$(target_alias)'
  88       toolexeclibdir='$(toolexecdir)/lib'
  89     else
  90       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  91       toolexeclibdir='$(libdir)'
  92     fi
  93     multi_os_directory=`$CC -print-multi-os-directory`
  94     case $multi_os_directory in
  95       .) ;; # Avoid trailing /.
  96       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  97     esac
  98     ;;
  99 esac
 100 AC_SUBST(toolexecdir)
 101 AC_SUBST(toolexeclibdir)
 102
 103 # Check the compiler.
 104 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 105 # We must force CC to /not/ be precious variables; otherwise
 106 # the wrong, non-multilib-adjusted value will be used in multilibs.
 107 # As a side effect, we have to subst CFLAGS ourselves.
 108
 109 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 110 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 111 AC_PROG_CC
 112 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 113
 114 AC_SUBST(CFLAGS)
 115
 116 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 117 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 118 # in both places for now and restore CFLAGS at the end of config.
 119 save_CFLAGS="$CFLAGS"
 120
 121 # Add -Wall -Werror if we are using GCC.
 122 if test "x$GCC" = "xyes"; then
 123   XCFLAGS="$XCFLAGS -Wall -Werror"
 124 fi
 125
 126 # Find other programs we need.
 127 AC_CHECK_TOOL(AR, ar)
 128 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 129 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 130 AC_PROG_MAKE_SET
 131 AC_PROG_INSTALL
 132
 133 # Configure libtool
 134 AM_PROG_LIBTOOL
 135 AC_SUBST(enable_shared)
 136 AC_SUBST(enable_static)
 137
 138 AM_MAINTAINER_MODE
 139
 140 # We need gfortran to compile parts of the library
 141 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 142 #AC_PROG_FC(gfortran)
 143 FC="$GFORTRAN"
 144 AC_PROG_FC(gfortran)
 145 FCFLAGS="$FCFLAGS -Wall"
 146
 147 # For libtool versioning info, format is CURRENT:REVISION:AGE
 148 libtool_VERSION=1:0:0
 149 AC_SUBST(libtool_VERSION)
 150
 151 # Check header files.
 152 AC_STDC_HEADERS
 153 AC_HEADER_TIME
 154 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h)
 155
 156 GCC_HEADER_STDINT(gstdint.h)
 157
 158 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 159 # In case the pthread.h system header is not found, this test will fail.
 160 XPCFLAGS=""
 161
 162 # Darwin doesn't need the -pthread option since threads are in libSystem
 163 AC_LINK_IFELSE(
 164  [AC_LANG_PROGRAM(
 165   [#include <pthread.h>
 166    void *g(void *d) { return NULL; }],
 167   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 168  [case $host in
 169    *-darwin*)
 170      ;;
 171    default)
 172      XPCFLAGS=" -Wc,-pthread"
 173      ;;
 174      esac],
 175  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 176   AC_LINK_IFELSE(
 177    [AC_LANG_PROGRAM(
 178     [#include <pthread.h>
 179      void *g(void *d) { return NULL; }],
 180     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 181    [],
 182    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 183
 184 # Check for functions needed.
 185 AC_CHECK_FUNCS(getloadavg clock_gettime)
 186
 187 # Check for broken semaphore implementation on darwin.
 188 # sem_init returns: sem_init error: Function not implemented.
 189 case "$host" in
 190   *-darwin*)
 191     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 192         Define if the POSIX Semaphores do not work on your system.)
 193     ;;
 194   *-linux*)
 195     case "$enable_linux_futex" in
 196       default)
 197         # If headers don't have gettid/futex syscalls definition, then
 198         # default to no, otherwise there will be compile time failures.
 199         # Otherwise, default to yes.  If we don't detect we are
 200         # compiled/linked against NPTL and not cross-compiling, check
 201         # if programs are run by default against NPTL and if not, issue
 202         # a warning.
 203         enable_linux_futex=no
 204         AC_LINK_IFELSE(
 205          [AC_LANG_PROGRAM(
 206           [#include <sys/syscall.h>
 207            int lk;],
 208           [syscall (SYS_gettid); syscall (SYS_futex, &lk, 0, 0, 0);])],
 209           [AC_LINK_IFELSE(
 210            [AC_LANG_PROGRAM(
 211             [#ifndef _GNU_SOURCE
 212              #define _GNU_SOURCE 1
 213              #endif
 214              #include <pthread.h>
 215              pthread_t th; void *status;],
 216             [pthread_tryjoin_np (th, &status);])],[enable_linux_futex=yes],
 217             [if test x$cross_compiling = xno; then
 218                if getconf GNU_LIBPTHREAD_VERSION 2>/dev/null \
 219                   | LC_ALL=C grep -i NPTL > /dev/null 2>/dev/null; then
 220                  AC_MSG_WARN([The kernel might not support futex or gettid syscalls.
 221 If so, please configure with --disable-linux-futex])
 222                fi
 223              fi
 224              enable_linux_futex=yes])])
 225         ;;
 226       yes)
 227         AC_LINK_IFELSE(
 228          [AC_LANG_PROGRAM(
 229           [#include <sys/syscall.h>
 230            int lk;],
 231           [syscall (SYS_gettid); syscall (SYS_futex, &lk, 0, 0, 0);])],[],
 232           [AC_MSG_ERROR([SYS_gettid and SYS_futex required for --enable-linux-futex])])
 233         ;;
 234     esac
 235     ;;
 236 esac
 237
 238 # At least for glibc, clock_gettime is in librt.  But don't pull that
 239 # in if it still doesn't give us the function we want.
 240 if test $ac_cv_func_clock_gettime = no; then
 241   AC_CHECK_LIB(rt, clock_gettime,
 242     [LIBS="-lrt $LIBS"
 243      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 244                [Define to 1 if you have the `clock_gettime' function.])])
 245 fi
 246
 247 # See if we support thread-local storage.
 248 GCC_CHECK_TLS
 249
 250 # See what sort of export controls are availible.
 251 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 252 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 253 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 254 LIBGOMP_ENABLE_SYMVERS
 255
 256 # Get target configury.
 257 . ${srcdir}/configure.tgt
 258 CFLAGS="$save_CFLAGS $XCFLAGS"
 259
 260 # Check for __sync_val_compare_and_swap, but only after the target has
 261 # had a chance to set XCFLAGS.
 262 LIBGOMP_CHECK_SYNC_BUILTINS
 263
 264 XCFLAGS="$XCFLAGS$XPCFLAGS"
 265
 266 AC_SUBST(config_path)
 267 AC_SUBST(XCFLAGS)
 268 AC_SUBST(XLDFLAGS)
 269
 270 # Cleanup and exit.
 271 CFLAGS="$save_CFLAGS"
 272 AC_CACHE_SAVE
 273
 274 if test ${multilib} = yes; then
 275   multilib_arg="--enable-multilib"
 276 else
 277   multilib_arg=
 278 fi
 279
 280 # Set up the set of libraries that we need to link against for libgomp.
 281 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 282 # which will force linkage against -lpthread (or equivalent for the system).
 283 # That's not 100% ideal, but about the best we can do easily.
 284 if test $enable_shared = yes; then
 285   link_gomp="-lgomp %{static: $LIBS}"
 286 else
 287   link_gomp="-lgomp $LIBS"
 288 fi
 289 AC_SUBST(link_gomp)
 290
 291 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 292
 293 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 294 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 295 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 296 # need to copy this macro to our acinclude.m4.
 297 save_CFLAGS="$CFLAGS"
 298 for i in $config_path; do
 299   if test -f $srcdir/config/$i/omp-lock.h; then
 300     CFLAGS="$CFLAGS -include $srcdir/config/$i/omp-lock.h"
 301     break
 302   fi
 303 done
 304
 305 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 306   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 307 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 308 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 309 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 310
 311 # If the lock fits in an integer, then arrange for Fortran to use that
 312 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 313 # Except that we don't have a way at present to multi-lib the installed
 314 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 315 # actual target.
 316 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 317 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 318 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 319   OMP_LOCK_KIND=8
 320 fi
 321 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 322   OMP_NEST_LOCK_KIND=8
 323 fi
 324
 325 AC_SUBST(OMP_LOCK_SIZE)
 326 AC_SUBST(OMP_LOCK_ALIGN)
 327 AC_SUBST(OMP_NEST_LOCK_SIZE)
 328 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 329 AC_SUBST(OMP_LOCK_KIND)
 330 AC_SUBST(OMP_NEST_LOCK_KIND)
 331 CFLAGS="$save_CFLAGS"
 332
 333 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 334 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 335 AC_OUTPUT