gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.13)
  29 AC_INIT(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 # Determine the host, build, and target systems
  33 AC_CANONICAL_SYSTEM
  34
  35 # Determine the target- and build-specific subdirectories
  36 GCC_TOPLEV_SUBDIRS
  37
  38 # Set program_transform_name
  39 AC_ARG_PROGRAM
  40
  41 # Check for bogus environment variables.
  42 # Test if LIBRARY_PATH contains the notation for the current directory
  43 # since this would lead to problems installing/building glibc.
  44 # LIBRARY_PATH contains the current directory if one of the following
  45 # is true:
  46 # - one of the terminals (":" and ";") is the first or last sign
  47 # - two terminals occur directly after each other
  48 # - the path contains an element with a dot in it
  49 AC_MSG_CHECKING(LIBRARY_PATH variable)
  50 changequote(,)dnl
  51 case ${LIBRARY_PATH} in
  52   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  53     library_path_setting="contains current directory"
  54     ;;
  55   *)
  56     library_path_setting="ok"
  57     ;;
  58 esac
  59 changequote([,])dnl
  60 AC_MSG_RESULT($library_path_setting)
  61 if test "$library_path_setting" != "ok"; then
  62 AC_MSG_ERROR([
  63 *** LIBRARY_PATH shouldn't contain the current directory when
  64 *** building gcc. Please change the environment variable
  65 *** and run configure again.])
  66 fi
  67
  68 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  69 # since this would lead to problems installing/building glibc.
  70 # GCC_EXEC_PREFIX contains the current directory if one of the following
  71 # is true:
  72 # - one of the terminals (":" and ";") is the first or last sign
  73 # - two terminals occur directly after each other
  74 # - the path contains an element with a dot in it
  75 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  76 changequote(,)dnl
  77 case ${GCC_EXEC_PREFIX} in
  78   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  79     gcc_exec_prefix_setting="contains current directory"
  80     ;;
  81   *)
  82     gcc_exec_prefix_setting="ok"
  83     ;;
  84 esac
  85 changequote([,])dnl
  86 AC_MSG_RESULT($gcc_exec_prefix_setting)
  87 if test "$gcc_exec_prefix_setting" != "ok"; then
  88 AC_MSG_ERROR([
  89 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  90 *** building gcc. Please change the environment variable
  91 *** and run configure again.])
  92 fi
  93
  94 # -----------
  95 # Directories
  96 # -----------
  97
  98 # Specify the local prefix
  99 local_prefix=
 100 AC_ARG_WITH(local-prefix,
 101 [  --with-local-prefix=DIR specifies directory to put local include],
 102 [case "${withval}" in
 103 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 104 no)     ;;
 105 *)      local_prefix=$with_local_prefix ;;
 106 esac])
 107
 108 # Default local prefix if it is empty
 109 if test x$local_prefix = x; then
 110         local_prefix=/usr/local
 111 fi
 112
 113 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 114 # passed in by the toplevel make and thus we'd get different behavior
 115 # depending on where we built the sources.
 116 gcc_gxx_include_dir=
 117 # Specify the g++ header file directory
 118 AC_ARG_WITH(gxx-include-dir,
 119 [  --with-gxx-include-dir=DIR
 120                           specifies directory to put g++ header files],
 121 [case "${withval}" in
 122 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 123 no)     ;;
 124 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 125 esac])
 126
 127 if test x${gcc_gxx_include_dir} = x; then
 128   if test x${enable_version_specific_runtime_libs} = xyes; then
 129     gcc_gxx_include_dir='${libsubdir}/include/c++'
 130   else
 131     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 132 changequote(<<, >>)dnl
 133     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 134 changequote([, ])dnl
 135   fi
 136 fi
 137
 138 AC_ARG_WITH(cpp_install_dir,
 139 [  --with-cpp-install-dir=DIR
 140                           install the user visible C preprocessor in DIR
 141                           (relative to PREFIX) as well as PREFIX/bin],
 142 [if test x$withval = xyes; then
 143   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 144 elif test x$withval != xno; then
 145   cpp_install_dir=$withval
 146 fi])
 147
 148 # -------------------
 149 # Find default linker
 150 # -------------------
 151
 152 # With GNU ld
 153 AC_ARG_WITH(gnu-ld,
 154 [  --with-gnu-ld           arrange to work with GNU ld.],
 155 gnu_ld_flag="$with_gnu_ld",
 156 gnu_ld_flag=no)
 157
 158 # With pre-defined ld
 159 AC_ARG_WITH(ld,
 160 [  --with-ld               arrange to use the specified ld (full pathname)],
 161 DEFAULT_LINKER="$with_ld")
 162 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 163   if test ! -x "$DEFAULT_LINKER"; then
 164     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 165   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 166     gnu_ld_flag=yes
 167   fi
 168   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 169         [Define to enable the use of a default linker.])
 170 fi
 171
 172 AC_MSG_CHECKING([whether a default linker was specified])
 173 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 174   if test x"$gnu_ld_flag" = x"no"; then
 175     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 176   else
 177     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 178   fi
 179 else
 180   AC_MSG_RESULT(no)
 181 fi
 182
 183 # ----------------------
 184 # Find default assembler
 185 # ----------------------
 186
 187 # With GNU as
 188 AC_ARG_WITH(gnu-as,
 189 [  --with-gnu-as           arrange to work with GNU as],
 190 gas_flag="$with_gnu_as",
 191 gas_flag=no)
 192
 193 AC_ARG_WITH(as,
 194 [  --with-as               arrange to use the specified as (full pathname)],
 195 DEFAULT_ASSEMBLER="$with_as")
 196 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_ASSEMBLER"; then
 198     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 199   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gas_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 203         [Define to enable the use of a default assembler.])
 204 fi
 205
 206 AC_MSG_CHECKING([whether a default assembler was specified])
 207 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 208   if test x"$gas_flag" = x"no"; then
 209     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 210   else
 211     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 212   fi
 213 else
 214   AC_MSG_RESULT(no)
 215 fi
 216
 217 # ---------------
 218 # Find C compiler
 219 # ---------------
 220
 221 # Find the native compiler
 222 AC_PROG_CC
 223 AC_PROG_CC_C_O
 224 # autoconf is lame and doesn't give us any substitution variable for this.
 225 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 226   NO_MINUS_C_MINUS_O=yes
 227 else
 228   OUTPUT_OPTION='-o $@'
 229 fi
 230 AC_SUBST(NO_MINUS_C_MINUS_O)
 231 AC_SUBST(OUTPUT_OPTION)
 232
 233 # -------------------------
 234 # Check C compiler features
 235 # -------------------------
 236
 237 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 238 ac_cv_prog_cc_no_long_long,
 239 [save_CFLAGS="$CFLAGS"
 240 CFLAGS="-Wno-long-long"
 241 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 242                ac_cv_prog_cc_no_long_long=no)
 243 CFLAGS="$save_CFLAGS"])
 244
 245 AC_PROG_CPP
 246 AC_C_INLINE
 247
 248 gcc_AC_C_LONG_LONG
 249 gcc_AC_C__BOOL
 250
 251 # sizeof(char) is 1 by definition.
 252 AC_COMPILE_CHECK_SIZEOF(void *)
 253 AC_COMPILE_CHECK_SIZEOF(short)
 254 AC_COMPILE_CHECK_SIZEOF(int)
 255 AC_COMPILE_CHECK_SIZEOF(long)
 256 if test $ac_cv_c_long_long = yes; then
 257   AC_COMPILE_CHECK_SIZEOF(long long)
 258 fi
 259 if test $ac_cv_c___int64 = yes; then
 260   AC_COMPILE_CHECK_SIZEOF(__int64)
 261 fi
 262
 263 # -----------------
 264 # Find Ada compiler
 265 # -----------------
 266
 267 # See if GNAT has been installed
 268 gcc_AC_PROG_GNAT
 269
 270 if test x$have_gnat != xno ; then
 271 AC_CACHE_CHECK(whether ${ADAC} accepts -Wno-long-long,
 272 ac_cv_prog_adac_no_long_long,
 273 [cat >conftest.adb <<EOF
 274 procedure conftest is begin null; end conftest;
 275 EOF
 276 if $ADAC -Wno-long-long -c conftest.adb 1>&5 2>&5 ; then
 277   ac_cv_prog_adac_no_long_long=yes
 278 else
 279   ac_cv_prog_adac_no_long_long=no
 280 fi
 281 rm -f conftest*])
 282 else
 283   ac_cv_prog_adac_no_long_long=yes
 284 fi
 285
 286 # ---------------------
 287 # Warnings and checking
 288 # ---------------------
 289
 290 strict1_warn=
 291 if test $ac_cv_prog_cc_no_long_long = yes && \
 292     test $ac_cv_prog_adac_no_long_long = yes ; then
 293   strict1_warn="-pedantic -Wno-long-long"
 294 fi
 295 AC_SUBST(strict1_warn)
 296
 297 # If the native compiler is GCC, we can enable warnings even in stage1.
 298 # That's useful for people building cross-compilers, or just running a
 299 # quick `make'.
 300 warn_cflags=
 301 if test "x$GCC" = "xyes"; then
 302   warn_cflags='$(GCC_WARN_CFLAGS)'
 303 fi
 304 AC_SUBST(warn_cflags)
 305
 306 # Enable -Werror in bootstrap stage2 and later.
 307 # Change the default to "no" on release branches.
 308 AC_ARG_ENABLE(werror,
 309 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 310 [enable_werror=yes])
 311 if test x$enable_werror = xyes ; then
 312   WERROR=-Werror
 313 fi
 314 AC_SUBST(WERROR)
 315
 316 # Enable expensive internal checks
 317 AC_ARG_ENABLE(checking,
 318 [  --enable-checking[=LIST]
 319                           enable expensive run-time checks.  With LIST,
 320                           enable only specific categories of checks.
 321                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 322                           default is misc,tree,gc,rtlflag],
 323 [ac_checking=
 324 ac_tree_checking=
 325 ac_rtl_checking=
 326 ac_rtlflag_checking=
 327 ac_gc_checking=
 328 ac_gc_always_collect=
 329 ac_fold_checking=
 330 case "${enableval}" in
 331 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 332         ac_rtlflag_checking=1 ;;
 333 no)     ;;
 334 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 335         set fnord $enableval; shift
 336         IFS="$ac_save_IFS"
 337         for check
 338         do
 339                 case $check in
 340                 misc)   ac_checking=1 ;;
 341                 tree)   ac_tree_checking=1 ;;
 342                 rtlflag)        ac_rtlflag_checking=1 ;;
 343                 rtl)    ac_rtl_checking=1 ;;
 344                 gc)     ac_gc_checking=1 ;;
 345                 gcac)   ac_gc_always_collect=1 ;;
 346                 fold)   ac_fold_checking=1 ;;
 347                 valgrind)       ac_checking_valgrind=1 ;;
 348                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 349                 esac
 350         done
 351         ;;
 352 esac
 353 ],
 354 # Enable some checks by default for development versions of GCC
 355 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 356 nocommon_flag=""
 357 if test x$ac_checking != x ; then
 358   AC_DEFINE(ENABLE_CHECKING, 1,
 359 [Define if you want more run-time sanity checks.  This one gets a grab
 360    bag of miscellaneous but relatively cheap checks.])
 361   nocommon_flag=-fno-common
 362 fi
 363 AC_SUBST(nocommon_flag)
 364 if test x$ac_tree_checking != x ; then
 365   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 366 [Define if you want all operations on trees (the basic data
 367    structure of the front ends) to be checked for dynamic type safety
 368    at runtime.  This is moderately expensive.])
 369 fi
 370 if test x$ac_rtl_checking != x ; then
 371   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 372 [Define if you want all operations on RTL (the basic data structure
 373    of the optimizer and back end) to be checked for dynamic type safety
 374    at runtime.  This is quite expensive.])
 375 fi
 376 if test x$ac_rtlflag_checking != x ; then
 377   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 378 [Define if you want RTL flag accesses to be checked against the RTL
 379    codes that are supported for each access macro.  This is relatively
 380    cheap.])
 381 fi
 382 if test x$ac_gc_checking != x ; then
 383   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 384 [Define if you want the garbage collector to do object poisoning and
 385    other memory allocation checks.  This is quite expensive.])
 386 fi
 387 if test x$ac_gc_always_collect != x ; then
 388   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 389 [Define if you want the garbage collector to operate in maximally
 390    paranoid mode, validating the entire heap and collecting garbage at
 391    every opportunity.  This is extremely expensive.])
 392 fi
 393 if test x$ac_fold_checking != x ; then
 394   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 395 [Define if you want fold checked that it never destructs its argument.
 396    This is quite expensive.])
 397 fi
 398 valgrind_path_defines=
 399 valgrind_command=
 400 if test x$ac_checking_valgrind != x ; then
 401   # It is certainly possible that there's valgrind but no valgrind.h.
 402   # GCC relies on making annotations so we must have both.
 403   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 404   AC_TRY_CPP(
 405     [#include <memcheck.h>
 406 #ifndef VALGRIND_DISCARD
 407 #error VALGRIND_DISCARD not defined
 408 #endif],
 409   [gcc_cv_header_memcheck_h=yes],
 410   gcc_cv_header_memcheck_h=no)
 411   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 412   AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 413   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 414         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 415   if test "x$valgrind_path" = "x" || (test $have_valgrind_h = no && test $gcc_cv_header_memcheck_h = no); then
 416         AC_MSG_ERROR([*** Can't find both valgrind and valgrind.h/memcheck.h])
 417   fi
 418   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 419   valgrind_command="$valgrind_path -q"
 420   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 421 [Define if you want to run subprograms and generated programs
 422    through valgrind (a memory checker).  This is extremely expensive.])
 423   if test $gcc_cv_header_memcheck_h = yes; then
 424     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 425         [Define if valgrind's memcheck.h header is installed.])
 426   fi
 427 fi
 428 AC_SUBST(valgrind_path_defines)
 429 AC_SUBST(valgrind_command)
 430
 431 # Enable code coverage collection
 432 AC_ARG_ENABLE(coverage,
 433 [  --enable-coverage[=LEVEL]
 434                           enable compiler\'s code coverage collection.
 435                           Use to measure compiler performance and locate
 436                           unused parts of the compiler. With LEVEL, specify
 437                           optimization. Values are opt, noopt,
 438                           default is noopt],
 439 [case "${enableval}" in
 440 yes|noopt)
 441         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 442         ;;
 443 opt)
 444         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 445         ;;
 446 *)
 447         AC_MSG_ERROR(unknown coverage setting $enableval)
 448         ;;
 449 esac],
 450 [coverage_flags=""])
 451 AC_SUBST(coverage_flags)
 452
 453 # -------------------------------
 454 # Miscenalleous configure options
 455 # -------------------------------
 456
 457 # With stabs
 458 AC_ARG_WITH(stabs,
 459 [  --with-stabs            arrange to use stabs instead of host debug format],
 460 stabs="$with_stabs",
 461 stabs=no)
 462
 463 # Determine whether or not multilibs are enabled.
 464 AC_ARG_ENABLE(multilib,
 465 [  --enable-multilib       enable library support for multiple ABIs],
 466 [], [enable_multilib=yes])
 467 AC_SUBST(enable_multilib)
 468
 469 # Enable __cxa_atexit for C++.
 470 AC_ARG_ENABLE(__cxa_atexit,
 471 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 472 [], [])
 473
 474 # Enable threads
 475 # Pass with no value to take the default
 476 # Pass with a value to specify a thread package
 477 AC_ARG_ENABLE(threads,
 478 [  --enable-threads        enable thread usage for target GCC
 479   --enable-threads=LIB    use LIB thread package for target GCC],,
 480 enable_threads='')
 481
 482 enable_threads_flag=$enable_threads
 483 # Check if a valid thread package
 484 case x${enable_threads_flag} in
 485         x | xno)
 486                 # No threads
 487                 target_thread_file='single'
 488                 ;;
 489         xyes)
 490                 # default
 491                 target_thread_file=''
 492                 ;;
 493         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 494         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix | xgnat)
 495                 target_thread_file=$enable_threads_flag
 496                 ;;
 497         *)
 498                 echo "$enable_threads is an unknown thread package" 1>&2
 499                 exit 1
 500                 ;;
 501 esac
 502
 503 AC_ARG_ENABLE(objc-gc,
 504 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 505                           the GNU Objective-C runtime],
 506 if test x$enable_objc_gc = xno; then
 507         objc_boehm_gc=''
 508 else
 509         objc_boehm_gc=1
 510 fi,
 511 objc_boehm_gc='')
 512
 513 AC_ARG_WITH(dwarf2,
 514 [  --with-dwarf2           force the default debug format to be DWARF 2],
 515 dwarf2="$with_dwarf2",
 516 dwarf2=no)
 517
 518 AC_ARG_ENABLE(shared,
 519 [  --disable-shared        don't provide a shared libgcc],
 520 [
 521   case $enable_shared in
 522   yes | no) ;;
 523   *)
 524     enable_shared=no
 525     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 526     for pkg in $enableval; do
 527       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 528         enable_shared=yes
 529       fi
 530     done
 531     IFS="$ac_save_ifs"
 532     ;;
 533   esac
 534 ], [enable_shared=yes])
 535 AC_SUBST(enable_shared)
 536
 537 AC_ARG_WITH(sysroot,
 538 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 539 [
 540  case ${with_sysroot} in
 541  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 542  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 543  esac
 544
 545  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 546  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 547
 548  if test "x$exec_prefix" = xNONE; then
 549   if test "x$prefix" = xNONE; then
 550    test_prefix=/usr/local
 551   else
 552    test_prefix=$prefix
 553   fi
 554  else
 555   test_prefix=$exec_prefix
 556  fi
 557  case ${TARGET_SYSTEM_ROOT} in
 558  "${test_prefix}"|"${test_prefix}/"*|\
 559  '${exec_prefix}'|'${exec_prefix}/'*)
 560    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 561    TARGET_SYSTEM_ROOT_DEFINE="$t"
 562    ;;
 563  esac
 564 ], [
 565  TARGET_SYSTEM_ROOT=
 566  TARGET_SYSTEM_ROOT_DEFINE=
 567  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 568 ])
 569 AC_SUBST(TARGET_SYSTEM_ROOT)
 570 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 571 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 572
 573 # Build with intermodule optimisations
 574 AC_ARG_ENABLE(intermodule,
 575 [  --enable-intermodule    build the compiler in one step],
 576 [case ${enable_intermodule} in
 577   yes) onestep="-onestep";;
 578   *) onestep="";;
 579 esac],
 580 [onestep=""])
 581 AC_SUBST(onestep)
 582
 583 # -------------------------
 584 # Checks for other programs
 585 # -------------------------
 586
 587 AC_PROG_MAKE_SET
 588
 589 # Find some useful tools
 590 AC_PROG_AWK
 591 gcc_AC_PROG_LN
 592 gcc_AC_PROG_LN_S
 593 AC_PROG_RANLIB
 594 gcc_AC_PROG_INSTALL
 595
 596 # See if cmp has --ignore-initial.
 597 gcc_AC_PROG_CMP_IGNORE_INITIAL
 598
 599 # See if we have the mktemp command.
 600 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 601
 602 # Do we have a single-tree copy of texinfo?
 603 if test -f $srcdir/../texinfo/Makefile.in; then
 604   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 605   gcc_cv_prog_makeinfo_modern=yes
 606   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 607 else
 608   # See if makeinfo has been installed and is modern enough
 609   # that we can use it.
 610   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 611   [GNU texinfo.* \([0-9][0-9.]*\)],
 612   [4.[2-9]*])
 613 fi
 614
 615 if test $gcc_cv_prog_makeinfo_modern = no; then
 616   AC_MSG_WARN([
 617 *** Makeinfo is missing or too old.
 618 *** Info documentation will not be built.])
 619   BUILD_INFO=
 620 else
 621   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 622 fi
 623
 624 # Is pod2man recent enough to regenerate manpages?
 625 AC_MSG_CHECKING([for recent Pod::Man])
 626 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 627   AC_MSG_RESULT(yes)
 628   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 629 else
 630   AC_MSG_RESULT(no)
 631   GENERATED_MANPAGES=
 632 fi
 633
 634 # How about lex?
 635 dnl Don't use AC_PROG_LEX; we insist on flex.
 636 dnl LEXLIB is not useful in gcc.
 637 if test -f $srcdir/../flex/skel.c; then
 638   FLEX='$(objdir)/../flex/flex'
 639 else
 640   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 641 fi
 642
 643 # Bison?
 644 # The -L switch is so bison can find its skeleton file.
 645 if test -f $srcdir/../bison/bison.simple; then
 646   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 647 else
 648   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 649 fi
 650
 651 # --------------------
 652 # Checks for C headers
 653 # --------------------
 654
 655 AC_MSG_CHECKING(for GNU C library)
 656 AC_CACHE_VAL(gcc_cv_glibc,
 657 [AC_TRY_COMPILE(
 658   [#include <features.h>],[
 659 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 660 #error Not a GNU C library system
 661 #endif],
 662   [gcc_cv_glibc=yes],
 663   gcc_cv_glibc=no)])
 664 AC_MSG_RESULT($gcc_cv_glibc)
 665 if test $gcc_cv_glibc = yes; then
 666   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 667 fi
 668
 669 AC_HEADER_STDC
 670 AC_HEADER_TIME
 671 gcc_AC_HEADER_STDBOOL
 672 gcc_AC_HEADER_STRING
 673 AC_HEADER_SYS_WAIT
 674 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 675                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 676                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 677                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 678
 679 # Check for thread headers.
 680 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 681 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 682
 683 # These tests can't be done till we know if we have limits.h.
 684 gcc_AC_C_CHAR_BIT
 685 AC_C_BIGENDIAN_CROSS
 686
 687 # --------
 688 # UNSORTED
 689 # --------
 690
 691 # Stage specific cflags for build.
 692 stage1_cflags=
 693 case $build in
 694 vax-*-*)
 695   if test x$GCC = xyes
 696   then
 697     stage1_cflags="-Wa,-J"
 698   else
 699     stage1_cflags="-J"
 700   fi
 701   ;;
 702 powerpc-*-darwin*)
 703   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 704   # sources; use -no-cpp-precomp to get to GNU cpp.
 705   # Apple's GCC has bugs in designated initializer handling, so disable
 706   # that too.
 707   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 708   ;;
 709 esac
 710 AC_SUBST(stage1_cflags)
 711
 712 # These libraries may be used by collect2.
 713 # We may need a special search path to get them linked.
 714 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 715 [save_LIBS="$LIBS"
 716 for libs in '' -lld -lmld \
 717                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 718                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 719 do
 720         LIBS="$libs"
 721         AC_TRY_LINK_FUNC(ldopen,
 722                 [gcc_cv_collect2_libs="$libs"; break])
 723 done
 724 LIBS="$save_LIBS"
 725 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 726 case $gcc_cv_collect2_libs in
 727         "none required")        ;;
 728         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 729 esac
 730 AC_SUBST(COLLECT2_LIBS)
 731
 732 # When building Ada code on Alpha, we need exc_resume which is usually in
 733 # -lexc.  So test for it.
 734 save_LIBS="$LIBS"
 735 LIBS=
 736 AC_SEARCH_LIBS(exc_resume, exc)
 737 GNAT_LIBEXC="$LIBS"
 738 LIBS="$save_LIBS"
 739 AC_SUBST(GNAT_LIBEXC)
 740
 741 # Some systems put ldexp and frexp in libm instead of libc; assume
 742 # they're both in the same place.  jcf-dump needs them.
 743 save_LIBS="$LIBS"
 744 LIBS=
 745 AC_SEARCH_LIBS(ldexp, m)
 746 LDEXP_LIB="$LIBS"
 747 LIBS="$save_LIBS"
 748 AC_SUBST(LDEXP_LIB)
 749
 750 # Use <inttypes.h> only if it exists,
 751 # doesn't clash with <sys/types.h>, and declares intmax_t.
 752 AC_MSG_CHECKING(for inttypes.h)
 753 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 754 [AC_TRY_COMPILE(
 755   [#include <sys/types.h>
 756 #include <inttypes.h>],
 757   [intmax_t i = -1;],
 758   [gcc_cv_header_inttypes_h=yes],
 759   gcc_cv_header_inttypes_h=no)])
 760 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 761 if test $gcc_cv_header_inttypes_h = yes; then
 762   AC_DEFINE(HAVE_INTTYPES_H, 1,
 763         [Define if you have a working <inttypes.h> header file.])
 764 fi
 765
 766 dnl Disabled until we have a complete test for buggy enum bitfields.
 767 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 768
 769 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 770         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 771         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 772         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 773         setlocale)
 774
 775 if test x$ac_cv_func_mbstowcs = xyes; then
 776   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 777 [    AC_TRY_RUN([#include <stdlib.h>
 778 int main()
 779 {
 780   mbstowcs(0, "", 0);
 781   return 0;
 782 }],
 783     gcc_cv_func_mbstowcs_works=yes,
 784     gcc_cv_func_mbstowcs_works=no,
 785     gcc_cv_func_mbstowcs_works=yes)])
 786   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 787     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 788   [Define this macro if mbstowcs does not crash when its
 789    first argument is NULL.])
 790   fi
 791 fi
 792
 793 gcc_AC_CHECK_TYPE(ssize_t, int)
 794
 795 # Try to determine the array type of the second argument of getgroups
 796 # for the target system (int or gid_t).
 797 AC_TYPE_GETGROUPS
 798 if test "${target}" = "${build}"; then
 799   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 800 else
 801   case "${target}" in
 802         # This condition may need some tweaking.  It should include all
 803         # targets where the array type of the second argument of getgroups
 804         # is int and the type of gid_t is not equivalent to int.
 805         *-*-sunos* | *-*-ultrix*)
 806                 TARGET_GETGROUPS_T=int
 807                 ;;
 808         *)
 809                 TARGET_GETGROUPS_T=gid_t
 810                 ;;
 811   esac
 812 fi
 813 AC_SUBST(TARGET_GETGROUPS_T)
 814
 815 gcc_AC_FUNC_PRINTF_PTR
 816 gcc_AC_FUNC_MMAP_BLACKLIST
 817
 818 case "${host}" in
 819 *-*-uwin*)
 820   AC_MSG_ERROR([
 821 *** UWIN may not be used as a host platform because
 822 *** linking with posix.dll is not allowed by the GNU GPL])
 823   ;;
 824 *-*-*vms*)
 825   # Under VMS, vfork works very different than on Unix. The standard test
 826   # won't work, and it isn't easily adaptable. It makes more sense to
 827   # just force it.
 828   ac_cv_func_vfork_works=yes
 829   ;;
 830 esac
 831 AC_FUNC_VFORK
 832
 833 AM_ICONV
 834 # Until we have in-tree GNU iconv:
 835 LIBICONV_DEP=
 836 AC_SUBST(LIBICONV_DEP)
 837
 838 AM_LC_MESSAGES
 839
 840 # We will need to find libiberty.h and ansidecl.h
 841 saved_CFLAGS="$CFLAGS"
 842 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 843 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 844         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 845         fprintf_unlocked strstr errno vasprintf \
 846         malloc realloc calloc free basename getopt clock, , ,[
 847 #include "ansidecl.h"
 848 #include "system.h"])
 849
 850 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 851 #include "ansidecl.h"
 852 #include "system.h"
 853 #ifdef HAVE_SYS_RESOURCE_H
 854 #include <sys/resource.h>
 855 #endif
 856 ])
 857
 858 AC_TRY_COMPILE([
 859 #include "ansidecl.h"
 860 #include "system.h"
 861 #ifdef HAVE_SYS_RESOURCE_H
 862 #include <sys/resource.h>
 863 #endif
 864 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 865 [Define to \`long' if <sys/resource.h> doesn't define.])])
 866
 867 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 868 #include "ansidecl.h"
 869 #include "system.h"
 870 #ifdef HAVE_LDFCN_H
 871 #include <ldfcn.h>
 872 #endif
 873 ])
 874
 875 gcc_AC_CHECK_DECLS(times, , ,[
 876 #include "ansidecl.h"
 877 #include "system.h"
 878 #ifdef HAVE_SYS_TIMES_H
 879 #include <sys/times.h>
 880 #endif
 881 ])
 882
 883 # More time-related stuff.
 884 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 885 AC_TRY_COMPILE([
 886 #include "ansidecl.h"
 887 #include "system.h"
 888 #ifdef HAVE_SYS_TIMES_H
 889 #include <sys/times.h>
 890 #endif
 891 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 892 if test $ac_cv_struct_tms = yes; then
 893   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 894   [Define if <sys/times.h> defines struct tms.])
 895 fi
 896
 897 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 898 # revisit after autoconf 2.50.
 899 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 900 AC_TRY_COMPILE([
 901 #include "ansidecl.h"
 902 #include "system.h"
 903 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 904 if test $gcc_cv_type_clock_t = yes; then
 905   AC_DEFINE(HAVE_CLOCK_T, 1,
 906   [Define if <time.h> defines clock_t.])
 907 fi
 908
 909 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
 910 [AC_TRY_COMPILE([
 911 #include "ansidecl.h"
 912 #include "system.h"
 913 ],
 914 [if ((uchar *)0) return 0;
 915  if (sizeof(uchar)) return 0;],
 916 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 917 if test $ac_cv_type_uchar = yes; then
 918   AC_DEFINE(HAVE_UCHAR, 1,
 919   [Define if <sys/types.h> defines \`uchar'.])
 920 fi
 921
 922 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 923 CFLAGS="$saved_CFLAGS"
 924
 925 gcc_AC_INITFINI_ARRAY
 926
 927 # mkdir takes a single argument on some systems.
 928 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 929
 930 # File extensions
 931 manext='.1'
 932 objext='.o'
 933 AC_SUBST(manext)
 934 AC_SUBST(objext)
 935
 936 # With Setjmp/Longjmp based exception handling.
 937 AC_ARG_ENABLE(sjlj-exceptions,
 938 [  --enable-sjlj-exceptions
 939                           arrange to use setjmp/longjmp exception handling],
 940 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
 941 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
 942   [Define 0/1 to force the choice for exception handling model.])])
 943
 944 AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
 945 # Use libunwind based exception handling.
 946 AC_ARG_ENABLE(libunwind-exceptions,
 947 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
 948 use_libunwind_exceptions=$enableval,
 949 use_libunwind_exceptions=$use_libunwind_default)
 950 if test x"$use_libunwind_exceptions" = xyes; then
 951    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
 952         [Define if gcc should use -lunwind.])
 953 fi
 954
 955 # --------------------------------------------------------
 956 # Build, host, and target specific configuration fragments
 957 # --------------------------------------------------------
 958
 959 # Collect build-machine-specific information.
 960 . ${srcdir}/config.build
 961
 962 # Collect host-machine-specific information.
 963 . ${srcdir}/config.host
 964
 965 target_gtfiles=
 966
 967 # Collect target-machine-specific information.
 968 for machine in $target ; do
 969         . ${srcdir}/config.gcc
 970 done
 971
 972 extra_objs="${host_extra_objs} ${extra_objs}"
 973
 974 # Default the target-machine variables that were not explicitly set.
 975 if test x"$tm_file" = x
 976 then tm_file=$cpu_type/$cpu_type.h; fi
 977
 978 if test x"$extra_headers" = x
 979 then extra_headers=; fi
 980
 981 if test x$md_file = x
 982 then md_file=$cpu_type/$cpu_type.md; fi
 983
 984 if test x$out_file = x
 985 then out_file=$cpu_type/$cpu_type.c; fi
 986
 987 if test x"$tmake_file" = x
 988 then tmake_file=$cpu_type/t-$cpu_type
 989 fi
 990
 991 if test x"$dwarf2" = xyes
 992 then tm_file="$tm_file tm-dwarf2.h"
 993 fi
 994
 995 # Say what files are being used for the output code and MD file.
 996 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 997 echo "Using \`$srcdir/config/$md_file' as machine description file."
 998
 999 # If any of the xm_file variables contain nonexistent files, warn
1000 # about them and drop them.
1001
1002 bx=
1003 for x in $build_xm_file; do
1004   if    test -f $srcdir/config/$x
1005   then      bx="$bx $x"
1006   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1007   fi
1008 done
1009 build_xm_file="$bx"
1010
1011 hx=
1012 for x in $host_xm_file; do
1013   if    test -f $srcdir/config/$x
1014   then      hx="$hx $x"
1015   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1016   fi
1017 done
1018 host_xm_file="$hx"
1019
1020 tx=
1021 for x in $xm_file; do
1022   if    test -f $srcdir/config/$x
1023   then      tx="$tx $x"
1024   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1025   fi
1026 done
1027 xm_file="$tx"
1028
1029 count=a
1030 for f in $tm_file; do
1031         count=${count}x
1032 done
1033 if test $count = ax; then
1034         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1035 else
1036         echo "Using the following target machine macro files:"
1037         for f in $tm_file; do
1038                 echo "  $srcdir/config/$f"
1039         done
1040 fi
1041
1042 if test x$need_64bit_hwint = xyes; then
1043         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1044 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1045 fi
1046
1047 count=a
1048 for f in $host_xm_file; do
1049         count=${count}x
1050 done
1051 if test $count = a; then
1052         :
1053 elif test $count = ax; then
1054         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1055 else
1056         echo "Using the following host machine macro files:"
1057         for f in $host_xm_file; do
1058                 echo "  $srcdir/config/$f"
1059         done
1060 fi
1061 echo "Using ${out_host_hook_obj} for host machine hooks."
1062
1063 if test "$host_xm_file" != "$build_xm_file"; then
1064         count=a
1065         for f in $build_xm_file; do
1066                 count=${count}x
1067         done
1068         if test $count = a; then
1069                 :
1070         elif test $count = ax; then
1071                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1072         else
1073                 echo "Using the following build machine macro files:"
1074                 for f in $build_xm_file; do
1075                         echo "  $srcdir/config/$f"
1076                 done
1077         fi
1078 fi
1079
1080 if test x$thread_file = x; then
1081         if test x$target_thread_file != x; then
1082                 thread_file=$target_thread_file
1083         else
1084                 thread_file='single'
1085         fi
1086 fi
1087
1088 if test x$enable___cxa_atexit = xyes || \
1089    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1090   AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1091   [Define if you want to use __cxa_atexit, rather than atexit, to
1092    register C++ destructors for local statics and global objects.
1093    This is essential for fully standards-compliant handling of
1094    destructors, but requires __cxa_atexit in libc.])
1095 fi
1096
1097 # Look for a file containing extra machine modes.
1098 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1099   extra_modes_file='$(srcdir)'/config/${extra_modes}
1100   AC_SUBST(extra_modes_file)
1101   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1102   [Define to the name of a file containing a list of extra machine modes
1103    for this architecture.])
1104   AC_DEFINE(EXTRA_CC_MODES, 1,
1105   [Define if the target architecture needs extra machine modes to represent
1106    the results of comparisons.])
1107 fi
1108
1109 # auto-host.h is the file containing items generated by autoconf and is
1110 # the first file included by config.h.
1111 # If host=build, it is correct to have bconfig include auto-host.h
1112 # as well.  If host!=build, we are in error and need to do more
1113 # work to find out the build config parameters.
1114 if test x$host = x$build
1115 then
1116         build_auto=auto-host.h
1117         FORBUILD=..
1118 else
1119         # We create a subdir, then run autoconf in the subdir.
1120         # To prevent recursion we set host and build for the new
1121         # invocation of configure to the build for this invocation
1122         # of configure.
1123         tempdir=build.$$
1124         rm -rf $tempdir
1125         mkdir $tempdir
1126         cd $tempdir
1127         case ${srcdir} in
1128         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1129         *) realsrcdir=../${srcdir};;
1130         esac
1131         saved_CFLAGS="${CFLAGS}"
1132         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1133         ${realsrcdir}/configure \
1134                 --target=$target_alias --host=$build_alias --build=$build_alias
1135         CFLAGS="${saved_CFLAGS}"
1136
1137         # We just finished tests for the build machine, so rename
1138         # the file auto-build.h in the gcc directory.
1139         mv auto-host.h ../auto-build.h
1140         cd ..
1141         rm -rf $tempdir
1142         build_auto=auto-build.h
1143         FORBUILD=../${build_subdir}
1144 fi
1145 AC_SUBST(FORBUILD)
1146
1147 tm_file="${tm_file} defaults.h"
1148 tm_p_file="${tm_p_file} tm-preds.h"
1149 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1150 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1151 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1152 # put this back in temporarily.
1153 xm_file="ansidecl.h ${xm_file}"
1154
1155 # --------
1156 # UNSORTED
1157 # --------
1158
1159 # Get the version trigger filename from the toplevel
1160 if test "${with_gcc_version_trigger+set}" = set; then
1161         gcc_version_trigger=$with_gcc_version_trigger
1162 else
1163         gcc_version_trigger=${srcdir}/version.c
1164 fi
1165 changequote(,)dnl
1166 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1167 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1168
1169 # Compile in configure arguments.
1170 if test -f configargs.h ; then
1171         # Being re-configured.
1172         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1173         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1174 else
1175         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1176 fi
1177
1178 # Double all backslashes and backslash all quotes to turn
1179 # gcc_config_arguments into a C string.
1180 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1181 $gcc_config_arguments
1182 EOF
1183 gcc_config_arguments_str=`cat conftest.out`
1184 rm -f conftest.out
1185
1186 cat > configargs.h <<EOF
1187 /* Generated automatically. */
1188 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1189 static const char thread_model[] = "$thread_file";
1190
1191 static const struct {
1192   const char *name, *value;
1193 } configure_default_options[] = $configure_default_options;
1194 EOF
1195 changequote([,])dnl
1196
1197 # Internationalization
1198 PACKAGE=gcc
1199 VERSION="$gcc_version"
1200 AC_SUBST(PACKAGE)
1201 AC_SUBST(VERSION)
1202
1203 ZW_GNU_GETTEXT_SISTER_DIR
1204
1205 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1206 # -liconv on the link line twice.
1207 case "$LIBINTL" in *$LIBICONV*)
1208         LIBICONV= ;;
1209 esac
1210
1211 # Windows32 Registry support for specifying GCC installation paths.
1212 AC_ARG_ENABLE(win32-registry,
1213 [  --disable-win32-registry
1214                           disable lookup of installation paths in the
1215                           Registry on Windows hosts
1216   --enable-win32-registry enable registry lookup (default)
1217   --enable-win32-registry=KEY
1218                           use KEY instead of GCC version as the last portion
1219                           of the registry key],,)
1220 case $host_os in
1221         win32 | pe | cygwin* | mingw32* | uwin*)
1222 AC_MSG_CHECKING(whether windows registry support is requested)
1223 if test "x$enable_win32_registry" != xno; then
1224   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1225 [Define to 1 if installation paths should be looked up in Windows32
1226    Registry. Ignored on non windows32 hosts.])
1227   AC_MSG_RESULT(yes)
1228   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1229 else
1230   AC_MSG_RESULT(no)
1231 fi
1232
1233 # Check if user specified a different registry key.
1234 case "x${enable_win32_registry}" in
1235 x | xyes)
1236   # default.
1237   gcc_cv_win32_registry_key="$VERSION"
1238   ;;
1239 xno)
1240   # no registry lookup.
1241   gcc_cv_win32_registry_key=''
1242   ;;
1243 *)
1244   # user-specified key.
1245   gcc_cv_win32_registry_key="$enable_win32_registry"
1246   ;;
1247 esac
1248
1249 if test "x$enable_win32_registry" != xno; then
1250   AC_MSG_CHECKING(registry key on windows hosts)
1251   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1252         [Define to be the last portion of registry key on windows hosts.])
1253   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1254 fi
1255 ;;
1256 esac
1257
1258 # Get an absolute path to the GCC top-level source directory
1259 holddir=`${PWDCMD-pwd}`
1260 cd $srcdir
1261 topdir=`${PWDCMD-pwd}`
1262 cd $holddir
1263
1264 # Conditionalize the makefile for this host machine.
1265 xmake_file=
1266 for f in ${host_xmake_file}
1267 do
1268         if test -f ${srcdir}/config/$f
1269         then
1270                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1271         fi
1272 done
1273
1274 # Conditionalize the makefile for this target machine.
1275 tmake_file_=
1276 for f in ${tmake_file}
1277 do
1278         if test -f ${srcdir}/config/$f
1279         then
1280                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1281         fi
1282 done
1283 tmake_file="${tmake_file_}"
1284
1285 symbolic_link='ln -s'
1286
1287 # If the host doesn't support symlinks, modify CC in
1288 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1289 # Otherwise, we can use "CC=$(CC)".
1290 rm -f symtest.tem
1291 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1292 then
1293         cc_set_by_configure="\$(CC)"
1294         quoted_cc_set_by_configure="\$(CC)"
1295         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1296         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1297 else
1298         rm -f symtest.tem
1299         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1300         then
1301                 symbolic_link="cp -p"
1302         else
1303                 symbolic_link="cp"
1304         fi
1305         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1306         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1307         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1308         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1309 fi
1310 rm -f symtest.tem
1311
1312 out_object_file=`basename $out_file .c`.o
1313
1314 tm_file_list=
1315 tm_include_list=
1316 for f in $tm_file; do
1317   case $f in
1318     defaults.h )
1319        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1320        tm_include_list="${tm_include_list} $f"
1321        ;;
1322     * )
1323        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1324        tm_include_list="${tm_include_list} config/$f"
1325        ;;
1326   esac
1327 done
1328
1329 tm_p_file_list=
1330 tm_p_include_list=
1331 for f in $tm_p_file; do
1332   case $f in
1333     tm-preds.h )
1334        tm_p_file_list="${tm_p_file_list} $f"
1335        tm_p_include_list="${tm_p_include_list} $f"
1336        ;;
1337     * )
1338        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1339        tm_p_include_list="${tm_p_include_list} config/$f"
1340   esac
1341 done
1342
1343 xm_file_list=
1344 xm_include_list=
1345 for f in $xm_file; do
1346   case $f in
1347     ansidecl.h )
1348        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1349        xm_include_list="${xm_include_list} $f"
1350        ;;
1351     auto-host.h )
1352        xm_file_list="${xm_file_list} $f"
1353        xm_include_list="${xm_include_list} $f"
1354        ;;
1355     * )
1356        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1357        xm_include_list="${xm_include_list} config/$f"
1358        ;;
1359   esac
1360 done
1361
1362 host_xm_file_list=
1363 host_xm_include_list=
1364 for f in $host_xm_file; do
1365   case $f in
1366     ansidecl.h )
1367        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1368        host_xm_include_list="${host_xm_include_list} $f"
1369        ;;
1370     auto-host.h )
1371        host_xm_file_list="${host_xm_file_list} $f"
1372        host_xm_include_list="${host_xm_include_list} $f"
1373        ;;
1374     * )
1375        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1376        host_xm_include_list="${host_xm_include_list} config/$f"
1377        ;;
1378   esac
1379 done
1380
1381 build_xm_file_list=
1382 for f in $build_xm_file; do
1383   case $f in
1384     ansidecl.h )
1385        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1386        build_xm_include_list="${build_xm_include_list} $f"
1387        ;;
1388     auto-build.h | auto-host.h )
1389        build_xm_file_list="${build_xm_file_list} $f"
1390        build_xm_include_list="${build_xm_include_list} $f"
1391        ;;
1392     * )
1393        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1394        build_xm_include_list="${build_xm_include_list} config/$f"
1395        ;;
1396   esac
1397 done
1398
1399 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1400 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1401 CROSS=                                          AC_SUBST(CROSS)
1402 ALL=all.internal                                AC_SUBST(ALL)
1403 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1404 if test x$host != x$target
1405 then
1406         CROSS="-DCROSS_COMPILE"
1407         ALL=all.cross
1408         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1409         case "$host","$target" in
1410         # Darwin crosses can use the host system's libraries and headers,
1411         # because of the fat library support.  Of course, it must be the
1412         # same version of Darwin on both sides.  Allow the user to
1413         # just say --target=foo-darwin without a version number to mean
1414         # "the version on this system".
1415             *-*-darwin*,*-*-darwin*)
1416                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1417                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1418                 if test $hostos = $targetos -o $targetos = darwin ; then
1419                     CROSS=
1420                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1421                     with_headers=yes
1422                 fi
1423                 ;;
1424
1425             i?86-*-*,x86_64-*-* \
1426             | powerpc*-*-*,powerpc64*-*-*)
1427                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1428         esac
1429 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1430         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1431         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1432 fi
1433
1434 # If this is a cross-compiler that does not
1435 # have its own set of headers then define
1436 # inhibit_libc
1437
1438 # If this is using newlib, without having the headers available now,
1439 # then define inhibit_libc in LIBGCC2_CFLAGS.
1440 # This prevents libgcc2 from containing any code which requires libc
1441 # support.
1442 inhibit_libc=
1443 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1444        test x$with_newlib = xyes ; } &&
1445      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1446        inhibit_libc=-Dinhibit_libc
1447 fi
1448 AC_SUBST(inhibit_libc)
1449
1450 # When building gcc with a cross-compiler, we need to adjust things so
1451 # that the generator programs are still built with the native compiler.
1452 # Also, we cannot run fixincludes or fix-header.
1453
1454 # These are the normal (build=host) settings:
1455 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1456 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1457 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1458 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1459
1460 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1461
1462 # Possibly disable fixproto, on a per-target basis.
1463 case ${use_fixproto} in
1464   no)
1465     STMP_FIXPROTO=
1466     ;;
1467   yes)
1468     STMP_FIXPROTO=stmp-fixproto
1469     ;;
1470 esac
1471 AC_SUBST(STMP_FIXPROTO)
1472
1473 # And these apply if build != host, or we are generating coverage data
1474 if test x$build != x$host || test "x$coverage_flags" != x
1475 then
1476     BUILD_PREFIX=build-
1477     BUILD_PREFIX_1=build-
1478     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1479
1480     if test "x$TARGET_SYSTEM_ROOT" = x; then
1481         STMP_FIXINC=
1482         STMP_FIXPROTO=
1483     fi
1484 fi
1485
1486 # Expand extra_headers to include complete path.
1487 # This substitutes for lots of t-* files.
1488 extra_headers_list=
1489 if test "x$extra_headers" = x
1490 then true
1491 else
1492         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1493         for file in $extra_headers;
1494         do
1495                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1496         done
1497 fi
1498
1499 # Add a definition of USE_COLLECT2 if system wants one.
1500 case $use_collect2 in
1501   no) use_collect2= ;;
1502   "") ;;
1503   *)
1504     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1505     xm_defines="${xm_defines} USE_COLLECT2"
1506     ;;
1507 esac
1508
1509 # Identify the assembler which will work hand-in-glove with the newly
1510 # built GCC, so that we can examine its features.  This is the assembler
1511 # which will be driven by the driver program.
1512 #
1513 # If build != host, and we aren't building gas in-tree, we identify a
1514 # build->target assembler and hope that it will have the same features
1515 # as the host->target assembler we'll be using.
1516 AC_MSG_CHECKING(what assembler to use)
1517 in_tree_gas=no
1518 gcc_cv_as=
1519 gcc_cv_gas_major_version=
1520 gcc_cv_gas_minor_version=
1521 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1522 if test -x "$DEFAULT_ASSEMBLER"; then
1523         gcc_cv_as="$DEFAULT_ASSEMBLER"
1524 elif test -x "$AS"; then
1525         gcc_cv_as="$AS"
1526 elif test -x as$host_exeext; then
1527         # Build using assembler in the current directory.
1528         gcc_cv_as=./as$host_exeext
1529 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1530      && test -f ../gas/Makefile; then
1531   # Single tree build which includes gas.
1532   in_tree_gas=yes
1533   _gcc_COMPUTE_GAS_VERSION
1534   rm -f as$host_exeext
1535   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1536   in_tree_gas_is_elf=no
1537   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1538      || (grep 'obj_format = multi' ../gas/Makefile \
1539          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1540   then
1541     in_tree_gas_is_elf=yes
1542   fi
1543 fi
1544
1545 if test "x$gcc_cv_as" = x; then
1546         # Search the same directories that the installed compiler will
1547         # search.  Else we may find the wrong assembler and lose.  If we
1548         # do not find a suitable assembler binary, then try the user's
1549         # path.
1550         #
1551         # Also note we have to check MD_EXEC_PREFIX before checking the
1552         # user's path.  Unfortunately, there is no good way to get at the
1553         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1554         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1555         # to be fixed as part of the make/configure rewrite too.
1556
1557         if test "x$exec_prefix" = xNONE; then
1558                 if test "x$prefix" = xNONE; then
1559                         test_prefix=/usr/local
1560                 else
1561                         test_prefix=$prefix
1562                 fi
1563         else
1564                 test_prefix=$exec_prefix
1565         fi
1566
1567         # If the loop below does not find an assembler, then use whatever
1568         # one we can find in the users's path.
1569         # user's path.
1570         if test "x$program_prefix" != xNONE; then
1571                 gcc_cv_as=${program_prefix}as$host_exeext
1572         else
1573                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1574         fi
1575
1576         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1577                    $test_prefix/lib/gcc-lib/$target_alias \
1578                    /usr/lib/gcc/$target_alias/$gcc_version \
1579                    /usr/lib/gcc/$target_alias \
1580                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1581                    $test_prefix/$target_alias/bin"
1582
1583         if test x$host = x$target; then
1584             test_dirs="$test_dirs \
1585                    /usr/libexec \
1586                    /usr/ccs/gcc \
1587                    /usr/ccs/bin \
1588                    /udk/usr/ccs/bin \
1589                    /bsd43/usr/lib/cmplrs/cc \
1590                    /usr/cross64/usr/bin \
1591                    /usr/lib/cmplrs/cc \
1592                    /sysv/usr/lib/cmplrs/cc \
1593                    /svr4/usr/lib/cmplrs/cc \
1594                    /usr/bin"
1595         fi
1596
1597         for dir in $test_dirs; do
1598                 if test -x $dir/as$host_exeext; then
1599                         gcc_cv_as=$dir/as$host_exeext
1600                         break;
1601                 fi
1602         done
1603 fi
1604 case $in_tree_gas in
1605   yes)
1606     AC_MSG_RESULT("newly built gas")
1607     ;;
1608   no)
1609     AC_MSG_RESULT($gcc_cv_as)
1610     ;;
1611 esac
1612
1613 # Identify the linker which will work hand-in-glove with the newly
1614 # built GCC, so that we can examine its features.  This is the linker
1615 # which will be driven by the driver program.
1616 #
1617 # If build != host, and we aren't building gas in-tree, we identify a
1618 # build->target linker and hope that it will have the same features
1619 # as the host->target linker we'll be using.
1620 AC_MSG_CHECKING(what linker to use)
1621 in_tree_ld=no
1622 gcc_cv_ld=
1623 gcc_cv_gld_major_version=
1624 gcc_cv_gld_minor_version=
1625 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1626 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1627 if test -x "$DEFAULT_LINKER"; then
1628         gcc_cv_ld="$DEFAULT_LINKER"
1629 elif test -x "$LD"; then
1630         gcc_cv_ld="$LD"
1631 elif test -x collect-ld$host_exeext; then
1632         # Build using linker in the current directory.
1633         gcc_cv_ld=./collect-ld$host_exeext
1634 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1635      && test -f ../ld/Makefile; then
1636         # Single tree build which includes ld.
1637         in_tree_ld=yes
1638         in_tree_ld_is_elf=no
1639         if (grep 'EMUL = .*elf' ../ld/Makefile \
1640             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1641           in_tree_ld_is_elf=yes
1642         fi
1643         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1644         do
1645 changequote(,)dnl
1646                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1647 changequote([,])dnl
1648                 if test x$gcc_cv_gld_version != x; then
1649                         break
1650                 fi
1651         done
1652 changequote(,)dnl
1653         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1654         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1655 changequote([,])dnl
1656         rm -f collect-ld$host_exeext
1657         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1658                 2>/dev/null
1659 fi
1660
1661 if test "x$gcc_cv_ld" = x; then
1662         # Search the same directories that the installed compiler will
1663         # search.  Else we may find the wrong linker and lose.  If we
1664         # do not find a suitable linker binary, then try the user's
1665         # path.
1666         #
1667         # Also note we have to check MD_EXEC_PREFIX before checking the
1668         # user's path.  Unfortunately, there is no good way to get at the
1669         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1670         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1671         # to be fixed as part of the make/configure rewrite too.
1672
1673         if test "x$exec_prefix" = xNONE; then
1674                 if test "x$prefix" = xNONE; then
1675                         test_prefix=/usr/local
1676                 else
1677                         test_prefix=$prefix
1678                 fi
1679         else
1680                 test_prefix=$exec_prefix
1681         fi
1682
1683         # If the loop below does not find an linker, then use whatever
1684         # one we can find in the users's path.
1685         # user's path.
1686         if test "x$program_prefix" != xNONE; then
1687                 gcc_cv_ld=${program_prefix}ld$host_exeext
1688         else
1689                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1690         fi
1691
1692         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1693                    $test_prefix/lib/gcc-lib/$target_alias \
1694                    /usr/lib/gcc/$target_alias/$gcc_version \
1695                    /usr/lib/gcc/$target_alias \
1696                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1697                    $test_prefix/$target_alias/bin"
1698
1699         if test x$host = x$target; then
1700             test_dirs="$test_dirs \
1701                    /usr/libexec \
1702                    /usr/ccs/gcc \
1703                    /usr/ccs/bin \
1704                    /udk/usr/ccs/bin \
1705                    /bsd43/usr/lib/cmplrs/cc \
1706                    /usr/cross64/usr/bin \
1707                    /usr/lib/cmplrs/cc \
1708                    /sysv/usr/lib/cmplrs/cc \
1709                    /svr4/usr/lib/cmplrs/cc \
1710                    /usr/bin"
1711         fi
1712
1713         for dir in $test_dirs; do
1714                 if test -x $dir/ld$host_exeext; then
1715                         gcc_cv_ld=$dir/ld$host_exeext
1716                         break;
1717                 fi
1718         done
1719 fi
1720 case $in_tree_ld in
1721   yes)
1722     AC_MSG_RESULT("newly built ld")
1723     ;;
1724   no)
1725     AC_MSG_RESULT($gcc_cv_ld)
1726     ;;
1727 esac
1728
1729 # Figure out what nm we will be using.
1730 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1731 AC_MSG_CHECKING(what nm to use)
1732 in_tree_nm=no
1733 if test -x nm$host_exeext; then
1734         gcc_cv_nm=./nm$host_exeext
1735 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1736      && test -f ../binutils/Makefile; then
1737         # Single tree build which includes binutils.
1738         in_tree_nm=yes
1739         gcc_cv_nm=./nm$host_exeext
1740         rm -f nm$host_exeext
1741         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1742 elif test "x$program_prefix" != xNONE; then
1743         gcc_cv_nm=${program_prefix}nm$host_exeext
1744 else
1745         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1746 fi
1747 case $in_tree_nm in
1748   yes) AC_MSG_RESULT("newly built nm") ;;
1749   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1750 esac
1751
1752 # Figure out what objdump we will be using.
1753 AC_MSG_CHECKING(what objdump to use)
1754 in_tree_objdump=no
1755 if test -x objdump$host_exeext; then
1756         gcc_cv_objdump=./objdump$host_exeext
1757 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1758      && test -f ../binutils/Makefile; then
1759         # Single tree build which includes binutils.
1760         in_tree_objdump=yes
1761         gcc_cv_objdump=./objdump$host_exeext
1762         rm -f objdump$host_exeext
1763         $symbolic_link ../binutils/objdump$host_exeext \
1764                 objdump$host_exeext 2>/dev/null
1765 elif test "x$program_prefix" != xNONE; then
1766         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1767 else
1768         gcc_cv_objdump=`echo objdump | \
1769                 sed ${program_transform_name}`$host_exeext
1770 fi
1771 case $in_tree_objdump in
1772   yes) AC_MSG_RESULT("newly built objdump") ;;
1773   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1774 esac
1775
1776 # Figure out what assembler alignment features are present.
1777 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1778  [2,6,0],,
1779 [.balign 4
1780 .p2align 2],,
1781 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1782   [Define if your assembler supports .balign and .p2align.])])
1783
1784 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1785  [2,8,0],,
1786  [.p2align 4,,7],,
1787 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1788   [Define if your assembler supports specifying the maximum number
1789    of bytes to skip when using the GAS .p2align command.])])
1790
1791 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1792  [elf,2,9,0],,
1793  [conftest_label1: .word 0
1794 .subsection -1
1795 conftest_label2: .word 0
1796 .previous],
1797  [if test x$gcc_cv_nm != x; then
1798     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1799     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1800     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1801     then :
1802     else gcc_cv_as_subsection_m1=yes
1803     fi
1804     rm -f conftest.nm1 conftest.nm2
1805   fi],
1806  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1807   [Define if your assembler supports .subsection and .subsection -1 starts
1808    emitting at the beginning of your section.])])
1809
1810 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1811  [2,2,0],,
1812  [      .weak foobar],,
1813 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1814
1815 # .hidden needs to be supported in both the assembler and the linker,
1816 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1817 # This is irritatingly difficult to feature test for; we have to check the
1818 # date string after the version number.  If we've got an in-tree
1819 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1820 # to be safe.
1821 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1822 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1823  [elf,2,13,0],,
1824 [       .hidden foobar
1825 foobar:])
1826
1827 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1828 [if test $in_tree_ld = yes ; then
1829   gcc_cv_ld_hidden=no
1830   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1831      && test $in_tree_ld_is_elf = yes; then
1832      gcc_cv_ld_hidden=yes
1833   fi
1834 else
1835   gcc_cv_ld_hidden=yes
1836   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
1837   if echo "$ld_ver" | grep GNU > /dev/null; then
1838 changequote(,)dnl
1839     ld_vers=`echo $ld_ver | sed -n \
1840         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1841         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1842         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1843         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1844         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1845         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1846     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1847     if test 0"$ld_date" -lt 20020404; then
1848       if test -n "$ld_date"; then
1849         # If there was date string, but was earlier than 2002-04-04, fail
1850         gcc_cv_ld_hidden=no
1851       elif test -z "$ld_vers"; then
1852         # If there was no date string nor ld version number, something is wrong
1853         gcc_cv_ld_hidden=no
1854       else
1855         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1856         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1857         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1858         test -z "$ld_vers_patch" && ld_vers_patch=0
1859         if test "$ld_vers_major" -lt 2; then
1860           gcc_cv_ld_hidden=no
1861         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1862           gcc_cv_ld_hidden="no"
1863         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1864           gcc_cv_ld_hidden=no
1865         fi
1866       fi
1867 changequote([,])dnl
1868     fi
1869   else
1870     # non-GNU linkers don't seem to support .hidden yet
1871     gcc_cv_ld_hidden=no
1872   fi
1873 fi])
1874 libgcc_visibility=no
1875 AC_SUBST(libgcc_visibility)
1876 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
1877   libgcc_visibility=yes
1878   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1879   [Define if your assembler and linker support .hidden.])
1880 fi
1881
1882 # Check if we have .[us]leb128, and support symbol arithmetic with it.
1883 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
1884   [elf,2,11,0],,
1885 [       .data
1886         .uleb128 L2 - L1
1887 L1:
1888         .uleb128 1280
1889         .sleb128 -1010
1890 L2:],
1891  [# GAS versions before 2.11 do not support uleb128,
1892   # despite appearing to.
1893   # ??? There exists an elf-specific test that will crash
1894   # the assembler.  Perhaps it's better to figure out whether
1895   # arbitrary sections are supported and try the test.
1896   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
1897   if echo "$as_ver" | grep GNU > /dev/null; then
1898 changequote(,)dnl
1899     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1900     as_major=`echo $as_ver | sed 's/\..*//'`
1901     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1902 changequote([,])dnl
1903     if test $as_major -eq 2 && test $as_minor -lt 11
1904     then :
1905     else gcc_cv_as_leb128=yes
1906     fi
1907   fi],
1908   [AC_DEFINE(HAVE_AS_LEB128, 1,
1909     [Define if your assembler supports .sleb128 and .uleb128.])])
1910
1911 # GAS versions up to and including 2.11.0 may mis-optimize
1912 # .eh_frame data.
1913 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
1914   [elf,2,12,0],,
1915 [       .text
1916 .LFB1:
1917         .4byte  0
1918 .L1:
1919         .4byte  0
1920 .LFE1:
1921         .section        .eh_frame,"aw",@progbits
1922 __FRAME_BEGIN__:
1923         .4byte  .LECIE1-.LSCIE1
1924 .LSCIE1:
1925         .4byte  0x0
1926         .byte   0x1
1927         .ascii "z\0"
1928         .byte   0x1
1929         .byte   0x78
1930         .byte   0x1a
1931         .byte   0x0
1932         .byte   0x4
1933         .4byte  1
1934         .p2align 1
1935 .LECIE1:
1936 .LSFDE1:
1937         .4byte  .LEFDE1-.LASFDE1
1938 .LASFDE1:
1939         .4byte  .LASFDE1-__FRAME_BEGIN__
1940         .4byte  .LFB1
1941         .4byte  .LFE1-.LFB1
1942         .byte   0x4
1943         .4byte  .LFE1-.LFB1
1944         .byte   0x4
1945         .4byte  .L1-.LFB1
1946 .LEFDE1:],
1947 [  cat > conftest.lit <<EOF
1948  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1949  0010 01000000 12000000 18000000 00000000  ................
1950  0020 08000000 04080000 0044               .........D
1951 EOF
1952   cat > conftest.big <<EOF
1953  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1954  0010 00000001 00000012 00000018 00000000  ................
1955  0020 00000008 04000000 0844               .........D
1956 EOF
1957   # If the assembler didn't choke, and we can objdump,
1958   # and we got the correct data, then succeed.
1959   if test x$gcc_cv_objdump != x \
1960   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1961      | tail -3 > conftest.got \
1962   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1963     || cmp conftest.big conftest.got > /dev/null 2>&1; }
1964   then
1965     gcc_cv_as_eh_frame=yes
1966   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
1967     gcc_cv_as_eh_frame=buggy
1968   else
1969     # Uh oh, what do we do now?
1970     gcc_cv_as_eh_frame=no
1971   fi])
1972
1973 if test $gcc_cv_as_eh_frame = buggy; then
1974   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1975   [Define if your assembler mis-optimizes .eh_frame data.])
1976 fi
1977
1978 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
1979  [elf,2,12,0], [--fatal-warnings],
1980  [.section .rodata.str, "aMS", @progbits, 1],,
1981  [AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1982 [Define if your assembler supports marking sections with SHF_MERGE flag.])])
1983
1984 # Thread-local storage - the check is heavily parametrized.
1985 conftest_s=
1986 tls_first_major=
1987 tls_first_minor=
1988 tls_as_opt=
1989 case "$target" in
1990 changequote(,)dnl
1991   alpha*-*-*)
1992     conftest_s='
1993         .section ".tdata","awT",@progbits
1994 foo:    .long   25
1995         .text
1996         ldq     $27,__tls_get_addr($29)         !literal!1
1997         lda     $16,foo($29)                    !tlsgd!1
1998         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
1999         ldq     $27,__tls_get_addr($29)         !literal!2
2000         lda     $16,foo($29)                    !tlsldm!2
2001         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2002         ldq     $1,foo($29)                     !gotdtprel
2003         ldah    $2,foo($29)                     !dtprelhi
2004         lda     $3,foo($2)                      !dtprello
2005         lda     $4,foo($29)                     !dtprel
2006         ldq     $1,foo($29)                     !gottprel
2007         ldah    $2,foo($29)                     !tprelhi
2008         lda     $3,foo($2)                      !tprello
2009         lda     $4,foo($29)                     !tprel'
2010         tls_first_major=2
2011         tls_first_minor=13
2012         ;;
2013   i[34567]86-*-*)
2014     conftest_s='
2015         .section ".tdata","awT",@progbits
2016 foo:    .long   25
2017         .text
2018         movl    %gs:0, %eax
2019         leal    foo@TLSGD(,%ebx,1), %eax
2020         leal    foo@TLSLDM(%ebx), %eax
2021         leal    foo@DTPOFF(%eax), %edx
2022         movl    foo@GOTTPOFF(%ebx), %eax
2023         subl    foo@GOTTPOFF(%ebx), %eax
2024         addl    foo@GOTNTPOFF(%ebx), %eax
2025         movl    foo@INDNTPOFF, %eax
2026         movl    $foo@TPOFF, %eax
2027         subl    $foo@TPOFF, %eax
2028         leal    foo@NTPOFF(%ecx), %eax'
2029         tls_first_major=2
2030         tls_first_minor=14
2031         ;;
2032   x86_64-*-*)
2033     conftest_s='
2034         .section ".tdata","awT",@progbits
2035 foo:    .long   25
2036         .text
2037         movq    %fs:0, %rax
2038         leaq    foo@TLSGD(%rip), %rdi
2039         leaq    foo@TLSLD(%rip), %rdi
2040         leaq    foo@DTPOFF(%rax), %rdx
2041         movq    foo@GOTTPOFF(%rip), %rax
2042         movq    $foo@TPOFF, %rax'
2043         tls_first_major=2
2044         tls_first_minor=14
2045         ;;
2046   ia64-*-*)
2047     conftest_s='
2048         .section ".tdata","awT",@progbits
2049 foo:    data8   25
2050         .text
2051         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2052         addl    r17 = @ltoff(@dtprel(foo#)), gp
2053         addl    r18 = @ltoff(@tprel(foo#)), gp
2054         addl    r19 = @dtprel(foo#), gp
2055         adds    r21 = @dtprel(foo#), r13
2056         movl    r23 = @dtprel(foo#)
2057         addl    r20 = @tprel(foo#), gp
2058         adds    r22 = @tprel(foo#), r13
2059         movl    r24 = @tprel(foo#)'
2060         tls_first_major=2
2061         tls_first_minor=13
2062         ;;
2063   powerpc-*-*)
2064     conftest_s='
2065         .section ".tdata","awT",@progbits
2066         .align 2
2067 ld0:    .space 4
2068 ld1:    .space 4
2069 x1:     .space 4
2070 x2:     .space 4
2071 x3:     .space 4
2072         .text
2073         addi 3,31,ld0@got@tlsgd
2074         bl __tls_get_addr
2075         addi 3,31,x1@got@tlsld
2076         bl __tls_get_addr
2077         addi 9,3,x1@dtprel
2078         addis 9,3,x2@dtprel@ha
2079         addi 9,9,x2@dtprel@l
2080         lwz 9,x3@got@tprel(31)
2081         add 9,9,x@tls
2082         addi 9,2,x1@tprel
2083         addis 9,2,x2@tprel@ha
2084         addi 9,9,x2@tprel@l'
2085         tls_first_major=2
2086         tls_first_minor=14
2087         tls_as_opt=-a32
2088         ;;
2089   powerpc64-*-*)
2090     conftest_s='
2091         .section ".tdata","awT",@progbits
2092         .align 3
2093 ld0:    .space 8
2094 ld1:    .space 8
2095 x1:     .space 8
2096 x2:     .space 8
2097 x3:     .space 8
2098         .text
2099         addi 3,2,ld0@got@tlsgd
2100         bl .__tls_get_addr
2101         nop
2102         addi 3,2,ld1@toc
2103         bl .__tls_get_addr
2104         nop
2105         addi 3,2,x1@got@tlsld
2106         bl .__tls_get_addr
2107         nop
2108         addi 9,3,x1@dtprel
2109         bl .__tls_get_addr
2110         nop
2111         addis 9,3,x2@dtprel@ha
2112         addi 9,9,x2@dtprel@l
2113         bl .__tls_get_addr
2114         nop
2115         ld 9,x3@got@dtprel(2)
2116         add 9,9,3
2117         bl .__tls_get_addr
2118         nop'
2119         tls_first_major=2
2120         tls_first_minor=14
2121         tls_as_opt=-a64
2122         ;;
2123   s390-*-*)
2124     conftest_s='
2125         .section ".tdata","awT",@progbits
2126 foo:    .long   25
2127         .text
2128         .long   foo@TLSGD
2129         .long   foo@TLSLDM
2130         .long   foo@DTPOFF
2131         .long   foo@NTPOFF
2132         .long   foo@GOTNTPOFF
2133         .long   foo@INDNTPOFF
2134         l       %r1,foo@GOTNTPOFF(%r12)
2135         l       %r1,0(%r1):tls_load:foo
2136         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2137         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2138         tls_first_major=2
2139         tls_first_minor=14
2140         tls_as_opt=-m31
2141         ;;
2142   s390x-*-*)
2143     conftest_s='
2144         .section ".tdata","awT",@progbits
2145 foo:    .long   25
2146         .text
2147         .quad   foo@TLSGD
2148         .quad   foo@TLSLDM
2149         .quad   foo@DTPOFF
2150         .quad   foo@NTPOFF
2151         .quad   foo@GOTNTPOFF
2152         lg      %r1,foo@GOTNTPOFF(%r12)
2153         larl    %r1,foo@INDNTPOFF
2154         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2155         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2156         tls_first_major=2
2157         tls_first_minor=14
2158         tls_as_opt="-m64 -Aesame"
2159         ;;
2160   sparc*-*-*)
2161     conftest_s='
2162         .section ".tdata","awT",@progbits
2163 foo:    .long   25
2164         .text
2165         sethi   %tgd_hi22(foo), %o0
2166         add     %o0, %tgd_lo10(foo), %o1
2167         add     %l7, %o1, %o0, %tgd_add(foo)
2168         call    __tls_get_addr, %tgd_call(foo)
2169         sethi   %tldm_hi22(foo), %l1
2170         add     %l1, %tldm_lo10(foo), %l2
2171         add     %l7, %l2, %o0, %tldm_add(foo)
2172         call    __tls_get_addr, %tldm_call(foo)
2173         sethi   %tldo_hix22(foo), %l3
2174         xor     %l3, %tldo_lox10(foo), %l4
2175         add     %o0, %l4, %l5, %tldo_add(foo)
2176         sethi   %tie_hi22(foo), %o3
2177         add     %o3, %tie_lo10(foo), %o3
2178         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2179         add     %g7, %o2, %o4, %tie_add(foo)
2180         sethi   %tle_hix22(foo), %l1
2181         xor     %l1, %tle_lox10(foo), %o5
2182         ld      [%g7 + %o5], %o1'
2183         tls_first_major=2
2184         tls_first_minor=14
2185         tls_as_opt=-32
2186         ;;
2187 changequote([,])dnl
2188 esac
2189 if test -z "$tls_first_major"; then
2190   : # If we don't have a check, assume no support.
2191 else
2192   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2193   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt --fatal-warnings],
2194   [$conftest_s],,
2195   [AC_DEFINE(HAVE_AS_TLS, 1,
2196             [Define if your assembler supports thread-local storage.])])
2197 fi
2198
2199 # Target-specific assembler checks.
2200
2201 case "$target" in
2202   # All TARGET_ABI_OSF targets.
2203   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2204     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2205         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2206 [       .set nomacro
2207         .text
2208         extbl   $3, $2, $3      !lituse_bytoff!1
2209         ldq     $2, a($29)      !literal!1
2210         ldq     $4, b($29)      !literal!2
2211         ldq_u   $3, 0($2)       !lituse_base!1
2212         ldq     $27, f($29)     !literal!5
2213         jsr     $26, ($27), f   !lituse_jsr!5
2214         ldah    $29, 0($26)     !gpdisp!3
2215         lda     $0, c($29)      !gprel
2216         ldah    $1, d($29)      !gprelhigh
2217         lda     $1, d($1)       !gprellow
2218         lda     $29, 0($29)     !gpdisp!3],,
2219     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2220   [Define if your assembler supports explicit relocations.])])
2221     ;;
2222
2223   sparc*-*-*)
2224     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2225       [.register %g2, #scratch],,
2226       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2227                 [Define if your assembler supports .register.])])
2228
2229     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2230       [-relax], [.text],,
2231       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2232                 [Define if your assembler supports -relax option.])])
2233
2234     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2235       gcc_cv_as_sparc_ua_pcrel,,
2236       [-K PIC],
2237 [.text
2238 foo:
2239         nop
2240 .data
2241 .align 4
2242 .byte 0
2243 .uaword %r_disp32(foo)],
2244       [if test x$gcc_cv_ld != x \
2245        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2246          gcc_cv_as_sparc_ua_pcrel=yes
2247        fi
2248        rm -f conftest],
2249       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2250                 [Define if your assembler and linker support unaligned PC relative relocs.])
2251
2252       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2253         gcc_cv_as_sparc_ua_pcrel_hidden,,
2254         [-K PIC],
2255 [.data
2256 .align 4
2257 .byte 0x31
2258 .uaword %r_disp32(foo)
2259 .byte 0x32, 0x33, 0x34
2260 .global foo
2261 .hidden foo
2262 foo:
2263 .skip 4],
2264         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2265          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2266          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2267             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2268             if $gcc_cv_objdump -R conftest 2> /dev/null \
2269                | grep 'DISP32' > /dev/null 2>&1; then
2270                 :
2271             else
2272                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2273             fi
2274          fi
2275          rm -f conftest],
2276          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2277                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2278     ]) # unaligned pcrel relocs
2279
2280     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2281       gcc_cv_as_sparc_offsetable_lo10,,
2282       [-xarch=v9],
2283 [.text
2284         or %g1, %lo(ab) + 12, %g1
2285         or %g1, %lo(ab + 12), %g1],
2286       [if test x$gcc_cv_objdump != x \
2287        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2288           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2289          gcc_cv_as_offsetable_lo10=yes
2290        fi],
2291        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2292                  [Define if your assembler supports offsetable %lo().])])
2293     ;;
2294
2295 changequote(,)dnl
2296   i[34567]86-*-* | x86_64-*-*)
2297 changequote([,])dnl
2298     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2299        gcc_cv_as_ix86_filds_fists,
2300       [2,9,0],, [filds mem; fists mem],,
2301       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2302         [Define if your assembler uses the new HImode fild and fist notation.])])
2303
2304     gcc_GAS_CHECK_FEATURE([cmov syntax],
2305       gcc_cv_as_ix86_cmov_sun_syntax,,,
2306       [cmovl.l %edx, %eax],,
2307       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2308         [Define if your assembler supports the Sun syntax for cmov.])])
2309
2310     # This one is used unconditionally by i386.[ch]; it is to be defined
2311     # to 1 if the feature is present, 0 otherwise.
2312     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2313         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2314 [       .text
2315 .L0:
2316         nop
2317         .data
2318         .long .L0@GOTOFF])
2319     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2320       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2321       [Define true if the assembler supports '.long foo@GOTOFF'.])
2322     ;;
2323
2324   ia64*-*-*)
2325     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2326         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2327 [       .text
2328         addl r15 = @ltoffx(x#), gp
2329         ;;
2330         ld8.mov r16 = [[r15]], x#],,
2331     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2332           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2333
2334     ;;
2335
2336   powerpc*-*-*)
2337     case $target in
2338       *-*-aix) conftest_s='     .csect .text[PR]';;
2339       *)       conftest_s='     .text';;
2340     esac
2341     conftest_s="$conftest_s
2342         mfcr 3,128"
2343
2344     gcc_GAS_CHECK_FEATURE([mfcr field support],
2345       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2346       [$conftest_s],,
2347       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2348           [Define if your assembler supports mfcr field.])])
2349     ;;
2350
2351   mips*-*-*)
2352     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2353       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2354 [       lw $4,%gp_rel(foo)($4)],,
2355       [if test x$target_cpu_default = x
2356        then target_cpu_default=MASK_EXPLICIT_RELOCS
2357        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2358        fi])
2359
2360     ;;
2361 esac
2362 # ??? Not all targets support dwarf2 debug_line, even within a version
2363 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2364 # info to the output file.  So, as supported targets are added to gas 2.11,
2365 # add some instruction here to (also) show we expect this might work.
2366 # ??? Once 2.11 is released, probably need to add first known working
2367 # version to the per-target configury.
2368 case "$target" in
2369   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2370   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2371   | xstormy16*-*-* | cris-*-*)
2372     insn="nop"
2373     ;;
2374   ia64*-*-*)
2375     insn="nop 0"
2376     ;;
2377   mmix-*-*)
2378     insn="swym 0"
2379     ;;
2380 esac
2381 if test x"$insn" != x; then
2382  conftest_s="\
2383         .file 1 \"conftest.s\"
2384         .loc 1 3 0
2385         $insn"
2386  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2387   gcc_cv_as_dwarf2_debug_line,
2388   [elf,2,11,0],, [$conftest_s],
2389   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2390    if grep debug_line conftest.o > /dev/null 2>&1; then
2391      gcc_cv_as_dwarf2_debug_line=yes
2392    fi])
2393
2394 # The .debug_line file table must be in the exact order that
2395 # we specified the files, since these indices are also used
2396 # by DW_AT_decl_file.  Approximate this test by testing if
2397 # the assembler bitches if the same index is assigned twice.
2398  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2399   gcc_cv_as_dwarf2_file_buggy,,,
2400 [       .file 1 "foo.s"
2401         .file 1 "bar.s"])
2402
2403  if test $gcc_cv_as_dwarf2_debug_line = yes \
2404  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2405         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2406   [Define if your assembler supports dwarf2 .file/.loc directives,
2407    and preserves file table indices exactly as given.])
2408  fi
2409
2410  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2411   gcc_cv_as_gdwarf2_flag,
2412   [elf,2,11,0], [--gdwarf2], [$insn],,
2413   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2414 [Define if your assembler supports the --gdwarf2 option.])])
2415
2416  gcc_GAS_CHECK_FEATURE([--gstabs option],
2417   gcc_cv_as_gstabs_flag,
2418   [elf,2,11,0], [--gstabs], [$insn],
2419   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2420    # and warns about it, but still exits successfully.  So check for
2421    # this.
2422    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2423    then :
2424    else gcc_cv_as_gstabs_flag=yes
2425    fi],
2426   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2427 [Define if your assembler supports the --gstabs option.])])
2428 fi
2429
2430 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2431 gcc_cv_ld_ro_rw_mix=unknown
2432 if test $in_tree_ld = yes ; then
2433   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2434      && test $in_tree_ld_is_elf = yes; then
2435     gcc_cv_ld_ro_rw_mix=read-write
2436   fi
2437 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2438   echo '.section myfoosect, "a"' > conftest1.s
2439   echo '.section myfoosect, "aw"' > conftest2.s
2440   echo '.byte 1' >> conftest2.s
2441   echo '.section myfoosect, "a"' > conftest3.s
2442   echo '.byte 0' >> conftest3.s
2443   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2444      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2445      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2446      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2447         conftest2.o conftest3.o > /dev/null 2>&1; then
2448     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2449                          | sed -e '/myfoosect/!d' -e N`
2450     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2451       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2452         gcc_cv_ld_ro_rw_mix=read-only
2453       else
2454         gcc_cv_ld_ro_rw_mix=read-write
2455       fi
2456     fi
2457   fi
2458 changequote(,)dnl
2459   rm -f conftest.* conftest[123].*
2460 changequote([,])dnl
2461 fi
2462 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2463         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2464   [Define if your linker links a mix of read-only
2465    and read-write sections into a read-write section.])
2466 fi
2467 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2468
2469 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2470 gcc_cv_ld_eh_frame_hdr=no
2471 if test $in_tree_ld = yes ; then
2472   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2473      && test $in_tree_ld_is_elf = yes; then
2474     gcc_cv_ld_eh_frame_hdr=yes
2475   fi
2476 elif test x$gcc_cv_ld != x; then
2477         # Check if linker supports --eh-frame-hdr option
2478         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2479                 gcc_cv_ld_eh_frame_hdr=yes
2480         fi
2481 fi
2482 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2483         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2484 [Define if your linker supports --eh-frame-hdr option.])
2485 fi
2486 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2487
2488 AC_MSG_CHECKING(linker position independent executable support)
2489 gcc_cv_ld_pie=no
2490 if test $in_tree_ld = yes ; then
2491   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2492      && test $in_tree_ld_is_elf = yes; then
2493     gcc_cv_ld_pie=yes
2494   fi
2495 elif test x$gcc_cv_ld != x; then
2496         # Check if linker supports -pie option
2497         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2498                 gcc_cv_ld_pie=yes
2499         fi
2500 fi
2501 if test x"$gcc_cv_ld_pie" = xyes; then
2502         AC_DEFINE(HAVE_LD_PIE, 1,
2503 [Define if your linker supports -pie option.])
2504 fi
2505 AC_MSG_RESULT($gcc_cv_ld_pie)
2506
2507 # Miscellaneous target-specific checks.
2508 case "$target" in
2509   mips*-*-*)
2510     AC_MSG_CHECKING(whether libgloss uses STARTUP directives consistently)
2511     gcc_cv_mips_libgloss_startup=no
2512     gcc_cv_libgloss_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/libgloss
2513     if test "x$exec_prefix" = xNONE; then
2514       if test "x$prefix" = xNONE; then
2515         test_prefix=/usr/local
2516       else
2517         test_prefix=$prefix
2518       fi
2519     else
2520       test_prefix=$exec_prefix
2521     fi
2522     for f in $gcc_cv_libgloss_srcdir/mips/idt.ld $test_prefix/$target_alias/lib/idt.ld
2523     do
2524       if grep '^STARTUP' $f > /dev/null 2>&1; then
2525         gcc_cv_mips_libgloss_startup=yes
2526         break
2527       fi
2528     done
2529     if test x"$gcc_cv_mips_libgloss_startup" = xyes; then
2530       AC_DEFINE(HAVE_MIPS_LIBGLOSS_STARTUP_DIRECTIVES, 1,
2531         [Define if your MIPS libgloss linker scripts consistently include STARTUP directives.])
2532     fi
2533     AC_MSG_RESULT($gcc_cv_mips_libgloss_startup)
2534     ;;
2535 esac
2536
2537 if test x$with_sysroot = x && test x$host = x$target \
2538    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2539   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2540 [Define to PREFIX/include if cpp should also search that directory.])
2541 fi
2542
2543 # Figure out what language subdirectories are present.
2544 # Look if the user specified --enable-languages="..."; if not, use
2545 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2546 # go away some day.
2547 # NB:  embedded tabs in this IF block -- do not untabify
2548 if test x"${enable_languages+set}" != xset; then
2549         if test x"${LANGUAGES+set}" = xset; then
2550                 enable_languages="${LANGUAGES}"
2551                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2552
2553         else
2554                 enable_languages=all
2555         fi
2556 else
2557         if test x"${enable_languages}" = x \
2558         || test x"${enable_languages}" = xyes;
2559         then
2560                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2561         fi
2562 fi
2563 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2564
2565 # First scan to see if an enabled language requires some other language.
2566 # We assume that a given config-lang.in will list all the language
2567 # front ends it requires, even if some are required indirectly.
2568 for lang in ${srcdir}/*/config-lang.in
2569 do
2570    case $lang in
2571     # The odd quoting in the next line works around
2572     # an apparent bug in bash 1.12 on linux.
2573 changequote(,)dnl
2574     ${srcdir}/[*]/config-lang.in)
2575        ;;
2576     *)
2577        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2578        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2579        for other in $this_lang_requires
2580        do
2581           case ,${enable_languages}, in
2582            *,$other,*)
2583               ;;
2584            *,all,*)
2585               ;;
2586            *,$lang_alias,*)
2587               enable_languages="$enable_languages,$other"
2588               ;;
2589           esac
2590        done
2591        ;;
2592 changequote([,])dnl
2593    esac
2594 done
2595
2596 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2597 found_languages=
2598 subdirs=
2599 for lang in ${srcdir}/*/config-lang.in
2600 do
2601         case $lang in
2602         # The odd quoting in the next line works around
2603         # an apparent bug in bash 1.12 on linux.
2604 changequote(,)dnl
2605         ${srcdir}/[*]/config-lang.in) ;;
2606         *)
2607           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2608           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2609           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2610           if test "x$lang_alias" = x
2611           then
2612                 echo "$lang doesn't set \$language." 1>&2
2613                 exit 1
2614           fi
2615           case ${build_by_default},${enable_languages}, in
2616           *,$lang_alias,*) add_this_lang=yes ;;
2617           no,*) add_this_lang=no ;;
2618           *,all,*) add_this_lang=yes ;;
2619           *) add_this_lang=no ;;
2620           esac
2621           found_languages="${found_languages} ${lang_alias}"
2622           if test x"${add_this_lang}" = xyes; then
2623                 case $lang in
2624                     ${srcdir}/ada/config-lang.in)
2625                         if test x$have_gnat = xyes ; then
2626                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2627                         fi
2628                         ;;
2629                     *)
2630                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2631                         ;;
2632                 esac
2633           fi
2634           ;;
2635 changequote([,])dnl
2636         esac
2637 done
2638
2639 missing_languages=
2640 for expected_language in ${expected_languages} ..
2641 do
2642     if test "${expected_language}" != ..; then
2643         missing_language="${expected_language}"
2644         if test "${expected_language}" = "c" \
2645            || test "${expected_language}" = "all"; then
2646                 missing_language=
2647         fi
2648         for found_language in ${found_languages} ..
2649         do
2650             if test "${found_language}" != ..; then
2651                 if test "${expected_language}" = "${found_language}"; then
2652                     missing_language=
2653                 fi
2654             fi
2655         done
2656         if test "x${missing_language}" != x; then
2657            missing_languages="${missing_languages} ${missing_language}"
2658         fi
2659     fi
2660 done
2661
2662 if test "x$missing_languages" != x; then
2663   AC_MSG_ERROR([
2664 The following requested languages were not found:${missing_languages}
2665 The following languages were available: c${found_languages}])
2666 fi
2667
2668 # Make gthr-default.h if we have a thread file.
2669 gthread_flags=
2670 if test $thread_file != single; then
2671     rm -f gthr-default.h
2672     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2673     gthread_flags=-DHAVE_GTHR_DEFAULT
2674 fi
2675 AC_SUBST(gthread_flags)
2676
2677 # Find out what GC implementation we want, or may, use.
2678 AC_ARG_WITH(gc,
2679 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2680                           with the compiler],
2681 [case "$withval" in
2682   simple | page)
2683     GGC=ggc-$withval
2684     ;;
2685   *)
2686     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2687     ;;
2688 esac],
2689 [GGC=ggc-page])
2690 AC_SUBST(GGC)
2691 echo "Using $GGC for garbage collection."
2692
2693 # Use the system's zlib library.
2694 zlibdir=-L../zlib
2695 zlibinc="-I\$(srcdir)/../zlib"
2696 AC_ARG_WITH(system-zlib,
2697 [  --with-system-zlib      use installed libz],
2698 zlibdir=
2699 zlibinc=
2700 )
2701 AC_SUBST(zlibdir)
2702 AC_SUBST(zlibinc)
2703
2704 dnl Very limited version of automake's enable-maintainer-mode
2705
2706 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2707   dnl maintainer-mode is disabled by default
2708   AC_ARG_ENABLE(maintainer-mode,
2709 [  --enable-maintainer-mode
2710                           enable make rules and dependencies not useful
2711                           (and sometimes confusing) to the casual installer],
2712       maintainer_mode=$enableval,
2713       maintainer_mode=no)
2714
2715 AC_MSG_RESULT($maintainer_mode)
2716
2717 if test "$maintainer_mode" = "yes"; then
2718   MAINT=''
2719 else
2720   MAINT='#'
2721 fi
2722 AC_SUBST(MAINT)dnl
2723
2724 # Make empty files to contain the specs and options for each language.
2725 # Then add #include lines to for a compiler that has specs and/or options.
2726
2727 lang_opt_files=
2728 lang_specs_files=
2729 lang_tree_files=
2730 for subdir in . $subdirs
2731 do
2732         if test -f $srcdir/$subdir/lang.opt; then
2733             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2734         fi
2735         if test -f $srcdir/$subdir/lang-specs.h; then
2736             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2737         fi
2738         if test -f $srcdir/$subdir/$subdir-tree.def; then
2739             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2740         fi
2741 done
2742
2743 # These (without "all_") are set in each config-lang.in.
2744 # `language' must be a single word so is spelled singularly.
2745 all_languages=
2746 all_boot_languages=
2747 all_compilers=
2748 all_stagestuff=
2749 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2750 # List of language makefile fragments.
2751 all_lang_makefrags=
2752 # List of language subdirectory makefiles.  Deprecated.
2753 all_lang_makefiles=
2754 # Files for gengtype
2755 all_gtfiles="$target_gtfiles"
2756 # Files for gengtype with language
2757 all_gtfiles_files_langs=
2758 all_gtfiles_files_files=
2759
2760 # Add the language fragments.
2761 # Languages are added via two mechanisms.  Some information must be
2762 # recorded in makefile variables, these are defined in config-lang.in.
2763 # We accumulate them and plug them into the main Makefile.
2764 # The other mechanism is a set of hooks for each of the main targets
2765 # like `clean', `install', etc.
2766
2767 language_hooks="Make-hooks"
2768
2769 for s in $subdirs
2770 do
2771                 language=
2772                 boot_language=
2773                 compilers=
2774                 stagestuff=
2775                 outputs=
2776                 gtfiles=
2777                 . ${srcdir}/$s/config-lang.in
2778                 if test "x$language" = x
2779                 then
2780                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2781                         exit 1
2782                 fi
2783                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2784                 if test -f ${srcdir}/$s/Makefile.in
2785                 then all_lang_makefiles="$s/Makefile"
2786                 fi
2787                 all_languages="$all_languages $language"
2788                 if test "x$boot_language" = xyes
2789                 then
2790                         all_boot_languages="$all_boot_languages $language"
2791                 fi
2792                 all_compilers="$all_compilers $compilers"
2793                 all_stagestuff="$all_stagestuff $stagestuff"
2794                 all_outputs="$all_outputs $outputs"
2795                 all_gtfiles="$all_gtfiles $gtfiles"
2796                 for f in $gtfiles
2797                 do
2798                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2799                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2800                 done
2801 done
2802
2803 # Pick up gtfiles for c
2804 gtfiles=
2805 s="c"
2806 . ${srcdir}/c-config-lang.in
2807 all_gtfiles="$all_gtfiles $gtfiles"
2808 for f in $gtfiles
2809 do
2810         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2811         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2812 done
2813
2814 check_languages=
2815 for language in $all_languages
2816 do
2817                 check_languages="$check_languages check-$language"
2818 done
2819
2820 # Since we can't use `::' targets, we link each language in
2821 # with a set of hooks, reached indirectly via lang.${target}.
2822
2823 rm -f Make-hooks
2824 touch Make-hooks
2825 target_list="all.build all.cross start.encap rest.encap tags \
2826         info dvi generated-manpages \
2827         install-normal install-common install-info install-man \
2828         uninstall \
2829         mostlyclean clean distclean extraclean maintainer-clean \
2830         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2831 for t in $target_list
2832 do
2833         x=
2834         for lang in $all_languages
2835         do
2836                         x="$x $lang.$t"
2837         done
2838         echo "lang.$t: $x" >> Make-hooks
2839 done
2840
2841 # Create .gdbinit.
2842
2843 echo "dir ." > .gdbinit
2844 echo "dir ${srcdir}" >> .gdbinit
2845 if test x$gdb_needs_out_file_path = xyes
2846 then
2847         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2848 fi
2849 if test "x$subdirs" != x; then
2850         for s in $subdirs
2851         do
2852                 echo "dir ${srcdir}/$s" >> .gdbinit
2853         done
2854 fi
2855 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2856
2857 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2858 # absolute path for gcc_tooldir based on inserting the number of up-directory
2859 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2860 # $(libsubdir)/@(unlibsubdir) based path.
2861 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2862 # make and thus we'd get different behavior depending on where we built the
2863 # sources.
2864 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2865     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2866 else
2867 changequote(<<, >>)dnl
2868 # An explanation of the sed strings:
2869 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2870 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2871 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2872 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2873 #
2874 # (*) Note this pattern overwrites the first character of the string
2875 # with a forward slash if one is not already present.  This is not a
2876 # problem because the exact names of the sub-directories concerned is
2877 # unimportant, just the number of them matters.
2878 #
2879 # The practical upshot of these patterns is like this:
2880 #
2881 #  prefix     exec_prefix        result
2882 #  ------     -----------        ------
2883 #   /foo        /foo/bar          ../
2884 #   /foo/       /foo/bar          ../
2885 #   /foo        /foo/bar/         ../
2886 #   /foo/       /foo/bar/         ../
2887 #   /foo        /foo/bar/ugg      ../../
2888 #
2889     dollar='$$'
2890     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2891 changequote([, ])dnl
2892 fi
2893 AC_SUBST(gcc_tooldir)
2894 AC_SUBST(dollar)
2895
2896 # Find a directory in which to install a shared libgcc.
2897
2898 AC_ARG_ENABLE(version-specific-runtime-libs,
2899 [  --enable-version-specific-runtime-libs
2900                           specify that runtime libraries should be
2901                           installed in a compiler-specific directory])
2902
2903 AC_ARG_WITH(slibdir,
2904 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2905 slibdir="$with_slibdir",
2906 if test "${enable_version_specific_runtime_libs+set}" = set; then
2907   slibdir='$(libsubdir)'
2908 elif test "$host" != "$target"; then
2909   slibdir='$(build_tooldir)/lib'
2910 else
2911   slibdir='$(libdir)'
2912 fi)
2913 AC_SUBST(slibdir)
2914
2915 objdir=`${PWDCMD-pwd}`
2916 AC_SUBST(objdir)
2917
2918 # Substitute configuration variables
2919 AC_SUBST(subdirs)
2920 AC_SUBST(srcdir)
2921 AC_SUBST(all_boot_languages)
2922 AC_SUBST(all_compilers)
2923 AC_SUBST(all_gtfiles)
2924 AC_SUBST(all_gtfiles_files_langs)
2925 AC_SUBST(all_gtfiles_files_files)
2926 AC_SUBST(all_lang_makefrags)
2927 AC_SUBST(all_lang_makefiles)
2928 AC_SUBST(all_languages)
2929 AC_SUBST(all_stagestuff)
2930 AC_SUBST(build_exeext)
2931 AC_SUBST(build_install_headers_dir)
2932 AC_SUBST(build_xm_file_list)
2933 AC_SUBST(build_xm_include_list)
2934 AC_SUBST(build_xm_defines)
2935 AC_SUBST(check_languages)
2936 AC_SUBST(cc_set_by_configure)
2937 AC_SUBST(quoted_cc_set_by_configure)
2938 AC_SUBST(cpp_install_dir)
2939 AC_SUBST(xmake_file)
2940 AC_SUBST(tmake_file)
2941 AC_SUBST(extra_headers_list)
2942 AC_SUBST(extra_objs)
2943 AC_SUBST(extra_parts)
2944 AC_SUBST(extra_passes)
2945 AC_SUBST(extra_programs)
2946 AC_SUBST(float_h_file)
2947 AC_SUBST(gcc_config_arguments)
2948 AC_SUBST(gcc_gxx_include_dir)
2949 AC_SUBST(libstdcxx_incdir)
2950 AC_SUBST(gcc_version)
2951 AC_SUBST(gcc_version_full)
2952 AC_SUBST(gcc_version_trigger)
2953 AC_SUBST(host_exeext)
2954 AC_SUBST(host_extra_gcc_objs)
2955 AC_SUBST(host_xm_file_list)
2956 AC_SUBST(host_xm_include_list)
2957 AC_SUBST(host_xm_defines)
2958 AC_SUBST(out_host_hook_obj)
2959 AC_SUBST(install)
2960 AC_SUBST(lang_opt_files)
2961 AC_SUBST(lang_specs_files)
2962 AC_SUBST(lang_tree_files)
2963 AC_SUBST(local_prefix)
2964 AC_SUBST(md_file)
2965 AC_SUBST(objc_boehm_gc)
2966 AC_SUBST(out_file)
2967 AC_SUBST(out_object_file)
2968 AC_SUBST(stage_prefix_set_by_configure)
2969 AC_SUBST(quoted_stage_prefix_set_by_configure)
2970 AC_SUBST(symbolic_link)
2971 AC_SUBST(thread_file)
2972 AC_SUBST(tm_file_list)
2973 AC_SUBST(tm_include_list)
2974 AC_SUBST(tm_defines)
2975 AC_SUBST(tm_p_file_list)
2976 AC_SUBST(tm_p_include_list)
2977 AC_SUBST(xm_file_list)
2978 AC_SUBST(xm_include_list)
2979 AC_SUBST(xm_defines)
2980 AC_SUBST(target_alias)
2981 AC_SUBST(c_target_objs)
2982 AC_SUBST(cxx_target_objs)
2983 AC_SUBST(target_cpu_default)
2984
2985 AC_SUBST_FILE(language_hooks)
2986
2987 # Echo that links are built
2988 if test x$host = x$target
2989 then
2990         str1="native "
2991 else
2992         str1="cross-"
2993         str2=" from $host"
2994 fi
2995
2996 if test x$host != x$build
2997 then
2998         str3=" on a $build system"
2999 fi
3000
3001 if test "x$str2" != x || test "x$str3" != x
3002 then
3003         str4=
3004 fi
3005
3006 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
3007
3008 if test "x$str2" != x || test "x$str3" != x
3009 then
3010         echo " ${str2}${str3}." 1>&2
3011 fi
3012
3013 # Configure the subdirectories
3014 # AC_CONFIG_SUBDIRS($subdirs)
3015
3016 # Create the Makefile
3017 # and configure language subdirectories
3018 AC_OUTPUT($all_outputs,
3019 [
3020 case x$CONFIG_HEADERS in
3021 xauto-host.h:config.in)
3022 echo > cstamp-h ;;
3023 esac
3024 # Make sure all the subdirs exist.
3025 for d in $subdirs
3026 do
3027     test -d $d || mkdir $d
3028 done
3029 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3030 # bootstrapping and the installation procedure can still use
3031 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3032 # FLAGS_TO_PASS has been modified to solve the problem there.
3033 # This is virtually a duplicate of what happens in configure.lang; we do
3034 # an extra check to make sure this only happens if ln -s can be used.
3035 if test "$symbolic_link" = "ln -s"; then
3036  for d in ${subdirs} fixinc ; do
3037         STARTDIR=`${PWDCMD-pwd}`
3038         cd $d
3039         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3040         do
3041                 rm -f $t
3042                 $symbolic_link ../$t $t 2>/dev/null
3043         done
3044         cd $STARTDIR
3045  done
3046 else true ; fi
3047 ],
3048 [subdirs='$subdirs'
3049 symbolic_link='$symbolic_link'
3050 ])