libchill/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU CC.
   6 #
   7 #GNU CHILL is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU CHILL is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU CHILL; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(chillrt0.c)
  24
  25 if test "${srcdir}" = "." ; then
  26   if test "${with_target_subdir}" != "." ; then
  27     topsrcdir=${with_multisrctop}../..
  28   else
  29     topsrcdir=${with_multisrctop}..
  30   fi
  31 else
  32   topsrcdir=${srcdir}/..
  33 fi
  34 dnl This is needed for a multilibbed build in the source tree so
  35 dnl that install-sh and config.sub get found.
  36 AC_CONFIG_AUX_DIR($topsrcdir)
  37
  38 # If the language specific compiler does not exist, but the "gcc" directory does,
  39 # we do not build anything. Note, $r is set by the top-level Makefile.
  40 compiler_name=cc1chill
  41 rm -f skip-this-dir
  42 AC_MSG_CHECKING(if compiler $compiler_name has been built)
  43 AC_CACHE_VAL(chill_cv_compiler_exists,
  44         [chill_cv_compiler_exists=yes
  45         if test -n "$r"; then
  46                 if test -d "$r"/gcc; then
  47                         if test -f "$r"/gcc/$compiler_name; then
  48                                 true
  49                         else
  50                                 chill_cv_compiler_exists=no
  51                                 echo "rm -f config.cache config.log multilib.out" > skip-this-dir
  52                         fi
  53                 fi
  54         fi
  55         ])
  56 AC_MSG_RESULT($chill_cv_compiler_exists)
  57 if test x$chill_cv_compiler_exists = xno
  58 then
  59         rm -f Makefile conftest* confdefs* core
  60         exit 0
  61 fi
  62
  63 dnl Checks for programs.
  64 # For chill we'll set CC to point at the built gcc, but this will get it into
  65 # the makefiles
  66 AC_PROG_CC
  67
  68 test "$AR" || AR=ar
  69 AC_SUBST(AR)
  70 AC_PROG_MAKE_SET
  71
  72 dnl Checks for libraries.
  73
  74 dnl Checks for header files.
  75 # Sanity check for the cross-compilation case:
  76 AC_CHECK_HEADER(stdio.h,:,
  77   [AC_MSG_ERROR([Can't find stdio.h.
  78 You must have a usable C system for the target already installed, at least
  79 including headers and, preferably, the library, before you can configure
  80 the Chill runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  81 then the target library, then build with \`LANGUAGES=chill'.])])
  82
  83 AC_HEADER_STDC
  84
  85 AC_MSG_CHECKING(for posix)
  86 AC_CACHE_VAL(chill_cv_header_posix,
  87   AC_EGREP_CPP(yes,
  88   [#include <sys/types.h>
  89 #include <unistd.h>
  90 #ifdef _POSIX_VERSION
  91   yes
  92 #endif
  93 ],
  94   chill_cv_header_posix=yes,
  95   chill_cv_header_posix=no))
  96 AC_MSG_RESULT($chill_cv_header_posix)
  97
  98 # We can rely on the GNU library being posix-ish.  I guess checking the
  99 # header isn't actually like checking the functions, though...
 100 AC_MSG_CHECKING(for GNU library)
 101 AC_CACHE_VAL(chill_cv_lib_gnu,
 102   AC_EGREP_CPP(yes,
 103     [#include <stdio.h>
 104 #ifdef __GNU_LIBRARY__
 105   yes
 106 #endif
 107 ],
 108   chill_cv_lib_gnu=yes, chill_cv_lib_gnu=no))
 109 AC_MSG_RESULT($chill_cv_lib_gnu)
 110
 111 dnl Checks for library functions.
 112 AC_TYPE_SIGNAL
 113 # we'll get atexit by default
 114 if test $ac_cv_header_stdc != yes; then
 115 AC_CHECK_FUNC(atexit,
 116   AC_DEFINE(onexit,atexit),dnl just in case
 117   [AC_DEFINE(NO_ONEXIT)
 118   AC_CHECK_FUNC(onexit,,
 119     [AC_CHECK_FUNC(on_exit,
 120      AC_DEFINE(onexit,on_exit),)])])
 121 else true
 122 fi
 123
 124 # We need multilib support, but only if configuring for the target.
 125 AC_OUTPUT(Makefile,
 126 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 127 if test -n "$CONFIG_FILES"; then
 128   if test -n "${with_target_subdir}"; then
 129     # FIXME: We shouldn't need to set ac_file
 130     ac_file=Makefile
 131     . ${topsrcdir}/config-ml.in
 132   fi
 133 fi],
 134 srcdir=${srcdir}
 135 host=${host}
 136 target=${target}
 137 with_target_subdir=${with_target_subdir}
 138 with_multisubdir=${with_multisubdir}
 139 ac_configure_args="--enable-multilib ${ac_configure_args}"
 140 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 141 topsrcdir=${topsrcdir}
 142 )
 143
 144
 145
 146 dnl Local Variables:
 147 dnl comment-start: "dnl "
 148 dnl comment-end: ""
 149 dnl comment-start-skip: "\\bdnl\\b\\s *"
 150 dnl End: