libf2c/libU77/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1998, 1999 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of the GNU Fortran libU77 library.
   6 #
   7 #This library is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU Library General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU Library General Public
  18 #License along with GNU Fortran; see the file COPYING.  If not, write
  19 #to Software Foundation, 59 Temple Place - Suite 330, Boston, MA  02111-1307,
  20 #USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(access_.c)
  24 AC_CONFIG_HEADER(config.h:config.hin)
  25
  26 dnl FIXME AC_PROG_CC wants CC to be able to link things, but it may
  27 dnl not be able to.
  28 define([AC_PROG_CC_WORKS],[])
  29
  30 # For g77 we'll set CC to point at the built gcc, but this will get it into
  31 # the makefiles
  32 AC_PROG_CC
  33
  34 # These defines are necessary to get 64-bit file size support.
  35 # NetBSD 1.4 header files does not support XOPEN_SOURCE == 500, but it
  36 # handles 64-bit file sizes without needing these defines.
  37 AC_MSG_CHECKING(whether _XOPEN_SOURCE may be defined)
  38 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500L
  39 #include <unistd.h>],,
  40 may_use_xopen_source=yes,
  41 may_use_xopen_source=no)
  42 AC_MSG_RESULT($may_use_xopen_source)
  43 if test $may_use_xopen_source = yes; then
  44   AC_DEFINE(_XOPEN_SOURCE, 500L, [Get Single Unix Specification semantics])
  45   # The following is needed by irix6.2 so that struct timeval is declared.
  46   AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Get Single Unix Specification semantics])
  47   # The following is needed by Solaris2.5.1 so that struct timeval is declared.
  48   AC_DEFINE(__EXTENSIONS__, 1, [Solaris extensions])
  49   AC_DEFINE(_FILE_OFFSET_BITS, 64, [Get 64-bit file size support])
  50 fi
  51
  52 dnl Checks for programs.
  53
  54 LIBTOOL='$(SHELL) ../libtool'
  55 AC_SUBST(LIBTOOL)
  56
  57 dnl AC_C_CROSS
  58 dnl Gives misleading `(cached)' message from the check.
  59 if test "$CROSS";then
  60   ac_cv_c_cross=yes
  61 else
  62   ac_cv_c_cross=no
  63 fi
  64
  65 test "$AR" || AR=ar
  66 AC_SUBST(AR)
  67 AC_PROG_MAKE_SET
  68
  69 dnl This is only because we (horribly) punt the chmod job to the program at
  70 dnl present.  Note that the result of this test could be wrong in the cross
  71 dnl case.
  72 AC_PATH_PROG(ac_cv_prog_chmod, chmod, no)
  73 if test "$ac_cv_prog_chmod" != no || test "$CROSS"; then
  74   MAYBES=chmod_.o
  75   AC_DEFINE_UNQUOTED(CHMOD_PATH,"$ac_cv_prog_chmod")
  76 else
  77   MAYBES=""
  78 fi
  79
  80 dnl Checks for header files.
  81 AC_HEADER_STDC
  82 AC_HEADER_TIME
  83 AC_CHECK_HEADERS(limits.h unistd.h sys/time.h string.h stdlib.h \
  84   sys/param.h sys/times.h)
  85
  86 dnl Checks for typedefs, structures, and compiler characteristics.
  87 AC_C_CONST
  88 AC_TYPE_SIZE_T
  89 AC_TYPE_MODE_T
  90
  91 AC_TYPE_PID_T
  92 dnl The next 3 demand a dummy fileblocks.o (added to LIBOJS).  We don't use
  93 dnl LIBOJS, though.
  94 AC_STRUCT_ST_BLKSIZE
  95 AC_STRUCT_ST_BLOCKS
  96 AC_STRUCT_ST_RDEV
  97 AC_STRUCT_TM
  98
  99 dnl Some systems (SVR4, SCO OpenServer) need -lsocket for gethostname()
 100 AC_CHECK_LIB(socket, gethostname, [LIBS="$LIBS -lsocket"])
 101
 102 dnl Checks for library functions.
 103
 104 AC_CHECK_FUNCS(symlink getcwd getwd lstat gethostname strerror clock \
 105   getrusage times alarm getlogin getgid getuid kill link ttyname)
 106
 107 dnl The standard autoconf HAVE_STRUCT_TIMEZONE doesn't actually check
 108 dnl for struct timezone, as you might think.  We also need to check how
 109 dnl to call gettimeofday if we have it.
 110 LIBU77_GETTIMEOFDAY
 111
 112 test $ac_cv_func_symlink = yes && MAYBES="$MAYBES symlnk_.o"
 113 test $ac_cv_func_lstat = yes && MAYBES="$MAYBES lstat_.o"
 114 test $ac_cv_func_gethostname = yes && MAYBES="$MAYBES hostnm_.o"
 115 test $ac_cv_func_clock = yes && MAYBES="$MAYBES mclock_.o"
 116 AC_SUBST(MAYBES)
 117
 118 AC_SUBST(CROSS)
 119 AC_SUBST(RANLIB)
 120 AC_SUBST(RANLIB_TEST)
 121
 122 AC_OUTPUT(Makefile)