gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 #Set to 1 on a release branch
  34 is_release=
  35
  36 # Determine the host, build, and target systems
  37 AC_CANONICAL_BUILD
  38 AC_CANONICAL_HOST
  39 AC_CANONICAL_TARGET
  40
  41 # Determine the noncanonical target name, for directory use.
  42 ACX_NONCANONICAL_TARGET
  43
  44 # Determine the target- and build-specific subdirectories
  45 GCC_TOPLEV_SUBDIRS
  46
  47 # Set program_transform_name
  48 AC_ARG_PROGRAM
  49
  50 # Check for bogus environment variables.
  51 # Test if LIBRARY_PATH contains the notation for the current directory
  52 # since this would lead to problems installing/building glibc.
  53 # LIBRARY_PATH contains the current directory if one of the following
  54 # is true:
  55 # - one of the terminals (":" and ";") is the first or last sign
  56 # - two terminals occur directly after each other
  57 # - the path contains an element with a dot in it
  58 AC_MSG_CHECKING(LIBRARY_PATH variable)
  59 changequote(,)dnl
  60 case ${LIBRARY_PATH} in
  61   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  62     library_path_setting="contains current directory"
  63     ;;
  64   *)
  65     library_path_setting="ok"
  66     ;;
  67 esac
  68 changequote([,])dnl
  69 AC_MSG_RESULT($library_path_setting)
  70 if test "$library_path_setting" != "ok"; then
  71 AC_MSG_ERROR([
  72 *** LIBRARY_PATH shouldn't contain the current directory when
  73 *** building gcc. Please change the environment variable
  74 *** and run configure again.])
  75 fi
  76
  77 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  78 # since this would lead to problems installing/building glibc.
  79 # GCC_EXEC_PREFIX contains the current directory if one of the following
  80 # is true:
  81 # - one of the terminals (":" and ";") is the first or last sign
  82 # - two terminals occur directly after each other
  83 # - the path contains an element with a dot in it
  84 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  85 changequote(,)dnl
  86 case ${GCC_EXEC_PREFIX} in
  87   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  88     gcc_exec_prefix_setting="contains current directory"
  89     ;;
  90   *)
  91     gcc_exec_prefix_setting="ok"
  92     ;;
  93 esac
  94 changequote([,])dnl
  95 AC_MSG_RESULT($gcc_exec_prefix_setting)
  96 if test "$gcc_exec_prefix_setting" != "ok"; then
  97 AC_MSG_ERROR([
  98 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  99 *** building gcc. Please change the environment variable
 100 *** and run configure again.])
 101 fi
 102
 103 # -----------
 104 # Directories
 105 # -----------
 106
 107 # Specify the local prefix
 108 local_prefix=
 109 AC_ARG_WITH(local-prefix,
 110 [  --with-local-prefix=DIR specifies directory to put local include],
 111 [case "${withval}" in
 112 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 113 no)     ;;
 114 *)      local_prefix=$with_local_prefix ;;
 115 esac])
 116
 117 # Default local prefix if it is empty
 118 if test x$local_prefix = x; then
 119         local_prefix=/usr/local
 120 fi
 121
 122 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 123 # passed in by the toplevel make and thus we'd get different behavior
 124 # depending on where we built the sources.
 125 gcc_gxx_include_dir=
 126 # Specify the g++ header file directory
 127 AC_ARG_WITH(gxx-include-dir,
 128 [  --with-gxx-include-dir=DIR
 129                           specifies directory to put g++ header files],
 130 [case "${withval}" in
 131 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 132 no)     ;;
 133 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 134 esac])
 135
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 141 changequote(<<, >>)dnl
 142     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 143 changequote([, ])dnl
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 AC_MSG_CHECKING([whether a default linker was specified])
 207 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 208   if test x"$gnu_ld_flag" = x"no"; then
 209     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 210   else
 211     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 212   fi
 213 else
 214   AC_MSG_RESULT(no)
 215 fi
 216
 217 # With demangler in GNU ld
 218 AC_ARG_WITH(demangler-in-ld,
 219 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 220 demangler_in_ld="$with_demangler_in_ld",
 221 demangler_in_ld=no)
 222
 223 # ----------------------
 224 # Find default assembler
 225 # ----------------------
 226
 227 # With GNU as
 228 AC_ARG_WITH(gnu-as,
 229 [  --with-gnu-as           arrange to work with GNU as],
 230 gas_flag="$with_gnu_as",
 231 gas_flag=no)
 232
 233 AC_ARG_WITH(as,
 234 [  --with-as               arrange to use the specified as (full pathname)],
 235 DEFAULT_ASSEMBLER="$with_as")
 236 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 237   if test ! -x "$DEFAULT_ASSEMBLER"; then
 238     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 239   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 240     gas_flag=yes
 241   fi
 242   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 243         [Define to enable the use of a default assembler.])
 244 fi
 245
 246 AC_MSG_CHECKING([whether a default assembler was specified])
 247 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 248   if test x"$gas_flag" = x"no"; then
 249     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 250   else
 251     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 252   fi
 253 else
 254   AC_MSG_RESULT(no)
 255 fi
 256
 257 # ---------------
 258 # Find C compiler
 259 # ---------------
 260
 261 # If a non-executable a.out is present (e.g. created by GNU as above even if
 262 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 263 # file, even when creating an executable, so an execution test fails.
 264 # Remove possible default executable files to avoid this.
 265 #
 266 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 267 # Autoconf includes it.
 268 rm -f a.out a.exe b.out
 269
 270 # Find the native compiler
 271 AC_PROG_CC
 272 AM_PROG_CC_C_O
 273 # autoconf is lame and doesn't give us any substitution variable for this.
 274 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 275   NO_MINUS_C_MINUS_O=yes
 276 else
 277   OUTPUT_OPTION='-o $@'
 278 fi
 279 AC_SUBST(NO_MINUS_C_MINUS_O)
 280 AC_SUBST(OUTPUT_OPTION)
 281
 282 # -------------------------
 283 # Check C compiler features
 284 # -------------------------
 285
 286 AC_PROG_CPP
 287 AC_C_INLINE
 288
 289 gcc_AC_C_LONG_LONG
 290
 291 # sizeof(char) is 1 by definition.
 292 AC_CHECK_SIZEOF(void *)
 293 AC_CHECK_SIZEOF(short)
 294 AC_CHECK_SIZEOF(int)
 295 AC_CHECK_SIZEOF(long)
 296 if test $ac_cv_c_long_long = yes; then
 297   AC_CHECK_SIZEOF(long long)
 298 fi
 299 if test $ac_cv_c___int64 = yes; then
 300   AC_CHECK_SIZEOF(__int64)
 301 fi
 302
 303 # ---------------------
 304 # Warnings and checking
 305 # ---------------------
 306
 307 # Check $CC warning features (if it's GCC).
 308 # We want to use -pedantic, but we don't want warnings about
 309 # * 'long long'
 310 # * variadic macros
 311 # So, we only use -pedantic if we can disable those warnings.
 312
 313 AC_CACHE_CHECK(
 314   [whether ${CC} accepts -Wno-long-long],
 315   [ac_cv_prog_cc_w_no_long_long],
 316   [save_CFLAGS="$CFLAGS"
 317   CFLAGS="-Wno-long-long"
 318   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 319                     [ac_cv_prog_cc_w_no_long_long=yes],
 320                     [ac_cv_prog_cc_w_no_long_long=no])
 321   CFLAGS="$save_CFLAGS"
 322   ])
 323
 324 AC_CACHE_CHECK(
 325   [whether ${CC} accepts -Wno-variadic-macros],
 326   [ac_cv_prog_cc_w_no_variadic_macros],
 327   [save_CFLAGS="$CFLAGS"
 328   CFLAGS="-Wno-variadic-macros"
 329   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 330                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 331                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 332   CFLAGS="$save_CFLAGS"
 333   ])
 334
 335 strict1_warn=
 336 if test $ac_cv_prog_cc_w_no_long_long = yes \
 337    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 338   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 339 fi
 340 AC_SUBST(strict1_warn)
 341
 342 # Add -Wold-style-definition if it's accepted
 343 AC_CACHE_CHECK(
 344   [whether ${CC} accepts -Wold-style-definition],
 345   [ac_cv_prog_cc_w_old_style_definition],
 346   [save_CFLAGS="$CFLAGS"
 347   CFLAGS="-Wold-style-definition"
 348   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 349                     [ac_cv_prog_cc_w_old_style_definition=yes],
 350                     [ac_cv_prog_cc_w_old_style_definition=no])
 351   CFLAGS="$save_CFLAGS"
 352   ])
 353 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 354   strict1_warn="${strict1_warn} -Wold-style-definition"
 355 fi
 356
 357 # Enable -Werror, period.
 358 AC_ARG_ENABLE(werror_always,
 359 [  --enable-werror-always         enable -Werror always], [],
 360 [enable_werror_always=no])
 361 if test x${enable_werror_always} = xyes ; then
 362   strict1_warn="${strict1_warn} -Werror"
 363   WERROR=-Werror
 364 fi
 365
 366 # If the native compiler is GCC, we can enable warnings even in stage1.
 367 # That's useful for people building cross-compilers, or just running a
 368 # quick `make'.
 369 warn_cflags=
 370 if test "x$GCC" = "xyes"; then
 371   warn_cflags='$(GCC_WARN_CFLAGS)'
 372 fi
 373 AC_SUBST(warn_cflags)
 374
 375 # Enable -Werror in bootstrap stage2 and later.
 376 AC_ARG_ENABLE(werror,
 377 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 378 [if test x$is_release = x ; then
 379   # Default to "yes" on development branches.
 380   enable_werror=yes
 381 else
 382   # Default to "no" on release branches.
 383   enable_werror=no
 384 fi])
 385 if test x$enable_werror = xyes ; then
 386   WERROR=-Werror
 387 fi
 388 AC_SUBST(WERROR)
 389
 390 # Enable expensive internal checks
 391 AC_ARG_ENABLE(checking,
 392 [  --enable-checking[=LIST]
 393                           enable expensive run-time checks.  With LIST,
 394                           enable only specific categories of checks.
 395                           Categories are: assert,fold,gc,gcac,misc,
 396                           rtlflag,rtl,tree,valgrind,release,yes,all;],
 397 [ac_checking_flags="${enableval}"],[
 398 # Determine the default checks.
 399 if test x$is_release = x ; then
 400   ac_checking_flags=yes
 401 else
 402   ac_checking_flags=release
 403 fi])
 404 ac_assert_checking=1
 405 ac_checking=
 406 ac_tree_checking=
 407 ac_rtl_checking=
 408 ac_rtlflag_checking=
 409 ac_gc_checking=
 410 ac_gc_always_collect=
 411 ac_fold_checking=
 412 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 413 for check in $ac_checking_flags
 414 do
 415         case $check in
 416         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 417                         ac_tree_checking=1 ; ac_gc_checking=1 ;
 418                         ac_rtlflag_checking=1 ;;
 419         no)             ac_assert_checking= ; ac_checking= ;
 420                         ac_tree_checking= ; ac_rtl_checking= ;
 421                         ac_rtlflag_checking= ; ac_gc_checking= ;
 422                         ac_gc_always_collect= ; ac_fold_checking= ;;
 423         all)            ac_assert_checking=1 ; ac_checking=1 ;
 424                         ac_tree_checking=1 ; ac_rtl_checking=1 ;
 425                         ac_rtlflag_checking=1 ; ac_gc_checking=1 ;
 426                         ac_gc_always_collect=1 ; ac_fold_checking=1 ;;
 427         release)        ac_assert_checking=1 ;;
 428         assert)         ac_assert_checking=1 ;;
 429         fold)           ac_fold_checking=1 ;;
 430         gc)             ac_gc_checking=1 ;;
 431         gcac)           ac_gc_always_collect=1 ;;
 432         misc)           ac_checking=1 ;;
 433         rtlflag)        ac_rtlflag_checking=1 ;;
 434         rtl)            ac_rtl_checking=1 ;;
 435         tree)           ac_tree_checking=1 ;;
 436         valgrind)       ac_checking_valgrind=1 ;;
 437         *)      AC_MSG_ERROR(unknown check category $check) ;;
 438         esac
 439 done
 440 IFS="$ac_save_IFS"
 441
 442 nocommon_flag=""
 443 if test x$ac_checking != x ; then
 444   AC_DEFINE(ENABLE_CHECKING, 1,
 445 [Define if you want more run-time sanity checks.  This one gets a grab
 446    bag of miscellaneous but relatively cheap checks.])
 447   nocommon_flag=-fno-common
 448 fi
 449 AC_SUBST(nocommon_flag)
 450 if test x$ac_assert_checking != x ; then
 451   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 452 [Define if you want assertions enabled.  This is a cheap check.])
 453 fi
 454 if test x$ac_tree_checking != x ; then
 455   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 456 [Define if you want all operations on trees (the basic data
 457    structure of the front ends) to be checked for dynamic type safety
 458    at runtime.  This is moderately expensive.  The tree browser debugging
 459    routines will also be enabled by this option.
 460    ])
 461   TREEBROWSER=tree-browser.o
 462 fi
 463 AC_SUBST(TREEBROWSER)
 464 if test x$ac_rtl_checking != x ; then
 465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 466 [Define if you want all operations on RTL (the basic data structure
 467    of the optimizer and back end) to be checked for dynamic type safety
 468    at runtime.  This is quite expensive.])
 469 fi
 470 if test x$ac_rtlflag_checking != x ; then
 471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 472 [Define if you want RTL flag accesses to be checked against the RTL
 473    codes that are supported for each access macro.  This is relatively
 474    cheap.])
 475 fi
 476 if test x$ac_gc_checking != x ; then
 477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 478 [Define if you want the garbage collector to do object poisoning and
 479    other memory allocation checks.  This is quite expensive.])
 480 fi
 481 if test x$ac_gc_always_collect != x ; then
 482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 483 [Define if you want the garbage collector to operate in maximally
 484    paranoid mode, validating the entire heap and collecting garbage at
 485    every opportunity.  This is extremely expensive.])
 486 fi
 487 if test x$ac_fold_checking != x ; then
 488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 489 [Define if you want fold checked that it never destructs its argument.
 490    This is quite expensive.])
 491 fi
 492 valgrind_path_defines=
 493 valgrind_command=
 494
 495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 496 dnl # an if statement.  This was the source of very frustrating bugs
 497 dnl # in converting to autoconf 2.5x!
 498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 499
 500 if test x$ac_checking_valgrind != x ; then
 501   # It is certainly possible that there's valgrind but no valgrind.h.
 502   # GCC relies on making annotations so we must have both.
 503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 504   AC_TRY_CPP(
 505     [#include <valgrind/memcheck.h>
 506 #ifndef VALGRIND_DISCARD
 507 #error VALGRIND_DISCARD not defined
 508 #endif],
 509   [gcc_cv_header_valgrind_memcheck_h=yes],
 510   [gcc_cv_header_valgrind_memcheck_h=no])
 511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 513   AC_TRY_CPP(
 514     [#include <memcheck.h>
 515 #ifndef VALGRIND_DISCARD
 516 #error VALGRIND_DISCARD not defined
 517 #endif],
 518   [gcc_cv_header_memcheck_h=yes],
 519   gcc_cv_header_memcheck_h=no)
 520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 523   if test "x$valgrind_path" = "x" \
 524     || (test $have_valgrind_h = no \
 525         && test $gcc_cv_header_memcheck_h = no \
 526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 528   fi
 529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 530   valgrind_command="$valgrind_path -q"
 531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 532 [Define if you want to run subprograms and generated programs
 533    through valgrind (a memory checker).  This is extremely expensive.])
 534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 536         [Define if valgrind's valgrind/memcheck.h header is installed.])
 537   fi
 538   if test $gcc_cv_header_memcheck_h = yes; then
 539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 540         [Define if valgrind's memcheck.h header is installed.])
 541   fi
 542 fi
 543 AC_SUBST(valgrind_path_defines)
 544 AC_SUBST(valgrind_command)
 545
 546 AC_ARG_ENABLE(mapped-location,
 547 [  --enable-mapped-location   location_t is fileline integer cookie],,
 548 enable_mapped_location=no)
 549
 550 if test "$enable_mapped_location" = yes ; then
 551   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 552 [Define if location_t is fileline integer cookie.])
 553 fi
 554
 555 # Enable code coverage collection
 556 AC_ARG_ENABLE(coverage,
 557 [  --enable-coverage[=LEVEL]
 558                           enable compiler's code coverage collection.
 559                           Use to measure compiler performance and locate
 560                           unused parts of the compiler. With LEVEL, specify
 561                           optimization. Values are opt, noopt,
 562                           default is noopt],
 563 [case "${enableval}" in
 564   yes|noopt)
 565     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 566     ;;
 567   opt)
 568     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 569     ;;
 570   no)
 571     # a.k.a. --disable-coverage
 572     coverage_flags=""
 573     ;;
 574   *)
 575     AC_MSG_ERROR(unknown coverage setting $enableval)
 576     ;;
 577 esac],
 578 [coverage_flags=""])
 579 AC_SUBST(coverage_flags)
 580
 581 AC_ARG_ENABLE(gather-detailed-mem-stats,
 582 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 583 [enable_gather_detailed_mem_stats=no])
 584 if test x$enable_gather_detailed_mem_stats = xyes ; then
 585   AC_DEFINE(GATHER_STATISTICS, 1,
 586         [Define to enable detailed memory allocation stats gathering.])
 587 fi
 588
 589 # -------------------------------
 590 # Miscenalleous configure options
 591 # -------------------------------
 592
 593 # With stabs
 594 AC_ARG_WITH(stabs,
 595 [  --with-stabs            arrange to use stabs instead of host debug format],
 596 stabs="$with_stabs",
 597 stabs=no)
 598
 599 # Determine whether or not multilibs are enabled.
 600 AC_ARG_ENABLE(multilib,
 601 [  --enable-multilib       enable library support for multiple ABIs],
 602 [], [enable_multilib=yes])
 603 AC_SUBST(enable_multilib)
 604
 605 # Enable __cxa_atexit for C++.
 606 AC_ARG_ENABLE(__cxa_atexit,
 607 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 608 [], [])
 609
 610 # Enable threads
 611 # Pass with no value to take the default
 612 # Pass with a value to specify a thread package
 613 AC_ARG_ENABLE(threads,
 614 [  --enable-threads        enable thread usage for target GCC
 615   --enable-threads=LIB    use LIB thread package for target GCC],,
 616 [enable_threads=''])
 617
 618 AC_ARG_ENABLE(objc-gc,
 619 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 620                           the GNU Objective-C runtime],
 621 if test x$enable_objc_gc = xno; then
 622         objc_boehm_gc=''
 623 else
 624         objc_boehm_gc=1
 625 fi,
 626 objc_boehm_gc='')
 627
 628 AC_ARG_WITH(dwarf2,
 629 [  --with-dwarf2           force the default debug format to be DWARF 2],
 630 dwarf2="$with_dwarf2",
 631 dwarf2=no)
 632
 633 AC_ARG_ENABLE(shared,
 634 [  --disable-shared        don't provide a shared libgcc],
 635 [
 636   case $enable_shared in
 637   yes | no) ;;
 638   *)
 639     enable_shared=no
 640     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 641     for pkg in $enableval; do
 642       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 643         enable_shared=yes
 644       fi
 645     done
 646     IFS="$ac_save_ifs"
 647     ;;
 648   esac
 649 ], [enable_shared=yes])
 650 AC_SUBST(enable_shared)
 651
 652 AC_ARG_WITH(sysroot,
 653 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 654 [
 655  case ${with_sysroot} in
 656  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 657  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 658  esac
 659
 660  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 661  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 662
 663  if test "x$exec_prefix" = xNONE; then
 664   if test "x$prefix" = xNONE; then
 665    test_prefix=/usr/local
 666   else
 667    test_prefix=$prefix
 668   fi
 669  else
 670   test_prefix=$exec_prefix
 671  fi
 672  case ${TARGET_SYSTEM_ROOT} in
 673  "${test_prefix}"|"${test_prefix}/"*|\
 674  '${exec_prefix}'|'${exec_prefix}/'*)
 675    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 676    TARGET_SYSTEM_ROOT_DEFINE="$t"
 677    ;;
 678  esac
 679 ], [
 680  TARGET_SYSTEM_ROOT=
 681  TARGET_SYSTEM_ROOT_DEFINE=
 682  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 683 ])
 684 AC_SUBST(TARGET_SYSTEM_ROOT)
 685 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 686 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 687
 688 # Build with intermodule optimisations
 689 AC_ARG_ENABLE(intermodule,
 690 [  --enable-intermodule    build the compiler in one step],
 691 [case ${enable_intermodule} in
 692   yes) onestep="-onestep";;
 693   *) onestep="";;
 694 esac],
 695 [onestep=""])
 696 AC_SUBST(onestep)
 697
 698 # Sanity check enable_languages in case someone does not run the toplevel
 699 # configure # script.
 700 AC_ARG_ENABLE(languages,
 701 [  --enable-languages=LIST specify which front-ends to build],
 702 [case ,${enable_languages}, in
 703        ,,|,yes,)
 704                 # go safe -- we cannot be much sure without the toplevel
 705                 # configure's
 706                 # analysis of which target libs are present and usable
 707                 enable_languages=c
 708                 ;;
 709          *,all,*)
 710                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 711                 ;;
 712         *,c,*)
 713                 ;;
 714         *)
 715                 enable_languages=c,${enable_languages}
 716                 ;;
 717 esac],
 718 [enable_languages=c])
 719
 720 subdirs=
 721 for lang in ${srcdir}/*/config-lang.in
 722 do
 723         case $lang in
 724         # The odd quoting in the next line works around
 725         # an apparent bug in bash 1.12 on linux.
 726 changequote(,)dnl
 727         ${srcdir}/[*]/config-lang.in) ;;
 728         *)
 729           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 730           if test "x$lang_alias" = x
 731           then
 732                 echo "$lang doesn't set \$language." 1>&2
 733                 exit 1
 734           fi
 735           case ",$enable_languages," in
 736           *,$lang_alias,*)
 737             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 738           esac
 739           ;;
 740 changequote([,])dnl
 741         esac
 742 done
 743
 744
 745 # -------------------------
 746 # Checks for other programs
 747 # -------------------------
 748
 749 AC_PROG_MAKE_SET
 750
 751 # Find some useful tools
 752 AC_PROG_AWK
 753 # We need awk to create options.c and options.h.
 754 # Bail out if it's missing.
 755 case ${AWK} in
 756   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 757 esac
 758
 759 gcc_AC_PROG_LN_S
 760 ACX_PROG_LN($LN_S)
 761 AC_PROG_RANLIB
 762 case "${host}" in
 763 *-*-darwin*)
 764   # By default, the Darwin ranlib will not treat common symbols as
 765   # definitions when  building the archive table of contents.  Other
 766   # ranlibs do that; pass an option to the Darwin ranlib that makes
 767   # it behave similarly.
 768   ranlib_flags="-c"
 769   ;;
 770 *)
 771   ranlib_flags=""
 772 esac
 773 AC_SUBST(ranlib_flags)
 774
 775 gcc_AC_PROG_INSTALL
 776
 777 # See if cmp has --ignore-initial.
 778 gcc_AC_PROG_CMP_IGNORE_INITIAL
 779
 780 # See if we have the mktemp command.
 781 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 782
 783 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 784
 785 # See if makeinfo has been installed and is modern enough
 786 # that we can use it.
 787 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 788   [GNU texinfo.* \([0-9][0-9.]*\)],
 789   [4.[2-9]*])
 790 if test $gcc_cv_prog_makeinfo_modern = no; then
 791   MAKEINFO="$MISSING makeinfo"
 792   AC_MSG_WARN([
 793 *** Makeinfo is missing or too old.
 794 *** Info documentation will not be built.])
 795   BUILD_INFO=
 796 else
 797   BUILD_INFO=info
 798 fi
 799 AC_SUBST(BUILD_INFO)
 800
 801 # Is pod2man recent enough to regenerate manpages?
 802 AC_MSG_CHECKING([for recent Pod::Man])
 803 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 804   AC_MSG_RESULT(yes)
 805   GENERATED_MANPAGES=generated-manpages
 806 else
 807   AC_MSG_RESULT(no)
 808   GENERATED_MANPAGES=
 809 fi
 810 AC_SUBST(GENERATED_MANPAGES)
 811
 812 # How about lex?
 813 dnl Don't use AC_PROG_LEX; we insist on flex.
 814 dnl LEXLIB is not useful in gcc.
 815 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 816
 817 # Bison?
 818 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 819
 820 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 821 # check for build == host before using them.
 822
 823 # NM
 824 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 825   && test -d ../binutils ; then
 826   NM='$(objdir)/../binutils/nm-new'
 827 else
 828   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 829 fi
 830
 831 # AR
 832 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 833   && test -d ../binutils ; then
 834   AR='$(objdir)/../binutils/ar'
 835 else
 836   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 837 fi
 838
 839
 840 # --------------------
 841 # Checks for C headers
 842 # --------------------
 843
 844 AC_MSG_CHECKING(for GNU C library)
 845 AC_CACHE_VAL(gcc_cv_glibc,
 846 [AC_TRY_COMPILE(
 847   [#include <features.h>],[
 848 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 849 #error Not a GNU C library system
 850 #endif],
 851   [gcc_cv_glibc=yes],
 852   gcc_cv_glibc=no)])
 853 AC_MSG_RESULT($gcc_cv_glibc)
 854 if test $gcc_cv_glibc = yes; then
 855   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 856 fi
 857
 858 # Need to reject headers which give warnings, so that the -Werror bootstrap
 859 # works later. *sigh*  This needs to come before all header checks.
 860 AC_PROG_CPP_WERROR
 861
 862 AC_HEADER_STDC
 863 AC_HEADER_TIME
 864 ACX_HEADER_STRING
 865 AC_HEADER_SYS_WAIT
 866 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 867                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 868                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 869                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 870
 871 # Check for thread headers.
 872 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 873 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 874
 875 # These tests can't be done till we know if we have limits.h.
 876 gcc_AC_C_CHAR_BIT
 877 AC_C_BIGENDIAN_CROSS
 878
 879 # --------
 880 # UNSORTED
 881 # --------
 882
 883 # Stage specific cflags for build.
 884 stage1_cflags=
 885 case $build in
 886 vax-*-*)
 887   if test x$GCC = xyes
 888   then
 889     stage1_cflags="-Wa,-J"
 890   else
 891     stage1_cflags="-J"
 892   fi
 893   ;;
 894 powerpc-*-darwin*)
 895   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 896   # sources; use -no-cpp-precomp to get to GNU cpp.
 897   # Apple's GCC has bugs in designated initializer handling, so disable
 898   # that too.
 899   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 900   ;;
 901 esac
 902 AC_SUBST(stage1_cflags)
 903
 904 # These libraries may be used by collect2.
 905 # We may need a special search path to get them linked.
 906 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 907 [save_LIBS="$LIBS"
 908 for libs in '' -lld -lmld \
 909                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 910                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 911 do
 912         LIBS="$libs"
 913         AC_TRY_LINK_FUNC(ldopen,
 914                 [gcc_cv_collect2_libs="$libs"; break])
 915 done
 916 LIBS="$save_LIBS"
 917 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 918 case $gcc_cv_collect2_libs in
 919         "none required")        ;;
 920         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 921 esac
 922 AC_SUBST(COLLECT2_LIBS)
 923
 924 # When building Ada code on Alpha, we need exc_resume which is usually in
 925 # -lexc.  So test for it.
 926 save_LIBS="$LIBS"
 927 LIBS=
 928 AC_SEARCH_LIBS(exc_resume, exc)
 929 GNAT_LIBEXC="$LIBS"
 930 LIBS="$save_LIBS"
 931 AC_SUBST(GNAT_LIBEXC)
 932
 933 # Some systems put ldexp and frexp in libm instead of libc; assume
 934 # they're both in the same place.  jcf-dump needs them.
 935 save_LIBS="$LIBS"
 936 LIBS=
 937 AC_SEARCH_LIBS(ldexp, m)
 938 LDEXP_LIB="$LIBS"
 939 LIBS="$save_LIBS"
 940 AC_SUBST(LDEXP_LIB)
 941
 942 # Use <inttypes.h> only if it exists,
 943 # doesn't clash with <sys/types.h>, and declares intmax_t.
 944 AC_MSG_CHECKING(for inttypes.h)
 945 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 946 [AC_TRY_COMPILE(
 947   [#include <sys/types.h>
 948 #include <inttypes.h>],
 949   [intmax_t i = -1;],
 950   [gcc_cv_header_inttypes_h=yes],
 951   gcc_cv_header_inttypes_h=no)])
 952 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 953 if test $gcc_cv_header_inttypes_h = yes; then
 954   AC_DEFINE(HAVE_INTTYPES_H, 1,
 955         [Define if you have a working <inttypes.h> header file.])
 956 fi
 957
 958 dnl Disabled until we have a complete test for buggy enum bitfields.
 959 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 960
 961 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 962         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 963         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 964         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 965         setlocale)
 966
 967 if test x$ac_cv_func_mbstowcs = xyes; then
 968   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 969 [    AC_TRY_RUN([#include <stdlib.h>
 970 int main()
 971 {
 972   mbstowcs(0, "", 0);
 973   return 0;
 974 }],
 975     gcc_cv_func_mbstowcs_works=yes,
 976     gcc_cv_func_mbstowcs_works=no,
 977     gcc_cv_func_mbstowcs_works=yes)])
 978   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 979     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 980   [Define this macro if mbstowcs does not crash when its
 981    first argument is NULL.])
 982   fi
 983 fi
 984
 985 AC_CHECK_TYPE(ssize_t, int)
 986
 987 # Try to determine the array type of the second argument of getgroups
 988 # for the target system (int or gid_t).
 989 AC_TYPE_GETGROUPS
 990 if test "${target}" = "${build}"; then
 991   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 992 else
 993   case "${target}" in
 994         # This condition may need some tweaking.  It should include all
 995         # targets where the array type of the second argument of getgroups
 996         # is int and the type of gid_t is not equivalent to int.
 997         *-*-sunos* | *-*-ultrix*)
 998                 TARGET_GETGROUPS_T=int
 999                 ;;
1000         *)
1001                 TARGET_GETGROUPS_T=gid_t
1002                 ;;
1003   esac
1004 fi
1005 AC_SUBST(TARGET_GETGROUPS_T)
1006
1007 gcc_AC_FUNC_PRINTF_PTR
1008 gcc_AC_FUNC_MMAP_BLACKLIST
1009
1010 case "${host}" in
1011 *-*-*vms*)
1012   # Under VMS, vfork works very differently than on Unix. The standard test
1013   # won't work, and it isn't easily adaptable. It makes more sense to
1014   # just force it.
1015   ac_cv_func_vfork_works=yes
1016   ;;
1017 esac
1018 AC_FUNC_VFORK
1019
1020 AM_ICONV
1021 # Until we have in-tree GNU iconv:
1022 LIBICONV_DEP=
1023 AC_SUBST(LIBICONV_DEP)
1024
1025 AM_LC_MESSAGES
1026
1027 AM_LANGINFO_CODESET
1028
1029 # We will need to find libiberty.h and ansidecl.h
1030 saved_CFLAGS="$CFLAGS"
1031 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1032 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
1033         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
1034         fprintf_unlocked strstr errno snprintf vasprintf \
1035         malloc realloc calloc free basename getopt clock getpagesize, , ,[
1036 #include "ansidecl.h"
1037 #include "system.h"])
1038
1039 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1040 #include "ansidecl.h"
1041 #include "system.h"
1042 #ifdef HAVE_SYS_RESOURCE_H
1043 #include <sys/resource.h>
1044 #endif
1045 ])
1046
1047 AC_TRY_COMPILE([
1048 #include "ansidecl.h"
1049 #include "system.h"
1050 #ifdef HAVE_SYS_RESOURCE_H
1051 #include <sys/resource.h>
1052 #endif
1053 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1054 [Define to \`long' if <sys/resource.h> doesn't define.])])
1055
1056 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1057 #include "ansidecl.h"
1058 #include "system.h"
1059 #ifdef HAVE_LDFCN_H
1060 #include <ldfcn.h>
1061 #endif
1062 ])
1063
1064 gcc_AC_CHECK_DECLS(times, , ,[
1065 #include "ansidecl.h"
1066 #include "system.h"
1067 #ifdef HAVE_SYS_TIMES_H
1068 #include <sys/times.h>
1069 #endif
1070 ])
1071
1072 # More time-related stuff.
1073 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1074 AC_TRY_COMPILE([
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 #ifdef HAVE_SYS_TIMES_H
1078 #include <sys/times.h>
1079 #endif
1080 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1081 if test $ac_cv_struct_tms = yes; then
1082   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1083   [Define if <sys/times.h> defines struct tms.])
1084 fi
1085
1086 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1087 # revisit after autoconf 2.50.
1088 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1089 AC_TRY_COMPILE([
1090 #include "ansidecl.h"
1091 #include "system.h"
1092 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1093 if test $gcc_cv_type_clock_t = yes; then
1094   AC_DEFINE(HAVE_CLOCK_T, 1,
1095   [Define if <time.h> defines clock_t.])
1096 fi
1097
1098 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1099 CFLAGS="$saved_CFLAGS"
1100
1101 gcc_AC_INITFINI_ARRAY
1102
1103 # mkdir takes a single argument on some systems.
1104 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1105
1106 # File extensions
1107 manext='.1'
1108 objext='.o'
1109 AC_SUBST(manext)
1110 AC_SUBST(objext)
1111
1112 # With Setjmp/Longjmp based exception handling.
1113 AC_ARG_ENABLE(sjlj-exceptions,
1114 [  --enable-sjlj-exceptions
1115                           arrange to use setjmp/longjmp exception handling],
1116 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1117 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1118   [Define 0/1 to force the choice for exception handling model.])])
1119
1120 # For platforms with the unwind ABI which includes an unwind library,
1121 # libunwind, we can choose to use the system libunwind.
1122 AC_ARG_WITH(system-libunwind,
1123 [  --with-system-libunwind use installed libunwind])
1124
1125 # --------------------------------------------------------
1126 # Build, host, and target specific configuration fragments
1127 # --------------------------------------------------------
1128
1129 # Collect build-machine-specific information.
1130 . ${srcdir}/config.build
1131
1132 # Collect host-machine-specific information.
1133 . ${srcdir}/config.host
1134
1135 target_gtfiles=
1136
1137 # Collect target-machine-specific information.
1138 . ${srcdir}/config.gcc
1139
1140 extra_objs="${host_extra_objs} ${extra_objs}"
1141 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1142
1143 # Default the target-machine variables that were not explicitly set.
1144 if test x"$tm_file" = x
1145 then tm_file=$cpu_type/$cpu_type.h; fi
1146
1147 if test x"$extra_headers" = x
1148 then extra_headers=; fi
1149
1150 if test x$md_file = x
1151 then md_file=$cpu_type/$cpu_type.md; fi
1152
1153 if test x$out_file = x
1154 then out_file=$cpu_type/$cpu_type.c; fi
1155
1156 if test x"$tmake_file" = x
1157 then tmake_file=$cpu_type/t-$cpu_type
1158 fi
1159
1160 if test x"$dwarf2" = xyes
1161 then tm_file="$tm_file tm-dwarf2.h"
1162 fi
1163
1164 # Say what files are being used for the output code and MD file.
1165 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1166 echo "Using \`$srcdir/config/$md_file' as machine description file."
1167
1168 # If any of the xm_file variables contain nonexistent files, warn
1169 # about them and drop them.
1170
1171 bx=
1172 for x in $build_xm_file; do
1173   if    test -f $srcdir/config/$x
1174   then      bx="$bx $x"
1175   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1176   fi
1177 done
1178 build_xm_file="$bx"
1179
1180 hx=
1181 for x in $host_xm_file; do
1182   if    test -f $srcdir/config/$x
1183   then      hx="$hx $x"
1184   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1185   fi
1186 done
1187 host_xm_file="$hx"
1188
1189 tx=
1190 for x in $xm_file; do
1191   if    test -f $srcdir/config/$x
1192   then      tx="$tx $x"
1193   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1194   fi
1195 done
1196 xm_file="$tx"
1197
1198 count=a
1199 for f in $tm_file; do
1200         count=${count}x
1201 done
1202 if test $count = ax; then
1203         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1204 else
1205         echo "Using the following target machine macro files:"
1206         for f in $tm_file; do
1207                 echo "  $srcdir/config/$f"
1208         done
1209 fi
1210
1211 if test x$need_64bit_hwint = xyes; then
1212         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1213 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1214 fi
1215
1216 if test x$use_long_long_for_widest_fast_int = xyes; then
1217         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1218 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1219 efficiently supported by the host hardware.])
1220 fi
1221
1222 count=a
1223 for f in $host_xm_file; do
1224         count=${count}x
1225 done
1226 if test $count = a; then
1227         :
1228 elif test $count = ax; then
1229         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1230 else
1231         echo "Using the following host machine macro files:"
1232         for f in $host_xm_file; do
1233                 echo "  $srcdir/config/$f"
1234         done
1235 fi
1236 echo "Using ${out_host_hook_obj} for host machine hooks."
1237
1238 if test "$host_xm_file" != "$build_xm_file"; then
1239         count=a
1240         for f in $build_xm_file; do
1241                 count=${count}x
1242         done
1243         if test $count = a; then
1244                 :
1245         elif test $count = ax; then
1246                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1247         else
1248                 echo "Using the following build machine macro files:"
1249                 for f in $build_xm_file; do
1250                         echo "  $srcdir/config/$f"
1251                 done
1252         fi
1253 fi
1254
1255 # ---------
1256 # Threading
1257 # ---------
1258
1259 # Check if a valid thread package
1260 case ${enable_threads} in
1261   "" | no)
1262     # No threads
1263     target_thread_file='single'
1264     ;;
1265   yes)
1266     # default
1267     target_thread_file='single'
1268     ;;
1269   aix | dce | gnat | irix | posix | rtems | \
1270   single | solaris | vxworks | win32 )
1271     target_thread_file=${enable_threads}
1272     ;;
1273   *)
1274     echo "${enable_threads} is an unknown thread package" 1>&2
1275     exit 1
1276     ;;
1277 esac
1278
1279 if test x${thread_file} = x; then
1280   # No thread file set by target-specific clauses in config.gcc,
1281   # so use file chosen by default logic above
1282   thread_file=${target_thread_file}
1283 fi
1284
1285 # Make gthr-default.h if we have a thread file.
1286 gthread_flags=
1287 if test $thread_file != single; then
1288   rm -f gthr-default.h
1289   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1290   gthread_flags=-DHAVE_GTHR_DEFAULT
1291 fi
1292 AC_SUBST(gthread_flags)
1293
1294 # --------
1295 # UNSORTED
1296 # --------
1297
1298 use_cxa_atexit=no
1299 if test x$enable___cxa_atexit = xyes || \
1300    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1301   if test x$host = x$target; then
1302     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1303         [echo "__cxa_atexit can't be enabled on this target"])
1304   else
1305     # We can't check for __cxa_atexit when building a cross, so assume
1306     # it is available
1307     use_cxa_atexit=yes
1308   fi
1309   if test x$use_cxa_atexit = xyes; then
1310     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1311       [Define if you want to use __cxa_atexit, rather than atexit, to
1312       register C++ destructors for local statics and global objects.
1313       This is essential for fully standards-compliant handling of
1314       destructors, but requires __cxa_atexit in libc.])
1315   fi
1316 fi
1317
1318 # Look for a file containing extra machine modes.
1319 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1320   extra_modes_file='$(srcdir)'/config/${extra_modes}
1321   AC_SUBST(extra_modes_file)
1322   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1323   [Define to the name of a file containing a list of extra machine modes
1324    for this architecture.])
1325 fi
1326
1327 # auto-host.h is the file containing items generated by autoconf and is
1328 # the first file included by config.h.
1329 # If host=build, it is correct to have bconfig include auto-host.h
1330 # as well.  If host!=build, we are in error and need to do more
1331 # work to find out the build config parameters.
1332 if test x$host = x$build
1333 then
1334         build_auto=auto-host.h
1335 else
1336         # We create a subdir, then run autoconf in the subdir.
1337         # To prevent recursion we set host and build for the new
1338         # invocation of configure to the build for this invocation
1339         # of configure.
1340         tempdir=build.$$
1341         rm -rf $tempdir
1342         mkdir $tempdir
1343         cd $tempdir
1344         case ${srcdir} in
1345         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1346         *) realsrcdir=../${srcdir};;
1347         esac
1348         saved_CFLAGS="${CFLAGS}"
1349         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1350         ${realsrcdir}/configure \
1351                 --enable-languages=${enable_languages-all} \
1352                 --target=$target_alias --host=$build_alias --build=$build_alias
1353         CFLAGS="${saved_CFLAGS}"
1354
1355         # We just finished tests for the build machine, so rename
1356         # the file auto-build.h in the gcc directory.
1357         mv auto-host.h ../auto-build.h
1358         cd ..
1359         rm -rf $tempdir
1360         build_auto=auto-build.h
1361 fi
1362 AC_SUBST(build_subdir)
1363
1364 tm_file="${tm_file} defaults.h"
1365 tm_p_file="${tm_p_file} tm-preds.h"
1366 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1367 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1368 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1369 # put this back in temporarily.
1370 xm_file="ansidecl.h ${xm_file}"
1371
1372 # --------
1373 # UNSORTED
1374 # --------
1375
1376 # Get the version trigger filename from the toplevel
1377 if test "${with_gcc_version_trigger+set}" = set; then
1378         gcc_version_trigger=$with_gcc_version_trigger
1379 else
1380         gcc_version_trigger=${srcdir}/version.c
1381 fi
1382 changequote(,)dnl
1383 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1384 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1385
1386 # Compile in configure arguments.
1387 if test -f configargs.h ; then
1388         # Being re-configured.
1389         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1390         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1391 else
1392         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1393 fi
1394
1395 # Double all backslashes and backslash all quotes to turn
1396 # gcc_config_arguments into a C string.
1397 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1398 $gcc_config_arguments
1399 EOF
1400 gcc_config_arguments_str=`cat conftest.out`
1401 rm -f conftest.out
1402
1403 cat > configargs.h <<EOF
1404 /* Generated automatically. */
1405 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1406 static const char thread_model[] = "$thread_file";
1407
1408 static const struct {
1409   const char *name, *value;
1410 } configure_default_options[] = $configure_default_options;
1411 EOF
1412 changequote([,])dnl
1413
1414 # Internationalization
1415 PACKAGE=gcc
1416 VERSION="$gcc_version"
1417 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
1418   [The name of this program for internationalization purposes.])
1419 AC_SUBST(PACKAGE)
1420 AC_SUBST(VERSION)
1421
1422 ZW_GNU_GETTEXT_SISTER_DIR
1423
1424 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1425 # -liconv on the link line twice.
1426 case "$LIBINTL" in *$LIBICONV*)
1427         LIBICONV= ;;
1428 esac
1429
1430 # Windows32 Registry support for specifying GCC installation paths.
1431 AC_ARG_ENABLE(win32-registry,
1432 [  --disable-win32-registry
1433                           disable lookup of installation paths in the
1434                           Registry on Windows hosts
1435   --enable-win32-registry enable registry lookup (default)
1436   --enable-win32-registry=KEY
1437                           use KEY instead of GCC version as the last portion
1438                           of the registry key],,)
1439 case $host_os in
1440         win32 | pe | cygwin* | mingw32* | uwin*)
1441 AC_MSG_CHECKING(whether windows registry support is requested)
1442 if test "x$enable_win32_registry" != xno; then
1443   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1444 [Define to 1 if installation paths should be looked up in Windows32
1445    Registry. Ignored on non windows32 hosts.])
1446   AC_MSG_RESULT(yes)
1447   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1448 else
1449   AC_MSG_RESULT(no)
1450 fi
1451
1452 # Check if user specified a different registry key.
1453 case "x${enable_win32_registry}" in
1454 x | xyes)
1455   # default.
1456   gcc_cv_win32_registry_key="$VERSION"
1457   ;;
1458 xno)
1459   # no registry lookup.
1460   gcc_cv_win32_registry_key=''
1461   ;;
1462 *)
1463   # user-specified key.
1464   gcc_cv_win32_registry_key="$enable_win32_registry"
1465   ;;
1466 esac
1467
1468 if test "x$enable_win32_registry" != xno; then
1469   AC_MSG_CHECKING(registry key on windows hosts)
1470   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1471         [Define to be the last portion of registry key on windows hosts.])
1472   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1473 fi
1474 ;;
1475 esac
1476
1477 # Get an absolute path to the GCC top-level source directory
1478 holddir=`${PWDCMD-pwd}`
1479 cd $srcdir
1480 topdir=`${PWDCMD-pwd}`
1481 cd $holddir
1482
1483 # Conditionalize the makefile for this host machine.
1484 xmake_file=
1485 for f in ${host_xmake_file}
1486 do
1487         if test -f ${srcdir}/config/$f
1488         then
1489                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1490         fi
1491 done
1492
1493 # Conditionalize the makefile for this target machine.
1494 tmake_file_=
1495 for f in ${tmake_file}
1496 do
1497         if test -f ${srcdir}/config/$f
1498         then
1499                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1500         fi
1501 done
1502 tmake_file="${tmake_file_}"
1503
1504 # If the host doesn't support symlinks, modify CC in
1505 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1506 # Otherwise, we can use "CC=$(CC)".
1507 rm -f symtest.tem
1508 case "$LN_S" in
1509         *-s*)
1510                 cc_set_by_configure="\$(CC)"
1511                 quoted_cc_set_by_configure="\$(CC)"
1512                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1513                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1514                 ;;
1515         *)
1516                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1517                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1518                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1519                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1520                 ;;
1521 esac
1522
1523 out_object_file=`basename $out_file .c`.o
1524
1525 tm_file_list=
1526 tm_include_list=
1527 for f in $tm_file; do
1528   case $f in
1529     defaults.h )
1530        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1531        tm_include_list="${tm_include_list} $f"
1532        ;;
1533     * )
1534        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1535        tm_include_list="${tm_include_list} config/$f"
1536        ;;
1537   esac
1538 done
1539
1540 tm_p_file_list=
1541 tm_p_include_list=
1542 for f in $tm_p_file; do
1543   case $f in
1544     tm-preds.h )
1545        tm_p_file_list="${tm_p_file_list} $f"
1546        tm_p_include_list="${tm_p_include_list} $f"
1547        ;;
1548     * )
1549        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1550        tm_p_include_list="${tm_p_include_list} config/$f"
1551   esac
1552 done
1553
1554 xm_file_list=
1555 xm_include_list=
1556 for f in $xm_file; do
1557   case $f in
1558     ansidecl.h )
1559        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1560        xm_include_list="${xm_include_list} $f"
1561        ;;
1562     auto-host.h )
1563        xm_file_list="${xm_file_list} $f"
1564        xm_include_list="${xm_include_list} $f"
1565        ;;
1566     * )
1567        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1568        xm_include_list="${xm_include_list} config/$f"
1569        ;;
1570   esac
1571 done
1572
1573 host_xm_file_list=
1574 host_xm_include_list=
1575 for f in $host_xm_file; do
1576   case $f in
1577     ansidecl.h )
1578        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1579        host_xm_include_list="${host_xm_include_list} $f"
1580        ;;
1581     auto-host.h )
1582        host_xm_file_list="${host_xm_file_list} $f"
1583        host_xm_include_list="${host_xm_include_list} $f"
1584        ;;
1585     * )
1586        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1587        host_xm_include_list="${host_xm_include_list} config/$f"
1588        ;;
1589   esac
1590 done
1591
1592 build_xm_file_list=
1593 for f in $build_xm_file; do
1594   case $f in
1595     ansidecl.h )
1596        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1597        build_xm_include_list="${build_xm_include_list} $f"
1598        ;;
1599     auto-build.h | auto-host.h )
1600        build_xm_file_list="${build_xm_file_list} $f"
1601        build_xm_include_list="${build_xm_include_list} $f"
1602        ;;
1603     * )
1604        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1605        build_xm_include_list="${build_xm_include_list} config/$f"
1606        ;;
1607   esac
1608 done
1609
1610 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1611 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1612 CROSS=                                          AC_SUBST(CROSS)
1613 ALL=all.internal                                AC_SUBST(ALL)
1614 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1615 if test x$host != x$target
1616 then
1617         CROSS="-DCROSS_COMPILE"
1618         ALL=all.cross
1619         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1620         case "$host","$target" in
1621         # Darwin crosses can use the host system's libraries and headers,
1622         # because of the fat library support.  Of course, it must be the
1623         # same version of Darwin on both sides.  Allow the user to
1624         # just say --target=foo-darwin without a version number to mean
1625         # "the version on this system".
1626             *-*-darwin*,*-*-darwin*)
1627                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1628                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1629                 if test $hostos = $targetos -o $targetos = darwin ; then
1630                     CROSS=
1631                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1632                     with_headers=yes
1633                 fi
1634                 ;;
1635
1636             i?86-*-*,x86_64-*-* \
1637             | powerpc*-*-*,powerpc64*-*-*)
1638                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1639         esac
1640 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1641         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1642         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1643 fi
1644
1645 # If this is a cross-compiler that does not
1646 # have its own set of headers then define
1647 # inhibit_libc
1648
1649 # If this is using newlib, without having the headers available now,
1650 # then define inhibit_libc in LIBGCC2_CFLAGS.
1651 # This prevents libgcc2 from containing any code which requires libc
1652 # support.
1653 inhibit_libc=
1654 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1655        test x$with_newlib = xyes ; } &&
1656      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1657        inhibit_libc=-Dinhibit_libc
1658 fi
1659 AC_SUBST(inhibit_libc)
1660
1661 # When building gcc with a cross-compiler, we need to adjust things so
1662 # that the generator programs are still built with the native compiler.
1663 # Also, we cannot run fixincludes or fix-header.
1664
1665 # These are the normal (build=host) settings:
1666 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1667 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1668 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1669
1670 # Possibly disable fixproto, on a per-target basis.
1671 case ${use_fixproto} in
1672   no)
1673     STMP_FIXPROTO=
1674     ;;
1675   yes)
1676     STMP_FIXPROTO=stmp-fixproto
1677     ;;
1678 esac
1679 AC_SUBST(STMP_FIXPROTO)
1680
1681 # And these apply if build != host, or we are generating coverage data
1682 if test x$build != x$host || test "x$coverage_flags" != x
1683 then
1684     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1685
1686     if test "x$TARGET_SYSTEM_ROOT" = x; then
1687         STMP_FIXINC=stmp-install-fixinc
1688         if [ "x$STMP_FIXPROTO" != x ] ; then
1689           STMP_FIXPROTO=stmp-install-fixproto
1690         fi
1691     fi
1692 fi
1693
1694 # When bootstrapping from the toplevel, only run fixincludes during stage1
1695 if test -d ../prev-gcc
1696 then
1697     STMP_FIXINC=stmp-install-fixinc
1698     cp -R ../prev-gcc/include include
1699 fi
1700
1701 # Expand extra_headers to include complete path.
1702 # This substitutes for lots of t-* files.
1703 extra_headers_list=
1704 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1705 for file in ${extra_headers} ; do
1706   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1707 done
1708
1709 # Define collect2 in Makefile.
1710 case $host_can_use_collect2 in
1711   no) collect2= ;;
1712   *) collect2='collect2$(exeext)' ;;
1713 esac
1714 AC_SUBST([collect2])
1715
1716 # Add a definition of USE_COLLECT2 if system wants one.
1717 case $use_collect2 in
1718   no) use_collect2= ;;
1719   "") ;;
1720   *)
1721     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1722     xm_defines="${xm_defines} USE_COLLECT2"
1723     case $host_can_use_collect2 in
1724       no)
1725         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1726         ;;
1727     esac
1728     ;;
1729 esac
1730
1731 # ---------------------------
1732 # Assembler & linker features
1733 # ---------------------------
1734
1735 # Identify the assembler which will work hand-in-glove with the newly
1736 # built GCC, so that we can examine its features.  This is the assembler
1737 # which will be driven by the driver program.
1738 #
1739 # If build != host, and we aren't building gas in-tree, we identify a
1740 # build->target assembler and hope that it will have the same features
1741 # as the host->target assembler we'll be using.
1742 AC_MSG_CHECKING(what assembler to use)
1743 in_tree_gas=no
1744 gcc_cv_as=
1745 gcc_cv_gas_major_version=
1746 gcc_cv_gas_minor_version=
1747 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1748 if test -x "$DEFAULT_ASSEMBLER"; then
1749         gcc_cv_as="$DEFAULT_ASSEMBLER"
1750 elif test -x as$build_exeext; then
1751         # Build using assembler in the current directory.
1752         gcc_cv_as=./as$build_exeext
1753 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1754      && test -f ../gas/Makefile \
1755      && test x$build = x$host; then
1756   # Single tree build which includes gas.  We want to prefer it
1757   # over whatever linker top-level may have detected, since
1758   # we'll use what we're building after installation anyway.
1759   in_tree_gas=yes
1760   _gcc_COMPUTE_GAS_VERSION
1761   rm -f as$build_exeext
1762   $LN_S ../gas/as-new$build_exeext as$build_exeext 2>/dev/null
1763   in_tree_gas_is_elf=no
1764   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1765      || (grep 'obj_format = multi' ../gas/Makefile \
1766          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1767   then
1768     in_tree_gas_is_elf=yes
1769   fi
1770 m4_pattern_allow([AS_FOR_TARGET])dnl
1771 elif test -x "$AS_FOR_TARGET"; then
1772         gcc_cv_as="$AS_FOR_TARGET"
1773 elif test -x "$AS" && test x$host = x$target; then
1774         gcc_cv_as="$AS"
1775 fi
1776
1777 if test "x$gcc_cv_as" = x; then
1778         # Search the same directories that the installed compiler will
1779         # search.  Else we may find the wrong assembler and lose.  If we
1780         # do not find a suitable assembler binary, then try the user's
1781         # path.
1782         #
1783         # Also note we have to check MD_EXEC_PREFIX before checking the
1784         # user's path.  Unfortunately, there is no good way to get at the
1785         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1786         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1787         # to be fixed as part of the make/configure rewrite too.
1788
1789         if test "x$exec_prefix" = xNONE; then
1790                 if test "x$prefix" = xNONE; then
1791                         test_prefix=/usr/local
1792                 else
1793                         test_prefix=$prefix
1794                 fi
1795         else
1796                 test_prefix=$exec_prefix
1797         fi
1798
1799         # If the loop below does not find an assembler, then use whatever
1800         # one we can find in the users's path.
1801         # user's path.
1802         if test "x$program_prefix" != xNONE; then
1803                 gcc_cv_as=${program_prefix}as$build_exeext
1804         else
1805                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$build_exeext
1806         fi
1807
1808         if test x$host = x$build; then
1809             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1810                        $test_prefix/libexec/gcc/$target_noncanonical \
1811                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1812                        /usr/lib/gcc/$target_noncanonical \
1813                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1814                        $test_prefix/$target_noncanonical/bin"
1815         else
1816             test_dirs=
1817         fi
1818
1819         if test x$host = x$target; then
1820             test_dirs="$test_dirs \
1821                    /usr/libexec \
1822                    /usr/ccs/gcc \
1823                    /usr/ccs/bin \
1824                    /udk/usr/ccs/bin \
1825                    /bsd43/usr/lib/cmplrs/cc \
1826                    /usr/cross64/usr/bin \
1827                    /usr/lib/cmplrs/cc \
1828                    /sysv/usr/lib/cmplrs/cc \
1829                    /svr4/usr/lib/cmplrs/cc \
1830                    /usr/bin"
1831         fi
1832
1833         for dir in $test_dirs; do
1834                 if test -x $dir/as$build_exeext; then
1835                         gcc_cv_as=$dir/as$build_exeext
1836                         break;
1837                 fi
1838         done
1839 fi
1840 case $in_tree_gas in
1841   yes)
1842     AC_MSG_RESULT("newly built gas")
1843     ;;
1844   no)
1845     AC_MSG_RESULT($gcc_cv_as)
1846     ;;
1847 esac
1848
1849 # Identify the linker which will work hand-in-glove with the newly
1850 # built GCC, so that we can examine its features.  This is the linker
1851 # which will be driven by the driver program.
1852 #
1853 # If build != host, and we aren't building gas in-tree, we identify a
1854 # build->target linker and hope that it will have the same features
1855 # as the host->target linker we'll be using.
1856 AC_MSG_CHECKING(what linker to use)
1857 in_tree_ld=no
1858 gcc_cv_ld=
1859 gcc_cv_gld_major_version=
1860 gcc_cv_gld_minor_version=
1861 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1862 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1863 if test -x "$DEFAULT_LINKER"; then
1864         gcc_cv_ld="$DEFAULT_LINKER"
1865 elif test -x collect-ld$build_exeext; then
1866         # Build using linker in the current directory.
1867         gcc_cv_ld=./collect-ld$build_exeext
1868 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1869      && test -f ../ld/Makefile \
1870      && test x$build = x$host; then
1871         # Single tree build which includes ld.  We want to prefer it
1872         # over whatever linker top-level may have detected, since
1873         # we'll use what we're building after installation anyway.
1874         in_tree_ld=yes
1875         in_tree_ld_is_elf=no
1876         if (grep 'EMUL = .*elf' ../ld/Makefile \
1877             || grep 'EMUL = .*linux' ../ld/Makefile \
1878             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1879           in_tree_ld_is_elf=yes
1880         fi
1881         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1882         do
1883 changequote(,)dnl
1884                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1885 changequote([,])dnl
1886                 if test x$gcc_cv_gld_version != x; then
1887                         break
1888                 fi
1889         done
1890 changequote(,)dnl
1891         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1892         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1893 changequote([,])dnl
1894         rm -f collect-ld$build_exeext
1895         $LN_S ../ld/ld-new$build_exeext collect-ld$build_exeext 2>/dev/null
1896 elif test -x "$LD_FOR_TARGET"; then
1897         gcc_cv_ld="$LD_FOR_TARGET"
1898 elif test -x "$LD" && test x$host = x$target; then
1899         gcc_cv_ld="$LD"
1900 fi
1901
1902 if test "x$gcc_cv_ld" = x; then
1903         # Search the same directories that the installed compiler will
1904         # search.  Else we may find the wrong linker and lose.  If we
1905         # do not find a suitable linker binary, then try the user's
1906         # path.
1907         #
1908         # Also note we have to check MD_EXEC_PREFIX before checking the
1909         # user's path.  Unfortunately, there is no good way to get at the
1910         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1911         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1912         # to be fixed as part of the make/configure rewrite too.
1913
1914         if test "x$exec_prefix" = xNONE; then
1915                 if test "x$prefix" = xNONE; then
1916                         test_prefix=/usr/local
1917                 else
1918                         test_prefix=$prefix
1919                 fi
1920         else
1921                 test_prefix=$exec_prefix
1922         fi
1923
1924         # If the loop below does not find an linker, then use whatever
1925         # one we can find in the users's path.
1926         # user's path.
1927         if test "x$program_prefix" != xNONE; then
1928                 gcc_cv_ld=${program_prefix}ld$build_exeext
1929         else
1930                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$build_exeext
1931         fi
1932
1933         if test x$host = x$build; then
1934             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1935                        $test_prefix/libexec/gcc/$target_noncanonical \
1936                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1937                        /usr/lib/gcc/$target_noncanonical \
1938                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1939                        $test_prefix/$target_noncanonical/bin"
1940         else
1941             test_dirs=
1942         fi
1943
1944         if test x$host = x$target; then
1945             test_dirs="$test_dirs \
1946                    /usr/libexec \
1947                    /usr/ccs/gcc \
1948                    /usr/ccs/bin \
1949                    /udk/usr/ccs/bin \
1950                    /bsd43/usr/lib/cmplrs/cc \
1951                    /usr/cross64/usr/bin \
1952                    /usr/lib/cmplrs/cc \
1953                    /sysv/usr/lib/cmplrs/cc \
1954                    /svr4/usr/lib/cmplrs/cc \
1955                    /usr/bin"
1956         fi
1957
1958         for dir in $test_dirs; do
1959                 if test -x $dir/ld$build_exeext; then
1960                         gcc_cv_ld=$dir/ld$build_exeext
1961                         break;
1962                 fi
1963         done
1964 fi
1965 case $in_tree_ld in
1966   yes)
1967     AC_MSG_RESULT("newly built ld")
1968     ;;
1969   no)
1970     AC_MSG_RESULT($gcc_cv_ld)
1971     ;;
1972 esac
1973
1974 # Figure out what nm we will be using.
1975 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1976 AC_MSG_CHECKING(what nm to use)
1977 in_tree_nm=no
1978 if test -x nm$build_exeext; then
1979         gcc_cv_nm=./nm$build_exeext
1980 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1981      && test -f ../binutils/Makefile; then
1982         # Single tree build which includes binutils.
1983         in_tree_nm=yes
1984         gcc_cv_nm=./nm$build_exeext
1985         rm -f nm$build_exeext
1986         $LN_S ../binutils/nm-new$build_exeext nm$build_exeext 2>/dev/null
1987 elif test "x$program_prefix" != xNONE; then
1988         gcc_cv_nm=${program_prefix}nm$build_exeext
1989 else
1990         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$build_exeext
1991 fi
1992 case $in_tree_nm in
1993   yes) AC_MSG_RESULT("newly built nm") ;;
1994   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1995 esac
1996
1997 # Figure out what objdump we will be using.
1998 AC_MSG_CHECKING(what objdump to use)
1999 in_tree_objdump=no
2000 if test -x objdump$build_exeext; then
2001         gcc_cv_objdump=./objdump$build_exeext
2002 elif test -f $gcc_cv_binutils_srcdir/configure.in \
2003      && test -f ../binutils/Makefile; then
2004         # Single tree build which includes binutils.
2005         in_tree_objdump=yes
2006         gcc_cv_objdump=./objdump$build_exeext
2007         rm -f objdump$build_exeext
2008         $LN_S ../binutils/objdump$build_exeext objdump$build_exeext 2>/dev/null
2009 elif test "x$program_prefix" != xNONE; then
2010         gcc_cv_objdump=${program_prefix}objdump$build_exeext
2011 else
2012         gcc_cv_objdump=`echo objdump | \
2013                 sed "${program_transform_name}"`$build_exeext
2014 fi
2015 case $in_tree_objdump in
2016   yes) AC_MSG_RESULT("newly built objdump") ;;
2017   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2018 esac
2019
2020 # Figure out what assembler alignment features are present.
2021 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2022  [2,6,0],,
2023 [.balign 4
2024 .p2align 2],,
2025 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2026   [Define if your assembler supports .balign and .p2align.])])
2027
2028 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2029  [2,8,0],,
2030  [.p2align 4,,7],,
2031 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2032   [Define if your assembler supports specifying the maximum number
2033    of bytes to skip when using the GAS .p2align command.])])
2034
2035 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2036  [elf,2,9,0],,
2037  [conftest_label1: .word 0
2038 .subsection -1
2039 conftest_label2: .word 0
2040 .previous],
2041  [if test x$gcc_cv_nm != x; then
2042     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2043     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2044     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2045     then :
2046     else gcc_cv_as_subsection_m1=yes
2047     fi
2048     rm -f conftest.nm1 conftest.nm2
2049   fi],
2050  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2051   [Define if your assembler supports .subsection and .subsection -1 starts
2052    emitting at the beginning of your section.])])
2053
2054 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2055  [2,2,0],,
2056  [      .weak foobar],,
2057 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2058
2059 # .hidden needs to be supported in both the assembler and the linker,
2060 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2061 # This is irritatingly difficult to feature test for; we have to check the
2062 # date string after the version number.  If we've got an in-tree
2063 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2064 # to be safe.
2065 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2066 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2067  [elf,2,13,0],,
2068 [       .hidden foobar
2069 foobar:])
2070
2071 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2072 [if test $in_tree_ld = yes ; then
2073   gcc_cv_ld_hidden=no
2074   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2075      && test $in_tree_ld_is_elf = yes; then
2076      gcc_cv_ld_hidden=yes
2077   fi
2078 else
2079   gcc_cv_ld_hidden=yes
2080   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2081   if echo "$ld_ver" | grep GNU > /dev/null; then
2082 changequote(,)dnl
2083     ld_vers=`echo $ld_ver | sed -n \
2084         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2085         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2086         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2087         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2088         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2089         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2090     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2091     if test 0"$ld_date" -lt 20020404; then
2092       if test -n "$ld_date"; then
2093         # If there was date string, but was earlier than 2002-04-04, fail
2094         gcc_cv_ld_hidden=no
2095       elif test -z "$ld_vers"; then
2096         # If there was no date string nor ld version number, something is wrong
2097         gcc_cv_ld_hidden=no
2098       else
2099         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2100         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2101         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2102         test -z "$ld_vers_patch" && ld_vers_patch=0
2103         if test "$ld_vers_major" -lt 2; then
2104           gcc_cv_ld_hidden=no
2105         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2106           gcc_cv_ld_hidden="no"
2107         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2108           gcc_cv_ld_hidden=no
2109         fi
2110       fi
2111 changequote([,])dnl
2112     fi
2113   else
2114     case "${target}" in
2115       hppa64*-*-hpux* | ia64*-*-hpux*)
2116         gcc_cv_ld_hidden=yes
2117         ;;
2118       *)
2119         gcc_cv_ld_hidden=no
2120         ;;
2121     esac
2122   fi
2123 fi])
2124 libgcc_visibility=no
2125 AC_SUBST(libgcc_visibility)
2126 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2127   libgcc_visibility=yes
2128   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2129   [Define if your assembler and linker support .hidden.])
2130 fi
2131
2132 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2133 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2134   [elf,2,11,0],,
2135 [       .data
2136         .uleb128 L2 - L1
2137 L1:
2138         .uleb128 1280
2139         .sleb128 -1010
2140 L2:],
2141  [# GAS versions before 2.11 do not support uleb128,
2142   # despite appearing to.
2143   # ??? There exists an elf-specific test that will crash
2144   # the assembler.  Perhaps it's better to figure out whether
2145   # arbitrary sections are supported and try the test.
2146   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2147   if echo "$as_ver" | grep GNU > /dev/null; then
2148 changequote(,)dnl
2149     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2150     as_major=`echo $as_ver | sed 's/\..*//'`
2151     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2152 changequote([,])dnl
2153     if test $as_major -eq 2 && test $as_minor -lt 11
2154     then :
2155     else gcc_cv_as_leb128=yes
2156     fi
2157   fi],
2158   [AC_DEFINE(HAVE_AS_LEB128, 1,
2159     [Define if your assembler supports .sleb128 and .uleb128.])])
2160
2161 # GAS versions up to and including 2.11.0 may mis-optimize
2162 # .eh_frame data.
2163 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2164   [elf,2,12,0],,
2165 [       .text
2166 .LFB1:
2167         .4byte  0
2168 .L1:
2169         .4byte  0
2170 .LFE1:
2171         .section        .eh_frame,"aw",@progbits
2172 __FRAME_BEGIN__:
2173         .4byte  .LECIE1-.LSCIE1
2174 .LSCIE1:
2175         .4byte  0x0
2176         .byte   0x1
2177         .ascii "z\0"
2178         .byte   0x1
2179         .byte   0x78
2180         .byte   0x1a
2181         .byte   0x0
2182         .byte   0x4
2183         .4byte  1
2184         .p2align 1
2185 .LECIE1:
2186 .LSFDE1:
2187         .4byte  .LEFDE1-.LASFDE1
2188 .LASFDE1:
2189         .4byte  .LASFDE1-__FRAME_BEGIN__
2190         .4byte  .LFB1
2191         .4byte  .LFE1-.LFB1
2192         .byte   0x4
2193         .4byte  .LFE1-.LFB1
2194         .byte   0x4
2195         .4byte  .L1-.LFB1
2196 .LEFDE1:],
2197 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2198 cat > conftest.lit <<EOF
2199  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2200  0010 01000000 12000000 18000000 00000000  ................
2201  0020 08000000 04080000 0044               .........D      @&t@
2202 EOF
2203 cat > conftest.big <<EOF
2204  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2205  0010 00000001 00000012 00000018 00000000  ................
2206  0020 00000008 04000000 0844               .........D      @&t@
2207 EOF
2208   # If the assembler didn't choke, and we can objdump,
2209   # and we got the correct data, then succeed.
2210   if test x$gcc_cv_objdump != x \
2211   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2212      | tail -3 > conftest.got \
2213   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2214     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2215   then
2216     gcc_cv_as_eh_frame=yes
2217   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2218     gcc_cv_as_eh_frame=buggy
2219   else
2220     # Uh oh, what do we do now?
2221     gcc_cv_as_eh_frame=no
2222   fi])
2223
2224 if test $gcc_cv_as_eh_frame = buggy; then
2225   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2226   [Define if your assembler mis-optimizes .eh_frame data.])
2227 fi
2228
2229 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2230  [elf,2,12,0], [--fatal-warnings],
2231  [.section .rodata.str, "aMS", @progbits, 1])
2232 if test $gcc_cv_as_shf_merge = no; then
2233   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2234     [elf,2,12,0], [--fatal-warnings],
2235     [.section .rodata.str, "aMS", %progbits, 1])
2236 fi
2237 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2238   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2239 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2240
2241 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2242  [elf,2,15,91], [--fatal-warnings],
2243  [.section .text,"axG",@progbits,.foo,comdat])
2244 if test $gcc_cv_as_comdat_group = yes; then
2245   gcc_cv_as_comdat_group_percent=no
2246 else
2247  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2248    [elf,2,15,91], [--fatal-warnings],
2249    [.section .text,"axG",%progbits,.foo,comdat])
2250 fi
2251 AC_DEFINE_UNQUOTED(HAVE_GAS_COMDAT_GROUP,
2252   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2253 [Define 0/1 if your assembler supports COMDAT group.])
2254
2255 # Thread-local storage - the check is heavily parametrized.
2256 conftest_s=
2257 tls_first_major=
2258 tls_first_minor=
2259 tls_as_opt=
2260 case "$target" in
2261 changequote(,)dnl
2262   alpha*-*-*)
2263     conftest_s='
2264         .section ".tdata","awT",@progbits
2265 foo:    .long   25
2266         .text
2267         ldq     $27,__tls_get_addr($29)         !literal!1
2268         lda     $16,foo($29)                    !tlsgd!1
2269         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2270         ldq     $27,__tls_get_addr($29)         !literal!2
2271         lda     $16,foo($29)                    !tlsldm!2
2272         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2273         ldq     $1,foo($29)                     !gotdtprel
2274         ldah    $2,foo($29)                     !dtprelhi
2275         lda     $3,foo($2)                      !dtprello
2276         lda     $4,foo($29)                     !dtprel
2277         ldq     $1,foo($29)                     !gottprel
2278         ldah    $2,foo($29)                     !tprelhi
2279         lda     $3,foo($2)                      !tprello
2280         lda     $4,foo($29)                     !tprel'
2281         tls_first_major=2
2282         tls_first_minor=13
2283         tls_as_opt=--fatal-warnings
2284         ;;
2285   i[34567]86-*-*)
2286     conftest_s='
2287         .section ".tdata","awT",@progbits
2288 foo:    .long   25
2289         .text
2290         movl    %gs:0, %eax
2291         leal    foo@TLSGD(,%ebx,1), %eax
2292         leal    foo@TLSLDM(%ebx), %eax
2293         leal    foo@DTPOFF(%eax), %edx
2294         movl    foo@GOTTPOFF(%ebx), %eax
2295         subl    foo@GOTTPOFF(%ebx), %eax
2296         addl    foo@GOTNTPOFF(%ebx), %eax
2297         movl    foo@INDNTPOFF, %eax
2298         movl    $foo@TPOFF, %eax
2299         subl    $foo@TPOFF, %eax
2300         leal    foo@NTPOFF(%ecx), %eax'
2301         tls_first_major=2
2302         tls_first_minor=14
2303         tls_as_opt=--fatal-warnings
2304         ;;
2305   x86_64-*-*)
2306     conftest_s='
2307         .section ".tdata","awT",@progbits
2308 foo:    .long   25
2309         .text
2310         movq    %fs:0, %rax
2311         leaq    foo@TLSGD(%rip), %rdi
2312         leaq    foo@TLSLD(%rip), %rdi
2313         leaq    foo@DTPOFF(%rax), %rdx
2314         movq    foo@GOTTPOFF(%rip), %rax
2315         movq    $foo@TPOFF, %rax'
2316         tls_first_major=2
2317         tls_first_minor=14
2318         tls_as_opt=--fatal-warnings
2319         ;;
2320   ia64-*-*)
2321     conftest_s='
2322         .section ".tdata","awT",@progbits
2323 foo:    data8   25
2324         .text
2325         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2326         addl    r17 = @ltoff(@dtprel(foo#)), gp
2327         addl    r18 = @ltoff(@tprel(foo#)), gp
2328         addl    r19 = @dtprel(foo#), gp
2329         adds    r21 = @dtprel(foo#), r13
2330         movl    r23 = @dtprel(foo#)
2331         addl    r20 = @tprel(foo#), gp
2332         adds    r22 = @tprel(foo#), r13
2333         movl    r24 = @tprel(foo#)'
2334         tls_first_major=2
2335         tls_first_minor=13
2336         tls_as_opt=--fatal-warnings
2337         ;;
2338   powerpc-*-*)
2339     conftest_s='
2340         .section ".tdata","awT",@progbits
2341         .align 2
2342 ld0:    .space 4
2343 ld1:    .space 4
2344 x1:     .space 4
2345 x2:     .space 4
2346 x3:     .space 4
2347         .text
2348         addi 3,31,ld0@got@tlsgd
2349         bl __tls_get_addr
2350         addi 3,31,x1@got@tlsld
2351         bl __tls_get_addr
2352         addi 9,3,x1@dtprel
2353         addis 9,3,x2@dtprel@ha
2354         addi 9,9,x2@dtprel@l
2355         lwz 9,x3@got@tprel(31)
2356         add 9,9,x@tls
2357         addi 9,2,x1@tprel
2358         addis 9,2,x2@tprel@ha
2359         addi 9,9,x2@tprel@l'
2360         tls_first_major=2
2361         tls_first_minor=14
2362         tls_as_opt="-a32 --fatal-warnings"
2363         ;;
2364   powerpc64-*-*)
2365     conftest_s='
2366         .section ".tdata","awT",@progbits
2367         .align 3
2368 ld0:    .space 8
2369 ld1:    .space 8
2370 x1:     .space 8
2371 x2:     .space 8
2372 x3:     .space 8
2373         .text
2374         addi 3,2,ld0@got@tlsgd
2375         bl .__tls_get_addr
2376         nop
2377         addi 3,2,ld1@toc
2378         bl .__tls_get_addr
2379         nop
2380         addi 3,2,x1@got@tlsld
2381         bl .__tls_get_addr
2382         nop
2383         addi 9,3,x1@dtprel
2384         bl .__tls_get_addr
2385         nop
2386         addis 9,3,x2@dtprel@ha
2387         addi 9,9,x2@dtprel@l
2388         bl .__tls_get_addr
2389         nop
2390         ld 9,x3@got@dtprel(2)
2391         add 9,9,3
2392         bl .__tls_get_addr
2393         nop'
2394         tls_first_major=2
2395         tls_first_minor=14
2396         tls_as_opt="-a64 --fatal-warnings"
2397         ;;
2398   s390-*-*)
2399     conftest_s='
2400         .section ".tdata","awT",@progbits
2401 foo:    .long   25
2402         .text
2403         .long   foo@TLSGD
2404         .long   foo@TLSLDM
2405         .long   foo@DTPOFF
2406         .long   foo@NTPOFF
2407         .long   foo@GOTNTPOFF
2408         .long   foo@INDNTPOFF
2409         l       %r1,foo@GOTNTPOFF(%r12)
2410         l       %r1,0(%r1):tls_load:foo
2411         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2412         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2413         tls_first_major=2
2414         tls_first_minor=14
2415         tls_as_opt="-m31 --fatal-warnings"
2416         ;;
2417   s390x-*-*)
2418     conftest_s='
2419         .section ".tdata","awT",@progbits
2420 foo:    .long   25
2421         .text
2422         .quad   foo@TLSGD
2423         .quad   foo@TLSLDM
2424         .quad   foo@DTPOFF
2425         .quad   foo@NTPOFF
2426         .quad   foo@GOTNTPOFF
2427         lg      %r1,foo@GOTNTPOFF(%r12)
2428         larl    %r1,foo@INDNTPOFF
2429         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2430         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2431         tls_first_major=2
2432         tls_first_minor=14
2433         tls_as_opt="-m64 -Aesame --fatal-warnings"
2434         ;;
2435   sh-*-* | sh[34]-*-*)
2436     conftest_s='
2437         .section ".tdata","awT",@progbits
2438 foo:    .long   25
2439         .text
2440         .long   foo@TLSGD
2441         .long   foo@TLSLDM
2442         .long   foo@DTPOFF
2443         .long   foo@GOTTPOFF
2444         .long   foo@TPOFF'
2445         tls_first_major=2
2446         tls_first_minor=13
2447         tls_as_opt=--fatal-warnings
2448         ;;
2449   sparc*-*-*)
2450     case "$target" in
2451       sparc*-sun-solaris2.*)
2452         on_solaris=yes
2453         ;;
2454       *)
2455         on_solaris=no
2456         ;;
2457     esac
2458     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2459       conftest_s='
2460         .section ".tdata",#alloc,#write,#tls
2461 foo:    .long   25
2462         .text
2463         sethi   %tgd_hi22(foo), %o0
2464         add     %o0, %tgd_lo10(foo), %o1
2465         add     %l7, %o1, %o0, %tgd_add(foo)
2466         call    __tls_get_addr, %tgd_call(foo)
2467         sethi   %tldm_hi22(foo), %l1
2468         add     %l1, %tldm_lo10(foo), %l2
2469         add     %l7, %l2, %o0, %tldm_add(foo)
2470         call    __tls_get_addr, %tldm_call(foo)
2471         sethi   %tldo_hix22(foo), %l3
2472         xor     %l3, %tldo_lox10(foo), %l4
2473         add     %o0, %l4, %l5, %tldo_add(foo)
2474         sethi   %tie_hi22(foo), %o3
2475         add     %o3, %tie_lo10(foo), %o3
2476         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2477         add     %g7, %o2, %o4, %tie_add(foo)
2478         sethi   %tle_hix22(foo), %l1
2479         xor     %l1, %tle_lox10(foo), %o5
2480         ld      [%g7 + %o5], %o1'
2481         tls_first_major=0
2482         tls_first_minor=0
2483     else
2484       conftest_s='
2485         .section ".tdata","awT",@progbits
2486 foo:    .long   25
2487         .text
2488         sethi   %tgd_hi22(foo), %o0
2489         add     %o0, %tgd_lo10(foo), %o1
2490         add     %l7, %o1, %o0, %tgd_add(foo)
2491         call    __tls_get_addr, %tgd_call(foo)
2492         sethi   %tldm_hi22(foo), %l1
2493         add     %l1, %tldm_lo10(foo), %l2
2494         add     %l7, %l2, %o0, %tldm_add(foo)
2495         call    __tls_get_addr, %tldm_call(foo)
2496         sethi   %tldo_hix22(foo), %l3
2497         xor     %l3, %tldo_lox10(foo), %l4
2498         add     %o0, %l4, %l5, %tldo_add(foo)
2499         sethi   %tie_hi22(foo), %o3
2500         add     %o3, %tie_lo10(foo), %o3
2501         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2502         add     %g7, %o2, %o4, %tie_add(foo)
2503         sethi   %tle_hix22(foo), %l1
2504         xor     %l1, %tle_lox10(foo), %o5
2505         ld      [%g7 + %o5], %o1'
2506         tls_first_major=2
2507         tls_first_minor=14
2508         tls_as_opt="-32 --fatal-warnings"
2509       fi
2510         ;;
2511 changequote([,])dnl
2512 esac
2513 if test -z "$tls_first_major"; then
2514   : # If we don't have a check, assume no support.
2515 else
2516   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2517   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2518   [AC_DEFINE(HAVE_AS_TLS, 1,
2519             [Define if your assembler supports thread-local storage.])])
2520 fi
2521
2522 # Target-specific assembler checks.
2523
2524 if test x"$demangler_in_ld" = xyes; then
2525   AC_MSG_CHECKING(linker --demangle support)
2526   gcc_cv_ld_demangle=no
2527   if test $in_tree_ld = yes; then
2528     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2529       gcc_cv_ld_demangle=yes
2530     fi
2531   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2532     # Check if the GNU linker supports --demangle option
2533     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2534       gcc_cv_ld_demangle=yes
2535     fi
2536   fi
2537   if test x"$gcc_cv_ld_demangle" = xyes; then
2538     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2539 [Define if your linker supports --demangle option.])
2540   fi
2541   AC_MSG_RESULT($gcc_cv_ld_demangle)
2542 fi
2543
2544 case "$target" in
2545   # All TARGET_ABI_OSF targets.
2546   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2547     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2548         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2549 [       .set nomacro
2550         .text
2551         extbl   $3, $2, $3      !lituse_bytoff!1
2552         ldq     $2, a($29)      !literal!1
2553         ldq     $4, b($29)      !literal!2
2554         ldq_u   $3, 0($2)       !lituse_base!1
2555         ldq     $27, f($29)     !literal!5
2556         jsr     $26, ($27), f   !lituse_jsr!5
2557         ldah    $29, 0($26)     !gpdisp!3
2558         lda     $0, c($29)      !gprel
2559         ldah    $1, d($29)      !gprelhigh
2560         lda     $1, d($1)       !gprellow
2561         lda     $29, 0($29)     !gpdisp!3],,
2562     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2563   [Define if your assembler supports explicit relocations.])])
2564     ;;
2565
2566   cris-*-*)
2567     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2568       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2569       [-no-mul-bug-abort], [.text],,
2570       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2571                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2572     ;;
2573
2574   sparc*-*-*)
2575     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2576       [.register %g2, #scratch],,
2577       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2578                 [Define if your assembler supports .register.])])
2579
2580     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2581       [-relax], [.text],,
2582       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2583                 [Define if your assembler supports -relax option.])])
2584
2585     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2586       gcc_cv_as_sparc_ua_pcrel,,
2587       [-K PIC],
2588 [.text
2589 foo:
2590         nop
2591 .data
2592 .align 4
2593 .byte 0
2594 .uaword %r_disp32(foo)],
2595       [if test x$gcc_cv_ld != x \
2596        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2597          gcc_cv_as_sparc_ua_pcrel=yes
2598        fi
2599        rm -f conftest],
2600       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2601                 [Define if your assembler and linker support unaligned PC relative relocs.])
2602
2603       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2604         gcc_cv_as_sparc_ua_pcrel_hidden,,
2605         [-K PIC],
2606 [.data
2607 .align 4
2608 .byte 0x31
2609 .uaword %r_disp32(foo)
2610 .byte 0x32, 0x33, 0x34
2611 .global foo
2612 .hidden foo
2613 foo:
2614 .skip 4],
2615         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2616          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2617          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2618             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2619             if $gcc_cv_objdump -R conftest 2> /dev/null \
2620                | grep 'DISP32' > /dev/null 2>&1; then
2621                 :
2622             else
2623                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2624             fi
2625          fi
2626          rm -f conftest],
2627          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2628                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2629     ]) # unaligned pcrel relocs
2630
2631     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2632       gcc_cv_as_sparc_offsetable_lo10,,
2633       [-xarch=v9],
2634 [.text
2635         or %g1, %lo(ab) + 12, %g1
2636         or %g1, %lo(ab + 12), %g1],
2637       [if test x$gcc_cv_objdump != x \
2638        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2639           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2640          gcc_cv_as_offsetable_lo10=yes
2641        fi],
2642        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2643                  [Define if your assembler supports offsetable %lo().])])
2644     ;;
2645
2646 changequote(,)dnl
2647   i[34567]86-*-* | x86_64-*-*)
2648 changequote([,])dnl
2649     case $target_os in
2650       cygwin* | pe | mingw32*)
2651         # Used for DWARF 2 in PE
2652         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2653           gcc_cv_as_ix86_pe_secrel32,
2654           [2,15,91],,
2655 [.text
2656 foo:    nop
2657 .data
2658         .secrel32 foo],
2659           [if test x$gcc_cv_ld != x \
2660            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2661              gcc_cv_as_ix86_pe_secrel32=yes
2662            fi
2663            rm -f conftest],
2664           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2665             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2666         ;;
2667     esac
2668
2669     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2670        gcc_cv_as_ix86_filds_fists,
2671       [2,9,0],, [filds mem; fists mem],,
2672       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2673         [Define if your assembler uses the new HImode fild and fist notation.])])
2674
2675     gcc_GAS_CHECK_FEATURE([cmov syntax],
2676       gcc_cv_as_ix86_cmov_sun_syntax,,,
2677       [cmovl.l %edx, %eax],,
2678       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2679         [Define if your assembler supports the Sun syntax for cmov.])])
2680
2681     # This one is used unconditionally by i386.[ch]; it is to be defined
2682     # to 1 if the feature is present, 0 otherwise.
2683     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2684         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2685 [       .text
2686 .L0:
2687         nop
2688         .data
2689         .long .L0@GOTOFF])
2690     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2691       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2692       [Define true if the assembler supports '.long foo@GOTOFF'.])
2693     ;;
2694
2695   ia64*-*-*)
2696     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2697         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2698 [       .text
2699         addl r15 = @ltoffx(x#), gp
2700         ;;
2701         ld8.mov r16 = [[r15]], x#],,
2702     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2703           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2704
2705     ;;
2706
2707   powerpc*-*-*)
2708     case $target in
2709       *-*-aix*) conftest_s='    .csect .text[[PR]]
2710         mfcr 3,128';;
2711       *-*-darwin*) conftest_s=' .text
2712         mfcr r3,128';;
2713       *) conftest_s='   .machine power4
2714         .text
2715         mfcr 3,128';;
2716     esac
2717
2718     gcc_GAS_CHECK_FEATURE([mfcr field support],
2719       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2720       [$conftest_s],,
2721       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2722           [Define if your assembler supports mfcr field.])])
2723     ;;
2724
2725   mips*-*-*)
2726     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2727       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2728 [       lw $4,%gp_rel(foo)($4)],,
2729       [if test x$target_cpu_default = x
2730        then target_cpu_default=MASK_EXPLICIT_RELOCS
2731        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2732        fi])
2733
2734     if test x$gas_flag = xyes \
2735        || test x"$host" != x"$build" \
2736        || test ! -x "$gcc_cv_as" \
2737        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2738       :
2739     else
2740       echo "*** This configuration requires the GNU assembler" >&2
2741       exit 1
2742     fi
2743     ;;
2744 esac
2745 # ??? Not all targets support dwarf2 debug_line, even within a version
2746 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2747 # info to the output file.  So, as supported targets are added to gas 2.11,
2748 # add some instruction here to (also) show we expect this might work.
2749 # ??? Once 2.11 is released, probably need to add first known working
2750 # version to the per-target configury.
2751 case "$target" in
2752   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2753   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2754   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2755     insn="nop"
2756     ;;
2757   ia64*-*-* | s390*-*-*)
2758     insn="nop 0"
2759     ;;
2760   mmix-*-*)
2761     insn="swym 0"
2762     ;;
2763 esac
2764 if test x"$insn" != x; then
2765  conftest_s="\
2766         .file 1 \"conftest.s\"
2767         .loc 1 3 0
2768         $insn"
2769  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2770   gcc_cv_as_dwarf2_debug_line,
2771   [elf,2,11,0],, [$conftest_s],
2772   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2773    if grep debug_line conftest.o > /dev/null 2>&1; then
2774      gcc_cv_as_dwarf2_debug_line=yes
2775    fi])
2776
2777 # The .debug_line file table must be in the exact order that
2778 # we specified the files, since these indices are also used
2779 # by DW_AT_decl_file.  Approximate this test by testing if
2780 # the assembler bitches if the same index is assigned twice.
2781  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2782   gcc_cv_as_dwarf2_file_buggy,,,
2783 [       .file 1 "foo.s"
2784         .file 1 "bar.s"])
2785
2786  if test $gcc_cv_as_dwarf2_debug_line = yes \
2787  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2788         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2789   [Define if your assembler supports dwarf2 .file/.loc directives,
2790    and preserves file table indices exactly as given.])
2791  fi
2792
2793  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2794   gcc_cv_as_gdwarf2_flag,
2795   [elf,2,11,0], [--gdwarf2], [$insn],,
2796   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2797 [Define if your assembler supports the --gdwarf2 option.])])
2798
2799  gcc_GAS_CHECK_FEATURE([--gstabs option],
2800   gcc_cv_as_gstabs_flag,
2801   [elf,2,11,0], [--gstabs], [$insn],
2802   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2803    # and warns about it, but still exits successfully.  So check for
2804    # this.
2805    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2806    then :
2807    else gcc_cv_as_gstabs_flag=yes
2808    fi],
2809   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2810 [Define if your assembler supports the --gstabs option.])])
2811 fi
2812
2813 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2814 gcc_cv_ld_ro_rw_mix=unknown
2815 if test $in_tree_ld = yes ; then
2816   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2817      && test $in_tree_ld_is_elf = yes; then
2818     gcc_cv_ld_ro_rw_mix=read-write
2819   fi
2820 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2821   echo '.section myfoosect, "a"' > conftest1.s
2822   echo '.section myfoosect, "aw"' > conftest2.s
2823   echo '.byte 1' >> conftest2.s
2824   echo '.section myfoosect, "a"' > conftest3.s
2825   echo '.byte 0' >> conftest3.s
2826   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2827      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2828      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2829      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2830         conftest2.o conftest3.o > /dev/null 2>&1; then
2831     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2832                          | sed -e '/myfoosect/!d' -e N`
2833     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2834       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2835         gcc_cv_ld_ro_rw_mix=read-only
2836       else
2837         gcc_cv_ld_ro_rw_mix=read-write
2838       fi
2839     fi
2840   fi
2841 changequote(,)dnl
2842   rm -f conftest.* conftest[123].*
2843 changequote([,])dnl
2844 fi
2845 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2846         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2847   [Define if your linker links a mix of read-only
2848    and read-write sections into a read-write section.])
2849 fi
2850 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2851
2852 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2853 gcc_cv_ld_eh_frame_hdr=no
2854 if test $in_tree_ld = yes ; then
2855   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2856      && test $in_tree_ld_is_elf = yes; then
2857     gcc_cv_ld_eh_frame_hdr=yes
2858   fi
2859 elif test x$gcc_cv_ld != x; then
2860         # Check if linker supports --eh-frame-hdr option
2861         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2862                 gcc_cv_ld_eh_frame_hdr=yes
2863         fi
2864 fi
2865 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2866         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2867 [Define if your linker supports --eh-frame-hdr option.])
2868 fi
2869 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2870
2871 AC_MSG_CHECKING(linker position independent executable support)
2872 gcc_cv_ld_pie=no
2873 if test $in_tree_ld = yes ; then
2874   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2875      && test $in_tree_ld_is_elf = yes; then
2876     gcc_cv_ld_pie=yes
2877   fi
2878 elif test x$gcc_cv_ld != x; then
2879         # Check if linker supports -pie option
2880         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2881                 gcc_cv_ld_pie=yes
2882         fi
2883 fi
2884 if test x"$gcc_cv_ld_pie" = xyes; then
2885         AC_DEFINE(HAVE_LD_PIE, 1,
2886 [Define if your linker supports -pie option.])
2887 fi
2888 AC_MSG_RESULT($gcc_cv_ld_pie)
2889
2890 # --------
2891 # UNSORTED
2892 # --------
2893
2894 AC_CACHE_CHECK(linker --as-needed support,
2895 gcc_cv_ld_as_needed,
2896 [gcc_cv_ld_as_needed=no
2897 if test $in_tree_ld = yes ; then
2898   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2899      && test $in_tree_ld_is_elf = yes; then
2900     gcc_cv_ld_as_needed=yes
2901   fi
2902 elif test x$gcc_cv_ld != x; then
2903         # Check if linker supports --as-needed and --no-as-needed options
2904         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2905                 gcc_cv_ld_as_needed=yes
2906         fi
2907 fi
2908 ])
2909 if test x"$gcc_cv_ld_as_needed" = xyes; then
2910         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2911 [Define if your linker supports --as-needed and --no-as-needed options.])
2912 fi
2913
2914 case "$target" in
2915   powerpc64*-*-linux*)
2916     AC_CACHE_CHECK(linker support for omitting dot symbols,
2917     gcc_cv_ld_no_dot_syms,
2918     [gcc_cv_ld_no_dot_syms=no
2919     if test $in_tree_ld = yes ; then
2920       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
2921         gcc_cv_ld_no_dot_syms=yes
2922       fi
2923     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
2924       cat > conftest1.s <<EOF
2925         .text
2926         bl .foo
2927 EOF
2928       cat > conftest2.s <<EOF
2929         .section ".opd","aw"
2930         .align 3
2931         .globl foo
2932         .type foo,@function
2933 foo:
2934         .quad .LEfoo,.TOC.@tocbase,0
2935         .text
2936 .LEfoo:
2937         blr
2938         .size foo,.-.LEfoo
2939 EOF
2940       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
2941          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
2942          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
2943         gcc_cv_ld_no_dot_syms=yes
2944       fi
2945       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
2946     fi
2947     ])
2948     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
2949       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
2950     [Define if your PowerPC64 linker only needs function descriptor syms.])
2951     fi
2952     ;;
2953 esac
2954
2955 if test x$with_sysroot = x && test x$host = x$target \
2956    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2957   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2958 [Define to PREFIX/include if cpp should also search that directory.])
2959 fi
2960
2961 # Find out what GC implementation we want, or may, use.
2962 AC_ARG_WITH(gc,
2963 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2964                           with the compiler],
2965 [case "$withval" in
2966   page | zone)
2967     GGC=ggc-$withval
2968     ;;
2969   *)
2970     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2971     ;;
2972 esac],
2973 [GGC=ggc-page])
2974 AC_SUBST(GGC)
2975 echo "Using $GGC for garbage collection."
2976
2977 # Use the system's zlib library.
2978 zlibdir=-L../zlib
2979 zlibinc="-I\$(srcdir)/../zlib"
2980 AC_ARG_WITH(system-zlib,
2981 [  --with-system-zlib      use installed libz],
2982 zlibdir=
2983 zlibinc=
2984 )
2985 AC_SUBST(zlibdir)
2986 AC_SUBST(zlibinc)
2987
2988 dnl Very limited version of automake's enable-maintainer-mode
2989
2990 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2991   dnl maintainer-mode is disabled by default
2992   AC_ARG_ENABLE(maintainer-mode,
2993 [  --enable-maintainer-mode
2994                           enable make rules and dependencies not useful
2995                           (and sometimes confusing) to the casual installer],
2996       maintainer_mode=$enableval,
2997       maintainer_mode=no)
2998
2999 AC_MSG_RESULT($maintainer_mode)
3000
3001 if test "$maintainer_mode" = "yes"; then
3002   MAINT=''
3003 else
3004   MAINT='#'
3005 fi
3006 AC_SUBST(MAINT)dnl
3007
3008 # --------------
3009 # Language hooks
3010 # --------------
3011
3012 # Make empty files to contain the specs and options for each language.
3013 # Then add #include lines to for a compiler that has specs and/or options.
3014
3015 lang_opt_files=
3016 lang_specs_files=
3017 lang_tree_files=
3018 for subdir in . $subdirs
3019 do
3020         if test -f $srcdir/$subdir/lang.opt; then
3021             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3022         fi
3023         if test -f $srcdir/$subdir/lang-specs.h; then
3024             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3025         fi
3026         if test -f $srcdir/$subdir/$subdir-tree.def; then
3027             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3028         fi
3029 done
3030
3031 # These (without "all_") are set in each config-lang.in.
3032 # `language' must be a single word so is spelled singularly.
3033 all_languages=
3034 all_boot_languages=
3035 all_compilers=
3036 all_stagestuff=
3037 all_outputs='Makefile gccbug mklibgcc mkheaders libada-mk'
3038 # List of language makefile fragments.
3039 all_lang_makefrags=
3040 # List of language subdirectory makefiles.  Deprecated.
3041 all_lang_makefiles=
3042 # Files for gengtype
3043 all_gtfiles="$target_gtfiles"
3044 # Files for gengtype with language
3045 all_gtfiles_files_langs=
3046 all_gtfiles_files_files=
3047
3048 # Add the language fragments.
3049 # Languages are added via two mechanisms.  Some information must be
3050 # recorded in makefile variables, these are defined in config-lang.in.
3051 # We accumulate them and plug them into the main Makefile.
3052 # The other mechanism is a set of hooks for each of the main targets
3053 # like `clean', `install', etc.
3054
3055 language_hooks="Make-hooks"
3056
3057 for s in $subdirs
3058 do
3059                 language=
3060                 boot_language=
3061                 compilers=
3062                 stagestuff=
3063                 outputs=
3064                 gtfiles=
3065                 . ${srcdir}/$s/config-lang.in
3066                 if test "x$language" = x
3067                 then
3068                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3069                         exit 1
3070                 fi
3071                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3072                 if test -f ${srcdir}/$s/Makefile.in
3073                 then all_lang_makefiles="$s/Makefile"
3074                 fi
3075                 all_languages="$all_languages $language"
3076                 if test "x$boot_language" = xyes
3077                 then
3078                         all_boot_languages="$all_boot_languages $language"
3079                 fi
3080                 all_compilers="$all_compilers $compilers"
3081                 all_stagestuff="$all_stagestuff $stagestuff"
3082                 all_outputs="$all_outputs $outputs"
3083                 all_gtfiles="$all_gtfiles $gtfiles"
3084                 for f in $gtfiles
3085                 do
3086                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3087                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3088                 done
3089 done
3090
3091 # Pick up gtfiles for c
3092 gtfiles=
3093 s="c"
3094 . ${srcdir}/c-config-lang.in
3095 all_gtfiles="$all_gtfiles $gtfiles"
3096 for f in $gtfiles
3097 do
3098         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3099         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3100 done
3101
3102 check_languages=
3103 for language in $all_languages
3104 do
3105                 check_languages="$check_languages check-$language"
3106 done
3107
3108 # We link each language in with a set of hooks, reached indirectly via
3109 # lang.${target}.
3110
3111 rm -f Make-hooks
3112 touch Make-hooks
3113 target_list="all.build all.cross start.encap rest.encap tags \
3114         install-normal install-common install-man \
3115         uninstall info man srcextra srcman srcinfo \
3116         mostlyclean clean distclean maintainer-clean \
3117         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3118 for t in $target_list
3119 do
3120         x=
3121         for lang in $all_languages
3122         do
3123                         x="$x $lang.$t"
3124         done
3125         echo "lang.$t: $x" >> Make-hooks
3126 done
3127
3128 # --------
3129 # UNSORTED
3130 # --------
3131
3132 # Create .gdbinit.
3133
3134 echo "dir ." > .gdbinit
3135 echo "dir ${srcdir}" >> .gdbinit
3136 if test x$gdb_needs_out_file_path = xyes
3137 then
3138         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3139 fi
3140 if test "x$subdirs" != x; then
3141         for s in $subdirs
3142         do
3143                 echo "dir ${srcdir}/$s" >> .gdbinit
3144         done
3145 fi
3146 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3147
3148 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3149 # absolute path for gcc_tooldir based on inserting the number of up-directory
3150 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3151 # $(libsubdir)/@(unlibsubdir) based path.
3152 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3153 # make and thus we'd get different behavior depending on where we built the
3154 # sources.
3155 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3156     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3157 else
3158 changequote(<<, >>)dnl
3159 # An explanation of the sed strings:
3160 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3161 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3162 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3163 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3164 #
3165 # (*) Note this pattern overwrites the first character of the string
3166 # with a forward slash if one is not already present.  This is not a
3167 # problem because the exact names of the sub-directories concerned is
3168 # unimportant, just the number of them matters.
3169 #
3170 # The practical upshot of these patterns is like this:
3171 #
3172 #  prefix     exec_prefix        result
3173 #  ------     -----------        ------
3174 #   /foo        /foo/bar          ../
3175 #   /foo/       /foo/bar          ../
3176 #   /foo        /foo/bar/         ../
3177 #   /foo/       /foo/bar/         ../
3178 #   /foo        /foo/bar/ugg      ../../
3179 #
3180     dollar='$$'
3181     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3182 changequote([, ])dnl
3183 fi
3184 AC_SUBST(gcc_tooldir)
3185 AC_SUBST(dollar)
3186
3187 # Find a directory in which to install a shared libgcc.
3188
3189 AC_ARG_ENABLE(version-specific-runtime-libs,
3190 [  --enable-version-specific-runtime-libs
3191                           specify that runtime libraries should be
3192                           installed in a compiler-specific directory])
3193
3194 AC_ARG_WITH(slibdir,
3195 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3196 slibdir="$with_slibdir",
3197 if test "${enable_version_specific_runtime_libs+set}" = set; then
3198   slibdir='$(libsubdir)'
3199 elif test "$host" != "$target"; then
3200   slibdir='$(build_tooldir)/lib'
3201 else
3202   slibdir='$(libdir)'
3203 fi)
3204 AC_SUBST(slibdir)
3205
3206 objdir=`${PWDCMD-pwd}`
3207 AC_SUBST(objdir)
3208
3209 # Substitute configuration variables
3210 AC_SUBST(subdirs)
3211 AC_SUBST(srcdir)
3212 AC_SUBST(all_boot_languages)
3213 AC_SUBST(all_compilers)
3214 AC_SUBST(all_gtfiles)
3215 AC_SUBST(all_gtfiles_files_langs)
3216 AC_SUBST(all_gtfiles_files_files)
3217 AC_SUBST(all_lang_makefrags)
3218 AC_SUBST(all_lang_makefiles)
3219 AC_SUBST(all_languages)
3220 AC_SUBST(all_stagestuff)
3221 AC_SUBST(build_exeext)
3222 AC_SUBST(build_install_headers_dir)
3223 AC_SUBST(build_xm_file_list)
3224 AC_SUBST(build_xm_include_list)
3225 AC_SUBST(build_xm_defines)
3226 AC_SUBST(check_languages)
3227 AC_SUBST(cc_set_by_configure)
3228 AC_SUBST(quoted_cc_set_by_configure)
3229 AC_SUBST(cpp_install_dir)
3230 AC_SUBST(xmake_file)
3231 AC_SUBST(tmake_file)
3232 AC_SUBST(extra_gcc_objs)
3233 AC_SUBST(extra_headers_list)
3234 AC_SUBST(extra_objs)
3235 AC_SUBST(extra_parts)
3236 AC_SUBST(extra_passes)
3237 AC_SUBST(extra_programs)
3238 AC_SUBST(float_h_file)
3239 AC_SUBST(gcc_config_arguments)
3240 AC_SUBST(gcc_gxx_include_dir)
3241 AC_SUBST(libstdcxx_incdir)
3242 AC_SUBST(gcc_version)
3243 AC_SUBST(gcc_version_full)
3244 AC_SUBST(gcc_version_trigger)
3245 AC_SUBST(host_exeext)
3246 AC_SUBST(host_xm_file_list)
3247 AC_SUBST(host_xm_include_list)
3248 AC_SUBST(host_xm_defines)
3249 AC_SUBST(out_host_hook_obj)
3250 AC_SUBST(install)
3251 AC_SUBST(lang_opt_files)
3252 AC_SUBST(lang_specs_files)
3253 AC_SUBST(lang_tree_files)
3254 AC_SUBST(local_prefix)
3255 AC_SUBST(md_file)
3256 AC_SUBST(objc_boehm_gc)
3257 AC_SUBST(out_file)
3258 AC_SUBST(out_object_file)
3259 AC_SUBST(stage_prefix_set_by_configure)
3260 AC_SUBST(quoted_stage_prefix_set_by_configure)
3261 AC_SUBST(thread_file)
3262 AC_SUBST(tm_file_list)
3263 AC_SUBST(tm_include_list)
3264 AC_SUBST(tm_defines)
3265 AC_SUBST(tm_p_file_list)
3266 AC_SUBST(tm_p_include_list)
3267 AC_SUBST(xm_file_list)
3268 AC_SUBST(xm_include_list)
3269 AC_SUBST(xm_defines)
3270 AC_SUBST(c_target_objs)
3271 AC_SUBST(cxx_target_objs)
3272 AC_SUBST(target_cpu_default)
3273
3274 AC_SUBST_FILE(language_hooks)
3275
3276 TL_AC_GNU_MAKE_GCC_LIB_PATH
3277
3278 # Echo link setup.
3279 if test x${build} = x${host} ; then
3280   if test x${host} = x${target} ; then
3281     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3282   else
3283     echo "Links are now set up to build a cross-compiler" 1>&2
3284     echo " from ${host} to ${target}." 1>&2
3285   fi
3286 else
3287   if test x${host} = x${target} ; then
3288     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3289     echo " for ${target}." 1>&2
3290   else
3291     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3292     echo " from ${host} to ${target}." 1>&2
3293   fi
3294 fi
3295
3296 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3297 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3298
3299 # Configure the subdirectories
3300 # AC_CONFIG_SUBDIRS($subdirs)
3301
3302 # Create the Makefile
3303 # and configure language subdirectories
3304 AC_CONFIG_FILES($all_outputs)
3305
3306 AC_CONFIG_COMMANDS([default],
3307 [
3308 case ${CONFIG_HEADERS} in
3309   *auto-host.h:config.in*)
3310   echo > cstamp-h ;;
3311 esac
3312 # Make sure all the subdirs exist.
3313 for d in $subdirs doc build
3314 do
3315     test -d $d || mkdir $d
3316 done
3317 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3318 # bootstrapping and the installation procedure can still use
3319 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3320 # FLAGS_TO_PASS has been modified to solve the problem there.
3321 # This is virtually a duplicate of what happens in configure.lang; we do
3322 # an extra check to make sure this only happens if ln -s can be used.
3323 case "$LN_S" in
3324   *-s*)
3325     for d in ${subdirs} ; do
3326         STARTDIR=`${PWDCMD-pwd}`
3327         cd $d
3328         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3329         do
3330                 rm -f $t
3331                 $LN_S ../$t $t 2>/dev/null
3332         done
3333         cd $STARTDIR
3334     done
3335   ;;
3336 esac
3337 ],
3338 [subdirs='$subdirs'])
3339 AC_OUTPUT