libf2c/libI77/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(ftell_.c)
  24
  25 dnl Checks for programs.
  26
  27 dnl FIXME AC_PROG_CC wants CC to be able to link things, but it may
  28 dnl not be able to.
  29 define([AC_PROG_CC_WORKS],[])
  30
  31 # For g77 we'll set CC to point at the built gcc, but this will get it into
  32 # the makefiles
  33 AC_PROG_CC
  34
  35 test "$AR" || AR=ar
  36 AC_SUBST(AR)
  37 AC_PROG_MAKE_SET
  38
  39 dnl Checks for libraries.
  40
  41 dnl Checks for header files.
  42 # Sanity check for the cross-compilation case:
  43 AC_CHECK_HEADER(stdio.h,:,
  44   [AC_MSG_ERROR([Can't find stdio.h.
  45 You must have a usable C system for the target already installed, at least
  46 including headers and, preferably, the library, before you can configure
  47 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  48 then the target library, then build with \`LANGUAGES=f77'.])])
  49
  50 AC_HEADER_STDC
  51 dnl We could do this if we didn't know we were using gcc
  52 dnl AC_MSG_CHECKING(for prototype-savvy compiler)
  53 dnl AC_CACHE_VAL(g77_cv_sys_proto,
  54 dnl   [AC_TRY_LINK(,
  55 dnl dnl looks screwy because TRY_LINK expects a function body
  56 dnl    [return 0;} int foo (int * bar) {],
  57 dnl    g77_cv_sys_proto=yes,
  58 dnl    [g77_cv_sys_proto=no
  59 dnl     AC_DEFINE(KR_headers)])])
  60 dnl AC_MSG_RESULT($g77_cv_sys_proto)
  61
  62 AC_MSG_CHECKING(for posix)
  63 AC_CACHE_VAL(g77_cv_header_posix,
  64   AC_EGREP_CPP(yes,
  65   [#include <sys/types.h>
  66 #include <unistd.h>
  67 #ifdef _POSIX_VERSION
  68   yes
  69 #endif
  70 ],
  71   g77_cv_header_posix=yes,
  72   g77_cv_header_posix=no))
  73 AC_MSG_RESULT($g77_cv_header_posix)
  74
  75 # We can rely on the GNU library being posix-ish.  I guess checking the
  76 # header isn't actually like checking the functions, though...
  77 AC_MSG_CHECKING(for GNU library)
  78 AC_CACHE_VAL(g77_cv_lib_gnu,
  79   AC_EGREP_CPP(yes,
  80     [#include <stdio.h>
  81 #ifdef __GNU_LIBRARY__
  82   yes
  83 #endif
  84 ],
  85   g77_cv_lib_gnu=yes, g77_cv_lib_gnu=no))
  86 AC_MSG_RESULT($g77_cv_lib_gnu)
  87
  88 # Apparently cygwin needs to be special-cased.
  89 AC_MSG_CHECKING([for cyg\`win'32])
  90 AC_CACHE_VAL(g77_cv_sys_cygwin32,
  91   AC_EGREP_CPP(yes,
  92   [#ifdef __CYGWIN32__
  93   yes
  94 #endif
  95 ],
  96   g77_cv_sys_cygwin32=yes,
  97   g77_cv_sys_cygwin32=no))
  98 AC_MSG_RESULT($g77_cv_sys_cygwin32)
  99
 100 # ditto for mingw32.
 101 AC_MSG_CHECKING([for mingw32])
 102 AC_CACHE_VAL(g77_cv_sys_mingw32,
 103   AC_EGREP_CPP(yes,
 104   [#ifdef __MINGW32__
 105   yes
 106 #endif
 107 ],
 108   g77_cv_sys_mingw32=yes,
 109   g77_cv_sys_mingw32=no))
 110 AC_MSG_RESULT($g77_cv_sys_mingw32)
 111
 112
 113 AC_CHECK_HEADER(fcntl.h,
 114    test $g77_cv_header_posix = yes && AC_DEFINE(_POSIX_SOURCE),
 115    AC_DEFINE(NO_FCNTL) AC_DEFINE(OPEN_DECL))
 116
 117 dnl Checks for typedefs, structures, and compiler characteristics.
 118 AC_C_CONST
 119 AC_TYPE_SIZE_T
 120
 121 dnl Checks for library functions.
 122
 123 # This should always succeed on unix.
 124 # Apparently positive result on cygwin loses re. NON_UNIX_STDIO
 125 # (as of cygwin b18). Likewise on mingw.
 126 AC_CHECK_FUNC(fstat)
 127 AC_MSG_CHECKING([need for NON_UNIX_STDIO])
 128 if test $g77_cv_sys_cygwin32 = yes \
 129   || test $g77_cv_sys_mingw32 = yes \
 130   || test $ac_cv_func_fstat = no; then
 131   AC_MSG_RESULT(yes)
 132   AC_DEFINE(NON_UNIX_STDIO)
 133 else
 134   AC_MSG_RESULT(no)
 135 fi
 136
 137 AC_CHECK_FUNCS(mkstemp)
 138 AC_CHECK_FUNCS(tempnam)
 139
 140 # posix will guarantee the right behaviour for sprintf, else we can't be
 141 # sure; HEADER_STDC wouldn't be the right check in sunos4, for instance.
 142 # However, on my sunos4/gcc setup unistd.h leads us wrongly to believe
 143 # we're posix-conformant, so always do the test.
 144 AC_MSG_CHECKING(for ansi/posix sprintf result)
 145 dnl This loses if included as an argument to AC_CACHE_VAL because the
 146 dnl changequote doesn't take effect and the [] vanish.
 147 dnl fixme: use cached value
 148 AC_TRY_RUN(changequote(<<, >>)dnl
 149   <<#include <stdio.h>
 150     /* does sprintf return the number of chars transferred? */
 151     main () {char foo[2]; (sprintf(foo, "1") == 1) ? exit(0) : exit(1);}
 152 >>changequote([, ]),
 153     g77_cv_sys_sprintf_ansi=yes,
 154     g77_cv_sys_sprintf_ansi=no,
 155     g77_cv_sys_sprintf_ansi=no)
 156 AC_CACHE_VAL(g77_cv_sys_sprintf_ansi,
 157      g77_cv_sys_sprintf_ansi=$g77_cv_sys_sprintf_ansi)
 158 dnl We get a misleading `(cached)' message...
 159 AC_MSG_RESULT($g77_cv_sys_sprintf_ansi)
 160
 161 # The cygwin patch takes steps to avoid defining USE_STRLEN here -- I don't
 162 # understand why.
 163 if test $g77_cv_sys_sprintf_ansi != yes; then
 164   AC_DEFINE(USE_STRLEN)
 165 fi
 166
 167 # define NON_ANSI_RW_MODES on unix (can't hurt)
 168 AC_MSG_CHECKING(NON_ANSI_RW_MODES)
 169 AC_EGREP_CPP(yes,
 170 [#ifdef unix
 171   yes
 172 #endif
 173 #ifdef __unix
 174   yes
 175 #endif
 176 #ifdef __unix__
 177   yes
 178 #endif
 179 ], is_unix=yes, is_unix=no)
 180 # NON_ANSI_RW_MODES shouldn't be necessary on cygwin for binary mounts.
 181 if test $g77_cv_sys_cygwin32 = yes || test $g77_cv_sys_mingw32 = yes; then
 182   AC_MSG_RESULT(no)
 183 else
 184   if test $is_unix = yes; then
 185     AC_DEFINE(NON_ANSI_RW_MODES)
 186     AC_MSG_RESULT(yes)
 187   else
 188     AC_MSG_RESULT(no)
 189   fi
 190 fi
 191
 192 # This EOF_CHAR is a misfeature on unix.
 193 AC_DEFINE(NO_EOF_CHAR_CHECK)
 194
 195 AC_DEFINE(Skip_f2c_Undefs)
 196
 197 AC_OUTPUT(Makefile)
 198
 199 dnl We might have configuration options to:
 200 dnl * change unit preconnexion in err.c (f_init.c)
 201 dnl * -DALWAYS_FLUSH
 202 dnl * -DOMIT_BLANK_CC
 203
 204 dnl Local Variables:
 205 dnl comment-start: "dnl "
 206 dnl comment-end: ""
 207 dnl comment-start-skip: "\\bdnl\\b\\s *"
 208 dnl End: