gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  22 #02110-1301, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 gcc_version=`cat $srcdir/BASE-VER`
  34
  35 # Determine the host, build, and target systems
  36 AC_CANONICAL_BUILD
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Determine the target- and build-specific subdirectories
  44 GCC_TOPLEV_SUBDIRS
  45
  46 # Set program_transform_name
  47 AC_ARG_PROGRAM
  48
  49 # Check for bogus environment variables.
  50 # Test if LIBRARY_PATH contains the notation for the current directory
  51 # since this would lead to problems installing/building glibc.
  52 # LIBRARY_PATH contains the current directory if one of the following
  53 # is true:
  54 # - one of the terminals (":" and ";") is the first or last sign
  55 # - two terminals occur directly after each other
  56 # - the path contains an element with a dot in it
  57 AC_MSG_CHECKING(LIBRARY_PATH variable)
  58 changequote(,)dnl
  59 case ${LIBRARY_PATH} in
  60   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  61     library_path_setting="contains current directory"
  62     ;;
  63   *)
  64     library_path_setting="ok"
  65     ;;
  66 esac
  67 changequote([,])dnl
  68 AC_MSG_RESULT($library_path_setting)
  69 if test "$library_path_setting" != "ok"; then
  70 AC_MSG_ERROR([
  71 *** LIBRARY_PATH shouldn't contain the current directory when
  72 *** building gcc. Please change the environment variable
  73 *** and run configure again.])
  74 fi
  75
  76 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  77 # since this would lead to problems installing/building glibc.
  78 # GCC_EXEC_PREFIX contains the current directory if one of the following
  79 # is true:
  80 # - one of the terminals (":" and ";") is the first or last sign
  81 # - two terminals occur directly after each other
  82 # - the path contains an element with a dot in it
  83 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  84 changequote(,)dnl
  85 case ${GCC_EXEC_PREFIX} in
  86   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  87     gcc_exec_prefix_setting="contains current directory"
  88     ;;
  89   *)
  90     gcc_exec_prefix_setting="ok"
  91     ;;
  92 esac
  93 changequote([,])dnl
  94 AC_MSG_RESULT($gcc_exec_prefix_setting)
  95 if test "$gcc_exec_prefix_setting" != "ok"; then
  96 AC_MSG_ERROR([
  97 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  98 *** building gcc. Please change the environment variable
  99 *** and run configure again.])
 100 fi
 101
 102 # -----------
 103 # Directories
 104 # -----------
 105
 106 # Specify the local prefix
 107 local_prefix=
 108 AC_ARG_WITH(local-prefix,
 109 [  --with-local-prefix=DIR specifies directory to put local include],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [  --with-gxx-include-dir=DIR
 128                           specifies directory to put g++ header files],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='c++/$(version)'
 140 changequote(<<, >>)dnl
 141     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 142 changequote([, ])dnl
 143   fi
 144 fi
 145
 146 AC_ARG_WITH(cpp_install_dir,
 147 [  --with-cpp-install-dir=DIR
 148                           install the user visible C preprocessor in DIR
 149                           (relative to PREFIX) as well as PREFIX/bin],
 150 [if test x$withval = xyes; then
 151   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 152 elif test x$withval != xno; then
 153   cpp_install_dir=$withval
 154 fi])
 155
 156 # We would like to our source tree to be readonly.  However when releases or
 157 # pre-releases are generated, the flex/bison generated files as well as the
 158 # various formats of manuals need to be included along with the rest of the
 159 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 160 # just that.
 161
 162 AC_MSG_CHECKING([whether to place generated files in the source directory])
 163   dnl generated-files-in-srcdir is disabled by default
 164   AC_ARG_ENABLE(generated-files-in-srcdir,
 165 [  --enable-generated-files-in-srcdir
 166                           put copies of generated files in source dir
 167                           intended for creating source tarballs for users
 168                           without texinfo bison or flex.],
 169       generated_files_in_srcdir=$enableval,
 170       generated_files_in_srcdir=no)
 171
 172 AC_MSG_RESULT($generated_files_in_srcdir)
 173
 174 if test "$generated_files_in_srcdir" = "yes"; then
 175   GENINSRC=''
 176 else
 177   GENINSRC='#'
 178 fi
 179 AC_SUBST(GENINSRC)
 180
 181 # -------------------
 182 # Find default linker
 183 # -------------------
 184
 185 # With GNU ld
 186 AC_ARG_WITH(gnu-ld,
 187 [  --with-gnu-ld           arrange to work with GNU ld.],
 188 gnu_ld_flag="$with_gnu_ld",
 189 gnu_ld_flag=no)
 190
 191 # With pre-defined ld
 192 AC_ARG_WITH(ld,
 193 [  --with-ld               arrange to use the specified ld (full pathname)],
 194 DEFAULT_LINKER="$with_ld")
 195 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 196   if test ! -x "$DEFAULT_LINKER"; then
 197     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 198   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 199     gnu_ld_flag=yes
 200   fi
 201   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 202         [Define to enable the use of a default linker.])
 203 fi
 204
 205 AC_MSG_CHECKING([whether a default linker was specified])
 206 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 207   if test x"$gnu_ld_flag" = x"no"; then
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 209   else
 210     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 211   fi
 212 else
 213   AC_MSG_RESULT(no)
 214 fi
 215
 216 # With demangler in GNU ld
 217 AC_ARG_WITH(demangler-in-ld,
 218 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 219 demangler_in_ld="$with_demangler_in_ld",
 220 demangler_in_ld=no)
 221
 222 # ----------------------
 223 # Find default assembler
 224 # ----------------------
 225
 226 # With GNU as
 227 AC_ARG_WITH(gnu-as,
 228 [  --with-gnu-as           arrange to work with GNU as],
 229 gas_flag="$with_gnu_as",
 230 gas_flag=no)
 231
 232 AC_ARG_WITH(as,
 233 [  --with-as               arrange to use the specified as (full pathname)],
 234 DEFAULT_ASSEMBLER="$with_as")
 235 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 236   if test ! -x "$DEFAULT_ASSEMBLER"; then
 237     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 238   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 239     gas_flag=yes
 240   fi
 241   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 242         [Define to enable the use of a default assembler.])
 243 fi
 244
 245 AC_MSG_CHECKING([whether a default assembler was specified])
 246 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 247   if test x"$gas_flag" = x"no"; then
 248     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 249   else
 250     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 251   fi
 252 else
 253   AC_MSG_RESULT(no)
 254 fi
 255
 256 # ---------------
 257 # Find C compiler
 258 # ---------------
 259
 260 # If a non-executable a.out is present (e.g. created by GNU as above even if
 261 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 262 # file, even when creating an executable, so an execution test fails.
 263 # Remove possible default executable files to avoid this.
 264 #
 265 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 266 # Autoconf includes it.
 267 rm -f a.out a.exe b.out
 268
 269 # Find the native compiler
 270 AC_PROG_CC
 271 AM_PROG_CC_C_O
 272 # autoconf is lame and doesn't give us any substitution variable for this.
 273 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 274   NO_MINUS_C_MINUS_O=yes
 275 else
 276   OUTPUT_OPTION='-o $@'
 277 fi
 278 AC_SUBST(NO_MINUS_C_MINUS_O)
 279 AC_SUBST(OUTPUT_OPTION)
 280
 281 # -------------------------
 282 # Check C compiler features
 283 # -------------------------
 284
 285 AC_PROG_CPP
 286 AC_C_INLINE
 287
 288 # sizeof(char) is 1 by definition.
 289 AC_CHECK_SIZEOF(void *)
 290 AC_CHECK_SIZEOF(short)
 291 AC_CHECK_SIZEOF(int)
 292 AC_CHECK_SIZEOF(long)
 293 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 294 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 295
 296 # ---------------------
 297 # Warnings and checking
 298 # ---------------------
 299
 300 # Check $CC warning features (if it's GCC).
 301 # We want to use -pedantic, but we don't want warnings about
 302 # * 'long long'
 303 # * variadic macros
 304 # * overlong strings
 305 # So, we only use -pedantic if we can disable those warnings.
 306
 307 AC_CACHE_CHECK(
 308   [whether ${CC} accepts -Wno-long-long],
 309   [ac_cv_prog_cc_w_no_long_long],
 310   [save_CFLAGS="$CFLAGS"
 311   CFLAGS="-Wno-long-long"
 312   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 313                     [ac_cv_prog_cc_w_no_long_long=yes],
 314                     [ac_cv_prog_cc_w_no_long_long=no])
 315   CFLAGS="$save_CFLAGS"
 316   ])
 317
 318 AC_CACHE_CHECK(
 319   [whether ${CC} accepts -Wno-variadic-macros],
 320   [ac_cv_prog_cc_w_no_variadic_macros],
 321   [save_CFLAGS="$CFLAGS"
 322   CFLAGS="-Wno-variadic-macros"
 323   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 324                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 325                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 326   CFLAGS="$save_CFLAGS"
 327   ])
 328
 329 AC_CACHE_CHECK(
 330   [whether ${CC} accepts -Wno-overlength-strings],
 331   [ac_cv_prog_cc_w_no_overlength_strings],
 332   [save_CFLAGS="$CFLAGS"
 333   CFLAGS="-Wno-overlength-strings"
 334   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 335                     [ac_cv_prog_cc_w_no_overlength_strings=yes],
 336                     [ac_cv_prog_cc_w_no_overlength_strings=no])
 337   CFLAGS="$save_CFLAGS"
 338   ])
 339
 340 strict1_warn=
 341 if test $ac_cv_prog_cc_w_no_long_long = yes \
 342    && test $ac_cv_prog_cc_w_no_variadic_macros = yes \
 343    && test $ac_cv_prog_cc_w_no_overlength_strings = yes ; then
 344   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros -Wno-overlength-strings"
 345 fi
 346
 347 # Add -Wold-style-definition if it's accepted
 348 AC_CACHE_CHECK(
 349   [whether ${CC} accepts -Wold-style-definition],
 350   [ac_cv_prog_cc_w_old_style_definition],
 351   [save_CFLAGS="$CFLAGS"
 352   CFLAGS="-Wold-style-definition"
 353   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 354                     [ac_cv_prog_cc_w_old_style_definition=yes],
 355                     [ac_cv_prog_cc_w_old_style_definition=no])
 356   CFLAGS="$save_CFLAGS"
 357   ])
 358 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 359   strict1_warn="${strict1_warn} -Wold-style-definition"
 360 fi
 361
 362 # Add -Wmissing-format-attribute if it's accepted
 363 AC_CACHE_CHECK(
 364   [whether ${CC} accepts -Wmissing-format-attribute],
 365   [ac_cv_prog_cc_w_missing_format_attribute],
 366   [save_CFLAGS="$CFLAGS"
 367   CFLAGS="-Wmissing-format-attribute"
 368   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 369                     [ac_cv_prog_cc_w_missing_format_attribute=yes],
 370                     [ac_cv_prog_cc_w_missing_format_attribute=no])
 371   CFLAGS="$save_CFLAGS"
 372   ])
 373 if test $ac_cv_prog_cc_w_missing_format_attribute = yes ; then
 374   strict1_warn="${strict1_warn} -Wmissing-format-attribute"
 375 fi
 376
 377 # Enable -Werror, period.
 378 AC_ARG_ENABLE(werror_always,
 379 [  --enable-werror-always         enable -Werror always], [],
 380 [enable_werror_always=no])
 381 if test x${enable_werror_always} = xyes ; then
 382   strict1_warn="${strict1_warn} -Werror"
 383   WERROR=-Werror
 384 fi
 385
 386 AC_SUBST(strict1_warn)
 387
 388 # Get C++ compatibility warning flag, if supported.
 389 AC_CACHE_CHECK(
 390   [whether ${CC} accepts -Wc++-compat],
 391   [ac_cv_prog_cc_w_cxx_compat],
 392   [save_CFLAGS="$CFLAGS"
 393   CFLAGS="-Wc++-compat"
 394   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 395                     [ac_cv_prog_cc_w_cxx_compat=yes],
 396                     [ac_cv_prog_cc_w_cxx_compat=no])
 397   CFLAGS="$save_CFLAGS"
 398   ])
 399 if test x${ac_cv_prog_cc_w_cxx_compat} = xyes; then
 400   cxx_compat_warn="-Wc++-compat"
 401 fi
 402 AC_SUBST(cxx_compat_warn)
 403
 404
 405 # If the native compiler is GCC, we can enable warnings even in stage1.
 406 # That's useful for people building cross-compilers, or just running a
 407 # quick `make'.
 408 warn_cflags=
 409 if test "x$GCC" = "xyes"; then
 410   warn_cflags='$(GCC_WARN_CFLAGS)'
 411 fi
 412 AC_SUBST(warn_cflags)
 413
 414 # Enable -Werror in bootstrap stage2 and later.
 415 is_release=
 416 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 417   is_release=yes
 418 fi
 419 AC_ARG_ENABLE(werror,
 420 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 421 [if test x$is_release = x ; then
 422   # Default to "yes" on development branches.
 423   enable_werror=yes
 424 else
 425   # Default to "no" on release branches.
 426   enable_werror=no
 427 fi])
 428 if test x$enable_werror = xyes ; then
 429   WERROR=-Werror
 430 fi
 431 AC_SUBST(WERROR)
 432
 433 # Enable expensive internal checks
 434 AC_ARG_ENABLE(checking,
 435 [  --enable-checking[=LIST]
 436                           enable expensive run-time checks.  With LIST,
 437                           enable only specific categories of checks.
 438                           Categories are: yes,no,all,none,release.
 439                           Flags are: assert,fold,gc,gcac,misc,
 440                           rtlflag,rtl,runtime,tree,valgrind.],
 441 [ac_checking_flags="${enableval}"],[
 442 # Determine the default checks.
 443 if test x$is_release = x ; then
 444   ac_checking_flags=yes
 445 else
 446   ac_checking_flags=release
 447 fi])
 448 ac_assert_checking=1
 449 ac_checking=
 450 ac_fold_checking=
 451 ac_gc_checking=
 452 ac_gc_always_collect=
 453 ac_rtl_checking=
 454 ac_rtlflag_checking=
 455 ac_runtime_checking=1
 456 ac_tree_checking=
 457 ac_valgrind_checking=
 458 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 459 for check in $ac_checking_flags
 460 do
 461         case $check in
 462         # these set all the flags to specific states
 463         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 464                         ac_fold_checking= ; ac_gc_checking=1 ;
 465                         ac_gc_always_collect= ; ac_rtl_checking= ;
 466                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 467                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 468         no|none)        ac_assert_checking= ; ac_checking= ;
 469                         ac_fold_checking= ; ac_gc_checking= ;
 470                         ac_gc_always_collect= ; ac_rtl_checking= ;
 471                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 472                         ac_tree_checking= ; ac_valgrind_checking= ;;
 473         all)            ac_assert_checking=1 ; ac_checking=1 ;
 474                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 475                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 476                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 477                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 478         release)        ac_assert_checking=1 ; ac_checking= ;
 479                         ac_fold_checking= ; ac_gc_checking= ;
 480                         ac_gc_always_collect= ; ac_rtl_checking= ;
 481                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 482                         ac_tree_checking= ; ac_valgrind_checking= ;;
 483         # these enable particular checks
 484         assert)         ac_assert_checking=1 ;;
 485         fold)           ac_fold_checking=1 ;;
 486         gc)             ac_gc_checking=1 ;;
 487         gcac)           ac_gc_always_collect=1 ;;
 488         misc)           ac_checking=1 ;;
 489         rtl)            ac_rtl_checking=1 ;;
 490         rtlflag)        ac_rtlflag_checking=1 ;;
 491         runtime)        ac_runtime_checking=1 ;;
 492         tree)           ac_tree_checking=1 ;;
 493         valgrind)       ac_valgrind_checking=1 ;;
 494         *)      AC_MSG_ERROR(unknown check category $check) ;;
 495         esac
 496 done
 497 IFS="$ac_save_IFS"
 498
 499 nocommon_flag=""
 500 if test x$ac_checking != x ; then
 501   AC_DEFINE(ENABLE_CHECKING, 1,
 502 [Define if you want more run-time sanity checks.  This one gets a grab
 503    bag of miscellaneous but relatively cheap checks.])
 504   nocommon_flag=-fno-common
 505 fi
 506 AC_SUBST(nocommon_flag)
 507 if test x$ac_assert_checking != x ; then
 508   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 509 [Define if you want assertions enabled.  This is a cheap check.])
 510 fi
 511 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 512 if test x$ac_runtime_checking != x ; then
 513   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 514 [Define if you want runtime assertions enabled.  This is a cheap check.])
 515 fi
 516 if test x$ac_tree_checking != x ; then
 517   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 518 [Define if you want all operations on trees (the basic data
 519    structure of the front ends) to be checked for dynamic type safety
 520    at runtime.  This is moderately expensive.  The tree browser debugging
 521    routines will also be enabled by this option.
 522    ])
 523   TREEBROWSER=tree-browser.o
 524 fi
 525 AC_SUBST(TREEBROWSER)
 526 if test x$ac_rtl_checking != x ; then
 527   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 528 [Define if you want all operations on RTL (the basic data structure
 529    of the optimizer and back end) to be checked for dynamic type safety
 530    at runtime.  This is quite expensive.])
 531 fi
 532 if test x$ac_rtlflag_checking != x ; then
 533   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 534 [Define if you want RTL flag accesses to be checked against the RTL
 535    codes that are supported for each access macro.  This is relatively
 536    cheap.])
 537 fi
 538 if test x$ac_gc_checking != x ; then
 539   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 540 [Define if you want the garbage collector to do object poisoning and
 541    other memory allocation checks.  This is quite expensive.])
 542 fi
 543 if test x$ac_gc_always_collect != x ; then
 544   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 545 [Define if you want the garbage collector to operate in maximally
 546    paranoid mode, validating the entire heap and collecting garbage at
 547    every opportunity.  This is extremely expensive.])
 548 fi
 549 if test x$ac_fold_checking != x ; then
 550   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 551 [Define if you want fold checked that it never destructs its argument.
 552    This is quite expensive.])
 553 fi
 554 valgrind_path_defines=
 555 valgrind_command=
 556
 557 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 558 dnl # an if statement.  This was the source of very frustrating bugs
 559 dnl # in converting to autoconf 2.5x!
 560 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 561
 562 if test x$ac_valgrind_checking != x ; then
 563   # It is certainly possible that there's valgrind but no valgrind.h.
 564   # GCC relies on making annotations so we must have both.
 565   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 566   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 567     [[#include <valgrind/memcheck.h>
 568 #ifndef VALGRIND_DISCARD
 569 #error VALGRIND_DISCARD not defined
 570 #endif]])],
 571   [gcc_cv_header_valgrind_memcheck_h=yes],
 572   [gcc_cv_header_valgrind_memcheck_h=no])
 573   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 574   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 575   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 576     [[#include <memcheck.h>
 577 #ifndef VALGRIND_DISCARD
 578 #error VALGRIND_DISCARD not defined
 579 #endif]])],
 580   [gcc_cv_header_memcheck_h=yes],
 581   [gcc_cv_header_memcheck_h=no])
 582   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 583   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 584         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 585   if test "x$valgrind_path" = "x" \
 586     || (test $have_valgrind_h = no \
 587         && test $gcc_cv_header_memcheck_h = no \
 588         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 589         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 590   fi
 591   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 592   valgrind_command="$valgrind_path -q"
 593   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 594 [Define if you want to run subprograms and generated programs
 595    through valgrind (a memory checker).  This is extremely expensive.])
 596   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 597     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 598         [Define if valgrind's valgrind/memcheck.h header is installed.])
 599   fi
 600   if test $gcc_cv_header_memcheck_h = yes; then
 601     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 602         [Define if valgrind's memcheck.h header is installed.])
 603   fi
 604 fi
 605 AC_SUBST(valgrind_path_defines)
 606 AC_SUBST(valgrind_command)
 607
 608 AC_ARG_ENABLE(mapped-location,
 609 [  --enable-mapped-location   location_t is fileline integer cookie],,
 610 enable_mapped_location=no)
 611
 612 if test "$enable_mapped_location" = yes ; then
 613   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 614 [Define if location_t is fileline integer cookie.])
 615 fi
 616
 617 # Enable code coverage collection
 618 AC_ARG_ENABLE(coverage,
 619 [  --enable-coverage[=LEVEL]
 620                           enable compiler's code coverage collection.
 621                           Use to measure compiler performance and locate
 622                           unused parts of the compiler. With LEVEL, specify
 623                           optimization. Values are opt, noopt,
 624                           default is noopt],
 625 [case "${enableval}" in
 626   yes|noopt)
 627     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 628     ;;
 629   opt)
 630     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 631     ;;
 632   no)
 633     # a.k.a. --disable-coverage
 634     coverage_flags=""
 635     ;;
 636   *)
 637     AC_MSG_ERROR(unknown coverage setting $enableval)
 638     ;;
 639 esac],
 640 [coverage_flags=""])
 641 AC_SUBST(coverage_flags)
 642
 643 AC_ARG_ENABLE(gather-detailed-mem-stats,
 644 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 645 [enable_gather_detailed_mem_stats=no])
 646 if test x$enable_gather_detailed_mem_stats = xyes ; then
 647   AC_DEFINE(GATHER_STATISTICS, 1,
 648         [Define to enable detailed memory allocation stats gathering.])
 649 fi
 650
 651 # -------------------------------
 652 # Miscenalleous configure options
 653 # -------------------------------
 654
 655 # With stabs
 656 AC_ARG_WITH(stabs,
 657 [  --with-stabs            arrange to use stabs instead of host debug format],
 658 stabs="$with_stabs",
 659 stabs=no)
 660
 661 # Determine whether or not multilibs are enabled.
 662 AC_ARG_ENABLE(multilib,
 663 [  --enable-multilib       enable library support for multiple ABIs],
 664 [], [enable_multilib=yes])
 665 AC_SUBST(enable_multilib)
 666
 667 # Enable __cxa_atexit for C++.
 668 AC_ARG_ENABLE(__cxa_atexit,
 669 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 670 [], [])
 671
 672 # Enable C extension for decimal float if target supports it.
 673 AC_ARG_ENABLE(decimal-float,
 674 [  --enable-decimal-float  enable decimal float extension to C],
 675 [
 676   if test x$enablevar = xyes ; then
 677     case $target in
 678     powerpc*-*-linux* | i?86*-*-linux*)
 679       ;;
 680     *)
 681       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 682       enable_decimal_float=no
 683       ;;
 684     esac
 685   fi
 686 ],
 687 [
 688   case $target in
 689   powerpc*-*-linux*)
 690     enable_decimal_float=yes
 691     ;;
 692   *)
 693     enable_decimal_float=no
 694     ;;
 695   esac
 696 ])
 697
 698 AC_SUBST(enable_decimal_float)
 699
 700 dfp=`if test $enable_decimal_float = yes; then echo 1; else echo 0; fi`
 701 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 702 [Define to 1 to enable decimal float extension to C.])
 703
 704 # Enable threads
 705 # Pass with no value to take the default
 706 # Pass with a value to specify a thread package
 707 AC_ARG_ENABLE(threads,
 708 [  --enable-threads        enable thread usage for target GCC
 709   --enable-threads=LIB    use LIB thread package for target GCC],,
 710 [enable_threads=''])
 711
 712 AC_ARG_ENABLE(tls,
 713 [  --enable-tls            enable or disable generation of tls code
 714                           overriding the assembler check for tls support],
 715 [
 716   case $enable_tls in
 717     yes | no) ;;
 718     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 719 Valid choices are 'yes' and 'no'.]) ;;
 720   esac
 721 ], [enable_tls=''])
 722
 723 AC_ARG_ENABLE(objc-gc,
 724 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 725                           the GNU Objective-C runtime],
 726 if test x$enable_objc_gc = xno; then
 727         objc_boehm_gc=''
 728 else
 729         objc_boehm_gc=1
 730 fi,
 731 objc_boehm_gc='')
 732
 733 AC_ARG_WITH(dwarf2,
 734 [  --with-dwarf2           force the default debug format to be DWARF 2],
 735 dwarf2="$with_dwarf2",
 736 dwarf2=no)
 737
 738 AC_ARG_ENABLE(shared,
 739 [  --disable-shared        don't provide a shared libgcc],
 740 [
 741   case $enable_shared in
 742   yes | no) ;;
 743   *)
 744     enable_shared=no
 745     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 746     for pkg in $enableval; do
 747       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 748         enable_shared=yes
 749       fi
 750     done
 751     IFS="$ac_save_ifs"
 752     ;;
 753   esac
 754 ], [enable_shared=yes])
 755 AC_SUBST(enable_shared)
 756
 757 AC_ARG_WITH(build-sysroot,
 758   [  --with-build-sysroot=sysroot
 759                           use sysroot as the system root during the build])
 760
 761 AC_ARG_WITH(sysroot,
 762 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 763 [
 764  case ${with_sysroot} in
 765  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 766  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 767  esac
 768
 769  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 770  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 771
 772  if test "x$exec_prefix" = xNONE; then
 773   if test "x$prefix" = xNONE; then
 774    test_prefix=/usr/local
 775   else
 776    test_prefix=$prefix
 777   fi
 778  else
 779   test_prefix=$exec_prefix
 780  fi
 781  case ${TARGET_SYSTEM_ROOT} in
 782  "${test_prefix}"|"${test_prefix}/"*|\
 783  '${exec_prefix}'|'${exec_prefix}/'*)
 784    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 785    TARGET_SYSTEM_ROOT_DEFINE="$t"
 786    ;;
 787  esac
 788 ], [
 789  TARGET_SYSTEM_ROOT=
 790  TARGET_SYSTEM_ROOT_DEFINE=
 791  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 792 ])
 793 AC_SUBST(TARGET_SYSTEM_ROOT)
 794 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 795 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 796
 797 # Build with intermodule optimisations
 798 AC_ARG_ENABLE(intermodule,
 799 [  --enable-intermodule    build the compiler in one step],
 800 [case ${enable_intermodule} in
 801   yes) onestep="-onestep";;
 802   *) onestep="";;
 803 esac],
 804 [onestep=""])
 805 AC_SUBST(onestep)
 806
 807 # Sanity check enable_languages in case someone does not run the toplevel
 808 # configure # script.
 809 AC_ARG_ENABLE(languages,
 810 [  --enable-languages=LIST specify which front-ends to build],
 811 [case ,${enable_languages}, in
 812        ,,|,yes,)
 813                 # go safe -- we cannot be much sure without the toplevel
 814                 # configure's
 815                 # analysis of which target libs are present and usable
 816                 enable_languages=c
 817                 ;;
 818          *,all,*)
 819                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 820                 ;;
 821         *,c,*)
 822                 ;;
 823         *)
 824                 enable_languages=c,${enable_languages}
 825                 ;;
 826 esac],
 827 [enable_languages=c])
 828
 829 subdirs=
 830 for lang in ${srcdir}/*/config-lang.in
 831 do
 832         case $lang in
 833         # The odd quoting in the next line works around
 834         # an apparent bug in bash 1.12 on linux.
 835 changequote(,)dnl
 836         ${srcdir}/[*]/config-lang.in) ;;
 837         *)
 838           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 839           if test "x$lang_alias" = x
 840           then
 841                 echo "$lang doesn't set \$language." 1>&2
 842                 exit 1
 843           fi
 844           case ",$enable_languages," in
 845           *,$lang_alias,*)
 846             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 847           esac
 848           ;;
 849 changequote([,])dnl
 850         esac
 851 done
 852
 853
 854 # -------------------------
 855 # Checks for other programs
 856 # -------------------------
 857
 858 AC_PROG_MAKE_SET
 859
 860 # Find some useful tools
 861 AC_PROG_AWK
 862 # We need awk to create options.c and options.h.
 863 # Bail out if it's missing.
 864 case ${AWK} in
 865   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 866 esac
 867
 868 gcc_AC_PROG_LN_S
 869 ACX_PROG_LN($LN_S)
 870 AC_PROG_RANLIB
 871 case "${host}" in
 872 *-*-darwin*)
 873   # By default, the Darwin ranlib will not treat common symbols as
 874   # definitions when  building the archive table of contents.  Other
 875   # ranlibs do that; pass an option to the Darwin ranlib that makes
 876   # it behave similarly.
 877   ranlib_flags="-c"
 878   ;;
 879 *)
 880   ranlib_flags=""
 881 esac
 882 AC_SUBST(ranlib_flags)
 883
 884 gcc_AC_PROG_INSTALL
 885
 886 # See if cmp has --ignore-initial.
 887 gcc_AC_PROG_CMP_IGNORE_INITIAL
 888
 889 # See if we have the mktemp command.
 890 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 891
 892 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 893
 894 # See if makeinfo has been installed and is modern enough
 895 # that we can use it.
 896 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 897   [GNU texinfo.* \([0-9][0-9.]*\)],
 898   [4.[4-9]*])
 899 if test $gcc_cv_prog_makeinfo_modern = no; then
 900   MAKEINFO="$MISSING makeinfo"
 901   AC_MSG_WARN([
 902 *** Makeinfo is missing or too old.
 903 *** Info documentation will not be built.])
 904   BUILD_INFO=
 905 else
 906   BUILD_INFO=info
 907 fi
 908 AC_SUBST(BUILD_INFO)
 909
 910 # Is pod2man recent enough to regenerate manpages?
 911 AC_MSG_CHECKING([for recent Pod::Man])
 912 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 913   AC_MSG_RESULT(yes)
 914   GENERATED_MANPAGES=generated-manpages
 915 else
 916   AC_MSG_RESULT(no)
 917   GENERATED_MANPAGES=
 918 fi
 919 AC_SUBST(GENERATED_MANPAGES)
 920
 921 # How about lex?
 922 dnl Don't use AC_PROG_LEX; we insist on flex.
 923 dnl LEXLIB is not useful in gcc.
 924 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 925
 926 # Bison?
 927 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 928
 929 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 930 # check for build == host before using them.
 931
 932 # NM
 933 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 934   && test -d ../binutils ; then
 935   NM='$(objdir)/../binutils/nm-new'
 936 else
 937   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 938 fi
 939
 940 # AR
 941 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 942   && test -d ../binutils ; then
 943   AR='$(objdir)/../binutils/ar'
 944 else
 945   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 946 fi
 947
 948
 949 # --------------------
 950 # Checks for C headers
 951 # --------------------
 952
 953 AC_MSG_CHECKING(for GNU C library)
 954 AC_CACHE_VAL(gcc_cv_glibc,
 955 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 956   [[#include <features.h>]], [[
 957 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 958 #error Not a GNU C library system
 959 #endif]])],
 960   [gcc_cv_glibc=yes],
 961   [gcc_cv_glibc=no])])
 962 AC_MSG_RESULT($gcc_cv_glibc)
 963 if test $gcc_cv_glibc = yes; then
 964   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 965 fi
 966
 967 # Need to reject headers which give warnings, so that the -Werror bootstrap
 968 # works later. *sigh*  This needs to come before all header checks.
 969 AC_PROG_CPP_WERROR
 970
 971 AC_HEADER_STDC
 972 AC_HEADER_TIME
 973 ACX_HEADER_STRING
 974 AC_HEADER_SYS_WAIT
 975 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 976                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 977                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 978                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 979
 980 # Check for thread headers.
 981 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 982 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 983
 984 # These tests can't be done till we know if we have limits.h.
 985 gcc_AC_C_CHAR_BIT
 986 AC_C_BIGENDIAN
 987
 988 # --------
 989 # UNSORTED
 990 # --------
 991
 992 # Stage specific cflags for build.
 993 stage1_cflags=
 994 case $build in
 995 vax-*-*)
 996   if test x$GCC = xyes
 997   then
 998     stage1_cflags="-Wa,-J"
 999   else
1000     stage1_cflags="-J"
1001   fi
1002   ;;
1003 powerpc-*-darwin*)
1004   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
1005   # sources; use -no-cpp-precomp to get to GNU cpp.
1006   # Apple's GCC has bugs in designated initializer handling, so disable
1007   # that too.
1008   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
1009   ;;
1010 esac
1011 AC_SUBST(stage1_cflags)
1012
1013 # These libraries may be used by collect2.
1014 # We may need a special search path to get them linked.
1015 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
1016 [save_LIBS="$LIBS"
1017 for libs in '' -lld -lmld \
1018                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
1019                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
1020 do
1021         LIBS="$libs"
1022         AC_TRY_LINK_FUNC(ldopen,
1023                 [gcc_cv_collect2_libs="$libs"; break])
1024 done
1025 LIBS="$save_LIBS"
1026 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1027 case $gcc_cv_collect2_libs in
1028         "none required")        ;;
1029         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1030 esac
1031 AC_SUBST(COLLECT2_LIBS)
1032
1033 # When building Ada code on Alpha, we need exc_resume which is usually in
1034 # -lexc.  So test for it.
1035 save_LIBS="$LIBS"
1036 LIBS=
1037 AC_SEARCH_LIBS(exc_resume, exc)
1038 GNAT_LIBEXC="$LIBS"
1039 LIBS="$save_LIBS"
1040 AC_SUBST(GNAT_LIBEXC)
1041
1042 # Some systems put ldexp and frexp in libm instead of libc; assume
1043 # they're both in the same place.  jcf-dump needs them.
1044 save_LIBS="$LIBS"
1045 LIBS=
1046 AC_SEARCH_LIBS(ldexp, m)
1047 LDEXP_LIB="$LIBS"
1048 LIBS="$save_LIBS"
1049 AC_SUBST(LDEXP_LIB)
1050
1051 # Use <inttypes.h> only if it exists,
1052 # doesn't clash with <sys/types.h>, and declares intmax_t.
1053 AC_MSG_CHECKING(for inttypes.h)
1054 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1055 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1056 [[#include <sys/types.h>
1057 #include <inttypes.h>]],
1058   [[intmax_t i = -1;]])],
1059   [gcc_cv_header_inttypes_h=yes],
1060   [gcc_cv_header_inttypes_h=no])])
1061 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1062 if test $gcc_cv_header_inttypes_h = yes; then
1063   AC_DEFINE(HAVE_INTTYPES_H, 1,
1064         [Define if you have a working <inttypes.h> header file.])
1065 fi
1066
1067 dnl Disabled until we have a complete test for buggy enum bitfields.
1068 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1069
1070 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1071   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1072   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1073   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1074   putchar_unlocked putc_unlocked)
1075 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1076         sysconf strsignal getrusage nl_langinfo scandir alphasort \
1077         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1078         gcc_UNLOCKED_FUNCS)
1079
1080 if test x$ac_cv_func_mbstowcs = xyes; then
1081   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1082 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1083 int main()
1084 {
1085   mbstowcs(0, "", 0);
1086   return 0;
1087 }]])],
1088     [gcc_cv_func_mbstowcs_works=yes],
1089     [gcc_cv_func_mbstowcs_works=no],
1090     [gcc_cv_func_mbstowcs_works=yes])])
1091   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1092     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1093   [Define this macro if mbstowcs does not crash when its
1094    first argument is NULL.])
1095   fi
1096 fi
1097
1098 AC_CHECK_TYPE(ssize_t, int)
1099
1100 # Try to determine the array type of the second argument of getgroups
1101 # for the target system (int or gid_t).
1102 AC_TYPE_GETGROUPS
1103 if test "${target}" = "${build}"; then
1104   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1105 else
1106   case "${target}" in
1107         # This condition may need some tweaking.  It should include all
1108         # targets where the array type of the second argument of getgroups
1109         # is int and the type of gid_t is not equivalent to int.
1110         *-*-sunos* | *-*-ultrix*)
1111                 TARGET_GETGROUPS_T=int
1112                 ;;
1113         *)
1114                 TARGET_GETGROUPS_T=gid_t
1115                 ;;
1116   esac
1117 fi
1118 AC_SUBST(TARGET_GETGROUPS_T)
1119
1120 gcc_AC_FUNC_MMAP_BLACKLIST
1121
1122 case "${host}" in
1123 *-*-*vms*)
1124   # Under VMS, vfork works very differently than on Unix. The standard test
1125   # won't work, and it isn't easily adaptable. It makes more sense to
1126   # just force it.
1127   ac_cv_func_vfork_works=yes
1128   ;;
1129 esac
1130 AC_FUNC_FORK
1131
1132 AM_ICONV
1133 # Until we have in-tree GNU iconv:
1134 LIBICONV_DEP=
1135 AC_SUBST(LIBICONV_DEP)
1136
1137 AM_LC_MESSAGES
1138
1139 AM_LANGINFO_CODESET
1140
1141 # We will need to find libiberty.h and ansidecl.h
1142 saved_CFLAGS="$CFLAGS"
1143 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1144 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1145         strsignal strstr strverscmp \
1146         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1147         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1148 #include "ansidecl.h"
1149 #include "system.h"])
1150
1151 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1152 #include "ansidecl.h"
1153 #include "system.h"
1154 #ifdef HAVE_SYS_RESOURCE_H
1155 #include <sys/resource.h>
1156 #endif
1157 ])
1158
1159 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1160 #include "ansidecl.h"
1161 #include "system.h"
1162 #ifdef HAVE_SYS_RESOURCE_H
1163 #include <sys/resource.h>
1164 #endif
1165 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1166 [Define to \`long' if <sys/resource.h> doesn't define.])])
1167
1168 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1169 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1170 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1171 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1172 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1173 #include "ansidecl.h"
1174 #include "system.h"
1175 #ifdef HAVE_LDFCN_H
1176 #undef FREAD
1177 #undef FWRITE
1178 #include <ldfcn.h>
1179 #endif
1180 ])
1181
1182 gcc_AC_CHECK_DECLS(times, , ,[
1183 #include "ansidecl.h"
1184 #include "system.h"
1185 #ifdef HAVE_SYS_TIMES_H
1186 #include <sys/times.h>
1187 #endif
1188 ])
1189
1190 # More time-related stuff.
1191 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1192 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1193 #include "ansidecl.h"
1194 #include "system.h"
1195 #ifdef HAVE_SYS_TIMES_H
1196 #include <sys/times.h>
1197 #endif
1198 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1199 if test $ac_cv_struct_tms = yes; then
1200   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1201   [Define if <sys/times.h> defines struct tms.])
1202 fi
1203
1204 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1205 # revisit after autoconf 2.50.
1206 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1207 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1208 #include "ansidecl.h"
1209 #include "system.h"
1210 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1211 if test $gcc_cv_type_clock_t = yes; then
1212   AC_DEFINE(HAVE_CLOCK_T, 1,
1213   [Define if <time.h> defines clock_t.])
1214 fi
1215
1216 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1217 CFLAGS="$saved_CFLAGS"
1218
1219 gcc_AC_INITFINI_ARRAY
1220
1221 # mkdir takes a single argument on some systems.
1222 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1223
1224 # File extensions
1225 manext='.1'
1226 objext='.o'
1227 AC_SUBST(manext)
1228 AC_SUBST(objext)
1229
1230 # With Setjmp/Longjmp based exception handling.
1231 AC_ARG_ENABLE(sjlj-exceptions,
1232 [  --enable-sjlj-exceptions
1233                           arrange to use setjmp/longjmp exception handling],
1234 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1235 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1236   [Define 0/1 to force the choice for exception handling model.])])
1237
1238 # For platforms with the unwind ABI which includes an unwind library,
1239 # libunwind, we can choose to use the system libunwind.
1240 AC_ARG_WITH(system-libunwind,
1241 [  --with-system-libunwind use installed libunwind])
1242
1243 # --------------------------------------------------------
1244 # Build, host, and target specific configuration fragments
1245 # --------------------------------------------------------
1246
1247 # Collect build-machine-specific information.
1248 . ${srcdir}/config.build
1249
1250 # Collect host-machine-specific information.
1251 . ${srcdir}/config.host
1252
1253 target_gtfiles=
1254
1255 # Collect target-machine-specific information.
1256 . ${srcdir}/config.gcc
1257
1258 extra_objs="${host_extra_objs} ${extra_objs}"
1259 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1260
1261 # Default the target-machine variables that were not explicitly set.
1262 if test x"$tm_file" = x
1263 then tm_file=$cpu_type/$cpu_type.h; fi
1264
1265 if test x"$extra_headers" = x
1266 then extra_headers=; fi
1267
1268 if test x$md_file = x
1269 then md_file=$cpu_type/$cpu_type.md; fi
1270
1271 if test x$out_file = x
1272 then out_file=$cpu_type/$cpu_type.c; fi
1273
1274 if test x"$tmake_file" = x
1275 then tmake_file=$cpu_type/t-$cpu_type
1276 fi
1277
1278 if test x"$dwarf2" = xyes
1279 then tm_file="$tm_file tm-dwarf2.h"
1280 fi
1281
1282 # Say what files are being used for the output code and MD file.
1283 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1284 echo "Using \`$srcdir/config/$md_file' as machine description file."
1285
1286 # If any of the xm_file variables contain nonexistent files, warn
1287 # about them and drop them.
1288
1289 bx=
1290 for x in $build_xm_file; do
1291   if    test -f $srcdir/config/$x
1292   then      bx="$bx $x"
1293   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1294   fi
1295 done
1296 build_xm_file="$bx"
1297
1298 hx=
1299 for x in $host_xm_file; do
1300   if    test -f $srcdir/config/$x
1301   then      hx="$hx $x"
1302   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1303   fi
1304 done
1305 host_xm_file="$hx"
1306
1307 tx=
1308 for x in $xm_file; do
1309   if    test -f $srcdir/config/$x
1310   then      tx="$tx $x"
1311   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1312   fi
1313 done
1314 xm_file="$tx"
1315
1316 count=a
1317 for f in $tm_file; do
1318         count=${count}x
1319 done
1320 if test $count = ax; then
1321         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1322 else
1323         echo "Using the following target machine macro files:"
1324         for f in $tm_file; do
1325                 echo "  $srcdir/config/$f"
1326         done
1327 fi
1328
1329 if test x$need_64bit_hwint = xyes; then
1330         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1331 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1332 fi
1333
1334 if test x$use_long_long_for_widest_fast_int = xyes; then
1335         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1336 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1337 efficiently supported by the host hardware.])
1338 fi
1339
1340 count=a
1341 for f in $host_xm_file; do
1342         count=${count}x
1343 done
1344 if test $count = a; then
1345         :
1346 elif test $count = ax; then
1347         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1348 else
1349         echo "Using the following host machine macro files:"
1350         for f in $host_xm_file; do
1351                 echo "  $srcdir/config/$f"
1352         done
1353 fi
1354 echo "Using ${out_host_hook_obj} for host machine hooks."
1355
1356 if test "$host_xm_file" != "$build_xm_file"; then
1357         count=a
1358         for f in $build_xm_file; do
1359                 count=${count}x
1360         done
1361         if test $count = a; then
1362                 :
1363         elif test $count = ax; then
1364                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1365         else
1366                 echo "Using the following build machine macro files:"
1367                 for f in $build_xm_file; do
1368                         echo "  $srcdir/config/$f"
1369                 done
1370         fi
1371 fi
1372
1373 # ---------
1374 # Threading
1375 # ---------
1376
1377 # Check if a valid thread package
1378 case ${enable_threads} in
1379   "" | no)
1380     # No threads
1381     target_thread_file='single'
1382     ;;
1383   yes)
1384     # default
1385     target_thread_file='single'
1386     ;;
1387   aix | dce | gnat | irix | posix | posix95 | rtems | \
1388   single | solaris | vxworks | win32 )
1389     target_thread_file=${enable_threads}
1390     ;;
1391   *)
1392     echo "${enable_threads} is an unknown thread package" 1>&2
1393     exit 1
1394     ;;
1395 esac
1396
1397 if test x${thread_file} = x; then
1398   # No thread file set by target-specific clauses in config.gcc,
1399   # so use file chosen by default logic above
1400   thread_file=${target_thread_file}
1401 fi
1402
1403 # Make gthr-default.h if we have a thread file.
1404 gthread_flags=
1405 if test $thread_file != single; then
1406   rm -f gthr-default.h
1407   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1408   gthread_flags=-DHAVE_GTHR_DEFAULT
1409 fi
1410 AC_SUBST(gthread_flags)
1411
1412 # --------
1413 # UNSORTED
1414 # --------
1415
1416 use_cxa_atexit=no
1417 if test x$enable___cxa_atexit = xyes || \
1418    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1419   if test x$host = x$target; then
1420     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1421         [echo "__cxa_atexit can't be enabled on this target"])
1422   else
1423     # We can't check for __cxa_atexit when building a cross, so assume
1424     # it is available
1425     use_cxa_atexit=yes
1426   fi
1427   if test x$use_cxa_atexit = xyes; then
1428     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1429       [Define if you want to use __cxa_atexit, rather than atexit, to
1430       register C++ destructors for local statics and global objects.
1431       This is essential for fully standards-compliant handling of
1432       destructors, but requires __cxa_atexit in libc.])
1433   fi
1434 fi
1435
1436 # Look for a file containing extra machine modes.
1437 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1438   extra_modes_file='$(srcdir)'/config/${extra_modes}
1439   AC_SUBST(extra_modes_file)
1440   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1441   [Define to the name of a file containing a list of extra machine modes
1442    for this architecture.])
1443 fi
1444
1445 # Convert extra_options into a form suitable for Makefile use.
1446 extra_opt_files=
1447 for f in $extra_options; do
1448   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1449 done
1450 AC_SUBST(extra_opt_files)
1451
1452 # auto-host.h is the file containing items generated by autoconf and is
1453 # the first file included by config.h.
1454 # If host=build, it is correct to have bconfig include auto-host.h
1455 # as well.  If host!=build, we are in error and need to do more
1456 # work to find out the build config parameters.
1457 if test x$host = x$build
1458 then
1459         build_auto=auto-host.h
1460 else
1461         # We create a subdir, then run autoconf in the subdir.
1462         # To prevent recursion we set host and build for the new
1463         # invocation of configure to the build for this invocation
1464         # of configure.
1465         tempdir=build.$$
1466         rm -rf $tempdir
1467         mkdir $tempdir
1468         cd $tempdir
1469         case ${srcdir} in
1470         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1471         *) realsrcdir=../${srcdir};;
1472         esac
1473         saved_CFLAGS="${CFLAGS}"
1474         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1475         ${realsrcdir}/configure \
1476                 --enable-languages=${enable_languages-all} \
1477                 --target=$target_alias --host=$build_alias --build=$build_alias
1478         CFLAGS="${saved_CFLAGS}"
1479
1480         # We just finished tests for the build machine, so rename
1481         # the file auto-build.h in the gcc directory.
1482         mv auto-host.h ../auto-build.h
1483         cd ..
1484         rm -rf $tempdir
1485         build_auto=auto-build.h
1486 fi
1487 AC_SUBST(build_subdir)
1488
1489 tm_file="${tm_file} defaults.h"
1490 tm_p_file="${tm_p_file} tm-preds.h"
1491 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1492 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1493 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1494 # put this back in temporarily.
1495 xm_file="auto-host.h ansidecl.h ${xm_file}"
1496
1497 # --------
1498 # UNSORTED
1499 # --------
1500
1501 changequote(,)dnl
1502 # Compile in configure arguments.
1503 if test -f configargs.h ; then
1504         # Being re-configured.
1505         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1506         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1507 else
1508         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1509 fi
1510
1511 # Double all backslashes and backslash all quotes to turn
1512 # gcc_config_arguments into a C string.
1513 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1514 $gcc_config_arguments
1515 EOF
1516 gcc_config_arguments_str=`cat conftest.out`
1517 rm -f conftest.out
1518
1519 cat > configargs.h <<EOF
1520 /* Generated automatically. */
1521 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1522 static const char thread_model[] = "$thread_file";
1523
1524 static const struct {
1525   const char *name, *value;
1526 } configure_default_options[] = $configure_default_options;
1527 EOF
1528 changequote([,])dnl
1529
1530 # Internationalization
1531 ZW_GNU_GETTEXT_SISTER_DIR
1532
1533 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1534 # -liconv on the link line twice.
1535 case "$LIBINTL" in *$LIBICONV*)
1536         LIBICONV= ;;
1537 esac
1538
1539 AC_ARG_ENABLE(secureplt,
1540 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1541 [], [])
1542
1543 # Windows32 Registry support for specifying GCC installation paths.
1544 AC_ARG_ENABLE(win32-registry,
1545 [  --disable-win32-registry
1546                           disable lookup of installation paths in the
1547                           Registry on Windows hosts
1548   --enable-win32-registry enable registry lookup (default)
1549   --enable-win32-registry=KEY
1550                           use KEY instead of GCC version as the last portion
1551                           of the registry key],,)
1552
1553 case $host_os in
1554   win32 | pe | cygwin* | mingw32* | uwin*)
1555     if test "x$enable_win32_registry" != xno; then
1556       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1557     fi
1558
1559     if test "x$enable_win32_registry" != xno; then
1560       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1561   [Define to 1 if installation paths should be looked up in the Windows
1562    Registry. Ignored on non-Windows hosts.])
1563
1564       if test "x$enable_win32_registry" != xyes \
1565          && test "x$enable_win32_registry" != x; then
1566         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1567   [Define to be the last component of the Windows registry key under which
1568    to look for installation paths.  The full key used will be
1569    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1570    The default is the GCC version number.])
1571       fi
1572     fi
1573   ;;
1574 esac
1575
1576 # Get an absolute path to the GCC top-level source directory
1577 holddir=`${PWDCMD-pwd}`
1578 cd $srcdir
1579 topdir=`${PWDCMD-pwd}`
1580 cd $holddir
1581
1582 # Conditionalize the makefile for this host machine.
1583 xmake_file=
1584 for f in ${host_xmake_file}
1585 do
1586         if test -f ${srcdir}/config/$f
1587         then
1588                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1589         fi
1590 done
1591
1592 # Conditionalize the makefile for this target machine.
1593 tmake_file_=
1594 for f in ${tmake_file}
1595 do
1596         if test -f ${srcdir}/config/$f
1597         then
1598                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1599         fi
1600 done
1601 tmake_file="${tmake_file_}"
1602
1603 # If the host doesn't support symlinks, modify CC in
1604 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1605 # Otherwise, we can use "CC=$(CC)".
1606 rm -f symtest.tem
1607 case "$LN_S" in
1608         *-s*)
1609                 cc_set_by_configure="\$(CC)"
1610                 quoted_cc_set_by_configure="\$(CC)"
1611                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1612                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1613                 ;;
1614         *)
1615                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1616                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1617                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1618                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1619                 ;;
1620 esac
1621
1622 # This is a terrible hack which will go away some day.
1623 host_cc_for_libada=${CC}
1624 AC_SUBST(host_cc_for_libada)
1625
1626 out_object_file=`basename $out_file .c`.o
1627
1628 tm_file_list="options.h"
1629 tm_include_list="options.h"
1630 for f in $tm_file; do
1631   case $f in
1632     defaults.h )
1633        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1634        tm_include_list="${tm_include_list} $f"
1635        ;;
1636     * )
1637        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1638        tm_include_list="${tm_include_list} config/$f"
1639        ;;
1640   esac
1641 done
1642
1643 tm_p_file_list=
1644 tm_p_include_list=
1645 for f in $tm_p_file; do
1646   case $f in
1647     tm-preds.h )
1648        tm_p_file_list="${tm_p_file_list} $f"
1649        tm_p_include_list="${tm_p_include_list} $f"
1650        ;;
1651     * )
1652        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1653        tm_p_include_list="${tm_p_include_list} config/$f"
1654   esac
1655 done
1656
1657 xm_file_list=
1658 xm_include_list=
1659 for f in $xm_file; do
1660   case $f in
1661     ansidecl.h )
1662        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1663        xm_include_list="${xm_include_list} $f"
1664        ;;
1665     auto-host.h )
1666        xm_file_list="${xm_file_list} $f"
1667        xm_include_list="${xm_include_list} $f"
1668        ;;
1669     * )
1670        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1671        xm_include_list="${xm_include_list} config/$f"
1672        ;;
1673   esac
1674 done
1675
1676 host_xm_file_list=
1677 host_xm_include_list=
1678 for f in $host_xm_file; do
1679   case $f in
1680     ansidecl.h )
1681        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1682        host_xm_include_list="${host_xm_include_list} $f"
1683        ;;
1684     auto-host.h )
1685        host_xm_file_list="${host_xm_file_list} $f"
1686        host_xm_include_list="${host_xm_include_list} $f"
1687        ;;
1688     * )
1689        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1690        host_xm_include_list="${host_xm_include_list} config/$f"
1691        ;;
1692   esac
1693 done
1694
1695 build_xm_file_list=
1696 for f in $build_xm_file; do
1697   case $f in
1698     ansidecl.h )
1699        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1700        build_xm_include_list="${build_xm_include_list} $f"
1701        ;;
1702     auto-build.h | auto-host.h )
1703        build_xm_file_list="${build_xm_file_list} $f"
1704        build_xm_include_list="${build_xm_include_list} $f"
1705        ;;
1706     * )
1707        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1708        build_xm_include_list="${build_xm_include_list} config/$f"
1709        ;;
1710   esac
1711 done
1712
1713 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1714 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1715 CROSS=                                          AC_SUBST(CROSS)
1716 ALL=all.internal                                AC_SUBST(ALL)
1717 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1718
1719 if test "x$with_build_sysroot" != x; then
1720   build_system_header_dir=$with_build_sysroot'$(NATIVE_SYSTEM_HEADER_DIR)'
1721 else
1722   # This value is used, even on a native system, because
1723   # CROSS_SYSTEM_HEADER_DIR is just
1724   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1725   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1726 fi
1727
1728 if test x$host != x$target
1729 then
1730         CROSS="-DCROSS_COMPILE"
1731         ALL=all.cross
1732         SYSTEM_HEADER_DIR=$build_system_header_dir
1733         case "$host","$target" in
1734         # Darwin crosses can use the host system's libraries and headers,
1735         # because of the fat library support.  Of course, it must be the
1736         # same version of Darwin on both sides.  Allow the user to
1737         # just say --target=foo-darwin without a version number to mean
1738         # "the version on this system".
1739             *-*-darwin*,*-*-darwin*)
1740                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1741                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1742                 if test $hostos = $targetos -o $targetos = darwin ; then
1743                     CROSS=
1744                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1745                     with_headers=yes
1746                 fi
1747                 ;;
1748
1749             i?86-*-*,x86_64-*-* \
1750             | powerpc*-*-*,powerpc64*-*-*)
1751                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1752         esac
1753 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1754         SYSTEM_HEADER_DIR=$build_system_header_dir
1755 fi
1756
1757 # If this is a cross-compiler that does not
1758 # have its own set of headers then define
1759 # inhibit_libc
1760
1761 # If this is using newlib, without having the headers available now,
1762 # then define inhibit_libc in LIBGCC2_CFLAGS.
1763 # This prevents libgcc2 from containing any code which requires libc
1764 # support.
1765 inhibit_libc=false
1766 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1767        test x$with_newlib = xyes ; } &&
1768      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1769        inhibit_libc=true
1770 fi
1771 AC_SUBST(inhibit_libc)
1772
1773 # When building gcc with a cross-compiler, we need to adjust things so
1774 # that the generator programs are still built with the native compiler.
1775 # Also, we cannot run fixincludes or fix-header.
1776
1777 # These are the normal (build=host) settings:
1778 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1779 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1780 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1781
1782 # Possibly disable fixproto, on a per-target basis.
1783 case ${use_fixproto} in
1784   no)
1785     STMP_FIXPROTO=
1786     ;;
1787   yes)
1788     STMP_FIXPROTO=stmp-fixproto
1789     ;;
1790 esac
1791 AC_SUBST(STMP_FIXPROTO)
1792
1793 # And these apply if build != host, or we are generating coverage data
1794 if test x$build != x$host || test "x$coverage_flags" != x
1795 then
1796     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1797
1798     if test "x$TARGET_SYSTEM_ROOT" = x; then
1799         if test "x$STMP_FIXPROTO" != x; then
1800           STMP_FIXPROTO=stmp-install-fixproto
1801         fi
1802     fi
1803 fi
1804
1805 # Expand extra_headers to include complete path.
1806 # This substitutes for lots of t-* files.
1807 extra_headers_list=
1808 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1809 for file in ${extra_headers} ; do
1810   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1811 done
1812
1813 # Define collect2 in Makefile.
1814 case $host_can_use_collect2 in
1815   no) collect2= ;;
1816   *) collect2='collect2$(exeext)' ;;
1817 esac
1818 AC_SUBST([collect2])
1819
1820 # Add a definition of USE_COLLECT2 if system wants one.
1821 case $use_collect2 in
1822   no) use_collect2= ;;
1823   "") ;;
1824   *)
1825     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1826     xm_defines="${xm_defines} USE_COLLECT2"
1827     case $host_can_use_collect2 in
1828       no)
1829         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1830         ;;
1831     esac
1832     ;;
1833 esac
1834
1835 # ---------------------------
1836 # Assembler & linker features
1837 # ---------------------------
1838
1839 # Identify the assembler which will work hand-in-glove with the newly
1840 # built GCC, so that we can examine its features.  This is the assembler
1841 # which will be driven by the driver program.
1842 #
1843 # If build != host, and we aren't building gas in-tree, we identify a
1844 # build->target assembler and hope that it will have the same features
1845 # as the host->target assembler we'll be using.
1846 gcc_cv_gas_major_version=
1847 gcc_cv_gas_minor_version=
1848 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1849
1850 m4_pattern_allow([AS_FOR_TARGET])dnl
1851 AS_VAR_SET_IF(gcc_cv_as,, [
1852 if test -x "$DEFAULT_ASSEMBLER"; then
1853         gcc_cv_as="$DEFAULT_ASSEMBLER"
1854 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1855      && test -f ../gas/Makefile \
1856      && test x$build = x$host; then
1857         gcc_cv_as=../gas/as-new$build_exeext
1858 elif test -x as$build_exeext; then
1859         # Build using assembler in the current directory.
1860         gcc_cv_as=./as$build_exeext
1861 elif test -x $AS_FOR_TARGET; then
1862         gcc_cv_as="$AS_FOR_TARGET"
1863 else
1864         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1865 fi])
1866
1867 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1868 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1869
1870 AC_MSG_CHECKING(what assembler to use)
1871 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1872   # Single tree build which includes gas.  We want to prefer it
1873   # over whatever linker top-level may have detected, since
1874   # we'll use what we're building after installation anyway.
1875   AC_MSG_RESULT(newly built gas)
1876   in_tree_gas=yes
1877   _gcc_COMPUTE_GAS_VERSION
1878   in_tree_gas_is_elf=no
1879   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1880      || (grep 'obj_format = multi' ../gas/Makefile \
1881          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1882   then
1883     in_tree_gas_is_elf=yes
1884   fi
1885 else
1886   AC_MSG_RESULT($gcc_cv_as)
1887   in_tree_gas=no
1888 fi
1889
1890 # Identify the linker which will work hand-in-glove with the newly
1891 # built GCC, so that we can examine its features.  This is the linker
1892 # which will be driven by the driver program.
1893 #
1894 # If build != host, and we aren't building gas in-tree, we identify a
1895 # build->target linker and hope that it will have the same features
1896 # as the host->target linker we'll be using.
1897 gcc_cv_gld_major_version=
1898 gcc_cv_gld_minor_version=
1899 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1900 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1901
1902 AS_VAR_SET_IF(gcc_cv_ld,, [
1903 if test -x "$DEFAULT_LINKER"; then
1904         gcc_cv_ld="$DEFAULT_LINKER"
1905 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1906      && test -f ../ld/Makefile \
1907      && test x$build = x$host; then
1908         gcc_cv_ld=../ld/ld-new$build_exeext
1909 elif test -x collect-ld$build_exeext; then
1910         # Build using linker in the current directory.
1911         gcc_cv_ld=./collect-ld$build_exeext
1912 elif test -x $LD_FOR_TARGET; then
1913         gcc_cv_ld="$LD_FOR_TARGET"
1914 else
1915         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1916 fi])
1917
1918 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1919 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1920
1921 AC_MSG_CHECKING(what linker to use)
1922 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1923         # Single tree build which includes ld.  We want to prefer it
1924         # over whatever linker top-level may have detected, since
1925         # we'll use what we're building after installation anyway.
1926         AC_MSG_RESULT(newly built ld)
1927         in_tree_ld=yes
1928         in_tree_ld_is_elf=no
1929         if (grep 'EMUL = .*elf' ../ld/Makefile \
1930             || grep 'EMUL = .*linux' ../ld/Makefile \
1931             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1932           in_tree_ld_is_elf=yes
1933         fi
1934         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1935         do
1936 changequote(,)dnl
1937                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1938                 if test x$gcc_cv_gld_version != x; then
1939                         break
1940                 fi
1941         done
1942         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1943         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1944 changequote([,])dnl
1945 else
1946         AC_MSG_RESULT($gcc_cv_ld)
1947         in_tree_ld=no
1948 fi
1949
1950 # Figure out what nm we will be using.
1951 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1952 AS_VAR_SET_IF(gcc_cv_nm,, [
1953 if test -f $gcc_cv_binutils_srcdir/configure.in \
1954      && test -f ../binutils/Makefile; then
1955         gcc_cv_nm=../binutils/nm-new$build_exeext
1956 elif test -x nm$build_exeext; then
1957         gcc_cv_nm=./nm$build_exeext
1958 elif test -x $NM_FOR_TARGET; then
1959         gcc_cv_nm="$NM_FOR_TARGET"
1960 else
1961         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1962 fi])
1963
1964 AC_MSG_CHECKING(what nm to use)
1965 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1966         # Single tree build which includes binutils.
1967         AC_MSG_RESULT(newly built nm)
1968         in_tree_nm=yes
1969 else
1970         AC_MSG_RESULT($gcc_cv_nm)
1971         in_tree_nm=no
1972 fi
1973
1974 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1975 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1976
1977 # Figure out what objdump we will be using.
1978 AS_VAR_SET_IF(gcc_cv_objdump,, [
1979 if test -f $gcc_cv_binutils_srcdir/configure.in \
1980      && test -f ../binutils/Makefile; then
1981         # Single tree build which includes binutils.
1982         gcc_cv_objdump=../binutils/objdump$build_exeext
1983 elif test -x objdump$build_exeext; then
1984         gcc_cv_objdump=./objdump$build_exeext
1985 elif test -x $OBJDUMP_FOR_TARGET; then
1986         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1987 else
1988         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1989 fi])
1990
1991 AC_MSG_CHECKING(what objdump to use)
1992 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1993         # Single tree build which includes binutils.
1994         AC_MSG_RESULT(newly built objdump)
1995 elif test x$gcc_cv_objdump = x; then
1996         AC_MSG_RESULT(not found)
1997 else
1998         AC_MSG_RESULT($gcc_cv_objdump)
1999 fi
2000
2001 # Figure out what assembler alignment features are present.
2002 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2003  [2,6,0],,
2004 [.balign 4
2005 .p2align 2],,
2006 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2007   [Define if your assembler supports .balign and .p2align.])])
2008
2009 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2010  [2,8,0],,
2011  [.p2align 4,,7],,
2012 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2013   [Define if your assembler supports specifying the maximum number
2014    of bytes to skip when using the GAS .p2align command.])])
2015
2016 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2017  [elf,2,9,0],,
2018  [conftest_label1: .word 0
2019 .subsection -1
2020 conftest_label2: .word 0
2021 .previous],
2022  [if test x$gcc_cv_nm != x; then
2023     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2024     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2025     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2026     then :
2027     else gcc_cv_as_subsection_m1=yes
2028     fi
2029     rm -f conftest.nm1 conftest.nm2
2030   fi],
2031  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2032   [Define if your assembler supports .subsection and .subsection -1 starts
2033    emitting at the beginning of your section.])])
2034
2035 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2036  [2,2,0],,
2037  [      .weak foobar],,
2038 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2039
2040 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2041  [2,17,0],,
2042  [      .weakref foobar, barfnot],,
2043 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2044
2045 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2046  [2,15,91],,
2047  [      .SPACE $TEXT$
2048         .NSUBSPA $CODE$,COMDAT],,
2049 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2050
2051 # .hidden needs to be supported in both the assembler and the linker,
2052 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2053 # This is irritatingly difficult to feature test for; we have to check the
2054 # date string after the version number.  If we've got an in-tree
2055 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2056 # to be safe.
2057 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2058 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2059  [elf,2,13,0],,
2060 [       .hidden foobar
2061 foobar:])
2062
2063 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2064 [if test $in_tree_ld = yes ; then
2065   gcc_cv_ld_hidden=no
2066   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2067      && test $in_tree_ld_is_elf = yes; then
2068      gcc_cv_ld_hidden=yes
2069   fi
2070 else
2071   gcc_cv_ld_hidden=yes
2072   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2073   if echo "$ld_ver" | grep GNU > /dev/null; then
2074 changequote(,)dnl
2075     ld_vers=`echo $ld_ver | sed -n \
2076         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2077         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2078         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2079         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2080         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2081         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2082         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   ].*$,\1,p'`
2083     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2084     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2085     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2086     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2087     if test 0"$ld_date" -lt 20020404; then
2088       if test -n "$ld_date"; then
2089         # If there was date string, but was earlier than 2002-04-04, fail
2090         gcc_cv_ld_hidden=no
2091       elif test -z "$ld_vers"; then
2092         # If there was no date string nor ld version number, something is wrong
2093         gcc_cv_ld_hidden=no
2094       else
2095         test -z "$ld_vers_patch" && ld_vers_patch=0
2096         if test "$ld_vers_major" -lt 2; then
2097           gcc_cv_ld_hidden=no
2098         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2099           gcc_cv_ld_hidden="no"
2100         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2101           gcc_cv_ld_hidden=no
2102         fi
2103       fi
2104 changequote([,])dnl
2105     fi
2106   else
2107     case "${target}" in
2108       hppa64*-*-hpux* | ia64*-*-hpux*)
2109         gcc_cv_ld_hidden=yes
2110         ;;
2111       *)
2112         gcc_cv_ld_hidden=no
2113         ;;
2114     esac
2115   fi
2116 fi])
2117 libgcc_visibility=no
2118 AC_SUBST(libgcc_visibility)
2119 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2120 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2121   libgcc_visibility=yes
2122   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2123   [Define if your assembler and linker support .hidden.])
2124 fi
2125
2126 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2127 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2128   [elf,2,11,0],,
2129 [       .data
2130         .uleb128 L2 - L1
2131 L1:
2132         .uleb128 1280
2133         .sleb128 -1010
2134 L2:],
2135  [# GAS versions before 2.11 do not support uleb128,
2136   # despite appearing to.
2137   # ??? There exists an elf-specific test that will crash
2138   # the assembler.  Perhaps it's better to figure out whether
2139   # arbitrary sections are supported and try the test.
2140   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2141   if echo "$as_ver" | grep GNU > /dev/null; then
2142 changequote(,)dnl
2143     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2144     as_major=`echo $as_ver | sed 's/\..*//'`
2145     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2146 changequote([,])dnl
2147     if test $as_major -eq 2 && test $as_minor -lt 11
2148     then :
2149     else gcc_cv_as_leb128=yes
2150     fi
2151   fi],
2152   [AC_DEFINE(HAVE_AS_LEB128, 1,
2153     [Define if your assembler supports .sleb128 and .uleb128.])])
2154
2155 # GAS versions up to and including 2.11.0 may mis-optimize
2156 # .eh_frame data.
2157 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2158   [elf,2,12,0],,
2159 [       .text
2160 .LFB1:
2161         .4byte  0
2162 .L1:
2163         .4byte  0
2164 .LFE1:
2165         .section        .eh_frame,"aw",@progbits
2166 __FRAME_BEGIN__:
2167         .4byte  .LECIE1-.LSCIE1
2168 .LSCIE1:
2169         .4byte  0x0
2170         .byte   0x1
2171         .ascii "z\0"
2172         .byte   0x1
2173         .byte   0x78
2174         .byte   0x1a
2175         .byte   0x0
2176         .byte   0x4
2177         .4byte  1
2178         .p2align 1
2179 .LECIE1:
2180 .LSFDE1:
2181         .4byte  .LEFDE1-.LASFDE1
2182 .LASFDE1:
2183         .4byte  .LASFDE1-__FRAME_BEGIN__
2184         .4byte  .LFB1
2185         .4byte  .LFE1-.LFB1
2186         .byte   0x4
2187         .4byte  .LFE1-.LFB1
2188         .byte   0x4
2189         .4byte  .L1-.LFB1
2190 .LEFDE1:],
2191 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2192 cat > conftest.lit <<EOF
2193  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2194  0010 01000000 12000000 18000000 00000000  ................
2195  0020 08000000 04080000 0044               .........D      @&t@
2196 EOF
2197 cat > conftest.big <<EOF
2198  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2199  0010 00000001 00000012 00000018 00000000  ................
2200  0020 00000008 04000000 0844               .........D      @&t@
2201 EOF
2202   # If the assembler didn't choke, and we can objdump,
2203   # and we got the correct data, then succeed.
2204   if test x$gcc_cv_objdump != x \
2205   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2206      | tail -3 > conftest.got \
2207   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2208     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2209   then
2210     gcc_cv_as_eh_frame=yes
2211   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2212     gcc_cv_as_eh_frame=buggy
2213   else
2214     # Uh oh, what do we do now?
2215     gcc_cv_as_eh_frame=no
2216   fi])
2217
2218 if test $gcc_cv_as_eh_frame = buggy; then
2219   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2220   [Define if your assembler mis-optimizes .eh_frame data.])
2221 fi
2222
2223 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2224  [elf,2,12,0], [--fatal-warnings],
2225  [.section .rodata.str, "aMS", @progbits, 1])
2226 if test $gcc_cv_as_shf_merge = no; then
2227   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2228     [elf,2,12,0], [--fatal-warnings],
2229     [.section .rodata.str, "aMS", %progbits, 1])
2230 fi
2231 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2232   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2233 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2234
2235 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2236  [elf,2,16,0], [--fatal-warnings],
2237  [.section .text,"axG",@progbits,.foo,comdat])
2238 if test $gcc_cv_as_comdat_group = yes; then
2239   gcc_cv_as_comdat_group_percent=no
2240 else
2241  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2242    [elf,2,16,0], [--fatal-warnings],
2243    [.section .text,"axG",%progbits,.foo,comdat])
2244 fi
2245 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2246   comdat_group=yes
2247   if test 0"$ld_date" -lt 20050308; then
2248     if test -n "$ld_date"; then
2249       # If there was date string, but was earlier than 2005-03-08, fail
2250       comdat_group=no
2251     elif test "$ld_vers_major" -lt 2; then
2252       comdat_group=no
2253     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2254       comdat_group=no
2255     fi
2256   fi
2257   if test $comdat_group = no; then
2258     gcc_cv_as_comdat_group=no
2259     gcc_cv_as_comdat_group_percent=no
2260   fi
2261 fi
2262 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2263   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2264 [Define 0/1 if your assembler and linker support COMDAT groups.])
2265
2266 # Thread-local storage - the check is heavily parametrized.
2267 conftest_s=
2268 tls_first_major=
2269 tls_first_minor=
2270 tls_as_opt=
2271 case "$target" in
2272 changequote(,)dnl
2273   alpha*-*-*)
2274     conftest_s='
2275         .section ".tdata","awT",@progbits
2276 foo:    .long   25
2277         .text
2278         ldq     $27,__tls_get_addr($29)         !literal!1
2279         lda     $16,foo($29)                    !tlsgd!1
2280         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2281         ldq     $27,__tls_get_addr($29)         !literal!2
2282         lda     $16,foo($29)                    !tlsldm!2
2283         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2284         ldq     $1,foo($29)                     !gotdtprel
2285         ldah    $2,foo($29)                     !dtprelhi
2286         lda     $3,foo($2)                      !dtprello
2287         lda     $4,foo($29)                     !dtprel
2288         ldq     $1,foo($29)                     !gottprel
2289         ldah    $2,foo($29)                     !tprelhi
2290         lda     $3,foo($2)                      !tprello
2291         lda     $4,foo($29)                     !tprel'
2292         tls_first_major=2
2293         tls_first_minor=13
2294         tls_as_opt=--fatal-warnings
2295         ;;
2296   frv*-*-*)
2297     conftest_s='
2298         .section ".tdata","awT",@progbits
2299 x:      .long   25
2300         .text
2301         call    #gettlsoff(x)'
2302         tls_first_major=2
2303         tls_first_minor=14
2304         ;;
2305   hppa*-*-linux*)
2306     conftest_s='
2307 t1:     .reg    %r20
2308 t2:     .reg    %r21
2309 gp:     .reg    %r19
2310         .section ".tdata","awT",@progbits
2311 foo:    .long   25
2312         .text
2313         .align  4
2314         addil LT%foo-$tls_gdidx$,gp
2315         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2316         b __tls_get_addr
2317         nop
2318         addil LT%foo-$tls_ldidx$,gp
2319         b __tls_get_addr
2320         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2321         addil LR%foo-$tls_dtpoff$,%ret0
2322         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2323         mfctl %cr27,%t1
2324         addil LT%foo-$tls_ieoff$,gp
2325         ldw RT%foo-$tls_ieoff$(%r1),%t2
2326         add %t1,%t2,%t3
2327         mfctl %cr27,%t1
2328         addil LR%foo-$tls_leoff$,%t1
2329         ldo RR%foo-$tls_leoff$(%r1),%t2'
2330         tls_first_major=2
2331         tls_first_minor=15
2332         tls_as_opt=--fatal-warnings
2333         ;;
2334   arm*-*-*)
2335     conftest_s='
2336         .section ".tdata","awT",%progbits
2337 foo:    .long   25
2338         .text
2339 .word foo(gottpoff)
2340 .word foo(tpoff)
2341 .word foo(tlsgd)
2342 .word foo(tlsldm)
2343 .word foo(tlsldo)'
2344         tls_first_major=2
2345         tls_first_minor=17
2346         ;;
2347   i[34567]86-*-*)
2348     conftest_s='
2349         .section ".tdata","awT",@progbits
2350 foo:    .long   25
2351         .text
2352         movl    %gs:0, %eax
2353         leal    foo@TLSGD(,%ebx,1), %eax
2354         leal    foo@TLSLDM(%ebx), %eax
2355         leal    foo@DTPOFF(%eax), %edx
2356         movl    foo@GOTTPOFF(%ebx), %eax
2357         subl    foo@GOTTPOFF(%ebx), %eax
2358         addl    foo@GOTNTPOFF(%ebx), %eax
2359         movl    foo@INDNTPOFF, %eax
2360         movl    $foo@TPOFF, %eax
2361         subl    $foo@TPOFF, %eax
2362         leal    foo@NTPOFF(%ecx), %eax'
2363         tls_first_major=2
2364         tls_first_minor=14
2365         tls_as_opt=--fatal-warnings
2366         ;;
2367   x86_64-*-*)
2368     conftest_s='
2369         .section ".tdata","awT",@progbits
2370 foo:    .long   25
2371         .text
2372         movq    %fs:0, %rax
2373         leaq    foo@TLSGD(%rip), %rdi
2374         leaq    foo@TLSLD(%rip), %rdi
2375         leaq    foo@DTPOFF(%rax), %rdx
2376         movq    foo@GOTTPOFF(%rip), %rax
2377         movq    $foo@TPOFF, %rax'
2378         tls_first_major=2
2379         tls_first_minor=14
2380         tls_as_opt=--fatal-warnings
2381         ;;
2382   ia64-*-*)
2383     conftest_s='
2384         .section ".tdata","awT",@progbits
2385 foo:    data8   25
2386         .text
2387         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2388         addl    r17 = @ltoff(@dtprel(foo#)), gp
2389         addl    r18 = @ltoff(@tprel(foo#)), gp
2390         addl    r19 = @dtprel(foo#), gp
2391         adds    r21 = @dtprel(foo#), r13
2392         movl    r23 = @dtprel(foo#)
2393         addl    r20 = @tprel(foo#), gp
2394         adds    r22 = @tprel(foo#), r13
2395         movl    r24 = @tprel(foo#)'
2396         tls_first_major=2
2397         tls_first_minor=13
2398         tls_as_opt=--fatal-warnings
2399         ;;
2400   mips*-*-*)
2401     conftest_s='
2402         .section .tdata,"awT",@progbits
2403 x:
2404         .word 2
2405         .text
2406         addiu $4, $28, %tlsgd(x)
2407         addiu $4, $28, %tlsldm(x)
2408         lui $4, %dtprel_hi(x)
2409         addiu $4, $4, %dtprel_lo(x)
2410         lw $4, %gottprel(x)($28)
2411         lui $4, %tprel_hi(x)
2412         addiu $4, $4, %tprel_lo(x)'
2413         tls_first_major=2
2414         tls_first_minor=16
2415         tls_as_opt='-32 --fatal-warnings'
2416         ;;
2417   powerpc-*-*)
2418     conftest_s='
2419         .section ".tdata","awT",@progbits
2420         .align 2
2421 ld0:    .space 4
2422 ld1:    .space 4
2423 x1:     .space 4
2424 x2:     .space 4
2425 x3:     .space 4
2426         .text
2427         addi 3,31,ld0@got@tlsgd
2428         bl __tls_get_addr
2429         addi 3,31,x1@got@tlsld
2430         bl __tls_get_addr
2431         addi 9,3,x1@dtprel
2432         addis 9,3,x2@dtprel@ha
2433         addi 9,9,x2@dtprel@l
2434         lwz 9,x3@got@tprel(31)
2435         add 9,9,x@tls
2436         addi 9,2,x1@tprel
2437         addis 9,2,x2@tprel@ha
2438         addi 9,9,x2@tprel@l'
2439         tls_first_major=2
2440         tls_first_minor=14
2441         tls_as_opt="-a32 --fatal-warnings"
2442         ;;
2443   powerpc64-*-*)
2444     conftest_s='
2445         .section ".tdata","awT",@progbits
2446         .align 3
2447 ld0:    .space 8
2448 ld1:    .space 8
2449 x1:     .space 8
2450 x2:     .space 8
2451 x3:     .space 8
2452         .text
2453         addi 3,2,ld0@got@tlsgd
2454         bl .__tls_get_addr
2455         nop
2456         addi 3,2,ld1@toc
2457         bl .__tls_get_addr
2458         nop
2459         addi 3,2,x1@got@tlsld
2460         bl .__tls_get_addr
2461         nop
2462         addi 9,3,x1@dtprel
2463         bl .__tls_get_addr
2464         nop
2465         addis 9,3,x2@dtprel@ha
2466         addi 9,9,x2@dtprel@l
2467         bl .__tls_get_addr
2468         nop
2469         ld 9,x3@got@dtprel(2)
2470         add 9,9,3
2471         bl .__tls_get_addr
2472         nop'
2473         tls_first_major=2
2474         tls_first_minor=14
2475         tls_as_opt="-a64 --fatal-warnings"
2476         ;;
2477   s390-*-*)
2478     conftest_s='
2479         .section ".tdata","awT",@progbits
2480 foo:    .long   25
2481         .text
2482         .long   foo@TLSGD
2483         .long   foo@TLSLDM
2484         .long   foo@DTPOFF
2485         .long   foo@NTPOFF
2486         .long   foo@GOTNTPOFF
2487         .long   foo@INDNTPOFF
2488         l       %r1,foo@GOTNTPOFF(%r12)
2489         l       %r1,0(%r1):tls_load:foo
2490         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2491         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2492         tls_first_major=2
2493         tls_first_minor=14
2494         tls_as_opt="-m31 --fatal-warnings"
2495         ;;
2496   s390x-*-*)
2497     conftest_s='
2498         .section ".tdata","awT",@progbits
2499 foo:    .long   25
2500         .text
2501         .quad   foo@TLSGD
2502         .quad   foo@TLSLDM
2503         .quad   foo@DTPOFF
2504         .quad   foo@NTPOFF
2505         .quad   foo@GOTNTPOFF
2506         lg      %r1,foo@GOTNTPOFF(%r12)
2507         larl    %r1,foo@INDNTPOFF
2508         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2509         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2510         tls_first_major=2
2511         tls_first_minor=14
2512         tls_as_opt="-m64 -Aesame --fatal-warnings"
2513         ;;
2514   sh-*-* | sh[34]-*-*)
2515     conftest_s='
2516         .section ".tdata","awT",@progbits
2517 foo:    .long   25
2518         .text
2519         .long   foo@TLSGD
2520         .long   foo@TLSLDM
2521         .long   foo@DTPOFF
2522         .long   foo@GOTTPOFF
2523         .long   foo@TPOFF'
2524         tls_first_major=2
2525         tls_first_minor=13
2526         tls_as_opt=--fatal-warnings
2527         ;;
2528   sparc*-*-*)
2529     case "$target" in
2530       sparc*-sun-solaris2.*)
2531         on_solaris=yes
2532         ;;
2533       *)
2534         on_solaris=no
2535         ;;
2536     esac
2537     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2538       conftest_s='
2539         .section ".tdata",#alloc,#write,#tls
2540 foo:    .long   25
2541         .text
2542         sethi   %tgd_hi22(foo), %o0
2543         add     %o0, %tgd_lo10(foo), %o1
2544         add     %l7, %o1, %o0, %tgd_add(foo)
2545         call    __tls_get_addr, %tgd_call(foo)
2546         sethi   %tldm_hi22(foo), %l1
2547         add     %l1, %tldm_lo10(foo), %l2
2548         add     %l7, %l2, %o0, %tldm_add(foo)
2549         call    __tls_get_addr, %tldm_call(foo)
2550         sethi   %tldo_hix22(foo), %l3
2551         xor     %l3, %tldo_lox10(foo), %l4
2552         add     %o0, %l4, %l5, %tldo_add(foo)
2553         sethi   %tie_hi22(foo), %o3
2554         add     %o3, %tie_lo10(foo), %o3
2555         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2556         add     %g7, %o2, %o4, %tie_add(foo)
2557         sethi   %tle_hix22(foo), %l1
2558         xor     %l1, %tle_lox10(foo), %o5
2559         ld      [%g7 + %o5], %o1'
2560         tls_first_major=0
2561         tls_first_minor=0
2562     else
2563       conftest_s='
2564         .section ".tdata","awT",@progbits
2565 foo:    .long   25
2566         .text
2567         sethi   %tgd_hi22(foo), %o0
2568         add     %o0, %tgd_lo10(foo), %o1
2569         add     %l7, %o1, %o0, %tgd_add(foo)
2570         call    __tls_get_addr, %tgd_call(foo)
2571         sethi   %tldm_hi22(foo), %l1
2572         add     %l1, %tldm_lo10(foo), %l2
2573         add     %l7, %l2, %o0, %tldm_add(foo)
2574         call    __tls_get_addr, %tldm_call(foo)
2575         sethi   %tldo_hix22(foo), %l3
2576         xor     %l3, %tldo_lox10(foo), %l4
2577         add     %o0, %l4, %l5, %tldo_add(foo)
2578         sethi   %tie_hi22(foo), %o3
2579         add     %o3, %tie_lo10(foo), %o3
2580         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2581         add     %g7, %o2, %o4, %tie_add(foo)
2582         sethi   %tle_hix22(foo), %l1
2583         xor     %l1, %tle_lox10(foo), %o5
2584         ld      [%g7 + %o5], %o1'
2585         tls_first_major=2
2586         tls_first_minor=14
2587         tls_as_opt="-32 --fatal-warnings"
2588       fi
2589         ;;
2590 changequote([,])dnl
2591 esac
2592 set_have_as_tls=no
2593 if test "x$enable_tls" = xno ; then
2594   : # TLS explicitly disabled.
2595 elif test "x$enable_tls" = xyes ; then
2596   set_have_as_tls=yes # TLS explicitly enabled.
2597 elif test -z "$tls_first_major"; then
2598   : # If we don't have a check, assume no support.
2599 else
2600   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2601   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2602   [set_have_as_tls=yes])
2603 fi
2604 if test $set_have_as_tls = yes ; then
2605   AC_DEFINE(HAVE_AS_TLS, 1,
2606             [Define if your assembler supports thread-local storage.])
2607 fi
2608
2609 # Target-specific assembler checks.
2610
2611 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2612 gcc_cv_ld_static_dynamic=no
2613 if test $in_tree_ld = yes ; then
2614   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2615     gcc_cv_ld_static_dynamic=yes
2616   fi
2617 elif test x$gcc_cv_ld != x; then
2618         # Check if linker supports -Bstatic/-Bdynamic option
2619         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2620           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2621                 gcc_cv_ld_static_dynamic=yes
2622         fi
2623 fi
2624 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2625         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2626 [Define if your linker supports -Bstatic/-Bdynamic option.])
2627 fi
2628 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2629
2630 if test x"$demangler_in_ld" = xyes; then
2631   AC_MSG_CHECKING(linker --demangle support)
2632   gcc_cv_ld_demangle=no
2633   if test $in_tree_ld = yes; then
2634     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2635       gcc_cv_ld_demangle=yes
2636     fi
2637   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2638     # Check if the GNU linker supports --demangle option
2639     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2640       gcc_cv_ld_demangle=yes
2641     fi
2642   fi
2643   if test x"$gcc_cv_ld_demangle" = xyes; then
2644     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2645 [Define if your linker supports --demangle option.])
2646   fi
2647   AC_MSG_RESULT($gcc_cv_ld_demangle)
2648 fi
2649
2650 case "$target" in
2651   # All TARGET_ABI_OSF targets.
2652   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2653     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2654         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2655 [       .set nomacro
2656         .text
2657         extbl   $3, $2, $3      !lituse_bytoff!1
2658         ldq     $2, a($29)      !literal!1
2659         ldq     $4, b($29)      !literal!2
2660         ldq_u   $3, 0($2)       !lituse_base!1
2661         ldq     $27, f($29)     !literal!5
2662         jsr     $26, ($27), f   !lituse_jsr!5
2663         ldah    $29, 0($26)     !gpdisp!3
2664         lda     $0, c($29)      !gprel
2665         ldah    $1, d($29)      !gprelhigh
2666         lda     $1, d($1)       !gprellow
2667         lda     $29, 0($29)     !gpdisp!3],,
2668     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2669   [Define if your assembler supports explicit relocations.])])
2670     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2671         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2672 [       .set nomacro
2673         .text
2674         ldq     $27, a($29)     !literal!1
2675         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2676     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2677   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2678     ;;
2679
2680   cris-*-*)
2681     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2682       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2683       [-no-mul-bug-abort], [.text],,
2684       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2685                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2686     ;;
2687
2688   sparc*-*-*)
2689     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2690       [.register %g2, #scratch],,
2691       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2692                 [Define if your assembler supports .register.])])
2693
2694     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2695       [-relax], [.text],,
2696       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2697                 [Define if your assembler supports -relax option.])])
2698
2699     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2700       gcc_cv_as_sparc_ua_pcrel,,
2701       [-K PIC],
2702 [.text
2703 foo:
2704         nop
2705 .data
2706 .align 4
2707 .byte 0
2708 .uaword %r_disp32(foo)],
2709       [if test x$gcc_cv_ld != x \
2710        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2711          gcc_cv_as_sparc_ua_pcrel=yes
2712        fi
2713        rm -f conftest],
2714       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2715                 [Define if your assembler and linker support unaligned PC relative relocs.])
2716
2717       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2718         gcc_cv_as_sparc_ua_pcrel_hidden,,
2719         [-K PIC],
2720 [.data
2721 .align 4
2722 .byte 0x31
2723 .uaword %r_disp32(foo)
2724 .byte 0x32, 0x33, 0x34
2725 .global foo
2726 .hidden foo
2727 foo:
2728 .skip 4],
2729         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2730          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2731          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2732             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2733             if $gcc_cv_objdump -R conftest 2> /dev/null \
2734                | grep 'DISP32' > /dev/null 2>&1; then
2735                 :
2736             else
2737                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2738             fi
2739          fi
2740          rm -f conftest],
2741          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2742                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2743     ]) # unaligned pcrel relocs
2744
2745     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2746       gcc_cv_as_sparc_offsetable_lo10,,
2747       [-xarch=v9],
2748 [.text
2749         or %g1, %lo(ab) + 12, %g1
2750         or %g1, %lo(ab + 12), %g1],
2751       [if test x$gcc_cv_objdump != x \
2752        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2753           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2754          gcc_cv_as_sparc_offsetable_lo10=yes
2755        fi],
2756        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2757                  [Define if your assembler supports offsetable %lo().])])
2758     ;;
2759
2760 changequote(,)dnl
2761   i[34567]86-*-* | x86_64-*-*)
2762 changequote([,])dnl
2763     case $target_os in
2764       cygwin* | pe | mingw32*)
2765         # Used for DWARF 2 in PE
2766         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2767           gcc_cv_as_ix86_pe_secrel32,
2768           [2,15,91],,
2769 [.text
2770 foo:    nop
2771 .data
2772         .secrel32 foo],
2773           [if test x$gcc_cv_ld != x \
2774            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2775              gcc_cv_as_ix86_pe_secrel32=yes
2776            fi
2777            rm -f conftest],
2778           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2779             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2780         ;;
2781     esac
2782
2783     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2784        gcc_cv_as_ix86_filds_fists,
2785       [2,9,0],, [filds mem; fists mem],,
2786       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2787         [Define if your assembler uses the new HImode fild and fist notation.])])
2788
2789     gcc_GAS_CHECK_FEATURE([cmov syntax],
2790       gcc_cv_as_ix86_cmov_sun_syntax,,,
2791       [cmovl.l %edx, %eax],,
2792       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2793         [Define if your assembler supports the Sun syntax for cmov.])])
2794
2795     # This one is used unconditionally by i386.[ch]; it is to be defined
2796     # to 1 if the feature is present, 0 otherwise.
2797     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2798         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2799 [       .text
2800 .L0:
2801         nop
2802         .data
2803         .long .L0@GOTOFF])
2804     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2805       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2806       [Define true if the assembler supports '.long foo@GOTOFF'.])
2807     ;;
2808
2809   ia64*-*-*)
2810     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2811         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2812 [       .text
2813         addl r15 = @ltoffx(x#), gp
2814         ;;
2815         ld8.mov r16 = [[r15]], x#],,
2816     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2817           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2818
2819     ;;
2820
2821   powerpc*-*-*)
2822     case $target in
2823       *-*-aix*) conftest_s='    .machine "pwr5"
2824         .csect .text[[PR]]
2825         mfcr 3,128';;
2826       *-*-darwin*)
2827         gcc_GAS_CHECK_FEATURE([.machine directive support],
2828           gcc_cv_as_machine_directive,,,
2829           [     .machine ppc7400])
2830         if test x$gcc_cv_as_machine_directive != xyes; then
2831           echo "*** This target requires an assembler supporting \".machine\"" >&2
2832           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2833           test x$build = x$target && exit 1
2834         fi
2835         conftest_s='    .text
2836         mfcr r3,128';;
2837       *) conftest_s='   .machine power4
2838         .text
2839         mfcr 3,128';;
2840     esac
2841
2842     gcc_GAS_CHECK_FEATURE([mfcr field support],
2843       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2844       [$conftest_s],,
2845       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2846           [Define if your assembler supports mfcr field.])])
2847
2848     case $target in
2849       *-*-aix*) conftest_s='    .machine "pwr5"
2850         .csect .text[[PR]]
2851         popcntb 3,3';;
2852       *) conftest_s='   .machine power5
2853         .text
2854         popcntb 3,3';;
2855     esac
2856
2857     gcc_GAS_CHECK_FEATURE([popcntb support],
2858       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2859       [$conftest_s],,
2860       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2861           [Define if your assembler supports popcntb field.])])
2862
2863     case $target in
2864       *-*-aix*) conftest_s='    .machine "pwr5x"
2865         .csect .text[[PR]]
2866         frin 1,1';;
2867       *) conftest_s='   .machine power5
2868         .text
2869         frin 1,1';;
2870     esac
2871
2872     gcc_GAS_CHECK_FEATURE([fp round support],
2873       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2874       [$conftest_s],,
2875       [AC_DEFINE(HAVE_AS_FPRND, 1,
2876           [Define if your assembler supports fprnd.])])
2877
2878     case $target in
2879       *-*-aix*) conftest_s='    .csect .text[[PR]]
2880 LCF..0:
2881         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2882       *-*-darwin*)
2883         conftest_s='    .text
2884 LCF0:
2885         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2886       *) conftest_s='   .text
2887 .LCF0:
2888         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2889     esac
2890
2891     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2892       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2893       [$conftest_s],,
2894       [AC_DEFINE(HAVE_AS_REL16, 1,
2895           [Define if your assembler supports R_PPC_REL16 relocs.])])
2896     ;;
2897
2898   mips*-*-*)
2899     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2900       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2901 [       lw $4,%gp_rel(foo)($4)],,
2902       [if test x$target_cpu_default = x
2903        then target_cpu_default=MASK_EXPLICIT_RELOCS
2904        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2905        fi])
2906     ;;
2907 esac
2908
2909 # Mips and HP-UX need the GNU assembler.
2910 # Linux on IA64 might be able to use the Intel assembler.
2911
2912 case "$target" in
2913   mips*-*-* | *-*-hpux* )
2914     if test x$gas_flag = xyes \
2915        || test x"$host" != x"$build" \
2916        || test ! -x "$gcc_cv_as" \
2917        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2918       :
2919     else
2920       echo "*** This configuration requires the GNU assembler" >&2
2921       exit 1
2922     fi
2923     ;;
2924 esac
2925
2926 # ??? Not all targets support dwarf2 debug_line, even within a version
2927 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2928 # info to the output file.  So, as supported targets are added to gas 2.11,
2929 # add some instruction here to (also) show we expect this might work.
2930 # ??? Once 2.11 is released, probably need to add first known working
2931 # version to the per-target configury.
2932 case "$target" in
2933   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2934   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2935   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-*)
2936     insn="nop"
2937     ;;
2938   ia64*-*-* | s390*-*-*)
2939     insn="nop 0"
2940     ;;
2941   mmix-*-*)
2942     insn="swym 0"
2943     ;;
2944 esac
2945 if test x"$insn" != x; then
2946  conftest_s="\
2947         .file 1 \"conftest.s\"
2948         .loc 1 3 0
2949         $insn"
2950  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2951   gcc_cv_as_dwarf2_debug_line,
2952   [elf,2,11,0],, [$conftest_s],
2953   [if test x$gcc_cv_objdump != x \
2954    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2955       | grep debug_line > /dev/null 2>&1; then
2956      gcc_cv_as_dwarf2_debug_line=yes
2957    fi])
2958
2959 # The .debug_line file table must be in the exact order that
2960 # we specified the files, since these indices are also used
2961 # by DW_AT_decl_file.  Approximate this test by testing if
2962 # the assembler bitches if the same index is assigned twice.
2963  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2964   gcc_cv_as_dwarf2_file_buggy,,,
2965 [       .file 1 "foo.s"
2966         .file 1 "bar.s"])
2967
2968  if test $gcc_cv_as_dwarf2_debug_line = yes \
2969  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2970         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2971   [Define if your assembler supports dwarf2 .file/.loc directives,
2972    and preserves file table indices exactly as given.])
2973  fi
2974
2975  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2976   gcc_cv_as_gdwarf2_flag,
2977   [elf,2,11,0], [--gdwarf2], [$insn],,
2978   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2979 [Define if your assembler supports the --gdwarf2 option.])])
2980
2981  gcc_GAS_CHECK_FEATURE([--gstabs option],
2982   gcc_cv_as_gstabs_flag,
2983   [elf,2,11,0], [--gstabs], [$insn],
2984   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2985    # and warns about it, but still exits successfully.  So check for
2986    # this.
2987    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2988    then :
2989    else gcc_cv_as_gstabs_flag=yes
2990    fi],
2991   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2992 [Define if your assembler supports the --gstabs option.])])
2993 fi
2994
2995 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2996 gcc_cv_ld_ro_rw_mix=unknown
2997 if test $in_tree_ld = yes ; then
2998   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2999      && test $in_tree_ld_is_elf = yes; then
3000     gcc_cv_ld_ro_rw_mix=read-write
3001   fi
3002 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3003   echo '.section myfoosect, "a"' > conftest1.s
3004   echo '.section myfoosect, "aw"' > conftest2.s
3005   echo '.byte 1' >> conftest2.s
3006   echo '.section myfoosect, "a"' > conftest3.s
3007   echo '.byte 0' >> conftest3.s
3008   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3009      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3010      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3011      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3012         conftest2.o conftest3.o > /dev/null 2>&1; then
3013     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3014                          | sed -e '/myfoosect/!d' -e N`
3015     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3016       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3017         gcc_cv_ld_ro_rw_mix=read-only
3018       else
3019         gcc_cv_ld_ro_rw_mix=read-write
3020       fi
3021     fi
3022   fi
3023 changequote(,)dnl
3024   rm -f conftest.* conftest[123].*
3025 changequote([,])dnl
3026 fi
3027 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3028         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3029   [Define if your linker links a mix of read-only
3030    and read-write sections into a read-write section.])
3031 fi
3032 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3033
3034 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3035 gcc_cv_ld_eh_frame_hdr=no
3036 if test $in_tree_ld = yes ; then
3037   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3038      && test $in_tree_ld_is_elf = yes; then
3039     gcc_cv_ld_eh_frame_hdr=yes
3040   fi
3041 elif test x$gcc_cv_ld != x; then
3042         # Check if linker supports --eh-frame-hdr option
3043         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3044                 gcc_cv_ld_eh_frame_hdr=yes
3045         fi
3046 fi
3047 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3048 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3049         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3050 [Define if your linker supports --eh-frame-hdr option.])
3051 fi
3052 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3053
3054 AC_MSG_CHECKING(linker position independent executable support)
3055 gcc_cv_ld_pie=no
3056 if test $in_tree_ld = yes ; then
3057   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3058      && test $in_tree_ld_is_elf = yes; then
3059     gcc_cv_ld_pie=yes
3060   fi
3061 elif test x$gcc_cv_ld != x; then
3062         # Check if linker supports -pie option
3063         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3064                 gcc_cv_ld_pie=yes
3065         fi
3066 fi
3067 if test x"$gcc_cv_ld_pie" = xyes; then
3068         AC_DEFINE(HAVE_LD_PIE, 1,
3069 [Define if your linker supports -pie option.])
3070 fi
3071 AC_MSG_RESULT($gcc_cv_ld_pie)
3072
3073 # --------
3074 # UNSORTED
3075 # --------
3076
3077 AC_CACHE_CHECK(linker --as-needed support,
3078 gcc_cv_ld_as_needed,
3079 [gcc_cv_ld_as_needed=no
3080 if test $in_tree_ld = yes ; then
3081   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3082      && test $in_tree_ld_is_elf = yes; then
3083     gcc_cv_ld_as_needed=yes
3084   fi
3085 elif test x$gcc_cv_ld != x; then
3086         # Check if linker supports --as-needed and --no-as-needed options
3087         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3088                 gcc_cv_ld_as_needed=yes
3089         fi
3090 fi
3091 ])
3092 if test x"$gcc_cv_ld_as_needed" = xyes; then
3093         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3094 [Define if your linker supports --as-needed and --no-as-needed options.])
3095 fi
3096
3097 case "$target:$tm_file" in
3098   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3099     AC_CACHE_CHECK(linker support for omitting dot symbols,
3100     gcc_cv_ld_no_dot_syms,
3101     [gcc_cv_ld_no_dot_syms=no
3102     if test $in_tree_ld = yes ; then
3103       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3104         gcc_cv_ld_no_dot_syms=yes
3105       fi
3106     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3107       cat > conftest1.s <<EOF
3108         .text
3109         bl .foo
3110 EOF
3111       cat > conftest2.s <<EOF
3112         .section ".opd","aw"
3113         .align 3
3114         .globl foo
3115         .type foo,@function
3116 foo:
3117         .quad .LEfoo,.TOC.@tocbase,0
3118         .text
3119 .LEfoo:
3120         blr
3121         .size foo,.-.LEfoo
3122 EOF
3123       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3124          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3125          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3126         gcc_cv_ld_no_dot_syms=yes
3127       fi
3128       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3129     fi
3130     ])
3131     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3132       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3133     [Define if your PowerPC64 linker only needs function descriptor syms.])
3134     fi
3135     ;;
3136 esac
3137
3138 AC_CACHE_CHECK(linker --sysroot support,
3139   gcc_cv_ld_sysroot,
3140   [gcc_cv_ld_sysroot=no
3141   if test $in_tree_ld = yes ; then
3142       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3143         gcc_cv_ld_sysroot=yes
3144       fi
3145   elif test x$gcc_cv_ld != x; then
3146     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3147       gcc_cv_ld_sysroot=yes
3148     fi
3149   fi])
3150 if test x"$gcc_cv_ld_sysroot" = xyes; then
3151   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3152   [Define if your linker supports --sysroot.])
3153 fi
3154
3155 if test x$with_sysroot = x && test x$host = x$target \
3156    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
3157   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3158 [Define to PREFIX/include if cpp should also search that directory.])
3159 fi
3160
3161 # Test for stack protector support in target C library.
3162 case "$target" in
3163   *-*-linux*)
3164     AC_CACHE_CHECK(__stack_chk_fail in target GNU C library,
3165       gcc_cv_libc_provides_ssp,
3166       [gcc_cv_libc_provides_ssp=no
3167       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3168         if test "x$with_sysroot" = x; then
3169           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3170         elif test "x$with_sysroot" = xyes; then
3171           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3172         else
3173           glibc_header_dir="${with_sysroot}/usr/include"
3174         fi
3175       else
3176         glibc_header_dir=/usr/include
3177       fi
3178       # glibc 2.4 and later provides __stack_chk_fail and
3179       # either __stack_chk_guard, or TLS access to stack guard canary.
3180       if test -f $glibc_header_dir/features.h \
3181          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3182             $glibc_header_dir/features.h > /dev/null; then
3183         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3184            $glibc_header_dir/features.h > /dev/null; then
3185           gcc_cv_libc_provides_ssp=yes
3186         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3187              $glibc_header_dir/features.h > /dev/null \
3188              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3189              $glibc_header_dir/features.h > /dev/null; then
3190           gcc_cv_libc_provides_ssp=yes
3191         fi
3192       fi]) ;;
3193   *) gcc_cv_libc_provides_ssp=no ;;
3194 esac
3195 if test x$gcc_cv_libc_provides_ssp = xyes; then
3196   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3197             [Define if your target C library provides stack protector support])
3198 fi
3199
3200 # Find out what GC implementation we want, or may, use.
3201 AC_ARG_WITH(gc,
3202 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3203                           with the compiler],
3204 [case "$withval" in
3205   page)
3206     GGC=ggc-$withval
3207     ;;
3208   zone)
3209     GGC=ggc-$withval
3210     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3211     ;;
3212   *)
3213     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3214     ;;
3215 esac],
3216 [GGC=ggc-page])
3217 AC_SUBST(GGC)
3218 echo "Using $GGC for garbage collection."
3219
3220 # Use the system's zlib library.
3221 zlibdir=-L../zlib
3222 zlibinc="-I\$(srcdir)/../zlib"
3223 AC_ARG_WITH(system-zlib,
3224 [  --with-system-zlib      use installed libz],
3225 zlibdir=
3226 zlibinc=
3227 )
3228 AC_SUBST(zlibdir)
3229 AC_SUBST(zlibinc)
3230
3231 dnl Very limited version of automake's enable-maintainer-mode
3232
3233 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3234   dnl maintainer-mode is disabled by default
3235   AC_ARG_ENABLE(maintainer-mode,
3236 [  --enable-maintainer-mode
3237                           enable make rules and dependencies not useful
3238                           (and sometimes confusing) to the casual installer],
3239       maintainer_mode=$enableval,
3240       maintainer_mode=no)
3241
3242 AC_MSG_RESULT($maintainer_mode)
3243
3244 if test "$maintainer_mode" = "yes"; then
3245   MAINT=''
3246 else
3247   MAINT='#'
3248 fi
3249 AC_SUBST(MAINT)dnl
3250
3251 # --------------
3252 # Language hooks
3253 # --------------
3254
3255 # Make empty files to contain the specs and options for each language.
3256 # Then add #include lines to for a compiler that has specs and/or options.
3257
3258 lang_opt_files=
3259 lang_specs_files=
3260 lang_tree_files=
3261 for subdir in . $subdirs
3262 do
3263         if test -f $srcdir/$subdir/lang.opt; then
3264             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3265         fi
3266         if test -f $srcdir/$subdir/lang-specs.h; then
3267             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3268         fi
3269         if test -f $srcdir/$subdir/$subdir-tree.def; then
3270             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3271         fi
3272 done
3273
3274 # These (without "all_") are set in each config-lang.in.
3275 # `language' must be a single word so is spelled singularly.
3276 all_languages=
3277 all_boot_languages=
3278 all_compilers=
3279 all_stagestuff=
3280 all_outputs='Makefile gccbug mklibgcc libada-mk'
3281 # List of language makefile fragments.
3282 all_lang_makefrags=
3283 # List of language subdirectory makefiles.  Deprecated.
3284 all_lang_makefiles=
3285 # Files for gengtype
3286 all_gtfiles="$target_gtfiles"
3287 # Files for gengtype with language
3288 all_gtfiles_files_langs=
3289 all_gtfiles_files_files=
3290
3291 # Add the language fragments.
3292 # Languages are added via two mechanisms.  Some information must be
3293 # recorded in makefile variables, these are defined in config-lang.in.
3294 # We accumulate them and plug them into the main Makefile.
3295 # The other mechanism is a set of hooks for each of the main targets
3296 # like `clean', `install', etc.
3297
3298 language_hooks="Make-hooks"
3299
3300 for s in $subdirs
3301 do
3302                 language=
3303                 boot_language=
3304                 compilers=
3305                 stagestuff=
3306                 outputs=
3307                 gtfiles=
3308                 . ${srcdir}/$s/config-lang.in
3309                 if test "x$language" = x
3310                 then
3311                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3312                         exit 1
3313                 fi
3314                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3315                 if test -f ${srcdir}/$s/Makefile.in
3316                 then all_lang_makefiles="$s/Makefile"
3317                 fi
3318                 all_languages="$all_languages $language"
3319                 if test "x$boot_language" = xyes
3320                 then
3321                         all_boot_languages="$all_boot_languages $language"
3322                 fi
3323                 all_compilers="$all_compilers $compilers"
3324                 all_stagestuff="$all_stagestuff $stagestuff"
3325                 all_outputs="$all_outputs $outputs"
3326                 all_gtfiles="$all_gtfiles $gtfiles"
3327                 for f in $gtfiles
3328                 do
3329                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3330                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3331                 done
3332 done
3333
3334 # Pick up gtfiles for c
3335 gtfiles=
3336 s="c"
3337 . ${srcdir}/c-config-lang.in
3338 all_gtfiles="$all_gtfiles $gtfiles"
3339 for f in $gtfiles
3340 do
3341         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3342         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3343 done
3344
3345 check_languages=
3346 for language in $all_languages
3347 do
3348                 check_languages="$check_languages check-$language"
3349 done
3350
3351 # We link each language in with a set of hooks, reached indirectly via
3352 # lang.${target}.
3353
3354 rm -f Make-hooks
3355 touch Make-hooks
3356 target_list="all.cross start.encap rest.encap tags \
3357         install-common install-man \
3358         uninstall info man srcextra srcman srcinfo \
3359         mostlyclean clean distclean maintainer-clean \
3360         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3361 for t in $target_list
3362 do
3363         x=
3364         for lang in $all_languages
3365         do
3366                         x="$x $lang.$t"
3367         done
3368         echo "lang.$t: $x" >> Make-hooks
3369 done
3370
3371 # --------
3372 # UNSORTED
3373 # --------
3374
3375 # Create .gdbinit.
3376
3377 echo "dir ." > .gdbinit
3378 echo "dir ${srcdir}" >> .gdbinit
3379 if test x$gdb_needs_out_file_path = xyes
3380 then
3381         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3382 fi
3383 if test "x$subdirs" != x; then
3384         for s in $subdirs
3385         do
3386                 echo "dir ${srcdir}/$s" >> .gdbinit
3387         done
3388 fi
3389 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3390
3391 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3392 # absolute path for gcc_tooldir based on inserting the number of up-directory
3393 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3394 # $(libsubdir)/@(unlibsubdir) based path.
3395 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3396 # make and thus we'd get different behavior depending on where we built the
3397 # sources.
3398 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3399     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3400 else
3401 changequote(<<, >>)dnl
3402 # An explanation of the sed strings:
3403 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3404 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3405 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3406 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3407 #
3408 # (*) Note this pattern overwrites the first character of the string
3409 # with a forward slash if one is not already present.  This is not a
3410 # problem because the exact names of the sub-directories concerned is
3411 # unimportant, just the number of them matters.
3412 #
3413 # The practical upshot of these patterns is like this:
3414 #
3415 #  prefix     exec_prefix        result
3416 #  ------     -----------        ------
3417 #   /foo        /foo/bar          ../
3418 #   /foo/       /foo/bar          ../
3419 #   /foo        /foo/bar/         ../
3420 #   /foo/       /foo/bar/         ../
3421 #   /foo        /foo/bar/ugg      ../../
3422 #
3423     dollar='$$'
3424     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3425 changequote([, ])dnl
3426 fi
3427 AC_SUBST(gcc_tooldir)
3428 AC_SUBST(dollar)
3429
3430 # Find a directory in which to install a shared libgcc.
3431
3432 AC_ARG_ENABLE(version-specific-runtime-libs,
3433 [  --enable-version-specific-runtime-libs
3434                           specify that runtime libraries should be
3435                           installed in a compiler-specific directory])
3436
3437 AC_ARG_WITH(slibdir,
3438 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3439 slibdir="$with_slibdir",
3440 if test "${enable_version_specific_runtime_libs+set}" = set; then
3441   slibdir='$(libsubdir)'
3442 elif test "$host" != "$target"; then
3443   slibdir='$(build_tooldir)/lib'
3444 else
3445   slibdir='$(libdir)'
3446 fi)
3447 AC_SUBST(slibdir)
3448
3449 objdir=`${PWDCMD-pwd}`
3450 AC_SUBST(objdir)
3451
3452 # Substitute configuration variables
3453 AC_SUBST(subdirs)
3454 AC_SUBST(srcdir)
3455 AC_SUBST(all_boot_languages)
3456 AC_SUBST(all_compilers)
3457 AC_SUBST(all_gtfiles)
3458 AC_SUBST(all_gtfiles_files_langs)
3459 AC_SUBST(all_gtfiles_files_files)
3460 AC_SUBST(all_lang_makefrags)
3461 AC_SUBST(all_lang_makefiles)
3462 AC_SUBST(all_languages)
3463 AC_SUBST(all_stagestuff)
3464 AC_SUBST(build_exeext)
3465 AC_SUBST(build_install_headers_dir)
3466 AC_SUBST(build_xm_file_list)
3467 AC_SUBST(build_xm_include_list)
3468 AC_SUBST(build_xm_defines)
3469 AC_SUBST(check_languages)
3470 AC_SUBST(cc_set_by_configure)
3471 AC_SUBST(quoted_cc_set_by_configure)
3472 AC_SUBST(cpp_install_dir)
3473 AC_SUBST(xmake_file)
3474 AC_SUBST(tmake_file)
3475 AC_SUBST(extra_gcc_objs)
3476 AC_SUBST(extra_headers_list)
3477 AC_SUBST(extra_objs)
3478 AC_SUBST(extra_parts)
3479 AC_SUBST(extra_passes)
3480 AC_SUBST(extra_programs)
3481 AC_SUBST(float_h_file)
3482 AC_SUBST(gcc_config_arguments)
3483 AC_SUBST(gcc_gxx_include_dir)
3484 AC_SUBST(libstdcxx_incdir)
3485 AC_SUBST(host_exeext)
3486 AC_SUBST(host_xm_file_list)
3487 AC_SUBST(host_xm_include_list)
3488 AC_SUBST(host_xm_defines)
3489 AC_SUBST(out_host_hook_obj)
3490 AC_SUBST(install)
3491 AC_SUBST(lang_opt_files)
3492 AC_SUBST(lang_specs_files)
3493 AC_SUBST(lang_tree_files)
3494 AC_SUBST(local_prefix)
3495 AC_SUBST(md_file)
3496 AC_SUBST(objc_boehm_gc)
3497 AC_SUBST(out_file)
3498 AC_SUBST(out_object_file)
3499 AC_SUBST(stage_prefix_set_by_configure)
3500 AC_SUBST(quoted_stage_prefix_set_by_configure)
3501 AC_SUBST(thread_file)
3502 AC_SUBST(tm_file_list)
3503 AC_SUBST(tm_include_list)
3504 AC_SUBST(tm_defines)
3505 AC_SUBST(tm_p_file_list)
3506 AC_SUBST(tm_p_include_list)
3507 AC_SUBST(xm_file_list)
3508 AC_SUBST(xm_include_list)
3509 AC_SUBST(xm_defines)
3510 AC_SUBST(c_target_objs)
3511 AC_SUBST(cxx_target_objs)
3512 AC_SUBST(target_cpu_default)
3513
3514 AC_SUBST_FILE(language_hooks)
3515
3516 # Echo link setup.
3517 if test x${build} = x${host} ; then
3518   if test x${host} = x${target} ; then
3519     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3520   else
3521     echo "Links are now set up to build a cross-compiler" 1>&2
3522     echo " from ${host} to ${target}." 1>&2
3523   fi
3524 else
3525   if test x${host} = x${target} ; then
3526     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3527     echo " for ${target}." 1>&2
3528   else
3529     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3530     echo " from ${host} to ${target}." 1>&2
3531   fi
3532 fi
3533
3534 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3535 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3536
3537 # Configure the subdirectories
3538 # AC_CONFIG_SUBDIRS($subdirs)
3539
3540 # Create the Makefile
3541 # and configure language subdirectories
3542 AC_CONFIG_FILES($all_outputs)
3543
3544 AC_CONFIG_COMMANDS([default],
3545 [
3546 case ${CONFIG_HEADERS} in
3547   *auto-host.h:config.in*)
3548   echo > cstamp-h ;;
3549 esac
3550 # Make sure all the subdirs exist.
3551 for d in $subdirs doc build
3552 do
3553     test -d $d || mkdir $d
3554 done
3555 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3556 # bootstrapping and the installation procedure can still use
3557 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3558 # FLAGS_TO_PASS has been modified to solve the problem there.
3559 # This is virtually a duplicate of what happens in configure.lang; we do
3560 # an extra check to make sure this only happens if ln -s can be used.
3561 case "$LN_S" in
3562   *-s*)
3563     for d in ${subdirs} ; do
3564         STARTDIR=`${PWDCMD-pwd}`
3565         cd $d
3566         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3567         do
3568                 rm -f $t
3569                 $LN_S ../$t $t 2>/dev/null
3570         done
3571         cd $STARTDIR
3572     done
3573   ;;
3574 esac
3575 ],
3576 [subdirs='$subdirs'])
3577 AC_OUTPUT