gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.64)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 AC_PROG_CXX
 280 ACX_PROG_GNAT([-I"$srcdir"/ada])
 281
 282 # autoconf is lame and doesn't give us any substitution variable for this.
 283 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 284   NO_MINUS_C_MINUS_O=yes
 285 else
 286   OUTPUT_OPTION='-o $@'
 287 fi
 288 AC_SUBST(NO_MINUS_C_MINUS_O)
 289 AC_SUBST(OUTPUT_OPTION)
 290
 291 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 292 # optimizations to be activated explicitly by the toplevel.
 293 case "$CC" in
 294   */prev-gcc/xgcc*) ;;
 295   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 296 esac
 297 AC_SUBST(CFLAGS)
 298
 299 # -------------------------
 300 # Check C compiler features
 301 # -------------------------
 302
 303 AC_USE_SYSTEM_EXTENSIONS
 304 AC_PROG_CPP
 305 AC_C_INLINE
 306
 307 AC_SYS_LARGEFILE
 308
 309 # sizeof(char) is 1 by definition.
 310 AC_CHECK_SIZEOF(void *)
 311 AC_CHECK_SIZEOF(short)
 312 AC_CHECK_SIZEOF(int)
 313 AC_CHECK_SIZEOF(long)
 314 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 315 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 316 GCC_STDINT_TYPES
 317
 318 # ---------------------
 319 # Warnings and checking
 320 # ---------------------
 321
 322 # Check $CC warning features (if it's GCC).
 323 # We want to use -pedantic, but we don't want warnings about
 324 # * 'long long'
 325 # * variadic macros
 326 # * overlong strings
 327 # So, we only use -pedantic if we can disable those warnings.
 328
 329 ACX_PROG_CC_WARNING_OPTS(
 330         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
 331 ACX_PROG_CC_WARNING_OPTS(
 332         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 333         [c_loose_warn])
 334 ACX_PROG_CC_WARNING_OPTS(
 335         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 336 ACX_PROG_CC_WARNING_OPTS(
 337         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 338 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 339         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 340                        [-Wno-overlength-strings])), [strict_warn])
 341 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 342
 343 # The above macros do nothing if the compiler is not GCC.  However, the
 344 # Makefile has more goo to add other flags, so these variables are used
 345 # to enable warnings only for GCC.
 346 warn_cflags=
 347 warn_cxxflags=
 348 if test "x$GCC" = "xyes"; then
 349   warn_cflags='$(GCC_WARN_CFLAGS)'
 350   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 351 fi
 352 AC_SUBST(warn_cflags)
 353 AC_SUBST(warn_cxxflags)
 354
 355 # Enable expensive internal checks
 356 is_release=
 357 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 358   is_release=yes
 359 fi
 360
 361 AC_ARG_ENABLE(checking,
 362 [  --enable-checking[=LIST]
 363                           enable expensive run-time checks.  With LIST,
 364                           enable only specific categories of checks.
 365                           Categories are: yes,no,all,none,release.
 366                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 367                           rtlflag,rtl,runtime,tree,valgrind,types.],
 368 [ac_checking_flags="${enableval}"],[
 369 # Determine the default checks.
 370 if test x$is_release = x ; then
 371   ac_checking_flags=yes
 372 else
 373   ac_checking_flags=release
 374 fi])
 375 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 376 for check in release $ac_checking_flags
 377 do
 378         case $check in
 379         # these set all the flags to specific states
 380         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 381                         ac_fold_checking= ; ac_gc_checking=1 ;
 382                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 383                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 384                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 385                         ac_types_checking=1 ;;
 386         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 387                         ac_fold_checking= ; ac_gc_checking= ;
 388                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 389                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 390                         ac_tree_checking= ; ac_valgrind_checking= ;
 391                         ac_types_checking= ;;
 392         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 393                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 394                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 395                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 396                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 397                         ac_types_checking=1 ;;
 398         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 399                         ac_fold_checking= ; ac_gc_checking= ;
 400                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 401                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 402                         ac_tree_checking= ; ac_valgrind_checking= ;
 403                         ac_types_checking= ;;
 404         # these enable particular checks
 405         assert)         ac_assert_checking=1 ;;
 406         df)             ac_df_checking=1 ;;
 407         fold)           ac_fold_checking=1 ;;
 408         gc)             ac_gc_checking=1 ;;
 409         gcac)           ac_gc_always_collect=1 ;;
 410         gimple)         ac_gimple_checking=1 ;;
 411         misc)           ac_checking=1 ;;
 412         rtl)            ac_rtl_checking=1 ;;
 413         rtlflag)        ac_rtlflag_checking=1 ;;
 414         runtime)        ac_runtime_checking=1 ;;
 415         tree)           ac_tree_checking=1 ;;
 416         types)          ac_types_checking=1 ;;
 417         valgrind)       ac_valgrind_checking=1 ;;
 418         *)      AC_MSG_ERROR(unknown check category $check) ;;
 419         esac
 420 done
 421 IFS="$ac_save_IFS"
 422
 423 nocommon_flag=""
 424 if test x$ac_checking != x ; then
 425   AC_DEFINE(ENABLE_CHECKING, 1,
 426 [Define if you want more run-time sanity checks.  This one gets a grab
 427    bag of miscellaneous but relatively cheap checks.])
 428   nocommon_flag=-fno-common
 429 fi
 430 AC_SUBST(nocommon_flag)
 431 if test x$ac_df_checking != x ; then
 432   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 433 [Define if you want more run-time sanity checks for dataflow.])
 434 fi
 435 if test x$ac_assert_checking != x ; then
 436   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 437 [Define if you want assertions enabled.  This is a cheap check.])
 438 fi
 439 if test x$ac_gimple_checking != x ; then
 440   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 441 [Define if you want operations on GIMPLE (the basic data structure of
 442 the high-level optimizers) to be checked for dynamic type safety at
 443 runtime.  This is moderately expensive.])
 444 fi
 445 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 446 if test x$ac_runtime_checking != x ; then
 447   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 448 [Define if you want runtime assertions enabled.  This is a cheap check.])
 449 fi
 450 if test x$ac_tree_checking != x ; then
 451   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 452 [Define if you want all operations on trees (the basic data
 453    structure of the front ends) to be checked for dynamic type safety
 454    at runtime.  This is moderately expensive.  The tree browser debugging
 455    routines will also be enabled by this option.
 456    ])
 457   TREEBROWSER=tree-browser.o
 458 fi
 459 if test x$ac_types_checking != x ; then
 460   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 461 [Define if you want all gimple types to be verified after gimplifiation.
 462    This is cheap.
 463    ])
 464 fi
 465 AC_SUBST(TREEBROWSER)
 466 if test x$ac_rtl_checking != x ; then
 467   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 468 [Define if you want all operations on RTL (the basic data structure
 469    of the optimizer and back end) to be checked for dynamic type safety
 470    at runtime.  This is quite expensive.])
 471 fi
 472 if test x$ac_rtlflag_checking != x ; then
 473   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 474 [Define if you want RTL flag accesses to be checked against the RTL
 475    codes that are supported for each access macro.  This is relatively
 476    cheap.])
 477 fi
 478 if test x$ac_gc_checking != x ; then
 479   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 480 [Define if you want the garbage collector to do object poisoning and
 481    other memory allocation checks.  This is quite expensive.])
 482 fi
 483 if test x$ac_gc_always_collect != x ; then
 484   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 485 [Define if you want the garbage collector to operate in maximally
 486    paranoid mode, validating the entire heap and collecting garbage at
 487    every opportunity.  This is extremely expensive.])
 488 fi
 489 if test x$ac_fold_checking != x ; then
 490   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 491 [Define if you want fold checked that it never destructs its argument.
 492    This is quite expensive.])
 493 fi
 494 valgrind_path_defines=
 495 valgrind_command=
 496
 497 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 498 dnl # an if statement.  This was the source of very frustrating bugs
 499 dnl # in converting to autoconf 2.5x!
 500 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 501
 502 if test x$ac_valgrind_checking != x ; then
 503   # It is certainly possible that there's valgrind but no valgrind.h.
 504   # GCC relies on making annotations so we must have both.
 505   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 506   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 507     [[#include <valgrind/memcheck.h>
 508 #ifndef VALGRIND_DISCARD
 509 #error VALGRIND_DISCARD not defined
 510 #endif]])],
 511   [gcc_cv_header_valgrind_memcheck_h=yes],
 512   [gcc_cv_header_valgrind_memcheck_h=no])
 513   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 514   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 515   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 516     [[#include <memcheck.h>
 517 #ifndef VALGRIND_DISCARD
 518 #error VALGRIND_DISCARD not defined
 519 #endif]])],
 520   [gcc_cv_header_memcheck_h=yes],
 521   [gcc_cv_header_memcheck_h=no])
 522   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 523   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 524         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 525   if test "x$valgrind_path" = "x" \
 526     || (test $have_valgrind_h = no \
 527         && test $gcc_cv_header_memcheck_h = no \
 528         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 529         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 530   fi
 531   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 532   valgrind_command="$valgrind_path -q"
 533   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 534 [Define if you want to run subprograms and generated programs
 535    through valgrind (a memory checker).  This is extremely expensive.])
 536   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 537     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 538         [Define if valgrind's valgrind/memcheck.h header is installed.])
 539   fi
 540   if test $gcc_cv_header_memcheck_h = yes; then
 541     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 542         [Define if valgrind's memcheck.h header is installed.])
 543   fi
 544 fi
 545 AC_SUBST(valgrind_path_defines)
 546 AC_SUBST(valgrind_command)
 547
 548 # Enable code coverage collection
 549 AC_ARG_ENABLE(coverage,
 550 [  --enable-coverage[=LEVEL]
 551                           enable compiler's code coverage collection.
 552                           Use to measure compiler performance and locate
 553                           unused parts of the compiler. With LEVEL, specify
 554                           optimization. Values are opt, noopt,
 555                           default is noopt],
 556 [case "${enableval}" in
 557   yes|noopt)
 558     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 559     ;;
 560   opt)
 561     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 562     ;;
 563   no)
 564     # a.k.a. --disable-coverage
 565     coverage_flags=""
 566     ;;
 567   *)
 568     AC_MSG_ERROR(unknown coverage setting $enableval)
 569     ;;
 570 esac],
 571 [coverage_flags=""])
 572 AC_SUBST(coverage_flags)
 573
 574 AC_ARG_ENABLE(gather-detailed-mem-stats,
 575 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 576 [enable_gather_detailed_mem_stats=no])
 577 if test x$enable_gather_detailed_mem_stats = xyes ; then
 578   AC_DEFINE(GATHER_STATISTICS, 1,
 579         [Define to enable detailed memory allocation stats gathering.])
 580 fi
 581
 582 # -------------------------------
 583 # Miscenalleous configure options
 584 # -------------------------------
 585
 586 # See if we are building gcc with C++.
 587 AC_ARG_ENABLE(build-with-cxx,
 588 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
 589 ENABLE_BUILD_WITH_CXX=$enableval,
 590 ENABLE_BUILD_WITH_CXX=no)
 591 AC_SUBST(ENABLE_BUILD_WITH_CXX)
 592 if test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
 593   AC_DEFINE(ENABLE_BUILD_WITH_CXX, 1,
 594             [Define if building with C++.])
 595 fi
 596
 597 # With stabs
 598 AC_ARG_WITH(stabs,
 599 [  --with-stabs            arrange to use stabs instead of host debug format],
 600 stabs="$with_stabs",
 601 stabs=no)
 602
 603 # Determine whether or not multilibs are enabled.
 604 AC_ARG_ENABLE(multilib,
 605 [  --enable-multilib       enable library support for multiple ABIs],
 606 [], [enable_multilib=yes])
 607 AC_SUBST(enable_multilib)
 608
 609 # Enable __cxa_atexit for C++.
 610 AC_ARG_ENABLE(__cxa_atexit,
 611 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 612 [], [])
 613
 614 # Enable C extension for decimal float if target supports it.
 615 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 616
 617 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 618 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 619 [Define to 1 to enable decimal float extension to C.])
 620
 621 # Use default_decimal_float for dependency.
 622 enable_decimal_float=$default_decimal_float
 623
 624 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 625 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 626 [Define to 1 to specify that we are using the BID decimal floating
 627 point format instead of DPD])
 628
 629 # Enable C extension for fixed-point arithmetic.
 630 AC_ARG_ENABLE(fixed-point,
 631 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 632 [
 633 ],
 634 [
 635   case $target in
 636     mips*-*-*)
 637       case $host in
 638         mips*-sgi-irix*)
 639           AC_MSG_WARN([fixed-point is not supported on IRIX, ignored])
 640           enable_fixed_point=no
 641           ;;
 642         *)
 643           enable_fixed_point=yes
 644           ;;
 645       esac
 646       ;;
 647     *)
 648       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 649       enable_fixed_point=no
 650       ;;
 651   esac
 652 ])
 653 AC_SUBST(enable_fixed_point)
 654
 655 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 656 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 657 [Define to 1 to enable fixed-point arithmetic extension to C.])
 658
 659 # Enable threads
 660 # Pass with no value to take the default
 661 # Pass with a value to specify a thread package
 662 AC_ARG_ENABLE(threads,
 663 [  --enable-threads        enable thread usage for target GCC
 664   --enable-threads=LIB    use LIB thread package for target GCC],,
 665 [enable_threads=''])
 666
 667 AC_ARG_ENABLE(tls,
 668 [  --enable-tls            enable or disable generation of tls code
 669                           overriding the assembler check for tls support],
 670 [
 671   case $enable_tls in
 672     yes | no) ;;
 673     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 674 Valid choices are 'yes' and 'no'.]) ;;
 675   esac
 676 ], [enable_tls=''])
 677
 678 AC_ARG_ENABLE(objc-gc,
 679 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 680                           the GNU Objective-C runtime],
 681 if test x$enable_objc_gc = xno; then
 682         objc_boehm_gc=''
 683 else
 684         objc_boehm_gc=1
 685 fi,
 686 objc_boehm_gc='')
 687
 688 AC_ARG_WITH(dwarf2,
 689 [  --with-dwarf2           force the default debug format to be DWARF 2],
 690 dwarf2="$with_dwarf2",
 691 dwarf2=no)
 692
 693 AC_ARG_ENABLE(shared,
 694 [  --disable-shared        don't provide a shared libgcc],
 695 [
 696   case $enable_shared in
 697   yes | no) ;;
 698   *)
 699     enable_shared=no
 700     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 701     for pkg in $enableval; do
 702       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 703         enable_shared=yes
 704       fi
 705     done
 706     IFS="$ac_save_ifs"
 707     ;;
 708   esac
 709 ], [enable_shared=yes])
 710 AC_SUBST(enable_shared)
 711
 712 AC_ARG_WITH(build-sysroot,
 713   [  --with-build-sysroot=sysroot
 714                           use sysroot as the system root during the build])
 715
 716 AC_ARG_WITH(sysroot,
 717 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 718 [
 719  case ${with_sysroot} in
 720  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 721  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 722  esac
 723
 724  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 725  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 726
 727  if test "x$prefix" = xNONE; then
 728   test_prefix=/usr/local
 729  else
 730   test_prefix=$prefix
 731  fi
 732  if test "x$exec_prefix" = xNONE; then
 733   test_exec_prefix=$test_prefix
 734  else
 735   test_exec_prefix=$exec_prefix
 736  fi
 737  case ${TARGET_SYSTEM_ROOT} in
 738  "${test_prefix}"|"${test_prefix}/"*|\
 739  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 740  '${prefix}'|'${prefix}/'*|\
 741  '${exec_prefix}'|'${exec_prefix}/'*)
 742    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 743    TARGET_SYSTEM_ROOT_DEFINE="$t"
 744    ;;
 745  esac
 746 ], [
 747  TARGET_SYSTEM_ROOT=
 748  TARGET_SYSTEM_ROOT_DEFINE=
 749  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 750 ])
 751 AC_SUBST(TARGET_SYSTEM_ROOT)
 752 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 753 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 754
 755 AC_ARG_WITH(specs,
 756   [AS_HELP_STRING([--with-specs=SPECS],
 757                   [add SPECS to driver command-line processing])],
 758   [CONFIGURE_SPECS=$withval],
 759   [CONFIGURE_SPECS=]
 760 )
 761 AC_SUBST(CONFIGURE_SPECS)
 762
 763 ACX_PKGVERSION([GCC])
 764 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 765
 766 # Sanity check enable_languages in case someone does not run the toplevel
 767 # configure # script.
 768 AC_ARG_ENABLE(languages,
 769 [  --enable-languages=LIST specify which front-ends to build],
 770 [case ,${enable_languages}, in
 771        ,,|,yes,)
 772                 # go safe -- we cannot be much sure without the toplevel
 773                 # configure's
 774                 # analysis of which target libs are present and usable
 775                 enable_languages=c
 776                 ;;
 777          *,all,*)
 778                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 779                 ;;
 780         *,c,*)
 781                 ;;
 782         *)
 783                 enable_languages=c,${enable_languages}
 784                 ;;
 785 esac],
 786 [enable_languages=c])
 787
 788 AC_ARG_WITH(multilib-list,
 789 [  --with-multilib-list    Select multilibs (SH only)],
 790 :,
 791 with_multilib_list=default)
 792
 793 # -------------------------
 794 # Checks for other programs
 795 # -------------------------
 796
 797 AC_PROG_MAKE_SET
 798
 799 # Find some useful tools
 800 AC_PROG_AWK
 801 # We need awk to create options.c and options.h.
 802 # Bail out if it's missing.
 803 case ${AWK} in
 804   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 805 esac
 806
 807 gcc_AC_PROG_LN_S
 808 ACX_PROG_LN($LN_S)
 809 AC_PROG_RANLIB
 810 case "${host}" in
 811 *-*-darwin*)
 812   # By default, the Darwin ranlib will not treat common symbols as
 813   # definitions when  building the archive table of contents.  Other
 814   # ranlibs do that; pass an option to the Darwin ranlib that makes
 815   # it behave similarly.
 816   ranlib_flags="-c"
 817   ;;
 818 *)
 819   ranlib_flags=""
 820 esac
 821 AC_SUBST(ranlib_flags)
 822
 823 gcc_AC_PROG_INSTALL
 824
 825 # See if cmp has --ignore-initial.
 826 gcc_AC_PROG_CMP_IGNORE_INITIAL
 827
 828 # See if we have the mktemp command.
 829 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 830
 831 # See if makeinfo has been installed and is modern enough
 832 # that we can use it.
 833 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 834   [GNU texinfo.* \([0-9][0-9.]*\)],
 835   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 836 if test $gcc_cv_prog_makeinfo_modern = no; then
 837   AC_MSG_WARN([
 838 *** Makeinfo is missing or too old.
 839 *** Info documentation will not be built.])
 840   BUILD_INFO=
 841 else
 842   BUILD_INFO=info
 843 fi
 844 AC_SUBST(BUILD_INFO)
 845
 846 # Is pod2man recent enough to regenerate manpages?
 847 AC_MSG_CHECKING([for recent Pod::Man])
 848 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 849   AC_MSG_RESULT(yes)
 850   GENERATED_MANPAGES=generated-manpages
 851 else
 852   AC_MSG_RESULT(no)
 853   GENERATED_MANPAGES=
 854 fi
 855 AC_SUBST(GENERATED_MANPAGES)
 856
 857 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 858
 859 # How about lex?
 860 dnl Don't use AC_PROG_LEX; we insist on flex.
 861 dnl LEXLIB is not useful in gcc.
 862 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 863
 864 # Bison?
 865 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 866
 867 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 868 # check for build == host before using them.
 869
 870 # NM
 871 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 872   && test -d ../binutils ; then
 873   NM='${objdir}/../binutils/nm-new'
 874 else
 875   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 876 fi
 877
 878 # AR
 879 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 880   && test -d ../binutils ; then
 881   AR='${objdir}/../binutils/ar'
 882 else
 883   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 884 fi
 885
 886
 887 # --------------------
 888 # Checks for C headers
 889 # --------------------
 890
 891 # Need to reject headers which give warnings, so that the -Werror bootstrap
 892 # works later. *sigh*  This needs to come before all header checks.
 893 AC_PROG_CPP_WERROR
 894
 895 AC_HEADER_STDC
 896 AC_HEADER_TIME
 897 ACX_HEADER_STRING
 898 AC_HEADER_SYS_WAIT
 899 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 900                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 901                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 902                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 903
 904 # Check for thread headers.
 905 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 906 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 907
 908 # These tests can't be done till we know if we have limits.h.
 909 gcc_AC_C_CHAR_BIT
 910 AC_C_BIGENDIAN
 911
 912 # ----------------------
 913 # Checks for C++ headers
 914 # ----------------------
 915
 916 AC_LANG_PUSH(C++)
 917
 918 AC_CHECK_HEADERS(unordered_map)
 919 AC_CHECK_HEADERS(tr1/unordered_map)
 920 AC_CHECK_HEADERS(ext/hash_map)
 921
 922 AC_LANG_POP(C++)
 923
 924 # --------
 925 # UNSORTED
 926 # --------
 927
 928
 929 # These libraries may be used by collect2.
 930 # We may need a special search path to get them linked.
 931 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 932 [save_LIBS="$LIBS"
 933 for libs in '' -lld -lmld \
 934                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 935                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 936 do
 937         LIBS="$libs"
 938         AC_TRY_LINK_FUNC(ldopen,
 939                 [gcc_cv_collect2_libs="$libs"; break])
 940 done
 941 LIBS="$save_LIBS"
 942 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 943 case $gcc_cv_collect2_libs in
 944         "none required")        ;;
 945         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 946 esac
 947 AC_SUBST(COLLECT2_LIBS)
 948
 949 # When building Ada code on Alpha, we need exc_resume which is usually in
 950 # -lexc.  So test for it.
 951 save_LIBS="$LIBS"
 952 LIBS=
 953 AC_SEARCH_LIBS(exc_resume, exc)
 954 GNAT_LIBEXC="$LIBS"
 955 LIBS="$save_LIBS"
 956 AC_SUBST(GNAT_LIBEXC)
 957
 958 # Some systems put ldexp and frexp in libm instead of libc; assume
 959 # they're both in the same place.  jcf-dump needs them.
 960 save_LIBS="$LIBS"
 961 LIBS=
 962 AC_SEARCH_LIBS(ldexp, m)
 963 LDEXP_LIB="$LIBS"
 964 LIBS="$save_LIBS"
 965 AC_SUBST(LDEXP_LIB)
 966
 967 # Use <inttypes.h> only if it exists,
 968 # doesn't clash with <sys/types.h>, and declares intmax_t.
 969 AC_MSG_CHECKING(for inttypes.h)
 970 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 971 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 972 [[#include <sys/types.h>
 973 #include <inttypes.h>]],
 974   [[intmax_t i = -1;]])],
 975   [gcc_cv_header_inttypes_h=yes],
 976   [gcc_cv_header_inttypes_h=no])])
 977 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 978 if test $gcc_cv_header_inttypes_h = yes; then
 979   AC_DEFINE(HAVE_INTTYPES_H, 1,
 980         [Define if you have a working <inttypes.h> header file.])
 981 fi
 982
 983 dnl Disabled until we have a complete test for buggy enum bitfields.
 984 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 985
 986 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 987   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 988   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 989   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 990   putchar_unlocked putc_unlocked)
 991 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 992         sysconf strsignal getrusage nl_langinfo \
 993         gettimeofday mbstowcs wcswidth mmap setlocale \
 994         gcc_UNLOCKED_FUNCS)
 995
 996 if test x$ac_cv_func_mbstowcs = xyes; then
 997   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 998 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 999 int main()
1000 {
1001   mbstowcs(0, "", 0);
1002   return 0;
1003 }]])],
1004     [gcc_cv_func_mbstowcs_works=yes],
1005     [gcc_cv_func_mbstowcs_works=no],
1006     [gcc_cv_func_mbstowcs_works=yes])])
1007   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1008     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1009   [Define this macro if mbstowcs does not crash when its
1010    first argument is NULL.])
1011   fi
1012 fi
1013
1014 AC_CHECK_TYPE(ssize_t, int)
1015 AC_CHECK_TYPE(caddr_t, char *)
1016
1017 gcc_AC_FUNC_MMAP_BLACKLIST
1018
1019 case "${host}" in
1020 *-*-*vms*)
1021   # Under VMS, vfork works very differently than on Unix. The standard test
1022   # won't work, and it isn't easily adaptable. It makes more sense to
1023   # just force it.
1024   ac_cv_func_vfork_works=yes
1025   ;;
1026 esac
1027 AC_FUNC_FORK
1028
1029 AM_ICONV
1030 # Until we have in-tree GNU iconv:
1031 LIBICONV_DEP=
1032 AC_SUBST(LIBICONV_DEP)
1033
1034 AM_LC_MESSAGES
1035
1036 AM_LANGINFO_CODESET
1037
1038 # We will need to find libiberty.h and ansidecl.h
1039 saved_CFLAGS="$CFLAGS"
1040 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1041 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1042         strsignal strstr strverscmp \
1043         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1044         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1045 #include "ansidecl.h"
1046 #include "system.h"])
1047
1048 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1049 #include "ansidecl.h"
1050 #include "system.h"
1051 #ifdef HAVE_SYS_RESOURCE_H
1052 #include <sys/resource.h>
1053 #endif
1054 ])
1055
1056 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1057 #include "ansidecl.h"
1058 #include "system.h"
1059 #ifdef HAVE_SYS_RESOURCE_H
1060 #include <sys/resource.h>
1061 #endif
1062 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1063 [Define to `long' if <sys/resource.h> doesn't define.])])
1064
1065 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1066 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1067 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1068 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1069 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1070 #include "ansidecl.h"
1071 #include "system.h"
1072 #ifdef HAVE_LDFCN_H
1073 #undef FREAD
1074 #undef FWRITE
1075 #include <ldfcn.h>
1076 #endif
1077 ])
1078
1079 gcc_AC_CHECK_DECLS(times, , ,[
1080 #include "ansidecl.h"
1081 #include "system.h"
1082 #ifdef HAVE_SYS_TIMES_H
1083 #include <sys/times.h>
1084 #endif
1085 ])
1086
1087 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #include <signal.h>
1091 ])
1092
1093 # More time-related stuff.
1094 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1095 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1096 #include "ansidecl.h"
1097 #include "system.h"
1098 #ifdef HAVE_SYS_TIMES_H
1099 #include <sys/times.h>
1100 #endif
1101 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1102 if test $ac_cv_struct_tms = yes; then
1103   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1104   [Define if <sys/times.h> defines struct tms.])
1105 fi
1106
1107 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1108 # revisit after autoconf 2.50.
1109 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1110 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1111 #include "ansidecl.h"
1112 #include "system.h"
1113 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1114 if test $gcc_cv_type_clock_t = yes; then
1115   AC_DEFINE(HAVE_CLOCK_T, 1,
1116   [Define if <time.h> defines clock_t.])
1117 fi
1118
1119 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1120 CFLAGS="$saved_CFLAGS"
1121
1122 gcc_AC_INITFINI_ARRAY
1123
1124 # mkdir takes a single argument on some systems.
1125 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1126
1127 # File extensions
1128 manext='.1'
1129 objext='.o'
1130 AC_SUBST(manext)
1131 AC_SUBST(objext)
1132
1133 # With Setjmp/Longjmp based exception handling.
1134 AC_ARG_ENABLE(sjlj-exceptions,
1135 [  --enable-sjlj-exceptions
1136                           arrange to use setjmp/longjmp exception handling],
1137 [case $target in
1138   *-*-hpux10*)
1139     if test $enableval != yes; then
1140       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1141       enableval=yes
1142     fi
1143     ;;
1144 esac
1145 force_sjlj_exceptions=yes],
1146 [case $target in
1147   *-*-hpux10*)
1148     force_sjlj_exceptions=yes
1149     enableval=yes
1150     ;;
1151   *)
1152     force_sjlj_exceptions=no
1153     ;;
1154 esac])
1155 if test $force_sjlj_exceptions = yes; then
1156   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1157   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1158     [Define 0/1 to force the choice for exception handling model.])
1159 fi
1160
1161 # For platforms with the unwind ABI which includes an unwind library,
1162 # libunwind, we can choose to use the system libunwind.
1163 # config.gcc also contains tests of with_system_libunwind.
1164 GCC_CHECK_UNWIND_GETIPINFO
1165
1166 # --------------------------------------------------------
1167 # Build, host, and target specific configuration fragments
1168 # --------------------------------------------------------
1169
1170 # Collect build-machine-specific information.
1171 . ${srcdir}/config.build
1172
1173 # Collect host-machine-specific information.
1174 . ${srcdir}/config.host
1175
1176 target_gtfiles=
1177
1178 # Collect target-machine-specific information.
1179 . ${srcdir}/config.gcc
1180
1181 extra_objs="${host_extra_objs} ${extra_objs}"
1182 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1183
1184 # Default the target-machine variables that were not explicitly set.
1185 if test x"$tm_file" = x
1186 then tm_file=$cpu_type/$cpu_type.h; fi
1187
1188 if test x"$extra_headers" = x
1189 then extra_headers=; fi
1190
1191 if test x$md_file = x
1192 then md_file=$cpu_type/$cpu_type.md; fi
1193
1194 if test x$out_file = x
1195 then out_file=$cpu_type/$cpu_type.c; fi
1196
1197 if test x"$tmake_file" = x
1198 then tmake_file=$cpu_type/t-$cpu_type
1199 fi
1200
1201 if test x"$dwarf2" = xyes
1202 then tm_file="$tm_file tm-dwarf2.h"
1203 fi
1204
1205 # Say what files are being used for the output code and MD file.
1206 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1207 echo "Using \`$srcdir/config/$md_file' as machine description file."
1208
1209 # If any of the xm_file variables contain nonexistent files, warn
1210 # about them and drop them.
1211
1212 bx=
1213 for x in $build_xm_file; do
1214   if    test -f $srcdir/config/$x
1215   then      bx="$bx $x"
1216   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1217   fi
1218 done
1219 build_xm_file="$bx"
1220
1221 hx=
1222 for x in $host_xm_file; do
1223   if    test -f $srcdir/config/$x
1224   then      hx="$hx $x"
1225   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1226   fi
1227 done
1228 host_xm_file="$hx"
1229
1230 tx=
1231 for x in $xm_file; do
1232   if    test -f $srcdir/config/$x
1233   then      tx="$tx $x"
1234   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1235   fi
1236 done
1237 xm_file="$tx"
1238
1239 count=a
1240 for f in $tm_file; do
1241         count=${count}x
1242 done
1243 if test $count = ax; then
1244         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1245 else
1246         echo "Using the following target machine macro files:"
1247         for f in $tm_file; do
1248                 echo "  $srcdir/config/$f"
1249         done
1250 fi
1251
1252 if test x$need_64bit_hwint = xyes; then
1253         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1254 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1255 fi
1256
1257 if test x$use_long_long_for_widest_fast_int = xyes; then
1258         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1259 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1260 efficiently supported by the host hardware.])
1261 fi
1262
1263 count=a
1264 for f in $host_xm_file; do
1265         count=${count}x
1266 done
1267 if test $count = a; then
1268         :
1269 elif test $count = ax; then
1270         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1271 else
1272         echo "Using the following host machine macro files:"
1273         for f in $host_xm_file; do
1274                 echo "  $srcdir/config/$f"
1275         done
1276 fi
1277 echo "Using ${out_host_hook_obj} for host machine hooks."
1278
1279 if test "$host_xm_file" != "$build_xm_file"; then
1280         count=a
1281         for f in $build_xm_file; do
1282                 count=${count}x
1283         done
1284         if test $count = a; then
1285                 :
1286         elif test $count = ax; then
1287                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1288         else
1289                 echo "Using the following build machine macro files:"
1290                 for f in $build_xm_file; do
1291                         echo "  $srcdir/config/$f"
1292                 done
1293         fi
1294 fi
1295
1296 case ${host} in
1297   powerpc*-*-darwin*)
1298     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1299       gcc_cv_mcontext_underscores,
1300       AC_COMPILE_IFELSE([
1301 #include <sys/cdefs.h>
1302 #include <sys/signal.h>
1303 #include <ucontext.h>
1304 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1305 ],
1306         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1307       if test $gcc_cv_mcontext_underscores = yes; then
1308         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1309           [mcontext_t fields start with __])
1310       fi
1311     ;;
1312 esac
1313
1314 # ---------
1315 # Threading
1316 # ---------
1317
1318 # Check if a valid thread package
1319 case ${enable_threads} in
1320   "" | no)
1321     # No threads
1322     target_thread_file='single'
1323     ;;
1324   yes)
1325     # default
1326     target_thread_file='single'
1327     ;;
1328   aix | dce | gnat | irix | posix | posix95 | rtems | \
1329   single | solaris | vxworks | win32 | mipssde)
1330     target_thread_file=${enable_threads}
1331     ;;
1332   *)
1333     echo "${enable_threads} is an unknown thread package" 1>&2
1334     exit 1
1335     ;;
1336 esac
1337
1338 if test x${thread_file} = x; then
1339   # No thread file set by target-specific clauses in config.gcc,
1340   # so use file chosen by default logic above
1341   thread_file=${target_thread_file}
1342 fi
1343
1344 # Make gthr-default.h if we have a thread file.
1345 gthread_flags=
1346 if test $thread_file != single; then
1347   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1348   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1349     rm -f gthr-default.h-t
1350   else
1351     mv -f gthr-default.h-t gthr-default.h
1352   fi
1353   gthread_flags=-DHAVE_GTHR_DEFAULT
1354 fi
1355 AC_SUBST(gthread_flags)
1356
1357 # --------
1358 # UNSORTED
1359 # --------
1360
1361 use_cxa_atexit=no
1362 if test x$enable___cxa_atexit = xyes || \
1363    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1364   if test x$host = x$target; then
1365     case $host in
1366       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1367       # keyed to flag_use_cxa_atexit
1368       *-*-mingw32*)
1369         use_cxa_atexit=yes
1370         ;;
1371       *)
1372         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1373           [echo "__cxa_atexit can't be enabled on this target"])
1374         ;;
1375     esac
1376   else
1377     # We can't check for __cxa_atexit when building a cross, so assume
1378     # it is available
1379     use_cxa_atexit=yes
1380   fi
1381   if test x$use_cxa_atexit = xyes; then
1382     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1383       [Define if you want to use __cxa_atexit, rather than atexit, to
1384       register C++ destructors for local statics and global objects.
1385       This is essential for fully standards-compliant handling of
1386       destructors, but requires __cxa_atexit in libc.])
1387   fi
1388 fi
1389
1390 # Look for a file containing extra machine modes.
1391 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1392   extra_modes_file='$(srcdir)'/config/${extra_modes}
1393   AC_SUBST(extra_modes_file)
1394   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1395   [Define to the name of a file containing a list of extra machine modes
1396    for this architecture.])
1397 fi
1398
1399 # Convert extra_options into a form suitable for Makefile use.
1400 extra_opt_files=
1401 all_opt_files=
1402 for f in $extra_options; do
1403   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1404   all_opt_files="$all_opt_files $srcdir/config/$f"
1405 done
1406 AC_SUBST(extra_opt_files)
1407
1408 # auto-host.h is the file containing items generated by autoconf and is
1409 # the first file included by config.h.
1410 # If host=build, it is correct to have bconfig include auto-host.h
1411 # as well.  If host!=build, we are in error and need to do more
1412 # work to find out the build config parameters.
1413 if test x$host = x$build
1414 then
1415         build_auto=auto-host.h
1416 else
1417         # We create a subdir, then run autoconf in the subdir.
1418         # To prevent recursion we set host and build for the new
1419         # invocation of configure to the build for this invocation
1420         # of configure.
1421         tempdir=build.$$
1422         rm -rf $tempdir
1423         mkdir $tempdir
1424         cd $tempdir
1425         case ${srcdir} in
1426         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1427         *) realsrcdir=../${srcdir};;
1428         esac
1429         saved_CFLAGS="${CFLAGS}"
1430         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1431         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1432         ${realsrcdir}/configure \
1433                 --enable-languages=${enable_languages-all} \
1434                 --target=$target_alias --host=$build_alias --build=$build_alias
1435         CFLAGS="${saved_CFLAGS}"
1436
1437         # We just finished tests for the build machine, so rename
1438         # the file auto-build.h in the gcc directory.
1439         mv auto-host.h ../auto-build.h
1440         cd ..
1441         rm -rf $tempdir
1442         build_auto=auto-build.h
1443 fi
1444 AC_SUBST(build_subdir)
1445
1446 tm_file="${tm_file} defaults.h"
1447 tm_p_file="${tm_p_file} tm-preds.h"
1448 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1449 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1450 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1451 # put this back in temporarily.
1452 xm_file="auto-host.h ansidecl.h ${xm_file}"
1453
1454 # --------
1455 # UNSORTED
1456 # --------
1457
1458 changequote(,)dnl
1459 # Compile in configure arguments.
1460 if test -f configargs.h ; then
1461         # Being re-configured.
1462         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1463         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1464 else
1465         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1466 fi
1467
1468 # Double all backslashes and backslash all quotes to turn
1469 # gcc_config_arguments into a C string.
1470 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1471 $gcc_config_arguments
1472 EOF
1473 gcc_config_arguments_str=`cat conftest.out`
1474 rm -f conftest.out
1475
1476 cat > configargs.h <<EOF
1477 /* Generated automatically. */
1478 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1479 static const char thread_model[] = "$thread_file";
1480
1481 static const struct {
1482   const char *name, *value;
1483 } configure_default_options[] = $configure_default_options;
1484 EOF
1485 changequote([,])dnl
1486
1487 changequote(,)dnl
1488 gcc_BASEVER=`cat $srcdir/BASE-VER`
1489 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1490 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1491 if test -f $srcdir/REVISION ; then
1492         gcc_REVISION=`cat $srcdir/REVISION`
1493 else
1494         gcc_REVISION=""
1495 fi
1496 cat > plugin-version.h <<EOF
1497 #include "configargs.h"
1498
1499 static char basever[] = "$gcc_BASEVER";
1500 static char datestamp[] = "$gcc_DATESTAMP";
1501 static char devphase[] = "$gcc_DEVPHASE";
1502 static char revision[] = "$gcc_REVISION";
1503
1504 /* FIXME plugins: We should make the version information more precise.
1505    One way to do is to add a checksum. */
1506
1507 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1508                                                 devphase, revision,
1509                                                 configuration_arguments};
1510 EOF
1511 changequote([,])dnl
1512
1513 # Internationalization
1514 ZW_GNU_GETTEXT_SISTER_DIR
1515
1516 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1517 # -liconv on the link line twice.
1518 case "$LIBINTL" in *$LIBICONV*)
1519         LIBICONV= ;;
1520 esac
1521
1522 AC_ARG_ENABLE(secureplt,
1523 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1524 [], [])
1525
1526 AC_ARG_ENABLE(leading-mingw64-underscores,
1527   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1528                  [Enable leading underscores on 64 bit mingw targets]),
1529   [],[])
1530 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1531   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1532     [Define if we should use leading underscore on 64 bit mingw targets])])
1533
1534 AC_ARG_ENABLE(cld,
1535 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1536 [enable_cld=no])
1537
1538 AC_ARG_ENABLE(frame-pointer,
1539 [  --enable-frame-pointer  enable -fno-omit-frame-pointer by default for 32bit x86], [],
1540 [
1541 case $target_os in
1542 linux* | darwin[[8912]]*)
1543   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1544   # DWARF2.
1545   enable_frame_pointer=no
1546   ;;
1547 *)
1548   enable_frame_pointer=yes
1549   ;;
1550 esac
1551 ])
1552
1553 # Windows32 Registry support for specifying GCC installation paths.
1554 AC_ARG_ENABLE(win32-registry,
1555 [  --disable-win32-registry
1556                           disable lookup of installation paths in the
1557                           Registry on Windows hosts
1558   --enable-win32-registry enable registry lookup (default)
1559   --enable-win32-registry=KEY
1560                           use KEY instead of GCC version as the last portion
1561                           of the registry key],,)
1562
1563 case $host_os in
1564   win32 | pe | cygwin* | mingw32* | uwin*)
1565     if test "x$enable_win32_registry" != xno; then
1566       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1567     fi
1568
1569     if test "x$enable_win32_registry" != xno; then
1570       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1571   [Define to 1 if installation paths should be looked up in the Windows
1572    Registry. Ignored on non-Windows hosts.])
1573
1574       if test "x$enable_win32_registry" != xyes \
1575          && test "x$enable_win32_registry" != x; then
1576         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1577   [Define to be the last component of the Windows registry key under which
1578    to look for installation paths.  The full key used will be
1579    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1580    The default is the GCC version number.])
1581       fi
1582     fi
1583   ;;
1584 esac
1585
1586 # Get an absolute path to the GCC top-level source directory
1587 holddir=`${PWDCMD-pwd}`
1588 cd $srcdir
1589 topdir=`${PWDCMD-pwd}`
1590 cd $holddir
1591
1592 # Conditionalize the makefile for this host machine.
1593 xmake_file=
1594 for f in ${host_xmake_file}
1595 do
1596         if test -f ${srcdir}/config/$f
1597         then
1598                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1599         fi
1600 done
1601
1602 # Conditionalize the makefile for this target machine.
1603 tmake_file_=
1604 for f in ${tmake_file}
1605 do
1606         if test -f ${srcdir}/config/$f
1607         then
1608                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1609         fi
1610 done
1611 tmake_file="${tmake_file_}"
1612
1613 out_object_file=`basename $out_file .c`.o
1614
1615 tm_file_list="options.h"
1616 tm_include_list="options.h insn-constants.h"
1617 for f in $tm_file; do
1618   case $f in
1619     ./* )
1620        f=`echo $f | sed 's/^..//'`
1621        tm_file_list="${tm_file_list} $f"
1622        tm_include_list="${tm_include_list} $f"
1623        ;;
1624     defaults.h )
1625        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1626        tm_include_list="${tm_include_list} $f"
1627        ;;
1628     * )
1629        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1630        tm_include_list="${tm_include_list} config/$f"
1631        ;;
1632   esac
1633 done
1634
1635 tm_p_file_list=
1636 tm_p_include_list=
1637 for f in $tm_p_file; do
1638   case $f in
1639     tm-preds.h )
1640        tm_p_file_list="${tm_p_file_list} $f"
1641        tm_p_include_list="${tm_p_include_list} $f"
1642        ;;
1643     * )
1644        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1645        tm_p_include_list="${tm_p_include_list} config/$f"
1646   esac
1647 done
1648
1649 xm_file_list=
1650 xm_include_list=
1651 for f in $xm_file; do
1652   case $f in
1653     ansidecl.h )
1654        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1655        xm_include_list="${xm_include_list} $f"
1656        ;;
1657     auto-host.h )
1658        xm_file_list="${xm_file_list} $f"
1659        xm_include_list="${xm_include_list} $f"
1660        ;;
1661     * )
1662        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1663        xm_include_list="${xm_include_list} config/$f"
1664        ;;
1665   esac
1666 done
1667
1668 host_xm_file_list=
1669 host_xm_include_list=
1670 for f in $host_xm_file; do
1671   case $f in
1672     ansidecl.h )
1673        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1674        host_xm_include_list="${host_xm_include_list} $f"
1675        ;;
1676     auto-host.h )
1677        host_xm_file_list="${host_xm_file_list} $f"
1678        host_xm_include_list="${host_xm_include_list} $f"
1679        ;;
1680     * )
1681        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1682        host_xm_include_list="${host_xm_include_list} config/$f"
1683        ;;
1684   esac
1685 done
1686
1687 build_xm_file_list=
1688 for f in $build_xm_file; do
1689   case $f in
1690     ansidecl.h )
1691        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1692        build_xm_include_list="${build_xm_include_list} $f"
1693        ;;
1694     auto-build.h | auto-host.h )
1695        build_xm_file_list="${build_xm_file_list} $f"
1696        build_xm_include_list="${build_xm_include_list} $f"
1697        ;;
1698     * )
1699        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1700        build_xm_include_list="${build_xm_include_list} config/$f"
1701        ;;
1702   esac
1703 done
1704
1705 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1706 # cross-compiler which does not use the native headers and libraries.
1707 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1708 CROSS=                                          AC_SUBST(CROSS)
1709 ALL=all.internal                                AC_SUBST(ALL)
1710 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1711
1712 if test "x$with_build_sysroot" != x; then
1713   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1714 else
1715   # This value is used, even on a native system, because
1716   # CROSS_SYSTEM_HEADER_DIR is just
1717   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1718   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1719 fi
1720
1721 if test x$host != x$target
1722 then
1723         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1724         ALL=all.cross
1725         SYSTEM_HEADER_DIR=$build_system_header_dir
1726         case "$host","$target" in
1727         # Darwin crosses can use the host system's libraries and headers,
1728         # because of the fat library support.  Of course, it must be the
1729         # same version of Darwin on both sides.  Allow the user to
1730         # just say --target=foo-darwin without a version number to mean
1731         # "the version on this system".
1732             *-*-darwin*,*-*-darwin*)
1733                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1734                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1735                 if test $hostos = $targetos -o $targetos = darwin ; then
1736                     CROSS=
1737                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1738                     with_headers=yes
1739                 fi
1740                 ;;
1741
1742             i?86-*-*,x86_64-*-* \
1743             | powerpc*-*-*,powerpc64*-*-*)
1744                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1745         esac
1746
1747         case $target in
1748                 *-*-mingw*)
1749                         if test "x$with_headers" = x; then
1750                                 with_headers=yes
1751                         fi
1752                         ;;
1753                 *)
1754                         ;;
1755         esac
1756 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1757         SYSTEM_HEADER_DIR=$build_system_header_dir
1758 fi
1759
1760 # If this is a cross-compiler that does not
1761 # have its own set of headers then define
1762 # inhibit_libc
1763
1764 # If this is using newlib, without having the headers available now,
1765 # then define inhibit_libc in LIBGCC2_CFLAGS.
1766 # This prevents libgcc2 from containing any code which requires libc
1767 # support.
1768 : ${inhibit_libc=false}
1769 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1770        test x$with_newlib = xyes ; } &&
1771      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1772        inhibit_libc=true
1773 fi
1774 AC_SUBST(inhibit_libc)
1775
1776 # When building gcc with a cross-compiler, we need to adjust things so
1777 # that the generator programs are still built with the native compiler.
1778 # Also, we cannot run fixincludes.
1779
1780 # These are the normal (build=host) settings:
1781 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1782 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1783 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1784 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1785
1786 # And these apply if build != host, or we are generating coverage data
1787 if test x$build != x$host || test "x$coverage_flags" != x
1788 then
1789     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1790     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1791 fi
1792
1793 # Expand extra_headers to include complete path.
1794 # This substitutes for lots of t-* files.
1795 extra_headers_list=
1796 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1797 for file in ${extra_headers} ; do
1798   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1799 done
1800
1801 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1802 if test x"$use_gcc_tgmath" = xyes
1803 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1804 fi
1805
1806 # Define collect2 in Makefile.
1807 case $host_can_use_collect2 in
1808   no) collect2= ;;
1809   *) collect2='collect2$(exeext)' ;;
1810 esac
1811 AC_SUBST([collect2])
1812
1813 # Add a definition of USE_COLLECT2 if system wants one.
1814 case $use_collect2 in
1815   no) use_collect2= ;;
1816   "") ;;
1817   *)
1818     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1819     xm_defines="${xm_defines} USE_COLLECT2"
1820     case $host_can_use_collect2 in
1821       no)
1822         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1823         ;;
1824     esac
1825     ;;
1826 esac
1827
1828 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
1829 [Define to the name of the LTO plugin DSO that must be
1830   passed to the linker's -plugin=LIB option.])
1831
1832 # ---------------------------
1833 # Assembler & linker features
1834 # ---------------------------
1835
1836 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1837 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1838 # However when ld-new is first executed from the build tree, libtool will
1839 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1840 # to the build tree.  While doing this we need to use the previous-stage
1841 # linker, or we have an infinite loop.  The presence of a shell script as
1842 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1843 # the gcc/collect-ld script.  So we need to know how libtool works, or
1844 # exec-tool will fail.
1845
1846 m4_defun([_LT_CONFIG_COMMANDS], [])
1847 AC_PROG_LIBTOOL
1848 AC_SUBST(objdir)
1849 AC_SUBST(enable_fast_install)
1850
1851 # Identify the assembler which will work hand-in-glove with the newly
1852 # built GCC, so that we can examine its features.  This is the assembler
1853 # which will be driven by the driver program.
1854 #
1855 # If build != host, and we aren't building gas in-tree, we identify a
1856 # build->target assembler and hope that it will have the same features
1857 # as the host->target assembler we'll be using.
1858 gcc_cv_gas_major_version=
1859 gcc_cv_gas_minor_version=
1860 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1861
1862 m4_pattern_allow([AS_FOR_TARGET])dnl
1863 AS_VAR_SET_IF(gcc_cv_as,, [
1864 if test -x "$DEFAULT_ASSEMBLER"; then
1865         gcc_cv_as="$DEFAULT_ASSEMBLER"
1866 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1867      && test -f ../gas/Makefile \
1868      && test x$build = x$host; then
1869         gcc_cv_as=../gas/as-new$build_exeext
1870 elif test -x as$build_exeext; then
1871         # Build using assembler in the current directory.
1872         gcc_cv_as=./as$build_exeext
1873 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
1874         gcc_cv_as="$AS_FOR_TARGET"
1875 else
1876         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1877 fi])
1878
1879 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1880 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1881 case "$ORIGINAL_AS_FOR_TARGET" in
1882   ./as | ./as$build_exeext) ;;
1883   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1884 esac
1885
1886 AC_MSG_CHECKING(what assembler to use)
1887 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1888   # Single tree build which includes gas.  We want to prefer it
1889   # over whatever linker top-level may have detected, since
1890   # we'll use what we're building after installation anyway.
1891   AC_MSG_RESULT(newly built gas)
1892   in_tree_gas=yes
1893   _gcc_COMPUTE_GAS_VERSION
1894   in_tree_gas_is_elf=no
1895   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1896      || (grep 'obj_format = multi' ../gas/Makefile \
1897          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1898   then
1899     in_tree_gas_is_elf=yes
1900   fi
1901 else
1902   AC_MSG_RESULT($gcc_cv_as)
1903   in_tree_gas=no
1904 fi
1905
1906 # Identify the linker which will work hand-in-glove with the newly
1907 # built GCC, so that we can examine its features.  This is the linker
1908 # which will be driven by the driver program.
1909 #
1910 # If build != host, and we aren't building gas in-tree, we identify a
1911 # build->target linker and hope that it will have the same features
1912 # as the host->target linker we'll be using.
1913 gcc_cv_gld_major_version=
1914 gcc_cv_gld_minor_version=
1915 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1916 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1917
1918 AS_VAR_SET_IF(gcc_cv_ld,, [
1919 if test -x "$DEFAULT_LINKER"; then
1920         gcc_cv_ld="$DEFAULT_LINKER"
1921 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1922      && test -f ../ld/Makefile \
1923      && test x$build = x$host; then
1924         gcc_cv_ld=../ld/ld-new$build_exeext
1925 elif test -x collect-ld$build_exeext; then
1926         # Build using linker in the current directory.
1927         gcc_cv_ld=./collect-ld$build_exeext
1928 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
1929         gcc_cv_ld="$LD_FOR_TARGET"
1930 else
1931         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1932 fi])
1933
1934 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1935 PLUGIN_LD=`basename $gcc_cv_ld`
1936 AC_ARG_WITH(plugin-ld,
1937 [  --with-plugin-ld=[[ARG]]  specify the plugin linker],
1938 [if test x"$withval" != x; then
1939    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1940    PLUGIN_LD="$withval"
1941  fi])
1942 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1943 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1944
1945 # Check to see if we are using gold instead of ld
1946 AC_MSG_CHECKING(whether we are using gold)
1947 ld_is_gold=no
1948 if test x$gcc_cv_ld != x; then
1949   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
1950      | grep "GNU gold" > /dev/null; then
1951     ld_is_gold=yes
1952   fi
1953 fi
1954 AC_MSG_RESULT($ld_is_gold)
1955
1956 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1957 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1958 case "$ORIGINAL_LD_FOR_TARGET" in
1959   ./collect-ld | ./collect-ld$build_exeext) ;;
1960   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1961 esac
1962
1963 AC_MSG_CHECKING(what linker to use)
1964 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1965         # Single tree build which includes ld.  We want to prefer it
1966         # over whatever linker top-level may have detected, since
1967         # we'll use what we're building after installation anyway.
1968         AC_MSG_RESULT(newly built ld)
1969         in_tree_ld=yes
1970         in_tree_ld_is_elf=no
1971         if (grep 'EMUL = .*elf' ../ld/Makefile \
1972             || grep 'EMUL = .*linux' ../ld/Makefile \
1973             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1974           in_tree_ld_is_elf=yes
1975         fi
1976         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1977         do
1978 changequote(,)dnl
1979                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1980                 if test x$gcc_cv_gld_version != x; then
1981                         break
1982                 fi
1983         done
1984         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1985         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1986 changequote([,])dnl
1987 else
1988         AC_MSG_RESULT($gcc_cv_ld)
1989         in_tree_ld=no
1990 fi
1991
1992 # Figure out what nm we will be using.
1993 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1994 AS_VAR_SET_IF(gcc_cv_nm,, [
1995 if test -f $gcc_cv_binutils_srcdir/configure.in \
1996      && test -f ../binutils/Makefile \
1997      && test x$build = x$host; then
1998         gcc_cv_nm=../binutils/nm-new$build_exeext
1999 elif test -x nm$build_exeext; then
2000         gcc_cv_nm=./nm$build_exeext
2001 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2002         gcc_cv_nm="$NM_FOR_TARGET"
2003 else
2004         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2005 fi])
2006
2007 AC_MSG_CHECKING(what nm to use)
2008 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2009         # Single tree build which includes binutils.
2010         AC_MSG_RESULT(newly built nm)
2011         in_tree_nm=yes
2012 else
2013         AC_MSG_RESULT($gcc_cv_nm)
2014         in_tree_nm=no
2015 fi
2016
2017 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2018 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2019 case "$ORIGINAL_NM_FOR_TARGET" in
2020   ./nm | ./nm$build_exeext) ;;
2021   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2022 esac
2023
2024
2025 # Figure out what objdump we will be using.
2026 AS_VAR_SET_IF(gcc_cv_objdump,, [
2027 if test -f $gcc_cv_binutils_srcdir/configure.in \
2028      && test -f ../binutils/Makefile \
2029      && test x$build = x$host; then
2030         # Single tree build which includes binutils.
2031         gcc_cv_objdump=../binutils/objdump$build_exeext
2032 elif test -x objdump$build_exeext; then
2033         gcc_cv_objdump=./objdump$build_exeext
2034 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2035         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2036 else
2037         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2038 fi])
2039
2040 AC_MSG_CHECKING(what objdump to use)
2041 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2042         # Single tree build which includes binutils.
2043         AC_MSG_RESULT(newly built objdump)
2044 elif test x$gcc_cv_objdump = x; then
2045         AC_MSG_RESULT(not found)
2046 else
2047         AC_MSG_RESULT($gcc_cv_objdump)
2048 fi
2049
2050 # Figure out what readelf we will be using.
2051 AS_VAR_SET_IF(gcc_cv_readelf,, [
2052 if test -f $gcc_cv_binutils_srcdir/configure.in \
2053      && test -f ../binutils/Makefile \
2054      && test x$build = x$host; then
2055         # Single tree build which includes binutils.
2056         gcc_cv_readelf=../binutils/readelf$build_exeext
2057 elif test -x readelf$build_exeext; then
2058         gcc_cv_readelf=./readelf$build_exeext
2059 else
2060         AC_PATH_PROG(gcc_cv_readelf, readelf)
2061 fi])
2062
2063 AC_MSG_CHECKING(what readelf to use)
2064 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2065         # Single tree build which includes binutils.
2066         AC_MSG_RESULT(newly built readelf)
2067 elif test x$gcc_cv_readelf = x; then
2068         AC_MSG_RESULT(not found)
2069 else
2070         AC_MSG_RESULT($gcc_cv_readelf)
2071 fi
2072
2073 # Figure out what assembler alignment features are present.
2074 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2075  [2,6,0],,
2076 [.balign 4
2077 .p2align 2],,
2078 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2079   [Define if your assembler supports .balign and .p2align.])])
2080
2081 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2082  [2,8,0],,
2083  [.p2align 4,,7],,
2084 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2085   [Define if your assembler supports specifying the maximum number
2086    of bytes to skip when using the GAS .p2align command.])])
2087
2088 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2089  [2,8,0],,
2090  [.literal16],,
2091 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2092   [Define if your assembler supports .literal16.])])
2093
2094 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2095  [elf,2,9,0],,
2096  [conftest_label1: .word 0
2097 .subsection -1
2098 conftest_label2: .word 0
2099 .previous],
2100  [if test x$gcc_cv_nm != x; then
2101     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2102     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2103     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2104     then :
2105     else gcc_cv_as_subsection_m1=yes
2106     fi
2107     rm -f conftest.nm1 conftest.nm2
2108   fi],
2109  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2110   [Define if your assembler supports .subsection and .subsection -1 starts
2111    emitting at the beginning of your section.])])
2112
2113 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2114  [2,2,0],,
2115  [      .weak foobar],,
2116 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2117
2118 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2119  [2,17,0],,
2120  [      .weakref foobar, barfnot],,
2121 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2122
2123 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2124  [2,15,91],,
2125  [      .SPACE $TEXT$
2126         .NSUBSPA $CODE$,COMDAT],,
2127 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2128
2129 # .hidden needs to be supported in both the assembler and the linker,
2130 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2131 # This is irritatingly difficult to feature test for; we have to check the
2132 # date string after the version number.  If we've got an in-tree
2133 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2134 # to be safe.
2135 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2136 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2137  [elf,2,13,0],,
2138 [       .hidden foobar
2139 foobar:],[
2140 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2141 # STV_HIDDEN, so disable .hidden support if so.
2142 case "${target}" in
2143   i?86-*-solaris2*)
2144     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2145       cat > conftest.s <<EOF
2146 .globl hidden
2147         .hidden hidden
2148 hidden:
2149 .globl default
2150         .set    default,hidden
2151 EOF
2152       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2153         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2154         grep '\.hidden default' > /dev/null; then
2155         gcc_cv_as_hidden=no
2156       else
2157         gcc_cv_as_hidden=yes
2158       fi
2159     else
2160       # Assume bug is present if objdump is missing.
2161       gcc_cv_as_hidden=no
2162     fi
2163     ;;
2164   *)
2165     gcc_cv_as_hidden=yes
2166     ;;
2167 esac])
2168
2169 # gnu_indirect_function type is an extension proposed at
2170 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2171 # selection of function implementation
2172 AC_ARG_ENABLE(gnu-indirect-function,
2173  [AS_HELP_STRING([--enable-gnu-indirect-function],
2174                  [enable the use of the @gnu_indirect_function to glibc systems])],
2175  [case $enable_gnu_indirect_function in
2176     yes | no) ;;
2177     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2178 Valid choices are 'yes' and 'no'.]) ;;
2179   esac],
2180  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2181 if test x$enable_gnu_indirect_function = xyes; then
2182   AC_DEFINE(HAVE_GNU_INDIRECT_FUNCTION, 1,
2183    [Define if your system supports gnu indirect functions.])
2184 fi
2185
2186 changequote(,)dnl
2187 if test $in_tree_ld != yes ; then
2188   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2189   if test x"$ld_is_gold" = xyes; then
2190     gcc_cv_ld_hidden=yes
2191   elif echo "$ld_ver" | grep GNU > /dev/null; then
2192     ld_vers=`echo $ld_ver | sed -n \
2193         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2194     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2195     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2196     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2197     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2198   else
2199     case "${target}" in
2200       *-*-solaris2*)
2201         #
2202         # Solaris 2 ld -V output looks like this for a regular version:
2203         #
2204         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
2205         #
2206         # but test versions add stuff at the end:
2207         #
2208         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
2209         #
2210         ld_ver=`$gcc_cv_ld -V 2>&1`
2211         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2212           ld_vers=`echo $ld_ver | sed -n \
2213             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2214           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2215           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2216         fi
2217         ;;
2218     esac
2219   fi
2220 fi
2221 changequote([,])dnl
2222
2223 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2224 [[if test $in_tree_ld = yes ; then
2225   gcc_cv_ld_hidden=no
2226   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2227      && test $in_tree_ld_is_elf = yes; then
2228      gcc_cv_ld_hidden=yes
2229   fi
2230 else
2231   gcc_cv_ld_hidden=yes
2232   if echo "$ld_ver" | grep GNU > /dev/null; then
2233     if test 0"$ld_date" -lt 20020404; then
2234       if test -n "$ld_date"; then
2235         # If there was date string, but was earlier than 2002-04-04, fail
2236         gcc_cv_ld_hidden=no
2237       elif test -z "$ld_vers"; then
2238         # If there was no date string nor ld version number, something is wrong
2239         gcc_cv_ld_hidden=no
2240       else
2241         test -z "$ld_vers_patch" && ld_vers_patch=0
2242         if test "$ld_vers_major" -lt 2; then
2243           gcc_cv_ld_hidden=no
2244         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2245           gcc_cv_ld_hidden="no"
2246         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2247           gcc_cv_ld_hidden=no
2248         fi
2249       fi
2250     fi
2251   else
2252     case "${target}" in
2253       hppa64*-*-hpux* | ia64*-*-hpux*)
2254         gcc_cv_ld_hidden=yes
2255         ;;
2256       *-*-solaris2.8*)
2257         # .hidden support was backported to Solaris 8, starting with ld
2258         # version 1.276.
2259         if test "$ld_vers_minor" -ge 276; then
2260           gcc_cv_ld_hidden=yes
2261         else
2262           gcc_cv_ld_hidden=no
2263         fi
2264         ;;
2265       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2266         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2267         # .symbolic was only added in Solaris 9 12/02.
2268         gcc_cv_ld_hidden=yes
2269         ;;
2270       *)
2271         gcc_cv_ld_hidden=no
2272         ;;
2273     esac
2274   fi
2275 fi]])
2276 libgcc_visibility=no
2277 AC_SUBST(libgcc_visibility)
2278 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2279 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2280   libgcc_visibility=yes
2281   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2282   [Define if your assembler and linker support .hidden.])
2283 fi
2284
2285 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2286 gcc_cv_ld_ro_rw_mix=unknown
2287 if test $in_tree_ld = yes ; then
2288   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2289      && test $in_tree_ld_is_elf = yes; then
2290     gcc_cv_ld_ro_rw_mix=read-write
2291   fi
2292 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2293   echo '.section myfoosect, "a"' > conftest1.s
2294   echo '.section myfoosect, "aw"' > conftest2.s
2295   echo '.byte 1' >> conftest2.s
2296   echo '.section myfoosect, "a"' > conftest3.s
2297   echo '.byte 0' >> conftest3.s
2298   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2299      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2300      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2301      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2302         conftest2.o conftest3.o > /dev/null 2>&1; then
2303     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2304                          | sed -e '/myfoosect/!d' -e N`
2305     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2306       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2307         gcc_cv_ld_ro_rw_mix=read-only
2308       else
2309         gcc_cv_ld_ro_rw_mix=read-write
2310       fi
2311     fi
2312   fi
2313 changequote(,)dnl
2314   rm -f conftest.* conftest[123].*
2315 changequote([,])dnl
2316 fi
2317 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2318         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2319   [Define if your linker links a mix of read-only
2320    and read-write sections into a read-write section.])
2321 fi
2322 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2323
2324 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2325 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2326   [elf,2,11,0],,
2327 [       .data
2328         .uleb128 L2 - L1
2329 L1:
2330         .uleb128 1280
2331         .sleb128 -1010
2332 L2:],
2333 [[# GAS versions before 2.11 do not support uleb128,
2334   # despite appearing to.
2335   # ??? There exists an elf-specific test that will crash
2336   # the assembler.  Perhaps it's better to figure out whether
2337   # arbitrary sections are supported and try the test.
2338   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2339   if echo "$as_ver" | grep GNU > /dev/null; then
2340     as_vers=`echo $as_ver | sed -n \
2341         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2342     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2343     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2344     if test $as_major -eq 2 && test $as_minor -lt 11
2345     then :
2346     else gcc_cv_as_leb128=yes
2347     fi
2348   fi]],
2349   [AC_DEFINE(HAVE_AS_LEB128, 1,
2350     [Define if your assembler supports .sleb128 and .uleb128.])])
2351
2352 # Check if we have assembler support for unwind directives.
2353 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2354   ,,
2355 [       .text
2356         .cfi_startproc
2357         .cfi_offset 0, 0
2358         .cfi_same_value 1
2359         .cfi_def_cfa 1, 2
2360         .cfi_escape 1, 2, 3, 4, 5
2361         .cfi_endproc],
2362 [case "$target" in
2363   *-*-solaris*)
2364     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2365     # read-only and read-write sections, we need to make sure that the
2366     # assembler used emits read-write .eh_frame sections.
2367     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2368       if test "x$gcc_cv_objdump" != x; then
2369         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2370                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2371           gcc_cv_as_cfi_directive=no
2372         else
2373           case "$target" in
2374             i?86-*-solaris2.1[[0-9]]*)
2375               # On Solaris/x86, make sure that GCC and gas agree on using
2376               # read-only .eh_frame sections for 64-bit.
2377               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2378                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2379                         sed -e /.eh_frame/!d -e N | \
2380                         grep READONLY > /dev/null; then
2381                 gcc_cv_as_cfi_directive=yes
2382               else
2383                 gcc_cv_as_cfi_directive=no
2384               fi
2385               ;;
2386             *)
2387               gcc_cv_as_cfi_directive=yes
2388               ;;
2389           esac
2390         fi
2391       else
2392         # no objdump, err on the side of caution
2393         gcc_cv_as_cfi_directive=no
2394       fi
2395     else
2396       gcc_cv_as_cfi_directive=yes
2397     fi
2398     ;;
2399   *-*-*)
2400     gcc_cv_as_cfi_directive=yes
2401     ;;
2402 esac])
2403 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2404 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2405   ,,
2406 [       .text
2407         .cfi_startproc
2408         .cfi_adjust_cfa_offset 64
2409         .skip 75040, 0
2410         .cfi_adjust_cfa_offset 128
2411         .cfi_endproc],
2412 [[
2413 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2414     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2415    gcc_cv_as_cfi_advance_working=yes
2416 fi
2417 ]])
2418 else
2419   # no objdump, err on the side of caution
2420   gcc_cv_as_cfi_advance_working=no
2421 fi
2422 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2423 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2424   [`if test $gcc_cv_as_cfi_directive = yes \
2425        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2426   [Define 0/1 if your assembler supports CFI directives.])
2427
2428 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2429 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2430   gcc_cv_as_cfi_personality_directive, ,,
2431 [       .text
2432         .cfi_startproc
2433         .cfi_personality 0, symbol
2434         .cfi_endproc])
2435 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2436   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2437     then echo 1; else echo 0; fi`],
2438   [Define 0/1 if your assembler supports .cfi_personality.])
2439
2440 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2441   gcc_cv_as_cfi_sections_directive, ,,
2442 [       .text
2443         .cfi_sections .debug_frame, .eh_frame
2444         .cfi_startproc
2445         .cfi_endproc],
2446 [case $target_os in
2447   win32 | pe | cygwin* | mingw32* | uwin*)
2448     # Need to check that we generated the correct relocation for the
2449     # .debug_frame section.  This was fixed for binutils 2.21.
2450     gcc_cv_as_cfi_sections_directive=no
2451     if test "x$gcc_cv_objdump" != x; then
2452      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2453         grep secrel > /dev/null; then
2454       gcc_cv_as_cfi_sections_directive=yes
2455      fi
2456     fi
2457     ;;
2458   *)
2459     gcc_cv_as_cfi_sections_directive=yes
2460     ;;
2461 esac])
2462 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2463 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2464   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2465     then echo 1; else echo 0; fi`],
2466   [Define 0/1 if your assembler supports .cfi_sections.])
2467
2468 # GAS versions up to and including 2.11.0 may mis-optimize
2469 # .eh_frame data.
2470 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2471   [elf,2,12,0],,
2472 [       .text
2473 .LFB1:
2474         .4byte  0
2475 .L1:
2476         .4byte  0
2477 .LFE1:
2478         .section        .eh_frame,"aw",@progbits
2479 __FRAME_BEGIN__:
2480         .4byte  .LECIE1-.LSCIE1
2481 .LSCIE1:
2482         .4byte  0x0
2483         .byte   0x1
2484         .ascii "z\0"
2485         .byte   0x1
2486         .byte   0x78
2487         .byte   0x1a
2488         .byte   0x0
2489         .byte   0x4
2490         .4byte  1
2491         .p2align 1
2492 .LECIE1:
2493 .LSFDE1:
2494         .4byte  .LEFDE1-.LASFDE1
2495 .LASFDE1:
2496         .4byte  .LASFDE1-__FRAME_BEGIN__
2497         .4byte  .LFB1
2498         .4byte  .LFE1-.LFB1
2499         .byte   0x4
2500         .4byte  .LFE1-.LFB1
2501         .byte   0x4
2502         .4byte  .L1-.LFB1
2503 .LEFDE1:],
2504 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2505 cat > conftest.lit <<EOF
2506  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2507  0010 01000000 12000000 18000000 00000000  ................
2508  0020 08000000 04080000 0044               .........D      @&t@
2509 EOF
2510 cat > conftest.big <<EOF
2511  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2512  0010 00000001 00000012 00000018 00000000  ................
2513  0020 00000008 04000000 0844               .........D      @&t@
2514 EOF
2515   # If the assembler didn't choke, and we can objdump,
2516   # and we got the correct data, then succeed.
2517   # The text in the here-document typically retains its unix-style line
2518   # endings, while the output of objdump will use host line endings.
2519   # Therefore, use diff -b for the comparisons.
2520   if test x$gcc_cv_objdump != x \
2521   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2522      | tail -3 > conftest.got \
2523   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2524     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2525   then
2526     gcc_cv_as_eh_frame=yes
2527   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2528     gcc_cv_as_eh_frame=buggy
2529   else
2530     # Uh oh, what do we do now?
2531     gcc_cv_as_eh_frame=no
2532   fi])
2533
2534 if test $gcc_cv_as_eh_frame = buggy; then
2535   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2536   [Define if your assembler mis-optimizes .eh_frame data.])
2537 fi
2538
2539 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2540  [elf,2,12,0], [--fatal-warnings],
2541  [.section .rodata.str, "aMS", @progbits, 1])
2542 if test $gcc_cv_as_shf_merge = no; then
2543   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2544     [elf,2,12,0], [--fatal-warnings],
2545     [.section .rodata.str, "aMS", %progbits, 1])
2546 fi
2547 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2548   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2549 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2550
2551 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2552  [elf,2,16,0], [--fatal-warnings],
2553  [.section .text,"axG",@progbits,.foo,comdat])
2554 if test $gcc_cv_as_comdat_group = yes; then
2555   gcc_cv_as_comdat_group_percent=no
2556 else
2557  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2558    [elf,2,16,0], [--fatal-warnings],
2559    [.section .text,"axG",%progbits,.foo,comdat])
2560 fi
2561 if test x"$ld_is_gold" = xyes; then
2562   comdat_group=yes
2563 elif test $in_tree_ld = yes ; then
2564   comdat_group=no
2565   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2566      && test $in_tree_ld_is_elf = yes; then
2567      comdat_group=yes
2568   fi
2569 elif echo "$ld_ver" | grep GNU > /dev/null; then
2570   comdat_group=yes
2571   if test 0"$ld_date" -lt 20050308; then
2572     if test -n "$ld_date"; then
2573       # If there was date string, but was earlier than 2005-03-08, fail
2574       comdat_group=no
2575     elif test "$ld_vers_major" -lt 2; then
2576       comdat_group=no
2577     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2578       comdat_group=no
2579     fi
2580   fi
2581 else
2582 changequote(,)dnl
2583   case "${target}" in
2584     *-*-solaris2.1[1-9]*)
2585       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2586       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2587       # version 1.688.
2588       #
2589       # FIXME: Maybe need to refine later when COMDAT group support with
2590       # Sun as is implemented.
2591       if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 1688; then
2592         comdat_group=yes
2593       else
2594         comdat_group=no
2595       fi
2596       ;;
2597     *)
2598       # Assume linkers other than GNU ld don't support COMDAT group.
2599       comdat_group=no
2600       ;;
2601   esac
2602 changequote([,])dnl
2603 fi
2604 # Allow overriding the automatic COMDAT group tests above.
2605 AC_ARG_ENABLE(comdat,
2606   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2607   [comdat_group="$enable_comdat"])
2608 if test $comdat_group = no; then
2609   gcc_cv_as_comdat_group=no
2610   gcc_cv_as_comdat_group_percent=no
2611 fi
2612 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2613   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2614 [Define 0/1 if your assembler and linker support COMDAT groups.])
2615
2616 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2617  gcc_cv_as_discriminator,
2618  [2,19,51],,
2619 [       .text
2620         .file 1 "conf.c"
2621         .loc 1 1 0 discriminator 1],,
2622 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2623   [Define if your assembler supports the .loc discriminator sub-directive.])])
2624
2625 # Thread-local storage - the check is heavily parameterized.
2626 conftest_s=
2627 tls_first_major=
2628 tls_first_minor=
2629 tls_as_opt=
2630 case "$target" in
2631 changequote(,)dnl
2632   alpha*-*-*)
2633     conftest_s='
2634         .section ".tdata","awT",@progbits
2635 foo:    .long   25
2636         .text
2637         ldq     $27,__tls_get_addr($29)         !literal!1
2638         lda     $16,foo($29)                    !tlsgd!1
2639         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2640         ldq     $27,__tls_get_addr($29)         !literal!2
2641         lda     $16,foo($29)                    !tlsldm!2
2642         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2643         ldq     $1,foo($29)                     !gotdtprel
2644         ldah    $2,foo($29)                     !dtprelhi
2645         lda     $3,foo($2)                      !dtprello
2646         lda     $4,foo($29)                     !dtprel
2647         ldq     $1,foo($29)                     !gottprel
2648         ldah    $2,foo($29)                     !tprelhi
2649         lda     $3,foo($2)                      !tprello
2650         lda     $4,foo($29)                     !tprel'
2651         tls_first_major=2
2652         tls_first_minor=13
2653         tls_as_opt=--fatal-warnings
2654         ;;
2655   cris-*-*|crisv32-*-*)
2656     conftest_s='
2657         .section ".tdata","awT",@progbits
2658 x:      .long   25
2659         .text
2660         move.d x:IE,$r10
2661         nop'
2662         tls_first_major=2
2663         tls_first_minor=20
2664         tls_as_opt=--fatal-warnings
2665         ;;
2666   frv*-*-*)
2667     conftest_s='
2668         .section ".tdata","awT",@progbits
2669 x:      .long   25
2670         .text
2671         call    #gettlsoff(x)'
2672         tls_first_major=2
2673         tls_first_minor=14
2674         ;;
2675   hppa*-*-linux*)
2676     conftest_s='
2677 t1:     .reg    %r20
2678 t2:     .reg    %r21
2679 gp:     .reg    %r19
2680         .section ".tdata","awT",@progbits
2681 foo:    .long   25
2682         .text
2683         .align  4
2684         addil LT%foo-$tls_gdidx$,gp
2685         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2686         b __tls_get_addr
2687         nop
2688         addil LT%foo-$tls_ldidx$,gp
2689         b __tls_get_addr
2690         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2691         addil LR%foo-$tls_dtpoff$,%ret0
2692         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2693         mfctl %cr27,%t1
2694         addil LT%foo-$tls_ieoff$,gp
2695         ldw RT%foo-$tls_ieoff$(%r1),%t2
2696         add %t1,%t2,%t3
2697         mfctl %cr27,%t1
2698         addil LR%foo-$tls_leoff$,%t1
2699         ldo RR%foo-$tls_leoff$(%r1),%t2'
2700         tls_first_major=2
2701         tls_first_minor=15
2702         tls_as_opt=--fatal-warnings
2703         ;;
2704   arm*-*-*)
2705     conftest_s='
2706         .section ".tdata","awT",%progbits
2707 foo:    .long   25
2708         .text
2709 .word foo(gottpoff)
2710 .word foo(tpoff)
2711 .word foo(tlsgd)
2712 .word foo(tlsldm)
2713 .word foo(tlsldo)'
2714         tls_first_major=2
2715         tls_first_minor=17
2716         ;;
2717   i[34567]86-*-*)
2718     case "$target" in
2719       i[34567]86-*-solaris2.*)
2720         on_solaris=yes
2721         tga_func=___tls_get_addr
2722         ;;
2723       *)
2724         on_solaris=no
2725         ;;
2726     esac
2727     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2728       conftest_s='
2729         .section .tdata,"awt",@progbits'
2730       tls_first_major=0
2731       tls_first_minor=0
2732 changequote([,])dnl
2733       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2734 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2735 changequote(,)dnl
2736     else
2737       conftest_s='
2738         .section ".tdata","awT",@progbits'
2739       tls_first_major=2
2740       tls_first_minor=14
2741       tls_as_opt="--fatal-warnings"
2742     fi
2743     conftest_s="$conftest_s
2744 foo:    .long   25
2745         .text
2746         movl    %gs:0, %eax
2747         leal    foo@tlsgd(,%ebx,1), %eax
2748         leal    foo@tlsldm(%ebx), %eax
2749         leal    foo@dtpoff(%eax), %edx
2750         movl    foo@gottpoff(%ebx), %eax
2751         subl    foo@gottpoff(%ebx), %eax
2752         addl    foo@gotntpoff(%ebx), %eax
2753         movl    foo@indntpoff, %eax
2754         movl    \$foo@tpoff, %eax
2755         subl    \$foo@tpoff, %eax
2756         leal    foo@ntpoff(%ecx), %eax"
2757     ;;
2758   x86_64-*-*)
2759     conftest_s='
2760         .section ".tdata","awT",@progbits
2761 foo:    .long   25
2762         .text
2763         movq    %fs:0, %rax
2764         leaq    foo@TLSGD(%rip), %rdi
2765         leaq    foo@TLSLD(%rip), %rdi
2766         leaq    foo@DTPOFF(%rax), %rdx
2767         movq    foo@GOTTPOFF(%rip), %rax
2768         movq    $foo@TPOFF, %rax'
2769         tls_first_major=2
2770         tls_first_minor=14
2771         tls_as_opt=--fatal-warnings
2772         ;;
2773   ia64-*-*)
2774     conftest_s='
2775         .section ".tdata","awT",@progbits
2776 foo:    data8   25
2777         .text
2778         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2779         addl    r17 = @ltoff(@dtprel(foo#)), gp
2780         addl    r18 = @ltoff(@tprel(foo#)), gp
2781         addl    r19 = @dtprel(foo#), gp
2782         adds    r21 = @dtprel(foo#), r13
2783         movl    r23 = @dtprel(foo#)
2784         addl    r20 = @tprel(foo#), gp
2785         adds    r22 = @tprel(foo#), r13
2786         movl    r24 = @tprel(foo#)'
2787         tls_first_major=2
2788         tls_first_minor=13
2789         tls_as_opt=--fatal-warnings
2790         ;;
2791   mips*-*-*)
2792     conftest_s='
2793         .section .tdata,"awT",@progbits
2794 x:
2795         .word 2
2796         .text
2797         addiu $4, $28, %tlsgd(x)
2798         addiu $4, $28, %tlsldm(x)
2799         lui $4, %dtprel_hi(x)
2800         addiu $4, $4, %dtprel_lo(x)
2801         lw $4, %gottprel(x)($28)
2802         lui $4, %tprel_hi(x)
2803         addiu $4, $4, %tprel_lo(x)'
2804         tls_first_major=2
2805         tls_first_minor=16
2806         tls_as_opt='-32 --fatal-warnings'
2807         ;;
2808   m68k-*-*)
2809     conftest_s='
2810         .section .tdata,"awT",@progbits
2811 x:
2812         .word 2
2813         .text
2814 foo:
2815         move.l x@TLSGD(%a5),%a0
2816         move.l x@TLSLDM(%a5),%a0
2817         move.l x@TLSLDO(%a5),%a0
2818         move.l x@TLSIE(%a5),%a0
2819         move.l x@TLSLE(%a5),%a0'
2820         tls_first_major=2
2821         tls_first_minor=19
2822         tls_as_opt='--fatal-warnings'
2823         ;;
2824   powerpc-*-*)
2825     conftest_s='
2826         .section ".tdata","awT",@progbits
2827         .align 2
2828 ld0:    .space 4
2829 ld1:    .space 4
2830 x1:     .space 4
2831 x2:     .space 4
2832 x3:     .space 4
2833         .text
2834         addi 3,31,ld0@got@tlsgd
2835         bl __tls_get_addr
2836         addi 3,31,x1@got@tlsld
2837         bl __tls_get_addr
2838         addi 9,3,x1@dtprel
2839         addis 9,3,x2@dtprel@ha
2840         addi 9,9,x2@dtprel@l
2841         lwz 9,x3@got@tprel(31)
2842         add 9,9,x@tls
2843         addi 9,2,x1@tprel
2844         addis 9,2,x2@tprel@ha
2845         addi 9,9,x2@tprel@l'
2846         tls_first_major=2
2847         tls_first_minor=14
2848         tls_as_opt="-a32 --fatal-warnings"
2849         ;;
2850   powerpc64-*-*)
2851     conftest_s='
2852         .section ".tdata","awT",@progbits
2853         .align 3
2854 ld0:    .space 8
2855 ld1:    .space 8
2856 x1:     .space 8
2857 x2:     .space 8
2858 x3:     .space 8
2859         .text
2860         addi 3,2,ld0@got@tlsgd
2861         bl .__tls_get_addr
2862         nop
2863         addi 3,2,ld1@toc
2864         bl .__tls_get_addr
2865         nop
2866         addi 3,2,x1@got@tlsld
2867         bl .__tls_get_addr
2868         nop
2869         addi 9,3,x1@dtprel
2870         bl .__tls_get_addr
2871         nop
2872         addis 9,3,x2@dtprel@ha
2873         addi 9,9,x2@dtprel@l
2874         bl .__tls_get_addr
2875         nop
2876         ld 9,x3@got@dtprel(2)
2877         add 9,9,3
2878         bl .__tls_get_addr
2879         nop'
2880         tls_first_major=2
2881         tls_first_minor=14
2882         tls_as_opt="-a64 --fatal-warnings"
2883         ;;
2884   s390-*-*)
2885     conftest_s='
2886         .section ".tdata","awT",@progbits
2887 foo:    .long   25
2888         .text
2889         .long   foo@TLSGD
2890         .long   foo@TLSLDM
2891         .long   foo@DTPOFF
2892         .long   foo@NTPOFF
2893         .long   foo@GOTNTPOFF
2894         .long   foo@INDNTPOFF
2895         l       %r1,foo@GOTNTPOFF(%r12)
2896         l       %r1,0(%r1):tls_load:foo
2897         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2898         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2899         tls_first_major=2
2900         tls_first_minor=14
2901         tls_as_opt="-m31 --fatal-warnings"
2902         ;;
2903   s390x-*-*)
2904     conftest_s='
2905         .section ".tdata","awT",@progbits
2906 foo:    .long   25
2907         .text
2908         .quad   foo@TLSGD
2909         .quad   foo@TLSLDM
2910         .quad   foo@DTPOFF
2911         .quad   foo@NTPOFF
2912         .quad   foo@GOTNTPOFF
2913         lg      %r1,foo@GOTNTPOFF(%r12)
2914         larl    %r1,foo@INDNTPOFF
2915         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2916         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2917         tls_first_major=2
2918         tls_first_minor=14
2919         tls_as_opt="-m64 -Aesame --fatal-warnings"
2920         ;;
2921   sh-*-* | sh[34]-*-*)
2922     conftest_s='
2923         .section ".tdata","awT",@progbits
2924 foo:    .long   25
2925         .text
2926         .long   foo@TLSGD
2927         .long   foo@TLSLDM
2928         .long   foo@DTPOFF
2929         .long   foo@GOTTPOFF
2930         .long   foo@TPOFF'
2931         tls_first_major=2
2932         tls_first_minor=13
2933         tls_as_opt=--fatal-warnings
2934         ;;
2935   sparc*-*-*)
2936     case "$target" in
2937       sparc*-sun-solaris2.*)
2938         on_solaris=yes
2939         tga_func=__tls_get_addr
2940         ;;
2941       *)
2942         on_solaris=no
2943         ;;
2944     esac
2945     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2946       conftest_s='
2947         .section ".tdata",#alloc,#write,#tls'
2948         tls_first_major=0
2949         tls_first_minor=0
2950     else
2951       conftest_s='
2952         .section ".tdata","awT",@progbits'
2953         tls_first_major=2
2954         tls_first_minor=14
2955         tls_as_opt="-32 --fatal-warnings"
2956     fi
2957     conftest_s="$conftest_s
2958 foo:    .long   25
2959         .text
2960         sethi   %tgd_hi22(foo), %o0
2961         add     %o0, %tgd_lo10(foo), %o1
2962         add     %l7, %o1, %o0, %tgd_add(foo)
2963         call    __tls_get_addr, %tgd_call(foo)
2964         sethi   %tldm_hi22(foo), %l1
2965         add     %l1, %tldm_lo10(foo), %l2
2966         add     %l7, %l2, %o0, %tldm_add(foo)
2967         call    __tls_get_addr, %tldm_call(foo)
2968         sethi   %tldo_hix22(foo), %l3
2969         xor     %l3, %tldo_lox10(foo), %l4
2970         add     %o0, %l4, %l5, %tldo_add(foo)
2971         sethi   %tie_hi22(foo), %o3
2972         add     %o3, %tie_lo10(foo), %o3
2973         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2974         add     %g7, %o2, %o4, %tie_add(foo)
2975         sethi   %tle_hix22(foo), %l1
2976         xor     %l1, %tle_lox10(foo), %o5
2977         ld      [%g7 + %o5], %o1"
2978         ;;
2979   xtensa*-*-*)
2980     conftest_s='
2981         .section ".tdata","awT",@progbits
2982 foo:    .long   25
2983         .text
2984         movi    a8, foo@TLSFUNC
2985         movi    a10, foo@TLSARG
2986         callx8.tls a8, foo@TLSCALL'
2987         tls_first_major=2
2988         tls_first_minor=19
2989         ;;
2990 changequote([,])dnl
2991 esac
2992 set_have_as_tls=no
2993 if test "x$enable_tls" = xno ; then
2994   : # TLS explicitly disabled.
2995 elif test "x$enable_tls" = xyes ; then
2996   set_have_as_tls=yes # TLS explicitly enabled.
2997 elif test -z "$tls_first_major"; then
2998   : # If we don't have a check, assume no support.
2999 else
3000   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3001   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3002   [set_have_as_tls=yes])
3003 fi
3004 case "$target" in
3005   *-*-irix6*)
3006     # IRIX 6.5 rld and libc.so lack TLS support, so even if gas and gld
3007     # with TLS support are in use, native TLS cannot work.
3008     set_have_as_tls=no
3009     ;;
3010   *-*-osf*)
3011     # Tru64 UNIX loader and libc.so lack TLS support, so even if gas and
3012     # gld with TLS support are in use, native TLS cannot work.
3013     set_have_as_tls=no
3014     ;;
3015   # TLS was introduced in the Solaris 9 FCS release and backported to
3016   # Solaris 8 patches.  Support for GNU-style TLS on x86 was only
3017   # introduced in Solaris 9 4/04, replacing the earlier Sun style that Sun
3018   # ld and GCC don't support any longer.
3019   *-*-solaris2.*)
3020     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
3021     ld_tls_support=no
3022     # Check ld and ld.so.1 TLS support.
3023     if echo "$ld_ver" | grep GNU > /dev/null; then
3024       # Assume all interesting versions of GNU ld have TLS support.
3025       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
3026       ld_tls_support=yes
3027     else
3028       case "$target" in
3029         # Solaris 8/x86 ld has GNU style TLS support since version 1.280.
3030         i?86-*-solaris2.8)
3031           min_tls_ld_vers_minor=280
3032           ;;
3033         # Solaris 8/SPARC ld has TLS support since version 1.272.
3034         sparc*-*-solaris2.8)
3035           min_tls_ld_vers_minor=272
3036           ;;
3037         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
3038         i?86-*-solaris2.9)
3039           min_tls_ld_vers_minor=374
3040           ;;
3041         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
3042         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
3043           min_tls_ld_vers_minor=343
3044           ;;
3045       esac
3046       if test "$ld_vers_major" -gt 1 || \
3047         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
3048         ld_tls_support=yes
3049       else
3050         set_have_as_tls=no
3051       fi
3052     fi
3053     AC_MSG_RESULT($ld_tls_support)
3054
3055     save_LIBS="$LIBS"
3056     save_LDFLAGS="$LDFLAGS"
3057     LIBS=
3058     LDFLAGS=
3059
3060     AC_MSG_CHECKING(alternate thread library)
3061     case "$target" in
3062       # TLS support was backported to Solaris 8 patches, but only lives in
3063       # the alternate thread library which became the default in Solaris 9.
3064       # We want to always use that, irrespective of TLS support.
3065       *-*-solaris2.8)
3066         # Take multilib subdir into account.  There's no spec to handle
3067         # this.  The 64 symlink exists since Solaris 8.
3068         lwp_dir=/usr/lib/lwp
3069         lwp_spec="-L$lwp_dir%{m64:/64} -R$lwp_dir%{m64:/64}"
3070         LDFLAGS="-L$lwp_dir -R$lwp_dir"
3071         ;;
3072       *-*-solaris2*)
3073         lwp_dir="none"
3074         lwp_spec=""
3075         ;;
3076     esac
3077     # Always define LIB_THREAD_LDFLAGS_SPEC, even without TLS support.
3078     AC_DEFINE_UNQUOTED(LIB_THREAD_LDFLAGS_SPEC, "$lwp_spec",
3079         [Define to the linker flags to use for -pthread.])
3080     AC_MSG_RESULT($lwp_dir)
3081
3082     AC_MSG_CHECKING(library containing $tga_func)
3083     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3084     # (32-bit x86) only lived in libthread, so check for that.  Keep
3085     # set_have_as_tls if found, disable if not.
3086     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3087     # Clear LIBS if we cannot support TLS.
3088     if test $set_have_as_tls = no; then
3089       LIBS=
3090     fi
3091     # Always define LIB_TLS_SPEC, even without TLS support.
3092     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3093         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3094     AC_MSG_RESULT($LIBS)
3095
3096     LIBS="$save_LIBS"
3097     LDFLAGS="$save_LDFLAGS"
3098     ;;
3099 esac
3100 if test $set_have_as_tls = yes ; then
3101   AC_DEFINE(HAVE_AS_TLS, 1,
3102             [Define if your assembler and linker support thread-local storage.])
3103 fi
3104
3105 # Target-specific assembler checks.
3106
3107 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3108 gcc_cv_ld_static_dynamic=no
3109 if test $in_tree_ld = yes ; then
3110   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3111     gcc_cv_ld_static_dynamic=yes
3112   fi
3113 elif test x$gcc_cv_ld != x; then
3114         # Check if linker supports -Bstatic/-Bdynamic option
3115         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3116           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3117                 gcc_cv_ld_static_dynamic=yes
3118         fi
3119 fi
3120 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3121         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3122 [Define if your linker supports -Bstatic/-Bdynamic option.])
3123 fi
3124 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3125
3126 if test x"$demangler_in_ld" = xyes; then
3127   AC_MSG_CHECKING(linker --demangle support)
3128   gcc_cv_ld_demangle=no
3129   if test $in_tree_ld = yes; then
3130     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3131       gcc_cv_ld_demangle=yes
3132     fi
3133   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3134     # Check if the GNU linker supports --demangle option
3135     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3136       gcc_cv_ld_demangle=yes
3137     fi
3138   fi
3139   if test x"$gcc_cv_ld_demangle" = xyes; then
3140     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3141 [Define if your linker supports --demangle option.])
3142   fi
3143   AC_MSG_RESULT($gcc_cv_ld_demangle)
3144 fi
3145
3146 case "$target" in
3147   # All TARGET_ABI_OSF targets.
3148   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
3149     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3150         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3151 [       .set nomacro
3152         .text
3153         extbl   $3, $2, $3      !lituse_bytoff!1
3154         ldq     $2, a($29)      !literal!1
3155         ldq     $4, b($29)      !literal!2
3156         ldq_u   $3, 0($2)       !lituse_base!1
3157         ldq     $27, f($29)     !literal!5
3158         jsr     $26, ($27), f   !lituse_jsr!5
3159         ldah    $29, 0($26)     !gpdisp!3
3160         lda     $0, c($29)      !gprel
3161         ldah    $1, d($29)      !gprelhigh
3162         lda     $1, d($1)       !gprellow
3163         lda     $29, 0($29)     !gpdisp!3],,
3164     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3165   [Define if your assembler supports explicit relocations.])])
3166     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3167         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3168 [       .set nomacro
3169         .text
3170         ldq     $27, a($29)     !literal!1
3171         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3172     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3173   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3174     ;;
3175
3176   cris-*-*)
3177     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3178       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3179       [-no-mul-bug-abort], [.text],,
3180       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3181                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3182     ;;
3183
3184   sparc*-*-*)
3185     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3186       [.register %g2, #scratch],,
3187       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3188                 [Define if your assembler supports .register.])])
3189
3190     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3191       [-relax], [.text],,
3192       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3193                 [Define if your assembler supports -relax option.])])
3194
3195     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3196       gcc_cv_as_sparc_gotdata_op,,
3197       [-K PIC],
3198 [.text
3199 foo:
3200         nop
3201 bar:
3202         sethi %gdop_hix22(foo), %g1
3203         xor    %g1, %gdop_lox10(foo), %g1
3204         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3205       [if test x$gcc_cv_ld != x \
3206        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3207          if $gcc_cv_ld -v | grep GNU >/dev/null 2>&1; then
3208            if test x$gcc_cv_objdump != x; then
3209              if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3210                 | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3211                gcc_cv_as_sparc_gotdata_op=no
3212              else
3213                gcc_cv_as_sparc_gotdata_op=yes
3214              fi
3215            fi
3216          else
3217            gcc_cv_as_sparc_gotdata_op=yes
3218          fi
3219        fi
3220        rm -f conftest],
3221       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3222                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3223
3224     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3225       gcc_cv_as_sparc_ua_pcrel,,
3226       [-K PIC],
3227 [.text
3228 foo:
3229         nop
3230 .data
3231 .align 4
3232 .byte 0
3233 .uaword %r_disp32(foo)],
3234       [if test x$gcc_cv_ld != x \
3235        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3236          gcc_cv_as_sparc_ua_pcrel=yes
3237        fi
3238        rm -f conftest],
3239       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3240                 [Define if your assembler and linker support unaligned PC relative relocs.])
3241
3242       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3243         gcc_cv_as_sparc_ua_pcrel_hidden,,
3244         [-K PIC],
3245 [.data
3246 .align 4
3247 .byte 0x31
3248 .uaword %r_disp32(foo)
3249 .byte 0x32, 0x33, 0x34
3250 .global foo
3251 .hidden foo
3252 foo:
3253 .skip 4],
3254         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3255          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3256          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3257             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3258             if $gcc_cv_objdump -R conftest 2> /dev/null \
3259                | grep 'DISP32' > /dev/null 2>&1; then
3260                 :
3261             else
3262                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3263             fi
3264          fi
3265          rm -f conftest],
3266          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3267                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3268     ]) # unaligned pcrel relocs
3269
3270     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3271       gcc_cv_as_sparc_offsetable_lo10,,
3272       [-xarch=v9],
3273 [.text
3274         or %g1, %lo(ab) + 12, %g1
3275         or %g1, %lo(ab + 12), %g1],
3276       [if test x$gcc_cv_objdump != x \
3277        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3278           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3279          gcc_cv_as_sparc_offsetable_lo10=yes
3280        fi],
3281        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3282                  [Define if your assembler supports offsetable %lo().])])
3283     ;;
3284
3285 changequote(,)dnl
3286   i[34567]86-*-* | x86_64-*-*)
3287 changequote([,])dnl
3288     case $target_os in
3289       cygwin*)
3290         # Full C++ conformance when using a shared libstdc++-v3 requires some
3291         # support from the Cygwin DLL, which in more recent versions exports
3292         # wrappers to aid in interposing and redirecting operators new, delete,
3293         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3294         # are configuring for a version of Cygwin that exports the wrappers.
3295         if test x$host = x$target; then
3296           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3297         else
3298           # Can't check presence of libc functions during cross-compile, so
3299           # we just have to assume we're building for an up-to-date target.
3300           gcc_ac_cygwin_dll_wrappers=yes
3301         fi
3302         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3303           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3304           [Define if you want to generate code by default that assumes that the
3305            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3306     esac
3307     case $target_os in
3308       cygwin* | pe | mingw32*)
3309         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3310         # definition is used unconditionally to initialise the default state of
3311         # the target option variable that governs usage of the feature.
3312         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3313          [2,19,52],,[.comm foo,1,32])
3314         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3315           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3316           [Define if your assembler supports specifying the alignment
3317            of objects allocated using the GAS .comm command.])
3318         # Used for DWARF 2 in PE
3319         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3320           gcc_cv_as_ix86_pe_secrel32,
3321           [2,15,91],,
3322 [.text
3323 foo:    nop
3324 .data
3325         .secrel32 foo],
3326           [if test x$gcc_cv_ld != x \
3327            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3328              gcc_cv_as_ix86_pe_secrel32=yes
3329            fi
3330            rm -f conftest],
3331           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3332             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3333         # Test if the assembler supports the extended form of the .section
3334         # directive that specifies section alignment.  LTO support uses this,
3335         # but normally only after installation, so we warn but don't fail the
3336         # configure if LTO is enabled but the assembler does not support it.
3337         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3338           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3339         if test x$gcc_cv_as_section_has_align != xyes; then
3340           case ",$enable_languages," in
3341             *,lto,*)
3342               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3343               ;;
3344           esac
3345         fi
3346         ;;
3347     esac
3348
3349     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3350        gcc_cv_as_ix86_filds,,,
3351        [filds mem; fists mem],,
3352        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3353          [Define if your assembler uses filds and fists mnemonics.])])
3354
3355     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3356        gcc_cv_as_ix86_fildq,,,
3357        [fildq mem; fistpq mem],,
3358        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3359          [Define if your assembler uses fildq and fistq mnemonics.])])
3360
3361     gcc_GAS_CHECK_FEATURE([cmov syntax],
3362       gcc_cv_as_ix86_cmov_sun_syntax,,,
3363       [cmovl.l %edx, %eax],,
3364       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3365         [Define if your assembler supports the Sun syntax for cmov.])])
3366
3367     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3368       gcc_cv_as_ix86_ffreep,,,
3369       [ffreep %st(1)],,
3370       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3371         [Define if your assembler supports the ffreep mnemonic.])])
3372
3373     gcc_GAS_CHECK_FEATURE([.quad directive],
3374       gcc_cv_as_ix86_quad,,,
3375       [.quad 0],,
3376       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3377         [Define if your assembler supports the .quad directive.])])
3378
3379     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3380       gcc_cv_as_ix86_sahf,,,
3381       [.code64
3382        sahf],,
3383       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3384         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3385
3386     gcc_GAS_CHECK_FEATURE([swap suffix],
3387       gcc_cv_as_ix86_swap,,,
3388       [movl.s %esp, %ebp],,
3389       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3390         [Define if your assembler supports the swap suffix.])])
3391
3392     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3393       gcc_cv_as_ix86_diff_sect_delta,,,
3394       [.section .rodata
3395 .L1:
3396         .long .L2-.L1
3397         .long .L3-.L1
3398         .text
3399 .L3:    nop
3400 .L2:    nop],,
3401       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3402         [Define if your assembler supports the subtraction of symbols in different sections.])])
3403
3404     # These two are used unconditionally by i386.[ch]; it is to be defined
3405     # to 1 if the feature is present, 0 otherwise.
3406     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3407         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3408 [       .text
3409 .L0:
3410         nop
3411         .data
3412         .long .L0@GOTOFF])
3413     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3414       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3415       [Define true if the assembler supports '.long foo@GOTOFF'.])
3416
3417     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3418         gcc_cv_as_ix86_rep_lock_prefix,,,
3419         [rep movsl
3420          lock addl %edi, (%eax,%esi)
3421          lock orl $0, (%esp)],,
3422         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3423           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3424
3425     ;;
3426
3427   ia64*-*-*)
3428     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3429         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3430 [       .text
3431         addl r15 = @ltoffx(x#), gp
3432         ;;
3433         ld8.mov r16 = [[r15]], x#],,
3434     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3435           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3436
3437     ;;
3438
3439   powerpc*-*-*)
3440     case $target in
3441       *-*-aix*) conftest_s='    .machine "pwr5"
3442         .csect .text[[PR]]
3443         mfcr 3,128';;
3444       *-*-darwin*)
3445         gcc_GAS_CHECK_FEATURE([.machine directive support],
3446           gcc_cv_as_machine_directive,,,
3447           [     .machine ppc7400])
3448         if test x$gcc_cv_as_machine_directive != xyes; then
3449           echo "*** This target requires an assembler supporting \".machine\"" >&2
3450           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3451           test x$build = x$target && exit 1
3452         fi
3453         conftest_s='    .text
3454         mfcr r3,128';;
3455       *) conftest_s='   .machine power4
3456         .text
3457         mfcr 3,128';;
3458     esac
3459
3460     gcc_GAS_CHECK_FEATURE([mfcr field support],
3461       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3462       [$conftest_s],,
3463       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3464           [Define if your assembler supports mfcr field.])])
3465
3466     case $target in
3467       *-*-aix*) conftest_s='    .machine "pwr5"
3468         .csect .text[[PR]]
3469         popcntb 3,3';;
3470       *) conftest_s='   .machine power5
3471         .text
3472         popcntb 3,3';;
3473     esac
3474
3475     gcc_GAS_CHECK_FEATURE([popcntb support],
3476       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3477       [$conftest_s],,
3478       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3479           [Define if your assembler supports popcntb field.])])
3480
3481     case $target in
3482       *-*-aix*) conftest_s='    .machine "pwr5x"
3483         .csect .text[[PR]]
3484         frin 1,1';;
3485       *) conftest_s='   .machine power5
3486         .text
3487         frin 1,1';;
3488     esac
3489
3490     gcc_GAS_CHECK_FEATURE([fp round support],
3491       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3492       [$conftest_s],,
3493       [AC_DEFINE(HAVE_AS_FPRND, 1,
3494           [Define if your assembler supports fprnd.])])
3495
3496     case $target in
3497       *-*-aix*) conftest_s='    .machine "pwr6"
3498         .csect .text[[PR]]
3499         mffgpr 1,3';;
3500       *) conftest_s='   .machine power6
3501         .text
3502         mffgpr 1,3';;
3503     esac
3504
3505     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3506       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3507       [$conftest_s],,
3508       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3509           [Define if your assembler supports mffgpr and mftgpr.])])
3510
3511     case $target in
3512       *-*-aix*) conftest_s='    .csect .text[[PR]]
3513 LCF..0:
3514         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3515       *-*-darwin*)
3516         conftest_s='    .text
3517 LCF0:
3518         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3519       *) conftest_s='   .text
3520 .LCF0:
3521         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3522     esac
3523
3524     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3525       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3526       [$conftest_s],,
3527       [AC_DEFINE(HAVE_AS_REL16, 1,
3528           [Define if your assembler supports R_PPC_REL16 relocs.])])
3529
3530     case $target in
3531       *-*-aix*) conftest_s='    .machine "pwr6"
3532         .csect .text[[PR]]
3533         cmpb 3,4,5';;
3534       *) conftest_s='   .machine power6
3535         .text
3536         cmpb 3,4,5';;
3537     esac
3538
3539     gcc_GAS_CHECK_FEATURE([compare bytes support],
3540       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3541       [$conftest_s],,
3542       [AC_DEFINE(HAVE_AS_CMPB, 1,
3543           [Define if your assembler supports cmpb.])])
3544
3545     case $target in
3546       *-*-aix*) conftest_s='    .machine "pwr6"
3547         .csect .text[[PR]]
3548         dadd 1,2,3';;
3549       *) conftest_s='   .machine power6
3550         .text
3551         dadd 1,2,3';;
3552     esac
3553
3554     gcc_GAS_CHECK_FEATURE([decimal float support],
3555       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3556       [$conftest_s],,
3557       [AC_DEFINE(HAVE_AS_DFP, 1,
3558           [Define if your assembler supports DFP instructions.])])
3559
3560     case $target in
3561       *-*-aix*) conftest_s='    .machine "pwr7"
3562         .csect .text[[PR]]
3563         lxvd2x 1,2,3';;
3564       *) conftest_s='   .machine power7
3565         .text
3566         lxvd2x 1,2,3';;
3567     esac
3568
3569     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3570       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3571       [$conftest_s],,
3572       [AC_DEFINE(HAVE_AS_VSX, 1,
3573           [Define if your assembler supports VSX instructions.])])
3574
3575     case $target in
3576       *-*-aix*) conftest_s='    .machine "pwr7"
3577         .csect .text[[PR]]
3578         popcntd 3,3';;
3579       *) conftest_s='   .machine power7
3580         .text
3581         popcntd 3,3';;
3582     esac
3583
3584     gcc_GAS_CHECK_FEATURE([popcntd support],
3585       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3586       [$conftest_s],,
3587       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3588           [Define if your assembler supports POPCNTD instructions.])])
3589
3590     case $target in
3591       *-*-aix*) conftest_s='    .csect .text[[PR]]
3592         lwsync';;
3593       *) conftest_s='   .text
3594         lwsync';;
3595     esac
3596
3597     gcc_GAS_CHECK_FEATURE([lwsync support],
3598       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3599       [$conftest_s],,
3600       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3601           [Define if your assembler supports LWSYNC instructions.])])
3602
3603     case $target in
3604       *-*-aix*) conftest_s='    .machine "476"
3605         .csect .text[[PR]]
3606         dci 0';;
3607       *) conftest_s='   .machine "476"
3608         .text
3609         dci 0';;
3610     esac
3611
3612     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3613       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3614       [$conftest_s],,
3615       [AC_DEFINE(HAVE_AS_DCI, 1,
3616           [Define if your assembler supports the DCI/ICI instructions.])])
3617
3618     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3619       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3620       [.gnu_attribute 4,1],,
3621       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3622           [Define if your assembler supports .gnu_attribute.])])
3623
3624     gcc_GAS_CHECK_FEATURE([tls marker support],
3625       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3626       [ bl __tls_get_addr(x@tlsgd)],,
3627       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3628           [Define if your assembler supports arg info for __tls_get_addr.])])
3629
3630     case $target in
3631       *-*-aix*)
3632         gcc_GAS_CHECK_FEATURE([.ref support],
3633           gcc_cv_as_aix_ref, [2.21.0],,
3634           [     .csect stuff[[rw]]
3635              stuff:
3636                 .long 1
3637                 .extern sym
3638                 .ref sym
3639           ],,
3640           [AC_DEFINE(HAVE_AS_REF, 1,
3641             [Define if your assembler supports .ref])])
3642         ;;
3643     esac
3644     ;;
3645
3646   mips*-*-*)
3647     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3648       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3649 [       lw $4,%gp_rel(foo)($4)],,
3650       [if test x$target_cpu_default = x
3651        then target_cpu_default=MASK_EXPLICIT_RELOCS
3652        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3653        fi])
3654     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3655       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3656       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3657                  [Define if the assembler understands -mno-shared.])])
3658
3659     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3660       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3661       [.gnu_attribute 4,1],,
3662       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3663           [Define if your assembler supports .gnu_attribute.])])
3664
3665     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3666       gcc_cv_as_mips_dtprelword, [2,18,0],,
3667       [.section .tdata,"awT",@progbits
3668 x:
3669         .word 2
3670         .text
3671         .dtprelword x+0x8000],,
3672       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3673           [Define if your assembler supports .dtprelword.])])
3674
3675     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
3676       gcc_cv_as_mips_dspr1_mult,,,
3677 [       .set    mips32r2
3678         .set    nodspr2
3679         .set    dsp
3680         madd    $ac3,$4,$5
3681         maddu   $ac3,$4,$5
3682         msub    $ac3,$4,$5
3683         msubu   $ac3,$4,$5
3684         mult    $ac3,$4,$5
3685         multu   $ac3,$4,$5],,
3686       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
3687           [Define if your assembler supports DSPR1 mult.])])
3688
3689     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3690     gcc_cv_as_ld_jalr_reloc=no
3691     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3692       if test $in_tree_ld = yes ; then
3693         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3694            && test $in_tree_ld_is_elf = yes; then
3695           gcc_cv_as_ld_jalr_reloc=yes
3696         fi
3697       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3698         echo '  .ent x' > conftest.s
3699         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3700         echo '  ld $25,%call16(y)($28)' >> conftest.s
3701         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3702         echo '1:        jalr $25' >> conftest.s
3703         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3704         echo '1:        jalr $25' >> conftest.s
3705         echo '  .end x' >> conftest.s
3706         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3707            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3708           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
3709              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
3710             gcc_cv_as_ld_jalr_reloc=yes
3711           fi
3712         fi
3713         rm -f conftest.*
3714       fi
3715     fi
3716     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3717       if test x$target_cpu_default = x; then
3718         target_cpu_default=MASK_RELAX_PIC_CALLS
3719       else
3720         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3721       fi
3722     fi
3723     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3724
3725     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3726       [gcc_cv_ld_mips_personality_relaxation],
3727       [gcc_cv_ld_mips_personality_relaxation=no
3728        if test $in_tree_ld = yes ; then
3729          if test "$gcc_cv_gld_major_version" -eq 2 \
3730                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3731                  -o "$gcc_cv_gld_major_version" -gt 2; then
3732            gcc_cv_ld_mips_personality_relaxation=yes
3733          fi
3734        elif test x$gcc_cv_as != x \
3735                  -a x$gcc_cv_ld != x \
3736                  -a x$gcc_cv_readelf != x ; then
3737          cat > conftest.s <<EOF
3738         .cfi_startproc
3739         .cfi_personality 0x80,indirect_ptr
3740         .ent test
3741 test:
3742         nop
3743         .end test
3744         .cfi_endproc
3745
3746         .section .data,"aw",@progbits
3747 indirect_ptr:
3748         .dc.a personality
3749 EOF
3750          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3751             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3752            if $gcc_cv_readelf -d conftest 2>&1 \
3753               | grep TEXTREL > /dev/null 2>&1; then
3754              :
3755            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3756                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3757              :
3758            else
3759              gcc_cv_ld_mips_personality_relaxation=yes
3760            fi
3761          fi
3762        fi
3763        rm -f conftest.s conftest.o conftest])
3764     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3765             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3766       [Define if your linker can relax absolute .eh_frame personality
3767 pointers into PC-relative form.])
3768     fi
3769     ;;
3770 esac
3771
3772 # Mips and HP-UX need the GNU assembler.
3773 # Linux on IA64 might be able to use the Intel assembler.
3774
3775 case "$target" in
3776   mips*-*-* | *-*-hpux* )
3777     if test x$gas_flag = xyes \
3778        || test x"$host" != x"$build" \
3779        || test ! -x "$gcc_cv_as" \
3780        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3781       :
3782     else
3783       echo "*** This configuration requires the GNU assembler" >&2
3784       exit 1
3785     fi
3786     ;;
3787 esac
3788
3789 # ??? Not all targets support dwarf2 debug_line, even within a version
3790 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3791 # info to the output file.  So, as supported targets are added to gas 2.11,
3792 # add some instruction here to (also) show we expect this might work.
3793 # ??? Once 2.11 is released, probably need to add first known working
3794 # version to the per-target configury.
3795 case "$cpu_type" in
3796   alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze | mips \
3797   | pa | rs6000 | score | sparc | spu | xstormy16 | xtensa)
3798     insn="nop"
3799     ;;
3800   ia64 | s390)
3801     insn="nop 0"
3802     ;;
3803   mmix)
3804     insn="swym 0"
3805     ;;
3806 esac
3807 if test x"$insn" != x; then
3808  conftest_s="\
3809         .file 1 \"conftest.s\"
3810         .loc 1 3 0
3811         $insn"
3812  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3813   gcc_cv_as_dwarf2_debug_line,
3814   [elf,2,11,0],, [$conftest_s],
3815   [if test x$gcc_cv_objdump != x \
3816    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3817       | grep debug_line > /dev/null 2>&1; then
3818      gcc_cv_as_dwarf2_debug_line=yes
3819    fi])
3820
3821 # The .debug_line file table must be in the exact order that
3822 # we specified the files, since these indices are also used
3823 # by DW_AT_decl_file.  Approximate this test by testing if
3824 # the assembler bitches if the same index is assigned twice.
3825  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3826   gcc_cv_as_dwarf2_file_buggy,,,
3827 [       .file 1 "foo.s"
3828         .file 1 "bar.s"])
3829
3830  if test $gcc_cv_as_dwarf2_debug_line = yes \
3831  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3832         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3833   [Define if your assembler supports dwarf2 .file/.loc directives,
3834    and preserves file table indices exactly as given.])
3835  fi
3836
3837  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3838   gcc_cv_as_gdwarf2_flag,
3839   [elf,2,11,0], [--gdwarf2], [$insn],,
3840   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3841 [Define if your assembler supports the --gdwarf2 option.])])
3842
3843  gcc_GAS_CHECK_FEATURE([--gstabs option],
3844   gcc_cv_as_gstabs_flag,
3845   [elf,2,11,0], [--gstabs], [$insn],
3846   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3847    # and warns about it, but still exits successfully.  So check for
3848    # this.
3849    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3850    then :
3851    else gcc_cv_as_gstabs_flag=yes
3852    fi],
3853   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3854 [Define if your assembler supports the --gstabs option.])])
3855
3856  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3857   gcc_cv_as_debug_prefix_map_flag,
3858   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3859   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3860 [Define if your assembler supports the --debug-prefix-map option.])])
3861 fi
3862
3863 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3864  ,,
3865 [.lcomm bar,4,16],,
3866 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3867   [Define if your assembler supports .lcomm with an alignment field.])])
3868
3869 AC_ARG_ENABLE(gnu-unique-object,
3870  [  --enable-gnu-unique-object  enable the use of the @gnu_unique_object ELF extension on
3871                                 glibc systems],
3872  [case $enable_gnu_unique_object in
3873     yes | no) ;;
3874     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
3875 Valid choices are 'yes' and 'no'.]) ;;
3876   esac],
3877  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
3878    [elf,2,19,52],,
3879    [.type foo, @gnu_unique_object],,
3880 # Also check for ld.so support, i.e. glibc 2.11 or higher.
3881    [[if test x$host = x$build -a x$host = x$target &&
3882        glibcver=`ldd --version 2>/dev/null | sed 's/.* //;q'`; then
3883       glibcmajor=`expr "$glibcver" : "\([0-9]*\)"`
3884       glibcminor=`expr "$glibcver" : "[2-9]*\.\([0-9]*\)"`
3885       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
3886       if test "$glibcnum" -ge 2011 ; then
3887         enable_gnu_unique_object=yes
3888       fi
3889     fi]])])
3890 if test x$enable_gnu_unique_object = xyes; then
3891   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
3892    [Define if your assembler supports @gnu_unique_object.])
3893 fi
3894
3895 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3896  [gcc_cv_as_line_zero],
3897  [gcc_cv_as_line_zero=no
3898   if test $in_tree_gas = yes; then
3899     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3900   elif test "x$gcc_cv_as" != x; then
3901     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3902     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3903        test "x`cat conftest.out`" = x
3904     then
3905       gcc_cv_as_line_zero=yes
3906     else
3907       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3908       cat conftest.s >&AS_MESSAGE_LOG_FD
3909       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3910       cat conftest.out >&AS_MESSAGE_LOG_FD
3911     fi
3912     rm -f conftest.o conftest.s conftest.out
3913   fi])
3914 if test "x$gcc_cv_as_line_zero" = xyes; then
3915   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3916 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3917 fi
3918
3919 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3920 gcc_cv_ld_eh_frame_hdr=no
3921 if test $in_tree_ld = yes ; then
3922   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3923      && test $in_tree_ld_is_elf = yes; then
3924     gcc_cv_ld_eh_frame_hdr=yes
3925   fi
3926 elif test x$gcc_cv_ld != x; then
3927         # Check if linker supports --eh-frame-hdr option
3928         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3929                 gcc_cv_ld_eh_frame_hdr=yes
3930         fi
3931 fi
3932 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3933 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3934         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3935 [Define if your linker supports --eh-frame-hdr option.])
3936 fi
3937 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3938
3939 AC_MSG_CHECKING(linker position independent executable support)
3940 gcc_cv_ld_pie=no
3941 if test $in_tree_ld = yes ; then
3942   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3943      && test $in_tree_ld_is_elf = yes; then
3944     gcc_cv_ld_pie=yes
3945   fi
3946 elif test x$gcc_cv_ld != x; then
3947         # Check if linker supports -pie option
3948         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3949                 gcc_cv_ld_pie=yes
3950         fi
3951 fi
3952 if test x"$gcc_cv_ld_pie" = xyes; then
3953         AC_DEFINE(HAVE_LD_PIE, 1,
3954 [Define if your linker supports -pie option.])
3955 fi
3956 AC_MSG_RESULT($gcc_cv_ld_pie)
3957
3958 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3959 gcc_cv_ld_eh_gc_sections=no
3960 if test $in_tree_ld = yes ; then
3961   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3962      && test $in_tree_ld_is_elf = yes; then
3963     gcc_cv_ld_eh_gc_sections=yes
3964   fi
3965 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3966   cat > conftest.s <<EOF
3967         .section        .text
3968 .globl _start
3969         .type _start, @function
3970 _start:
3971         .long foo
3972         .size _start, .-_start
3973         .section        .text.foo,"ax",@progbits
3974         .type foo, @function
3975 foo:
3976         .long 0
3977         .size foo, .-foo
3978         .section        .gcc_except_table.foo,"a",@progbits
3979 .L0:
3980         .long 0
3981         .section        .eh_frame,"a",@progbits
3982         .long .L0
3983 EOF
3984   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3985     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3986          | grep "gc-sections option ignored" > /dev/null; then
3987       gcc_cv_ld_eh_gc_sections=no
3988     elif $gcc_cv_objdump -h conftest 2> /dev/null \
3989          | grep gcc_except_table > /dev/null; then
3990       gcc_cv_ld_eh_gc_sections=yes
3991       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3992       if test x$gcc_cv_as_comdat_group != xyes; then
3993         gcc_cv_ld_eh_gc_sections=no
3994         cat > conftest.s <<EOF
3995         .section        .text
3996 .globl _start
3997         .type _start, @function
3998 _start:
3999         .long foo
4000         .size _start, .-_start
4001         .section        .gnu.linkonce.t.foo,"ax",@progbits
4002         .type foo, @function
4003 foo:
4004         .long 0
4005         .size foo, .-foo
4006         .section        .gcc_except_table.foo,"a",@progbits
4007 .L0:
4008         .long 0
4009         .section        .eh_frame,"a",@progbits
4010         .long .L0
4011 EOF
4012         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4013           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4014                | grep "gc-sections option ignored" > /dev/null; then
4015             gcc_cv_ld_eh_gc_sections=no
4016           elif $gcc_cv_objdump -h conftest 2> /dev/null \
4017                | grep gcc_except_table > /dev/null; then
4018             gcc_cv_ld_eh_gc_sections=yes
4019           fi
4020         fi
4021       fi
4022     fi
4023   fi
4024   rm -f conftest.s conftest.o conftest
4025 fi
4026 case "$target" in
4027   hppa*-*-linux*)
4028     # ??? This apparently exposes a binutils bug with PC-relative relocations.
4029     gcc_cv_ld_eh_gc_sections=no
4030     ;;
4031 esac
4032 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
4033         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
4034   [Define if your linker supports garbage collection of
4035    sections in presence of EH frames.])
4036 fi
4037 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
4038
4039 # --------
4040 # UNSORTED
4041 # --------
4042
4043 AC_CACHE_CHECK(linker --as-needed support,
4044 gcc_cv_ld_as_needed,
4045 [gcc_cv_ld_as_needed=no
4046 if test $in_tree_ld = yes ; then
4047   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4048      && test $in_tree_ld_is_elf = yes; then
4049     gcc_cv_ld_as_needed=yes
4050   fi
4051 elif test x$gcc_cv_ld != x; then
4052         # Check if linker supports --as-needed and --no-as-needed options
4053         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
4054                 gcc_cv_ld_as_needed=yes
4055         fi
4056 fi
4057 ])
4058 if test x"$gcc_cv_ld_as_needed" = xyes; then
4059         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
4060 [Define if your linker supports --as-needed and --no-as-needed options.])
4061 fi
4062
4063 case "$target:$tm_file" in
4064   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
4065     AC_CACHE_CHECK(linker support for omitting dot symbols,
4066     gcc_cv_ld_no_dot_syms,
4067     [gcc_cv_ld_no_dot_syms=no
4068     if test $in_tree_ld = yes ; then
4069       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
4070         gcc_cv_ld_no_dot_syms=yes
4071       fi
4072     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4073       cat > conftest1.s <<EOF
4074         .text
4075         bl .foo
4076 EOF
4077       cat > conftest2.s <<EOF
4078         .section ".opd","aw"
4079         .align 3
4080         .globl foo
4081         .type foo,@function
4082 foo:
4083         .quad .LEfoo,.TOC.@tocbase,0
4084         .text
4085 .LEfoo:
4086         blr
4087         .size foo,.-.LEfoo
4088 EOF
4089       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
4090          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
4091          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
4092         gcc_cv_ld_no_dot_syms=yes
4093       fi
4094       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
4095     fi
4096     ])
4097     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
4098       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
4099     [Define if your PowerPC64 linker only needs function descriptor syms.])
4100     fi
4101
4102     AC_CACHE_CHECK(linker large toc support,
4103     gcc_cv_ld_large_toc,
4104     [gcc_cv_ld_large_toc=no
4105     if test $in_tree_ld = yes ; then
4106       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
4107         gcc_cv_ld_large_toc=yes
4108       fi
4109     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4110       cat > conftest.s <<EOF
4111         .section ".tbss","awT",@nobits
4112         .align 3
4113 ie0:    .space 8
4114         .global _start
4115         .text
4116 _start:
4117         addis 9,13,ie0@got@tprel@ha
4118         ld 9,ie0@got@tprel@l(9)
4119 EOF
4120       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
4121          && $gcc_cv_ld -melf64ppc --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
4122         gcc_cv_ld_large_toc=yes
4123       fi
4124       rm -f conftest conftest.o conftest.s
4125     fi
4126     ])
4127     if test x"$gcc_cv_ld_large_toc" = xyes; then
4128       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
4129     [Define if your PowerPC64 linker supports a large TOC.])
4130     fi
4131     ;;
4132 esac
4133
4134 AC_CACHE_CHECK(linker --build-id support,
4135   gcc_cv_ld_buildid,
4136   [gcc_cv_ld_buildid=no
4137   if test $in_tree_ld = yes ; then
4138     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4139        "$gcc_cv_gld_minor_version" -ge 18 -o \
4140        "$gcc_cv_gld_major_version" -gt 2 \
4141        && test $in_tree_ld_is_elf = yes; then
4142       gcc_cv_ld_buildid=yes
4143     fi
4144   elif test x$gcc_cv_ld != x; then
4145     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
4146       gcc_cv_ld_buildid=yes
4147     fi
4148   fi])
4149 if test x"$gcc_cv_ld_buildid" = xyes; then
4150   AC_DEFINE(HAVE_LD_BUILDID, 1,
4151   [Define if your linker supports --build-id.])
4152 fi
4153
4154 AC_ARG_ENABLE(linker-build-id,
4155 [  --enable-linker-build-id
4156                           compiler will always pass --build-id to linker],
4157 [],
4158 enable_linker_build_id=no)
4159
4160 if test x"$enable_linker_build_id" = xyes; then
4161   if test x"$gcc_cv_ld_buildid" = xyes; then
4162     AC_DEFINE(ENABLE_LD_BUILDID, 1,
4163     [Define if gcc should always pass --build-id to linker.])
4164   else
4165     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
4166   fi
4167 fi
4168
4169 # In binutils 2.21, GNU ld gained support for new emulations fully
4170 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
4171 AC_CACHE_CHECK(linker *_sol2 emulation support,
4172   gcc_cv_ld_sol2_emulation,
4173   [gcc_cv_ld_sol2_emulation=no
4174   if test $in_tree_ld = yes ; then
4175     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4176        "$gcc_cv_gld_minor_version" -ge 21 -o \
4177        "$gcc_cv_gld_major_version" -gt 2 \
4178        && test $in_tree_ld_is_elf = yes; then
4179       gcc_cv_ld_sol2_emulation=yes
4180     fi
4181   elif test x$gcc_cv_ld != x; then
4182     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
4183        grep _sol2 > /dev/null; then
4184       gcc_cv_ld_sol2_emulation=yes
4185     fi
4186   fi])
4187 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
4188   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
4189   [Define if your linker supports the *_sol2 emulations.])
4190 fi
4191
4192 AC_CACHE_CHECK(linker --sysroot support,
4193   gcc_cv_ld_sysroot,
4194   [gcc_cv_ld_sysroot=no
4195   if test $in_tree_ld = yes ; then
4196       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
4197         gcc_cv_ld_sysroot=yes
4198       fi
4199   elif test x$gcc_cv_ld != x; then
4200     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
4201       gcc_cv_ld_sysroot=yes
4202     fi
4203   fi])
4204 if test x"$gcc_cv_ld_sysroot" = xyes; then
4205   AC_DEFINE(HAVE_LD_SYSROOT, 1,
4206   [Define if your linker supports --sysroot.])
4207 fi
4208
4209 if test x$with_sysroot = x && test x$host = x$target \
4210    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4211    && test "$prefix" != "NONE"; then
4212   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4213 [Define to PREFIX/include if cpp should also search that directory.])
4214 fi
4215
4216 # Test for stack protector support in target C library.
4217 AC_CACHE_CHECK(__stack_chk_fail in target C library,
4218       gcc_cv_libc_provides_ssp,
4219       [gcc_cv_libc_provides_ssp=no
4220     case "$target" in
4221        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
4222       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4223         if test "x$with_headers" != x; then
4224           glibc_header_dir=$with_headers
4225         elif test "x$with_sysroot" = x; then
4226           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4227         elif test "x$with_build_sysroot" != "x"; then
4228           glibc_header_dir="${with_build_sysroot}/usr/include"
4229         elif test "x$with_sysroot" = xyes; then
4230           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
4231         else
4232           glibc_header_dir="${with_sysroot}/usr/include"
4233         fi
4234       else
4235         glibc_header_dir=/usr/include
4236       fi
4237       [# glibc 2.4 and later provides __stack_chk_fail and
4238       # either __stack_chk_guard, or TLS access to stack guard canary.
4239       if test -f $glibc_header_dir/features.h \
4240          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
4241             $glibc_header_dir/features.h > /dev/null; then
4242         if $EGREP '^[   ]*#[    ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
4243            $glibc_header_dir/features.h > /dev/null; then
4244           gcc_cv_libc_provides_ssp=yes
4245         elif $EGREP '^[         ]*#[    ]*define[       ]+__GLIBC__[    ]+2' \
4246              $glibc_header_dir/features.h > /dev/null \
4247              && $EGREP '^[      ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
4248              $glibc_header_dir/features.h > /dev/null; then
4249           gcc_cv_libc_provides_ssp=yes
4250         elif $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
4251              $glibc_header_dir/features.h > /dev/null && \
4252              test -f $glibc_header_dir/bits/uClibc_config.h && \
4253              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
4254              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
4255           gcc_cv_libc_provides_ssp=yes
4256         fi
4257       fi]
4258         ;;
4259        *-*-gnu*)
4260          # Avoid complicated tests (see
4261          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
4262          # simply assert that glibc does provide this, which is true for all
4263          # realistically usable GNU/Hurd configurations.
4264          gcc_cv_libc_provides_ssp=yes;;
4265        *-*-darwin* | *-*-freebsd*)
4266          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
4267            [echo "no __stack_chk_fail on this target"])
4268         ;;
4269   *) gcc_cv_libc_provides_ssp=no ;;
4270     esac])
4271
4272 if test x$gcc_cv_libc_provides_ssp = xyes; then
4273   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
4274             [Define if your target C library provides stack protector support])
4275 fi
4276
4277 # Check if TFmode long double should be used by default or not.
4278 # Some glibc targets used DFmode long double, but with glibc 2.4
4279 # and later they can use TFmode.
4280 case "$target" in
4281   powerpc*-*-linux* | \
4282   powerpc*-*-gnu* | \
4283   sparc*-*-linux* | \
4284   s390*-*-linux* | \
4285   alpha*-*-linux*)
4286     AC_ARG_WITH(long-double-128,
4287 [  --with-long-double-128  Use 128-bit long double by default.],
4288       gcc_cv_target_ldbl128="$with_long_double_128",
4289       [[gcc_cv_target_ldbl128=no
4290       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4291         if test "x$with_sysroot" = x; then
4292           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4293         elif test "x$with_build_sysroot" != "x"; then
4294           glibc_header_dir="${with_build_sysroot}/usr/include"
4295         elif test "x$with_sysroot" = xyes; then
4296           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
4297         else
4298           glibc_header_dir="${with_sysroot}/usr/include"
4299         fi
4300       else
4301         glibc_header_dir=/usr/include
4302       fi
4303       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
4304         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
4305       && gcc_cv_target_ldbl128=yes
4306       ]])
4307     ;;
4308 esac
4309 if test x$gcc_cv_target_ldbl128 = xyes; then
4310   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
4311             [Define if TFmode long double should be the default])
4312 fi
4313
4314 # Find out what GC implementation we want, or may, use.
4315 AC_ARG_WITH(gc,
4316 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
4317                           with the compiler],
4318 [case "$withval" in
4319   page)
4320     GGC=ggc-$withval
4321     ;;
4322   zone)
4323     GGC=ggc-$withval
4324     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
4325     ;;
4326   *)
4327     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
4328     ;;
4329 esac],
4330 [GGC=ggc-page])
4331 AC_SUBST(GGC)
4332 echo "Using $GGC for garbage collection."
4333
4334 # Libraries to use on the host.  This will normally be set by the top
4335 # level Makefile.  Here we simply capture the value for our Makefile.
4336 if test -z "${HOST_LIBS+set}"; then
4337   HOST_LIBS=
4338 fi
4339 AC_SUBST(HOST_LIBS)
4340
4341 # Use the system's zlib library.
4342 zlibdir=-L../zlib
4343 zlibinc="-I\$(srcdir)/../zlib"
4344 AC_ARG_WITH(system-zlib,
4345 [  --with-system-zlib      use installed libz],
4346 zlibdir=
4347 zlibinc=
4348 )
4349 AC_SUBST(zlibdir)
4350 AC_SUBST(zlibinc)
4351
4352 dnl Very limited version of automake's enable-maintainer-mode
4353
4354 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
4355   dnl maintainer-mode is disabled by default
4356   AC_ARG_ENABLE(maintainer-mode,
4357 [  --enable-maintainer-mode
4358                           enable make rules and dependencies not useful
4359                           (and sometimes confusing) to the casual installer],
4360       maintainer_mode=$enableval,
4361       maintainer_mode=no)
4362
4363 AC_MSG_RESULT($maintainer_mode)
4364
4365 if test "$maintainer_mode" = "yes"; then
4366   MAINT=''
4367 else
4368   MAINT='#'
4369 fi
4370 AC_SUBST(MAINT)dnl
4371
4372 # --------------
4373 # Language hooks
4374 # --------------
4375
4376 # Make empty files to contain the specs and options for each language.
4377 # Then add #include lines to for a compiler that has specs and/or options.
4378
4379 subdirs=
4380 lang_opt_files=
4381 lang_specs_files=
4382 lang_tree_files=
4383 # These (without "all_") are set in each config-lang.in.
4384 # `language' must be a single word so is spelled singularly.
4385 all_languages=
4386 all_compilers=
4387 all_outputs='Makefile'
4388 # List of language makefile fragments.
4389 all_lang_makefrags=
4390 # Additional files for gengtype
4391 all_gtfiles="$target_gtfiles"
4392
4393 # These are the languages that are set in --enable-languages,
4394 # and are available in the GCC tree.
4395 all_selected_languages=
4396
4397 # Add the language fragments.
4398 # Languages are added via two mechanisms.  Some information must be
4399 # recorded in makefile variables, these are defined in config-lang.in.
4400 # We accumulate them and plug them into the main Makefile.
4401 # The other mechanism is a set of hooks for each of the main targets
4402 # like `clean', `install', etc.
4403
4404 language_hooks="Make-hooks"
4405
4406 for lang in ${srcdir}/*/config-lang.in
4407 do
4408 changequote(,)dnl
4409         test "$lang" = "${srcdir}/*/config-lang.in" && continue
4410
4411         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
4412         if test "x$lang_alias" = x
4413         then
4414               echo "$lang doesn't set \$language." 1>&2
4415               exit 1
4416         fi
4417         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
4418         subdirs="$subdirs $subdir"
4419
4420         # $gcc_subdir is where the gcc integration files are to be found
4421         # for a language, both for internal compiler purposes (compiler
4422         # sources implementing front-end to GCC tree converters), and for
4423         # build infrastructure purposes (Make-lang.in, etc.)
4424         #
4425         # This will be <subdir> (relative to $srcdir) if a line like
4426         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
4427         # is found in <langdir>/config-lang.in, and will remain <langdir>
4428         # otherwise.
4429         #
4430         # Except for the language alias (fetched above), the regular
4431         # "config-lang.in" contents are always retrieved from $gcc_subdir,
4432         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
4433         # only this and the language alias.
4434
4435         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
4436         if [ "$gcc_subdir" = "" ]; then
4437            gcc_subdir="$subdir"
4438         fi
4439
4440         case ",$enable_languages," in
4441         *,$lang_alias,*)
4442             all_selected_languages="$all_selected_languages $lang_alias"
4443             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
4444                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
4445             fi
4446             ;;
4447         esac
4448 changequote([,])dnl
4449
4450         language=
4451         boot_language=
4452         compilers=
4453         outputs=
4454         gtfiles=
4455         subdir_requires=
4456         . ${srcdir}/$gcc_subdir/config-lang.in
4457         if test "x$language" = x
4458         then
4459                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
4460                 exit 1
4461         fi
4462
4463         ok=:
4464         case ",$enable_languages," in
4465                 *,$lang_alias,*) ;;
4466                 *)
4467                         for i in $subdir_requires; do
4468                                 test -f "${srcdir}/$i/config-lang.in" && continue
4469                                 ok=false
4470                                 break
4471                         done
4472                 ;;
4473         esac
4474         $ok || continue
4475
4476         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
4477         if test -f $srcdir/$gcc_subdir/lang.opt; then
4478             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
4479             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
4480         fi
4481         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
4482             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
4483         fi
4484         all_languages="$all_languages $language"
4485         all_compilers="$all_compilers $compilers"
4486         all_outputs="$all_outputs $outputs"
4487         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
4488         case ",$enable_languages," in
4489                 *,lto,*)
4490                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
4491                     enable_lto=yes
4492                     AC_SUBST(enable_lto)
4493                     ;;
4494                 *) ;;
4495         esac
4496 done
4497
4498 # Pick up gtfiles for c
4499 gtfiles=
4500 . ${srcdir}/c-config-lang.in
4501 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
4502
4503 check_languages=
4504 for language in $all_selected_languages
4505 do
4506         check_languages="$check_languages check-$language"
4507 done
4508
4509 # We link each language in with a set of hooks, reached indirectly via
4510 # lang.${target}.  Only do so for selected languages.
4511
4512 rm -f Make-hooks
4513 touch Make-hooks
4514 target_list="all.cross start.encap rest.encap tags \
4515         install-common install-man install-info install-pdf install-html dvi \
4516         pdf html uninstall info man srcextra srcman srcinfo \
4517         mostlyclean clean distclean maintainer-clean install-plugin"
4518
4519 for t in $target_list
4520 do
4521         x=
4522         for lang in $all_selected_languages
4523         do
4524                 x="$x $lang.$t"
4525         done
4526         echo "lang.$t: $x" >> Make-hooks
4527 done
4528
4529 # --------
4530 # Option include files
4531 # --------
4532
4533 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
4534 option_includes="option-includes.mk"
4535 AC_SUBST_FILE(option_includes)
4536
4537 # --------
4538 # UNSORTED
4539 # --------
4540
4541 # Create .gdbinit.
4542
4543 echo "dir ." > .gdbinit
4544 echo "dir ${srcdir}" >> .gdbinit
4545 if test x$gdb_needs_out_file_path = xyes
4546 then
4547         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
4548 fi
4549 if test "x$subdirs" != x; then
4550         for s in $subdirs
4551         do
4552                 echo "dir ${srcdir}/$s" >> .gdbinit
4553         done
4554 fi
4555 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
4556
4557 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
4558 AC_SUBST(gcc_tooldir)
4559 AC_SUBST(dollar)
4560
4561 # Find a directory in which to install a shared libgcc.
4562
4563 AC_ARG_ENABLE(version-specific-runtime-libs,
4564 [  --enable-version-specific-runtime-libs
4565                           specify that runtime libraries should be
4566                           installed in a compiler-specific directory])
4567
4568 AC_ARG_WITH(slibdir,
4569 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
4570 slibdir="$with_slibdir",
4571 if test "${enable_version_specific_runtime_libs+set}" = set; then
4572   slibdir='$(libsubdir)'
4573 elif test "$host" != "$target"; then
4574   slibdir='$(build_tooldir)/lib'
4575 else
4576   slibdir='$(libdir)'
4577 fi)
4578 AC_SUBST(slibdir)
4579
4580 # Substitute configuration variables
4581 AC_SUBST(subdirs)
4582 AC_SUBST(srcdir)
4583 AC_SUBST(all_compilers)
4584 AC_SUBST(all_gtfiles)
4585 AC_SUBST(all_lang_makefrags)
4586 AC_SUBST(all_languages)
4587 AC_SUBST(all_selected_languages)
4588 AC_SUBST(build_exeext)
4589 AC_SUBST(build_install_headers_dir)
4590 AC_SUBST(build_xm_file_list)
4591 AC_SUBST(build_xm_include_list)
4592 AC_SUBST(build_xm_defines)
4593 AC_SUBST(build_file_translate)
4594 AC_SUBST(check_languages)
4595 AC_SUBST(cpp_install_dir)
4596 AC_SUBST(xmake_file)
4597 AC_SUBST(tmake_file)
4598 AC_SUBST(TM_ENDIAN_CONFIG)
4599 AC_SUBST(TM_MULTILIB_CONFIG)
4600 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
4601 AC_SUBST(extra_gcc_objs)
4602 AC_SUBST(user_headers_inc_next_pre)
4603 AC_SUBST(user_headers_inc_next_post)
4604 AC_SUBST(extra_headers_list)
4605 AC_SUBST(extra_objs)
4606 AC_SUBST(extra_parts)
4607 AC_SUBST(extra_passes)
4608 AC_SUBST(extra_programs)
4609 AC_SUBST(float_h_file)
4610 AC_SUBST(gcc_config_arguments)
4611 AC_SUBST(gcc_gxx_include_dir)
4612 AC_SUBST(host_exeext)
4613 AC_SUBST(host_xm_file_list)
4614 AC_SUBST(host_xm_include_list)
4615 AC_SUBST(host_xm_defines)
4616 AC_SUBST(out_host_hook_obj)
4617 AC_SUBST(install)
4618 AC_SUBST(lang_opt_files)
4619 AC_SUBST(lang_specs_files)
4620 AC_SUBST(lang_tree_files)
4621 AC_SUBST(local_prefix)
4622 AC_SUBST(md_file)
4623 AC_SUBST(objc_boehm_gc)
4624 AC_SUBST(out_file)
4625 AC_SUBST(out_object_file)
4626 AC_SUBST(thread_file)
4627 AC_SUBST(tm_file_list)
4628 AC_SUBST(tm_include_list)
4629 AC_SUBST(tm_defines)
4630 AC_SUBST(tm_p_file_list)
4631 AC_SUBST(tm_p_include_list)
4632 AC_SUBST(xm_file_list)
4633 AC_SUBST(xm_include_list)
4634 AC_SUBST(xm_defines)
4635 AC_SUBST(use_gcc_stdint)
4636 AC_SUBST(c_target_objs)
4637 AC_SUBST(cxx_target_objs)
4638 AC_SUBST(fortran_target_objs)
4639 AC_SUBST(target_cpu_default)
4640
4641 AC_SUBST_FILE(language_hooks)
4642
4643 # Echo link setup.
4644 if test x${build} = x${host} ; then
4645   if test x${host} = x${target} ; then
4646     echo "Links are now set up to build a native compiler for ${target}." 1>&2
4647   else
4648     echo "Links are now set up to build a cross-compiler" 1>&2
4649     echo " from ${host} to ${target}." 1>&2
4650   fi
4651 else
4652   if test x${host} = x${target} ; then
4653     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
4654     echo " for ${target}." 1>&2
4655   else
4656     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
4657     echo " from ${host} to ${target}." 1>&2
4658   fi
4659 fi
4660
4661 AC_ARG_VAR(GMPLIBS,[How to link GMP])
4662 AC_ARG_VAR(GMPINC,[How to find GMP include files])
4663
4664 AC_ARG_VAR(PPLLIBS,[How to link PPL])
4665 AC_ARG_VAR(PPLINC,[How to find PPL include files])
4666
4667 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
4668 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
4669 if test "x${CLOOGLIBS}" != "x" ; then
4670    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
4671 fi
4672
4673 # Check for plugin support
4674 AC_ARG_ENABLE(plugin,
4675 [  --enable-plugin         enable plugin support],
4676 enable_plugin=$enableval,
4677 enable_plugin=yes; default_plugin=yes)
4678
4679 pluginlibs=
4680
4681 case "${host}" in
4682   *-*-darwin*)
4683     if test x$build = x$host; then
4684       export_sym_check="nm${exeext} -g"
4685     elif test x$host = x$target; then
4686       export_sym_check="$gcc_cv_nm -g"
4687     else
4688       export_sym_check=
4689     fi
4690   ;;
4691   *)
4692     if test x$build = x$host; then
4693       export_sym_check="objdump${exeext} -T"
4694     elif test x$host = x$target; then
4695       export_sym_check="$gcc_cv_objdump -T"
4696     else
4697       export_sym_check=
4698     fi
4699   ;;
4700 esac
4701
4702 if test x"$enable_plugin" = x"yes"; then
4703
4704   AC_MSG_CHECKING([for exported symbols])
4705   if test "x$export_sym_check" != x; then
4706     echo "int main() {return 0;} int foobar() {return 0;}" > conftest.c
4707     ${CC} ${CFLAGS} ${LDFLAGS} conftest.c -o conftest > /dev/null 2>&1
4708     if $export_sym_check conftest | grep foobar > /dev/null; then
4709       : # No need to use a flag
4710       AC_MSG_RESULT([yes])
4711     else
4712       AC_MSG_RESULT([yes])
4713       AC_MSG_CHECKING([for -rdynamic])
4714       ${CC} ${CFLAGS} ${LDFLAGS} -rdynamic conftest.c -o conftest > /dev/null 2>&1
4715       if $export_sym_check conftest | grep foobar > /dev/null; then
4716         plugin_rdynamic=yes
4717         pluginlibs="-rdynamic"
4718       else
4719         plugin_rdynamic=no
4720         enable_plugin=no
4721       fi
4722       AC_MSG_RESULT([$plugin_rdynamic])
4723     fi
4724   else
4725     AC_MSG_RESULT([unable to check])
4726   fi
4727
4728   # Check -ldl
4729   saved_LIBS="$LIBS"
4730   AC_SEARCH_LIBS([dlopen], [dl])
4731   if test x"$ac_cv_search_dlopen" = x"-ldl"; then
4732     pluginlibs="$pluginlibs -ldl"
4733   fi
4734   LIBS="$saved_LIBS"
4735
4736   # Check that we can build shared objects with -fPIC -shared
4737   saved_LDFLAGS="$LDFLAGS"
4738   saved_CFLAGS="$CFLAGS"
4739   case "${host}" in
4740     *-*-darwin*)
4741       CFLAGS=`echo $CFLAGS | sed s/-mdynamic-no-pic//g`
4742       CFLAGS="$CFLAGS -fPIC"
4743       LDFLAGS="$LDFLAGS -shared -undefined dynamic_lookup"
4744     ;;
4745     *)
4746       CFLAGS="$CFLAGS -fPIC"
4747       LDFLAGS="$LDFLAGS -fPIC -shared"
4748     ;;
4749   esac
4750   AC_MSG_CHECKING([for -fPIC -shared])
4751   AC_TRY_LINK(
4752     [extern int X;],[return X == 0;],
4753     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
4754     [AC_MSG_RESULT([no]); have_pic_shared=no])
4755   if test x"$have_pic_shared" != x"yes" -o x"$ac_cv_search_dlopen" = x"no"; then
4756     pluginlibs=
4757     enable_plugin=no
4758   fi
4759   LDFLAGS="$saved_LDFLAGS"
4760   CFLAGS="$saved_CFLAGS"
4761
4762   # If plugin support had been requested but not available, fail.
4763   if test x"$enable_plugin" = x"no" ; then
4764     if test x"$default_plugin" != x"yes"; then
4765       AC_MSG_ERROR([
4766 Building GCC with plugin support requires a host that supports
4767 -fPIC, -shared, -ldl and -rdynamic.])
4768     fi
4769   fi
4770 fi
4771
4772 AC_SUBST(pluginlibs)
4773 AC_SUBST(enable_plugin)
4774 if test x"$enable_plugin" = x"yes"; then
4775   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
4776 fi
4777
4778 # Configure the subdirectories
4779 # AC_CONFIG_SUBDIRS($subdirs)
4780
4781 # Create the Makefile
4782 # and configure language subdirectories
4783 AC_CONFIG_FILES($all_outputs)
4784
4785 AC_CONFIG_COMMANDS([default],
4786 [
4787 case ${CONFIG_HEADERS} in
4788   *auto-host.h:config.in*)
4789   echo > cstamp-h ;;
4790 esac
4791 # Make sure all the subdirs exist.
4792 for d in $subdirs doc build c-family
4793 do
4794     test -d $d || mkdir $d
4795 done
4796 ],
4797 [subdirs='$subdirs'])
4798 AC_OUTPUT
4799