gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 2, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to the Free
  20 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname)],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname)],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib       enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC
 277   --enable-threads=LIB    use LIB thread package for target GCC],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2           force the default debug format to be DWARF 2],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared        don't provide a shared libgcc],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Set program_transform_name
 339 AC_ARG_PROGRAM
 340
 341 # Find the native compiler
 342 AC_PROG_CC
 343 AC_PROG_CC_C_O
 344 # autoconf is lame and doesn't give us any substitution variable for this.
 345 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 346   NO_MINUS_C_MINUS_O=yes
 347 else
 348   OUTPUT_OPTION='-o $@'
 349 fi
 350 AC_SUBST(NO_MINUS_C_MINUS_O)
 351 AC_SUBST(OUTPUT_OPTION)
 352
 353 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 354 ac_cv_prog_cc_no_long_long,
 355 [save_CFLAGS="$CFLAGS"
 356 CFLAGS="-Wno-long-long"
 357 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 358                ac_cv_prog_cc_no_long_long=no)
 359 CFLAGS="$save_CFLAGS"])
 360 strict1_warn=
 361 if test $ac_cv_prog_cc_no_long_long = yes; then
 362   strict1_warn="-pedantic -Wno-long-long"
 363 fi
 364 AC_SUBST(strict1_warn)
 365
 366 AC_PROG_CPP
 367 AC_C_INLINE
 368 gcc_AC_C_VOLATILE
 369
 370 gcc_AC_C_LONG_DOUBLE
 371 gcc_AC_C_LONG_LONG
 372 gcc_AC_C__BOOL
 373
 374 # sizeof(char) is 1 by definition.
 375 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 376 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 377 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 378 if test $ac_cv_c_long_long = yes; then
 379   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 380 fi
 381 if test $ac_cv_c___int64 = yes; then
 382   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 383 fi
 384
 385 gcc_AC_C_CHARSET
 386
 387 # If the native compiler is GCC, we can enable warnings even in stage1.
 388 # That's useful for people building cross-compilers, or just running a
 389 # quick `make'.
 390 warn_cflags=
 391 if test "x$GCC" = "xyes"; then
 392   warn_cflags='$(GCC_WARN_CFLAGS)'
 393 fi
 394 AC_SUBST(warn_cflags)
 395
 396 # Stage specific cflags for build.
 397 stage1_cflags=
 398 case $build in
 399 vax-*-*)
 400   if test x$GCC = xyes
 401   then
 402     stage1_cflags="-Wa,-J"
 403   else
 404     stage1_cflags="-J"
 405   fi
 406   ;;
 407 esac
 408 AC_SUBST(stage1_cflags)
 409
 410 AC_PROG_MAKE_SET
 411
 412 AC_MSG_CHECKING([whether a default assembler was specified])
 413 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 414     if test x"$gas_flag" = x"no"; then
 415         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 416     else
 417         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 418     fi
 419 else
 420     AC_MSG_RESULT(no)
 421 fi
 422
 423 AC_MSG_CHECKING([whether a default linker was specified])
 424 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 425     if test x"$gnu_ld_flag" = x"no"; then
 426         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 427     else
 428         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 429     fi
 430 else
 431     AC_MSG_RESULT(no)
 432 fi
 433
 434 AC_MSG_CHECKING(for GNU C library)
 435 AC_CACHE_VAL(gcc_cv_glibc,
 436 [AC_TRY_COMPILE(
 437   [#include <features.h>],[
 438 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 439 #error Not a GNU C library system
 440 #endif],
 441   [gcc_cv_glibc=yes],
 442   gcc_cv_glibc=no)])
 443 AC_MSG_RESULT($gcc_cv_glibc)
 444 if test $gcc_cv_glibc = yes; then
 445   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 446 fi
 447
 448 # Find some useful tools
 449 AC_PROG_AWK
 450 gcc_AC_PROG_LN
 451 gcc_AC_PROG_LN_S
 452 AC_PROG_RANLIB
 453 gcc_AC_PROG_INSTALL
 454
 455 AC_HEADER_STDC
 456 AC_HEADER_TIME
 457 gcc_AC_HEADER_STDBOOL
 458 gcc_AC_HEADER_STRING
 459 AC_HEADER_SYS_WAIT
 460 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 461                  fcntl.h unistd.h sys/file.h sys/time.h \
 462                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 463                  direct.h malloc.h langinfo.h)
 464
 465 # Check for thread headers.
 466 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 467 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 468
 469 # These tests can't be done till we know if we have limits.h.
 470 gcc_AC_C_CHAR_BIT
 471 gcc_AC_C_COMPILE_ENDIAN
 472 gcc_AC_C_FLOAT_FORMAT
 473
 474 # See if GNAT has been installed
 475 gcc_AC_PROG_GNAT
 476
 477 # See if we have the mktemp command.
 478 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 479
 480 # Do we have a single-tree copy of texinfo?
 481 if test -f $srcdir/../texinfo/Makefile.in; then
 482   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 483   gcc_cv_prog_makeinfo_modern=yes
 484   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 485 else
 486   # See if makeinfo has been installed and is modern enough
 487   # that we can use it.
 488   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 489   [GNU texinfo.* \([0-9][0-9.]*\)],
 490   [4.*])
 491 fi
 492
 493 if test $gcc_cv_prog_makeinfo_modern = no; then
 494   AC_MSG_WARN([
 495 *** Makeinfo is missing or too old.
 496 *** Info documentation will not be built.])
 497   BUILD_INFO=
 498 else
 499   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 500 fi
 501
 502 # Is pod2man recent enough to regenerate manpages?
 503 AC_MSG_CHECKING([for recent Pod::Man])
 504 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 505   AC_MSG_RESULT(yes)
 506   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 507 else
 508   AC_MSG_RESULT(no)
 509   GENERATED_MANPAGES=
 510 fi
 511
 512 # How about lex?
 513 dnl Don't use AC_PROG_LEX; we insist on flex.
 514 dnl LEXLIB is not useful in gcc.
 515 if test -f $srcdir/../flex/skel.c; then
 516   FLEX='$(objdir)/../flex/flex'
 517 else
 518   AC_CHECK_PROG(FLEX, flex, flex, false)
 519 fi
 520
 521 # Bison?
 522 # The -L switch is so bison can find its skeleton file.
 523 if test -f $srcdir/../bison/bison.simple; then
 524   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 525 else
 526   AC_CHECK_PROG(BISON, bison, bison, false)
 527 fi
 528
 529 # These libraries may be used by collect2.
 530 # We may need a special search path to get them linked.
 531 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 532 [save_LIBS="$LIBS"
 533 for libs in '' -lld -lmld \
 534                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 535                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 536 do
 537         LIBS="$libs"
 538         AC_TRY_LINK_FUNC(ldopen,
 539                 [gcc_cv_collect2_libs="$libs"; break])
 540 done
 541 LIBS="$save_LIBS"
 542 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 543 case $gcc_cv_collect2_libs in
 544         "none required")        ;;
 545         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 546 esac
 547 AC_SUBST(COLLECT2_LIBS)
 548
 549 # When building Ada code on Alpha, we need exc_resume which is usually in
 550 # -lexc.  So test for it.
 551 save_LIBS="$LIBS"
 552 LIBS=
 553 AC_SEARCH_LIBS(exc_resume, exc)
 554 GNAT_LIBEXC="$LIBS"
 555 LIBS="$save_LIBS"
 556 AC_SUBST(GNAT_LIBEXC)
 557
 558 # See if the stage1 system preprocessor understands the ANSI C
 559 # preprocessor stringification operator.  (Used by symcat.h.)
 560 AC_C_STRINGIZE
 561
 562 # Use <inttypes.h> only if it exists,
 563 # doesn't clash with <sys/types.h>, and declares intmax_t.
 564 AC_MSG_CHECKING(for inttypes.h)
 565 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 566 [AC_TRY_COMPILE(
 567   [#include <sys/types.h>
 568 #include <inttypes.h>],
 569   [intmax_t i = -1;],
 570   [gcc_cv_header_inttypes_h=yes],
 571   gcc_cv_header_inttypes_h=no)])
 572 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 573 if test $gcc_cv_header_inttypes_h = yes; then
 574   AC_DEFINE(HAVE_INTTYPES_H, 1,
 575         [Define if you have a working <inttypes.h> header file.])
 576 fi
 577
 578 dnl Disabled until we have a complete test for buggy enum bitfields.
 579 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 580
 581 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 582         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 583         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo lstat)
 584
 585 AC_CHECK_TYPE(ssize_t, int)
 586
 587 # Try to determine the array type of the second argument of getgroups
 588 # for the target system (int or gid_t).
 589 AC_TYPE_GETGROUPS
 590 if test "${target}" = "${build}"; then
 591   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 592 else
 593   case "${target}" in
 594         # This condition may need some tweaking.  It should include all
 595         # targets where the array type of the second argument of getgroups
 596         # is int and the type of gid_t is not equivalent to int.
 597         *-*-sunos* | *-*-ultrix*)
 598                 TARGET_GETGROUPS_T=int
 599                 ;;
 600         *)
 601                 TARGET_GETGROUPS_T=gid_t
 602                 ;;
 603   esac
 604 fi
 605 AC_SUBST(TARGET_GETGROUPS_T)
 606
 607 gcc_AC_FUNC_PRINTF_PTR
 608
 609 case "${host}" in
 610 *-*-uwin*)
 611   AC_MSG_ERROR([
 612 *** UWIN may not be used as a host platform because
 613 *** linking with posix.dll is not allowed by the GNU GPL])
 614   ;;
 615 *-*-*vms*)
 616   # Under VMS, vfork works very different than on Unix. The standard test
 617   # won't work, and it isn't easily adaptable. It makes more sense to
 618   # just force it.
 619   ac_cv_func_vfork_works=yes
 620   ;;
 621 esac
 622 AC_FUNC_VFORK
 623 AC_FUNC_MMAP_ANYWHERE
 624 AC_FUNC_MMAP_FILE
 625
 626 AM_ICONV
 627
 628 # We will need to find libiberty.h and ansidecl.h
 629 saved_CFLAGS="$CFLAGS"
 630 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 631 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 632         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 633         fprintf_unlocked strstr environ errno \
 634         malloc realloc calloc free basename getopt clock, , ,[
 635 #include "ansidecl.h"
 636 #include "system.h"])
 637
 638 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 639 #include "ansidecl.h"
 640 #include "system.h"
 641 #ifdef HAVE_SYS_RESOURCE_H
 642 #include <sys/resource.h>
 643 #endif
 644 ])
 645
 646 gcc_AC_CHECK_DECLS(times, , ,[
 647 #include "ansidecl.h"
 648 #include "system.h"
 649 #ifdef HAVE_SYS_TIMES_H
 650 #include <sys/times.h>
 651 #endif
 652 ])
 653
 654 # More time-related stuff.
 655 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 656 AC_TRY_COMPILE([
 657 #include "ansidecl.h"
 658 #include "system.h"
 659 #ifdef HAVE_SYS_TIMES_H
 660 #include <sys/times.h>
 661 #endif
 662 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 663 if test $ac_cv_struct_tms = yes; then
 664   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 665   [Define if <sys/times.h> defines struct tms.])
 666 fi
 667
 668 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 669 # revisit after autoconf 2.50.
 670 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 671 AC_TRY_COMPILE([
 672 #include "ansidecl.h"
 673 #include "system.h"
 674 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 675 if test $gcc_cv_type_clock_t = yes; then
 676   AC_DEFINE(HAVE_CLOCK_T, 1,
 677   [Define if <time.h> defines clock_t.])
 678 fi
 679
 680 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 681 CFLAGS="$saved_CFLAGS"
 682
 683 # mkdir takes a single argument on some systems.
 684 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 685
 686 # File extensions
 687 manext='.1'
 688 objext='.o'
 689 AC_SUBST(manext)
 690 AC_SUBST(objext)
 691
 692 build_xm_file=
 693 build_xm_defines=
 694 build_install_headers_dir=install-headers-tar
 695 build_exeext=
 696 host_xm_file=
 697 host_xm_defines=
 698 host_xmake_file=
 699 host_truncate_target=
 700 host_exeext=
 701
 702 # Decode the host machine, then the target machine.
 703 # For the host machine, we save the xm_file variable as host_xm_file;
 704 # then we decode the target machine and forget everything else
 705 # that came from the host machine.
 706 for machine in $build $host $target; do
 707         . ${srcdir}/config.gcc
 708 done
 709
 710 extra_objs="${host_extra_objs} ${extra_objs}"
 711
 712 # Default the target-machine variables that were not explicitly set.
 713 if test x"$tm_file" = x
 714 then tm_file=$cpu_type/$cpu_type.h; fi
 715
 716 if test x"$extra_headers" = x
 717 then extra_headers=; fi
 718
 719 if test x$md_file = x
 720 then md_file=$cpu_type/$cpu_type.md; fi
 721
 722 if test x$out_file = x
 723 then out_file=$cpu_type/$cpu_type.c; fi
 724
 725 if test x"$tmake_file" = x
 726 then tmake_file=$cpu_type/t-$cpu_type
 727 fi
 728
 729 if test x"$dwarf2" = xyes
 730 then tm_file="$tm_file tm-dwarf2.h"
 731 fi
 732
 733 if test x$float_format = x
 734 then float_format=i64
 735 fi
 736
 737 if test $float_format = none
 738 then float_h_file=Makefile.in
 739 else float_h_file=float-$float_format.h
 740 fi
 741
 742 # Handle cpp installation.
 743 if test x$enable_cpp != xno
 744 then
 745   tmake_file="$tmake_file t-install-cpp"
 746 fi
 747
 748 # Say what files are being used for the output code and MD file.
 749 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 750 echo "Using \`$srcdir/config/$md_file' as machine description file."
 751
 752 # If any of the xm_file variables contain nonexistent files, warn
 753 # about them and drop them.
 754
 755 bx=
 756 for x in $build_xm_file; do
 757   if    test -f $srcdir/config/$x
 758   then      bx="$bx $x"
 759   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 760   fi
 761 done
 762 build_xm_file="$bx"
 763
 764 hx=
 765 for x in $host_xm_file; do
 766   if    test -f $srcdir/config/$x
 767   then      hx="$hx $x"
 768   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 769   fi
 770 done
 771 host_xm_file="$hx"
 772
 773 tx=
 774 for x in $xm_file; do
 775   if    test -f $srcdir/config/$x
 776   then      tx="$tx $x"
 777   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 778   fi
 779 done
 780 xm_file="$tx"
 781
 782 count=a
 783 for f in $tm_file; do
 784         count=${count}x
 785 done
 786 if test $count = ax; then
 787         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 788 else
 789         echo "Using the following target machine macro files:"
 790         for f in $tm_file; do
 791                 echo "  $srcdir/config/$f"
 792         done
 793 fi
 794
 795 count=a
 796 for f in $host_xm_file; do
 797         count=${count}x
 798 done
 799 if test $count = a; then
 800         :
 801 elif test $count = ax; then
 802         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 803 else
 804         echo "Using the following host machine macro files:"
 805         for f in $host_xm_file; do
 806                 echo "  $srcdir/config/$f"
 807         done
 808 fi
 809
 810 if test "$host_xm_file" != "$build_xm_file"; then
 811         count=a
 812         for f in $build_xm_file; do
 813                 count=${count}x
 814         done
 815         if test $count = a; then
 816                 :
 817         elif test $count = ax; then
 818                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 819         else
 820                 echo "Using the following build machine macro files:"
 821                 for f in $build_xm_file; do
 822                         echo "  $srcdir/config/$f"
 823                 done
 824         fi
 825 fi
 826
 827 if test x$thread_file = x; then
 828         if test x$target_thread_file != x; then
 829                 thread_file=$target_thread_file
 830         else
 831                 thread_file='single'
 832         fi
 833 fi
 834
 835 # auto-host.h is the file containing items generated by autoconf and is
 836 # the first file included by config.h.
 837 # If host=build, it is correct to have hconfig include auto-host.h
 838 # as well.  If host!=build, we are in error and need to do more
 839 # work to find out the build config parameters.
 840 if test x$host = x$build
 841 then
 842         build_auto=auto-host.h
 843         FORBUILD=..
 844 else
 845         # We create a subdir, then run autoconf in the subdir.
 846         # To prevent recursion we set host and build for the new
 847         # invocation of configure to the build for this invocation
 848         # of configure.
 849         tempdir=build.$$
 850         rm -rf $tempdir
 851         mkdir $tempdir
 852         cd $tempdir
 853         case ${srcdir} in
 854         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 855         *) realsrcdir=../${srcdir};;
 856         esac
 857         saved_CFLAGS="${CFLAGS}"
 858         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
 859         ${realsrcdir}/configure \
 860                 --target=$target --host=$build --build=$build
 861         CFLAGS="${saved_CFLAGS}"
 862
 863         # We just finished tests for the build machine, so rename
 864         # the file auto-build.h in the gcc directory.
 865         mv auto-host.h ../auto-build.h
 866         cd ..
 867         rm -rf $tempdir
 868         build_auto=auto-build.h
 869         FORBUILD=../$build
 870 fi
 871 AC_SUBST(FORBUILD)
 872
 873 tm_file="${tm_file} defaults.h"
 874 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 875 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 876 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 877
 878 # Truncate the target if necessary
 879 if test x$host_truncate_target != x; then
 880         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 881 fi
 882
 883 # Get the version trigger filename from the toplevel
 884 if test "${with_gcc_version_trigger+set}" = set; then
 885         gcc_version_trigger=$with_gcc_version_trigger
 886 else
 887         gcc_version_trigger=${srcdir}/version.c
 888 fi
 889 changequote(,)dnl
 890 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 891 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 892
 893 # Compile in configure arguments.
 894 if test -f configargs.h ; then
 895         # Being re-configured.
 896         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
 897         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 898 else
 899         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 900 fi
 901 cat > configargs.h <<EOF
 902 /* Generated automatically. */
 903 static const char configuration_arguments[] = "$gcc_config_arguments";
 904 static const char thread_model[] = "$thread_file";
 905 EOF
 906 changequote([,])dnl
 907
 908 # Internationalization
 909 PACKAGE=gcc
 910 VERSION="$gcc_version"
 911 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 912         [Define to the name of the distribution.])
 913 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 914         [Define to the version of the distribution.])
 915 AC_SUBST(PACKAGE)
 916 AC_SUBST(VERSION)
 917
 918 # Enable NLS support by default
 919 AC_ARG_ENABLE(nls,
 920   [  --enable-nls            use Native Language Support (default)],
 921   , enable_nls=yes)
 922
 923 # if cross compiling, disable NLS support.
 924 # It's not worth the trouble, at least for now.
 925
 926 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 927   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 928   enable_nls=no
 929 fi
 930
 931 AM_GNU_GETTEXT
 932
 933 # Windows32 Registry support for specifying GCC installation paths.
 934 AC_ARG_ENABLE(win32-registry,
 935 [  --disable-win32-registry
 936                           disable lookup of installation paths in the
 937                           Registry on Windows hosts
 938   --enable-win32-registry enable registry lookup (default)
 939   --enable-win32-registry=KEY
 940                           use KEY instead of GCC version as the last portion
 941                           of the registry key],,)
 942 case $host_os in
 943         win32 | pe | cygwin* | mingw32* | uwin*)
 944 AC_MSG_CHECKING(whether windows registry support is requested)
 945 if test "x$enable_win32_registry" != xno; then
 946   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 947 [Define to 1 if installation paths should be looked up in Windows32
 948    Registry. Ignored on non windows32 hosts.])
 949   AC_MSG_RESULT(yes)
 950   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 951 else
 952   AC_MSG_RESULT(no)
 953 fi
 954
 955 # Check if user specified a different registry key.
 956 case "x${enable_win32_registry}" in
 957 x | xyes)
 958   # default.
 959   gcc_cv_win32_registry_key="$VERSION"
 960   ;;
 961 xno)
 962   # no registry lookup.
 963   gcc_cv_win32_registry_key=''
 964   ;;
 965 *)
 966   # user-specified key.
 967   gcc_cv_win32_registry_key="$enable_win32_registry"
 968   ;;
 969 esac
 970
 971 if test "x$enable_win32_registry" != xno; then
 972   AC_MSG_CHECKING(registry key on windows hosts)
 973   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 974         [Define to be the last portion of registry key on windows hosts.])
 975   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 976 fi
 977 ;;
 978 esac
 979
 980 # Get an absolute path to the GCC top-level source directory
 981 holddir=`pwd`
 982 cd $srcdir
 983 topdir=`pwd`
 984 cd $holddir
 985
 986 # Conditionalize the makefile for this host machine.
 987 # Make-host contains the concatenation of all host makefile fragments
 988 # [there can be more than one].  This file is built by configure.frag.
 989 host_overrides=Make-host
 990 dep_host_xmake_file=
 991 for f in .. ${host_xmake_file}
 992 do
 993         if test -f ${srcdir}/config/$f
 994         then
 995                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 996         fi
 997 done
 998
 999 # Conditionalize the makefile for this target machine.
1000 # Make-target contains the concatenation of all host makefile fragments
1001 # [there can be more than one].  This file is built by configure.frag.
1002 target_overrides=Make-target
1003 dep_tmake_file=
1004 for f in .. ${tmake_file}
1005 do
1006         if test -f ${srcdir}/config/$f
1007         then
1008                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1009         fi
1010 done
1011
1012 # If the host doesn't support symlinks, modify CC in
1013 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1014 # Otherwise, we can use "CC=$(CC)".
1015 rm -f symtest.tem
1016 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1017 then
1018         cc_set_by_configure="\$(CC)"
1019         quoted_cc_set_by_configure="\$(CC)"
1020         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1021         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1022 else
1023         rm -f symtest.tem
1024         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1025         then
1026                 symbolic_link="cp -p"
1027         else
1028                 symbolic_link="cp"
1029         fi
1030         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1031         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1032         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1033         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1034 fi
1035 rm -f symtest.tem
1036
1037 out_object_file=`basename $out_file .c`.o
1038
1039 tm_file_list=
1040 for f in $tm_file; do
1041   case $f in
1042     ansidecl.h )
1043        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1044     defaults.h )
1045        tm_file_list="${tm_file_list} $f" ;;
1046     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1047   esac
1048 done
1049
1050 tm_p_file_list=
1051 for f in $tm_p_file; do
1052     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1053 done
1054
1055 host_xm_file_list=
1056 for f in $host_xm_file; do
1057   case $f in
1058     ansidecl.h )
1059        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1060     auto-host.h | defaults.h )
1061        host_xm_file_list="${host_xm_file_list} $f" ;;
1062     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1063   esac
1064 done
1065
1066 build_xm_file_list=
1067 for f in $build_xm_file; do
1068   case $f in
1069     ansidecl.h )
1070        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1071     auto-build.h | auto-host.h | defaults.h )
1072        build_xm_file_list="${build_xm_file_list} $f" ;;
1073     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1074   esac
1075 done
1076
1077 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1078 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1079 CROSS=                                          AC_SUBST(CROSS)
1080 ALL=all.internal                                AC_SUBST(ALL)
1081 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1082 if test x$host != x$target
1083 then
1084         CROSS="-DCROSS_COMPILE"
1085         ALL=all.cross
1086         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1087 fi
1088
1089 # If this is a cross-compiler that does not
1090 # have its own set of headers then define
1091 # inhibit_libc
1092
1093 # If this is using newlib, then define inhibit_libc in LIBGCC2_CFLAGS.
1094 # This prevents libgcc2 from containing any code which requires libc
1095 # support.
1096 inhibit_libc=
1097 if [test x$host != x$target] && [test x$with_headers = x]; then
1098        inhibit_libc=-Dinhibit_libc
1099 else
1100        if [test x$with_newlib = xyes]; then
1101                inhibit_libc=-Dinhibit_libc
1102        fi
1103 fi
1104 AC_SUBST(inhibit_libc)
1105
1106 # When building gcc with a cross-compiler, we need to adjust things so
1107 # that the generator programs are still built with the native compiler.
1108 # Also, we cannot run fixincludes or fix-header.
1109 # Note that the terminology here is wrong; it should be BUILD_* throughout.
1110 # FIXME.
1111
1112 # These are the normal (build=host) settings:
1113 HOST_PREFIX=                    AC_SUBST(HOST_PREFIX)
1114 HOST_PREFIX_1=ignore-           AC_SUBST(HOST_PREFIX_1)
1115 HOST_CC='$(CC)'                 AC_SUBST(HOST_CC)
1116 HOST_CFLAGS='$(ALL_CFLAGS)'     AC_SUBST(HOST_CFLAGS)
1117
1118 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1119 STMP_FIXPROTO=stmp-fixproto     AC_SUBST(STMP_FIXPROTO)
1120
1121 # And these apply if build != host.
1122 if test x$build != x$host
1123 then
1124     HOST_PREFIX=build-
1125     HOST_PREFIX_1=build-
1126     HOST_CC='$(CC_FOR_BUILD)'
1127     HOST_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD) $(XCFLAGS)'
1128
1129     STMP_FIXINC=
1130     STMP_FIXPROTO=
1131 fi
1132
1133 # Expand extra_headers to include complete path.
1134 # This substitutes for lots of t-* files.
1135 extra_headers_list=
1136 if test "x$extra_headers" = x
1137 then true
1138 else
1139         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1140         for file in $extra_headers;
1141         do
1142                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1143         done
1144 fi
1145
1146 if test x$use_collect2 = xno; then
1147         use_collect2=
1148 fi
1149
1150 # Add a definition of USE_COLLECT2 if system wants one.
1151 if test x$use_collect2 != x
1152 then
1153         host_xm_defines="${host_xm_defines} USE_COLLECT2"
1154         xm_defines="${xm_defines} USE_COLLECT2"
1155 fi
1156
1157 # If we have gas in the build tree, make a link to it.
1158 if test -f ../gas/Makefile; then
1159         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1160 fi
1161
1162 # If we have nm and objdump in the build tree, make a link to them.
1163 if test -f ../binutils/Makefile; then
1164         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1165         rm -f objdump; $symbolic_link ../binutils/objdump$host_exeext objdump$host_exeext 2>/dev/null
1166 fi
1167
1168 # If we have ld in the build tree, make a link to it.
1169 if test -f ../ld/Makefile; then
1170         rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1171 fi
1172
1173 # Figure out what assembler we will be using.
1174 AC_MSG_CHECKING(what assembler to use)
1175 gcc_cv_as=
1176 gcc_cv_gas_major_version=
1177 gcc_cv_gas_minor_version=
1178 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1179 gcc_cv_as_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1180 if test -x "$DEFAULT_ASSEMBLER"; then
1181         gcc_cv_as="$DEFAULT_ASSEMBLER"
1182 elif test -x "$AS"; then
1183         gcc_cv_as="$AS"
1184 elif test -x as$host_exeext; then
1185         # Build using assembler in the current directory.
1186         gcc_cv_as=./as$host_exeext
1187 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1188         # Single tree build which includes gas.
1189         for f in $gcc_cv_as_bfd_srcdir/configure $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1190         do
1191 changequote(,)dnl
1192                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1193 changequote([,])dnl
1194                 if test x$gcc_cv_gas_version != x; then
1195                         break
1196                 fi
1197         done
1198 changequote(,)dnl
1199         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1200         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1201 changequote([,])dnl
1202 fi
1203
1204 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1205         # Native build.
1206         # Search the same directories that the installed compiler will
1207         # search.  Else we may find the wrong assembler and lose.  If we
1208         # do not find a suitable assembler binary, then try the user's
1209         # path.
1210         #
1211         # Also note we have to check MD_EXEC_PREFIX before checking the
1212         # user's path.  Unfortunately, there is no good way to get at the
1213         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1214         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1215         # to be fixed as part of the make/configure rewrite too.
1216
1217         if test "x$exec_prefix" = xNONE; then
1218                 if test "x$prefix" = xNONE; then
1219                         test_prefix=/usr/local
1220                 else
1221                         test_prefix=$prefix
1222                 fi
1223         else
1224                 test_prefix=$exec_prefix
1225         fi
1226
1227         # If the loop below does not find an assembler, then use whatever
1228         # one we can find in the users's path.
1229         # user's path.
1230         gcc_cv_as=as$host_exeext
1231
1232         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1233                    $test_prefix/lib/gcc-lib/$target \
1234                    /usr/lib/gcc/$target/$gcc_version \
1235                    /usr/lib/gcc/$target \
1236                    $test_prefix/$target/bin/$target/$gcc_version \
1237                    $test_prefix/$target/bin \
1238                    /usr/libexec \
1239                    /usr/ccs/gcc \
1240                    /usr/ccs/bin \
1241                    /udk/usr/ccs/bin \
1242                    /bsd43/usr/lib/cmplrs/cc \
1243                    /usr/cross64/usr/bin \
1244                    /usr/lib/cmplrs/cc \
1245                    /sysv/usr/lib/cmplrs/cc \
1246                    /svr4/usr/lib/cmplrs/cc \
1247                    /usr/bin"
1248
1249         for dir in $test_dirs; do
1250                 if test -f $dir/as$host_exeext; then
1251                         gcc_cv_as=$dir/as$host_exeext
1252                         break;
1253                 fi
1254         done
1255 fi
1256 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1257   AC_MSG_RESULT("newly built gas")
1258 else
1259   AC_MSG_RESULT($gcc_cv_as)
1260 fi
1261
1262 # Figure out what linker we will be using.
1263 AC_MSG_CHECKING(what linker to use)
1264 gcc_cv_ld=
1265 gcc_cv_gld_major_version=
1266 gcc_cv_gld_minor_version=
1267 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1268 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1269 if test -x "$DEFAULT_LINKER"; then
1270         gcc_cv_ld="$DEFAULT_LINKER"
1271 elif test -x "$LD"; then
1272         gcc_cv_ld="$LD"
1273 elif test -x ld$host_exeext; then
1274         # Build using linker in the current directory.
1275         gcc_cv_ld=./ld$host_exeext
1276 elif test -f $gcc_cv_ld_gld_srcdir/configure.in -a -f ../ld/Makefile; then
1277         # Single tree build which includes ld.
1278         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1279         do
1280 changequote(,)dnl
1281                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1282 changequote([,])dnl
1283                 if test x$gcc_cv_gld_version != x; then
1284                         break
1285                 fi
1286         done
1287 changequote(,)dnl
1288         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1289         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1290 changequote([,])dnl
1291 fi
1292
1293 if test "x$gcc_cv_ld" = x -a x$host = x$target; then
1294         # Native build.
1295         # Search the same directories that the installed compiler will
1296         # search.  Else we may find the wrong linker and lose.  If we
1297         # do not find a suitable linker binary, then try the user's
1298         # path.
1299         #
1300         # Also note we have to check MD_EXEC_PREFIX before checking the
1301         # user's path.  Unfortunately, there is no good way to get at the
1302         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1303         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1304         # to be fixed as part of the make/configure rewrite too.
1305
1306         if test "x$exec_prefix" = xNONE; then
1307                 if test "x$prefix" = xNONE; then
1308                         test_prefix=/usr/local
1309                 else
1310                         test_prefix=$prefix
1311                 fi
1312         else
1313                 test_prefix=$exec_prefix
1314         fi
1315
1316         # If the loop below does not find an linker, then use whatever
1317         # one we can find in the users's path.
1318         # user's path.
1319         gcc_cv_ld=ld$host_exeext
1320
1321         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1322                    $test_prefix/lib/gcc-lib/$target \
1323                    /usr/lib/gcc/$target/$gcc_version \
1324                    /usr/lib/gcc/$target \
1325                    $test_prefix/$target/bin/$target/$gcc_version \
1326                    $test_prefix/$target/bin \
1327                    /usr/libexec \
1328                    /usr/ccs/gcc \
1329                    /usr/ccs/bin \
1330                    /udk/usr/ccs/bin \
1331                    /bsd43/usr/lib/cmplrs/cc \
1332                    /usr/cross64/usr/bin \
1333                    /usr/lib/cmplrs/cc \
1334                    /sysv/usr/lib/cmplrs/cc \
1335                    /svr4/usr/lib/cmplrs/cc \
1336                    /usr/bin"
1337
1338         for dir in $test_dirs; do
1339                 if test -f $dir/ld$host_exeext; then
1340                         gcc_cv_ld=$dir/ld$host_exeext
1341                         break;
1342                 fi
1343         done
1344 fi
1345 if test x$gcc_cv_gld_major_version != x -a x$gcc_cv_gld_minor_version != x; then
1346   AC_MSG_RESULT("newly built ld")
1347 else
1348   AC_MSG_RESULT($gcc_cv_ld)
1349 fi
1350
1351 # Figure out what nm we will be using.
1352 AC_MSG_CHECKING(what nm to use)
1353 if test -x nm$host_exeext; then
1354         gcc_cv_nm=./nm$host_exeext
1355 elif test x$host = x$target; then
1356         # Native build.
1357         gcc_cv_nm=nm$host_exeext
1358 fi
1359 AC_MSG_RESULT($gcc_cv_nm)
1360
1361 # Figure out what objdump we will be using.
1362 AC_MSG_CHECKING(what objdump to use)
1363 if test -x objdump$host_exeext; then
1364         gcc_cv_objdump=./objdump$host_exeext
1365 elif test x$host = x$target; then
1366         # Native build.
1367         gcc_cv_objdump=objdump$host_exeext
1368 fi
1369 AC_MSG_RESULT($gcc_cv_objdump)
1370
1371 # Figure out what assembler alignment features are present.
1372 AC_MSG_CHECKING(assembler alignment features)
1373 gcc_cv_as_alignment_features=none
1374 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1375         # Gas version 2.6 and later support for .balign and .p2align.
1376         # bytes to skip when using .p2align.
1377         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1378                 gcc_cv_as_alignment_features=".balign and .p2align"
1379                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1380         fi
1381         # Gas version 2.8 and later support specifying the maximum
1382         # bytes to skip when using .p2align.
1383         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1384                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1385                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1386         fi
1387 elif test x$gcc_cv_as != x; then
1388         # Check if we have .balign and .p2align
1389         echo ".balign  4" > conftest.s
1390         echo ".p2align  2" >> conftest.s
1391         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1392                 gcc_cv_as_alignment_features=".balign and .p2align"
1393                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1394         fi
1395         rm -f conftest.s conftest.o
1396         # Check if specifying the maximum bytes to skip when
1397         # using .p2align is supported.
1398         echo ".p2align 4,,7" > conftest.s
1399         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1400                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1401                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1402         fi
1403         rm -f conftest.s conftest.o
1404 fi
1405 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1406
1407 AC_MSG_CHECKING(assembler subsection support)
1408 gcc_cv_as_subsections=no
1409 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1410   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1411     gcc_cv_as_subsections="working .subsection -1"
1412   fi
1413 elif test x$gcc_cv_as != x; then
1414         # Check if we have .subsection
1415         echo ".subsection 1" > conftest.s
1416         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1417                 gcc_cv_as_subsections=".subsection"
1418                 if test x$gcc_cv_nm != x; then
1419                         cat > conftest.s <<EOF
1420 conftest_label1: .word 0
1421 .subsection -1
1422 conftest_label2: .word 0
1423 .previous
1424 EOF
1425                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1426                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1427                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1428                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1429                                         :
1430                                 else
1431                                         gcc_cv_as_subsections="working .subsection -1"
1432                                 fi
1433                         fi
1434                 fi
1435         fi
1436         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1437 fi
1438 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1439         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1440 [Define if your assembler supports .subsection and .subsection -1 starts
1441    emitting at the beginning of your section.])
1442 fi
1443 AC_MSG_RESULT($gcc_cv_as_subsections)
1444
1445 AC_MSG_CHECKING(assembler weak support)
1446 gcc_cv_as_weak=no
1447 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1448   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1449     gcc_cv_as_weak="yes"
1450   fi
1451 elif test x$gcc_cv_as != x; then
1452         # Check if we have .weak
1453         echo "  .weak foobar" > conftest.s
1454         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1455                 gcc_cv_as_weak="yes"
1456         fi
1457         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1458 fi
1459 if test x"$gcc_cv_as_weak" = xyes; then
1460         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1461 fi
1462 AC_MSG_RESULT($gcc_cv_as_weak)
1463
1464 AC_MSG_CHECKING(assembler hidden support)
1465 gcc_cv_as_hidden=no
1466 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1467   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1468     gcc_cv_as_hidden="yes"
1469   fi
1470 elif test x$gcc_cv_as != x; then
1471         # Check if we have .hidden
1472         echo "  .hidden foobar" > conftest.s
1473         echo "foobar:" >> conftest.s
1474         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1475                 gcc_cv_as_hidden="yes"
1476         fi
1477         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1478 fi
1479 if test x"$gcc_cv_as_hidden" = xyes; then
1480         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1481                 [Define if your assembler supports .hidden.])
1482 fi
1483 AC_MSG_RESULT($gcc_cv_as_hidden)
1484
1485 AC_MSG_CHECKING(assembler leb128 support)
1486 gcc_cv_as_leb128=no
1487 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1488   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1489     gcc_cv_as_leb128="yes"
1490   fi
1491 elif test x$gcc_cv_as != x; then
1492         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1493         cat > conftest.s <<EOF
1494         .data
1495         .uleb128 L2 - L1
1496 L1:
1497         .uleb128 1280
1498         .sleb128 -1010
1499 L2:
1500 EOF
1501         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1502                 gcc_cv_as_leb128="yes"
1503
1504                 # GAS versions before 2.11 do not support uleb128,
1505                 # despite appearing to.
1506                 # ??? There exists an elf-specific test that will crash
1507                 # the assembler.  Perhaps it's better to figure out whether
1508                 # arbitrary sections are supported and try the test.
1509                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1510                 if echo "$as_ver" | grep GNU > /dev/null; then
1511 changequote(,)dnl
1512                         as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1513                         as_major=`echo $as_ver | sed 's/\..*//'`
1514                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1515 changequote([,])dnl
1516                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1517                                 gcc_cv_as_leb128="no"
1518                         fi
1519                 fi
1520         fi
1521         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1522 fi
1523 if test x"$gcc_cv_as_leb128" = xyes; then
1524         AC_DEFINE(HAVE_AS_LEB128, 1,
1525                 [Define if your assembler supports .uleb128.])
1526 fi
1527 AC_MSG_RESULT($gcc_cv_as_leb128)
1528
1529 AC_MSG_CHECKING(assembler eh_frame optimization)
1530 gcc_cv_as_eh_frame=no
1531 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1532   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1533     gcc_cv_as_eh_frame="yes"
1534   fi
1535 elif test x$gcc_cv_as != x; then
1536         # Check if this is GAS.
1537         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1538         rm -f a.out 2> /dev/null
1539         if echo "$as_ver" | grep GNU > /dev/null; then
1540                 # Versions up to and including 2.11.0 may mis-optimize
1541                 # .eh_frame data.  Try something.
1542                 cat > conftest.s <<EOF
1543         .text
1544 .LFB1:
1545         .4byte  0
1546 .L1:
1547         .4byte  0
1548 .LFE1:
1549         .section        .eh_frame,"aw",@progbits
1550 __FRAME_BEGIN__:
1551         .4byte  .LECIE1-.LSCIE1
1552 .LSCIE1:
1553         .4byte  0x0
1554         .byte   0x1
1555         .ascii "z\0"
1556         .byte   0x1
1557         .byte   0x78
1558         .byte   0x1a
1559         .byte   0x0
1560         .byte   0x4
1561         .4byte  1
1562         .p2align 1
1563 .LECIE1:
1564 .LSFDE1:
1565         .4byte  .LEFDE1-.LASFDE1
1566 .LASFDE1:
1567         .4byte  .LASFDE1-__FRAME_BEGIN__
1568         .4byte  .LFB1
1569         .4byte  .LFE1-.LFB1
1570         .byte   0x4
1571         .4byte  .LFE1-.LFB1
1572         .byte   0x4
1573         .4byte  .L1-.LFB1
1574 .LEFDE1:
1575 EOF
1576                 cat > conftest.lit <<EOF
1577  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1578  0010 01000000 12000000 18000000 00000000  ................
1579  0020 08000000 04080000 0044               .........D
1580 EOF
1581                 cat > conftest.big <<EOF
1582  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1583  0010 00000001 00000012 00000018 00000000  ................
1584  0020 00000008 04000000 0844               .........D
1585 EOF
1586                 # If the assembler didn't choke, and we can objdump,
1587                 # and we got the correct data, then succeed.
1588                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1589                    && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1590                       | tail -3 > conftest.got \
1591                    && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1592                         || cmp conftest.big conftest.got > /dev/null 2>&1; }
1593                 then
1594                         gcc_cv_as_eh_frame="yes"
1595                 else
1596                         gcc_cv_as_eh_frame="bad"
1597                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
1598                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1599         [Define if your assembler mis-optimizes .eh_frame data.])
1600                         fi
1601                 fi
1602         fi
1603         rm -f conftest.*
1604 fi
1605 AC_MSG_RESULT($gcc_cv_as_eh_frame)
1606
1607 AC_MSG_CHECKING(assembler section merging support)
1608 gcc_cv_as_shf_merge=no
1609 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1610   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1611     gcc_cv_as_shf_merge=yes
1612   fi
1613 elif test x$gcc_cv_as != x; then
1614         # Check if we support SHF_MERGE sections
1615         echo '.section .rodata.str, "aMS", @progbits, 1' > conftest.s
1616         if $gcc_cv_as --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1; then
1617                 gcc_cv_as_shf_merge=yes
1618         fi
1619         rm -f conftest.s conftest.o
1620 fi
1621 if test x"$gcc_cv_as_shf_merge" = xyes; then
1622         AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1623 [Define if your assembler supports marking sections with SHF_MERGE flag.])
1624 fi
1625 AC_MSG_RESULT($gcc_cv_as_shf_merge)
1626
1627 case "$target" in
1628   # All TARGET_ABI_OSF targets.
1629   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
1630     AC_CACHE_CHECK([assembler supports explicit relocations],
1631         gcc_cv_as_explicit_relocs, [
1632         gcc_cv_as_explicit_relocs=unknown
1633         if test x$gcc_cv_gas_major_version != x \
1634                 -a x$gcc_cv_gas_minor_version != x
1635         then
1636            if test "$gcc_cv_gas_major_version" -eq 2 \
1637                    -a "$gcc_cv_gas_minor_version" -ge 12 \
1638                    -o "$gcc_cv_gas_major_version" -gt 2; then
1639               gcc_cv_as_explicit_relocs=yes
1640            fi
1641         elif test x$gcc_cv_as != x; then
1642             cat > conftest.s << 'EOF'
1643         .set nomacro
1644         .text
1645         extbl   $3, $2, $3      !lituse_bytoff!1
1646         ldq     $2, a($29)      !literal!1
1647         ldq     $4, b($29)      !literal!2
1648         ldq_u   $3, 0($2)       !lituse_base!1
1649         ldq     $27, f($29)     !literal!5
1650         jsr     $26, ($27), f   !lituse_jsr!5
1651         ldah    $29, 0($26)     !gpdisp!3
1652         lda     $0, c($29)      !gprel
1653         ldah    $1, d($29)      !gprelhigh
1654         lda     $1, d($1)       !gprellow
1655         lda     $29, 0($29)     !gpdisp!3
1656 EOF
1657             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1658                 gcc_cv_as_explicit_relocs=yes
1659             else
1660                 gcc_cv_as_explicit_relocs=no
1661             fi
1662             rm -f conftest.s conftest.o
1663         fi
1664     ])
1665     if test "x$gcc_cv_as_explicit_relocs" = xyes; then
1666         AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
1667                 [Define if your assembler supports explicit relocations.])
1668     fi
1669     ;;
1670   sparc*-*-*)
1671     AC_CACHE_CHECK([assembler .register pseudo-op support],
1672         gcc_cv_as_register_pseudo_op, [
1673         gcc_cv_as_register_pseudo_op=unknown
1674         if test x$gcc_cv_as != x; then
1675             # Check if we have .register
1676             echo ".register %g2, #scratch" > conftest.s
1677             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1678                 gcc_cv_as_register_pseudo_op=yes
1679             else
1680                 gcc_cv_as_register_pseudo_op=no
1681             fi
1682             rm -f conftest.s conftest.o
1683         fi
1684     ])
1685     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1686         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1687                 [Define if your assembler supports .register.])
1688     fi
1689
1690     AC_CACHE_CHECK([assembler supports -relax],
1691         gcc_cv_as_relax_opt, [
1692         gcc_cv_as_relax_opt=unknown
1693         if test x$gcc_cv_as != x; then
1694             # Check if gas supports -relax
1695             echo ".text" > conftest.s
1696             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1697                 gcc_cv_as_relax_opt=yes
1698             else
1699                 gcc_cv_as_relax_opt=no
1700             fi
1701             rm -f conftest.s conftest.o
1702         fi
1703     ])
1704     if test "x$gcc_cv_as_relax_opt" = xyes; then
1705         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1706                 [Define if your assembler supports -relax option.])
1707     fi
1708
1709     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
1710         gcc_cv_as_sparc_ua_pcrel, [
1711         gcc_cv_as_sparc_ua_pcrel=unknown
1712         if test x$gcc_cv_as != x -a x$gcc_cv_ld != x; then
1713             gcc_cv_as_sparc_ua_pcrel=no
1714             echo ".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo)" > conftest.s
1715             if $gcc_cv_as -K PIC -o conftest.o conftest.s > /dev/null 2>&1; then
1716                 if $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
1717                     gcc_cv_as_sparc_ua_pcrel=yes
1718                 fi
1719             fi
1720             rm -f conftest.s conftest.o conftest
1721         fi
1722     ])
1723     if test "x$gcc_cv_as_sparc_ua_pcrel" = xyes; then
1724         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
1725                 [Define if your assembler and linker support unaligned PC relative relocs.])
1726     fi
1727
1728     case "$tm_file" in
1729     *64*)
1730         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1731             gcc_cv_as_flags64, [
1732                 if test -n "$gcc_cv_as"; then
1733                     echo ".xword foo" > conftest.s
1734                     gcc_cv_as_flags64=no
1735                     for flag in "-xarch=v9" "-64 -Av9"; do
1736                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1737                             > /dev/null 2>&1; then
1738                             gcc_cv_as_flags64=$flag
1739                             break
1740                         fi
1741                     done
1742                     rm -f conftest.s conftest.o
1743                 else
1744                     if test "$gas" = yes; then
1745                         gcc_cv_as_flags64="-64 -Av9"
1746                     else
1747                         gcc_cv_as_flags64="-xarch=v9"
1748                     fi
1749                 fi
1750         ])
1751         if test "x$gcc_cv_as_flags64" = xno; then
1752 changequote(, )
1753             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1754             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1755 changequote([, ])
1756         else
1757             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1758                         [Define if the assembler supports 64bit sparc.])
1759         fi
1760         ;;
1761     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1762         ;;
1763     esac
1764
1765     if test "x$gcc_cv_as_flags64" != xno; then
1766         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1767             gcc_cv_as_offsetable_lo10, [
1768             gcc_cv_as_offsetable_lo10=unknown
1769             if test "x$gcc_cv_as" != x; then
1770                 # Check if assembler has offsetable %lo()
1771                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1772                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1773                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1774                         > /dev/null 2>&1 &&
1775                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1776                         > /dev/null 2>&1; then
1777                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1778                         gcc_cv_as_offsetable_lo10=no
1779                     else
1780                         gcc_cv_as_offsetable_lo10=yes
1781                     fi
1782                 else
1783                     gcc_cv_as_offsetable_lo10=no
1784                 fi
1785                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1786             fi
1787         ])
1788         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1789             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1790                 [Define if your assembler supports offsetable %lo().])
1791         fi
1792     fi
1793
1794     ;;
1795
1796 changequote(,)dnl
1797   i[34567]86-*-* | x86_64-*-*)
1798 changequote([,])dnl
1799     AC_MSG_CHECKING(assembler instructions)
1800     gcc_cv_as_instructions=
1801     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1802       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1803         gcc_cv_as_instructions="filds fists"
1804       fi
1805     elif test x$gcc_cv_as != x; then
1806         set "filds fists" "filds mem; fists mem"
1807         while test $# -gt 0
1808         do
1809                 echo "$2" > conftest.s
1810                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1811                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1812                 fi
1813                 shift 2
1814         done
1815         rm -f conftest.s conftest.o
1816     fi
1817     if test x"$gcc_cv_as_instructions" != x; then
1818         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1819     fi
1820     AC_MSG_RESULT($gcc_cv_as_instructions)
1821
1822     AC_MSG_CHECKING(assembler GOTOFF in data directives)
1823     gcc_cv_as_gotoff_in_data=no
1824     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x
1825     then
1826       if test "$gcc_cv_gas_major_version" -eq 2 \
1827          -a "$gcc_cv_gas_minor_version" -ge 11 \
1828          -o "$gcc_cv_gas_major_version" -gt 2; then
1829         gcc_cv_as_gotoff_in_data=yes
1830       fi
1831     elif test x$gcc_cv_as != x; then
1832         cat > conftest.s <<EOF
1833         .text
1834 .L0:
1835         nop
1836         .data
1837         .long .L0@GOTOFF
1838 EOF
1839         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1840           gcc_cv_as_gotoff_in_data=yes
1841         fi
1842     fi
1843     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
1844       [`if test $gcc_cv_as_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
1845       [Define true if the assembler supports '.long foo@GOTOFF'.])
1846     AC_MSG_RESULT($gcc_cv_as_gotoff_in_data)
1847     ;;
1848 esac
1849
1850 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1851 gcc_cv_as_dwarf2_debug_line=no
1852 # ??? Not all targets support dwarf2 debug_line, even within a version
1853 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1854 # info to the output file.  So, as supported targets are added to gas 2.11,
1855 # add some instruction here to (also) show we expect this might work.
1856 # ??? Once 2.11 is released, probably need to add first known working
1857 # version to the per-target configury.
1858 case "$target" in
1859   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* | x86_64*-*-*)
1860     insn="nop"
1861     ;;
1862   ia64*-*-*)
1863     insn="nop 0"
1864     ;;
1865   esac
1866 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1867 then
1868   if test "$gcc_cv_gas_major_version" -eq 2 \
1869         -a "$gcc_cv_gas_minor_version" -ge 11 \
1870         -o "$gcc_cv_gas_major_version" -gt 2 \
1871      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1872      && test x"$insn" != x ; then
1873     gcc_cv_as_dwarf2_debug_line="yes"
1874   fi
1875 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1876         echo '  .file 1 "conftest.s"' > conftest.s
1877         echo '  .loc 1 3 0' >> conftest.s
1878         echo "  $insn" >> conftest.s
1879         # ??? This fails with non-gnu grep.
1880         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1881            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1882                 # The .debug_line file table must be in the exact order that
1883                 # we specified the files, since these indices are also used
1884                 # by DW_AT_decl_file.  Approximate this test by testing if
1885                 # the assembler bitches if the same index is assigned twice.
1886                 echo '  .file 1 "foo.s"' > conftest.s
1887                 echo '  .file 1 "bar.s"' >> conftest.s
1888                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1889                 then
1890                   gcc_cv_as_dwarf2_debug_line="no"
1891                 else
1892                   gcc_cv_as_dwarf2_debug_line="yes"
1893                 fi
1894         fi
1895         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1896 fi
1897 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1898         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1899 [Define if your assembler supports dwarf2 .file/.loc directives,
1900    and preserves file table indices exactly as given.])
1901 fi
1902 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1903
1904 AC_MSG_CHECKING(assembler --gdwarf2 support)
1905 gcc_cv_as_gdwarf2_flag=no
1906 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1907 then
1908   if test "$gcc_cv_gas_major_version" -eq 2 \
1909         -a "$gcc_cv_gas_minor_version" -ge 11 \
1910         -o "$gcc_cv_gas_major_version" -gt 2 \
1911      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1912      && test x"$insn" != x ; then
1913     gcc_cv_as_gdwarf2_debug_flag="yes"
1914   fi
1915 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1916         echo '' > conftest.s
1917         # ??? This fails with non-gnu grep.
1918         if $gcc_cv_as --gdwarf2 -o conftest.o conftest.s > /dev/null 2>&1
1919           then
1920           gcc_cv_as_gdwarf2_flag="yes"
1921         fi
1922         rm -f conftest.s conftest.o
1923 fi
1924 if test x"$gcc_cv_as_gdwarf2_flag" = xyes; then
1925         AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
1926 [Define if your assembler supports the --gdwarf2 option.])
1927 fi
1928 AC_MSG_RESULT($gcc_cv_as_gdwarf2_flag)
1929
1930 AC_MSG_CHECKING(assembler --gstabs support)
1931 gcc_cv_as_gstabs_flag=no
1932 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1933 then
1934   if test "$gcc_cv_gas_major_version" -eq 2 \
1935         -a "$gcc_cv_gas_minor_version" -ge 11 \
1936         -o "$gcc_cv_gas_major_version" -gt 2 \
1937      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1938      && test x"$insn" != x ; then
1939     gcc_cv_as_gstabs_debug_flag="yes"
1940   fi
1941 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1942         echo '' > conftest.s
1943         # ??? This fails with non-gnu grep.
1944         if $gcc_cv_as --gstabs -o conftest.o conftest.s > /dev/null 2>&1 ; then
1945           gcc_cv_as_gstabs_flag="yes"
1946         fi
1947         rm -f conftest.s conftest.o
1948 fi
1949 if test x"$gcc_cv_as_gstabs_flag" = xyes; then
1950         AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
1951 [Define if your assembler supports the --gstabs option.])
1952 fi
1953 AC_MSG_RESULT($gcc_cv_as_gstabs_flag)
1954
1955 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
1956 gcc_cv_ld_eh_frame_hdr=no
1957 if test x$gcc_cv_gld_major_version != x -a x$gcc_cv_gld_minor_version != x; then
1958   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 && grep 'EMUL = elf' ../ld/Makefile > /dev/null; then
1959     gcc_cv_ld_eh_frame_hdr=yes
1960   fi
1961 elif test x$gcc_cv_ld != x; then
1962         # Check if linker supports --eh-frame-hdr option
1963         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
1964                 gcc_cv_ld_eh_frame_hdr=yes
1965         fi
1966 fi
1967 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
1968         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
1969 [Define if your linker supports --eh-frame-hdr option.])
1970 fi
1971 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
1972
1973 if test "$prefix" != "/usr" && test "$prefix" != "/usr/local" ; then
1974   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include")
1975 fi
1976
1977 # Figure out what language subdirectories are present.
1978 # Look if the user specified --enable-languages="..."; if not, use
1979 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1980 # go away some day.
1981 # NB:  embedded tabs in this IF block -- do not untabify
1982 if test x"${enable_languages+set}" != xset; then
1983         if test x"${LANGUAGES+set}" = xset; then
1984                 enable_languages="${LANGUAGES}"
1985                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
1986
1987         else
1988                 enable_languages=all
1989         fi
1990 else
1991         if test x"${enable_languages}" = x ||
1992            test x"${enable_languages}" = xyes;
1993         then
1994                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
1995         fi
1996 fi
1997 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
1998
1999 # First scan to see if an enabled language requires some other language.
2000 # We assume that a given config-lang.in will list all the language
2001 # front ends it requires, even if some are required indirectly.
2002 for lang in ${srcdir}/*/config-lang.in ..
2003 do
2004    case $lang in
2005     ..)
2006        ;;
2007     # The odd quoting in the next line works around
2008     # an apparent bug in bash 1.12 on linux.
2009 changequote(,)dnl
2010     ${srcdir}/[*]/config-lang.in)
2011        ;;
2012     *)
2013        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2014        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2015        for other in $this_lang_requires
2016        do
2017           case ,${enable_languages}, in
2018            *,$other,*)
2019               ;;
2020            *,all,*)
2021               ;;
2022            *,$lang_alias,*)
2023               enable_languages="$enable_languages,$other"
2024               ;;
2025           esac
2026        done
2027        ;;
2028 changequote([,])dnl
2029    esac
2030 done
2031
2032 subdirs=
2033 for lang in ${srcdir}/*/config-lang.in ..
2034 do
2035         case $lang in
2036         ..) ;;
2037         # The odd quoting in the next line works around
2038         # an apparent bug in bash 1.12 on linux.
2039 changequote(,)dnl
2040         ${srcdir}/[*]/config-lang.in) ;;
2041         *)
2042           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2043           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2044           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2045           if test "x$lang_alias" = x
2046           then
2047                 echo "$lang doesn't set \$language." 1>&2
2048                 exit 1
2049           fi
2050           case ${build_by_default},${enable_languages}, in
2051           *,$lang_alias,*) add_this_lang=yes ;;
2052           no,*) add_this_lang=no ;;
2053           *,all,*) add_this_lang=yes ;;
2054           *) add_this_lang=no ;;
2055           esac
2056           if test x"${add_this_lang}" = xyes; then
2057                 case $lang in
2058                     ${srcdir}/ada/config-lang.in)
2059                         if test x$have_gnat = xyes ; then
2060                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2061                         fi
2062                         ;;
2063                     *)
2064                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2065                         ;;
2066                 esac
2067           fi
2068           ;;
2069 changequote([,])dnl
2070         esac
2071 done
2072
2073 # Make gthr-default.h if we have a thread file.
2074 gthread_flags=
2075 if test $thread_file != single; then
2076     rm -f gthr-default.h
2077     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2078     gthread_flags=-DHAVE_GTHR_DEFAULT
2079 fi
2080 AC_SUBST(gthread_flags)
2081
2082 # Find out what GC implementation we want, or may, use.
2083 AC_ARG_WITH(gc,
2084 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2085                           with the compiler],
2086 [case "$withval" in
2087   simple | page)
2088     GGC=ggc-$withval
2089     ;;
2090   *)
2091     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2092     ;;
2093 esac],
2094 [GGC=ggc-page])
2095 AC_SUBST(GGC)
2096 echo "Using $GGC for garbage collection."
2097
2098 # Use the system's zlib library.
2099 zlibdir=-L../zlib
2100 zlibinc="-I\$(srcdir)/../zlib"
2101 AC_ARG_WITH(system-zlib,
2102 [  --with-system-zlib      use installed libz],
2103 zlibdir=
2104 zlibinc=
2105 )
2106 AC_SUBST(zlibdir)
2107 AC_SUBST(zlibinc)
2108
2109 dnl Very limited version of automake's enable-maintainer-mode
2110
2111 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2112   dnl maintainer-mode is disabled by default
2113   AC_ARG_ENABLE(maintainer-mode,
2114 [  --enable-maintainer-mode
2115                           enable make rules and dependencies not useful
2116                           (and sometimes confusing) to the casual installer],
2117       maintainer_mode=$enableval,
2118       maintainer_mode=no)
2119
2120 AC_MSG_RESULT($maintainer_mode)
2121
2122 if test "$maintainer_mode" = "yes"; then
2123   MAINT=''
2124 else
2125   MAINT='#'
2126 fi
2127 AC_SUBST(MAINT)dnl
2128
2129 # With Setjmp/Longjmp based exception handling.
2130 AC_ARG_ENABLE(sjlj-exceptions,
2131 [  --enable-sjlj-exceptions
2132                           arrange to use setjmp/longjmp exception handling],
2133 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
2134 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
2135   [Define 0/1 to force the choice for exception handling model.])])
2136
2137 # Make empty files to contain the specs and options for each language.
2138 # Then add #include lines to for a compiler that has specs and/or options.
2139
2140 lang_specs_files=
2141 lang_options_files=
2142 lang_tree_files=
2143 rm -f specs.h options.h gencheck.h
2144 touch specs.h options.h gencheck.h
2145 for subdir in . $subdirs
2146 do
2147         if test -f $srcdir/$subdir/lang-specs.h; then
2148                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
2149                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2150         fi
2151         if test -f $srcdir/$subdir/lang-options.h; then
2152                 echo "#include \"$subdir/lang-options.h\"" >>options.h
2153                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
2154         fi
2155         if test -f $srcdir/$subdir/$subdir-tree.def; then
2156                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
2157                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2158         fi
2159 done
2160
2161 # These (without "all_") are set in each config-lang.in.
2162 # `language' must be a single word so is spelled singularly.
2163 all_languages=
2164 all_boot_languages=
2165 all_compilers=
2166 all_stagestuff=
2167 all_outputs='Makefile intl/Makefile fixinc/Makefile gccbug mklibgcc'
2168 # List of language makefile fragments.
2169 all_lang_makefiles=
2170
2171 # Add the language fragments.
2172 # Languages are added via two mechanisms.  Some information must be
2173 # recorded in makefile variables, these are defined in config-lang.in.
2174 # We accumulate them and plug them into the main Makefile.
2175 # The other mechanism is a set of hooks for each of the main targets
2176 # like `clean', `install', etc.
2177
2178 language_fragments="Make-lang"
2179 language_hooks="Make-hooks"
2180
2181 for s in .. $subdirs
2182 do
2183         if test $s != ".."
2184         then
2185                 language=
2186                 boot_language=
2187                 compilers=
2188                 stagestuff=
2189                 outputs=
2190                 . ${srcdir}/$s/config-lang.in
2191                 if test "x$language" = x
2192                 then
2193                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2194                         exit 1
2195                 fi
2196                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
2197                 if test -f ${srcdir}/$s/Makefile.in
2198                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
2199                 fi
2200                 all_languages="$all_languages $language"
2201                 if test "x$boot_language" = xyes
2202                 then
2203                         all_boot_languages="$all_boot_languages $language"
2204                 fi
2205                 all_compilers="$all_compilers $compilers"
2206                 all_stagestuff="$all_stagestuff $stagestuff"
2207                 all_outputs="$all_outputs $outputs"
2208         fi
2209 done
2210
2211 check_languages=
2212 for language in .. $all_languages
2213 do
2214         if test $language != ".."
2215         then
2216                 check_languages="$check_languages check-$language"
2217         fi
2218 done
2219
2220 # Since we can't use `::' targets, we link each language in
2221 # with a set of hooks, reached indirectly via lang.${target}.
2222
2223 rm -f Make-hooks
2224 touch Make-hooks
2225 target_list="all.build all.cross start.encap rest.encap \
2226         info dvi generated-manpages \
2227         install-normal install-common install-info install-man \
2228         uninstall \
2229         mostlyclean clean distclean extraclean maintainer-clean \
2230         stage1 stage2 stage3 stage4"
2231 for t in $target_list
2232 do
2233         x=
2234         for lang in .. $all_languages
2235         do
2236                 if test $lang != ".."; then
2237                         x="$x $lang.$t"
2238                 fi
2239         done
2240         echo "lang.$t: $x" >> Make-hooks
2241 done
2242
2243 # Create .gdbinit.
2244
2245 echo "dir ." > .gdbinit
2246 echo "dir ${srcdir}" >> .gdbinit
2247 if test x$gdb_needs_out_file_path = xyes
2248 then
2249         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2250 fi
2251 if test "x$subdirs" != x; then
2252         for s in $subdirs
2253         do
2254                 echo "dir ${srcdir}/$s" >> .gdbinit
2255         done
2256 fi
2257 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2258
2259 # Define variables host_canonical and build_canonical
2260 # because some Cygnus local changes in the Makefile depend on them.
2261 build_canonical=${build}
2262 host_canonical=${host}
2263 target_subdir=
2264 if test "${host}" != "${target}" ; then
2265     target_subdir=${target_alias}/
2266 fi
2267 AC_SUBST(build_canonical)
2268 AC_SUBST(host_canonical)
2269 AC_SUBST(target_subdir)
2270
2271 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2272 # absolute path for gcc_tooldir based on inserting the number of up-directory
2273 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2274 # $(libsubdir)/@(unlibsubdir) based path.
2275 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2276 # make and thus we'd get different behavior depending on where we built the
2277 # sources.
2278 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2279     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2280 else
2281 changequote(<<, >>)dnl
2282 # An explanation of the sed strings:
2283 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2284 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2285 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2286 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2287 #
2288 # (*) Note this pattern overwrites the first character of the string
2289 # with a forward slash if one is not already present.  This is not a
2290 # problem because the exact names of the sub-directories concerned is
2291 # unimportant, just the number of them matters.
2292 #
2293 # The practical upshot of these patterns is like this:
2294 #
2295 #  prefix     exec_prefix        result
2296 #  ------     -----------        ------
2297 #   /foo        /foo/bar          ../
2298 #   /foo/       /foo/bar          ../
2299 #   /foo        /foo/bar/         ../
2300 #   /foo/       /foo/bar/         ../
2301 #   /foo        /foo/bar/ugg      ../../
2302 #
2303     dollar='$$'
2304     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2305 changequote([, ])dnl
2306 fi
2307 AC_SUBST(gcc_tooldir)
2308 AC_SUBST(dollar)
2309
2310 # Find a directory in which to install a shared libgcc.
2311
2312 AC_ARG_ENABLE(version-specific-runtime-libs,
2313 [  --enable-version-specific-runtime-libs
2314                           specify that runtime libraries should be
2315                           installed in a compiler-specific directory])
2316
2317 AC_ARG_WITH(slibdir,
2318 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2319 slibdir="$with_slibdir",
2320 if test "${enable_version_specific_runtime_libs+set}" = set; then
2321   slibdir='$(libsubdir)'
2322 elif test "$host" != "$target"; then
2323   slibdir='$(build_tooldir)/lib'
2324 else
2325   slibdir='$(libdir)'
2326 fi)
2327 AC_SUBST(slibdir)
2328
2329 # Nothing to do for FLOAT_H, float_format already handled.
2330 objdir=`pwd`
2331 AC_SUBST(objdir)
2332
2333 # Process the language and host/target makefile fragments.
2334 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
2335
2336 # Substitute configuration variables
2337 AC_SUBST(subdirs)
2338 AC_SUBST(all_boot_languages)
2339 AC_SUBST(all_compilers)
2340 AC_SUBST(all_lang_makefiles)
2341 AC_SUBST(all_languages)
2342 AC_SUBST(all_stagestuff)
2343 AC_SUBST(build_exeext)
2344 AC_SUBST(build_install_headers_dir)
2345 AC_SUBST(build_xm_file_list)
2346 AC_SUBST(build_xm_file)
2347 AC_SUBST(build_xm_defines)
2348 AC_SUBST(check_languages)
2349 AC_SUBST(cc_set_by_configure)
2350 AC_SUBST(quoted_cc_set_by_configure)
2351 AC_SUBST(cpp_install_dir)
2352 AC_SUBST(dep_host_xmake_file)
2353 AC_SUBST(dep_tmake_file)
2354 AC_SUBST(extra_headers_list)
2355 AC_SUBST(extra_objs)
2356 AC_SUBST(extra_parts)
2357 AC_SUBST(extra_passes)
2358 AC_SUBST(extra_programs)
2359 AC_SUBST(float_h_file)
2360 AC_SUBST(gcc_config_arguments)
2361 AC_SUBST(gcc_gxx_include_dir)
2362 AC_SUBST(libstdcxx_incdir)
2363 AC_SUBST(gcc_version)
2364 AC_SUBST(gcc_version_full)
2365 AC_SUBST(gcc_version_trigger)
2366 AC_SUBST(host_exeext)
2367 AC_SUBST(host_extra_gcc_objs)
2368 AC_SUBST(host_xm_file_list)
2369 AC_SUBST(host_xm_file)
2370 AC_SUBST(host_xm_defines)
2371 AC_SUBST(install)
2372 AC_SUBST(lang_options_files)
2373 AC_SUBST(lang_specs_files)
2374 AC_SUBST(lang_tree_files)
2375 AC_SUBST(local_prefix)
2376 AC_SUBST(md_file)
2377 AC_SUBST(objc_boehm_gc)
2378 AC_SUBST(out_file)
2379 AC_SUBST(out_object_file)
2380 AC_SUBST(stage_prefix_set_by_configure)
2381 AC_SUBST(quoted_stage_prefix_set_by_configure)
2382 AC_SUBST(symbolic_link)
2383 AC_SUBST(thread_file)
2384 AC_SUBST(tm_file_list)
2385 AC_SUBST(tm_file)
2386 AC_SUBST(tm_p_file_list)
2387 AC_SUBST(tm_p_file)
2388 AC_SUBST(xm_file)
2389 AC_SUBST(xm_defines)
2390 AC_SUBST(target_alias)
2391 AC_SUBST(c_target_objs)
2392 AC_SUBST(cxx_target_objs)
2393 AC_SUBST(target_cpu_default)
2394
2395 AC_SUBST_FILE(target_overrides)
2396 AC_SUBST_FILE(host_overrides)
2397 AC_SUBST_FILE(language_fragments)
2398 AC_SUBST_FILE(language_hooks)
2399
2400 # Echo that links are built
2401 if test x$host = x$target
2402 then
2403         str1="native "
2404 else
2405         str1="cross-"
2406         str2=" from $host"
2407 fi
2408
2409 if test x$host != x$build
2410 then
2411         str3=" on a $build system"
2412 fi
2413
2414 if test "x$str2" != x || test "x$str3" != x
2415 then
2416         str4=
2417 fi
2418
2419 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2420
2421 if test "x$str2" != x || test "x$str3" != x
2422 then
2423         echo " ${str2}${str3}." 1>&2
2424 fi
2425
2426 # Truncate the target if necessary
2427 if test x$host_truncate_target != x; then
2428         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2429 fi
2430
2431 # Configure the subdirectories
2432 # AC_CONFIG_SUBDIRS($subdirs)
2433
2434 # Create the Makefile
2435 # and configure language subdirectories
2436 AC_OUTPUT($all_outputs,
2437 [
2438 case x$CONFIG_HEADERS in
2439 xauto-host.h:config.in)
2440 echo > cstamp-h ;;
2441 esac
2442 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2443 # bootstrapping and the installation procedure can still use
2444 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2445 # FLAGS_TO_PASS has been modified to solve the problem there.
2446 # This is virtually a duplicate of what happens in configure.lang; we do
2447 # an extra check to make sure this only happens if ln -s can be used.
2448 if test "$symbolic_link" = "ln -s"; then
2449  for d in .. ${subdirs} fixinc ; do
2450    if test $d != ..; then
2451         STARTDIR=`pwd`
2452         cd $d
2453         for t in stage1 stage2 stage3 stage4 include
2454         do
2455                 rm -f $t
2456                 $symbolic_link ../$t $t 2>/dev/null
2457         done
2458         cd $STARTDIR
2459    fi
2460  done
2461 else true ; fi
2462 # Avoid having to add intl to our include paths.
2463 if test -f intl/libintl.h; then
2464   echo creating libintl.h
2465   echo '#include "intl/libintl.h"' >libintl.h
2466 fi
2467 ],
2468 [
2469 host='${host}'
2470 build='${build}'
2471 target='${target}'
2472 target_alias='${target_alias}'
2473 srcdir='${srcdir}'
2474 subdirs='${subdirs}'
2475 symbolic_link='${symbolic_link}'
2476 program_transform_set='${program_transform_set}'
2477 program_transform_name='${program_transform_name}'
2478 dep_host_xmake_file='${dep_host_xmake_file}'
2479 host_xmake_file='${host_xmake_file}'
2480 dep_tmake_file='${dep_tmake_file}'
2481 tmake_file='${tmake_file}'
2482 thread_file='${thread_file}'
2483 gcc_config_arguments='${gcc_config_arguments}'
2484 gcc_version='${gcc_version}'
2485 gcc_version_full='${gcc_version_full}'
2486 gcc_version_trigger='${gcc_version_trigger}'
2487 local_prefix='${local_prefix}'
2488 build_install_headers_dir='${build_install_headers_dir}'
2489 build_exeext='${build_exeext}'
2490 host_exeext='${host_exeext}'
2491 out_file='${out_file}'
2492 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2493 SET_MAKE='${SET_MAKE}'
2494 target_list='${target_list}'
2495 target_overrides='${target_overrides}'
2496 host_overrides='${host_overrides}'
2497 cpp_install_dir='${cpp_install_dir}'
2498 ])