libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   cris-*-*)
  55         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  56         ;;
  57
  58   frv-*-*)
  59         TARGET=FRV; TARGETDIR=frv
  60         ;;
  61
  62   hppa*-*-linux* | parisc*-*-linux*)
  63         TARGET=PA_LINUX; TARGETDIR=pa
  64         ;;
  65   hppa*64-*-hpux*)
  66         TARGET=PA64_HPUX; TARGETDIR=pa
  67         ;;
  68   hppa*-*-hpux*)
  69         TARGET=PA_HPUX; TARGETDIR=pa
  70         ;;
  71
  72   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  73         TARGET=X86_WIN32; TARGETDIR=x86
  74         ;;
  75   i?86-*-darwin*)
  76         TARGET=X86_DARWIN; TARGETDIR=x86
  77         ;;
  78   i?86-*-solaris2.1[[0-9]]*)
  79         TARGET=X86_64; TARGETDIR=x86
  80         ;;
  81   i?86-*-*)
  82         TARGET=X86; TARGETDIR=x86
  83         ;;
  84
  85   ia64*-*-*)
  86         TARGET=IA64; TARGETDIR=ia64
  87         ;;
  88
  89   m32r*-*-*)
  90         TARGET=M32R; TARGETDIR=m32r
  91         ;;
  92
  93   m68k-*-*)
  94         TARGET=M68K; TARGETDIR=m68k
  95         ;;
  96
  97   mips64*-*)
  98         ;;
  99   mips-sgi-irix5.* | mips-sgi-irix6.*)
 100         TARGET=MIPS_IRIX; TARGETDIR=mips
 101         ;;
 102   mips*-*-linux*)
 103         TARGET=MIPS_LINUX; TARGETDIR=mips
 104         ;;
 105
 106   powerpc*-*-linux* | powerpc-*-sysv*)
 107         TARGET=POWERPC; TARGETDIR=powerpc
 108         ;;
 109   powerpc-*-beos*)
 110         TARGET=POWERPC; TARGETDIR=powerpc
 111         ;;
 112   powerpc-*-darwin*)
 113         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 114         ;;
 115   powerpc-*-aix* | rs6000-*-aix*)
 116         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 117         ;;
 118   powerpc-*-freebsd*)
 119         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 120         ;;
 121   powerpc*-*-rtems*)
 122         TARGET=POWERPC; TARGETDIR=powerpc
 123         ;;
 124
 125   s390-*-* | s390x-*-*)
 126         TARGET=S390; TARGETDIR=s390
 127         ;;
 128
 129   sh-*-* | sh[[34]]*-*-*)
 130         TARGET=SH; TARGETDIR=sh
 131         ;;
 132   sh64-*-* | sh5*-*-*)
 133         TARGET=SH64; TARGETDIR=sh64
 134         ;;
 135
 136   sparc*-*-*)
 137         TARGET=SPARC; TARGETDIR=sparc
 138         ;;
 139
 140   x86_64-*-darwin*)
 141         TARGET=X86_DARWIN; TARGETDIR=x86
 142         ;;
 143   x86_64-*-cygwin* | x86_64-*-mingw*)
 144         ;;
 145   x86_64-*-*)
 146         TARGET=X86_64; TARGETDIR=x86
 147         ;;
 148 esac
 149
 150 AC_SUBST(AM_RUNTESTFLAGS)
 151
 152 if test $TARGETDIR = unknown; then
 153   AC_MSG_ERROR(["libffi has not been ported to $host."])
 154 fi
 155
 156 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
 157 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
 158 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 159 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 160 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 161 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 162 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 163 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 164 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 165 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 166 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 167 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 168 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 169 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 170 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 171 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 172 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 173 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 174 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 175 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 176 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 177 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 178 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 179 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 180
 181 case x$TARGET in
 182   xMIPS*) TARGET=MIPS ;;
 183   *) ;;
 184 esac
 185
 186 AC_HEADER_STDC
 187 AC_CHECK_FUNCS(memcpy)
 188 AC_FUNC_ALLOCA
 189
 190 AC_CHECK_SIZEOF(double)
 191 AC_CHECK_SIZEOF(long double)
 192
 193 # Also AC_SUBST this variable for ffi.h.
 194 if test -z "$HAVE_LONG_DOUBLE"; then
 195   HAVE_LONG_DOUBLE=0
 196   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 197     if test $ac_cv_sizeof_long_double != 0; then
 198       HAVE_LONG_DOUBLE=1
 199       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 200     fi
 201   fi
 202 fi
 203 AC_SUBST(HAVE_LONG_DOUBLE)
 204
 205 AC_C_BIGENDIAN
 206
 207 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 208     libffi_cv_as_cfi_pseudo_op, [
 209     libffi_cv_as_cfi_pseudo_op=unknown
 210     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 211                    [libffi_cv_as_cfi_pseudo_op=yes],
 212                    [libffi_cv_as_cfi_pseudo_op=no])
 213 ])
 214 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 215     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 216               [Define if your assembler supports .cfi_* directives.])
 217 fi
 218
 219 if test x$TARGET = xSPARC; then
 220     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 221         libffi_cv_as_sparc_ua_pcrel, [
 222         save_CFLAGS="$CFLAGS"
 223         save_LDFLAGS="$LDFLAGS"
 224         CFLAGS="$CFLAGS -fpic"
 225         LDFLAGS="$LDFLAGS -shared"
 226         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 227                     [libffi_cv_as_sparc_ua_pcrel=yes],
 228                     [libffi_cv_as_sparc_ua_pcrel=no])
 229         CFLAGS="$save_CFLAGS"
 230         LDFLAGS="$save_LDFLAGS"])
 231     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 232         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 233                   [Define if your assembler and linker support unaligned PC relative relocs.])
 234     fi
 235
 236     AC_CACHE_CHECK([assembler .register pseudo-op support],
 237        libffi_cv_as_register_pseudo_op, [
 238        libffi_cv_as_register_pseudo_op=unknown
 239        # Check if we have .register
 240        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 241                        [libffi_cv_as_register_pseudo_op=yes],
 242                        [libffi_cv_as_register_pseudo_op=no])
 243     ])
 244     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 245        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 246                [Define if your assembler supports .register.])
 247     fi
 248 fi
 249
 250 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 251     libffi_cv_ro_eh_frame, [
 252         libffi_cv_ro_eh_frame=no
 253         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 254         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 255             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 256                 libffi_cv_ro_eh_frame=yes
 257             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 258                  | grep -v '#write' > /dev/null; then
 259                 libffi_cv_ro_eh_frame=yes
 260             fi
 261         fi
 262         rm -f conftest.*
 263     ])
 264 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 265     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 266               [Define if .eh_frame sections should be read-only.])
 267     AC_DEFINE(EH_FRAME_FLAGS, "a",
 268               [Define to the flags needed for the .section .eh_frame directive.])
 269 else
 270     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 271               [Define to the flags needed for the .section .eh_frame directive.])
 272 fi
 273
 274 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 275     libffi_cv_hidden_visibility_attribute, [
 276         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 277         libffi_cv_hidden_visibility_attribute=no
 278         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 279             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 280                 libffi_cv_hidden_visibility_attribute=yes
 281             fi
 282         fi
 283         rm -f conftest.*
 284     ])
 285 if test $libffi_cv_hidden_visibility_attribute = yes; then
 286     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 287               [Define if __attribute__((visibility("hidden"))) is supported.])
 288 fi
 289
 290 AH_BOTTOM([
 291 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 292 #ifdef LIBFFI_ASM
 293 #define FFI_HIDDEN(name) .hidden name
 294 #else
 295 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 296 #endif
 297 #else
 298 #ifdef LIBFFI_ASM
 299 #define FFI_HIDDEN(name)
 300 #else
 301 #define FFI_HIDDEN
 302 #endif
 303 #endif
 304 ])
 305
 306 AC_SUBST(TARGET)
 307 AC_SUBST(TARGETDIR)
 308
 309 AC_SUBST(SHELL)
 310
 311 AC_ARG_ENABLE(debug,
 312 [  --enable-debug          debugging mode],
 313   if test "$enable_debug" = "yes"; then
 314     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 315   fi)
 316
 317 AC_ARG_ENABLE(structs,
 318 [  --disable-structs       omit code for struct support],
 319   if test "$enable_structs" = "no"; then
 320     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 321   fi)
 322
 323 AC_ARG_ENABLE(raw-api,
 324 [  --disable-raw-api       make the raw api unavailable],
 325   if test "$enable_raw_api" = "no"; then
 326     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 327   fi)
 328
 329 AC_ARG_ENABLE(purify-safety,
 330 [  --enable-purify-safety  purify-safe mode],
 331   if test "$enable_purify_safety" = "yes"; then
 332     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 333   fi)
 334
 335 if test -n "$with_cross_host" &&
 336    test x"$with_cross_host" != x"no"; then
 337   toolexecdir='$(exec_prefix)/$(target_alias)'
 338   toolexeclibdir='$(toolexecdir)/lib'
 339 else
 340   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 341   toolexeclibdir='$(libdir)'
 342 fi
 343 multi_os_directory=`$CC -print-multi-os-directory`
 344 case $multi_os_directory in
 345   .) ;; # Avoid trailing /.
 346   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 347 esac
 348 AC_SUBST(toolexecdir)
 349 AC_SUBST(toolexeclibdir)
 350
 351 if test "${multilib}" = "yes"; then
 352   multilib_arg="--enable-multilib"
 353 else
 354   multilib_arg=
 355 fi
 356
 357 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 358 AC_CONFIG_COMMANDS(src, [
 359 test -d src || mkdir src
 360 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 361 ], [TARGETDIR="$TARGETDIR"])
 362
 363 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 364
 365 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 366
 367 AC_OUTPUT