gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 2, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to the Free
  20 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname)],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname)],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib       enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC
 277   --enable-threads=LIB    use LIB thread package for target GCC],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2           force the default debug format to be DWARF 2],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared        don't provide a shared libgcc],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Find the native compiler
 339 AC_PROG_CC
 340 AC_PROG_CC_C_O
 341 # autoconf is lame and doesn't give us any substitution variable for this.
 342 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 343   NO_MINUS_C_MINUS_O=yes
 344 else
 345   OUTPUT_OPTION='-o $@'
 346 fi
 347 AC_SUBST(NO_MINUS_C_MINUS_O)
 348 AC_SUBST(OUTPUT_OPTION)
 349
 350 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 351 ac_cv_prog_cc_no_long_long,
 352 [save_CFLAGS="$CFLAGS"
 353 CFLAGS="-Wno-long-long"
 354 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 355                ac_cv_prog_cc_no_long_long=no)
 356 CFLAGS="$save_CFLAGS"])
 357 strict1_warn=
 358 if test $ac_cv_prog_cc_no_long_long = yes; then
 359   strict1_warn="-pedantic -Wno-long-long"
 360 fi
 361 AC_SUBST(strict1_warn)
 362
 363 AC_PROG_CPP
 364 AC_C_INLINE
 365 gcc_AC_C_VOLATILE
 366
 367 gcc_AC_C_LONG_DOUBLE
 368 gcc_AC_C_LONG_LONG
 369 gcc_AC_C__BOOL
 370
 371 # sizeof(char) is 1 by definition.
 372 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 373 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 374 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 375 if test $ac_cv_c_long_long = yes; then
 376   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 377 fi
 378 if test $ac_cv_c___int64 = yes; then
 379   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 380 fi
 381
 382 gcc_AC_C_CHARSET
 383
 384 # If the native compiler is GCC, we can enable warnings even in stage1.
 385 # That's useful for people building cross-compilers, or just running a
 386 # quick `make'.
 387 warn_cflags=
 388 if test "x$GCC" = "xyes"; then
 389   warn_cflags='$(GCC_WARN_CFLAGS)'
 390 fi
 391 AC_SUBST(warn_cflags)
 392
 393 # Stage specific cflags for build.
 394 stage1_cflags=
 395 case $build in
 396 vax-*-*)
 397   if test x$GCC = xyes
 398   then
 399     stage1_cflags="-Wa,-J"
 400   else
 401     stage1_cflags="-J"
 402   fi
 403   ;;
 404 esac
 405 AC_SUBST(stage1_cflags)
 406
 407 AC_PROG_MAKE_SET
 408
 409 AC_MSG_CHECKING([whether a default assembler was specified])
 410 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 411     if test x"$gas_flag" = x"no"; then
 412         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 413     else
 414         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 415     fi
 416 else
 417     AC_MSG_RESULT(no)
 418 fi
 419
 420 AC_MSG_CHECKING([whether a default linker was specified])
 421 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 422     if test x"$gnu_ld_flag" = x"no"; then
 423         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 424     else
 425         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 426     fi
 427 else
 428     AC_MSG_RESULT(no)
 429 fi
 430
 431 AC_MSG_CHECKING(for GNU C library)
 432 AC_CACHE_VAL(gcc_cv_glibc,
 433 [AC_TRY_COMPILE(
 434   [#include <features.h>],[
 435 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 436 #error Not a GNU C library system
 437 #endif],
 438   [gcc_cv_glibc=yes],
 439   gcc_cv_glibc=no)])
 440 AC_MSG_RESULT($gcc_cv_glibc)
 441 if test $gcc_cv_glibc = yes; then
 442   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 443 fi
 444
 445 # Find some useful tools
 446 AC_PROG_AWK
 447 gcc_AC_PROG_LN
 448 gcc_AC_PROG_LN_S
 449 AC_PROG_RANLIB
 450 gcc_AC_PROG_INSTALL
 451
 452 AC_HEADER_STDC
 453 AC_HEADER_TIME
 454 gcc_AC_HEADER_STDBOOL
 455 gcc_AC_HEADER_STRING
 456 AC_HEADER_SYS_WAIT
 457 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 458                  fcntl.h unistd.h sys/file.h sys/time.h \
 459                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 460                  direct.h malloc.h langinfo.h)
 461
 462 # Check for thread headers.
 463 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 464 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 465
 466 # These tests can't be done till we know if we have limits.h.
 467 gcc_AC_C_CHAR_BIT
 468 gcc_AC_C_COMPILE_ENDIAN
 469 gcc_AC_C_FLOAT_FORMAT
 470
 471 # See if GNAT has been installed
 472 AC_CHECK_PROG(have_gnat, gnatbind, yes, no)
 473
 474 # See if we have the mktemp command.
 475 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 476
 477 # Do we have a single-tree copy of texinfo?
 478 if test -f $srcdir/../texinfo/Makefile.in; then
 479   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 480   gcc_cv_prog_makeinfo_modern=yes
 481   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 482 else
 483   # See if makeinfo has been installed and is modern enough
 484   # that we can use it.
 485   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 486   [GNU texinfo.* \([0-9][0-9.]*\)],
 487   [4.*])
 488 fi
 489
 490 if test $gcc_cv_prog_makeinfo_modern = no; then
 491   AC_MSG_WARN([
 492 *** Makeinfo is missing or too old.
 493 *** Info documentation will not be built.])
 494   BUILD_INFO=
 495 else
 496   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 497 fi
 498
 499 # Is pod2man recent enough to regenerate manpages?
 500 AC_MSG_CHECKING([for recent Pod::Man])
 501 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 502   AC_MSG_RESULT(yes)
 503   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 504 else
 505   AC_MSG_RESULT(no)
 506   GENERATED_MANPAGES=
 507 fi
 508
 509 # How about lex?
 510 dnl Don't use AC_PROG_LEX; we insist on flex.
 511 dnl LEXLIB is not useful in gcc.
 512 if test -f $srcdir/../flex/skel.c; then
 513   FLEX='$(objdir)/../flex/flex'
 514 else
 515   AC_CHECK_PROG(FLEX, flex, flex, false)
 516 fi
 517
 518 # Bison?
 519 # The -L switch is so bison can find its skeleton file.
 520 if test -f $srcdir/../bison/bison.simple; then
 521   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 522 else
 523   AC_CHECK_PROG(BISON, bison, bison, false)
 524 fi
 525
 526 # These libraries may be used by collect2.
 527 # We may need a special search path to get them linked.
 528 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 529 [save_LIBS="$LIBS"
 530 for libs in '' -lld -lmld \
 531                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 532                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 533 do
 534         LIBS="$libs"
 535         AC_TRY_LINK_FUNC(ldopen,
 536                 [gcc_cv_collect2_libs="$libs"; break])
 537 done
 538 LIBS="$save_LIBS"
 539 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 540 case $gcc_cv_collect2_libs in
 541         "none required")        ;;
 542         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 543 esac
 544 AC_SUBST(COLLECT2_LIBS)
 545
 546 # When building Ada code on Alpha, we need exc_resume which is usually in
 547 # -lexc.  So test for it.
 548 save_LIBS="$LIBS"
 549 LIBS=
 550 AC_SEARCH_LIBS(exc_resume, exc)
 551 GNAT_LIBEXC="$LIBS"
 552 LIBS="$save_LIBS"
 553 AC_SUBST(GNAT_LIBEXC)
 554
 555 # See if the stage1 system preprocessor understands the ANSI C
 556 # preprocessor stringification operator.  (Used by symcat.h.)
 557 AC_C_STRINGIZE
 558
 559 # Use <inttypes.h> only if it exists,
 560 # doesn't clash with <sys/types.h>, and declares intmax_t.
 561 AC_MSG_CHECKING(for inttypes.h)
 562 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 563 [AC_TRY_COMPILE(
 564   [#include <sys/types.h>
 565 #include <inttypes.h>],
 566   [intmax_t i = -1;],
 567   [gcc_cv_header_inttypes_h=yes],
 568   gcc_cv_header_inttypes_h=no)])
 569 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 570 if test $gcc_cv_header_inttypes_h = yes; then
 571   AC_DEFINE(HAVE_INTTYPES_H, 1,
 572         [Define if you have a working <inttypes.h> header file.])
 573 fi
 574
 575 dnl Disabled until we have a complete test for buggy enum bitfields.
 576 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 577
 578 AC_CHECK_FUNCS(strtoul bsearch popen times clock \
 579         strchr strrchr kill getrlimit setrlimit atoll atoq \
 580         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 581         fputs_unlocked getrusage nl_langinfo lstat)
 582
 583 AC_CHECK_TYPE(ssize_t, int)
 584
 585 # Try to determine the array type of the second argument of getgroups
 586 # for the target system (int or gid_t).
 587 AC_TYPE_GETGROUPS
 588 if test "${target}" = "${build}"; then
 589   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 590 else
 591   case "${target}" in
 592         # This condition may need some tweaking.  It should include all
 593         # targets where the array type of the second argument of getgroups
 594         # is int and the type of gid_t is not equivalent to int.
 595         *-*-sunos* | *-*-ultrix*)
 596                 TARGET_GETGROUPS_T=int
 597                 ;;
 598         *)
 599                 TARGET_GETGROUPS_T=gid_t
 600                 ;;
 601   esac
 602 fi
 603 AC_SUBST(TARGET_GETGROUPS_T)
 604
 605 gcc_AC_FUNC_VFPRINTF_DOPRNT
 606 gcc_AC_FUNC_STRSTR
 607 gcc_AC_FUNC_PRINTF_PTR
 608
 609 case "${host}" in
 610 *-*-uwin*)
 611   AC_MSG_ERROR([
 612 *** UWIN may not be used as a host platform because
 613 *** linking with posix.dll is not allowed by the GNU GPL])
 614   ;;
 615 esac
 616 AC_FUNC_VFORK
 617 AC_FUNC_MMAP_ANYWHERE
 618 AC_FUNC_MMAP_FILE
 619
 620 AM_ICONV
 621
 622 # We will need to find libiberty.h and ansidecl.h
 623 saved_CFLAGS="$CFLAGS"
 624 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 625 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 626         strsignal putc_unlocked fputs_unlocked strstr environ errno \
 627         malloc realloc calloc free basename getopt clock, , ,[
 628 #include "ansidecl.h"
 629 #include "system.h"])
 630
 631 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 632 #include "ansidecl.h"
 633 #include "system.h"
 634 #ifdef HAVE_SYS_RESOURCE_H
 635 #include <sys/resource.h>
 636 #endif
 637 ])
 638
 639 gcc_AC_CHECK_DECLS(times, , ,[
 640 #include "ansidecl.h"
 641 #include "system.h"
 642 #ifdef HAVE_SYS_TIMES_H
 643 #include <sys/times.h>
 644 #endif
 645 ])
 646
 647 # More time-related stuff.
 648 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 649 AC_TRY_COMPILE([
 650 #include "ansidecl.h"
 651 #include "system.h"
 652 #ifdef HAVE_SYS_TIMES_H
 653 #include <sys/times.h>
 654 #endif
 655 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 656 if test $ac_cv_struct_tms = yes; then
 657   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 658   [Define if <sys/times.h> defines struct tms.])
 659 fi
 660
 661 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 662 # revisit after autoconf 2.50.
 663 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 664 AC_TRY_COMPILE([
 665 #include "ansidecl.h"
 666 #include "system.h"
 667 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 668 if test $gcc_cv_type_clock_t = yes; then
 669   AC_DEFINE(HAVE_CLOCK_T, 1,
 670   [Define if <time.h> defines clock_t.])
 671 fi
 672
 673 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 674 CFLAGS="$saved_CFLAGS"
 675
 676 # mkdir takes a single argument on some systems.
 677 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 678
 679 # File extensions
 680 manext='.1'
 681 objext='.o'
 682 AC_SUBST(manext)
 683 AC_SUBST(objext)
 684
 685 build_xm_file=
 686 build_xm_defines=
 687 build_install_headers_dir=install-headers-tar
 688 build_exeext=
 689 host_xm_file=
 690 host_xm_defines=
 691 host_xmake_file=
 692 host_truncate_target=
 693 host_exeext=
 694
 695 # Decode the host machine, then the target machine.
 696 # For the host machine, we save the xm_file variable as host_xm_file;
 697 # then we decode the target machine and forget everything else
 698 # that came from the host machine.
 699 for machine in $build $host $target; do
 700         . ${srcdir}/config.gcc
 701 done
 702
 703 extra_objs="${host_extra_objs} ${extra_objs}"
 704
 705 # Default the target-machine variables that were not explicitly set.
 706 if test x"$tm_file" = x
 707 then tm_file=$cpu_type/$cpu_type.h; fi
 708
 709 if test x"$extra_headers" = x
 710 then extra_headers=; fi
 711
 712 if test x$md_file = x
 713 then md_file=$cpu_type/$cpu_type.md; fi
 714
 715 if test x$out_file = x
 716 then out_file=$cpu_type/$cpu_type.c; fi
 717
 718 if test x"$tmake_file" = x
 719 then tmake_file=$cpu_type/t-$cpu_type
 720 fi
 721
 722 if test x"$dwarf2" = xyes
 723 then tm_file="$tm_file tm-dwarf2.h"
 724 fi
 725
 726 if test x$float_format = x
 727 then float_format=i64
 728 fi
 729
 730 if test $float_format = none
 731 then float_h_file=Makefile.in
 732 else float_h_file=float-$float_format.h
 733 fi
 734
 735 # Handle cpp installation.
 736 if test x$enable_cpp != xno
 737 then
 738   tmake_file="$tmake_file t-install-cpp"
 739 fi
 740
 741 # Say what files are being used for the output code and MD file.
 742 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 743 echo "Using \`$srcdir/config/$md_file' as machine description file."
 744
 745 # If any of the xm_file variables contain nonexistent files, warn
 746 # about them and drop them.
 747
 748 bx=
 749 for x in $build_xm_file; do
 750   if    test -f $srcdir/config/$x
 751   then      bx="$bx $x"
 752   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 753   fi
 754 done
 755 build_xm_file="$bx"
 756
 757 hx=
 758 for x in $host_xm_file; do
 759   if    test -f $srcdir/config/$x
 760   then      hx="$hx $x"
 761   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 762   fi
 763 done
 764 host_xm_file="$hx"
 765
 766 tx=
 767 for x in $xm_file; do
 768   if    test -f $srcdir/config/$x
 769   then      tx="$tx $x"
 770   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 771   fi
 772 done
 773 xm_file="$tx"
 774
 775 count=a
 776 for f in $tm_file; do
 777         count=${count}x
 778 done
 779 if test $count = ax; then
 780         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 781 else
 782         echo "Using the following target machine macro files:"
 783         for f in $tm_file; do
 784                 echo "  $srcdir/config/$f"
 785         done
 786 fi
 787
 788 count=a
 789 for f in $host_xm_file; do
 790         count=${count}x
 791 done
 792 if test $count = a; then
 793         :
 794 elif test $count = ax; then
 795         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 796 else
 797         echo "Using the following host machine macro files:"
 798         for f in $host_xm_file; do
 799                 echo "  $srcdir/config/$f"
 800         done
 801 fi
 802
 803 if test "$host_xm_file" != "$build_xm_file"; then
 804         count=a
 805         for f in $build_xm_file; do
 806                 count=${count}x
 807         done
 808         if test $count = a; then
 809                 :
 810         elif test $count = ax; then
 811                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 812         else
 813                 echo "Using the following build machine macro files:"
 814                 for f in $build_xm_file; do
 815                         echo "  $srcdir/config/$f"
 816                 done
 817         fi
 818 fi
 819
 820 if test x$thread_file = x; then
 821         if test x$target_thread_file != x; then
 822                 thread_file=$target_thread_file
 823         else
 824                 thread_file='single'
 825         fi
 826 fi
 827
 828 # auto-host.h is the file containing items generated by autoconf and is
 829 # the first file included by config.h.
 830 # If host=build, it is correct to have hconfig include auto-host.h
 831 # as well.  If host!=build, we are in error and need to do more
 832 # work to find out the build config parameters.
 833 if test x$host = x$build
 834 then
 835         build_auto=auto-host.h
 836 else
 837         # We create a subdir, then run autoconf in the subdir.
 838         # To prevent recursion we set host and build for the new
 839         # invocation of configure to the build for this invocation
 840         # of configure.
 841         tempdir=build.$$
 842         rm -rf $tempdir
 843         mkdir $tempdir
 844         cd $tempdir
 845         case ${srcdir} in
 846         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 847         *) realsrcdir=../${srcdir};;
 848         esac
 849         saved_CFLAGS="${CFLAGS}"
 850         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
 851         ${realsrcdir}/configure \
 852                 --target=$target --host=$build --build=$build
 853         CFLAGS="${saved_CFLAGS}"
 854
 855         # We just finished tests for the build machine, so rename
 856         # the file auto-build.h in the gcc directory.
 857         mv auto-host.h ../auto-build.h
 858         cd ..
 859         rm -rf $tempdir
 860         build_auto=auto-build.h
 861 fi
 862
 863 tm_file="${tm_file} defaults.h"
 864 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 865 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 866 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 867
 868 # Truncate the target if necessary
 869 if test x$host_truncate_target != x; then
 870         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 871 fi
 872
 873 # Get the version trigger filename from the toplevel
 874 if test "${with_gcc_version_trigger+set}" = set; then
 875         gcc_version_trigger=$with_gcc_version_trigger
 876 else
 877         gcc_version_trigger=${srcdir}/version.c
 878 fi
 879 changequote(,)dnl
 880 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 881 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 882
 883 # Compile in configure arguments.
 884 if test -f configargs.h ; then
 885         # Being re-configured.
 886         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
 887         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 888 else
 889         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 890 fi
 891 cat > configargs.h <<EOF
 892 /* Generated automatically. */
 893 static const char configuration_arguments[] = "$gcc_config_arguments";
 894 static const char thread_model[] = "$thread_file";
 895 EOF
 896 changequote([,])dnl
 897
 898 # Internationalization
 899 PACKAGE=gcc
 900 VERSION="$gcc_version"
 901 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 902         [Define to the name of the distribution.])
 903 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 904         [Define to the version of the distribution.])
 905 AC_SUBST(PACKAGE)
 906 AC_SUBST(VERSION)
 907
 908 ALL_LINGUAS="sv"
 909
 910 # Enable NLS support by default
 911 AC_ARG_ENABLE(nls,
 912   [  --enable-nls            use Native Language Support (default)],
 913   , enable_nls=yes)
 914
 915 # if cross compiling, disable NLS support.
 916 # It's not worth the trouble, at least for now.
 917
 918 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 919   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 920   enable_nls=no
 921 fi
 922
 923 # if NLS is enabled, also enable check in po subdir
 924 if test $enable_nls = yes; then
 925   CHECK_PO=check-po
 926 else
 927   CHECK_PO=""
 928 fi
 929
 930 AC_SUBST(CHECK_PO)
 931
 932 AM_GNU_GETTEXT
 933 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 934
 935 # Windows32 Registry support for specifying GCC installation paths.
 936 AC_ARG_ENABLE(win32-registry,
 937 [  --disable-win32-registry
 938                           disable lookup of installation paths in the
 939                           Registry on Windows hosts
 940   --enable-win32-registry enable registry lookup (default)
 941   --enable-win32-registry=KEY
 942                           use KEY instead of GCC version as the last portion
 943                           of the registry key],,)
 944 case $host_os in
 945         win32 | pe | cygwin* | mingw32* | uwin*)
 946 AC_MSG_CHECKING(whether windows registry support is requested)
 947 if test "x$enable_win32_registry" != xno; then
 948   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 949 [Define to 1 if installation paths should be looked up in Windows32
 950    Registry. Ignored on non windows32 hosts.])
 951   AC_MSG_RESULT(yes)
 952   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 953 else
 954   AC_MSG_RESULT(no)
 955 fi
 956
 957 # Check if user specified a different registry key.
 958 case "x${enable_win32_registry}" in
 959 x | xyes)
 960   # default.
 961   gcc_cv_win32_registry_key="$VERSION"
 962   ;;
 963 xno)
 964   # no registry lookup.
 965   gcc_cv_win32_registry_key=''
 966   ;;
 967 *)
 968   # user-specified key.
 969   gcc_cv_win32_registry_key="$enable_win32_registry"
 970   ;;
 971 esac
 972
 973 if test "x$enable_win32_registry" != xno; then
 974   AC_MSG_CHECKING(registry key on windows hosts)
 975   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 976         [Define to be the last portion of registry key on windows hosts.])
 977   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 978 fi
 979 ;;
 980 esac
 981
 982 # Get an absolute path to the GCC top-level source directory
 983 holddir=`pwd`
 984 cd $srcdir
 985 topdir=`pwd`
 986 cd $holddir
 987
 988 # Conditionalize the makefile for this host machine.
 989 # Make-host contains the concatenation of all host makefile fragments
 990 # [there can be more than one].  This file is built by configure.frag.
 991 host_overrides=Make-host
 992 dep_host_xmake_file=
 993 for f in .. ${host_xmake_file}
 994 do
 995         if test -f ${srcdir}/config/$f
 996         then
 997                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 998         fi
 999 done
1000
1001 # Conditionalize the makefile for this target machine.
1002 # Make-target contains the concatenation of all host makefile fragments
1003 # [there can be more than one].  This file is built by configure.frag.
1004 target_overrides=Make-target
1005 dep_tmake_file=
1006 for f in .. ${tmake_file}
1007 do
1008         if test -f ${srcdir}/config/$f
1009         then
1010                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1011         fi
1012 done
1013
1014 # If the host doesn't support symlinks, modify CC in
1015 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1016 # Otherwise, we can use "CC=$(CC)".
1017 rm -f symtest.tem
1018 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1019 then
1020         cc_set_by_configure="\$(CC)"
1021         quoted_cc_set_by_configure="\$(CC)"
1022         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1023 else
1024         rm -f symtest.tem
1025         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1026         then
1027                 symbolic_link="cp -p"
1028         else
1029                 symbolic_link="cp"
1030         fi
1031         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1032         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1033         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1034 fi
1035 rm -f symtest.tem
1036
1037 out_object_file=`basename $out_file .c`.o
1038
1039 tm_file_list=
1040 for f in $tm_file; do
1041   case $f in
1042     ansidecl.h )
1043        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1044     defaults.h )
1045        tm_file_list="${tm_file_list} $f" ;;
1046     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1047   esac
1048 done
1049
1050 tm_p_file_list=
1051 for f in $tm_p_file; do
1052     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1053 done
1054
1055 host_xm_file_list=
1056 for f in $host_xm_file; do
1057   case $f in
1058     ansidecl.h )
1059        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1060     auto-host.h | defaults.h )
1061        host_xm_file_list="${host_xm_file_list} $f" ;;
1062     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1063   esac
1064 done
1065
1066 build_xm_file_list=
1067 for f in $build_xm_file; do
1068   case $f in
1069     ansidecl.h )
1070        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1071     auto-build.h | auto-host.h | defaults.h )
1072        build_xm_file_list="${build_xm_file_list} $f" ;;
1073     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1074   esac
1075 done
1076
1077 # Define macro CROSS_COMPILE in compilation
1078 # if this is a cross-compiler.
1079 # Also use all.cross instead of all.internal
1080 # and add cross-make to Makefile.
1081 cross_overrides="/dev/null"
1082 if test x$host != x$target
1083 then
1084         cross_defines="CROSS=-DCROSS_COMPILE"
1085         cross_overrides="${topdir}/cross-make"
1086 fi
1087
1088 # If this is a cross-compiler that does not
1089 # have its own set of headers then define
1090 # inhibit_libc
1091
1092 # If this is using newlib, then define inhibit_libc in LIBGCC2_CFLAGS.
1093 # This prevents libgcc2 from containing any code which requires libc
1094 # support.
1095 inhibit_libc=
1096 if [test x$host != x$target] && [test x$with_headers = x]; then
1097        inhibit_libc=-Dinhibit_libc
1098 else
1099        if [test x$with_newlib = xyes]; then
1100                inhibit_libc=-Dinhibit_libc
1101        fi
1102 fi
1103 AC_SUBST(inhibit_libc)
1104
1105 # When building gcc with a cross-compiler, we need to fix a few things.
1106 # This must come after cross-make as we want all.build to override
1107 # all.cross.
1108 build_overrides="/dev/null"
1109 if test x$build != x$host
1110 then
1111         build_overrides="${topdir}/build-make"
1112 fi
1113
1114 # Expand extra_headers to include complete path.
1115 # This substitutes for lots of t-* files.
1116 extra_headers_list=
1117 if test "x$extra_headers" = x
1118 then true
1119 else
1120         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1121         for file in $extra_headers;
1122         do
1123                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1124         done
1125 fi
1126
1127 if test x$use_collect2 = xno; then
1128         use_collect2=
1129 fi
1130
1131 # Add a definition of USE_COLLECT2 if system wants one.
1132 if test x$use_collect2 != x
1133 then
1134         host_xm_defines="${host_xm_defines} USE_COLLECT2"
1135         xm_defines="${xm_defines} USE_COLLECT2"
1136 fi
1137
1138 # If we have gas in the build tree, make a link to it.
1139 if test -f ../gas/Makefile; then
1140         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1141 fi
1142
1143 # If we have nm in the build tree, make a link to it.
1144 if test -f ../binutils/Makefile; then
1145         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1146 fi
1147
1148 # If we have ld in the build tree, make a link to it.
1149 if test -f ../ld/Makefile; then
1150         rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1151 fi
1152
1153 # Figure out what assembler we will be using.
1154 AC_MSG_CHECKING(what assembler to use)
1155 gcc_cv_as=
1156 gcc_cv_gas_major_version=
1157 gcc_cv_gas_minor_version=
1158 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1159 if test -x "$DEFAULT_ASSEMBLER"; then
1160         gcc_cv_as="$DEFAULT_ASSEMBLER"
1161 elif test -x "$AS"; then
1162         gcc_cv_as="$AS"
1163 elif test -x as$host_exeext; then
1164         # Build using assembler in the current directory.
1165         gcc_cv_as=./as$host_exeext
1166 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1167         # Single tree build which includes gas.
1168         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1169         do
1170 changequote(,)dnl
1171                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1172 changequote([,])dnl
1173                 if test x$gcc_cv_gas_version != x; then
1174                         break
1175                 fi
1176         done
1177 changequote(,)dnl
1178         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1179         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1180 changequote([,])dnl
1181 fi
1182
1183 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1184         # Native build.
1185         # Search the same directories that the installed compiler will
1186         # search.  Else we may find the wrong assembler and lose.  If we
1187         # do not find a suitable assembler binary, then try the user's
1188         # path.
1189         #
1190         # Also note we have to check MD_EXEC_PREFIX before checking the
1191         # user's path.  Unfortunately, there is no good way to get at the
1192         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1193         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1194         # to be fixed as part of the make/configure rewrite too.
1195
1196         if test "x$exec_prefix" = xNONE; then
1197                 if test "x$prefix" = xNONE; then
1198                         test_prefix=/usr/local
1199                 else
1200                         test_prefix=$prefix
1201                 fi
1202         else
1203                 test_prefix=$exec_prefix
1204         fi
1205
1206         # If the loop below does not find an assembler, then use whatever
1207         # one we can find in the users's path.
1208         # user's path.
1209         gcc_cv_as=as$host_exeext
1210
1211         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1212                    $test_prefix/lib/gcc-lib/$target \
1213                    /usr/lib/gcc/$target/$gcc_version \
1214                    /usr/lib/gcc/$target \
1215                    $test_prefix/$target/bin/$target/$gcc_version \
1216                    $test_prefix/$target/bin \
1217                    /usr/libexec \
1218                    /usr/ccs/gcc \
1219                    /usr/ccs/bin \
1220                    /udk/usr/ccs/bin \
1221                    /bsd43/usr/lib/cmplrs/cc \
1222                    /usr/cross64/usr/bin \
1223                    /usr/lib/cmplrs/cc \
1224                    /sysv/usr/lib/cmplrs/cc \
1225                    /svr4/usr/lib/cmplrs/cc \
1226                    /usr/bin"
1227
1228         for dir in $test_dirs; do
1229                 if test -f $dir/as$host_exeext; then
1230                         gcc_cv_as=$dir/as$host_exeext
1231                         break;
1232                 fi
1233         done
1234 fi
1235 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1236   AC_MSG_RESULT("newly built gas")
1237 else
1238   AC_MSG_RESULT($gcc_cv_as)
1239 fi
1240
1241 # Figure out what nm we will be using.
1242 AC_MSG_CHECKING(what nm to use)
1243 if test -x nm$host_exeext; then
1244         gcc_cv_nm=./nm$host_exeext
1245 elif test x$host = x$target; then
1246         # Native build.
1247         gcc_cv_nm=nm$host_exeext
1248 fi
1249 AC_MSG_RESULT($gcc_cv_nm)
1250
1251 # Figure out what assembler alignment features are present.
1252 AC_MSG_CHECKING(assembler alignment features)
1253 gcc_cv_as_alignment_features=none
1254 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1255         # Gas version 2.6 and later support for .balign and .p2align.
1256         # bytes to skip when using .p2align.
1257         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1258                 gcc_cv_as_alignment_features=".balign and .p2align"
1259                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1260         fi
1261         # Gas version 2.8 and later support specifying the maximum
1262         # bytes to skip when using .p2align.
1263         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1264                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1265                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1266         fi
1267 elif test x$gcc_cv_as != x; then
1268         # Check if we have .balign and .p2align
1269         echo ".balign  4" > conftest.s
1270         echo ".p2align  2" >> conftest.s
1271         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1272                 gcc_cv_as_alignment_features=".balign and .p2align"
1273                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1274         fi
1275         rm -f conftest.s conftest.o
1276         # Check if specifying the maximum bytes to skip when
1277         # using .p2align is supported.
1278         echo ".p2align 4,,7" > conftest.s
1279         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1280                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1281                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1282         fi
1283         rm -f conftest.s conftest.o
1284 fi
1285 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1286
1287 AC_MSG_CHECKING(assembler subsection support)
1288 gcc_cv_as_subsections=no
1289 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1290   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1291     gcc_cv_as_subsections="working .subsection -1"
1292   fi
1293 elif test x$gcc_cv_as != x; then
1294         # Check if we have .subsection
1295         echo ".subsection 1" > conftest.s
1296         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1297                 gcc_cv_as_subsections=".subsection"
1298                 if test x$gcc_cv_nm != x; then
1299                         cat > conftest.s <<EOF
1300 conftest_label1: .word 0
1301 .subsection -1
1302 conftest_label2: .word 0
1303 .previous
1304 EOF
1305                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1306                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1307                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1308                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1309                                         :
1310                                 else
1311                                         gcc_cv_as_subsections="working .subsection -1"
1312                                 fi
1313                         fi
1314                 fi
1315         fi
1316         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1317 fi
1318 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1319         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1320 [Define if your assembler supports .subsection and .subsection -1 starts
1321    emitting at the beginning of your section.])
1322 fi
1323 AC_MSG_RESULT($gcc_cv_as_subsections)
1324
1325 AC_MSG_CHECKING(assembler weak support)
1326 gcc_cv_as_weak=no
1327 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1328   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1329     gcc_cv_as_weak="yes"
1330   fi
1331 elif test x$gcc_cv_as != x; then
1332         # Check if we have .weak
1333         echo "  .weak foobar" > conftest.s
1334         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1335                 gcc_cv_as_weak="yes"
1336         fi
1337         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1338 fi
1339 if test x"$gcc_cv_as_weak" = xyes; then
1340         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1341 fi
1342 AC_MSG_RESULT($gcc_cv_as_weak)
1343
1344 AC_MSG_CHECKING(assembler hidden support)
1345 gcc_cv_as_hidden=no
1346 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1347   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1348     gcc_cv_as_hidden="yes"
1349   fi
1350 elif test x$gcc_cv_as != x; then
1351         # Check if we have .hidden
1352         echo "  .hidden foobar" > conftest.s
1353         echo "foobar:" >> conftest.s
1354         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1355                 gcc_cv_as_hidden="yes"
1356         fi
1357         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1358 fi
1359 if test x"$gcc_cv_as_hidden" = xyes; then
1360         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1361                 [Define if your assembler supports .hidden.])
1362 fi
1363 AC_MSG_RESULT($gcc_cv_as_hidden)
1364
1365 AC_MSG_CHECKING(assembler leb128 support)
1366 gcc_cv_as_leb128=no
1367 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1368   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1369     gcc_cv_as_leb128="yes"
1370   fi
1371 elif test x$gcc_cv_as != x; then
1372         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1373         cat > conftest.s <<EOF
1374         .data
1375         .uleb128 L2 - L1
1376 L1:
1377         .uleb128 1280
1378         .sleb128 -1010
1379 L2:
1380 EOF
1381         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1382                 gcc_cv_as_leb128="yes"
1383
1384                 # GAS versions before 2.11 do not support uleb128,
1385                 # despite appearing to.
1386                 # ??? There exists an elf-specific test that will crash
1387                 # the assembler.  Perhaps it's better to figure out whether
1388                 # arbitrary sections are supported and try the test.
1389                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1390                 if echo "$as_ver" | grep GNU > /dev/null; then
1391                         as_ver=`echo $as_ver | sed -e 's/.* //'`
1392                         as_major=`echo $as_ver | sed 's/\..*//'`
1393 changequote(,)dnl
1394                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1395 changequote([,])dnl
1396                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1397                                 gcc_cv_as_leb128="no"
1398                         fi
1399                 fi
1400         fi
1401         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1402 fi
1403 if test x"$gcc_cv_as_leb128" = xyes; then
1404         AC_DEFINE(HAVE_AS_LEB128, 1,
1405                 [Define if your assembler supports .uleb128.])
1406 fi
1407 AC_MSG_RESULT($gcc_cv_as_leb128)
1408
1409 AC_MSG_CHECKING(assembler eh_frame optimization)
1410 gcc_cv_as_eh_frame=no
1411 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1412   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1413     gcc_cv_as_eh_frame="yes"
1414   fi
1415 elif test x$gcc_cv_as != x; then
1416         # Check if this is GAS.
1417         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1418         rm -f a.out 2> /dev/null
1419         if echo "$as_ver" | grep GNU > /dev/null; then
1420                 # Versions up to and including 2.11.0 may mis-optimize
1421                 # .eh_frame data.  Try something.
1422                 cat > conftest.s <<EOF
1423         .text
1424 .LFB1:
1425         .4byte  0
1426 .L1:
1427         .4byte  0
1428 .LFE1:
1429         .section        .eh_frame,"aw",@progbits
1430 __FRAME_BEGIN__:
1431         .4byte  .LECIE1-.LSCIE1
1432 .LSCIE1:
1433         .4byte  0x0
1434         .byte   0x1
1435         .ascii "z\0"
1436         .byte   0x1
1437         .byte   0x78
1438         .byte   0x1a
1439         .byte   0x0
1440         .byte   0x4
1441         .4byte  1
1442         .p2align 1
1443 .LECIE1:
1444 .LSFDE1:
1445         .4byte  .LEFDE1-.LASFDE1
1446 .LASFDE1:
1447         .4byte  .LASFDE1-__FRAME_BEGIN__
1448         .4byte  .LFB1
1449         .4byte  .LFE1-.LFB1
1450         .byte   0x4
1451         .4byte  .LFE1-.LFB1
1452         .byte   0x4
1453         .4byte  .L1-.LFB1
1454 .LEFDE1:
1455 EOF
1456                 cat > conftest.lit <<EOF
1457  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1458  0010 01000000 12000000 18000000 00000000  ................
1459  0020 08000000 04080000 0044               .........D
1460 EOF
1461                 cat > conftest.big <<EOF
1462  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1463  0010 00000001 00000012 00000018 00000000  ................
1464  0020 00000008 04000000 0844               .........D
1465 EOF
1466                 # If the assembler didn't choke, and we can objdump,
1467                 # and we got the correct data, then succeed.
1468                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1469                    && objdump -s -j .eh_frame conftest.o 2>/dev/null \
1470                       | tail -3 > conftest.got \
1471                    && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1472                         || cmp conftest.big conftest.got > /dev/null 2>&1; }
1473                 then
1474                         gcc_cv_as_eh_frame="yes"
1475                 else
1476                         gcc_cv_as_eh_frame="bad"
1477                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
1478                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1479         [Define if your assembler mis-optimizes .eh_frame data.])
1480                         fi
1481                 fi
1482         fi
1483         rm -f conftest.*
1484 fi
1485 AC_MSG_RESULT($gcc_cv_as_eh_frame)
1486
1487 AC_MSG_CHECKING(assembler section merging support)
1488 gcc_cv_as_shf_merge=no
1489 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1490   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1491     gcc_cv_as_shf_merge=yes
1492   fi
1493 elif test x$gcc_cv_as != x; then
1494         # Check if we support SHF_MERGE sections
1495         echo '.section .rodata.str, "aMS", @progbits, 1' > conftest.s
1496         if $gcc_cv_as --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1; then
1497                 gcc_cv_as_shf_merge=yes
1498         fi
1499         rm -f conftest.s conftest.o
1500 fi
1501 if test x"$gcc_cv_as_shf_merge" = xyes; then
1502         AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1503 [Define if your assembler supports marking sections with SHF_MERGE flag.])
1504 fi
1505 AC_MSG_RESULT($gcc_cv_as_shf_merge)
1506
1507 case "$target" in
1508   sparc*-*-*)
1509     AC_CACHE_CHECK([assembler .register pseudo-op support],
1510         gcc_cv_as_register_pseudo_op, [
1511         gcc_cv_as_register_pseudo_op=unknown
1512         if test x$gcc_cv_as != x; then
1513             # Check if we have .register
1514             echo ".register %g2, #scratch" > conftest.s
1515             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1516                 gcc_cv_as_register_pseudo_op=yes
1517             else
1518                 gcc_cv_as_register_pseudo_op=no
1519             fi
1520             rm -f conftest.s conftest.o
1521         fi
1522     ])
1523     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1524         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1525                 [Define if your assembler supports .register.])
1526     fi
1527
1528     AC_CACHE_CHECK([assembler supports -relax],
1529         gcc_cv_as_relax_opt, [
1530         gcc_cv_as_relax_opt=unknown
1531         if test x$gcc_cv_as != x; then
1532             # Check if gas supports -relax
1533             echo ".text" > conftest.s
1534             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1535                 gcc_cv_as_relax_opt=yes
1536             else
1537                 gcc_cv_as_relax_opt=no
1538             fi
1539             rm -f conftest.s conftest.o
1540         fi
1541     ])
1542     if test "x$gcc_cv_as_relax_opt" = xyes; then
1543         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1544                 [Define if your assembler supports -relax option.])
1545     fi
1546
1547     case "$tm_file" in
1548     *64*)
1549         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1550             gcc_cv_as_flags64, [
1551                 if test -n "$gcc_cv_as"; then
1552                     echo ".xword foo" > conftest.s
1553                     gcc_cv_as_flags64=no
1554                     for flag in "-xarch=v9" "-64 -Av9"; do
1555                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1556                             > /dev/null 2>&1; then
1557                             gcc_cv_as_flags64=$flag
1558                             break
1559                         fi
1560                     done
1561                     rm -f conftest.s conftest.o
1562                 else
1563                     if test "$gas" = yes; then
1564                         gcc_cv_as_flags64="-64 -Av9"
1565                     else
1566                         gcc_cv_as_flags64="-xarch=v9"
1567                     fi
1568                 fi
1569         ])
1570         if test "x$gcc_cv_as_flags64" = xno; then
1571 changequote(, )
1572             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1573             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1574 changequote([, ])
1575         else
1576             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1577                         [Define if the assembler supports 64bit sparc.])
1578         fi
1579         ;;
1580     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1581         ;;
1582     esac
1583
1584     if test "x$gcc_cv_as_flags64" != xno; then
1585         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1586             gcc_cv_as_offsetable_lo10, [
1587             gcc_cv_as_offsetable_lo10=unknown
1588             if test "x$gcc_cv_as" != x; then
1589                 # Check if assembler has offsetable %lo()
1590                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1591                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1592                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1593                         > /dev/null 2>&1 &&
1594                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1595                         > /dev/null 2>&1; then
1596                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1597                         gcc_cv_as_offsetable_lo10=no
1598                     else
1599                         gcc_cv_as_offsetable_lo10=yes
1600                     fi
1601                 else
1602                     gcc_cv_as_offsetable_lo10=no
1603                 fi
1604                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1605             fi
1606         ])
1607         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1608             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1609                 [Define if your assembler supports offsetable %lo().])
1610         fi
1611     fi
1612
1613     ;;
1614
1615 changequote(,)dnl
1616   i[34567]86-*-*)
1617 changequote([,])dnl
1618     AC_MSG_CHECKING(assembler instructions)
1619     gcc_cv_as_instructions=
1620     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1621       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1622         gcc_cv_as_instructions="filds fists"
1623       fi
1624     elif test x$gcc_cv_as != x; then
1625         set "filds fists" "filds mem; fists mem"
1626         while test $# -gt 0
1627         do
1628                 echo "$2" > conftest.s
1629                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1630                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1631                 fi
1632                 shift 2
1633         done
1634         rm -f conftest.s conftest.o
1635     fi
1636     if test x"$gcc_cv_as_instructions" != x; then
1637         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1638     fi
1639     AC_MSG_RESULT($gcc_cv_as_instructions)
1640     ;;
1641 esac
1642
1643 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1644 gcc_cv_as_dwarf2_debug_line=no
1645 # ??? Not all targets support dwarf2 debug_line, even within a version
1646 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1647 # info to the output file.  So, as supported targets are added to gas 2.11,
1648 # add some instruction here to (also) show we expect this might work.
1649 # ??? Once 2.11 is released, probably need to add first known working
1650 # version to the per-target configury.
1651 case "$target" in
1652   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-*)
1653     insn="nop"
1654     ;;
1655   ia64*-*-*)
1656     insn="nop 0"
1657     ;;
1658   esac
1659 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1660 then
1661   if test "$gcc_cv_gas_major_version" -eq 2 \
1662         -a "$gcc_cv_gas_minor_version" -ge 11 \
1663         -o "$gcc_cv_gas_major_version" -gt 2 \
1664      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1665      && test x"$insn" != x ; then
1666     gcc_cv_as_dwarf2_debug_line="yes"
1667   fi
1668 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1669         echo '  .file 1 "conftest.s"' > conftest.s
1670         echo '  .loc 1 3 0' >> conftest.s
1671         echo "  $insn" >> conftest.s
1672         # ??? This fails with non-gnu grep.
1673         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1674            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1675                 # The .debug_line file table must be in the exact order that
1676                 # we specified the files, since these indicies are also used
1677                 # by DW_AT_decl_file.  Approximate this test by testing if
1678                 # the assembler bitches if the same index is assigned twice.
1679                 echo '  .file 1 "foo.s"' > conftest.s
1680                 echo '  .file 1 "bar.s"' >> conftest.s
1681                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1682                 then
1683                   gcc_cv_as_dwarf2_debug_line="no"
1684                 else
1685                   gcc_cv_as_dwarf2_debug_line="yes"
1686                 fi
1687         fi
1688         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1689 fi
1690 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1691         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1692 [Define if your assembler supports dwarf2 .file/.loc directives,
1693    and preserves file table indicies exactly as given.])
1694 fi
1695 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1696
1697 # Figure out what language subdirectories are present.
1698 # Look if the user specified --enable-languages="..."; if not, use
1699 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1700 # go away some day.
1701 if test x"${enable_languages+set}" != xset; then
1702         if test x"${LANGUAGES+set}" = xset; then
1703                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1704         else
1705                 enable_languages=all
1706         fi
1707 else
1708         if test x"${enable_languages}" = x; then
1709                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1710         fi
1711 fi
1712
1713 # First scan to see if an enabled language requires some other language.
1714 # We assume that a given config-lang.in will list all the language
1715 # front ends it requires, even if some are required indirectly.
1716 for lang in ${srcdir}/*/config-lang.in ..
1717 do
1718    case $lang in
1719     ..)
1720        ;;
1721     # The odd quoting in the next line works around
1722     # an apparent bug in bash 1.12 on linux.
1723 changequote(,)dnl
1724     ${srcdir}/[*]/config-lang.in)
1725        ;;
1726     *)
1727        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
1728        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
1729        for other in $this_lang_requires
1730        do
1731           case ,${enable_languages}, in
1732            *,$other,*)
1733               ;;
1734            *,all,*)
1735               ;;
1736            *,$lang_alias,*)
1737               enable_languages="$enable_languages,$other"
1738               ;;
1739           esac
1740        done
1741        ;;
1742 changequote([,])dnl
1743    esac
1744 done
1745
1746 subdirs=
1747 for lang in ${srcdir}/*/config-lang.in ..
1748 do
1749         case $lang in
1750         ..) ;;
1751         # The odd quoting in the next line works around
1752         # an apparent bug in bash 1.12 on linux.
1753 changequote(,)dnl
1754         ${srcdir}/[*]/config-lang.in) ;;
1755         *)
1756           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1757           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1758           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1759           if test "x$lang_alias" = x
1760           then
1761                 echo "$lang doesn't set \$language." 1>&2
1762                 exit 1
1763           fi
1764           case ${build_by_default},${enable_languages}, in
1765           *,$lang_alias,*) add_this_lang=yes ;;
1766           no,*) add_this_lang=no ;;
1767           *,all,*) add_this_lang=yes ;;
1768           *) add_this_lang=no ;;
1769           esac
1770           if test x"${add_this_lang}" = xyes; then
1771                 case $lang in
1772                     ${srcdir}/ada/config-lang.in)
1773                         if test x$have_gnat = xyes ; then
1774                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1775                         fi
1776                         ;;
1777                     *)
1778                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1779                         ;;
1780                 esac
1781           fi
1782           ;;
1783 changequote([,])dnl
1784         esac
1785 done
1786
1787 # Make gthr-default.h if we have a thread file.
1788 gthread_flags=
1789 if test $thread_file != single; then
1790     rm -f gthr-default.h
1791     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1792     gthread_flags=-DHAVE_GTHR_DEFAULT
1793 fi
1794 AC_SUBST(gthread_flags)
1795
1796 # Find out what GC implementation we want, or may, use.
1797 AC_ARG_WITH(gc,
1798 [  --with-gc={simple,page} choose the garbage collection mechanism to use
1799                           with the compiler],
1800 [case "$withval" in
1801   simple | page)
1802     GGC=ggc-$withval
1803     ;;
1804   *)
1805     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1806     ;;
1807 esac],
1808 [GGC=ggc-page])
1809 AC_SUBST(GGC)
1810 echo "Using $GGC for garbage collection."
1811
1812 # Use the system's zlib library.
1813 zlibdir=-L../zlib
1814 zlibinc="-I\$(srcdir)/../zlib"
1815 AC_ARG_WITH(system-zlib,
1816 [  --with-system-zlib      use installed libz],
1817 zlibdir=
1818 zlibinc=
1819 )
1820 AC_SUBST(zlibdir)
1821 AC_SUBST(zlibinc)
1822
1823 dnl Very limited version of automake's enable-maintainer-mode
1824
1825 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1826   dnl maintainer-mode is disabled by default
1827   AC_ARG_ENABLE(maintainer-mode,
1828 [  --enable-maintainer-mode
1829                           enable make rules and dependencies not useful
1830                           (and sometimes confusing) to the casual installer],
1831       maintainer_mode=$enableval,
1832       maintainer_mode=no)
1833
1834 AC_MSG_RESULT($maintainer_mode)
1835
1836 if test "$maintainer_mode" = "yes"; then
1837   MAINT=''
1838 else
1839   MAINT='#'
1840 fi
1841 AC_SUBST(MAINT)dnl
1842
1843 # With Setjmp/Longjmp based exception handling.
1844 AC_ARG_ENABLE(sjlj-exceptions,
1845 [  --enable-sjlj-exceptions
1846                           arrange to use setjmp/longjmp exception handling],
1847 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1848 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1849   [Define 0/1 to force the choice for exception handling model.])])
1850
1851 # Make empty files to contain the specs and options for each language.
1852 # Then add #include lines to for a compiler that has specs and/or options.
1853
1854 lang_specs_files=
1855 lang_options_files=
1856 lang_tree_files=
1857 rm -f specs.h options.h gencheck.h
1858 touch specs.h options.h gencheck.h
1859 for subdir in . $subdirs
1860 do
1861         if test -f $srcdir/$subdir/lang-specs.h; then
1862                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1863                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1864         fi
1865         if test -f $srcdir/$subdir/lang-options.h; then
1866                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1867                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1868         fi
1869         if test -f $srcdir/$subdir/$subdir-tree.def; then
1870                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1871                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1872         fi
1873 done
1874
1875 # These (without "all_") are set in each config-lang.in.
1876 # `language' must be a single word so is spelled singularly.
1877 all_languages=
1878 all_boot_languages=
1879 all_compilers=
1880 all_stagestuff=
1881 all_diff_excludes=
1882 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1883 # List of language makefile fragments.
1884 all_lang_makefiles=
1885 all_headers=
1886 all_lib2funcs=
1887
1888 # Add the language fragments.
1889 # Languages are added via two mechanisms.  Some information must be
1890 # recorded in makefile variables, these are defined in config-lang.in.
1891 # We accumulate them and plug them into the main Makefile.
1892 # The other mechanism is a set of hooks for each of the main targets
1893 # like `clean', `install', etc.
1894
1895 language_fragments="Make-lang"
1896 language_hooks="Make-hooks"
1897
1898 for s in .. $subdirs
1899 do
1900         if test $s != ".."
1901         then
1902                 language=
1903                 boot_language=
1904                 compilers=
1905                 stagestuff=
1906                 diff_excludes=
1907                 headers=
1908                 outputs=
1909                 lib2funcs=
1910                 . ${srcdir}/$s/config-lang.in
1911                 if test "x$language" = x
1912                 then
1913                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1914                         exit 1
1915                 fi
1916                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1917                 if test -f ${srcdir}/$s/Makefile.in
1918                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1919                 fi
1920                 all_languages="$all_languages $language"
1921                 if test "x$boot_language" = xyes
1922                 then
1923                         all_boot_languages="$all_boot_languages $language"
1924                 fi
1925                 all_compilers="$all_compilers $compilers"
1926                 all_stagestuff="$all_stagestuff $stagestuff"
1927                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1928                 all_headers="$all_headers $headers"
1929                 all_outputs="$all_outputs $outputs"
1930                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1931         fi
1932 done
1933
1934 check_languages=
1935 for language in .. $all_languages
1936 do
1937         if test $language != ".."
1938         then
1939                 check_languages="$check_languages check-$language"
1940         fi
1941 done
1942
1943 # Since we can't use `::' targets, we link each language in
1944 # with a set of hooks, reached indirectly via lang.${target}.
1945
1946 rm -f Make-hooks
1947 touch Make-hooks
1948 target_list="all.build all.cross start.encap rest.encap \
1949         info dvi \
1950         install-normal install-common install-info install-man \
1951         uninstall \
1952         mostlyclean clean distclean extraclean maintainer-clean \
1953         stage1 stage2 stage3 stage4"
1954 for t in $target_list
1955 do
1956         x=
1957         for lang in .. $all_languages
1958         do
1959                 if test $lang != ".."; then
1960                         x="$x $lang.$t"
1961                 fi
1962         done
1963         echo "lang.$t: $x" >> Make-hooks
1964 done
1965
1966 # Create .gdbinit.
1967
1968 echo "dir ." > .gdbinit
1969 echo "dir ${srcdir}" >> .gdbinit
1970 if test x$gdb_needs_out_file_path = xyes
1971 then
1972         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1973 fi
1974 if test "x$subdirs" != x; then
1975         for s in $subdirs
1976         do
1977                 echo "dir ${srcdir}/$s" >> .gdbinit
1978         done
1979 fi
1980 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
1981
1982 # Define variables host_canonical and build_canonical
1983 # because some Cygnus local changes in the Makefile depend on them.
1984 build_canonical=${build}
1985 host_canonical=${host}
1986 target_subdir=
1987 if test "${host}" != "${target}" ; then
1988     target_subdir=${target_alias}/
1989 fi
1990 AC_SUBST(build_canonical)
1991 AC_SUBST(host_canonical)
1992 AC_SUBST(target_subdir)
1993
1994 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
1995 # absolute path for gcc_tooldir based on inserting the number of up-directory
1996 # movements required to get from $(exec_prefix) to $(prefix) into the basic
1997 # $(libsubdir)/@(unlibsubdir) based path.
1998 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
1999 # make and thus we'd get different behavior depending on where we built the
2000 # sources.
2001 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2002     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2003 else
2004 changequote(<<, >>)dnl
2005 # An explanation of the sed strings:
2006 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2007 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2008 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2009 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
2010 #
2011 # (*) Note this pattern overwrites the first character of the string
2012 # with a forward slash if one is not already present.  This is not a
2013 # problem because the exact names of the sub-directories concerned is
2014 # unimportant, just the number of them matters.
2015 #
2016 # The practical upshot of these patterns is like this:
2017 #
2018 #  prefix     exec_prefix        result
2019 #  ------     -----------        ------
2020 #   /foo        /foo/bar          ../
2021 #   /foo/       /foo/bar          ../
2022 #   /foo        /foo/bar/         ../
2023 #   /foo/       /foo/bar/         ../
2024 #   /foo        /foo/bar/ugg      ../../
2025 #
2026     dollar='$$'
2027     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2028 changequote([, ])dnl
2029 fi
2030 AC_SUBST(gcc_tooldir)
2031 AC_SUBST(dollar)
2032
2033 # Find a directory in which to install a shared libgcc.
2034
2035 AC_ARG_ENABLE(version-specific-runtime-libs,
2036 [  --enable-version-specific-runtime-libs
2037                           specify that runtime libraries should be
2038                           installed in a compiler-specific directory])
2039
2040 AC_ARG_WITH(slibdir,
2041 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2042 slibdir="$with_slibdir",
2043 if test "${enable_version_specific_runtime_libs+set}" = set; then
2044   slibdir='$(libsubdir)'
2045 elif test "$host" != "$target"; then
2046   slibdir='$(build_tooldir)/lib'
2047 else
2048   slibdir='$(libdir)'
2049 fi)
2050 AC_SUBST(slibdir)
2051
2052 # Nothing to do for FLOAT_H, float_format already handled.
2053 objdir=`pwd`
2054 AC_SUBST(objdir)
2055
2056 # Process the language and host/target makefile fragments.
2057 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
2058
2059 # Substitute configuration variables
2060 AC_SUBST(subdirs)
2061 AC_SUBST(all_boot_languages)
2062 AC_SUBST(all_compilers)
2063 AC_SUBST(all_diff_excludes)
2064 AC_SUBST(all_headers)
2065 AC_SUBST(all_lang_makefiles)
2066 AC_SUBST(all_languages)
2067 AC_SUBST(all_lib2funcs)
2068 AC_SUBST(all_stagestuff)
2069 AC_SUBST(build_exeext)
2070 AC_SUBST(build_install_headers_dir)
2071 AC_SUBST(build_xm_file_list)
2072 AC_SUBST(build_xm_file)
2073 AC_SUBST(build_xm_defines)
2074 AC_SUBST(check_languages)
2075 AC_SUBST(cc_set_by_configure)
2076 AC_SUBST(quoted_cc_set_by_configure)
2077 AC_SUBST(cpp_install_dir)
2078 AC_SUBST(dep_host_xmake_file)
2079 AC_SUBST(dep_tmake_file)
2080 AC_SUBST(extra_c_flags)
2081 AC_SUBST(extra_headers_list)
2082 AC_SUBST(extra_objs)
2083 AC_SUBST(extra_parts)
2084 AC_SUBST(extra_passes)
2085 AC_SUBST(extra_programs)
2086 AC_SUBST(float_h_file)
2087 AC_SUBST(gcc_config_arguments)
2088 AC_SUBST(gcc_gxx_include_dir)
2089 AC_SUBST(libstdcxx_incdir)
2090 AC_SUBST(gcc_version)
2091 AC_SUBST(gcc_version_full)
2092 AC_SUBST(gcc_version_trigger)
2093 AC_SUBST(host_exeext)
2094 AC_SUBST(host_extra_gcc_objs)
2095 AC_SUBST(host_xm_file_list)
2096 AC_SUBST(host_xm_file)
2097 AC_SUBST(host_xm_defines)
2098 AC_SUBST(install)
2099 AC_SUBST(lang_options_files)
2100 AC_SUBST(lang_specs_files)
2101 AC_SUBST(lang_tree_files)
2102 AC_SUBST(local_prefix)
2103 AC_SUBST(md_file)
2104 AC_SUBST(objc_boehm_gc)
2105 AC_SUBST(out_file)
2106 AC_SUBST(out_object_file)
2107 AC_SUBST(stage_prefix_set_by_configure)
2108 AC_SUBST(symbolic_link)
2109 AC_SUBST(thread_file)
2110 AC_SUBST(tm_file_list)
2111 AC_SUBST(tm_file)
2112 AC_SUBST(tm_p_file_list)
2113 AC_SUBST(tm_p_file)
2114 AC_SUBST(xm_file)
2115 AC_SUBST(xm_defines)
2116 AC_SUBST(c_target_objs)
2117 AC_SUBST(cxx_target_objs)
2118 AC_SUBST(target_cpu_default)
2119
2120 AC_SUBST_FILE(target_overrides)
2121 AC_SUBST_FILE(host_overrides)
2122 AC_SUBST(cross_defines)
2123 AC_SUBST_FILE(cross_overrides)
2124 AC_SUBST_FILE(build_overrides)
2125 AC_SUBST_FILE(language_fragments)
2126 AC_SUBST_FILE(language_hooks)
2127
2128 # Echo that links are built
2129 if test x$host = x$target
2130 then
2131         str1="native "
2132 else
2133         str1="cross-"
2134         str2=" from $host"
2135 fi
2136
2137 if test x$host != x$build
2138 then
2139         str3=" on a $build system"
2140 fi
2141
2142 if test "x$str2" != x || test "x$str3" != x
2143 then
2144         str4=
2145 fi
2146
2147 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2148
2149 if test "x$str2" != x || test "x$str3" != x
2150 then
2151         echo " ${str2}${str3}." 1>&2
2152 fi
2153
2154 # Truncate the target if necessary
2155 if test x$host_truncate_target != x; then
2156         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2157 fi
2158
2159 # Configure the subdirectories
2160 # AC_CONFIG_SUBDIRS($subdirs)
2161
2162 # Create the Makefile
2163 # and configure language subdirectories
2164 AC_OUTPUT($all_outputs,
2165 [
2166 case x$CONFIG_HEADERS in
2167 xauto-host.h:config.in)
2168 echo > cstamp-h ;;
2169 esac
2170 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2171 # bootstrapping and the installation procedure can still use
2172 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2173 # FLAGS_TO_PASS has been modified to solve the problem there.
2174 # This is virtually a duplicate of what happens in configure.lang; we do
2175 # an extra check to make sure this only happens if ln -s can be used.
2176 if test "$symbolic_link" = "ln -s"; then
2177  for d in .. ${subdirs} ; do
2178    if test $d != ..; then
2179         STARTDIR=`pwd`
2180         cd $d
2181         for t in stage1 stage2 stage3 stage4 include
2182         do
2183                 rm -f $t
2184                 $symbolic_link ../$t $t 2>/dev/null
2185         done
2186         cd $STARTDIR
2187    fi
2188  done
2189 else true ; fi
2190 # Avoid having to add intl to our include paths.
2191 if test -f intl/libintl.h; then
2192   echo creating libintl.h
2193   echo '#include "intl/libintl.h"' >libintl.h
2194 fi
2195 ],
2196 [
2197 host='${host}'
2198 build='${build}'
2199 target='${target}'
2200 target_alias='${target_alias}'
2201 srcdir='${srcdir}'
2202 subdirs='${subdirs}'
2203 symbolic_link='${symbolic_link}'
2204 program_transform_set='${program_transform_set}'
2205 program_transform_name='${program_transform_name}'
2206 dep_host_xmake_file='${dep_host_xmake_file}'
2207 host_xmake_file='${host_xmake_file}'
2208 dep_tmake_file='${dep_tmake_file}'
2209 tmake_file='${tmake_file}'
2210 thread_file='${thread_file}'
2211 gcc_config_arguments='${gcc_config_arguments}'
2212 gcc_version='${gcc_version}'
2213 gcc_version_full='${gcc_version_full}'
2214 gcc_version_trigger='${gcc_version_trigger}'
2215 local_prefix='${local_prefix}'
2216 build_install_headers_dir='${build_install_headers_dir}'
2217 build_exeext='${build_exeext}'
2218 host_exeext='${host_exeext}'
2219 out_file='${out_file}'
2220 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2221 SET_MAKE='${SET_MAKE}'
2222 target_list='${target_list}'
2223 target_overrides='${target_overrides}'
2224 host_overrides='${host_overrides}'
2225 cross_defines='${cross_defines}'
2226 cross_overrides='${cross_overrides}'
2227 build_overrides='${build_overrides}'
2228 cpp_install_dir='${cpp_install_dir}'
2229 ])