libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=1:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  46 AC_SUBST(WARN_FLAGS)
  47
  48 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  49 WERROR="-Werror"
  50 AC_SUBST(WERROR)
  51
  52 glibgo_toolexecdir=no
  53 glibgo_toolexeclibdir=no
  54 glibgo_prefixdir=$prefix
  55
  56 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  57 AC_ARG_ENABLE([version-specific-runtime-libs],
  58   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  59                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  60   [case "$enableval" in
  61     yes) version_specific_libs=yes ;;
  62     no)  version_specific_libs=no ;;
  63     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  64    esac],
  65   [version_specific_libs=no])
  66 AC_MSG_RESULT($version_specific_libs)
  67
  68 # Version-specific runtime libs processing.
  69 if test $version_specific_libs = yes; then
  70   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  71   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  72 fi
  73
  74 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  75 # Install a library built with a cross compiler in tooldir, not libdir.
  76 if test x"$glibgo_toolexecdir" = x"no"; then
  77   if test -n "$with_cross_host" &&
  78      test x"$with_cross_host" != x"no"; then
  79     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  80     glibgo_toolexeclibdir='${toolexecdir}/lib'
  81   else
  82     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  83     glibgo_toolexeclibdir='${libdir}'
  84   fi
  85   multi_os_directory=`$CC -print-multi-os-directory`
  86   case $multi_os_directory in
  87     .) ;; # Avoid trailing /.
  88     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
  89   esac
  90 fi
  91
  92 AC_SUBST(glibgo_prefixdir)
  93 AC_SUBST(glibgo_toolexecdir)
  94 AC_SUBST(glibgo_toolexeclibdir)
  95
  96 # See if the user wants to configure without libffi.  Some
  97 # architectures don't support it.  FIXME: We should set a default
  98 # based on the host.
  99 AC_ARG_WITH(libffi,
 100   AS_HELP_STRING([--without-libffi],
 101                  [don't use libffi]),
 102   [:],
 103   [with_libffi=${with_libffi_default-yes}])
 104
 105 LIBFFI=
 106 LIBFFIINCS=
 107 if test "$with_libffi" != no; then
 108    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 109    LIBFFI=../libffi/libffi_convenience.la
 110    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 111 fi
 112 AC_SUBST(LIBFFI)
 113 AC_SUBST(LIBFFIINCS)
 114
 115 is_darwin=no
 116 is_freebsd=no
 117 is_irix=no
 118 is_linux=no
 119 is_rtems=no
 120 is_solaris=no
 121 GOOS=unknown
 122 case ${host} in
 123   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 124   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 125   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 126   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 127   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 128   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 129 esac
 130 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 131 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 132 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 133 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 134 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 135 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 136 AC_SUBST(GOOS)
 137
 138 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 139 is_386=no
 140 is_arm=no
 141 is_m68k=no
 142 is_mips=no
 143 is_mips64=no
 144 is_ppc=no
 145 is_ppc64=no
 146 is_sparc=no
 147 is_sparc64=no
 148 is_x86_64=no
 149 GOARCH=unknown
 150 case ${host} in
 151   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 152     is_arm=yes
 153     GOARCH=arm
 154     ;;
 155 changequote(,)dnl
 156   i[34567]86-*-* | x86_64-*-*)
 157 changequote([,])dnl
 158     AC_COMPILE_IFELSE([
 159 #ifdef __x86_64__
 160 #error 64-bit
 161 #endif],
 162 [is_386=yes], [is_x86_64=yes])
 163     if test "$is_386" = "yes"; then
 164       GOARCH=386
 165     else
 166       GOARCH=amd64
 167     fi
 168     ;;
 169   m68k*-*-*)
 170     is_m68k=yes
 171     GOARCH=m68k
 172     ;;
 173   mips*-*-*)
 174     AC_COMPILE_IFELSE([
 175 #ifdef __mips64
 176 #error 64-bit
 177 #endif],
 178 [is_mips=yes], [is_mips64=yes])
 179     if test "$is_mips" = "yes"; then
 180       GOARCH=mips
 181     else
 182       GOARCH=mips64
 183     fi
 184     ;;
 185   rs6000*-*-* | powerpc*-*-*)
 186     AC_COMPILE_IFELSE([
 187 #ifdef _ARCH_PPC64
 188 #error 64-bit
 189 #endif],
 190 [is_ppc=yes], [is_ppc64=yes])
 191     if test "$is_ppc" = "yes"; then
 192       GOARCH=ppc
 193     else
 194       GOARCH=ppc64
 195     fi
 196     ;;
 197   sparc*-*-*)
 198     AC_COMPILE_IFELSE([
 199 #if defined(__sparcv9) || defined(__arch64__)
 200 #error 64-bit
 201 #endif],
 202 [is_sparc=yes], [is_sparc64=yes])
 203     if test "$is_sparc" = "yes"; then
 204       GOARCH=sparc
 205     else
 206       GOARCH=sparc64
 207     fi
 208     ;;
 209 esac
 210 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 211 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 212 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 213 AM_CONDITIONAL(LIBGO_IS_MIPS, test $is_mips = yes)
 214 AM_CONDITIONAL(LIBGO_IS_MIPS64, test $is_mips64 = yes)
 215 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 216 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 217 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 218 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 219 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 220 AC_SUBST(GOARCH)
 221
 222 dnl Some files are only present when needed for specific architectures.
 223 GO_SYSCALLS_SYSCALL_OS_ARCH_FILE=
 224 if test -f ${srcdir}/syscalls/syscall_${GOOS}_${GOARCH}.go; then
 225   GO_SYSCALLS_SYSCALL_OS_ARCH_FILE=syscalls/syscall_${GOOS}_${GOARCH}.go
 226 fi
 227 AC_SUBST(GO_SYSCALLS_SYSCALL_OS_ARCH_FILE)
 228
 229 GO_DEBUG_PROC_REGS_OS_ARCH_FILE=
 230 if test -f ${srcdir}/go/debug/proc/regs_${GOOS}_${GOARCH}.go; then
 231   GO_DEBUG_PROC_REGS_OS_ARCH_FILE=go/debug/proc/regs_${GOOS}_${GOARCH}.go
 232 fi
 233 AC_SUBST(GO_DEBUG_PROC_REGS_OS_ARCH_FILE)
 234
 235 dnl Use -fsplit-stack when compiling C code if available.
 236 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 237 [libgo_cv_c_split_stack_supported],
 238 [CFLAGS_hold=$CFLAGS
 239 CFLAGS="$CFLAGS -fsplit-stack"
 240 AC_COMPILE_IFELSE([[int i;]],
 241 [libgo_cv_c_split_stack_supported=yes],
 242 [libgo_cv_c_split_stack_supported=no])
 243 CFLAGS=$CFLAGS_hold])
 244 if test "$libgo_cv_c_split_stack_supported" = yes; then
 245   SPLIT_STACK=-fsplit-stack
 246   AC_DEFINE(USING_SPLIT_STACK, 1,
 247                 [Define if the compiler supports -fsplit-stack])
 248 else
 249   SPLIT_STACK=
 250 fi
 251 AC_SUBST(SPLIT_STACK)
 252 AM_CONDITIONAL(USING_SPLIT_STACK,
 253         test "$libgo_cv_c_split_stack_supported" = yes)
 254
 255 dnl Check whether the linker does stack munging when calling from
 256 dnl split-stack into non-split-stack code.  We check this by looking
 257 dnl at the --help output.  FIXME: This is only half right: it's
 258 dnl possible for the linker to support this for some targets but not
 259 dnl others.
 260 AC_CACHE_CHECK([whether linker supports split stack],
 261 [libgo_cv_c_linker_supports_split_stack],
 262 libgo_cv_c_linker_supports_split_stack=no
 263 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 264   libgo_cv_c_linker_supports_split_stack=yes
 265 fi)
 266 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 267   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 268             [Define if the linker support split stack adjustments])
 269 fi
 270
 271 dnl Test for the -lm library.
 272 MATH_LIBS=
 273 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 274 AC_SUBST(MATH_LIBS)
 275
 276 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 277 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 278   [libgo_cv_lib_sockets=
 279    libgo_check_both=no
 280    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 281    if test "$libgo_check_socket" = "yes"; then
 282      unset ac_cv_func_connect
 283      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 284                   libgo_check_both=yes)
 285    fi
 286    if test "$libgo_check_both" = "yes"; then
 287      libgo_old_libs=$LIBS
 288      LIBS="$LIBS -lsocket -lnsl"
 289      unset ac_cv_func_accept
 290      AC_CHECK_FUNC(accept,
 291                    [libgo_check_nsl=no
 292                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 293      unset ac_cv_func_accept
 294      LIBS=$libgo_old_libs
 295    fi
 296    unset ac_cv_func_gethostbyname
 297    libgo_old_libs="$LIBS"
 298    AC_CHECK_FUNC(gethostbyname, ,
 299                  [AC_CHECK_LIB(nsl, main,
 300                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 301    unset ac_cv_func_gethostbyname
 302    LIBS=$libgo_old_libs
 303 ])
 304 NET_LIBS="$libgo_cv_lib_sockets"
 305 AC_SUBST(NET_LIBS)
 306
 307 dnl Test whether the compiler supports the -pthread option.
 308 AC_CACHE_CHECK([whether -pthread is supported],
 309 [libgo_cv_lib_pthread],
 310 [CFLAGS_hold=$CFLAGS
 311 CFLAGS="$CFLAGS -pthread"
 312 AC_COMPILE_IFELSE([[int i;]],
 313 [libgo_cv_lib_pthread=yes],
 314 [libgo_cv_lib_pthread=no])
 315 CFLAGS=$CFLAGS_hold])
 316 PTHREAD_CFLAGS=
 317 if test "$libgo_cv_lib_pthread" = yes; then
 318   PTHREAD_CFLAGS=-pthread
 319 fi
 320 AC_SUBST(PTHREAD_CFLAGS)
 321
 322 dnl Test for the -lpthread library.
 323 PTHREAD_LIBS=
 324 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 325 AC_SUBST(PTHREAD_LIBS)
 326
 327 dnl Test if -lrt is required for sched_yield.
 328 AC_SEARCH_LIBS([sched_yield], [rt])
 329
 330 AC_C_BIGENDIAN
 331
 332 GCC_CHECK_UNWIND_GETIPINFO
 333
 334 AC_ARG_ENABLE(sjlj-exceptions,
 335   AC_HELP_STRING([--enable-sjlj-exceptions],
 336                  [force use of builtin_setjmp for exceptions]),
 337   [case "$enableval" in
 338    yes|no|auto) ;;
 339    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 340    esac],
 341   [enable_sjlj_exceptions=auto])
 342
 343 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 344 [libgo_cv_lib_sjlj_exceptions],
 345 [AC_LANG_CONFTEST(
 346   [AC_LANG_SOURCE([
 347 void bar ();
 348 void clean (int *);
 349 void foo ()
 350 {
 351   int i __attribute__ ((cleanup (clean)));
 352   bar();
 353 }
 354 ])])
 355 CFLAGS_hold=$CFLAGS
 356 CFLAGS="--save-temps -fexceptions"
 357 libgo_cv_lib_sjlj_exceptions=unknown
 358 AS_IF([ac_fn_c_try_compile],
 359   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 360     libgo_cv_lib_sjlj_exceptions=yes
 361   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 362     libgo_cv_lib_sjlj_exceptions=no
 363   fi])
 364 CFLAGS=$CFLAGS_hold
 365 rm -f conftest*
 366 ])
 367
 368 if test "$enable_sjlj_exceptions" = "auto"; then
 369   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 370 fi
 371
 372 case $enable_sjlj_exceptions in
 373 yes)
 374   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 375         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 376   ;;
 377 no)
 378   ;;
 379 *)
 380   AC_MSG_ERROR([unable to detect exception model])
 381   ;;
 382 esac
 383
 384 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h)
 385 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 386
 387 AC_CHECK_FUNCS(srandom random strerror_r strsignal wait4)
 388 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 389 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 390
 391 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 392 [libgo_cv_func___sync_bool_compare_and_swap_4],
 393 [AC_LINK_IFELSE([
 394 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 395 uint32 i;
 396 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 397 ],
 398 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 399 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 400 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 401   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 402     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 403 fi
 404
 405 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 406 [libgo_cv_func___sync_fetch_and_add_4],
 407 [AC_LINK_IFELSE([
 408 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 409 uint32 i;
 410 int main() { return __sync_fetch_and_add (&i, 1); }
 411 ],
 412 [libgo_cv_func___sync_fetch_and_add_4=yes],
 413 [libgo_cv_func___sync_fetch_and_add_4=no])])
 414 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 415   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 416     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 417 fi
 418
 419 dnl For x86 we want to use the -minline-all-stringops option to avoid
 420 dnl forcing a stack split when calling memcpy and friends.
 421 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 422 [libgo_cv_c_stringops],
 423 [CFLAGS_hold=$CFLAGS
 424 CFLAGS="$CFLAGS -minline-all-stringops"
 425 AC_COMPILE_IFELSE([int i;],
 426 [libgo_cv_c_stringops=yes],
 427 [libgo_cv_c_stringops=no])
 428 CFLAGS=$CFLAGS_hold])
 429 STRINGOPS_FLAG=
 430 if test "$libgo_cv_c_stringops" = yes; then
 431   STRINGOPS_FLAG=-minline-all-stringops
 432 fi
 433 AC_SUBST(STRINGOPS_FLAG)
 434
 435 CFLAGS_hold=$CFLAGS
 436 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 437 AC_CHECK_TYPES(off64_t)
 438 CFLAGS=$CFLAGS_hold
 439
 440 AC_CACHE_SAVE
 441
 442 if test ${multilib} = yes; then
 443   multilib_arg="--enable-multilib"
 444 else
 445   multilib_arg=
 446 fi
 447
 448 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 449
 450 AC_CONFIG_COMMANDS([default],
 451 [if test -n "$CONFIG_FILES"; then
 452    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 453    # that multilib installs will end up installed in the correct place.
 454    # The testsuite needs it for multilib-aware ABI baseline files.
 455    # To work around this not being passed down from config-ml.in ->
 456    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 457    # append it here.  Only modify Makefiles that have just been created.
 458    #
 459    # Also, get rid of this simulated-VPATH thing that automake does.
 460    cat > vpsed << \_EOF
 461 s!`test -f '$<' || echo '$(srcdir)/'`!!
 462 _EOF
 463    for i in $SUBDIRS; do
 464     case $CONFIG_FILES in
 465      *${i}/Makefile*)
 466        #echo "Adding MULTISUBDIR to $i/Makefile"
 467        sed -f vpsed $i/Makefile > tmp
 468        grep '^MULTISUBDIR =' Makefile >> tmp
 469        mv tmp $i/Makefile
 470        ;;
 471     esac
 472    done
 473    rm vpsed
 474  fi
 475 ],
 476 [
 477 # Variables needed in config.status (file generation) which aren't already
 478 # passed by autoconf.
 479 SUBDIRS="$SUBDIRS"
 480 ])
 481
 482 AC_OUTPUT