gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 ACX_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # With demangler in GNU ld
 215 AC_ARG_WITH(demangler-in-ld,
 216 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 217 demangler_in_ld="$with_demangler_in_ld",
 218 demangler_in_ld=no)
 219
 220 # ----------------------
 221 # Find default assembler
 222 # ----------------------
 223
 224 # With GNU as
 225 AC_ARG_WITH(gnu-as,
 226 [  --with-gnu-as           arrange to work with GNU as],
 227 gas_flag="$with_gnu_as",
 228 gas_flag=no)
 229
 230 AC_ARG_WITH(as,
 231 [  --with-as               arrange to use the specified as (full pathname)],
 232 DEFAULT_ASSEMBLER="$with_as")
 233 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 234   if test ! -x "$DEFAULT_ASSEMBLER"; then
 235     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 236   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 237     gas_flag=yes
 238   fi
 239   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 240         [Define to enable the use of a default assembler.])
 241 fi
 242
 243 AC_MSG_CHECKING([whether a default assembler was specified])
 244 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 245   if test x"$gas_flag" = x"no"; then
 246     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 247   else
 248     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 249   fi
 250 else
 251   AC_MSG_RESULT(no)
 252 fi
 253
 254 # ---------------
 255 # Find C compiler
 256 # ---------------
 257
 258 # If a non-executable a.out is present (e.g. created by GNU as above even if
 259 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 260 # file, even when creating an executable, so an execution test fails.
 261 # Remove possible default executable files to avoid this.
 262 #
 263 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 264 # Autoconf includes it.
 265 rm -f a.out a.exe b.out
 266
 267 # Find the native compiler
 268 AC_PROG_CC
 269 AC_PROG_CC_C_O
 270 # autoconf is lame and doesn't give us any substitution variable for this.
 271 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 272   NO_MINUS_C_MINUS_O=yes
 273 else
 274   OUTPUT_OPTION='-o $@'
 275 fi
 276 AC_SUBST(NO_MINUS_C_MINUS_O)
 277 AC_SUBST(OUTPUT_OPTION)
 278
 279 # -------------------------
 280 # Check C compiler features
 281 # -------------------------
 282
 283 AC_PROG_CPP
 284 AC_C_INLINE
 285
 286 gcc_AC_C_LONG_LONG
 287
 288 # sizeof(char) is 1 by definition.
 289 AC_COMPILE_CHECK_SIZEOF(void *)
 290 AC_COMPILE_CHECK_SIZEOF(short)
 291 AC_COMPILE_CHECK_SIZEOF(int)
 292 AC_COMPILE_CHECK_SIZEOF(long)
 293 if test $ac_cv_c_long_long = yes; then
 294   AC_COMPILE_CHECK_SIZEOF(long long)
 295 fi
 296 if test $ac_cv_c___int64 = yes; then
 297   AC_COMPILE_CHECK_SIZEOF(__int64)
 298 fi
 299
 300 # ---------------------
 301 # Warnings and checking
 302 # ---------------------
 303
 304 # Check $CC warning features (if it's GCC).
 305 # We want to use -pedantic, but we don't want warnings about
 306 # * 'long long'
 307 # * variadic macros
 308 # So, we only use -pedantic if we can disable those warnings.
 309
 310 AC_CACHE_CHECK(
 311   [whether ${CC} accepts -Wno-long-long],
 312   [ac_cv_prog_cc_w_no_long_long],
 313   [save_CFLAGS="$CFLAGS"
 314   CFLAGS="-Wno-long-long"
 315   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 316                     [ac_cv_prog_cc_w_no_long_long=yes],
 317                     [ac_cv_prog_cc_w_no_long_long=no])
 318   CFLAGS="$save_CFLAGS"
 319   ])
 320
 321 AC_CACHE_CHECK(
 322   [whether ${CC} accepts -Wno-variadic-macros],
 323   [ac_cv_prog_cc_w_no_variadic_macros],
 324   [save_CFLAGS="$CFLAGS"
 325   CFLAGS="-Wno-variadic-macros"
 326   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 327                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 328                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 329   CFLAGS="$save_CFLAGS"
 330   ])
 331
 332 strict1_warn=
 333 if test $ac_cv_prog_cc_w_no_long_long = yes \
 334    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 335   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 336 fi
 337 AC_SUBST(strict1_warn)
 338
 339 # Add -Wold-style-definition if it's accepted
 340 AC_CACHE_CHECK(
 341   [whether ${CC} accepts -Wold-style-definition],
 342   [ac_cv_prog_cc_w_old_style_definition],
 343   [save_CFLAGS="$CFLAGS"
 344   CFLAGS="-Wold-style-definition"
 345   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 346                     [ac_cv_prog_cc_w_old_style_definition=yes],
 347                     [ac_cv_prog_cc_w_old_style_definition=no])
 348   CFLAGS="$save_CFLAGS"
 349   ])
 350 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 351   strict1_warn="${strict1_warn} -Wold-style-definition"
 352 fi
 353
 354 # Enable -Werror, period.
 355 AC_ARG_ENABLE(werror_always,
 356 [  --enable-werror-always         enable -Werror always], [],
 357 [enable_werror_always=no])
 358 if test x${enable_werror_always} = xyes ; then
 359   strict1_warn="${strict1_warn} -Werror"
 360   WERROR=-Werror
 361 fi
 362
 363 # If the native compiler is GCC, we can enable warnings even in stage1.
 364 # That's useful for people building cross-compilers, or just running a
 365 # quick `make'.
 366 warn_cflags=
 367 if test "x$GCC" = "xyes"; then
 368   warn_cflags='$(GCC_WARN_CFLAGS)'
 369 fi
 370 AC_SUBST(warn_cflags)
 371
 372 # Enable -Werror in bootstrap stage2 and later.
 373 # Change the default to "no" on release branches.
 374 AC_ARG_ENABLE(werror,
 375 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 376 [enable_werror=yes])
 377 if test x$enable_werror = xyes ; then
 378   WERROR=-Werror
 379 fi
 380 AC_SUBST(WERROR)
 381
 382 # Enable expensive internal checks
 383 AC_ARG_ENABLE(checking,
 384 [  --enable-checking[=LIST]
 385                           enable expensive run-time checks.  With LIST,
 386                           enable only specific categories of checks.
 387                           Categories are: fold,gc,gcac,misc,rtlflag,rtl,
 388                           tree,valgrind; default is gc,misc,rtlflag,tree],
 389 [ac_checking=
 390 ac_tree_checking=
 391 ac_rtl_checking=
 392 ac_rtlflag_checking=
 393 ac_gc_checking=
 394 ac_gc_always_collect=
 395 ac_fold_checking=
 396 case "${enableval}" in
 397 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 398         ac_rtlflag_checking=1 ;;
 399 no)     ;;
 400 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 401         set fnord $enableval; shift
 402         IFS="$ac_save_IFS"
 403         for check
 404         do
 405                 case $check in
 406                 fold)   ac_fold_checking=1 ;;
 407                 gc)     ac_gc_checking=1 ;;
 408                 gcac)   ac_gc_always_collect=1 ;;
 409                 misc)   ac_checking=1 ;;
 410                 rtlflag)        ac_rtlflag_checking=1 ;;
 411                 rtl)    ac_rtl_checking=1 ;;
 412                 tree)   ac_tree_checking=1 ;;
 413                 valgrind)       ac_checking_valgrind=1 ;;
 414                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 415                 esac
 416         done
 417         ;;
 418 esac
 419 ],
 420 # Enable some checks by default for development versions of GCC
 421 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 422 nocommon_flag=""
 423 if test x$ac_checking != x ; then
 424   AC_DEFINE(ENABLE_CHECKING, 1,
 425 [Define if you want more run-time sanity checks.  This one gets a grab
 426    bag of miscellaneous but relatively cheap checks.])
 427   nocommon_flag=-fno-common
 428 fi
 429 AC_SUBST(nocommon_flag)
 430 if test x$ac_tree_checking != x ; then
 431   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 432 [Define if you want all operations on trees (the basic data
 433    structure of the front ends) to be checked for dynamic type safety
 434    at runtime.  This is moderately expensive.  The tree browser debugging
 435    routines will also be enabled by this option.
 436    ])
 437   TREEBROWSER=tree-browser.o
 438 fi
 439 AC_SUBST(TREEBROWSER)
 440 if test x$ac_rtl_checking != x ; then
 441   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 442 [Define if you want all operations on RTL (the basic data structure
 443    of the optimizer and back end) to be checked for dynamic type safety
 444    at runtime.  This is quite expensive.])
 445 fi
 446 if test x$ac_rtlflag_checking != x ; then
 447   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 448 [Define if you want RTL flag accesses to be checked against the RTL
 449    codes that are supported for each access macro.  This is relatively
 450    cheap.])
 451 fi
 452 if test x$ac_gc_checking != x ; then
 453   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 454 [Define if you want the garbage collector to do object poisoning and
 455    other memory allocation checks.  This is quite expensive.])
 456 fi
 457 if test x$ac_gc_always_collect != x ; then
 458   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 459 [Define if you want the garbage collector to operate in maximally
 460    paranoid mode, validating the entire heap and collecting garbage at
 461    every opportunity.  This is extremely expensive.])
 462 fi
 463 if test x$ac_fold_checking != x ; then
 464   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 465 [Define if you want fold checked that it never destructs its argument.
 466    This is quite expensive.])
 467 fi
 468 valgrind_path_defines=
 469 valgrind_command=
 470
 471 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 472 dnl # an if statement.  This was the source of very frustrating bugs
 473 dnl # in converting to autoconf 2.5x!
 474 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 475
 476 if test x$ac_checking_valgrind != x ; then
 477   # It is certainly possible that there's valgrind but no valgrind.h.
 478   # GCC relies on making annotations so we must have both.
 479   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 480   AC_TRY_CPP(
 481     [#include <valgrind/memcheck.h>
 482 #ifndef VALGRIND_DISCARD
 483 #error VALGRIND_DISCARD not defined
 484 #endif],
 485   [gcc_cv_header_valgrind_memcheck_h=yes],
 486   [gcc_cv_header_valgrind_memcheck_h=no])
 487   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 488   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 489   AC_TRY_CPP(
 490     [#include <memcheck.h>
 491 #ifndef VALGRIND_DISCARD
 492 #error VALGRIND_DISCARD not defined
 493 #endif],
 494   [gcc_cv_header_memcheck_h=yes],
 495   gcc_cv_header_memcheck_h=no)
 496   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 497   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 498         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 499   if test "x$valgrind_path" = "x" \
 500     || (test $have_valgrind_h = no \
 501         && test $gcc_cv_header_memcheck_h = no \
 502         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 503         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 504   fi
 505   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 506   valgrind_command="$valgrind_path -q"
 507   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 508 [Define if you want to run subprograms and generated programs
 509    through valgrind (a memory checker).  This is extremely expensive.])
 510   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 511     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 512         [Define if valgrind's valgrind/memcheck.h header is installed.])
 513   fi
 514   if test $gcc_cv_header_memcheck_h = yes; then
 515     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 516         [Define if valgrind's memcheck.h header is installed.])
 517   fi
 518 fi
 519 AC_SUBST(valgrind_path_defines)
 520 AC_SUBST(valgrind_command)
 521
 522 AC_ARG_ENABLE(mapped-location,
 523 [  --enable-mapped-location   location_t is fileline integer cookie],,
 524 enable_mapped_location=no)
 525
 526 if test "$enable_mapped_location" = yes ; then
 527   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 528 [Define if location_t is fileline integer cookie.])
 529 fi
 530
 531 # Enable code coverage collection
 532 AC_ARG_ENABLE(coverage,
 533 [  --enable-coverage[=LEVEL]
 534                           enable compiler\'s code coverage collection.
 535                           Use to measure compiler performance and locate
 536                           unused parts of the compiler. With LEVEL, specify
 537                           optimization. Values are opt, noopt,
 538                           default is noopt],
 539 [case "${enableval}" in
 540   yes|noopt)
 541     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 542     ;;
 543   opt)
 544     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 545     ;;
 546   no)
 547     # a.k.a. --disable-coverage
 548     coverage_flags=""
 549     ;;
 550   *)
 551     AC_MSG_ERROR(unknown coverage setting $enableval)
 552     ;;
 553 esac],
 554 [coverage_flags=""])
 555 AC_SUBST(coverage_flags)
 556
 557 AC_ARG_ENABLE(gather-detailed-mem-stats,
 558 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 559 [enable_gather_detailed_mem_stats=no])
 560 if test x$enable_gather_detailed_mem_stats = xyes ; then
 561   AC_DEFINE(GATHER_STATISTICS, 1,
 562         [Define to enable detailed memory allocation stats gathering.])
 563 fi
 564
 565 # -------------------------------
 566 # Miscenalleous configure options
 567 # -------------------------------
 568
 569 # With stabs
 570 AC_ARG_WITH(stabs,
 571 [  --with-stabs            arrange to use stabs instead of host debug format],
 572 stabs="$with_stabs",
 573 stabs=no)
 574
 575 # Determine whether or not multilibs are enabled.
 576 AC_ARG_ENABLE(multilib,
 577 [  --enable-multilib       enable library support for multiple ABIs],
 578 [], [enable_multilib=yes])
 579 AC_SUBST(enable_multilib)
 580
 581 # Enable __cxa_atexit for C++.
 582 AC_ARG_ENABLE(__cxa_atexit,
 583 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 584 [], [])
 585
 586 # Enable threads
 587 # Pass with no value to take the default
 588 # Pass with a value to specify a thread package
 589 AC_ARG_ENABLE(threads,
 590 [  --enable-threads        enable thread usage for target GCC
 591   --enable-threads=LIB    use LIB thread package for target GCC],,
 592 [enable_threads=''])
 593
 594 AC_ARG_ENABLE(objc-gc,
 595 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 596                           the GNU Objective-C runtime],
 597 if test x$enable_objc_gc = xno; then
 598         objc_boehm_gc=''
 599 else
 600         objc_boehm_gc=1
 601 fi,
 602 objc_boehm_gc='')
 603
 604 AC_ARG_WITH(dwarf2,
 605 [  --with-dwarf2           force the default debug format to be DWARF 2],
 606 dwarf2="$with_dwarf2",
 607 dwarf2=no)
 608
 609 AC_ARG_ENABLE(shared,
 610 [  --disable-shared        don't provide a shared libgcc],
 611 [
 612   case $enable_shared in
 613   yes | no) ;;
 614   *)
 615     enable_shared=no
 616     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 617     for pkg in $enableval; do
 618       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 619         enable_shared=yes
 620       fi
 621     done
 622     IFS="$ac_save_ifs"
 623     ;;
 624   esac
 625 ], [enable_shared=yes])
 626 AC_SUBST(enable_shared)
 627
 628 AC_ARG_WITH(sysroot,
 629 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 630 [
 631  case ${with_sysroot} in
 632  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 633  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 634  esac
 635
 636  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 637  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 638
 639  if test "x$exec_prefix" = xNONE; then
 640   if test "x$prefix" = xNONE; then
 641    test_prefix=/usr/local
 642   else
 643    test_prefix=$prefix
 644   fi
 645  else
 646   test_prefix=$exec_prefix
 647  fi
 648  case ${TARGET_SYSTEM_ROOT} in
 649  "${test_prefix}"|"${test_prefix}/"*|\
 650  '${exec_prefix}'|'${exec_prefix}/'*)
 651    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 652    TARGET_SYSTEM_ROOT_DEFINE="$t"
 653    ;;
 654  esac
 655 ], [
 656  TARGET_SYSTEM_ROOT=
 657  TARGET_SYSTEM_ROOT_DEFINE=
 658  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 659 ])
 660 AC_SUBST(TARGET_SYSTEM_ROOT)
 661 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 662 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 663
 664 # Build with intermodule optimisations
 665 AC_ARG_ENABLE(intermodule,
 666 [  --enable-intermodule    build the compiler in one step],
 667 [case ${enable_intermodule} in
 668   yes) onestep="-onestep";;
 669   *) onestep="";;
 670 esac],
 671 [onestep=""])
 672 AC_SUBST(onestep)
 673
 674 # Sanity check enable_languages in case someone does not run the toplevel
 675 # configure # script.
 676 AC_ARG_ENABLE(languages,
 677 [  --enable-languages=LIST specify which front-ends to build],
 678 [case ,${enable_languages}, in
 679        ,,|,yes,)
 680                 # go safe -- we cannot be much sure without the toplevel
 681                 # configure's
 682                 # analysis of which target libs are present and usable
 683                 enable_languages=c
 684                 ;;
 685          *,all,*)
 686                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 687                 ;;
 688         *,c,*)
 689                 ;;
 690         *)
 691                 enable_languages=c,${enable_languages}
 692                 ;;
 693 esac],
 694 [enable_languages=c])
 695
 696 subdirs=
 697 for lang in ${srcdir}/*/config-lang.in
 698 do
 699         case $lang in
 700         # The odd quoting in the next line works around
 701         # an apparent bug in bash 1.12 on linux.
 702 changequote(,)dnl
 703         ${srcdir}/[*]/config-lang.in) ;;
 704         *)
 705           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 706           if test "x$lang_alias" = x
 707           then
 708                 echo "$lang doesn't set \$language." 1>&2
 709                 exit 1
 710           fi
 711           case ",$enable_languages," in
 712           *,$lang_alias,*)
 713             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 714           esac
 715           ;;
 716 changequote([,])dnl
 717         esac
 718 done
 719
 720
 721 # -------------------------
 722 # Checks for other programs
 723 # -------------------------
 724
 725 AC_PROG_MAKE_SET
 726
 727 # Find some useful tools
 728 AC_PROG_AWK
 729 # We need awk to create options.c and options.h.
 730 # Bail out if it's missing.
 731 case ${AWK} in
 732   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 733 esac
 734
 735 gcc_AC_PROG_LN_S
 736 ACX_PROG_LN($LN_S)
 737 AC_PROG_RANLIB
 738 case "${host}" in
 739 *-*-darwin*)
 740   # By default, the Darwin ranlib will not treat common symbols as
 741   # definitions when  building the archive table of contents.  Other
 742   # ranlibs do that; pass an option to the Darwin ranlib that makes
 743   # it behave similarly.
 744   ranlib_flags="-c"
 745   ;;
 746 *)
 747   ranlib_flags=""
 748 esac
 749 AC_SUBST(ranlib_flags)
 750
 751 gcc_AC_PROG_INSTALL
 752
 753 # See if cmp has --ignore-initial.
 754 gcc_AC_PROG_CMP_IGNORE_INITIAL
 755
 756 # See if we have the mktemp command.
 757 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 758
 759 # Do we have a single-tree copy of texinfo?
 760 if test -f $srcdir/../texinfo/Makefile.in; then
 761   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 762   gcc_cv_prog_makeinfo_modern=yes
 763   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 764 else
 765   # See if makeinfo has been installed and is modern enough
 766   # that we can use it.
 767   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 768   [GNU texinfo.* \([0-9][0-9.]*\)],
 769   [4.[2-9]*])
 770 fi
 771
 772 if test $gcc_cv_prog_makeinfo_modern = no; then
 773   AC_MSG_WARN([
 774 *** Makeinfo is missing or too old.
 775 *** Info documentation will not be built.])
 776   BUILD_INFO=
 777 else
 778   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 779 fi
 780
 781 # Is pod2man recent enough to regenerate manpages?
 782 AC_MSG_CHECKING([for recent Pod::Man])
 783 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 784   AC_MSG_RESULT(yes)
 785   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 786 else
 787   AC_MSG_RESULT(no)
 788   GENERATED_MANPAGES=
 789 fi
 790
 791 # How about lex?
 792 dnl Don't use AC_PROG_LEX; we insist on flex.
 793 dnl LEXLIB is not useful in gcc.
 794 if test x${build} = x${host} && test -f $srcdir/../flex/skel.c \
 795   && test -d ../flex ; then
 796   FLEX='$(objdir)/../flex/flex'
 797 else
 798   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 799 fi
 800
 801 # Bison?
 802 # The -L switch is so bison can find its skeleton file.
 803 if test x${build} = x${host} && test -f $srcdir/../bison/bison.simple \
 804   && test -d ../bison ; then
 805   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 806 else
 807   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 808 fi
 809
 810 # NM
 811 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 812   && test -d ../binutils ; then
 813   NM='$(objdir)/../binutils/nm-new'
 814 else
 815   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 816 fi
 817
 818 # AR
 819 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 820   && test -d ../binutils ; then
 821   AR='$(objdir)/../binutils/ar'
 822 else
 823   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 824 fi
 825
 826
 827 # --------------------
 828 # Checks for C headers
 829 # --------------------
 830
 831 AC_MSG_CHECKING(for GNU C library)
 832 AC_CACHE_VAL(gcc_cv_glibc,
 833 [AC_TRY_COMPILE(
 834   [#include <features.h>],[
 835 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 836 #error Not a GNU C library system
 837 #endif],
 838   [gcc_cv_glibc=yes],
 839   gcc_cv_glibc=no)])
 840 AC_MSG_RESULT($gcc_cv_glibc)
 841 if test $gcc_cv_glibc = yes; then
 842   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 843 fi
 844
 845 # Need to reject headers which give warnings, so that the -Werror bootstrap
 846 # works later. *sigh*  This needs to come before all header checks.
 847 AC_PROG_CPP_WERROR
 848
 849 AC_HEADER_STDC
 850 AC_HEADER_TIME
 851 ACX_HEADER_STRING
 852 AC_HEADER_SYS_WAIT
 853 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 854                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 855                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 856                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 857
 858 # Check for thread headers.
 859 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 860 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 861
 862 # These tests can't be done till we know if we have limits.h.
 863 gcc_AC_C_CHAR_BIT
 864 AC_C_BIGENDIAN_CROSS
 865
 866 # --------
 867 # UNSORTED
 868 # --------
 869
 870 # Stage specific cflags for build.
 871 stage1_cflags=
 872 case $build in
 873 vax-*-*)
 874   if test x$GCC = xyes
 875   then
 876     stage1_cflags="-Wa,-J"
 877   else
 878     stage1_cflags="-J"
 879   fi
 880   ;;
 881 powerpc-*-darwin*)
 882   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 883   # sources; use -no-cpp-precomp to get to GNU cpp.
 884   # Apple's GCC has bugs in designated initializer handling, so disable
 885   # that too.
 886   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 887   ;;
 888 esac
 889 AC_SUBST(stage1_cflags)
 890
 891 # These libraries may be used by collect2.
 892 # We may need a special search path to get them linked.
 893 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 894 [save_LIBS="$LIBS"
 895 for libs in '' -lld -lmld \
 896                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 897                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 898 do
 899         LIBS="$libs"
 900         AC_TRY_LINK_FUNC(ldopen,
 901                 [gcc_cv_collect2_libs="$libs"; break])
 902 done
 903 LIBS="$save_LIBS"
 904 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 905 case $gcc_cv_collect2_libs in
 906         "none required")        ;;
 907         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 908 esac
 909 AC_SUBST(COLLECT2_LIBS)
 910
 911 # When building Ada code on Alpha, we need exc_resume which is usually in
 912 # -lexc.  So test for it.
 913 save_LIBS="$LIBS"
 914 LIBS=
 915 AC_SEARCH_LIBS(exc_resume, exc)
 916 GNAT_LIBEXC="$LIBS"
 917 LIBS="$save_LIBS"
 918 AC_SUBST(GNAT_LIBEXC)
 919
 920 # Some systems put ldexp and frexp in libm instead of libc; assume
 921 # they're both in the same place.  jcf-dump needs them.
 922 save_LIBS="$LIBS"
 923 LIBS=
 924 AC_SEARCH_LIBS(ldexp, m)
 925 LDEXP_LIB="$LIBS"
 926 LIBS="$save_LIBS"
 927 AC_SUBST(LDEXP_LIB)
 928
 929 # Use <inttypes.h> only if it exists,
 930 # doesn't clash with <sys/types.h>, and declares intmax_t.
 931 AC_MSG_CHECKING(for inttypes.h)
 932 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 933 [AC_TRY_COMPILE(
 934   [#include <sys/types.h>
 935 #include <inttypes.h>],
 936   [intmax_t i = -1;],
 937   [gcc_cv_header_inttypes_h=yes],
 938   gcc_cv_header_inttypes_h=no)])
 939 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 940 if test $gcc_cv_header_inttypes_h = yes; then
 941   AC_DEFINE(HAVE_INTTYPES_H, 1,
 942         [Define if you have a working <inttypes.h> header file.])
 943 fi
 944
 945 dnl Disabled until we have a complete test for buggy enum bitfields.
 946 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 947
 948 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 949         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 950         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 951         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 952         setlocale)
 953
 954 if test x$ac_cv_func_mbstowcs = xyes; then
 955   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 956 [    AC_TRY_RUN([#include <stdlib.h>
 957 int main()
 958 {
 959   mbstowcs(0, "", 0);
 960   return 0;
 961 }],
 962     gcc_cv_func_mbstowcs_works=yes,
 963     gcc_cv_func_mbstowcs_works=no,
 964     gcc_cv_func_mbstowcs_works=yes)])
 965   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 966     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 967   [Define this macro if mbstowcs does not crash when its
 968    first argument is NULL.])
 969   fi
 970 fi
 971
 972 AC_CHECK_TYPE(ssize_t, int)
 973
 974 # Try to determine the array type of the second argument of getgroups
 975 # for the target system (int or gid_t).
 976 AC_TYPE_GETGROUPS
 977 if test "${target}" = "${build}"; then
 978   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 979 else
 980   case "${target}" in
 981         # This condition may need some tweaking.  It should include all
 982         # targets where the array type of the second argument of getgroups
 983         # is int and the type of gid_t is not equivalent to int.
 984         *-*-sunos* | *-*-ultrix*)
 985                 TARGET_GETGROUPS_T=int
 986                 ;;
 987         *)
 988                 TARGET_GETGROUPS_T=gid_t
 989                 ;;
 990   esac
 991 fi
 992 AC_SUBST(TARGET_GETGROUPS_T)
 993
 994 gcc_AC_FUNC_PRINTF_PTR
 995 gcc_AC_FUNC_MMAP_BLACKLIST
 996
 997 case "${host}" in
 998 *-*-*vms*)
 999   # Under VMS, vfork works very differently than on Unix. The standard test
1000   # won't work, and it isn't easily adaptable. It makes more sense to
1001   # just force it.
1002   ac_cv_func_vfork_works=yes
1003   ;;
1004 esac
1005 AC_FUNC_VFORK
1006
1007 AM_ICONV
1008 # Until we have in-tree GNU iconv:
1009 LIBICONV_DEP=
1010 AC_SUBST(LIBICONV_DEP)
1011
1012 AM_LC_MESSAGES
1013
1014 # We will need to find libiberty.h and ansidecl.h
1015 saved_CFLAGS="$CFLAGS"
1016 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1017 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
1018         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
1019         fprintf_unlocked strstr errno snprintf vasprintf \
1020         malloc realloc calloc free basename getopt clock getpagesize, , ,[
1021 #include "ansidecl.h"
1022 #include "system.h"])
1023
1024 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1025 #include "ansidecl.h"
1026 #include "system.h"
1027 #ifdef HAVE_SYS_RESOURCE_H
1028 #include <sys/resource.h>
1029 #endif
1030 ])
1031
1032 AC_TRY_COMPILE([
1033 #include "ansidecl.h"
1034 #include "system.h"
1035 #ifdef HAVE_SYS_RESOURCE_H
1036 #include <sys/resource.h>
1037 #endif
1038 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1039 [Define to \`long' if <sys/resource.h> doesn't define.])])
1040
1041 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1042 #include "ansidecl.h"
1043 #include "system.h"
1044 #ifdef HAVE_LDFCN_H
1045 #include <ldfcn.h>
1046 #endif
1047 ])
1048
1049 gcc_AC_CHECK_DECLS(times, , ,[
1050 #include "ansidecl.h"
1051 #include "system.h"
1052 #ifdef HAVE_SYS_TIMES_H
1053 #include <sys/times.h>
1054 #endif
1055 ])
1056
1057 # More time-related stuff.
1058 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1059 AC_TRY_COMPILE([
1060 #include "ansidecl.h"
1061 #include "system.h"
1062 #ifdef HAVE_SYS_TIMES_H
1063 #include <sys/times.h>
1064 #endif
1065 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1066 if test $ac_cv_struct_tms = yes; then
1067   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1068   [Define if <sys/times.h> defines struct tms.])
1069 fi
1070
1071 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1072 # revisit after autoconf 2.50.
1073 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1074 AC_TRY_COMPILE([
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1078 if test $gcc_cv_type_clock_t = yes; then
1079   AC_DEFINE(HAVE_CLOCK_T, 1,
1080   [Define if <time.h> defines clock_t.])
1081 fi
1082
1083 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1084 CFLAGS="$saved_CFLAGS"
1085
1086 gcc_AC_INITFINI_ARRAY
1087
1088 # mkdir takes a single argument on some systems.
1089 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1090
1091 # File extensions
1092 manext='.1'
1093 objext='.o'
1094 AC_SUBST(manext)
1095 AC_SUBST(objext)
1096
1097 # With Setjmp/Longjmp based exception handling.
1098 AC_ARG_ENABLE(sjlj-exceptions,
1099 [  --enable-sjlj-exceptions
1100                           arrange to use setjmp/longjmp exception handling],
1101 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1102 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1103   [Define 0/1 to force the choice for exception handling model.])])
1104
1105 if test x$host = x$target; then
1106    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
1107 else
1108    use_libunwind_default=no
1109 fi
1110 # Use libunwind based exception handling.
1111 AC_ARG_ENABLE(libunwind-exceptions,
1112 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
1113 use_libunwind_exceptions=$enableval,
1114 use_libunwind_exceptions=$use_libunwind_default)
1115 if test x"$use_libunwind_exceptions" = xyes; then
1116    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
1117         [Define if gcc should use -lunwind.])
1118 fi
1119
1120 # --------------------------------------------------------
1121 # Build, host, and target specific configuration fragments
1122 # --------------------------------------------------------
1123
1124 # Collect build-machine-specific information.
1125 . ${srcdir}/config.build
1126
1127 # Collect host-machine-specific information.
1128 . ${srcdir}/config.host
1129
1130 target_gtfiles=
1131
1132 # Collect target-machine-specific information.
1133 . ${srcdir}/config.gcc
1134
1135 extra_objs="${host_extra_objs} ${extra_objs}"
1136 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1137
1138 # Default the target-machine variables that were not explicitly set.
1139 if test x"$tm_file" = x
1140 then tm_file=$cpu_type/$cpu_type.h; fi
1141
1142 if test x"$extra_headers" = x
1143 then extra_headers=; fi
1144
1145 if test x$md_file = x
1146 then md_file=$cpu_type/$cpu_type.md; fi
1147
1148 if test x$out_file = x
1149 then out_file=$cpu_type/$cpu_type.c; fi
1150
1151 if test x"$tmake_file" = x
1152 then tmake_file=$cpu_type/t-$cpu_type
1153 fi
1154
1155 if test x"$dwarf2" = xyes
1156 then tm_file="$tm_file tm-dwarf2.h"
1157 fi
1158
1159 # Say what files are being used for the output code and MD file.
1160 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1161 echo "Using \`$srcdir/config/$md_file' as machine description file."
1162
1163 # If any of the xm_file variables contain nonexistent files, warn
1164 # about them and drop them.
1165
1166 bx=
1167 for x in $build_xm_file; do
1168   if    test -f $srcdir/config/$x
1169   then      bx="$bx $x"
1170   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1171   fi
1172 done
1173 build_xm_file="$bx"
1174
1175 hx=
1176 for x in $host_xm_file; do
1177   if    test -f $srcdir/config/$x
1178   then      hx="$hx $x"
1179   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1180   fi
1181 done
1182 host_xm_file="$hx"
1183
1184 tx=
1185 for x in $xm_file; do
1186   if    test -f $srcdir/config/$x
1187   then      tx="$tx $x"
1188   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1189   fi
1190 done
1191 xm_file="$tx"
1192
1193 count=a
1194 for f in $tm_file; do
1195         count=${count}x
1196 done
1197 if test $count = ax; then
1198         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1199 else
1200         echo "Using the following target machine macro files:"
1201         for f in $tm_file; do
1202                 echo "  $srcdir/config/$f"
1203         done
1204 fi
1205
1206 if test x$need_64bit_hwint = xyes; then
1207         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1208 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1209 fi
1210
1211 count=a
1212 for f in $host_xm_file; do
1213         count=${count}x
1214 done
1215 if test $count = a; then
1216         :
1217 elif test $count = ax; then
1218         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1219 else
1220         echo "Using the following host machine macro files:"
1221         for f in $host_xm_file; do
1222                 echo "  $srcdir/config/$f"
1223         done
1224 fi
1225 echo "Using ${out_host_hook_obj} for host machine hooks."
1226
1227 if test "$host_xm_file" != "$build_xm_file"; then
1228         count=a
1229         for f in $build_xm_file; do
1230                 count=${count}x
1231         done
1232         if test $count = a; then
1233                 :
1234         elif test $count = ax; then
1235                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1236         else
1237                 echo "Using the following build machine macro files:"
1238                 for f in $build_xm_file; do
1239                         echo "  $srcdir/config/$f"
1240                 done
1241         fi
1242 fi
1243
1244 # ---------
1245 # Threading
1246 # ---------
1247
1248 # Check if a valid thread package
1249 case ${enable_threads} in
1250   "" | no)
1251     # No threads
1252     target_thread_file='single'
1253     ;;
1254   yes)
1255     # default
1256     target_thread_file='single'
1257     ;;
1258   aix | dce | gnat | irix | posix | rtems | \
1259   single | solaris | vxworks | win32 )
1260     target_thread_file=${enable_threads}
1261     ;;
1262   *)
1263     echo "${enable_threads} is an unknown thread package" 1>&2
1264     exit 1
1265     ;;
1266 esac
1267
1268 if test x${thread_file} = x; then
1269   # No thread file set by target-specific clauses in config.gcc,
1270   # so use file chosen by default logic above
1271   thread_file=${target_thread_file}
1272 fi
1273
1274 # Make gthr-default.h if we have a thread file.
1275 gthread_flags=
1276 if test $thread_file != single; then
1277   rm -f gthr-default.h
1278   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1279   gthread_flags=-DHAVE_GTHR_DEFAULT
1280 fi
1281 AC_SUBST(gthread_flags)
1282
1283 # --------
1284 # UNSORTED
1285 # --------
1286
1287 if test x$enable___cxa_atexit = xyes || \
1288    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1289    AC_CHECK_FUNC(__cxa_atexit,
1290         [AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1291         [Define if you want to use __cxa_atexit, rather than atexit, to
1292         register C++ destructors for local statics and global objects.
1293         This is essential for fully standards-compliant handling of
1294         destructors, but requires __cxa_atexit in libc.])],
1295         echo "__cxa_atexit can't be enabled on this target")
1296 fi
1297
1298 # Look for a file containing extra machine modes.
1299 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1300   extra_modes_file='$(srcdir)'/config/${extra_modes}
1301   AC_SUBST(extra_modes_file)
1302   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1303   [Define to the name of a file containing a list of extra machine modes
1304    for this architecture.])
1305 fi
1306
1307 # auto-host.h is the file containing items generated by autoconf and is
1308 # the first file included by config.h.
1309 # If host=build, it is correct to have bconfig include auto-host.h
1310 # as well.  If host!=build, we are in error and need to do more
1311 # work to find out the build config parameters.
1312 if test x$host = x$build
1313 then
1314         build_auto=auto-host.h
1315         FORBUILD=..
1316 else
1317         # We create a subdir, then run autoconf in the subdir.
1318         # To prevent recursion we set host and build for the new
1319         # invocation of configure to the build for this invocation
1320         # of configure.
1321         tempdir=build.$$
1322         rm -rf $tempdir
1323         mkdir $tempdir
1324         cd $tempdir
1325         case ${srcdir} in
1326         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1327         *) realsrcdir=../${srcdir};;
1328         esac
1329         saved_CFLAGS="${CFLAGS}"
1330         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1331         ${realsrcdir}/configure \
1332                 --enable-languages=${enable_languages-all} \
1333                 --target=$target_alias --host=$build_alias --build=$build_alias
1334         CFLAGS="${saved_CFLAGS}"
1335
1336         # We just finished tests for the build machine, so rename
1337         # the file auto-build.h in the gcc directory.
1338         mv auto-host.h ../auto-build.h
1339         cd ..
1340         rm -rf $tempdir
1341         build_auto=auto-build.h
1342         FORBUILD=../${build_subdir}
1343 fi
1344 AC_SUBST(FORBUILD)
1345
1346 tm_file="${tm_file} defaults.h"
1347 tm_p_file="${tm_p_file} tm-preds.h"
1348 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1349 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1350 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1351 # put this back in temporarily.
1352 xm_file="ansidecl.h ${xm_file}"
1353
1354 # --------
1355 # UNSORTED
1356 # --------
1357
1358 # Get the version trigger filename from the toplevel
1359 if test "${with_gcc_version_trigger+set}" = set; then
1360         gcc_version_trigger=$with_gcc_version_trigger
1361 else
1362         gcc_version_trigger=${srcdir}/version.c
1363 fi
1364 changequote(,)dnl
1365 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1366 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1367
1368 # Compile in configure arguments.
1369 if test -f configargs.h ; then
1370         # Being re-configured.
1371         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1372         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1373 else
1374         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1375 fi
1376
1377 # Double all backslashes and backslash all quotes to turn
1378 # gcc_config_arguments into a C string.
1379 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1380 $gcc_config_arguments
1381 EOF
1382 gcc_config_arguments_str=`cat conftest.out`
1383 rm -f conftest.out
1384
1385 cat > configargs.h <<EOF
1386 /* Generated automatically. */
1387 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1388 static const char thread_model[] = "$thread_file";
1389
1390 static const struct {
1391   const char *name, *value;
1392 } configure_default_options[] = $configure_default_options;
1393 EOF
1394 changequote([,])dnl
1395
1396 # Internationalization
1397 PACKAGE=gcc
1398 VERSION="$gcc_version"
1399 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
1400   [The name of this program for internationalization purposes.])
1401 AC_SUBST(PACKAGE)
1402 AC_SUBST(VERSION)
1403
1404 ZW_GNU_GETTEXT_SISTER_DIR
1405
1406 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1407 # -liconv on the link line twice.
1408 case "$LIBINTL" in *$LIBICONV*)
1409         LIBICONV= ;;
1410 esac
1411
1412 # Windows32 Registry support for specifying GCC installation paths.
1413 AC_ARG_ENABLE(win32-registry,
1414 [  --disable-win32-registry
1415                           disable lookup of installation paths in the
1416                           Registry on Windows hosts
1417   --enable-win32-registry enable registry lookup (default)
1418   --enable-win32-registry=KEY
1419                           use KEY instead of GCC version as the last portion
1420                           of the registry key],,)
1421 case $host_os in
1422         win32 | pe | cygwin* | mingw32* | uwin*)
1423 AC_MSG_CHECKING(whether windows registry support is requested)
1424 if test "x$enable_win32_registry" != xno; then
1425   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1426 [Define to 1 if installation paths should be looked up in Windows32
1427    Registry. Ignored on non windows32 hosts.])
1428   AC_MSG_RESULT(yes)
1429   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1430 else
1431   AC_MSG_RESULT(no)
1432 fi
1433
1434 # Check if user specified a different registry key.
1435 case "x${enable_win32_registry}" in
1436 x | xyes)
1437   # default.
1438   gcc_cv_win32_registry_key="$VERSION"
1439   ;;
1440 xno)
1441   # no registry lookup.
1442   gcc_cv_win32_registry_key=''
1443   ;;
1444 *)
1445   # user-specified key.
1446   gcc_cv_win32_registry_key="$enable_win32_registry"
1447   ;;
1448 esac
1449
1450 if test "x$enable_win32_registry" != xno; then
1451   AC_MSG_CHECKING(registry key on windows hosts)
1452   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1453         [Define to be the last portion of registry key on windows hosts.])
1454   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1455 fi
1456 ;;
1457 esac
1458
1459 # Get an absolute path to the GCC top-level source directory
1460 holddir=`${PWDCMD-pwd}`
1461 cd $srcdir
1462 topdir=`${PWDCMD-pwd}`
1463 cd $holddir
1464
1465 # Conditionalize the makefile for this host machine.
1466 xmake_file=
1467 for f in ${host_xmake_file}
1468 do
1469         if test -f ${srcdir}/config/$f
1470         then
1471                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1472         fi
1473 done
1474
1475 # Conditionalize the makefile for this target machine.
1476 tmake_file_=
1477 for f in ${tmake_file}
1478 do
1479         if test -f ${srcdir}/config/$f
1480         then
1481                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1482         fi
1483 done
1484 tmake_file="${tmake_file_}"
1485
1486 symbolic_link='ln -s'
1487
1488 # If the host doesn't support symlinks, modify CC in
1489 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1490 # Otherwise, we can use "CC=$(CC)".
1491 rm -f symtest.tem
1492 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1493 then
1494         cc_set_by_configure="\$(CC)"
1495         quoted_cc_set_by_configure="\$(CC)"
1496         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1497         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1498 else
1499         rm -f symtest.tem
1500         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1501         then
1502                 symbolic_link="cp -p"
1503         else
1504                 symbolic_link="cp"
1505         fi
1506         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1507         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1508         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1509         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1510 fi
1511 rm -f symtest.tem
1512
1513 out_object_file=`basename $out_file .c`.o
1514
1515 tm_file_list=
1516 tm_include_list=
1517 for f in $tm_file; do
1518   case $f in
1519     defaults.h )
1520        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1521        tm_include_list="${tm_include_list} $f"
1522        ;;
1523     * )
1524        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1525        tm_include_list="${tm_include_list} config/$f"
1526        ;;
1527   esac
1528 done
1529
1530 tm_p_file_list=
1531 tm_p_include_list=
1532 for f in $tm_p_file; do
1533   case $f in
1534     tm-preds.h )
1535        tm_p_file_list="${tm_p_file_list} $f"
1536        tm_p_include_list="${tm_p_include_list} $f"
1537        ;;
1538     * )
1539        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1540        tm_p_include_list="${tm_p_include_list} config/$f"
1541   esac
1542 done
1543
1544 xm_file_list=
1545 xm_include_list=
1546 for f in $xm_file; do
1547   case $f in
1548     ansidecl.h )
1549        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1550        xm_include_list="${xm_include_list} $f"
1551        ;;
1552     auto-host.h )
1553        xm_file_list="${xm_file_list} $f"
1554        xm_include_list="${xm_include_list} $f"
1555        ;;
1556     * )
1557        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1558        xm_include_list="${xm_include_list} config/$f"
1559        ;;
1560   esac
1561 done
1562
1563 host_xm_file_list=
1564 host_xm_include_list=
1565 for f in $host_xm_file; do
1566   case $f in
1567     ansidecl.h )
1568        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1569        host_xm_include_list="${host_xm_include_list} $f"
1570        ;;
1571     auto-host.h )
1572        host_xm_file_list="${host_xm_file_list} $f"
1573        host_xm_include_list="${host_xm_include_list} $f"
1574        ;;
1575     * )
1576        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1577        host_xm_include_list="${host_xm_include_list} config/$f"
1578        ;;
1579   esac
1580 done
1581
1582 build_xm_file_list=
1583 for f in $build_xm_file; do
1584   case $f in
1585     ansidecl.h )
1586        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1587        build_xm_include_list="${build_xm_include_list} $f"
1588        ;;
1589     auto-build.h | auto-host.h )
1590        build_xm_file_list="${build_xm_file_list} $f"
1591        build_xm_include_list="${build_xm_include_list} $f"
1592        ;;
1593     * )
1594        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1595        build_xm_include_list="${build_xm_include_list} config/$f"
1596        ;;
1597   esac
1598 done
1599
1600 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1601 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1602 CROSS=                                          AC_SUBST(CROSS)
1603 ALL=all.internal                                AC_SUBST(ALL)
1604 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1605 if test x$host != x$target
1606 then
1607         CROSS="-DCROSS_COMPILE"
1608         ALL=all.cross
1609         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1610         case "$host","$target" in
1611         # Darwin crosses can use the host system's libraries and headers,
1612         # because of the fat library support.  Of course, it must be the
1613         # same version of Darwin on both sides.  Allow the user to
1614         # just say --target=foo-darwin without a version number to mean
1615         # "the version on this system".
1616             *-*-darwin*,*-*-darwin*)
1617                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1618                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1619                 if test $hostos = $targetos -o $targetos = darwin ; then
1620                     CROSS=
1621                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1622                     with_headers=yes
1623                 fi
1624                 ;;
1625
1626             i?86-*-*,x86_64-*-* \
1627             | powerpc*-*-*,powerpc64*-*-*)
1628                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1629         esac
1630 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1631         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1632         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1633 fi
1634
1635 # If this is a cross-compiler that does not
1636 # have its own set of headers then define
1637 # inhibit_libc
1638
1639 # If this is using newlib, without having the headers available now,
1640 # then define inhibit_libc in LIBGCC2_CFLAGS.
1641 # This prevents libgcc2 from containing any code which requires libc
1642 # support.
1643 inhibit_libc=
1644 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1645        test x$with_newlib = xyes ; } &&
1646      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1647        inhibit_libc=-Dinhibit_libc
1648 fi
1649 AC_SUBST(inhibit_libc)
1650
1651 # When building gcc with a cross-compiler, we need to adjust things so
1652 # that the generator programs are still built with the native compiler.
1653 # Also, we cannot run fixincludes or fix-header.
1654
1655 # These are the normal (build=host) settings:
1656 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1657 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1658 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1659
1660 # Possibly disable fixproto, on a per-target basis.
1661 case ${use_fixproto} in
1662   no)
1663     STMP_FIXPROTO=
1664     ;;
1665   yes)
1666     STMP_FIXPROTO=stmp-fixproto
1667     ;;
1668 esac
1669 AC_SUBST(STMP_FIXPROTO)
1670
1671 # And these apply if build != host, or we are generating coverage data
1672 if test x$build != x$host || test "x$coverage_flags" != x
1673 then
1674     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1675
1676     if test "x$TARGET_SYSTEM_ROOT" = x; then
1677         STMP_FIXINC=
1678         STMP_FIXPROTO=
1679     fi
1680 fi
1681
1682 # Expand extra_headers to include complete path.
1683 # This substitutes for lots of t-* files.
1684 extra_headers_list=
1685 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1686 for file in ${extra_headers} ; do
1687   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1688 done
1689
1690 # Define collect2 in Makefile.
1691 case $host_can_use_collect2 in
1692   no) collect2= ;;
1693   *) collect2='collect2$(exeext)' ;;
1694 esac
1695 AC_SUBST([collect2])
1696
1697 # Add a definition of USE_COLLECT2 if system wants one.
1698 case $use_collect2 in
1699   no) use_collect2= ;;
1700   "") ;;
1701   *)
1702     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1703     xm_defines="${xm_defines} USE_COLLECT2"
1704     case $host_can_use_collect2 in
1705       no)
1706         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1707         ;;
1708     esac
1709     ;;
1710 esac
1711
1712 # ---------------------------
1713 # Assembler & linker features
1714 # ---------------------------
1715
1716 # Identify the assembler which will work hand-in-glove with the newly
1717 # built GCC, so that we can examine its features.  This is the assembler
1718 # which will be driven by the driver program.
1719 #
1720 # If build != host, and we aren't building gas in-tree, we identify a
1721 # build->target assembler and hope that it will have the same features
1722 # as the host->target assembler we'll be using.
1723 AC_MSG_CHECKING(what assembler to use)
1724 in_tree_gas=no
1725 gcc_cv_as=
1726 gcc_cv_gas_major_version=
1727 gcc_cv_gas_minor_version=
1728 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1729 if test -x "$DEFAULT_ASSEMBLER"; then
1730         gcc_cv_as="$DEFAULT_ASSEMBLER"
1731 elif test -x as$host_exeext; then
1732         # Build using assembler in the current directory.
1733         gcc_cv_as=./as$host_exeext
1734 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1735      && test -f ../gas/Makefile \
1736      && test x$build = x$host; then
1737   # Single tree build which includes gas.  We want to prefer it
1738   # over whatever linker top-level may have detected, since
1739   # we'll use what we're building after installation anyway.
1740   in_tree_gas=yes
1741   _gcc_COMPUTE_GAS_VERSION
1742   rm -f as$host_exeext
1743   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1744   in_tree_gas_is_elf=no
1745   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1746      || (grep 'obj_format = multi' ../gas/Makefile \
1747          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1748   then
1749     in_tree_gas_is_elf=yes
1750   fi
1751 m4_pattern_allow([AS_FOR_TARGET])dnl
1752 elif test -x "$AS_FOR_TARGET"; then
1753         gcc_cv_as="$AS_FOR_TARGET"
1754 elif test -x "$AS" && test x$host = x$target; then
1755         gcc_cv_as="$AS"
1756 fi
1757
1758 if test "x$gcc_cv_as" = x; then
1759         # Search the same directories that the installed compiler will
1760         # search.  Else we may find the wrong assembler and lose.  If we
1761         # do not find a suitable assembler binary, then try the user's
1762         # path.
1763         #
1764         # Also note we have to check MD_EXEC_PREFIX before checking the
1765         # user's path.  Unfortunately, there is no good way to get at the
1766         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1767         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1768         # to be fixed as part of the make/configure rewrite too.
1769
1770         if test "x$exec_prefix" = xNONE; then
1771                 if test "x$prefix" = xNONE; then
1772                         test_prefix=/usr/local
1773                 else
1774                         test_prefix=$prefix
1775                 fi
1776         else
1777                 test_prefix=$exec_prefix
1778         fi
1779
1780         # If the loop below does not find an assembler, then use whatever
1781         # one we can find in the users's path.
1782         # user's path.
1783         if test "x$program_prefix" != xNONE; then
1784                 gcc_cv_as=${program_prefix}as$host_exeext
1785         else
1786                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$host_exeext
1787         fi
1788
1789         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1790                    $test_prefix/libexec/gcc/$target_noncanonical \
1791                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1792                    /usr/lib/gcc/$target_noncanonical \
1793                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1794                    $test_prefix/$target_noncanonical/bin"
1795
1796         if test x$host = x$target; then
1797             test_dirs="$test_dirs \
1798                    /usr/libexec \
1799                    /usr/ccs/gcc \
1800                    /usr/ccs/bin \
1801                    /udk/usr/ccs/bin \
1802                    /bsd43/usr/lib/cmplrs/cc \
1803                    /usr/cross64/usr/bin \
1804                    /usr/lib/cmplrs/cc \
1805                    /sysv/usr/lib/cmplrs/cc \
1806                    /svr4/usr/lib/cmplrs/cc \
1807                    /usr/bin"
1808         fi
1809
1810         for dir in $test_dirs; do
1811                 if test -x $dir/as$host_exeext; then
1812                         gcc_cv_as=$dir/as$host_exeext
1813                         break;
1814                 fi
1815         done
1816 fi
1817 case $in_tree_gas in
1818   yes)
1819     AC_MSG_RESULT("newly built gas")
1820     ;;
1821   no)
1822     AC_MSG_RESULT($gcc_cv_as)
1823     ;;
1824 esac
1825
1826 # Identify the linker which will work hand-in-glove with the newly
1827 # built GCC, so that we can examine its features.  This is the linker
1828 # which will be driven by the driver program.
1829 #
1830 # If build != host, and we aren't building gas in-tree, we identify a
1831 # build->target linker and hope that it will have the same features
1832 # as the host->target linker we'll be using.
1833 AC_MSG_CHECKING(what linker to use)
1834 in_tree_ld=no
1835 gcc_cv_ld=
1836 gcc_cv_gld_major_version=
1837 gcc_cv_gld_minor_version=
1838 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1839 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1840 if test -x "$DEFAULT_LINKER"; then
1841         gcc_cv_ld="$DEFAULT_LINKER"
1842 elif test -x collect-ld$host_exeext; then
1843         # Build using linker in the current directory.
1844         gcc_cv_ld=./collect-ld$host_exeext
1845 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1846      && test -f ../ld/Makefile \
1847      && test x$build = x$host; then
1848         # Single tree build which includes ld.  We want to prefer it
1849         # over whatever linker top-level may have detected, since
1850         # we'll use what we're building after installation anyway.
1851         in_tree_ld=yes
1852         in_tree_ld_is_elf=no
1853         if (grep 'EMUL = .*elf' ../ld/Makefile \
1854             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1855           in_tree_ld_is_elf=yes
1856         fi
1857         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1858         do
1859 changequote(,)dnl
1860                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1861 changequote([,])dnl
1862                 if test x$gcc_cv_gld_version != x; then
1863                         break
1864                 fi
1865         done
1866 changequote(,)dnl
1867         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1868         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1869 changequote([,])dnl
1870         rm -f collect-ld$host_exeext
1871         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1872                 2>/dev/null
1873 elif test -x "$LD_FOR_TARGET"; then
1874         gcc_cv_ld="$LD_FOR_TARGET"
1875 elif test -x "$LD" && test x$host = x$target; then
1876         gcc_cv_ld="$LD"
1877 fi
1878
1879 if test "x$gcc_cv_ld" = x; then
1880         # Search the same directories that the installed compiler will
1881         # search.  Else we may find the wrong linker and lose.  If we
1882         # do not find a suitable linker binary, then try the user's
1883         # path.
1884         #
1885         # Also note we have to check MD_EXEC_PREFIX before checking the
1886         # user's path.  Unfortunately, there is no good way to get at the
1887         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1888         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1889         # to be fixed as part of the make/configure rewrite too.
1890
1891         if test "x$exec_prefix" = xNONE; then
1892                 if test "x$prefix" = xNONE; then
1893                         test_prefix=/usr/local
1894                 else
1895                         test_prefix=$prefix
1896                 fi
1897         else
1898                 test_prefix=$exec_prefix
1899         fi
1900
1901         # If the loop below does not find an linker, then use whatever
1902         # one we can find in the users's path.
1903         # user's path.
1904         if test "x$program_prefix" != xNONE; then
1905                 gcc_cv_ld=${program_prefix}ld$host_exeext
1906         else
1907                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$host_exeext
1908         fi
1909
1910         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1911                    $test_prefix/libexec/gcc/$target_noncanonical \
1912                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1913                    /usr/lib/gcc/$target_noncanonical \
1914                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1915                    $test_prefix/$target_noncanonical/bin"
1916
1917         if test x$host = x$target; then
1918             test_dirs="$test_dirs \
1919                    /usr/libexec \
1920                    /usr/ccs/gcc \
1921                    /usr/ccs/bin \
1922                    /udk/usr/ccs/bin \
1923                    /bsd43/usr/lib/cmplrs/cc \
1924                    /usr/cross64/usr/bin \
1925                    /usr/lib/cmplrs/cc \
1926                    /sysv/usr/lib/cmplrs/cc \
1927                    /svr4/usr/lib/cmplrs/cc \
1928                    /usr/bin"
1929         fi
1930
1931         for dir in $test_dirs; do
1932                 if test -x $dir/ld$host_exeext; then
1933                         gcc_cv_ld=$dir/ld$host_exeext
1934                         break;
1935                 fi
1936         done
1937 fi
1938 case $in_tree_ld in
1939   yes)
1940     AC_MSG_RESULT("newly built ld")
1941     ;;
1942   no)
1943     AC_MSG_RESULT($gcc_cv_ld)
1944     ;;
1945 esac
1946
1947 # Figure out what nm we will be using.
1948 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1949 AC_MSG_CHECKING(what nm to use)
1950 in_tree_nm=no
1951 if test -x nm$host_exeext; then
1952         gcc_cv_nm=./nm$host_exeext
1953 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1954      && test -f ../binutils/Makefile; then
1955         # Single tree build which includes binutils.
1956         in_tree_nm=yes
1957         gcc_cv_nm=./nm$host_exeext
1958         rm -f nm$host_exeext
1959         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1960 elif test "x$program_prefix" != xNONE; then
1961         gcc_cv_nm=${program_prefix}nm$host_exeext
1962 else
1963         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$host_exeext
1964 fi
1965 case $in_tree_nm in
1966   yes) AC_MSG_RESULT("newly built nm") ;;
1967   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1968 esac
1969
1970 # Figure out what objdump we will be using.
1971 AC_MSG_CHECKING(what objdump to use)
1972 in_tree_objdump=no
1973 if test -x objdump$host_exeext; then
1974         gcc_cv_objdump=./objdump$host_exeext
1975 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1976      && test -f ../binutils/Makefile; then
1977         # Single tree build which includes binutils.
1978         in_tree_objdump=yes
1979         gcc_cv_objdump=./objdump$host_exeext
1980         rm -f objdump$host_exeext
1981         $symbolic_link ../binutils/objdump$host_exeext \
1982                 objdump$host_exeext 2>/dev/null
1983 elif test "x$program_prefix" != xNONE; then
1984         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1985 else
1986         gcc_cv_objdump=`echo objdump | \
1987                 sed "${program_transform_name}"`$host_exeext
1988 fi
1989 case $in_tree_objdump in
1990   yes) AC_MSG_RESULT("newly built objdump") ;;
1991   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1992 esac
1993
1994 # Figure out what assembler alignment features are present.
1995 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1996  [2,6,0],,
1997 [.balign 4
1998 .p2align 2],,
1999 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2000   [Define if your assembler supports .balign and .p2align.])])
2001
2002 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2003  [2,8,0],,
2004  [.p2align 4,,7],,
2005 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2006   [Define if your assembler supports specifying the maximum number
2007    of bytes to skip when using the GAS .p2align command.])])
2008
2009 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2010  [elf,2,9,0],,
2011  [conftest_label1: .word 0
2012 .subsection -1
2013 conftest_label2: .word 0
2014 .previous],
2015  [if test x$gcc_cv_nm != x; then
2016     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2017     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2018     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2019     then :
2020     else gcc_cv_as_subsection_m1=yes
2021     fi
2022     rm -f conftest.nm1 conftest.nm2
2023   fi],
2024  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2025   [Define if your assembler supports .subsection and .subsection -1 starts
2026    emitting at the beginning of your section.])])
2027
2028 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2029  [2,2,0],,
2030  [      .weak foobar],,
2031 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2032
2033 # .hidden needs to be supported in both the assembler and the linker,
2034 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2035 # This is irritatingly difficult to feature test for; we have to check the
2036 # date string after the version number.  If we've got an in-tree
2037 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2038 # to be safe.
2039 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2040 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2041  [elf,2,13,0],,
2042 [       .hidden foobar
2043 foobar:])
2044
2045 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2046 [if test $in_tree_ld = yes ; then
2047   gcc_cv_ld_hidden=no
2048   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2049      && test $in_tree_ld_is_elf = yes; then
2050      gcc_cv_ld_hidden=yes
2051   fi
2052 else
2053   gcc_cv_ld_hidden=yes
2054   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2055   if echo "$ld_ver" | grep GNU > /dev/null; then
2056 changequote(,)dnl
2057     ld_vers=`echo $ld_ver | sed -n \
2058         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2059         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2060         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2061         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2062         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2063         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2064     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2065     if test 0"$ld_date" -lt 20020404; then
2066       if test -n "$ld_date"; then
2067         # If there was date string, but was earlier than 2002-04-04, fail
2068         gcc_cv_ld_hidden=no
2069       elif test -z "$ld_vers"; then
2070         # If there was no date string nor ld version number, something is wrong
2071         gcc_cv_ld_hidden=no
2072       else
2073         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2074         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2075         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2076         test -z "$ld_vers_patch" && ld_vers_patch=0
2077         if test "$ld_vers_major" -lt 2; then
2078           gcc_cv_ld_hidden=no
2079         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2080           gcc_cv_ld_hidden="no"
2081         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2082           gcc_cv_ld_hidden=no
2083         fi
2084       fi
2085 changequote([,])dnl
2086     fi
2087   else
2088     case "${target}" in
2089       hppa64*-*-hpux* | ia64*-*-hpux*)
2090         gcc_cv_ld_hidden=yes
2091         ;;
2092       *)
2093         gcc_cv_ld_hidden=no
2094         ;;
2095     esac
2096   fi
2097 fi])
2098 libgcc_visibility=no
2099 AC_SUBST(libgcc_visibility)
2100 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2101   libgcc_visibility=yes
2102   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2103   [Define if your assembler and linker support .hidden.])
2104 fi
2105
2106 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2107 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2108   [elf,2,11,0],,
2109 [       .data
2110         .uleb128 L2 - L1
2111 L1:
2112         .uleb128 1280
2113         .sleb128 -1010
2114 L2:],
2115  [# GAS versions before 2.11 do not support uleb128,
2116   # despite appearing to.
2117   # ??? There exists an elf-specific test that will crash
2118   # the assembler.  Perhaps it's better to figure out whether
2119   # arbitrary sections are supported and try the test.
2120   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2121   if echo "$as_ver" | grep GNU > /dev/null; then
2122 changequote(,)dnl
2123     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2124     as_major=`echo $as_ver | sed 's/\..*//'`
2125     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2126 changequote([,])dnl
2127     if test $as_major -eq 2 && test $as_minor -lt 11
2128     then :
2129     else gcc_cv_as_leb128=yes
2130     fi
2131   fi],
2132   [AC_DEFINE(HAVE_AS_LEB128, 1,
2133     [Define if your assembler supports .sleb128 and .uleb128.])])
2134
2135 # GAS versions up to and including 2.11.0 may mis-optimize
2136 # .eh_frame data.
2137 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2138   [elf,2,12,0],,
2139 [       .text
2140 .LFB1:
2141         .4byte  0
2142 .L1:
2143         .4byte  0
2144 .LFE1:
2145         .section        .eh_frame,"aw",@progbits
2146 __FRAME_BEGIN__:
2147         .4byte  .LECIE1-.LSCIE1
2148 .LSCIE1:
2149         .4byte  0x0
2150         .byte   0x1
2151         .ascii "z\0"
2152         .byte   0x1
2153         .byte   0x78
2154         .byte   0x1a
2155         .byte   0x0
2156         .byte   0x4
2157         .4byte  1
2158         .p2align 1
2159 .LECIE1:
2160 .LSFDE1:
2161         .4byte  .LEFDE1-.LASFDE1
2162 .LASFDE1:
2163         .4byte  .LASFDE1-__FRAME_BEGIN__
2164         .4byte  .LFB1
2165         .4byte  .LFE1-.LFB1
2166         .byte   0x4
2167         .4byte  .LFE1-.LFB1
2168         .byte   0x4
2169         .4byte  .L1-.LFB1
2170 .LEFDE1:],
2171 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2172 cat > conftest.lit <<EOF
2173  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2174  0010 01000000 12000000 18000000 00000000  ................
2175  0020 08000000 04080000 0044               .........D      @&t@
2176 EOF
2177 cat > conftest.big <<EOF
2178  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2179  0010 00000001 00000012 00000018 00000000  ................
2180  0020 00000008 04000000 0844               .........D      @&t@
2181 EOF
2182   # If the assembler didn't choke, and we can objdump,
2183   # and we got the correct data, then succeed.
2184   if test x$gcc_cv_objdump != x \
2185   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2186      | tail -3 > conftest.got \
2187   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2188     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2189   then
2190     gcc_cv_as_eh_frame=yes
2191   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2192     gcc_cv_as_eh_frame=buggy
2193   else
2194     # Uh oh, what do we do now?
2195     gcc_cv_as_eh_frame=no
2196   fi])
2197
2198 if test $gcc_cv_as_eh_frame = buggy; then
2199   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2200   [Define if your assembler mis-optimizes .eh_frame data.])
2201 fi
2202
2203 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2204  [elf,2,12,0], [--fatal-warnings],
2205  [.section .rodata.str, "aMS", @progbits, 1])
2206 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2207   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2208 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2209
2210 # Thread-local storage - the check is heavily parametrized.
2211 conftest_s=
2212 tls_first_major=
2213 tls_first_minor=
2214 tls_as_opt=
2215 case "$target" in
2216 changequote(,)dnl
2217   alpha*-*-*)
2218     conftest_s='
2219         .section ".tdata","awT",@progbits
2220 foo:    .long   25
2221         .text
2222         ldq     $27,__tls_get_addr($29)         !literal!1
2223         lda     $16,foo($29)                    !tlsgd!1
2224         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2225         ldq     $27,__tls_get_addr($29)         !literal!2
2226         lda     $16,foo($29)                    !tlsldm!2
2227         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2228         ldq     $1,foo($29)                     !gotdtprel
2229         ldah    $2,foo($29)                     !dtprelhi
2230         lda     $3,foo($2)                      !dtprello
2231         lda     $4,foo($29)                     !dtprel
2232         ldq     $1,foo($29)                     !gottprel
2233         ldah    $2,foo($29)                     !tprelhi
2234         lda     $3,foo($2)                      !tprello
2235         lda     $4,foo($29)                     !tprel'
2236         tls_first_major=2
2237         tls_first_minor=13
2238         tls_as_opt=--fatal-warnings
2239         ;;
2240   i[34567]86-*-*)
2241     conftest_s='
2242         .section ".tdata","awT",@progbits
2243 foo:    .long   25
2244         .text
2245         movl    %gs:0, %eax
2246         leal    foo@TLSGD(,%ebx,1), %eax
2247         leal    foo@TLSLDM(%ebx), %eax
2248         leal    foo@DTPOFF(%eax), %edx
2249         movl    foo@GOTTPOFF(%ebx), %eax
2250         subl    foo@GOTTPOFF(%ebx), %eax
2251         addl    foo@GOTNTPOFF(%ebx), %eax
2252         movl    foo@INDNTPOFF, %eax
2253         movl    $foo@TPOFF, %eax
2254         subl    $foo@TPOFF, %eax
2255         leal    foo@NTPOFF(%ecx), %eax'
2256         tls_first_major=2
2257         tls_first_minor=14
2258         tls_as_opt=--fatal-warnings
2259         ;;
2260   x86_64-*-*)
2261     conftest_s='
2262         .section ".tdata","awT",@progbits
2263 foo:    .long   25
2264         .text
2265         movq    %fs:0, %rax
2266         leaq    foo@TLSGD(%rip), %rdi
2267         leaq    foo@TLSLD(%rip), %rdi
2268         leaq    foo@DTPOFF(%rax), %rdx
2269         movq    foo@GOTTPOFF(%rip), %rax
2270         movq    $foo@TPOFF, %rax'
2271         tls_first_major=2
2272         tls_first_minor=14
2273         tls_as_opt=--fatal-warnings
2274         ;;
2275   ia64-*-*)
2276     conftest_s='
2277         .section ".tdata","awT",@progbits
2278 foo:    data8   25
2279         .text
2280         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2281         addl    r17 = @ltoff(@dtprel(foo#)), gp
2282         addl    r18 = @ltoff(@tprel(foo#)), gp
2283         addl    r19 = @dtprel(foo#), gp
2284         adds    r21 = @dtprel(foo#), r13
2285         movl    r23 = @dtprel(foo#)
2286         addl    r20 = @tprel(foo#), gp
2287         adds    r22 = @tprel(foo#), r13
2288         movl    r24 = @tprel(foo#)'
2289         tls_first_major=2
2290         tls_first_minor=13
2291         tls_as_opt=--fatal-warnings
2292         ;;
2293   powerpc-*-*)
2294     conftest_s='
2295         .section ".tdata","awT",@progbits
2296         .align 2
2297 ld0:    .space 4
2298 ld1:    .space 4
2299 x1:     .space 4
2300 x2:     .space 4
2301 x3:     .space 4
2302         .text
2303         addi 3,31,ld0@got@tlsgd
2304         bl __tls_get_addr
2305         addi 3,31,x1@got@tlsld
2306         bl __tls_get_addr
2307         addi 9,3,x1@dtprel
2308         addis 9,3,x2@dtprel@ha
2309         addi 9,9,x2@dtprel@l
2310         lwz 9,x3@got@tprel(31)
2311         add 9,9,x@tls
2312         addi 9,2,x1@tprel
2313         addis 9,2,x2@tprel@ha
2314         addi 9,9,x2@tprel@l'
2315         tls_first_major=2
2316         tls_first_minor=14
2317         tls_as_opt="-a32 --fatal-warnings"
2318         ;;
2319   powerpc64-*-*)
2320     conftest_s='
2321         .section ".tdata","awT",@progbits
2322         .align 3
2323 ld0:    .space 8
2324 ld1:    .space 8
2325 x1:     .space 8
2326 x2:     .space 8
2327 x3:     .space 8
2328         .text
2329         addi 3,2,ld0@got@tlsgd
2330         bl .__tls_get_addr
2331         nop
2332         addi 3,2,ld1@toc
2333         bl .__tls_get_addr
2334         nop
2335         addi 3,2,x1@got@tlsld
2336         bl .__tls_get_addr
2337         nop
2338         addi 9,3,x1@dtprel
2339         bl .__tls_get_addr
2340         nop
2341         addis 9,3,x2@dtprel@ha
2342         addi 9,9,x2@dtprel@l
2343         bl .__tls_get_addr
2344         nop
2345         ld 9,x3@got@dtprel(2)
2346         add 9,9,3
2347         bl .__tls_get_addr
2348         nop'
2349         tls_first_major=2
2350         tls_first_minor=14
2351         tls_as_opt="-a64 --fatal-warnings"
2352         ;;
2353   s390-*-*)
2354     conftest_s='
2355         .section ".tdata","awT",@progbits
2356 foo:    .long   25
2357         .text
2358         .long   foo@TLSGD
2359         .long   foo@TLSLDM
2360         .long   foo@DTPOFF
2361         .long   foo@NTPOFF
2362         .long   foo@GOTNTPOFF
2363         .long   foo@INDNTPOFF
2364         l       %r1,foo@GOTNTPOFF(%r12)
2365         l       %r1,0(%r1):tls_load:foo
2366         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2367         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2368         tls_first_major=2
2369         tls_first_minor=14
2370         tls_as_opt="-m31 --fatal-warnings"
2371         ;;
2372   s390x-*-*)
2373     conftest_s='
2374         .section ".tdata","awT",@progbits
2375 foo:    .long   25
2376         .text
2377         .quad   foo@TLSGD
2378         .quad   foo@TLSLDM
2379         .quad   foo@DTPOFF
2380         .quad   foo@NTPOFF
2381         .quad   foo@GOTNTPOFF
2382         lg      %r1,foo@GOTNTPOFF(%r12)
2383         larl    %r1,foo@INDNTPOFF
2384         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2385         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2386         tls_first_major=2
2387         tls_first_minor=14
2388         tls_as_opt="-m64 -Aesame --fatal-warnings"
2389         ;;
2390   sh-*-* | sh[34]-*-*)
2391     conftest_s='
2392         .section ".tdata","awT",@progbits
2393 foo:    .long   25
2394         .text
2395         .long   foo@TLSGD
2396         .long   foo@TLSLDM
2397         .long   foo@DTPOFF
2398         .long   foo@GOTTPOFF
2399         .long   foo@TPOFF'
2400         tls_first_major=2
2401         tls_first_minor=13
2402         tls_as_opt=--fatal-warnings
2403         ;;
2404   sparc*-*-*)
2405     case "$target" in
2406       sparc*-sun-solaris2.*)
2407         on_solaris=yes
2408         ;;
2409       *)
2410         on_solaris=no
2411         ;;
2412     esac
2413     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2414       conftest_s='
2415         .section ".tdata",#alloc,#write,#tls
2416 foo:    .long   25
2417         .text
2418         sethi   %tgd_hi22(foo), %o0
2419         add     %o0, %tgd_lo10(foo), %o1
2420         add     %l7, %o1, %o0, %tgd_add(foo)
2421         call    __tls_get_addr, %tgd_call(foo)
2422         sethi   %tldm_hi22(foo), %l1
2423         add     %l1, %tldm_lo10(foo), %l2
2424         add     %l7, %l2, %o0, %tldm_add(foo)
2425         call    __tls_get_addr, %tldm_call(foo)
2426         sethi   %tldo_hix22(foo), %l3
2427         xor     %l3, %tldo_lox10(foo), %l4
2428         add     %o0, %l4, %l5, %tldo_add(foo)
2429         sethi   %tie_hi22(foo), %o3
2430         add     %o3, %tie_lo10(foo), %o3
2431         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2432         add     %g7, %o2, %o4, %tie_add(foo)
2433         sethi   %tle_hix22(foo), %l1
2434         xor     %l1, %tle_lox10(foo), %o5
2435         ld      [%g7 + %o5], %o1'
2436         tls_first_major=0
2437         tls_first_minor=0
2438     else
2439       conftest_s='
2440         .section ".tdata","awT",@progbits
2441 foo:    .long   25
2442         .text
2443         sethi   %tgd_hi22(foo), %o0
2444         add     %o0, %tgd_lo10(foo), %o1
2445         add     %l7, %o1, %o0, %tgd_add(foo)
2446         call    __tls_get_addr, %tgd_call(foo)
2447         sethi   %tldm_hi22(foo), %l1
2448         add     %l1, %tldm_lo10(foo), %l2
2449         add     %l7, %l2, %o0, %tldm_add(foo)
2450         call    __tls_get_addr, %tldm_call(foo)
2451         sethi   %tldo_hix22(foo), %l3
2452         xor     %l3, %tldo_lox10(foo), %l4
2453         add     %o0, %l4, %l5, %tldo_add(foo)
2454         sethi   %tie_hi22(foo), %o3
2455         add     %o3, %tie_lo10(foo), %o3
2456         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2457         add     %g7, %o2, %o4, %tie_add(foo)
2458         sethi   %tle_hix22(foo), %l1
2459         xor     %l1, %tle_lox10(foo), %o5
2460         ld      [%g7 + %o5], %o1'
2461         tls_first_major=2
2462         tls_first_minor=14
2463         tls_as_opt="-32 --fatal-warnings"
2464       fi
2465         ;;
2466 changequote([,])dnl
2467 esac
2468 if test -z "$tls_first_major"; then
2469   : # If we don't have a check, assume no support.
2470 else
2471   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2472   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2473   [AC_DEFINE(HAVE_AS_TLS, 1,
2474             [Define if your assembler supports thread-local storage.])])
2475 fi
2476
2477 # Target-specific assembler checks.
2478
2479 if test x"$demangler_in_ld" = xyes; then
2480   AC_MSG_CHECKING(linker --demangle support)
2481   gcc_cv_ld_demangle=no
2482   if test $in_tree_ld = yes; then
2483     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2484       gcc_cv_ld_demangle=yes
2485     fi
2486   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2487     # Check if the GNU linker supports --demangle option
2488     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2489       gcc_cv_ld_demangle=yes
2490     fi
2491   fi
2492   if test x"$gcc_cv_ld_demangle" = xyes; then
2493     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2494 [Define if your linker supports --demangle option.])
2495   fi
2496   AC_MSG_RESULT($gcc_cv_ld_demangle)
2497 fi
2498
2499 case "$target" in
2500   # All TARGET_ABI_OSF targets.
2501   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2502     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2503         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2504 [       .set nomacro
2505         .text
2506         extbl   $3, $2, $3      !lituse_bytoff!1
2507         ldq     $2, a($29)      !literal!1
2508         ldq     $4, b($29)      !literal!2
2509         ldq_u   $3, 0($2)       !lituse_base!1
2510         ldq     $27, f($29)     !literal!5
2511         jsr     $26, ($27), f   !lituse_jsr!5
2512         ldah    $29, 0($26)     !gpdisp!3
2513         lda     $0, c($29)      !gprel
2514         ldah    $1, d($29)      !gprelhigh
2515         lda     $1, d($1)       !gprellow
2516         lda     $29, 0($29)     !gpdisp!3],,
2517     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2518   [Define if your assembler supports explicit relocations.])])
2519     ;;
2520
2521   cris-*-*)
2522     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2523       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2524       [-no-mul-bug-abort], [.text],,
2525       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2526                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2527     ;;
2528
2529   sparc*-*-*)
2530     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2531       [.register %g2, #scratch],,
2532       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2533                 [Define if your assembler supports .register.])])
2534
2535     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2536       [-relax], [.text],,
2537       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2538                 [Define if your assembler supports -relax option.])])
2539
2540     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2541       gcc_cv_as_sparc_ua_pcrel,,
2542       [-K PIC],
2543 [.text
2544 foo:
2545         nop
2546 .data
2547 .align 4
2548 .byte 0
2549 .uaword %r_disp32(foo)],
2550       [if test x$gcc_cv_ld != x \
2551        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2552          gcc_cv_as_sparc_ua_pcrel=yes
2553        fi
2554        rm -f conftest],
2555       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2556                 [Define if your assembler and linker support unaligned PC relative relocs.])
2557
2558       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2559         gcc_cv_as_sparc_ua_pcrel_hidden,,
2560         [-K PIC],
2561 [.data
2562 .align 4
2563 .byte 0x31
2564 .uaword %r_disp32(foo)
2565 .byte 0x32, 0x33, 0x34
2566 .global foo
2567 .hidden foo
2568 foo:
2569 .skip 4],
2570         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2571          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2572          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2573             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2574             if $gcc_cv_objdump -R conftest 2> /dev/null \
2575                | grep 'DISP32' > /dev/null 2>&1; then
2576                 :
2577             else
2578                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2579             fi
2580          fi
2581          rm -f conftest],
2582          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2583                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2584     ]) # unaligned pcrel relocs
2585
2586     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2587       gcc_cv_as_sparc_offsetable_lo10,,
2588       [-xarch=v9],
2589 [.text
2590         or %g1, %lo(ab) + 12, %g1
2591         or %g1, %lo(ab + 12), %g1],
2592       [if test x$gcc_cv_objdump != x \
2593        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2594           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2595          gcc_cv_as_offsetable_lo10=yes
2596        fi],
2597        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2598                  [Define if your assembler supports offsetable %lo().])])
2599     ;;
2600
2601 changequote(,)dnl
2602   i[34567]86-*-* | x86_64-*-*)
2603 changequote([,])dnl
2604     case $target_os in
2605       cygwin* | pe | mingw32*)
2606         # Used for DWARF 2 in PE
2607         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2608           gcc_cv_as_ix86_pe_secrel32,
2609           [2,15,91],,
2610 [.text
2611 foo:    nop
2612 .data
2613         .secrel32 foo],
2614           [if test x$gcc_cv_ld != x \
2615            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2616              gcc_cv_as_ix86_pe_secrel32=yes
2617            fi
2618            rm -f conftest],
2619           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2620             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2621         ;;
2622     esac
2623
2624     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2625        gcc_cv_as_ix86_filds_fists,
2626       [2,9,0],, [filds mem; fists mem],,
2627       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2628         [Define if your assembler uses the new HImode fild and fist notation.])])
2629
2630     gcc_GAS_CHECK_FEATURE([cmov syntax],
2631       gcc_cv_as_ix86_cmov_sun_syntax,,,
2632       [cmovl.l %edx, %eax],,
2633       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2634         [Define if your assembler supports the Sun syntax for cmov.])])
2635
2636     # This one is used unconditionally by i386.[ch]; it is to be defined
2637     # to 1 if the feature is present, 0 otherwise.
2638     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2639         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2640 [       .text
2641 .L0:
2642         nop
2643         .data
2644         .long .L0@GOTOFF])
2645     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2646       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2647       [Define true if the assembler supports '.long foo@GOTOFF'.])
2648     ;;
2649
2650   ia64*-*-*)
2651     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2652         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2653 [       .text
2654         addl r15 = @ltoffx(x#), gp
2655         ;;
2656         ld8.mov r16 = [[r15]], x#],,
2657     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2658           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2659
2660     ;;
2661
2662   powerpc*-*-*)
2663     case $target in
2664       *-*-aix*) conftest_s='    .csect .text[[PR]]
2665         mfcr 3,128';;
2666       *-*-darwin*) conftest_s=' .text
2667         mfcr r3,128';;
2668       *)       conftest_s='     .text
2669         mfcr 3,128';;
2670     esac
2671
2672     gcc_GAS_CHECK_FEATURE([mfcr field support],
2673       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2674       [$conftest_s],,
2675       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2676           [Define if your assembler supports mfcr field.])])
2677     ;;
2678
2679   mips*-*-*)
2680     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2681       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2682 [       lw $4,%gp_rel(foo)($4)],,
2683       [if test x$target_cpu_default = x
2684        then target_cpu_default=MASK_EXPLICIT_RELOCS
2685        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2686        fi])
2687
2688     ;;
2689 esac
2690 # ??? Not all targets support dwarf2 debug_line, even within a version
2691 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2692 # info to the output file.  So, as supported targets are added to gas 2.11,
2693 # add some instruction here to (also) show we expect this might work.
2694 # ??? Once 2.11 is released, probably need to add first known working
2695 # version to the per-target configury.
2696 case "$target" in
2697   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2698   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2699   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2700     insn="nop"
2701     ;;
2702   ia64*-*-* | s390*-*-*)
2703     insn="nop 0"
2704     ;;
2705   mmix-*-*)
2706     insn="swym 0"
2707     ;;
2708 esac
2709 if test x"$insn" != x; then
2710  conftest_s="\
2711         .file 1 \"conftest.s\"
2712         .loc 1 3 0
2713         $insn"
2714  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2715   gcc_cv_as_dwarf2_debug_line,
2716   [elf,2,11,0],, [$conftest_s],
2717   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2718    if grep debug_line conftest.o > /dev/null 2>&1; then
2719      gcc_cv_as_dwarf2_debug_line=yes
2720    fi])
2721
2722 # The .debug_line file table must be in the exact order that
2723 # we specified the files, since these indices are also used
2724 # by DW_AT_decl_file.  Approximate this test by testing if
2725 # the assembler bitches if the same index is assigned twice.
2726  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2727   gcc_cv_as_dwarf2_file_buggy,,,
2728 [       .file 1 "foo.s"
2729         .file 1 "bar.s"])
2730
2731  if test $gcc_cv_as_dwarf2_debug_line = yes \
2732  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2733         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2734   [Define if your assembler supports dwarf2 .file/.loc directives,
2735    and preserves file table indices exactly as given.])
2736  fi
2737
2738  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2739   gcc_cv_as_gdwarf2_flag,
2740   [elf,2,11,0], [--gdwarf2], [$insn],,
2741   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2742 [Define if your assembler supports the --gdwarf2 option.])])
2743
2744  gcc_GAS_CHECK_FEATURE([--gstabs option],
2745   gcc_cv_as_gstabs_flag,
2746   [elf,2,11,0], [--gstabs], [$insn],
2747   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2748    # and warns about it, but still exits successfully.  So check for
2749    # this.
2750    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2751    then :
2752    else gcc_cv_as_gstabs_flag=yes
2753    fi],
2754   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2755 [Define if your assembler supports the --gstabs option.])])
2756 fi
2757
2758 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2759 gcc_cv_ld_ro_rw_mix=unknown
2760 if test $in_tree_ld = yes ; then
2761   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2762      && test $in_tree_ld_is_elf = yes; then
2763     gcc_cv_ld_ro_rw_mix=read-write
2764   fi
2765 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2766   echo '.section myfoosect, "a"' > conftest1.s
2767   echo '.section myfoosect, "aw"' > conftest2.s
2768   echo '.byte 1' >> conftest2.s
2769   echo '.section myfoosect, "a"' > conftest3.s
2770   echo '.byte 0' >> conftest3.s
2771   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2772      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2773      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2774      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2775         conftest2.o conftest3.o > /dev/null 2>&1; then
2776     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2777                          | sed -e '/myfoosect/!d' -e N`
2778     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2779       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2780         gcc_cv_ld_ro_rw_mix=read-only
2781       else
2782         gcc_cv_ld_ro_rw_mix=read-write
2783       fi
2784     fi
2785   fi
2786 changequote(,)dnl
2787   rm -f conftest.* conftest[123].*
2788 changequote([,])dnl
2789 fi
2790 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2791         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2792   [Define if your linker links a mix of read-only
2793    and read-write sections into a read-write section.])
2794 fi
2795 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2796
2797 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2798 gcc_cv_ld_eh_frame_hdr=no
2799 if test $in_tree_ld = yes ; then
2800   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2801      && test $in_tree_ld_is_elf = yes; then
2802     gcc_cv_ld_eh_frame_hdr=yes
2803   fi
2804 elif test x$gcc_cv_ld != x; then
2805         # Check if linker supports --eh-frame-hdr option
2806         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2807                 gcc_cv_ld_eh_frame_hdr=yes
2808         fi
2809 fi
2810 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2811         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2812 [Define if your linker supports --eh-frame-hdr option.])
2813 fi
2814 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2815
2816 AC_MSG_CHECKING(linker position independent executable support)
2817 gcc_cv_ld_pie=no
2818 if test $in_tree_ld = yes ; then
2819   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2820      && test $in_tree_ld_is_elf = yes; then
2821     gcc_cv_ld_pie=yes
2822   fi
2823 elif test x$gcc_cv_ld != x; then
2824         # Check if linker supports -pie option
2825         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2826                 gcc_cv_ld_pie=yes
2827         fi
2828 fi
2829 if test x"$gcc_cv_ld_pie" = xyes; then
2830         AC_DEFINE(HAVE_LD_PIE, 1,
2831 [Define if your linker supports -pie option.])
2832 fi
2833 AC_MSG_RESULT($gcc_cv_ld_pie)
2834
2835 # --------
2836 # UNSORTED
2837 # --------
2838
2839 AC_CACHE_CHECK(linker --as-needed support,
2840 gcc_cv_ld_as_needed,
2841 [gcc_cv_ld_as_needed=no
2842 if test $in_tree_ld = yes ; then
2843   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2844      && test $in_tree_ld_is_elf = yes; then
2845     gcc_cv_ld_as_needed=yes
2846   fi
2847 elif test x$gcc_cv_ld != x; then
2848         # Check if linker supports --as-needed and --no-as-needed options
2849         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2850                 gcc_cv_ld_as_needed=yes
2851         fi
2852 fi
2853 ])
2854 if test x"$gcc_cv_ld_as_needed" = xyes; then
2855         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2856 [Define if your linker supports --as-needed and --no-as-needed options.])
2857 fi
2858
2859 if test x$with_sysroot = x && test x$host = x$target \
2860    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2861   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2862 [Define to PREFIX/include if cpp should also search that directory.])
2863 fi
2864
2865 # Find out what GC implementation we want, or may, use.
2866 AC_ARG_WITH(gc,
2867 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2868                           with the compiler],
2869 [case "$withval" in
2870   page | zone)
2871     GGC=ggc-$withval
2872     ;;
2873   *)
2874     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2875     ;;
2876 esac],
2877 [GGC=ggc-page])
2878 AC_SUBST(GGC)
2879 echo "Using $GGC for garbage collection."
2880
2881 # Use the system's zlib library.
2882 zlibdir=-L../zlib
2883 zlibinc="-I\$(srcdir)/../zlib"
2884 AC_ARG_WITH(system-zlib,
2885 [  --with-system-zlib      use installed libz],
2886 zlibdir=
2887 zlibinc=
2888 )
2889 AC_SUBST(zlibdir)
2890 AC_SUBST(zlibinc)
2891
2892 dnl Very limited version of automake's enable-maintainer-mode
2893
2894 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2895   dnl maintainer-mode is disabled by default
2896   AC_ARG_ENABLE(maintainer-mode,
2897 [  --enable-maintainer-mode
2898                           enable make rules and dependencies not useful
2899                           (and sometimes confusing) to the casual installer],
2900       maintainer_mode=$enableval,
2901       maintainer_mode=no)
2902
2903 AC_MSG_RESULT($maintainer_mode)
2904
2905 if test "$maintainer_mode" = "yes"; then
2906   MAINT=''
2907 else
2908   MAINT='#'
2909 fi
2910 AC_SUBST(MAINT)dnl
2911
2912 AC_MSG_CHECKING([whether to use libbanshee for points-to alias analysis])
2913 AC_ARG_WITH(libbanshee,
2914 [  --with-libbanshee      enable libbanshee],
2915 libbanshee="$with_libbanshee",
2916 libbanshee=no)
2917
2918 if test x"$libbanshee" = xyes; then
2919         BANSHEELIB="../libbanshee/points-to/libandersen.a ../libbanshee/engine/libbansheeengine.a ../libbanshee/libcompat/libbansheecompat.a "
2920         BANSHEEINC="-I\$(srcdir)/../libbanshee/libcompat -I\$(srcdir)/../libbanshee -I\$(srcdir)/../libbanshee/points-to"
2921         ANDER="tree-alias-ander.o"
2922         AC_DEFINE(HAVE_BANSHEE, 1, [Define if BANSHEE is available])
2923 else
2924         BANSHEELIB=""
2925         BANSHEEINC=""
2926         ANDER=""
2927 fi
2928 AC_MSG_RESULT($with_libbanshee)
2929
2930 AC_SUBST(ANDER)
2931 AC_SUBST(BANSHEEINC)
2932 AC_SUBST(BANSHEELIB)
2933
2934 # --------------
2935 # Language hooks
2936 # --------------
2937
2938 # Make empty files to contain the specs and options for each language.
2939 # Then add #include lines to for a compiler that has specs and/or options.
2940
2941 lang_opt_files=
2942 lang_specs_files=
2943 lang_tree_files=
2944 for subdir in . $subdirs
2945 do
2946         if test -f $srcdir/$subdir/lang.opt; then
2947             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2948         fi
2949         if test -f $srcdir/$subdir/lang-specs.h; then
2950             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2951         fi
2952         if test -f $srcdir/$subdir/$subdir-tree.def; then
2953             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2954         fi
2955 done
2956
2957 # These (without "all_") are set in each config-lang.in.
2958 # `language' must be a single word so is spelled singularly.
2959 all_languages=
2960 all_boot_languages=
2961 all_compilers=
2962 all_stagestuff=
2963 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders libada-mk'
2964 # List of language makefile fragments.
2965 all_lang_makefrags=
2966 # List of language subdirectory makefiles.  Deprecated.
2967 all_lang_makefiles=
2968 # Files for gengtype
2969 all_gtfiles="$target_gtfiles"
2970 # Files for gengtype with language
2971 all_gtfiles_files_langs=
2972 all_gtfiles_files_files=
2973
2974 # Add the language fragments.
2975 # Languages are added via two mechanisms.  Some information must be
2976 # recorded in makefile variables, these are defined in config-lang.in.
2977 # We accumulate them and plug them into the main Makefile.
2978 # The other mechanism is a set of hooks for each of the main targets
2979 # like `clean', `install', etc.
2980
2981 language_hooks="Make-hooks"
2982
2983 for s in $subdirs
2984 do
2985                 language=
2986                 boot_language=
2987                 compilers=
2988                 stagestuff=
2989                 outputs=
2990                 gtfiles=
2991                 . ${srcdir}/$s/config-lang.in
2992                 if test "x$language" = x
2993                 then
2994                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2995                         exit 1
2996                 fi
2997                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2998                 if test -f ${srcdir}/$s/Makefile.in
2999                 then all_lang_makefiles="$s/Makefile"
3000                 fi
3001                 all_languages="$all_languages $language"
3002                 if test "x$boot_language" = xyes
3003                 then
3004                         all_boot_languages="$all_boot_languages $language"
3005                 fi
3006                 all_compilers="$all_compilers $compilers"
3007                 all_stagestuff="$all_stagestuff $stagestuff"
3008                 all_outputs="$all_outputs $outputs"
3009                 all_gtfiles="$all_gtfiles $gtfiles"
3010                 for f in $gtfiles
3011                 do
3012                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3013                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3014                 done
3015 done
3016
3017 # Pick up gtfiles for c
3018 gtfiles=
3019 s="c"
3020 . ${srcdir}/c-config-lang.in
3021 all_gtfiles="$all_gtfiles $gtfiles"
3022 for f in $gtfiles
3023 do
3024         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3025         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3026 done
3027
3028 check_languages=
3029 for language in $all_languages
3030 do
3031                 check_languages="$check_languages check-$language"
3032 done
3033
3034 # We link each language in with a set of hooks, reached indirectly via
3035 # lang.${target}.
3036
3037 rm -f Make-hooks
3038 touch Make-hooks
3039 target_list="all.build all.cross start.encap rest.encap tags \
3040         install-normal install-common install-man \
3041         uninstall info man srcextra srcman srcinfo \
3042         mostlyclean clean distclean maintainer-clean \
3043         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3044 for t in $target_list
3045 do
3046         x=
3047         for lang in $all_languages
3048         do
3049                         x="$x $lang.$t"
3050         done
3051         echo "lang.$t: $x" >> Make-hooks
3052 done
3053
3054 # --------
3055 # UNSORTED
3056 # --------
3057
3058 # Create .gdbinit.
3059
3060 echo "dir ." > .gdbinit
3061 echo "dir ${srcdir}" >> .gdbinit
3062 if test x$gdb_needs_out_file_path = xyes
3063 then
3064         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3065 fi
3066 if test "x$subdirs" != x; then
3067         for s in $subdirs
3068         do
3069                 echo "dir ${srcdir}/$s" >> .gdbinit
3070         done
3071 fi
3072 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3073
3074 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3075 # absolute path for gcc_tooldir based on inserting the number of up-directory
3076 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3077 # $(libsubdir)/@(unlibsubdir) based path.
3078 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3079 # make and thus we'd get different behavior depending on where we built the
3080 # sources.
3081 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3082     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3083 else
3084 changequote(<<, >>)dnl
3085 # An explanation of the sed strings:
3086 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3087 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3088 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3089 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3090 #
3091 # (*) Note this pattern overwrites the first character of the string
3092 # with a forward slash if one is not already present.  This is not a
3093 # problem because the exact names of the sub-directories concerned is
3094 # unimportant, just the number of them matters.
3095 #
3096 # The practical upshot of these patterns is like this:
3097 #
3098 #  prefix     exec_prefix        result
3099 #  ------     -----------        ------
3100 #   /foo        /foo/bar          ../
3101 #   /foo/       /foo/bar          ../
3102 #   /foo        /foo/bar/         ../
3103 #   /foo/       /foo/bar/         ../
3104 #   /foo        /foo/bar/ugg      ../../
3105 #
3106     dollar='$$'
3107     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3108 changequote([, ])dnl
3109 fi
3110 AC_SUBST(gcc_tooldir)
3111 AC_SUBST(dollar)
3112
3113 # Find a directory in which to install a shared libgcc.
3114
3115 AC_ARG_ENABLE(version-specific-runtime-libs,
3116 [  --enable-version-specific-runtime-libs
3117                           specify that runtime libraries should be
3118                           installed in a compiler-specific directory])
3119
3120 AC_ARG_WITH(slibdir,
3121 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3122 slibdir="$with_slibdir",
3123 if test "${enable_version_specific_runtime_libs+set}" = set; then
3124   slibdir='$(libsubdir)'
3125 elif test "$host" != "$target"; then
3126   slibdir='$(build_tooldir)/lib'
3127 else
3128   slibdir='$(libdir)'
3129 fi)
3130 AC_SUBST(slibdir)
3131
3132 objdir=`${PWDCMD-pwd}`
3133 AC_SUBST(objdir)
3134
3135 # Substitute configuration variables
3136 AC_SUBST(subdirs)
3137 AC_SUBST(srcdir)
3138 AC_SUBST(all_boot_languages)
3139 AC_SUBST(all_compilers)
3140 AC_SUBST(all_gtfiles)
3141 AC_SUBST(all_gtfiles_files_langs)
3142 AC_SUBST(all_gtfiles_files_files)
3143 AC_SUBST(all_lang_makefrags)
3144 AC_SUBST(all_lang_makefiles)
3145 AC_SUBST(all_languages)
3146 AC_SUBST(all_stagestuff)
3147 AC_SUBST(build_exeext)
3148 AC_SUBST(build_install_headers_dir)
3149 AC_SUBST(build_xm_file_list)
3150 AC_SUBST(build_xm_include_list)
3151 AC_SUBST(build_xm_defines)
3152 AC_SUBST(check_languages)
3153 AC_SUBST(cc_set_by_configure)
3154 AC_SUBST(quoted_cc_set_by_configure)
3155 AC_SUBST(cpp_install_dir)
3156 AC_SUBST(xmake_file)
3157 AC_SUBST(tmake_file)
3158 AC_SUBST(extra_gcc_objs)
3159 AC_SUBST(extra_headers_list)
3160 AC_SUBST(extra_objs)
3161 AC_SUBST(extra_parts)
3162 AC_SUBST(extra_passes)
3163 AC_SUBST(extra_programs)
3164 AC_SUBST(float_h_file)
3165 AC_SUBST(gcc_config_arguments)
3166 AC_SUBST(gcc_gxx_include_dir)
3167 AC_SUBST(libstdcxx_incdir)
3168 AC_SUBST(gcc_version)
3169 AC_SUBST(gcc_version_full)
3170 AC_SUBST(gcc_version_trigger)
3171 AC_SUBST(host_exeext)
3172 AC_SUBST(host_xm_file_list)
3173 AC_SUBST(host_xm_include_list)
3174 AC_SUBST(host_xm_defines)
3175 AC_SUBST(out_host_hook_obj)
3176 AC_SUBST(install)
3177 AC_SUBST(lang_opt_files)
3178 AC_SUBST(lang_specs_files)
3179 AC_SUBST(lang_tree_files)
3180 AC_SUBST(local_prefix)
3181 AC_SUBST(md_file)
3182 AC_SUBST(objc_boehm_gc)
3183 AC_SUBST(out_file)
3184 AC_SUBST(out_object_file)
3185 AC_SUBST(stage_prefix_set_by_configure)
3186 AC_SUBST(quoted_stage_prefix_set_by_configure)
3187 AC_SUBST(symbolic_link)
3188 AC_SUBST(thread_file)
3189 AC_SUBST(tm_file_list)
3190 AC_SUBST(tm_include_list)
3191 AC_SUBST(tm_defines)
3192 AC_SUBST(tm_p_file_list)
3193 AC_SUBST(tm_p_include_list)
3194 AC_SUBST(xm_file_list)
3195 AC_SUBST(xm_include_list)
3196 AC_SUBST(xm_defines)
3197 AC_SUBST(c_target_objs)
3198 AC_SUBST(cxx_target_objs)
3199 AC_SUBST(target_cpu_default)
3200
3201 AC_SUBST_FILE(language_hooks)
3202
3203 # If it doesn't already exist, create document directory
3204 echo "checking for the document directory." 1>&2
3205 if test -d doc ; then
3206   true
3207 else
3208   mkdir doc
3209 fi
3210
3211 # Echo link setup.
3212 if test x${build} = x${host} ; then
3213   if test x${host} = x${target} ; then
3214     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3215   else
3216     echo "Links are now set up to build a cross-compiler" 1>&2
3217     echo " from ${host} to ${target}." 1>&2
3218   fi
3219 else
3220   if test x${host} = x${target} ; then
3221     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3222     echo " for ${target}." 1>&2
3223   else
3224     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3225     echo " from ${host} to ${target}." 1>&2
3226   fi
3227 fi
3228
3229 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3230 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3231
3232 # Configure the subdirectories
3233 # AC_CONFIG_SUBDIRS($subdirs)
3234
3235 # Create the Makefile
3236 # and configure language subdirectories
3237 AC_CONFIG_FILES($all_outputs)
3238
3239 AC_CONFIG_COMMANDS([default],
3240 [
3241 case ${CONFIG_HEADERS} in
3242   *auto-host.h:config.in*)
3243   echo > cstamp-h ;;
3244 esac
3245 # Make sure all the subdirs exist.
3246 for d in $subdirs
3247 do
3248     test -d $d || mkdir $d
3249 done
3250 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3251 # bootstrapping and the installation procedure can still use
3252 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3253 # FLAGS_TO_PASS has been modified to solve the problem there.
3254 # This is virtually a duplicate of what happens in configure.lang; we do
3255 # an extra check to make sure this only happens if ln -s can be used.
3256 if test "$symbolic_link" = "ln -s"; then
3257  for d in ${subdirs} fixinc ; do
3258         STARTDIR=`${PWDCMD-pwd}`
3259         cd $d
3260         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3261         do
3262                 rm -f $t
3263                 $symbolic_link ../$t $t 2>/dev/null
3264         done
3265         cd $STARTDIR
3266  done
3267 else true ; fi
3268 ],
3269 [subdirs='$subdirs'
3270 symbolic_link='$symbolic_link'
3271 ])
3272 AC_OUTPUT