libffi/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(fficonfig.h.in)
   3 AM_CONFIG_HEADER(fficonfig.h)
   4
   5 # This works around the fact that libtool configuration may change LD
   6 # for this particular configuration, but some shells, instead of
   7 # keeping the changes in LD private, export them just because LD is
   8 # exported.
   9 ORIGINAL_LD_FOR_MULTILIBS=$LD
  10
  11 dnl Default to --enable-multilib
  12 AC_ARG_ENABLE(multilib,
  13 [  --enable-multilib       build many library versions (default)],
  14 [case "${enableval}" in
  15   yes) multilib=yes ;;
  16   no)  multilib=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  18  esac], [multilib=yes])dnl
  19
  20 dnl We may get other options which we don't document:
  21 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  22
  23 if test "${srcdir}" = "."; then
  24   if test "${with_target_subdir}" != "."; then
  25     libffi_basedir="${srcdir}/${with_multisrctop}.."
  26   else
  27     libffi_basedir="${srcdir}/${with_multisrctop}"
  28   fi
  29 else
  30   libffi_basedir="${srcdir}"
  31 fi
  32 AC_SUBST(libffi_basedir)
  33
  34 AC_CANONICAL_HOST
  35
  36 AM_PROG_LIBTOOL
  37
  38 AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
  39
  40 AC_EXEEXT
  41 AM_MAINTAINER_MODE
  42
  43 AC_PROG_CC
  44 AC_PROG_LIBTOOL
  45
  46 TARGETDIR="unknown"
  47 case "$host" in
  48 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;;
  49 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  50 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  53 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  54 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  55 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  56 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  57 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  58 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  59 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  60 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  61 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  62 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  63 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  64 powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  65 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  66 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  67 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  68 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  69 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  70 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  71 esac
  72
  73 if test $TARGETDIR = unknown; then
  74   AC_ERROR("libffi has not been ported to $host.")
  75 fi
  76
  77 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
  78 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
  79 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  80 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  81 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  82 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
  83 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
  84 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
  85 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
  86 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
  87 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
  88 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
  89 AM_CONDITIONAL(S390, test x$TARGET = xS390)
  90
  91 AC_HEADER_STDC
  92 AC_CHECK_FUNCS(memcpy)
  93 AC_FUNC_ALLOCA
  94
  95 dnl AC_CHECK_SIZEOF(char)
  96 AC_COMPILE_CHECK_SIZEOF(short)
  97 AC_COMPILE_CHECK_SIZEOF(int)
  98 AC_COMPILE_CHECK_SIZEOF(long)
  99 AC_COMPILE_CHECK_SIZEOF(long long)
 100 AC_COMPILE_CHECK_SIZEOF(float)
 101 AC_COMPILE_CHECK_SIZEOF(double)
 102 AC_COMPILE_CHECK_SIZEOF(long double)
 103
 104 AC_COMPILE_CHECK_SIZEOF(void *)
 105 AC_C_BIGENDIAN_CROSS
 106
 107 if test x$TARGET = xSPARC; then
 108     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 109         libffi_cv_as_sparc_ua_pcrel, [
 110         save_CFLAGS="$CFLAGS"
 111         save_LDFLAGS="$LDFLAGS"
 112         CFLAGS="$CFLAGS -fpic"
 113         LDFLAGS="$LDFLAGS -shared"
 114         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 115                     [libffi_cv_as_sparc_ua_pcrel=yes],
 116                     [libffi_cv_as_sparc_ua_pcrel=no])
 117         CFLAGS="$save_CFLAGS"
 118         LDFLAGS="$save_LDFLAGS"])
 119     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 120         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 121                   [Define if your assembler and linker support unaligned PC relative relocs.])
 122     fi
 123 fi
 124
 125 AC_SUBST(TARGET)
 126 AC_SUBST(TARGETDIR)
 127
 128 AC_SUBST(SHELL)
 129
 130 AC_ARG_ENABLE(debug,
 131 [  --enable-debug          debugging mode],
 132   if test "$enable_debug" = "yes"; then
 133     AC_DEFINE(FFI_DEBUG)
 134   fi)
 135
 136 AC_ARG_ENABLE(structs,
 137 [  --disable-structs       omit code for struct support],
 138   if test "$enable_structs" = "no"; then
 139     AC_DEFINE(FFI_NO_STRUCTS)
 140   fi)
 141
 142 AC_ARG_ENABLE(raw-api,
 143 [  --disable-raw-api       make the raw api unavailable],
 144   if test "$enable_raw_api" = "no"; then
 145     AC_DEFINE(FFI_NO_RAW_API)
 146   fi)
 147
 148 AC_ARG_ENABLE(purify-safety,
 149 [  --enable-purify-safety  purify-safe mode],
 150   if test "$enable_purify_safety" = "yes"; then
 151     AC_DEFINE(USING_PURIFY)
 152   fi)
 153
 154 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 155
 156 if test "${multilib}" = "yes"; then
 157   multilib_arg="--enable-multilib"
 158 else
 159   multilib_arg=
 160 fi
 161
 162 AC_OUTPUT(include/Makefile include/ffi.h Makefile,
 163 [
 164 if test -n "$CONFIG_FILES"; then
 165    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 166    ac_file=Makefile . ${libffi_basedir}/../config-ml.in
 167 fi
 168 ],
 169 srcdir=${srcdir}
 170 host=${host}
 171 target=${target}
 172 with_multisubdir=${with_multisubdir}
 173 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 174 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 175 libffi_basedir=${libffi_basedir}
 176 CC="${CC}"
 177 DEFS="$DEFS"
 178 test ! -d include && mkdir include
 179 test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h
 180 if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then
 181         echo fficonfig.h unchanged
 182 else
 183         echo Moving fficonfig.h to include/fficonfig.h
 184         cp fficonfig.h include/fficonfig.h
 185 fi
 186 )
 187
 188 # Make target subdirectories if required.
 189 test -d src || mkdir src
 190 test -d src/${TARGETDIR} || mkdir src/${TARGETDIR}