libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=1:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  46 AC_SUBST(WARN_FLAGS)
  47
  48 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  49 WERROR="-Werror"
  50 AC_SUBST(WERROR)
  51
  52 glibgo_toolexecdir=no
  53 glibgo_toolexeclibdir=no
  54 glibgo_prefixdir=$prefix
  55
  56 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  57 AC_ARG_ENABLE([version-specific-runtime-libs],
  58   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  59                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  60   [case "$enableval" in
  61     yes) version_specific_libs=yes ;;
  62     no)  version_specific_libs=no ;;
  63     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  64    esac],
  65   [version_specific_libs=no])
  66 AC_MSG_RESULT($version_specific_libs)
  67
  68 # Version-specific runtime libs processing.
  69 if test $version_specific_libs = yes; then
  70   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  71   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  72 fi
  73
  74 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  75 # Install a library built with a cross compiler in tooldir, not libdir.
  76 if test x"$glibgo_toolexecdir" = x"no"; then
  77   if test -n "$with_cross_host" &&
  78      test x"$with_cross_host" != x"no"; then
  79     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  80     glibgo_toolexeclibdir='${toolexecdir}/lib'
  81   else
  82     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  83     glibgo_toolexeclibdir='${libdir}'
  84   fi
  85   multi_os_directory=`$CC -print-multi-os-directory`
  86   case $multi_os_directory in
  87     .) ;; # Avoid trailing /.
  88     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
  89   esac
  90 fi
  91
  92 AC_SUBST(glibgo_prefixdir)
  93 AC_SUBST(glibgo_toolexecdir)
  94 AC_SUBST(glibgo_toolexeclibdir)
  95
  96 # See if the user wants to configure without libffi.  Some
  97 # architectures don't support it.  FIXME: We should set a default
  98 # based on the host.
  99 AC_ARG_WITH(libffi,
 100   AS_HELP_STRING([--without-libffi],
 101                  [don't use libffi]),
 102   [:],
 103   [with_libffi=${with_libffi_default-yes}])
 104
 105 LIBFFI=
 106 LIBFFIINCS=
 107 if test "$with_libffi" != no; then
 108    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 109    LIBFFI=../libffi/libffi_convenience.la
 110    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 111 fi
 112 AC_SUBST(LIBFFI)
 113 AC_SUBST(LIBFFIINCS)
 114
 115 is_darwin=no
 116 is_freebsd=no
 117 is_linux=no
 118 is_rtems=no
 119 is_solaris=no
 120 GOOS=unknown
 121 case ${host} in
 122   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 123   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 124   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 125   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 126   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 127 esac
 128 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 129 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 130 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 131 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 132 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 133 AC_SUBST(GOOS)
 134
 135 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 136 is_386=no
 137 is_arm=no
 138 is_m68k=no
 139 is_mips=no
 140 is_mips64=no
 141 is_ppc=no
 142 is_ppc64=no
 143 is_sparc=no
 144 is_sparc64=no
 145 is_x86_64=no
 146 GOARCH=unknown
 147 case ${host} in
 148   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 149     is_arm=yes
 150     GOARCH=arm
 151     ;;
 152 changequote(,)dnl
 153   i[34567]86-*-* | x86_64-*-*)
 154 changequote([,])dnl
 155     AC_COMPILE_IFELSE([
 156 #ifdef __x86_64__
 157 #error 64-bit
 158 #endif],
 159 [is_386=yes], [is_x86_64=yes])
 160     if test "$is_386" = "yes"; then
 161       GOARCH=386
 162     else
 163       GOARCH=amd64
 164     fi
 165     ;;
 166   m68k*-*-*)
 167     is_m68k=yes
 168     GOARCH=m68k
 169     ;;
 170   mips*-*-*)
 171     AC_COMPILE_IFELSE([
 172 #ifdef __mips64
 173 #error 64-bit
 174 #endif],
 175 [is_mips=yes], [is_mips64=yes])
 176     if test "$is_mips" = "yes"; then
 177       GOARCH=mips
 178     else
 179       GOARCH=mips64
 180     fi
 181     ;;
 182   rs6000*-*-* | powerpc*-*-*)
 183     AC_COMPILE_IFELSE([
 184 #ifdef _ARCH_PPC64
 185 #error 64-bit
 186 #endif],
 187 [is_ppc=yes], [is_ppc64=yes])
 188     if test "$is_ppc" = "yes"; then
 189       GOARCH=ppc
 190     else
 191       GOARCH=ppc64
 192     fi
 193     ;;
 194   sparc*-*-*)
 195     AC_COMPILE_IFELSE([
 196 #if defined(__sparcv9) || defined(__arch64__)
 197 #error 64-bit
 198 #endif],
 199 [is_sparc=yes], [is_sparc64=yes])
 200     if test "$is_sparc" = "yes"; then
 201       GOARCH=sparc
 202     else
 203       GOARCH=sparc64
 204     fi
 205     ;;
 206 esac
 207 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 208 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 209 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 210 AM_CONDITIONAL(LIBGO_IS_MIPS, test $is_mips = yes)
 211 AM_CONDITIONAL(LIBGO_IS_MIPS64, test $is_mips64 = yes)
 212 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 213 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 214 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 215 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 216 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 217 AC_SUBST(GOARCH)
 218
 219 dnl Some files are only present when needed for specific architectures.
 220 GO_SYSCALLS_SYSCALL_OS_ARCH_FILE=
 221 if test -f ${srcdir}/syscalls/syscall_${GOOS}_${GOARCH}.go; then
 222   GO_SYSCALLS_SYSCALL_OS_ARCH_FILE=syscalls/syscall_${GOOS}_${GOARCH}.go
 223 fi
 224 AC_SUBST(GO_SYSCALLS_SYSCALL_OS_ARCH_FILE)
 225
 226 GO_DEBUG_PROC_REGS_OS_ARCH_FILE=
 227 if test -f ${srcdir}/go/debug/proc/regs_${GOOS}_${GOARCH}.go; then
 228   GO_DEBUG_PROC_REGS_OS_ARCH_FILE=go/debug/proc/regs_${GOOS}_${GOARCH}.go
 229 fi
 230 AC_SUBST(GO_DEBUG_PROC_REGS_OS_ARCH_FILE)
 231
 232 dnl Use -fsplit-stack when compiling C code if available.
 233 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 234 [libgo_cv_c_split_stack_supported],
 235 [CFLAGS_hold=$CFLAGS
 236 CFLAGS="$CFLAGS -fsplit-stack"
 237 AC_COMPILE_IFELSE([[int i;]],
 238 [libgo_cv_c_split_stack_supported=yes],
 239 [libgo_cv_c_split_stack_supported=no])
 240 CFLAGS=$CFLAGS_hold])
 241 if test "$libgo_cv_c_split_stack_supported" = yes; then
 242   SPLIT_STACK=-fsplit-stack
 243   AC_DEFINE(USING_SPLIT_STACK, 1,
 244                 [Define if the compiler supports -fsplit-stack])
 245 else
 246   SPLIT_STACK=
 247 fi
 248 AC_SUBST(SPLIT_STACK)
 249 AM_CONDITIONAL(USING_SPLIT_STACK,
 250         test "$libgo_cv_c_split_stack_supported" = yes)
 251
 252 dnl Check whether the linker does stack munging when calling from
 253 dnl split-stack into non-split-stack code.  We check this by looking
 254 dnl at the --help output.  FIXME: This is only half right: it's
 255 dnl possible for the linker to support this for some targets but not
 256 dnl others.
 257 AC_CACHE_CHECK([whether linker supports split stack],
 258 [libgo_cv_c_linker_supports_split_stack],
 259 libgo_cv_c_linker_supports_split_stack=no
 260 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 261   libgo_cv_c_linker_supports_split_stack=yes
 262 fi)
 263 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 264   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 265             [Define if the linker support split stack adjustments])
 266 fi
 267
 268 dnl Test for the -lm library.
 269 MATH_LIBS=
 270 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 271 AC_SUBST(MATH_LIBS)
 272
 273 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 274 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 275   [libgo_cv_lib_sockets=
 276    libgo_check_both=no
 277    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 278    if test "$libgo_check_socket" = "yes"; then
 279      unset ac_cv_func_connect
 280      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 281                   libgo_check_both=yes)
 282    fi
 283    if test "$libgo_check_both" = "yes"; then
 284      libgo_old_libs=$LIBS
 285      LIBS="$LIBS -lsocket -lnsl"
 286      unset ac_cv_func_accept
 287      AC_CHECK_FUNC(accept,
 288                    [libgo_check_nsl=no
 289                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 290      unset ac_cv_func_accept
 291      LIBS=$libgo_old_libs
 292    fi
 293    unset ac_cv_func_gethostbyname
 294    libgo_old_libs="$LIBS"
 295    AC_CHECK_FUNC(gethostbyname, ,
 296                  [AC_CHECK_LIB(nsl, main,
 297                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 298    unset ac_cv_func_gethostbyname
 299    LIBS=$libgo_old_libs
 300 ])
 301 NET_LIBS="$libgo_cv_lib_sockets"
 302 AC_SUBST(NET_LIBS)
 303
 304 dnl Test whether the compiler supports the -pthread option.
 305 AC_CACHE_CHECK([whether -pthread is supported],
 306 [libgo_cv_lib_pthread],
 307 [CFLAGS_hold=$CFLAGS
 308 CFLAGS="$CFLAGS -pthread"
 309 AC_COMPILE_IFELSE([[int i;]],
 310 [libgo_cv_lib_pthread=yes],
 311 [libgo_cv_lib_pthread=no])
 312 CFLAGS=$CFLAGS_hold])
 313 PTHREAD_CFLAGS=
 314 if test "$libgo_cv_lib_pthread" = yes; then
 315   PTHREAD_CFLAGS=-pthread
 316 fi
 317 AC_SUBST(PTHREAD_CFLAGS)
 318
 319 dnl Test for the -lpthread library.
 320 PTHREAD_LIBS=
 321 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 322 AC_SUBST(PTHREAD_LIBS)
 323
 324 dnl Test if -lrt is required for sched_yield.
 325 AC_SEARCH_LIBS([sched_yield], [rt])
 326
 327 AC_C_BIGENDIAN
 328
 329 GCC_CHECK_UNWIND_GETIPINFO
 330
 331 AC_ARG_ENABLE(sjlj-exceptions,
 332   AC_HELP_STRING([--enable-sjlj-exceptions],
 333                  [force use of builtin_setjmp for exceptions]),
 334   [case "$enableval" in
 335    yes|no|auto) ;;
 336    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 337    esac],
 338   [enable_sjlj_exceptions=auto])
 339
 340 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 341 [libgo_cv_lib_sjlj_exceptions],
 342 [AC_LANG_CONFTEST(
 343   [AC_LANG_SOURCE([
 344 void bar ();
 345 void clean (int *);
 346 void foo ()
 347 {
 348   int i __attribute__ ((cleanup (clean)));
 349   bar();
 350 }
 351 ])])
 352 CFLAGS_hold=$CFLAGS
 353 CFLAGS="--save-temps -fexceptions"
 354 libgo_cv_lib_sjlj_exceptions=unknown
 355 AS_IF([ac_fn_c_try_compile],
 356   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 357     libgo_cv_lib_sjlj_exceptions=yes
 358   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 359     libgo_cv_lib_sjlj_exceptions=no
 360   fi])
 361 CFLAGS=$CFLAGS_hold
 362 rm -f conftest*
 363 ])
 364
 365 if test "$enable_sjlj_exceptions" = "auto"; then
 366   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 367 fi
 368
 369 case $enable_sjlj_exceptions in
 370 yes)
 371   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 372         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 373   ;;
 374 no)
 375   ;;
 376 *)
 377   AC_MSG_ERROR([unable to detect exception model])
 378   ;;
 379 esac
 380
 381 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h)
 382 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 383
 384 AC_CHECK_FUNCS(srandom random strerror_r strsignal)
 385 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 386
 387 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 388 [libgo_cv_func___sync_bool_compare_and_swap_4],
 389 [AC_LINK_IFELSE([
 390 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 391 uint32 i;
 392 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 393 ],
 394 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 395 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 396 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 397   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 398     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 399 fi
 400
 401 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 402 [libgo_cv_func___sync_fetch_and_add_4],
 403 [AC_LINK_IFELSE([
 404 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 405 uint32 i;
 406 int main() { return __sync_fetch_and_add (&i, 1); }
 407 ],
 408 [libgo_cv_func___sync_fetch_and_add_4=yes],
 409 [libgo_cv_func___sync_fetch_and_add_4=no])])
 410 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 411   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 412     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 413 fi
 414
 415 dnl For x86 we want to use the -minline-all-stringops option to avoid
 416 dnl forcing a stack split when calling memcpy and friends.
 417 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 418 [libgo_cv_c_stringops],
 419 [CFLAGS_hold=$CFLAGS
 420 CFLAGS="$CFLAGS -minline-all-stringops"
 421 AC_COMPILE_IFELSE([int i;],
 422 [libgo_cv_c_stringops=yes],
 423 [libgo_cv_c_stringops=no])
 424 CFLAGS=$CFLAGS_hold])
 425 STRINGOPS_FLAG=
 426 if test "$libgo_cv_c_stringops" = yes; then
 427   STRINGOPS_FLAG=-minline-all-stringops
 428 fi
 429 AC_SUBST(STRINGOPS_FLAG)
 430
 431 CFLAGS_hold=$CFLAGS
 432 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 433 AC_CHECK_TYPES(off64_t)
 434 CFLAGS=$CFLAGS_hold
 435
 436 AC_CACHE_SAVE
 437
 438 if test ${multilib} = yes; then
 439   multilib_arg="--enable-multilib"
 440 else
 441   multilib_arg=
 442 fi
 443
 444 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 445
 446 AC_CONFIG_COMMANDS([default],
 447 [if test -n "$CONFIG_FILES"; then
 448    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 449    # that multilib installs will end up installed in the correct place.
 450    # The testsuite needs it for multilib-aware ABI baseline files.
 451    # To work around this not being passed down from config-ml.in ->
 452    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 453    # append it here.  Only modify Makefiles that have just been created.
 454    #
 455    # Also, get rid of this simulated-VPATH thing that automake does.
 456    cat > vpsed << \_EOF
 457 s!`test -f '$<' || echo '$(srcdir)/'`!!
 458 _EOF
 459    for i in $SUBDIRS; do
 460     case $CONFIG_FILES in
 461      *${i}/Makefile*)
 462        #echo "Adding MULTISUBDIR to $i/Makefile"
 463        sed -f vpsed $i/Makefile > tmp
 464        grep '^MULTISUBDIR =' Makefile >> tmp
 465        mv tmp $i/Makefile
 466        ;;
 467     esac
 468    done
 469    rm vpsed
 470  fi
 471 ],
 472 [
 473 # Variables needed in config.status (file generation) which aren't already
 474 # passed by autoconf.
 475 SUBDIRS="$SUBDIRS"
 476 ])
 477
 478 AC_OUTPUT