gcc/gengtype-lex.l

   1 /* -*- indented-text -*- */
   2 /* Process source files and output type information.
   3    Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   4
   5 This file is part of GCC.
   6
   7 GCC is free software; you can redistribute it and/or modify it under
   8 the terms of the GNU General Public License as published by the Free
   9 Software Foundation; either version 2, or (at your option) any later
  10 version.
  11
  12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GCC; see the file COPYING.  If not, write to the Free
  19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 02111-1307, USA.  */
  21
  22 %{
  23 #include "bconfig.h"
  24 #include "coretypes.h"
  25 #include "system.h"
  26
  27 #define malloc xmalloc
  28 #define realloc xrealloc
  29
  30 #include "gengtype.h"
  31 #include "gengtype-yacc.h"
  32
  33 #undef YY_USE_PROTOS
  34 #define YY_DECL int yylex ()
  35
  36 static void update_lineno (const char *l, size_t len);
  37
  38 struct fileloc lexer_line;
  39 int lexer_toplevel_done;
  40
  41 static void
  42 update_lineno (const char *l, size_t len)
  43 {
  44   while (len-- > 0)
  45     if (*l++ == '\n')
  46       lexer_line.line++;
  47 }
  48
  49 %}
  50
  51 ID      [[:alpha:]_][[:alnum:]_]*
  52 WS      [[:space:]]+
  53 IWORD   short|long|(un)?signed|char|int|HOST_WIDE_INT|bool|size_t|CHAR_BITFIELD
  54 ITYPE   {IWORD}({WS}{IWORD})*
  55
  56 %x in_struct in_struct_comment in_comment in_yacc_escape
  57 %option warn noyywrap nounput nodefault perf-report
  58 %option 8bit never-interactive
  59 %%
  60
  61 [^[:alnum:]_]typedef{WS}(struct|union){WS}{ID}{WS}?[*[:space:]]{WS}?{ID}{WS}?";" {
  62   char *tagstart;
  63   size_t taglen;
  64   char *namestart;
  65   size_t namelen;
  66   int is_pointer = 0;
  67   struct type *t;
  68   int union_p;
  69
  70   tagstart = yytext + strlen (" typedef ");
  71   while (ISSPACE (*tagstart))
  72     tagstart++;
  73   union_p = tagstart[0] == 'u';
  74   tagstart += strlen ("union ");
  75   while (ISSPACE (*tagstart))
  76     tagstart++;
  77   for (taglen = 1; ISIDNUM (tagstart[taglen]); taglen++)
  78     ;
  79   for (namestart = tagstart + taglen;
  80        ! ISIDNUM (*namestart);
  81        namestart++)
  82     if (*namestart == '*')
  83       is_pointer = 1;
  84   for (namelen = 1; ISIDNUM (namestart[namelen]); namelen++)
  85     ;
  86   t = find_structure (xmemdup (tagstart, taglen, taglen+1), union_p);
  87   if (is_pointer)
  88     t = create_pointer (t);
  89   do_typedef (xmemdup (namestart, namelen, namelen+1), t, &lexer_line);
  90   update_lineno (yytext, yyleng);
  91 }
  92
  93 [^[:alnum:]_]typedef{WS}{ITYPE}{WS}{ID}{WS}?";" {
  94
  95   char *namestart;
  96   size_t namelen;
  97   struct type *t;
  98   char *typestart;
  99   size_t typelen;
 100
 101   for (namestart = yytext + yyleng - 2; ISSPACE (*namestart); namestart--)
 102     ;
 103   for (namelen = 1; !ISSPACE (namestart[-namelen]); namelen++)
 104     ;
 105   namestart -= namelen - 1;
 106   for (typestart = yytext + strlen (" typedef ");
 107        ISSPACE(*typestart);
 108        typestart++)
 109     ;
 110   for (typelen = namestart - typestart;
 111        ISSPACE(typestart[typelen-1]);
 112        typelen--)
 113     ;
 114
 115   t = create_scalar_type (typestart, typelen);
 116   do_typedef (xmemdup (namestart, namelen, namelen+1), t, &lexer_line);
 117   update_lineno (yytext, yyleng);
 118 }
 119
 120 [^[:alnum:]_]typedef{WS}{ID}{WS}{ID}{WS}PARAMS {
 121   char *namestart;
 122   size_t namelen;
 123   struct type *t;
 124
 125   for (namestart = yytext + yyleng - 7; ISSPACE (*namestart); namestart--)
 126     ;
 127   for (namelen = 1; !ISSPACE (namestart[-namelen]); namelen++)
 128     ;
 129   namestart -= namelen - 1;
 130
 131   t = create_scalar_type ("function type", sizeof ("function type")-1);
 132   do_typedef (xmemdup (namestart, namelen, namelen+1), t, &lexer_line);
 133   update_lineno (yytext, yyleng);
 134 }
 135 [^[:alnum:]_]typedef{WS}{ID}{WS}?"("{WS}?"*"{WS}?{ID}{WS}?")"{WS}?PARAMS {
 136   char *namestart;
 137   size_t namelen;
 138   struct type *t;
 139
 140   for (namestart = yytext + yyleng - 7; !ISIDNUM (*namestart); namestart--)
 141     ;
 142   for (namelen = 1; ISIDNUM (namestart[-namelen]); namelen++)
 143     ;
 144   namestart -= namelen - 1;
 145
 146   t = create_scalar_type ("function type", sizeof ("function type")-1);
 147   do_typedef (xmemdup (namestart, namelen, namelen+1), t, &lexer_line);
 148   update_lineno (yytext, yyleng);
 149 }
 150
 151 [^[:alnum:]_](typedef{WS})?(struct|union){WS}{ID}{WS}/"GTY" {
 152   char *tagstart;
 153   size_t taglen;
 154   int typedef_p;
 155   int union_p;
 156
 157   typedef_p = yytext[1] == 't';
 158   if (typedef_p)
 159     for (tagstart = yytext + strlen (" typedef ");
 160          ISSPACE(*tagstart);
 161          tagstart++)
 162       ;
 163   else
 164     tagstart = yytext + 1;
 165
 166   union_p = tagstart[0] == 'u';
 167   tagstart += strlen ("union ");
 168   while (ISSPACE (*tagstart))
 169     tagstart++;
 170   for (taglen = 1; ISIDNUM (tagstart[taglen]); taglen++)
 171     ;
 172
 173   yylval.t = find_structure (xmemdup (tagstart, taglen, taglen + 1), union_p);
 174   BEGIN(in_struct);
 175   update_lineno (yytext, yyleng);
 176   return typedef_p ? ENT_TYPEDEF_STRUCT : ENT_STRUCT;
 177 }
 178
 179 [^[:alnum:]_](extern|static){WS}/"GTY" {
 180   BEGIN(in_struct);
 181   update_lineno (yytext, yyleng);
 182   return ENT_EXTERNSTATIC;
 183 }
 184
 185 ^"%union"{WS}"{"{WS}/"GTY" {
 186   BEGIN(in_struct);
 187   update_lineno (yytext, yyleng);
 188   return ENT_YACCUNION;
 189 }
 190
 191 <in_struct>{
 192
 193 "/*"                            { BEGIN(in_struct_comment); }
 194
 195 ^"%{"                           { BEGIN(in_yacc_escape); }
 196
 197 ^"@@".*                         /* Used for c-parse.in C/ObjC demarcation.  */
 198
 199 {WS}                            { update_lineno (yytext, yyleng); }
 200
 201 "const"/[^[:alnum:]_]           /* don't care */
 202
 203 "GTY"/[^[:alnum:]_]             { return GTY_TOKEN; }
 204 "union"/[^[:alnum:]_]           { return UNION; }
 205 "struct"/[^[:alnum:]_]          { return STRUCT; }
 206 "enum"/[^[:alnum:]_]            { return ENUM; }
 207 "ptr_alias"/[^[:alnum:]_]       { return ALIAS; }
 208 [0-9]+                          { return NUM; }
 209 "param"[0-9]*"_is"/[^[:alnum:]_]                {
 210   yylval.s = xmemdup (yytext, yyleng, yyleng+1);
 211   return PARAM_IS;
 212 }
 213
 214 {IWORD}({WS}{IWORD})*/[^[:alnum:]_]             |
 215 "ENUM_BITFIELD"{WS}?"("{WS}?{ID}{WS}?")"        {
 216   size_t len;
 217
 218   for (len = yyleng; ISSPACE (yytext[len-1]); len--)
 219     ;
 220
 221   yylval.t = create_scalar_type (yytext, len);
 222   update_lineno (yytext, yyleng);
 223   return SCALAR;
 224 }
 225
 226 {ID}/[^[:alnum:]_]              {
 227   yylval.s = xmemdup (yytext, yyleng, yyleng+1);
 228   return ID;
 229 }
 230
 231 \"([^"\\]|\\.)*\"               {
 232   yylval.s = xmemdup (yytext+1, yyleng-2, yyleng-1);
 233   return STRING;
 234 }
 235 "["[^\[\]]*"]"                  {
 236   yylval.s = xmemdup (yytext+1, yyleng-2, yyleng-1);
 237   return ARRAY;
 238 }
 239 ^"%"{ID}                        {
 240   yylval.s = xmemdup (yytext+1, yyleng-1, yyleng);
 241   return PERCENT_ID;
 242 }
 243 "'"("\\".|[^\\])"'"             {
 244   yylval.s = xmemdup (yytext+1, yyleng-2, yyleng);
 245   return CHAR;
 246 }
 247
 248 [(){},*:<>]                     { return yytext[0]; }
 249
 250 [;=]                            {
 251   if (lexer_toplevel_done)
 252     {
 253       BEGIN(INITIAL);
 254       lexer_toplevel_done = 0;
 255     }
 256   return yytext[0];
 257 }
 258
 259 ^"%%"                           {
 260   BEGIN(INITIAL);
 261   return PERCENTPERCENT;
 262 }
 263
 264 .                               {
 265   error_at_line (&lexer_line, "unexpected character `%s'", yytext);
 266 }
 267 }
 268
 269 "/*"                    { BEGIN(in_comment); }
 270 \n                      { lexer_line.line++; }
 271 {ID}                    |
 272 "'"("\\".|[^\\])"'"     |
 273 [^"/\n]                 /* do nothing */
 274 \"([^"\\]|\\.|\\\n)*\"  { update_lineno (yytext, yyleng); }
 275 "/"/[^*]                /* do nothing */
 276
 277 <in_comment,in_struct_comment>{
 278 \n              { lexer_line.line++; }
 279 [^*\n]{16}      |
 280 [^*\n]          /* do nothing */
 281 "*"/[^/]        /* do nothing */
 282 }
 283 <in_comment>"*/"        { BEGIN(INITIAL); }
 284 <in_struct_comment>"*/" { BEGIN(in_struct); }
 285
 286 <in_yacc_escape>{
 287 \n              { lexer_line.line++; }
 288 [^%]{16}        |
 289 [^%]            /* do nothing */
 290 "%"/[^}]        /* do nothing */
 291 "%}"            { BEGIN(in_struct); }
 292 "%"             {
 293   error_at_line (&lexer_line,
 294                  "unterminated %%{; unexpected EOF");
 295 }
 296 }
 297
 298
 299 ["/]                    |
 300 <in_struct_comment,in_comment>"*"       {
 301   error_at_line (&lexer_line,
 302                  "unterminated comment or string; unexpected EOF");
 303 }
 304
 305 %%
 306
 307 void
 308 yyerror (const char *s)
 309 {
 310   error_at_line (&lexer_line, s);
 311 }
 312
 313 void
 314 parse_file (const char *fname)
 315 {
 316   yyin = fopen (fname, "r");
 317   lexer_line.file = fname;
 318   lexer_line.line = 1;
 319   if (yyin == NULL)
 320     {
 321       perror (fname);
 322       exit (1);
 323     }
 324   if (yyparse() != 0)
 325     exit (1);
 326   fclose (yyin);
 327 }