gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.64)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [AS_HELP_STRING([--with-local-prefix=DIR],
 109                 [specifies directory to put local include])],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
 128                 [specifies directory to put g++ header files])],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 145   fi
 146 fi
 147
 148 gcc_gxx_include_dir_add_sysroot=0
 149 if test "${with_sysroot+set}" = set; then
 150   gcc_gxx_without_sysroot=`expr "${gcc_gxx_include_dir}" : "${with_sysroot}"'\(.*\)'`
 151   if test "${gcc_gxx_without_sysroot}"; then
 152     gcc_gxx_include_dir="${gcc_gxx_without_sysroot}"
 153     gcc_gxx_include_dir_add_sysroot=1
 154   fi
 155 fi
 156
 157 AC_ARG_WITH(cpp_install_dir,
 158 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
 159                 [install the user visible C preprocessor in DIR
 160                  (relative to PREFIX) as well as PREFIX/bin])],
 161 [if test x$withval = xyes; then
 162   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 163 elif test x$withval != xno; then
 164   cpp_install_dir=$withval
 165 fi])
 166
 167 # We would like to our source tree to be readonly.  However when releases or
 168 # pre-releases are generated, the flex/bison generated files as well as the
 169 # various formats of manuals need to be included along with the rest of the
 170 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 171 # just that.
 172
 173 AC_MSG_CHECKING([whether to place generated files in the source directory])
 174   dnl generated-files-in-srcdir is disabled by default
 175   AC_ARG_ENABLE(generated-files-in-srcdir,
 176     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
 177                     [put copies of generated files in source dir
 178                      intended for creating source tarballs for users
 179                      without texinfo bison or flex])],
 180       generated_files_in_srcdir=$enableval,
 181       generated_files_in_srcdir=no)
 182
 183 AC_MSG_RESULT($generated_files_in_srcdir)
 184
 185 if test "$generated_files_in_srcdir" = "yes"; then
 186   GENINSRC=''
 187 else
 188   GENINSRC='#'
 189 fi
 190 AC_SUBST(GENINSRC)
 191
 192 # -------------------
 193 # Find default linker
 194 # -------------------
 195
 196 # With GNU ld
 197 AC_ARG_WITH(gnu-ld,
 198 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 199 gnu_ld_flag="$with_gnu_ld",
 200 gnu_ld_flag=no)
 201
 202 # With pre-defined ld
 203 AC_ARG_WITH(ld,
 204 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 205 DEFAULT_LINKER="$with_ld")
 206 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 207   if test ! -x "$DEFAULT_LINKER"; then
 208     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 209   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 210     gnu_ld_flag=yes
 211   fi
 212   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 213         [Define to enable the use of a default linker.])
 214 fi
 215
 216 AC_MSG_CHECKING([whether a default linker was specified])
 217 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 218   if test x"$gnu_ld_flag" = x"no"; then
 219     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 220   else
 221     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 222   fi
 223 else
 224   AC_MSG_RESULT(no)
 225 fi
 226
 227 # With demangler in GNU ld
 228 AC_ARG_WITH(demangler-in-ld,
 229 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 230 demangler_in_ld="$with_demangler_in_ld",
 231 demangler_in_ld=yes)
 232
 233 # ----------------------
 234 # Find default assembler
 235 # ----------------------
 236
 237 # With GNU as
 238 AC_ARG_WITH(gnu-as,
 239 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 240 gas_flag="$with_gnu_as",
 241 gas_flag=no)
 242
 243 AC_ARG_WITH(as,
 244 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 245 DEFAULT_ASSEMBLER="$with_as")
 246 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 247   if test ! -x "$DEFAULT_ASSEMBLER"; then
 248     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 249   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 250     gas_flag=yes
 251   fi
 252   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 253         [Define to enable the use of a default assembler.])
 254 fi
 255
 256 AC_MSG_CHECKING([whether a default assembler was specified])
 257 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 258   if test x"$gas_flag" = x"no"; then
 259     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 260   else
 261     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 262   fi
 263 else
 264   AC_MSG_RESULT(no)
 265 fi
 266
 267 # ---------------
 268 # Find C compiler
 269 # ---------------
 270
 271 # If a non-executable a.out is present (e.g. created by GNU as above even if
 272 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 273 # file, even when creating an executable, so an execution test fails.
 274 # Remove possible default executable files to avoid this.
 275 #
 276 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 277 # Autoconf includes it.
 278 rm -f a.out a.exe b.out
 279
 280 # Find the native compiler
 281 AC_PROG_CC
 282 AM_PROG_CC_C_O
 283 AC_PROG_CXX
 284 ACX_PROG_GNAT([-I"$srcdir"/ada])
 285
 286 # autoconf is lame and doesn't give us any substitution variable for this.
 287 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 288   NO_MINUS_C_MINUS_O=yes
 289 else
 290   OUTPUT_OPTION='-o $@'
 291 fi
 292 AC_SUBST(NO_MINUS_C_MINUS_O)
 293 AC_SUBST(OUTPUT_OPTION)
 294
 295 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 296 # optimizations to be activated explicitly by the toplevel.
 297 case "$CC" in
 298   */prev-gcc/xgcc*) ;;
 299   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 300 esac
 301 AC_SUBST(CFLAGS)
 302
 303 # Determine PICFLAG for target gnatlib.
 304 GCC_PICFLAG_FOR_TARGET
 305 AC_SUBST(PICFLAG_FOR_TARGET)
 306
 307 # -------------------------
 308 # Check C compiler features
 309 # -------------------------
 310
 311 AC_USE_SYSTEM_EXTENSIONS
 312 AC_PROG_CPP
 313 AC_C_INLINE
 314
 315 AC_SYS_LARGEFILE
 316
 317 # sizeof(char) is 1 by definition.
 318 AC_CHECK_SIZEOF(void *)
 319 AC_CHECK_SIZEOF(short)
 320 AC_CHECK_SIZEOF(int)
 321 AC_CHECK_SIZEOF(long)
 322 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 323 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 324 GCC_STDINT_TYPES
 325
 326 # ---------------------
 327 # Warnings and checking
 328 # ---------------------
 329
 330 # Check $CC warning features (if it's GCC).
 331 # We want to use -pedantic, but we don't want warnings about
 332 # * 'long long'
 333 # * variadic macros
 334 # * overlong strings
 335 # * C++11 narrowing conversions in { }
 336 # So, we only use -pedantic if we can disable those warnings.
 337
 338 ACX_PROG_CC_WARNING_OPTS(
 339         m4_quote(m4_do([-W -Wall -Wno-narrowing -Wwrite-strings -Wcast-qual])), [loose_warn])
 340 ACX_PROG_CC_WARNING_OPTS(
 341         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 342         [c_loose_warn])
 343 ACX_PROG_CC_WARNING_OPTS(
 344         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 345 ACX_PROG_CC_WARNING_OPTS(
 346         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 347 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 348         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 349                        [-Wno-overlength-strings])), [strict_warn])
 350 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 351
 352 # The above macros do nothing if the compiler is not GCC.  However, the
 353 # Makefile has more goo to add other flags, so these variables are used
 354 # to enable warnings only for GCC.
 355 warn_cflags=
 356 warn_cxxflags=
 357 if test "x$GCC" = "xyes"; then
 358   warn_cflags='$(GCC_WARN_CFLAGS)'
 359   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 360 fi
 361 AC_SUBST(warn_cflags)
 362 AC_SUBST(warn_cxxflags)
 363
 364 # Disable exceptions and RTTI if building with g++
 365 ACX_PROG_CC_WARNING_OPTS(
 366         m4_quote(m4_do([-fno-exceptions -fno-rtti])), [noexception_flags])
 367
 368 # Enable expensive internal checks
 369 is_release=
 370 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 371   is_release=yes
 372 fi
 373
 374 AC_ARG_ENABLE(checking,
 375 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 376                 [enable expensive run-time checks.  With LIST,
 377                  enable only specific categories of checks.
 378                  Categories are: yes,no,all,none,release.
 379                  Flags are: assert,df,fold,gc,gcac,gimple,misc,
 380                  rtlflag,rtl,runtime,tree,valgrind,types])],
 381 [ac_checking_flags="${enableval}"],[
 382 # Determine the default checks.
 383 if test x$is_release = x ; then
 384   ac_checking_flags=yes
 385 else
 386   ac_checking_flags=release
 387 fi])
 388 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 389 for check in release $ac_checking_flags
 390 do
 391         case $check in
 392         # these set all the flags to specific states
 393         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 394                         ac_fold_checking= ; ac_gc_checking=1 ;
 395                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 396                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 397                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 398                         ac_types_checking=1 ;;
 399         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 400                         ac_fold_checking= ; ac_gc_checking= ;
 401                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 402                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 403                         ac_tree_checking= ; ac_valgrind_checking= ;
 404                         ac_types_checking= ;;
 405         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 406                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 407                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 408                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 409                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 410                         ac_types_checking=1 ;;
 411         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 412                         ac_fold_checking= ; ac_gc_checking= ;
 413                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 414                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 415                         ac_tree_checking= ; ac_valgrind_checking= ;
 416                         ac_types_checking= ;;
 417         # these enable particular checks
 418         assert)         ac_assert_checking=1 ;;
 419         df)             ac_df_checking=1 ;;
 420         fold)           ac_fold_checking=1 ;;
 421         gc)             ac_gc_checking=1 ;;
 422         gcac)           ac_gc_always_collect=1 ;;
 423         gimple)         ac_gimple_checking=1 ;;
 424         misc)           ac_checking=1 ;;
 425         rtl)            ac_rtl_checking=1 ;;
 426         rtlflag)        ac_rtlflag_checking=1 ;;
 427         runtime)        ac_runtime_checking=1 ;;
 428         tree)           ac_tree_checking=1 ;;
 429         types)          ac_types_checking=1 ;;
 430         valgrind)       ac_valgrind_checking=1 ;;
 431         *)      AC_MSG_ERROR(unknown check category $check) ;;
 432         esac
 433 done
 434 IFS="$ac_save_IFS"
 435
 436 nocommon_flag=""
 437 if test x$ac_checking != x ; then
 438   AC_DEFINE(ENABLE_CHECKING, 1,
 439 [Define if you want more run-time sanity checks.  This one gets a grab
 440    bag of miscellaneous but relatively cheap checks.])
 441   nocommon_flag=-fno-common
 442 fi
 443 AC_SUBST(nocommon_flag)
 444 if test x$ac_df_checking != x ; then
 445   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 446 [Define if you want more run-time sanity checks for dataflow.])
 447 fi
 448 if test x$ac_assert_checking != x ; then
 449   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 450 [Define if you want assertions enabled.  This is a cheap check.])
 451 fi
 452 if test x$ac_gimple_checking != x ; then
 453   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 454 [Define if you want operations on GIMPLE (the basic data structure of
 455 the high-level optimizers) to be checked for dynamic type safety at
 456 runtime.  This is moderately expensive.])
 457 fi
 458 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 459 if test x$ac_runtime_checking != x ; then
 460   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 461 [Define if you want runtime assertions enabled.  This is a cheap check.])
 462 fi
 463 if test x$ac_tree_checking != x ; then
 464   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 465 [Define if you want all operations on trees (the basic data
 466    structure of the front ends) to be checked for dynamic type safety
 467    at runtime.  This is moderately expensive.  The tree browser debugging
 468    routines will also be enabled by this option.
 469    ])
 470   TREEBROWSER=tree-browser.o
 471 fi
 472 if test x$ac_types_checking != x ; then
 473   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 474 [Define if you want all gimple types to be verified after gimplifiation.
 475    This is cheap.
 476    ])
 477 fi
 478 AC_SUBST(TREEBROWSER)
 479 if test x$ac_rtl_checking != x ; then
 480   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 481 [Define if you want all operations on RTL (the basic data structure
 482    of the optimizer and back end) to be checked for dynamic type safety
 483    at runtime.  This is quite expensive.])
 484 fi
 485 if test x$ac_rtlflag_checking != x ; then
 486   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 487 [Define if you want RTL flag accesses to be checked against the RTL
 488    codes that are supported for each access macro.  This is relatively
 489    cheap.])
 490 fi
 491 if test x$ac_gc_checking != x ; then
 492   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 493 [Define if you want the garbage collector to do object poisoning and
 494    other memory allocation checks.  This is quite expensive.])
 495 fi
 496 if test x$ac_gc_always_collect != x ; then
 497   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 498 [Define if you want the garbage collector to operate in maximally
 499    paranoid mode, validating the entire heap and collecting garbage at
 500    every opportunity.  This is extremely expensive.])
 501 fi
 502 if test x$ac_fold_checking != x ; then
 503   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 504 [Define if you want fold checked that it never destructs its argument.
 505    This is quite expensive.])
 506 fi
 507 valgrind_path_defines=
 508 valgrind_command=
 509
 510 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 511 dnl # an if statement.  This was the source of very frustrating bugs
 512 dnl # in converting to autoconf 2.5x!
 513 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 514
 515 if test x$ac_valgrind_checking != x ; then
 516   # It is certainly possible that there's valgrind but no valgrind.h.
 517   # GCC relies on making annotations so we must have both.
 518   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 519   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 520     [[#include <valgrind/memcheck.h>
 521 #ifndef VALGRIND_DISCARD
 522 #error VALGRIND_DISCARD not defined
 523 #endif]])],
 524   [gcc_cv_header_valgrind_memcheck_h=yes],
 525   [gcc_cv_header_valgrind_memcheck_h=no])
 526   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 527   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 528   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 529     [[#include <memcheck.h>
 530 #ifndef VALGRIND_DISCARD
 531 #error VALGRIND_DISCARD not defined
 532 #endif]])],
 533   [gcc_cv_header_memcheck_h=yes],
 534   [gcc_cv_header_memcheck_h=no])
 535   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 536   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 537         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 538   if test "x$valgrind_path" = "x" \
 539     || (test $have_valgrind_h = no \
 540         && test $gcc_cv_header_memcheck_h = no \
 541         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 542         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 543   fi
 544   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 545   valgrind_command="$valgrind_path -q"
 546   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 547 [Define if you want to run subprograms and generated programs
 548    through valgrind (a memory checker).  This is extremely expensive.])
 549   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 550     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 551         [Define if valgrind's valgrind/memcheck.h header is installed.])
 552   fi
 553   if test $gcc_cv_header_memcheck_h = yes; then
 554     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 555         [Define if valgrind's memcheck.h header is installed.])
 556   fi
 557 fi
 558 AC_SUBST(valgrind_path_defines)
 559 AC_SUBST(valgrind_command)
 560
 561 # Enable code coverage collection
 562 AC_ARG_ENABLE(coverage,
 563 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
 564                 [enable compiler's code coverage collection.
 565                  Use to measure compiler performance and locate
 566                  unused parts of the compiler. With LEVEL, specify
 567                  optimization. Values are opt, noopt,
 568                  default is noopt])],
 569 [case "${enableval}" in
 570   yes|noopt)
 571     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 572     ;;
 573   opt)
 574     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 575     ;;
 576   no)
 577     # a.k.a. --disable-coverage
 578     coverage_flags=""
 579     ;;
 580   *)
 581     AC_MSG_ERROR(unknown coverage setting $enableval)
 582     ;;
 583 esac],
 584 [coverage_flags=""])
 585 AC_SUBST(coverage_flags)
 586
 587 AC_ARG_ENABLE(gather-detailed-mem-stats,
 588 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
 589                 [enable detailed memory allocation stats gathering])], [],
 590 [enable_gather_detailed_mem_stats=no])
 591 if test x$enable_gather_detailed_mem_stats = xyes ; then
 592   AC_DEFINE(GATHER_STATISTICS, 1,
 593         [Define to enable detailed memory allocation stats gathering.])
 594 fi
 595
 596 # -------------------------------
 597 # Miscenalleous configure options
 598 # -------------------------------
 599
 600 # See if we are building gcc with C++.
 601 AC_ARG_ENABLE(build-with-cxx,
 602 [AS_HELP_STRING([--enable-build-with-cxx],
 603                 [build with C++ compiler instead of C compiler])],
 604 ENABLE_BUILD_WITH_CXX=$enableval,
 605 ENABLE_BUILD_WITH_CXX=no)
 606 AC_SUBST(ENABLE_BUILD_WITH_CXX)
 607 if test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
 608   AC_DEFINE(ENABLE_BUILD_WITH_CXX, 1,
 609             [Define if building with C++.])
 610 fi
 611
 612 # With stabs
 613 AC_ARG_WITH(stabs,
 614 [AS_HELP_STRING([--with-stabs],
 615                 [arrange to use stabs instead of host debug format])],
 616 stabs="$with_stabs",
 617 stabs=no)
 618
 619 # Determine whether or not multilibs are enabled.
 620 AC_ARG_ENABLE(multilib,
 621 [AS_HELP_STRING([--enable-multilib],
 622                 [enable library support for multiple ABIs])],
 623 [], [enable_multilib=yes])
 624 AC_SUBST(enable_multilib)
 625
 626 # Enable __cxa_atexit for C++.
 627 AC_ARG_ENABLE(__cxa_atexit,
 628 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 629 [], [])
 630
 631 # Enable C extension for decimal float if target supports it.
 632 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 633
 634 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 635 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 636 [Define to 1 to enable decimal float extension to C.])
 637
 638 # Use default_decimal_float for dependency.
 639 enable_decimal_float=$default_decimal_float
 640
 641 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 642 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 643 [Define to 1 to specify that we are using the BID decimal floating
 644 point format instead of DPD])
 645
 646 # Enable C extension for fixed-point arithmetic.
 647 AC_ARG_ENABLE(fixed-point,
 648 [AS_HELP_STRING([--enable-fixed-point],
 649                 [enable fixed-point arithmetic extension to C])],
 650 [],
 651 [
 652   case $target in
 653     arm*)
 654       enable_fixed_point=yes
 655       ;;
 656
 657     mips*-*-*)
 658       enable_fixed_point=yes
 659       ;;
 660     *)
 661       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 662       enable_fixed_point=no
 663       ;;
 664   esac
 665 ])
 666 AC_SUBST(enable_fixed_point)
 667
 668 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 669 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 670 [Define to 1 to enable fixed-point arithmetic extension to C.])
 671
 672 # Enable threads
 673 # Pass with no value to take the default
 674 # Pass with a value to specify a thread package
 675 AC_ARG_ENABLE(threads,
 676 [AS_HELP_STRING([[--enable-threads[=LIB]]],
 677                 [enable thread usage for target GCC,
 678                  using LIB thread package])],,
 679 [enable_threads=''])
 680
 681 AC_ARG_ENABLE(tls,
 682 [AS_HELP_STRING([--enable-tls],
 683                 [enable or disable generation of tls code
 684                  overriding the assembler check for tls support])],
 685 [
 686   case $enable_tls in
 687     yes | no) ;;
 688     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 689 Valid choices are 'yes' and 'no'.]) ;;
 690   esac
 691 ], [enable_tls=''])
 692
 693 AC_ARG_ENABLE(objc-gc,
 694 [AS_HELP_STRING([--enable-objc-gc],
 695                 [enable the use of Boehm's garbage collector with
 696                  the GNU Objective-C runtime])],
 697 if test x$enable_objc_gc = xno; then
 698         objc_boehm_gc=''
 699 else
 700         objc_boehm_gc=1
 701 fi,
 702 objc_boehm_gc='')
 703
 704 AC_ARG_WITH(dwarf2,
 705 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
 706 dwarf2="$with_dwarf2",
 707 dwarf2=no)
 708
 709 AC_ARG_ENABLE(shared,
 710 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
 711 [
 712   case $enable_shared in
 713   yes | no) ;;
 714   *)
 715     enable_shared=no
 716     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 717     for pkg in $enableval; do
 718       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 719         enable_shared=yes
 720       fi
 721     done
 722     IFS="$ac_save_ifs"
 723     ;;
 724   esac
 725 ], [enable_shared=yes])
 726 AC_SUBST(enable_shared)
 727
 728 AC_ARG_WITH([native-system-header-dir],
 729   [  --with-native-system-header-dir=dir
 730                           use dir as the directory to look for standard
 731                           system header files in.  Defaults to /usr/include.],
 732 [
 733  case ${with_native_system_header_dir} in
 734  yes|no) AC_MSG_ERROR([bad value ${withval} given for --with-native-system-header-dir]) ;;
 735  /* | [[A-Za-z]]:[[\\/]]*) ;;
 736  *) AC_MSG_ERROR([--with-native-system-header-dir argument ${withval} must be an absolute directory]) ;;
 737  esac
 738  configured_native_system_header_dir="${withval}"
 739 ], [configured_native_system_header_dir=])
 740
 741 AC_ARG_WITH(build-sysroot,
 742   [AS_HELP_STRING([--with-build-sysroot=sysroot],
 743                   [use sysroot as the system root during the build])],
 744   [if test x"$withval" != x ; then
 745      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
 746    fi],
 747   [SYSROOT_CFLAGS_FOR_TARGET=])
 748 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 749
 750 AC_ARG_WITH(sysroot,
 751 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
 752                 [search for usr/lib, usr/include, et al, within DIR])],
 753 [
 754  case ${with_sysroot} in
 755  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 756  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 757  esac
 758
 759  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 760  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 761
 762  if test "x$prefix" = xNONE; then
 763   test_prefix=/usr/local
 764  else
 765   test_prefix=$prefix
 766  fi
 767  if test "x$exec_prefix" = xNONE; then
 768   test_exec_prefix=$test_prefix
 769  else
 770   test_exec_prefix=$exec_prefix
 771  fi
 772  case ${TARGET_SYSTEM_ROOT} in
 773  "${test_prefix}"|"${test_prefix}/"*|\
 774  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 775  '${prefix}'|'${prefix}/'*|\
 776  '${exec_prefix}'|'${exec_prefix}/'*)
 777    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 778    TARGET_SYSTEM_ROOT_DEFINE="$t"
 779    ;;
 780  esac
 781 ], [
 782  TARGET_SYSTEM_ROOT=
 783  TARGET_SYSTEM_ROOT_DEFINE=
 784  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 785 ])
 786 AC_SUBST(TARGET_SYSTEM_ROOT)
 787 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 788 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 789
 790 AC_ARG_WITH(specs,
 791   [AS_HELP_STRING([--with-specs=SPECS],
 792                   [add SPECS to driver command-line processing])],
 793   [CONFIGURE_SPECS=$withval],
 794   [CONFIGURE_SPECS=]
 795 )
 796 AC_SUBST(CONFIGURE_SPECS)
 797
 798 ACX_PKGVERSION([GCC])
 799 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 800
 801 # Sanity check enable_languages in case someone does not run the toplevel
 802 # configure # script.
 803 AC_ARG_ENABLE(languages,
 804 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
 805 [case ,${enable_languages}, in
 806        ,,|,yes,)
 807                 # go safe -- we cannot be much sure without the toplevel
 808                 # configure's
 809                 # analysis of which target libs are present and usable
 810                 enable_languages=c
 811                 ;;
 812          *,all,*)
 813                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 814                 ;;
 815         *,c,*)
 816                 ;;
 817         *)
 818                 enable_languages=c,${enable_languages}
 819                 ;;
 820 esac],
 821 [enable_languages=c])
 822
 823 AC_ARG_WITH(multilib-list,
 824 [AS_HELP_STRING([--with-multilib-list], [select multilibs (SH and x86-64 only)])],
 825 :,
 826 with_multilib_list=default)
 827
 828 # -------------------------
 829 # Checks for other programs
 830 # -------------------------
 831
 832 AC_PROG_MAKE_SET
 833
 834 # Find some useful tools
 835 AC_PROG_AWK
 836 # We need awk to create options.c and options.h.
 837 # Bail out if it's missing.
 838 case ${AWK} in
 839   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 840 esac
 841
 842 gcc_AC_PROG_LN_S
 843 ACX_PROG_LN($LN_S)
 844 AC_PROG_RANLIB
 845 ranlib_flags=""
 846 AC_SUBST(ranlib_flags)
 847
 848 gcc_AC_PROG_INSTALL
 849
 850 # See if cmp has --ignore-initial.
 851 gcc_AC_PROG_CMP_IGNORE_INITIAL
 852
 853 # See if we have the mktemp command.
 854 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 855
 856 # See if makeinfo has been installed and is modern enough
 857 # that we can use it.
 858 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 859   [GNU texinfo.* \([0-9][0-9.]*\)],
 860   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 861 if test $gcc_cv_prog_makeinfo_modern = no; then
 862   AC_MSG_WARN([
 863 *** Makeinfo is missing or too old.
 864 *** Info documentation will not be built.])
 865   BUILD_INFO=
 866 else
 867   BUILD_INFO=info
 868 fi
 869 AC_SUBST(BUILD_INFO)
 870
 871 # Is pod2man recent enough to regenerate manpages?
 872 AC_MSG_CHECKING([for recent Pod::Man])
 873 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 874   AC_MSG_RESULT(yes)
 875   GENERATED_MANPAGES=generated-manpages
 876 else
 877   AC_MSG_RESULT(no)
 878   GENERATED_MANPAGES=
 879 fi
 880 AC_SUBST(GENERATED_MANPAGES)
 881
 882 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 883
 884 # How about lex?
 885 dnl Don't use AC_PROG_LEX; we insist on flex.
 886 dnl LEXLIB is not useful in gcc.
 887 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 888
 889 # Bison?
 890 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 891
 892 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 893 # check for build == host before using them.
 894
 895 # NM
 896 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 897   && test -d ../binutils ; then
 898   NM='${objdir}/../binutils/nm-new'
 899 else
 900   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 901 fi
 902
 903 # AR
 904 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 905   && test -d ../binutils ; then
 906   AR='${objdir}/../binutils/ar'
 907 else
 908   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 909 fi
 910
 911
 912 # --------------------
 913 # Checks for C headers
 914 # --------------------
 915
 916 # Need to reject headers which give warnings, so that the -Werror bootstrap
 917 # works later. *sigh*  This needs to come before all header checks.
 918 AC_PROG_CPP_WERROR
 919
 920 AC_HEADER_STDC
 921 AC_HEADER_TIME
 922 ACX_HEADER_STRING
 923 AC_HEADER_SYS_WAIT
 924 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 925                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 926                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 927                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 928
 929 # Check for thread headers.
 930 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 931 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 932
 933 # These tests can't be done till we know if we have limits.h.
 934 gcc_AC_C_CHAR_BIT
 935 AC_C_BIGENDIAN
 936
 937 # ----------------------
 938 # Checks for C++ headers
 939 # ----------------------
 940
 941 dnl Autoconf will give an error in the configure script if there is no
 942 dnl C++ preprocessor.  Hack to prevent that.
 943 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
 944 AC_PROG_CXXCPP
 945 m4_popdef([AC_MSG_ERROR])[]dnl
 946
 947 AC_LANG_PUSH(C++)
 948
 949 AC_CHECK_HEADERS(unordered_map)
 950 AC_CHECK_HEADERS(tr1/unordered_map)
 951 AC_CHECK_HEADERS(ext/hash_map)
 952
 953 AC_LANG_POP(C++)
 954
 955 # --------
 956 # UNSORTED
 957 # --------
 958
 959
 960 # These libraries may be used by collect2.
 961 # We may need a special search path to get them linked.
 962 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 963 [save_LIBS="$LIBS"
 964 for libs in '' -lld -lmld \
 965                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 966                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 967 do
 968         LIBS="$libs"
 969         AC_TRY_LINK_FUNC(ldopen,
 970                 [gcc_cv_collect2_libs="$libs"; break])
 971 done
 972 LIBS="$save_LIBS"
 973 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 974 case $gcc_cv_collect2_libs in
 975         "none required")        ;;
 976         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 977 esac
 978 AC_SUBST(COLLECT2_LIBS)
 979
 980 # When building Ada code on Alpha, we need exc_resume which is usually in
 981 # -lexc.  So test for it.
 982 save_LIBS="$LIBS"
 983 LIBS=
 984 AC_SEARCH_LIBS(exc_resume, exc)
 985 GNAT_LIBEXC="$LIBS"
 986 LIBS="$save_LIBS"
 987 AC_SUBST(GNAT_LIBEXC)
 988
 989 # To support -mcpu=native on Solaris/SPARC, we need libkstat.
 990 save_LIBS="$LIBS"
 991 LIBS=
 992 AC_SEARCH_LIBS(kstat_open, kstat)
 993 EXTRA_GCC_LIBS="$LIBS"
 994 LIBS="$save_LIBS"
 995 AC_SUBST(EXTRA_GCC_LIBS)
 996
 997 # Some systems put ldexp and frexp in libm instead of libc; assume
 998 # they're both in the same place.  jcf-dump needs them.
 999 save_LIBS="$LIBS"
1000 LIBS=
1001 AC_SEARCH_LIBS(ldexp, m)
1002 LDEXP_LIB="$LIBS"
1003 LIBS="$save_LIBS"
1004 AC_SUBST(LDEXP_LIB)
1005
1006 # Use <inttypes.h> only if it exists,
1007 # doesn't clash with <sys/types.h>, and declares intmax_t.
1008 AC_MSG_CHECKING(for inttypes.h)
1009 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1010 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1011 [[#include <sys/types.h>
1012 #include <inttypes.h>]],
1013   [[intmax_t i = -1;]])],
1014   [gcc_cv_header_inttypes_h=yes],
1015   [gcc_cv_header_inttypes_h=no])])
1016 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1017 if test $gcc_cv_header_inttypes_h = yes; then
1018   AC_DEFINE(HAVE_INTTYPES_H, 1,
1019         [Define if you have a working <inttypes.h> header file.])
1020 fi
1021
1022 dnl Disabled until we have a complete test for buggy enum bitfields.
1023 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1024
1025 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1026   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1027   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1028   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1029   putchar_unlocked putc_unlocked)
1030 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1031         sysconf strsignal getrusage nl_langinfo \
1032         gettimeofday mbstowcs wcswidth mmap setlocale \
1033         gcc_UNLOCKED_FUNCS madvise)
1034
1035 if test x$ac_cv_func_mbstowcs = xyes; then
1036   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1037 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1038 int main()
1039 {
1040   mbstowcs(0, "", 0);
1041   return 0;
1042 }]])],
1043     [gcc_cv_func_mbstowcs_works=yes],
1044     [gcc_cv_func_mbstowcs_works=no],
1045     [gcc_cv_func_mbstowcs_works=yes])])
1046   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1047     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1048   [Define this macro if mbstowcs does not crash when its
1049    first argument is NULL.])
1050   fi
1051 fi
1052
1053 AC_CHECK_TYPE(ssize_t, int)
1054 AC_CHECK_TYPE(caddr_t, char *)
1055
1056 GCC_AC_FUNC_MMAP_BLACKLIST
1057
1058 case "${host}" in
1059 *-*-*vms*)
1060   # Under VMS, vfork works very differently than on Unix. The standard test
1061   # won't work, and it isn't easily adaptable. It makes more sense to
1062   # just force it.
1063   ac_cv_func_vfork_works=yes
1064   ;;
1065 esac
1066 AC_FUNC_FORK
1067
1068 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which exposes a different
1069 # iconv() prototype.
1070 AS_IF([test "$ENABLE_BUILD_WITH_CXX" = "yes"],
1071   [AC_LANG_PUSH([C++])
1072    AM_ICONV
1073    AC_LANG_POP([C++])],
1074   [AM_ICONV])
1075
1076 # Until we have in-tree GNU iconv:
1077 LIBICONV_DEP=
1078 AC_SUBST(LIBICONV_DEP)
1079
1080 AM_LC_MESSAGES
1081
1082 AM_LANGINFO_CODESET
1083
1084 # We will need to find libiberty.h and ansidecl.h
1085 saved_CFLAGS="$CFLAGS"
1086 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1087 saved_CXXFLAGS="$CXXFLAGS"
1088 CXXFLAGS="$CXXFLAGS -I${srcdir} -I${srcdir}/../include"
1089 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1090         strsignal strstr stpcpy strverscmp \
1091         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1092         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1093 #include "ansidecl.h"
1094 #include "system.h"])
1095
1096 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1097 #include "ansidecl.h"
1098 #include "system.h"
1099 #ifdef HAVE_SYS_RESOURCE_H
1100 #include <sys/resource.h>
1101 #endif
1102 ])
1103
1104 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1105 #include "ansidecl.h"
1106 #include "system.h"
1107 #ifdef HAVE_SYS_RESOURCE_H
1108 #include <sys/resource.h>
1109 #endif
1110 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1111 [Define to `long' if <sys/resource.h> doesn't define.])])
1112
1113 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1114 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1115 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1116 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1117 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1118 #include "ansidecl.h"
1119 #include "system.h"
1120 #ifdef HAVE_LDFCN_H
1121 #undef FREAD
1122 #undef FWRITE
1123 #include <ldfcn.h>
1124 #endif
1125 ])
1126
1127 gcc_AC_CHECK_DECLS(times, , ,[
1128 #include "ansidecl.h"
1129 #include "system.h"
1130 #ifdef HAVE_SYS_TIMES_H
1131 #include <sys/times.h>
1132 #endif
1133 ])
1134
1135 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1136 #include "ansidecl.h"
1137 #include "system.h"
1138 #include <signal.h>
1139 ])
1140
1141 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which hides the madvise()
1142 # prototype.
1143 AS_IF([test "$ENABLE_BUILD_WITH_CXX" = "yes"],
1144   [AC_LANG_PUSH([C++])
1145    gcc_AC_CHECK_DECLS(madvise, , ,[
1146      #include "ansidecl.h"
1147      #include "system.h"
1148    ])
1149    AC_LANG_POP([C++])],
1150   [gcc_AC_CHECK_DECLS(madvise, , ,[
1151      #include "ansidecl.h"
1152      #include "system.h"
1153    ])
1154 ])
1155
1156 # More time-related stuff.
1157 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1158 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1159 #include "ansidecl.h"
1160 #include "system.h"
1161 #ifdef HAVE_SYS_TIMES_H
1162 #include <sys/times.h>
1163 #endif
1164 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1165 if test $ac_cv_struct_tms = yes; then
1166   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1167   [Define if <sys/times.h> defines struct tms.])
1168 fi
1169
1170 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1171 # revisit after autoconf 2.50.
1172 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1173 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1174 #include "ansidecl.h"
1175 #include "system.h"
1176 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1177 if test $gcc_cv_type_clock_t = yes; then
1178   AC_DEFINE(HAVE_CLOCK_T, 1,
1179   [Define if <time.h> defines clock_t.])
1180 fi
1181
1182 # Restore CFLAGS, CXXFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1183 CFLAGS="$saved_CFLAGS"
1184 CXXFLAGS="$saved_CXXFLAGS"
1185
1186 # mkdir takes a single argument on some systems.
1187 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1188
1189 # File extensions
1190 manext='.1'
1191 objext='.o'
1192 AC_SUBST(manext)
1193 AC_SUBST(objext)
1194
1195 # With Setjmp/Longjmp based exception handling.
1196 AC_ARG_ENABLE(sjlj-exceptions,
1197 [AS_HELP_STRING([--enable-sjlj-exceptions],
1198                 [arrange to use setjmp/longjmp exception handling])],
1199 [case $target in
1200   *-*-hpux10*)
1201     if test $enableval != yes; then
1202       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1203       enableval=yes
1204     fi
1205     ;;
1206 esac
1207 force_sjlj_exceptions=yes],
1208 [case $target in
1209   *-*-hpux10*)
1210     force_sjlj_exceptions=yes
1211     enableval=yes
1212     ;;
1213   *)
1214     force_sjlj_exceptions=no
1215     ;;
1216 esac])
1217 if test $force_sjlj_exceptions = yes; then
1218   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1219   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1220     [Define 0/1 to force the choice for exception handling model.])
1221 fi
1222
1223 # --------------------------------------------------------
1224 # Build, host, and target specific configuration fragments
1225 # --------------------------------------------------------
1226
1227 # Collect build-machine-specific information.
1228 . ${srcdir}/config.build
1229
1230 # Collect host-machine-specific information.
1231 . ${srcdir}/config.host
1232
1233 target_gtfiles=
1234
1235 # Collect target-machine-specific information.
1236 . ${srcdir}/config.gcc
1237
1238 extra_objs="${host_extra_objs} ${extra_objs}"
1239 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1240
1241 # Default the target-machine variables that were not explicitly set.
1242 if test x"$tm_file" = x
1243 then tm_file=$cpu_type/$cpu_type.h; fi
1244
1245 if test x"$extra_headers" = x
1246 then extra_headers=; fi
1247
1248 if test x$md_file = x
1249 then md_file=$cpu_type/$cpu_type.md; fi
1250
1251 if test x$out_file = x
1252 then out_file=$cpu_type/$cpu_type.c; fi
1253
1254 if test x"$tmake_file" = x
1255 then tmake_file=$cpu_type/t-$cpu_type
1256 fi
1257
1258 # Support --enable-initfini-array.
1259 if test x$enable_initfini_array != xno; then
1260   tm_file="${tm_file} initfini-array.h"
1261 fi
1262
1263 if test x"$dwarf2" = xyes
1264 then tm_file="$tm_file tm-dwarf2.h"
1265 fi
1266
1267 # Say what files are being used for the output code and MD file.
1268 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1269 echo "Using \`$srcdir/config/$md_file' as machine description file."
1270
1271 # If any of the xm_file variables contain nonexistent files, warn
1272 # about them and drop them.
1273
1274 bx=
1275 for x in $build_xm_file; do
1276   if    test -f $srcdir/config/$x
1277   then      bx="$bx $x"
1278   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1279   fi
1280 done
1281 build_xm_file="$bx"
1282
1283 hx=
1284 for x in $host_xm_file; do
1285   if    test -f $srcdir/config/$x
1286   then      hx="$hx $x"
1287   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1288   fi
1289 done
1290 host_xm_file="$hx"
1291
1292 tx=
1293 for x in $xm_file; do
1294   if    test -f $srcdir/config/$x
1295   then      tx="$tx $x"
1296   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1297   fi
1298 done
1299 xm_file="$tx"
1300
1301 count=a
1302 for f in $tm_file; do
1303         count=${count}x
1304 done
1305 if test $count = ax; then
1306         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1307 else
1308         echo "Using the following target machine macro files:"
1309         for f in $tm_file; do
1310                 echo "  $srcdir/config/$f"
1311         done
1312 fi
1313
1314 if test x$need_64bit_hwint = xyes; then
1315         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1316 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1317 fi
1318
1319 if test x$use_long_long_for_widest_fast_int = xyes; then
1320         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1321 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1322 efficiently supported by the host hardware.])
1323 fi
1324
1325 gnu_ld_bool=`if test x"$gnu_ld" = x"yes"; then echo 1; else echo 0; fi`
1326 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld_bool, [Define to 1 if using GNU ld.])
1327
1328 gnu_as_bool=`if test x"$gas" = x"yes"; then echo 1; else echo 0; fi`
1329 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as_bool, [Define to 1 if using GNU as.])
1330
1331 count=a
1332 for f in $host_xm_file; do
1333         count=${count}x
1334 done
1335 if test $count = a; then
1336         :
1337 elif test $count = ax; then
1338         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1339 else
1340         echo "Using the following host machine macro files:"
1341         for f in $host_xm_file; do
1342                 echo "  $srcdir/config/$f"
1343         done
1344 fi
1345 echo "Using ${out_host_hook_obj} for host machine hooks."
1346
1347 if test "$host_xm_file" != "$build_xm_file"; then
1348         count=a
1349         for f in $build_xm_file; do
1350                 count=${count}x
1351         done
1352         if test $count = a; then
1353                 :
1354         elif test $count = ax; then
1355                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1356         else
1357                 echo "Using the following build machine macro files:"
1358                 for f in $build_xm_file; do
1359                         echo "  $srcdir/config/$f"
1360                 done
1361         fi
1362 fi
1363
1364 if test -n "$configured_native_system_header_dir"; then
1365   native_system_header_dir=$configured_native_system_header_dir
1366 fi
1367 NATIVE_SYSTEM_HEADER_DIR="$native_system_header_dir"
1368 AC_SUBST(NATIVE_SYSTEM_HEADER_DIR)
1369
1370 case ${host} in
1371   powerpc*-*-darwin*)
1372     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1373       gcc_cv_mcontext_underscores,
1374       AC_COMPILE_IFELSE([
1375 #include <sys/cdefs.h>
1376 #include <sys/signal.h>
1377 #include <ucontext.h>
1378 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1379 ],
1380         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1381       if test $gcc_cv_mcontext_underscores = yes; then
1382         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1383           [mcontext_t fields start with __])
1384       fi
1385     ;;
1386 esac
1387
1388 # ---------
1389 # Threading
1390 # ---------
1391
1392 # Check if a valid thread package
1393 case ${enable_threads} in
1394   "" | no)
1395     # No threads
1396     target_thread_file='single'
1397     ;;
1398   yes)
1399     # default
1400     target_thread_file='single'
1401     ;;
1402   aix | dce | lynx | mipssde | posix | rtems | \
1403   single | tpf | vxworks | win32)
1404     target_thread_file=${enable_threads}
1405     ;;
1406   *)
1407     echo "${enable_threads} is an unknown thread package" 1>&2
1408     exit 1
1409     ;;
1410 esac
1411
1412 if test x${thread_file} = x; then
1413   # No thread file set by target-specific clauses in config.gcc,
1414   # so use file chosen by default logic above
1415   thread_file=${target_thread_file}
1416 fi
1417
1418 # --------
1419 # UNSORTED
1420 # --------
1421
1422 use_cxa_atexit=no
1423 if test x$enable___cxa_atexit = xyes || \
1424    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1425   if test x$host = x$target; then
1426     case $host in
1427       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1428       # keyed to flag_use_cxa_atexit
1429       *-*-mingw32*)
1430         use_cxa_atexit=yes
1431         ;;
1432       *)
1433         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1434           [echo "__cxa_atexit can't be enabled on this target"])
1435         ;;
1436     esac
1437   else
1438     # We can't check for __cxa_atexit when building a cross, so assume
1439     # it is available
1440     use_cxa_atexit=yes
1441   fi
1442   if test x$use_cxa_atexit = xyes; then
1443     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1444       [Define if you want to use __cxa_atexit, rather than atexit, to
1445       register C++ destructors for local statics and global objects.
1446       This is essential for fully standards-compliant handling of
1447       destructors, but requires __cxa_atexit in libc.])
1448   fi
1449 fi
1450
1451 # Look for a file containing extra machine modes.
1452 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1453   extra_modes_file='$(srcdir)'/config/${extra_modes}
1454   AC_SUBST(extra_modes_file)
1455   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1456   [Define to the name of a file containing a list of extra machine modes
1457    for this architecture.])
1458 fi
1459
1460 # Convert extra_options into a form suitable for Makefile use.
1461 extra_opt_files=
1462 all_opt_files=
1463 for f in $extra_options; do
1464   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1465   all_opt_files="$all_opt_files $srcdir/config/$f"
1466 done
1467 AC_SUBST(extra_opt_files)
1468
1469 # auto-host.h is the file containing items generated by autoconf and is
1470 # the first file included by config.h.
1471 # If host=build, it is correct to have bconfig include auto-host.h
1472 # as well.  If host!=build, we are in error and need to do more
1473 # work to find out the build config parameters.
1474 if test x$host = x$build
1475 then
1476         build_auto=auto-host.h
1477 else
1478         # We create a subdir, then run autoconf in the subdir.
1479         # To prevent recursion we set host and build for the new
1480         # invocation of configure to the build for this invocation
1481         # of configure.
1482         tempdir=build.$$
1483         rm -rf $tempdir
1484         mkdir $tempdir
1485         cd $tempdir
1486         case ${srcdir} in
1487         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1488         *) realsrcdir=../${srcdir};;
1489         esac
1490         saved_CFLAGS="${CFLAGS}"
1491         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1492         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1493         ${realsrcdir}/configure \
1494                 --enable-languages=${enable_languages-all} \
1495                 --target=$target_alias --host=$build_alias --build=$build_alias
1496         CFLAGS="${saved_CFLAGS}"
1497
1498         # We just finished tests for the build machine, so rename
1499         # the file auto-build.h in the gcc directory.
1500         mv auto-host.h ../auto-build.h
1501         cd ..
1502         rm -rf $tempdir
1503         build_auto=auto-build.h
1504 fi
1505 AC_SUBST(build_subdir)
1506
1507 tm_file="${tm_file} defaults.h"
1508 tm_p_file="${tm_p_file} tm-preds.h"
1509 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1510 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1511 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1512 # put this back in temporarily.
1513 xm_file="auto-host.h ansidecl.h ${xm_file}"
1514
1515 # --------
1516 # UNSORTED
1517 # --------
1518
1519 changequote(,)dnl
1520 # Compile in configure arguments.
1521 if test -f configargs.h ; then
1522         # Being re-configured.
1523         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1524         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1525 else
1526         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1527 fi
1528
1529 # Double all backslashes and backslash all quotes to turn
1530 # gcc_config_arguments into a C string.
1531 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1532 $gcc_config_arguments
1533 EOF
1534 gcc_config_arguments_str=`cat conftest.out`
1535 rm -f conftest.out
1536
1537 cat > configargs.h <<EOF
1538 /* Generated automatically. */
1539 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1540 static const char thread_model[] = "$thread_file";
1541
1542 static const struct {
1543   const char *name, *value;
1544 } configure_default_options[] = $configure_default_options;
1545 EOF
1546 changequote([,])dnl
1547
1548 changequote(,)dnl
1549 gcc_BASEVER=`cat $srcdir/BASE-VER`
1550 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1551 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1552 if test -f $srcdir/REVISION ; then
1553         gcc_REVISION=`cat $srcdir/REVISION`
1554 else
1555         gcc_REVISION=""
1556 fi
1557 cat > plugin-version.h <<EOF
1558 #include "configargs.h"
1559
1560 #define GCCPLUGIN_VERSION_MAJOR   `echo $gcc_BASEVER | sed -e 's/^\([0-9]*\).*$/\1/'`
1561 #define GCCPLUGIN_VERSION_MINOR   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.\([0-9]*\).*$/\1/'`
1562 #define GCCPLUGIN_VERSION_PATCHLEVEL   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.[0-9]*\.\([0-9]*\)$/\1/'`
1563 #define GCCPLUGIN_VERSION  (GCCPLUGIN_VERSION_MAJOR*1000 + GCCPLUGIN_VERSION_MINOR)
1564
1565 static char basever[] = "$gcc_BASEVER";
1566 static char datestamp[] = "$gcc_DATESTAMP";
1567 static char devphase[] = "$gcc_DEVPHASE";
1568 static char revision[] = "$gcc_REVISION";
1569
1570 /* FIXME plugins: We should make the version information more precise.
1571    One way to do is to add a checksum. */
1572
1573 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1574                                                 devphase, revision,
1575                                                 configuration_arguments};
1576 EOF
1577 changequote([,])dnl
1578
1579 # Internationalization
1580 ZW_GNU_GETTEXT_SISTER_DIR
1581
1582 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1583 # -liconv on the link line twice.
1584 case "$LIBINTL" in *$LIBICONV*)
1585         LIBICONV= ;;
1586 esac
1587
1588 AC_ARG_ENABLE(secureplt,
1589 [AS_HELP_STRING([--enable-secureplt],
1590                 [enable -msecure-plt by default for PowerPC])],
1591 [], [])
1592
1593 AC_ARG_ENABLE(leading-mingw64-underscores,
1594   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1595                  [enable leading underscores on 64 bit mingw targets]),
1596   [],[])
1597 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1598   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1599     [Define if we should use leading underscore on 64 bit mingw targets])])
1600
1601 AC_ARG_ENABLE(cld,
1602 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
1603 [enable_cld=no])
1604
1605 AC_ARG_ENABLE(frame-pointer,
1606 [AS_HELP_STRING([--enable-frame-pointer],
1607                 [enable -fno-omit-frame-pointer by default for 32bit x86])], [],
1608 [
1609 case $target_os in
1610 linux* | darwin[[8912]]*)
1611   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1612   # DWARF2.
1613   enable_frame_pointer=no
1614   ;;
1615 *)
1616   enable_frame_pointer=yes
1617   ;;
1618 esac
1619 ])
1620
1621 # Windows32 Registry support for specifying GCC installation paths.
1622 AC_ARG_ENABLE(win32-registry,
1623 [AS_HELP_STRING([--disable-win32-registry],
1624                 [disable lookup of installation paths in the
1625                  Registry on Windows hosts])
1626 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
1627 AS_HELP_STRING([--enable-win32-registry=KEY],
1628                [use KEY instead of GCC version as the last portion
1629                 of the registry key])],,)
1630
1631 case $host_os in
1632   win32 | pe | cygwin* | mingw32* | uwin*)
1633     if test "x$enable_win32_registry" != xno; then
1634       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1635     fi
1636
1637     if test "x$enable_win32_registry" != xno; then
1638       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1639   [Define to 1 if installation paths should be looked up in the Windows
1640    Registry. Ignored on non-Windows hosts.])
1641
1642       if test "x$enable_win32_registry" != xyes \
1643          && test "x$enable_win32_registry" != x; then
1644         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1645   [Define to be the last component of the Windows registry key under which
1646    to look for installation paths.  The full key used will be
1647    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1648    The default is the GCC version number.])
1649       fi
1650     fi
1651   ;;
1652 esac
1653
1654 # Get an absolute path to the GCC top-level source directory
1655 holddir=`${PWDCMD-pwd}`
1656 cd $srcdir
1657 topdir=`${PWDCMD-pwd}`
1658 cd $holddir
1659
1660 # Conditionalize the makefile for this host machine.
1661 xmake_file=
1662 for f in ${host_xmake_file}
1663 do
1664         if test -f ${srcdir}/config/$f
1665         then
1666                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1667         fi
1668 done
1669
1670 # Conditionalize the makefile for this target machine.
1671 tmake_file_=
1672 for f in ${tmake_file}
1673 do
1674         if test -f ${srcdir}/config/$f
1675         then
1676                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1677         fi
1678 done
1679 tmake_file="${tmake_file_}"
1680
1681 out_object_file=`basename $out_file .c`.o
1682 common_out_object_file=`basename $common_out_file .c`.o
1683
1684 tm_file_list="options.h"
1685 tm_include_list="options.h insn-constants.h"
1686 for f in $tm_file; do
1687   case $f in
1688     ./* )
1689        f=`echo $f | sed 's/^..//'`
1690        tm_file_list="${tm_file_list} $f"
1691        tm_include_list="${tm_include_list} $f"
1692        ;;
1693     defaults.h )
1694        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1695        tm_include_list="${tm_include_list} $f"
1696        ;;
1697     * )
1698        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1699        tm_include_list="${tm_include_list} config/$f"
1700        ;;
1701   esac
1702 done
1703
1704 tm_p_file_list=
1705 tm_p_include_list=
1706 for f in $tm_p_file; do
1707   case $f in
1708     tm-preds.h )
1709        tm_p_file_list="${tm_p_file_list} $f"
1710        tm_p_include_list="${tm_p_include_list} $f"
1711        ;;
1712     * )
1713        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1714        tm_p_include_list="${tm_p_include_list} config/$f"
1715   esac
1716 done
1717
1718 xm_file_list=
1719 xm_include_list=
1720 for f in $xm_file; do
1721   case $f in
1722     ansidecl.h )
1723        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1724        xm_include_list="${xm_include_list} $f"
1725        ;;
1726     auto-host.h )
1727        xm_file_list="${xm_file_list} $f"
1728        xm_include_list="${xm_include_list} $f"
1729        ;;
1730     * )
1731        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1732        xm_include_list="${xm_include_list} config/$f"
1733        ;;
1734   esac
1735 done
1736
1737 host_xm_file_list=
1738 host_xm_include_list=
1739 for f in $host_xm_file; do
1740   case $f in
1741     ansidecl.h )
1742        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1743        host_xm_include_list="${host_xm_include_list} $f"
1744        ;;
1745     auto-host.h )
1746        host_xm_file_list="${host_xm_file_list} $f"
1747        host_xm_include_list="${host_xm_include_list} $f"
1748        ;;
1749     * )
1750        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1751        host_xm_include_list="${host_xm_include_list} config/$f"
1752        ;;
1753   esac
1754 done
1755
1756 build_xm_file_list=
1757 for f in $build_xm_file; do
1758   case $f in
1759     ansidecl.h )
1760        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1761        build_xm_include_list="${build_xm_include_list} $f"
1762        ;;
1763     auto-build.h | auto-host.h )
1764        build_xm_file_list="${build_xm_file_list} $f"
1765        build_xm_include_list="${build_xm_include_list} $f"
1766        ;;
1767     * )
1768        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1769        build_xm_include_list="${build_xm_include_list} config/$f"
1770        ;;
1771   esac
1772 done
1773
1774 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1775 # cross-compiler which does not use the native headers and libraries.
1776 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1777 CROSS=                                          AC_SUBST(CROSS)
1778 ALL=all.internal                                AC_SUBST(ALL)
1779 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1780
1781 if test "x$with_build_sysroot" != x; then
1782   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1783 else
1784   # This value is used, even on a native system, because
1785   # CROSS_SYSTEM_HEADER_DIR is just
1786   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1787   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1788 fi
1789
1790 if test x$host != x$target
1791 then
1792         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1793         ALL=all.cross
1794         SYSTEM_HEADER_DIR=$build_system_header_dir
1795         case "$host","$target" in
1796         # Darwin crosses can use the host system's libraries and headers,
1797         # because of the fat library support.  Of course, it must be the
1798         # same version of Darwin on both sides.  Allow the user to
1799         # just say --target=foo-darwin without a version number to mean
1800         # "the version on this system".
1801             *-*-darwin*,*-*-darwin*)
1802                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1803                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1804                 if test $hostos = $targetos -o $targetos = darwin ; then
1805                     CROSS=
1806                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1807                     with_headers=yes
1808                 fi
1809                 ;;
1810
1811             i?86-*-*,x86_64-*-* \
1812             | powerpc*-*-*,powerpc64*-*-*)
1813                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1814         esac
1815
1816         case $target in
1817                 *-*-mingw*)
1818                         if test "x$with_headers" = x; then
1819                                 with_headers=yes
1820                         fi
1821                         ;;
1822                 *)
1823                         ;;
1824         esac
1825 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1826         SYSTEM_HEADER_DIR=$build_system_header_dir
1827 fi
1828
1829 # If this is a cross-compiler that does not
1830 # have its own set of headers then define
1831 # inhibit_libc
1832
1833 # If this is using newlib, without having the headers available now,
1834 # then define inhibit_libc in LIBGCC2_CFLAGS.
1835 # This prevents libgcc2 from containing any code which requires libc
1836 # support.
1837 : ${inhibit_libc=false}
1838 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1839        test x$with_newlib = xyes ; } &&
1840      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1841        inhibit_libc=true
1842 fi
1843 AC_SUBST(inhibit_libc)
1844
1845 # When building gcc with a cross-compiler, we need to adjust things so
1846 # that the generator programs are still built with the native compiler.
1847 # Also, we cannot run fixincludes.
1848
1849 # These are the normal (build=host) settings:
1850 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1851 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1852 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1853 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1854
1855 # And these apply if build != host, or we are generating coverage data
1856 if test x$build != x$host || test "x$coverage_flags" != x
1857 then
1858     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1859     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1860 fi
1861
1862 # Expand extra_headers to include complete path.
1863 # This substitutes for lots of t-* files.
1864 extra_headers_list=
1865 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1866 for file in ${extra_headers} ; do
1867   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1868 done
1869
1870 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1871 if test x"$use_gcc_tgmath" = xyes
1872 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1873 fi
1874
1875 # Define collect2 in Makefile.
1876 case $host_can_use_collect2 in
1877   no) collect2= ;;
1878   *) collect2='collect2$(exeext)' ;;
1879 esac
1880 AC_SUBST([collect2])
1881
1882 # Add a definition of USE_COLLECT2 if system wants one.
1883 case $use_collect2 in
1884   no) use_collect2= ;;
1885   "") ;;
1886   *)
1887     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1888     xm_defines="${xm_defines} USE_COLLECT2"
1889     case $host_can_use_collect2 in
1890       no)
1891         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1892         ;;
1893     esac
1894     ;;
1895 esac
1896
1897 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
1898 [Define to the name of the LTO plugin DSO that must be
1899   passed to the linker's -plugin=LIB option.])
1900
1901 # ---------------------------
1902 # Assembler & linker features
1903 # ---------------------------
1904
1905 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1906 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1907 # However when ld-new is first executed from the build tree, libtool will
1908 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1909 # to the build tree.  While doing this we need to use the previous-stage
1910 # linker, or we have an infinite loop.  The presence of a shell script as
1911 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1912 # the gcc/collect-ld script.  So we need to know how libtool works, or
1913 # exec-tool will fail.
1914
1915 m4_defun([_LT_CONFIG_COMMANDS], [])
1916 AC_PROG_LIBTOOL
1917 AC_SUBST(objdir)
1918 AC_SUBST(enable_fast_install)
1919
1920 # Identify the assembler which will work hand-in-glove with the newly
1921 # built GCC, so that we can examine its features.  This is the assembler
1922 # which will be driven by the driver program.
1923 #
1924 # If build != host, and we aren't building gas in-tree, we identify a
1925 # build->target assembler and hope that it will have the same features
1926 # as the host->target assembler we'll be using.
1927 gcc_cv_gas_major_version=
1928 gcc_cv_gas_minor_version=
1929 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1930
1931 m4_pattern_allow([AS_FOR_TARGET])dnl
1932 AS_VAR_SET_IF(gcc_cv_as,, [
1933 if test -x "$DEFAULT_ASSEMBLER"; then
1934         gcc_cv_as="$DEFAULT_ASSEMBLER"
1935 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1936      && test -f ../gas/Makefile \
1937      && test x$build = x$host; then
1938         gcc_cv_as=../gas/as-new$build_exeext
1939 elif test -x as$build_exeext; then
1940         # Build using assembler in the current directory.
1941         gcc_cv_as=./as$build_exeext
1942 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
1943         gcc_cv_as="$AS_FOR_TARGET"
1944 else
1945         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1946 fi])
1947
1948 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1949 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1950 case "$ORIGINAL_AS_FOR_TARGET" in
1951   ./as | ./as$build_exeext) ;;
1952   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1953 esac
1954
1955 AC_MSG_CHECKING(what assembler to use)
1956 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1957   # Single tree build which includes gas.  We want to prefer it
1958   # over whatever linker top-level may have detected, since
1959   # we'll use what we're building after installation anyway.
1960   AC_MSG_RESULT(newly built gas)
1961   in_tree_gas=yes
1962   _gcc_COMPUTE_GAS_VERSION
1963   in_tree_gas_is_elf=no
1964   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1965      || (grep 'obj_format = multi' ../gas/Makefile \
1966          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1967   then
1968     in_tree_gas_is_elf=yes
1969   fi
1970 else
1971   AC_MSG_RESULT($gcc_cv_as)
1972   in_tree_gas=no
1973 fi
1974
1975 # Identify the linker which will work hand-in-glove with the newly
1976 # built GCC, so that we can examine its features.  This is the linker
1977 # which will be driven by the driver program.
1978 #
1979 # If build != host, and we aren't building gas in-tree, we identify a
1980 # build->target linker and hope that it will have the same features
1981 # as the host->target linker we'll be using.
1982 gcc_cv_gld_major_version=
1983 gcc_cv_gld_minor_version=
1984 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1985 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1986
1987 AS_VAR_SET_IF(gcc_cv_ld,, [
1988 if test -x "$DEFAULT_LINKER"; then
1989         gcc_cv_ld="$DEFAULT_LINKER"
1990 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1991      && test -f ../ld/Makefile \
1992      && test x$build = x$host; then
1993         gcc_cv_ld=../ld/ld-new$build_exeext
1994 elif test -x collect-ld$build_exeext; then
1995         # Build using linker in the current directory.
1996         gcc_cv_ld=./collect-ld$build_exeext
1997 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
1998         gcc_cv_ld="$LD_FOR_TARGET"
1999 else
2000         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
2001 fi])
2002
2003 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
2004 PLUGIN_LD_SUFFIX=`basename $gcc_cv_ld | sed -e "s,$target_alias-,,"`
2005 AC_ARG_WITH(plugin-ld,
2006 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
2007 [if test x"$withval" != x; then
2008    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
2009    PLUGIN_LD_SUFFIX=`echo $withval | sed -e "s,$target_alias-,,"`
2010  fi])
2011 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
2012 AC_DEFINE_UNQUOTED(PLUGIN_LD_SUFFIX, "$PLUGIN_LD_SUFFIX", [Specify plugin linker])
2013
2014 # Check to see if we are using gold instead of ld
2015 AC_MSG_CHECKING(whether we are using gold)
2016 ld_is_gold=no
2017 if test x$gcc_cv_ld != x; then
2018   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
2019      | grep "GNU gold" > /dev/null; then
2020     ld_is_gold=yes
2021   fi
2022 fi
2023 AC_MSG_RESULT($ld_is_gold)
2024
2025 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
2026 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
2027 case "$ORIGINAL_LD_FOR_TARGET" in
2028   ./collect-ld | ./collect-ld$build_exeext) ;;
2029   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
2030 esac
2031
2032 AC_MSG_CHECKING(what linker to use)
2033 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
2034    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
2035         # Single tree build which includes ld.  We want to prefer it
2036         # over whatever linker top-level may have detected, since
2037         # we'll use what we're building after installation anyway.
2038         AC_MSG_RESULT(newly built ld)
2039         in_tree_ld=yes
2040         in_tree_ld_is_elf=no
2041         if (grep 'EMUL = .*elf' ../ld/Makefile \
2042             || grep 'EMUL = .*linux' ../ld/Makefile \
2043             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
2044           in_tree_ld_is_elf=yes
2045         elif test "$ld_is_gold" = yes; then
2046           in_tree_ld_is_elf=yes
2047         fi
2048         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
2049         do
2050 changequote(,)dnl
2051                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
2052                 if test x$gcc_cv_gld_version != x; then
2053                         break
2054                 fi
2055         done
2056         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2057         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2058 changequote([,])dnl
2059 else
2060         AC_MSG_RESULT($gcc_cv_ld)
2061         in_tree_ld=no
2062 fi
2063
2064 # Figure out what nm we will be using.
2065 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2066 AS_VAR_SET_IF(gcc_cv_nm,, [
2067 if test -f $gcc_cv_binutils_srcdir/configure.in \
2068      && test -f ../binutils/Makefile \
2069      && test x$build = x$host; then
2070         gcc_cv_nm=../binutils/nm-new$build_exeext
2071 elif test -x nm$build_exeext; then
2072         gcc_cv_nm=./nm$build_exeext
2073 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2074         gcc_cv_nm="$NM_FOR_TARGET"
2075 else
2076         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2077 fi])
2078
2079 AC_MSG_CHECKING(what nm to use)
2080 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2081         # Single tree build which includes binutils.
2082         AC_MSG_RESULT(newly built nm)
2083         in_tree_nm=yes
2084 else
2085         AC_MSG_RESULT($gcc_cv_nm)
2086         in_tree_nm=no
2087 fi
2088
2089 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2090 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2091 case "$ORIGINAL_NM_FOR_TARGET" in
2092   ./nm | ./nm$build_exeext) ;;
2093   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2094 esac
2095
2096
2097 # Figure out what objdump we will be using.
2098 AS_VAR_SET_IF(gcc_cv_objdump,, [
2099 if test -f $gcc_cv_binutils_srcdir/configure.in \
2100      && test -f ../binutils/Makefile \
2101      && test x$build = x$host; then
2102         # Single tree build which includes binutils.
2103         gcc_cv_objdump=../binutils/objdump$build_exeext
2104 elif test -x objdump$build_exeext; then
2105         gcc_cv_objdump=./objdump$build_exeext
2106 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2107         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2108 else
2109         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2110 fi])
2111
2112 AC_MSG_CHECKING(what objdump to use)
2113 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2114         # Single tree build which includes binutils.
2115         AC_MSG_RESULT(newly built objdump)
2116 elif test x$gcc_cv_objdump = x; then
2117         AC_MSG_RESULT(not found)
2118 else
2119         AC_MSG_RESULT($gcc_cv_objdump)
2120 fi
2121
2122 # Figure out what readelf we will be using.
2123 AS_VAR_SET_IF(gcc_cv_readelf,, [
2124 if test -f $gcc_cv_binutils_srcdir/configure.in \
2125      && test -f ../binutils/Makefile \
2126      && test x$build = x$host; then
2127         # Single tree build which includes binutils.
2128         gcc_cv_readelf=../binutils/readelf$build_exeext
2129 elif test -x readelf$build_exeext; then
2130         gcc_cv_readelf=./readelf$build_exeext
2131 else
2132         AC_PATH_PROG(gcc_cv_readelf, readelf)
2133 fi])
2134
2135 AC_MSG_CHECKING(what readelf to use)
2136 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2137         # Single tree build which includes binutils.
2138         AC_MSG_RESULT(newly built readelf)
2139 elif test x$gcc_cv_readelf = x; then
2140         AC_MSG_RESULT(not found)
2141 else
2142         AC_MSG_RESULT($gcc_cv_readelf)
2143 fi
2144
2145 # Figure out what assembler alignment features are present.
2146 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2147  [2,6,0],,
2148 [.balign 4
2149 .p2align 2],,
2150 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2151   [Define if your assembler supports .balign and .p2align.])])
2152
2153 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2154  [2,8,0],,
2155  [.p2align 4,,7],,
2156 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2157   [Define if your assembler supports specifying the maximum number
2158    of bytes to skip when using the GAS .p2align command.])])
2159
2160 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2161  [2,8,0],,
2162  [.literal16],,
2163 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2164   [Define if your assembler supports .literal16.])])
2165
2166 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2167  [elf,2,9,0],,
2168  [conftest_label1: .word 0
2169 .subsection -1
2170 conftest_label2: .word 0
2171 .previous],
2172  [if test x$gcc_cv_nm != x; then
2173     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2174     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2175     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2176     then :
2177     else gcc_cv_as_subsection_m1=yes
2178     fi
2179     rm -f conftest.nm1 conftest.nm2
2180   fi],
2181  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2182   [Define if your assembler supports .subsection and .subsection -1 starts
2183    emitting at the beginning of your section.])])
2184
2185 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2186  [2,2,0],,
2187  [      .weak foobar],,
2188 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2189
2190 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2191  [2,17,0],,
2192  [      .weakref foobar, barfnot],,
2193 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2194
2195 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2196  [2,15,91],,
2197  [      .SPACE $TEXT$
2198         .NSUBSPA $CODE$,COMDAT],,
2199 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2200
2201 # .hidden needs to be supported in both the assembler and the linker,
2202 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2203 # This is irritatingly difficult to feature test for; we have to check the
2204 # date string after the version number.  If we've got an in-tree
2205 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2206 # to be safe.
2207 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2208 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2209  [elf,2,13,0],,
2210 [       .hidden foobar
2211 foobar:],[
2212 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2213 # STV_HIDDEN, so disable .hidden support if so.
2214 case "${target}" in
2215   i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
2216     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2217       cat > conftest.s <<EOF
2218 .globl hidden
2219         .hidden hidden
2220 hidden:
2221 .globl default
2222         .set    default,hidden
2223 EOF
2224       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2225         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2226         grep '\.hidden default' > /dev/null; then
2227         gcc_cv_as_hidden=no
2228       else
2229         gcc_cv_as_hidden=yes
2230       fi
2231     else
2232       # Assume bug is present if objdump is missing.
2233       gcc_cv_as_hidden=no
2234     fi
2235     ;;
2236   *)
2237     gcc_cv_as_hidden=yes
2238     ;;
2239 esac])
2240 case "${target}" in
2241   *-*-darwin*)
2242     # Darwin as has some visibility support, though with a different syntax.
2243     gcc_cv_as_hidden=yes
2244     ;;
2245 esac
2246
2247 # gnu_indirect_function type is an extension proposed at
2248 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2249 # selection of function implementation
2250 AC_ARG_ENABLE(gnu-indirect-function,
2251  [AS_HELP_STRING([--enable-gnu-indirect-function],
2252                  [enable the use of the @gnu_indirect_function to glibc systems])],
2253  [case $enable_gnu_indirect_function in
2254     yes | no) ;;
2255     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2256 Valid choices are 'yes' and 'no'.]) ;;
2257   esac],
2258  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2259 if test x$enable_gnu_indirect_function = xyes; then
2260   AC_DEFINE(HAVE_GNU_INDIRECT_FUNCTION, 1,
2261    [Define if your system supports gnu indirect functions.])
2262 fi
2263
2264 changequote(,)dnl
2265 if test $in_tree_ld != yes ; then
2266   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2267   if echo "$ld_ver" | grep GNU > /dev/null; then
2268     if test x"$ld_is_gold" = xyes; then
2269       # GNU gold --version looks like this:
2270       #
2271       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2272       #
2273       # We extract the binutils version which is more familiar and specific
2274       # than the gold version.
2275       ld_vers=`echo $ld_ver | sed -n \
2276           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2277     else
2278       # GNU ld --version looks like this:
2279       #
2280       # GNU ld (GNU Binutils) 2.21.51.20110225
2281       ld_vers=`echo $ld_ver | sed -n \
2282           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2283     fi
2284     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2285     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2286     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2287     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2288   else
2289     case "${target}" in
2290       *-*-solaris2*)
2291         # See acinclude.m4 (gcc_SUN_LD_VERSION) for the version number
2292         # format.
2293         #
2294         # Don't reuse gcc_gv_sun_ld_vers_* in case a linker other than
2295         # /usr/ccs/bin/ld has been configured.
2296         ld_ver=`$gcc_cv_ld -V 2>&1`
2297         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2298           ld_vers=`echo $ld_ver | sed -n \
2299             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2300           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2301           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2302         fi
2303         ;;
2304     esac
2305   fi
2306 fi
2307 changequote([,])dnl
2308
2309 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2310 [[if test $in_tree_ld = yes ; then
2311   gcc_cv_ld_hidden=no
2312   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2313      && test $in_tree_ld_is_elf = yes; then
2314      gcc_cv_ld_hidden=yes
2315   fi
2316 else
2317   gcc_cv_ld_hidden=yes
2318   if test x"$ld_is_gold" = xyes; then
2319     :
2320   elif echo "$ld_ver" | grep GNU > /dev/null; then
2321     if test 0"$ld_date" -lt 20020404; then
2322       if test -n "$ld_date"; then
2323         # If there was date string, but was earlier than 2002-04-04, fail
2324         gcc_cv_ld_hidden=no
2325       elif test -z "$ld_vers"; then
2326         # If there was no date string nor ld version number, something is wrong
2327         gcc_cv_ld_hidden=no
2328       else
2329         test -z "$ld_vers_patch" && ld_vers_patch=0
2330         if test "$ld_vers_major" -lt 2; then
2331           gcc_cv_ld_hidden=no
2332         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2333           gcc_cv_ld_hidden="no"
2334         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2335           gcc_cv_ld_hidden=no
2336         fi
2337       fi
2338     fi
2339   else
2340     case "${target}" in
2341       *-*-darwin*)
2342         # Darwin ld has some visibility support.
2343         gcc_cv_ld_hidden=yes
2344         ;;
2345       hppa64*-*-hpux* | ia64*-*-hpux*)
2346         gcc_cv_ld_hidden=yes
2347         ;;
2348       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2349         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2350         # .symbolic was only added in Solaris 9 12/02.
2351         gcc_cv_ld_hidden=yes
2352         ;;
2353       *)
2354         gcc_cv_ld_hidden=no
2355         ;;
2356     esac
2357   fi
2358 fi]])
2359 libgcc_visibility=no
2360 AC_SUBST(libgcc_visibility)
2361 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2362 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2363   libgcc_visibility=yes
2364   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2365   [Define if your assembler and linker support .hidden.])
2366 fi
2367
2368 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2369 gcc_cv_ld_ro_rw_mix=unknown
2370 if test $in_tree_ld = yes ; then
2371   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2372      && test $in_tree_ld_is_elf = yes; then
2373     gcc_cv_ld_ro_rw_mix=read-write
2374   fi
2375 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2376   echo '.section myfoosect, "a"' > conftest1.s
2377   echo '.section myfoosect, "aw"' > conftest2.s
2378   echo '.byte 1' >> conftest2.s
2379   echo '.section myfoosect, "a"' > conftest3.s
2380   echo '.byte 0' >> conftest3.s
2381   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2382      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2383      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2384      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2385         conftest2.o conftest3.o > /dev/null 2>&1; then
2386     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2387                          | sed -e '/myfoosect/!d' -e N`
2388     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2389       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2390         gcc_cv_ld_ro_rw_mix=read-only
2391       else
2392         gcc_cv_ld_ro_rw_mix=read-write
2393       fi
2394     fi
2395   fi
2396 changequote(,)dnl
2397   rm -f conftest.* conftest[123].*
2398 changequote([,])dnl
2399 fi
2400 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2401         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2402   [Define if your linker links a mix of read-only
2403    and read-write sections into a read-write section.])
2404 fi
2405 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2406
2407 gcc_AC_INITFINI_ARRAY
2408
2409 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2410 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2411   [elf,2,11,0],,
2412 [       .data
2413         .uleb128 L2 - L1
2414 L1:
2415         .uleb128 1280
2416         .sleb128 -1010
2417 L2:],
2418 [[# GAS versions before 2.11 do not support uleb128,
2419   # despite appearing to.
2420   # ??? There exists an elf-specific test that will crash
2421   # the assembler.  Perhaps it's better to figure out whether
2422   # arbitrary sections are supported and try the test.
2423   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2424   if echo "$as_ver" | grep GNU > /dev/null; then
2425     as_vers=`echo $as_ver | sed -n \
2426         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2427     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2428     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2429     if test $as_major -eq 2 && test $as_minor -lt 11
2430     then :
2431     else gcc_cv_as_leb128=yes
2432     fi
2433   fi]],
2434   [AC_DEFINE(HAVE_AS_LEB128, 1,
2435     [Define if your assembler supports .sleb128 and .uleb128.])])
2436
2437 # Check if we have assembler support for unwind directives.
2438 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2439   ,,
2440 [       .text
2441         .cfi_startproc
2442         .cfi_offset 0, 0
2443         .cfi_same_value 1
2444         .cfi_def_cfa 1, 2
2445         .cfi_escape 1, 2, 3, 4, 5
2446         .cfi_endproc],
2447 [case "$target" in
2448   *-*-solaris*)
2449     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2450     # read-only and read-write sections, we need to make sure that the
2451     # assembler used emits read-write .eh_frame sections.
2452     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2453       if test "x$gcc_cv_objdump" != x; then
2454         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2455                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2456           gcc_cv_as_cfi_directive=no
2457         else
2458           case "$target" in
2459             i?86-*-solaris2.1[[0-9]]* | x86_64-*-solaris2.1[[0-9]]*)
2460               # On Solaris/x86, make sure that GCC and gas agree on using
2461               # read-only .eh_frame sections for 64-bit.
2462               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2463                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2464                         sed -e /.eh_frame/!d -e N | \
2465                         grep READONLY > /dev/null; then
2466                 gcc_cv_as_cfi_directive=yes
2467               else
2468                 gcc_cv_as_cfi_directive=no
2469               fi
2470               ;;
2471             *)
2472               gcc_cv_as_cfi_directive=yes
2473               ;;
2474           esac
2475         fi
2476       else
2477         # no objdump, err on the side of caution
2478         gcc_cv_as_cfi_directive=no
2479       fi
2480     else
2481       gcc_cv_as_cfi_directive=yes
2482     fi
2483     ;;
2484   *-*-*)
2485     gcc_cv_as_cfi_directive=yes
2486     ;;
2487 esac])
2488 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2489 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2490   ,,
2491 [       .text
2492         .cfi_startproc
2493         .cfi_adjust_cfa_offset 64
2494         .skip 75040, 0
2495         .cfi_adjust_cfa_offset 128
2496         .cfi_endproc],
2497 [[
2498 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2499     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2500    gcc_cv_as_cfi_advance_working=yes
2501 fi
2502 ]])
2503 else
2504   # no objdump, err on the side of caution
2505   gcc_cv_as_cfi_advance_working=no
2506 fi
2507 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2508 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2509   [`if test $gcc_cv_as_cfi_directive = yes \
2510        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2511   [Define 0/1 if your assembler supports CFI directives.])
2512
2513 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2514 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2515   gcc_cv_as_cfi_personality_directive, ,,
2516 [       .text
2517         .cfi_startproc
2518         .cfi_personality 0, symbol
2519         .cfi_endproc])
2520 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2521   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2522     then echo 1; else echo 0; fi`],
2523   [Define 0/1 if your assembler supports .cfi_personality.])
2524
2525 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2526   gcc_cv_as_cfi_sections_directive, ,,
2527 [       .text
2528         .cfi_sections .debug_frame, .eh_frame
2529         .cfi_startproc
2530         .cfi_endproc],
2531 [case $target_os in
2532   win32 | pe | cygwin* | mingw32* | uwin*)
2533     # Need to check that we generated the correct relocation for the
2534     # .debug_frame section.  This was fixed for binutils 2.21.
2535     gcc_cv_as_cfi_sections_directive=no
2536     if test "x$gcc_cv_objdump" != x; then
2537      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2538         grep secrel > /dev/null; then
2539       gcc_cv_as_cfi_sections_directive=yes
2540      fi
2541     fi
2542     ;;
2543   *)
2544     gcc_cv_as_cfi_sections_directive=yes
2545     ;;
2546 esac])
2547 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2548 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2549   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2550     then echo 1; else echo 0; fi`],
2551   [Define 0/1 if your assembler supports .cfi_sections.])
2552
2553 # GAS versions up to and including 2.11.0 may mis-optimize
2554 # .eh_frame data.
2555 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2556   [elf,2,12,0],,
2557 [       .text
2558 .LFB1:
2559         .4byte  0
2560 .L1:
2561         .4byte  0
2562 .LFE1:
2563         .section        .eh_frame,"aw",@progbits
2564 __FRAME_BEGIN__:
2565         .4byte  .LECIE1-.LSCIE1
2566 .LSCIE1:
2567         .4byte  0x0
2568         .byte   0x1
2569         .ascii "z\0"
2570         .byte   0x1
2571         .byte   0x78
2572         .byte   0x1a
2573         .byte   0x0
2574         .byte   0x4
2575         .4byte  1
2576         .p2align 1
2577 .LECIE1:
2578 .LSFDE1:
2579         .4byte  .LEFDE1-.LASFDE1
2580 .LASFDE1:
2581         .4byte  .LASFDE1-__FRAME_BEGIN__
2582         .4byte  .LFB1
2583         .4byte  .LFE1-.LFB1
2584         .byte   0x4
2585         .4byte  .LFE1-.LFB1
2586         .byte   0x4
2587         .4byte  .L1-.LFB1
2588 .LEFDE1:],
2589 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2590 cat > conftest.lit <<EOF
2591  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2592  0010 01000000 12000000 18000000 00000000  ................
2593  0020 08000000 04080000 0044               .........D      @&t@
2594 EOF
2595 cat > conftest.big <<EOF
2596  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2597  0010 00000001 00000012 00000018 00000000  ................
2598  0020 00000008 04000000 0844               .........D      @&t@
2599 EOF
2600   # If the assembler didn't choke, and we can objdump,
2601   # and we got the correct data, then succeed.
2602   # The text in the here-document typically retains its unix-style line
2603   # endings, while the output of objdump will use host line endings.
2604   # Therefore, use diff -b for the comparisons.
2605   if test x$gcc_cv_objdump != x \
2606   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2607      | tail -3 > conftest.got \
2608   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2609     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2610   then
2611     gcc_cv_as_eh_frame=yes
2612   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2613     gcc_cv_as_eh_frame=buggy
2614   else
2615     # Uh oh, what do we do now?
2616     gcc_cv_as_eh_frame=no
2617   fi])
2618
2619 if test $gcc_cv_as_eh_frame = buggy; then
2620   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2621   [Define if your assembler mis-optimizes .eh_frame data.])
2622 fi
2623
2624 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2625  [elf,2,12,0], [--fatal-warnings],
2626  [.section .rodata.str, "aMS", @progbits, 1])
2627 if test $gcc_cv_as_shf_merge = no; then
2628   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2629     [elf,2,12,0], [--fatal-warnings],
2630     [.section .rodata.str, "aMS", %progbits, 1])
2631 fi
2632 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2633   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2634 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2635
2636 gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as)],
2637  gcc_cv_as_comdat_group,
2638  [elf,2,16,0], [--fatal-warnings],
2639  [.section .text,"axG",@progbits,.foo,comdat])
2640 if test $gcc_cv_as_comdat_group = yes; then
2641   gcc_cv_as_comdat_group_percent=no
2642   gcc_cv_as_comdat_group_group=no
2643 else
2644  gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as, %type)],
2645    gcc_cv_as_comdat_group_percent,
2646    [elf,2,16,0], [--fatal-warnings],
2647    [.section .text,"axG",%progbits,.foo,comdat])
2648  if test $gcc_cv_as_comdat_group_percent = yes; then
2649    gcc_cv_as_comdat_group_group=no
2650  else
2651    case "${target}" in
2652      # Sun as uses a completely different syntax.
2653      *-*-solaris2*)
2654        case "${target}" in
2655          sparc*-*-solaris2*)
2656            conftest_s='
2657                .group foo,".text%foo",#comdat
2658                .section ".text%foo", #alloc,#execinstr,#progbits
2659                .globl foo
2660              foo:
2661              '
2662            ;;
2663          i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
2664            conftest_s='
2665                .group foo,.text%foo,#comdat
2666                .section .text%foo, "ax", @progbits
2667                .globl  foo
2668              foo:
2669              '
2670            ;;
2671        esac
2672        gcc_GAS_CHECK_FEATURE([COMDAT group support (Sun as, .group)],
2673          gcc_cv_as_comdat_group_group,
2674          ,, [$conftest_s])
2675        ;;
2676    esac
2677  fi
2678 fi
2679 if test x"$ld_is_gold" = xyes; then
2680   comdat_group=yes
2681 elif test $in_tree_ld = yes ; then
2682   comdat_group=no
2683   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2684      && test $in_tree_ld_is_elf = yes; then
2685      comdat_group=yes
2686   fi
2687 elif echo "$ld_ver" | grep GNU > /dev/null; then
2688   comdat_group=yes
2689   if test 0"$ld_date" -lt 20050308; then
2690     if test -n "$ld_date"; then
2691       # If there was date string, but was earlier than 2005-03-08, fail
2692       comdat_group=no
2693     elif test "$ld_vers_major" -lt 2; then
2694       comdat_group=no
2695     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2696       comdat_group=no
2697     fi
2698   fi
2699 else
2700 changequote(,)dnl
2701   case "${target}" in
2702     *-*-solaris2.1[1-9]*)
2703       comdat_group=no
2704       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2705       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2706       # version 1.688.
2707       #
2708       # If using Sun as for COMDAT group as emitted by GCC, one needs at
2709       # least ld version 1.2267.
2710       if test "$ld_vers_major" -gt 1; then
2711         comdat_group=yes
2712       elif test "x$gas_flag" = xyes && test "$ld_vers_minor" -ge 1688; then
2713         comdat_group=yes
2714       elif test "$ld_vers_minor" -ge 2267; then
2715         comdat_group=yes
2716       fi
2717       ;;
2718     *)
2719       # Assume linkers other than GNU ld don't support COMDAT group.
2720       comdat_group=no
2721       ;;
2722   esac
2723 changequote([,])dnl
2724 fi
2725 # Allow overriding the automatic COMDAT group tests above.
2726 AC_ARG_ENABLE(comdat,
2727   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2728   [comdat_group="$enable_comdat"])
2729 if test $comdat_group = no; then
2730   gcc_cv_as_comdat_group=no
2731   gcc_cv_as_comdat_group_percent=no
2732   gcc_cv_as_comdat_group_group=no
2733 fi
2734 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2735   [`if test $gcc_cv_as_comdat_group = yes \
2736     || test $gcc_cv_as_comdat_group_percent = yes \
2737     || test $gcc_cv_as_comdat_group_group = yes; then echo 1; else echo 0; fi`],
2738 [Define 0/1 if your assembler and linker support COMDAT groups.])
2739
2740 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2741  gcc_cv_as_discriminator,
2742  [2,19,51],,
2743 [       .text
2744         .file 1 "conf.c"
2745         .loc 1 1 0 discriminator 1],,
2746 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2747   [Define if your assembler supports the .loc discriminator sub-directive.])])
2748
2749 # Thread-local storage - the check is heavily parameterized.
2750 conftest_s=
2751 tls_first_major=
2752 tls_first_minor=
2753 tls_as_opt=
2754 case "$target" in
2755 changequote(,)dnl
2756   alpha*-*-*)
2757     conftest_s='
2758         .section ".tdata","awT",@progbits
2759 foo:    .long   25
2760         .text
2761         ldq     $27,__tls_get_addr($29)         !literal!1
2762         lda     $16,foo($29)                    !tlsgd!1
2763         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2764         ldq     $27,__tls_get_addr($29)         !literal!2
2765         lda     $16,foo($29)                    !tlsldm!2
2766         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2767         ldq     $1,foo($29)                     !gotdtprel
2768         ldah    $2,foo($29)                     !dtprelhi
2769         lda     $3,foo($2)                      !dtprello
2770         lda     $4,foo($29)                     !dtprel
2771         ldq     $1,foo($29)                     !gottprel
2772         ldah    $2,foo($29)                     !tprelhi
2773         lda     $3,foo($2)                      !tprello
2774         lda     $4,foo($29)                     !tprel'
2775         tls_first_major=2
2776         tls_first_minor=13
2777         tls_as_opt=--fatal-warnings
2778         ;;
2779   cris-*-*|crisv32-*-*)
2780     conftest_s='
2781         .section ".tdata","awT",@progbits
2782 x:      .long   25
2783         .text
2784         move.d x:IE,$r10
2785         nop'
2786         tls_first_major=2
2787         tls_first_minor=20
2788         tls_as_opt=--fatal-warnings
2789         ;;
2790   frv*-*-*)
2791     conftest_s='
2792         .section ".tdata","awT",@progbits
2793 x:      .long   25
2794         .text
2795         call    #gettlsoff(x)'
2796         tls_first_major=2
2797         tls_first_minor=14
2798         ;;
2799   hppa*-*-linux*)
2800     conftest_s='
2801 t1:     .reg    %r20
2802 t2:     .reg    %r21
2803 gp:     .reg    %r19
2804         .section ".tdata","awT",@progbits
2805 foo:    .long   25
2806         .text
2807         .align  4
2808         addil LT%foo-$tls_gdidx$,gp
2809         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2810         b __tls_get_addr
2811         nop
2812         addil LT%foo-$tls_ldidx$,gp
2813         b __tls_get_addr
2814         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2815         addil LR%foo-$tls_dtpoff$,%ret0
2816         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2817         mfctl %cr27,%t1
2818         addil LT%foo-$tls_ieoff$,gp
2819         ldw RT%foo-$tls_ieoff$(%r1),%t2
2820         add %t1,%t2,%t3
2821         mfctl %cr27,%t1
2822         addil LR%foo-$tls_leoff$,%t1
2823         ldo RR%foo-$tls_leoff$(%r1),%t2'
2824         tls_first_major=2
2825         tls_first_minor=15
2826         tls_as_opt=--fatal-warnings
2827         ;;
2828   arm*-*-*)
2829     conftest_s='
2830         .section ".tdata","awT",%progbits
2831 foo:    .long   25
2832         .text
2833 .word foo(gottpoff)
2834 .word foo(tpoff)
2835 .word foo(tlsgd)
2836 .word foo(tlsldm)
2837 .word foo(tlsldo)'
2838         tls_first_major=2
2839         tls_first_minor=17
2840         ;;
2841   i[34567]86-*-* | x86_64-*-solaris2.1[0-9]*)
2842     case "$target" in
2843       i[34567]86-*-solaris2.*)
2844         on_solaris=yes
2845         tga_func=___tls_get_addr
2846         ;;
2847       x86_64-*-solaris2.1[0-9]*)
2848         on_solaris=yes
2849         tga_func=__tls_get_addr
2850         ;;
2851       *)
2852         on_solaris=no
2853         ;;
2854     esac
2855     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2856       conftest_s='
2857         .section .tdata,"awt",@progbits'
2858       tls_first_major=0
2859       tls_first_minor=0
2860 changequote([,])dnl
2861       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2862 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2863 changequote(,)dnl
2864     else
2865       conftest_s='
2866         .section ".tdata","awT",@progbits'
2867       tls_first_major=2
2868       tls_first_minor=14
2869       tls_as_opt="--fatal-warnings"
2870     fi
2871     conftest_s="$conftest_s
2872 foo:    .long   25
2873         .text
2874         movl    %gs:0, %eax
2875         leal    foo@tlsgd(,%ebx,1), %eax
2876         leal    foo@tlsldm(%ebx), %eax
2877         leal    foo@dtpoff(%eax), %edx
2878         movl    foo@gottpoff(%ebx), %eax
2879         subl    foo@gottpoff(%ebx), %eax
2880         addl    foo@gotntpoff(%ebx), %eax
2881         movl    foo@indntpoff, %eax
2882         movl    \$foo@tpoff, %eax
2883         subl    \$foo@tpoff, %eax
2884         leal    foo@ntpoff(%ecx), %eax"
2885     ;;
2886   x86_64-*-*)
2887     conftest_s='
2888         .section ".tdata","awT",@progbits
2889 foo:    .long   25
2890         .text
2891         movq    %fs:0, %rax
2892         leaq    foo@TLSGD(%rip), %rdi
2893         leaq    foo@TLSLD(%rip), %rdi
2894         leaq    foo@DTPOFF(%rax), %rdx
2895         movq    foo@GOTTPOFF(%rip), %rax
2896         movq    $foo@TPOFF, %rax'
2897         tls_first_major=2
2898         tls_first_minor=14
2899         tls_as_opt=--fatal-warnings
2900         ;;
2901   ia64-*-*)
2902     conftest_s='
2903         .section ".tdata","awT",@progbits
2904 foo:    data8   25
2905         .text
2906         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2907         addl    r17 = @ltoff(@dtprel(foo#)), gp
2908         addl    r18 = @ltoff(@tprel(foo#)), gp
2909         addl    r19 = @dtprel(foo#), gp
2910         adds    r21 = @dtprel(foo#), r13
2911         movl    r23 = @dtprel(foo#)
2912         addl    r20 = @tprel(foo#), gp
2913         adds    r22 = @tprel(foo#), r13
2914         movl    r24 = @tprel(foo#)'
2915         tls_first_major=2
2916         tls_first_minor=13
2917         tls_as_opt=--fatal-warnings
2918         ;;
2919   mips*-*-*)
2920     conftest_s='
2921         .section .tdata,"awT",@progbits
2922 x:
2923         .word 2
2924         .text
2925         addiu $4, $28, %tlsgd(x)
2926         addiu $4, $28, %tlsldm(x)
2927         lui $4, %dtprel_hi(x)
2928         addiu $4, $4, %dtprel_lo(x)
2929         lw $4, %gottprel(x)($28)
2930         lui $4, %tprel_hi(x)
2931         addiu $4, $4, %tprel_lo(x)'
2932         tls_first_major=2
2933         tls_first_minor=16
2934         tls_as_opt='-32 --fatal-warnings'
2935         ;;
2936   m68k-*-*)
2937     conftest_s='
2938         .section .tdata,"awT",@progbits
2939 x:
2940         .word 2
2941         .text
2942 foo:
2943         move.l x@TLSGD(%a5),%a0
2944         move.l x@TLSLDM(%a5),%a0
2945         move.l x@TLSLDO(%a5),%a0
2946         move.l x@TLSIE(%a5),%a0
2947         move.l x@TLSLE(%a5),%a0'
2948         tls_first_major=2
2949         tls_first_minor=19
2950         tls_as_opt='--fatal-warnings'
2951         ;;
2952   powerpc-*-*)
2953     conftest_s='
2954         .section ".tdata","awT",@progbits
2955         .align 2
2956 ld0:    .space 4
2957 ld1:    .space 4
2958 x1:     .space 4
2959 x2:     .space 4
2960 x3:     .space 4
2961         .text
2962         addi 3,31,ld0@got@tlsgd
2963         bl __tls_get_addr
2964         addi 3,31,x1@got@tlsld
2965         bl __tls_get_addr
2966         addi 9,3,x1@dtprel
2967         addis 9,3,x2@dtprel@ha
2968         addi 9,9,x2@dtprel@l
2969         lwz 9,x3@got@tprel(31)
2970         add 9,9,x@tls
2971         addi 9,2,x1@tprel
2972         addis 9,2,x2@tprel@ha
2973         addi 9,9,x2@tprel@l'
2974         tls_first_major=2
2975         tls_first_minor=14
2976         tls_as_opt="-a32 --fatal-warnings"
2977         ;;
2978   powerpc64-*-*)
2979     conftest_s='
2980         .section ".tdata","awT",@progbits
2981         .align 3
2982 ld0:    .space 8
2983 ld1:    .space 8
2984 x1:     .space 8
2985 x2:     .space 8
2986 x3:     .space 8
2987         .text
2988         addi 3,2,ld0@got@tlsgd
2989         bl .__tls_get_addr
2990         nop
2991         addi 3,2,ld1@toc
2992         bl .__tls_get_addr
2993         nop
2994         addi 3,2,x1@got@tlsld
2995         bl .__tls_get_addr
2996         nop
2997         addi 9,3,x1@dtprel
2998         bl .__tls_get_addr
2999         nop
3000         addis 9,3,x2@dtprel@ha
3001         addi 9,9,x2@dtprel@l
3002         bl .__tls_get_addr
3003         nop
3004         ld 9,x3@got@dtprel(2)
3005         add 9,9,3
3006         bl .__tls_get_addr
3007         nop'
3008         tls_first_major=2
3009         tls_first_minor=14
3010         tls_as_opt="-a64 --fatal-warnings"
3011         ;;
3012   s390-*-*)
3013     conftest_s='
3014         .section ".tdata","awT",@progbits
3015 foo:    .long   25
3016         .text
3017         .long   foo@TLSGD
3018         .long   foo@TLSLDM
3019         .long   foo@DTPOFF
3020         .long   foo@NTPOFF
3021         .long   foo@GOTNTPOFF
3022         .long   foo@INDNTPOFF
3023         l       %r1,foo@GOTNTPOFF(%r12)
3024         l       %r1,0(%r1):tls_load:foo
3025         bas     %r14,0(%r1,%r13):tls_gdcall:foo
3026         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
3027         tls_first_major=2
3028         tls_first_minor=14
3029         tls_as_opt="-m31 --fatal-warnings"
3030         ;;
3031   s390x-*-*)
3032     conftest_s='
3033         .section ".tdata","awT",@progbits
3034 foo:    .long   25
3035         .text
3036         .quad   foo@TLSGD
3037         .quad   foo@TLSLDM
3038         .quad   foo@DTPOFF
3039         .quad   foo@NTPOFF
3040         .quad   foo@GOTNTPOFF
3041         lg      %r1,foo@GOTNTPOFF(%r12)
3042         larl    %r1,foo@INDNTPOFF
3043         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
3044         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
3045         tls_first_major=2
3046         tls_first_minor=14
3047         tls_as_opt="-m64 -Aesame --fatal-warnings"
3048         ;;
3049   sh-*-* | sh[34]-*-*)
3050     conftest_s='
3051         .section ".tdata","awT",@progbits
3052 foo:    .long   25
3053         .text
3054         .long   foo@TLSGD
3055         .long   foo@TLSLDM
3056         .long   foo@DTPOFF
3057         .long   foo@GOTTPOFF
3058         .long   foo@TPOFF'
3059         tls_first_major=2
3060         tls_first_minor=13
3061         tls_as_opt=--fatal-warnings
3062         ;;
3063   sparc*-*-*)
3064     case "$target" in
3065       sparc*-sun-solaris2.*)
3066         on_solaris=yes
3067         tga_func=__tls_get_addr
3068         ;;
3069       *)
3070         on_solaris=no
3071         ;;
3072     esac
3073     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3074       conftest_s='
3075         .section ".tdata",#alloc,#write,#tls'
3076         tls_first_major=0
3077         tls_first_minor=0
3078     else
3079       conftest_s='
3080         .section ".tdata","awT",@progbits'
3081         tls_first_major=2
3082         tls_first_minor=14
3083         tls_as_opt="-32 --fatal-warnings"
3084     fi
3085     conftest_s="$conftest_s
3086 foo:    .long   25
3087         .text
3088         sethi   %tgd_hi22(foo), %o0
3089         add     %o0, %tgd_lo10(foo), %o1
3090         add     %l7, %o1, %o0, %tgd_add(foo)
3091         call    __tls_get_addr, %tgd_call(foo)
3092         sethi   %tldm_hi22(foo), %l1
3093         add     %l1, %tldm_lo10(foo), %l2
3094         add     %l7, %l2, %o0, %tldm_add(foo)
3095         call    __tls_get_addr, %tldm_call(foo)
3096         sethi   %tldo_hix22(foo), %l3
3097         xor     %l3, %tldo_lox10(foo), %l4
3098         add     %o0, %l4, %l5, %tldo_add(foo)
3099         sethi   %tie_hi22(foo), %o3
3100         add     %o3, %tie_lo10(foo), %o3
3101         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3102         add     %g7, %o2, %o4, %tie_add(foo)
3103         sethi   %tle_hix22(foo), %l1
3104         xor     %l1, %tle_lox10(foo), %o5
3105         ld      [%g7 + %o5], %o1"
3106         ;;
3107   tilepro*-*-*)
3108       conftest_s='
3109         .section ".tdata","awT",@progbits
3110 foo:    .long   25
3111         .text
3112         addli   r0, zero, tls_gd(foo)
3113         auli    r0, zero, tls_gd_ha16(foo)
3114         addli   r0, r0, tls_gd_lo16(foo)
3115         jal     __tls_get_addr
3116         addli   r0, zero, tls_ie(foo)
3117         auli    r0, r0, tls_ie_ha16(foo)
3118         addli   r0, r0, tls_ie_lo16(foo)'
3119         tls_first_major=2
3120         tls_first_minor=22
3121         tls_as_opt="--fatal-warnings"
3122         ;;
3123   tilegx*-*-*)
3124       conftest_s='
3125         .section ".tdata","awT",@progbits
3126 foo:    .long   25
3127         .text
3128         shl16insli r0, zero, hw0_last_tls_gd(foo)
3129         shl16insli r0, zero, hw1_last_tls_gd(foo)
3130         shl16insli r0, r0,   hw0_tls_gd(foo)
3131         jal        __tls_get_addr
3132         shl16insli r0, zero, hw1_last_tls_ie(foo)
3133         shl16insli r0, r0,   hw0_tls_ie(foo)'
3134         tls_first_major=2
3135         tls_first_minor=22
3136         tls_as_opt="--fatal-warnings"
3137         ;;
3138   xtensa*-*-*)
3139     conftest_s='
3140         .section ".tdata","awT",@progbits
3141 foo:    .long   25
3142         .text
3143         movi    a8, foo@TLSFUNC
3144         movi    a10, foo@TLSARG
3145         callx8.tls a8, foo@TLSCALL'
3146         tls_first_major=2
3147         tls_first_minor=19
3148         ;;
3149 changequote([,])dnl
3150 esac
3151 set_have_as_tls=no
3152 if test "x$enable_tls" = xno ; then
3153   : # TLS explicitly disabled.
3154 elif test "x$enable_tls" = xyes ; then
3155   set_have_as_tls=yes # TLS explicitly enabled.
3156 elif test -z "$tls_first_major"; then
3157   : # If we don't have a check, assume no support.
3158 else
3159   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3160   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3161   [set_have_as_tls=yes])
3162 fi
3163 case "$target" in
3164   # TLS was introduced in the Solaris 9 FCS release.  Support for GNU-style
3165   # TLS on x86 was only introduced in Solaris 9 4/04, replacing the earlier
3166   # Sun style that Sun ld and GCC don't support any longer.
3167   *-*-solaris2.*)
3168     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
3169     ld_tls_support=no
3170     # Check ld and ld.so.1 TLS support.
3171     if echo "$ld_ver" | grep GNU > /dev/null; then
3172       # Assume all interesting versions of GNU ld have TLS support.
3173       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
3174       ld_tls_support=yes
3175     else
3176       case "$target" in
3177         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
3178         i?86-*-solaris2.9)
3179           min_tls_ld_vers_minor=374
3180           ;;
3181         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
3182         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
3183           min_tls_ld_vers_minor=343
3184           ;;
3185       esac
3186       if test "$ld_vers_major" -gt 1 || \
3187         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
3188         ld_tls_support=yes
3189       else
3190         set_have_as_tls=no
3191       fi
3192     fi
3193     AC_MSG_RESULT($ld_tls_support)
3194
3195     save_LIBS="$LIBS"
3196     save_LDFLAGS="$LDFLAGS"
3197     LIBS=
3198     LDFLAGS=
3199
3200     AC_MSG_CHECKING(library containing $tga_func)
3201     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3202     # (32-bit x86) only lived in libthread, so check for that.  Keep
3203     # set_have_as_tls if found, disable if not.
3204     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3205     # Clear LIBS if we cannot support TLS.
3206     if test $set_have_as_tls = no; then
3207       LIBS=
3208     fi
3209     # Always define LIB_TLS_SPEC, even without TLS support.
3210     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3211         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3212     AC_MSG_RESULT($LIBS)
3213
3214     LIBS="$save_LIBS"
3215     LDFLAGS="$save_LDFLAGS"
3216     ;;
3217 esac
3218 if test $set_have_as_tls = yes ; then
3219   AC_DEFINE(HAVE_AS_TLS, 1,
3220             [Define if your assembler and linker support thread-local storage.])
3221 fi
3222
3223 # Target-specific assembler checks.
3224
3225 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3226 gcc_cv_ld_static_dynamic=no
3227 gcc_cv_ld_static_option='-Bstatic'
3228 gcc_cv_ld_dynamic_option='-Bdynamic'
3229 if test $in_tree_ld = yes ; then
3230   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3231     gcc_cv_ld_static_dynamic=yes
3232   fi
3233 elif test x$gcc_cv_ld != x; then
3234   # Check if linker supports -Bstatic/-Bdynamic option
3235   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3236      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3237       gcc_cv_ld_static_dynamic=yes
3238   else
3239     case "$target" in
3240       # HP-UX ld uses -a flags to select between shared and archive.
3241       *-*-hpux*)
3242         if test x"$gnu_ld" = xno; then
3243           gcc_cv_ld_static_dynamic=yes
3244           gcc_cv_ld_static_option="-aarchive_shared"
3245           gcc_cv_ld_dynamic_option="-adefault"
3246         fi
3247         ;;
3248       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3249       *-*-solaris2*)
3250         gcc_cv_ld_static_dynamic=yes
3251         ;;
3252     esac
3253   fi
3254 fi
3255 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3256         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3257 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3258         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3259 [Define to the linker option to disable use of shared objects.])
3260         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3261 [Define to the linker option to enable use of shared objects.])
3262 fi
3263 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3264
3265 if test x"$demangler_in_ld" = xyes; then
3266   AC_MSG_CHECKING(linker --demangle support)
3267   gcc_cv_ld_demangle=no
3268   if test $in_tree_ld = yes; then
3269     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3270       gcc_cv_ld_demangle=yes
3271     fi
3272   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3273     # Check if the GNU linker supports --demangle option
3274     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3275       gcc_cv_ld_demangle=yes
3276     fi
3277   fi
3278   if test x"$gcc_cv_ld_demangle" = xyes; then
3279     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3280 [Define if your linker supports --demangle option.])
3281   fi
3282   AC_MSG_RESULT($gcc_cv_ld_demangle)
3283 fi
3284
3285 AC_MSG_CHECKING(linker plugin support)
3286 gcc_cv_lto_plugin=0
3287 if test -f liblto_plugin.la; then
3288   save_ld_ver="$ld_ver"
3289   save_ld_vers_major="$ld_vers_major"
3290   save_ld_vers_minor="$ld_vers_minor"
3291   save_ld_is_gold="$ld_is_gold"
3292
3293   ld_is_gold=no
3294
3295   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3296     ld_ver="GNU ld"
3297     # FIXME: ld_is_gold?
3298     ld_vers_major="$gcc_cv_gld_major_version"
3299     ld_vers_minor="$gcc_cv_gld_minor_version"
3300   else
3301     # Determine plugin linker version.
3302     # FIXME: Partial duplicate from above, generalize.
3303 changequote(,)dnl
3304     ld_ver=`$ORIGINAL_PLUGIN_LD_FOR_TARGET --version 2>/dev/null | sed 1q`
3305     if echo "$ld_ver" | grep GNU > /dev/null; then
3306       if echo "$ld_ver" | grep "GNU gold" > /dev/null; then
3307         ld_is_gold=yes
3308         ld_vers=`echo $ld_ver | sed -n \
3309             -e 's,^[^)]*[        ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
3310       else
3311         ld_vers=`echo $ld_ver | sed -n \
3312             -e 's,^.*[   ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
3313       fi
3314       ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3315       ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3316     fi
3317 changequote([,])dnl
3318   fi
3319
3320   # Determine plugin support.
3321   if echo "$ld_ver" | grep GNU > /dev/null; then
3322     # Require GNU ld or gold 2.21+ for plugin support by default.
3323     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3324       gcc_cv_lto_plugin=2
3325     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3326     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3327       gcc_cv_lto_plugin=1
3328     fi
3329   fi
3330
3331   ld_ver="$save_ld_ver"
3332   ld_vers_major="$save_ld_vers_major"
3333   ld_vers_minor="$save_ld_vers_minor"
3334   ld_is_gold="$save_ld_is_gold"
3335 fi
3336 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3337   [Define to the level of your linker's plugin support.])
3338 AC_MSG_RESULT($gcc_cv_lto_plugin)
3339
3340 case "$target" in
3341   # All TARGET_ABI_OSF targets.
3342   alpha*-*-linux* | alpha*-*-*bsd*)
3343     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3344         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3345 [       .set nomacro
3346         .text
3347         extbl   $3, $2, $3      !lituse_bytoff!1
3348         ldq     $2, a($29)      !literal!1
3349         ldq     $4, b($29)      !literal!2
3350         ldq_u   $3, 0($2)       !lituse_base!1
3351         ldq     $27, f($29)     !literal!5
3352         jsr     $26, ($27), f   !lituse_jsr!5
3353         ldah    $29, 0($26)     !gpdisp!3
3354         lda     $0, c($29)      !gprel
3355         ldah    $1, d($29)      !gprelhigh
3356         lda     $1, d($1)       !gprellow
3357         lda     $29, 0($29)     !gpdisp!3],,
3358     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3359   [Define if your assembler supports explicit relocations.])])
3360     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3361         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3362 [       .set nomacro
3363         .text
3364         ldq     $27, a($29)     !literal!1
3365         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3366     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3367   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3368     ;;
3369
3370   cris-*-*)
3371     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3372       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3373       [-no-mul-bug-abort], [.text],,
3374       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3375                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3376     ;;
3377
3378   sparc*-*-*)
3379     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3380       [.register %g2, #scratch],,
3381       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3382                 [Define if your assembler supports .register.])])
3383
3384     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3385       [-relax], [.text],,
3386       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3387                 [Define if your assembler supports -relax option.])])
3388
3389     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3390       gcc_cv_as_sparc_gotdata_op,,
3391       [-K PIC],
3392 [.text
3393 .align 4
3394 foo:
3395         nop
3396 bar:
3397         sethi %gdop_hix22(foo), %g1
3398         xor    %g1, %gdop_lox10(foo), %g1
3399         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3400       [if test x$gcc_cv_ld != x \
3401        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3402          if test x$gcc_cv_objdump != x; then
3403            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3404               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3405                gcc_cv_as_sparc_gotdata_op=no
3406            else
3407                gcc_cv_as_sparc_gotdata_op=yes
3408            fi
3409          fi
3410        fi
3411        rm -f conftest],
3412       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3413                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3414
3415     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3416       gcc_cv_as_sparc_ua_pcrel,,
3417       [-K PIC],
3418 [.text
3419 foo:
3420         nop
3421 .data
3422 .align 4
3423 .byte 0
3424 .uaword %r_disp32(foo)],
3425       [if test x$gcc_cv_ld != x \
3426        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3427          gcc_cv_as_sparc_ua_pcrel=yes
3428        fi
3429        rm -f conftest],
3430       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3431                 [Define if your assembler and linker support unaligned PC relative relocs.])
3432
3433       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3434         gcc_cv_as_sparc_ua_pcrel_hidden,,
3435         [-K PIC],
3436 [.data
3437 .align 4
3438 .byte 0x31
3439 .uaword %r_disp32(foo)
3440 .byte 0x32, 0x33, 0x34
3441 .global foo
3442 .hidden foo
3443 foo:
3444 .skip 4],
3445         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3446          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3447          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3448             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3449             if $gcc_cv_objdump -R conftest 2> /dev/null \
3450                | grep 'DISP32' > /dev/null 2>&1; then
3451                 :
3452             else
3453                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3454             fi
3455          fi
3456          rm -f conftest],
3457          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3458                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3459     ]) # unaligned pcrel relocs
3460
3461     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3462       gcc_cv_as_sparc_offsetable_lo10,,
3463       [-xarch=v9],
3464 [.text
3465         or %g1, %lo(ab) + 12, %g1
3466         or %g1, %lo(ab + 12), %g1],
3467       [if test x$gcc_cv_objdump != x \
3468        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3469           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3470          gcc_cv_as_sparc_offsetable_lo10=yes
3471        fi],
3472        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3473                  [Define if your assembler supports offsetable %lo().])])
3474
3475     gcc_GAS_CHECK_FEATURE([FMAF, HPC, and VIS 3.0 instructions],
3476       gcc_cv_as_sparc_fmaf,,
3477       [-xarch=v9d],
3478       [.text
3479        .register %g2, #scratch
3480        .register %g3, #scratch
3481        .align 4
3482        fmaddd %f0, %f2, %f4, %f6
3483        addxccc %g1, %g2, %g3
3484        fsrl32 %f2, %f4, %f8
3485        fnaddd %f10, %f12, %f14],,
3486       [AC_DEFINE(HAVE_AS_FMAF_HPC_VIS3, 1,
3487                 [Define if your assembler supports FMAF, HPC, and VIS 3.0 instructions.])])
3488     ;;
3489
3490 changequote(,)dnl
3491   i[34567]86-*-* | x86_64-*-*)
3492 changequote([,])dnl
3493     case $target_os in
3494       cygwin*)
3495         # Full C++ conformance when using a shared libstdc++-v3 requires some
3496         # support from the Cygwin DLL, which in more recent versions exports
3497         # wrappers to aid in interposing and redirecting operators new, delete,
3498         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3499         # are configuring for a version of Cygwin that exports the wrappers.
3500         if test x$host = x$target; then
3501           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3502         else
3503           # Can't check presence of libc functions during cross-compile, so
3504           # we just have to assume we're building for an up-to-date target.
3505           gcc_ac_cygwin_dll_wrappers=yes
3506         fi
3507         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3508           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3509           [Define if you want to generate code by default that assumes that the
3510            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3511     esac
3512     case $target_os in
3513       cygwin* | pe | mingw32* | interix*)
3514         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3515         # definition is used unconditionally to initialise the default state of
3516         # the target option variable that governs usage of the feature.
3517         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3518          [2,19,52],,[.comm foo,1,32])
3519         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3520           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3521           [Define if your assembler supports specifying the alignment
3522            of objects allocated using the GAS .comm command.])
3523         # Used for DWARF 2 in PE
3524         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3525           gcc_cv_as_ix86_pe_secrel32,
3526           [2,15,91],,
3527 [.text
3528 foo:    nop
3529 .data
3530         .secrel32 foo],
3531           [if test x$gcc_cv_ld != x \
3532            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3533              gcc_cv_as_ix86_pe_secrel32=yes
3534            fi
3535            rm -f conftest],
3536           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3537             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3538         # Test if the assembler supports the extended form of the .section
3539         # directive that specifies section alignment.  LTO support uses this,
3540         # but normally only after installation, so we warn but don't fail the
3541         # configure if LTO is enabled but the assembler does not support it.
3542         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3543           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3544         if test x$gcc_cv_as_section_has_align != xyes; then
3545           case ",$enable_languages," in
3546             *,lto,*)
3547               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3548               ;;
3549           esac
3550         fi
3551         # Test if the assembler supports the section flag 'e' for specifying
3552         # an excluded section.
3553         gcc_GAS_CHECK_FEATURE([.section with e], gcc_cv_as_section_has_e,
3554           [2,22,51],,
3555 [.section foo1,"e"
3556 .byte 0,0,0,0])
3557         AC_DEFINE_UNQUOTED(HAVE_GAS_SECTION_EXCLUDE,
3558           [`if test $gcc_cv_as_section_has_e = yes; then echo 1; else echo 0; fi`],
3559           [Define if your assembler supports specifying the section flag e.])
3560         ;;
3561     esac
3562
3563     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3564        gcc_cv_as_ix86_filds,,,
3565        [filds mem; fists mem],,
3566        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3567          [Define if your assembler uses filds and fists mnemonics.])])
3568
3569     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3570        gcc_cv_as_ix86_fildq,,,
3571        [fildq mem; fistpq mem],,
3572        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3573          [Define if your assembler uses fildq and fistq mnemonics.])])
3574
3575     gcc_GAS_CHECK_FEATURE([cmov syntax],
3576       gcc_cv_as_ix86_cmov_sun_syntax,,,
3577       [cmovl.l %edx, %eax],,
3578       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3579         [Define if your assembler supports the Sun syntax for cmov.])])
3580
3581     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3582       gcc_cv_as_ix86_ffreep,,,
3583       [ffreep %st(1)],,
3584       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3585         [Define if your assembler supports the ffreep mnemonic.])])
3586
3587     gcc_GAS_CHECK_FEATURE([.quad directive],
3588       gcc_cv_as_ix86_quad,,,
3589       [.quad 0],,
3590       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3591         [Define if your assembler supports the .quad directive.])])
3592
3593     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3594       gcc_cv_as_ix86_sahf,,,
3595       [.code64
3596        sahf],,
3597       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3598         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3599
3600     gcc_GAS_CHECK_FEATURE([hle prefixes],
3601       gcc_cv_as_ix86_hle,,,
3602       [.code64
3603        lock xacquire cmpxchg %esi, (%rcx)
3604        ],,
3605       [AC_DEFINE(HAVE_AS_IX86_HLE, 1,
3606         [Define if your assembler supports HLE prefixes.])])
3607
3608     gcc_GAS_CHECK_FEATURE([swap suffix],
3609       gcc_cv_as_ix86_swap,,,
3610       [movl.s %esp, %ebp],,
3611       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3612         [Define if your assembler supports the swap suffix.])])
3613
3614     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3615       gcc_cv_as_ix86_diff_sect_delta,,,
3616       [.section .rodata
3617 .L1:
3618         .long .L2-.L1
3619         .long .L3-.L1
3620         .text
3621 .L3:    nop
3622 .L2:    nop],,
3623       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3624         [Define if your assembler supports the subtraction of symbols in different sections.])])
3625
3626     # These two are used unconditionally by i386.[ch]; it is to be defined
3627     # to 1 if the feature is present, 0 otherwise.
3628     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3629         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3630 [       .text
3631 .L0:
3632         nop
3633         .data
3634         .long .L0@GOTOFF])
3635     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3636       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3637       [Define true if the assembler supports '.long foo@GOTOFF'.])
3638
3639     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3640         gcc_cv_as_ix86_rep_lock_prefix,,,
3641         [rep movsl
3642          lock addl %edi, (%eax,%esi)
3643          lock orl $0, (%esp)],,
3644         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3645           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3646
3647     gcc_GAS_CHECK_FEATURE([R_386_TLS_GD_PLT reloc],
3648         gcc_cv_as_ix86_tlsgdplt,,,
3649         [call    tls_gd@tlsgdplt],
3650         [if test x$gcc_cv_ld != x \
3651          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3652            gcc_cv_as_ix86_tlsgdplt=yes
3653          fi
3654          rm -f conftest],
3655       [AC_DEFINE(HAVE_AS_IX86_TLSGDPLT, 1,
3656         [Define if your assembler and linker support @tlsgdplt.])])
3657
3658     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM_PLT reloc],
3659         gcc_cv_as_ix86_tlsldmplt,,,
3660         [tls_ld:
3661          call    tls_ld@tlsldmplt],
3662         [if test x$gcc_cv_ld != x \
3663          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3664            gcc_cv_as_ix86_tlsldmplt=yes
3665          fi
3666          rm -f conftest],
3667       [AC_DEFINE(HAVE_AS_IX86_TLSLDMPLT, 1,
3668         [Define if your assembler and linker support @tlsldmplt.])])
3669
3670     ;;
3671
3672   ia64*-*-*)
3673     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3674         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3675 [       .text
3676         addl r15 = @ltoffx(x#), gp
3677         ;;
3678         ld8.mov r16 = [[r15]], x#],,
3679     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3680           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3681
3682     ;;
3683
3684   powerpc*-*-*)
3685     case $target in
3686       *-*-aix*) conftest_s='    .machine "pwr5"
3687         .csect .text[[PR]]
3688         mfcr 3,128';;
3689       *-*-darwin*)
3690         gcc_GAS_CHECK_FEATURE([.machine directive support],
3691           gcc_cv_as_machine_directive,,,
3692           [     .machine ppc7400])
3693         if test x$gcc_cv_as_machine_directive != xyes; then
3694           echo "*** This target requires an assembler supporting \".machine\"" >&2
3695           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3696           test x$build = x$target && exit 1
3697         fi
3698         conftest_s='    .text
3699         mfcr r3,128';;
3700       *) conftest_s='   .machine power4
3701         .text
3702         mfcr 3,128';;
3703     esac
3704
3705     gcc_GAS_CHECK_FEATURE([mfcr field support],
3706       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3707       [$conftest_s],,
3708       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3709           [Define if your assembler supports mfcr field.])])
3710
3711     case $target in
3712       *-*-aix*) conftest_s='    .machine "pwr5"
3713         .csect .text[[PR]]
3714         popcntb 3,3';;
3715       *) conftest_s='   .machine power5
3716         .text
3717         popcntb 3,3';;
3718     esac
3719
3720     gcc_GAS_CHECK_FEATURE([popcntb support],
3721       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3722       [$conftest_s],,
3723       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3724           [Define if your assembler supports popcntb field.])])
3725
3726     case $target in
3727       *-*-aix*) conftest_s='    .machine "pwr5x"
3728         .csect .text[[PR]]
3729         frin 1,1';;
3730       *) conftest_s='   .machine power5
3731         .text
3732         frin 1,1';;
3733     esac
3734
3735     gcc_GAS_CHECK_FEATURE([fp round support],
3736       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3737       [$conftest_s],,
3738       [AC_DEFINE(HAVE_AS_FPRND, 1,
3739           [Define if your assembler supports fprnd.])])
3740
3741     case $target in
3742       *-*-aix*) conftest_s='    .machine "pwr6"
3743         .csect .text[[PR]]
3744         mffgpr 1,3';;
3745       *) conftest_s='   .machine power6
3746         .text
3747         mffgpr 1,3';;
3748     esac
3749
3750     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3751       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3752       [$conftest_s],,
3753       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3754           [Define if your assembler supports mffgpr and mftgpr.])])
3755
3756     case $target in
3757       *-*-aix*) conftest_s='    .csect .text[[PR]]
3758 LCF..0:
3759         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3760       *-*-darwin*)
3761         conftest_s='    .text
3762 LCF0:
3763         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3764       *) conftest_s='   .text
3765 .LCF0:
3766         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3767     esac
3768
3769     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3770       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3771       [$conftest_s],,
3772       [AC_DEFINE(HAVE_AS_REL16, 1,
3773           [Define if your assembler supports R_PPC_REL16 relocs.])])
3774
3775     case $target in
3776       *-*-aix*) conftest_s='    .machine "pwr6"
3777         .csect .text[[PR]]
3778         cmpb 3,4,5';;
3779       *) conftest_s='   .machine power6
3780         .text
3781         cmpb 3,4,5';;
3782     esac
3783
3784     gcc_GAS_CHECK_FEATURE([compare bytes support],
3785       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3786       [$conftest_s],,
3787       [AC_DEFINE(HAVE_AS_CMPB, 1,
3788           [Define if your assembler supports cmpb.])])
3789
3790     case $target in
3791       *-*-aix*) conftest_s='    .machine "pwr6"
3792         .csect .text[[PR]]
3793         dadd 1,2,3';;
3794       *) conftest_s='   .machine power6
3795         .text
3796         dadd 1,2,3';;
3797     esac
3798
3799     gcc_GAS_CHECK_FEATURE([decimal float support],
3800       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3801       [$conftest_s],,
3802       [AC_DEFINE(HAVE_AS_DFP, 1,
3803           [Define if your assembler supports DFP instructions.])])
3804
3805     case $target in
3806       *-*-aix*) conftest_s='    .machine "pwr7"
3807         .csect .text[[PR]]
3808         lxvd2x 1,2,3';;
3809       *) conftest_s='   .machine power7
3810         .text
3811         lxvd2x 1,2,3';;
3812     esac
3813
3814     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3815       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3816       [$conftest_s],,
3817       [AC_DEFINE(HAVE_AS_VSX, 1,
3818           [Define if your assembler supports VSX instructions.])])
3819
3820     case $target in
3821       *-*-aix*) conftest_s='    .machine "pwr7"
3822         .csect .text[[PR]]
3823         popcntd 3,3';;
3824       *) conftest_s='   .machine power7
3825         .text
3826         popcntd 3,3';;
3827     esac
3828
3829     gcc_GAS_CHECK_FEATURE([popcntd support],
3830       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3831       [$conftest_s],,
3832       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3833           [Define if your assembler supports POPCNTD instructions.])])
3834
3835     case $target in
3836       *-*-aix*) conftest_s='    .csect .text[[PR]]
3837         lwsync';;
3838       *) conftest_s='   .text
3839         lwsync';;
3840     esac
3841
3842     gcc_GAS_CHECK_FEATURE([lwsync support],
3843       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3844       [$conftest_s],,
3845       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3846           [Define if your assembler supports LWSYNC instructions.])])
3847
3848     case $target in
3849       *-*-aix*) conftest_s='    .machine "476"
3850         .csect .text[[PR]]
3851         dci 0';;
3852       *) conftest_s='   .machine "476"
3853         .text
3854         dci 0';;
3855     esac
3856
3857     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3858       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3859       [$conftest_s],,
3860       [AC_DEFINE(HAVE_AS_DCI, 1,
3861           [Define if your assembler supports the DCI/ICI instructions.])])
3862
3863     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3864       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3865       [.gnu_attribute 4,1],,
3866       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3867           [Define if your assembler supports .gnu_attribute.])])
3868
3869     gcc_GAS_CHECK_FEATURE([tls marker support],
3870       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3871       [ bl __tls_get_addr(x@tlsgd)],,
3872       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3873           [Define if your assembler supports arg info for __tls_get_addr.])])
3874
3875     case $target in
3876       *-*-aix*)
3877         gcc_GAS_CHECK_FEATURE([.ref support],
3878           gcc_cv_as_aix_ref, [2.21.0],,
3879           [     .csect stuff[[rw]]
3880              stuff:
3881                 .long 1
3882                 .extern sym
3883                 .ref sym
3884           ],,
3885           [AC_DEFINE(HAVE_AS_REF, 1,
3886             [Define if your assembler supports .ref])])
3887         ;;
3888     esac
3889     ;;
3890
3891   mips*-*-*)
3892     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3893       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3894 [       lw $4,%gp_rel(foo)($4)],,
3895       [if test x$target_cpu_default = x
3896        then target_cpu_default=MASK_EXPLICIT_RELOCS
3897        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3898        fi])
3899     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3900       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3901       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3902                  [Define if the assembler understands -mno-shared.])])
3903
3904     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3905       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3906       [.gnu_attribute 4,1],,
3907       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3908           [Define if your assembler supports .gnu_attribute.])])
3909
3910     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3911       gcc_cv_as_mips_dtprelword, [2,18,0],,
3912       [.section .tdata,"awT",@progbits
3913 x:
3914         .word 2
3915         .text
3916         .dtprelword x+0x8000],,
3917       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3918           [Define if your assembler supports .dtprelword.])])
3919
3920     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
3921       gcc_cv_as_mips_dspr1_mult,,,
3922 [       .set    mips32r2
3923         .set    nodspr2
3924         .set    dsp
3925         madd    $ac3,$4,$5
3926         maddu   $ac3,$4,$5
3927         msub    $ac3,$4,$5
3928         msubu   $ac3,$4,$5
3929         mult    $ac3,$4,$5
3930         multu   $ac3,$4,$5],,
3931       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
3932           [Define if your assembler supports DSPR1 mult.])])
3933
3934     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3935     gcc_cv_as_ld_jalr_reloc=no
3936     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3937       if test $in_tree_ld = yes ; then
3938         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3939            && test $in_tree_ld_is_elf = yes; then
3940           gcc_cv_as_ld_jalr_reloc=yes
3941         fi
3942       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3943         echo '  .ent x' > conftest.s
3944         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3945         echo '  ld $25,%call16(y)($28)' >> conftest.s
3946         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3947         echo '1:        jalr $25' >> conftest.s
3948         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3949         echo '1:        jalr $25' >> conftest.s
3950         echo '  .end x' >> conftest.s
3951         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3952            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3953           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
3954              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
3955             gcc_cv_as_ld_jalr_reloc=yes
3956           fi
3957         fi
3958         rm -f conftest.*
3959       fi
3960     fi
3961     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3962       if test x$target_cpu_default = x; then
3963         target_cpu_default=MASK_RELAX_PIC_CALLS
3964       else
3965         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3966       fi
3967     fi
3968     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3969
3970     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3971       [gcc_cv_ld_mips_personality_relaxation],
3972       [gcc_cv_ld_mips_personality_relaxation=no
3973        if test $in_tree_ld = yes ; then
3974          if test "$gcc_cv_gld_major_version" -eq 2 \
3975                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3976                  -o "$gcc_cv_gld_major_version" -gt 2; then
3977            gcc_cv_ld_mips_personality_relaxation=yes
3978          fi
3979        elif test x$gcc_cv_as != x \
3980                  -a x$gcc_cv_ld != x \
3981                  -a x$gcc_cv_readelf != x ; then
3982          cat > conftest.s <<EOF
3983         .cfi_startproc
3984         .cfi_personality 0x80,indirect_ptr
3985         .ent test
3986 test:
3987         nop
3988         .end test
3989         .cfi_endproc
3990
3991         .section .data,"aw",@progbits
3992 indirect_ptr:
3993         .dc.a personality
3994 EOF
3995          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3996             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3997            if $gcc_cv_readelf -d conftest 2>&1 \
3998               | grep TEXTREL > /dev/null 2>&1; then
3999              :
4000            elif $gcc_cv_readelf --relocs conftest 2>&1 \
4001                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
4002              :
4003            else
4004              gcc_cv_ld_mips_personality_relaxation=yes
4005            fi
4006          fi
4007        fi
4008        rm -f conftest.s conftest.o conftest])
4009     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
4010             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
4011       [Define if your linker can relax absolute .eh_frame personality
4012 pointers into PC-relative form.])
4013     fi
4014     ;;
4015 esac
4016
4017 # Mips and HP-UX need the GNU assembler.
4018 # Linux on IA64 might be able to use the Intel assembler.
4019
4020 case "$target" in
4021   mips*-*-* | *-*-hpux* )
4022     if test x$gas_flag = xyes \
4023        || test x"$host" != x"$build" \
4024        || test ! -x "$gcc_cv_as" \
4025        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
4026       :
4027     else
4028       echo "*** This configuration requires the GNU assembler" >&2
4029       exit 1
4030     fi
4031     ;;
4032 esac
4033
4034 # ??? Not all targets support dwarf2 debug_line, even within a version
4035 # of gas.  Moreover, we need to emit a valid instruction to trigger any
4036 # info to the output file.  So, as supported targets are added to gas 2.11,
4037 # add some instruction here to (also) show we expect this might work.
4038 # ??? Once 2.11 is released, probably need to add first known working
4039 # version to the per-target configury.
4040 case "$cpu_type" in
4041   alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze | mips \
4042   | pa | rs6000 | score | sparc | spu | tilegx | tilepro | xstormy16 | xtensa)
4043     insn="nop"
4044     ;;
4045   ia64 | s390)
4046     insn="nop 0"
4047     ;;
4048   mmix)
4049     insn="swym 0"
4050     ;;
4051 esac
4052 if test x"$insn" != x; then
4053  conftest_s="\
4054         .file 1 \"conftest.s\"
4055         .loc 1 3 0
4056         $insn"
4057  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
4058   gcc_cv_as_dwarf2_debug_line,
4059   [elf,2,11,0],, [$conftest_s],
4060   [if test x$gcc_cv_objdump != x \
4061    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
4062       | grep debug_line > /dev/null 2>&1; then
4063      gcc_cv_as_dwarf2_debug_line=yes
4064    fi])
4065
4066 # The .debug_line file table must be in the exact order that
4067 # we specified the files, since these indices are also used
4068 # by DW_AT_decl_file.  Approximate this test by testing if
4069 # the assembler bitches if the same index is assigned twice.
4070  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
4071   gcc_cv_as_dwarf2_file_buggy,,,
4072 [       .file 1 "foo.s"
4073         .file 1 "bar.s"])
4074
4075  if test $gcc_cv_as_dwarf2_debug_line = yes \
4076  && test $gcc_cv_as_dwarf2_file_buggy = no; then
4077         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
4078   [Define if your assembler supports dwarf2 .file/.loc directives,
4079    and preserves file table indices exactly as given.])
4080  fi
4081
4082  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
4083   gcc_cv_as_gdwarf2_flag,
4084   [elf,2,11,0], [--gdwarf2], [$insn],,
4085   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
4086 [Define if your assembler supports the --gdwarf2 option.])])
4087
4088  gcc_GAS_CHECK_FEATURE([--gstabs option],
4089   gcc_cv_as_gstabs_flag,
4090   [elf,2,11,0], [--gstabs], [$insn],
4091   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
4092    # and warns about it, but still exits successfully.  So check for
4093    # this.
4094    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
4095    then :
4096    else gcc_cv_as_gstabs_flag=yes
4097    fi],
4098   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
4099 [Define if your assembler supports the --gstabs option.])])
4100
4101  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
4102   gcc_cv_as_debug_prefix_map_flag,
4103   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
4104   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
4105 [Define if your assembler supports the --debug-prefix-map option.])])
4106 fi
4107
4108 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
4109  ,,
4110 [.lcomm bar,4,16],,
4111 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
4112   [Define if your assembler supports .lcomm with an alignment field.])])
4113
4114 AC_ARG_ENABLE(gnu-unique-object,
4115  [AS_HELP_STRING([--enable-gnu-unique-object],
4116    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
4117  [case $enable_gnu_unique_object in
4118     yes | no) ;;
4119     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
4120 Valid choices are 'yes' and 'no'.]) ;;
4121   esac],
4122  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
4123    [elf,2,19,52],,
4124    [.type foo, '$target_type_format_char'gnu_unique_object],,
4125 # We need to unquote above to to use the definition from config.gcc.
4126 # Also check for ld.so support, i.e. glibc 2.11 or higher.
4127    [[if test x$host = x$build -a x$host = x$target &&
4128        ldd --version 2>/dev/null &&
4129        glibcver=`ldd --version 2>/dev/null | sed 's/.* //;q'`; then
4130       glibcmajor=`expr "$glibcver" : "\([0-9]*\)"`
4131       glibcminor=`expr "$glibcver" : "[2-9]*\.\([0-9]*\)"`
4132       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
4133       if test "$glibcnum" -ge 2011 ; then
4134         enable_gnu_unique_object=yes
4135       fi
4136     fi]])])
4137 if test x$enable_gnu_unique_object = xyes; then
4138   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
4139    [Define if your assembler supports @gnu_unique_object.])
4140 fi
4141
4142 AC_CACHE_CHECK([assembler for tolerance to line number 0],
4143  [gcc_cv_as_line_zero],
4144  [gcc_cv_as_line_zero=no
4145   if test $in_tree_gas = yes; then
4146     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
4147   elif test "x$gcc_cv_as" != x; then
4148     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
4149     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
4150        test "x`cat conftest.out`" = x
4151     then
4152       gcc_cv_as_line_zero=yes
4153     else
4154       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
4155       cat conftest.s >&AS_MESSAGE_LOG_FD
4156       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
4157       cat conftest.out >&AS_MESSAGE_LOG_FD
4158     fi
4159     rm -f conftest.o conftest.s conftest.out
4160   fi])
4161 if test "x$gcc_cv_as_line_zero" = xyes; then
4162   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
4163 [Define if the assembler won't complain about a line such as # 0 "" 2.])
4164 fi
4165
4166 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
4167 gcc_cv_ld_eh_frame_hdr=no
4168 if test $in_tree_ld = yes ; then
4169   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4170      && test $in_tree_ld_is_elf = yes; then
4171     gcc_cv_ld_eh_frame_hdr=yes
4172   fi
4173 elif test x$gcc_cv_ld != x; then
4174   if echo "$ld_ver" | grep GNU > /dev/null; then
4175     # Check if linker supports --eh-frame-hdr option
4176     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4177       gcc_cv_ld_eh_frame_hdr=yes
4178     fi
4179   else
4180     case "$target" in
4181       *-*-solaris2*)
4182         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4183         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4184           gcc_cv_ld_eh_frame_hdr=yes
4185         fi
4186         ;;
4187     esac
4188   fi
4189 fi
4190 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4191 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4192         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4193 [Define if your linker supports .eh_frame_hdr.])
4194 fi
4195 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4196
4197 AC_MSG_CHECKING(linker position independent executable support)
4198 gcc_cv_ld_pie=no
4199 if test $in_tree_ld = yes ; then
4200   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
4201      && test $in_tree_ld_is_elf = yes; then
4202     gcc_cv_ld_pie=yes
4203   fi
4204 elif test x$gcc_cv_ld != x; then
4205         # Check if linker supports -pie option
4206         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
4207                 gcc_cv_ld_pie=yes
4208         fi
4209 fi
4210 if test x"$gcc_cv_ld_pie" = xyes; then
4211         AC_DEFINE(HAVE_LD_PIE, 1,
4212 [Define if your linker supports -pie option.])
4213 fi
4214 AC_MSG_RESULT($gcc_cv_ld_pie)
4215
4216 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
4217 gcc_cv_ld_eh_gc_sections=no
4218 if test $in_tree_ld = yes ; then
4219   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
4220      && test $in_tree_ld_is_elf = yes; then
4221     gcc_cv_ld_eh_gc_sections=yes
4222   fi
4223 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
4224   cat > conftest.s <<EOF
4225         .section        .text
4226 .globl _start
4227         .type _start, @function
4228 _start:
4229         .long foo
4230         .size _start, .-_start
4231         .section        .text.foo,"ax",@progbits
4232         .type foo, @function
4233 foo:
4234         .long 0
4235         .size foo, .-foo
4236         .section        .gcc_except_table.foo,"a",@progbits
4237 .L0:
4238         .long 0
4239         .section        .eh_frame,"a",@progbits
4240         .long .L0
4241 EOF
4242   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4243     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4244          | grep "gc-sections option ignored" > /dev/null; then
4245       gcc_cv_ld_eh_gc_sections=no
4246     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4247          | grep gcc_except_table > /dev/null; then
4248       gcc_cv_ld_eh_gc_sections=yes
4249       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
4250       if test x$gcc_cv_as_comdat_group != xyes; then
4251         gcc_cv_ld_eh_gc_sections=no
4252         cat > conftest.s <<EOF
4253         .section        .text
4254 .globl _start
4255         .type _start, @function
4256 _start:
4257         .long foo
4258         .size _start, .-_start
4259         .section        .gnu.linkonce.t.foo,"ax",@progbits
4260         .type foo, @function
4261 foo:
4262         .long 0
4263         .size foo, .-foo
4264         .section        .gcc_except_table.foo,"a",@progbits
4265 .L0:
4266         .long 0
4267         .section        .eh_frame,"a",@progbits
4268         .long .L0
4269 EOF
4270         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4271           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4272                | grep "gc-sections option ignored" > /dev/null; then
4273             gcc_cv_ld_eh_gc_sections=no
4274           elif $gcc_cv_objdump -h conftest 2> /dev/null \
4275                | grep gcc_except_table > /dev/null; then
4276             gcc_cv_ld_eh_gc_sections=yes
4277           fi
4278         fi
4279       fi
4280     fi
4281   fi
4282   rm -f conftest.s conftest.o conftest
4283 fi
4284 case "$target" in
4285   hppa*-*-linux*)
4286     # ??? This apparently exposes a binutils bug with PC-relative relocations.
4287     gcc_cv_ld_eh_gc_sections=no
4288     ;;
4289 esac
4290 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
4291         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
4292   [Define if your linker supports garbage collection of
4293    sections in presence of EH frames.])
4294 fi
4295 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
4296
4297 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
4298 gcc_cv_ld_eh_gc_sections_bug=no
4299 if test $in_tree_ld = yes ; then
4300   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
4301      && test $in_tree_ld_is_elf = yes; then
4302     gcc_cv_ld_eh_gc_sections_bug=yes
4303   fi
4304 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
4305   gcc_cv_ld_eh_gc_sections_bug=yes
4306   cat > conftest.s <<EOF
4307         .section        .text
4308 .globl _start
4309         .type _start, @function
4310 _start:
4311         .long foo
4312         .size _start, .-_start
4313         .section        .text.startup.foo,"ax",@progbits
4314         .type foo, @function
4315 foo:
4316         .long 0
4317         .size foo, .-foo
4318         .section        .gcc_except_table.foo,"a",@progbits
4319 .L0:
4320         .long 0
4321         .section        .eh_frame,"a",@progbits
4322         .long .L0
4323 EOF
4324   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4325     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4326          | grep "gc-sections option ignored" > /dev/null; then
4327       :
4328     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4329          | grep gcc_except_table > /dev/null; then
4330       gcc_cv_ld_eh_gc_sections_bug=no
4331     fi
4332   fi
4333   rm -f conftest.s conftest.o conftest
4334 fi
4335 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
4336         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
4337   [Define if your linker has buggy garbage collection of
4338    sections support when .text.startup.foo like sections are used.])
4339 fi
4340 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
4341
4342 # --------
4343 # UNSORTED
4344 # --------
4345
4346 AC_CACHE_CHECK(linker --as-needed support,
4347 gcc_cv_ld_as_needed,
4348 [gcc_cv_ld_as_needed=no
4349 if test $in_tree_ld = yes ; then
4350   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4351      && test $in_tree_ld_is_elf = yes; then
4352     gcc_cv_ld_as_needed=yes
4353   fi
4354 elif test x$gcc_cv_ld != x; then
4355         # Check if linker supports --as-needed and --no-as-needed options
4356         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
4357                 gcc_cv_ld_as_needed=yes
4358         fi
4359 fi
4360 ])
4361 if test x"$gcc_cv_ld_as_needed" = xyes; then
4362         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
4363 [Define if your linker supports --as-needed and --no-as-needed options.])
4364 fi
4365
4366 case "$target:$tm_file" in
4367   powerpc64-*-freebsd* | powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
4368   case "$target" in
4369      *-*-linux*)
4370      emul_name="-melf64ppc"
4371       ;;
4372      *-*-freebsd*)
4373      emul_name="-melf64ppc_fbsd"
4374       ;;
4375   esac
4376     AC_CACHE_CHECK(linker support for omitting dot symbols,
4377     gcc_cv_ld_no_dot_syms,
4378     [gcc_cv_ld_no_dot_syms=no
4379     if test $in_tree_ld = yes ; then
4380       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
4381         gcc_cv_ld_no_dot_syms=yes
4382       fi
4383     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4384       cat > conftest1.s <<EOF
4385         .text
4386         bl .foo
4387 EOF
4388       cat > conftest2.s <<EOF
4389         .section ".opd","aw"
4390         .align 3
4391         .globl foo
4392         .type foo,@function
4393 foo:
4394         .quad .LEfoo,.TOC.@tocbase,0
4395         .text
4396 .LEfoo:
4397         blr
4398         .size foo,.-.LEfoo
4399 EOF
4400       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
4401          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
4402          && $gcc_cv_ld $emul_name -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
4403         gcc_cv_ld_no_dot_syms=yes
4404       fi
4405       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
4406     fi
4407     ])
4408     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
4409       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
4410     [Define if your PowerPC64 linker only needs function descriptor syms.])
4411     fi
4412
4413     AC_CACHE_CHECK(linker large toc support,
4414     gcc_cv_ld_large_toc,
4415     [gcc_cv_ld_large_toc=no
4416     if test $in_tree_ld = yes ; then
4417       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
4418         gcc_cv_ld_large_toc=yes
4419       fi
4420     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4421       cat > conftest.s <<EOF
4422         .section ".tbss","awT",@nobits
4423         .align 3
4424 ie0:    .space 8
4425         .global _start
4426         .text
4427 _start:
4428         addis 9,13,ie0@got@tprel@ha
4429         ld 9,ie0@got@tprel@l(9)
4430 EOF
4431       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
4432          && $gcc_cv_ld $emul_name --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
4433         gcc_cv_ld_large_toc=yes
4434       fi
4435       rm -f conftest conftest.o conftest.s
4436     fi
4437     ])
4438     if test x"$gcc_cv_ld_large_toc" = xyes; then
4439       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
4440     [Define if your PowerPC64 linker supports a large TOC.])
4441     fi
4442     ;;
4443 esac
4444
4445 AC_CACHE_CHECK(linker --build-id support,
4446   gcc_cv_ld_buildid,
4447   [gcc_cv_ld_buildid=no
4448   if test $in_tree_ld = yes ; then
4449     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4450        "$gcc_cv_gld_minor_version" -ge 18 -o \
4451        "$gcc_cv_gld_major_version" -gt 2 \
4452        && test $in_tree_ld_is_elf = yes; then
4453       gcc_cv_ld_buildid=yes
4454     fi
4455   elif test x$gcc_cv_ld != x; then
4456     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
4457       gcc_cv_ld_buildid=yes
4458     fi
4459   fi])
4460 if test x"$gcc_cv_ld_buildid" = xyes; then
4461   AC_DEFINE(HAVE_LD_BUILDID, 1,
4462   [Define if your linker supports --build-id.])
4463 fi
4464
4465 AC_ARG_ENABLE(linker-build-id,
4466 [AS_HELP_STRING([--enable-linker-build-id],
4467                 [compiler will always pass --build-id to linker])],
4468 [],
4469 enable_linker_build_id=no)
4470
4471 if test x"$enable_linker_build_id" = xyes; then
4472   if test x"$gcc_cv_ld_buildid" = xyes; then
4473     AC_DEFINE(ENABLE_LD_BUILDID, 1,
4474     [Define if gcc should always pass --build-id to linker.])
4475   else
4476     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
4477   fi
4478 fi
4479
4480 # In binutils 2.21, GNU ld gained support for new emulations fully
4481 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
4482 AC_CACHE_CHECK(linker *_sol2 emulation support,
4483   gcc_cv_ld_sol2_emulation,
4484   [gcc_cv_ld_sol2_emulation=no
4485   if test $in_tree_ld = yes ; then
4486     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4487        "$gcc_cv_gld_minor_version" -ge 21 -o \
4488        "$gcc_cv_gld_major_version" -gt 2 \
4489        && test $in_tree_ld_is_elf = yes; then
4490       gcc_cv_ld_sol2_emulation=yes
4491     fi
4492   elif test x$gcc_cv_ld != x; then
4493     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
4494        grep _sol2 > /dev/null; then
4495       gcc_cv_ld_sol2_emulation=yes
4496     fi
4497   fi])
4498 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
4499   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
4500   [Define if your linker supports the *_sol2 emulations.])
4501 fi
4502
4503 AC_CACHE_CHECK(linker --sysroot support,
4504   gcc_cv_ld_sysroot,
4505   [gcc_cv_ld_sysroot=no
4506   if test $in_tree_ld = yes ; then
4507       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
4508         gcc_cv_ld_sysroot=yes
4509       fi
4510   elif test x$gcc_cv_ld != x; then
4511     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
4512       gcc_cv_ld_sysroot=yes
4513     fi
4514   fi])
4515 if test x"$gcc_cv_ld_sysroot" = xyes; then
4516   AC_DEFINE(HAVE_LD_SYSROOT, 1,
4517   [Define if your linker supports --sysroot.])
4518 fi
4519
4520 if test x$with_sysroot = x && test x$host = x$target \
4521    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4522    && test "$prefix" != "NONE"; then
4523   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4524 [Define to PREFIX/include if cpp should also search that directory.])
4525 fi
4526
4527 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4528   if test "x$with_headers" != x; then
4529     target_header_dir=$with_headers
4530   elif test "x$with_sysroot" = x; then
4531     target_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4532   elif test "x$with_build_sysroot" != "x"; then
4533     target_header_dir="${with_build_sysroot}${native_system_header_dir}"
4534   elif test "x$with_sysroot" = xyes; then
4535     target_header_dir="${exec_prefix}/${target_noncanonical}/sys-root${native_system_header_dir}"
4536   else
4537     target_header_dir="${with_sysroot}${native_system_header_dir}"
4538   fi
4539 else
4540   target_header_dir=${native_system_header_dir}
4541 fi
4542
4543 # Test for stack protector support in target C library.
4544 AC_CACHE_CHECK(__stack_chk_fail in target C library,
4545       gcc_cv_libc_provides_ssp,
4546       [gcc_cv_libc_provides_ssp=no
4547     case "$target" in
4548        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
4549       [# glibc 2.4 and later provides __stack_chk_fail and
4550       # either __stack_chk_guard, or TLS access to stack guard canary.
4551       if test -f $target_header_dir/features.h \
4552          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
4553             $target_header_dir/features.h > /dev/null; then
4554         if $EGREP '^[   ]*#[    ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
4555            $target_header_dir/features.h > /dev/null; then
4556           gcc_cv_libc_provides_ssp=yes
4557         elif $EGREP '^[         ]*#[    ]*define[       ]+__GLIBC__[    ]+2' \
4558              $target_header_dir/features.h > /dev/null \
4559              && $EGREP '^[      ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
4560              $target_header_dir/features.h > /dev/null; then
4561           gcc_cv_libc_provides_ssp=yes
4562         elif $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
4563              $target_header_dir/features.h > /dev/null && \
4564              test -f $target_header_dir/bits/uClibc_config.h && \
4565              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
4566              $target_header_dir/bits/uClibc_config.h > /dev/null; then
4567           gcc_cv_libc_provides_ssp=yes
4568         fi
4569       # all versions of Bionic support stack protector
4570       elif test -f $target_header_dir/sys/cdefs.h \
4571         && $EGREP '^[  ]*#[    ]*define[       ]+__BIONIC__[   ]+1' \
4572            $target_header_dir/sys/cdefs.h > /dev/null; then
4573          gcc_cv_libc_provides_ssp=yes
4574       fi]
4575         ;;
4576        *-*-gnu*)
4577          # Avoid complicated tests (see
4578          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
4579          # simply assert that glibc does provide this, which is true for all
4580          # realistically usable GNU/Hurd configurations.
4581          gcc_cv_libc_provides_ssp=yes;;
4582        *-*-darwin* | *-*-freebsd*)
4583          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
4584            [echo "no __stack_chk_fail on this target"])
4585         ;;
4586   *) gcc_cv_libc_provides_ssp=no ;;
4587     esac])
4588
4589 if test x$gcc_cv_libc_provides_ssp = xyes; then
4590   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
4591             [Define if your target C library provides stack protector support])
4592 fi
4593
4594 # Test for <sys/sdt.h> on the target.
4595 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
4596 AC_MSG_CHECKING(sys/sdt.h in the target C library)
4597 have_sys_sdt_h=no
4598 if test -f $target_header_dir/sys/sdt.h; then
4599   have_sys_sdt_h=yes
4600   AC_DEFINE(HAVE_SYS_SDT_H, 1,
4601             [Define if your target C library provides sys/sdt.h])
4602 fi
4603 AC_MSG_RESULT($have_sys_sdt_h)
4604
4605 # Check if TFmode long double should be used by default or not.
4606 # Some glibc targets used DFmode long double, but with glibc 2.4
4607 # and later they can use TFmode.
4608 case "$target" in
4609   powerpc*-*-linux* | \
4610   sparc*-*-linux* | \
4611   s390*-*-linux* | \
4612   alpha*-*-linux*)
4613     AC_ARG_WITH(long-double-128,
4614       [AS_HELP_STRING([--with-long-double-128],
4615                       [use 128-bit long double by default])],
4616       gcc_cv_target_ldbl128="$with_long_double_128",
4617       [[gcc_cv_target_ldbl128=no
4618       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
4619         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
4620       && gcc_cv_target_ldbl128=yes
4621       ]])
4622     ;;
4623 esac
4624 if test x$gcc_cv_target_ldbl128 = xyes; then
4625   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
4626             [Define if TFmode long double should be the default])
4627 fi
4628
4629 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
4630 gcc_cv_target_dl_iterate_phdr=unknown
4631 case "$target" in
4632   # Restrict to Solaris 11+.  While most of the Solaris 11 linker changes
4633   # were backported to Solaris 10 Update 10, dl_iterate_phdr only lives in
4634   # libdl there, both complicating its use and breaking compatibility
4635   # between Solaris 10 updates.
4636   *-*-solaris2.1[[1-9]]*)
4637     # <link.h> needs both a dl_iterate_phdr declaration and support for
4638     # compilation with largefile support.
4639     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
4640       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
4641       gcc_cv_target_dl_iterate_phdr=yes
4642     else
4643       gcc_cv_target_dl_iterate_phdr=no
4644     fi
4645     ;;
4646 esac
4647 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
4648 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
4649    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
4650 [Define if your target C library provides the `dl_iterate_phdr' function.])
4651 fi
4652 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
4653
4654 # Find out what GC implementation we want, or may, use.
4655 AC_ARG_WITH(gc,
4656 [AS_HELP_STRING([--with-gc={page,zone}],
4657                 [choose the garbage collection mechanism to use
4658                  with the compiler])],
4659 [case "$withval" in
4660   page)
4661     GGC=ggc-$withval
4662     ;;
4663   zone)
4664     GGC=ggc-$withval
4665     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
4666     ;;
4667   *)
4668     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
4669     ;;
4670 esac],
4671 [GGC=ggc-page])
4672 AC_SUBST(GGC)
4673 echo "Using $GGC for garbage collection."
4674
4675 # Libraries to use on the host.  This will normally be set by the top
4676 # level Makefile.  Here we simply capture the value for our Makefile.
4677 if test -z "${HOST_LIBS+set}"; then
4678   HOST_LIBS=
4679 fi
4680 AC_SUBST(HOST_LIBS)
4681
4682 # Use the system's zlib library.
4683 zlibdir=-L../zlib
4684 zlibinc="-I\$(srcdir)/../zlib"
4685 AC_ARG_WITH(system-zlib,
4686 [AS_HELP_STRING([--with-system-zlib], [use installed libz])],
4687 zlibdir=
4688 zlibinc=
4689 )
4690 AC_SUBST(zlibdir)
4691 AC_SUBST(zlibinc)
4692
4693 dnl Very limited version of automake's enable-maintainer-mode
4694
4695 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
4696   dnl maintainer-mode is disabled by default
4697   AC_ARG_ENABLE(maintainer-mode,
4698 [AS_HELP_STRING([--enable-maintainer-mode],
4699                 [enable make rules and dependencies not useful
4700                  (and sometimes confusing) to the casual installer])],
4701       maintainer_mode=$enableval,
4702       maintainer_mode=no)
4703
4704 AC_MSG_RESULT($maintainer_mode)
4705
4706 if test "$maintainer_mode" = "yes"; then
4707   MAINT=''
4708 else
4709   MAINT='#'
4710 fi
4711 AC_SUBST(MAINT)dnl
4712
4713 # --------------
4714 # Language hooks
4715 # --------------
4716
4717 # Make empty files to contain the specs and options for each language.
4718 # Then add #include lines to for a compiler that has specs and/or options.
4719
4720 subdirs=
4721 lang_opt_files=
4722 lang_specs_files=
4723 lang_tree_files=
4724 # These (without "all_") are set in each config-lang.in.
4725 # `language' must be a single word so is spelled singularly.
4726 all_languages=
4727 all_compilers=
4728 all_outputs='Makefile'
4729 # List of language makefile fragments.
4730 all_lang_makefrags=
4731 # Additional files for gengtype
4732 all_gtfiles="$target_gtfiles"
4733
4734 # These are the languages that are set in --enable-languages,
4735 # and are available in the GCC tree.
4736 all_selected_languages=
4737
4738 # Add the language fragments.
4739 # Languages are added via two mechanisms.  Some information must be
4740 # recorded in makefile variables, these are defined in config-lang.in.
4741 # We accumulate them and plug them into the main Makefile.
4742 # The other mechanism is a set of hooks for each of the main targets
4743 # like `clean', `install', etc.
4744
4745 language_hooks="Make-hooks"
4746
4747 for lang in ${srcdir}/*/config-lang.in
4748 do
4749 changequote(,)dnl
4750         test "$lang" = "${srcdir}/*/config-lang.in" && continue
4751
4752         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
4753         if test "x$lang_alias" = x
4754         then
4755               echo "$lang doesn't set \$language." 1>&2
4756               exit 1
4757         fi
4758         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
4759         subdirs="$subdirs $subdir"
4760
4761         # $gcc_subdir is where the gcc integration files are to be found
4762         # for a language, both for internal compiler purposes (compiler
4763         # sources implementing front-end to GCC tree converters), and for
4764         # build infrastructure purposes (Make-lang.in, etc.)
4765         #
4766         # This will be <subdir> (relative to $srcdir) if a line like
4767         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
4768         # is found in <langdir>/config-lang.in, and will remain <langdir>
4769         # otherwise.
4770         #
4771         # Except for the language alias (fetched above), the regular
4772         # "config-lang.in" contents are always retrieved from $gcc_subdir,
4773         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
4774         # only this and the language alias.
4775
4776         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
4777         if [ "$gcc_subdir" = "" ]; then
4778            gcc_subdir="$subdir"
4779         fi
4780
4781         case ",$enable_languages," in
4782         *,$lang_alias,*)
4783             all_selected_languages="$all_selected_languages $lang_alias"
4784             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
4785                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
4786             fi
4787             ;;
4788         esac
4789 changequote([,])dnl
4790
4791         language=
4792         boot_language=
4793         compilers=
4794         outputs=
4795         gtfiles=
4796         subdir_requires=
4797         . ${srcdir}/$gcc_subdir/config-lang.in
4798         if test "x$language" = x
4799         then
4800                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
4801                 exit 1
4802         fi
4803
4804         ok=:
4805         case ",$enable_languages," in
4806                 *,$lang_alias,*) ;;
4807                 *)
4808                         for i in $subdir_requires; do
4809                                 test -f "${srcdir}/$i/config-lang.in" && continue
4810                                 ok=false
4811                                 break
4812                         done
4813                 ;;
4814         esac
4815         $ok || continue
4816
4817         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
4818         if test -f $srcdir/$gcc_subdir/lang.opt; then
4819             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
4820             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
4821         fi
4822         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
4823             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
4824         fi
4825         all_languages="$all_languages $language"
4826         all_compilers="$all_compilers $compilers"
4827         all_outputs="$all_outputs $outputs"
4828         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
4829         case ",$enable_languages," in
4830                 *,lto,*)
4831                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
4832                     enable_lto=yes
4833                     AC_SUBST(enable_lto)
4834                     ;;
4835                 *) ;;
4836         esac
4837 done
4838
4839 # Pick up gtfiles for c
4840 gtfiles=
4841 . ${srcdir}/c-config-lang.in
4842 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
4843
4844 check_languages=
4845 for language in $all_selected_languages
4846 do
4847         check_languages="$check_languages check-$language"
4848 done
4849
4850 # We link each language in with a set of hooks, reached indirectly via
4851 # lang.${target}.  Only do so for selected languages.
4852
4853 rm -f Make-hooks
4854 touch Make-hooks
4855 target_list="all.cross start.encap rest.encap tags \
4856         install-common install-man install-info install-pdf install-html dvi \
4857         pdf html uninstall info man srcextra srcman srcinfo \
4858         mostlyclean clean distclean maintainer-clean install-plugin"
4859
4860 for t in $target_list
4861 do
4862         x=
4863         for lang in $all_selected_languages
4864         do
4865                 x="$x $lang.$t"
4866         done
4867         echo "lang.$t: $x" >> Make-hooks
4868 done
4869
4870 # --------
4871 # Option include files
4872 # --------
4873
4874 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
4875 option_includes="option-includes.mk"
4876 AC_SUBST_FILE(option_includes)
4877
4878 # --------
4879 # UNSORTED
4880 # --------
4881
4882 # Create .gdbinit.
4883
4884 echo "dir ." > .gdbinit
4885 echo "dir ${srcdir}" >> .gdbinit
4886 if test x$gdb_needs_out_file_path = xyes
4887 then
4888         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
4889 fi
4890 if test "x$subdirs" != x; then
4891         for s in $subdirs
4892         do
4893                 echo "dir ${srcdir}/$s" >> .gdbinit
4894         done
4895 fi
4896 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
4897
4898 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
4899 AC_SUBST(gcc_tooldir)
4900 AC_SUBST(dollar)
4901
4902 # Find a directory in which to install a shared libgcc.
4903
4904 AC_ARG_ENABLE(version-specific-runtime-libs,
4905 [AS_HELP_STRING([--enable-version-specific-runtime-libs],
4906                 [specify that runtime libraries should be
4907                  installed in a compiler-specific directory])])
4908
4909 # Substitute configuration variables
4910 AC_SUBST(subdirs)
4911 AC_SUBST(srcdir)
4912 AC_SUBST(all_compilers)
4913 AC_SUBST(all_gtfiles)
4914 AC_SUBST(all_lang_makefrags)
4915 AC_SUBST(all_languages)
4916 AC_SUBST(all_selected_languages)
4917 AC_SUBST(build_exeext)
4918 AC_SUBST(build_install_headers_dir)
4919 AC_SUBST(build_xm_file_list)
4920 AC_SUBST(build_xm_include_list)
4921 AC_SUBST(build_xm_defines)
4922 AC_SUBST(build_file_translate)
4923 AC_SUBST(check_languages)
4924 AC_SUBST(cpp_install_dir)
4925 AC_SUBST(xmake_file)
4926 AC_SUBST(tmake_file)
4927 AC_SUBST(TM_ENDIAN_CONFIG)
4928 AC_SUBST(TM_MULTILIB_CONFIG)
4929 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
4930 AC_SUBST(extra_gcc_objs)
4931 AC_SUBST(user_headers_inc_next_pre)
4932 AC_SUBST(user_headers_inc_next_post)
4933 AC_SUBST(extra_headers_list)
4934 AC_SUBST(extra_objs)
4935 AC_SUBST(extra_programs)
4936 AC_SUBST(float_h_file)
4937 AC_SUBST(gcc_config_arguments)
4938 AC_SUBST(gcc_gxx_include_dir)
4939 AC_SUBST(gcc_gxx_include_dir_add_sysroot)
4940 AC_SUBST(host_exeext)
4941 AC_SUBST(host_xm_file_list)
4942 AC_SUBST(host_xm_include_list)
4943 AC_SUBST(host_xm_defines)
4944 AC_SUBST(out_host_hook_obj)
4945 AC_SUBST(install)
4946 AC_SUBST(lang_opt_files)
4947 AC_SUBST(lang_specs_files)
4948 AC_SUBST(lang_tree_files)
4949 AC_SUBST(local_prefix)
4950 AC_SUBST(md_file)
4951 AC_SUBST(objc_boehm_gc)
4952 AC_SUBST(out_file)
4953 AC_SUBST(out_object_file)
4954 AC_SUBST(common_out_file)
4955 AC_SUBST(common_out_object_file)
4956 AC_SUBST(tm_file_list)
4957 AC_SUBST(tm_include_list)
4958 AC_SUBST(tm_defines)
4959 AC_SUBST(tm_p_file_list)
4960 AC_SUBST(tm_p_include_list)
4961 AC_SUBST(xm_file_list)
4962 AC_SUBST(xm_include_list)
4963 AC_SUBST(xm_defines)
4964 AC_SUBST(use_gcc_stdint)
4965 AC_SUBST(c_target_objs)
4966 AC_SUBST(cxx_target_objs)
4967 AC_SUBST(fortran_target_objs)
4968 AC_SUBST(target_cpu_default)
4969
4970 AC_SUBST_FILE(language_hooks)
4971
4972 # Echo link setup.
4973 if test x${build} = x${host} ; then
4974   if test x${host} = x${target} ; then
4975     echo "Links are now set up to build a native compiler for ${target}." 1>&2
4976   else
4977     echo "Links are now set up to build a cross-compiler" 1>&2
4978     echo " from ${host} to ${target}." 1>&2
4979   fi
4980 else
4981   if test x${host} = x${target} ; then
4982     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
4983     echo " for ${target}." 1>&2
4984   else
4985     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
4986     echo " from ${host} to ${target}." 1>&2
4987   fi
4988 fi
4989
4990 AC_ARG_VAR(GMPLIBS,[How to link GMP])
4991 AC_ARG_VAR(GMPINC,[How to find GMP include files])
4992
4993 AC_ARG_VAR(PPLLIBS,[How to link PPL])
4994 AC_ARG_VAR(PPLINC,[How to find PPL include files])
4995
4996 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
4997 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
4998 if test "x${CLOOGLIBS}" != "x" ; then
4999    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
5000 fi
5001
5002 # Check for plugin support
5003 AC_ARG_ENABLE(plugin,
5004 [AS_HELP_STRING([--enable-plugin], [enable plugin support])],
5005 enable_plugin=$enableval,
5006 enable_plugin=yes; default_plugin=yes)
5007
5008 pluginlibs=
5009
5010 case "${host}" in
5011   *-*-darwin*)
5012     if test x$build = x$host; then
5013       export_sym_check="nm${exeext} -g"
5014     elif test x$host = x$target; then
5015       export_sym_check="$gcc_cv_nm -g"
5016     else
5017       export_sym_check=
5018     fi
5019   ;;
5020   *)
5021     if test x$build = x$host; then
5022       export_sym_check="objdump${exeext} -T"
5023     elif test x$host = x$target; then
5024       export_sym_check="$gcc_cv_objdump -T"
5025     else
5026       export_sym_check=
5027     fi
5028   ;;
5029 esac
5030
5031 if test x"$enable_plugin" = x"yes"; then
5032
5033   AC_MSG_CHECKING([for exported symbols])
5034   if test "x$export_sym_check" != x; then
5035     echo "int main() {return 0;} int foobar() {return 0;}" > conftest.c
5036     ${CC} ${CFLAGS} ${LDFLAGS} conftest.c -o conftest > /dev/null 2>&1
5037     if $export_sym_check conftest | grep foobar > /dev/null; then
5038       : # No need to use a flag
5039       AC_MSG_RESULT([yes])
5040     else
5041       AC_MSG_RESULT([yes])
5042       AC_MSG_CHECKING([for -rdynamic])
5043       ${CC} ${CFLAGS} ${LDFLAGS} -rdynamic conftest.c -o conftest > /dev/null 2>&1
5044       if $export_sym_check conftest | grep foobar > /dev/null; then
5045         plugin_rdynamic=yes
5046         pluginlibs="-rdynamic"
5047       else
5048         plugin_rdynamic=no
5049         enable_plugin=no
5050       fi
5051       AC_MSG_RESULT([$plugin_rdynamic])
5052     fi
5053   else
5054     AC_MSG_RESULT([unable to check])
5055   fi
5056
5057   # Check -ldl
5058   saved_LIBS="$LIBS"
5059   AC_SEARCH_LIBS([dlopen], [dl])
5060   if test x"$ac_cv_search_dlopen" = x"-ldl"; then
5061     pluginlibs="$pluginlibs -ldl"
5062   fi
5063   LIBS="$saved_LIBS"
5064
5065   # Check that we can build shared objects with -fPIC -shared
5066   saved_LDFLAGS="$LDFLAGS"
5067   saved_CFLAGS="$CFLAGS"
5068   case "${host}" in
5069     *-*-darwin*)
5070       CFLAGS=`echo $CFLAGS | sed s/-mdynamic-no-pic//g`
5071       CFLAGS="$CFLAGS -fPIC"
5072       LDFLAGS="$LDFLAGS -shared -undefined dynamic_lookup"
5073     ;;
5074     *)
5075       CFLAGS="$CFLAGS -fPIC"
5076       LDFLAGS="$LDFLAGS -fPIC -shared"
5077     ;;
5078   esac
5079   AC_MSG_CHECKING([for -fPIC -shared])
5080   AC_TRY_LINK(
5081     [extern int X;],[return X == 0;],
5082     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
5083     [AC_MSG_RESULT([no]); have_pic_shared=no])
5084   if test x"$have_pic_shared" != x"yes" -o x"$ac_cv_search_dlopen" = x"no"; then
5085     pluginlibs=
5086     enable_plugin=no
5087   fi
5088   LDFLAGS="$saved_LDFLAGS"
5089   CFLAGS="$saved_CFLAGS"
5090
5091   # If plugin support had been requested but not available, fail.
5092   if test x"$enable_plugin" = x"no" ; then
5093     if test x"$default_plugin" != x"yes"; then
5094       AC_MSG_ERROR([
5095 Building GCC with plugin support requires a host that supports
5096 -fPIC, -shared, -ldl and -rdynamic.])
5097     fi
5098   fi
5099 fi
5100
5101 AC_SUBST(pluginlibs)
5102 AC_SUBST(enable_plugin)
5103 if test x"$enable_plugin" = x"yes"; then
5104   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
5105 fi
5106
5107
5108 AC_ARG_ENABLE(libquadmath-support,
5109 [AS_HELP_STRING([--disable-libquadmath-support],
5110   [disable libquadmath support for Fortran])],
5111 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
5112 ENABLE_LIBQUADMATH_SUPPORT=yes)
5113 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
5114   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
5115             [Define to 1 to enable libquadmath support])
5116 fi
5117
5118
5119 # Specify what hash style to use by default.
5120 AC_ARG_WITH([linker-hash-style],
5121 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
5122                 [specify the linker hash style])],
5123 [case x"$withval" in
5124    xsysv)
5125      LINKER_HASH_STYLE=sysv
5126      ;;
5127    xgnu)
5128      LINKER_HASH_STYLE=gnu
5129      ;;
5130    xboth)
5131      LINKER_HASH_STYLE=both
5132      ;;
5133    *)
5134      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
5135      ;;
5136  esac],
5137 [LINKER_HASH_STYLE=''])
5138 if test x"${LINKER_HASH_STYLE}" != x; then
5139   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
5140                                          [The linker hash style])
5141 fi
5142
5143 # Configure the subdirectories
5144 # AC_CONFIG_SUBDIRS($subdirs)
5145
5146 # Create the Makefile
5147 # and configure language subdirectories
5148 AC_CONFIG_FILES($all_outputs)
5149
5150 AC_CONFIG_COMMANDS([default],
5151 [
5152 case ${CONFIG_HEADERS} in
5153   *auto-host.h:config.in*)
5154   echo > cstamp-h ;;
5155 esac
5156 # Make sure all the subdirs exist.
5157 for d in $subdirs doc build common c-family
5158 do
5159     test -d $d || mkdir $d
5160 done
5161 ],
5162 [subdirs='$subdirs'])
5163 AC_OUTPUT
5164