gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files and targets accumulated by configure.
  38
  39 CONFIG_OBS=
  40 CONFIG_DEPS=
  41 CONFIG_SRCS=
  42 ENABLE_CFLAGS=
  43
  44 CONFIG_ALL=
  45 CONFIG_CLEAN=
  46 CONFIG_INSTALL=
  47 CONFIG_UNINSTALL=
  48
  49 dnl Set up for gettext.
  50 ZW_GNU_GETTEXT_SISTER_DIR
  51
  52 localedir='${datadir}/locale'
  53 AC_SUBST(localedir)
  54
  55 if test x"$USE_NLS" = xyes; then
  56    CONFIG_ALL="$CONFIG_ALL all-po"
  57    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  58    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  59    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  60 fi
  61
  62 PACKAGE=gdb
  63 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  64 AC_SUBST(PACKAGE)
  65
  66 debugdir=${libdir}/debug
  67
  68 AC_ARG_WITH(separate-debug-dir,
  69 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  70 [debugdir="${withval}"])
  71
  72 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  73               [Global directory for separate debug files. ])
  74 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  75
  76 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
  77   if test "x$prefix" = xNONE; then
  78     test_prefix=/usr/local
  79   else
  80     test_prefix=$prefix
  81   fi
  82 else
  83   test_prefix=$exec_prefix
  84 fi
  85 case ${debugdir} in
  86 "${test_prefix}"|"${test_prefix}/"*|\
  87 '${exec_prefix}'|'${exec_prefix}/'*)
  88   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
  89   ;;
  90 esac
  91
  92 AC_CONFIG_SUBDIRS(doc testsuite)
  93
  94 # Provide defaults for some variables set by the per-host and per-target
  95 # configuration.
  96 gdb_host_obs=posix-hdep.o
  97
  98 if test "${target}" = "${host}"; then
  99   gdb_native=yes
 100 else
 101   gdb_native=no
 102 fi
 103
 104 . $srcdir/configure.host
 105
 106 . $srcdir/configure.tgt
 107
 108 # Fetch the default architecture and default target vector from BFD.
 109 targ=$target; . $srcdir/../bfd/config.bfd
 110
 111 # We only want the first architecture, so strip off the others if
 112 # there is more than one.
 113 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 114
 115 if test "x$targ_archs" != x; then
 116   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 117     [Define to BFD's default architecture. ])
 118 fi
 119 if test "x$targ_defvec" != x; then
 120   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 121     [Define to BFD's default target vector. ])
 122 fi
 123
 124 AC_ARG_PROGRAM
 125
 126 # The CLI cannot be disabled yet, but may be in the future.
 127
 128 # Enable CLI.
 129 AC_ARG_ENABLE(gdbcli,
 130 [  --disable-gdbcli        disable command-line interface (CLI)],
 131   [case $enableval in
 132     yes)
 133       ;;
 134     no)
 135       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 136     *)
 137       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 138   esac],
 139   [enable_gdbcli=yes])
 140 if test x"$enable_gdbcli" = xyes; then
 141   if test -d $srcdir/cli; then
 142     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 143     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 144     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 145     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 146   fi
 147 fi
 148
 149 # Enable MI.
 150 AC_ARG_ENABLE(gdbmi,
 151 [  --disable-gdbmi         disable machine-interface (MI)],
 152   [case $enableval in
 153     yes | no)
 154       ;;
 155     *)
 156       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 157   esac],
 158   [enable_gdbmi=yes])
 159 if test x"$enable_gdbmi" = xyes; then
 160   if test -d $srcdir/mi; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 164     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 165   fi
 166 fi
 167
 168 # Enable TUI.
 169 AC_ARG_ENABLE(tui,
 170 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 171   [case $enableval in
 172     yes | no)
 173       ;;
 174     *)
 175       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 176   esac],enable_tui=yes)
 177
 178 # Enable gdbtk.
 179 AC_ARG_ENABLE(gdbtk,
 180 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 181   [case $enableval in
 182     yes | no)
 183       ;;
 184     *)
 185       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 186   esac],
 187   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 188     enable_gdbtk=yes
 189   else
 190     enable_gdbtk=no
 191   fi])
 192 # We unconditionally disable gdbtk tests on selected platforms.
 193 case $host_os in
 194   go32* | windows*)
 195     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 196     enable_gdbtk=no ;;
 197 esac
 198
 199 # Libunwind support.
 200 AC_ARG_WITH(libunwind,
 201 [  --with-libunwind            Use libunwind frame unwinding support],
 202 [case "${withval}" in
 203   yes)  enable_libunwind=yes ;;
 204   no)   enable_libunwind=no ;;
 205   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 206 esac],[
 207   AC_CHECK_HEADERS(libunwind.h)
 208   AC_CHECK_HEADERS(libunwind-ia64.h)
 209   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 210     enable_libunwind=yes;
 211   fi
 212 ])
 213
 214 if test x"$enable_libunwind" = xyes; then
 215   AC_CHECK_HEADERS(libunwind.h)
 216   AC_CHECK_HEADERS(libunwind-ia64.h)
 217   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 218   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 219   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 220   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 221 fi
 222
 223 # Profiling support.
 224 AC_ARG_ENABLE(profiling,
 225 [  --enable-profiling      enable profiling of GDB],
 226   [case $enableval in
 227     yes | no)
 228       ;;
 229     *)
 230       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 231   esac],
 232  [enable_profiling=no])
 233
 234 AC_CHECK_FUNCS(monstartup _mcleanup)
 235 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 236 [AC_TRY_LINK(
 237 [#include <stdlib.h>
 238 extern char _etext;
 239 ],
 240 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 241 if test $ac_cv_var__etext = yes; then
 242   AC_DEFINE(HAVE__ETEXT, 1,
 243             [Define to 1 if your system has the _etext variable. ])
 244 fi
 245 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 246 [AC_TRY_LINK(
 247 [#include <stdlib.h>
 248 extern char etext;
 249 ],
 250 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 251 if test $ac_cv_var_etext = yes; then
 252   AC_DEFINE(HAVE_ETEXT, 1,
 253             [Define to 1 if your system has the etext variable. ])
 254 fi
 255 if test "$enable_profiling" = yes ; then
 256   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 257     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 258   fi
 259   PROFILE_CFLAGS=-pg
 260   OLD_CFLAGS="$CFLAGS"
 261   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 262
 263   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 264     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 265      ac_cv_cc_supports_pg=no)])
 266
 267   if test $ac_cv_cc_supports_pg = no; then
 268     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 269   fi
 270
 271   CFLAGS="$OLD_CFLAGS"
 272 fi
 273
 274 # --------------------- #
 275 # Checks for programs.  #
 276 # --------------------- #
 277
 278 AC_PROG_AWK
 279 AC_PROG_INSTALL
 280 AC_PROG_LN_S
 281 AC_PROG_RANLIB
 282 AC_PROG_YACC
 283
 284 AC_CHECK_TOOL(AR, ar)
 285 AC_CHECK_TOOL(DLLTOOL, dlltool)
 286 AC_CHECK_TOOL(WINDRES, windres)
 287
 288 # Needed for GNU/Hurd.
 289 AC_CHECK_TOOL(MIG, mig)
 290
 291 # ---------------------- #
 292 # Checks for libraries.  #
 293 # ---------------------- #
 294
 295 # We might need to link with -lm; most simulators need it.
 296 AC_CHECK_LIB(m, main)
 297
 298 # We need to link with -lw to get `wctype' on Solaris before Solaris
 299 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 300 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 301 # is known to have this problem).  Therefore we avoid libw if we can.
 302 AC_CHECK_FUNC(wctype, [],
 303   [AC_CHECK_LIB(w, wctype)])
 304
 305 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 306 AC_SEARCH_LIBS(gethostbyname, nsl)
 307
 308 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 309 AC_SEARCH_LIBS(socketpair, socket)
 310
 311 # For the TUI, we need enhanced curses functionality.
 312 #
 313 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 314 # curses library because the latter might not provide all the
 315 # functionality we need.  However, this leads to problems on systems
 316 # where the linker searches /usr/local/lib, but the compiler doesn't
 317 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 318 # default installation of ncurses on alpha*-dec-osf* will lead to such
 319 # a situation.
 320 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 321
 322 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 323 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 324
 325 # Since GDB uses Readline, we need termcap functionality.  In many
 326 # cases this will be provided by the curses library, but some systems
 327 # have a seperate termcap library, or no curses library at all.
 328
 329 case $host_os in
 330   cygwin*)
 331     if test -d $srcdir/libtermcap; then
 332       LIBS="../libtermcap/libtermcap.a $LIBS"
 333       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 334     fi ;;
 335   go32* | *djgpp*)
 336     ac_cv_search_tgetent="none required"
 337     ;;
 338   *mingw32*)
 339     ac_cv_search_tgetent="none required"
 340     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 341     ;;
 342 esac
 343
 344 # These are the libraries checked by Readline.
 345 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 346
 347 if test "$ac_cv_search_tgetent" = no; then
 348   AC_MSG_ERROR([no termcap library found])
 349 fi
 350
 351 AC_ARG_WITH([system-readline],
 352   [AS_HELP_STRING([--with-system-readline],
 353                   [use installed readline library])])
 354
 355 if test "$with_system_readline" = yes; then
 356   READLINE=-lreadline
 357   READLINE_DEPS=
 358   READLINE_CFLAGS=
 359 else
 360   READLINE='$(READLINE_DIR)/libreadline.a'
 361   READLINE_DEPS='$(READLINE)'
 362   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 363 fi
 364 AC_SUBST(READLINE)
 365 AC_SUBST(READLINE_DEPS)
 366 AC_SUBST(READLINE_CFLAGS)
 367
 368 AC_ARG_WITH(expat,
 369   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 370   [], [with_expat=auto])
 371 AC_MSG_CHECKING([whether to use expat])
 372 AC_MSG_RESULT([$with_expat])
 373
 374 if test "${with_expat}" = no; then
 375   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 376   HAVE_LIBEXPAT=no
 377 else
 378   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 379                         [XML_Parser p = XML_ParserCreate (0);])
 380   if test "$HAVE_LIBEXPAT" != yes; then
 381     if test "$with_expat" = yes; then
 382       AC_MSG_ERROR([expat is missing or unusable])
 383     else
 384       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 385     fi
 386   else
 387     save_LIBS=$LIBS
 388     LIBS="$LIBS $LIBEXPAT"
 389     AC_CHECK_FUNCS(XML_StopParser)
 390     LIBS=$save_LIBS
 391   fi
 392 fi
 393
 394 # ------------------------- #
 395 # Checks for header files.  #
 396 # ------------------------- #
 397
 398 AC_HEADER_DIRENT
 399 AC_HEADER_STAT
 400 AC_HEADER_STDC
 401 AC_CHECK_HEADERS(nlist.h)
 402 AC_CHECK_HEADERS(link.h, [], [],
 403 [#if HAVE_SYS_TYPES_H
 404 # include <sys/types.h>
 405 #endif
 406 #if HAVE_NLIST_H
 407 # include <nlist.h>
 408 #endif
 409 ])
 410 AC_CHECK_HEADERS(machine/reg.h)
 411 AC_CHECK_HEADERS(poll.h sys/poll.h)
 412 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 413 AC_CHECK_HEADERS(signal.h)
 414 AC_CHECK_HEADERS(stddef.h)
 415 AC_CHECK_HEADERS(stdlib.h)
 416 AC_CHECK_HEADERS(stdint.h)
 417 AC_CHECK_HEADERS(string.h memory.h strings.h)
 418 AC_CHECK_HEADERS(sys/fault.h)
 419 AC_CHECK_HEADERS(sys/file.h)
 420 AC_CHECK_HEADERS(sys/filio.h)
 421 AC_CHECK_HEADERS(sys/ioctl.h)
 422 AC_CHECK_HEADERS(sys/param.h)
 423 AC_CHECK_HEADERS(sys/resource.h)
 424 AC_CHECK_HEADERS(sys/proc.h, [], [],
 425 [#if HAVE_SYS_PARAM_H
 426 # include <sys/param.h>
 427 #endif
 428 ])
 429 AC_CHECK_HEADERS(sys/procfs.h)
 430 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 431 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 432 AC_CHECK_HEADERS(sys/select.h)
 433 AC_CHECK_HEADERS(sys/syscall.h)
 434 AC_CHECK_HEADERS(sys/types.h)
 435 AC_CHECK_HEADERS(sys/user.h, [], [],
 436 [#if HAVE_SYS_PARAM_H
 437 # include <sys/param.h>
 438 #endif
 439 ])
 440 AC_CHECK_HEADERS(sys/wait.h wait.h)
 441 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 442 AC_CHECK_HEADERS(unistd.h)
 443
 444 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 445 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 446 # think that we don't have <curses.h> if we're using GCC.
 447 case $host_os in
 448   solaris2.[[789]])
 449     if test "$GCC" = yes; then
 450       AC_DEFINE(_MSE_INT_H, 1,
 451         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 452    Solaris 2.[789] when using GCC. ])
 453     fi ;;
 454 esac
 455 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 456 AC_CHECK_HEADERS(ncurses/term.h)
 457 AC_CHECK_HEADERS(term.h, [], [],
 458 [#if HAVE_CURSES_H
 459 # include <curses.h>
 460 #endif
 461 ])
 462
 463 # Check for HP/UX 64-bit shared library support
 464 AC_CHECK_HEADERS(elf_hp.h)
 465
 466 # FIXME: kettenis/20030102: In most cases we include these
 467 # unconditionally, so what's the point in checking these?
 468 AC_CHECK_HEADERS(ctype.h time.h)
 469
 470 # Create a header we can use portably to get the standard integer types.
 471 GCC_HEADER_STDINT(gdb_stdint.h)
 472
 473 # ------------------------- #
 474 # Checks for declarations.  #
 475 # ------------------------- #
 476
 477 AC_CHECK_DECLS([free, malloc, realloc])
 478 AC_CHECK_DECLS([strerror, strstr])
 479 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 480
 481 # ----------------------- #
 482 # Checks for structures.  #
 483 # ----------------------- #
 484
 485 AC_CHECK_MEMBERS([struct stat.st_blocks])
 486 AC_CHECK_MEMBERS([struct stat.st_blksize])
 487
 488 # ------------------ #
 489 # Checks for types.  #
 490 # ------------------ #
 491
 492 AC_TYPE_SIGNAL
 493 AC_CHECK_TYPES(socklen_t, [], [],
 494 [#include <sys/types.h>
 495 #include <sys/socket.h>
 496 ])
 497 AC_CHECK_TYPES(uintptr_t, [], [], [#include <stdint.h>])
 498
 499 # ------------------------------------- #
 500 # Checks for compiler characteristics.  #
 501 # ------------------------------------- #
 502
 503 AC_C_CONST
 504 AC_C_INLINE
 505 AC_C_BIGENDIAN
 506
 507 # ------------------------------ #
 508 # Checks for library functions.  #
 509 # ------------------------------ #
 510
 511 AC_FUNC_ALLOCA
 512 AC_FUNC_MMAP
 513 AC_FUNC_VFORK
 514 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 515 AC_CHECK_FUNCS(getrusage)
 516 AC_CHECK_FUNCS(getuid getgid)
 517 AC_CHECK_FUNCS(poll)
 518 AC_CHECK_FUNCS(pread64)
 519 AC_CHECK_FUNCS(sbrk)
 520 AC_CHECK_FUNCS(setpgid setpgrp)
 521 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 522 AC_CHECK_FUNCS(socketpair)
 523 AC_CHECK_FUNCS(syscall)
 524 AC_CHECK_FUNCS(ttrace)
 525 AC_CHECK_FUNCS(wborder)
 526
 527 # Check the return and argument types of ptrace.  No canned test for
 528 # this, so roll our own.
 529 gdb_ptrace_headers='
 530 #if HAVE_SYS_TYPES_H
 531 # include <sys/types.h>
 532 #endif
 533 #if HAVE_SYS_PTRACE_H
 534 # include <sys/ptrace.h>
 535 #endif
 536 #if HAVE_UNISTD_H
 537 # include <unistd.h>
 538 #endif
 539 '
 540 # There is no point in checking if we don't have a prototype.
 541 AC_CHECK_DECLS(ptrace, [], [
 542   : ${gdb_cv_func_ptrace_ret='int'}
 543   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 544 ], $gdb_ptrace_headers)
 545 # Check return type.
 546 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 547   AC_TRY_COMPILE($gdb_ptrace_headers,
 548     [extern int ptrace ();],
 549     gdb_cv_func_ptrace_ret='int',
 550     gdb_cv_func_ptrace_ret='long'))
 551 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 552   [Define as the return type of ptrace.])
 553 # Check argument types.
 554 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 555 for gdb_arg1 in 'int' 'long'; do
 556  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 557   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 558    for gdb_arg4 in 'int' 'long'; do
 559      AC_TRY_COMPILE($gdb_ptrace_headers, [
 560 extern $gdb_cv_func_ptrace_ret
 561   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 562 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 563     break 4;])
 564     for gdb_arg5 in 'int *' 'int' 'long'; do
 565      AC_TRY_COMPILE($gdb_ptrace_headers, [
 566 extern $gdb_cv_func_ptrace_ret
 567   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 568 ], [
 569 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 570     break 5;])
 571     done
 572    done
 573   done
 574  done
 575 done
 576 # Provide a safe default value.
 577 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 578 ])
 579 ac_save_IFS=$IFS; IFS=','
 580 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 581 IFS=$ac_save_IFS
 582 shift
 583 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 584   [Define to the type of arg 3 for ptrace.])
 585 if test -n "$[5]"; then
 586   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 587     [Define to the type of arg 5 for ptrace.])
 588 fi
 589
 590 dnl AC_FUNC_SETPGRP does not work when cross compiling
 591 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 592 if test "$cross_compiling" = no; then
 593   AC_FUNC_SETPGRP
 594 else
 595   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 596     [AC_TRY_COMPILE([
 597 #include <unistd.h>
 598 ], [
 599   if (setpgrp(1,1) == -1)
 600     exit (0);
 601   else
 602     exit (1);
 603 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 604 if test $ac_cv_func_setpgrp_void = yes; then
 605   AC_DEFINE(SETPGRP_VOID, 1)
 606 fi
 607 fi
 608
 609 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 610 # since sigsetjmp might only be defined as a macro.
 611 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 612 [AC_TRY_COMPILE([
 613 #include <setjmp.h>
 614 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 615 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 616 if test $gdb_cv_func_sigsetjmp = yes; then
 617   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 618 fi
 619
 620 # Assume we'll default to using the included libiberty regex.
 621 gdb_use_included_regex=yes
 622
 623 # However, if the system regex is GNU regex, then default to *not*
 624 # using the included regex.
 625 AC_CACHE_CHECK(
 626   [for GNU regex],
 627   [gdb_cv_have_gnu_regex],
 628   [AC_TRY_COMPILE(
 629     [#include <gnu-versions.h>],
 630     [#define REGEX_INTERFACE_VERSION 1
 631 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 632 # error "Version mismatch"
 633 #endif],
 634     gdb_cv_have_gnu_regex=yes,
 635     gdb_cv_have_gnu_regex=no)])
 636 if test $gdb_cv_have_gnu_regex = yes; then
 637   gdb_use_included_regex=no
 638 fi
 639
 640 AC_ARG_WITH(included-regex,
 641   [  --without-included-regex don't use included regex; this is the default
 642                           on systems with version 2 of the GNU C library
 643                           (use with caution on other system)],
 644   gdb_with_regex=$withval,
 645   gdb_with_regex=$gdb_use_included_regex)
 646 if test "$gdb_with_regex" = yes; then
 647   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 648     [Define to 1 if the regex included in libiberty should be used.])
 649 fi
 650
 651 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 652 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 653 [#include <sys/param.h>
 654 #include <sys/proc.h>
 655 ])
 656
 657 # See if <sys/lwp.h> defines `struct lwp`.
 658 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 659 [AC_TRY_COMPILE([#include <sys/param.h>
 660 #include <sys/lwp.h>], [struct lwp l;],
 661 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 662 if test $gdb_cv_struct_lwp = yes; then
 663   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 664             [Define to 1 if your system has struct lwp.])
 665 fi
 666
 667 # See if <machine/reg.h> degines `struct reg'.
 668 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 669 [AC_TRY_COMPILE([#include <sys/types.h>
 670 #include <machine/reg.h>], [struct reg r;],
 671 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 672 if test $gdb_cv_struct_reg = yes; then
 673   AC_DEFINE(HAVE_STRUCT_REG, 1,
 674             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 675 fi
 676
 677 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 678 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 679 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 680                  [#include <machine/reg.h>])
 681
 682 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 683 AC_MSG_CHECKING(for PTRACE_GETREGS)
 684 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 685 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 686                 [PTRACE_GETREGS;],
 687                 [gdb_cv_have_ptrace_getregs=yes],
 688                 [gdb_cv_have_ptrace_getregs=no])])
 689 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 690 if test $gdb_cv_have_ptrace_getregs = yes; then
 691   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 692   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 693 fi
 694
 695 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 696 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 697 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 698 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 699                 [PTRACE_GETFPXREGS;],
 700                 [gdb_cv_have_ptrace_getfpxregs=yes],
 701                 [gdb_cv_have_ptrace_getfpxregs=no])])
 702 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 703 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 704   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 705   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 706 fi
 707
 708 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 709 AC_MSG_CHECKING(for PT_GETDBREGS)
 710 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 711 [AC_TRY_COMPILE([#include <sys/types.h>
 712 #include <sys/ptrace.h>],
 713                 [PT_GETDBREGS;],
 714                 [gdb_cv_have_pt_getdbregs=yes],
 715                 [gdb_cv_have_pt_getdbregs=no])])
 716 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 717 if test $gdb_cv_have_pt_getdbregs = yes; then
 718   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 719   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 720 fi
 721
 722 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 723 AC_MSG_CHECKING(for PT_GETXMMREGS)
 724 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 725 [AC_TRY_COMPILE([#include <sys/types.h>
 726 #include <sys/ptrace.h>],
 727                 [PT_GETXMMREGS;],
 728                 [gdb_cv_have_pt_getxmmregs=yes],
 729                 [gdb_cv_have_pt_getxmmregs=no])])
 730 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 731 if test $gdb_cv_have_pt_getxmmregs = yes; then
 732   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 733   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 734 fi
 735
 736 # Detect which type of /proc is in use, such as for Unixware or Solaris.
 737
 738 if test "${target}" = "${host}"; then
 739   case "${host}" in
 740   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 741       AC_DEFINE(NEW_PROC_API, 1,
 742       [Define if you want to use new multi-fd /proc interface
 743        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 744       ;;
 745   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 746       AC_DEFINE(NEW_PROC_API, 1,
 747       [Define if you want to use new multi-fd /proc interface
 748        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 749       ;;
 750   mips-sgi-irix5*)
 751       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 752       AC_DEFINE([_KMEMUSER], 1,
 753       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 754        around a <sys/proc.h> problem on IRIX 5.])
 755       ;;
 756   esac
 757 fi
 758
 759 if test "$ac_cv_header_sys_procfs_h" = yes; then
 760   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 761   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 762   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 763   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 764   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 765   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 766   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 767   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 768   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 769   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 770   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 771   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 772   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 773   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 774
 775
 776   dnl Check for broken prfpregset_t type
 777
 778   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 779   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 780   dnl instead of the struct itself).  We detect this here, and work
 781   dnl around it in gdb_proc_service.h.
 782
 783   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 784     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 785     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 786       [AC_TRY_RUN([#include <sys/procfs.h>
 787        int main ()
 788        {
 789          if (sizeof (prfpregset_t) == sizeof (void *))
 790            return 1;
 791          return 0;
 792        }],
 793        gdb_cv_prfpregset_t_broken=no,
 794        gdb_cv_prfpregset_t_broken=yes,
 795        gdb_cv_prfpregset_t_broken=yes)])
 796     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 797     if test $gdb_cv_prfpregset_t_broken = yes; then
 798       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
 799       [Define if the prfpregset_t type is broken.])
 800     fi
 801   fi
 802
 803   dnl Check for PIOCSET ioctl entry
 804
 805   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 806   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 807   [AC_TRY_COMPILE([#include <unistd.h>
 808 #include <sys/types.h>
 809 #include <sys/procfs.h>
 810 ], [
 811     int dummy;;
 812     dummy = ioctl(0, PIOCSET, &dummy);
 813   ],
 814   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 815   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 816   if test $gdb_cv_have_procfs_piocset = yes; then
 817     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
 818     [Define if ioctl argument PIOCSET is available.])
 819   fi
 820 fi
 821
 822 dnl For native ports (host == target), check to see what kind of
 823 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 824 if test ${host} = ${target} ; then
 825   dnl Check for struct link_map with l_ members which are indicative
 826   dnl of SVR4-like shared libraries
 827
 828   AC_MSG_CHECKING(for member l_addr in struct link_map)
 829   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 830     [AC_TRY_COMPILE([#include <link.h>],
 831                     [struct link_map lm; (void) lm.l_addr;],
 832                     gdb_cv_have_struct_link_map_with_l_members=yes,
 833                     gdb_cv_have_struct_link_map_with_l_members=no)])
 834   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 835   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 836     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
 837     [Define if <link.h> exists and defines struct link_map which has
 838      members with an ``l_'' prefix.  (For Solaris, SVR4, and
 839      SVR4-like systems.)])
 840   fi
 841
 842   dnl Check for struct link_map with lm_ members which are indicative
 843   dnl of SunOS-like shared libraries
 844
 845   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 846   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 847     [AC_TRY_COMPILE([#include <sys/types.h>
 848 #include <link.h>],
 849                     [struct link_map lm; (void) lm.lm_addr;],
 850                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 851                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 852   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 853   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 854     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
 855     [Define if <link.h> exists and defines struct link_map which has
 856      members with an ``lm_'' prefix.  (For SunOS.)])
 857   fi
 858
 859   dnl Check for struct so_map with som_ members which are found on
 860   dnl some *BSD systems.
 861
 862   AC_MSG_CHECKING(for member som_addr in struct so_map)
 863   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 864     [AC_TRY_COMPILE([#include <sys/types.h>
 865 #ifdef HAVE_NLIST_H
 866 #include <nlist.h>
 867 #endif
 868 #include <link.h>],
 869                     [struct so_map lm; (void) lm.som_addr;],
 870                     gdb_cv_have_struct_so_map_with_som_members=yes,
 871                     gdb_cv_have_struct_so_map_with_som_members=no)])
 872   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 873   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 874     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
 875     [Define if <link.h> exists and defines a struct so_map which has
 876      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
 877   fi
 878
 879   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 880   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 881
 882   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 883   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 884     [AC_TRY_COMPILE([#define _SYSCALL32
 885 #include <sys/link.h>], [struct link_map32 l;],
 886      gdb_cv_have_struct_link_map32=yes,
 887      gdb_cv_have_struct_link_map32=no)])
 888   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 889   if test $gdb_cv_have_struct_link_map32 = yes; then
 890     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
 891     [Define if <sys/link.h> has struct link_map32])
 892     AC_DEFINE(_SYSCALL32, 1,
 893     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
 894   fi
 895 fi
 896
 897 # Check if the compiler supports the `long long' type.
 898
 899 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 900                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 901 [[extern long long foo;]],
 902 [[switch (foo & 2) { case 0: return 1; }]])],
 903                                   gdb_cv_c_long_long=yes,
 904                                   gdb_cv_c_long_long=no)])
 905 if test $gdb_cv_c_long_long = yes; then
 906   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 907             [Define to 1 if the compiler supports long long.])
 908 fi
 909
 910 # Check if the compiler and runtime support printing long longs.
 911
 912 AC_CACHE_CHECK([for long long support in printf],
 913                gdb_cv_printf_has_long_long,
 914                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 915 [[char buf[32];
 916   long long l = 0;
 917   l = (l << 16) + 0x0123;
 918   l = (l << 16) + 0x4567;
 919   l = (l << 16) + 0x89ab;
 920   l = (l << 16) + 0xcdef;
 921   sprintf (buf, "0x%016llx", l);
 922   return (strcmp ("0x0123456789abcdef", buf));]])],
 923                               gdb_cv_printf_has_long_long=yes,
 924                               gdb_cv_printf_has_long_long=no,
 925                               gdb_cv_printf_has_long_long=no)])
 926 if test $gdb_cv_printf_has_long_long = yes; then
 927   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 928             [Define to 1 if the "%ll" format works to print long longs.])
 929 fi
 930
 931 # Check if the compiler supports the `long double' type.  We can't use
 932 # AC_C_LONG_DOUBLE because that one does additional checks on the
 933 # constants defined in <float.h> that fail on some systems,
 934 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 935
 936 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 937                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 938                                   gdb_cv_c_long_double=yes,
 939                                   gdb_cv_c_long_double=no)])
 940 if test $gdb_cv_c_long_double = yes; then
 941   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 942            [Define to 1 if the compiler supports long double.])
 943 fi
 944
 945 # Check if the compiler and runtime support printing long doubles.
 946
 947 AC_CACHE_CHECK([for long double support in printf],
 948                gdb_cv_printf_has_long_double,
 949                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 950 [[char buf[16];
 951   long double f = 3.141592653;
 952   sprintf (buf, "%Lg", f);
 953   return (strncmp ("3.14159", buf, 7));]])],
 954                               gdb_cv_printf_has_long_double=yes,
 955                               gdb_cv_printf_has_long_double=no,
 956                               gdb_cv_printf_has_long_double=no)])
 957 if test $gdb_cv_printf_has_long_double = yes; then
 958   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 959             [Define to 1 if the "%Lg" format works to print long doubles.])
 960 fi
 961
 962 # Check if the compiler and runtime support scanning long doubles.
 963
 964 AC_CACHE_CHECK([for long double support in scanf],
 965                gdb_cv_scanf_has_long_double,
 966                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 967 [[#include <stdio.h>]],
 968 [[char *buf = "3.141592653";
 969   long double f = 0;
 970   sscanf (buf, "%Lg", &f);
 971   return !(f > 3.14159 && f < 3.14160);]])],
 972                               gdb_cv_scanf_has_long_double=yes,
 973                               gdb_cv_scanf_has_long_double=no,
 974                               gdb_cv_scanf_has_long_double=no)])
 975 if test $gdb_cv_scanf_has_long_double = yes; then
 976   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 977             [Define to 1 if the "%Lg" format works to scan long doubles.])
 978 fi
 979
 980 case ${host_os} in
 981 aix*)
 982   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 983     SAVE_LDFLAGS=$LDFLAGS
 984
 985     case $GCC in
 986     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 987     *) gdb_cv_bigtoc=-bbigtoc ;;
 988     esac
 989
 990     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 991     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 992     LDFLAGS="${SAVE_LDFLAGS}"
 993   ])
 994   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 995   ;;
 996 esac
 997
 998
 999 dnl For certain native configurations, we need to check whether thread
1000 dnl support can be built in or not.
1001 dnl
1002 dnl Note that we only want this if we are both native (host == target),
1003 dnl and not doing a canadian cross build (build == host).
1004
1005 if test ${build} = ${host} -a ${host} = ${target} ; then
1006    case ${host_os} in
1007    hpux*)
1008       AC_MSG_CHECKING(for HPUX/OSF thread support)
1009       if test -f /usr/include/dce/cma_config.h ; then
1010          if test "$GCC" = "yes" ; then
1011             AC_MSG_RESULT(yes)
1012             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1013             [Define if you have HPUX threads])
1014             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1015             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1016          else
1017             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1018          fi
1019       else
1020          AC_MSG_RESULT(no)
1021       fi
1022       ;;
1023    solaris*)
1024       # See if thread_db library is around for Solaris thread debugging.
1025       # Note that we must explicitly test for version 1 of the library
1026       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1027       # the same API.
1028       AC_MSG_CHECKING(for Solaris thread debugging library)
1029       if test -f /usr/lib/libthread_db.so.1 ; then
1030          AC_MSG_RESULT(yes)
1031          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1032          [Define if using Solaris thread debugging.])
1033          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1034          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1035          AC_CHECK_LIB(dl, dlopen)
1036          if test "$GCC" = "yes" ; then
1037             # The GNU linker requires the -export-dynamic option to make
1038             # all symbols visible in the dynamic symbol table.
1039             hold_ldflags=$LDFLAGS
1040             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1041             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1042             AC_TRY_LINK(, [int i;], found=yes, found=no)
1043             LDFLAGS=$hold_ldflags
1044             AC_MSG_RESULT($found)
1045             if test $found = yes; then
1046                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1047             fi
1048          fi
1049          # Sun randomly tweaked the prototypes in <proc_service.h>
1050          # at one point.
1051          AC_MSG_CHECKING(if <proc_service.h> is old)
1052          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1053             AC_TRY_COMPILE([
1054                 #include <proc_service.h>
1055                 ps_err_e ps_pdwrite
1056                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1057             ],, gdb_cv_proc_service_is_old=no,
1058                 gdb_cv_proc_service_is_old=yes)
1059          ])
1060          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1061          if test $gdb_cv_proc_service_is_old = yes; then
1062             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1063             [Define if <proc_service.h> on solaris uses int instead of
1064              size_t, and assorted other type changes.])
1065          fi
1066       else
1067          AC_MSG_RESULT(no)
1068       fi
1069       ;;
1070    aix*)
1071       AC_MSG_CHECKING(for AiX thread debugging library)
1072       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1073                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1074                                    [#ifndef PTHDB_VERSION_3
1075                                     #error
1076                                     #endif],
1077                                    gdb_cv_have_aix_thread_debug=yes,
1078                                    gdb_cv_have_aix_thread_debug=no)])
1079       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1080       if test $gdb_cv_have_aix_thread_debug = yes; then
1081          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1082          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1083          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1084       fi
1085       ;;
1086    esac
1087    AC_SUBST(CONFIG_LDFLAGS)
1088 fi
1089
1090 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1091 dnl other error codes.
1092 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1093    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1094                   gdb_cv_thread_db_h_has_td_notalloc,
1095      AC_TRY_COMPILE(
1096        [#include <thread_db.h>],
1097        [int i = TD_NOTALLOC;],
1098        gdb_cv_thread_db_h_has_td_notalloc=yes,
1099        gdb_cv_thread_db_h_has_td_notalloc=no
1100      )
1101    )
1102    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1103                   gdb_cv_thread_db_h_has_td_version,
1104      AC_TRY_COMPILE(
1105        [#include <thread_db.h>],
1106        [int i = TD_VERSION;],
1107        gdb_cv_thread_db_h_has_td_version=yes,
1108        gdb_cv_thread_db_h_has_td_version=no
1109      )
1110    )
1111    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1112                   gdb_cv_thread_db_h_has_td_notls,
1113      AC_TRY_COMPILE(
1114        [#include <thread_db.h>],
1115        [int i = TD_NOTLS;],
1116        gdb_cv_thread_db_h_has_td_notls=yes,
1117        gdb_cv_thread_db_h_has_td_notls=no
1118      )
1119    )
1120 fi
1121 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1122   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1123             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1124 fi
1125 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1126   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1127             [Define if <thread_db.h> has the TD_VERSION error code.])
1128 fi
1129 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1130   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1131             [Define if <thread_db.h> has the TD_NOTLS error code.])
1132 fi
1133
1134 dnl See if we have a sys/syscall header file that has __NR_tkill.
1135 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1136    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1137                   gdb_cv_sys_syscall_h_has_tkill,
1138      AC_TRY_COMPILE(
1139        [#include <sys/syscall.h>],
1140        [int i = __NR_tkill;],
1141        gdb_cv_sys_syscall_h_has_tkill=yes,
1142        gdb_cv_sys_syscall_h_has_tkill=no
1143      )
1144    )
1145 fi
1146 dnl See if we can issue tkill syscall.
1147 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1148   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1149 fi
1150
1151 dnl Handle optional features that can be enabled.
1152
1153 AC_ARG_WITH(sysroot,
1154 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1155 [
1156  case ${with_sysroot} in
1157  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1158  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1159  esac
1160
1161  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1162
1163  if test "x$prefix" = xNONE; then
1164   test_prefix=/usr/local
1165  else
1166   test_prefix=$prefix
1167  fi
1168  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1169   test_exec_prefix=$test_prefix
1170  else
1171   test_exec_prefix=$exec_prefix
1172  fi
1173  case ${TARGET_SYSTEM_ROOT} in
1174  "${test_prefix}"|"${test_prefix}/"*|\
1175  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1176  '${prefix}'|'${prefix}/'*|\
1177  '${exec_prefix}'|'${exec_prefix}/'*)
1178    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1179    TARGET_SYSTEM_ROOT_DEFINE="$t"
1180    ;;
1181  esac
1182 ], [
1183  TARGET_SYSTEM_ROOT=
1184  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1185 ])
1186 AC_SUBST(TARGET_SYSTEM_ROOT)
1187 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1188
1189 AC_ARG_ENABLE(werror,
1190   [  --enable-werror    treat compile warnings as errors],
1191   [case "${enableval}" in
1192      yes | y) ERROR_ON_WARNING="yes" ;;
1193      no | n)  ERROR_ON_WARNING="no" ;;
1194      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1195    esac])
1196
1197 # Enable -Werror by default when using gcc
1198 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1199     ERROR_ON_WARNING=yes
1200 fi
1201
1202 WERROR_CFLAGS=""
1203 if test "${ERROR_ON_WARNING}" = yes ; then
1204     WERROR_CFLAGS="-Werror"
1205 fi
1206
1207 # The entries after -Wno-pointer-sign are disabled warnings which may
1208 # be enabled in the future, which can not currently be used to build
1209 # GDB.
1210 # NOTE: If you change this list, remember to update
1211 # gdb/doc/gdbint.texinfo.
1212 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1213 -Wformat-nonliteral -Wno-pointer-sign \
1214 -Wno-unused -Wno-switch -Wno-char-subscripts"
1215
1216 AC_ARG_ENABLE(build-warnings,
1217 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1218 [case "${enableval}" in
1219   yes)  ;;
1220   no)   build_warnings="-w";;
1221   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1222         build_warnings="${build_warnings} ${t}";;
1223   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1224         build_warnings="${t} ${build_warnings}";;
1225   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1226 esac
1227 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1228   echo "Setting compiler warning flags = $build_warnings" 6>&1
1229 fi])dnl
1230 AC_ARG_ENABLE(gdb-build-warnings,
1231 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1232 [case "${enableval}" in
1233   yes)  ;;
1234   no)   build_warnings="-w";;
1235   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1236         build_warnings="${build_warnings} ${t}";;
1237   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1238         build_warnings="${t} ${build_warnings}";;
1239   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1240 esac
1241 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1242   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1243 fi])dnl
1244 WARN_CFLAGS=""
1245 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1246 then
1247     AC_MSG_CHECKING(compiler warning flags)
1248     # Separate out the -Werror flag as some files just cannot be
1249     # compiled with it enabled.
1250     for w in ${build_warnings}; do
1251         case $w in
1252         -Werr*) WERROR_CFLAGS=-Werror ;;
1253         *) # Check that GCC accepts it
1254             saved_CFLAGS="$CFLAGS"
1255             CFLAGS="$CFLAGS $w"
1256             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1257             CFLAGS="$saved_CFLAGS"
1258         esac
1259     done
1260     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1261 fi
1262 AC_SUBST(WARN_CFLAGS)
1263 AC_SUBST(WERROR_CFLAGS)
1264
1265 # In the Cygwin environment, we need some additional flags.
1266 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1267 [AC_EGREP_CPP(lose, [
1268 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1269 lose
1270 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1271
1272
1273 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1274 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1275 case ${host} in
1276   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1277   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1278   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1279 esac
1280 AC_SUBST(SER_HARDWIRE)
1281
1282 # libreadline needs libuser32.a in a cygwin environment
1283 WIN32LIBS=
1284 if test x$gdb_cv_os_cygwin = xyes; then
1285     WIN32LIBS="-luser32"
1286     case "${target}" in
1287         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1288         ;;
1289     esac
1290 fi
1291
1292 # The ser-tcp.c module requires sockets.
1293 case ${host} in
1294   *mingw32*)
1295     AC_DEFINE(USE_WIN32API, 1,
1296               [Define if we should use the Windows API, instead of the
1297                POSIX API.  On Windows, we use the Windows API when
1298                building for MinGW, but the POSIX API when building
1299                for Cygwin.])
1300     WIN32LIBS="$WIN32LIBS -lws2_32"
1301     ;;
1302 esac
1303 AC_SUBST(WIN32LIBS)
1304
1305 # Add ELF support to GDB, but only if BFD includes ELF support.
1306 OLD_CFLAGS=$CFLAGS
1307 OLD_LDFLAGS=$LDFLAGS
1308 OLD_LIBS=$LIBS
1309 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1310 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1311 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1312 LIBS="$LIBS -lbfd -liberty $intl"
1313 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1314 [AC_TRY_LINK(
1315 [#include <stdlib.h>
1316 #include "bfd.h"
1317 #include "elf-bfd.h"
1318 ],
1319 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1320 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1321 if test $gdb_cv_var_elf = yes; then
1322   CONFIG_OBS="$CONFIG_OBS elfread.o"
1323   AC_DEFINE(HAVE_ELF, 1,
1324             [Define if ELF support should be included.])
1325 fi
1326 CFLAGS=$OLD_CFLAGS
1327 LDFLAGS=$OLD_LDFLAGS
1328 LIBS=$OLD_LIBS
1329
1330 # Add any host-specific objects to GDB.
1331 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1332
1333 LIBGUI="../libgui/src/libgui.a"
1334 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1335 AC_SUBST(LIBGUI)
1336 AC_SUBST(GUI_CFLAGS_X)
1337
1338 WIN32LDAPP=
1339 AC_SUBST(WIN32LIBS)
1340 AC_SUBST(WIN32LDAPP)
1341
1342 case "${host}" in
1343 *-*-cygwin*)
1344     configdir="win"
1345     ;;
1346 *)
1347     configdir="unix"
1348     ;;
1349 esac
1350
1351 GDBTKLIBS=
1352 if test "${enable_gdbtk}" = "yes"; then
1353
1354     # Gdbtk must have an absolute path to srcdir in order to run
1355     # properly when not installed.
1356     here=`pwd`
1357     cd ${srcdir}
1358     GDBTK_SRC_DIR=`pwd`
1359     cd $here
1360
1361     CY_AC_PATH_TCLCONFIG
1362     if test -z "${no_tcl}"; then
1363         CY_AC_LOAD_TCLCONFIG
1364         CY_AC_PATH_TKCONFIG
1365
1366         # now look for Tcl library stuff
1367
1368         tcldir="../tcl/${configdir}/"
1369
1370         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1371
1372         # If $no_tk is nonempty, then we can't do Tk, and there is no
1373         # point to doing Tcl.
1374         if test -z "${no_tk}"; then
1375            CY_AC_LOAD_TKCONFIG
1376            CY_AC_PATH_TCLH
1377            CY_AC_PATH_TKH
1378            CY_AC_PATH_ITCLH
1379            CY_AC_PATH_ITKH
1380
1381
1382            # now look for Tk library stuff
1383
1384            tkdir="../tk/${configdir}/"
1385
1386            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1387
1388            # now look for Itcl library stuff
1389
1390            CY_AC_PATH_ITCLCONFIG
1391            if test -z "${no_itcl}"; then
1392              CY_AC_LOAD_ITCLCONFIG
1393
1394              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1395              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1396            fi
1397
1398
1399            # now look for Itk library stuff
1400            CY_AC_PATH_ITKCONFIG
1401            if test -z "${no_itcl}"; then
1402              CY_AC_LOAD_ITKCONFIG
1403
1404              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1405              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1406            fi
1407
1408            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1409
1410            # Include some libraries that Tcl and Tk want.
1411            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1412            # Yes, the ordering seems wrong here.  But it isn't.
1413            # TK_LIBS is the list of libraries that need to be linked
1414            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1415            # were in LIBS then any link tests after this point would
1416            # try to include things like `$(LIBGUI)', which wouldn't work.
1417            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1418
1419            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1420            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1421            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1422            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1423            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1424            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1425            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1426
1427            if test x$gdb_cv_os_cygwin = xyes; then
1428               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1429               WIN32LDAPP="-Wl,--subsystem,console"
1430               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1431            fi
1432         fi
1433     fi
1434
1435     AC_CONFIG_SUBDIRS(gdbtk)
1436 fi
1437
1438 AC_SUBST(X_CFLAGS)
1439 AC_SUBST(X_LDFLAGS)
1440 AC_SUBST(X_LIBS)
1441 AC_SUBST(TCL_DEPS)
1442 AC_SUBST(TK_DEPS)
1443 AC_SUBST(ITCLLIB)
1444 AC_SUBST(ITCL_DEPS)
1445 AC_SUBST(ITKLIB)
1446 AC_SUBST(ITK_DEPS)
1447 AC_SUBST(GDBTKLIBS)
1448 AC_SUBST(GDBTK_CFLAGS)
1449 AC_SUBST(GDBTK_SRC_DIR)
1450
1451 AC_PATH_X
1452
1453 # Check whether we should enable the TUI, but only do so if we really
1454 # can.
1455 if test x"$enable_tui" = xyes; then
1456   if test -d $srcdir/tui; then
1457     if test "$ac_cv_search_waddstr" != no; then
1458       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1459       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1460       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1461       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1462       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1463       CONFIG_ALL="${CONFIG_ALL} all-tui"
1464       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1465       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1466       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1467     else
1468       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1469     fi
1470   fi
1471 fi
1472
1473 # Unlike the sim directory, whether a simulator is linked is controlled by
1474 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1475 # This code just checks for a few cases where we'd like to ignore those
1476 # definitions, even when they're present in the '.mt' file.  These cases
1477 # are when --disable-sim is specified, or if the simulator directory is
1478 # not part of the source tree.
1479 #
1480 AC_ARG_ENABLE(sim,
1481 [  --enable-sim            Link gdb with simulator],
1482 [echo "enable_sim = $enable_sim";
1483  echo "enableval = ${enableval}";
1484  case "${enableval}" in
1485   yes) ignore_sim=false ;;
1486   no)  ignore_sim=true ;;
1487   *)   ignore_sim=false ;;
1488  esac],
1489 [ignore_sim=false])
1490
1491 if test ! -d "${srcdir}/../sim"; then
1492   ignore_sim=true
1493 fi
1494
1495 if test "${ignore_sim}" = "true"; then
1496     IGNORE_SIM="SIM="
1497     IGNORE_SIM_OBS="SIM_OBS="
1498 else
1499     IGNORE_SIM=""
1500     IGNORE_SIM_OBS=""
1501     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1502 fi
1503 AC_SUBST(IGNORE_SIM)
1504 AC_SUBST(IGNORE_SIM_OBS)
1505
1506 AC_SUBST(ENABLE_CFLAGS)
1507 AC_SUBST(PROFILE_CFLAGS)
1508
1509 AC_SUBST(CONFIG_OBS)
1510 AC_SUBST(CONFIG_DEPS)
1511 AC_SUBST(CONFIG_SRCS)
1512 AC_SUBST(CONFIG_ALL)
1513 AC_SUBST(CONFIG_CLEAN)
1514 AC_SUBST(CONFIG_INSTALL)
1515 AC_SUBST(CONFIG_UNINSTALL)
1516
1517 # List of host floatformats.
1518 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1519 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1520 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1521
1522 # target_subdir is used by the testsuite to find the target libraries.
1523 target_subdir=
1524 if test "${host}" != "${target}"; then
1525     target_subdir="${target_alias}/"
1526 fi
1527 AC_SUBST(target_subdir)
1528
1529 frags=
1530 if test "${gdb_native}" = "yes"; then
1531   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1532   if test ! -f ${host_makefile_frag}; then
1533     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1534   fi
1535   frags="$frags $host_makefile_frag"
1536 else
1537   host_makefile_frag=/dev/null
1538 fi
1539
1540 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1541 if test ! -f ${target_makefile_frag}; then
1542   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1543 fi
1544 frags="$frags $target_makefile_frag"
1545
1546 AC_SUBST_FILE(host_makefile_frag)
1547 AC_SUBST_FILE(target_makefile_frag)
1548 AC_SUBST(frags)
1549
1550 changequote(,)dnl
1551 hostfile=`sed -n '
1552 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1553 ' ${host_makefile_frag}`
1554
1555 targetfile=`sed -n '
1556 s/^[    ]*DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1557 ' ${target_makefile_frag}`
1558
1559 if test "${gdb_native}" = "yes"; then
1560 # We pick this up from the host configuration file (.mh) because we
1561 # do not have a native configuration Makefile fragment.
1562 nativefile=`sed -n '
1563 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1564 ' ${host_makefile_frag}`
1565 fi
1566 changequote([,])
1567
1568 if test x"${gdb_osabi}" != x ; then
1569     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1570                        [Define to the default OS ABI for this configuration.])
1571 fi
1572
1573 # Enable multi-ice-gdb-server.
1574 AC_ARG_ENABLE(multi-ice,
1575 [  --enable-multi-ice      build the multi-ice-gdb-server],
1576   [case $enableval in
1577     yes | no)
1578       ;;
1579     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1580   esac])
1581 if test "x$enable_multi_ice" = xyes; then
1582    AC_CONFIG_SUBDIRS(multi-ice)
1583 fi
1584
1585 # We only build gdbserver automatically in a native configuration.
1586 if test "$gdb_native" = "yes"; then
1587   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1588   if test "x$build_gdbserver" = xyes; then
1589     AC_MSG_RESULT(yes)
1590     AC_CONFIG_SUBDIRS(gdbserver)
1591   else
1592     AC_MSG_RESULT(no)
1593   fi
1594 fi
1595
1596 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1597 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1598 # to an empty version.
1599
1600 files=
1601 links=
1602
1603 rm -f xm.h
1604 xm_h=""
1605 if test "${hostfile}" != ""; then
1606     xm_h=xm.h
1607     case "${hostfile}" in
1608       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1609       * ) GDB_XM_FILE="${hostfile}"
1610     esac
1611     files="${files} ${GDB_XM_FILE}"
1612     links="${links} xm.h"
1613     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}", [hostfile])
1614 fi
1615 AC_SUBST(xm_h)
1616
1617 rm -f tm.h
1618 tm_h=""
1619 if test "${targetfile}" != ""; then
1620     tm_h=tm.h
1621     case "${targetfile}" in
1622       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1623       * ) GDB_TM_FILE="${targetfile}"
1624     esac
1625     files="${files} ${GDB_TM_FILE}"
1626     links="${links} tm.h"
1627     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}", [targetfile])
1628 fi
1629 AC_SUBST(tm_h)
1630
1631 rm -f nm.h
1632 nm_h=""
1633 if test "${nativefile}" != ""; then
1634     nm_h=nm.h
1635     case "${nativefile}" in
1636       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1637       * ) GDB_NM_FILE="${nativefile}"
1638     esac
1639     files="${files} ${GDB_NM_FILE}"
1640     links="${links} nm.h"
1641     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1642 fi
1643 AC_SUBST(nm_h)
1644
1645 AC_LINK_FILES($files, $links)
1646
1647 dnl Check for exe extension set on certain hosts (e.g. Win32)
1648 AC_EXEEXT
1649
1650 dnl  Detect the character set used by this host.
1651
1652 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1653 dnl  superset of ASCII containing the characters needed for French,
1654 dnl  German, Spanish, Italian, and possibly others), but if were
1655 dnl  *were* to support any host character sets other than ISO-8859-1,
1656 dnl  here's where we'd detect it.
1657 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1658           [Define to be a string naming the default host character set.])
1659
1660 AM_ICONV
1661
1662 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1663 [
1664 dnl Autoconf doesn't provide a mechanism for modifying definitions
1665 dnl provided by makefile fragments.
1666 dnl
1667
1668 changequote(,)dnl
1669 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1670 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1671 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1672 mv -f Makefile.tmp Makefile
1673 changequote([,])dnl
1674
1675
1676 case x$CONFIG_HEADERS in
1677 xconfig.h:config.in)
1678 echo > stamp-h ;;
1679 esac
1680 ],
1681 [
1682 gdb_host_cpu=$gdb_host_cpu
1683 gdb_target_cpu=$gdb_target_cpu
1684 nativefile=$nativefile
1685 ])
1686
1687 exit 0