libf2c/libU77/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1998, 1999 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of the GNU Fortran libU77 library.
   6 #
   7 #This library is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU Library General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU Library General Public
  18 #License along with GNU Fortran; see the file COPYING.  If not, write
  19 #to Software Foundation, 59 Temple Place - Suite 330, Boston, MA  02111-1307,
  20 #USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(access_.c)
  24 AC_CONFIG_HEADER(config.h:config.hin)
  25
  26 # These defines are necessary to get 64-bit file size support.
  27
  28 AC_DEFINE(_XOPEN_SOURCE, 500L, [Get Single Unix Specification semantics])
  29 # The following is needed by irix6.2 so that struct timeval is declared.
  30 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Get Single Unix Specification semantics])
  31 # The following is needed by Solaris2.5.1 so that struct timeval is declared.
  32 AC_DEFINE(__EXTENSIONS__, 1, [Solaris extensions])
  33 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Get 64-bit file size support])
  34
  35 dnl Checks for programs.
  36
  37 dnl FIXME AC_PROG_CC wants CC to be able to link things, but it may
  38 dnl not be able to.
  39 define([AC_PROG_CC_WORKS],[])
  40
  41 # For g77 we'll set CC to point at the built gcc, but this will get it into
  42 # the makefiles
  43 AC_PROG_CC
  44 dnl AC_C_CROSS
  45 dnl Gives misleading `(cached)' message from the check.
  46 if test "$CROSS";then
  47   ac_cv_c_cross=yes
  48 else
  49   ac_cv_c_cross=no
  50 fi
  51
  52 test "$AR" || AR=ar
  53 AC_SUBST(AR)
  54 AC_PROG_MAKE_SET
  55
  56 dnl This is only because we (horribly) punt the chmod job to the program at
  57 dnl present.  Note that the result of this test could be wrong in the cross
  58 dnl case.
  59 AC_PATH_PROG(ac_cv_prog_chmod, chmod, no)
  60 if test "$ac_cv_prog_chmod" != no || test "$CROSS"; then
  61   MAYBES=chmod_.o
  62   AC_DEFINE_UNQUOTED(CHMOD_PATH,"$ac_cv_prog_chmod")
  63 else
  64   MAYBES=""
  65 fi
  66
  67 dnl Checks for header files.
  68 AC_HEADER_STDC
  69 dnl We could do this if we didn't know we were using gcc
  70 dnl AC_MSG_CHECKING(for prototype-savvy compiler)
  71 dnl AC_CACHE_VAL(ac_cv_sys_proto,
  72 dnl   [AC_TRY_LINK(,
  73 dnl dnl looks screwy because TRY_LINK expects a function body
  74 dnl    [return 0;} int foo (int * bar) {],
  75 dnl    ac_cv_sys_proto=yes,
  76 dnl    [ac_cv_sys_proto=no
  77 dnl     AC_DEFINE(KR_headers)])])
  78 dnl AC_MSG_RESULT($ac_cv_sys_proto)
  79
  80 AC_HEADER_TIME
  81 AC_CHECK_HEADERS(limits.h unistd.h sys/time.h string.h stdlib.h \
  82   sys/param.h sys/times.h)
  83
  84 dnl Checks for typedefs, structures, and compiler characteristics.
  85 AC_C_CONST
  86 AC_TYPE_SIZE_T
  87 AC_TYPE_MODE_T
  88
  89 AC_TYPE_PID_T
  90 dnl The next 3 demand a dummy fileblocks.o (added to LIBOJS).  We don't use
  91 dnl LIBOJS, though.
  92 AC_STRUCT_ST_BLKSIZE
  93 AC_STRUCT_ST_BLOCKS
  94 AC_STRUCT_ST_RDEV
  95 AC_STRUCT_TM
  96
  97 dnl Some systems (SVR4, SCO OpenServer) need -lsocket for gethostname()
  98 AC_CHECK_LIB(socket, gethostname, [LIBS="$LIBS -lsocket"])
  99
 100 dnl Checks for library functions.
 101
 102 AC_CHECK_FUNCS(symlink getcwd getwd lstat gethostname strerror clock \
 103   getrusage times alarm getlogin getgid getuid kill link ttyname)
 104
 105 dnl The standard autoconf HAVE_STRUCT_TIMEZONE doesn't actually check
 106 dnl for struct timezone, as you might think.  We also need to check how
 107 dnl to call gettimeofday if we have it.
 108 LIBU77_GETTIMEOFDAY
 109
 110 test $ac_cv_func_symlink = yes && MAYBES="$MAYBES symlnk_.o"
 111 test $ac_cv_func_lstat = yes && MAYBES="$MAYBES lstat_.o"
 112 test $ac_cv_func_gethostname = yes && MAYBES="$MAYBES hostnm_.o"
 113 test $ac_cv_func_clock = yes && MAYBES="$MAYBES mclock_.o"
 114 AC_SUBST(MAYBES)
 115
 116 AC_SUBST(CROSS)
 117 AC_SUBST(RANLIB)
 118 AC_SUBST(RANLIB_TEST)
 119
 120 AC_OUTPUT(Makefile)