libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=1:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  54 WERROR="-Werror"
  55 AC_SUBST(WERROR)
  56
  57 glibgo_toolexecdir=no
  58 glibgo_toolexeclibdir=no
  59 glibgo_prefixdir=$prefix
  60
  61 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  62 AC_ARG_ENABLE([version-specific-runtime-libs],
  63   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  64                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  65   [case "$enableval" in
  66     yes) version_specific_libs=yes ;;
  67     no)  version_specific_libs=no ;;
  68     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  69    esac],
  70   [version_specific_libs=no])
  71 AC_MSG_RESULT($version_specific_libs)
  72
  73 # Version-specific runtime libs processing.
  74 if test $version_specific_libs = yes; then
  75   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  76   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  77 fi
  78
  79 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  80 # Install a library built with a cross compiler in tooldir, not libdir.
  81 if test x"$glibgo_toolexecdir" = x"no"; then
  82   if test -n "$with_cross_host" &&
  83      test x"$with_cross_host" != x"no"; then
  84     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  85     glibgo_toolexeclibdir='${toolexecdir}/lib'
  86   else
  87     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  88     glibgo_toolexeclibdir='${libdir}'
  89   fi
  90   multi_os_directory=`$CC -print-multi-os-directory`
  91   case $multi_os_directory in
  92     .) ;; # Avoid trailing /.
  93     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
  94   esac
  95 fi
  96
  97 AC_SUBST(glibgo_prefixdir)
  98 AC_SUBST(glibgo_toolexecdir)
  99 AC_SUBST(glibgo_toolexeclibdir)
 100
 101 # See if the user wants to configure without libffi.  Some
 102 # architectures don't support it.  FIXME: We should set a default
 103 # based on the host.
 104 AC_ARG_WITH(libffi,
 105   AS_HELP_STRING([--without-libffi],
 106                  [don't use libffi]),
 107   [:],
 108   [with_libffi=${with_libffi_default-yes}])
 109
 110 LIBFFI=
 111 LIBFFIINCS=
 112 if test "$with_libffi" != no; then
 113    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 114    LIBFFI=../libffi/libffi_convenience.la
 115    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 116 fi
 117 AC_SUBST(LIBFFI)
 118 AC_SUBST(LIBFFIINCS)
 119
 120 is_darwin=no
 121 is_freebsd=no
 122 is_irix=no
 123 is_linux=no
 124 is_rtems=no
 125 is_solaris=no
 126 GOOS=unknown
 127 case ${host} in
 128   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 129   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 130   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 131   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 132   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 133   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 134 esac
 135 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 136 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 137 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 138 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 139 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 140 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 141 AC_SUBST(GOOS)
 142
 143 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 144 is_386=no
 145 is_alpha=no
 146 is_arm=no
 147 is_m68k=no
 148 mips_abi=unknown
 149 is_ppc=no
 150 is_ppc64=no
 151 is_sparc=no
 152 is_sparc64=no
 153 is_x86_64=no
 154 GOARCH=unknown
 155 case ${host} in
 156   alpha*-*-*)
 157     is_alpha=yes
 158     GOARCH=alpha
 159     ;;
 160   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 161     is_arm=yes
 162     GOARCH=arm
 163     ;;
 164 changequote(,)dnl
 165   i[34567]86-*-* | x86_64-*-*)
 166 changequote([,])dnl
 167     AC_COMPILE_IFELSE([
 168 #ifdef __x86_64__
 169 #error 64-bit
 170 #endif],
 171 [is_386=yes], [is_x86_64=yes])
 172     if test "$is_386" = "yes"; then
 173       GOARCH=386
 174     else
 175       GOARCH=amd64
 176     fi
 177     ;;
 178   m68k*-*-*)
 179     is_m68k=yes
 180     GOARCH=m68k
 181     ;;
 182   mips*-*-*)
 183     AC_COMPILE_IFELSE([
 184 #if _MIPS_SIM != _ABIO32
 185 #error not o32
 186 #endif],
 187 [mips_abi="o32"],
 188         [AC_COMPILE_IFELSE([
 189 #if _MIPS_SIM != _ABIN32
 190 #error not n32
 191 #endif],
 192 [mips_abi="n32"],
 193         [AC_COMPILE_IFELSE([
 194 #if _MIPS_SIM != _ABI64
 195 #error not n64
 196 #endif],
 197 [mips_abi="n64"],
 198         [AC_COMPILE_IFELSE([
 199 #if _MIPS_SIM != _ABIO64
 200 #error not o64
 201 #endif],
 202 [mips_abi="o64"],
 203         [AC_MSG_ERROR([unknown MIPS ABI])
 204 [mips_abi="n32"]])])])])
 205     case "$mips_abi" in
 206     "o32") GOARCH=mipso32 ;;
 207     "n32") GOARCH=mipsn32 ;;
 208     "n64") GOARCH=mipsn64 ;;
 209     "o64") GOARCH=mipso64 ;;
 210     esac
 211     ;;
 212   rs6000*-*-* | powerpc*-*-*)
 213     AC_COMPILE_IFELSE([
 214 #ifdef _ARCH_PPC64
 215 #error 64-bit
 216 #endif],
 217 [is_ppc=yes], [is_ppc64=yes])
 218     if test "$is_ppc" = "yes"; then
 219       GOARCH=ppc
 220     else
 221       GOARCH=ppc64
 222     fi
 223     ;;
 224   sparc*-*-*)
 225     AC_COMPILE_IFELSE([
 226 #if defined(__sparcv9) || defined(__arch64__)
 227 #error 64-bit
 228 #endif],
 229 [is_sparc=yes], [is_sparc64=yes])
 230     if test "$is_sparc" = "yes"; then
 231       GOARCH=sparc
 232     else
 233       GOARCH=sparc64
 234     fi
 235     ;;
 236 esac
 237 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 238 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 239 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 240 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 241 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 242 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 243 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 244 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 245 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 246 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 247 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 248 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 249 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 250 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 251 AC_SUBST(GOARCH)
 252
 253 dnl Some files are only present when needed for specific architectures.
 254 GO_LIBCALL_OS_FILE=
 255 GO_LIBCALL_OS_ARCH_FILE=
 256 GO_SYSCALL_OS_FILE=
 257 GO_SYSCALL_OS_ARCH_FILE=
 258 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 259   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 260 fi
 261 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 262   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 263 fi
 264 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 265   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 266 fi
 267 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 268   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 269 fi
 270 AC_SUBST(GO_LIBCALL_OS_FILE)
 271 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 272 AC_SUBST(GO_SYSCALL_OS_FILE)
 273 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 274
 275 dnl Some targets need special flags to build sysinfo.go.
 276 case "$target" in
 277     mips-sgi-irix6.5*)
 278         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 279         # msghdr in <sys/socket.h>.
 280         OSCFLAGS='-D_XOPEN_SOURCE=500'
 281         ;;
 282     *-*-solaris2.[[89]])
 283         # Solaris 8/9 need this so struct msghdr gets the msg_control
 284         # etc. fields in <sys/socket.h> (_XPG4_2).
 285         OSCFLAGS='-D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D__EXTENSIONS__'
 286         ;;
 287     *-*-solaris2.1[[01]])
 288         # Solaris 10+ needs this so struct msghdr gets the msg_control
 289         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=500 as
 290         # above doesn't work with C99.
 291         OSCFLAGS='-D_XOPEN_SOURCE=600 -D__EXTENSIONS__'
 292         ;;
 293 esac
 294 AC_SUBST(OSCFLAGS)
 295
 296 dnl Use -fsplit-stack when compiling C code if available.
 297 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 298 [libgo_cv_c_split_stack_supported],
 299 [CFLAGS_hold=$CFLAGS
 300 CFLAGS="$CFLAGS -fsplit-stack"
 301 AC_COMPILE_IFELSE([[int i;]],
 302 [libgo_cv_c_split_stack_supported=yes],
 303 [libgo_cv_c_split_stack_supported=no])
 304 CFLAGS=$CFLAGS_hold])
 305 if test "$libgo_cv_c_split_stack_supported" = yes; then
 306   SPLIT_STACK=-fsplit-stack
 307   AC_DEFINE(USING_SPLIT_STACK, 1,
 308                 [Define if the compiler supports -fsplit-stack])
 309 else
 310   SPLIT_STACK=
 311 fi
 312 AC_SUBST(SPLIT_STACK)
 313 AM_CONDITIONAL(USING_SPLIT_STACK,
 314         test "$libgo_cv_c_split_stack_supported" = yes)
 315
 316 dnl Check whether the linker does stack munging when calling from
 317 dnl split-stack into non-split-stack code.  We check this by looking
 318 dnl at the --help output.  FIXME: This is only half right: it's
 319 dnl possible for the linker to support this for some targets but not
 320 dnl others.
 321 AC_CACHE_CHECK([whether linker supports split stack],
 322 [libgo_cv_c_linker_supports_split_stack],
 323 libgo_cv_c_linker_supports_split_stack=no
 324 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 325   libgo_cv_c_linker_supports_split_stack=yes
 326 fi)
 327 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 328   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 329             [Define if the linker support split stack adjustments])
 330 fi
 331
 332 dnl Test for the -lm library.
 333 MATH_LIBS=
 334 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 335 AC_SUBST(MATH_LIBS)
 336
 337 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 338 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 339   [libgo_cv_lib_sockets=
 340    libgo_check_both=no
 341    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 342    if test "$libgo_check_socket" = "yes"; then
 343      unset ac_cv_func_connect
 344      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 345                   libgo_check_both=yes)
 346    fi
 347    if test "$libgo_check_both" = "yes"; then
 348      libgo_old_libs=$LIBS
 349      LIBS="$LIBS -lsocket -lnsl"
 350      unset ac_cv_func_accept
 351      AC_CHECK_FUNC(accept,
 352                    [libgo_check_nsl=no
 353                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 354      unset ac_cv_func_accept
 355      LIBS=$libgo_old_libs
 356    fi
 357    unset ac_cv_func_gethostbyname
 358    libgo_old_libs="$LIBS"
 359    AC_CHECK_FUNC(gethostbyname, ,
 360                  [AC_CHECK_LIB(nsl, main,
 361                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 362    unset ac_cv_func_gethostbyname
 363    LIBS=$libgo_old_libs
 364 ])
 365 NET_LIBS="$libgo_cv_lib_sockets"
 366 AC_SUBST(NET_LIBS)
 367
 368 dnl Test whether the compiler supports the -pthread option.
 369 AC_CACHE_CHECK([whether -pthread is supported],
 370 [libgo_cv_lib_pthread],
 371 [CFLAGS_hold=$CFLAGS
 372 CFLAGS="$CFLAGS -pthread"
 373 AC_COMPILE_IFELSE([[int i;]],
 374 [libgo_cv_lib_pthread=yes],
 375 [libgo_cv_lib_pthread=no])
 376 CFLAGS=$CFLAGS_hold])
 377 PTHREAD_CFLAGS=
 378 if test "$libgo_cv_lib_pthread" = yes; then
 379   PTHREAD_CFLAGS=-pthread
 380 fi
 381 AC_SUBST(PTHREAD_CFLAGS)
 382
 383 dnl Test for the -lpthread library.
 384 PTHREAD_LIBS=
 385 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 386 AC_SUBST(PTHREAD_LIBS)
 387
 388 dnl Test if -lrt is required for sched_yield.
 389 AC_SEARCH_LIBS([sched_yield], [rt])
 390
 391 AC_C_BIGENDIAN
 392
 393 GCC_CHECK_UNWIND_GETIPINFO
 394
 395 AC_ARG_ENABLE(sjlj-exceptions,
 396   AC_HELP_STRING([--enable-sjlj-exceptions],
 397                  [force use of builtin_setjmp for exceptions]),
 398   [case "$enableval" in
 399    yes|no|auto) ;;
 400    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 401    esac],
 402   [enable_sjlj_exceptions=auto])
 403
 404 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 405 [libgo_cv_lib_sjlj_exceptions],
 406 [AC_LANG_CONFTEST(
 407   [AC_LANG_SOURCE([
 408 void bar ();
 409 void clean (int *);
 410 void foo ()
 411 {
 412   int i __attribute__ ((cleanup (clean)));
 413   bar();
 414 }
 415 ])])
 416 CFLAGS_hold=$CFLAGS
 417 CFLAGS="--save-temps -fexceptions"
 418 libgo_cv_lib_sjlj_exceptions=unknown
 419 AS_IF([ac_fn_c_try_compile],
 420   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 421     libgo_cv_lib_sjlj_exceptions=yes
 422   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 423     libgo_cv_lib_sjlj_exceptions=no
 424   fi])
 425 CFLAGS=$CFLAGS_hold
 426 rm -f conftest*
 427 ])
 428
 429 if test "$enable_sjlj_exceptions" = "auto"; then
 430   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 431 fi
 432
 433 case $enable_sjlj_exceptions in
 434 yes)
 435   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 436         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 437   ;;
 438 no)
 439   ;;
 440 *)
 441   AC_MSG_ERROR([unable to detect exception model])
 442   ;;
 443 esac
 444
 445 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h)
 446
 447 AC_CHECK_HEADERS([linux/filter.h linux/netlink.h linux/rtnetlink.h], [], [],
 448 [#ifdef HAVE_SYS_SOCKET_H
 449 #include <sys/socket.h>
 450 #endif
 451 ])
 452
 453 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 454
 455 AC_CHECK_FUNCS(srandom random strerror_r strsignal wait4 mincore setenv)
 456 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 457 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 458
 459 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 460 [libgo_cv_func___sync_bool_compare_and_swap_4],
 461 [AC_LINK_IFELSE([
 462 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 463 uint32 i;
 464 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 465 ],
 466 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 467 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 468 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 469   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 470     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 471 fi
 472
 473 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 474 [libgo_cv_func___sync_fetch_and_add_4],
 475 [AC_LINK_IFELSE([
 476 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 477 uint32 i;
 478 int main() { return __sync_fetch_and_add (&i, 1); }
 479 ],
 480 [libgo_cv_func___sync_fetch_and_add_4=yes],
 481 [libgo_cv_func___sync_fetch_and_add_4=no])])
 482 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 483   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 484     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 485 fi
 486
 487 dnl For x86 we want to use the -minline-all-stringops option to avoid
 488 dnl forcing a stack split when calling memcpy and friends.
 489 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 490 [libgo_cv_c_stringops],
 491 [CFLAGS_hold=$CFLAGS
 492 CFLAGS="$CFLAGS -minline-all-stringops"
 493 AC_COMPILE_IFELSE([int i;],
 494 [libgo_cv_c_stringops=yes],
 495 [libgo_cv_c_stringops=no])
 496 CFLAGS=$CFLAGS_hold])
 497 STRINGOPS_FLAG=
 498 if test "$libgo_cv_c_stringops" = yes; then
 499   STRINGOPS_FLAG=-minline-all-stringops
 500 fi
 501 AC_SUBST(STRINGOPS_FLAG)
 502
 503 CFLAGS_hold=$CFLAGS
 504 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 505 AC_CHECK_TYPES(off64_t)
 506 CFLAGS=$CFLAGS_hold
 507
 508 dnl Work out the size of the epoll_events struct on GNU/Linux.
 509 AC_CACHE_CHECK([epoll_event size],
 510 [libgo_cv_c_epoll_event_size],
 511 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 512 [sizeof (struct epoll_event)],
 513 [#include <sys/epoll.h>],
 514 [libgo_cv_c_epoll_event_size=0])])
 515 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 516 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 517
 518 dnl Work out the offset of the fd field in the epoll_events struct on
 519 dnl GNU/Linux.
 520 AC_CACHE_CHECK([epoll_event data.fd offset],
 521 [libgo_cv_c_epoll_event_fd_offset],
 522 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 523 [offsetof (struct epoll_event, data.fd)],
 524 [#include <stddef.h>
 525 #include <sys/epoll.h>],
 526 [libgo_cv_c_epoll_event_fd_offset=0])])
 527 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 528 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 529
 530 AC_CACHE_SAVE
 531
 532 if test ${multilib} = yes; then
 533   multilib_arg="--enable-multilib"
 534 else
 535   multilib_arg=
 536 fi
 537
 538 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 539
 540 AC_CONFIG_COMMANDS([default],
 541 [if test -n "$CONFIG_FILES"; then
 542    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 543    # that multilib installs will end up installed in the correct place.
 544    # The testsuite needs it for multilib-aware ABI baseline files.
 545    # To work around this not being passed down from config-ml.in ->
 546    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 547    # append it here.  Only modify Makefiles that have just been created.
 548    #
 549    # Also, get rid of this simulated-VPATH thing that automake does.
 550    cat > vpsed << \_EOF
 551 s!`test -f '$<' || echo '$(srcdir)/'`!!
 552 _EOF
 553    for i in $SUBDIRS; do
 554     case $CONFIG_FILES in
 555      *${i}/Makefile*)
 556        #echo "Adding MULTISUBDIR to $i/Makefile"
 557        sed -f vpsed $i/Makefile > tmp
 558        grep '^MULTISUBDIR =' Makefile >> tmp
 559        mv tmp $i/Makefile
 560        ;;
 561     esac
 562    done
 563    rm vpsed
 564  fi
 565 ],
 566 [
 567 # Variables needed in config.status (file generation) which aren't already
 568 # passed by autoconf.
 569 SUBDIRS="$SUBDIRS"
 570 ])
 571
 572 AC_OUTPUT