gcc/gengtype-lex.l

   1 /* -*- indented-text -*- */
   2 /* Process source files and output type information.
   3    Copyright (C) 2002 Free Software Foundation, Inc.
   4
   5 This file is part of GCC.
   6
   7 GCC is free software; you can redistribute it and/or modify it under
   8 the terms of the GNU General Public License as published by the Free
   9 Software Foundation; either version 2, or (at your option) any later
  10 version.
  11
  12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GCC; see the file COPYING.  If not, write to the Free
  19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 02111-1307, USA.  */
  21
  22 %{
  23 #define malloc xmalloc
  24 #define realloc xrealloc
  25
  26 #include "hconfig.h"
  27 #include "system.h"
  28 #include "gengtype.h"
  29 #include "gengtype-yacc.h"
  30
  31 #undef YY_USE_PROTOS
  32 #define YY_DECL int yylex ()
  33
  34 static void update_lineno PARAMS ((const char *l, size_t len));
  35
  36 struct fileloc lexer_line;
  37 int lexer_toplevel_done;
  38
  39 static void
  40 update_lineno (l, len)
  41      const char *l;
  42      size_t len;
  43 {
  44   while (len-- > 0)
  45     if (*l++ == '\n')
  46       lexer_line.line++;
  47 }
  48
  49 %}
  50
  51 ID      [[:alpha:]_][[:alnum:]_]*
  52 WS      [[:space:]]+
  53 IWORD   short|long|(un)?signed|char|int|HOST_WIDE_INT|bool|size_t
  54 ITYPE   {IWORD}({WS}{IWORD})*
  55
  56 %x in_struct in_struct_comment in_comment in_yacc_escape
  57 %option warn noyywrap nounput nodefault perf-report
  58 %option 8bit never-interactive
  59 %%
  60
  61 [^[:alnum:]_]typedef{WS}(struct|union){WS}{ID}{WS}?[*[:space:]]{WS}?{ID}{WS}?";" {
  62   char *tagstart;
  63   size_t taglen;
  64   char *namestart;
  65   size_t namelen;
  66   int is_pointer = 0;
  67   struct type *t;
  68   int union_p;
  69
  70   tagstart = yytext + strlen (" typedef ");
  71   while (ISSPACE (*tagstart))
  72     tagstart++;
  73   union_p = tagstart[0] == 'u';
  74   tagstart += strlen ("union ");
  75   while (ISSPACE (*tagstart))
  76     tagstart++;
  77   for (taglen = 1; ISIDNUM (tagstart[taglen]); taglen++)
  78     ;
  79   for (namestart = tagstart + taglen;
  80        ! ISIDNUM (*namestart);
  81        namestart++)
  82     if (*namestart == '*')
  83       is_pointer = 1;
  84   for (namelen = 1; ISIDNUM (namestart[namelen]); namelen++)
  85     ;
  86   t = find_structure (xmemdup (tagstart, taglen, taglen+1), union_p);
  87   if (is_pointer)
  88     t = create_pointer (t);
  89   do_typedef (xmemdup (namestart, namelen, namelen+1), t, &lexer_line);
  90   update_lineno (yytext, yyleng);
  91 }
  92
  93 [^[:alnum:]_]typedef{WS}{ITYPE}{WS}{ID}{WS}?";" {
  94
  95   char *namestart;
  96   size_t namelen;
  97   struct type *t;
  98   char *typestart;
  99   size_t typelen;
 100
 101   for (namestart = yytext + yyleng - 2; ISSPACE (*namestart); namestart--)
 102     ;
 103   for (namelen = 1; !ISSPACE (namestart[-namelen]); namelen++)
 104     ;
 105   namestart -= namelen - 1;
 106   for (typestart = yytext + strlen (" typedef ");
 107        ISSPACE(*typestart);
 108        typestart++)
 109     ;
 110   for (typelen = namestart - typestart;
 111        ISSPACE(typestart[typelen-1]);
 112        typelen--)
 113     ;
 114
 115   t = create_scalar_type (typestart, typelen);
 116   do_typedef (xmemdup (namestart, namelen, namelen+1), t, &lexer_line);
 117   update_lineno (yytext, yyleng);
 118 }
 119
 120 [^[:alnum:]_]typedef{WS}{ID}{WS}{ID}{WS}PARAMS {
 121   char *namestart;
 122   size_t namelen;
 123   struct type *t;
 124
 125   for (namestart = yytext + yyleng - 7; ISSPACE (*namestart); namestart--)
 126     ;
 127   for (namelen = 1; !ISSPACE (namestart[-namelen]); namelen++)
 128     ;
 129   namestart -= namelen - 1;
 130
 131   t = create_scalar_type ("function type", sizeof ("function type")-1);
 132   do_typedef (xmemdup (namestart, namelen, namelen+1), t, &lexer_line);
 133   update_lineno (yytext, yyleng);
 134 }
 135 [^[:alnum:]_]typedef{WS}{ID}{WS}?"("{WS}?"*"{WS}?{ID}{WS}?")"{WS}?PARAMS {
 136   char *namestart;
 137   size_t namelen;
 138   struct type *t;
 139
 140   for (namestart = yytext + yyleng - 7; !ISIDNUM (*namestart); namestart--)
 141     ;
 142   for (namelen = 1; ISIDNUM (namestart[-namelen]); namelen++)
 143     ;
 144   namestart -= namelen - 1;
 145
 146   t = create_scalar_type ("function type", sizeof ("function type")-1);
 147   do_typedef (xmemdup (namestart, namelen, namelen+1), t, &lexer_line);
 148   update_lineno (yytext, yyleng);
 149 }
 150
 151 [^[:alnum:]_](typedef{WS})?(struct|union){WS}{ID}{WS}/"GTY" {
 152   char *tagstart;
 153   size_t taglen;
 154   int typedef_p;
 155   int union_p;
 156
 157   typedef_p = yytext[1] == 't';
 158   if (typedef_p)
 159     for (tagstart = yytext + strlen (" typedef ");
 160          ISSPACE(*tagstart);
 161          tagstart++)
 162       ;
 163   else
 164     tagstart = yytext + 1;
 165
 166   union_p = tagstart[0] == 'u';
 167   tagstart += strlen ("union ");
 168   while (ISSPACE (*tagstart))
 169     tagstart++;
 170   for (taglen = 1; ISIDNUM (tagstart[taglen]); taglen++)
 171     ;
 172
 173   yylval.t = find_structure (xmemdup (tagstart, taglen, taglen + 1), union_p);
 174   BEGIN(in_struct);
 175   update_lineno (yytext, yyleng);
 176   return typedef_p ? ENT_TYPEDEF_STRUCT : ENT_STRUCT;
 177 }
 178
 179 [^[:alnum:]_](extern|static){WS}/"GTY" {
 180   BEGIN(in_struct);
 181   update_lineno (yytext, yyleng);
 182   return ENT_EXTERNSTATIC;
 183 }
 184
 185 ^"%union"{WS}"{"{WS}/"GTY" {
 186   BEGIN(in_struct);
 187   update_lineno (yytext, yyleng);
 188   return ENT_YACCUNION;
 189 }
 190
 191 <in_struct>{
 192
 193 "/*"                            { BEGIN(in_struct_comment); }
 194
 195 ^"%{"                           { BEGIN(in_yacc_escape); }
 196
 197 {WS}                            { update_lineno (yytext, yyleng); }
 198
 199 "const"/[^[:alnum:]_]           /* don't care */
 200
 201 "GTY"/[^[:alnum:]_]             { return GTY_TOKEN; }
 202 "union"/[^[:alnum:]_]           { return UNION; }
 203 "struct"/[^[:alnum:]_]          { return STRUCT; }
 204 "enum"/[^[:alnum:]_]            { return ENUM; }
 205 "ptr_alias"/[^[:alnum:]_]       { return ALIAS; }
 206 "param_is"/[^[:alnum:]_]        { return PARAM_IS; }
 207 [0-9]+                          { return NUM; }
 208
 209 {IWORD}({WS}{IWORD})*/[^[:alnum:]_]             |
 210 "ENUM_BITFIELD"{WS}?"("{WS}?{ID}{WS}?")"        {
 211   size_t len;
 212
 213   for (len = yyleng; ISSPACE (yytext[len-1]); len--)
 214     ;
 215
 216   yylval.t = create_scalar_type (yytext, len);
 217   update_lineno (yytext, yyleng);
 218   return SCALAR;
 219 }
 220
 221 {ID}/[^[:alnum:]_]              {
 222   yylval.s = xmemdup (yytext, yyleng, yyleng+1);
 223   return ID;
 224 }
 225
 226 \"([^"\\]|\\.)*\"               {
 227   yylval.s = xmemdup (yytext+1, yyleng-2, yyleng-1);
 228   return STRING;
 229 }
 230 "["[^\[\]]*"]"                  {
 231   yylval.s = xmemdup (yytext+1, yyleng-2, yyleng-1);
 232   return ARRAY;
 233 }
 234 ^"%"{ID}                        {
 235   yylval.s = xmemdup (yytext+1, yyleng-1, yyleng);
 236   return PERCENT_ID;
 237 }
 238 "'"("\\".|[^\\])"'"             {
 239   yylval.s = xmemdup (yytext+1, yyleng-2, yyleng);
 240   return CHAR;
 241 }
 242
 243 [(){},*:<>]                     { return yytext[0]; }
 244
 245 [;=]                            {
 246   if (lexer_toplevel_done)
 247     {
 248       BEGIN(INITIAL);
 249       lexer_toplevel_done = 0;
 250     }
 251   return yytext[0];
 252 }
 253
 254 ^"%%"                           {
 255   BEGIN(INITIAL);
 256   return PERCENTPERCENT;
 257 }
 258
 259 .                               {
 260   error_at_line (&lexer_line, "unexpected character `%s'", yytext);
 261 }
 262 }
 263
 264 "/*"                    { BEGIN(in_comment); }
 265 \n                      { lexer_line.line++; }
 266 {ID}                    |
 267 "'"("\\".|[^\\])"'"     |
 268 [^"/\n]                 /* do nothing */
 269 \"([^"\\]|\\.|\\\n)*\"  { update_lineno (yytext, yyleng); }
 270 "/"/[^*]                /* do nothing */
 271
 272 <in_comment,in_struct_comment>{
 273 \n              { lexer_line.line++; }
 274 [^*\n]{16}      |
 275 [^*\n]          /* do nothing */
 276 "*"/[^/]        /* do nothing */
 277 }
 278 <in_comment>"*/"        { BEGIN(INITIAL); }
 279 <in_struct_comment>"*/" { BEGIN(in_struct); }
 280
 281 <in_yacc_escape>{
 282 \n              { lexer_line.line++; }
 283 [^%]{16}        |
 284 [^%]            /* do nothing */
 285 "%"/[^}]        /* do nothing */
 286 "%}"            { BEGIN(in_struct); }
 287 "%"             {
 288   error_at_line (&lexer_line,
 289                  "unterminated %%{; unexpected EOF");
 290 }
 291 }
 292
 293
 294 ["/]                    |
 295 <in_struct_comment,in_comment>"*"       {
 296   error_at_line (&lexer_line,
 297                  "unterminated comment or string; unexpected EOF");
 298 }
 299
 300 %%
 301
 302 void
 303 yyerror (s)
 304      const char *s;
 305 {
 306   error_at_line (&lexer_line, s);
 307 }
 308
 309 void
 310 parse_file (fname)
 311       const char *fname;
 312 {
 313   yyin = fopen (fname, "r");
 314   lexer_line.file = fname;
 315   lexer_line.line = 1;
 316   if (yyin == NULL)
 317     {
 318       perror (fname);
 319       exit (1);
 320     }
 321   if (yyparse() != 0)
 322     exit (1);
 323   fclose (yyin);
 324 }