gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 _GCC_TOPLEV_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # ----------------------
 215 # Find default assembler
 216 # ----------------------
 217
 218 # With GNU as
 219 AC_ARG_WITH(gnu-as,
 220 [  --with-gnu-as           arrange to work with GNU as],
 221 gas_flag="$with_gnu_as",
 222 gas_flag=no)
 223
 224 AC_ARG_WITH(as,
 225 [  --with-as               arrange to use the specified as (full pathname)],
 226 DEFAULT_ASSEMBLER="$with_as")
 227 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 228   if test ! -x "$DEFAULT_ASSEMBLER"; then
 229     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 230   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 231     gas_flag=yes
 232   fi
 233   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 234         [Define to enable the use of a default assembler.])
 235 fi
 236
 237 AC_MSG_CHECKING([whether a default assembler was specified])
 238 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 239   if test x"$gas_flag" = x"no"; then
 240     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 241   else
 242     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 243   fi
 244 else
 245   AC_MSG_RESULT(no)
 246 fi
 247
 248 # ---------------
 249 # Find C compiler
 250 # ---------------
 251
 252 # If a non-executable a.out is present (e.g. created by GNU as above even if
 253 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 254 # file, even when creating an executable, so an execution test fails.
 255 # Remove possible default executable files to avoid this.
 256 #
 257 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 258 # Autoconf includes it.
 259 rm -f a.out a.exe b.out
 260
 261 # Find the native compiler
 262 AC_PROG_CC
 263 AC_PROG_CC_C_O
 264 # autoconf is lame and doesn't give us any substitution variable for this.
 265 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 266   NO_MINUS_C_MINUS_O=yes
 267 else
 268   OUTPUT_OPTION='-o $@'
 269 fi
 270 AC_SUBST(NO_MINUS_C_MINUS_O)
 271 AC_SUBST(OUTPUT_OPTION)
 272
 273 # -------------------------
 274 # Check C compiler features
 275 # -------------------------
 276
 277 AC_PROG_CPP
 278 AC_C_INLINE
 279
 280 gcc_AC_C_LONG_LONG
 281
 282 # sizeof(char) is 1 by definition.
 283 AC_COMPILE_CHECK_SIZEOF(void *)
 284 AC_COMPILE_CHECK_SIZEOF(short)
 285 AC_COMPILE_CHECK_SIZEOF(int)
 286 AC_COMPILE_CHECK_SIZEOF(long)
 287 if test $ac_cv_c_long_long = yes; then
 288   AC_COMPILE_CHECK_SIZEOF(long long)
 289 fi
 290 if test $ac_cv_c___int64 = yes; then
 291   AC_COMPILE_CHECK_SIZEOF(__int64)
 292 fi
 293
 294 # ---------------------
 295 # Warnings and checking
 296 # ---------------------
 297
 298 # Check $CC warning features (if it's GCC).
 299 # We want to use -pedantic, but we don't want warnings about
 300 # * 'long long'
 301 # * variadic macros
 302 # So, we only use -pedantic if we can disable those warnings.
 303
 304 AC_CACHE_CHECK(
 305   [whether ${CC} accepts -Wno-long-long],
 306   [ac_cv_prog_cc_w_no_long_long],
 307   [save_CFLAGS="$CFLAGS"
 308   CFLAGS="-Wno-long-long"
 309   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 310                     [ac_cv_prog_cc_w_no_long_long=yes],
 311                     [ac_cv_prog_cc_w_no_long_long=no])
 312   CFLAGS="$save_CFLAGS"
 313   ])
 314
 315 AC_CACHE_CHECK(
 316   [whether ${CC} accepts -Wno-variadic-macros],
 317   [ac_cv_prog_cc_w_no_variadic_macros],
 318   [save_CFLAGS="$CFLAGS"
 319   CFLAGS="-Wno-variadic-macros"
 320   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 321                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 322                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 323   CFLAGS="$save_CFLAGS"
 324   ])
 325
 326 strict1_warn=
 327 if test $ac_cv_prog_cc_w_no_long_long = yes \
 328    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 329   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 330 fi
 331 AC_SUBST(strict1_warn)
 332
 333 # Add -Wold-style-definition if it's accepted
 334 AC_CACHE_CHECK(
 335   [whether ${CC} accepts -Wold-style-definition],
 336   [ac_cv_prog_cc_w_old_style_definition],
 337   [save_CFLAGS="$CFLAGS"
 338   CFLAGS="-Wold-style-definition"
 339   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 340                     [ac_cv_prog_cc_w_old_style_definition=yes],
 341                     [ac_cv_prog_cc_w_old_style_definition=no])
 342   CFLAGS="$save_CFLAGS"
 343   ])
 344 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 345   strict1_warn="${strict1_warn} -Wold-style-definition"
 346 fi
 347
 348 # Enable -Werror, period.
 349 AC_ARG_ENABLE(werror_always,
 350 [  --enable-werror-always         enable -Werror always], [],
 351 [enable_werror_always=no])
 352 if test x${enable_werror_always} = xyes ; then
 353   strict1_warn="${strict1_warn} -Werror"
 354   WERROR=-Werror
 355 fi
 356
 357 # If the native compiler is GCC, we can enable warnings even in stage1.
 358 # That's useful for people building cross-compilers, or just running a
 359 # quick `make'.
 360 warn_cflags=
 361 if test "x$GCC" = "xyes"; then
 362   warn_cflags='$(GCC_WARN_CFLAGS)'
 363 fi
 364 AC_SUBST(warn_cflags)
 365
 366 # Enable -Werror in bootstrap stage2 and later.
 367 # Change the default to "no" on release branches.
 368 AC_ARG_ENABLE(werror,
 369 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 370 [enable_werror=yes])
 371 if test x$enable_werror = xyes ; then
 372   WERROR=-Werror
 373 fi
 374 AC_SUBST(WERROR)
 375
 376 # Enable expensive internal checks
 377 AC_ARG_ENABLE(checking,
 378 [  --enable-checking[=LIST]
 379                           enable expensive run-time checks.  With LIST,
 380                           enable only specific categories of checks.
 381                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 382                           default is misc,tree,gc,rtlflag],
 383 [ac_checking=
 384 ac_tree_checking=
 385 ac_rtl_checking=
 386 ac_rtlflag_checking=
 387 ac_gc_checking=
 388 ac_gc_always_collect=
 389 ac_fold_checking=
 390 case "${enableval}" in
 391 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 392         ac_rtlflag_checking=1 ;;
 393 no)     ;;
 394 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 395         set fnord $enableval; shift
 396         IFS="$ac_save_IFS"
 397         for check
 398         do
 399                 case $check in
 400                 misc)   ac_checking=1 ;;
 401                 tree)   ac_tree_checking=1 ;;
 402                 rtlflag)        ac_rtlflag_checking=1 ;;
 403                 rtl)    ac_rtl_checking=1 ;;
 404                 gc)     ac_gc_checking=1 ;;
 405                 gcac)   ac_gc_always_collect=1 ;;
 406                 fold)   ac_fold_checking=1 ;;
 407                 valgrind)       ac_checking_valgrind=1 ;;
 408                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 409                 esac
 410         done
 411         ;;
 412 esac
 413 ],
 414 # Enable some checks by default for development versions of GCC
 415 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 416 nocommon_flag=""
 417 if test x$ac_checking != x ; then
 418   AC_DEFINE(ENABLE_CHECKING, 1,
 419 [Define if you want more run-time sanity checks.  This one gets a grab
 420    bag of miscellaneous but relatively cheap checks.])
 421   nocommon_flag=-fno-common
 422 fi
 423 AC_SUBST(nocommon_flag)
 424 if test x$ac_tree_checking != x ; then
 425   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 426 [Define if you want all operations on trees (the basic data
 427    structure of the front ends) to be checked for dynamic type safety
 428    at runtime.  This is moderately expensive.  The tree browser debugging
 429    routines will also be enabled by this option.
 430    ])
 431   TREEBROWSER=tree-browser.o
 432 fi
 433 AC_SUBST(TREEBROWSER)
 434 if test x$ac_rtl_checking != x ; then
 435   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 436 [Define if you want all operations on RTL (the basic data structure
 437    of the optimizer and back end) to be checked for dynamic type safety
 438    at runtime.  This is quite expensive.])
 439 fi
 440 if test x$ac_rtlflag_checking != x ; then
 441   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 442 [Define if you want RTL flag accesses to be checked against the RTL
 443    codes that are supported for each access macro.  This is relatively
 444    cheap.])
 445 fi
 446 if test x$ac_gc_checking != x ; then
 447   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 448 [Define if you want the garbage collector to do object poisoning and
 449    other memory allocation checks.  This is quite expensive.])
 450 fi
 451 if test x$ac_gc_always_collect != x ; then
 452   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 453 [Define if you want the garbage collector to operate in maximally
 454    paranoid mode, validating the entire heap and collecting garbage at
 455    every opportunity.  This is extremely expensive.])
 456 fi
 457 if test x$ac_fold_checking != x ; then
 458   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 459 [Define if you want fold checked that it never destructs its argument.
 460    This is quite expensive.])
 461 fi
 462 valgrind_path_defines=
 463 valgrind_command=
 464
 465 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 466 dnl # an if statement.  This was the source of very frustrating bugs
 467 dnl # in converting to autoconf 2.5x!
 468 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 469
 470 if test x$ac_checking_valgrind != x ; then
 471   # It is certainly possible that there's valgrind but no valgrind.h.
 472   # GCC relies on making annotations so we must have both.
 473   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 474   AC_TRY_CPP(
 475     [#include <valgrind/memcheck.h>
 476 #ifndef VALGRIND_DISCARD
 477 #error VALGRIND_DISCARD not defined
 478 #endif],
 479   [gcc_cv_header_valgrind_memcheck_h=yes],
 480   [gcc_cv_header_valgrind_memcheck_h=no])
 481   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 482   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 483   AC_TRY_CPP(
 484     [#include <memcheck.h>
 485 #ifndef VALGRIND_DISCARD
 486 #error VALGRIND_DISCARD not defined
 487 #endif],
 488   [gcc_cv_header_memcheck_h=yes],
 489   gcc_cv_header_memcheck_h=no)
 490   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 491   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 492         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 493   if test "x$valgrind_path" = "x" \
 494     || (test $have_valgrind_h = no \
 495         && test $gcc_cv_header_memcheck_h = no \
 496         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 497         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 498   fi
 499   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 500   valgrind_command="$valgrind_path -q"
 501   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 502 [Define if you want to run subprograms and generated programs
 503    through valgrind (a memory checker).  This is extremely expensive.])
 504   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 505     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 506         [Define if valgrind's valgrind/memcheck.h header is installed.])
 507   fi
 508   if test $gcc_cv_header_memcheck_h = yes; then
 509     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 510         [Define if valgrind's memcheck.h header is installed.])
 511   fi
 512 fi
 513 AC_SUBST(valgrind_path_defines)
 514 AC_SUBST(valgrind_command)
 515
 516 AC_ARG_ENABLE(mapped-location,
 517 [  --enable-mapped-location   location_t is fileline integer cookie],,
 518 enable_mapped_location=no)
 519
 520 if test "$enable_mapped_location" = yes ; then
 521   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 522 [Define if location_t is fileline integer cookie.])
 523 fi
 524
 525 # Enable code coverage collection
 526 AC_ARG_ENABLE(coverage,
 527 [  --enable-coverage[=LEVEL]
 528                           enable compiler\'s code coverage collection.
 529                           Use to measure compiler performance and locate
 530                           unused parts of the compiler. With LEVEL, specify
 531                           optimization. Values are opt, noopt,
 532                           default is noopt],
 533 [case "${enableval}" in
 534   yes|noopt)
 535     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 536     ;;
 537   opt)
 538     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 539     ;;
 540   no)
 541     # a.k.a. --disable-coverage
 542     coverage_flags=""
 543     ;;
 544   *)
 545     AC_MSG_ERROR(unknown coverage setting $enableval)
 546     ;;
 547 esac],
 548 [coverage_flags=""])
 549 AC_SUBST(coverage_flags)
 550
 551 AC_ARG_ENABLE(gather-detailed-mem-stats,
 552 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 553 [enable_gather_detailed_mem_stats=no])
 554 if test x$enable_gather_detailed_mem_stats = xyes ; then
 555   AC_DEFINE(GATHER_STATISTICS, 1,
 556         [Define to enable detailed memory allocation stats gathering.])
 557 fi
 558
 559 # -------------------------------
 560 # Miscenalleous configure options
 561 # -------------------------------
 562
 563 # With stabs
 564 AC_ARG_WITH(stabs,
 565 [  --with-stabs            arrange to use stabs instead of host debug format],
 566 stabs="$with_stabs",
 567 stabs=no)
 568
 569 # Determine whether or not multilibs are enabled.
 570 AC_ARG_ENABLE(multilib,
 571 [  --enable-multilib       enable library support for multiple ABIs],
 572 [], [enable_multilib=yes])
 573 AC_SUBST(enable_multilib)
 574
 575 # Enable __cxa_atexit for C++.
 576 AC_ARG_ENABLE(__cxa_atexit,
 577 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 578 [], [])
 579
 580 # Enable threads
 581 # Pass with no value to take the default
 582 # Pass with a value to specify a thread package
 583 AC_ARG_ENABLE(threads,
 584 [  --enable-threads        enable thread usage for target GCC
 585   --enable-threads=LIB    use LIB thread package for target GCC],,
 586 [enable_threads=''])
 587
 588 AC_ARG_ENABLE(objc-gc,
 589 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 590                           the GNU Objective-C runtime],
 591 if test x$enable_objc_gc = xno; then
 592         objc_boehm_gc=''
 593 else
 594         objc_boehm_gc=1
 595 fi,
 596 objc_boehm_gc='')
 597
 598 AC_ARG_WITH(dwarf2,
 599 [  --with-dwarf2           force the default debug format to be DWARF 2],
 600 dwarf2="$with_dwarf2",
 601 dwarf2=no)
 602
 603 AC_ARG_ENABLE(shared,
 604 [  --disable-shared        don't provide a shared libgcc],
 605 [
 606   case $enable_shared in
 607   yes | no) ;;
 608   *)
 609     enable_shared=no
 610     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 611     for pkg in $enableval; do
 612       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 613         enable_shared=yes
 614       fi
 615     done
 616     IFS="$ac_save_ifs"
 617     ;;
 618   esac
 619 ], [enable_shared=yes])
 620 AC_SUBST(enable_shared)
 621
 622 AC_ARG_WITH(sysroot,
 623 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 624 [
 625  case ${with_sysroot} in
 626  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 627  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 628  esac
 629
 630  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 631  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 632
 633  if test "x$exec_prefix" = xNONE; then
 634   if test "x$prefix" = xNONE; then
 635    test_prefix=/usr/local
 636   else
 637    test_prefix=$prefix
 638   fi
 639  else
 640   test_prefix=$exec_prefix
 641  fi
 642  case ${TARGET_SYSTEM_ROOT} in
 643  "${test_prefix}"|"${test_prefix}/"*|\
 644  '${exec_prefix}'|'${exec_prefix}/'*)
 645    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 646    TARGET_SYSTEM_ROOT_DEFINE="$t"
 647    ;;
 648  esac
 649 ], [
 650  TARGET_SYSTEM_ROOT=
 651  TARGET_SYSTEM_ROOT_DEFINE=
 652  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 653 ])
 654 AC_SUBST(TARGET_SYSTEM_ROOT)
 655 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 656 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 657
 658 # Build with intermodule optimisations
 659 AC_ARG_ENABLE(intermodule,
 660 [  --enable-intermodule    build the compiler in one step],
 661 [case ${enable_intermodule} in
 662   yes) onestep="-onestep";;
 663   *) onestep="";;
 664 esac],
 665 [onestep=""])
 666 AC_SUBST(onestep)
 667
 668 # Sanity check enable_languages in case someone does not run the toplevel
 669 # configure # script.
 670 AC_ARG_ENABLE(languages,
 671 [  --enable-languages=LIST specify which front-ends to build],
 672 [case ,${enable_languages}, in
 673        ,,|,yes,)
 674                 # go safe -- we cannot be much sure without the toplevel
 675                 # configure's
 676                 # analysis of which target libs are present and usable
 677                 enable_languages=c
 678                 ;;
 679          *,all,*)
 680                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 681                 ;;
 682         *,c,*)
 683                 ;;
 684         *)
 685                 enable_languages=c,${enable_languages}
 686                 ;;
 687 esac],
 688 [enable_languages=c])
 689
 690 subdirs=
 691 for lang in ${srcdir}/*/config-lang.in
 692 do
 693         case $lang in
 694         # The odd quoting in the next line works around
 695         # an apparent bug in bash 1.12 on linux.
 696 changequote(,)dnl
 697         ${srcdir}/[*]/config-lang.in) ;;
 698         *)
 699           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 700           if test "x$lang_alias" = x
 701           then
 702                 echo "$lang doesn't set \$language." 1>&2
 703                 exit 1
 704           fi
 705           case ",$enable_languages," in
 706           *,$lang_alias,*)
 707             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 708           esac
 709           ;;
 710 changequote([,])dnl
 711         esac
 712 done
 713
 714
 715 # -------------------------
 716 # Checks for other programs
 717 # -------------------------
 718
 719 AC_PROG_MAKE_SET
 720
 721 # Find some useful tools
 722 AC_PROG_AWK
 723 # We need awk to run opts.sh (to create options.c and options.h).
 724 # Bail out if it's missing.
 725 case ${AWK} in
 726   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 727 esac
 728
 729 gcc_AC_PROG_LN_S
 730 ACX_PROG_LN($LN_S)
 731 AC_PROG_RANLIB
 732 gcc_AC_PROG_INSTALL
 733
 734 # See if cmp has --ignore-initial.
 735 gcc_AC_PROG_CMP_IGNORE_INITIAL
 736
 737 # See if we have the mktemp command.
 738 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 739
 740 # Do we have a single-tree copy of texinfo?
 741 if test -f $srcdir/../texinfo/Makefile.in; then
 742   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 743   gcc_cv_prog_makeinfo_modern=yes
 744   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 745 else
 746   # See if makeinfo has been installed and is modern enough
 747   # that we can use it.
 748   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 749   [GNU texinfo.* \([0-9][0-9.]*\)],
 750   [4.[2-9]*])
 751 fi
 752
 753 if test $gcc_cv_prog_makeinfo_modern = no; then
 754   AC_MSG_WARN([
 755 *** Makeinfo is missing or too old.
 756 *** Info documentation will not be built.])
 757   BUILD_INFO=
 758 else
 759   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 760 fi
 761
 762 # Is pod2man recent enough to regenerate manpages?
 763 AC_MSG_CHECKING([for recent Pod::Man])
 764 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 765   AC_MSG_RESULT(yes)
 766   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 767 else
 768   AC_MSG_RESULT(no)
 769   GENERATED_MANPAGES=
 770 fi
 771
 772 # How about lex?
 773 dnl Don't use AC_PROG_LEX; we insist on flex.
 774 dnl LEXLIB is not useful in gcc.
 775 if test x${build} = x${host} && test -f $srcdir/../flex/skel.c; then
 776   FLEX='$(objdir)/../flex/flex'
 777 else
 778   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 779 fi
 780
 781 # Bison?
 782 # The -L switch is so bison can find its skeleton file.
 783 if test x${build} = x${host} && test -f $srcdir/../bison/bison.simple; then
 784   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 785 else
 786   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 787 fi
 788
 789 # --------------------
 790 # Checks for C headers
 791 # --------------------
 792
 793 AC_MSG_CHECKING(for GNU C library)
 794 AC_CACHE_VAL(gcc_cv_glibc,
 795 [AC_TRY_COMPILE(
 796   [#include <features.h>],[
 797 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 798 #error Not a GNU C library system
 799 #endif],
 800   [gcc_cv_glibc=yes],
 801   gcc_cv_glibc=no)])
 802 AC_MSG_RESULT($gcc_cv_glibc)
 803 if test $gcc_cv_glibc = yes; then
 804   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 805 fi
 806
 807 # Need to reject headers which give warnings, so that the -Werror bootstrap
 808 # works later. *sigh*  This needs to come before all header checks.
 809 AC_PROG_CPP_WERROR
 810
 811 AC_HEADER_STDC
 812 AC_HEADER_TIME
 813 ACX_HEADER_STRING
 814 AC_HEADER_SYS_WAIT
 815 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 816                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 817                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 818                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 819
 820 # Check for thread headers.
 821 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 822 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 823
 824 # These tests can't be done till we know if we have limits.h.
 825 gcc_AC_C_CHAR_BIT
 826 AC_C_BIGENDIAN_CROSS
 827
 828 # --------
 829 # UNSORTED
 830 # --------
 831
 832 # Stage specific cflags for build.
 833 stage1_cflags=
 834 case $build in
 835 vax-*-*)
 836   if test x$GCC = xyes
 837   then
 838     stage1_cflags="-Wa,-J"
 839   else
 840     stage1_cflags="-J"
 841   fi
 842   ;;
 843 powerpc-*-darwin*)
 844   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 845   # sources; use -no-cpp-precomp to get to GNU cpp.
 846   # Apple's GCC has bugs in designated initializer handling, so disable
 847   # that too.
 848   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 849   ;;
 850 esac
 851 AC_SUBST(stage1_cflags)
 852
 853 # These libraries may be used by collect2.
 854 # We may need a special search path to get them linked.
 855 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 856 [save_LIBS="$LIBS"
 857 for libs in '' -lld -lmld \
 858                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 859                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 860 do
 861         LIBS="$libs"
 862         AC_TRY_LINK_FUNC(ldopen,
 863                 [gcc_cv_collect2_libs="$libs"; break])
 864 done
 865 LIBS="$save_LIBS"
 866 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 867 case $gcc_cv_collect2_libs in
 868         "none required")        ;;
 869         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 870 esac
 871 AC_SUBST(COLLECT2_LIBS)
 872
 873 # When building Ada code on Alpha, we need exc_resume which is usually in
 874 # -lexc.  So test for it.
 875 save_LIBS="$LIBS"
 876 LIBS=
 877 AC_SEARCH_LIBS(exc_resume, exc)
 878 GNAT_LIBEXC="$LIBS"
 879 LIBS="$save_LIBS"
 880 AC_SUBST(GNAT_LIBEXC)
 881
 882 # Some systems put ldexp and frexp in libm instead of libc; assume
 883 # they're both in the same place.  jcf-dump needs them.
 884 save_LIBS="$LIBS"
 885 LIBS=
 886 AC_SEARCH_LIBS(ldexp, m)
 887 LDEXP_LIB="$LIBS"
 888 LIBS="$save_LIBS"
 889 AC_SUBST(LDEXP_LIB)
 890
 891 # Use <inttypes.h> only if it exists,
 892 # doesn't clash with <sys/types.h>, and declares intmax_t.
 893 AC_MSG_CHECKING(for inttypes.h)
 894 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 895 [AC_TRY_COMPILE(
 896   [#include <sys/types.h>
 897 #include <inttypes.h>],
 898   [intmax_t i = -1;],
 899   [gcc_cv_header_inttypes_h=yes],
 900   gcc_cv_header_inttypes_h=no)])
 901 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 902 if test $gcc_cv_header_inttypes_h = yes; then
 903   AC_DEFINE(HAVE_INTTYPES_H, 1,
 904         [Define if you have a working <inttypes.h> header file.])
 905 fi
 906
 907 dnl Disabled until we have a complete test for buggy enum bitfields.
 908 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 909
 910 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 911         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 912         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 913         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 914         setlocale)
 915
 916 if test x$ac_cv_func_mbstowcs = xyes; then
 917   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 918 [    AC_TRY_RUN([#include <stdlib.h>
 919 int main()
 920 {
 921   mbstowcs(0, "", 0);
 922   return 0;
 923 }],
 924     gcc_cv_func_mbstowcs_works=yes,
 925     gcc_cv_func_mbstowcs_works=no,
 926     gcc_cv_func_mbstowcs_works=yes)])
 927   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 928     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 929   [Define this macro if mbstowcs does not crash when its
 930    first argument is NULL.])
 931   fi
 932 fi
 933
 934 AC_CHECK_TYPE(ssize_t, int)
 935
 936 # Try to determine the array type of the second argument of getgroups
 937 # for the target system (int or gid_t).
 938 AC_TYPE_GETGROUPS
 939 if test "${target}" = "${build}"; then
 940   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 941 else
 942   case "${target}" in
 943         # This condition may need some tweaking.  It should include all
 944         # targets where the array type of the second argument of getgroups
 945         # is int and the type of gid_t is not equivalent to int.
 946         *-*-sunos* | *-*-ultrix*)
 947                 TARGET_GETGROUPS_T=int
 948                 ;;
 949         *)
 950                 TARGET_GETGROUPS_T=gid_t
 951                 ;;
 952   esac
 953 fi
 954 AC_SUBST(TARGET_GETGROUPS_T)
 955
 956 gcc_AC_FUNC_PRINTF_PTR
 957 gcc_AC_FUNC_MMAP_BLACKLIST
 958
 959 case "${host}" in
 960 *-*-*vms*)
 961   # Under VMS, vfork works very differently than on Unix. The standard test
 962   # won't work, and it isn't easily adaptable. It makes more sense to
 963   # just force it.
 964   ac_cv_func_vfork_works=yes
 965   ;;
 966 esac
 967 AC_FUNC_VFORK
 968
 969 AM_ICONV
 970 # Until we have in-tree GNU iconv:
 971 LIBICONV_DEP=
 972 AC_SUBST(LIBICONV_DEP)
 973
 974 AM_LC_MESSAGES
 975
 976 # We will need to find libiberty.h and ansidecl.h
 977 saved_CFLAGS="$CFLAGS"
 978 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 979 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 980         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 981         fprintf_unlocked strstr errno snprintf vasprintf \
 982         malloc realloc calloc free basename getopt clock, , ,[
 983 #include "ansidecl.h"
 984 #include "system.h"])
 985
 986 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 987 #include "ansidecl.h"
 988 #include "system.h"
 989 #ifdef HAVE_SYS_RESOURCE_H
 990 #include <sys/resource.h>
 991 #endif
 992 ])
 993
 994 AC_TRY_COMPILE([
 995 #include "ansidecl.h"
 996 #include "system.h"
 997 #ifdef HAVE_SYS_RESOURCE_H
 998 #include <sys/resource.h>
 999 #endif
1000 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1001 [Define to \`long' if <sys/resource.h> doesn't define.])])
1002
1003 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1004 #include "ansidecl.h"
1005 #include "system.h"
1006 #ifdef HAVE_LDFCN_H
1007 #include <ldfcn.h>
1008 #endif
1009 ])
1010
1011 gcc_AC_CHECK_DECLS(times, , ,[
1012 #include "ansidecl.h"
1013 #include "system.h"
1014 #ifdef HAVE_SYS_TIMES_H
1015 #include <sys/times.h>
1016 #endif
1017 ])
1018
1019 # More time-related stuff.
1020 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1021 AC_TRY_COMPILE([
1022 #include "ansidecl.h"
1023 #include "system.h"
1024 #ifdef HAVE_SYS_TIMES_H
1025 #include <sys/times.h>
1026 #endif
1027 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1028 if test $ac_cv_struct_tms = yes; then
1029   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1030   [Define if <sys/times.h> defines struct tms.])
1031 fi
1032
1033 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1034 # revisit after autoconf 2.50.
1035 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1036 AC_TRY_COMPILE([
1037 #include "ansidecl.h"
1038 #include "system.h"
1039 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1040 if test $gcc_cv_type_clock_t = yes; then
1041   AC_DEFINE(HAVE_CLOCK_T, 1,
1042   [Define if <time.h> defines clock_t.])
1043 fi
1044
1045 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1046 CFLAGS="$saved_CFLAGS"
1047
1048 gcc_AC_INITFINI_ARRAY
1049
1050 # mkdir takes a single argument on some systems.
1051 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1052
1053 # File extensions
1054 manext='.1'
1055 objext='.o'
1056 AC_SUBST(manext)
1057 AC_SUBST(objext)
1058
1059 # With Setjmp/Longjmp based exception handling.
1060 AC_ARG_ENABLE(sjlj-exceptions,
1061 [  --enable-sjlj-exceptions
1062                           arrange to use setjmp/longjmp exception handling],
1063 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1064 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1065   [Define 0/1 to force the choice for exception handling model.])])
1066
1067 if test x$host = x$target; then
1068    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
1069 else
1070    use_libunwind_default=no
1071 fi
1072 # Use libunwind based exception handling.
1073 AC_ARG_ENABLE(libunwind-exceptions,
1074 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
1075 use_libunwind_exceptions=$enableval,
1076 use_libunwind_exceptions=$use_libunwind_default)
1077 if test x"$use_libunwind_exceptions" = xyes; then
1078    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
1079         [Define if gcc should use -lunwind.])
1080 fi
1081
1082 # --------------------------------------------------------
1083 # Build, host, and target specific configuration fragments
1084 # --------------------------------------------------------
1085
1086 # Collect build-machine-specific information.
1087 . ${srcdir}/config.build
1088
1089 # Collect host-machine-specific information.
1090 . ${srcdir}/config.host
1091
1092 target_gtfiles=
1093
1094 # Collect target-machine-specific information.
1095 . ${srcdir}/config.gcc
1096
1097 extra_objs="${host_extra_objs} ${extra_objs}"
1098 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1099
1100 # Default the target-machine variables that were not explicitly set.
1101 if test x"$tm_file" = x
1102 then tm_file=$cpu_type/$cpu_type.h; fi
1103
1104 if test x"$extra_headers" = x
1105 then extra_headers=; fi
1106
1107 if test x$md_file = x
1108 then md_file=$cpu_type/$cpu_type.md; fi
1109
1110 if test x$out_file = x
1111 then out_file=$cpu_type/$cpu_type.c; fi
1112
1113 if test x"$tmake_file" = x
1114 then tmake_file=$cpu_type/t-$cpu_type
1115 fi
1116
1117 if test x"$dwarf2" = xyes
1118 then tm_file="$tm_file tm-dwarf2.h"
1119 fi
1120
1121 # Say what files are being used for the output code and MD file.
1122 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1123 echo "Using \`$srcdir/config/$md_file' as machine description file."
1124
1125 # If any of the xm_file variables contain nonexistent files, warn
1126 # about them and drop them.
1127
1128 bx=
1129 for x in $build_xm_file; do
1130   if    test -f $srcdir/config/$x
1131   then      bx="$bx $x"
1132   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1133   fi
1134 done
1135 build_xm_file="$bx"
1136
1137 hx=
1138 for x in $host_xm_file; do
1139   if    test -f $srcdir/config/$x
1140   then      hx="$hx $x"
1141   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1142   fi
1143 done
1144 host_xm_file="$hx"
1145
1146 tx=
1147 for x in $xm_file; do
1148   if    test -f $srcdir/config/$x
1149   then      tx="$tx $x"
1150   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1151   fi
1152 done
1153 xm_file="$tx"
1154
1155 count=a
1156 for f in $tm_file; do
1157         count=${count}x
1158 done
1159 if test $count = ax; then
1160         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1161 else
1162         echo "Using the following target machine macro files:"
1163         for f in $tm_file; do
1164                 echo "  $srcdir/config/$f"
1165         done
1166 fi
1167
1168 if test x$need_64bit_hwint = xyes; then
1169         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1170 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1171 fi
1172
1173 count=a
1174 for f in $host_xm_file; do
1175         count=${count}x
1176 done
1177 if test $count = a; then
1178         :
1179 elif test $count = ax; then
1180         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1181 else
1182         echo "Using the following host machine macro files:"
1183         for f in $host_xm_file; do
1184                 echo "  $srcdir/config/$f"
1185         done
1186 fi
1187 echo "Using ${out_host_hook_obj} for host machine hooks."
1188
1189 if test "$host_xm_file" != "$build_xm_file"; then
1190         count=a
1191         for f in $build_xm_file; do
1192                 count=${count}x
1193         done
1194         if test $count = a; then
1195                 :
1196         elif test $count = ax; then
1197                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1198         else
1199                 echo "Using the following build machine macro files:"
1200                 for f in $build_xm_file; do
1201                         echo "  $srcdir/config/$f"
1202                 done
1203         fi
1204 fi
1205
1206 # ---------
1207 # Threading
1208 # ---------
1209
1210 # Check if a valid thread package
1211 case ${enable_threads} in
1212   "" | no)
1213     # No threads
1214     target_thread_file='single'
1215     ;;
1216   yes)
1217     # default
1218     target_thread_file='single'
1219     ;;
1220   aix | dce | gnat | irix | posix | rtems | \
1221   single | solaris | vxworks | win32 )
1222     target_thread_file=${enable_threads}
1223     ;;
1224   *)
1225     echo "${enable_threads} is an unknown thread package" 1>&2
1226     exit 1
1227     ;;
1228 esac
1229
1230 if test x${thread_file} = x; then
1231   # No thread file set by target-specific clauses in config.gcc,
1232   # so use file chosen by default logic above
1233   thread_file=${target_thread_file}
1234 fi
1235
1236 # Make gthr-default.h if we have a thread file.
1237 gthread_flags=
1238 if test $thread_file != single; then
1239   rm -f gthr-default.h
1240   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1241   gthread_flags=-DHAVE_GTHR_DEFAULT
1242 fi
1243 AC_SUBST(gthread_flags)
1244
1245 # --------
1246 # UNSORTED
1247 # --------
1248
1249 if test x$enable___cxa_atexit = xyes || \
1250    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1251    AC_CHECK_FUNC(__cxa_atexit,
1252         [AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1253         [Define if you want to use __cxa_atexit, rather than atexit, to
1254         register C++ destructors for local statics and global objects.
1255         This is essential for fully standards-compliant handling of
1256         destructors, but requires __cxa_atexit in libc.])],
1257         echo "__cxa_atexit can't be enabled on this target")
1258 fi
1259
1260 # Look for a file containing extra machine modes.
1261 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1262   extra_modes_file='$(srcdir)'/config/${extra_modes}
1263   AC_SUBST(extra_modes_file)
1264   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1265   [Define to the name of a file containing a list of extra machine modes
1266    for this architecture.])
1267 fi
1268
1269 # auto-host.h is the file containing items generated by autoconf and is
1270 # the first file included by config.h.
1271 # If host=build, it is correct to have bconfig include auto-host.h
1272 # as well.  If host!=build, we are in error and need to do more
1273 # work to find out the build config parameters.
1274 if test x$host = x$build
1275 then
1276         build_auto=auto-host.h
1277         FORBUILD=..
1278 else
1279         # We create a subdir, then run autoconf in the subdir.
1280         # To prevent recursion we set host and build for the new
1281         # invocation of configure to the build for this invocation
1282         # of configure.
1283         tempdir=build.$$
1284         rm -rf $tempdir
1285         mkdir $tempdir
1286         cd $tempdir
1287         case ${srcdir} in
1288         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1289         *) realsrcdir=../${srcdir};;
1290         esac
1291         saved_CFLAGS="${CFLAGS}"
1292         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1293         ${realsrcdir}/configure \
1294                 --enable-languages=${enable_languages-all} \
1295                 --target=$target_alias --host=$build_alias --build=$build_alias
1296         CFLAGS="${saved_CFLAGS}"
1297
1298         # We just finished tests for the build machine, so rename
1299         # the file auto-build.h in the gcc directory.
1300         mv auto-host.h ../auto-build.h
1301         cd ..
1302         rm -rf $tempdir
1303         build_auto=auto-build.h
1304         FORBUILD=../${build_subdir}
1305 fi
1306 AC_SUBST(FORBUILD)
1307
1308 tm_file="${tm_file} defaults.h"
1309 tm_p_file="${tm_p_file} tm-preds.h"
1310 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1311 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1312 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1313 # put this back in temporarily.
1314 xm_file="ansidecl.h ${xm_file}"
1315
1316 # --------
1317 # UNSORTED
1318 # --------
1319
1320 # Get the version trigger filename from the toplevel
1321 if test "${with_gcc_version_trigger+set}" = set; then
1322         gcc_version_trigger=$with_gcc_version_trigger
1323 else
1324         gcc_version_trigger=${srcdir}/version.c
1325 fi
1326 changequote(,)dnl
1327 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1328 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1329
1330 # Compile in configure arguments.
1331 if test -f configargs.h ; then
1332         # Being re-configured.
1333         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1334         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1335 else
1336         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1337 fi
1338
1339 # Double all backslashes and backslash all quotes to turn
1340 # gcc_config_arguments into a C string.
1341 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1342 $gcc_config_arguments
1343 EOF
1344 gcc_config_arguments_str=`cat conftest.out`
1345 rm -f conftest.out
1346
1347 cat > configargs.h <<EOF
1348 /* Generated automatically. */
1349 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1350 static const char thread_model[] = "$thread_file";
1351
1352 static const struct {
1353   const char *name, *value;
1354 } configure_default_options[] = $configure_default_options;
1355 EOF
1356 changequote([,])dnl
1357
1358 # Internationalization
1359 PACKAGE=gcc
1360 VERSION="$gcc_version"
1361 AC_SUBST(PACKAGE)
1362 AC_SUBST(VERSION)
1363
1364 ZW_GNU_GETTEXT_SISTER_DIR
1365
1366 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1367 # -liconv on the link line twice.
1368 case "$LIBINTL" in *$LIBICONV*)
1369         LIBICONV= ;;
1370 esac
1371
1372 # Windows32 Registry support for specifying GCC installation paths.
1373 AC_ARG_ENABLE(win32-registry,
1374 [  --disable-win32-registry
1375                           disable lookup of installation paths in the
1376                           Registry on Windows hosts
1377   --enable-win32-registry enable registry lookup (default)
1378   --enable-win32-registry=KEY
1379                           use KEY instead of GCC version as the last portion
1380                           of the registry key],,)
1381 case $host_os in
1382         win32 | pe | cygwin* | mingw32* | uwin*)
1383 AC_MSG_CHECKING(whether windows registry support is requested)
1384 if test "x$enable_win32_registry" != xno; then
1385   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1386 [Define to 1 if installation paths should be looked up in Windows32
1387    Registry. Ignored on non windows32 hosts.])
1388   AC_MSG_RESULT(yes)
1389   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1390 else
1391   AC_MSG_RESULT(no)
1392 fi
1393
1394 # Check if user specified a different registry key.
1395 case "x${enable_win32_registry}" in
1396 x | xyes)
1397   # default.
1398   gcc_cv_win32_registry_key="$VERSION"
1399   ;;
1400 xno)
1401   # no registry lookup.
1402   gcc_cv_win32_registry_key=''
1403   ;;
1404 *)
1405   # user-specified key.
1406   gcc_cv_win32_registry_key="$enable_win32_registry"
1407   ;;
1408 esac
1409
1410 if test "x$enable_win32_registry" != xno; then
1411   AC_MSG_CHECKING(registry key on windows hosts)
1412   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1413         [Define to be the last portion of registry key on windows hosts.])
1414   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1415 fi
1416 ;;
1417 esac
1418
1419 # Get an absolute path to the GCC top-level source directory
1420 holddir=`${PWDCMD-pwd}`
1421 cd $srcdir
1422 topdir=`${PWDCMD-pwd}`
1423 cd $holddir
1424
1425 # Conditionalize the makefile for this host machine.
1426 xmake_file=
1427 for f in ${host_xmake_file}
1428 do
1429         if test -f ${srcdir}/config/$f
1430         then
1431                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1432         fi
1433 done
1434
1435 # Conditionalize the makefile for this target machine.
1436 tmake_file_=
1437 for f in ${tmake_file}
1438 do
1439         if test -f ${srcdir}/config/$f
1440         then
1441                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1442         fi
1443 done
1444 tmake_file="${tmake_file_}"
1445
1446 symbolic_link='ln -s'
1447
1448 # If the host doesn't support symlinks, modify CC in
1449 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1450 # Otherwise, we can use "CC=$(CC)".
1451 rm -f symtest.tem
1452 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1453 then
1454         cc_set_by_configure="\$(CC)"
1455         quoted_cc_set_by_configure="\$(CC)"
1456         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1457         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1458 else
1459         rm -f symtest.tem
1460         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1461         then
1462                 symbolic_link="cp -p"
1463         else
1464                 symbolic_link="cp"
1465         fi
1466         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1467         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1468         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1469         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1470 fi
1471 rm -f symtest.tem
1472
1473 out_object_file=`basename $out_file .c`.o
1474
1475 tm_file_list=
1476 tm_include_list=
1477 for f in $tm_file; do
1478   case $f in
1479     defaults.h )
1480        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1481        tm_include_list="${tm_include_list} $f"
1482        ;;
1483     * )
1484        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1485        tm_include_list="${tm_include_list} config/$f"
1486        ;;
1487   esac
1488 done
1489
1490 tm_p_file_list=
1491 tm_p_include_list=
1492 for f in $tm_p_file; do
1493   case $f in
1494     tm-preds.h )
1495        tm_p_file_list="${tm_p_file_list} $f"
1496        tm_p_include_list="${tm_p_include_list} $f"
1497        ;;
1498     * )
1499        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1500        tm_p_include_list="${tm_p_include_list} config/$f"
1501   esac
1502 done
1503
1504 xm_file_list=
1505 xm_include_list=
1506 for f in $xm_file; do
1507   case $f in
1508     ansidecl.h )
1509        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1510        xm_include_list="${xm_include_list} $f"
1511        ;;
1512     auto-host.h )
1513        xm_file_list="${xm_file_list} $f"
1514        xm_include_list="${xm_include_list} $f"
1515        ;;
1516     * )
1517        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1518        xm_include_list="${xm_include_list} config/$f"
1519        ;;
1520   esac
1521 done
1522
1523 host_xm_file_list=
1524 host_xm_include_list=
1525 for f in $host_xm_file; do
1526   case $f in
1527     ansidecl.h )
1528        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1529        host_xm_include_list="${host_xm_include_list} $f"
1530        ;;
1531     auto-host.h )
1532        host_xm_file_list="${host_xm_file_list} $f"
1533        host_xm_include_list="${host_xm_include_list} $f"
1534        ;;
1535     * )
1536        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1537        host_xm_include_list="${host_xm_include_list} config/$f"
1538        ;;
1539   esac
1540 done
1541
1542 build_xm_file_list=
1543 for f in $build_xm_file; do
1544   case $f in
1545     ansidecl.h )
1546        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1547        build_xm_include_list="${build_xm_include_list} $f"
1548        ;;
1549     auto-build.h | auto-host.h )
1550        build_xm_file_list="${build_xm_file_list} $f"
1551        build_xm_include_list="${build_xm_include_list} $f"
1552        ;;
1553     * )
1554        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1555        build_xm_include_list="${build_xm_include_list} config/$f"
1556        ;;
1557   esac
1558 done
1559
1560 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1561 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1562 CROSS=                                          AC_SUBST(CROSS)
1563 ALL=all.internal                                AC_SUBST(ALL)
1564 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1565 if test x$host != x$target
1566 then
1567         CROSS="-DCROSS_COMPILE"
1568         ALL=all.cross
1569         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1570         case "$host","$target" in
1571         # Darwin crosses can use the host system's libraries and headers,
1572         # because of the fat library support.  Of course, it must be the
1573         # same version of Darwin on both sides.  Allow the user to
1574         # just say --target=foo-darwin without a version number to mean
1575         # "the version on this system".
1576             *-*-darwin*,*-*-darwin*)
1577                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1578                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1579                 if test $hostos = $targetos -o $targetos = darwin ; then
1580                     CROSS=
1581                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1582                     with_headers=yes
1583                 fi
1584                 ;;
1585
1586             i?86-*-*,x86_64-*-* \
1587             | powerpc*-*-*,powerpc64*-*-*)
1588                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1589         esac
1590 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1591         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1592         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1593 fi
1594
1595 # If this is a cross-compiler that does not
1596 # have its own set of headers then define
1597 # inhibit_libc
1598
1599 # If this is using newlib, without having the headers available now,
1600 # then define inhibit_libc in LIBGCC2_CFLAGS.
1601 # This prevents libgcc2 from containing any code which requires libc
1602 # support.
1603 inhibit_libc=
1604 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1605        test x$with_newlib = xyes ; } &&
1606      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1607        inhibit_libc=-Dinhibit_libc
1608 fi
1609 AC_SUBST(inhibit_libc)
1610
1611 # When building gcc with a cross-compiler, we need to adjust things so
1612 # that the generator programs are still built with the native compiler.
1613 # Also, we cannot run fixincludes or fix-header.
1614
1615 # These are the normal (build=host) settings:
1616 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1617 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1618 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1619 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1620
1621 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1622
1623 # Possibly disable fixproto, on a per-target basis.
1624 case ${use_fixproto} in
1625   no)
1626     STMP_FIXPROTO=
1627     ;;
1628   yes)
1629     STMP_FIXPROTO=stmp-fixproto
1630     ;;
1631 esac
1632 AC_SUBST(STMP_FIXPROTO)
1633
1634 # And these apply if build != host, or we are generating coverage data
1635 if test x$build != x$host || test "x$coverage_flags" != x
1636 then
1637     BUILD_PREFIX=build-
1638     BUILD_PREFIX_1=build-
1639     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1640
1641     if test "x$TARGET_SYSTEM_ROOT" = x; then
1642         STMP_FIXINC=
1643         STMP_FIXPROTO=
1644     fi
1645 fi
1646
1647 # Expand extra_headers to include complete path.
1648 # This substitutes for lots of t-* files.
1649 extra_headers_list=
1650 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1651 for file in ${extra_headers} ; do
1652   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1653 done
1654
1655 # Define collect2 in Makefile.
1656 case $host_can_use_collect2 in
1657   no) collect2= ;;
1658   *) collect2='collect2$(exeext)' ;;
1659 esac
1660 AC_SUBST([collect2])
1661
1662 # Add a definition of USE_COLLECT2 if system wants one.
1663 case $use_collect2 in
1664   no) use_collect2= ;;
1665   "") ;;
1666   *)
1667     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1668     xm_defines="${xm_defines} USE_COLLECT2"
1669     case $host_can_use_collect2 in
1670       no)
1671         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1672         ;;
1673     esac
1674     ;;
1675 esac
1676
1677 # ---------------------------
1678 # Assembler & linker features
1679 # ---------------------------
1680
1681 # Identify the assembler which will work hand-in-glove with the newly
1682 # built GCC, so that we can examine its features.  This is the assembler
1683 # which will be driven by the driver program.
1684 #
1685 # If build != host, and we aren't building gas in-tree, we identify a
1686 # build->target assembler and hope that it will have the same features
1687 # as the host->target assembler we'll be using.
1688 AC_MSG_CHECKING(what assembler to use)
1689 in_tree_gas=no
1690 gcc_cv_as=
1691 gcc_cv_gas_major_version=
1692 gcc_cv_gas_minor_version=
1693 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1694 if test -x "$DEFAULT_ASSEMBLER"; then
1695         gcc_cv_as="$DEFAULT_ASSEMBLER"
1696 elif test -x as$host_exeext; then
1697         # Build using assembler in the current directory.
1698         gcc_cv_as=./as$host_exeext
1699 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1700      && test -f ../gas/Makefile \
1701      && test x$build = x$host; then
1702   # Single tree build which includes gas.  We want to prefer it
1703   # over whatever linker top-level may have detected, since
1704   # we'll use what we're building after installation anyway.
1705   in_tree_gas=yes
1706   _gcc_COMPUTE_GAS_VERSION
1707   rm -f as$host_exeext
1708   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1709   in_tree_gas_is_elf=no
1710   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1711      || (grep 'obj_format = multi' ../gas/Makefile \
1712          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1713   then
1714     in_tree_gas_is_elf=yes
1715   fi
1716 m4_pattern_allow([AS_FOR_TARGET])dnl
1717 elif test -x "$AS_FOR_TARGET"; then
1718         gcc_cv_as="$AS_FOR_TARGET"
1719 elif test -x "$AS" && test x$host = x$target; then
1720         gcc_cv_as="$AS"
1721 fi
1722
1723 if test "x$gcc_cv_as" = x; then
1724         # Search the same directories that the installed compiler will
1725         # search.  Else we may find the wrong assembler and lose.  If we
1726         # do not find a suitable assembler binary, then try the user's
1727         # path.
1728         #
1729         # Also note we have to check MD_EXEC_PREFIX before checking the
1730         # user's path.  Unfortunately, there is no good way to get at the
1731         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1732         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1733         # to be fixed as part of the make/configure rewrite too.
1734
1735         if test "x$exec_prefix" = xNONE; then
1736                 if test "x$prefix" = xNONE; then
1737                         test_prefix=/usr/local
1738                 else
1739                         test_prefix=$prefix
1740                 fi
1741         else
1742                 test_prefix=$exec_prefix
1743         fi
1744
1745         # If the loop below does not find an assembler, then use whatever
1746         # one we can find in the users's path.
1747         # user's path.
1748         if test "x$program_prefix" != xNONE; then
1749                 gcc_cv_as=${program_prefix}as$host_exeext
1750         else
1751                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$host_exeext
1752         fi
1753
1754         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1755                    $test_prefix/libexec/gcc/$target_noncanonical \
1756                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1757                    /usr/lib/gcc/$target_noncanonical \
1758                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1759                    $test_prefix/$target_noncanonical/bin"
1760
1761         if test x$host = x$target; then
1762             test_dirs="$test_dirs \
1763                    /usr/libexec \
1764                    /usr/ccs/gcc \
1765                    /usr/ccs/bin \
1766                    /udk/usr/ccs/bin \
1767                    /bsd43/usr/lib/cmplrs/cc \
1768                    /usr/cross64/usr/bin \
1769                    /usr/lib/cmplrs/cc \
1770                    /sysv/usr/lib/cmplrs/cc \
1771                    /svr4/usr/lib/cmplrs/cc \
1772                    /usr/bin"
1773         fi
1774
1775         for dir in $test_dirs; do
1776                 if test -x $dir/as$host_exeext; then
1777                         gcc_cv_as=$dir/as$host_exeext
1778                         break;
1779                 fi
1780         done
1781 fi
1782 case $in_tree_gas in
1783   yes)
1784     AC_MSG_RESULT("newly built gas")
1785     ;;
1786   no)
1787     AC_MSG_RESULT($gcc_cv_as)
1788     ;;
1789 esac
1790
1791 # Identify the linker which will work hand-in-glove with the newly
1792 # built GCC, so that we can examine its features.  This is the linker
1793 # which will be driven by the driver program.
1794 #
1795 # If build != host, and we aren't building gas in-tree, we identify a
1796 # build->target linker and hope that it will have the same features
1797 # as the host->target linker we'll be using.
1798 AC_MSG_CHECKING(what linker to use)
1799 in_tree_ld=no
1800 gcc_cv_ld=
1801 gcc_cv_gld_major_version=
1802 gcc_cv_gld_minor_version=
1803 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1804 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1805 if test -x "$DEFAULT_LINKER"; then
1806         gcc_cv_ld="$DEFAULT_LINKER"
1807 elif test -x collect-ld$host_exeext; then
1808         # Build using linker in the current directory.
1809         gcc_cv_ld=./collect-ld$host_exeext
1810 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1811      && test -f ../ld/Makefile \
1812      && test x$build = x$host; then
1813         # Single tree build which includes ld.  We want to prefer it
1814         # over whatever linker top-level may have detected, since
1815         # we'll use what we're building after installation anyway.
1816         in_tree_ld=yes
1817         in_tree_ld_is_elf=no
1818         if (grep 'EMUL = .*elf' ../ld/Makefile \
1819             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1820           in_tree_ld_is_elf=yes
1821         fi
1822         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1823         do
1824 changequote(,)dnl
1825                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1826 changequote([,])dnl
1827                 if test x$gcc_cv_gld_version != x; then
1828                         break
1829                 fi
1830         done
1831 changequote(,)dnl
1832         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1833         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1834 changequote([,])dnl
1835         rm -f collect-ld$host_exeext
1836         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1837                 2>/dev/null
1838 elif test -x "$LD_FOR_TARGET"; then
1839         gcc_cv_ld="$LD_FOR_TARGET"
1840 elif test -x "$LD" && test x$host = x$target; then
1841         gcc_cv_ld="$LD"
1842 fi
1843
1844 if test "x$gcc_cv_ld" = x; then
1845         # Search the same directories that the installed compiler will
1846         # search.  Else we may find the wrong linker and lose.  If we
1847         # do not find a suitable linker binary, then try the user's
1848         # path.
1849         #
1850         # Also note we have to check MD_EXEC_PREFIX before checking the
1851         # user's path.  Unfortunately, there is no good way to get at the
1852         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1853         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1854         # to be fixed as part of the make/configure rewrite too.
1855
1856         if test "x$exec_prefix" = xNONE; then
1857                 if test "x$prefix" = xNONE; then
1858                         test_prefix=/usr/local
1859                 else
1860                         test_prefix=$prefix
1861                 fi
1862         else
1863                 test_prefix=$exec_prefix
1864         fi
1865
1866         # If the loop below does not find an linker, then use whatever
1867         # one we can find in the users's path.
1868         # user's path.
1869         if test "x$program_prefix" != xNONE; then
1870                 gcc_cv_ld=${program_prefix}ld$host_exeext
1871         else
1872                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$host_exeext
1873         fi
1874
1875         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1876                    $test_prefix/libexec/gcc/$target_noncanonical \
1877                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1878                    /usr/lib/gcc/$target_noncanonical \
1879                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1880                    $test_prefix/$target_noncanonical/bin"
1881
1882         if test x$host = x$target; then
1883             test_dirs="$test_dirs \
1884                    /usr/libexec \
1885                    /usr/ccs/gcc \
1886                    /usr/ccs/bin \
1887                    /udk/usr/ccs/bin \
1888                    /bsd43/usr/lib/cmplrs/cc \
1889                    /usr/cross64/usr/bin \
1890                    /usr/lib/cmplrs/cc \
1891                    /sysv/usr/lib/cmplrs/cc \
1892                    /svr4/usr/lib/cmplrs/cc \
1893                    /usr/bin"
1894         fi
1895
1896         for dir in $test_dirs; do
1897                 if test -x $dir/ld$host_exeext; then
1898                         gcc_cv_ld=$dir/ld$host_exeext
1899                         break;
1900                 fi
1901         done
1902 fi
1903 case $in_tree_ld in
1904   yes)
1905     AC_MSG_RESULT("newly built ld")
1906     ;;
1907   no)
1908     AC_MSG_RESULT($gcc_cv_ld)
1909     ;;
1910 esac
1911
1912 # Figure out what nm we will be using.
1913 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1914 AC_MSG_CHECKING(what nm to use)
1915 in_tree_nm=no
1916 if test -x nm$host_exeext; then
1917         gcc_cv_nm=./nm$host_exeext
1918 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1919      && test -f ../binutils/Makefile; then
1920         # Single tree build which includes binutils.
1921         in_tree_nm=yes
1922         gcc_cv_nm=./nm$host_exeext
1923         rm -f nm$host_exeext
1924         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1925 elif test "x$program_prefix" != xNONE; then
1926         gcc_cv_nm=${program_prefix}nm$host_exeext
1927 else
1928         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$host_exeext
1929 fi
1930 case $in_tree_nm in
1931   yes) AC_MSG_RESULT("newly built nm") ;;
1932   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1933 esac
1934
1935 # Figure out what objdump we will be using.
1936 AC_MSG_CHECKING(what objdump to use)
1937 in_tree_objdump=no
1938 if test -x objdump$host_exeext; then
1939         gcc_cv_objdump=./objdump$host_exeext
1940 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1941      && test -f ../binutils/Makefile; then
1942         # Single tree build which includes binutils.
1943         in_tree_objdump=yes
1944         gcc_cv_objdump=./objdump$host_exeext
1945         rm -f objdump$host_exeext
1946         $symbolic_link ../binutils/objdump$host_exeext \
1947                 objdump$host_exeext 2>/dev/null
1948 elif test "x$program_prefix" != xNONE; then
1949         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1950 else
1951         gcc_cv_objdump=`echo objdump | \
1952                 sed "${program_transform_name}"`$host_exeext
1953 fi
1954 case $in_tree_objdump in
1955   yes) AC_MSG_RESULT("newly built objdump") ;;
1956   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1957 esac
1958
1959 # Figure out what assembler alignment features are present.
1960 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1961  [2,6,0],,
1962 [.balign 4
1963 .p2align 2],,
1964 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1965   [Define if your assembler supports .balign and .p2align.])])
1966
1967 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1968  [2,8,0],,
1969  [.p2align 4,,7],,
1970 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1971   [Define if your assembler supports specifying the maximum number
1972    of bytes to skip when using the GAS .p2align command.])])
1973
1974 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1975  [elf,2,9,0],,
1976  [conftest_label1: .word 0
1977 .subsection -1
1978 conftest_label2: .word 0
1979 .previous],
1980  [if test x$gcc_cv_nm != x; then
1981     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1982     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1983     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1984     then :
1985     else gcc_cv_as_subsection_m1=yes
1986     fi
1987     rm -f conftest.nm1 conftest.nm2
1988   fi],
1989  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1990   [Define if your assembler supports .subsection and .subsection -1 starts
1991    emitting at the beginning of your section.])])
1992
1993 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1994  [2,2,0],,
1995  [      .weak foobar],,
1996 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1997
1998 # .hidden needs to be supported in both the assembler and the linker,
1999 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2000 # This is irritatingly difficult to feature test for; we have to check the
2001 # date string after the version number.  If we've got an in-tree
2002 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2003 # to be safe.
2004 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2005 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2006  [elf,2,13,0],,
2007 [       .hidden foobar
2008 foobar:])
2009
2010 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2011 [if test $in_tree_ld = yes ; then
2012   gcc_cv_ld_hidden=no
2013   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2014      && test $in_tree_ld_is_elf = yes; then
2015      gcc_cv_ld_hidden=yes
2016   fi
2017 else
2018   gcc_cv_ld_hidden=yes
2019   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2020   if echo "$ld_ver" | grep GNU > /dev/null; then
2021 changequote(,)dnl
2022     ld_vers=`echo $ld_ver | sed -n \
2023         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2024         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2025         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2026         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2027         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2028         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2029     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2030     if test 0"$ld_date" -lt 20020404; then
2031       if test -n "$ld_date"; then
2032         # If there was date string, but was earlier than 2002-04-04, fail
2033         gcc_cv_ld_hidden=no
2034       elif test -z "$ld_vers"; then
2035         # If there was no date string nor ld version number, something is wrong
2036         gcc_cv_ld_hidden=no
2037       else
2038         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2039         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2040         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2041         test -z "$ld_vers_patch" && ld_vers_patch=0
2042         if test "$ld_vers_major" -lt 2; then
2043           gcc_cv_ld_hidden=no
2044         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2045           gcc_cv_ld_hidden="no"
2046         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2047           gcc_cv_ld_hidden=no
2048         fi
2049       fi
2050 changequote([,])dnl
2051     fi
2052   else
2053     case "${target}" in
2054       hppa64*-*-hpux* | ia64*-*-hpux*)
2055         gcc_cv_ld_hidden=yes
2056         ;;
2057       *)
2058         gcc_cv_ld_hidden=no
2059         ;;
2060     esac
2061   fi
2062 fi])
2063 libgcc_visibility=no
2064 AC_SUBST(libgcc_visibility)
2065 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2066   libgcc_visibility=yes
2067   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2068   [Define if your assembler and linker support .hidden.])
2069 fi
2070
2071 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2072 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2073   [elf,2,11,0],,
2074 [       .data
2075         .uleb128 L2 - L1
2076 L1:
2077         .uleb128 1280
2078         .sleb128 -1010
2079 L2:],
2080  [# GAS versions before 2.11 do not support uleb128,
2081   # despite appearing to.
2082   # ??? There exists an elf-specific test that will crash
2083   # the assembler.  Perhaps it's better to figure out whether
2084   # arbitrary sections are supported and try the test.
2085   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2086   if echo "$as_ver" | grep GNU > /dev/null; then
2087 changequote(,)dnl
2088     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2089     as_major=`echo $as_ver | sed 's/\..*//'`
2090     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2091 changequote([,])dnl
2092     if test $as_major -eq 2 && test $as_minor -lt 11
2093     then :
2094     else gcc_cv_as_leb128=yes
2095     fi
2096   fi],
2097   [AC_DEFINE(HAVE_AS_LEB128, 1,
2098     [Define if your assembler supports .sleb128 and .uleb128.])])
2099
2100 # GAS versions up to and including 2.11.0 may mis-optimize
2101 # .eh_frame data.
2102 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2103   [elf,2,12,0],,
2104 [       .text
2105 .LFB1:
2106         .4byte  0
2107 .L1:
2108         .4byte  0
2109 .LFE1:
2110         .section        .eh_frame,"aw",@progbits
2111 __FRAME_BEGIN__:
2112         .4byte  .LECIE1-.LSCIE1
2113 .LSCIE1:
2114         .4byte  0x0
2115         .byte   0x1
2116         .ascii "z\0"
2117         .byte   0x1
2118         .byte   0x78
2119         .byte   0x1a
2120         .byte   0x0
2121         .byte   0x4
2122         .4byte  1
2123         .p2align 1
2124 .LECIE1:
2125 .LSFDE1:
2126         .4byte  .LEFDE1-.LASFDE1
2127 .LASFDE1:
2128         .4byte  .LASFDE1-__FRAME_BEGIN__
2129         .4byte  .LFB1
2130         .4byte  .LFE1-.LFB1
2131         .byte   0x4
2132         .4byte  .LFE1-.LFB1
2133         .byte   0x4
2134         .4byte  .L1-.LFB1
2135 .LEFDE1:],
2136 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2137 cat > conftest.lit <<EOF
2138  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2139  0010 01000000 12000000 18000000 00000000  ................
2140  0020 08000000 04080000 0044               .........D      @&t@
2141 EOF
2142 cat > conftest.big <<EOF
2143  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2144  0010 00000001 00000012 00000018 00000000  ................
2145  0020 00000008 04000000 0844               .........D      @&t@
2146 EOF
2147   # If the assembler didn't choke, and we can objdump,
2148   # and we got the correct data, then succeed.
2149   if test x$gcc_cv_objdump != x \
2150   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2151      | tail -3 > conftest.got \
2152   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2153     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2154   then
2155     gcc_cv_as_eh_frame=yes
2156   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2157     gcc_cv_as_eh_frame=buggy
2158   else
2159     # Uh oh, what do we do now?
2160     gcc_cv_as_eh_frame=no
2161   fi])
2162
2163 if test $gcc_cv_as_eh_frame = buggy; then
2164   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2165   [Define if your assembler mis-optimizes .eh_frame data.])
2166 fi
2167
2168 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2169  [elf,2,12,0], [--fatal-warnings],
2170  [.section .rodata.str, "aMS", @progbits, 1])
2171 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2172   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2173 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2174
2175 # Thread-local storage - the check is heavily parametrized.
2176 conftest_s=
2177 tls_first_major=
2178 tls_first_minor=
2179 tls_as_opt=
2180 case "$target" in
2181 changequote(,)dnl
2182   alpha*-*-*)
2183     conftest_s='
2184         .section ".tdata","awT",@progbits
2185 foo:    .long   25
2186         .text
2187         ldq     $27,__tls_get_addr($29)         !literal!1
2188         lda     $16,foo($29)                    !tlsgd!1
2189         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2190         ldq     $27,__tls_get_addr($29)         !literal!2
2191         lda     $16,foo($29)                    !tlsldm!2
2192         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2193         ldq     $1,foo($29)                     !gotdtprel
2194         ldah    $2,foo($29)                     !dtprelhi
2195         lda     $3,foo($2)                      !dtprello
2196         lda     $4,foo($29)                     !dtprel
2197         ldq     $1,foo($29)                     !gottprel
2198         ldah    $2,foo($29)                     !tprelhi
2199         lda     $3,foo($2)                      !tprello
2200         lda     $4,foo($29)                     !tprel'
2201         tls_first_major=2
2202         tls_first_minor=13
2203         tls_as_opt=--fatal-warnings
2204         ;;
2205   i[34567]86-*-*)
2206     conftest_s='
2207         .section ".tdata","awT",@progbits
2208 foo:    .long   25
2209         .text
2210         movl    %gs:0, %eax
2211         leal    foo@TLSGD(,%ebx,1), %eax
2212         leal    foo@TLSLDM(%ebx), %eax
2213         leal    foo@DTPOFF(%eax), %edx
2214         movl    foo@GOTTPOFF(%ebx), %eax
2215         subl    foo@GOTTPOFF(%ebx), %eax
2216         addl    foo@GOTNTPOFF(%ebx), %eax
2217         movl    foo@INDNTPOFF, %eax
2218         movl    $foo@TPOFF, %eax
2219         subl    $foo@TPOFF, %eax
2220         leal    foo@NTPOFF(%ecx), %eax'
2221         tls_first_major=2
2222         tls_first_minor=14
2223         tls_as_opt=--fatal-warnings
2224         ;;
2225   x86_64-*-*)
2226     conftest_s='
2227         .section ".tdata","awT",@progbits
2228 foo:    .long   25
2229         .text
2230         movq    %fs:0, %rax
2231         leaq    foo@TLSGD(%rip), %rdi
2232         leaq    foo@TLSLD(%rip), %rdi
2233         leaq    foo@DTPOFF(%rax), %rdx
2234         movq    foo@GOTTPOFF(%rip), %rax
2235         movq    $foo@TPOFF, %rax'
2236         tls_first_major=2
2237         tls_first_minor=14
2238         tls_as_opt=--fatal-warnings
2239         ;;
2240   ia64-*-*)
2241     conftest_s='
2242         .section ".tdata","awT",@progbits
2243 foo:    data8   25
2244         .text
2245         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2246         addl    r17 = @ltoff(@dtprel(foo#)), gp
2247         addl    r18 = @ltoff(@tprel(foo#)), gp
2248         addl    r19 = @dtprel(foo#), gp
2249         adds    r21 = @dtprel(foo#), r13
2250         movl    r23 = @dtprel(foo#)
2251         addl    r20 = @tprel(foo#), gp
2252         adds    r22 = @tprel(foo#), r13
2253         movl    r24 = @tprel(foo#)'
2254         tls_first_major=2
2255         tls_first_minor=13
2256         tls_as_opt=--fatal-warnings
2257         ;;
2258   powerpc-*-*)
2259     conftest_s='
2260         .section ".tdata","awT",@progbits
2261         .align 2
2262 ld0:    .space 4
2263 ld1:    .space 4
2264 x1:     .space 4
2265 x2:     .space 4
2266 x3:     .space 4
2267         .text
2268         addi 3,31,ld0@got@tlsgd
2269         bl __tls_get_addr
2270         addi 3,31,x1@got@tlsld
2271         bl __tls_get_addr
2272         addi 9,3,x1@dtprel
2273         addis 9,3,x2@dtprel@ha
2274         addi 9,9,x2@dtprel@l
2275         lwz 9,x3@got@tprel(31)
2276         add 9,9,x@tls
2277         addi 9,2,x1@tprel
2278         addis 9,2,x2@tprel@ha
2279         addi 9,9,x2@tprel@l'
2280         tls_first_major=2
2281         tls_first_minor=14
2282         tls_as_opt="-a32 --fatal-warnings"
2283         ;;
2284   powerpc64-*-*)
2285     conftest_s='
2286         .section ".tdata","awT",@progbits
2287         .align 3
2288 ld0:    .space 8
2289 ld1:    .space 8
2290 x1:     .space 8
2291 x2:     .space 8
2292 x3:     .space 8
2293         .text
2294         addi 3,2,ld0@got@tlsgd
2295         bl .__tls_get_addr
2296         nop
2297         addi 3,2,ld1@toc
2298         bl .__tls_get_addr
2299         nop
2300         addi 3,2,x1@got@tlsld
2301         bl .__tls_get_addr
2302         nop
2303         addi 9,3,x1@dtprel
2304         bl .__tls_get_addr
2305         nop
2306         addis 9,3,x2@dtprel@ha
2307         addi 9,9,x2@dtprel@l
2308         bl .__tls_get_addr
2309         nop
2310         ld 9,x3@got@dtprel(2)
2311         add 9,9,3
2312         bl .__tls_get_addr
2313         nop'
2314         tls_first_major=2
2315         tls_first_minor=14
2316         tls_as_opt="-a64 --fatal-warnings"
2317         ;;
2318   s390-*-*)
2319     conftest_s='
2320         .section ".tdata","awT",@progbits
2321 foo:    .long   25
2322         .text
2323         .long   foo@TLSGD
2324         .long   foo@TLSLDM
2325         .long   foo@DTPOFF
2326         .long   foo@NTPOFF
2327         .long   foo@GOTNTPOFF
2328         .long   foo@INDNTPOFF
2329         l       %r1,foo@GOTNTPOFF(%r12)
2330         l       %r1,0(%r1):tls_load:foo
2331         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2332         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2333         tls_first_major=2
2334         tls_first_minor=14
2335         tls_as_opt="-m31 --fatal-warnings"
2336         ;;
2337   s390x-*-*)
2338     conftest_s='
2339         .section ".tdata","awT",@progbits
2340 foo:    .long   25
2341         .text
2342         .quad   foo@TLSGD
2343         .quad   foo@TLSLDM
2344         .quad   foo@DTPOFF
2345         .quad   foo@NTPOFF
2346         .quad   foo@GOTNTPOFF
2347         lg      %r1,foo@GOTNTPOFF(%r12)
2348         larl    %r1,foo@INDNTPOFF
2349         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2350         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2351         tls_first_major=2
2352         tls_first_minor=14
2353         tls_as_opt="-m64 -Aesame --fatal-warnings"
2354         ;;
2355   sh-*-* | sh[34]-*-*)
2356     conftest_s='
2357         .section ".tdata","awT",@progbits
2358 foo:    .long   25
2359         .text
2360         .long   foo@TLSGD
2361         .long   foo@TLSLDM
2362         .long   foo@DTPOFF
2363         .long   foo@GOTTPOFF
2364         .long   foo@TPOFF'
2365         tls_first_major=2
2366         tls_first_minor=13
2367         tls_as_opt=--fatal-warnings
2368         ;;
2369   sparc*-*-*)
2370     case "$target" in
2371       sparc*-sun-solaris2.*)
2372         on_solaris=yes
2373         ;;
2374       *)
2375         on_solaris=no
2376         ;;
2377     esac
2378     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2379       conftest_s='
2380         .section ".tdata",#alloc,#write,#tls
2381 foo:    .long   25
2382         .text
2383         sethi   %tgd_hi22(foo), %o0
2384         add     %o0, %tgd_lo10(foo), %o1
2385         add     %l7, %o1, %o0, %tgd_add(foo)
2386         call    __tls_get_addr, %tgd_call(foo)
2387         sethi   %tldm_hi22(foo), %l1
2388         add     %l1, %tldm_lo10(foo), %l2
2389         add     %l7, %l2, %o0, %tldm_add(foo)
2390         call    __tls_get_addr, %tldm_call(foo)
2391         sethi   %tldo_hix22(foo), %l3
2392         xor     %l3, %tldo_lox10(foo), %l4
2393         add     %o0, %l4, %l5, %tldo_add(foo)
2394         sethi   %tie_hi22(foo), %o3
2395         add     %o3, %tie_lo10(foo), %o3
2396         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2397         add     %g7, %o2, %o4, %tie_add(foo)
2398         sethi   %tle_hix22(foo), %l1
2399         xor     %l1, %tle_lox10(foo), %o5
2400         ld      [%g7 + %o5], %o1'
2401         tls_first_major=0
2402         tls_first_minor=0
2403     else
2404       conftest_s='
2405         .section ".tdata","awT",@progbits
2406 foo:    .long   25
2407         .text
2408         sethi   %tgd_hi22(foo), %o0
2409         add     %o0, %tgd_lo10(foo), %o1
2410         add     %l7, %o1, %o0, %tgd_add(foo)
2411         call    __tls_get_addr, %tgd_call(foo)
2412         sethi   %tldm_hi22(foo), %l1
2413         add     %l1, %tldm_lo10(foo), %l2
2414         add     %l7, %l2, %o0, %tldm_add(foo)
2415         call    __tls_get_addr, %tldm_call(foo)
2416         sethi   %tldo_hix22(foo), %l3
2417         xor     %l3, %tldo_lox10(foo), %l4
2418         add     %o0, %l4, %l5, %tldo_add(foo)
2419         sethi   %tie_hi22(foo), %o3
2420         add     %o3, %tie_lo10(foo), %o3
2421         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2422         add     %g7, %o2, %o4, %tie_add(foo)
2423         sethi   %tle_hix22(foo), %l1
2424         xor     %l1, %tle_lox10(foo), %o5
2425         ld      [%g7 + %o5], %o1'
2426         tls_first_major=2
2427         tls_first_minor=14
2428         tls_as_opt="-32 --fatal-warnings"
2429       fi
2430         ;;
2431 changequote([,])dnl
2432 esac
2433 if test -z "$tls_first_major"; then
2434   : # If we don't have a check, assume no support.
2435 else
2436   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2437   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2438   [AC_DEFINE(HAVE_AS_TLS, 1,
2439             [Define if your assembler supports thread-local storage.])])
2440 fi
2441
2442 # Target-specific assembler checks.
2443
2444 case "$target" in
2445   # All TARGET_ABI_OSF targets.
2446   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2447     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2448         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2449 [       .set nomacro
2450         .text
2451         extbl   $3, $2, $3      !lituse_bytoff!1
2452         ldq     $2, a($29)      !literal!1
2453         ldq     $4, b($29)      !literal!2
2454         ldq_u   $3, 0($2)       !lituse_base!1
2455         ldq     $27, f($29)     !literal!5
2456         jsr     $26, ($27), f   !lituse_jsr!5
2457         ldah    $29, 0($26)     !gpdisp!3
2458         lda     $0, c($29)      !gprel
2459         ldah    $1, d($29)      !gprelhigh
2460         lda     $1, d($1)       !gprellow
2461         lda     $29, 0($29)     !gpdisp!3],,
2462     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2463   [Define if your assembler supports explicit relocations.])])
2464     ;;
2465
2466   cris-*-*)
2467     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2468       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2469       [-no-mul-bug-abort], [.text],,
2470       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2471                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2472     ;;
2473
2474   sparc*-*-*)
2475     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2476       [.register %g2, #scratch],,
2477       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2478                 [Define if your assembler supports .register.])])
2479
2480     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2481       [-relax], [.text],,
2482       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2483                 [Define if your assembler supports -relax option.])])
2484
2485     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2486       gcc_cv_as_sparc_ua_pcrel,,
2487       [-K PIC],
2488 [.text
2489 foo:
2490         nop
2491 .data
2492 .align 4
2493 .byte 0
2494 .uaword %r_disp32(foo)],
2495       [if test x$gcc_cv_ld != x \
2496        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2497          gcc_cv_as_sparc_ua_pcrel=yes
2498        fi
2499        rm -f conftest],
2500       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2501                 [Define if your assembler and linker support unaligned PC relative relocs.])
2502
2503       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2504         gcc_cv_as_sparc_ua_pcrel_hidden,,
2505         [-K PIC],
2506 [.data
2507 .align 4
2508 .byte 0x31
2509 .uaword %r_disp32(foo)
2510 .byte 0x32, 0x33, 0x34
2511 .global foo
2512 .hidden foo
2513 foo:
2514 .skip 4],
2515         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2516          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2517          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2518             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2519             if $gcc_cv_objdump -R conftest 2> /dev/null \
2520                | grep 'DISP32' > /dev/null 2>&1; then
2521                 :
2522             else
2523                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2524             fi
2525          fi
2526          rm -f conftest],
2527          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2528                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2529     ]) # unaligned pcrel relocs
2530
2531     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2532       gcc_cv_as_sparc_offsetable_lo10,,
2533       [-xarch=v9],
2534 [.text
2535         or %g1, %lo(ab) + 12, %g1
2536         or %g1, %lo(ab + 12), %g1],
2537       [if test x$gcc_cv_objdump != x \
2538        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2539           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2540          gcc_cv_as_offsetable_lo10=yes
2541        fi],
2542        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2543                  [Define if your assembler supports offsetable %lo().])])
2544     ;;
2545
2546 changequote(,)dnl
2547   i[34567]86-*-* | x86_64-*-*)
2548 changequote([,])dnl
2549     case $target_os in
2550       cygwin* | pe | mingw32*)
2551         # Used for DWARF 2 in PE
2552         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2553           gcc_cv_as_ix86_pe_secrel32,
2554           [2,15,91],,
2555 [.text
2556 foo:    nop
2557 .data
2558         .secrel32 foo],
2559           [if test x$gcc_cv_ld != x \
2560            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2561              gcc_cv_as_ix86_pe_secrel32=yes
2562            fi
2563            rm -f conftest],
2564           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2565             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2566         ;;
2567     esac
2568
2569     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2570        gcc_cv_as_ix86_filds_fists,
2571       [2,9,0],, [filds mem; fists mem],,
2572       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2573         [Define if your assembler uses the new HImode fild and fist notation.])])
2574
2575     gcc_GAS_CHECK_FEATURE([cmov syntax],
2576       gcc_cv_as_ix86_cmov_sun_syntax,,,
2577       [cmovl.l %edx, %eax],,
2578       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2579         [Define if your assembler supports the Sun syntax for cmov.])])
2580
2581     # This one is used unconditionally by i386.[ch]; it is to be defined
2582     # to 1 if the feature is present, 0 otherwise.
2583     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2584         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2585 [       .text
2586 .L0:
2587         nop
2588         .data
2589         .long .L0@GOTOFF])
2590     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2591       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2592       [Define true if the assembler supports '.long foo@GOTOFF'.])
2593     ;;
2594
2595   ia64*-*-*)
2596     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2597         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2598 [       .text
2599         addl r15 = @ltoffx(x#), gp
2600         ;;
2601         ld8.mov r16 = [[r15]], x#],,
2602     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2603           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2604
2605     ;;
2606
2607   powerpc*-*-*)
2608     case $target in
2609       *-*-aix*) conftest_s='    .csect .text[[PR]]
2610         mfcr 3,128';;
2611       *-*-darwin*) conftest_s=' .text
2612         mfcr r3,128';;
2613       *)       conftest_s='     .text
2614         mfcr 3,128';;
2615     esac
2616
2617     gcc_GAS_CHECK_FEATURE([mfcr field support],
2618       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2619       [$conftest_s],,
2620       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2621           [Define if your assembler supports mfcr field.])])
2622     ;;
2623
2624   mips*-*-*)
2625     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2626       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2627 [       lw $4,%gp_rel(foo)($4)],,
2628       [if test x$target_cpu_default = x
2629        then target_cpu_default=MASK_EXPLICIT_RELOCS
2630        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2631        fi])
2632
2633     ;;
2634 esac
2635 # ??? Not all targets support dwarf2 debug_line, even within a version
2636 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2637 # info to the output file.  So, as supported targets are added to gas 2.11,
2638 # add some instruction here to (also) show we expect this might work.
2639 # ??? Once 2.11 is released, probably need to add first known working
2640 # version to the per-target configury.
2641 case "$target" in
2642   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2643   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2644   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2645     insn="nop"
2646     ;;
2647   ia64*-*-* | s390*-*-*)
2648     insn="nop 0"
2649     ;;
2650   mmix-*-*)
2651     insn="swym 0"
2652     ;;
2653 esac
2654 if test x"$insn" != x; then
2655  conftest_s="\
2656         .file 1 \"conftest.s\"
2657         .loc 1 3 0
2658         $insn"
2659  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2660   gcc_cv_as_dwarf2_debug_line,
2661   [elf,2,11,0],, [$conftest_s],
2662   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2663    if grep debug_line conftest.o > /dev/null 2>&1; then
2664      gcc_cv_as_dwarf2_debug_line=yes
2665    fi])
2666
2667 # The .debug_line file table must be in the exact order that
2668 # we specified the files, since these indices are also used
2669 # by DW_AT_decl_file.  Approximate this test by testing if
2670 # the assembler bitches if the same index is assigned twice.
2671  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2672   gcc_cv_as_dwarf2_file_buggy,,,
2673 [       .file 1 "foo.s"
2674         .file 1 "bar.s"])
2675
2676  if test $gcc_cv_as_dwarf2_debug_line = yes \
2677  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2678         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2679   [Define if your assembler supports dwarf2 .file/.loc directives,
2680    and preserves file table indices exactly as given.])
2681  fi
2682
2683  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2684   gcc_cv_as_gdwarf2_flag,
2685   [elf,2,11,0], [--gdwarf2], [$insn],,
2686   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2687 [Define if your assembler supports the --gdwarf2 option.])])
2688
2689  gcc_GAS_CHECK_FEATURE([--gstabs option],
2690   gcc_cv_as_gstabs_flag,
2691   [elf,2,11,0], [--gstabs], [$insn],
2692   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2693    # and warns about it, but still exits successfully.  So check for
2694    # this.
2695    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2696    then :
2697    else gcc_cv_as_gstabs_flag=yes
2698    fi],
2699   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2700 [Define if your assembler supports the --gstabs option.])])
2701 fi
2702
2703 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2704 gcc_cv_ld_ro_rw_mix=unknown
2705 if test $in_tree_ld = yes ; then
2706   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2707      && test $in_tree_ld_is_elf = yes; then
2708     gcc_cv_ld_ro_rw_mix=read-write
2709   fi
2710 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2711   echo '.section myfoosect, "a"' > conftest1.s
2712   echo '.section myfoosect, "aw"' > conftest2.s
2713   echo '.byte 1' >> conftest2.s
2714   echo '.section myfoosect, "a"' > conftest3.s
2715   echo '.byte 0' >> conftest3.s
2716   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2717      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2718      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2719      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2720         conftest2.o conftest3.o > /dev/null 2>&1; then
2721     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2722                          | sed -e '/myfoosect/!d' -e N`
2723     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2724       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2725         gcc_cv_ld_ro_rw_mix=read-only
2726       else
2727         gcc_cv_ld_ro_rw_mix=read-write
2728       fi
2729     fi
2730   fi
2731 changequote(,)dnl
2732   rm -f conftest.* conftest[123].*
2733 changequote([,])dnl
2734 fi
2735 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2736         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2737   [Define if your linker links a mix of read-only
2738    and read-write sections into a read-write section.])
2739 fi
2740 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2741
2742 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2743 gcc_cv_ld_eh_frame_hdr=no
2744 if test $in_tree_ld = yes ; then
2745   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2746      && test $in_tree_ld_is_elf = yes; then
2747     gcc_cv_ld_eh_frame_hdr=yes
2748   fi
2749 elif test x$gcc_cv_ld != x; then
2750         # Check if linker supports --eh-frame-hdr option
2751         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2752                 gcc_cv_ld_eh_frame_hdr=yes
2753         fi
2754 fi
2755 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2756         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2757 [Define if your linker supports --eh-frame-hdr option.])
2758 fi
2759 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2760
2761 AC_MSG_CHECKING(linker position independent executable support)
2762 gcc_cv_ld_pie=no
2763 if test $in_tree_ld = yes ; then
2764   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2765      && test $in_tree_ld_is_elf = yes; then
2766     gcc_cv_ld_pie=yes
2767   fi
2768 elif test x$gcc_cv_ld != x; then
2769         # Check if linker supports -pie option
2770         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2771                 gcc_cv_ld_pie=yes
2772         fi
2773 fi
2774 if test x"$gcc_cv_ld_pie" = xyes; then
2775         AC_DEFINE(HAVE_LD_PIE, 1,
2776 [Define if your linker supports -pie option.])
2777 fi
2778 AC_MSG_RESULT($gcc_cv_ld_pie)
2779
2780 # --------
2781 # UNSORTED
2782 # --------
2783
2784 AC_CACHE_CHECK(linker --as-needed support,
2785 gcc_cv_ld_as_needed,
2786 [gcc_cv_ld_as_needed=no
2787 if test $in_tree_ld = yes ; then
2788   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2789      && test $in_tree_ld_is_elf = yes; then
2790     gcc_cv_ld_as_needed=yes
2791   fi
2792 elif test x$gcc_cv_ld != x; then
2793         # Check if linker supports --as-needed and --no-as-needed options
2794         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2795                 gcc_cv_ld_as_needed=yes
2796         fi
2797 fi
2798 ])
2799 if test x"$gcc_cv_ld_as_needed" = xyes; then
2800         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2801 [Define if your linker supports --as-needed and --no-as-needed options.])
2802 fi
2803
2804 if test x$with_sysroot = x && test x$host = x$target \
2805    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2806   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2807 [Define to PREFIX/include if cpp should also search that directory.])
2808 fi
2809
2810 # Find out what GC implementation we want, or may, use.
2811 AC_ARG_WITH(gc,
2812 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2813                           with the compiler],
2814 [case "$withval" in
2815   page | zone)
2816     GGC=ggc-$withval
2817     ;;
2818   *)
2819     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2820     ;;
2821 esac],
2822 [GGC=ggc-page])
2823 AC_SUBST(GGC)
2824 echo "Using $GGC for garbage collection."
2825
2826 # Use the system's zlib library.
2827 zlibdir=-L../zlib
2828 zlibinc="-I\$(srcdir)/../zlib"
2829 AC_ARG_WITH(system-zlib,
2830 [  --with-system-zlib      use installed libz],
2831 zlibdir=
2832 zlibinc=
2833 )
2834 AC_SUBST(zlibdir)
2835 AC_SUBST(zlibinc)
2836
2837 dnl Very limited version of automake's enable-maintainer-mode
2838
2839 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2840   dnl maintainer-mode is disabled by default
2841   AC_ARG_ENABLE(maintainer-mode,
2842 [  --enable-maintainer-mode
2843                           enable make rules and dependencies not useful
2844                           (and sometimes confusing) to the casual installer],
2845       maintainer_mode=$enableval,
2846       maintainer_mode=no)
2847
2848 AC_MSG_RESULT($maintainer_mode)
2849
2850 if test "$maintainer_mode" = "yes"; then
2851   MAINT=''
2852 else
2853   MAINT='#'
2854 fi
2855 AC_SUBST(MAINT)dnl
2856
2857 AC_MSG_CHECKING([whether to use libbanshee for points-to alias analysis])
2858 AC_ARG_WITH(libbanshee,
2859 [  --with-libbanshee      enable libbanshee],
2860 libbanshee="$with_libbanshee",
2861 libbanshee=no)
2862
2863 if test x"$libbanshee" = xyes; then
2864         BANSHEELIB="../libbanshee/points-to/libandersen.a ../libbanshee/engine/libbansheeengine.a ../libbanshee/libcompat/libbansheecompat.a "
2865         BANSHEEINC="-I\$(srcdir)/../libbanshee/libcompat -I\$(srcdir)/../libbanshee -I\$(srcdir)/../libbanshee/points-to"
2866         ANDER="tree-alias-ander.o"
2867         AC_DEFINE(HAVE_BANSHEE, 1, [Define if BANSHEE is available])
2868 else
2869         BANSHEELIB=""
2870         BANSHEEINC=""
2871         ANDER=""
2872 fi
2873 AC_MSG_RESULT($with_libbanshee)
2874
2875 AC_SUBST(ANDER)
2876 AC_SUBST(BANSHEEINC)
2877 AC_SUBST(BANSHEELIB)
2878
2879 # --------------
2880 # Language hooks
2881 # --------------
2882
2883 # Make empty files to contain the specs and options for each language.
2884 # Then add #include lines to for a compiler that has specs and/or options.
2885
2886 lang_opt_files=
2887 lang_specs_files=
2888 lang_tree_files=
2889 for subdir in . $subdirs
2890 do
2891         if test -f $srcdir/$subdir/lang.opt; then
2892             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2893         fi
2894         if test -f $srcdir/$subdir/lang-specs.h; then
2895             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2896         fi
2897         if test -f $srcdir/$subdir/$subdir-tree.def; then
2898             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2899         fi
2900 done
2901
2902 # These (without "all_") are set in each config-lang.in.
2903 # `language' must be a single word so is spelled singularly.
2904 all_languages=
2905 all_boot_languages=
2906 all_compilers=
2907 all_stagestuff=
2908 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders libada-mk'
2909 # List of language makefile fragments.
2910 all_lang_makefrags=
2911 # List of language subdirectory makefiles.  Deprecated.
2912 all_lang_makefiles=
2913 # Files for gengtype
2914 all_gtfiles="$target_gtfiles"
2915 # Files for gengtype with language
2916 all_gtfiles_files_langs=
2917 all_gtfiles_files_files=
2918
2919 # Add the language fragments.
2920 # Languages are added via two mechanisms.  Some information must be
2921 # recorded in makefile variables, these are defined in config-lang.in.
2922 # We accumulate them and plug them into the main Makefile.
2923 # The other mechanism is a set of hooks for each of the main targets
2924 # like `clean', `install', etc.
2925
2926 language_hooks="Make-hooks"
2927
2928 for s in $subdirs
2929 do
2930                 language=
2931                 boot_language=
2932                 compilers=
2933                 stagestuff=
2934                 outputs=
2935                 gtfiles=
2936                 . ${srcdir}/$s/config-lang.in
2937                 if test "x$language" = x
2938                 then
2939                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2940                         exit 1
2941                 fi
2942                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2943                 if test -f ${srcdir}/$s/Makefile.in
2944                 then all_lang_makefiles="$s/Makefile"
2945                 fi
2946                 all_languages="$all_languages $language"
2947                 if test "x$boot_language" = xyes
2948                 then
2949                         all_boot_languages="$all_boot_languages $language"
2950                 fi
2951                 all_compilers="$all_compilers $compilers"
2952                 all_stagestuff="$all_stagestuff $stagestuff"
2953                 all_outputs="$all_outputs $outputs"
2954                 all_gtfiles="$all_gtfiles $gtfiles"
2955                 for f in $gtfiles
2956                 do
2957                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2958                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2959                 done
2960 done
2961
2962 # Pick up gtfiles for c
2963 gtfiles=
2964 s="c"
2965 . ${srcdir}/c-config-lang.in
2966 all_gtfiles="$all_gtfiles $gtfiles"
2967 for f in $gtfiles
2968 do
2969         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2970         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2971 done
2972
2973 check_languages=
2974 for language in $all_languages
2975 do
2976                 check_languages="$check_languages check-$language"
2977 done
2978
2979 # We link each language in with a set of hooks, reached indirectly via
2980 # lang.${target}.
2981
2982 rm -f Make-hooks
2983 touch Make-hooks
2984 target_list="all.build all.cross start.encap rest.encap tags \
2985         install-normal install-common install-man \
2986         uninstall info man srcextra srcman srcinfo \
2987         mostlyclean clean distclean maintainer-clean \
2988         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2989 for t in $target_list
2990 do
2991         x=
2992         for lang in $all_languages
2993         do
2994                         x="$x $lang.$t"
2995         done
2996         echo "lang.$t: $x" >> Make-hooks
2997 done
2998
2999 # --------
3000 # UNSORTED
3001 # --------
3002
3003 # Create .gdbinit.
3004
3005 echo "dir ." > .gdbinit
3006 echo "dir ${srcdir}" >> .gdbinit
3007 if test x$gdb_needs_out_file_path = xyes
3008 then
3009         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3010 fi
3011 if test "x$subdirs" != x; then
3012         for s in $subdirs
3013         do
3014                 echo "dir ${srcdir}/$s" >> .gdbinit
3015         done
3016 fi
3017 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3018
3019 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3020 # absolute path for gcc_tooldir based on inserting the number of up-directory
3021 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3022 # $(libsubdir)/@(unlibsubdir) based path.
3023 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3024 # make and thus we'd get different behavior depending on where we built the
3025 # sources.
3026 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3027     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3028 else
3029 changequote(<<, >>)dnl
3030 # An explanation of the sed strings:
3031 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3032 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3033 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3034 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3035 #
3036 # (*) Note this pattern overwrites the first character of the string
3037 # with a forward slash if one is not already present.  This is not a
3038 # problem because the exact names of the sub-directories concerned is
3039 # unimportant, just the number of them matters.
3040 #
3041 # The practical upshot of these patterns is like this:
3042 #
3043 #  prefix     exec_prefix        result
3044 #  ------     -----------        ------
3045 #   /foo        /foo/bar          ../
3046 #   /foo/       /foo/bar          ../
3047 #   /foo        /foo/bar/         ../
3048 #   /foo/       /foo/bar/         ../
3049 #   /foo        /foo/bar/ugg      ../../
3050 #
3051     dollar='$$'
3052     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3053 changequote([, ])dnl
3054 fi
3055 AC_SUBST(gcc_tooldir)
3056 AC_SUBST(dollar)
3057
3058 # Find a directory in which to install a shared libgcc.
3059
3060 AC_ARG_ENABLE(version-specific-runtime-libs,
3061 [  --enable-version-specific-runtime-libs
3062                           specify that runtime libraries should be
3063                           installed in a compiler-specific directory])
3064
3065 AC_ARG_WITH(slibdir,
3066 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3067 slibdir="$with_slibdir",
3068 if test "${enable_version_specific_runtime_libs+set}" = set; then
3069   slibdir='$(libsubdir)'
3070 elif test "$host" != "$target"; then
3071   slibdir='$(build_tooldir)/lib'
3072 else
3073   slibdir='$(libdir)'
3074 fi)
3075 AC_SUBST(slibdir)
3076
3077 objdir=`${PWDCMD-pwd}`
3078 AC_SUBST(objdir)
3079
3080 # Substitute configuration variables
3081 AC_SUBST(subdirs)
3082 AC_SUBST(srcdir)
3083 AC_SUBST(all_boot_languages)
3084 AC_SUBST(all_compilers)
3085 AC_SUBST(all_gtfiles)
3086 AC_SUBST(all_gtfiles_files_langs)
3087 AC_SUBST(all_gtfiles_files_files)
3088 AC_SUBST(all_lang_makefrags)
3089 AC_SUBST(all_lang_makefiles)
3090 AC_SUBST(all_languages)
3091 AC_SUBST(all_stagestuff)
3092 AC_SUBST(build_exeext)
3093 AC_SUBST(build_install_headers_dir)
3094 AC_SUBST(build_xm_file_list)
3095 AC_SUBST(build_xm_include_list)
3096 AC_SUBST(build_xm_defines)
3097 AC_SUBST(check_languages)
3098 AC_SUBST(cc_set_by_configure)
3099 AC_SUBST(quoted_cc_set_by_configure)
3100 AC_SUBST(cpp_install_dir)
3101 AC_SUBST(xmake_file)
3102 AC_SUBST(tmake_file)
3103 AC_SUBST(extra_gcc_objs)
3104 AC_SUBST(extra_headers_list)
3105 AC_SUBST(extra_objs)
3106 AC_SUBST(extra_parts)
3107 AC_SUBST(extra_passes)
3108 AC_SUBST(extra_programs)
3109 AC_SUBST(float_h_file)
3110 AC_SUBST(gcc_config_arguments)
3111 AC_SUBST(gcc_gxx_include_dir)
3112 AC_SUBST(libstdcxx_incdir)
3113 AC_SUBST(gcc_version)
3114 AC_SUBST(gcc_version_full)
3115 AC_SUBST(gcc_version_trigger)
3116 AC_SUBST(host_exeext)
3117 AC_SUBST(host_xm_file_list)
3118 AC_SUBST(host_xm_include_list)
3119 AC_SUBST(host_xm_defines)
3120 AC_SUBST(out_host_hook_obj)
3121 AC_SUBST(install)
3122 AC_SUBST(lang_opt_files)
3123 AC_SUBST(lang_specs_files)
3124 AC_SUBST(lang_tree_files)
3125 AC_SUBST(local_prefix)
3126 AC_SUBST(md_file)
3127 AC_SUBST(objc_boehm_gc)
3128 AC_SUBST(out_file)
3129 AC_SUBST(out_object_file)
3130 AC_SUBST(stage_prefix_set_by_configure)
3131 AC_SUBST(quoted_stage_prefix_set_by_configure)
3132 AC_SUBST(symbolic_link)
3133 AC_SUBST(thread_file)
3134 AC_SUBST(tm_file_list)
3135 AC_SUBST(tm_include_list)
3136 AC_SUBST(tm_defines)
3137 AC_SUBST(tm_p_file_list)
3138 AC_SUBST(tm_p_include_list)
3139 AC_SUBST(xm_file_list)
3140 AC_SUBST(xm_include_list)
3141 AC_SUBST(xm_defines)
3142 AC_SUBST(target_noncanonical)
3143 AC_SUBST(c_target_objs)
3144 AC_SUBST(cxx_target_objs)
3145 AC_SUBST(target_cpu_default)
3146
3147 AC_SUBST_FILE(language_hooks)
3148
3149 # If it doesn't already exist, create document directory
3150 echo "checking for the document directory." 1>&2
3151 if test -d doc ; then
3152   true
3153 else
3154   mkdir doc
3155 fi
3156
3157 # Echo link setup.
3158 if test x${build} = x${host} ; then
3159   if test x${host} = x${target} ; then
3160     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3161   else
3162     echo "Links are now set up to build a cross-compiler" 1>&2
3163     echo " from ${host} to ${target}." 1>&2
3164   fi
3165 else
3166   if test x${host} = x${target} ; then
3167     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3168     echo " for ${target}." 1>&2
3169   else
3170     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3171     echo " from ${host} to ${target}." 1>&2
3172   fi
3173 fi
3174
3175 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3176 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3177
3178 # Configure the subdirectories
3179 # AC_CONFIG_SUBDIRS($subdirs)
3180
3181 # Create the Makefile
3182 # and configure language subdirectories
3183 AC_CONFIG_FILES($all_outputs)
3184
3185 AC_CONFIG_COMMANDS([default],
3186 [
3187 case ${CONFIG_HEADERS} in
3188   *auto-host.h:config.in*)
3189   echo > cstamp-h ;;
3190 esac
3191 # Make sure all the subdirs exist.
3192 for d in $subdirs
3193 do
3194     test -d $d || mkdir $d
3195 done
3196 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3197 # bootstrapping and the installation procedure can still use
3198 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3199 # FLAGS_TO_PASS has been modified to solve the problem there.
3200 # This is virtually a duplicate of what happens in configure.lang; we do
3201 # an extra check to make sure this only happens if ln -s can be used.
3202 if test "$symbolic_link" = "ln -s"; then
3203  for d in ${subdirs} fixinc ; do
3204         STARTDIR=`${PWDCMD-pwd}`
3205         cd $d
3206         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3207         do
3208                 rm -f $t
3209                 $symbolic_link ../$t $t 2>/dev/null
3210         done
3211         cd $STARTDIR
3212  done
3213 else true ; fi
3214 ],
3215 [subdirs='$subdirs'
3216 symbolic_link='$symbolic_link'
3217 ])
3218 AC_OUTPUT