libf2c/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 1999, 2002 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.13)
  23 AC_INIT(libF77/Version.c)
  24
  25 # This works around the fact that libtool configuration may change LD
  26 # for this particular configuration, but some shells, instead of
  27 # keeping the changes in LD private, export them just because LD is
  28 # exported.
  29 ORIGINAL_LD_FOR_MULTILIBS=$LD
  30
  31 GLIBCPP_TOPREL_CONFIGURE
  32
  33 AC_CANONICAL_SYSTEM
  34 target_alias=${target_alias-$target}
  35 AC_SUBST(target_alias)
  36
  37 GLIBCPP_CONFIGURE(.)
  38 GLIBCPP_EXPORT_INSTALL_INFO
  39
  40 dnl Checks for programs.
  41
  42 AM_PROG_LIBTOOL
  43
  44 dnl These should be inherited in the recursive make, but ensure they are
  45 dnl defined:
  46 test "$AR" || AR=ar
  47 AC_SUBST(AR)
  48 if test "$RANLIB"; then :
  49   AC_SUBST(RANLIB)
  50 else
  51   AC_PROG_RANLIB
  52 fi
  53 AC_PROG_INSTALL
  54 AC_PROG_MAKE_SET
  55
  56 dnl Checks for header files.
  57 # Sanity check for the cross-compilation case:
  58 AC_CHECK_HEADER(stdio.h,:,
  59   [AC_MSG_ERROR([Can't find stdio.h.
  60 You must have a usable C system for the target already installed, at least
  61 including headers and, preferably, the library, before you can configure
  62 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  63 then the target library, then build with \`LANGUAGES=f77'.])])
  64
  65 dnl Checks for g77 integer types built into gcc's C front end.
  66 AC_MSG_CHECKING(for built-in g77 integer types)
  67 AC_CACHE_VAL(libf2c_cv_has_g77_builtin_types,
  68 [AC_TRY_COMPILE(,
  69   [__g77_integer g77i;
  70 __g77_uinteger g77ui;
  71 __g77_longint g77l;
  72 __g77_ulongint g77ul;],
  73   libf2c_cv_has_g77_builtin_types=yes,
  74   libf2c_cv_has_g77_builtin_types=no)])
  75 AC_MSG_RESULT($libf2c_cv_has_g77_builtin_types)
  76 if test $libf2c_cv_has_g77_builtin_types = no; then
  77   AC_MSG_ERROR([gcc doesn't define all of the built in types __g77_integer,
  78 __g77_uinteger, __g77_longint, and __g77_ulongint.  You may not be using
  79 a new enough version of gcc, or your target may not have type sizes which
  80 accommodate those types.])
  81 fi
  82
  83 # avoid confusion in case the `makefile's from the f2c distribution have
  84 # got put here
  85 test -f libF77/makefile && mv libF77/makefile  libF77/makefile.ori
  86 test -f libI77/makefile && mv libI77/makefile  libI77/makefile.ori
  87 test -f libU77/makefile && mv libU77/makefile  libU77/makefile.ori
  88
  89 AC_CONFIG_SUBDIRS(libU77 libI77 libF77)
  90 # Do Makefile first since g2c.h depends on it and shouldn't get an
  91 # earlier timestamp.  Of course, it does when the multilib gunk below
  92 # edits Makefile, sigh; see additional touch below.
  93 AC_OUTPUT(Makefile g2c.h:g2c.hin,
  94  [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
  95 if test -n "$CONFIG_FILES"; then
  96   LD="${ORIGINAL_LD_FOR_MULTILIBS}"
  97   if test -n "${with_target_subdir}"; then
  98     # FIXME: We shouldn't need to set ac_file
  99     ac_file=Makefile
 100     . ${toplevel_srcdir}/config-ml.in
 101     touch g2c.h   # to keep it more recent than Makefile
 102   fi
 103 fi],
 104 srcdir=${srcdir}
 105 host=${host}
 106 target=${target}
 107 with_target_subdir=${with_target_subdir}
 108 with_multisubdir=${with_multisubdir}
 109 ac_configure_args="--enable-multilib ${ac_configure_args}"
 110 toplevel_srcdir=${toplevel_srcdir}
 111 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 112 )
 113
 114
 115 dnl Local Variables:
 116 dnl comment-start: "dnl "
 117 dnl comment-end: ""
 118 dnl comment-start-skip: "\\bdnl\\b\\s *"
 119 dnl End: