gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.13)
  29 AC_INIT(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 # Determine the host, build, and target systems
  33 AC_CANONICAL_SYSTEM
  34
  35 # Determine the target- and build-specific subdirectories
  36 GCC_TOPLEV_SUBDIRS
  37
  38 # Set program_transform_name
  39 AC_ARG_PROGRAM
  40
  41 # Check for bogus environment variables.
  42 # Test if LIBRARY_PATH contains the notation for the current directory
  43 # since this would lead to problems installing/building glibc.
  44 # LIBRARY_PATH contains the current directory if one of the following
  45 # is true:
  46 # - one of the terminals (":" and ";") is the first or last sign
  47 # - two terminals occur directly after each other
  48 # - the path contains an element with a dot in it
  49 AC_MSG_CHECKING(LIBRARY_PATH variable)
  50 changequote(,)dnl
  51 case ${LIBRARY_PATH} in
  52   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  53     library_path_setting="contains current directory"
  54     ;;
  55   *)
  56     library_path_setting="ok"
  57     ;;
  58 esac
  59 changequote([,])dnl
  60 AC_MSG_RESULT($library_path_setting)
  61 if test "$library_path_setting" != "ok"; then
  62 AC_MSG_ERROR([
  63 *** LIBRARY_PATH shouldn't contain the current directory when
  64 *** building gcc. Please change the environment variable
  65 *** and run configure again.])
  66 fi
  67
  68 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  69 # since this would lead to problems installing/building glibc.
  70 # GCC_EXEC_PREFIX contains the current directory if one of the following
  71 # is true:
  72 # - one of the terminals (":" and ";") is the first or last sign
  73 # - two terminals occur directly after each other
  74 # - the path contains an element with a dot in it
  75 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  76 changequote(,)dnl
  77 case ${GCC_EXEC_PREFIX} in
  78   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  79     gcc_exec_prefix_setting="contains current directory"
  80     ;;
  81   *)
  82     gcc_exec_prefix_setting="ok"
  83     ;;
  84 esac
  85 changequote([,])dnl
  86 AC_MSG_RESULT($gcc_exec_prefix_setting)
  87 if test "$gcc_exec_prefix_setting" != "ok"; then
  88 AC_MSG_ERROR([
  89 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  90 *** building gcc. Please change the environment variable
  91 *** and run configure again.])
  92 fi
  93
  94 # -----------
  95 # Directories
  96 # -----------
  97
  98 # Specify the local prefix
  99 local_prefix=
 100 AC_ARG_WITH(local-prefix,
 101 [  --with-local-prefix=DIR specifies directory to put local include],
 102 [case "${withval}" in
 103 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 104 no)     ;;
 105 *)      local_prefix=$with_local_prefix ;;
 106 esac])
 107
 108 # Default local prefix if it is empty
 109 if test x$local_prefix = x; then
 110         local_prefix=/usr/local
 111 fi
 112
 113 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 114 # passed in by the toplevel make and thus we'd get different behavior
 115 # depending on where we built the sources.
 116 gcc_gxx_include_dir=
 117 # Specify the g++ header file directory
 118 AC_ARG_WITH(gxx-include-dir,
 119 [  --with-gxx-include-dir=DIR
 120                           specifies directory to put g++ header files],
 121 [case "${withval}" in
 122 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 123 no)     ;;
 124 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 125 esac])
 126
 127 if test x${gcc_gxx_include_dir} = x; then
 128   if test x${enable_version_specific_runtime_libs} = xyes; then
 129     gcc_gxx_include_dir='${libsubdir}/include/c++'
 130   else
 131     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 132 changequote(<<, >>)dnl
 133     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 134 changequote([, ])dnl
 135   fi
 136 fi
 137
 138 AC_ARG_WITH(cpp_install_dir,
 139 [  --with-cpp-install-dir=DIR
 140                           install the user visible C preprocessor in DIR
 141                           (relative to PREFIX) as well as PREFIX/bin],
 142 [if test x$withval = xyes; then
 143   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 144 elif test x$withval != xno; then
 145   cpp_install_dir=$withval
 146 fi])
 147
 148 # -------------------
 149 # Find default linker
 150 # -------------------
 151
 152 # With GNU ld
 153 AC_ARG_WITH(gnu-ld,
 154 [  --with-gnu-ld           arrange to work with GNU ld.],
 155 gnu_ld_flag="$with_gnu_ld",
 156 gnu_ld_flag=no)
 157
 158 # With pre-defined ld
 159 AC_ARG_WITH(ld,
 160 [  --with-ld               arrange to use the specified ld (full pathname)],
 161 DEFAULT_LINKER="$with_ld")
 162 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 163   if test ! -x "$DEFAULT_LINKER"; then
 164     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 165   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 166     gnu_ld_flag=yes
 167   fi
 168   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 169         [Define to enable the use of a default linker.])
 170 fi
 171
 172 AC_MSG_CHECKING([whether a default linker was specified])
 173 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 174   if test x"$gnu_ld_flag" = x"no"; then
 175     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 176   else
 177     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 178   fi
 179 else
 180   AC_MSG_RESULT(no)
 181 fi
 182
 183 # ----------------------
 184 # Find default assembler
 185 # ----------------------
 186
 187 # With GNU as
 188 AC_ARG_WITH(gnu-as,
 189 [  --with-gnu-as           arrange to work with GNU as],
 190 gas_flag="$with_gnu_as",
 191 gas_flag=no)
 192
 193 AC_ARG_WITH(as,
 194 [  --with-as               arrange to use the specified as (full pathname)],
 195 DEFAULT_ASSEMBLER="$with_as")
 196 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_ASSEMBLER"; then
 198     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 199   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gas_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 203         [Define to enable the use of a default assembler.])
 204 fi
 205
 206 AC_MSG_CHECKING([whether a default assembler was specified])
 207 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 208   if test x"$gas_flag" = x"no"; then
 209     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 210   else
 211     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 212   fi
 213 else
 214   AC_MSG_RESULT(no)
 215 fi
 216
 217 # ---------------
 218 # Find C compiler
 219 # ---------------
 220
 221 # Find the native compiler
 222 AC_PROG_CC
 223 AC_PROG_CC_C_O
 224 # autoconf is lame and doesn't give us any substitution variable for this.
 225 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 226   NO_MINUS_C_MINUS_O=yes
 227 else
 228   OUTPUT_OPTION='-o $@'
 229 fi
 230 AC_SUBST(NO_MINUS_C_MINUS_O)
 231 AC_SUBST(OUTPUT_OPTION)
 232
 233 # -------------------------
 234 # Check C compiler features
 235 # -------------------------
 236
 237 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 238 ac_cv_prog_cc_no_long_long,
 239 [save_CFLAGS="$CFLAGS"
 240 CFLAGS="-Wno-long-long"
 241 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 242                ac_cv_prog_cc_no_long_long=no)
 243 CFLAGS="$save_CFLAGS"])
 244
 245 AC_PROG_CPP
 246 AC_C_INLINE
 247
 248 gcc_AC_C_LONG_LONG
 249 gcc_AC_C__BOOL
 250
 251 # sizeof(char) is 1 by definition.
 252 AC_COMPILE_CHECK_SIZEOF(void *)
 253 AC_COMPILE_CHECK_SIZEOF(short)
 254 AC_COMPILE_CHECK_SIZEOF(int)
 255 AC_COMPILE_CHECK_SIZEOF(long)
 256 if test $ac_cv_c_long_long = yes; then
 257   AC_COMPILE_CHECK_SIZEOF(long long)
 258 fi
 259 if test $ac_cv_c___int64 = yes; then
 260   AC_COMPILE_CHECK_SIZEOF(__int64)
 261 fi
 262
 263 # -----------------
 264 # Find Ada compiler
 265 # -----------------
 266
 267 # See if GNAT has been installed
 268 gcc_AC_PROG_GNAT
 269
 270 if test x$have_gnat != xno ; then
 271 AC_CACHE_CHECK(whether ${ADAC} accepts -Wno-long-long,
 272 ac_cv_prog_adac_no_long_long,
 273 [cat >conftest.adb <<EOF
 274 procedure conftest is begin null; end conftest;
 275 EOF
 276 if $ADAC -Wno-long-long -c conftest.adb 1>&5 2>&5 ; then
 277   ac_cv_prog_adac_no_long_long=yes
 278 else
 279   ac_cv_prog_adac_no_long_long=no
 280 fi
 281 rm -f conftest*])
 282 else
 283   ac_cv_prog_adac_no_long_long=yes
 284 fi
 285
 286 # ---------------------
 287 # Warnings and checking
 288 # ---------------------
 289
 290 strict1_warn=
 291 if test $ac_cv_prog_cc_no_long_long = yes && \
 292     test $ac_cv_prog_adac_no_long_long = yes ; then
 293   strict1_warn="-pedantic -Wno-long-long"
 294 fi
 295 AC_SUBST(strict1_warn)
 296
 297 # If the native compiler is GCC, we can enable warnings even in stage1.
 298 # That's useful for people building cross-compilers, or just running a
 299 # quick `make'.
 300 warn_cflags=
 301 if test "x$GCC" = "xyes"; then
 302   warn_cflags='$(GCC_WARN_CFLAGS)'
 303 fi
 304 AC_SUBST(warn_cflags)
 305
 306 # Enable -Werror in bootstrap stage2 and later.
 307 # Change the default to "no" on release branches.
 308 AC_ARG_ENABLE(werror,
 309 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 310 [enable_werror=yes])
 311 if test x$enable_werror = xyes ; then
 312   WERROR=-Werror
 313 fi
 314 AC_SUBST(WERROR)
 315
 316 # Enable expensive internal checks
 317 AC_ARG_ENABLE(checking,
 318 [  --enable-checking[=LIST]
 319                           enable expensive run-time checks.  With LIST,
 320                           enable only specific categories of checks.
 321                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 322                           default is misc,tree,gc,rtlflag],
 323 [ac_checking=
 324 ac_tree_checking=
 325 ac_rtl_checking=
 326 ac_rtlflag_checking=
 327 ac_gc_checking=
 328 ac_gc_always_collect=
 329 ac_fold_checking=
 330 case "${enableval}" in
 331 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 332         ac_rtlflag_checking=1 ;;
 333 no)     ;;
 334 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 335         set fnord $enableval; shift
 336         IFS="$ac_save_IFS"
 337         for check
 338         do
 339                 case $check in
 340                 misc)   ac_checking=1 ;;
 341                 tree)   ac_tree_checking=1 ;;
 342                 rtlflag)        ac_rtlflag_checking=1 ;;
 343                 rtl)    ac_rtl_checking=1 ;;
 344                 gc)     ac_gc_checking=1 ;;
 345                 gcac)   ac_gc_always_collect=1 ;;
 346                 fold)   ac_fold_checking=1 ;;
 347                 valgrind)       ac_checking_valgrind=1 ;;
 348                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 349                 esac
 350         done
 351         ;;
 352 esac
 353 ],
 354 # Enable some checks by default for development versions of GCC
 355 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 356 nocommon_flag=""
 357 if test x$ac_checking != x ; then
 358   AC_DEFINE(ENABLE_CHECKING, 1,
 359 [Define if you want more run-time sanity checks.  This one gets a grab
 360    bag of miscellaneous but relatively cheap checks.])
 361   nocommon_flag=-fno-common
 362 fi
 363 AC_SUBST(nocommon_flag)
 364 if test x$ac_tree_checking != x ; then
 365   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 366 [Define if you want all operations on trees (the basic data
 367    structure of the front ends) to be checked for dynamic type safety
 368    at runtime.  This is moderately expensive.])
 369 fi
 370 if test x$ac_rtl_checking != x ; then
 371   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 372 [Define if you want all operations on RTL (the basic data structure
 373    of the optimizer and back end) to be checked for dynamic type safety
 374    at runtime.  This is quite expensive.])
 375 fi
 376 if test x$ac_rtlflag_checking != x ; then
 377   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 378 [Define if you want RTL flag accesses to be checked against the RTL
 379    codes that are supported for each access macro.  This is relatively
 380    cheap.])
 381 fi
 382 if test x$ac_gc_checking != x ; then
 383   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 384 [Define if you want the garbage collector to do object poisoning and
 385    other memory allocation checks.  This is quite expensive.])
 386 fi
 387 if test x$ac_gc_always_collect != x ; then
 388   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 389 [Define if you want the garbage collector to operate in maximally
 390    paranoid mode, validating the entire heap and collecting garbage at
 391    every opportunity.  This is extremely expensive.])
 392 fi
 393 if test x$ac_fold_checking != x ; then
 394   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 395 [Define if you want fold checked that it never destructs its argument.
 396    This is quite expensive.])
 397 fi
 398 valgrind_path_defines=
 399 valgrind_command=
 400 if test x$ac_checking_valgrind != x ; then
 401   # It is certainly possible that there's valgrind but no valgrind.h.
 402   # GCC relies on making annotations so we must have both.
 403   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 404   AC_TRY_CPP(
 405     [#include <memcheck.h>
 406 #ifndef VALGRIND_DISCARD
 407 #error VALGRIND_DISCARD not defined
 408 #endif],
 409   [gcc_cv_header_memcheck_h=yes],
 410   gcc_cv_header_memcheck_h=no)
 411   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 412   AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 413   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 414         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 415   if test "x$valgrind_path" = "x" || (test $have_valgrind_h = no && test $gcc_cv_header_memcheck_h = no); then
 416         AC_MSG_ERROR([*** Can't find both valgrind and valgrind.h/memcheck.h])
 417   fi
 418   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 419   valgrind_command="$valgrind_path -q"
 420   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 421 [Define if you want to run subprograms and generated programs
 422    through valgrind (a memory checker).  This is extremely expensive.])
 423   if test $gcc_cv_header_memcheck_h = yes; then
 424     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 425         [Define if valgrind's memcheck.h header is installed.])
 426   fi
 427 fi
 428 AC_SUBST(valgrind_path_defines)
 429 AC_SUBST(valgrind_command)
 430
 431 # Enable code coverage collection
 432 AC_ARG_ENABLE(coverage,
 433 [  --enable-coverage[=LEVEL]
 434                           enable compiler\'s code coverage collection.
 435                           Use to measure compiler performance and locate
 436                           unused parts of the compiler. With LEVEL, specify
 437                           optimization. Values are opt, noopt,
 438                           default is noopt],
 439 [case "${enableval}" in
 440 yes|noopt)
 441         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 442         ;;
 443 opt)
 444         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 445         ;;
 446 *)
 447         AC_MSG_ERROR(unknown coverage setting $enableval)
 448         ;;
 449 esac],
 450 [coverage_flags=""])
 451 AC_SUBST(coverage_flags)
 452
 453 # -------------------------------
 454 # Miscenalleous configure options
 455 # -------------------------------
 456
 457 # With stabs
 458 AC_ARG_WITH(stabs,
 459 [  --with-stabs            arrange to use stabs instead of host debug format],
 460 stabs="$with_stabs",
 461 stabs=no)
 462
 463 # Determine whether or not multilibs are enabled.
 464 AC_ARG_ENABLE(multilib,
 465 [  --enable-multilib       enable library support for multiple ABIs],
 466 [], [enable_multilib=yes])
 467 AC_SUBST(enable_multilib)
 468
 469 # Enable __cxa_atexit for C++.
 470 AC_ARG_ENABLE(__cxa_atexit,
 471 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 472 [], [])
 473
 474 # Enable threads
 475 # Pass with no value to take the default
 476 # Pass with a value to specify a thread package
 477 AC_ARG_ENABLE(threads,
 478 [  --enable-threads        enable thread usage for target GCC
 479   --enable-threads=LIB    use LIB thread package for target GCC],,
 480 enable_threads='')
 481 # Save in case it gets overwritten in config.gcc
 482 enable_threads_flag=$enable_threads
 483
 484 AC_ARG_ENABLE(objc-gc,
 485 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 486                           the GNU Objective-C runtime],
 487 if test x$enable_objc_gc = xno; then
 488         objc_boehm_gc=''
 489 else
 490         objc_boehm_gc=1
 491 fi,
 492 objc_boehm_gc='')
 493
 494 AC_ARG_WITH(dwarf2,
 495 [  --with-dwarf2           force the default debug format to be DWARF 2],
 496 dwarf2="$with_dwarf2",
 497 dwarf2=no)
 498
 499 AC_ARG_ENABLE(shared,
 500 [  --disable-shared        don't provide a shared libgcc],
 501 [
 502   case $enable_shared in
 503   yes | no) ;;
 504   *)
 505     enable_shared=no
 506     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 507     for pkg in $enableval; do
 508       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 509         enable_shared=yes
 510       fi
 511     done
 512     IFS="$ac_save_ifs"
 513     ;;
 514   esac
 515 ], [enable_shared=yes])
 516 AC_SUBST(enable_shared)
 517
 518 AC_ARG_WITH(sysroot,
 519 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 520 [
 521  case ${with_sysroot} in
 522  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 523  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 524  esac
 525
 526  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 527  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 528
 529  if test "x$exec_prefix" = xNONE; then
 530   if test "x$prefix" = xNONE; then
 531    test_prefix=/usr/local
 532   else
 533    test_prefix=$prefix
 534   fi
 535  else
 536   test_prefix=$exec_prefix
 537  fi
 538  case ${TARGET_SYSTEM_ROOT} in
 539  "${test_prefix}"|"${test_prefix}/"*|\
 540  '${exec_prefix}'|'${exec_prefix}/'*)
 541    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 542    TARGET_SYSTEM_ROOT_DEFINE="$t"
 543    ;;
 544  esac
 545 ], [
 546  TARGET_SYSTEM_ROOT=
 547  TARGET_SYSTEM_ROOT_DEFINE=
 548  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 549 ])
 550 AC_SUBST(TARGET_SYSTEM_ROOT)
 551 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 552 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 553
 554 # Build with intermodule optimisations
 555 AC_ARG_ENABLE(intermodule,
 556 [  --enable-intermodule    build the compiler in one step],
 557 [case ${enable_intermodule} in
 558   yes) onestep="-onestep";;
 559   *) onestep="";;
 560 esac],
 561 [onestep=""])
 562 AC_SUBST(onestep)
 563
 564 # -------------------------
 565 # Checks for other programs
 566 # -------------------------
 567
 568 AC_PROG_MAKE_SET
 569
 570 # Find some useful tools
 571 AC_PROG_AWK
 572 gcc_AC_PROG_LN
 573 gcc_AC_PROG_LN_S
 574 AC_PROG_RANLIB
 575 gcc_AC_PROG_INSTALL
 576
 577 # See if cmp has --ignore-initial.
 578 gcc_AC_PROG_CMP_IGNORE_INITIAL
 579
 580 # See if we have the mktemp command.
 581 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 582
 583 # Do we have a single-tree copy of texinfo?
 584 if test -f $srcdir/../texinfo/Makefile.in; then
 585   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 586   gcc_cv_prog_makeinfo_modern=yes
 587   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 588 else
 589   # See if makeinfo has been installed and is modern enough
 590   # that we can use it.
 591   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 592   [GNU texinfo.* \([0-9][0-9.]*\)],
 593   [4.[2-9]*])
 594 fi
 595
 596 if test $gcc_cv_prog_makeinfo_modern = no; then
 597   AC_MSG_WARN([
 598 *** Makeinfo is missing or too old.
 599 *** Info documentation will not be built.])
 600   BUILD_INFO=
 601 else
 602   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 603 fi
 604
 605 # Is pod2man recent enough to regenerate manpages?
 606 AC_MSG_CHECKING([for recent Pod::Man])
 607 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 608   AC_MSG_RESULT(yes)
 609   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 610 else
 611   AC_MSG_RESULT(no)
 612   GENERATED_MANPAGES=
 613 fi
 614
 615 # How about lex?
 616 dnl Don't use AC_PROG_LEX; we insist on flex.
 617 dnl LEXLIB is not useful in gcc.
 618 if test -f $srcdir/../flex/skel.c; then
 619   FLEX='$(objdir)/../flex/flex'
 620 else
 621   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 622 fi
 623
 624 # Bison?
 625 # The -L switch is so bison can find its skeleton file.
 626 if test -f $srcdir/../bison/bison.simple; then
 627   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 628 else
 629   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 630 fi
 631
 632 # --------------------
 633 # Checks for C headers
 634 # --------------------
 635
 636 AC_MSG_CHECKING(for GNU C library)
 637 AC_CACHE_VAL(gcc_cv_glibc,
 638 [AC_TRY_COMPILE(
 639   [#include <features.h>],[
 640 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 641 #error Not a GNU C library system
 642 #endif],
 643   [gcc_cv_glibc=yes],
 644   gcc_cv_glibc=no)])
 645 AC_MSG_RESULT($gcc_cv_glibc)
 646 if test $gcc_cv_glibc = yes; then
 647   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 648 fi
 649
 650 AC_HEADER_STDC
 651 AC_HEADER_TIME
 652 gcc_AC_HEADER_STDBOOL
 653 gcc_AC_HEADER_STRING
 654 AC_HEADER_SYS_WAIT
 655 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 656                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 657                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 658                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 659
 660 # Check for thread headers.
 661 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 662 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 663
 664 # These tests can't be done till we know if we have limits.h.
 665 gcc_AC_C_CHAR_BIT
 666 AC_C_BIGENDIAN_CROSS
 667
 668 # --------
 669 # UNSORTED
 670 # --------
 671
 672 # Stage specific cflags for build.
 673 stage1_cflags=
 674 case $build in
 675 vax-*-*)
 676   if test x$GCC = xyes
 677   then
 678     stage1_cflags="-Wa,-J"
 679   else
 680     stage1_cflags="-J"
 681   fi
 682   ;;
 683 powerpc-*-darwin*)
 684   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 685   # sources; use -no-cpp-precomp to get to GNU cpp.
 686   # Apple's GCC has bugs in designated initializer handling, so disable
 687   # that too.
 688   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 689   ;;
 690 esac
 691 AC_SUBST(stage1_cflags)
 692
 693 # These libraries may be used by collect2.
 694 # We may need a special search path to get them linked.
 695 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 696 [save_LIBS="$LIBS"
 697 for libs in '' -lld -lmld \
 698                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 699                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 700 do
 701         LIBS="$libs"
 702         AC_TRY_LINK_FUNC(ldopen,
 703                 [gcc_cv_collect2_libs="$libs"; break])
 704 done
 705 LIBS="$save_LIBS"
 706 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 707 case $gcc_cv_collect2_libs in
 708         "none required")        ;;
 709         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 710 esac
 711 AC_SUBST(COLLECT2_LIBS)
 712
 713 # When building Ada code on Alpha, we need exc_resume which is usually in
 714 # -lexc.  So test for it.
 715 save_LIBS="$LIBS"
 716 LIBS=
 717 AC_SEARCH_LIBS(exc_resume, exc)
 718 GNAT_LIBEXC="$LIBS"
 719 LIBS="$save_LIBS"
 720 AC_SUBST(GNAT_LIBEXC)
 721
 722 # Some systems put ldexp and frexp in libm instead of libc; assume
 723 # they're both in the same place.  jcf-dump needs them.
 724 save_LIBS="$LIBS"
 725 LIBS=
 726 AC_SEARCH_LIBS(ldexp, m)
 727 LDEXP_LIB="$LIBS"
 728 LIBS="$save_LIBS"
 729 AC_SUBST(LDEXP_LIB)
 730
 731 # Use <inttypes.h> only if it exists,
 732 # doesn't clash with <sys/types.h>, and declares intmax_t.
 733 AC_MSG_CHECKING(for inttypes.h)
 734 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 735 [AC_TRY_COMPILE(
 736   [#include <sys/types.h>
 737 #include <inttypes.h>],
 738   [intmax_t i = -1;],
 739   [gcc_cv_header_inttypes_h=yes],
 740   gcc_cv_header_inttypes_h=no)])
 741 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 742 if test $gcc_cv_header_inttypes_h = yes; then
 743   AC_DEFINE(HAVE_INTTYPES_H, 1,
 744         [Define if you have a working <inttypes.h> header file.])
 745 fi
 746
 747 dnl Disabled until we have a complete test for buggy enum bitfields.
 748 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 749
 750 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 751         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 752         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 753         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 754         setlocale)
 755
 756 if test x$ac_cv_func_mbstowcs = xyes; then
 757   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 758 [    AC_TRY_RUN([#include <stdlib.h>
 759 int main()
 760 {
 761   mbstowcs(0, "", 0);
 762   return 0;
 763 }],
 764     gcc_cv_func_mbstowcs_works=yes,
 765     gcc_cv_func_mbstowcs_works=no,
 766     gcc_cv_func_mbstowcs_works=yes)])
 767   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 768     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 769   [Define this macro if mbstowcs does not crash when its
 770    first argument is NULL.])
 771   fi
 772 fi
 773
 774 gcc_AC_CHECK_TYPE(ssize_t, int)
 775
 776 # Try to determine the array type of the second argument of getgroups
 777 # for the target system (int or gid_t).
 778 AC_TYPE_GETGROUPS
 779 if test "${target}" = "${build}"; then
 780   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 781 else
 782   case "${target}" in
 783         # This condition may need some tweaking.  It should include all
 784         # targets where the array type of the second argument of getgroups
 785         # is int and the type of gid_t is not equivalent to int.
 786         *-*-sunos* | *-*-ultrix*)
 787                 TARGET_GETGROUPS_T=int
 788                 ;;
 789         *)
 790                 TARGET_GETGROUPS_T=gid_t
 791                 ;;
 792   esac
 793 fi
 794 AC_SUBST(TARGET_GETGROUPS_T)
 795
 796 gcc_AC_FUNC_PRINTF_PTR
 797 gcc_AC_FUNC_MMAP_BLACKLIST
 798
 799 case "${host}" in
 800 *-*-*vms*)
 801   # Under VMS, vfork works very differently than on Unix. The standard test
 802   # won't work, and it isn't easily adaptable. It makes more sense to
 803   # just force it.
 804   ac_cv_func_vfork_works=yes
 805   ;;
 806 esac
 807 AC_FUNC_VFORK
 808
 809 AM_ICONV
 810 # Until we have in-tree GNU iconv:
 811 LIBICONV_DEP=
 812 AC_SUBST(LIBICONV_DEP)
 813
 814 AM_LC_MESSAGES
 815
 816 # We will need to find libiberty.h and ansidecl.h
 817 saved_CFLAGS="$CFLAGS"
 818 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 819 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 820         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 821         fprintf_unlocked strstr errno vasprintf \
 822         malloc realloc calloc free basename getopt clock, , ,[
 823 #include "ansidecl.h"
 824 #include "system.h"])
 825
 826 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 827 #include "ansidecl.h"
 828 #include "system.h"
 829 #ifdef HAVE_SYS_RESOURCE_H
 830 #include <sys/resource.h>
 831 #endif
 832 ])
 833
 834 AC_TRY_COMPILE([
 835 #include "ansidecl.h"
 836 #include "system.h"
 837 #ifdef HAVE_SYS_RESOURCE_H
 838 #include <sys/resource.h>
 839 #endif
 840 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 841 [Define to \`long' if <sys/resource.h> doesn't define.])])
 842
 843 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 844 #include "ansidecl.h"
 845 #include "system.h"
 846 #ifdef HAVE_LDFCN_H
 847 #include <ldfcn.h>
 848 #endif
 849 ])
 850
 851 gcc_AC_CHECK_DECLS(times, , ,[
 852 #include "ansidecl.h"
 853 #include "system.h"
 854 #ifdef HAVE_SYS_TIMES_H
 855 #include <sys/times.h>
 856 #endif
 857 ])
 858
 859 # More time-related stuff.
 860 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 861 AC_TRY_COMPILE([
 862 #include "ansidecl.h"
 863 #include "system.h"
 864 #ifdef HAVE_SYS_TIMES_H
 865 #include <sys/times.h>
 866 #endif
 867 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 868 if test $ac_cv_struct_tms = yes; then
 869   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 870   [Define if <sys/times.h> defines struct tms.])
 871 fi
 872
 873 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 874 # revisit after autoconf 2.50.
 875 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 876 AC_TRY_COMPILE([
 877 #include "ansidecl.h"
 878 #include "system.h"
 879 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 880 if test $gcc_cv_type_clock_t = yes; then
 881   AC_DEFINE(HAVE_CLOCK_T, 1,
 882   [Define if <time.h> defines clock_t.])
 883 fi
 884
 885 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
 886 [AC_TRY_COMPILE([
 887 #include "ansidecl.h"
 888 #include "system.h"
 889 ],
 890 [if ((uchar *)0) return 0;
 891  if (sizeof(uchar)) return 0;],
 892 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 893 if test $ac_cv_type_uchar = yes; then
 894   AC_DEFINE(HAVE_UCHAR, 1,
 895   [Define if <sys/types.h> defines \`uchar'.])
 896 fi
 897
 898 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 899 CFLAGS="$saved_CFLAGS"
 900
 901 gcc_AC_INITFINI_ARRAY
 902
 903 # mkdir takes a single argument on some systems.
 904 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 905
 906 # File extensions
 907 manext='.1'
 908 objext='.o'
 909 AC_SUBST(manext)
 910 AC_SUBST(objext)
 911
 912 # With Setjmp/Longjmp based exception handling.
 913 AC_ARG_ENABLE(sjlj-exceptions,
 914 [  --enable-sjlj-exceptions
 915                           arrange to use setjmp/longjmp exception handling],
 916 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
 917 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
 918   [Define 0/1 to force the choice for exception handling model.])])
 919
 920 if test x$host = x$target; then
 921    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
 922 else
 923    use_libunwind_default=no
 924 fi
 925 # Use libunwind based exception handling.
 926 AC_ARG_ENABLE(libunwind-exceptions,
 927 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
 928 use_libunwind_exceptions=$enableval,
 929 use_libunwind_exceptions=$use_libunwind_default)
 930 if test x"$use_libunwind_exceptions" = xyes; then
 931    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
 932         [Define if gcc should use -lunwind.])
 933 fi
 934
 935 # --------------------------------------------------------
 936 # Build, host, and target specific configuration fragments
 937 # --------------------------------------------------------
 938
 939 # Collect build-machine-specific information.
 940 . ${srcdir}/config.build
 941
 942 # Collect host-machine-specific information.
 943 . ${srcdir}/config.host
 944
 945 target_gtfiles=
 946
 947 # Collect target-machine-specific information.
 948 . ${srcdir}/config.gcc
 949
 950 extra_objs="${host_extra_objs} ${extra_objs}"
 951
 952 # Default the target-machine variables that were not explicitly set.
 953 if test x"$tm_file" = x
 954 then tm_file=$cpu_type/$cpu_type.h; fi
 955
 956 if test x"$extra_headers" = x
 957 then extra_headers=; fi
 958
 959 if test x$md_file = x
 960 then md_file=$cpu_type/$cpu_type.md; fi
 961
 962 if test x$out_file = x
 963 then out_file=$cpu_type/$cpu_type.c; fi
 964
 965 if test x"$tmake_file" = x
 966 then tmake_file=$cpu_type/t-$cpu_type
 967 fi
 968
 969 if test x"$dwarf2" = xyes
 970 then tm_file="$tm_file tm-dwarf2.h"
 971 fi
 972
 973 # Say what files are being used for the output code and MD file.
 974 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 975 echo "Using \`$srcdir/config/$md_file' as machine description file."
 976
 977 # If any of the xm_file variables contain nonexistent files, warn
 978 # about them and drop them.
 979
 980 bx=
 981 for x in $build_xm_file; do
 982   if    test -f $srcdir/config/$x
 983   then      bx="$bx $x"
 984   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 985   fi
 986 done
 987 build_xm_file="$bx"
 988
 989 hx=
 990 for x in $host_xm_file; do
 991   if    test -f $srcdir/config/$x
 992   then      hx="$hx $x"
 993   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 994   fi
 995 done
 996 host_xm_file="$hx"
 997
 998 tx=
 999 for x in $xm_file; do
1000   if    test -f $srcdir/config/$x
1001   then      tx="$tx $x"
1002   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1003   fi
1004 done
1005 xm_file="$tx"
1006
1007 count=a
1008 for f in $tm_file; do
1009         count=${count}x
1010 done
1011 if test $count = ax; then
1012         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1013 else
1014         echo "Using the following target machine macro files:"
1015         for f in $tm_file; do
1016                 echo "  $srcdir/config/$f"
1017         done
1018 fi
1019
1020 if test x$need_64bit_hwint = xyes; then
1021         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1022 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1023 fi
1024
1025 count=a
1026 for f in $host_xm_file; do
1027         count=${count}x
1028 done
1029 if test $count = a; then
1030         :
1031 elif test $count = ax; then
1032         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1033 else
1034         echo "Using the following host machine macro files:"
1035         for f in $host_xm_file; do
1036                 echo "  $srcdir/config/$f"
1037         done
1038 fi
1039 echo "Using ${out_host_hook_obj} for host machine hooks."
1040
1041 if test "$host_xm_file" != "$build_xm_file"; then
1042         count=a
1043         for f in $build_xm_file; do
1044                 count=${count}x
1045         done
1046         if test $count = a; then
1047                 :
1048         elif test $count = ax; then
1049                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1050         else
1051                 echo "Using the following build machine macro files:"
1052                 for f in $build_xm_file; do
1053                         echo "  $srcdir/config/$f"
1054                 done
1055         fi
1056 fi
1057
1058 # Check if a valid thread package
1059 case ${enable_threads_flag} in
1060   "" | no)
1061     # No threads
1062     target_thread_file='single'
1063     ;;
1064   yes)
1065     # default
1066     target_thread_file='single'
1067     ;;
1068   aix | dce | gnat | irix | posix | rtems | \
1069   single | solaris | vxworks | win32 )
1070     target_thread_file=${enable_threads_flag}
1071     ;;
1072   *)
1073     echo "${enable_threads_flag} is an unknown thread package" 1>&2
1074     exit 1
1075     ;;
1076 esac
1077
1078 if test x${thread_file} = x; then
1079   # No thread file set by target-specific clauses in config.gcc,
1080   # so use file chosen by default logic above
1081   thread_file=${target_thread_file}
1082 fi
1083
1084 if test x$enable___cxa_atexit = xyes || \
1085    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1086   AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1087   [Define if you want to use __cxa_atexit, rather than atexit, to
1088    register C++ destructors for local statics and global objects.
1089    This is essential for fully standards-compliant handling of
1090    destructors, but requires __cxa_atexit in libc.])
1091 fi
1092
1093 # Look for a file containing extra machine modes.
1094 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1095   extra_modes_file='$(srcdir)'/config/${extra_modes}
1096   AC_SUBST(extra_modes_file)
1097   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1098   [Define to the name of a file containing a list of extra machine modes
1099    for this architecture.])
1100   AC_DEFINE(EXTRA_CC_MODES, 1,
1101   [Define if the target architecture needs extra machine modes to represent
1102    the results of comparisons.])
1103 fi
1104
1105 # auto-host.h is the file containing items generated by autoconf and is
1106 # the first file included by config.h.
1107 # If host=build, it is correct to have bconfig include auto-host.h
1108 # as well.  If host!=build, we are in error and need to do more
1109 # work to find out the build config parameters.
1110 if test x$host = x$build
1111 then
1112         build_auto=auto-host.h
1113         FORBUILD=..
1114 else
1115         # We create a subdir, then run autoconf in the subdir.
1116         # To prevent recursion we set host and build for the new
1117         # invocation of configure to the build for this invocation
1118         # of configure.
1119         tempdir=build.$$
1120         rm -rf $tempdir
1121         mkdir $tempdir
1122         cd $tempdir
1123         case ${srcdir} in
1124         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1125         *) realsrcdir=../${srcdir};;
1126         esac
1127         saved_CFLAGS="${CFLAGS}"
1128         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1129         ${realsrcdir}/configure \
1130                 --target=$target_alias --host=$build_alias --build=$build_alias
1131         CFLAGS="${saved_CFLAGS}"
1132
1133         # We just finished tests for the build machine, so rename
1134         # the file auto-build.h in the gcc directory.
1135         mv auto-host.h ../auto-build.h
1136         cd ..
1137         rm -rf $tempdir
1138         build_auto=auto-build.h
1139         FORBUILD=../${build_subdir}
1140 fi
1141 AC_SUBST(FORBUILD)
1142
1143 tm_file="${tm_file} defaults.h"
1144 tm_p_file="${tm_p_file} tm-preds.h"
1145 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1146 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1147 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1148 # put this back in temporarily.
1149 xm_file="ansidecl.h ${xm_file}"
1150
1151 # --------
1152 # UNSORTED
1153 # --------
1154
1155 # Get the version trigger filename from the toplevel
1156 if test "${with_gcc_version_trigger+set}" = set; then
1157         gcc_version_trigger=$with_gcc_version_trigger
1158 else
1159         gcc_version_trigger=${srcdir}/version.c
1160 fi
1161 changequote(,)dnl
1162 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1163 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1164
1165 # Compile in configure arguments.
1166 if test -f configargs.h ; then
1167         # Being re-configured.
1168         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1169         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1170 else
1171         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1172 fi
1173
1174 # Double all backslashes and backslash all quotes to turn
1175 # gcc_config_arguments into a C string.
1176 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1177 $gcc_config_arguments
1178 EOF
1179 gcc_config_arguments_str=`cat conftest.out`
1180 rm -f conftest.out
1181
1182 cat > configargs.h <<EOF
1183 /* Generated automatically. */
1184 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1185 static const char thread_model[] = "$thread_file";
1186
1187 static const struct {
1188   const char *name, *value;
1189 } configure_default_options[] = $configure_default_options;
1190 EOF
1191 changequote([,])dnl
1192
1193 # Internationalization
1194 PACKAGE=gcc
1195 VERSION="$gcc_version"
1196 AC_SUBST(PACKAGE)
1197 AC_SUBST(VERSION)
1198
1199 ZW_GNU_GETTEXT_SISTER_DIR
1200
1201 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1202 # -liconv on the link line twice.
1203 case "$LIBINTL" in *$LIBICONV*)
1204         LIBICONV= ;;
1205 esac
1206
1207 # Windows32 Registry support for specifying GCC installation paths.
1208 AC_ARG_ENABLE(win32-registry,
1209 [  --disable-win32-registry
1210                           disable lookup of installation paths in the
1211                           Registry on Windows hosts
1212   --enable-win32-registry enable registry lookup (default)
1213   --enable-win32-registry=KEY
1214                           use KEY instead of GCC version as the last portion
1215                           of the registry key],,)
1216 case $host_os in
1217         win32 | pe | cygwin* | mingw32* | uwin*)
1218 AC_MSG_CHECKING(whether windows registry support is requested)
1219 if test "x$enable_win32_registry" != xno; then
1220   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1221 [Define to 1 if installation paths should be looked up in Windows32
1222    Registry. Ignored on non windows32 hosts.])
1223   AC_MSG_RESULT(yes)
1224   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1225 else
1226   AC_MSG_RESULT(no)
1227 fi
1228
1229 # Check if user specified a different registry key.
1230 case "x${enable_win32_registry}" in
1231 x | xyes)
1232   # default.
1233   gcc_cv_win32_registry_key="$VERSION"
1234   ;;
1235 xno)
1236   # no registry lookup.
1237   gcc_cv_win32_registry_key=''
1238   ;;
1239 *)
1240   # user-specified key.
1241   gcc_cv_win32_registry_key="$enable_win32_registry"
1242   ;;
1243 esac
1244
1245 if test "x$enable_win32_registry" != xno; then
1246   AC_MSG_CHECKING(registry key on windows hosts)
1247   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1248         [Define to be the last portion of registry key on windows hosts.])
1249   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1250 fi
1251 ;;
1252 esac
1253
1254 # Get an absolute path to the GCC top-level source directory
1255 holddir=`${PWDCMD-pwd}`
1256 cd $srcdir
1257 topdir=`${PWDCMD-pwd}`
1258 cd $holddir
1259
1260 # Conditionalize the makefile for this host machine.
1261 xmake_file=
1262 for f in ${host_xmake_file}
1263 do
1264         if test -f ${srcdir}/config/$f
1265         then
1266                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1267         fi
1268 done
1269
1270 # Conditionalize the makefile for this target machine.
1271 tmake_file_=
1272 for f in ${tmake_file}
1273 do
1274         if test -f ${srcdir}/config/$f
1275         then
1276                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1277         fi
1278 done
1279 tmake_file="${tmake_file_}"
1280
1281 symbolic_link='ln -s'
1282
1283 # If the host doesn't support symlinks, modify CC in
1284 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1285 # Otherwise, we can use "CC=$(CC)".
1286 rm -f symtest.tem
1287 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1288 then
1289         cc_set_by_configure="\$(CC)"
1290         quoted_cc_set_by_configure="\$(CC)"
1291         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1292         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1293 else
1294         rm -f symtest.tem
1295         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1296         then
1297                 symbolic_link="cp -p"
1298         else
1299                 symbolic_link="cp"
1300         fi
1301         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1302         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1303         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1304         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1305 fi
1306 rm -f symtest.tem
1307
1308 out_object_file=`basename $out_file .c`.o
1309
1310 tm_file_list=
1311 tm_include_list=
1312 for f in $tm_file; do
1313   case $f in
1314     defaults.h )
1315        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1316        tm_include_list="${tm_include_list} $f"
1317        ;;
1318     * )
1319        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1320        tm_include_list="${tm_include_list} config/$f"
1321        ;;
1322   esac
1323 done
1324
1325 tm_p_file_list=
1326 tm_p_include_list=
1327 for f in $tm_p_file; do
1328   case $f in
1329     tm-preds.h )
1330        tm_p_file_list="${tm_p_file_list} $f"
1331        tm_p_include_list="${tm_p_include_list} $f"
1332        ;;
1333     * )
1334        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1335        tm_p_include_list="${tm_p_include_list} config/$f"
1336   esac
1337 done
1338
1339 xm_file_list=
1340 xm_include_list=
1341 for f in $xm_file; do
1342   case $f in
1343     ansidecl.h )
1344        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1345        xm_include_list="${xm_include_list} $f"
1346        ;;
1347     auto-host.h )
1348        xm_file_list="${xm_file_list} $f"
1349        xm_include_list="${xm_include_list} $f"
1350        ;;
1351     * )
1352        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1353        xm_include_list="${xm_include_list} config/$f"
1354        ;;
1355   esac
1356 done
1357
1358 host_xm_file_list=
1359 host_xm_include_list=
1360 for f in $host_xm_file; do
1361   case $f in
1362     ansidecl.h )
1363        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1364        host_xm_include_list="${host_xm_include_list} $f"
1365        ;;
1366     auto-host.h )
1367        host_xm_file_list="${host_xm_file_list} $f"
1368        host_xm_include_list="${host_xm_include_list} $f"
1369        ;;
1370     * )
1371        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1372        host_xm_include_list="${host_xm_include_list} config/$f"
1373        ;;
1374   esac
1375 done
1376
1377 build_xm_file_list=
1378 for f in $build_xm_file; do
1379   case $f in
1380     ansidecl.h )
1381        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1382        build_xm_include_list="${build_xm_include_list} $f"
1383        ;;
1384     auto-build.h | auto-host.h )
1385        build_xm_file_list="${build_xm_file_list} $f"
1386        build_xm_include_list="${build_xm_include_list} $f"
1387        ;;
1388     * )
1389        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1390        build_xm_include_list="${build_xm_include_list} config/$f"
1391        ;;
1392   esac
1393 done
1394
1395 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1396 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1397 CROSS=                                          AC_SUBST(CROSS)
1398 ALL=all.internal                                AC_SUBST(ALL)
1399 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1400 if test x$host != x$target
1401 then
1402         CROSS="-DCROSS_COMPILE"
1403         ALL=all.cross
1404         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1405         case "$host","$target" in
1406         # Darwin crosses can use the host system's libraries and headers,
1407         # because of the fat library support.  Of course, it must be the
1408         # same version of Darwin on both sides.  Allow the user to
1409         # just say --target=foo-darwin without a version number to mean
1410         # "the version on this system".
1411             *-*-darwin*,*-*-darwin*)
1412                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1413                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1414                 if test $hostos = $targetos -o $targetos = darwin ; then
1415                     CROSS=
1416                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1417                     with_headers=yes
1418                 fi
1419                 ;;
1420
1421             i?86-*-*,x86_64-*-* \
1422             | powerpc*-*-*,powerpc64*-*-*)
1423                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1424         esac
1425 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1426         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1427         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1428 fi
1429
1430 # If this is a cross-compiler that does not
1431 # have its own set of headers then define
1432 # inhibit_libc
1433
1434 # If this is using newlib, without having the headers available now,
1435 # then define inhibit_libc in LIBGCC2_CFLAGS.
1436 # This prevents libgcc2 from containing any code which requires libc
1437 # support.
1438 inhibit_libc=
1439 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1440        test x$with_newlib = xyes ; } &&
1441      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1442        inhibit_libc=-Dinhibit_libc
1443 fi
1444 AC_SUBST(inhibit_libc)
1445
1446 # When building gcc with a cross-compiler, we need to adjust things so
1447 # that the generator programs are still built with the native compiler.
1448 # Also, we cannot run fixincludes or fix-header.
1449
1450 # These are the normal (build=host) settings:
1451 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1452 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1453 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1454 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1455
1456 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1457
1458 # Possibly disable fixproto, on a per-target basis.
1459 case ${use_fixproto} in
1460   no)
1461     STMP_FIXPROTO=
1462     ;;
1463   yes)
1464     STMP_FIXPROTO=stmp-fixproto
1465     ;;
1466 esac
1467 AC_SUBST(STMP_FIXPROTO)
1468
1469 # And these apply if build != host, or we are generating coverage data
1470 if test x$build != x$host || test "x$coverage_flags" != x
1471 then
1472     BUILD_PREFIX=build-
1473     BUILD_PREFIX_1=build-
1474     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1475
1476     if test "x$TARGET_SYSTEM_ROOT" = x; then
1477         STMP_FIXINC=
1478         STMP_FIXPROTO=
1479     fi
1480 fi
1481
1482 # Expand extra_headers to include complete path.
1483 # This substitutes for lots of t-* files.
1484 extra_headers_list=
1485 if test "x$extra_headers" = x
1486 then true
1487 else
1488         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1489         for file in $extra_headers;
1490         do
1491                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1492         done
1493 fi
1494
1495 # Add a definition of USE_COLLECT2 if system wants one.
1496 case $use_collect2 in
1497   no) use_collect2= ;;
1498   "") ;;
1499   *)
1500     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1501     xm_defines="${xm_defines} USE_COLLECT2"
1502     ;;
1503 esac
1504
1505 # Identify the assembler which will work hand-in-glove with the newly
1506 # built GCC, so that we can examine its features.  This is the assembler
1507 # which will be driven by the driver program.
1508 #
1509 # If build != host, and we aren't building gas in-tree, we identify a
1510 # build->target assembler and hope that it will have the same features
1511 # as the host->target assembler we'll be using.
1512 AC_MSG_CHECKING(what assembler to use)
1513 in_tree_gas=no
1514 gcc_cv_as=
1515 gcc_cv_gas_major_version=
1516 gcc_cv_gas_minor_version=
1517 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1518 if test -x "$DEFAULT_ASSEMBLER"; then
1519         gcc_cv_as="$DEFAULT_ASSEMBLER"
1520 elif test -x "$AS"; then
1521         gcc_cv_as="$AS"
1522 elif test -x as$host_exeext; then
1523         # Build using assembler in the current directory.
1524         gcc_cv_as=./as$host_exeext
1525 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1526      && test -f ../gas/Makefile; then
1527   # Single tree build which includes gas.
1528   in_tree_gas=yes
1529   _gcc_COMPUTE_GAS_VERSION
1530   rm -f as$host_exeext
1531   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1532   in_tree_gas_is_elf=no
1533   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1534      || (grep 'obj_format = multi' ../gas/Makefile \
1535          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1536   then
1537     in_tree_gas_is_elf=yes
1538   fi
1539 fi
1540
1541 if test "x$gcc_cv_as" = x; then
1542         # Search the same directories that the installed compiler will
1543         # search.  Else we may find the wrong assembler and lose.  If we
1544         # do not find a suitable assembler binary, then try the user's
1545         # path.
1546         #
1547         # Also note we have to check MD_EXEC_PREFIX before checking the
1548         # user's path.  Unfortunately, there is no good way to get at the
1549         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1550         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1551         # to be fixed as part of the make/configure rewrite too.
1552
1553         if test "x$exec_prefix" = xNONE; then
1554                 if test "x$prefix" = xNONE; then
1555                         test_prefix=/usr/local
1556                 else
1557                         test_prefix=$prefix
1558                 fi
1559         else
1560                 test_prefix=$exec_prefix
1561         fi
1562
1563         # If the loop below does not find an assembler, then use whatever
1564         # one we can find in the users's path.
1565         # user's path.
1566         if test "x$program_prefix" != xNONE; then
1567                 gcc_cv_as=${program_prefix}as$host_exeext
1568         else
1569                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1570         fi
1571
1572         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1573                    $test_prefix/lib/gcc-lib/$target_alias \
1574                    /usr/lib/gcc/$target_alias/$gcc_version \
1575                    /usr/lib/gcc/$target_alias \
1576                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1577                    $test_prefix/$target_alias/bin"
1578
1579         if test x$host = x$target; then
1580             test_dirs="$test_dirs \
1581                    /usr/libexec \
1582                    /usr/ccs/gcc \
1583                    /usr/ccs/bin \
1584                    /udk/usr/ccs/bin \
1585                    /bsd43/usr/lib/cmplrs/cc \
1586                    /usr/cross64/usr/bin \
1587                    /usr/lib/cmplrs/cc \
1588                    /sysv/usr/lib/cmplrs/cc \
1589                    /svr4/usr/lib/cmplrs/cc \
1590                    /usr/bin"
1591         fi
1592
1593         for dir in $test_dirs; do
1594                 if test -x $dir/as$host_exeext; then
1595                         gcc_cv_as=$dir/as$host_exeext
1596                         break;
1597                 fi
1598         done
1599 fi
1600 case $in_tree_gas in
1601   yes)
1602     AC_MSG_RESULT("newly built gas")
1603     ;;
1604   no)
1605     AC_MSG_RESULT($gcc_cv_as)
1606     ;;
1607 esac
1608
1609 # Identify the linker which will work hand-in-glove with the newly
1610 # built GCC, so that we can examine its features.  This is the linker
1611 # which will be driven by the driver program.
1612 #
1613 # If build != host, and we aren't building gas in-tree, we identify a
1614 # build->target linker and hope that it will have the same features
1615 # as the host->target linker we'll be using.
1616 AC_MSG_CHECKING(what linker to use)
1617 in_tree_ld=no
1618 gcc_cv_ld=
1619 gcc_cv_gld_major_version=
1620 gcc_cv_gld_minor_version=
1621 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1622 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1623 if test -x "$DEFAULT_LINKER"; then
1624         gcc_cv_ld="$DEFAULT_LINKER"
1625 elif test -x "$LD"; then
1626         gcc_cv_ld="$LD"
1627 elif test -x collect-ld$host_exeext; then
1628         # Build using linker in the current directory.
1629         gcc_cv_ld=./collect-ld$host_exeext
1630 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1631      && test -f ../ld/Makefile; then
1632         # Single tree build which includes ld.
1633         in_tree_ld=yes
1634         in_tree_ld_is_elf=no
1635         if (grep 'EMUL = .*elf' ../ld/Makefile \
1636             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1637           in_tree_ld_is_elf=yes
1638         fi
1639         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1640         do
1641 changequote(,)dnl
1642                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1643 changequote([,])dnl
1644                 if test x$gcc_cv_gld_version != x; then
1645                         break
1646                 fi
1647         done
1648 changequote(,)dnl
1649         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1650         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1651 changequote([,])dnl
1652         rm -f collect-ld$host_exeext
1653         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1654                 2>/dev/null
1655 fi
1656
1657 if test "x$gcc_cv_ld" = x; then
1658         # Search the same directories that the installed compiler will
1659         # search.  Else we may find the wrong linker and lose.  If we
1660         # do not find a suitable linker binary, then try the user's
1661         # path.
1662         #
1663         # Also note we have to check MD_EXEC_PREFIX before checking the
1664         # user's path.  Unfortunately, there is no good way to get at the
1665         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1666         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1667         # to be fixed as part of the make/configure rewrite too.
1668
1669         if test "x$exec_prefix" = xNONE; then
1670                 if test "x$prefix" = xNONE; then
1671                         test_prefix=/usr/local
1672                 else
1673                         test_prefix=$prefix
1674                 fi
1675         else
1676                 test_prefix=$exec_prefix
1677         fi
1678
1679         # If the loop below does not find an linker, then use whatever
1680         # one we can find in the users's path.
1681         # user's path.
1682         if test "x$program_prefix" != xNONE; then
1683                 gcc_cv_ld=${program_prefix}ld$host_exeext
1684         else
1685                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1686         fi
1687
1688         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1689                    $test_prefix/lib/gcc-lib/$target_alias \
1690                    /usr/lib/gcc/$target_alias/$gcc_version \
1691                    /usr/lib/gcc/$target_alias \
1692                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1693                    $test_prefix/$target_alias/bin"
1694
1695         if test x$host = x$target; then
1696             test_dirs="$test_dirs \
1697                    /usr/libexec \
1698                    /usr/ccs/gcc \
1699                    /usr/ccs/bin \
1700                    /udk/usr/ccs/bin \
1701                    /bsd43/usr/lib/cmplrs/cc \
1702                    /usr/cross64/usr/bin \
1703                    /usr/lib/cmplrs/cc \
1704                    /sysv/usr/lib/cmplrs/cc \
1705                    /svr4/usr/lib/cmplrs/cc \
1706                    /usr/bin"
1707         fi
1708
1709         for dir in $test_dirs; do
1710                 if test -x $dir/ld$host_exeext; then
1711                         gcc_cv_ld=$dir/ld$host_exeext
1712                         break;
1713                 fi
1714         done
1715 fi
1716 case $in_tree_ld in
1717   yes)
1718     AC_MSG_RESULT("newly built ld")
1719     ;;
1720   no)
1721     AC_MSG_RESULT($gcc_cv_ld)
1722     ;;
1723 esac
1724
1725 # Figure out what nm we will be using.
1726 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1727 AC_MSG_CHECKING(what nm to use)
1728 in_tree_nm=no
1729 if test -x nm$host_exeext; then
1730         gcc_cv_nm=./nm$host_exeext
1731 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1732      && test -f ../binutils/Makefile; then
1733         # Single tree build which includes binutils.
1734         in_tree_nm=yes
1735         gcc_cv_nm=./nm$host_exeext
1736         rm -f nm$host_exeext
1737         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1738 elif test "x$program_prefix" != xNONE; then
1739         gcc_cv_nm=${program_prefix}nm$host_exeext
1740 else
1741         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1742 fi
1743 case $in_tree_nm in
1744   yes) AC_MSG_RESULT("newly built nm") ;;
1745   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1746 esac
1747
1748 # Figure out what objdump we will be using.
1749 AC_MSG_CHECKING(what objdump to use)
1750 in_tree_objdump=no
1751 if test -x objdump$host_exeext; then
1752         gcc_cv_objdump=./objdump$host_exeext
1753 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1754      && test -f ../binutils/Makefile; then
1755         # Single tree build which includes binutils.
1756         in_tree_objdump=yes
1757         gcc_cv_objdump=./objdump$host_exeext
1758         rm -f objdump$host_exeext
1759         $symbolic_link ../binutils/objdump$host_exeext \
1760                 objdump$host_exeext 2>/dev/null
1761 elif test "x$program_prefix" != xNONE; then
1762         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1763 else
1764         gcc_cv_objdump=`echo objdump | \
1765                 sed ${program_transform_name}`$host_exeext
1766 fi
1767 case $in_tree_objdump in
1768   yes) AC_MSG_RESULT("newly built objdump") ;;
1769   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1770 esac
1771
1772 # Figure out what assembler alignment features are present.
1773 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1774  [2,6,0],,
1775 [.balign 4
1776 .p2align 2],,
1777 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1778   [Define if your assembler supports .balign and .p2align.])])
1779
1780 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1781  [2,8,0],,
1782  [.p2align 4,,7],,
1783 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1784   [Define if your assembler supports specifying the maximum number
1785    of bytes to skip when using the GAS .p2align command.])])
1786
1787 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1788  [elf,2,9,0],,
1789  [conftest_label1: .word 0
1790 .subsection -1
1791 conftest_label2: .word 0
1792 .previous],
1793  [if test x$gcc_cv_nm != x; then
1794     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1795     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1796     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1797     then :
1798     else gcc_cv_as_subsection_m1=yes
1799     fi
1800     rm -f conftest.nm1 conftest.nm2
1801   fi],
1802  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1803   [Define if your assembler supports .subsection and .subsection -1 starts
1804    emitting at the beginning of your section.])])
1805
1806 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1807  [2,2,0],,
1808  [      .weak foobar],,
1809 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1810
1811 # .hidden needs to be supported in both the assembler and the linker,
1812 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1813 # This is irritatingly difficult to feature test for; we have to check the
1814 # date string after the version number.  If we've got an in-tree
1815 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1816 # to be safe.
1817 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1818 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1819  [elf,2,13,0],,
1820 [       .hidden foobar
1821 foobar:])
1822
1823 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1824 [if test $in_tree_ld = yes ; then
1825   gcc_cv_ld_hidden=no
1826   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1827      && test $in_tree_ld_is_elf = yes; then
1828      gcc_cv_ld_hidden=yes
1829   fi
1830 else
1831   gcc_cv_ld_hidden=yes
1832   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
1833   if echo "$ld_ver" | grep GNU > /dev/null; then
1834 changequote(,)dnl
1835     ld_vers=`echo $ld_ver | sed -n \
1836         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1837         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1838         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1839         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1840         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1841         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1842     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1843     if test 0"$ld_date" -lt 20020404; then
1844       if test -n "$ld_date"; then
1845         # If there was date string, but was earlier than 2002-04-04, fail
1846         gcc_cv_ld_hidden=no
1847       elif test -z "$ld_vers"; then
1848         # If there was no date string nor ld version number, something is wrong
1849         gcc_cv_ld_hidden=no
1850       else
1851         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1852         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1853         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1854         test -z "$ld_vers_patch" && ld_vers_patch=0
1855         if test "$ld_vers_major" -lt 2; then
1856           gcc_cv_ld_hidden=no
1857         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1858           gcc_cv_ld_hidden="no"
1859         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1860           gcc_cv_ld_hidden=no
1861         fi
1862       fi
1863 changequote([,])dnl
1864     fi
1865   else
1866     # non-GNU linkers don't seem to support .hidden yet
1867     gcc_cv_ld_hidden=no
1868   fi
1869 fi])
1870 libgcc_visibility=no
1871 AC_SUBST(libgcc_visibility)
1872 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
1873   libgcc_visibility=yes
1874   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1875   [Define if your assembler and linker support .hidden.])
1876 fi
1877
1878 # Check if we have .[us]leb128, and support symbol arithmetic with it.
1879 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
1880   [elf,2,11,0],,
1881 [       .data
1882         .uleb128 L2 - L1
1883 L1:
1884         .uleb128 1280
1885         .sleb128 -1010
1886 L2:],
1887  [# GAS versions before 2.11 do not support uleb128,
1888   # despite appearing to.
1889   # ??? There exists an elf-specific test that will crash
1890   # the assembler.  Perhaps it's better to figure out whether
1891   # arbitrary sections are supported and try the test.
1892   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
1893   if echo "$as_ver" | grep GNU > /dev/null; then
1894 changequote(,)dnl
1895     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1896     as_major=`echo $as_ver | sed 's/\..*//'`
1897     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1898 changequote([,])dnl
1899     if test $as_major -eq 2 && test $as_minor -lt 11
1900     then :
1901     else gcc_cv_as_leb128=yes
1902     fi
1903   fi],
1904   [AC_DEFINE(HAVE_AS_LEB128, 1,
1905     [Define if your assembler supports .sleb128 and .uleb128.])])
1906
1907 # GAS versions up to and including 2.11.0 may mis-optimize
1908 # .eh_frame data.
1909 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
1910   [elf,2,12,0],,
1911 [       .text
1912 .LFB1:
1913         .4byte  0
1914 .L1:
1915         .4byte  0
1916 .LFE1:
1917         .section        .eh_frame,"aw",@progbits
1918 __FRAME_BEGIN__:
1919         .4byte  .LECIE1-.LSCIE1
1920 .LSCIE1:
1921         .4byte  0x0
1922         .byte   0x1
1923         .ascii "z\0"
1924         .byte   0x1
1925         .byte   0x78
1926         .byte   0x1a
1927         .byte   0x0
1928         .byte   0x4
1929         .4byte  1
1930         .p2align 1
1931 .LECIE1:
1932 .LSFDE1:
1933         .4byte  .LEFDE1-.LASFDE1
1934 .LASFDE1:
1935         .4byte  .LASFDE1-__FRAME_BEGIN__
1936         .4byte  .LFB1
1937         .4byte  .LFE1-.LFB1
1938         .byte   0x4
1939         .4byte  .LFE1-.LFB1
1940         .byte   0x4
1941         .4byte  .L1-.LFB1
1942 .LEFDE1:],
1943 [  cat > conftest.lit <<EOF
1944  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1945  0010 01000000 12000000 18000000 00000000  ................
1946  0020 08000000 04080000 0044               .........D
1947 EOF
1948   cat > conftest.big <<EOF
1949  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1950  0010 00000001 00000012 00000018 00000000  ................
1951  0020 00000008 04000000 0844               .........D
1952 EOF
1953   # If the assembler didn't choke, and we can objdump,
1954   # and we got the correct data, then succeed.
1955   if test x$gcc_cv_objdump != x \
1956   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1957      | tail -3 > conftest.got \
1958   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1959     || cmp conftest.big conftest.got > /dev/null 2>&1; }
1960   then
1961     gcc_cv_as_eh_frame=yes
1962   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
1963     gcc_cv_as_eh_frame=buggy
1964   else
1965     # Uh oh, what do we do now?
1966     gcc_cv_as_eh_frame=no
1967   fi])
1968
1969 if test $gcc_cv_as_eh_frame = buggy; then
1970   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1971   [Define if your assembler mis-optimizes .eh_frame data.])
1972 fi
1973
1974 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
1975  [elf,2,12,0], [--fatal-warnings],
1976  [.section .rodata.str, "aMS", @progbits, 1])
1977 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
1978   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
1979 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
1980
1981 # Thread-local storage - the check is heavily parametrized.
1982 conftest_s=
1983 tls_first_major=
1984 tls_first_minor=
1985 tls_as_opt=
1986 case "$target" in
1987 changequote(,)dnl
1988   alpha*-*-*)
1989     conftest_s='
1990         .section ".tdata","awT",@progbits
1991 foo:    .long   25
1992         .text
1993         ldq     $27,__tls_get_addr($29)         !literal!1
1994         lda     $16,foo($29)                    !tlsgd!1
1995         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
1996         ldq     $27,__tls_get_addr($29)         !literal!2
1997         lda     $16,foo($29)                    !tlsldm!2
1998         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
1999         ldq     $1,foo($29)                     !gotdtprel
2000         ldah    $2,foo($29)                     !dtprelhi
2001         lda     $3,foo($2)                      !dtprello
2002         lda     $4,foo($29)                     !dtprel
2003         ldq     $1,foo($29)                     !gottprel
2004         ldah    $2,foo($29)                     !tprelhi
2005         lda     $3,foo($2)                      !tprello
2006         lda     $4,foo($29)                     !tprel'
2007         tls_first_major=2
2008         tls_first_minor=13
2009         ;;
2010   i[34567]86-*-*)
2011     conftest_s='
2012         .section ".tdata","awT",@progbits
2013 foo:    .long   25
2014         .text
2015         movl    %gs:0, %eax
2016         leal    foo@TLSGD(,%ebx,1), %eax
2017         leal    foo@TLSLDM(%ebx), %eax
2018         leal    foo@DTPOFF(%eax), %edx
2019         movl    foo@GOTTPOFF(%ebx), %eax
2020         subl    foo@GOTTPOFF(%ebx), %eax
2021         addl    foo@GOTNTPOFF(%ebx), %eax
2022         movl    foo@INDNTPOFF, %eax
2023         movl    $foo@TPOFF, %eax
2024         subl    $foo@TPOFF, %eax
2025         leal    foo@NTPOFF(%ecx), %eax'
2026         tls_first_major=2
2027         tls_first_minor=14
2028         ;;
2029   x86_64-*-*)
2030     conftest_s='
2031         .section ".tdata","awT",@progbits
2032 foo:    .long   25
2033         .text
2034         movq    %fs:0, %rax
2035         leaq    foo@TLSGD(%rip), %rdi
2036         leaq    foo@TLSLD(%rip), %rdi
2037         leaq    foo@DTPOFF(%rax), %rdx
2038         movq    foo@GOTTPOFF(%rip), %rax
2039         movq    $foo@TPOFF, %rax'
2040         tls_first_major=2
2041         tls_first_minor=14
2042         ;;
2043   ia64-*-*)
2044     conftest_s='
2045         .section ".tdata","awT",@progbits
2046 foo:    data8   25
2047         .text
2048         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2049         addl    r17 = @ltoff(@dtprel(foo#)), gp
2050         addl    r18 = @ltoff(@tprel(foo#)), gp
2051         addl    r19 = @dtprel(foo#), gp
2052         adds    r21 = @dtprel(foo#), r13
2053         movl    r23 = @dtprel(foo#)
2054         addl    r20 = @tprel(foo#), gp
2055         adds    r22 = @tprel(foo#), r13
2056         movl    r24 = @tprel(foo#)'
2057         tls_first_major=2
2058         tls_first_minor=13
2059         ;;
2060   powerpc-*-*)
2061     conftest_s='
2062         .section ".tdata","awT",@progbits
2063         .align 2
2064 ld0:    .space 4
2065 ld1:    .space 4
2066 x1:     .space 4
2067 x2:     .space 4
2068 x3:     .space 4
2069         .text
2070         addi 3,31,ld0@got@tlsgd
2071         bl __tls_get_addr
2072         addi 3,31,x1@got@tlsld
2073         bl __tls_get_addr
2074         addi 9,3,x1@dtprel
2075         addis 9,3,x2@dtprel@ha
2076         addi 9,9,x2@dtprel@l
2077         lwz 9,x3@got@tprel(31)
2078         add 9,9,x@tls
2079         addi 9,2,x1@tprel
2080         addis 9,2,x2@tprel@ha
2081         addi 9,9,x2@tprel@l'
2082         tls_first_major=2
2083         tls_first_minor=14
2084         tls_as_opt=-a32
2085         ;;
2086   powerpc64-*-*)
2087     conftest_s='
2088         .section ".tdata","awT",@progbits
2089         .align 3
2090 ld0:    .space 8
2091 ld1:    .space 8
2092 x1:     .space 8
2093 x2:     .space 8
2094 x3:     .space 8
2095         .text
2096         addi 3,2,ld0@got@tlsgd
2097         bl .__tls_get_addr
2098         nop
2099         addi 3,2,ld1@toc
2100         bl .__tls_get_addr
2101         nop
2102         addi 3,2,x1@got@tlsld
2103         bl .__tls_get_addr
2104         nop
2105         addi 9,3,x1@dtprel
2106         bl .__tls_get_addr
2107         nop
2108         addis 9,3,x2@dtprel@ha
2109         addi 9,9,x2@dtprel@l
2110         bl .__tls_get_addr
2111         nop
2112         ld 9,x3@got@dtprel(2)
2113         add 9,9,3
2114         bl .__tls_get_addr
2115         nop'
2116         tls_first_major=2
2117         tls_first_minor=14
2118         tls_as_opt=-a64
2119         ;;
2120   s390-*-*)
2121     conftest_s='
2122         .section ".tdata","awT",@progbits
2123 foo:    .long   25
2124         .text
2125         .long   foo@TLSGD
2126         .long   foo@TLSLDM
2127         .long   foo@DTPOFF
2128         .long   foo@NTPOFF
2129         .long   foo@GOTNTPOFF
2130         .long   foo@INDNTPOFF
2131         l       %r1,foo@GOTNTPOFF(%r12)
2132         l       %r1,0(%r1):tls_load:foo
2133         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2134         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2135         tls_first_major=2
2136         tls_first_minor=14
2137         tls_as_opt=-m31
2138         ;;
2139   s390x-*-*)
2140     conftest_s='
2141         .section ".tdata","awT",@progbits
2142 foo:    .long   25
2143         .text
2144         .quad   foo@TLSGD
2145         .quad   foo@TLSLDM
2146         .quad   foo@DTPOFF
2147         .quad   foo@NTPOFF
2148         .quad   foo@GOTNTPOFF
2149         lg      %r1,foo@GOTNTPOFF(%r12)
2150         larl    %r1,foo@INDNTPOFF
2151         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2152         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2153         tls_first_major=2
2154         tls_first_minor=14
2155         tls_as_opt="-m64 -Aesame"
2156         ;;
2157   sh-*-* | sh[34]-*-*)
2158     conftest_s='
2159         .section ".tdata","awT",@progbits
2160 foo:    .long   25
2161         .text
2162         .long   foo@TLSGD
2163         .long   foo@TLSLDM
2164         .long   foo@DTPOFF
2165         .long   foo@GOTTPOFF
2166         .long   foo@TPOFF'
2167         tls_first_major=2
2168         tls_first_minor=13
2169         ;;
2170   sparc*-*-*)
2171     conftest_s='
2172         .section ".tdata","awT",@progbits
2173 foo:    .long   25
2174         .text
2175         sethi   %tgd_hi22(foo), %o0
2176         add     %o0, %tgd_lo10(foo), %o1
2177         add     %l7, %o1, %o0, %tgd_add(foo)
2178         call    __tls_get_addr, %tgd_call(foo)
2179         sethi   %tldm_hi22(foo), %l1
2180         add     %l1, %tldm_lo10(foo), %l2
2181         add     %l7, %l2, %o0, %tldm_add(foo)
2182         call    __tls_get_addr, %tldm_call(foo)
2183         sethi   %tldo_hix22(foo), %l3
2184         xor     %l3, %tldo_lox10(foo), %l4
2185         add     %o0, %l4, %l5, %tldo_add(foo)
2186         sethi   %tie_hi22(foo), %o3
2187         add     %o3, %tie_lo10(foo), %o3
2188         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2189         add     %g7, %o2, %o4, %tie_add(foo)
2190         sethi   %tle_hix22(foo), %l1
2191         xor     %l1, %tle_lox10(foo), %o5
2192         ld      [%g7 + %o5], %o1'
2193         tls_first_major=2
2194         tls_first_minor=14
2195         tls_as_opt=-32
2196         ;;
2197 changequote([,])dnl
2198 esac
2199 if test -z "$tls_first_major"; then
2200   : # If we don't have a check, assume no support.
2201 else
2202   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2203   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt --fatal-warnings],
2204   [$conftest_s],,
2205   [AC_DEFINE(HAVE_AS_TLS, 1,
2206             [Define if your assembler supports thread-local storage.])])
2207 fi
2208
2209 # Target-specific assembler checks.
2210
2211 case "$target" in
2212   # All TARGET_ABI_OSF targets.
2213   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2214     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2215         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2216 [       .set nomacro
2217         .text
2218         extbl   $3, $2, $3      !lituse_bytoff!1
2219         ldq     $2, a($29)      !literal!1
2220         ldq     $4, b($29)      !literal!2
2221         ldq_u   $3, 0($2)       !lituse_base!1
2222         ldq     $27, f($29)     !literal!5
2223         jsr     $26, ($27), f   !lituse_jsr!5
2224         ldah    $29, 0($26)     !gpdisp!3
2225         lda     $0, c($29)      !gprel
2226         ldah    $1, d($29)      !gprelhigh
2227         lda     $1, d($1)       !gprellow
2228         lda     $29, 0($29)     !gpdisp!3],,
2229     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2230   [Define if your assembler supports explicit relocations.])])
2231     ;;
2232
2233   sparc*-*-*)
2234     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2235       [.register %g2, #scratch],,
2236       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2237                 [Define if your assembler supports .register.])])
2238
2239     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2240       [-relax], [.text],,
2241       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2242                 [Define if your assembler supports -relax option.])])
2243
2244     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2245       gcc_cv_as_sparc_ua_pcrel,,
2246       [-K PIC],
2247 [.text
2248 foo:
2249         nop
2250 .data
2251 .align 4
2252 .byte 0
2253 .uaword %r_disp32(foo)],
2254       [if test x$gcc_cv_ld != x \
2255        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2256          gcc_cv_as_sparc_ua_pcrel=yes
2257        fi
2258        rm -f conftest],
2259       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2260                 [Define if your assembler and linker support unaligned PC relative relocs.])
2261
2262       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2263         gcc_cv_as_sparc_ua_pcrel_hidden,,
2264         [-K PIC],
2265 [.data
2266 .align 4
2267 .byte 0x31
2268 .uaword %r_disp32(foo)
2269 .byte 0x32, 0x33, 0x34
2270 .global foo
2271 .hidden foo
2272 foo:
2273 .skip 4],
2274         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2275          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2276          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2277             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2278             if $gcc_cv_objdump -R conftest 2> /dev/null \
2279                | grep 'DISP32' > /dev/null 2>&1; then
2280                 :
2281             else
2282                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2283             fi
2284          fi
2285          rm -f conftest],
2286          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2287                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2288     ]) # unaligned pcrel relocs
2289
2290     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2291       gcc_cv_as_sparc_offsetable_lo10,,
2292       [-xarch=v9],
2293 [.text
2294         or %g1, %lo(ab) + 12, %g1
2295         or %g1, %lo(ab + 12), %g1],
2296       [if test x$gcc_cv_objdump != x \
2297        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2298           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2299          gcc_cv_as_offsetable_lo10=yes
2300        fi],
2301        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2302                  [Define if your assembler supports offsetable %lo().])])
2303     ;;
2304
2305 changequote(,)dnl
2306   i[34567]86-*-* | x86_64-*-*)
2307 changequote([,])dnl
2308     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2309        gcc_cv_as_ix86_filds_fists,
2310       [2,9,0],, [filds mem; fists mem],,
2311       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2312         [Define if your assembler uses the new HImode fild and fist notation.])])
2313
2314     gcc_GAS_CHECK_FEATURE([cmov syntax],
2315       gcc_cv_as_ix86_cmov_sun_syntax,,,
2316       [cmovl.l %edx, %eax],,
2317       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2318         [Define if your assembler supports the Sun syntax for cmov.])])
2319
2320     # This one is used unconditionally by i386.[ch]; it is to be defined
2321     # to 1 if the feature is present, 0 otherwise.
2322     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2323         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2324 [       .text
2325 .L0:
2326         nop
2327         .data
2328         .long .L0@GOTOFF])
2329     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2330       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2331       [Define true if the assembler supports '.long foo@GOTOFF'.])
2332     ;;
2333
2334   ia64*-*-*)
2335     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2336         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2337 [       .text
2338         addl r15 = @ltoffx(x#), gp
2339         ;;
2340         ld8.mov r16 = [[r15]], x#],,
2341     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2342           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2343
2344     ;;
2345
2346   powerpc*-*-*)
2347     case $target in
2348       *-*-aix) conftest_s='     .csect .text[PR]';;
2349       *)       conftest_s='     .text';;
2350     esac
2351     conftest_s="$conftest_s
2352         mfcr 3,128"
2353
2354     gcc_GAS_CHECK_FEATURE([mfcr field support],
2355       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2356       [$conftest_s],,
2357       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2358           [Define if your assembler supports mfcr field.])])
2359     ;;
2360
2361   mips*-*-*)
2362     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2363       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2364 [       lw $4,%gp_rel(foo)($4)],,
2365       [if test x$target_cpu_default = x
2366        then target_cpu_default=MASK_EXPLICIT_RELOCS
2367        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2368        fi])
2369
2370     ;;
2371 esac
2372 # ??? Not all targets support dwarf2 debug_line, even within a version
2373 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2374 # info to the output file.  So, as supported targets are added to gas 2.11,
2375 # add some instruction here to (also) show we expect this might work.
2376 # ??? Once 2.11 is released, probably need to add first known working
2377 # version to the per-target configury.
2378 case "$target" in
2379   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2380   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2381   | xstormy16*-*-* | cris-*-*)
2382     insn="nop"
2383     ;;
2384   ia64*-*-*)
2385     insn="nop 0"
2386     ;;
2387   mmix-*-*)
2388     insn="swym 0"
2389     ;;
2390 esac
2391 if test x"$insn" != x; then
2392  conftest_s="\
2393         .file 1 \"conftest.s\"
2394         .loc 1 3 0
2395         $insn"
2396  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2397   gcc_cv_as_dwarf2_debug_line,
2398   [elf,2,11,0],, [$conftest_s],
2399   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2400    if grep debug_line conftest.o > /dev/null 2>&1; then
2401      gcc_cv_as_dwarf2_debug_line=yes
2402    fi])
2403
2404 # The .debug_line file table must be in the exact order that
2405 # we specified the files, since these indices are also used
2406 # by DW_AT_decl_file.  Approximate this test by testing if
2407 # the assembler bitches if the same index is assigned twice.
2408  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2409   gcc_cv_as_dwarf2_file_buggy,,,
2410 [       .file 1 "foo.s"
2411         .file 1 "bar.s"])
2412
2413  if test $gcc_cv_as_dwarf2_debug_line = yes \
2414  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2415         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2416   [Define if your assembler supports dwarf2 .file/.loc directives,
2417    and preserves file table indices exactly as given.])
2418  fi
2419
2420  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2421   gcc_cv_as_gdwarf2_flag,
2422   [elf,2,11,0], [--gdwarf2], [$insn],,
2423   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2424 [Define if your assembler supports the --gdwarf2 option.])])
2425
2426  gcc_GAS_CHECK_FEATURE([--gstabs option],
2427   gcc_cv_as_gstabs_flag,
2428   [elf,2,11,0], [--gstabs], [$insn],
2429   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2430    # and warns about it, but still exits successfully.  So check for
2431    # this.
2432    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2433    then :
2434    else gcc_cv_as_gstabs_flag=yes
2435    fi],
2436   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2437 [Define if your assembler supports the --gstabs option.])])
2438 fi
2439
2440 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2441 gcc_cv_ld_ro_rw_mix=unknown
2442 if test $in_tree_ld = yes ; then
2443   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2444      && test $in_tree_ld_is_elf = yes; then
2445     gcc_cv_ld_ro_rw_mix=read-write
2446   fi
2447 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2448   echo '.section myfoosect, "a"' > conftest1.s
2449   echo '.section myfoosect, "aw"' > conftest2.s
2450   echo '.byte 1' >> conftest2.s
2451   echo '.section myfoosect, "a"' > conftest3.s
2452   echo '.byte 0' >> conftest3.s
2453   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2454      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2455      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2456      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2457         conftest2.o conftest3.o > /dev/null 2>&1; then
2458     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2459                          | sed -e '/myfoosect/!d' -e N`
2460     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2461       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2462         gcc_cv_ld_ro_rw_mix=read-only
2463       else
2464         gcc_cv_ld_ro_rw_mix=read-write
2465       fi
2466     fi
2467   fi
2468 changequote(,)dnl
2469   rm -f conftest.* conftest[123].*
2470 changequote([,])dnl
2471 fi
2472 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2473         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2474   [Define if your linker links a mix of read-only
2475    and read-write sections into a read-write section.])
2476 fi
2477 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2478
2479 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2480 gcc_cv_ld_eh_frame_hdr=no
2481 if test $in_tree_ld = yes ; then
2482   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2483      && test $in_tree_ld_is_elf = yes; then
2484     gcc_cv_ld_eh_frame_hdr=yes
2485   fi
2486 elif test x$gcc_cv_ld != x; then
2487         # Check if linker supports --eh-frame-hdr option
2488         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2489                 gcc_cv_ld_eh_frame_hdr=yes
2490         fi
2491 fi
2492 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2493         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2494 [Define if your linker supports --eh-frame-hdr option.])
2495 fi
2496 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2497
2498 AC_MSG_CHECKING(linker position independent executable support)
2499 gcc_cv_ld_pie=no
2500 if test $in_tree_ld = yes ; then
2501   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2502      && test $in_tree_ld_is_elf = yes; then
2503     gcc_cv_ld_pie=yes
2504   fi
2505 elif test x$gcc_cv_ld != x; then
2506         # Check if linker supports -pie option
2507         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2508                 gcc_cv_ld_pie=yes
2509         fi
2510 fi
2511 if test x"$gcc_cv_ld_pie" = xyes; then
2512         AC_DEFINE(HAVE_LD_PIE, 1,
2513 [Define if your linker supports -pie option.])
2514 fi
2515 AC_MSG_RESULT($gcc_cv_ld_pie)
2516
2517 # Miscellaneous target-specific checks.
2518 case "$target" in
2519   mips*-*-*)
2520     AC_MSG_CHECKING(whether libgloss uses STARTUP directives consistently)
2521     gcc_cv_mips_libgloss_startup=no
2522     gcc_cv_libgloss_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/libgloss
2523     if test "x$exec_prefix" = xNONE; then
2524       if test "x$prefix" = xNONE; then
2525         test_prefix=/usr/local
2526       else
2527         test_prefix=$prefix
2528       fi
2529     else
2530       test_prefix=$exec_prefix
2531     fi
2532     for f in $gcc_cv_libgloss_srcdir/mips/idt.ld $test_prefix/$target_alias/lib/idt.ld
2533     do
2534       if grep '^STARTUP' $f > /dev/null 2>&1; then
2535         gcc_cv_mips_libgloss_startup=yes
2536         break
2537       fi
2538     done
2539     if test x"$gcc_cv_mips_libgloss_startup" = xyes; then
2540       AC_DEFINE(HAVE_MIPS_LIBGLOSS_STARTUP_DIRECTIVES, 1,
2541         [Define if your MIPS libgloss linker scripts consistently include STARTUP directives.])
2542     fi
2543     AC_MSG_RESULT($gcc_cv_mips_libgloss_startup)
2544     ;;
2545 esac
2546
2547 if test x$with_sysroot = x && test x$host = x$target \
2548    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2549   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2550 [Define to PREFIX/include if cpp should also search that directory.])
2551 fi
2552
2553 # Figure out what language subdirectories are present.
2554 # Look if the user specified --enable-languages="..."; if not, use
2555 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2556 # go away some day.
2557 # NB:  embedded tabs in this IF block -- do not untabify
2558 if test x"${enable_languages+set}" != xset; then
2559         if test x"${LANGUAGES+set}" = xset; then
2560                 enable_languages="${LANGUAGES}"
2561                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2562
2563         else
2564                 enable_languages=all
2565         fi
2566 else
2567         if test x"${enable_languages}" = x \
2568         || test x"${enable_languages}" = xyes;
2569         then
2570                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2571         fi
2572 fi
2573 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2574
2575 # First scan to see if an enabled language requires some other language.
2576 # We assume that a given config-lang.in will list all the language
2577 # front ends it requires, even if some are required indirectly.
2578 for lang in ${srcdir}/*/config-lang.in
2579 do
2580    case $lang in
2581     # The odd quoting in the next line works around
2582     # an apparent bug in bash 1.12 on linux.
2583 changequote(,)dnl
2584     ${srcdir}/[*]/config-lang.in)
2585        ;;
2586     *)
2587        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2588        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2589        for other in $this_lang_requires
2590        do
2591           case ,${enable_languages}, in
2592            *,$other,*)
2593               ;;
2594            *,all,*)
2595               ;;
2596            *,$lang_alias,*)
2597               enable_languages="$enable_languages,$other"
2598               ;;
2599           esac
2600        done
2601        ;;
2602 changequote([,])dnl
2603    esac
2604 done
2605
2606 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2607 found_languages=
2608 subdirs=
2609 for lang in ${srcdir}/*/config-lang.in
2610 do
2611         case $lang in
2612         # The odd quoting in the next line works around
2613         # an apparent bug in bash 1.12 on linux.
2614 changequote(,)dnl
2615         ${srcdir}/[*]/config-lang.in) ;;
2616         *)
2617           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2618           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2619           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2620           if test "x$lang_alias" = x
2621           then
2622                 echo "$lang doesn't set \$language." 1>&2
2623                 exit 1
2624           fi
2625           case ${build_by_default},${enable_languages}, in
2626           *,$lang_alias,*) add_this_lang=yes ;;
2627           no,*) add_this_lang=no ;;
2628           *,all,*) add_this_lang=yes ;;
2629           *) add_this_lang=no ;;
2630           esac
2631           found_languages="${found_languages} ${lang_alias}"
2632           if test x"${add_this_lang}" = xyes; then
2633                 case $lang in
2634                     ${srcdir}/ada/config-lang.in)
2635                         if test x$have_gnat = xyes ; then
2636                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2637                         fi
2638                         ;;
2639                     *)
2640                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2641                         ;;
2642                 esac
2643           fi
2644           ;;
2645 changequote([,])dnl
2646         esac
2647 done
2648
2649 missing_languages=
2650 for expected_language in ${expected_languages} ..
2651 do
2652     if test "${expected_language}" != ..; then
2653         missing_language="${expected_language}"
2654         if test "${expected_language}" = "c" \
2655            || test "${expected_language}" = "all"; then
2656                 missing_language=
2657         fi
2658         for found_language in ${found_languages} ..
2659         do
2660             if test "${found_language}" != ..; then
2661                 if test "${expected_language}" = "${found_language}"; then
2662                     missing_language=
2663                 fi
2664             fi
2665         done
2666         if test "x${missing_language}" != x; then
2667            missing_languages="${missing_languages} ${missing_language}"
2668         fi
2669     fi
2670 done
2671
2672 if test "x$missing_languages" != x; then
2673   AC_MSG_ERROR([
2674 The following requested languages were not found:${missing_languages}
2675 The following languages were available: c${found_languages}])
2676 fi
2677
2678 # Make gthr-default.h if we have a thread file.
2679 gthread_flags=
2680 if test $thread_file != single; then
2681     rm -f gthr-default.h
2682     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2683     gthread_flags=-DHAVE_GTHR_DEFAULT
2684 fi
2685 AC_SUBST(gthread_flags)
2686
2687 # Find out what GC implementation we want, or may, use.
2688 AC_ARG_WITH(gc,
2689 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2690                           with the compiler],
2691 [case "$withval" in
2692   simple | page)
2693     GGC=ggc-$withval
2694     ;;
2695   *)
2696     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2697     ;;
2698 esac],
2699 [GGC=ggc-page])
2700 AC_SUBST(GGC)
2701 echo "Using $GGC for garbage collection."
2702
2703 # Use the system's zlib library.
2704 zlibdir=-L../zlib
2705 zlibinc="-I\$(srcdir)/../zlib"
2706 AC_ARG_WITH(system-zlib,
2707 [  --with-system-zlib      use installed libz],
2708 zlibdir=
2709 zlibinc=
2710 )
2711 AC_SUBST(zlibdir)
2712 AC_SUBST(zlibinc)
2713
2714 dnl Very limited version of automake's enable-maintainer-mode
2715
2716 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2717   dnl maintainer-mode is disabled by default
2718   AC_ARG_ENABLE(maintainer-mode,
2719 [  --enable-maintainer-mode
2720                           enable make rules and dependencies not useful
2721                           (and sometimes confusing) to the casual installer],
2722       maintainer_mode=$enableval,
2723       maintainer_mode=no)
2724
2725 AC_MSG_RESULT($maintainer_mode)
2726
2727 if test "$maintainer_mode" = "yes"; then
2728   MAINT=''
2729 else
2730   MAINT='#'
2731 fi
2732 AC_SUBST(MAINT)dnl
2733
2734 # Make empty files to contain the specs and options for each language.
2735 # Then add #include lines to for a compiler that has specs and/or options.
2736
2737 lang_opt_files=
2738 lang_specs_files=
2739 lang_tree_files=
2740 for subdir in . $subdirs
2741 do
2742         if test -f $srcdir/$subdir/lang.opt; then
2743             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2744         fi
2745         if test -f $srcdir/$subdir/lang-specs.h; then
2746             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2747         fi
2748         if test -f $srcdir/$subdir/$subdir-tree.def; then
2749             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2750         fi
2751 done
2752
2753 # These (without "all_") are set in each config-lang.in.
2754 # `language' must be a single word so is spelled singularly.
2755 all_languages=
2756 all_boot_languages=
2757 all_compilers=
2758 all_stagestuff=
2759 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2760 # List of language makefile fragments.
2761 all_lang_makefrags=
2762 # List of language subdirectory makefiles.  Deprecated.
2763 all_lang_makefiles=
2764 # Files for gengtype
2765 all_gtfiles="$target_gtfiles"
2766 # Files for gengtype with language
2767 all_gtfiles_files_langs=
2768 all_gtfiles_files_files=
2769
2770 # Add the language fragments.
2771 # Languages are added via two mechanisms.  Some information must be
2772 # recorded in makefile variables, these are defined in config-lang.in.
2773 # We accumulate them and plug them into the main Makefile.
2774 # The other mechanism is a set of hooks for each of the main targets
2775 # like `clean', `install', etc.
2776
2777 language_hooks="Make-hooks"
2778
2779 for s in $subdirs
2780 do
2781                 language=
2782                 boot_language=
2783                 compilers=
2784                 stagestuff=
2785                 outputs=
2786                 gtfiles=
2787                 . ${srcdir}/$s/config-lang.in
2788                 if test "x$language" = x
2789                 then
2790                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2791                         exit 1
2792                 fi
2793                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2794                 if test -f ${srcdir}/$s/Makefile.in
2795                 then all_lang_makefiles="$s/Makefile"
2796                 fi
2797                 all_languages="$all_languages $language"
2798                 if test "x$boot_language" = xyes
2799                 then
2800                         all_boot_languages="$all_boot_languages $language"
2801                 fi
2802                 all_compilers="$all_compilers $compilers"
2803                 all_stagestuff="$all_stagestuff $stagestuff"
2804                 all_outputs="$all_outputs $outputs"
2805                 all_gtfiles="$all_gtfiles $gtfiles"
2806                 for f in $gtfiles
2807                 do
2808                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2809                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2810                 done
2811 done
2812
2813 # Pick up gtfiles for c
2814 gtfiles=
2815 s="c"
2816 . ${srcdir}/c-config-lang.in
2817 all_gtfiles="$all_gtfiles $gtfiles"
2818 for f in $gtfiles
2819 do
2820         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2821         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2822 done
2823
2824 check_languages=
2825 for language in $all_languages
2826 do
2827                 check_languages="$check_languages check-$language"
2828 done
2829
2830 # We link each language in with a set of hooks, reached indirectly via
2831 # lang.${target}.
2832
2833 rm -f Make-hooks
2834 touch Make-hooks
2835 target_list="all.build all.cross start.encap rest.encap tags \
2836         install-normal install-common install-info install-man \
2837         uninstall \
2838         mostlyclean clean distclean extraclean maintainer-clean \
2839         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2840 for t in $target_list
2841 do
2842         x=
2843         for lang in $all_languages
2844         do
2845                         x="$x $lang.$t"
2846         done
2847         echo "lang.$t: $x" >> Make-hooks
2848 done
2849
2850 # Create .gdbinit.
2851
2852 echo "dir ." > .gdbinit
2853 echo "dir ${srcdir}" >> .gdbinit
2854 if test x$gdb_needs_out_file_path = xyes
2855 then
2856         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2857 fi
2858 if test "x$subdirs" != x; then
2859         for s in $subdirs
2860         do
2861                 echo "dir ${srcdir}/$s" >> .gdbinit
2862         done
2863 fi
2864 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2865
2866 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2867 # absolute path for gcc_tooldir based on inserting the number of up-directory
2868 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2869 # $(libsubdir)/@(unlibsubdir) based path.
2870 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2871 # make and thus we'd get different behavior depending on where we built the
2872 # sources.
2873 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2874     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2875 else
2876 changequote(<<, >>)dnl
2877 # An explanation of the sed strings:
2878 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2879 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2880 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2881 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2882 #
2883 # (*) Note this pattern overwrites the first character of the string
2884 # with a forward slash if one is not already present.  This is not a
2885 # problem because the exact names of the sub-directories concerned is
2886 # unimportant, just the number of them matters.
2887 #
2888 # The practical upshot of these patterns is like this:
2889 #
2890 #  prefix     exec_prefix        result
2891 #  ------     -----------        ------
2892 #   /foo        /foo/bar          ../
2893 #   /foo/       /foo/bar          ../
2894 #   /foo        /foo/bar/         ../
2895 #   /foo/       /foo/bar/         ../
2896 #   /foo        /foo/bar/ugg      ../../
2897 #
2898     dollar='$$'
2899     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2900 changequote([, ])dnl
2901 fi
2902 AC_SUBST(gcc_tooldir)
2903 AC_SUBST(dollar)
2904
2905 # Find a directory in which to install a shared libgcc.
2906
2907 AC_ARG_ENABLE(version-specific-runtime-libs,
2908 [  --enable-version-specific-runtime-libs
2909                           specify that runtime libraries should be
2910                           installed in a compiler-specific directory])
2911
2912 AC_ARG_WITH(slibdir,
2913 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2914 slibdir="$with_slibdir",
2915 if test "${enable_version_specific_runtime_libs+set}" = set; then
2916   slibdir='$(libsubdir)'
2917 elif test "$host" != "$target"; then
2918   slibdir='$(build_tooldir)/lib'
2919 else
2920   slibdir='$(libdir)'
2921 fi)
2922 AC_SUBST(slibdir)
2923
2924 objdir=`${PWDCMD-pwd}`
2925 AC_SUBST(objdir)
2926
2927 # Substitute configuration variables
2928 AC_SUBST(subdirs)
2929 AC_SUBST(srcdir)
2930 AC_SUBST(all_boot_languages)
2931 AC_SUBST(all_compilers)
2932 AC_SUBST(all_gtfiles)
2933 AC_SUBST(all_gtfiles_files_langs)
2934 AC_SUBST(all_gtfiles_files_files)
2935 AC_SUBST(all_lang_makefrags)
2936 AC_SUBST(all_lang_makefiles)
2937 AC_SUBST(all_languages)
2938 AC_SUBST(all_stagestuff)
2939 AC_SUBST(build_exeext)
2940 AC_SUBST(build_install_headers_dir)
2941 AC_SUBST(build_xm_file_list)
2942 AC_SUBST(build_xm_include_list)
2943 AC_SUBST(build_xm_defines)
2944 AC_SUBST(check_languages)
2945 AC_SUBST(cc_set_by_configure)
2946 AC_SUBST(quoted_cc_set_by_configure)
2947 AC_SUBST(cpp_install_dir)
2948 AC_SUBST(xmake_file)
2949 AC_SUBST(tmake_file)
2950 AC_SUBST(extra_headers_list)
2951 AC_SUBST(extra_objs)
2952 AC_SUBST(extra_parts)
2953 AC_SUBST(extra_passes)
2954 AC_SUBST(extra_programs)
2955 AC_SUBST(float_h_file)
2956 AC_SUBST(gcc_config_arguments)
2957 AC_SUBST(gcc_gxx_include_dir)
2958 AC_SUBST(libstdcxx_incdir)
2959 AC_SUBST(gcc_version)
2960 AC_SUBST(gcc_version_full)
2961 AC_SUBST(gcc_version_trigger)
2962 AC_SUBST(host_exeext)
2963 AC_SUBST(host_extra_gcc_objs)
2964 AC_SUBST(host_xm_file_list)
2965 AC_SUBST(host_xm_include_list)
2966 AC_SUBST(host_xm_defines)
2967 AC_SUBST(out_host_hook_obj)
2968 AC_SUBST(install)
2969 AC_SUBST(lang_opt_files)
2970 AC_SUBST(lang_specs_files)
2971 AC_SUBST(lang_tree_files)
2972 AC_SUBST(local_prefix)
2973 AC_SUBST(md_file)
2974 AC_SUBST(objc_boehm_gc)
2975 AC_SUBST(out_file)
2976 AC_SUBST(out_object_file)
2977 AC_SUBST(stage_prefix_set_by_configure)
2978 AC_SUBST(quoted_stage_prefix_set_by_configure)
2979 AC_SUBST(symbolic_link)
2980 AC_SUBST(thread_file)
2981 AC_SUBST(tm_file_list)
2982 AC_SUBST(tm_include_list)
2983 AC_SUBST(tm_defines)
2984 AC_SUBST(tm_p_file_list)
2985 AC_SUBST(tm_p_include_list)
2986 AC_SUBST(xm_file_list)
2987 AC_SUBST(xm_include_list)
2988 AC_SUBST(xm_defines)
2989 AC_SUBST(target_alias)
2990 AC_SUBST(c_target_objs)
2991 AC_SUBST(cxx_target_objs)
2992 AC_SUBST(target_cpu_default)
2993
2994 AC_SUBST_FILE(language_hooks)
2995
2996 # Echo that links are built
2997 if test x$host = x$target
2998 then
2999         str1="native "
3000 else
3001         str1="cross-"
3002         str2=" from $host"
3003 fi
3004
3005 if test x$host != x$build
3006 then
3007         str3=" on a $build system"
3008 fi
3009
3010 if test "x$str2" != x || test "x$str3" != x
3011 then
3012         str4=
3013 fi
3014
3015 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
3016
3017 if test "x$str2" != x || test "x$str3" != x
3018 then
3019         echo " ${str2}${str3}." 1>&2
3020 fi
3021
3022 # Configure the subdirectories
3023 # AC_CONFIG_SUBDIRS($subdirs)
3024
3025 # Create the Makefile
3026 # and configure language subdirectories
3027 AC_OUTPUT($all_outputs,
3028 [
3029 case x$CONFIG_HEADERS in
3030 xauto-host.h:config.in)
3031 echo > cstamp-h ;;
3032 esac
3033 # Make sure all the subdirs exist.
3034 for d in $subdirs
3035 do
3036     test -d $d || mkdir $d
3037 done
3038 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3039 # bootstrapping and the installation procedure can still use
3040 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3041 # FLAGS_TO_PASS has been modified to solve the problem there.
3042 # This is virtually a duplicate of what happens in configure.lang; we do
3043 # an extra check to make sure this only happens if ln -s can be used.
3044 if test "$symbolic_link" = "ln -s"; then
3045  for d in ${subdirs} fixinc ; do
3046         STARTDIR=`${PWDCMD-pwd}`
3047         cd $d
3048         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3049         do
3050                 rm -f $t
3051                 $symbolic_link ../$t $t 2>/dev/null
3052         done
3053         cd $STARTDIR
3054  done
3055 else true ; fi
3056 ],
3057 [subdirs='$subdirs'
3058 symbolic_link='$symbolic_link'
3059 ])