libf2c/libI77/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 2001 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(ftell_.c)
  24 AC_CONFIG_HEADER(config.h)
  25
  26 # These defines are necessary to get 64-bit file size support.
  27
  28 AC_DEFINE(_XOPEN_SOURCE, 500L, [Get Single Unix Specification semantics])
  29 # The following is needed by irix6.2 so that struct timeval is declared.
  30 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Get Single Unix Specification semantics])
  31 # The following is needed by Solaris2.5.1 so that struct timeval is declared.
  32 AC_DEFINE(__EXTENSIONS__, 1, [Solaris extensions])
  33 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Get 64-bit file size support])
  34
  35 dnl Checks for programs.
  36
  37 dnl FIXME AC_PROG_CC wants CC to be able to link things, but it may
  38 dnl not be able to.
  39 define([AC_PROG_CC_WORKS],[])
  40
  41 # For g77 we'll set CC to point at the built gcc, but this will get it into
  42 # the makefiles
  43 AC_PROG_CC
  44
  45 LIBTOOL='$(SHELL) ../libtool'
  46 AC_SUBST(LIBTOOL)
  47
  48 test "$AR" || AR=ar
  49 AC_SUBST(AR)
  50 AC_PROG_MAKE_SET
  51
  52 dnl Checks for libraries.
  53
  54 dnl Checks for header files.
  55 # Sanity check for the cross-compilation case:
  56 AC_CHECK_HEADER(stdio.h,:,
  57   [AC_MSG_ERROR([Can't find stdio.h.
  58 You must have a usable C system for the target already installed, at least
  59 including headers and, preferably, the library, before you can configure
  60 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  61 then the target library, then build with \`LANGUAGES=f77'.])])
  62
  63 AC_HEADER_STDC
  64 dnl We could do this if we didn't know we were using gcc
  65 dnl AC_MSG_CHECKING(for prototype-savvy compiler)
  66 dnl AC_CACHE_VAL(g77_cv_sys_proto,
  67 dnl   [AC_TRY_LINK(,
  68 dnl dnl looks screwy because TRY_LINK expects a function body
  69 dnl    [return 0;} int foo (int * bar) {],
  70 dnl    g77_cv_sys_proto=yes,
  71 dnl    [g77_cv_sys_proto=no
  72 dnl     AC_DEFINE(KR_headers)])])
  73 dnl AC_MSG_RESULT($g77_cv_sys_proto)
  74
  75 AC_MSG_CHECKING(for posix)
  76 AC_CACHE_VAL(g77_cv_header_posix,
  77   AC_EGREP_CPP(yes,
  78   [#include <sys/types.h>
  79 #include <unistd.h>
  80 #ifdef _POSIX_VERSION
  81   yes
  82 #endif
  83 ],
  84   g77_cv_header_posix=yes,
  85   g77_cv_header_posix=no))
  86 AC_MSG_RESULT($g77_cv_header_posix)
  87
  88 # We can rely on the GNU library being posix-ish.  I guess checking the
  89 # header isn't actually like checking the functions, though...
  90 AC_MSG_CHECKING(for GNU library)
  91 AC_CACHE_VAL(g77_cv_lib_gnu,
  92   AC_EGREP_CPP(yes,
  93     [#include <stdio.h>
  94 #ifdef __GNU_LIBRARY__
  95   yes
  96 #endif
  97 ],
  98   g77_cv_lib_gnu=yes, g77_cv_lib_gnu=no))
  99 AC_MSG_RESULT($g77_cv_lib_gnu)
 100
 101 # Apparently cygwin needs to be special-cased.
 102 AC_MSG_CHECKING([for cyg\`win'32])
 103 AC_CACHE_VAL(g77_cv_sys_cygwin32,
 104   AC_EGREP_CPP(yes,
 105   [#ifdef __CYGWIN32__
 106   yes
 107 #endif
 108 ],
 109   g77_cv_sys_cygwin32=yes,
 110   g77_cv_sys_cygwin32=no))
 111 AC_MSG_RESULT($g77_cv_sys_cygwin32)
 112
 113 # ditto for mingw32.
 114 AC_MSG_CHECKING([for mingw32])
 115 AC_CACHE_VAL(g77_cv_sys_mingw32,
 116   AC_EGREP_CPP(yes,
 117   [#ifdef __MINGW32__
 118   yes
 119 #endif
 120 ],
 121   g77_cv_sys_mingw32=yes,
 122   g77_cv_sys_mingw32=no))
 123 AC_MSG_RESULT($g77_cv_sys_mingw32)
 124
 125
 126 AC_CHECK_HEADER(fcntl.h,
 127    test $g77_cv_header_posix = yes && AC_DEFINE(_POSIX_SOURCE),
 128    AC_DEFINE(NO_FCNTL, 1, [Define if fcntl.h is missing.])
 129    AC_DEFINE(OPEN_DECL, 1, [Define if fcntl.h is missing.]))
 130
 131 dnl Checks for typedefs, structures, and compiler characteristics.
 132 AC_C_CONST
 133 AC_TYPE_SIZE_T
 134
 135 dnl Checks for library functions.
 136
 137 # This should always succeed on unix.
 138 # Apparently positive result on cygwin loses re. NON_UNIX_STDIO
 139 # (as of cygwin b18). Likewise on mingw.
 140 AC_CHECK_FUNC(fstat)
 141 AC_MSG_CHECKING([need for NON_UNIX_STDIO])
 142 if test $g77_cv_sys_cygwin32 = yes \
 143   || test $g77_cv_sys_mingw32 = yes \
 144   || test $ac_cv_func_fstat = no; then
 145   AC_MSG_RESULT(yes)
 146   AC_DEFINE(NON_UNIX_STDIO, 1, [Define if we do not have Unix Stdio.])
 147 else
 148   AC_MSG_RESULT(no)
 149 fi
 150
 151 AC_CHECK_FUNCS(fseeko)
 152 AC_CHECK_FUNCS(ftello)
 153 AC_CHECK_FUNCS(ftruncate)
 154 AC_CHECK_FUNCS(mkstemp)
 155 AC_CHECK_FUNCS(tempnam)
 156
 157 # posix will guarantee the right behaviour for sprintf, else we can't be
 158 # sure; HEADER_STDC wouldn't be the right check in sunos4, for instance.
 159 # However, on my sunos4/gcc setup unistd.h leads us wrongly to believe
 160 # we're posix-conformant, so always do the test.
 161 AC_MSG_CHECKING(for ansi/posix sprintf result)
 162 dnl This loses if included as an argument to AC_CACHE_VAL because the
 163 dnl changequote doesn't take effect and the [] vanish.
 164 dnl fixme: use cached value
 165 AC_TRY_RUN(changequote(<<, >>)dnl
 166   <<#include <stdio.h>
 167     /* does sprintf return the number of chars transferred? */
 168     main () {char foo[2]; (sprintf(foo, "1") == 1) ? exit(0) : exit(1);}
 169 >>changequote([, ]),
 170     g77_cv_sys_sprintf_ansi=yes,
 171     g77_cv_sys_sprintf_ansi=no,
 172     g77_cv_sys_sprintf_ansi=no)
 173 AC_CACHE_VAL(g77_cv_sys_sprintf_ansi,
 174      g77_cv_sys_sprintf_ansi=$g77_cv_sys_sprintf_ansi)
 175 dnl We get a misleading `(cached)' message...
 176 AC_MSG_RESULT($g77_cv_sys_sprintf_ansi)
 177
 178 # The cygwin patch takes steps to avoid defining USE_STRLEN here -- I don't
 179 # understand why.
 180 if test $g77_cv_sys_sprintf_ansi != yes; then
 181   AC_DEFINE(USE_STRLEN, 1, [Define if we use strlen.])
 182 fi
 183
 184 # define NON_ANSI_RW_MODES on unix (can't hurt)
 185 AC_MSG_CHECKING(NON_ANSI_RW_MODES)
 186 AC_EGREP_CPP(yes,
 187 [#ifdef unix
 188   yes
 189 #endif
 190 #ifdef __unix
 191   yes
 192 #endif
 193 #ifdef __unix__
 194   yes
 195 #endif
 196 ], is_unix=yes, is_unix=no)
 197 # NON_ANSI_RW_MODES shouldn't be necessary on cygwin for binary mounts.
 198 if test $g77_cv_sys_cygwin32 = yes || test $g77_cv_sys_mingw32 = yes; then
 199   AC_MSG_RESULT(no)
 200 else
 201   if test $is_unix = yes; then
 202     AC_DEFINE(NON_ANSI_RW_MODES, 1, [Define if we have non ANSI RW modes.])
 203     AC_MSG_RESULT(yes)
 204   else
 205     AC_MSG_RESULT(no)
 206   fi
 207 fi
 208
 209 # This EOF_CHAR is a misfeature on unix.
 210 AC_DEFINE(NO_EOF_CHAR_CHECK, 1, [Always defined.])
 211
 212 AC_TYPE_OFF_T
 213
 214 AC_DEFINE(Skip_f2c_Undefs, 1, [Define to skip f2c undefs.])
 215
 216 AC_OUTPUT(Makefile)
 217
 218 dnl We might have configuration options to:
 219 dnl * change unit preconnexion in err.c (f_init.c)
 220 dnl * -DALWAYS_FLUSH
 221 dnl * -DOMIT_BLANK_CC
 222
 223 dnl Local Variables:
 224 dnl comment-start: "dnl "
 225 dnl comment-end: ""
 226 dnl comment-start-skip: "\\bdnl\\b\\s *"
 227 dnl End: