libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=1:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  46 AC_SUBST(WARN_FLAGS)
  47
  48 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  49 WERROR="-Werror"
  50 AC_SUBST(WERROR)
  51
  52 glibgo_toolexecdir=no
  53 glibgo_toolexeclibdir=no
  54 glibgo_prefixdir=$prefix
  55
  56 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  57 AC_ARG_ENABLE([version-specific-runtime-libs],
  58   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  59                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  60   [case "$enableval" in
  61     yes) version_specific_libs=yes ;;
  62     no)  version_specific_libs=no ;;
  63     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  64    esac],
  65   [version_specific_libs=no])
  66 AC_MSG_RESULT($version_specific_libs)
  67
  68 # Version-specific runtime libs processing.
  69 if test $version_specific_libs = yes; then
  70   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  71   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  72 fi
  73
  74 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  75 # Install a library built with a cross compiler in tooldir, not libdir.
  76 if test x"$glibgo_toolexecdir" = x"no"; then
  77   if test -n "$with_cross_host" &&
  78      test x"$with_cross_host" != x"no"; then
  79     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  80     glibgo_toolexeclibdir='${toolexecdir}/lib'
  81   else
  82     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  83     glibgo_toolexeclibdir='${libdir}'
  84   fi
  85   multi_os_directory=`$CC -print-multi-os-directory`
  86   case $multi_os_directory in
  87     .) ;; # Avoid trailing /.
  88     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
  89   esac
  90 fi
  91
  92 AC_SUBST(glibgo_prefixdir)
  93 AC_SUBST(glibgo_toolexecdir)
  94 AC_SUBST(glibgo_toolexeclibdir)
  95
  96 # See if the user wants to configure without libffi.  Some
  97 # architectures don't support it.  FIXME: We should set a default
  98 # based on the host.
  99 AC_ARG_WITH(libffi,
 100   AS_HELP_STRING([--without-libffi],
 101                  [don't use libffi]),
 102   [:],
 103   [with_libffi=${with_libffi_default-yes}])
 104
 105 LIBFFI=
 106 LIBFFIINCS=
 107 if test "$with_libffi" != no; then
 108    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 109    LIBFFI=../libffi/libffi_convenience.la
 110    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 111 fi
 112 AC_SUBST(LIBFFI)
 113 AC_SUBST(LIBFFIINCS)
 114
 115 is_darwin=no
 116 is_freebsd=no
 117 is_irix=no
 118 is_linux=no
 119 is_rtems=no
 120 is_solaris=no
 121 GOOS=unknown
 122 case ${host} in
 123   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 124   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 125   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 126   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 127   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 128   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 129 esac
 130 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 131 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 132 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 133 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 134 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 135 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 136 AC_SUBST(GOOS)
 137
 138 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 139 is_386=no
 140 is_arm=no
 141 is_m68k=no
 142 mips_abi=""
 143 is_ppc=no
 144 is_ppc64=no
 145 is_sparc=no
 146 is_sparc64=no
 147 is_x86_64=no
 148 GOARCH=unknown
 149 case ${host} in
 150   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 151     is_arm=yes
 152     GOARCH=arm
 153     ;;
 154 changequote(,)dnl
 155   i[34567]86-*-* | x86_64-*-*)
 156 changequote([,])dnl
 157     AC_COMPILE_IFELSE([
 158 #ifdef __x86_64__
 159 #error 64-bit
 160 #endif],
 161 [is_386=yes], [is_x86_64=yes])
 162     if test "$is_386" = "yes"; then
 163       GOARCH=386
 164     else
 165       GOARCH=amd64
 166     fi
 167     ;;
 168   m68k*-*-*)
 169     is_m68k=yes
 170     GOARCH=m68k
 171     ;;
 172   mips*-*-*)
 173     AC_COMPILE_IFELSE([
 174 #if _MIPS_SIM != _ABIO32
 175 #error not o32
 176 #endif],
 177 [mips_abi="o32"],
 178         [AC_COMPILE_IFELSE([
 179 #if _MIPS_SIM != _ABIN32
 180 #error not n32
 181 #endif],
 182 [mips_abi="n32"],
 183         [AC_COMPILE_IFELSE([
 184 #if _MIPS_SIM != _ABI64
 185 #error not n64
 186 #endif],
 187 [mips_abi="n64"],
 188         [AC_COMPILE_IFELSE([
 189 #if _MIPS_SIM != _ABIO64
 190 #error not o64
 191 #endif],
 192 [mips_abi="o64"],
 193         [AC_MSG_ERROR([unknown MIPS ABI])
 194 [mips_abi="n32"]])])])])
 195     case "$mips_abi" in
 196     "o32") GOARCH=mipso32 ;;
 197     "n32") GOARCH=mipsn32 ;;
 198     "n64") GOARCH=mipsn64 ;;
 199     "o64") GOARCH=mipso64 ;;
 200     esac
 201     ;;
 202   rs6000*-*-* | powerpc*-*-*)
 203     AC_COMPILE_IFELSE([
 204 #ifdef _ARCH_PPC64
 205 #error 64-bit
 206 #endif],
 207 [is_ppc=yes], [is_ppc64=yes])
 208     if test "$is_ppc" = "yes"; then
 209       GOARCH=ppc
 210     else
 211       GOARCH=ppc64
 212     fi
 213     ;;
 214   sparc*-*-*)
 215     AC_COMPILE_IFELSE([
 216 #if defined(__sparcv9) || defined(__arch64__)
 217 #error 64-bit
 218 #endif],
 219 [is_sparc=yes], [is_sparc64=yes])
 220     if test "$is_sparc" = "yes"; then
 221       GOARCH=sparc
 222     else
 223       GOARCH=sparc64
 224     fi
 225     ;;
 226 esac
 227 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 228 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 229 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 230 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != "")
 231 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 232 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 233 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 234 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 235 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 236 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 237 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 238 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 239 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 240 AC_SUBST(GOARCH)
 241
 242 dnl Some files are only present when needed for specific architectures.
 243 GO_SYSCALLS_SYSCALL_OS_ARCH_FILE=
 244 if test -f ${srcdir}/syscalls/syscall_${GOOS}_${GOARCH}.go; then
 245   GO_SYSCALLS_SYSCALL_OS_ARCH_FILE=syscalls/syscall_${GOOS}_${GOARCH}.go
 246 fi
 247 AC_SUBST(GO_SYSCALLS_SYSCALL_OS_ARCH_FILE)
 248
 249 GO_DEBUG_PROC_REGS_OS_ARCH_FILE=
 250 if test -f ${srcdir}/go/debug/proc/regs_${GOOS}_${GOARCH}.go; then
 251   GO_DEBUG_PROC_REGS_OS_ARCH_FILE=go/debug/proc/regs_${GOOS}_${GOARCH}.go
 252 fi
 253 AC_SUBST(GO_DEBUG_PROC_REGS_OS_ARCH_FILE)
 254
 255 dnl Use -fsplit-stack when compiling C code if available.
 256 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 257 [libgo_cv_c_split_stack_supported],
 258 [CFLAGS_hold=$CFLAGS
 259 CFLAGS="$CFLAGS -fsplit-stack"
 260 AC_COMPILE_IFELSE([[int i;]],
 261 [libgo_cv_c_split_stack_supported=yes],
 262 [libgo_cv_c_split_stack_supported=no])
 263 CFLAGS=$CFLAGS_hold])
 264 if test "$libgo_cv_c_split_stack_supported" = yes; then
 265   SPLIT_STACK=-fsplit-stack
 266   AC_DEFINE(USING_SPLIT_STACK, 1,
 267                 [Define if the compiler supports -fsplit-stack])
 268 else
 269   SPLIT_STACK=
 270 fi
 271 AC_SUBST(SPLIT_STACK)
 272 AM_CONDITIONAL(USING_SPLIT_STACK,
 273         test "$libgo_cv_c_split_stack_supported" = yes)
 274
 275 dnl Check whether the linker does stack munging when calling from
 276 dnl split-stack into non-split-stack code.  We check this by looking
 277 dnl at the --help output.  FIXME: This is only half right: it's
 278 dnl possible for the linker to support this for some targets but not
 279 dnl others.
 280 AC_CACHE_CHECK([whether linker supports split stack],
 281 [libgo_cv_c_linker_supports_split_stack],
 282 libgo_cv_c_linker_supports_split_stack=no
 283 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 284   libgo_cv_c_linker_supports_split_stack=yes
 285 fi)
 286 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 287   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 288             [Define if the linker support split stack adjustments])
 289 fi
 290
 291 dnl Test for the -lm library.
 292 MATH_LIBS=
 293 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 294 AC_SUBST(MATH_LIBS)
 295
 296 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 297 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 298   [libgo_cv_lib_sockets=
 299    libgo_check_both=no
 300    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 301    if test "$libgo_check_socket" = "yes"; then
 302      unset ac_cv_func_connect
 303      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 304                   libgo_check_both=yes)
 305    fi
 306    if test "$libgo_check_both" = "yes"; then
 307      libgo_old_libs=$LIBS
 308      LIBS="$LIBS -lsocket -lnsl"
 309      unset ac_cv_func_accept
 310      AC_CHECK_FUNC(accept,
 311                    [libgo_check_nsl=no
 312                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 313      unset ac_cv_func_accept
 314      LIBS=$libgo_old_libs
 315    fi
 316    unset ac_cv_func_gethostbyname
 317    libgo_old_libs="$LIBS"
 318    AC_CHECK_FUNC(gethostbyname, ,
 319                  [AC_CHECK_LIB(nsl, main,
 320                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 321    unset ac_cv_func_gethostbyname
 322    LIBS=$libgo_old_libs
 323 ])
 324 NET_LIBS="$libgo_cv_lib_sockets"
 325 AC_SUBST(NET_LIBS)
 326
 327 dnl Test whether the compiler supports the -pthread option.
 328 AC_CACHE_CHECK([whether -pthread is supported],
 329 [libgo_cv_lib_pthread],
 330 [CFLAGS_hold=$CFLAGS
 331 CFLAGS="$CFLAGS -pthread"
 332 AC_COMPILE_IFELSE([[int i;]],
 333 [libgo_cv_lib_pthread=yes],
 334 [libgo_cv_lib_pthread=no])
 335 CFLAGS=$CFLAGS_hold])
 336 PTHREAD_CFLAGS=
 337 if test "$libgo_cv_lib_pthread" = yes; then
 338   PTHREAD_CFLAGS=-pthread
 339 fi
 340 AC_SUBST(PTHREAD_CFLAGS)
 341
 342 dnl Test for the -lpthread library.
 343 PTHREAD_LIBS=
 344 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 345 AC_SUBST(PTHREAD_LIBS)
 346
 347 dnl Test if -lrt is required for sched_yield.
 348 AC_SEARCH_LIBS([sched_yield], [rt])
 349
 350 AC_C_BIGENDIAN
 351
 352 GCC_CHECK_UNWIND_GETIPINFO
 353
 354 AC_ARG_ENABLE(sjlj-exceptions,
 355   AC_HELP_STRING([--enable-sjlj-exceptions],
 356                  [force use of builtin_setjmp for exceptions]),
 357   [case "$enableval" in
 358    yes|no|auto) ;;
 359    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 360    esac],
 361   [enable_sjlj_exceptions=auto])
 362
 363 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 364 [libgo_cv_lib_sjlj_exceptions],
 365 [AC_LANG_CONFTEST(
 366   [AC_LANG_SOURCE([
 367 void bar ();
 368 void clean (int *);
 369 void foo ()
 370 {
 371   int i __attribute__ ((cleanup (clean)));
 372   bar();
 373 }
 374 ])])
 375 CFLAGS_hold=$CFLAGS
 376 CFLAGS="--save-temps -fexceptions"
 377 libgo_cv_lib_sjlj_exceptions=unknown
 378 AS_IF([ac_fn_c_try_compile],
 379   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 380     libgo_cv_lib_sjlj_exceptions=yes
 381   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 382     libgo_cv_lib_sjlj_exceptions=no
 383   fi])
 384 CFLAGS=$CFLAGS_hold
 385 rm -f conftest*
 386 ])
 387
 388 if test "$enable_sjlj_exceptions" = "auto"; then
 389   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 390 fi
 391
 392 case $enable_sjlj_exceptions in
 393 yes)
 394   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 395         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 396   ;;
 397 no)
 398   ;;
 399 *)
 400   AC_MSG_ERROR([unable to detect exception model])
 401   ;;
 402 esac
 403
 404 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h)
 405 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 406
 407 AC_CHECK_FUNCS(srandom random strerror_r strsignal wait4)
 408 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 409 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 410
 411 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 412 [libgo_cv_func___sync_bool_compare_and_swap_4],
 413 [AC_LINK_IFELSE([
 414 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 415 uint32 i;
 416 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 417 ],
 418 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 419 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 420 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 421   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 422     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 423 fi
 424
 425 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 426 [libgo_cv_func___sync_fetch_and_add_4],
 427 [AC_LINK_IFELSE([
 428 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 429 uint32 i;
 430 int main() { return __sync_fetch_and_add (&i, 1); }
 431 ],
 432 [libgo_cv_func___sync_fetch_and_add_4=yes],
 433 [libgo_cv_func___sync_fetch_and_add_4=no])])
 434 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 435   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 436     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 437 fi
 438
 439 dnl For x86 we want to use the -minline-all-stringops option to avoid
 440 dnl forcing a stack split when calling memcpy and friends.
 441 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 442 [libgo_cv_c_stringops],
 443 [CFLAGS_hold=$CFLAGS
 444 CFLAGS="$CFLAGS -minline-all-stringops"
 445 AC_COMPILE_IFELSE([int i;],
 446 [libgo_cv_c_stringops=yes],
 447 [libgo_cv_c_stringops=no])
 448 CFLAGS=$CFLAGS_hold])
 449 STRINGOPS_FLAG=
 450 if test "$libgo_cv_c_stringops" = yes; then
 451   STRINGOPS_FLAG=-minline-all-stringops
 452 fi
 453 AC_SUBST(STRINGOPS_FLAG)
 454
 455 CFLAGS_hold=$CFLAGS
 456 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 457 AC_CHECK_TYPES(off64_t)
 458 CFLAGS=$CFLAGS_hold
 459
 460 AC_CACHE_SAVE
 461
 462 if test ${multilib} = yes; then
 463   multilib_arg="--enable-multilib"
 464 else
 465   multilib_arg=
 466 fi
 467
 468 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 469
 470 AC_CONFIG_COMMANDS([default],
 471 [if test -n "$CONFIG_FILES"; then
 472    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 473    # that multilib installs will end up installed in the correct place.
 474    # The testsuite needs it for multilib-aware ABI baseline files.
 475    # To work around this not being passed down from config-ml.in ->
 476    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 477    # append it here.  Only modify Makefiles that have just been created.
 478    #
 479    # Also, get rid of this simulated-VPATH thing that automake does.
 480    cat > vpsed << \_EOF
 481 s!`test -f '$<' || echo '$(srcdir)/'`!!
 482 _EOF
 483    for i in $SUBDIRS; do
 484     case $CONFIG_FILES in
 485      *${i}/Makefile*)
 486        #echo "Adding MULTISUBDIR to $i/Makefile"
 487        sed -f vpsed $i/Makefile > tmp
 488        grep '^MULTISUBDIR =' Makefile >> tmp
 489        mv tmp $i/Makefile
 490        ;;
 491     esac
 492    done
 493    rm vpsed
 494  fi
 495 ],
 496 [
 497 # Variables needed in config.status (file generation) which aren't already
 498 # passed by autoconf.
 499 SUBDIRS="$SUBDIRS"
 500 ])
 501
 502 AC_OUTPUT