libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   6 AC_CONFIG_SRCDIR(ucnid.h)
   7 AC_CANONICAL_SYSTEM
   8 AM_INIT_AUTOMAKE(foreign)
   9 AM_MAINTAINER_MODE
  10
  11 # Checks for programs.
  12 AC_PROG_CC
  13 AC_PROG_RANLIB
  14
  15 # Checks for header files.
  16 AC_HEADER_TIME
  17 ACX_HEADER_STRING
  18 ACX_HEADER_STDBOOL
  19 AC_CHECK_HEADERS(iconv.h locale.h fcntl.h limits.h stddef.h \
  20         stdlib.h strings.h string.h sys/file.h unistd.h)
  21
  22 # Checks for typedefs, structures, and compiler characteristics.
  23 AC_C_CONST
  24 AC_C_INLINE
  25 AC_FUNC_OBSTACK
  26 AC_TYPE_OFF_T
  27 AC_TYPE_SIZE_T
  28 AC_STRUCT_TM
  29 AC_CHECK_SIZEOF(int)
  30 AC_CHECK_SIZEOF(long)
  31 AC_CHECK_FUNCS(putc_unlocked fputc_unlocked fputs_unlocked \
  32         fwrite_unlocked fprintf_unlocked)
  33 AC_CHECK_DECLS([abort, errno, putc_unlocked, fputc_unlocked,
  34         fputs_unlocked, fwrite_unlocked, fprintf_unlocked])
  35
  36 # Checks for library functions.
  37 AC_FUNC_ALLOCA
  38 AC_HEADER_STDC
  39 AM_LANGINFO_CODESET
  40 ZW_GNU_GETTEXT_SISTER_DIR
  41
  42 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  43 [AC_TRY_COMPILE([
  44 #include "ansidecl.h"
  45 #include "system.h"
  46 ],
  47 [if ((uchar *)0) return 0;
  48  if (sizeof(uchar)) return 0;],
  49 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
  50 if test $ac_cv_type_uchar = yes; then
  51   AC_DEFINE(HAVE_UCHAR, 1,
  52   [Define if <sys/types.h> defines \`uchar'.])
  53 fi
  54
  55 AM_ICONV
  56 AM_CONDITIONAL(ENABLE_NLS, [test "x$enable_nls" != xno])
  57 AC_ARG_ENABLE(checking,
  58 [  --enable-checking      enable expensive run-time checks],,
  59 enable_checking=no)
  60
  61 if test $enable_checking != no ; then
  62   AC_DEFINE(ENABLE_CHECKING, 1,
  63 [Define if you want more run-time sanity checks.])
  64 fi
  65
  66 m4_changequote(,)
  67 case $target in
  68         alpha*-*-* | \
  69         x86_64-*-* | \
  70         ia64-*-* | \
  71         hppa*64*-*-* | parisc*64*-*-* | \
  72         mips*-*-* | \
  73         mmix-*-* | \
  74         powerpc*-*-* | \
  75         rs6000*-*-* | \
  76         s390*-*-* | \
  77         sparc64*-*-* | ultrasparc-*-freebsd* | \
  78         sparcv9-*-solaris2* | \
  79         sparc-*-solaris2.[789] | sparc-*-solaris2.1[0-9] | \
  80         sh[123456789l]*-*-*)
  81                 need_64bit_hwint=yes ;;
  82         *)
  83                 need_64bit_hwint=no ;;
  84 esac
  85
  86 case $need_64bit_hwint:$ac_cv_sizeof_long in
  87         *:8 | no:*) host_wide_int=long ;;
  88         *) host_wide_int='long long' ;;
  89 esac
  90 m4_changequote([,])
  91
  92 AC_DEFINE_UNQUOTED(HOST_WIDE_INT, $host_wide_int,
  93 [Define to the widest efficient host integer type at least
  94    as wide as the target's size_t type.])
  95
  96 AC_CONFIG_HEADERS(config.h:config.in)
  97 AC_CONFIG_FILES(Makefile)
  98 AC_OUTPUT