gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.57)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 _GCC_TOPLEV_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # ----------------------
 215 # Find default assembler
 216 # ----------------------
 217
 218 # With GNU as
 219 AC_ARG_WITH(gnu-as,
 220 [  --with-gnu-as           arrange to work with GNU as],
 221 gas_flag="$with_gnu_as",
 222 gas_flag=no)
 223
 224 AC_ARG_WITH(as,
 225 [  --with-as               arrange to use the specified as (full pathname)],
 226 DEFAULT_ASSEMBLER="$with_as")
 227 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 228   if test ! -x "$DEFAULT_ASSEMBLER"; then
 229     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 230   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 231     gas_flag=yes
 232   fi
 233   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 234         [Define to enable the use of a default assembler.])
 235 fi
 236
 237 AC_MSG_CHECKING([whether a default assembler was specified])
 238 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 239   if test x"$gas_flag" = x"no"; then
 240     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 241   else
 242     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 243   fi
 244 else
 245   AC_MSG_RESULT(no)
 246 fi
 247
 248 # ---------------
 249 # Find C compiler
 250 # ---------------
 251
 252 # If a non-executable a.out is present (e.g. created by GNU as above even if
 253 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 254 # file, even when creating an executable, so an execution test fails.
 255 # Remove possible default executable files to avoid this.
 256 #
 257 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 258 # Autoconf includes it.
 259 rm -f a.out a.exe b.out
 260
 261 # Find the native compiler
 262 AC_PROG_CC
 263 AC_PROG_CC_C_O
 264 # autoconf is lame and doesn't give us any substitution variable for this.
 265 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 266   NO_MINUS_C_MINUS_O=yes
 267 else
 268   OUTPUT_OPTION='-o $@'
 269 fi
 270 AC_SUBST(NO_MINUS_C_MINUS_O)
 271 AC_SUBST(OUTPUT_OPTION)
 272
 273 # -------------------------
 274 # Check C compiler features
 275 # -------------------------
 276
 277 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 278 ac_cv_prog_cc_no_long_long,
 279 [save_CFLAGS="$CFLAGS"
 280 CFLAGS="-Wno-long-long"
 281 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 282                ac_cv_prog_cc_no_long_long=no)
 283 CFLAGS="$save_CFLAGS"])
 284
 285 AC_PROG_CPP
 286 AC_C_INLINE
 287
 288 gcc_AC_C_LONG_LONG
 289 gcc_AC_C__BOOL
 290
 291 # sizeof(char) is 1 by definition.
 292 AC_COMPILE_CHECK_SIZEOF(void *)
 293 AC_COMPILE_CHECK_SIZEOF(short)
 294 AC_COMPILE_CHECK_SIZEOF(int)
 295 AC_COMPILE_CHECK_SIZEOF(long)
 296 if test $ac_cv_c_long_long = yes; then
 297   AC_COMPILE_CHECK_SIZEOF(long long)
 298 fi
 299 if test $ac_cv_c___int64 = yes; then
 300   AC_COMPILE_CHECK_SIZEOF(__int64)
 301 fi
 302
 303 # -----------------
 304 # Find Ada compiler
 305 # -----------------
 306
 307 # See if GNAT has been installed
 308 gcc_AC_PROG_GNAT
 309
 310 # ---------------------
 311 # Warnings and checking
 312 # ---------------------
 313
 314 strict1_warn=
 315 if test $ac_cv_prog_cc_no_long_long = yes ; then
 316   strict1_warn="-pedantic -Wno-long-long"
 317 fi
 318 AC_SUBST(strict1_warn)
 319
 320 # If the native compiler is GCC, we can enable warnings even in stage1.
 321 # That's useful for people building cross-compilers, or just running a
 322 # quick `make'.
 323 warn_cflags=
 324 if test "x$GCC" = "xyes"; then
 325   warn_cflags='$(GCC_WARN_CFLAGS)'
 326 fi
 327 AC_SUBST(warn_cflags)
 328
 329 # Enable -Werror in bootstrap stage2 and later.
 330 # Change the default to "no" on release branches.
 331 AC_ARG_ENABLE(werror,
 332 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 333 [enable_werror=yes])
 334 if test x$enable_werror = xyes ; then
 335   WERROR=-Werror
 336 fi
 337 AC_SUBST(WERROR)
 338
 339 # Enable expensive internal checks
 340 AC_ARG_ENABLE(checking,
 341 [  --enable-checking[=LIST]
 342                           enable expensive run-time checks.  With LIST,
 343                           enable only specific categories of checks.
 344                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 345                           default is misc,tree,gc,rtlflag],
 346 [ac_checking=
 347 ac_tree_checking=
 348 ac_rtl_checking=
 349 ac_rtlflag_checking=
 350 ac_gc_checking=
 351 ac_gc_always_collect=
 352 ac_fold_checking=
 353 case "${enableval}" in
 354 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 355         ac_rtlflag_checking=1 ;;
 356 no)     ;;
 357 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 358         set fnord $enableval; shift
 359         IFS="$ac_save_IFS"
 360         for check
 361         do
 362                 case $check in
 363                 misc)   ac_checking=1 ;;
 364                 tree)   ac_tree_checking=1 ;;
 365                 rtlflag)        ac_rtlflag_checking=1 ;;
 366                 rtl)    ac_rtl_checking=1 ;;
 367                 gc)     ac_gc_checking=1 ;;
 368                 gcac)   ac_gc_always_collect=1 ;;
 369                 fold)   ac_fold_checking=1 ;;
 370                 valgrind)       ac_checking_valgrind=1 ;;
 371                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 372                 esac
 373         done
 374         ;;
 375 esac
 376 ],
 377 # Enable some checks by default for development versions of GCC
 378 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 379 nocommon_flag=""
 380 if test x$ac_checking != x ; then
 381   AC_DEFINE(ENABLE_CHECKING, 1,
 382 [Define if you want more run-time sanity checks.  This one gets a grab
 383    bag of miscellaneous but relatively cheap checks.])
 384   nocommon_flag=-fno-common
 385 fi
 386 AC_SUBST(nocommon_flag)
 387 if test x$ac_tree_checking != x ; then
 388   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 389 [Define if you want all operations on trees (the basic data
 390    structure of the front ends) to be checked for dynamic type safety
 391    at runtime.  This is moderately expensive.])
 392 fi
 393 if test x$ac_rtl_checking != x ; then
 394   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 395 [Define if you want all operations on RTL (the basic data structure
 396    of the optimizer and back end) to be checked for dynamic type safety
 397    at runtime.  This is quite expensive.])
 398 fi
 399 if test x$ac_rtlflag_checking != x ; then
 400   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 401 [Define if you want RTL flag accesses to be checked against the RTL
 402    codes that are supported for each access macro.  This is relatively
 403    cheap.])
 404 fi
 405 if test x$ac_gc_checking != x ; then
 406   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 407 [Define if you want the garbage collector to do object poisoning and
 408    other memory allocation checks.  This is quite expensive.])
 409 fi
 410 if test x$ac_gc_always_collect != x ; then
 411   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 412 [Define if you want the garbage collector to operate in maximally
 413    paranoid mode, validating the entire heap and collecting garbage at
 414    every opportunity.  This is extremely expensive.])
 415 fi
 416 if test x$ac_fold_checking != x ; then
 417   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 418 [Define if you want fold checked that it never destructs its argument.
 419    This is quite expensive.])
 420 fi
 421 valgrind_path_defines=
 422 valgrind_command=
 423
 424 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 425 dnl # an if statement.  This was the source of very frustrating bugs
 426 dnl # in converting to autoconf 2.5x!
 427 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 428
 429 if test x$ac_checking_valgrind != x ; then
 430   # It is certainly possible that there's valgrind but no valgrind.h.
 431   # GCC relies on making annotations so we must have both.
 432   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 433   AC_TRY_CPP(
 434     [#include <valgrind/memcheck.h>
 435 #ifndef VALGRIND_DISCARD
 436 #error VALGRIND_DISCARD not defined
 437 #endif],
 438   [gcc_cv_header_valgrind_memcheck_h=yes],
 439   [gcc_cv_header_valgrind_memcheck_h=no])
 440   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 441   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 442   AC_TRY_CPP(
 443     [#include <memcheck.h>
 444 #ifndef VALGRIND_DISCARD
 445 #error VALGRIND_DISCARD not defined
 446 #endif],
 447   [gcc_cv_header_memcheck_h=yes],
 448   gcc_cv_header_memcheck_h=no)
 449   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 450   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 451         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 452   if test "x$valgrind_path" = "x" \
 453     || (test $have_valgrind_h = no \
 454         && test $gcc_cv_header_memcheck_h = no \
 455         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 456         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 457   fi
 458   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 459   valgrind_command="$valgrind_path -q"
 460   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 461 [Define if you want to run subprograms and generated programs
 462    through valgrind (a memory checker).  This is extremely expensive.])
 463   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 464     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 465         [Define if valgrind's valgrind/memcheck.h header is installed.])
 466   fi
 467   if test $gcc_cv_header_memcheck_h = yes; then
 468     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 469         [Define if valgrind's memcheck.h header is installed.])
 470   fi
 471 fi
 472 AC_SUBST(valgrind_path_defines)
 473 AC_SUBST(valgrind_command)
 474
 475 # Enable code coverage collection
 476 AC_ARG_ENABLE(coverage,
 477 [  --enable-coverage[=LEVEL]
 478                           enable compiler\'s code coverage collection.
 479                           Use to measure compiler performance and locate
 480                           unused parts of the compiler. With LEVEL, specify
 481                           optimization. Values are opt, noopt,
 482                           default is noopt],
 483 [case "${enableval}" in
 484 yes|noopt)
 485         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 486         ;;
 487 opt)
 488         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 489         ;;
 490 *)
 491         AC_MSG_ERROR(unknown coverage setting $enableval)
 492         ;;
 493 esac],
 494 [coverage_flags=""])
 495 AC_SUBST(coverage_flags)
 496
 497 AC_ARG_ENABLE(gather-detailed-mem-stats,
 498 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 499 [enable_gather_detailed_mem_stats=no])
 500 if test x$enable_gather_detailed_mem_stats = xyes ; then
 501   AC_DEFINE(GATHER_STATISTICS, 1,
 502         [Define to enable detailed memory allocation stats gathering.])
 503 fi
 504
 505 # -------------------------------
 506 # Miscenalleous configure options
 507 # -------------------------------
 508
 509 # With stabs
 510 AC_ARG_WITH(stabs,
 511 [  --with-stabs            arrange to use stabs instead of host debug format],
 512 stabs="$with_stabs",
 513 stabs=no)
 514
 515 # Determine whether or not multilibs are enabled.
 516 AC_ARG_ENABLE(multilib,
 517 [  --enable-multilib       enable library support for multiple ABIs],
 518 [], [enable_multilib=yes])
 519 AC_SUBST(enable_multilib)
 520
 521 # Enable __cxa_atexit for C++.
 522 AC_ARG_ENABLE(__cxa_atexit,
 523 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 524 [], [])
 525
 526 # Enable threads
 527 # Pass with no value to take the default
 528 # Pass with a value to specify a thread package
 529 AC_ARG_ENABLE(threads,
 530 [  --enable-threads        enable thread usage for target GCC
 531   --enable-threads=LIB    use LIB thread package for target GCC],,
 532 enable_threads='')
 533 # Save in case it gets overwritten in config.gcc
 534 enable_threads_flag=$enable_threads
 535
 536 AC_ARG_ENABLE(objc-gc,
 537 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 538                           the GNU Objective-C runtime],
 539 if test x$enable_objc_gc = xno; then
 540         objc_boehm_gc=''
 541 else
 542         objc_boehm_gc=1
 543 fi,
 544 objc_boehm_gc='')
 545
 546 AC_ARG_WITH(dwarf2,
 547 [  --with-dwarf2           force the default debug format to be DWARF 2],
 548 dwarf2="$with_dwarf2",
 549 dwarf2=no)
 550
 551 AC_ARG_ENABLE(shared,
 552 [  --disable-shared        don't provide a shared libgcc],
 553 [
 554   case $enable_shared in
 555   yes | no) ;;
 556   *)
 557     enable_shared=no
 558     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 559     for pkg in $enableval; do
 560       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 561         enable_shared=yes
 562       fi
 563     done
 564     IFS="$ac_save_ifs"
 565     ;;
 566   esac
 567 ], [enable_shared=yes])
 568 AC_SUBST(enable_shared)
 569
 570 AC_ARG_WITH(sysroot,
 571 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 572 [
 573  case ${with_sysroot} in
 574  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 575  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 576  esac
 577
 578  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 579  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 580
 581  if test "x$exec_prefix" = xNONE; then
 582   if test "x$prefix" = xNONE; then
 583    test_prefix=/usr/local
 584   else
 585    test_prefix=$prefix
 586   fi
 587  else
 588   test_prefix=$exec_prefix
 589  fi
 590  case ${TARGET_SYSTEM_ROOT} in
 591  "${test_prefix}"|"${test_prefix}/"*|\
 592  '${exec_prefix}'|'${exec_prefix}/'*)
 593    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 594    TARGET_SYSTEM_ROOT_DEFINE="$t"
 595    ;;
 596  esac
 597 ], [
 598  TARGET_SYSTEM_ROOT=
 599  TARGET_SYSTEM_ROOT_DEFINE=
 600  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 601 ])
 602 AC_SUBST(TARGET_SYSTEM_ROOT)
 603 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 604 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 605
 606 # Build with intermodule optimisations
 607 AC_ARG_ENABLE(intermodule,
 608 [  --enable-intermodule    build the compiler in one step],
 609 [case ${enable_intermodule} in
 610   yes) onestep="-onestep";;
 611   *) onestep="";;
 612 esac],
 613 [onestep=""])
 614 AC_SUBST(onestep)
 615
 616 # -------------------------
 617 # Checks for other programs
 618 # -------------------------
 619
 620 AC_PROG_MAKE_SET
 621
 622 # Find some useful tools
 623 AC_PROG_AWK
 624 # We need awk to run opts.sh (to create options.c and options.h).
 625 # Bail out if it's missing.
 626 case ${AWK} in
 627   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 628 esac
 629
 630 gcc_AC_PROG_LN
 631 gcc_AC_PROG_LN_S
 632 AC_PROG_RANLIB
 633 gcc_AC_PROG_INSTALL
 634
 635 # See if cmp has --ignore-initial.
 636 gcc_AC_PROG_CMP_IGNORE_INITIAL
 637
 638 # See if we have the mktemp command.
 639 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 640
 641 # Do we have a single-tree copy of texinfo?
 642 if test -f $srcdir/../texinfo/Makefile.in; then
 643   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 644   gcc_cv_prog_makeinfo_modern=yes
 645   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 646 else
 647   # See if makeinfo has been installed and is modern enough
 648   # that we can use it.
 649   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 650   [GNU texinfo.* \([0-9][0-9.]*\)],
 651   [4.[2-9]*])
 652 fi
 653
 654 if test $gcc_cv_prog_makeinfo_modern = no; then
 655   AC_MSG_WARN([
 656 *** Makeinfo is missing or too old.
 657 *** Info documentation will not be built.])
 658   BUILD_INFO=
 659 else
 660   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 661 fi
 662
 663 # Is pod2man recent enough to regenerate manpages?
 664 AC_MSG_CHECKING([for recent Pod::Man])
 665 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 666   AC_MSG_RESULT(yes)
 667   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 668 else
 669   AC_MSG_RESULT(no)
 670   GENERATED_MANPAGES=
 671 fi
 672
 673 # How about lex?
 674 dnl Don't use AC_PROG_LEX; we insist on flex.
 675 dnl LEXLIB is not useful in gcc.
 676 if test -f $srcdir/../flex/skel.c; then
 677   FLEX='$(objdir)/../flex/flex'
 678 else
 679   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 680 fi
 681
 682 # Bison?
 683 # The -L switch is so bison can find its skeleton file.
 684 if test -f $srcdir/../bison/bison.simple; then
 685   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 686 else
 687   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 688 fi
 689
 690 # --------------------
 691 # Checks for C headers
 692 # --------------------
 693
 694 AC_MSG_CHECKING(for GNU C library)
 695 AC_CACHE_VAL(gcc_cv_glibc,
 696 [AC_TRY_COMPILE(
 697   [#include <features.h>],[
 698 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 699 #error Not a GNU C library system
 700 #endif],
 701   [gcc_cv_glibc=yes],
 702   gcc_cv_glibc=no)])
 703 AC_MSG_RESULT($gcc_cv_glibc)
 704 if test $gcc_cv_glibc = yes; then
 705   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 706 fi
 707
 708 # Need to reject headers which give warnings, so that the -Werror bootstrap
 709 # works later. *sigh*  This needs to come before all header checks.
 710 AC_PROG_CPP_WERROR
 711
 712 AC_HEADER_STDC
 713 AC_HEADER_TIME
 714 gcc_AC_HEADER_STDBOOL
 715 gcc_AC_HEADER_STRING
 716 AC_HEADER_SYS_WAIT
 717 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 718                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 719                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 720                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 721
 722 # Check for thread headers.
 723 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 724 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 725
 726 # These tests can't be done till we know if we have limits.h.
 727 gcc_AC_C_CHAR_BIT
 728 AC_C_BIGENDIAN_CROSS
 729
 730 # --------
 731 # UNSORTED
 732 # --------
 733
 734 # Stage specific cflags for build.
 735 stage1_cflags=
 736 case $build in
 737 vax-*-*)
 738   if test x$GCC = xyes
 739   then
 740     stage1_cflags="-Wa,-J"
 741   else
 742     stage1_cflags="-J"
 743   fi
 744   ;;
 745 powerpc-*-darwin*)
 746   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 747   # sources; use -no-cpp-precomp to get to GNU cpp.
 748   # Apple's GCC has bugs in designated initializer handling, so disable
 749   # that too.
 750   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 751   ;;
 752 esac
 753 AC_SUBST(stage1_cflags)
 754
 755 # These libraries may be used by collect2.
 756 # We may need a special search path to get them linked.
 757 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 758 [save_LIBS="$LIBS"
 759 for libs in '' -lld -lmld \
 760                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 761                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 762 do
 763         LIBS="$libs"
 764         AC_TRY_LINK_FUNC(ldopen,
 765                 [gcc_cv_collect2_libs="$libs"; break])
 766 done
 767 LIBS="$save_LIBS"
 768 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 769 case $gcc_cv_collect2_libs in
 770         "none required")        ;;
 771         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 772 esac
 773 AC_SUBST(COLLECT2_LIBS)
 774
 775 # When building Ada code on Alpha, we need exc_resume which is usually in
 776 # -lexc.  So test for it.
 777 save_LIBS="$LIBS"
 778 LIBS=
 779 AC_SEARCH_LIBS(exc_resume, exc)
 780 GNAT_LIBEXC="$LIBS"
 781 LIBS="$save_LIBS"
 782 AC_SUBST(GNAT_LIBEXC)
 783
 784 # Some systems put ldexp and frexp in libm instead of libc; assume
 785 # they're both in the same place.  jcf-dump needs them.
 786 save_LIBS="$LIBS"
 787 LIBS=
 788 AC_SEARCH_LIBS(ldexp, m)
 789 LDEXP_LIB="$LIBS"
 790 LIBS="$save_LIBS"
 791 AC_SUBST(LDEXP_LIB)
 792
 793 # Use <inttypes.h> only if it exists,
 794 # doesn't clash with <sys/types.h>, and declares intmax_t.
 795 AC_MSG_CHECKING(for inttypes.h)
 796 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 797 [AC_TRY_COMPILE(
 798   [#include <sys/types.h>
 799 #include <inttypes.h>],
 800   [intmax_t i = -1;],
 801   [gcc_cv_header_inttypes_h=yes],
 802   gcc_cv_header_inttypes_h=no)])
 803 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 804 if test $gcc_cv_header_inttypes_h = yes; then
 805   AC_DEFINE(HAVE_INTTYPES_H, 1,
 806         [Define if you have a working <inttypes.h> header file.])
 807 fi
 808
 809 dnl Disabled until we have a complete test for buggy enum bitfields.
 810 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 811
 812 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 813         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 814         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 815         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 816         setlocale)
 817
 818 if test x$ac_cv_func_mbstowcs = xyes; then
 819   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 820 [    AC_TRY_RUN([#include <stdlib.h>
 821 int main()
 822 {
 823   mbstowcs(0, "", 0);
 824   return 0;
 825 }],
 826     gcc_cv_func_mbstowcs_works=yes,
 827     gcc_cv_func_mbstowcs_works=no,
 828     gcc_cv_func_mbstowcs_works=yes)])
 829   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 830     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 831   [Define this macro if mbstowcs does not crash when its
 832    first argument is NULL.])
 833   fi
 834 fi
 835
 836 AC_CHECK_TYPE(ssize_t, int)
 837
 838 # Try to determine the array type of the second argument of getgroups
 839 # for the target system (int or gid_t).
 840 AC_TYPE_GETGROUPS
 841 if test "${target}" = "${build}"; then
 842   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 843 else
 844   case "${target}" in
 845         # This condition may need some tweaking.  It should include all
 846         # targets where the array type of the second argument of getgroups
 847         # is int and the type of gid_t is not equivalent to int.
 848         *-*-sunos* | *-*-ultrix*)
 849                 TARGET_GETGROUPS_T=int
 850                 ;;
 851         *)
 852                 TARGET_GETGROUPS_T=gid_t
 853                 ;;
 854   esac
 855 fi
 856 AC_SUBST(TARGET_GETGROUPS_T)
 857
 858 gcc_AC_FUNC_PRINTF_PTR
 859 gcc_AC_FUNC_MMAP_BLACKLIST
 860
 861 case "${host}" in
 862 *-*-*vms*)
 863   # Under VMS, vfork works very differently than on Unix. The standard test
 864   # won't work, and it isn't easily adaptable. It makes more sense to
 865   # just force it.
 866   ac_cv_func_vfork_works=yes
 867   ;;
 868 esac
 869 AC_FUNC_VFORK
 870
 871 AM_ICONV
 872 # Until we have in-tree GNU iconv:
 873 LIBICONV_DEP=
 874 AC_SUBST(LIBICONV_DEP)
 875
 876 AM_LC_MESSAGES
 877
 878 # We will need to find libiberty.h and ansidecl.h
 879 saved_CFLAGS="$CFLAGS"
 880 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 881 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 882         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 883         fprintf_unlocked strstr errno snprintf vasprintf \
 884         malloc realloc calloc free basename getopt clock, , ,[
 885 #include "ansidecl.h"
 886 #include "system.h"])
 887
 888 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 889 #include "ansidecl.h"
 890 #include "system.h"
 891 #ifdef HAVE_SYS_RESOURCE_H
 892 #include <sys/resource.h>
 893 #endif
 894 ])
 895
 896 AC_TRY_COMPILE([
 897 #include "ansidecl.h"
 898 #include "system.h"
 899 #ifdef HAVE_SYS_RESOURCE_H
 900 #include <sys/resource.h>
 901 #endif
 902 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 903 [Define to \`long' if <sys/resource.h> doesn't define.])])
 904
 905 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 906 #include "ansidecl.h"
 907 #include "system.h"
 908 #ifdef HAVE_LDFCN_H
 909 #include <ldfcn.h>
 910 #endif
 911 ])
 912
 913 gcc_AC_CHECK_DECLS(times, , ,[
 914 #include "ansidecl.h"
 915 #include "system.h"
 916 #ifdef HAVE_SYS_TIMES_H
 917 #include <sys/times.h>
 918 #endif
 919 ])
 920
 921 # More time-related stuff.
 922 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 923 AC_TRY_COMPILE([
 924 #include "ansidecl.h"
 925 #include "system.h"
 926 #ifdef HAVE_SYS_TIMES_H
 927 #include <sys/times.h>
 928 #endif
 929 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 930 if test $ac_cv_struct_tms = yes; then
 931   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 932   [Define if <sys/times.h> defines struct tms.])
 933 fi
 934
 935 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 936 # revisit after autoconf 2.50.
 937 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 938 AC_TRY_COMPILE([
 939 #include "ansidecl.h"
 940 #include "system.h"
 941 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 942 if test $gcc_cv_type_clock_t = yes; then
 943   AC_DEFINE(HAVE_CLOCK_T, 1,
 944   [Define if <time.h> defines clock_t.])
 945 fi
 946
 947 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
 948 [AC_TRY_COMPILE([
 949 #include "ansidecl.h"
 950 #include "system.h"
 951 ],
 952 [if ((uchar *)0) return 0;
 953  if (sizeof(uchar)) return 0;],
 954 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 955 if test $ac_cv_type_uchar = yes; then
 956   AC_DEFINE(HAVE_UCHAR, 1,
 957   [Define if <sys/types.h> defines \`uchar'.])
 958 fi
 959
 960 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 961 CFLAGS="$saved_CFLAGS"
 962
 963 gcc_AC_INITFINI_ARRAY
 964
 965 # mkdir takes a single argument on some systems.
 966 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 967
 968 # File extensions
 969 manext='.1'
 970 objext='.o'
 971 AC_SUBST(manext)
 972 AC_SUBST(objext)
 973
 974 # With Setjmp/Longjmp based exception handling.
 975 AC_ARG_ENABLE(sjlj-exceptions,
 976 [  --enable-sjlj-exceptions
 977                           arrange to use setjmp/longjmp exception handling],
 978 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
 979 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
 980   [Define 0/1 to force the choice for exception handling model.])])
 981
 982 if test x$host = x$target; then
 983    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
 984 else
 985    use_libunwind_default=no
 986 fi
 987 # Use libunwind based exception handling.
 988 AC_ARG_ENABLE(libunwind-exceptions,
 989 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
 990 use_libunwind_exceptions=$enableval,
 991 use_libunwind_exceptions=$use_libunwind_default)
 992 if test x"$use_libunwind_exceptions" = xyes; then
 993    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
 994         [Define if gcc should use -lunwind.])
 995 fi
 996
 997 # --------------------------------------------------------
 998 # Build, host, and target specific configuration fragments
 999 # --------------------------------------------------------
1000
1001 # Collect build-machine-specific information.
1002 . ${srcdir}/config.build
1003
1004 # Collect host-machine-specific information.
1005 . ${srcdir}/config.host
1006
1007 target_gtfiles=
1008
1009 # Collect target-machine-specific information.
1010 . ${srcdir}/config.gcc
1011
1012 extra_objs="${host_extra_objs} ${extra_objs}"
1013
1014 # Default the target-machine variables that were not explicitly set.
1015 if test x"$tm_file" = x
1016 then tm_file=$cpu_type/$cpu_type.h; fi
1017
1018 if test x"$extra_headers" = x
1019 then extra_headers=; fi
1020
1021 if test x$md_file = x
1022 then md_file=$cpu_type/$cpu_type.md; fi
1023
1024 if test x$out_file = x
1025 then out_file=$cpu_type/$cpu_type.c; fi
1026
1027 if test x"$tmake_file" = x
1028 then tmake_file=$cpu_type/t-$cpu_type
1029 fi
1030
1031 if test x"$dwarf2" = xyes
1032 then tm_file="$tm_file tm-dwarf2.h"
1033 fi
1034
1035 # Say what files are being used for the output code and MD file.
1036 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1037 echo "Using \`$srcdir/config/$md_file' as machine description file."
1038
1039 # If any of the xm_file variables contain nonexistent files, warn
1040 # about them and drop them.
1041
1042 bx=
1043 for x in $build_xm_file; do
1044   if    test -f $srcdir/config/$x
1045   then      bx="$bx $x"
1046   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1047   fi
1048 done
1049 build_xm_file="$bx"
1050
1051 hx=
1052 for x in $host_xm_file; do
1053   if    test -f $srcdir/config/$x
1054   then      hx="$hx $x"
1055   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1056   fi
1057 done
1058 host_xm_file="$hx"
1059
1060 tx=
1061 for x in $xm_file; do
1062   if    test -f $srcdir/config/$x
1063   then      tx="$tx $x"
1064   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1065   fi
1066 done
1067 xm_file="$tx"
1068
1069 count=a
1070 for f in $tm_file; do
1071         count=${count}x
1072 done
1073 if test $count = ax; then
1074         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1075 else
1076         echo "Using the following target machine macro files:"
1077         for f in $tm_file; do
1078                 echo "  $srcdir/config/$f"
1079         done
1080 fi
1081
1082 if test x$need_64bit_hwint = xyes; then
1083         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1084 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1085 fi
1086
1087 count=a
1088 for f in $host_xm_file; do
1089         count=${count}x
1090 done
1091 if test $count = a; then
1092         :
1093 elif test $count = ax; then
1094         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1095 else
1096         echo "Using the following host machine macro files:"
1097         for f in $host_xm_file; do
1098                 echo "  $srcdir/config/$f"
1099         done
1100 fi
1101 echo "Using ${out_host_hook_obj} for host machine hooks."
1102
1103 if test "$host_xm_file" != "$build_xm_file"; then
1104         count=a
1105         for f in $build_xm_file; do
1106                 count=${count}x
1107         done
1108         if test $count = a; then
1109                 :
1110         elif test $count = ax; then
1111                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1112         else
1113                 echo "Using the following build machine macro files:"
1114                 for f in $build_xm_file; do
1115                         echo "  $srcdir/config/$f"
1116                 done
1117         fi
1118 fi
1119
1120 # Check if a valid thread package
1121 case ${enable_threads_flag} in
1122   "" | no)
1123     # No threads
1124     target_thread_file='single'
1125     ;;
1126   yes)
1127     # default
1128     target_thread_file='single'
1129     ;;
1130   aix | dce | gnat | irix | posix | rtems | \
1131   single | solaris | vxworks | win32 )
1132     target_thread_file=${enable_threads_flag}
1133     ;;
1134   *)
1135     echo "${enable_threads_flag} is an unknown thread package" 1>&2
1136     exit 1
1137     ;;
1138 esac
1139
1140 if test x${thread_file} = x; then
1141   # No thread file set by target-specific clauses in config.gcc,
1142   # so use file chosen by default logic above
1143   thread_file=${target_thread_file}
1144 fi
1145
1146 if test x$enable___cxa_atexit = xyes || \
1147    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1148    AC_CHECK_FUNC(__cxa_atexit,
1149         [AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1150         [Define if you want to use __cxa_atexit, rather than atexit, to
1151         register C++ destructors for local statics and global objects.
1152         This is essential for fully standards-compliant handling of
1153         destructors, but requires __cxa_atexit in libc.])],
1154         echo "__cxa_atexit can't be enabled on this target")
1155 fi
1156
1157 # Look for a file containing extra machine modes.
1158 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1159   extra_modes_file='$(srcdir)'/config/${extra_modes}
1160   AC_SUBST(extra_modes_file)
1161   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1162   [Define to the name of a file containing a list of extra machine modes
1163    for this architecture.])
1164 fi
1165
1166 # auto-host.h is the file containing items generated by autoconf and is
1167 # the first file included by config.h.
1168 # If host=build, it is correct to have bconfig include auto-host.h
1169 # as well.  If host!=build, we are in error and need to do more
1170 # work to find out the build config parameters.
1171 if test x$host = x$build
1172 then
1173         build_auto=auto-host.h
1174         FORBUILD=..
1175 else
1176         # We create a subdir, then run autoconf in the subdir.
1177         # To prevent recursion we set host and build for the new
1178         # invocation of configure to the build for this invocation
1179         # of configure.
1180         tempdir=build.$$
1181         rm -rf $tempdir
1182         mkdir $tempdir
1183         cd $tempdir
1184         case ${srcdir} in
1185         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1186         *) realsrcdir=../${srcdir};;
1187         esac
1188         saved_CFLAGS="${CFLAGS}"
1189         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1190         ${realsrcdir}/configure \
1191                 --target=$target_alias --host=$build_alias --build=$build_alias
1192         CFLAGS="${saved_CFLAGS}"
1193
1194         # We just finished tests for the build machine, so rename
1195         # the file auto-build.h in the gcc directory.
1196         mv auto-host.h ../auto-build.h
1197         cd ..
1198         rm -rf $tempdir
1199         build_auto=auto-build.h
1200         FORBUILD=../${build_subdir}
1201 fi
1202 AC_SUBST(FORBUILD)
1203
1204 tm_file="${tm_file} defaults.h"
1205 tm_p_file="${tm_p_file} tm-preds.h"
1206 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1207 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1208 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1209 # put this back in temporarily.
1210 xm_file="ansidecl.h ${xm_file}"
1211
1212 # --------
1213 # UNSORTED
1214 # --------
1215
1216 # Get the version trigger filename from the toplevel
1217 if test "${with_gcc_version_trigger+set}" = set; then
1218         gcc_version_trigger=$with_gcc_version_trigger
1219 else
1220         gcc_version_trigger=${srcdir}/version.c
1221 fi
1222 changequote(,)dnl
1223 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1224 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1225
1226 # Compile in configure arguments.
1227 if test -f configargs.h ; then
1228         # Being re-configured.
1229         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1230         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1231 else
1232         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1233 fi
1234
1235 # Double all backslashes and backslash all quotes to turn
1236 # gcc_config_arguments into a C string.
1237 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1238 $gcc_config_arguments
1239 EOF
1240 gcc_config_arguments_str=`cat conftest.out`
1241 rm -f conftest.out
1242
1243 cat > configargs.h <<EOF
1244 /* Generated automatically. */
1245 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1246 static const char thread_model[] = "$thread_file";
1247
1248 static const struct {
1249   const char *name, *value;
1250 } configure_default_options[] = $configure_default_options;
1251 EOF
1252 changequote([,])dnl
1253
1254 # Internationalization
1255 PACKAGE=gcc
1256 VERSION="$gcc_version"
1257 AC_SUBST(PACKAGE)
1258 AC_SUBST(VERSION)
1259
1260 ZW_GNU_GETTEXT_SISTER_DIR
1261
1262 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1263 # -liconv on the link line twice.
1264 case "$LIBINTL" in *$LIBICONV*)
1265         LIBICONV= ;;
1266 esac
1267
1268 # Windows32 Registry support for specifying GCC installation paths.
1269 AC_ARG_ENABLE(win32-registry,
1270 [  --disable-win32-registry
1271                           disable lookup of installation paths in the
1272                           Registry on Windows hosts
1273   --enable-win32-registry enable registry lookup (default)
1274   --enable-win32-registry=KEY
1275                           use KEY instead of GCC version as the last portion
1276                           of the registry key],,)
1277 case $host_os in
1278         win32 | pe | cygwin* | mingw32* | uwin*)
1279 AC_MSG_CHECKING(whether windows registry support is requested)
1280 if test "x$enable_win32_registry" != xno; then
1281   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1282 [Define to 1 if installation paths should be looked up in Windows32
1283    Registry. Ignored on non windows32 hosts.])
1284   AC_MSG_RESULT(yes)
1285   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1286 else
1287   AC_MSG_RESULT(no)
1288 fi
1289
1290 # Check if user specified a different registry key.
1291 case "x${enable_win32_registry}" in
1292 x | xyes)
1293   # default.
1294   gcc_cv_win32_registry_key="$VERSION"
1295   ;;
1296 xno)
1297   # no registry lookup.
1298   gcc_cv_win32_registry_key=''
1299   ;;
1300 *)
1301   # user-specified key.
1302   gcc_cv_win32_registry_key="$enable_win32_registry"
1303   ;;
1304 esac
1305
1306 if test "x$enable_win32_registry" != xno; then
1307   AC_MSG_CHECKING(registry key on windows hosts)
1308   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1309         [Define to be the last portion of registry key on windows hosts.])
1310   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1311 fi
1312 ;;
1313 esac
1314
1315 # Get an absolute path to the GCC top-level source directory
1316 holddir=`${PWDCMD-pwd}`
1317 cd $srcdir
1318 topdir=`${PWDCMD-pwd}`
1319 cd $holddir
1320
1321 # Conditionalize the makefile for this host machine.
1322 xmake_file=
1323 for f in ${host_xmake_file}
1324 do
1325         if test -f ${srcdir}/config/$f
1326         then
1327                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1328         fi
1329 done
1330
1331 # Conditionalize the makefile for this target machine.
1332 tmake_file_=
1333 for f in ${tmake_file}
1334 do
1335         if test -f ${srcdir}/config/$f
1336         then
1337                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1338         fi
1339 done
1340 tmake_file="${tmake_file_}"
1341
1342 symbolic_link='ln -s'
1343
1344 # If the host doesn't support symlinks, modify CC in
1345 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1346 # Otherwise, we can use "CC=$(CC)".
1347 rm -f symtest.tem
1348 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1349 then
1350         cc_set_by_configure="\$(CC)"
1351         quoted_cc_set_by_configure="\$(CC)"
1352         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1353         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1354 else
1355         rm -f symtest.tem
1356         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1357         then
1358                 symbolic_link="cp -p"
1359         else
1360                 symbolic_link="cp"
1361         fi
1362         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1363         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1364         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1365         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1366 fi
1367 rm -f symtest.tem
1368
1369 out_object_file=`basename $out_file .c`.o
1370
1371 tm_file_list=
1372 tm_include_list=
1373 for f in $tm_file; do
1374   case $f in
1375     defaults.h )
1376        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1377        tm_include_list="${tm_include_list} $f"
1378        ;;
1379     * )
1380        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1381        tm_include_list="${tm_include_list} config/$f"
1382        ;;
1383   esac
1384 done
1385
1386 tm_p_file_list=
1387 tm_p_include_list=
1388 for f in $tm_p_file; do
1389   case $f in
1390     tm-preds.h )
1391        tm_p_file_list="${tm_p_file_list} $f"
1392        tm_p_include_list="${tm_p_include_list} $f"
1393        ;;
1394     * )
1395        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1396        tm_p_include_list="${tm_p_include_list} config/$f"
1397   esac
1398 done
1399
1400 xm_file_list=
1401 xm_include_list=
1402 for f in $xm_file; do
1403   case $f in
1404     ansidecl.h )
1405        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1406        xm_include_list="${xm_include_list} $f"
1407        ;;
1408     auto-host.h )
1409        xm_file_list="${xm_file_list} $f"
1410        xm_include_list="${xm_include_list} $f"
1411        ;;
1412     * )
1413        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1414        xm_include_list="${xm_include_list} config/$f"
1415        ;;
1416   esac
1417 done
1418
1419 host_xm_file_list=
1420 host_xm_include_list=
1421 for f in $host_xm_file; do
1422   case $f in
1423     ansidecl.h )
1424        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1425        host_xm_include_list="${host_xm_include_list} $f"
1426        ;;
1427     auto-host.h )
1428        host_xm_file_list="${host_xm_file_list} $f"
1429        host_xm_include_list="${host_xm_include_list} $f"
1430        ;;
1431     * )
1432        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1433        host_xm_include_list="${host_xm_include_list} config/$f"
1434        ;;
1435   esac
1436 done
1437
1438 build_xm_file_list=
1439 for f in $build_xm_file; do
1440   case $f in
1441     ansidecl.h )
1442        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1443        build_xm_include_list="${build_xm_include_list} $f"
1444        ;;
1445     auto-build.h | auto-host.h )
1446        build_xm_file_list="${build_xm_file_list} $f"
1447        build_xm_include_list="${build_xm_include_list} $f"
1448        ;;
1449     * )
1450        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1451        build_xm_include_list="${build_xm_include_list} config/$f"
1452        ;;
1453   esac
1454 done
1455
1456 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1457 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1458 CROSS=                                          AC_SUBST(CROSS)
1459 ALL=all.internal                                AC_SUBST(ALL)
1460 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1461 if test x$host != x$target
1462 then
1463         CROSS="-DCROSS_COMPILE"
1464         ALL=all.cross
1465         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1466         case "$host","$target" in
1467         # Darwin crosses can use the host system's libraries and headers,
1468         # because of the fat library support.  Of course, it must be the
1469         # same version of Darwin on both sides.  Allow the user to
1470         # just say --target=foo-darwin without a version number to mean
1471         # "the version on this system".
1472             *-*-darwin*,*-*-darwin*)
1473                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1474                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1475                 if test $hostos = $targetos -o $targetos = darwin ; then
1476                     CROSS=
1477                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1478                     with_headers=yes
1479                 fi
1480                 ;;
1481
1482             i?86-*-*,x86_64-*-* \
1483             | powerpc*-*-*,powerpc64*-*-*)
1484                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1485         esac
1486 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1487         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1488         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1489 fi
1490
1491 # If this is a cross-compiler that does not
1492 # have its own set of headers then define
1493 # inhibit_libc
1494
1495 # If this is using newlib, without having the headers available now,
1496 # then define inhibit_libc in LIBGCC2_CFLAGS.
1497 # This prevents libgcc2 from containing any code which requires libc
1498 # support.
1499 inhibit_libc=
1500 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1501        test x$with_newlib = xyes ; } &&
1502      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1503        inhibit_libc=-Dinhibit_libc
1504 fi
1505 AC_SUBST(inhibit_libc)
1506
1507 # When building gcc with a cross-compiler, we need to adjust things so
1508 # that the generator programs are still built with the native compiler.
1509 # Also, we cannot run fixincludes or fix-header.
1510
1511 # These are the normal (build=host) settings:
1512 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1513 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1514 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1515 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1516
1517 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1518
1519 # Possibly disable fixproto, on a per-target basis.
1520 case ${use_fixproto} in
1521   no)
1522     STMP_FIXPROTO=
1523     ;;
1524   yes)
1525     STMP_FIXPROTO=stmp-fixproto
1526     ;;
1527 esac
1528 AC_SUBST(STMP_FIXPROTO)
1529
1530 # And these apply if build != host, or we are generating coverage data
1531 if test x$build != x$host || test "x$coverage_flags" != x
1532 then
1533     BUILD_PREFIX=build-
1534     BUILD_PREFIX_1=build-
1535     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1536
1537     if test "x$TARGET_SYSTEM_ROOT" = x; then
1538         STMP_FIXINC=
1539         STMP_FIXPROTO=
1540     fi
1541 fi
1542
1543 # Expand extra_headers to include complete path.
1544 # This substitutes for lots of t-* files.
1545 extra_headers_list=
1546 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1547 for file in ${extra_headers} ; do
1548   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1549 done
1550
1551 # Add a definition of USE_COLLECT2 if system wants one.
1552 case $use_collect2 in
1553   no) use_collect2= ;;
1554   "") ;;
1555   *)
1556     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1557     xm_defines="${xm_defines} USE_COLLECT2"
1558     ;;
1559 esac
1560
1561 # Identify the assembler which will work hand-in-glove with the newly
1562 # built GCC, so that we can examine its features.  This is the assembler
1563 # which will be driven by the driver program.
1564 #
1565 # If build != host, and we aren't building gas in-tree, we identify a
1566 # build->target assembler and hope that it will have the same features
1567 # as the host->target assembler we'll be using.
1568 AC_MSG_CHECKING(what assembler to use)
1569 in_tree_gas=no
1570 gcc_cv_as=
1571 gcc_cv_gas_major_version=
1572 gcc_cv_gas_minor_version=
1573 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1574 if test -x "$DEFAULT_ASSEMBLER"; then
1575         gcc_cv_as="$DEFAULT_ASSEMBLER"
1576 elif test -x "$AS"; then
1577         gcc_cv_as="$AS"
1578 elif test -x as$host_exeext; then
1579         # Build using assembler in the current directory.
1580         gcc_cv_as=./as$host_exeext
1581 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1582      && test -f ../gas/Makefile; then
1583   # Single tree build which includes gas.
1584   in_tree_gas=yes
1585   _gcc_COMPUTE_GAS_VERSION
1586   rm -f as$host_exeext
1587   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1588   in_tree_gas_is_elf=no
1589   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1590      || (grep 'obj_format = multi' ../gas/Makefile \
1591          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1592   then
1593     in_tree_gas_is_elf=yes
1594   fi
1595 fi
1596
1597 if test "x$gcc_cv_as" = x; then
1598         # Search the same directories that the installed compiler will
1599         # search.  Else we may find the wrong assembler and lose.  If we
1600         # do not find a suitable assembler binary, then try the user's
1601         # path.
1602         #
1603         # Also note we have to check MD_EXEC_PREFIX before checking the
1604         # user's path.  Unfortunately, there is no good way to get at the
1605         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1606         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1607         # to be fixed as part of the make/configure rewrite too.
1608
1609         if test "x$exec_prefix" = xNONE; then
1610                 if test "x$prefix" = xNONE; then
1611                         test_prefix=/usr/local
1612                 else
1613                         test_prefix=$prefix
1614                 fi
1615         else
1616                 test_prefix=$exec_prefix
1617         fi
1618
1619         # If the loop below does not find an assembler, then use whatever
1620         # one we can find in the users's path.
1621         # user's path.
1622         if test "x$program_prefix" != xNONE; then
1623                 gcc_cv_as=${program_prefix}as$host_exeext
1624         else
1625                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1626         fi
1627
1628         test_dirs="$test_prefix/lib/gcc-lib/$target_noncanonical/$gcc_version \
1629                    $test_prefix/lib/gcc-lib/$target_noncanonical \
1630                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1631                    /usr/lib/gcc/$target_noncanonical \
1632                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1633                    $test_prefix/$target_noncanonical/bin"
1634
1635         if test x$host = x$target; then
1636             test_dirs="$test_dirs \
1637                    /usr/libexec \
1638                    /usr/ccs/gcc \
1639                    /usr/ccs/bin \
1640                    /udk/usr/ccs/bin \
1641                    /bsd43/usr/lib/cmplrs/cc \
1642                    /usr/cross64/usr/bin \
1643                    /usr/lib/cmplrs/cc \
1644                    /sysv/usr/lib/cmplrs/cc \
1645                    /svr4/usr/lib/cmplrs/cc \
1646                    /usr/bin"
1647         fi
1648
1649         for dir in $test_dirs; do
1650                 if test -x $dir/as$host_exeext; then
1651                         gcc_cv_as=$dir/as$host_exeext
1652                         break;
1653                 fi
1654         done
1655 fi
1656 case $in_tree_gas in
1657   yes)
1658     AC_MSG_RESULT("newly built gas")
1659     ;;
1660   no)
1661     AC_MSG_RESULT($gcc_cv_as)
1662     ;;
1663 esac
1664
1665 # Identify the linker which will work hand-in-glove with the newly
1666 # built GCC, so that we can examine its features.  This is the linker
1667 # which will be driven by the driver program.
1668 #
1669 # If build != host, and we aren't building gas in-tree, we identify a
1670 # build->target linker and hope that it will have the same features
1671 # as the host->target linker we'll be using.
1672 AC_MSG_CHECKING(what linker to use)
1673 in_tree_ld=no
1674 gcc_cv_ld=
1675 gcc_cv_gld_major_version=
1676 gcc_cv_gld_minor_version=
1677 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1678 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1679 if test -x "$DEFAULT_LINKER"; then
1680         gcc_cv_ld="$DEFAULT_LINKER"
1681 elif test -x "$LD"; then
1682         gcc_cv_ld="$LD"
1683 elif test -x collect-ld$host_exeext; then
1684         # Build using linker in the current directory.
1685         gcc_cv_ld=./collect-ld$host_exeext
1686 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1687      && test -f ../ld/Makefile; then
1688         # Single tree build which includes ld.
1689         in_tree_ld=yes
1690         in_tree_ld_is_elf=no
1691         if (grep 'EMUL = .*elf' ../ld/Makefile \
1692             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1693           in_tree_ld_is_elf=yes
1694         fi
1695         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1696         do
1697 changequote(,)dnl
1698                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1699 changequote([,])dnl
1700                 if test x$gcc_cv_gld_version != x; then
1701                         break
1702                 fi
1703         done
1704 changequote(,)dnl
1705         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1706         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1707 changequote([,])dnl
1708         rm -f collect-ld$host_exeext
1709         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1710                 2>/dev/null
1711 fi
1712
1713 if test "x$gcc_cv_ld" = x; then
1714         # Search the same directories that the installed compiler will
1715         # search.  Else we may find the wrong linker and lose.  If we
1716         # do not find a suitable linker binary, then try the user's
1717         # path.
1718         #
1719         # Also note we have to check MD_EXEC_PREFIX before checking the
1720         # user's path.  Unfortunately, there is no good way to get at the
1721         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1722         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1723         # to be fixed as part of the make/configure rewrite too.
1724
1725         if test "x$exec_prefix" = xNONE; then
1726                 if test "x$prefix" = xNONE; then
1727                         test_prefix=/usr/local
1728                 else
1729                         test_prefix=$prefix
1730                 fi
1731         else
1732                 test_prefix=$exec_prefix
1733         fi
1734
1735         # If the loop below does not find an linker, then use whatever
1736         # one we can find in the users's path.
1737         # user's path.
1738         if test "x$program_prefix" != xNONE; then
1739                 gcc_cv_ld=${program_prefix}ld$host_exeext
1740         else
1741                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1742         fi
1743
1744         test_dirs="$test_prefix/lib/gcc-lib/$target_noncanonical/$gcc_version \
1745                    $test_prefix/lib/gcc-lib/$target_noncanonical \
1746                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1747                    /usr/lib/gcc/$target_noncanonical \
1748                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1749                    $test_prefix/$target_noncanonical/bin"
1750
1751         if test x$host = x$target; then
1752             test_dirs="$test_dirs \
1753                    /usr/libexec \
1754                    /usr/ccs/gcc \
1755                    /usr/ccs/bin \
1756                    /udk/usr/ccs/bin \
1757                    /bsd43/usr/lib/cmplrs/cc \
1758                    /usr/cross64/usr/bin \
1759                    /usr/lib/cmplrs/cc \
1760                    /sysv/usr/lib/cmplrs/cc \
1761                    /svr4/usr/lib/cmplrs/cc \
1762                    /usr/bin"
1763         fi
1764
1765         for dir in $test_dirs; do
1766                 if test -x $dir/ld$host_exeext; then
1767                         gcc_cv_ld=$dir/ld$host_exeext
1768                         break;
1769                 fi
1770         done
1771 fi
1772 case $in_tree_ld in
1773   yes)
1774     AC_MSG_RESULT("newly built ld")
1775     ;;
1776   no)
1777     AC_MSG_RESULT($gcc_cv_ld)
1778     ;;
1779 esac
1780
1781 # Figure out what nm we will be using.
1782 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1783 AC_MSG_CHECKING(what nm to use)
1784 in_tree_nm=no
1785 if test -x nm$host_exeext; then
1786         gcc_cv_nm=./nm$host_exeext
1787 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1788      && test -f ../binutils/Makefile; then
1789         # Single tree build which includes binutils.
1790         in_tree_nm=yes
1791         gcc_cv_nm=./nm$host_exeext
1792         rm -f nm$host_exeext
1793         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1794 elif test "x$program_prefix" != xNONE; then
1795         gcc_cv_nm=${program_prefix}nm$host_exeext
1796 else
1797         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1798 fi
1799 case $in_tree_nm in
1800   yes) AC_MSG_RESULT("newly built nm") ;;
1801   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1802 esac
1803
1804 # Figure out what objdump we will be using.
1805 AC_MSG_CHECKING(what objdump to use)
1806 in_tree_objdump=no
1807 if test -x objdump$host_exeext; then
1808         gcc_cv_objdump=./objdump$host_exeext
1809 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1810      && test -f ../binutils/Makefile; then
1811         # Single tree build which includes binutils.
1812         in_tree_objdump=yes
1813         gcc_cv_objdump=./objdump$host_exeext
1814         rm -f objdump$host_exeext
1815         $symbolic_link ../binutils/objdump$host_exeext \
1816                 objdump$host_exeext 2>/dev/null
1817 elif test "x$program_prefix" != xNONE; then
1818         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1819 else
1820         gcc_cv_objdump=`echo objdump | \
1821                 sed ${program_transform_name}`$host_exeext
1822 fi
1823 case $in_tree_objdump in
1824   yes) AC_MSG_RESULT("newly built objdump") ;;
1825   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1826 esac
1827
1828 # Figure out what assembler alignment features are present.
1829 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1830  [2,6,0],,
1831 [.balign 4
1832 .p2align 2],,
1833 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1834   [Define if your assembler supports .balign and .p2align.])])
1835
1836 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1837  [2,8,0],,
1838  [.p2align 4,,7],,
1839 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1840   [Define if your assembler supports specifying the maximum number
1841    of bytes to skip when using the GAS .p2align command.])])
1842
1843 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1844  [elf,2,9,0],,
1845  [conftest_label1: .word 0
1846 .subsection -1
1847 conftest_label2: .word 0
1848 .previous],
1849  [if test x$gcc_cv_nm != x; then
1850     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1851     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1852     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1853     then :
1854     else gcc_cv_as_subsection_m1=yes
1855     fi
1856     rm -f conftest.nm1 conftest.nm2
1857   fi],
1858  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1859   [Define if your assembler supports .subsection and .subsection -1 starts
1860    emitting at the beginning of your section.])])
1861
1862 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1863  [2,2,0],,
1864  [      .weak foobar],,
1865 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1866
1867 # .hidden needs to be supported in both the assembler and the linker,
1868 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1869 # This is irritatingly difficult to feature test for; we have to check the
1870 # date string after the version number.  If we've got an in-tree
1871 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1872 # to be safe.
1873 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1874 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1875  [elf,2,13,0],,
1876 [       .hidden foobar
1877 foobar:])
1878
1879 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1880 [if test $in_tree_ld = yes ; then
1881   gcc_cv_ld_hidden=no
1882   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1883      && test $in_tree_ld_is_elf = yes; then
1884      gcc_cv_ld_hidden=yes
1885   fi
1886 else
1887   gcc_cv_ld_hidden=yes
1888   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
1889   if echo "$ld_ver" | grep GNU > /dev/null; then
1890 changequote(,)dnl
1891     ld_vers=`echo $ld_ver | sed -n \
1892         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1893         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1894         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1895         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1896         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1897         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1898     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1899     if test 0"$ld_date" -lt 20020404; then
1900       if test -n "$ld_date"; then
1901         # If there was date string, but was earlier than 2002-04-04, fail
1902         gcc_cv_ld_hidden=no
1903       elif test -z "$ld_vers"; then
1904         # If there was no date string nor ld version number, something is wrong
1905         gcc_cv_ld_hidden=no
1906       else
1907         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1908         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1909         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1910         test -z "$ld_vers_patch" && ld_vers_patch=0
1911         if test "$ld_vers_major" -lt 2; then
1912           gcc_cv_ld_hidden=no
1913         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1914           gcc_cv_ld_hidden="no"
1915         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1916           gcc_cv_ld_hidden=no
1917         fi
1918       fi
1919 changequote([,])dnl
1920     fi
1921   else
1922     case "${target}" in
1923       hppa64*-*-hpux* | ia64*-*-hpux*)
1924         gcc_cv_ld_hidden=yes
1925         ;;
1926       *)
1927         gcc_cv_ld_hidden=no
1928         ;;
1929     esac
1930   fi
1931 fi])
1932 libgcc_visibility=no
1933 AC_SUBST(libgcc_visibility)
1934 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
1935   libgcc_visibility=yes
1936   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1937   [Define if your assembler and linker support .hidden.])
1938 fi
1939
1940 # Check if we have .[us]leb128, and support symbol arithmetic with it.
1941 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
1942   [elf,2,11,0],,
1943 [       .data
1944         .uleb128 L2 - L1
1945 L1:
1946         .uleb128 1280
1947         .sleb128 -1010
1948 L2:],
1949  [# GAS versions before 2.11 do not support uleb128,
1950   # despite appearing to.
1951   # ??? There exists an elf-specific test that will crash
1952   # the assembler.  Perhaps it's better to figure out whether
1953   # arbitrary sections are supported and try the test.
1954   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
1955   if echo "$as_ver" | grep GNU > /dev/null; then
1956 changequote(,)dnl
1957     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1958     as_major=`echo $as_ver | sed 's/\..*//'`
1959     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1960 changequote([,])dnl
1961     if test $as_major -eq 2 && test $as_minor -lt 11
1962     then :
1963     else gcc_cv_as_leb128=yes
1964     fi
1965   fi],
1966   [AC_DEFINE(HAVE_AS_LEB128, 1,
1967     [Define if your assembler supports .sleb128 and .uleb128.])])
1968
1969 # GAS versions up to and including 2.11.0 may mis-optimize
1970 # .eh_frame data.
1971 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
1972   [elf,2,12,0],,
1973 [       .text
1974 .LFB1:
1975         .4byte  0
1976 .L1:
1977         .4byte  0
1978 .LFE1:
1979         .section        .eh_frame,"aw",@progbits
1980 __FRAME_BEGIN__:
1981         .4byte  .LECIE1-.LSCIE1
1982 .LSCIE1:
1983         .4byte  0x0
1984         .byte   0x1
1985         .ascii "z\0"
1986         .byte   0x1
1987         .byte   0x78
1988         .byte   0x1a
1989         .byte   0x0
1990         .byte   0x4
1991         .4byte  1
1992         .p2align 1
1993 .LECIE1:
1994 .LSFDE1:
1995         .4byte  .LEFDE1-.LASFDE1
1996 .LASFDE1:
1997         .4byte  .LASFDE1-__FRAME_BEGIN__
1998         .4byte  .LFB1
1999         .4byte  .LFE1-.LFB1
2000         .byte   0x4
2001         .4byte  .LFE1-.LFB1
2002         .byte   0x4
2003         .4byte  .L1-.LFB1
2004 .LEFDE1:],
2005 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2006 cat > conftest.lit <<EOF
2007  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2008  0010 01000000 12000000 18000000 00000000  ................
2009  0020 08000000 04080000 0044               .........D      @&t@
2010 EOF
2011 cat > conftest.big <<EOF
2012  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2013  0010 00000001 00000012 00000018 00000000  ................
2014  0020 00000008 04000000 0844               .........D      @&t@
2015 EOF
2016   # If the assembler didn't choke, and we can objdump,
2017   # and we got the correct data, then succeed.
2018   if test x$gcc_cv_objdump != x \
2019   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2020      | tail -3 > conftest.got \
2021   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2022     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2023   then
2024     gcc_cv_as_eh_frame=yes
2025   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2026     gcc_cv_as_eh_frame=buggy
2027   else
2028     # Uh oh, what do we do now?
2029     gcc_cv_as_eh_frame=no
2030   fi])
2031
2032 if test $gcc_cv_as_eh_frame = buggy; then
2033   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2034   [Define if your assembler mis-optimizes .eh_frame data.])
2035 fi
2036
2037 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2038  [elf,2,12,0], [--fatal-warnings],
2039  [.section .rodata.str, "aMS", @progbits, 1])
2040 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2041   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2042 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2043
2044 # Thread-local storage - the check is heavily parametrized.
2045 conftest_s=
2046 tls_first_major=
2047 tls_first_minor=
2048 tls_as_opt=
2049 case "$target" in
2050 changequote(,)dnl
2051   alpha*-*-*)
2052     conftest_s='
2053         .section ".tdata","awT",@progbits
2054 foo:    .long   25
2055         .text
2056         ldq     $27,__tls_get_addr($29)         !literal!1
2057         lda     $16,foo($29)                    !tlsgd!1
2058         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2059         ldq     $27,__tls_get_addr($29)         !literal!2
2060         lda     $16,foo($29)                    !tlsldm!2
2061         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2062         ldq     $1,foo($29)                     !gotdtprel
2063         ldah    $2,foo($29)                     !dtprelhi
2064         lda     $3,foo($2)                      !dtprello
2065         lda     $4,foo($29)                     !dtprel
2066         ldq     $1,foo($29)                     !gottprel
2067         ldah    $2,foo($29)                     !tprelhi
2068         lda     $3,foo($2)                      !tprello
2069         lda     $4,foo($29)                     !tprel'
2070         tls_first_major=2
2071         tls_first_minor=13
2072         tls_as_opt=--fatal-warnings
2073         ;;
2074   i[34567]86-*-*)
2075     conftest_s='
2076         .section ".tdata","awT",@progbits
2077 foo:    .long   25
2078         .text
2079         movl    %gs:0, %eax
2080         leal    foo@TLSGD(,%ebx,1), %eax
2081         leal    foo@TLSLDM(%ebx), %eax
2082         leal    foo@DTPOFF(%eax), %edx
2083         movl    foo@GOTTPOFF(%ebx), %eax
2084         subl    foo@GOTTPOFF(%ebx), %eax
2085         addl    foo@GOTNTPOFF(%ebx), %eax
2086         movl    foo@INDNTPOFF, %eax
2087         movl    $foo@TPOFF, %eax
2088         subl    $foo@TPOFF, %eax
2089         leal    foo@NTPOFF(%ecx), %eax'
2090         tls_first_major=2
2091         tls_first_minor=14
2092         tls_as_opt=--fatal-warnings
2093         ;;
2094   x86_64-*-*)
2095     conftest_s='
2096         .section ".tdata","awT",@progbits
2097 foo:    .long   25
2098         .text
2099         movq    %fs:0, %rax
2100         leaq    foo@TLSGD(%rip), %rdi
2101         leaq    foo@TLSLD(%rip), %rdi
2102         leaq    foo@DTPOFF(%rax), %rdx
2103         movq    foo@GOTTPOFF(%rip), %rax
2104         movq    $foo@TPOFF, %rax'
2105         tls_first_major=2
2106         tls_first_minor=14
2107         tls_as_opt=--fatal-warnings
2108         ;;
2109   ia64-*-*)
2110     conftest_s='
2111         .section ".tdata","awT",@progbits
2112 foo:    data8   25
2113         .text
2114         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2115         addl    r17 = @ltoff(@dtprel(foo#)), gp
2116         addl    r18 = @ltoff(@tprel(foo#)), gp
2117         addl    r19 = @dtprel(foo#), gp
2118         adds    r21 = @dtprel(foo#), r13
2119         movl    r23 = @dtprel(foo#)
2120         addl    r20 = @tprel(foo#), gp
2121         adds    r22 = @tprel(foo#), r13
2122         movl    r24 = @tprel(foo#)'
2123         tls_first_major=2
2124         tls_first_minor=13
2125         tls_as_opt=--fatal-warnings
2126         ;;
2127   powerpc-*-*)
2128     conftest_s='
2129         .section ".tdata","awT",@progbits
2130         .align 2
2131 ld0:    .space 4
2132 ld1:    .space 4
2133 x1:     .space 4
2134 x2:     .space 4
2135 x3:     .space 4
2136         .text
2137         addi 3,31,ld0@got@tlsgd
2138         bl __tls_get_addr
2139         addi 3,31,x1@got@tlsld
2140         bl __tls_get_addr
2141         addi 9,3,x1@dtprel
2142         addis 9,3,x2@dtprel@ha
2143         addi 9,9,x2@dtprel@l
2144         lwz 9,x3@got@tprel(31)
2145         add 9,9,x@tls
2146         addi 9,2,x1@tprel
2147         addis 9,2,x2@tprel@ha
2148         addi 9,9,x2@tprel@l'
2149         tls_first_major=2
2150         tls_first_minor=14
2151         tls_as_opt="-a32 --fatal-warnings"
2152         ;;
2153   powerpc64-*-*)
2154     conftest_s='
2155         .section ".tdata","awT",@progbits
2156         .align 3
2157 ld0:    .space 8
2158 ld1:    .space 8
2159 x1:     .space 8
2160 x2:     .space 8
2161 x3:     .space 8
2162         .text
2163         addi 3,2,ld0@got@tlsgd
2164         bl .__tls_get_addr
2165         nop
2166         addi 3,2,ld1@toc
2167         bl .__tls_get_addr
2168         nop
2169         addi 3,2,x1@got@tlsld
2170         bl .__tls_get_addr
2171         nop
2172         addi 9,3,x1@dtprel
2173         bl .__tls_get_addr
2174         nop
2175         addis 9,3,x2@dtprel@ha
2176         addi 9,9,x2@dtprel@l
2177         bl .__tls_get_addr
2178         nop
2179         ld 9,x3@got@dtprel(2)
2180         add 9,9,3
2181         bl .__tls_get_addr
2182         nop'
2183         tls_first_major=2
2184         tls_first_minor=14
2185         tls_as_opt="-a64 --fatal-warnings"
2186         ;;
2187   s390-*-*)
2188     conftest_s='
2189         .section ".tdata","awT",@progbits
2190 foo:    .long   25
2191         .text
2192         .long   foo@TLSGD
2193         .long   foo@TLSLDM
2194         .long   foo@DTPOFF
2195         .long   foo@NTPOFF
2196         .long   foo@GOTNTPOFF
2197         .long   foo@INDNTPOFF
2198         l       %r1,foo@GOTNTPOFF(%r12)
2199         l       %r1,0(%r1):tls_load:foo
2200         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2201         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2202         tls_first_major=2
2203         tls_first_minor=14
2204         tls_as_opt="-m31 --fatal-warnings"
2205         ;;
2206   s390x-*-*)
2207     conftest_s='
2208         .section ".tdata","awT",@progbits
2209 foo:    .long   25
2210         .text
2211         .quad   foo@TLSGD
2212         .quad   foo@TLSLDM
2213         .quad   foo@DTPOFF
2214         .quad   foo@NTPOFF
2215         .quad   foo@GOTNTPOFF
2216         lg      %r1,foo@GOTNTPOFF(%r12)
2217         larl    %r1,foo@INDNTPOFF
2218         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2219         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2220         tls_first_major=2
2221         tls_first_minor=14
2222         tls_as_opt="-m64 -Aesame --fatal-warnings"
2223         ;;
2224   sh-*-* | sh[34]-*-*)
2225     conftest_s='
2226         .section ".tdata","awT",@progbits
2227 foo:    .long   25
2228         .text
2229         .long   foo@TLSGD
2230         .long   foo@TLSLDM
2231         .long   foo@DTPOFF
2232         .long   foo@GOTTPOFF
2233         .long   foo@TPOFF'
2234         tls_first_major=2
2235         tls_first_minor=13
2236         tls_as_opt=--fatal-warnings
2237         ;;
2238   sparc*-*-*)
2239     case "$target" in
2240       sparc*-sun-solaris2.*)
2241         on_solaris=yes
2242         ;;
2243       *)
2244         on_solaris=no
2245         ;;
2246     esac
2247     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2248       conftest_s='
2249         .section ".tdata",#alloc,#write,#tls
2250 foo:    .long   25
2251         .text
2252         sethi   %tgd_hi22(foo), %o0
2253         add     %o0, %tgd_lo10(foo), %o1
2254         add     %l7, %o1, %o0, %tgd_add(foo)
2255         call    __tls_get_addr, %tgd_call(foo)
2256         sethi   %tldm_hi22(foo), %l1
2257         add     %l1, %tldm_lo10(foo), %l2
2258         add     %l7, %l2, %o0, %tldm_add(foo)
2259         call    __tls_get_addr, %tldm_call(foo)
2260         sethi   %tldo_hix22(foo), %l3
2261         xor     %l3, %tldo_lox10(foo), %l4
2262         add     %o0, %l4, %l5, %tldo_add(foo)
2263         sethi   %tie_hi22(foo), %o3
2264         add     %o3, %tie_lo10(foo), %o3
2265         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2266         add     %g7, %o2, %o4, %tie_add(foo)
2267         sethi   %tle_hix22(foo), %l1
2268         xor     %l1, %tle_lox10(foo), %o5
2269         ld      [%g7 + %o5], %o1'
2270         tls_first_major=0
2271         tls_first_minor=0
2272     else
2273       conftest_s='
2274         .section ".tdata","awT",@progbits
2275 foo:    .long   25
2276         .text
2277         sethi   %tgd_hi22(foo), %o0
2278         add     %o0, %tgd_lo10(foo), %o1
2279         add     %l7, %o1, %o0, %tgd_add(foo)
2280         call    __tls_get_addr, %tgd_call(foo)
2281         sethi   %tldm_hi22(foo), %l1
2282         add     %l1, %tldm_lo10(foo), %l2
2283         add     %l7, %l2, %o0, %tldm_add(foo)
2284         call    __tls_get_addr, %tldm_call(foo)
2285         sethi   %tldo_hix22(foo), %l3
2286         xor     %l3, %tldo_lox10(foo), %l4
2287         add     %o0, %l4, %l5, %tldo_add(foo)
2288         sethi   %tie_hi22(foo), %o3
2289         add     %o3, %tie_lo10(foo), %o3
2290         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2291         add     %g7, %o2, %o4, %tie_add(foo)
2292         sethi   %tle_hix22(foo), %l1
2293         xor     %l1, %tle_lox10(foo), %o5
2294         ld      [%g7 + %o5], %o1'
2295         tls_first_major=2
2296         tls_first_minor=14
2297         tls_as_opt="-32 --fatal-warnings"
2298       fi
2299         ;;
2300 changequote([,])dnl
2301 esac
2302 if test -z "$tls_first_major"; then
2303   : # If we don't have a check, assume no support.
2304 else
2305   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2306   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2307   [AC_DEFINE(HAVE_AS_TLS, 1,
2308             [Define if your assembler supports thread-local storage.])])
2309 fi
2310
2311 # Target-specific assembler checks.
2312
2313 case "$target" in
2314   # All TARGET_ABI_OSF targets.
2315   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2316     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2317         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2318 [       .set nomacro
2319         .text
2320         extbl   $3, $2, $3      !lituse_bytoff!1
2321         ldq     $2, a($29)      !literal!1
2322         ldq     $4, b($29)      !literal!2
2323         ldq_u   $3, 0($2)       !lituse_base!1
2324         ldq     $27, f($29)     !literal!5
2325         jsr     $26, ($27), f   !lituse_jsr!5
2326         ldah    $29, 0($26)     !gpdisp!3
2327         lda     $0, c($29)      !gprel
2328         ldah    $1, d($29)      !gprelhigh
2329         lda     $1, d($1)       !gprellow
2330         lda     $29, 0($29)     !gpdisp!3],,
2331     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2332   [Define if your assembler supports explicit relocations.])])
2333     ;;
2334
2335   sparc*-*-*)
2336     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2337       [.register %g2, #scratch],,
2338       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2339                 [Define if your assembler supports .register.])])
2340
2341     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2342       [-relax], [.text],,
2343       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2344                 [Define if your assembler supports -relax option.])])
2345
2346     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2347       gcc_cv_as_sparc_ua_pcrel,,
2348       [-K PIC],
2349 [.text
2350 foo:
2351         nop
2352 .data
2353 .align 4
2354 .byte 0
2355 .uaword %r_disp32(foo)],
2356       [if test x$gcc_cv_ld != x \
2357        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2358          gcc_cv_as_sparc_ua_pcrel=yes
2359        fi
2360        rm -f conftest],
2361       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2362                 [Define if your assembler and linker support unaligned PC relative relocs.])
2363
2364       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2365         gcc_cv_as_sparc_ua_pcrel_hidden,,
2366         [-K PIC],
2367 [.data
2368 .align 4
2369 .byte 0x31
2370 .uaword %r_disp32(foo)
2371 .byte 0x32, 0x33, 0x34
2372 .global foo
2373 .hidden foo
2374 foo:
2375 .skip 4],
2376         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2377          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2378          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2379             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2380             if $gcc_cv_objdump -R conftest 2> /dev/null \
2381                | grep 'DISP32' > /dev/null 2>&1; then
2382                 :
2383             else
2384                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2385             fi
2386          fi
2387          rm -f conftest],
2388          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2389                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2390     ]) # unaligned pcrel relocs
2391
2392     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2393       gcc_cv_as_sparc_offsetable_lo10,,
2394       [-xarch=v9],
2395 [.text
2396         or %g1, %lo(ab) + 12, %g1
2397         or %g1, %lo(ab + 12), %g1],
2398       [if test x$gcc_cv_objdump != x \
2399        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2400           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2401          gcc_cv_as_offsetable_lo10=yes
2402        fi],
2403        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2404                  [Define if your assembler supports offsetable %lo().])])
2405     ;;
2406
2407 changequote(,)dnl
2408   i[34567]86-*-* | x86_64-*-*)
2409 changequote([,])dnl
2410     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2411        gcc_cv_as_ix86_filds_fists,
2412       [2,9,0],, [filds mem; fists mem],,
2413       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2414         [Define if your assembler uses the new HImode fild and fist notation.])])
2415
2416     gcc_GAS_CHECK_FEATURE([cmov syntax],
2417       gcc_cv_as_ix86_cmov_sun_syntax,,,
2418       [cmovl.l %edx, %eax],,
2419       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2420         [Define if your assembler supports the Sun syntax for cmov.])])
2421
2422     # This one is used unconditionally by i386.[ch]; it is to be defined
2423     # to 1 if the feature is present, 0 otherwise.
2424     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2425         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2426 [       .text
2427 .L0:
2428         nop
2429         .data
2430         .long .L0@GOTOFF])
2431     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2432       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2433       [Define true if the assembler supports '.long foo@GOTOFF'.])
2434     ;;
2435
2436   ia64*-*-*)
2437     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2438         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2439 [       .text
2440         addl r15 = @ltoffx(x#), gp
2441         ;;
2442         ld8.mov r16 = [[r15]], x#],,
2443     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2444           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2445
2446     ;;
2447
2448   powerpc*-*-*)
2449     case $target in
2450       *-*-aix*) conftest_s='    .csect .text[[PR]]
2451         mfcr 3,128';;
2452       *-*-darwin*) conftest_s=' .text
2453         mfcr r3,128';;
2454       *)       conftest_s='     .text
2455         mfcr 3,128';;
2456     esac
2457
2458     gcc_GAS_CHECK_FEATURE([mfcr field support],
2459       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2460       [$conftest_s],,
2461       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2462           [Define if your assembler supports mfcr field.])])
2463     ;;
2464
2465   mips*-*-*)
2466     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2467       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2468 [       lw $4,%gp_rel(foo)($4)],,
2469       [if test x$target_cpu_default = x
2470        then target_cpu_default=MASK_EXPLICIT_RELOCS
2471        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2472        fi])
2473
2474     ;;
2475 esac
2476 # ??? Not all targets support dwarf2 debug_line, even within a version
2477 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2478 # info to the output file.  So, as supported targets are added to gas 2.11,
2479 # add some instruction here to (also) show we expect this might work.
2480 # ??? Once 2.11 is released, probably need to add first known working
2481 # version to the per-target configury.
2482 case "$target" in
2483   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2484   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2485   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2486     insn="nop"
2487     ;;
2488   ia64*-*-* | s390*-*-*)
2489     insn="nop 0"
2490     ;;
2491   mmix-*-*)
2492     insn="swym 0"
2493     ;;
2494 esac
2495 if test x"$insn" != x; then
2496  conftest_s="\
2497         .file 1 \"conftest.s\"
2498         .loc 1 3 0
2499         $insn"
2500  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2501   gcc_cv_as_dwarf2_debug_line,
2502   [elf,2,11,0],, [$conftest_s],
2503   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2504    if grep debug_line conftest.o > /dev/null 2>&1; then
2505      gcc_cv_as_dwarf2_debug_line=yes
2506    fi])
2507
2508 # The .debug_line file table must be in the exact order that
2509 # we specified the files, since these indices are also used
2510 # by DW_AT_decl_file.  Approximate this test by testing if
2511 # the assembler bitches if the same index is assigned twice.
2512  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2513   gcc_cv_as_dwarf2_file_buggy,,,
2514 [       .file 1 "foo.s"
2515         .file 1 "bar.s"])
2516
2517  if test $gcc_cv_as_dwarf2_debug_line = yes \
2518  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2519         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2520   [Define if your assembler supports dwarf2 .file/.loc directives,
2521    and preserves file table indices exactly as given.])
2522  fi
2523
2524  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2525   gcc_cv_as_gdwarf2_flag,
2526   [elf,2,11,0], [--gdwarf2], [$insn],,
2527   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2528 [Define if your assembler supports the --gdwarf2 option.])])
2529
2530  gcc_GAS_CHECK_FEATURE([--gstabs option],
2531   gcc_cv_as_gstabs_flag,
2532   [elf,2,11,0], [--gstabs], [$insn],
2533   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2534    # and warns about it, but still exits successfully.  So check for
2535    # this.
2536    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2537    then :
2538    else gcc_cv_as_gstabs_flag=yes
2539    fi],
2540   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2541 [Define if your assembler supports the --gstabs option.])])
2542 fi
2543
2544 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2545 gcc_cv_ld_ro_rw_mix=unknown
2546 if test $in_tree_ld = yes ; then
2547   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2548      && test $in_tree_ld_is_elf = yes; then
2549     gcc_cv_ld_ro_rw_mix=read-write
2550   fi
2551 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2552   echo '.section myfoosect, "a"' > conftest1.s
2553   echo '.section myfoosect, "aw"' > conftest2.s
2554   echo '.byte 1' >> conftest2.s
2555   echo '.section myfoosect, "a"' > conftest3.s
2556   echo '.byte 0' >> conftest3.s
2557   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2558      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2559      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2560      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2561         conftest2.o conftest3.o > /dev/null 2>&1; then
2562     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2563                          | sed -e '/myfoosect/!d' -e N`
2564     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2565       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2566         gcc_cv_ld_ro_rw_mix=read-only
2567       else
2568         gcc_cv_ld_ro_rw_mix=read-write
2569       fi
2570     fi
2571   fi
2572 changequote(,)dnl
2573   rm -f conftest.* conftest[123].*
2574 changequote([,])dnl
2575 fi
2576 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2577         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2578   [Define if your linker links a mix of read-only
2579    and read-write sections into a read-write section.])
2580 fi
2581 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2582
2583 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2584 gcc_cv_ld_eh_frame_hdr=no
2585 if test $in_tree_ld = yes ; then
2586   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2587      && test $in_tree_ld_is_elf = yes; then
2588     gcc_cv_ld_eh_frame_hdr=yes
2589   fi
2590 elif test x$gcc_cv_ld != x; then
2591         # Check if linker supports --eh-frame-hdr option
2592         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2593                 gcc_cv_ld_eh_frame_hdr=yes
2594         fi
2595 fi
2596 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2597         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2598 [Define if your linker supports --eh-frame-hdr option.])
2599 fi
2600 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2601
2602 AC_MSG_CHECKING(linker position independent executable support)
2603 gcc_cv_ld_pie=no
2604 if test $in_tree_ld = yes ; then
2605   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2606      && test $in_tree_ld_is_elf = yes; then
2607     gcc_cv_ld_pie=yes
2608   fi
2609 elif test x$gcc_cv_ld != x; then
2610         # Check if linker supports -pie option
2611         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2612                 gcc_cv_ld_pie=yes
2613         fi
2614 fi
2615 if test x"$gcc_cv_ld_pie" = xyes; then
2616         AC_DEFINE(HAVE_LD_PIE, 1,
2617 [Define if your linker supports -pie option.])
2618 fi
2619 AC_MSG_RESULT($gcc_cv_ld_pie)
2620
2621 if test x$with_sysroot = x && test x$host = x$target \
2622    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2623   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2624 [Define to PREFIX/include if cpp should also search that directory.])
2625 fi
2626
2627 # Figure out what language subdirectories are present.
2628 # Look if the user specified --enable-languages="..."; if not, use
2629 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2630 # go away some day.
2631 # NB:  embedded tabs in this IF block -- do not untabify
2632 if test x"${enable_languages+set}" != xset; then
2633         if test x"${LANGUAGES+set}" = xset; then
2634                 enable_languages="${LANGUAGES}"
2635                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2636
2637         else
2638                 enable_languages=all
2639         fi
2640 else
2641         if test x"${enable_languages}" = x \
2642         || test x"${enable_languages}" = xyes;
2643         then
2644                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2645         fi
2646 fi
2647 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2648
2649 # First scan to see if an enabled language requires some other language.
2650 # We assume that a given config-lang.in will list all the language
2651 # front ends it requires, even if some are required indirectly.
2652 for lang in ${srcdir}/*/config-lang.in
2653 do
2654    case $lang in
2655     # The odd quoting in the next line works around
2656     # an apparent bug in bash 1.12 on linux.
2657 changequote(,)dnl
2658     ${srcdir}/[*]/config-lang.in)
2659        ;;
2660     *)
2661        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2662        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2663        for other in $this_lang_requires
2664        do
2665           case ,${enable_languages}, in
2666            *,$other,*)
2667               ;;
2668            *,all,*)
2669               ;;
2670            *,$lang_alias,*)
2671               enable_languages="$enable_languages,$other"
2672               ;;
2673           esac
2674        done
2675        ;;
2676 changequote([,])dnl
2677    esac
2678 done
2679
2680 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2681 found_languages=
2682 subdirs=
2683 for lang in ${srcdir}/*/config-lang.in
2684 do
2685         case $lang in
2686         # The odd quoting in the next line works around
2687         # an apparent bug in bash 1.12 on linux.
2688 changequote(,)dnl
2689         ${srcdir}/[*]/config-lang.in) ;;
2690         *)
2691           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2692           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2693           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2694           if test "x$lang_alias" = x
2695           then
2696                 echo "$lang doesn't set \$language." 1>&2
2697                 exit 1
2698           fi
2699           case ${build_by_default},${enable_languages}, in
2700           *,$lang_alias,*) add_this_lang=yes ;;
2701           no,*) add_this_lang=no ;;
2702           *,all,*) add_this_lang=yes ;;
2703           *) add_this_lang=no ;;
2704           esac
2705           found_languages="${found_languages} ${lang_alias}"
2706           if test x"${add_this_lang}" = xyes; then
2707                 case $lang in
2708                     ${srcdir}/ada/config-lang.in)
2709                         if test x$have_gnat = xyes ; then
2710                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2711                         fi
2712                         ;;
2713                     *)
2714                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2715                         ;;
2716                 esac
2717           fi
2718           ;;
2719 changequote([,])dnl
2720         esac
2721 done
2722
2723 missing_languages=
2724 for expected_language in ${expected_languages} ..
2725 do
2726     if test "${expected_language}" != ..; then
2727         missing_language="${expected_language}"
2728         if test "${expected_language}" = "c" \
2729            || test "${expected_language}" = "all"; then
2730                 missing_language=
2731         fi
2732         for found_language in ${found_languages} ..
2733         do
2734             if test "${found_language}" != ..; then
2735                 if test "${expected_language}" = "${found_language}"; then
2736                     missing_language=
2737                 fi
2738             fi
2739         done
2740         if test "x${missing_language}" != x; then
2741            missing_languages="${missing_languages} ${missing_language}"
2742         fi
2743     fi
2744 done
2745
2746 if test "x$missing_languages" != x; then
2747   AC_MSG_ERROR([
2748 The following requested languages were not found:${missing_languages}
2749 The following languages were available: c${found_languages}])
2750 fi
2751
2752 # Make gthr-default.h if we have a thread file.
2753 gthread_flags=
2754 if test $thread_file != single; then
2755     rm -f gthr-default.h
2756     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2757     gthread_flags=-DHAVE_GTHR_DEFAULT
2758 fi
2759 AC_SUBST(gthread_flags)
2760
2761 # Find out what GC implementation we want, or may, use.
2762 AC_ARG_WITH(gc,
2763 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2764                           with the compiler],
2765 [case "$withval" in
2766   page | zone)
2767     GGC=ggc-$withval
2768     ;;
2769   *)
2770     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2771     ;;
2772 esac],
2773 [GGC=ggc-page])
2774 AC_SUBST(GGC)
2775 echo "Using $GGC for garbage collection."
2776
2777 # Use the system's zlib library.
2778 zlibdir=-L../zlib
2779 zlibinc="-I\$(srcdir)/../zlib"
2780 AC_ARG_WITH(system-zlib,
2781 [  --with-system-zlib      use installed libz],
2782 zlibdir=
2783 zlibinc=
2784 )
2785 AC_SUBST(zlibdir)
2786 AC_SUBST(zlibinc)
2787
2788 dnl Very limited version of automake's enable-maintainer-mode
2789
2790 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2791   dnl maintainer-mode is disabled by default
2792   AC_ARG_ENABLE(maintainer-mode,
2793 [  --enable-maintainer-mode
2794                           enable make rules and dependencies not useful
2795                           (and sometimes confusing) to the casual installer],
2796       maintainer_mode=$enableval,
2797       maintainer_mode=no)
2798
2799 AC_MSG_RESULT($maintainer_mode)
2800
2801 if test "$maintainer_mode" = "yes"; then
2802   MAINT=''
2803 else
2804   MAINT='#'
2805 fi
2806 AC_SUBST(MAINT)dnl
2807
2808 # Make empty files to contain the specs and options for each language.
2809 # Then add #include lines to for a compiler that has specs and/or options.
2810
2811 lang_opt_files=
2812 lang_specs_files=
2813 lang_tree_files=
2814 for subdir in . $subdirs
2815 do
2816         if test -f $srcdir/$subdir/lang.opt; then
2817             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2818         fi
2819         if test -f $srcdir/$subdir/lang-specs.h; then
2820             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2821         fi
2822         if test -f $srcdir/$subdir/$subdir-tree.def; then
2823             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2824         fi
2825 done
2826
2827 # These (without "all_") are set in each config-lang.in.
2828 # `language' must be a single word so is spelled singularly.
2829 all_languages=
2830 all_boot_languages=
2831 all_compilers=
2832 all_stagestuff=
2833 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2834 # List of language makefile fragments.
2835 all_lang_makefrags=
2836 # List of language subdirectory makefiles.  Deprecated.
2837 all_lang_makefiles=
2838 # Files for gengtype
2839 all_gtfiles="$target_gtfiles"
2840 # Files for gengtype with language
2841 all_gtfiles_files_langs=
2842 all_gtfiles_files_files=
2843
2844 # Add the language fragments.
2845 # Languages are added via two mechanisms.  Some information must be
2846 # recorded in makefile variables, these are defined in config-lang.in.
2847 # We accumulate them and plug them into the main Makefile.
2848 # The other mechanism is a set of hooks for each of the main targets
2849 # like `clean', `install', etc.
2850
2851 language_hooks="Make-hooks"
2852
2853 for s in $subdirs
2854 do
2855                 language=
2856                 boot_language=
2857                 compilers=
2858                 stagestuff=
2859                 outputs=
2860                 gtfiles=
2861                 . ${srcdir}/$s/config-lang.in
2862                 if test "x$language" = x
2863                 then
2864                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2865                         exit 1
2866                 fi
2867                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2868                 if test -f ${srcdir}/$s/Makefile.in
2869                 then all_lang_makefiles="$s/Makefile"
2870                 fi
2871                 all_languages="$all_languages $language"
2872                 if test "x$boot_language" = xyes
2873                 then
2874                         all_boot_languages="$all_boot_languages $language"
2875                 fi
2876                 all_compilers="$all_compilers $compilers"
2877                 all_stagestuff="$all_stagestuff $stagestuff"
2878                 all_outputs="$all_outputs $outputs"
2879                 all_gtfiles="$all_gtfiles $gtfiles"
2880                 for f in $gtfiles
2881                 do
2882                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2883                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2884                 done
2885 done
2886
2887 # Pick up gtfiles for c
2888 gtfiles=
2889 s="c"
2890 . ${srcdir}/c-config-lang.in
2891 all_gtfiles="$all_gtfiles $gtfiles"
2892 for f in $gtfiles
2893 do
2894         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2895         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2896 done
2897
2898 check_languages=
2899 for language in $all_languages
2900 do
2901                 check_languages="$check_languages check-$language"
2902 done
2903
2904 # We link each language in with a set of hooks, reached indirectly via
2905 # lang.${target}.
2906
2907 rm -f Make-hooks
2908 touch Make-hooks
2909 target_list="all.build all.cross start.encap rest.encap tags \
2910         install-normal install-common install-man \
2911         uninstall info man srcextra srcman srcinfo \
2912         mostlyclean clean distclean maintainer-clean \
2913         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2914 for t in $target_list
2915 do
2916         x=
2917         for lang in $all_languages
2918         do
2919                         x="$x $lang.$t"
2920         done
2921         echo "lang.$t: $x" >> Make-hooks
2922 done
2923
2924 # Create .gdbinit.
2925
2926 echo "dir ." > .gdbinit
2927 echo "dir ${srcdir}" >> .gdbinit
2928 if test x$gdb_needs_out_file_path = xyes
2929 then
2930         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2931 fi
2932 if test "x$subdirs" != x; then
2933         for s in $subdirs
2934         do
2935                 echo "dir ${srcdir}/$s" >> .gdbinit
2936         done
2937 fi
2938 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2939
2940 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2941 # absolute path for gcc_tooldir based on inserting the number of up-directory
2942 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2943 # $(libsubdir)/@(unlibsubdir) based path.
2944 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2945 # make and thus we'd get different behavior depending on where we built the
2946 # sources.
2947 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2948     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
2949 else
2950 changequote(<<, >>)dnl
2951 # An explanation of the sed strings:
2952 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2953 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2954 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2955 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2956 #
2957 # (*) Note this pattern overwrites the first character of the string
2958 # with a forward slash if one is not already present.  This is not a
2959 # problem because the exact names of the sub-directories concerned is
2960 # unimportant, just the number of them matters.
2961 #
2962 # The practical upshot of these patterns is like this:
2963 #
2964 #  prefix     exec_prefix        result
2965 #  ------     -----------        ------
2966 #   /foo        /foo/bar          ../
2967 #   /foo/       /foo/bar          ../
2968 #   /foo        /foo/bar/         ../
2969 #   /foo/       /foo/bar/         ../
2970 #   /foo        /foo/bar/ugg      ../../
2971 #
2972     dollar='$$'
2973     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
2974 changequote([, ])dnl
2975 fi
2976 AC_SUBST(gcc_tooldir)
2977 AC_SUBST(dollar)
2978
2979 # Find a directory in which to install a shared libgcc.
2980
2981 AC_ARG_ENABLE(version-specific-runtime-libs,
2982 [  --enable-version-specific-runtime-libs
2983                           specify that runtime libraries should be
2984                           installed in a compiler-specific directory])
2985
2986 AC_ARG_WITH(slibdir,
2987 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2988 slibdir="$with_slibdir",
2989 if test "${enable_version_specific_runtime_libs+set}" = set; then
2990   slibdir='$(libsubdir)'
2991 elif test "$host" != "$target"; then
2992   slibdir='$(build_tooldir)/lib'
2993 else
2994   slibdir='$(libdir)'
2995 fi)
2996 AC_SUBST(slibdir)
2997
2998 objdir=`${PWDCMD-pwd}`
2999 AC_SUBST(objdir)
3000
3001 # Substitute configuration variables
3002 AC_SUBST(subdirs)
3003 AC_SUBST(srcdir)
3004 AC_SUBST(all_boot_languages)
3005 AC_SUBST(all_compilers)
3006 AC_SUBST(all_gtfiles)
3007 AC_SUBST(all_gtfiles_files_langs)
3008 AC_SUBST(all_gtfiles_files_files)
3009 AC_SUBST(all_lang_makefrags)
3010 AC_SUBST(all_lang_makefiles)
3011 AC_SUBST(all_languages)
3012 AC_SUBST(all_stagestuff)
3013 AC_SUBST(build_exeext)
3014 AC_SUBST(build_install_headers_dir)
3015 AC_SUBST(build_xm_file_list)
3016 AC_SUBST(build_xm_include_list)
3017 AC_SUBST(build_xm_defines)
3018 AC_SUBST(check_languages)
3019 AC_SUBST(cc_set_by_configure)
3020 AC_SUBST(quoted_cc_set_by_configure)
3021 AC_SUBST(cpp_install_dir)
3022 AC_SUBST(xmake_file)
3023 AC_SUBST(tmake_file)
3024 AC_SUBST(extra_headers_list)
3025 AC_SUBST(extra_objs)
3026 AC_SUBST(extra_parts)
3027 AC_SUBST(extra_passes)
3028 AC_SUBST(extra_programs)
3029 AC_SUBST(float_h_file)
3030 AC_SUBST(gcc_config_arguments)
3031 AC_SUBST(gcc_gxx_include_dir)
3032 AC_SUBST(libstdcxx_incdir)
3033 AC_SUBST(gcc_version)
3034 AC_SUBST(gcc_version_full)
3035 AC_SUBST(gcc_version_trigger)
3036 AC_SUBST(host_exeext)
3037 AC_SUBST(host_extra_gcc_objs)
3038 AC_SUBST(host_xm_file_list)
3039 AC_SUBST(host_xm_include_list)
3040 AC_SUBST(host_xm_defines)
3041 AC_SUBST(out_host_hook_obj)
3042 AC_SUBST(install)
3043 AC_SUBST(lang_opt_files)
3044 AC_SUBST(lang_specs_files)
3045 AC_SUBST(lang_tree_files)
3046 AC_SUBST(local_prefix)
3047 AC_SUBST(md_file)
3048 AC_SUBST(objc_boehm_gc)
3049 AC_SUBST(out_file)
3050 AC_SUBST(out_object_file)
3051 AC_SUBST(stage_prefix_set_by_configure)
3052 AC_SUBST(quoted_stage_prefix_set_by_configure)
3053 AC_SUBST(symbolic_link)
3054 AC_SUBST(thread_file)
3055 AC_SUBST(tm_file_list)
3056 AC_SUBST(tm_include_list)
3057 AC_SUBST(tm_defines)
3058 AC_SUBST(tm_p_file_list)
3059 AC_SUBST(tm_p_include_list)
3060 AC_SUBST(xm_file_list)
3061 AC_SUBST(xm_include_list)
3062 AC_SUBST(xm_defines)
3063 AC_SUBST(target_noncanonical)
3064 AC_SUBST(c_target_objs)
3065 AC_SUBST(cxx_target_objs)
3066 AC_SUBST(target_cpu_default)
3067
3068 AC_SUBST_FILE(language_hooks)
3069
3070 # If it doesn't already exist, create document directory
3071 echo "checking for the document directory." 1>&2
3072 if test -d doc ; then
3073   true
3074 else
3075   mkdir doc
3076 fi
3077
3078 # Echo link setup.
3079 if test x${build} = x${host} ; then
3080   if test x${host} = x${target} ; then
3081     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3082   else
3083     echo "Links are now set up to build a cross-compiler" 1>&2
3084     echo " from ${host} to ${target}." 1>&2
3085   fi
3086 else
3087   if test x${host} = x${target} ; then
3088     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3089     echo " for ${target}." 1>&2
3090   else
3091     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3092     echo " from ${host} to ${target}." 1>&2
3093   fi
3094 fi
3095
3096 # Configure the subdirectories
3097 # AC_CONFIG_SUBDIRS($subdirs)
3098
3099 # Create the Makefile
3100 # and configure language subdirectories
3101 AC_CONFIG_FILES($all_outputs)
3102
3103 AC_CONFIG_COMMANDS([default],
3104 [
3105 case ${CONFIG_HEADERS} in
3106   *auto-host.h:config.in*)
3107   echo > cstamp-h ;;
3108 esac
3109 # Make sure all the subdirs exist.
3110 for d in $subdirs
3111 do
3112     test -d $d || mkdir $d
3113 done
3114 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3115 # bootstrapping and the installation procedure can still use
3116 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3117 # FLAGS_TO_PASS has been modified to solve the problem there.
3118 # This is virtually a duplicate of what happens in configure.lang; we do
3119 # an extra check to make sure this only happens if ln -s can be used.
3120 if test "$symbolic_link" = "ln -s"; then
3121  for d in ${subdirs} fixinc ; do
3122         STARTDIR=`${PWDCMD-pwd}`
3123         cd $d
3124         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3125         do
3126                 rm -f $t
3127                 $symbolic_link ../$t $t 2>/dev/null
3128         done
3129         cd $STARTDIR
3130  done
3131 else true ; fi
3132 ],
3133 [subdirs='$subdirs'
3134 symbolic_link='$symbolic_link'
3135 ])
3136 AC_OUTPUT