gcc/c-parse.in

   1 /* YACC parser for C syntax and for Objective C.  -*-c-*-
   2    Copyright (C) 1987, 1988, 1989, 1992, 1993, 1994, 1995, 1996,
   3    1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 This file is part of GCC.
   6
   7 GCC is free software; you can redistribute it and/or modify it under
   8 the terms of the GNU General Public License as published by the Free
   9 Software Foundation; either version 2, or (at your option) any later
  10 version.
  11
  12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GCC; see the file COPYING.  If not, write to the Free
  19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 02111-1307, USA.  */
  21
  22 /* This file defines the grammar of C and that of Objective C.
  23    ifobjc ... end ifobjc  conditionals contain code for Objective C only.
  24    ifc ... end ifc  conditionals contain code for C only.
  25    Sed commands in Makefile.in are used to convert this file into
  26    c-parse.y and into objc-parse.y.  */
  27
  28 /* To whomever it may concern: I have heard that such a thing was once
  29    written by AT&T, but I have never seen it.  */
  30
  31 ifobjc
  32 %expect 31 /* shift/reduce conflicts, and 1 reduce/reduce conflict.  */
  33 end ifobjc
  34 ifc
  35 %expect 10 /* shift/reduce conflicts, and no reduce/reduce conflicts.  */
  36 end ifc
  37
  38 %{
  39 #include "config.h"
  40 #include "system.h"
  41 #include "tree.h"
  42 #include "input.h"
  43 #include "cpplib.h"
  44 #include "intl.h"
  45 #include "timevar.h"
  46 #include "c-lex.h"
  47 #include "c-tree.h"
  48 #include "c-pragma.h"
  49 #include "flags.h"
  50 #include "output.h"
  51 #include "toplev.h"
  52 #include "ggc.h"
  53 #include "diagnostic.h"
  54
  55 #ifdef MULTIBYTE_CHARS
  56 #include <locale.h>
  57 #endif
  58
  59 ifobjc
  60 #include "objc-act.h"
  61 end ifobjc
  62
  63 /* Since parsers are distinct for each language, put the language string
  64    definition here.  */
  65 ifobjc
  66 const char * const language_string = "GNU Objective-C";
  67 end ifobjc
  68 ifc
  69 const char * const language_string = "GNU C";
  70 end ifc
  71
  72 /* Like YYERROR but do call yyerror.  */
  73 #define YYERROR1 { yyerror ("syntax error"); YYERROR; }
  74
  75 /* Cause the "yydebug" variable to be defined.  */
  76 #define YYDEBUG 1
  77
  78 /* Rename the "yyparse" function so that we can override it elsewhere.  */
  79 #define yyparse yyparse_1
  80 %}
  81
  82 %start program
  83
  84 %union {long itype; tree ttype; enum tree_code code;
  85         const char *filename; int lineno; }
  86
  87 /* All identifiers that are not reserved words
  88    and are not declared typedefs in the current block */
  89 %token IDENTIFIER
  90
  91 /* All identifiers that are declared typedefs in the current block.
  92    In some contexts, they are treated just like IDENTIFIER,
  93    but they can also serve as typespecs in declarations.  */
  94 %token TYPENAME
  95
  96 /* Reserved words that specify storage class.
  97    yylval contains an IDENTIFIER_NODE which indicates which one.  */
  98 %token SCSPEC
  99
 100 /* Reserved words that specify type.
 101    yylval contains an IDENTIFIER_NODE which indicates which one.  */
 102 %token TYPESPEC
 103
 104 /* Reserved words that qualify type: "const", "volatile", or "restrict".
 105    yylval contains an IDENTIFIER_NODE which indicates which one.  */
 106 %token TYPE_QUAL
 107
 108 /* Character or numeric constants.
 109    yylval is the node for the constant.  */
 110 %token CONSTANT
 111
 112 /* String constants in raw form.
 113    yylval is a STRING_CST node.  */
 114 %token STRING
 115
 116 /* "...", used for functions with variable arglists.  */
 117 %token ELLIPSIS
 118
 119 /* the reserved words */
 120 /* SCO include files test "ASM", so use something else. */
 121 %token SIZEOF ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
 122 %token BREAK CONTINUE RETURN GOTO ASM_KEYWORD TYPEOF ALIGNOF
 123 %token ATTRIBUTE EXTENSION LABEL
 124 %token REALPART IMAGPART VA_ARG
 125 %token PTR_VALUE PTR_BASE PTR_EXTENT
 126
 127 /* function name can be a string const or a var decl. */
 128 %token STRING_FUNC_NAME VAR_FUNC_NAME
 129
 130 /* Add precedence rules to solve dangling else s/r conflict */
 131 %nonassoc IF
 132 %nonassoc ELSE
 133
 134 /* Define the operator tokens and their precedences.
 135    The value is an integer because, if used, it is the tree code
 136    to use in the expression made from the operator.  */
 137
 138 %right <code> ASSIGN '='
 139 %right <code> '?' ':'
 140 %left <code> OROR
 141 %left <code> ANDAND
 142 %left <code> '|'
 143 %left <code> '^'
 144 %left <code> '&'
 145 %left <code> EQCOMPARE
 146 %left <code> ARITHCOMPARE
 147 %left <code> LSHIFT RSHIFT
 148 %left <code> '+' '-'
 149 %left <code> '*' '/' '%'
 150 %right <code> UNARY PLUSPLUS MINUSMINUS
 151 %left HYPERUNARY
 152 %left <code> POINTSAT '.' '(' '['
 153
 154 /* The Objective-C keywords.  These are included in C and in
 155    Objective C, so that the token codes are the same in both.  */
 156 %token INTERFACE IMPLEMENTATION END SELECTOR DEFS ENCODE
 157 %token CLASSNAME PUBLIC PRIVATE PROTECTED PROTOCOL OBJECTNAME CLASS ALIAS
 158
 159 %type <code> unop
 160 %type <ttype> ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
 161 %type <ttype> BREAK CONTINUE RETURN GOTO ASM_KEYWORD SIZEOF TYPEOF ALIGNOF
 162
 163 %type <ttype> identifier IDENTIFIER TYPENAME CONSTANT expr nonnull_exprlist exprlist
 164 %type <ttype> expr_no_commas cast_expr unary_expr primary string STRING
 165 %type <ttype> declspecs_nosc_nots_nosa_noea declspecs_nosc_nots_nosa_ea
 166 %type <ttype> declspecs_nosc_nots_sa_noea declspecs_nosc_nots_sa_ea
 167 %type <ttype> declspecs_nosc_ts_nosa_noea declspecs_nosc_ts_nosa_ea
 168 %type <ttype> declspecs_nosc_ts_sa_noea declspecs_nosc_ts_sa_ea
 169 %type <ttype> declspecs_sc_nots_nosa_noea declspecs_sc_nots_nosa_ea
 170 %type <ttype> declspecs_sc_nots_sa_noea declspecs_sc_nots_sa_ea
 171 %type <ttype> declspecs_sc_ts_nosa_noea declspecs_sc_ts_nosa_ea
 172 %type <ttype> declspecs_sc_ts_sa_noea declspecs_sc_ts_sa_ea
 173 %type <ttype> declspecs_ts declspecs_nots
 174 %type <ttype> declspecs_ts_nosa declspecs_nots_nosa
 175 %type <ttype> declspecs_nosc_ts declspecs_nosc_nots declspecs_nosc declspecs
 176 %type <ttype> maybe_type_quals_attrs typespec_nonattr typespec_attr
 177 %type <ttype> typespec_reserved_nonattr typespec_reserved_attr
 178 %type <ttype> typespec_nonreserved_nonattr
 179
 180 %type <ttype> SCSPEC TYPESPEC TYPE_QUAL maybe_type_qual
 181 %type <ttype> initdecls notype_initdecls initdcl notype_initdcl
 182 %type <ttype> init maybeasm
 183 %type <ttype> asm_operands nonnull_asm_operands asm_operand asm_clobbers
 184 %type <ttype> maybe_attribute attributes attribute attribute_list attrib
 185 %type <ttype> any_word extension
 186
 187 %type <ttype> compstmt compstmt_start compstmt_nostart compstmt_primary_start
 188 %type <ttype> do_stmt_start poplevel stmt label
 189
 190 %type <ttype> c99_block_start c99_block_end
 191 %type <ttype> declarator
 192 %type <ttype> notype_declarator after_type_declarator
 193 %type <ttype> parm_declarator
 194 %type <ttype> parm_declarator_starttypename parm_declarator_nostarttypename
 195 %type <ttype> array_declarator
 196
 197 %type <ttype> structsp_attr structsp_nonattr
 198 %type <ttype> component_decl_list component_decl_list2
 199 %type <ttype> component_decl components components_notype component_declarator
 200 %type <ttype> component_notype_declarator
 201 %type <ttype> enumlist enumerator
 202 %type <ttype> struct_head union_head enum_head
 203 %type <ttype> typename absdcl absdcl1 absdcl1_ea absdcl1_noea
 204 %type <ttype> direct_absdcl1 absdcl_maybe_attribute
 205 %type <ttype> xexpr parms parm firstparm identifiers
 206
 207 %type <ttype> parmlist parmlist_1 parmlist_2
 208 %type <ttype> parmlist_or_identifiers parmlist_or_identifiers_1
 209 %type <ttype> identifiers_or_typenames
 210
 211 %type <itype> setspecs setspecs_fp
 212
 213 %type <filename> save_filename
 214 %type <lineno> save_lineno
 215 \f
 216 ifobjc
 217 /* the Objective-C nonterminals */
 218
 219 %type <ttype> ivar_decl_list ivar_decls ivar_decl ivars ivar_declarator
 220 %type <ttype> methoddecl unaryselector keywordselector selector
 221 %type <ttype> keyworddecl receiver objcmessageexpr messageargs
 222 %type <ttype> keywordexpr keywordarglist keywordarg
 223 %type <ttype> myparms myparm optparmlist reservedwords objcselectorexpr
 224 %type <ttype> selectorarg keywordnamelist keywordname objcencodeexpr
 225 %type <ttype> objc_string non_empty_protocolrefs protocolrefs identifier_list objcprotocolexpr
 226
 227 %type <ttype> CLASSNAME OBJECTNAME
 228 end ifobjc
 229 \f
 230 %{
 231 /* Number of statements (loosely speaking) and compound statements
 232    seen so far.  */
 233 static int stmt_count;
 234 static int compstmt_count;
 235
 236 /* Input file and line number of the end of the body of last simple_if;
 237    used by the stmt-rule immediately after simple_if returns.  */
 238 static const char *if_stmt_file;
 239 static int if_stmt_line;
 240
 241 /* List of types and structure classes of the current declaration.  */
 242 static tree current_declspecs = NULL_TREE;
 243 static tree prefix_attributes = NULL_TREE;
 244
 245 /* List of all the attributes applying to the identifier currently being
 246    declared; includes prefix_attributes and possibly some more attributes
 247    just after a comma.  */
 248 static tree all_prefix_attributes = NULL_TREE;
 249
 250 /* Stack of saved values of current_declspecs, prefix_attributes and
 251    all_prefix_attributes.  */
 252 static tree declspec_stack;
 253
 254 /* PUSH_DECLSPEC_STACK is called from setspecs; POP_DECLSPEC_STACK
 255    should be called from the productions making use of setspecs.  */
 256 #define PUSH_DECLSPEC_STACK                                              \
 257   do {                                                                   \
 258     declspec_stack = tree_cons (build_tree_list (prefix_attributes,      \
 259                                                  all_prefix_attributes), \
 260                                 current_declspecs,                       \
 261                                 declspec_stack);                         \
 262   } while (0)
 263
 264 #define POP_DECLSPEC_STACK                                              \
 265   do {                                                                  \
 266     current_declspecs = TREE_VALUE (declspec_stack);                    \
 267     prefix_attributes = TREE_PURPOSE (TREE_PURPOSE (declspec_stack));   \
 268     all_prefix_attributes = TREE_VALUE (TREE_PURPOSE (declspec_stack)); \
 269     declspec_stack = TREE_CHAIN (declspec_stack);                       \
 270   } while (0)
 271
 272 /* For __extension__, save/restore the warning flags which are
 273    controlled by __extension__.  */
 274 #define SAVE_WARN_FLAGS()       \
 275         size_int (pedantic | (warn_pointer_arith << 1))
 276 #define RESTORE_WARN_FLAGS(tval) \
 277   do {                                     \
 278     int val = tree_low_cst (tval, 0);      \
 279     pedantic = val & 1;                    \
 280     warn_pointer_arith = (val >> 1) & 1;   \
 281   } while (0)
 282
 283 ifobjc
 284 /* Objective-C specific parser/lexer information */
 285
 286 static enum tree_code objc_inherit_code;
 287 static int objc_pq_context = 0, objc_public_flag = 0;
 288
 289 /* The following flag is needed to contextualize ObjC lexical analysis.
 290    In some cases (e.g., 'int NSObject;'), it is undesirable to bind
 291    an identifier to an ObjC class, even if a class with that name
 292    exists.  */
 293 static int objc_need_raw_identifier;
 294 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   objc_need_raw_identifier = VAL
 295 end ifobjc
 296
 297 ifc
 298 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   /* nothing */
 299 end ifc
 300
 301 /* Tell yyparse how to print a token's value, if yydebug is set.  */
 302
 303 #define YYPRINT(FILE,YYCHAR,YYLVAL) yyprint(FILE,YYCHAR,YYLVAL)
 304
 305 static void yyprint       PARAMS ((FILE *, int, YYSTYPE));
 306 static void yyerror       PARAMS ((const char *));
 307 static int yylexname      PARAMS ((void));
 308 static inline int _yylex  PARAMS ((void));
 309 static int  yylex         PARAMS ((void));
 310 static void init_reswords PARAMS ((void));
 311
 312 /* Add GC roots for variables local to this file.  */
 313 void
 314 c_parse_init ()
 315 {
 316   ggc_add_tree_root (&declspec_stack, 1);
 317   ggc_add_tree_root (&current_declspecs, 1);
 318   ggc_add_tree_root (&prefix_attributes, 1);
 319   ggc_add_tree_root (&all_prefix_attributes, 1);
 320 }
 321
 322 %}
 323 \f
 324 %%
 325 program: /* empty */
 326                 { if (pedantic)
 327                     pedwarn ("ISO C forbids an empty source file");
 328                   finish_file ();
 329                 }
 330         | extdefs
 331                 {
 332                   /* In case there were missing closebraces,
 333                      get us back to the global binding level.  */
 334                   while (! global_bindings_p ())
 335                     poplevel (0, 0, 0);
 336 ifc
 337                   finish_fname_decls ();
 338 end ifc
 339                   finish_file ();
 340                 }
 341         ;
 342
 343 /* the reason for the strange actions in this rule
 344  is so that notype_initdecls when reached via datadef
 345  can find a valid list of type and sc specs in $0. */
 346
 347 extdefs:
 348         {$<ttype>$ = NULL_TREE; } extdef
 349         | extdefs {$<ttype>$ = NULL_TREE; ggc_collect(); } extdef
 350         ;
 351
 352 extdef:
 353         fndef
 354         | datadef
 355 ifobjc
 356         | objcdef
 357 end ifobjc
 358         | ASM_KEYWORD '(' expr ')' ';'
 359                 { STRIP_NOPS ($3);
 360                   if ((TREE_CODE ($3) == ADDR_EXPR
 361                        && TREE_CODE (TREE_OPERAND ($3, 0)) == STRING_CST)
 362                       || TREE_CODE ($3) == STRING_CST)
 363                     assemble_asm ($3);
 364                   else
 365                     error ("argument of `asm' is not a constant string"); }
 366         | extension extdef
 367                 { RESTORE_WARN_FLAGS ($1); }
 368         ;
 369
 370 datadef:
 371           setspecs notype_initdecls ';'
 372                 { if (pedantic)
 373                     error ("ISO C forbids data definition with no type or storage class");
 374                   else if (!flag_traditional)
 375                     warning ("data definition has no type or storage class");
 376
 377                   POP_DECLSPEC_STACK; }
 378         | declspecs_nots setspecs notype_initdecls ';'
 379                 { POP_DECLSPEC_STACK; }
 380         | declspecs_ts setspecs initdecls ';'
 381                 { POP_DECLSPEC_STACK; }
 382         | declspecs ';'
 383           { shadow_tag ($1); }
 384         | error ';'
 385         | error '}'
 386         | ';'
 387                 { if (pedantic)
 388                     pedwarn ("ISO C does not allow extra `;' outside of a function"); }
 389         ;
 390 \f
 391 fndef:
 392           declspecs_ts setspecs declarator
 393                 { if (! start_function (current_declspecs, $3,
 394                                         all_prefix_attributes))
 395                     YYERROR1;
 396                 }
 397           old_style_parm_decls
 398                 { store_parm_decls (); }
 399           save_filename save_lineno compstmt_or_error
 400                 { DECL_SOURCE_FILE (current_function_decl) = $7;
 401                   DECL_SOURCE_LINE (current_function_decl) = $8;
 402                   finish_function (0);
 403                   POP_DECLSPEC_STACK; }
 404         | declspecs_ts setspecs declarator error
 405                 { POP_DECLSPEC_STACK; }
 406         | declspecs_nots setspecs notype_declarator
 407                 { if (! start_function (current_declspecs, $3,
 408                                         all_prefix_attributes))
 409                     YYERROR1;
 410                 }
 411           old_style_parm_decls
 412                 { store_parm_decls (); }
 413           save_filename save_lineno compstmt_or_error
 414                 { DECL_SOURCE_FILE (current_function_decl) = $7;
 415                   DECL_SOURCE_LINE (current_function_decl) = $8;
 416                   finish_function (0);
 417                   POP_DECLSPEC_STACK; }
 418         | declspecs_nots setspecs notype_declarator error
 419                 { POP_DECLSPEC_STACK; }
 420         | setspecs notype_declarator
 421                 { if (! start_function (NULL_TREE, $2,
 422                                         all_prefix_attributes))
 423                     YYERROR1;
 424                 }
 425           old_style_parm_decls
 426                 { store_parm_decls (); }
 427           save_filename save_lineno compstmt_or_error
 428                 { DECL_SOURCE_FILE (current_function_decl) = $6;
 429                   DECL_SOURCE_LINE (current_function_decl) = $7;
 430                   finish_function (0);
 431                   POP_DECLSPEC_STACK; }
 432         | setspecs notype_declarator error
 433                 { POP_DECLSPEC_STACK; }
 434         ;
 435
 436 identifier:
 437         IDENTIFIER
 438         | TYPENAME
 439 ifobjc
 440         | OBJECTNAME
 441         | CLASSNAME
 442 end ifobjc
 443         ;
 444
 445 unop:     '&'
 446                 { $$ = ADDR_EXPR; }
 447         | '-'
 448                 { $$ = NEGATE_EXPR; }
 449         | '+'
 450                 { $$ = CONVERT_EXPR;
 451 ifc
 452   if (warn_traditional && !in_system_header)
 453     warning ("traditional C rejects the unary plus operator");
 454 end ifc
 455                 }
 456         | PLUSPLUS
 457                 { $$ = PREINCREMENT_EXPR; }
 458         | MINUSMINUS
 459                 { $$ = PREDECREMENT_EXPR; }
 460         | '~'
 461                 { $$ = BIT_NOT_EXPR; }
 462         | '!'
 463                 { $$ = TRUTH_NOT_EXPR; }
 464         ;
 465
 466 expr:   nonnull_exprlist
 467                 { $$ = build_compound_expr ($1); }
 468         ;
 469
 470 exprlist:
 471           /* empty */
 472                 { $$ = NULL_TREE; }
 473         | nonnull_exprlist
 474         ;
 475
 476 nonnull_exprlist:
 477         expr_no_commas
 478                 { $$ = build_tree_list (NULL_TREE, $1); }
 479         | nonnull_exprlist ',' expr_no_commas
 480                 { chainon ($1, build_tree_list (NULL_TREE, $3)); }
 481         ;
 482
 483 unary_expr:
 484         primary
 485         | '*' cast_expr   %prec UNARY
 486                 { $$ = build_indirect_ref ($2, "unary *"); }
 487         /* __extension__ turns off -pedantic for following primary.  */
 488         | extension cast_expr     %prec UNARY
 489                 { $$ = $2;
 490                   RESTORE_WARN_FLAGS ($1); }
 491         | unop cast_expr  %prec UNARY
 492                 { $$ = build_unary_op ($1, $2, 0);
 493                   overflow_warning ($$); }
 494         /* Refer to the address of a label as a pointer.  */
 495         | ANDAND identifier
 496                 { $$ = finish_label_address_expr ($2); }
 497 /* This seems to be impossible on some machines, so let's turn it off.
 498    You can use __builtin_next_arg to find the anonymous stack args.
 499         | '&' ELLIPSIS
 500                 { tree types = TYPE_ARG_TYPES (TREE_TYPE (current_function_decl));
 501                   $$ = error_mark_node;
 502                   if (TREE_VALUE (tree_last (types)) == void_type_node)
 503                     error ("`&...' used in function with fixed number of arguments");
 504                   else
 505                     {
 506                       if (pedantic)
 507                         pedwarn ("ISO C forbids `&...'");
 508                       $$ = tree_last (DECL_ARGUMENTS (current_function_decl));
 509                       $$ = build_unary_op (ADDR_EXPR, $$, 0);
 510                     } }
 511 */
 512         | sizeof unary_expr  %prec UNARY
 513                 { skip_evaluation--;
 514                   if (TREE_CODE ($2) == COMPONENT_REF
 515                       && DECL_C_BIT_FIELD (TREE_OPERAND ($2, 1)))
 516                     error ("`sizeof' applied to a bit-field");
 517                   $$ = c_sizeof (TREE_TYPE ($2)); }
 518         | sizeof '(' typename ')'  %prec HYPERUNARY
 519                 { skip_evaluation--;
 520                   $$ = c_sizeof (groktypename ($3)); }
 521         | alignof unary_expr  %prec UNARY
 522                 { skip_evaluation--;
 523                   $$ = c_alignof_expr ($2); }
 524         | alignof '(' typename ')'  %prec HYPERUNARY
 525                 { skip_evaluation--;
 526                   $$ = c_alignof (groktypename ($3)); }
 527         | REALPART cast_expr %prec UNARY
 528                 { $$ = build_unary_op (REALPART_EXPR, $2, 0); }
 529         | IMAGPART cast_expr %prec UNARY
 530                 { $$ = build_unary_op (IMAGPART_EXPR, $2, 0); }
 531         ;
 532
 533 sizeof:
 534         SIZEOF { skip_evaluation++; }
 535         ;
 536
 537 alignof:
 538         ALIGNOF { skip_evaluation++; }
 539         ;
 540
 541 cast_expr:
 542         unary_expr
 543         | '(' typename ')' cast_expr  %prec UNARY
 544                 { $$ = c_cast_expr ($2, $4); }
 545         ;
 546
 547 expr_no_commas:
 548           cast_expr
 549         | expr_no_commas '+' expr_no_commas
 550                 { $$ = parser_build_binary_op ($2, $1, $3); }
 551         | expr_no_commas '-' expr_no_commas
 552                 { $$ = parser_build_binary_op ($2, $1, $3); }
 553         | expr_no_commas '*' expr_no_commas
 554                 { $$ = parser_build_binary_op ($2, $1, $3); }
 555         | expr_no_commas '/' expr_no_commas
 556                 { $$ = parser_build_binary_op ($2, $1, $3); }
 557         | expr_no_commas '%' expr_no_commas
 558                 { $$ = parser_build_binary_op ($2, $1, $3); }
 559         | expr_no_commas LSHIFT expr_no_commas
 560                 { $$ = parser_build_binary_op ($2, $1, $3); }
 561         | expr_no_commas RSHIFT expr_no_commas
 562                 { $$ = parser_build_binary_op ($2, $1, $3); }
 563         | expr_no_commas ARITHCOMPARE expr_no_commas
 564                 { $$ = parser_build_binary_op ($2, $1, $3); }
 565         | expr_no_commas EQCOMPARE expr_no_commas
 566                 { $$ = parser_build_binary_op ($2, $1, $3); }
 567         | expr_no_commas '&' expr_no_commas
 568                 { $$ = parser_build_binary_op ($2, $1, $3); }
 569         | expr_no_commas '|' expr_no_commas
 570                 { $$ = parser_build_binary_op ($2, $1, $3); }
 571         | expr_no_commas '^' expr_no_commas
 572                 { $$ = parser_build_binary_op ($2, $1, $3); }
 573         | expr_no_commas ANDAND
 574                 { $1 = truthvalue_conversion (default_conversion ($1));
 575                   skip_evaluation += $1 == boolean_false_node; }
 576           expr_no_commas
 577                 { skip_evaluation -= $1 == boolean_false_node;
 578                   $$ = parser_build_binary_op (TRUTH_ANDIF_EXPR, $1, $4); }
 579         | expr_no_commas OROR
 580                 { $1 = truthvalue_conversion (default_conversion ($1));
 581                   skip_evaluation += $1 == boolean_true_node; }
 582           expr_no_commas
 583                 { skip_evaluation -= $1 == boolean_true_node;
 584                   $$ = parser_build_binary_op (TRUTH_ORIF_EXPR, $1, $4); }
 585         | expr_no_commas '?'
 586                 { $1 = truthvalue_conversion (default_conversion ($1));
 587                   skip_evaluation += $1 == boolean_false_node; }
 588           expr ':'
 589                 { skip_evaluation += (($1 == boolean_true_node)
 590                                       - ($1 == boolean_false_node)); }
 591           expr_no_commas
 592                 { skip_evaluation -= $1 == boolean_true_node;
 593                   $$ = build_conditional_expr ($1, $4, $7); }
 594         | expr_no_commas '?'
 595                 { if (pedantic)
 596                     pedwarn ("ISO C forbids omitting the middle term of a ?: expression");
 597                   /* Make sure first operand is calculated only once.  */
 598                   $<ttype>2 = save_expr ($1);
 599                   $1 = truthvalue_conversion (default_conversion ($<ttype>2));
 600                   skip_evaluation += $1 == boolean_true_node; }
 601           ':' expr_no_commas
 602                 { skip_evaluation -= $1 == boolean_true_node;
 603                   $$ = build_conditional_expr ($1, $<ttype>2, $5); }
 604         | expr_no_commas '=' expr_no_commas
 605                 { char class;
 606                   $$ = build_modify_expr ($1, NOP_EXPR, $3);
 607                   class = TREE_CODE_CLASS (TREE_CODE ($$));
 608                   if (IS_EXPR_CODE_CLASS (class))
 609                     C_SET_EXP_ORIGINAL_CODE ($$, MODIFY_EXPR);
 610                 }
 611         | expr_no_commas ASSIGN expr_no_commas
 612                 { char class;
 613                   $$ = build_modify_expr ($1, $2, $3);
 614                   /* This inhibits warnings in truthvalue_conversion.  */
 615                   class = TREE_CODE_CLASS (TREE_CODE ($$));
 616                   if (IS_EXPR_CODE_CLASS (class))
 617                     C_SET_EXP_ORIGINAL_CODE ($$, ERROR_MARK);
 618                 }
 619         ;
 620
 621 primary:
 622         IDENTIFIER
 623                 {
 624                   if (yychar == YYEMPTY)
 625                     yychar = YYLEX;
 626                   $$ = build_external_ref ($1, yychar == '(');
 627                 }
 628         | CONSTANT
 629         | string
 630                 { $$ = combine_strings ($1); }
 631         | VAR_FUNC_NAME
 632                 { $$ = fname_decl (C_RID_CODE ($$), $$); }
 633         | '(' typename ')' '{'
 634                 { start_init (NULL_TREE, NULL, 0);
 635                   $2 = groktypename ($2);
 636                   really_start_incremental_init ($2); }
 637           initlist_maybe_comma '}'  %prec UNARY
 638                 { const char *name;
 639                   tree result = pop_init_level (0);
 640                   tree type = $2;
 641                   finish_init ();
 642
 643                   if (pedantic && ! flag_isoc99)
 644                     pedwarn ("ISO C89 forbids compound literals");
 645                   if (TYPE_NAME (type) != 0)
 646                     {
 647                       if (TREE_CODE (TYPE_NAME (type)) == IDENTIFIER_NODE)
 648                         name = IDENTIFIER_POINTER (TYPE_NAME (type));
 649                       else
 650                         name = IDENTIFIER_POINTER (DECL_NAME (TYPE_NAME (type)));
 651                     }
 652                   else
 653                     name = "";
 654                   $$ = result;
 655                   if (TREE_CODE (type) == ARRAY_TYPE && !COMPLETE_TYPE_P (type))
 656                     {
 657                       int failure = complete_array_type (type, $$, 1);
 658                       if (failure)
 659                         abort ();
 660                     }
 661                 }
 662         | '(' expr ')'
 663                 { char class = TREE_CODE_CLASS (TREE_CODE ($2));
 664                   if (IS_EXPR_CODE_CLASS (class))
 665                     C_SET_EXP_ORIGINAL_CODE ($2, ERROR_MARK);
 666                   $$ = $2; }
 667         | '(' error ')'
 668                 { $$ = error_mark_node; }
 669         | compstmt_primary_start compstmt_nostart ')'
 670                  { tree saved_last_tree;
 671
 672                    if (pedantic)
 673                      pedwarn ("ISO C forbids braced-groups within expressions");
 674                   pop_label_level ();
 675
 676                   saved_last_tree = COMPOUND_BODY ($1);
 677                   RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
 678                   last_tree = saved_last_tree;
 679                   TREE_CHAIN (last_tree) = NULL_TREE;
 680                   if (!last_expr_type)
 681                     last_expr_type = void_type_node;
 682                   $$ = build1 (STMT_EXPR, last_expr_type, $1);
 683                   TREE_SIDE_EFFECTS ($$) = 1;
 684                 }
 685         | compstmt_primary_start error ')'
 686                 {
 687                   pop_label_level ();
 688                   last_tree = COMPOUND_BODY ($1);
 689                   TREE_CHAIN (last_tree) = NULL_TREE;
 690                   $$ = error_mark_node;
 691                 }
 692         | primary '(' exprlist ')'   %prec '.'
 693                 { $$ = build_function_call ($1, $3); }
 694         | VA_ARG '(' expr_no_commas ',' typename ')'
 695                 { $$ = build_va_arg ($3, groktypename ($5)); }
 696         | primary '[' expr ']'   %prec '.'
 697                 { $$ = build_array_ref ($1, $3); }
 698         | primary '.' identifier
 699                 {
 700 ifobjc
 701                     if (!is_public ($1, $3))
 702                       $$ = error_mark_node;
 703                     else
 704 end ifobjc
 705                       $$ = build_component_ref ($1, $3);
 706                 }
 707         | primary POINTSAT identifier
 708                 {
 709                   tree expr = build_indirect_ref ($1, "->");
 710
 711 ifobjc
 712                       if (!is_public (expr, $3))
 713                         $$ = error_mark_node;
 714                       else
 715 end ifobjc
 716                         $$ = build_component_ref (expr, $3);
 717                 }
 718         | primary PLUSPLUS
 719                 { $$ = build_unary_op (POSTINCREMENT_EXPR, $1, 0); }
 720         | primary MINUSMINUS
 721                 { $$ = build_unary_op (POSTDECREMENT_EXPR, $1, 0); }
 722 ifobjc
 723         | objcmessageexpr
 724                 { $$ = build_message_expr ($1); }
 725         | objcselectorexpr
 726                 { $$ = build_selector_expr ($1); }
 727         | objcprotocolexpr
 728                 { $$ = build_protocol_expr ($1); }
 729         | objcencodeexpr
 730                 { $$ = build_encode_expr ($1); }
 731         | objc_string
 732                 { $$ = build_objc_string_object ($1); }
 733 end ifobjc
 734         ;
 735
 736 /* Produces a STRING_CST with perhaps more STRING_CSTs chained onto it.  */
 737 string:
 738           STRING
 739         | string STRING
 740                 {
 741 ifc
 742                   static int last_lineno = 0;
 743                   static const char *last_input_filename = 0;
 744 end ifc
 745                   $$ = chainon ($1, $2);
 746 ifc
 747                   if (warn_traditional && !in_system_header
 748                       && (lineno != last_lineno || !last_input_filename ||
 749                           strcmp (last_input_filename, input_filename)))
 750                     {
 751                       warning ("traditional C rejects string concatenation");
 752                       last_lineno = lineno;
 753                       last_input_filename = input_filename;
 754                     }
 755 end ifc
 756                 }
 757         ;
 758
 759 ifobjc
 760 /* Produces an STRING_CST with perhaps more STRING_CSTs chained
 761    onto it, which is to be read as an ObjC string object.  */
 762 objc_string:
 763           '@' STRING
 764                 { $$ = $2; }
 765         | objc_string '@' STRING
 766                 { $$ = chainon ($1, $3); }
 767         ;
 768 end ifobjc
 769
 770 old_style_parm_decls:
 771         /* empty */
 772         | datadecls
 773         | datadecls ELLIPSIS
 774                 /* ... is used here to indicate a varargs function.  */
 775                 { c_mark_varargs ();
 776                   if (pedantic)
 777                     pedwarn ("ISO C does not permit use of `varargs.h'"); }
 778         ;
 779
 780 /* The following are analogous to lineno_decl, decls and decl
 781    except that they do not allow nested functions.
 782    They are used for old-style parm decls.  */
 783 lineno_datadecl:
 784           save_filename save_lineno datadecl
 785                 { }
 786         ;
 787
 788 datadecls:
 789         lineno_datadecl
 790         | errstmt
 791         | datadecls lineno_datadecl
 792         | lineno_datadecl errstmt
 793         ;
 794
 795 /* We don't allow prefix attributes here because they cause reduce/reduce
 796    conflicts: we can't know whether we're parsing a function decl with
 797    attribute suffix, or function defn with attribute prefix on first old
 798    style parm.  */
 799 datadecl:
 800         declspecs_ts_nosa setspecs initdecls ';'
 801                 { POP_DECLSPEC_STACK; }
 802         | declspecs_nots_nosa setspecs notype_initdecls ';'
 803                 { POP_DECLSPEC_STACK; }
 804         | declspecs_ts_nosa ';'
 805                 { shadow_tag_warned ($1, 1);
 806                   pedwarn ("empty declaration"); }
 807         | declspecs_nots_nosa ';'
 808                 { pedwarn ("empty declaration"); }
 809         ;
 810
 811 /* This combination which saves a lineno before a decl
 812    is the normal thing to use, rather than decl itself.
 813    This is to avoid shift/reduce conflicts in contexts
 814    where statement labels are allowed.  */
 815 lineno_decl:
 816           save_filename save_lineno decl
 817                 { }
 818         ;
 819
 820 /* records the type and storage class specs to use for processing
 821    the declarators that follow.
 822    Maintains a stack of outer-level values of current_declspecs,
 823    for the sake of parm declarations nested in function declarators.  */
 824 setspecs: /* empty */
 825                 { pending_xref_error ();
 826                   PUSH_DECLSPEC_STACK;
 827                   split_specs_attrs ($<ttype>0,
 828                                      &current_declspecs, &prefix_attributes);
 829                   all_prefix_attributes = prefix_attributes; }
 830         ;
 831
 832 /* Possibly attributes after a comma, which should reset all_prefix_attributes
 833    to prefix_attributes with these ones chained on the front.  */
 834 maybe_resetattrs:
 835           maybe_attribute
 836                 { all_prefix_attributes = chainon ($1, prefix_attributes); }
 837         ;
 838
 839 decl:
 840         declspecs_ts setspecs initdecls ';'
 841                 { POP_DECLSPEC_STACK; }
 842         | declspecs_nots setspecs notype_initdecls ';'
 843                 { POP_DECLSPEC_STACK; }
 844         | declspecs_ts setspecs nested_function
 845                 { POP_DECLSPEC_STACK; }
 846         | declspecs_nots setspecs notype_nested_function
 847                 { POP_DECLSPEC_STACK; }
 848         | declspecs ';'
 849                 { shadow_tag ($1); }
 850         | extension decl
 851                 { RESTORE_WARN_FLAGS ($1); }
 852         ;
 853
 854 /* A list of declaration specifiers.  These are:
 855
 856    - Storage class specifiers (SCSPEC), which for GCC currently include
 857    function specifiers ("inline").
 858
 859    - Type specifiers (typespec_*).
 860
 861    - Type qualifiers (TYPE_QUAL).
 862
 863    - Attribute specifier lists (attributes).
 864
 865    These are stored as a TREE_LIST; the head of the list is the last
 866    item in the specifier list.  Each entry in the list has either a
 867    TREE_PURPOSE that is an attribute specifier list, or a TREE_VALUE that
 868    is a single other specifier or qualifier; and a TREE_CHAIN that is the
 869    rest of the list.  TREE_STATIC is set on the list if something other
 870    than a storage class specifier or attribute has been seen; this is used
 871    to warn for the obsolescent usage of storage class specifiers other than
 872    at the start of the list.  (Doing this properly would require function
 873    specifiers to be handled separately from storage class specifiers.)
 874
 875    The various cases below are classified according to:
 876
 877    (a) Whether a storage class specifier is included or not; some
 878    places in the grammar disallow storage class specifiers (_sc or _nosc).
 879
 880    (b) Whether a type specifier has been seen; after a type specifier,
 881    a typedef name is an identifier to redeclare (_ts or _nots).
 882
 883    (c) Whether the list starts with an attribute; in certain places,
 884    the grammar requires specifiers that don't start with an attribute
 885    (_sa or _nosa).
 886
 887    (d) Whether the list ends with an attribute (or a specifier such that
 888    any following attribute would have been parsed as part of that specifier);
 889    this avoids shift-reduce conflicts in the parsing of attributes
 890    (_ea or _noea).
 891
 892    TODO:
 893
 894    (i) Distinguish between function specifiers and storage class specifiers,
 895    at least for the purpose of warnings about obsolescent usage.
 896
 897    (ii) Halve the number of productions here by eliminating the _sc/_nosc
 898    distinction and instead checking where required that storage class
 899    specifiers aren't present.  */
 900
 901 /* Declspecs which contain at least one type specifier or typedef name.
 902    (Just `const' or `volatile' is not enough.)
 903    A typedef'd name following these is taken as a name to be declared.
 904    Declspecs have a non-NULL TREE_VALUE, attributes do not.  */
 905
 906 declspecs_nosc_nots_nosa_noea:
 907           TYPE_QUAL
 908                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 909                   TREE_STATIC ($$) = 1; }
 910         | declspecs_nosc_nots_nosa_noea TYPE_QUAL
 911                 { $$ = tree_cons (NULL_TREE, $2, $1);
 912                   TREE_STATIC ($$) = 1; }
 913         | declspecs_nosc_nots_nosa_ea TYPE_QUAL
 914                 { $$ = tree_cons (NULL_TREE, $2, $1);
 915                   TREE_STATIC ($$) = 1; }
 916         ;
 917
 918 declspecs_nosc_nots_nosa_ea:
 919           declspecs_nosc_nots_nosa_noea attributes
 920                 { $$ = tree_cons ($2, NULL_TREE, $1);
 921                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 922         ;
 923
 924 declspecs_nosc_nots_sa_noea:
 925           declspecs_nosc_nots_sa_noea TYPE_QUAL
 926                 { $$ = tree_cons (NULL_TREE, $2, $1);
 927                   TREE_STATIC ($$) = 1; }
 928         | declspecs_nosc_nots_sa_ea TYPE_QUAL
 929                 { $$ = tree_cons (NULL_TREE, $2, $1);
 930                   TREE_STATIC ($$) = 1; }
 931         ;
 932
 933 declspecs_nosc_nots_sa_ea:
 934           attributes
 935                 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE);
 936                   TREE_STATIC ($$) = 0; }
 937         | declspecs_nosc_nots_sa_noea attributes
 938                 { $$ = tree_cons ($2, NULL_TREE, $1);
 939                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 940         ;
 941
 942 declspecs_nosc_ts_nosa_noea:
 943           typespec_nonattr
 944                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 945                   TREE_STATIC ($$) = 1; }
 946         | declspecs_nosc_ts_nosa_noea TYPE_QUAL
 947                 { $$ = tree_cons (NULL_TREE, $2, $1);
 948                   TREE_STATIC ($$) = 1; }
 949         | declspecs_nosc_ts_nosa_ea TYPE_QUAL
 950                 { $$ = tree_cons (NULL_TREE, $2, $1);
 951                   TREE_STATIC ($$) = 1; }
 952         | declspecs_nosc_ts_nosa_noea typespec_reserved_nonattr
 953                 { $$ = tree_cons (NULL_TREE, $2, $1);
 954                   TREE_STATIC ($$) = 1; }
 955         | declspecs_nosc_ts_nosa_ea typespec_reserved_nonattr
 956                 { $$ = tree_cons (NULL_TREE, $2, $1);
 957                   TREE_STATIC ($$) = 1; }
 958         | declspecs_nosc_nots_nosa_noea typespec_nonattr
 959                 { $$ = tree_cons (NULL_TREE, $2, $1);
 960                   TREE_STATIC ($$) = 1; }
 961         | declspecs_nosc_nots_nosa_ea typespec_nonattr
 962                 { $$ = tree_cons (NULL_TREE, $2, $1);
 963                   TREE_STATIC ($$) = 1; }
 964         ;
 965
 966 declspecs_nosc_ts_nosa_ea:
 967           typespec_attr
 968                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 969                   TREE_STATIC ($$) = 1; }
 970         | declspecs_nosc_ts_nosa_noea attributes
 971                 { $$ = tree_cons ($2, NULL_TREE, $1);
 972                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 973         | declspecs_nosc_ts_nosa_noea typespec_reserved_attr
 974                 { $$ = tree_cons (NULL_TREE, $2, $1);
 975                   TREE_STATIC ($$) = 1; }
 976         | declspecs_nosc_ts_nosa_ea typespec_reserved_attr
 977                 { $$ = tree_cons (NULL_TREE, $2, $1);
 978                   TREE_STATIC ($$) = 1; }
 979         | declspecs_nosc_nots_nosa_noea typespec_attr
 980                 { $$ = tree_cons (NULL_TREE, $2, $1);
 981                   TREE_STATIC ($$) = 1; }
 982         | declspecs_nosc_nots_nosa_ea typespec_attr
 983                 { $$ = tree_cons (NULL_TREE, $2, $1);
 984                   TREE_STATIC ($$) = 1; }
 985         ;
 986
 987 declspecs_nosc_ts_sa_noea:
 988           declspecs_nosc_ts_sa_noea TYPE_QUAL
 989                 { $$ = tree_cons (NULL_TREE, $2, $1);
 990                   TREE_STATIC ($$) = 1; }
 991         | declspecs_nosc_ts_sa_ea TYPE_QUAL
 992                 { $$ = tree_cons (NULL_TREE, $2, $1);
 993                   TREE_STATIC ($$) = 1; }
 994         | declspecs_nosc_ts_sa_noea typespec_reserved_nonattr
 995                 { $$ = tree_cons (NULL_TREE, $2, $1);
 996                   TREE_STATIC ($$) = 1; }
 997         | declspecs_nosc_ts_sa_ea typespec_reserved_nonattr
 998                 { $$ = tree_cons (NULL_TREE, $2, $1);
 999                   TREE_STATIC ($$) = 1; }
1000         | declspecs_nosc_nots_sa_noea typespec_nonattr
1001                 { $$ = tree_cons (NULL_TREE, $2, $1);
1002                   TREE_STATIC ($$) = 1; }
1003         | declspecs_nosc_nots_sa_ea typespec_nonattr
1004                 { $$ = tree_cons (NULL_TREE, $2, $1);
1005                   TREE_STATIC ($$) = 1; }
1006         ;
1007
1008 declspecs_nosc_ts_sa_ea:
1009           declspecs_nosc_ts_sa_noea attributes
1010                 { $$ = tree_cons ($2, NULL_TREE, $1);
1011                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1012         | declspecs_nosc_ts_sa_noea typespec_reserved_attr
1013                 { $$ = tree_cons (NULL_TREE, $2, $1);
1014                   TREE_STATIC ($$) = 1; }
1015         | declspecs_nosc_ts_sa_ea typespec_reserved_attr
1016                 { $$ = tree_cons (NULL_TREE, $2, $1);
1017                   TREE_STATIC ($$) = 1; }
1018         | declspecs_nosc_nots_sa_noea typespec_attr
1019                 { $$ = tree_cons (NULL_TREE, $2, $1);
1020                   TREE_STATIC ($$) = 1; }
1021         | declspecs_nosc_nots_sa_ea typespec_attr
1022                 { $$ = tree_cons (NULL_TREE, $2, $1);
1023                   TREE_STATIC ($$) = 1; }
1024         ;
1025
1026 declspecs_sc_nots_nosa_noea:
1027           SCSPEC
1028                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
1029                   TREE_STATIC ($$) = 0; }
1030         | declspecs_sc_nots_nosa_noea TYPE_QUAL
1031                 { $$ = tree_cons (NULL_TREE, $2, $1);
1032                   TREE_STATIC ($$) = 1; }
1033         | declspecs_sc_nots_nosa_ea TYPE_QUAL
1034                 { $$ = tree_cons (NULL_TREE, $2, $1);
1035                   TREE_STATIC ($$) = 1; }
1036         | declspecs_nosc_nots_nosa_noea SCSPEC
1037                 { if (extra_warnings && TREE_STATIC ($1))
1038                     warning ("`%s' is not at beginning of declaration",
1039                              IDENTIFIER_POINTER ($2));
1040                   $$ = tree_cons (NULL_TREE, $2, $1);
1041                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1042         | declspecs_nosc_nots_nosa_ea SCSPEC
1043                 { if (extra_warnings && TREE_STATIC ($1))
1044                     warning ("`%s' is not at beginning of declaration",
1045                              IDENTIFIER_POINTER ($2));
1046                   $$ = tree_cons (NULL_TREE, $2, $1);
1047                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1048         | declspecs_sc_nots_nosa_noea SCSPEC
1049                 { if (extra_warnings && TREE_STATIC ($1))
1050                     warning ("`%s' is not at beginning of declaration",
1051                              IDENTIFIER_POINTER ($2));
1052                   $$ = tree_cons (NULL_TREE, $2, $1);
1053                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1054         | declspecs_sc_nots_nosa_ea SCSPEC
1055                 { if (extra_warnings && TREE_STATIC ($1))
1056                     warning ("`%s' is not at beginning of declaration",
1057                              IDENTIFIER_POINTER ($2));
1058                   $$ = tree_cons (NULL_TREE, $2, $1);
1059                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1060         ;
1061
1062 declspecs_sc_nots_nosa_ea:
1063           declspecs_sc_nots_nosa_noea attributes
1064                 { $$ = tree_cons ($2, NULL_TREE, $1);
1065                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1066         ;
1067
1068 declspecs_sc_nots_sa_noea:
1069           declspecs_sc_nots_sa_noea TYPE_QUAL
1070                 { $$ = tree_cons (NULL_TREE, $2, $1);
1071                   TREE_STATIC ($$) = 1; }
1072         | declspecs_sc_nots_sa_ea TYPE_QUAL
1073                 { $$ = tree_cons (NULL_TREE, $2, $1);
1074                   TREE_STATIC ($$) = 1; }
1075         | declspecs_nosc_nots_sa_noea SCSPEC
1076                 { if (extra_warnings && TREE_STATIC ($1))
1077                     warning ("`%s' is not at beginning of declaration",
1078                              IDENTIFIER_POINTER ($2));
1079                   $$ = tree_cons (NULL_TREE, $2, $1);
1080                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1081         | declspecs_nosc_nots_sa_ea SCSPEC
1082                 { if (extra_warnings && TREE_STATIC ($1))
1083                     warning ("`%s' is not at beginning of declaration",
1084                              IDENTIFIER_POINTER ($2));
1085                   $$ = tree_cons (NULL_TREE, $2, $1);
1086                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1087         | declspecs_sc_nots_sa_noea SCSPEC
1088                 { if (extra_warnings && TREE_STATIC ($1))
1089                     warning ("`%s' is not at beginning of declaration",
1090                              IDENTIFIER_POINTER ($2));
1091                   $$ = tree_cons (NULL_TREE, $2, $1);
1092                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1093         | declspecs_sc_nots_sa_ea SCSPEC
1094                 { if (extra_warnings && TREE_STATIC ($1))
1095                     warning ("`%s' is not at beginning of declaration",
1096                              IDENTIFIER_POINTER ($2));
1097                   $$ = tree_cons (NULL_TREE, $2, $1);
1098                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1099         ;
1100
1101 declspecs_sc_nots_sa_ea:
1102           declspecs_sc_nots_sa_noea attributes
1103                 { $$ = tree_cons ($2, NULL_TREE, $1);
1104                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1105         ;
1106
1107 declspecs_sc_ts_nosa_noea:
1108           declspecs_sc_ts_nosa_noea TYPE_QUAL
1109                 { $$ = tree_cons (NULL_TREE, $2, $1);
1110                   TREE_STATIC ($$) = 1; }
1111         | declspecs_sc_ts_nosa_ea TYPE_QUAL
1112                 { $$ = tree_cons (NULL_TREE, $2, $1);
1113                   TREE_STATIC ($$) = 1; }
1114         | declspecs_sc_ts_nosa_noea typespec_reserved_nonattr
1115                 { $$ = tree_cons (NULL_TREE, $2, $1);
1116                   TREE_STATIC ($$) = 1; }
1117         | declspecs_sc_ts_nosa_ea typespec_reserved_nonattr
1118                 { $$ = tree_cons (NULL_TREE, $2, $1);
1119                   TREE_STATIC ($$) = 1; }
1120         | declspecs_sc_nots_nosa_noea typespec_nonattr
1121                 { $$ = tree_cons (NULL_TREE, $2, $1);
1122                   TREE_STATIC ($$) = 1; }
1123         | declspecs_sc_nots_nosa_ea typespec_nonattr
1124                 { $$ = tree_cons (NULL_TREE, $2, $1);
1125                   TREE_STATIC ($$) = 1; }
1126         | declspecs_nosc_ts_nosa_noea SCSPEC
1127                 { if (extra_warnings && TREE_STATIC ($1))
1128                     warning ("`%s' is not at beginning of declaration",
1129                              IDENTIFIER_POINTER ($2));
1130                   $$ = tree_cons (NULL_TREE, $2, $1);
1131                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1132         | declspecs_nosc_ts_nosa_ea SCSPEC
1133                 { if (extra_warnings && TREE_STATIC ($1))
1134                     warning ("`%s' is not at beginning of declaration",
1135                              IDENTIFIER_POINTER ($2));
1136                   $$ = tree_cons (NULL_TREE, $2, $1);
1137                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1138         | declspecs_sc_ts_nosa_noea SCSPEC
1139                 { if (extra_warnings && TREE_STATIC ($1))
1140                     warning ("`%s' is not at beginning of declaration",
1141                              IDENTIFIER_POINTER ($2));
1142                   $$ = tree_cons (NULL_TREE, $2, $1);
1143                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1144         | declspecs_sc_ts_nosa_ea SCSPEC
1145                 { if (extra_warnings && TREE_STATIC ($1))
1146                     warning ("`%s' is not at beginning of declaration",
1147                              IDENTIFIER_POINTER ($2));
1148                   $$ = tree_cons (NULL_TREE, $2, $1);
1149                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1150         ;
1151
1152 declspecs_sc_ts_nosa_ea:
1153           declspecs_sc_ts_nosa_noea attributes
1154                 { $$ = tree_cons ($2, NULL_TREE, $1);
1155                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1156         | declspecs_sc_ts_nosa_noea typespec_reserved_attr
1157                 { $$ = tree_cons (NULL_TREE, $2, $1);
1158                   TREE_STATIC ($$) = 1; }
1159         | declspecs_sc_ts_nosa_ea typespec_reserved_attr
1160                 { $$ = tree_cons (NULL_TREE, $2, $1);
1161                   TREE_STATIC ($$) = 1; }
1162         | declspecs_sc_nots_nosa_noea typespec_attr
1163                 { $$ = tree_cons (NULL_TREE, $2, $1);
1164                   TREE_STATIC ($$) = 1; }
1165         | declspecs_sc_nots_nosa_ea typespec_attr
1166                 { $$ = tree_cons (NULL_TREE, $2, $1);
1167                   TREE_STATIC ($$) = 1; }
1168         ;
1169
1170 declspecs_sc_ts_sa_noea:
1171           declspecs_sc_ts_sa_noea TYPE_QUAL
1172                 { $$ = tree_cons (NULL_TREE, $2, $1);
1173                   TREE_STATIC ($$) = 1; }
1174         | declspecs_sc_ts_sa_ea TYPE_QUAL
1175                 { $$ = tree_cons (NULL_TREE, $2, $1);
1176                   TREE_STATIC ($$) = 1; }
1177         | declspecs_sc_ts_sa_noea typespec_reserved_nonattr
1178                 { $$ = tree_cons (NULL_TREE, $2, $1);
1179                   TREE_STATIC ($$) = 1; }
1180         | declspecs_sc_ts_sa_ea typespec_reserved_nonattr
1181                 { $$ = tree_cons (NULL_TREE, $2, $1);
1182                   TREE_STATIC ($$) = 1; }
1183         | declspecs_sc_nots_sa_noea typespec_nonattr
1184                 { $$ = tree_cons (NULL_TREE, $2, $1);
1185                   TREE_STATIC ($$) = 1; }
1186         | declspecs_sc_nots_sa_ea typespec_nonattr
1187                 { $$ = tree_cons (NULL_TREE, $2, $1);
1188                   TREE_STATIC ($$) = 1; }
1189         | declspecs_nosc_ts_sa_noea SCSPEC
1190                 { if (extra_warnings && TREE_STATIC ($1))
1191                     warning ("`%s' is not at beginning of declaration",
1192                              IDENTIFIER_POINTER ($2));
1193                   $$ = tree_cons (NULL_TREE, $2, $1);
1194                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1195         | declspecs_nosc_ts_sa_ea SCSPEC
1196                 { if (extra_warnings && TREE_STATIC ($1))
1197                     warning ("`%s' is not at beginning of declaration",
1198                              IDENTIFIER_POINTER ($2));
1199                   $$ = tree_cons (NULL_TREE, $2, $1);
1200                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1201         | declspecs_sc_ts_sa_noea SCSPEC
1202                 { if (extra_warnings && TREE_STATIC ($1))
1203                     warning ("`%s' is not at beginning of declaration",
1204                              IDENTIFIER_POINTER ($2));
1205                   $$ = tree_cons (NULL_TREE, $2, $1);
1206                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1207         | declspecs_sc_ts_sa_ea SCSPEC
1208                 { if (extra_warnings && TREE_STATIC ($1))
1209                     warning ("`%s' is not at beginning of declaration",
1210                              IDENTIFIER_POINTER ($2));
1211                   $$ = tree_cons (NULL_TREE, $2, $1);
1212                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1213         ;
1214
1215 declspecs_sc_ts_sa_ea:
1216           declspecs_sc_ts_sa_noea attributes
1217                 { $$ = tree_cons ($2, NULL_TREE, $1);
1218                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1219         | declspecs_sc_ts_sa_noea typespec_reserved_attr
1220                 { $$ = tree_cons (NULL_TREE, $2, $1);
1221                   TREE_STATIC ($$) = 1; }
1222         | declspecs_sc_ts_sa_ea typespec_reserved_attr
1223                 { $$ = tree_cons (NULL_TREE, $2, $1);
1224                   TREE_STATIC ($$) = 1; }
1225         | declspecs_sc_nots_sa_noea typespec_attr
1226                 { $$ = tree_cons (NULL_TREE, $2, $1);
1227                   TREE_STATIC ($$) = 1; }
1228         | declspecs_sc_nots_sa_ea typespec_attr
1229                 { $$ = tree_cons (NULL_TREE, $2, $1);
1230                   TREE_STATIC ($$) = 1; }
1231         ;
1232
1233 /* Particular useful classes of declspecs.  */
1234 declspecs_ts:
1235           declspecs_nosc_ts_nosa_noea
1236         | declspecs_nosc_ts_nosa_ea
1237         | declspecs_nosc_ts_sa_noea
1238         | declspecs_nosc_ts_sa_ea
1239         | declspecs_sc_ts_nosa_noea
1240         | declspecs_sc_ts_nosa_ea
1241         | declspecs_sc_ts_sa_noea
1242         | declspecs_sc_ts_sa_ea
1243         ;
1244
1245 declspecs_nots:
1246           declspecs_nosc_nots_nosa_noea
1247         | declspecs_nosc_nots_nosa_ea
1248         | declspecs_nosc_nots_sa_noea
1249         | declspecs_nosc_nots_sa_ea
1250         | declspecs_sc_nots_nosa_noea
1251         | declspecs_sc_nots_nosa_ea
1252         | declspecs_sc_nots_sa_noea
1253         | declspecs_sc_nots_sa_ea
1254         ;
1255
1256 declspecs_ts_nosa:
1257           declspecs_nosc_ts_nosa_noea
1258         | declspecs_nosc_ts_nosa_ea
1259         | declspecs_sc_ts_nosa_noea
1260         | declspecs_sc_ts_nosa_ea
1261         ;
1262
1263 declspecs_nots_nosa:
1264           declspecs_nosc_nots_nosa_noea
1265         | declspecs_nosc_nots_nosa_ea
1266         | declspecs_sc_nots_nosa_noea
1267         | declspecs_sc_nots_nosa_ea
1268         ;
1269
1270 declspecs_nosc_ts:
1271           declspecs_nosc_ts_nosa_noea
1272         | declspecs_nosc_ts_nosa_ea
1273         | declspecs_nosc_ts_sa_noea
1274         | declspecs_nosc_ts_sa_ea
1275         ;
1276
1277 declspecs_nosc_nots:
1278           declspecs_nosc_nots_nosa_noea
1279         | declspecs_nosc_nots_nosa_ea
1280         | declspecs_nosc_nots_sa_noea
1281         | declspecs_nosc_nots_sa_ea
1282         ;
1283
1284 declspecs_nosc:
1285           declspecs_nosc_ts_nosa_noea
1286         | declspecs_nosc_ts_nosa_ea
1287         | declspecs_nosc_ts_sa_noea
1288         | declspecs_nosc_ts_sa_ea
1289         | declspecs_nosc_nots_nosa_noea
1290         | declspecs_nosc_nots_nosa_ea
1291         | declspecs_nosc_nots_sa_noea
1292         | declspecs_nosc_nots_sa_ea
1293         ;
1294
1295 declspecs:
1296           declspecs_nosc_nots_nosa_noea
1297         | declspecs_nosc_nots_nosa_ea
1298         | declspecs_nosc_nots_sa_noea
1299         | declspecs_nosc_nots_sa_ea
1300         | declspecs_nosc_ts_nosa_noea
1301         | declspecs_nosc_ts_nosa_ea
1302         | declspecs_nosc_ts_sa_noea
1303         | declspecs_nosc_ts_sa_ea
1304         | declspecs_sc_nots_nosa_noea
1305         | declspecs_sc_nots_nosa_ea
1306         | declspecs_sc_nots_sa_noea
1307         | declspecs_sc_nots_sa_ea
1308         | declspecs_sc_ts_nosa_noea
1309         | declspecs_sc_ts_nosa_ea
1310         | declspecs_sc_ts_sa_noea
1311         | declspecs_sc_ts_sa_ea
1312         ;
1313
1314 /* A (possibly empty) sequence of type qualifiers and attributes.  */
1315 maybe_type_quals_attrs:
1316           /* empty */
1317                 { $$ = NULL_TREE; }
1318         | declspecs_nosc_nots
1319                 { $$ = $1; }
1320         ;
1321
1322 /* A type specifier (but not a type qualifier).
1323    Once we have seen one of these in a declaration,
1324    if a typedef name appears then it is being redeclared.
1325
1326    The _reserved versions start with a reserved word and may appear anywhere
1327    in the declaration specifiers; the _nonreserved versions may only
1328    appear before any other type specifiers, and after that are (if names)
1329    being redeclared.
1330
1331    FIXME: should the _nonreserved version be restricted to names being
1332    redeclared only?  The other entries there relate only the GNU extensions
1333    and Objective C, and are historically parsed thus, and don't make sense
1334    after other type specifiers, but it might be cleaner to count them as
1335    _reserved.
1336
1337    _attr means: specifiers that either end with attributes,
1338    or are such that any following attributes would
1339    be parsed as part of the specifier.
1340
1341    _nonattr: specifiers.  */
1342
1343 typespec_nonattr:
1344           typespec_reserved_nonattr
1345         | typespec_nonreserved_nonattr
1346         ;
1347
1348 typespec_attr:
1349           typespec_reserved_attr
1350         ;
1351
1352 typespec_reserved_nonattr:
1353           TYPESPEC
1354                 { OBJC_NEED_RAW_IDENTIFIER (1); }
1355         | structsp_nonattr
1356         ;
1357
1358 typespec_reserved_attr:
1359           structsp_attr
1360         ;
1361
1362 typespec_nonreserved_nonattr:
1363           TYPENAME
1364                 { /* For a typedef name, record the meaning, not the name.
1365                      In case of `foo foo, bar;'.  */
1366                   $$ = lookup_name ($1); }
1367 ifobjc
1368         | CLASSNAME protocolrefs
1369                 { $$ = get_static_reference ($1, $2); }
1370         | OBJECTNAME protocolrefs
1371                 { $$ = get_object_reference ($2); }
1372
1373 /* Make "<SomeProtocol>" equivalent to "id <SomeProtocol>"
1374    - nisse@lysator.liu.se */
1375         | non_empty_protocolrefs
1376                 { $$ = get_object_reference ($1); }
1377 end ifobjc
1378         | TYPEOF '(' expr ')'
1379                 { $$ = TREE_TYPE ($3); }
1380         | TYPEOF '(' typename ')'
1381                 { $$ = groktypename ($3); }
1382         ;
1383
1384 /* typespec_nonreserved_attr does not exist.  */
1385
1386 initdecls:
1387         initdcl
1388         | initdecls ',' maybe_resetattrs initdcl
1389         ;
1390
1391 notype_initdecls:
1392         notype_initdcl
1393         | notype_initdecls ',' maybe_resetattrs notype_initdcl
1394         ;
1395
1396 maybeasm:
1397           /* empty */
1398                 { $$ = NULL_TREE; }
1399         | ASM_KEYWORD '(' string ')'
1400                 { if (TREE_CHAIN ($3)) $3 = combine_strings ($3);
1401                   $$ = $3;
1402                 }
1403         ;
1404
1405 initdcl:
1406           declarator maybeasm maybe_attribute '='
1407                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1408                                           chainon ($3, all_prefix_attributes));
1409                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1410           init
1411 /* Note how the declaration of the variable is in effect while its init is parsed! */
1412                 { finish_init ();
1413                   finish_decl ($<ttype>5, $6, $2); }
1414         | declarator maybeasm maybe_attribute
1415                 { tree d = start_decl ($1, current_declspecs, 0,
1416                                        chainon ($3, all_prefix_attributes));
1417                   finish_decl (d, NULL_TREE, $2);
1418                 }
1419         ;
1420
1421 notype_initdcl:
1422           notype_declarator maybeasm maybe_attribute '='
1423                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1424                                           chainon ($3, all_prefix_attributes));
1425                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1426           init
1427 /* Note how the declaration of the variable is in effect while its init is parsed! */
1428                 { finish_init ();
1429                   finish_decl ($<ttype>5, $6, $2); }
1430         | notype_declarator maybeasm maybe_attribute
1431                 { tree d = start_decl ($1, current_declspecs, 0,
1432                                        chainon ($3, all_prefix_attributes));
1433                   finish_decl (d, NULL_TREE, $2); }
1434         ;
1435 /* the * rules are dummies to accept the Apollo extended syntax
1436    so that the header files compile. */
1437 maybe_attribute:
1438       /* empty */
1439                 { $$ = NULL_TREE; }
1440         | attributes
1441                 { $$ = $1; }
1442         ;
1443
1444 attributes:
1445       attribute
1446                 { $$ = $1; }
1447         | attributes attribute
1448                 { $$ = chainon ($1, $2); }
1449         ;
1450
1451 attribute:
1452       ATTRIBUTE '(' '(' attribute_list ')' ')'
1453                 { $$ = $4; }
1454         ;
1455
1456 attribute_list:
1457       attrib
1458                 { $$ = $1; }
1459         | attribute_list ',' attrib
1460                 { $$ = chainon ($1, $3); }
1461         ;
1462
1463 attrib:
1464     /* empty */
1465                 { $$ = NULL_TREE; }
1466         | any_word
1467                 { $$ = build_tree_list ($1, NULL_TREE); }
1468         | any_word '(' IDENTIFIER ')'
1469                 { $$ = build_tree_list ($1, build_tree_list (NULL_TREE, $3)); }
1470         | any_word '(' IDENTIFIER ',' nonnull_exprlist ')'
1471                 { $$ = build_tree_list ($1, tree_cons (NULL_TREE, $3, $5)); }
1472         | any_word '(' exprlist ')'
1473                 { $$ = build_tree_list ($1, $3); }
1474         ;
1475
1476 /* This still leaves out most reserved keywords,
1477    shouldn't we include them?  */
1478
1479 any_word:
1480           identifier
1481         | SCSPEC
1482         | TYPESPEC
1483         | TYPE_QUAL
1484         ;
1485 \f
1486 /* Initializers.  `init' is the entry point.  */
1487
1488 init:
1489         expr_no_commas
1490         | '{'
1491                 { really_start_incremental_init (NULL_TREE); }
1492           initlist_maybe_comma '}'
1493                 { $$ = pop_init_level (0); }
1494         | error
1495                 { $$ = error_mark_node; }
1496         ;
1497
1498 /* `initlist_maybe_comma' is the guts of an initializer in braces.  */
1499 initlist_maybe_comma:
1500           /* empty */
1501                 { if (pedantic)
1502                     pedwarn ("ISO C forbids empty initializer braces"); }
1503         | initlist1 maybecomma
1504         ;
1505
1506 initlist1:
1507           initelt
1508         | initlist1 ',' initelt
1509         ;
1510
1511 /* `initelt' is a single element of an initializer.
1512    It may use braces.  */
1513 initelt:
1514           designator_list '=' initval
1515                 { if (pedantic && ! flag_isoc99)
1516                     pedwarn ("ISO C89 forbids specifying subobject to initialize"); }
1517         | designator initval
1518                 { if (pedantic)
1519                     pedwarn ("obsolete use of designated initializer without `='"); }
1520         | identifier ':'
1521                 { set_init_label ($1);
1522                   if (pedantic)
1523                     pedwarn ("obsolete use of designated initializer with `:'"); }
1524           initval
1525         | initval
1526         ;
1527
1528 initval:
1529           '{'
1530                 { push_init_level (0); }
1531           initlist_maybe_comma '}'
1532                 { process_init_element (pop_init_level (0)); }
1533         | expr_no_commas
1534                 { process_init_element ($1); }
1535         | error
1536         ;
1537
1538 designator_list:
1539           designator
1540         | designator_list designator
1541         ;
1542
1543 designator:
1544           '.' identifier
1545                 { set_init_label ($2); }
1546         /* These are for labeled elements.  The syntax for an array element
1547            initializer conflicts with the syntax for an Objective-C message,
1548            so don't include these productions in the Objective-C grammar.  */
1549 ifc
1550         | '[' expr_no_commas ELLIPSIS expr_no_commas ']'
1551                 { set_init_index ($2, $4);
1552                   if (pedantic)
1553                     pedwarn ("ISO C forbids specifying range of elements to initialize"); }
1554         | '[' expr_no_commas ']'
1555                 { set_init_index ($2, NULL_TREE); }
1556 end ifc
1557         ;
1558 \f
1559 nested_function:
1560           declarator
1561                 { if (pedantic)
1562                     pedwarn ("ISO C forbids nested functions");
1563
1564                   push_function_context ();
1565                   if (! start_function (current_declspecs, $1,
1566                                         all_prefix_attributes))
1567                     {
1568                       pop_function_context ();
1569                       YYERROR1;
1570                     }
1571                 }
1572            old_style_parm_decls
1573                 { store_parm_decls (); }
1574 /* This used to use compstmt_or_error.
1575    That caused a bug with input `f(g) int g {}',
1576    where the use of YYERROR1 above caused an error
1577    which then was handled by compstmt_or_error.
1578    There followed a repeated execution of that same rule,
1579    which called YYERROR1 again, and so on.  */
1580           save_filename save_lineno compstmt
1581                 { tree decl = current_function_decl;
1582                   DECL_SOURCE_FILE (decl) = $5;
1583                   DECL_SOURCE_LINE (decl) = $6;
1584                   finish_function (1);
1585                   pop_function_context ();
1586                   add_decl_stmt (decl); }
1587         ;
1588
1589 notype_nested_function:
1590           notype_declarator
1591                 { if (pedantic)
1592                     pedwarn ("ISO C forbids nested functions");
1593
1594                   push_function_context ();
1595                   if (! start_function (current_declspecs, $1,
1596                                         all_prefix_attributes))
1597                     {
1598                       pop_function_context ();
1599                       YYERROR1;
1600                     }
1601                 }
1602           old_style_parm_decls
1603                 { store_parm_decls (); }
1604 /* This used to use compstmt_or_error.
1605    That caused a bug with input `f(g) int g {}',
1606    where the use of YYERROR1 above caused an error
1607    which then was handled by compstmt_or_error.
1608    There followed a repeated execution of that same rule,
1609    which called YYERROR1 again, and so on.  */
1610           save_filename save_lineno compstmt
1611                 { tree decl = current_function_decl;
1612                   DECL_SOURCE_FILE (decl) = $5;
1613                   DECL_SOURCE_LINE (decl) = $6;
1614                   finish_function (1);
1615                   pop_function_context ();
1616                   add_decl_stmt (decl); }
1617         ;
1618
1619 /* Any kind of declarator (thus, all declarators allowed
1620    after an explicit typespec).  */
1621
1622 declarator:
1623           after_type_declarator
1624         | notype_declarator
1625         ;
1626
1627 /* A declarator that is allowed only after an explicit typespec.  */
1628
1629 after_type_declarator:
1630           '(' maybe_attribute after_type_declarator ')'
1631                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1632         | after_type_declarator '(' parmlist_or_identifiers  %prec '.'
1633                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1634 /*      | after_type_declarator '(' error ')'  %prec '.'
1635                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1636                   poplevel (0, 0, 0); }  */
1637         | after_type_declarator array_declarator  %prec '.'
1638                 { $$ = set_array_declarator_type ($2, $1, 0); }
1639         | '*' maybe_type_quals_attrs after_type_declarator  %prec UNARY
1640                 { $$ = make_pointer_declarator ($2, $3); }
1641         | TYPENAME
1642 ifobjc
1643         | OBJECTNAME
1644 end ifobjc
1645         ;
1646
1647 /* Kinds of declarator that can appear in a parameter list
1648    in addition to notype_declarator.  This is like after_type_declarator
1649    but does not allow a typedef name in parentheses as an identifier
1650    (because it would conflict with a function with that typedef as arg).  */
1651 parm_declarator:
1652           parm_declarator_starttypename
1653         | parm_declarator_nostarttypename
1654         ;
1655
1656 parm_declarator_starttypename:
1657           parm_declarator_starttypename '(' parmlist_or_identifiers  %prec '.'
1658                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1659 /*      | parm_declarator_starttypename '(' error ')'  %prec '.'
1660                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1661                   poplevel (0, 0, 0); }  */
1662         | parm_declarator_starttypename array_declarator  %prec '.'
1663                 { $$ = set_array_declarator_type ($2, $1, 0); }
1664         | TYPENAME
1665 ifobjc
1666         | OBJECTNAME
1667 end ifobjc
1668         ;
1669
1670 parm_declarator_nostarttypename:
1671           parm_declarator_nostarttypename '(' parmlist_or_identifiers  %prec '.'
1672                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1673 /*      | parm_declarator_nostarttypename '(' error ')'  %prec '.'
1674                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1675                   poplevel (0, 0, 0); }  */
1676         | parm_declarator_nostarttypename array_declarator  %prec '.'
1677                 { $$ = set_array_declarator_type ($2, $1, 0); }
1678         | '*' maybe_type_quals_attrs parm_declarator_starttypename  %prec UNARY
1679                 { $$ = make_pointer_declarator ($2, $3); }
1680         | '*' maybe_type_quals_attrs parm_declarator_nostarttypename  %prec UNARY
1681                 { $$ = make_pointer_declarator ($2, $3); }
1682         | '(' maybe_attribute parm_declarator_nostarttypename ')'
1683                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1684         ;
1685
1686 /* A declarator allowed whether or not there has been
1687    an explicit typespec.  These cannot redeclare a typedef-name.  */
1688
1689 notype_declarator:
1690           notype_declarator '(' parmlist_or_identifiers  %prec '.'
1691                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1692 /*      | notype_declarator '(' error ')'  %prec '.'
1693                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1694                   poplevel (0, 0, 0); }  */
1695         | '(' maybe_attribute notype_declarator ')'
1696                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1697         | '*' maybe_type_quals_attrs notype_declarator  %prec UNARY
1698                 { $$ = make_pointer_declarator ($2, $3); }
1699         | notype_declarator array_declarator  %prec '.'
1700                 { $$ = set_array_declarator_type ($2, $1, 0); }
1701         | IDENTIFIER
1702         ;
1703
1704 struct_head:
1705           STRUCT
1706                 { $$ = NULL_TREE; }
1707         | STRUCT attributes
1708                 { $$ = $2; }
1709         ;
1710
1711 union_head:
1712           UNION
1713                 { $$ = NULL_TREE; }
1714         | UNION attributes
1715                 { $$ = $2; }
1716         ;
1717
1718 enum_head:
1719           ENUM
1720                 { $$ = NULL_TREE; }
1721         | ENUM attributes
1722                 { $$ = $2; }
1723         ;
1724
1725 /* structsp_attr: struct/union/enum specifiers that either
1726    end with attributes, or are such that any following attributes would
1727    be parsed as part of the struct/union/enum specifier.
1728
1729    structsp_nonattr: other struct/union/enum specifiers.  */
1730
1731 structsp_attr:
1732           struct_head identifier '{'
1733                 { $$ = start_struct (RECORD_TYPE, $2);
1734                   /* Start scope of tag before parsing components.  */
1735                 }
1736           component_decl_list '}' maybe_attribute
1737                 { $$ = finish_struct ($<ttype>4, $5, chainon ($1, $7)); }
1738         | struct_head '{' component_decl_list '}' maybe_attribute
1739                 { $$ = finish_struct (start_struct (RECORD_TYPE, NULL_TREE),
1740                                       $3, chainon ($1, $5));
1741                 }
1742         | union_head identifier '{'
1743                 { $$ = start_struct (UNION_TYPE, $2); }
1744           component_decl_list '}' maybe_attribute
1745                 { $$ = finish_struct ($<ttype>4, $5, chainon ($1, $7)); }
1746         | union_head '{' component_decl_list '}' maybe_attribute
1747                 { $$ = finish_struct (start_struct (UNION_TYPE, NULL_TREE),
1748                                       $3, chainon ($1, $5));
1749                 }
1750         | enum_head identifier '{'
1751                 { $$ = start_enum ($2); }
1752           enumlist maybecomma_warn '}' maybe_attribute
1753                 { $$ = finish_enum ($<ttype>4, nreverse ($5),
1754                                     chainon ($1, $8)); }
1755         | enum_head '{'
1756                 { $$ = start_enum (NULL_TREE); }
1757           enumlist maybecomma_warn '}' maybe_attribute
1758                 { $$ = finish_enum ($<ttype>3, nreverse ($4),
1759                                     chainon ($1, $7)); }
1760         ;
1761
1762 structsp_nonattr:
1763           struct_head identifier
1764                 { $$ = xref_tag (RECORD_TYPE, $2); }
1765         | union_head identifier
1766                 { $$ = xref_tag (UNION_TYPE, $2); }
1767         | enum_head identifier
1768                 { $$ = xref_tag (ENUMERAL_TYPE, $2);
1769                   /* In ISO C, enumerated types can be referred to
1770                      only if already defined.  */
1771                   if (pedantic && !COMPLETE_TYPE_P ($$))
1772                     pedwarn ("ISO C forbids forward references to `enum' types"); }
1773         ;
1774
1775 maybecomma:
1776           /* empty */
1777         | ','
1778         ;
1779
1780 maybecomma_warn:
1781           /* empty */
1782         | ','
1783                 { if (pedantic && ! flag_isoc99)
1784                     pedwarn ("comma at end of enumerator list"); }
1785         ;
1786
1787 component_decl_list:
1788           component_decl_list2
1789                 { $$ = $1; }
1790         | component_decl_list2 component_decl
1791                 { $$ = chainon ($1, $2);
1792                   pedwarn ("no semicolon at end of struct or union"); }
1793         ;
1794
1795 component_decl_list2:   /* empty */
1796                 { $$ = NULL_TREE; }
1797         | component_decl_list2 component_decl ';'
1798                 { $$ = chainon ($1, $2); }
1799         | component_decl_list2 ';'
1800                 { if (pedantic)
1801                     pedwarn ("extra semicolon in struct or union specified"); }
1802 ifobjc
1803         /* foo(sizeof(struct{ @defs(ClassName)})); */
1804         | DEFS '(' CLASSNAME ')'
1805                 {
1806                   tree interface = lookup_interface ($3);
1807
1808                   if (interface)
1809                     $$ = get_class_ivars (interface);
1810                   else
1811                     {
1812                       error ("Cannot find interface declaration for `%s'",
1813                              IDENTIFIER_POINTER ($3));
1814                       $$ = NULL_TREE;
1815                     }
1816                 }
1817 end ifobjc
1818         ;
1819
1820 component_decl:
1821           declspecs_nosc_ts setspecs components
1822                 { $$ = $3;
1823                   POP_DECLSPEC_STACK; }
1824         | declspecs_nosc_ts setspecs save_filename save_lineno
1825                 {
1826                   /* Support for unnamed structs or unions as members of
1827                      structs or unions (which is [a] useful and [b] supports
1828                      MS P-SDK).  */
1829                   if (pedantic)
1830                     pedwarn ("ISO C doesn't support unnamed structs/unions");
1831
1832                   $$ = grokfield($3, $4, NULL, current_declspecs, NULL_TREE);
1833                   POP_DECLSPEC_STACK; }
1834         | declspecs_nosc_nots setspecs components_notype
1835                 { $$ = $3;
1836                   POP_DECLSPEC_STACK; }
1837         | declspecs_nosc_nots
1838                 { if (pedantic)
1839                     pedwarn ("ISO C forbids member declarations with no members");
1840                   shadow_tag($1);
1841                   $$ = NULL_TREE; }
1842         | error
1843                 { $$ = NULL_TREE; }
1844         | extension component_decl
1845                 { $$ = $2;
1846                   RESTORE_WARN_FLAGS ($1); }
1847         ;
1848
1849 components:
1850           component_declarator
1851         | components ',' maybe_resetattrs component_declarator
1852                 { $$ = chainon ($1, $4); }
1853         ;
1854
1855 components_notype:
1856           component_notype_declarator
1857         | components_notype ',' maybe_resetattrs component_notype_declarator
1858                 { $$ = chainon ($1, $4); }
1859         ;
1860
1861 component_declarator:
1862           save_filename save_lineno declarator maybe_attribute
1863                 { $$ = grokfield ($1, $2, $3, current_declspecs, NULL_TREE);
1864                   decl_attributes (&$$, chainon ($4, all_prefix_attributes), 0); }
1865         | save_filename save_lineno
1866           declarator ':' expr_no_commas maybe_attribute
1867                 { $$ = grokfield ($1, $2, $3, current_declspecs, $5);
1868                   decl_attributes (&$$, chainon ($6, all_prefix_attributes), 0); }
1869         | save_filename save_lineno ':' expr_no_commas maybe_attribute
1870                 { $$ = grokfield ($1, $2, NULL_TREE, current_declspecs, $4);
1871                   decl_attributes (&$$, chainon ($5, all_prefix_attributes), 0); }
1872         ;
1873
1874 component_notype_declarator:
1875           save_filename save_lineno notype_declarator maybe_attribute
1876                 { $$ = grokfield ($1, $2, $3, current_declspecs, NULL_TREE);
1877                   decl_attributes (&$$, chainon ($4, all_prefix_attributes), 0); }
1878         | save_filename save_lineno
1879           notype_declarator ':' expr_no_commas maybe_attribute
1880                 { $$ = grokfield ($1, $2, $3, current_declspecs, $5);
1881                   decl_attributes (&$$, chainon ($6, all_prefix_attributes), 0); }
1882         | save_filename save_lineno ':' expr_no_commas maybe_attribute
1883                 { $$ = grokfield ($1, $2, NULL_TREE, current_declspecs, $4);
1884                   decl_attributes (&$$, chainon ($5, all_prefix_attributes), 0); }
1885         ;
1886
1887 /* We chain the enumerators in reverse order.
1888    They are put in forward order where enumlist is used.
1889    (The order used to be significant, but no longer is so.
1890    However, we still maintain the order, just to be clean.)  */
1891
1892 enumlist:
1893           enumerator
1894         | enumlist ',' enumerator
1895                 { if ($1 == error_mark_node)
1896                     $$ = $1;
1897                   else
1898                     $$ = chainon ($3, $1); }
1899         | error
1900                 { $$ = error_mark_node; }
1901         ;
1902
1903
1904 enumerator:
1905           identifier
1906                 { $$ = build_enumerator ($1, NULL_TREE); }
1907         | identifier '=' expr_no_commas
1908                 { $$ = build_enumerator ($1, $3); }
1909         ;
1910
1911 typename:
1912           declspecs_nosc
1913                 { tree specs, attrs;
1914                   pending_xref_error ();
1915                   split_specs_attrs ($1, &specs, &attrs);
1916                   /* We don't yet support attributes here.  */
1917                   if (attrs != NULL_TREE)
1918                     warning ("attributes on type name ignored");
1919                   $<ttype>$ = specs; }
1920           absdcl
1921                 { $$ = build_tree_list ($<ttype>2, $3); }
1922         ;
1923
1924 absdcl:   /* an absolute declarator */
1925         /* empty */
1926                 { $$ = NULL_TREE; }
1927         | absdcl1
1928         ;
1929
1930 absdcl_maybe_attribute:   /* absdcl maybe_attribute, but not just attributes */
1931         /* empty */
1932                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1933                                                          NULL_TREE),
1934                                         all_prefix_attributes); }
1935         | absdcl1
1936                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1937                                                          $1),
1938                                         all_prefix_attributes); }
1939         | absdcl1_noea attributes
1940                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1941                                                          $1),
1942                                         chainon ($2, all_prefix_attributes)); }
1943         ;
1944
1945 absdcl1:  /* a nonempty absolute declarator */
1946           absdcl1_ea
1947         | absdcl1_noea
1948         ;
1949
1950 absdcl1_noea:
1951           direct_absdcl1
1952         | '*' maybe_type_quals_attrs absdcl1_noea
1953                 { $$ = make_pointer_declarator ($2, $3); }
1954         ;
1955
1956 absdcl1_ea:
1957           '*' maybe_type_quals_attrs
1958                 { $$ = make_pointer_declarator ($2, NULL_TREE); }
1959         | '*' maybe_type_quals_attrs absdcl1_ea
1960                 { $$ = make_pointer_declarator ($2, $3); }
1961         ;
1962
1963 direct_absdcl1:
1964           '(' maybe_attribute absdcl1 ')'
1965                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1966         | direct_absdcl1 '(' parmlist
1967                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1968         | direct_absdcl1 array_declarator
1969                 { $$ = set_array_declarator_type ($2, $1, 1); }
1970         | '(' parmlist
1971                 { $$ = build_nt (CALL_EXPR, NULL_TREE, $2, NULL_TREE); }
1972         | array_declarator
1973                 { $$ = set_array_declarator_type ($1, NULL_TREE, 1); }
1974         ;
1975
1976 /* The [...] part of a declarator for an array type.  */
1977
1978 array_declarator:
1979           '[' expr ']'
1980                 { $$ = build_array_declarator ($2, NULL_TREE, 0, 0); }
1981         | '[' declspecs_nosc expr ']'
1982                 { $$ = build_array_declarator ($3, $2, 0, 0); }
1983         | '[' ']'
1984                 { $$ = build_array_declarator (NULL_TREE, NULL_TREE, 0, 0); }
1985         | '[' declspecs_nosc ']'
1986                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 0); }
1987         | '[' '*' ']'
1988                 { $$ = build_array_declarator (NULL_TREE, NULL_TREE, 0, 1); }
1989         | '[' declspecs_nosc '*' ']'
1990                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 1); }
1991         | '[' SCSPEC expr ']'
1992                 { if (C_RID_CODE ($2) != RID_STATIC)
1993                     error ("storage class specifier in array declarator");
1994                   $$ = build_array_declarator ($3, NULL_TREE, 1, 0); }
1995         | '[' SCSPEC declspecs_nosc expr ']'
1996                 { if (C_RID_CODE ($2) != RID_STATIC)
1997                     error ("storage class specifier in array declarator");
1998                   $$ = build_array_declarator ($4, $3, 1, 0); }
1999         | '[' declspecs_nosc SCSPEC expr ']'
2000                 { if (C_RID_CODE ($3) != RID_STATIC)
2001                     error ("storage class specifier in array declarator");
2002                   $$ = build_array_declarator ($4, $2, 1, 0); }
2003         ;
2004
2005 /* A nonempty series of declarations and statements (possibly followed by
2006    some labels) that can form the body of a compound statement.
2007    NOTE: we don't allow labels on declarations; this might seem like a
2008    natural extension, but there would be a conflict between attributes
2009    on the label and prefix attributes on the declaration.  */
2010
2011 stmts_and_decls:
2012           lineno_stmt_decl_or_labels_ending_stmt
2013         | lineno_stmt_decl_or_labels_ending_decl
2014         | lineno_stmt_decl_or_labels_ending_label
2015                 {
2016                   pedwarn ("deprecated use of label at end of compound statement");
2017                 }
2018         | lineno_stmt_decl_or_labels_ending_error
2019         ;
2020
2021 lineno_stmt_decl_or_labels_ending_stmt:
2022           lineno_stmt
2023         | lineno_stmt_decl_or_labels_ending_stmt lineno_stmt
2024         | lineno_stmt_decl_or_labels_ending_decl lineno_stmt
2025         | lineno_stmt_decl_or_labels_ending_label lineno_stmt
2026         | lineno_stmt_decl_or_labels_ending_error lineno_stmt
2027         ;
2028
2029 lineno_stmt_decl_or_labels_ending_decl:
2030           lineno_decl
2031         | lineno_stmt_decl_or_labels_ending_stmt lineno_decl
2032                 { if (pedantic && !flag_isoc99)
2033                     pedwarn ("ISO C89 forbids mixed declarations and code"); }
2034         | lineno_stmt_decl_or_labels_ending_decl lineno_decl
2035         | lineno_stmt_decl_or_labels_ending_error lineno_decl
2036         ;
2037
2038 lineno_stmt_decl_or_labels_ending_label:
2039           lineno_label
2040         | lineno_stmt_decl_or_labels_ending_stmt lineno_label
2041         | lineno_stmt_decl_or_labels_ending_decl lineno_label
2042         | lineno_stmt_decl_or_labels_ending_label lineno_label
2043         | lineno_stmt_decl_or_labels_ending_error lineno_label
2044         ;
2045
2046 lineno_stmt_decl_or_labels_ending_error:
2047         errstmt
2048         | lineno_stmt_decl_or_labels errstmt
2049         ;
2050
2051 lineno_stmt_decl_or_labels:
2052           lineno_stmt_decl_or_labels_ending_stmt
2053         | lineno_stmt_decl_or_labels_ending_decl
2054         | lineno_stmt_decl_or_labels_ending_label
2055         | lineno_stmt_decl_or_labels_ending_error
2056         ;
2057
2058 errstmt:  error ';'
2059         ;
2060
2061 pushlevel:  /* empty */
2062                 { pushlevel (0);
2063                   clear_last_expr ();
2064                   add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2065 ifobjc
2066                   if (objc_method_context)
2067                     add_objc_decls ();
2068 end ifobjc
2069                 }
2070         ;
2071
2072 poplevel:  /* empty */
2073                 { $$ = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0); }
2074
2075 /* Start and end blocks created for the new scopes of C99.  */
2076 c99_block_start: /* empty */
2077                 { if (flag_isoc99)
2078                     {
2079                       $$ = c_begin_compound_stmt ();
2080                       pushlevel (0);
2081                       clear_last_expr ();
2082                       add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2083 ifobjc
2084                       if (objc_method_context)
2085                         add_objc_decls ();
2086 end ifobjc
2087                     }
2088                   else
2089                     $$ = NULL_TREE;
2090                 }
2091         ;
2092
2093 /* Productions using c99_block_start and c99_block_end will need to do what's
2094    in compstmt: RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); $$ = $2; where
2095    $1 is the value of c99_block_start and $2 of c99_block_end.  */
2096 c99_block_end: /* empty */
2097                 { if (flag_isoc99)
2098                     {
2099                       tree scope_stmt = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0);
2100                       $$ = poplevel (kept_level_p (), 0, 0);
2101                       SCOPE_STMT_BLOCK (TREE_PURPOSE (scope_stmt))
2102                         = SCOPE_STMT_BLOCK (TREE_VALUE (scope_stmt))
2103                         = $$;
2104                     }
2105                   else
2106                     $$ = NULL_TREE; }
2107         ;
2108
2109 /* Read zero or more forward-declarations for labels
2110    that nested functions can jump to.  */
2111 maybe_label_decls:
2112           /* empty */
2113         | label_decls
2114                 { if (pedantic)
2115                     pedwarn ("ISO C forbids label declarations"); }
2116         ;
2117
2118 label_decls:
2119           label_decl
2120         | label_decls label_decl
2121         ;
2122
2123 label_decl:
2124           LABEL identifiers_or_typenames ';'
2125                 { tree link;
2126                   for (link = $2; link; link = TREE_CHAIN (link))
2127                     {
2128                       tree label = shadow_label (TREE_VALUE (link));
2129                       C_DECLARED_LABEL_FLAG (label) = 1;
2130                       add_decl_stmt (label);
2131                     }
2132                 }
2133         ;
2134
2135 /* This is the body of a function definition.
2136    It causes syntax errors to ignore to the next openbrace.  */
2137 compstmt_or_error:
2138           compstmt
2139                 {}
2140         | error compstmt
2141         ;
2142
2143 compstmt_start: '{' { compstmt_count++;
2144                       $$ = c_begin_compound_stmt (); }
2145
2146 compstmt_nostart: '}'
2147                 { $$ = convert (void_type_node, integer_zero_node); }
2148         | pushlevel maybe_label_decls compstmt_contents_nonempty '}' poplevel
2149                 { $$ = poplevel (kept_level_p (), 1, 0);
2150                   SCOPE_STMT_BLOCK (TREE_PURPOSE ($5))
2151                     = SCOPE_STMT_BLOCK (TREE_VALUE ($5))
2152                     = $$; }
2153         ;
2154
2155 compstmt_contents_nonempty:
2156           stmts_and_decls
2157         | error
2158         ;
2159
2160 compstmt_primary_start:
2161         '(' '{'
2162                 { if (current_function_decl == 0)
2163                     {
2164                       error ("braced-group within expression allowed only inside a function");
2165                       YYERROR;
2166                     }
2167                   /* We must force a BLOCK for this level
2168                      so that, if it is not expanded later,
2169                      there is a way to turn off the entire subtree of blocks
2170                      that are contained in it.  */
2171                   keep_next_level ();
2172                   push_label_level ();
2173                   compstmt_count++;
2174                   $$ = add_stmt (build_stmt (COMPOUND_STMT, last_tree));
2175                 }
2176
2177 compstmt: compstmt_start compstmt_nostart
2178                 { RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2179                   $$ = $1; }
2180         ;
2181
2182 /* Value is number of statements counted as of the closeparen.  */
2183 simple_if:
2184           if_prefix c99_block_lineno_labeled_stmt
2185                 { c_finish_then (); }
2186 /* Make sure c_expand_end_cond is run once
2187    for each call to c_expand_start_cond.
2188    Otherwise a crash is likely.  */
2189         | if_prefix error
2190         ;
2191
2192 if_prefix:
2193           IF '(' expr ')'
2194                 { c_expand_start_cond (truthvalue_conversion ($3),
2195                                        compstmt_count);
2196                   $<itype>$ = stmt_count;
2197                   if_stmt_file = $<filename>-2;
2198                   if_stmt_line = $<lineno>-1; }
2199         ;
2200
2201 /* This is a subroutine of stmt.
2202    It is used twice, once for valid DO statements
2203    and once for catching errors in parsing the end test.  */
2204 do_stmt_start:
2205           DO
2206                 { stmt_count++;
2207                   compstmt_count++;
2208                   $<ttype>$
2209                     = add_stmt (build_stmt (DO_STMT, NULL_TREE,
2210                                             NULL_TREE));
2211                   /* In the event that a parse error prevents
2212                      parsing the complete do-statement, set the
2213                      condition now.  Otherwise, we can get crashes at
2214                      RTL-generation time.  */
2215                   DO_COND ($<ttype>$) = error_mark_node; }
2216           c99_block_lineno_labeled_stmt WHILE
2217                 { $$ = $<ttype>2;
2218                   RECHAIN_STMTS ($$, DO_BODY ($$)); }
2219         ;
2220
2221 /* The forced readahead in here is because we might be at the end of a
2222    line, and the line and file won't be bumped until yylex absorbs the
2223    first token on the next line.  */
2224 save_filename:
2225                 { if (yychar == YYEMPTY)
2226                     yychar = YYLEX;
2227                   $$ = input_filename; }
2228         ;
2229
2230 save_lineno:
2231                 { if (yychar == YYEMPTY)
2232                     yychar = YYLEX;
2233                   $$ = lineno; }
2234         ;
2235
2236 lineno_labeled_stmt:
2237           lineno_stmt
2238         | lineno_label lineno_labeled_stmt
2239         ;
2240
2241 /* Like lineno_labeled_stmt, but a block in C99.  */
2242 c99_block_lineno_labeled_stmt:
2243           c99_block_start lineno_labeled_stmt c99_block_end
2244                 { if (flag_isoc99)
2245                     RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); }
2246         ;
2247
2248 lineno_stmt:
2249           save_filename save_lineno stmt
2250                 { if ($3)
2251                     {
2252                       STMT_LINENO ($3) = $2;
2253                       /* ??? We currently have no way of recording
2254                          the filename for a statement.  This probably
2255                          matters little in practice at the moment,
2256                          but I suspect that problems will occur when
2257                          doing inlining at the tree level.  */
2258                     }
2259                 }
2260         ;
2261
2262 lineno_label:
2263           save_filename save_lineno label
2264                 { if ($3)
2265                     {
2266                       STMT_LINENO ($3) = $2;
2267                     }
2268                 }
2269         ;
2270
2271 select_or_iter_stmt:
2272           simple_if ELSE
2273                 { c_expand_start_else ();
2274                   $<itype>1 = stmt_count; }
2275           c99_block_lineno_labeled_stmt
2276                 { c_finish_else ();
2277                   c_expand_end_cond ();
2278                   if (extra_warnings && stmt_count == $<itype>1)
2279                     warning ("empty body in an else-statement"); }
2280         | simple_if %prec IF
2281                 { c_expand_end_cond ();
2282                   /* This warning is here instead of in simple_if, because we
2283                      do not want a warning if an empty if is followed by an
2284                      else statement.  Increment stmt_count so we don't
2285                      give a second error if this is a nested `if'.  */
2286                   if (extra_warnings && stmt_count++ == $<itype>1)
2287                     warning_with_file_and_line (if_stmt_file, if_stmt_line,
2288                                                 "empty body in an if-statement"); }
2289 /* Make sure c_expand_end_cond is run once
2290    for each call to c_expand_start_cond.
2291    Otherwise a crash is likely.  */
2292         | simple_if ELSE error
2293                 { c_expand_end_cond (); }
2294         | WHILE
2295                 { stmt_count++; }
2296           '(' expr ')'
2297                 { $4 = truthvalue_conversion ($4);
2298                   $<ttype>$
2299                     = add_stmt (build_stmt (WHILE_STMT, $4, NULL_TREE)); }
2300           c99_block_lineno_labeled_stmt
2301                 { RECHAIN_STMTS ($<ttype>6, WHILE_BODY ($<ttype>6)); }
2302         | do_stmt_start
2303           '(' expr ')' ';'
2304                 { DO_COND ($1) = truthvalue_conversion ($3); }
2305         | do_stmt_start error
2306                 { }
2307         | FOR
2308                 { $<ttype>$ = build_stmt (FOR_STMT, NULL_TREE, NULL_TREE,
2309                                           NULL_TREE, NULL_TREE);
2310                   add_stmt ($<ttype>$); }
2311           '(' for_init_stmt
2312                 { stmt_count++;
2313                   RECHAIN_STMTS ($<ttype>2, FOR_INIT_STMT ($<ttype>2)); }
2314           xexpr ';'
2315                 { if ($6)
2316                     FOR_COND ($<ttype>2) = truthvalue_conversion ($6); }
2317           xexpr ')'
2318                 { FOR_EXPR ($<ttype>2) = $9; }
2319           c99_block_lineno_labeled_stmt
2320                 { RECHAIN_STMTS ($<ttype>2, FOR_BODY ($<ttype>2)); }
2321         | SWITCH '(' expr ')'
2322                 { stmt_count++;
2323                   $<ttype>$ = c_start_case ($3); }
2324           c99_block_lineno_labeled_stmt
2325                 { c_finish_case (); }
2326         ;
2327
2328 for_init_stmt:
2329           xexpr ';'
2330                 { add_stmt (build_stmt (EXPR_STMT, $1)); }
2331         | decl
2332                 { check_for_loop_decls (); }
2333         ;
2334
2335 /* Parse a single real statement, not including any labels.  */
2336 stmt:
2337           compstmt
2338                 { stmt_count++; $$ = $1; }
2339         | expr ';'
2340                 { stmt_count++;
2341                   $$ = c_expand_expr_stmt ($1); }
2342         | c99_block_start select_or_iter_stmt c99_block_end
2343                 { if (flag_isoc99)
2344                     RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2345                   $$ = NULL_TREE; }
2346         | BREAK ';'
2347                 { stmt_count++;
2348                   $$ = add_stmt (build_break_stmt ()); }
2349         | CONTINUE ';'
2350                 { stmt_count++;
2351                   $$ = add_stmt (build_continue_stmt ()); }
2352         | RETURN ';'
2353                 { stmt_count++;
2354                   $$ = c_expand_return (NULL_TREE); }
2355         | RETURN expr ';'
2356                 { stmt_count++;
2357                   $$ = c_expand_return ($2); }
2358         | ASM_KEYWORD maybe_type_qual '(' expr ')' ';'
2359                 { stmt_count++;
2360                   $$ = simple_asm_stmt ($4); }
2361         /* This is the case with just output operands.  */
2362         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ')' ';'
2363                 { stmt_count++;
2364                   $$ = build_asm_stmt ($2, $4, $6, NULL_TREE, NULL_TREE); }
2365         /* This is the case with input operands as well.  */
2366         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2367           asm_operands ')' ';'
2368                 { stmt_count++;
2369                   $$ = build_asm_stmt ($2, $4, $6, $8, NULL_TREE); }
2370         /* This is the case with clobbered registers as well.  */
2371         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2372           asm_operands ':' asm_clobbers ')' ';'
2373                 { stmt_count++;
2374                   $$ = build_asm_stmt ($2, $4, $6, $8, $10); }
2375         | GOTO identifier ';'
2376                 { tree decl;
2377                   stmt_count++;
2378                   decl = lookup_label ($2);
2379                   if (decl != 0)
2380                     {
2381                       TREE_USED (decl) = 1;
2382                       $$ = add_stmt (build_stmt (GOTO_STMT, decl));
2383                     }
2384                   else
2385                     $$ = NULL_TREE;
2386                 }
2387         | GOTO '*' expr ';'
2388                 { if (pedantic)
2389                     pedwarn ("ISO C forbids `goto *expr;'");
2390                   stmt_count++;
2391                   $3 = convert (ptr_type_node, $3);
2392                   $$ = add_stmt (build_stmt (GOTO_STMT, $3)); }
2393         | ';'
2394                 { $$ = NULL_TREE; }
2395         ;
2396
2397 /* Any kind of label, including jump labels and case labels.
2398    ANSI C accepts labels only before statements, but we allow them
2399    also at the end of a compound statement.  */
2400
2401 label:    CASE expr_no_commas ':'
2402                 { stmt_count++;
2403                   $$ = do_case ($2, NULL_TREE); }
2404         | CASE expr_no_commas ELLIPSIS expr_no_commas ':'
2405                 { stmt_count++;
2406                   $$ = do_case ($2, $4); }
2407         | DEFAULT ':'
2408                 { stmt_count++;
2409                   $$ = do_case (NULL_TREE, NULL_TREE); }
2410         | identifier save_filename save_lineno ':' maybe_attribute
2411                 { tree label = define_label ($2, $3, $1);
2412                   stmt_count++;
2413                   if (label)
2414                     {
2415                       decl_attributes (&label, $5, 0);
2416                       $$ = add_stmt (build_stmt (LABEL_STMT, label));
2417                     }
2418                   else
2419                     $$ = NULL_TREE;
2420                 }
2421         ;
2422
2423 /* Either a type-qualifier or nothing.  First thing in an `asm' statement.  */
2424
2425 maybe_type_qual:
2426         /* empty */
2427                 { emit_line_note (input_filename, lineno);
2428                   $$ = NULL_TREE; }
2429         | TYPE_QUAL
2430                 { emit_line_note (input_filename, lineno); }
2431         ;
2432
2433 xexpr:
2434         /* empty */
2435                 { $$ = NULL_TREE; }
2436         | expr
2437         ;
2438
2439 /* These are the operands other than the first string and colon
2440    in  asm ("addextend %2,%1": "=dm" (x), "0" (y), "g" (*x))  */
2441 asm_operands: /* empty */
2442                 { $$ = NULL_TREE; }
2443         | nonnull_asm_operands
2444         ;
2445
2446 nonnull_asm_operands:
2447           asm_operand
2448         | nonnull_asm_operands ',' asm_operand
2449                 { $$ = chainon ($1, $3); }
2450         ;
2451
2452 asm_operand:
2453           STRING '(' expr ')'
2454                 { $$ = build_tree_list (build_tree_list (NULL_TREE, $1), $3); }
2455         | '[' identifier ']' STRING '(' expr ')'
2456                 { $$ = build_tree_list (build_tree_list ($2, $4), $6); }
2457         ;
2458
2459 asm_clobbers:
2460           string
2461                 { $$ = tree_cons (NULL_TREE, combine_strings ($1), NULL_TREE); }
2462         | asm_clobbers ',' string
2463                 { $$ = tree_cons (NULL_TREE, combine_strings ($3), $1); }
2464         ;
2465 \f
2466 /* This is what appears inside the parens in a function declarator.
2467    Its value is a list of ..._TYPE nodes.  Attributes must appear here
2468    to avoid a conflict with their appearance after an open parenthesis
2469    in an abstract declarator, as in
2470    "void bar (int (__attribute__((__mode__(SI))) int foo));".  */
2471 parmlist:
2472           maybe_attribute
2473                 { pushlevel (0);
2474                   clear_parm_order ();
2475                   declare_parm_level (0); }
2476           parmlist_1
2477                 { $$ = $3;
2478                   parmlist_tags_warning ();
2479                   poplevel (0, 0, 0); }
2480         ;
2481
2482 parmlist_1:
2483           parmlist_2 ')'
2484         | parms ';'
2485                 { tree parm;
2486                   if (pedantic)
2487                     pedwarn ("ISO C forbids forward parameter declarations");
2488                   /* Mark the forward decls as such.  */
2489                   for (parm = getdecls (); parm; parm = TREE_CHAIN (parm))
2490                     TREE_ASM_WRITTEN (parm) = 1;
2491                   clear_parm_order (); }
2492           maybe_attribute
2493                 { /* Dummy action so attributes are in known place
2494                      on parser stack.  */ }
2495           parmlist_1
2496                 { $$ = $6; }
2497         | error ')'
2498                 { $$ = tree_cons (NULL_TREE, NULL_TREE, NULL_TREE); }
2499         ;
2500
2501 /* This is what appears inside the parens in a function declarator.
2502    Is value is represented in the format that grokdeclarator expects.  */
2503 parmlist_2:  /* empty */
2504                 { $$ = get_parm_info (0); }
2505         | ELLIPSIS
2506                 { $$ = get_parm_info (0);
2507                   /* Gcc used to allow this as an extension.  However, it does
2508                      not work for all targets, and thus has been disabled.
2509                      Also, since func (...) and func () are indistinguishable,
2510                      it caused problems with the code in expand_builtin which
2511                      tries to verify that BUILT_IN_NEXT_ARG is being used
2512                      correctly.  */
2513                   error ("ISO C requires a named argument before `...'");
2514                 }
2515         | parms
2516                 { $$ = get_parm_info (1); }
2517         | parms ',' ELLIPSIS
2518                 { $$ = get_parm_info (0); }
2519         ;
2520
2521 parms:
2522         firstparm
2523                 { push_parm_decl ($1); }
2524         | parms ',' parm
2525                 { push_parm_decl ($3); }
2526         ;
2527
2528 /* A single parameter declaration or parameter type name,
2529    as found in a parmlist.  */
2530 parm:
2531           declspecs_ts setspecs parm_declarator maybe_attribute
2532                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2533                                                          $3),
2534                                         chainon ($4, all_prefix_attributes));
2535                   POP_DECLSPEC_STACK; }
2536         | declspecs_ts setspecs notype_declarator maybe_attribute
2537                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2538                                                          $3),
2539                                         chainon ($4, all_prefix_attributes));
2540                   POP_DECLSPEC_STACK; }
2541         | declspecs_ts setspecs absdcl_maybe_attribute
2542                 { $$ = $3;
2543                   POP_DECLSPEC_STACK; }
2544         | declspecs_nots setspecs notype_declarator maybe_attribute
2545                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2546                                                          $3),
2547                                         chainon ($4, all_prefix_attributes));
2548                   POP_DECLSPEC_STACK; }
2549
2550         | declspecs_nots setspecs absdcl_maybe_attribute
2551                 { $$ = $3;
2552                   POP_DECLSPEC_STACK; }
2553         ;
2554
2555 /* The first parm, which must suck attributes from off the top of the parser
2556    stack.  */
2557 firstparm:
2558           declspecs_ts_nosa setspecs_fp parm_declarator maybe_attribute
2559                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2560                                                          $3),
2561                                         chainon ($4, all_prefix_attributes));
2562                   POP_DECLSPEC_STACK; }
2563         | declspecs_ts_nosa setspecs_fp notype_declarator maybe_attribute
2564                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2565                                                          $3),
2566                                         chainon ($4, all_prefix_attributes));
2567                   POP_DECLSPEC_STACK; }
2568         | declspecs_ts_nosa setspecs_fp absdcl_maybe_attribute
2569                 { $$ = $3;
2570                   POP_DECLSPEC_STACK; }
2571         | declspecs_nots_nosa setspecs_fp notype_declarator maybe_attribute
2572                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2573                                                          $3),
2574                                         chainon ($4, all_prefix_attributes));
2575                   POP_DECLSPEC_STACK; }
2576
2577         | declspecs_nots_nosa setspecs_fp absdcl_maybe_attribute
2578                 { $$ = $3;
2579                   POP_DECLSPEC_STACK; }
2580         ;
2581
2582 setspecs_fp:
2583           setspecs
2584                 { prefix_attributes = chainon (prefix_attributes, $<ttype>-2);
2585                   all_prefix_attributes = prefix_attributes; }
2586         ;
2587
2588 /* This is used in a function definition
2589    where either a parmlist or an identifier list is ok.
2590    Its value is a list of ..._TYPE nodes or a list of identifiers.  */
2591 parmlist_or_identifiers:
2592                 { pushlevel (0);
2593                   clear_parm_order ();
2594                   declare_parm_level (1); }
2595           parmlist_or_identifiers_1
2596                 { $$ = $2;
2597                   parmlist_tags_warning ();
2598                   poplevel (0, 0, 0); }
2599         ;
2600
2601 parmlist_or_identifiers_1:
2602           parmlist_1
2603         | identifiers ')'
2604                 { tree t;
2605                   for (t = $1; t; t = TREE_CHAIN (t))
2606                     if (TREE_VALUE (t) == NULL_TREE)
2607                       error ("`...' in old-style identifier list");
2608                   $$ = tree_cons (NULL_TREE, NULL_TREE, $1); }
2609         ;
2610
2611 /* A nonempty list of identifiers.  */
2612 identifiers:
2613         IDENTIFIER
2614                 { $$ = build_tree_list (NULL_TREE, $1); }
2615         | identifiers ',' IDENTIFIER
2616                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2617         ;
2618
2619 /* A nonempty list of identifiers, including typenames.  */
2620 identifiers_or_typenames:
2621         identifier
2622                 { $$ = build_tree_list (NULL_TREE, $1); }
2623         | identifiers_or_typenames ',' identifier
2624                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2625         ;
2626
2627 extension:
2628         EXTENSION
2629                 { $$ = SAVE_WARN_FLAGS();
2630                   pedantic = 0;
2631                   warn_pointer_arith = 0; }
2632         ;
2633 \f
2634 ifobjc
2635 /* Objective-C productions.  */
2636
2637 objcdef:
2638           classdef
2639         | classdecl
2640         | aliasdecl
2641         | protocoldef
2642         | methoddef
2643         | END
2644                 {
2645                   if (objc_implementation_context)
2646                     {
2647                       finish_class (objc_implementation_context);
2648                       objc_ivar_chain = NULL_TREE;
2649                       objc_implementation_context = NULL_TREE;
2650                     }
2651                   else
2652                     warning ("`@end' must appear in an implementation context");
2653                 }
2654         ;
2655
2656 /* A nonempty list of identifiers.  */
2657 identifier_list:
2658         identifier
2659                 { $$ = build_tree_list (NULL_TREE, $1); }
2660         | identifier_list ',' identifier
2661                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2662         ;
2663
2664 classdecl:
2665           CLASS identifier_list ';'
2666                 {
2667                   objc_declare_class ($2);
2668                 }
2669
2670 aliasdecl:
2671           ALIAS identifier identifier ';'
2672                 {
2673                   objc_declare_alias ($2, $3);
2674                 }
2675
2676 classdef:
2677           INTERFACE identifier protocolrefs '{'
2678                 {
2679                   objc_interface_context = objc_ivar_context
2680                     = start_class (CLASS_INTERFACE_TYPE, $2, NULL_TREE, $3);
2681                   objc_public_flag = 0;
2682                 }
2683           ivar_decl_list '}'
2684                 {
2685                   continue_class (objc_interface_context);
2686                 }
2687           methodprotolist
2688           END
2689                 {
2690                   finish_class (objc_interface_context);
2691                   objc_interface_context = NULL_TREE;
2692                 }
2693
2694         | INTERFACE identifier protocolrefs
2695                 {
2696                   objc_interface_context
2697                     = start_class (CLASS_INTERFACE_TYPE, $2, NULL_TREE, $3);
2698                   continue_class (objc_interface_context);
2699                 }
2700           methodprotolist
2701           END
2702                 {
2703                   finish_class (objc_interface_context);
2704                   objc_interface_context = NULL_TREE;
2705                 }
2706
2707         | INTERFACE identifier ':' identifier protocolrefs '{'
2708                 {
2709                   objc_interface_context = objc_ivar_context
2710                     = start_class (CLASS_INTERFACE_TYPE, $2, $4, $5);
2711                   objc_public_flag = 0;
2712                 }
2713           ivar_decl_list '}'
2714                 {
2715                   continue_class (objc_interface_context);
2716                 }
2717           methodprotolist
2718           END
2719                 {
2720                   finish_class (objc_interface_context);
2721                   objc_interface_context = NULL_TREE;
2722                 }
2723
2724         | INTERFACE identifier ':' identifier protocolrefs
2725                 {
2726                   objc_interface_context
2727                     = start_class (CLASS_INTERFACE_TYPE, $2, $4, $5);
2728                   continue_class (objc_interface_context);
2729                 }
2730           methodprotolist
2731           END
2732                 {
2733                   finish_class (objc_interface_context);
2734                   objc_interface_context = NULL_TREE;
2735                 }
2736
2737         | IMPLEMENTATION identifier '{'
2738                 {
2739                   objc_implementation_context = objc_ivar_context
2740                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, NULL_TREE, NULL_TREE);
2741                   objc_public_flag = 0;
2742                 }
2743           ivar_decl_list '}'
2744                 {
2745                   objc_ivar_chain
2746                     = continue_class (objc_implementation_context);
2747                 }
2748
2749         | IMPLEMENTATION identifier
2750                 {
2751                   objc_implementation_context
2752                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, NULL_TREE, NULL_TREE);
2753                   objc_ivar_chain
2754                     = continue_class (objc_implementation_context);
2755                 }
2756
2757         | IMPLEMENTATION identifier ':' identifier '{'
2758                 {
2759                   objc_implementation_context = objc_ivar_context
2760                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2761                   objc_public_flag = 0;
2762                 }
2763           ivar_decl_list '}'
2764                 {
2765                   objc_ivar_chain
2766                     = continue_class (objc_implementation_context);
2767                 }
2768
2769         | IMPLEMENTATION identifier ':' identifier
2770                 {
2771                   objc_implementation_context
2772                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2773                   objc_ivar_chain
2774                     = continue_class (objc_implementation_context);
2775                 }
2776
2777         | INTERFACE identifier '(' identifier ')' protocolrefs
2778                 {
2779                   objc_interface_context
2780                     = start_class (CATEGORY_INTERFACE_TYPE, $2, $4, $6);
2781                   continue_class (objc_interface_context);
2782                 }
2783           methodprotolist
2784           END
2785                 {
2786                   finish_class (objc_interface_context);
2787                   objc_interface_context = NULL_TREE;
2788                 }
2789
2790         | IMPLEMENTATION identifier '(' identifier ')'
2791                 {
2792                   objc_implementation_context
2793                     = start_class (CATEGORY_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2794                   objc_ivar_chain
2795                     = continue_class (objc_implementation_context);
2796                 }
2797         ;
2798
2799 protocoldef:
2800           PROTOCOL identifier protocolrefs
2801                 {
2802                   objc_pq_context = 1;
2803                   objc_interface_context
2804                     = start_protocol(PROTOCOL_INTERFACE_TYPE, $2, $3);
2805                 }
2806           methodprotolist END
2807                 {
2808                   objc_pq_context = 0;
2809                   finish_protocol(objc_interface_context);
2810                   objc_interface_context = NULL_TREE;
2811                 }
2812         /* The @protocol forward-declaration production introduces a
2813            reduce/reduce conflict on ';', which should be resolved in
2814            favor of the production 'identifier_list -> identifier'.  */
2815         | PROTOCOL identifier_list ';'
2816                 {
2817                   objc_declare_protocols ($2);
2818                 }
2819         ;
2820
2821 protocolrefs:
2822           /* empty */
2823                 {
2824                   $$ = NULL_TREE;
2825                 }
2826         | non_empty_protocolrefs
2827         ;
2828
2829 non_empty_protocolrefs:
2830           ARITHCOMPARE identifier_list ARITHCOMPARE
2831                 {
2832                   if ($1 == LT_EXPR && $3 == GT_EXPR)
2833                     $$ = $2;
2834                   else
2835                     YYERROR1;
2836                 }
2837         ;
2838
2839 ivar_decl_list:
2840           ivar_decl_list visibility_spec ivar_decls
2841         | ivar_decls
2842         ;
2843
2844 visibility_spec:
2845           PRIVATE { objc_public_flag = 2; }
2846         | PROTECTED { objc_public_flag = 0; }
2847         | PUBLIC { objc_public_flag = 1; }
2848         ;
2849
2850 ivar_decls:
2851           /* empty */
2852                 {
2853                   $$ = NULL_TREE;
2854                 }
2855         | ivar_decls ivar_decl ';'
2856         | ivar_decls ';'
2857                 {
2858                   if (pedantic)
2859                     pedwarn ("extra semicolon in struct or union specified");
2860                 }
2861         ;
2862
2863
2864 /* There is a shift-reduce conflict here, because `components' may
2865    start with a `typename'.  It happens that shifting (the default resolution)
2866    does the right thing, because it treats the `typename' as part of
2867    a `typed_typespecs'.
2868
2869    It is possible that this same technique would allow the distinction
2870    between `notype_initdecls' and `initdecls' to be eliminated.
2871    But I am being cautious and not trying it.  */
2872
2873 ivar_decl:
2874         declspecs_nosc_ts setspecs ivars
2875                 { $$ = $3;
2876                   POP_DECLSPEC_STACK; }
2877         | declspecs_nosc_nots setspecs ivars
2878                 { $$ = $3;
2879                   POP_DECLSPEC_STACK; }
2880         | error
2881                 { $$ = NULL_TREE; }
2882         ;
2883
2884 ivars:
2885           /* empty */
2886                 { $$ = NULL_TREE; }
2887         | ivar_declarator
2888         | ivars ',' maybe_resetattrs ivar_declarator
2889         ;
2890
2891 ivar_declarator:
2892           declarator
2893                 {
2894                   $$ = add_instance_variable (objc_ivar_context,
2895                                               objc_public_flag,
2896                                               $1, current_declspecs,
2897                                               NULL_TREE);
2898                 }
2899         | declarator ':' expr_no_commas
2900                 {
2901                   $$ = add_instance_variable (objc_ivar_context,
2902                                               objc_public_flag,
2903                                               $1, current_declspecs, $3);
2904                 }
2905         | ':' expr_no_commas
2906                 {
2907                   $$ = add_instance_variable (objc_ivar_context,
2908                                               objc_public_flag,
2909                                               NULL_TREE,
2910                                               current_declspecs, $2);
2911                 }
2912         ;
2913
2914 methodtype:
2915           '+'
2916                 { objc_inherit_code = CLASS_METHOD_DECL; }
2917         | '-'
2918                 { objc_inherit_code = INSTANCE_METHOD_DECL; }
2919         ;
2920
2921 methoddef:
2922           methodtype
2923                 {
2924                   objc_pq_context = 1;
2925                   if (!objc_implementation_context)
2926                     fatal_error ("method definition not in class context");
2927                 }
2928           methoddecl
2929                 {
2930                   objc_pq_context = 0;
2931                   if (objc_inherit_code == CLASS_METHOD_DECL)
2932                     add_class_method (objc_implementation_context, $3);
2933                   else
2934                     add_instance_method (objc_implementation_context, $3);
2935                   start_method_def ($3);
2936                 }
2937           optarglist
2938                 {
2939                   continue_method_def ();
2940                 }
2941           compstmt_or_error
2942                 {
2943                   finish_method_def ();
2944                 }
2945         ;
2946
2947 /* the reason for the strange actions in this rule
2948  is so that notype_initdecls when reached via datadef
2949  can find a valid list of type and sc specs in $0. */
2950
2951 methodprotolist:
2952           /* empty  */
2953         | {$<ttype>$ = NULL_TREE; } methodprotolist2
2954         ;
2955
2956 methodprotolist2:                /* eliminates a shift/reduce conflict */
2957            methodproto
2958         |  datadef
2959         | methodprotolist2 methodproto
2960         | methodprotolist2 {$<ttype>$ = NULL_TREE; } datadef
2961         ;
2962
2963 semi_or_error:
2964           ';'
2965         | error
2966         ;
2967
2968 methodproto:
2969           methodtype
2970                 {
2971                   /* Remember protocol qualifiers in prototypes.  */
2972                   objc_pq_context = 1;
2973                 }
2974           methoddecl
2975                 {
2976                   /* Forget protocol qualifiers here.  */
2977                   objc_pq_context = 0;
2978                   if (objc_inherit_code == CLASS_METHOD_DECL)
2979                     add_class_method (objc_interface_context, $3);
2980                   else
2981                     add_instance_method (objc_interface_context, $3);
2982                 }
2983           semi_or_error
2984         ;
2985
2986 methoddecl:
2987           '(' typename ')' unaryselector
2988                 {
2989                   $$ = build_method_decl (objc_inherit_code, $2, $4, NULL_TREE);
2990                 }
2991
2992         | unaryselector
2993                 {
2994                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, NULL_TREE);
2995                 }
2996
2997         | '(' typename ')' keywordselector optparmlist
2998                 {
2999                   $$ = build_method_decl (objc_inherit_code, $2, $4, $5);
3000                 }
3001
3002         | keywordselector optparmlist
3003                 {
3004                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, $2);
3005                 }
3006         ;
3007
3008 /* "optarglist" assumes that start_method_def has already been called...
3009    if it is not, the "xdecls" will not be placed in the proper scope */
3010
3011 optarglist:
3012           /* empty */
3013         | ';' myxdecls
3014         ;
3015
3016 /* to get around the following situation: "int foo (int a) int b; {}" that
3017    is synthesized when parsing "- a:a b:b; id c; id d; { ... }" */
3018
3019 myxdecls:
3020           /* empty */
3021         | mydecls
3022         ;
3023
3024 mydecls:
3025         mydecl
3026         | errstmt
3027         | mydecls mydecl
3028         | mydecl errstmt
3029         ;
3030
3031 mydecl:
3032         declspecs_ts setspecs myparms ';'
3033                 { POP_DECLSPEC_STACK; }
3034         | declspecs_ts ';'
3035                 { shadow_tag ($1); }
3036         | declspecs_nots ';'
3037                 { pedwarn ("empty declaration"); }
3038         ;
3039
3040 myparms:
3041         myparm
3042                 { push_parm_decl ($1); }
3043         | myparms ',' myparm
3044                 { push_parm_decl ($3); }
3045         ;
3046
3047 /* A single parameter declaration or parameter type name,
3048    as found in a parmlist. DOES NOT ALLOW AN INITIALIZER OR ASMSPEC */
3049
3050 myparm:
3051           parm_declarator maybe_attribute
3052                 { $$ = build_tree_list (build_tree_list (current_declspecs,
3053                                                          $1),
3054                                         chainon ($2, all_prefix_attributes)); }
3055         | notype_declarator maybe_attribute
3056                 { $$ = build_tree_list (build_tree_list (current_declspecs,
3057                                                          $1),
3058                                         chainon ($2, all_prefix_attributes)); }
3059         | absdcl_maybe_attribute
3060                 { $$ = $1; }
3061         ;
3062
3063 optparmlist:
3064           /* empty */
3065                 {
3066                   $$ = NULL_TREE;
3067                 }
3068         | ',' ELLIPSIS
3069                 {
3070                   /* oh what a kludge! */
3071                   $$ = objc_ellipsis_node;
3072                 }
3073         | ','
3074                 {
3075                   pushlevel (0);
3076                 }
3077           parmlist_2
3078                 {
3079                   /* returns a tree list node generated by get_parm_info */
3080                   $$ = $3;
3081                   poplevel (0, 0, 0);
3082                 }
3083         ;
3084
3085 unaryselector:
3086           selector
3087         ;
3088
3089 keywordselector:
3090           keyworddecl
3091
3092         | keywordselector keyworddecl
3093                 {
3094                   $$ = chainon ($1, $2);
3095                 }
3096         ;
3097
3098 selector:
3099           IDENTIFIER
3100         | TYPENAME
3101         | CLASSNAME
3102         | OBJECTNAME
3103         | reservedwords
3104         ;
3105
3106 reservedwords:
3107           ENUM | STRUCT | UNION | IF | ELSE | WHILE | DO | FOR
3108         | SWITCH | CASE | DEFAULT | BREAK | CONTINUE | RETURN
3109         | GOTO | ASM_KEYWORD | SIZEOF | TYPEOF | ALIGNOF
3110         | TYPESPEC | TYPE_QUAL
3111         ;
3112
3113 keyworddecl:
3114           selector ':' '(' typename ')' identifier
3115                 {
3116                   $$ = build_keyword_decl ($1, $4, $6);
3117                 }
3118
3119         | selector ':' identifier
3120                 {
3121                   $$ = build_keyword_decl ($1, NULL_TREE, $3);
3122                 }
3123
3124         | ':' '(' typename ')' identifier
3125                 {
3126                   $$ = build_keyword_decl (NULL_TREE, $3, $5);
3127                 }
3128
3129         | ':' identifier
3130                 {
3131                   $$ = build_keyword_decl (NULL_TREE, NULL_TREE, $2);
3132                 }
3133         ;
3134
3135 messageargs:
3136           selector
3137         | keywordarglist
3138         ;
3139
3140 keywordarglist:
3141           keywordarg
3142         | keywordarglist keywordarg
3143                 {
3144                   $$ = chainon ($1, $2);
3145                 }
3146         ;
3147
3148
3149 keywordexpr:
3150           nonnull_exprlist
3151                 {
3152                   if (TREE_CHAIN ($1) == NULL_TREE)
3153                     /* just return the expr., remove a level of indirection */
3154                     $$ = TREE_VALUE ($1);
3155                   else
3156                     /* we have a comma expr., we will collapse later */
3157                     $$ = $1;
3158                 }
3159         ;
3160
3161 keywordarg:
3162           selector ':' keywordexpr
3163                 {
3164                   $$ = build_tree_list ($1, $3);
3165                 }
3166         | ':' keywordexpr
3167                 {
3168                   $$ = build_tree_list (NULL_TREE, $2);
3169                 }
3170         ;
3171
3172 receiver:
3173           expr
3174         | CLASSNAME
3175                 {
3176                   $$ = get_class_reference ($1);
3177                 }
3178         ;
3179
3180 objcmessageexpr:
3181           '['
3182                 { objc_receiver_context = 1; }
3183           receiver
3184                 { objc_receiver_context = 0; }
3185           messageargs ']'
3186                 {
3187                   $$ = build_tree_list ($3, $5);
3188                 }
3189         ;
3190
3191 selectorarg:
3192           selector
3193         | keywordnamelist
3194         ;
3195
3196 keywordnamelist:
3197           keywordname
3198         | keywordnamelist keywordname
3199                 {
3200                   $$ = chainon ($1, $2);
3201                 }
3202         ;
3203
3204 keywordname:
3205           selector ':'
3206                 {
3207                   $$ = build_tree_list ($1, NULL_TREE);
3208                 }
3209         | ':'
3210                 {
3211                   $$ = build_tree_list (NULL_TREE, NULL_TREE);
3212                 }
3213         ;
3214
3215 objcselectorexpr:
3216           SELECTOR '(' selectorarg ')'
3217                 {
3218                   $$ = $3;
3219                 }
3220         ;
3221
3222 objcprotocolexpr:
3223           PROTOCOL '(' identifier ')'
3224                 {
3225                   $$ = $3;
3226                 }
3227         ;
3228
3229 /* extension to support C-structures in the archiver */
3230
3231 objcencodeexpr:
3232           ENCODE '(' typename ')'
3233                 {
3234                   $$ = groktypename ($3);
3235                 }
3236         ;
3237
3238 end ifobjc
3239 %%
3240
3241 /* yylex() is a thin wrapper around c_lex(), all it does is translate
3242    cpplib.h's token codes into yacc's token codes.  */
3243
3244 static enum cpp_ttype last_token;
3245
3246 /* The reserved keyword table.  */
3247 struct resword
3248 {
3249   const char *word;
3250   ENUM_BITFIELD(rid) rid : 16;
3251   unsigned int disable   : 16;
3252 };
3253
3254 /* Disable mask.  Keywords are disabled if (reswords[i].disable & mask) is
3255    _true_.  */
3256 #define D_TRAD  0x01    /* not in traditional C */
3257 #define D_C89   0x02    /* not in C89 */
3258 #define D_EXT   0x04    /* GCC extension */
3259 #define D_EXT89 0x08    /* GCC extension incorporated in C99 */
3260 #define D_OBJC  0x10    /* Objective C only */
3261
3262 static const struct resword reswords[] =
3263 {
3264   { "_Bool",            RID_BOOL,       0 },
3265   { "_Complex",         RID_COMPLEX,    0 },
3266   { "__FUNCTION__",     RID_FUNCTION_NAME, 0 },
3267   { "__PRETTY_FUNCTION__", RID_PRETTY_FUNCTION_NAME, 0 },
3268   { "__alignof",        RID_ALIGNOF,    0 },
3269   { "__alignof__",      RID_ALIGNOF,    0 },
3270   { "__asm",            RID_ASM,        0 },
3271   { "__asm__",          RID_ASM,        0 },
3272   { "__attribute",      RID_ATTRIBUTE,  0 },
3273   { "__attribute__",    RID_ATTRIBUTE,  0 },
3274   { "__bounded",        RID_BOUNDED,    0 },
3275   { "__bounded__",      RID_BOUNDED,    0 },
3276   { "__builtin_va_arg", RID_VA_ARG,     0 },
3277   { "__complex",        RID_COMPLEX,    0 },
3278   { "__complex__",      RID_COMPLEX,    0 },
3279   { "__const",          RID_CONST,      0 },
3280   { "__const__",        RID_CONST,      0 },
3281   { "__extension__",    RID_EXTENSION,  0 },
3282   { "__func__",         RID_C99_FUNCTION_NAME, 0 },
3283   { "__imag",           RID_IMAGPART,   0 },
3284   { "__imag__",         RID_IMAGPART,   0 },
3285   { "__inline",         RID_INLINE,     0 },
3286   { "__inline__",       RID_INLINE,     0 },
3287   { "__label__",        RID_LABEL,      0 },
3288   { "__ptrbase",        RID_PTRBASE,    0 },
3289   { "__ptrbase__",      RID_PTRBASE,    0 },
3290   { "__ptrextent",      RID_PTREXTENT,  0 },
3291   { "__ptrextent__",    RID_PTREXTENT,  0 },
3292   { "__ptrvalue",       RID_PTRVALUE,   0 },
3293   { "__ptrvalue__",     RID_PTRVALUE,   0 },
3294   { "__real",           RID_REALPART,   0 },
3295   { "__real__",         RID_REALPART,   0 },
3296   { "__restrict",       RID_RESTRICT,   0 },
3297   { "__restrict__",     RID_RESTRICT,   0 },
3298   { "__signed",         RID_SIGNED,     0 },
3299   { "__signed__",       RID_SIGNED,     0 },
3300   { "__typeof",         RID_TYPEOF,     0 },
3301   { "__typeof__",       RID_TYPEOF,     0 },
3302   { "__unbounded",      RID_UNBOUNDED,  0 },
3303   { "__unbounded__",    RID_UNBOUNDED,  0 },
3304   { "__volatile",       RID_VOLATILE,   0 },
3305   { "__volatile__",     RID_VOLATILE,   0 },
3306   { "asm",              RID_ASM,        D_EXT },
3307   { "auto",             RID_AUTO,       0 },
3308   { "break",            RID_BREAK,      0 },
3309   { "case",             RID_CASE,       0 },
3310   { "char",             RID_CHAR,       0 },
3311   { "const",            RID_CONST,      D_TRAD },
3312   { "continue",         RID_CONTINUE,   0 },
3313   { "default",          RID_DEFAULT,    0 },
3314   { "do",               RID_DO,         0 },
3315   { "double",           RID_DOUBLE,     0 },
3316   { "else",             RID_ELSE,       0 },
3317   { "enum",             RID_ENUM,       0 },
3318   { "extern",           RID_EXTERN,     0 },
3319   { "float",            RID_FLOAT,      0 },
3320   { "for",              RID_FOR,        0 },
3321   { "goto",             RID_GOTO,       0 },
3322   { "if",               RID_IF,         0 },
3323   { "inline",           RID_INLINE,     D_TRAD|D_EXT89 },
3324   { "int",              RID_INT,        0 },
3325   { "long",             RID_LONG,       0 },
3326   { "register",         RID_REGISTER,   0 },
3327   { "restrict",         RID_RESTRICT,   D_TRAD|D_C89 },
3328   { "return",           RID_RETURN,     0 },
3329   { "short",            RID_SHORT,      0 },
3330   { "signed",           RID_SIGNED,     D_TRAD },
3331   { "sizeof",           RID_SIZEOF,     0 },
3332   { "static",           RID_STATIC,     0 },
3333   { "struct",           RID_STRUCT,     0 },
3334   { "switch",           RID_SWITCH,     0 },
3335   { "typedef",          RID_TYPEDEF,    0 },
3336   { "typeof",           RID_TYPEOF,     D_TRAD|D_EXT },
3337   { "union",            RID_UNION,      0 },
3338   { "unsigned",         RID_UNSIGNED,   0 },
3339   { "void",             RID_VOID,       0 },
3340   { "volatile",         RID_VOLATILE,   D_TRAD },
3341   { "while",            RID_WHILE,      0 },
3342 ifobjc
3343   { "id",               RID_ID,                 D_OBJC },
3344
3345   /* These objc keywords are recognized only immediately after
3346      an '@'.  */
3347   { "class",            RID_AT_CLASS,           D_OBJC },
3348   { "compatibility_alias", RID_AT_ALIAS,        D_OBJC },
3349   { "defs",             RID_AT_DEFS,            D_OBJC },
3350   { "encode",           RID_AT_ENCODE,          D_OBJC },
3351   { "end",              RID_AT_END,             D_OBJC },
3352   { "implementation",   RID_AT_IMPLEMENTATION,  D_OBJC },
3353   { "interface",        RID_AT_INTERFACE,       D_OBJC },
3354   { "private",          RID_AT_PRIVATE,         D_OBJC },
3355   { "protected",        RID_AT_PROTECTED,       D_OBJC },
3356   { "protocol",         RID_AT_PROTOCOL,        D_OBJC },
3357   { "public",           RID_AT_PUBLIC,          D_OBJC },
3358   { "selector",         RID_AT_SELECTOR,        D_OBJC },
3359
3360   /* These are recognized only in protocol-qualifier context
3361      (see above) */
3362   { "bycopy",           RID_BYCOPY,             D_OBJC },
3363   { "byref",            RID_BYREF,              D_OBJC },
3364   { "in",               RID_IN,                 D_OBJC },
3365   { "inout",            RID_INOUT,              D_OBJC },
3366   { "oneway",           RID_ONEWAY,             D_OBJC },
3367   { "out",              RID_OUT,                D_OBJC },
3368 end ifobjc
3369 };
3370 #define N_reswords (sizeof reswords / sizeof (struct resword))
3371
3372 /* Table mapping from RID_* constants to yacc token numbers.
3373    Unfortunately we have to have entries for all the keywords in all
3374    three languages.  */
3375 static const short rid_to_yy[RID_MAX] =
3376 {
3377   /* RID_STATIC */      SCSPEC,
3378   /* RID_UNSIGNED */    TYPESPEC,
3379   /* RID_LONG */        TYPESPEC,
3380   /* RID_CONST */       TYPE_QUAL,
3381   /* RID_EXTERN */      SCSPEC,
3382   /* RID_REGISTER */    SCSPEC,
3383   /* RID_TYPEDEF */     SCSPEC,
3384   /* RID_SHORT */       TYPESPEC,
3385   /* RID_INLINE */      SCSPEC,
3386   /* RID_VOLATILE */    TYPE_QUAL,
3387   /* RID_SIGNED */      TYPESPEC,
3388   /* RID_AUTO */        SCSPEC,
3389   /* RID_RESTRICT */    TYPE_QUAL,
3390
3391   /* C extensions */
3392   /* RID_BOUNDED */     TYPE_QUAL,
3393   /* RID_UNBOUNDED */   TYPE_QUAL,
3394   /* RID_COMPLEX */     TYPESPEC,
3395
3396   /* C++ */
3397   /* RID_FRIEND */      0,
3398   /* RID_VIRTUAL */     0,
3399   /* RID_EXPLICIT */    0,
3400   /* RID_EXPORT */      0,
3401   /* RID_MUTABLE */     0,
3402
3403   /* ObjC */
3404   /* RID_IN */          TYPE_QUAL,
3405   /* RID_OUT */         TYPE_QUAL,
3406   /* RID_INOUT */       TYPE_QUAL,
3407   /* RID_BYCOPY */      TYPE_QUAL,
3408   /* RID_BYREF */       TYPE_QUAL,
3409   /* RID_ONEWAY */      TYPE_QUAL,
3410
3411   /* C */
3412   /* RID_INT */         TYPESPEC,
3413   /* RID_CHAR */        TYPESPEC,
3414   /* RID_FLOAT */       TYPESPEC,
3415   /* RID_DOUBLE */      TYPESPEC,
3416   /* RID_VOID */        TYPESPEC,
3417   /* RID_ENUM */        ENUM,
3418   /* RID_STRUCT */      STRUCT,
3419   /* RID_UNION */       UNION,
3420   /* RID_IF */          IF,
3421   /* RID_ELSE */        ELSE,
3422   /* RID_WHILE */       WHILE,
3423   /* RID_DO */          DO,
3424   /* RID_FOR */         FOR,
3425   /* RID_SWITCH */      SWITCH,
3426   /* RID_CASE */        CASE,
3427   /* RID_DEFAULT */     DEFAULT,
3428   /* RID_BREAK */       BREAK,
3429   /* RID_CONTINUE */    CONTINUE,
3430   /* RID_RETURN */      RETURN,
3431   /* RID_GOTO */        GOTO,
3432   /* RID_SIZEOF */      SIZEOF,
3433
3434   /* C extensions */
3435   /* RID_ASM */         ASM_KEYWORD,
3436   /* RID_TYPEOF */      TYPEOF,
3437   /* RID_ALIGNOF */     ALIGNOF,
3438   /* RID_ATTRIBUTE */   ATTRIBUTE,
3439   /* RID_VA_ARG */      VA_ARG,
3440   /* RID_EXTENSION */   EXTENSION,
3441   /* RID_IMAGPART */    IMAGPART,
3442   /* RID_REALPART */    REALPART,
3443   /* RID_LABEL */       LABEL,
3444   /* RID_PTRBASE */     PTR_BASE,
3445   /* RID_PTREXTENT */   PTR_EXTENT,
3446   /* RID_PTRVALUE */    PTR_VALUE,
3447
3448   /* RID_FUNCTION_NAME */               STRING_FUNC_NAME,
3449   /* RID_PRETTY_FUNCTION_NAME */        STRING_FUNC_NAME,
3450   /* RID_C99_FUNCTION_NAME */           VAR_FUNC_NAME,
3451
3452   /* C++ */
3453   /* RID_BOOL */        TYPESPEC,
3454   /* RID_WCHAR */       0,
3455   /* RID_CLASS */       0,
3456   /* RID_PUBLIC */      0,
3457   /* RID_PRIVATE */     0,
3458   /* RID_PROTECTED */   0,
3459   /* RID_TEMPLATE */    0,
3460   /* RID_NULL */        0,
3461   /* RID_CATCH */       0,
3462   /* RID_DELETE */      0,
3463   /* RID_FALSE */       0,
3464   /* RID_NAMESPACE */   0,
3465   /* RID_NEW */         0,
3466   /* RID_OPERATOR */    0,
3467   /* RID_THIS */        0,
3468   /* RID_THROW */       0,
3469   /* RID_TRUE */        0,
3470   /* RID_TRY */         0,
3471   /* RID_TYPENAME */    0,
3472   /* RID_TYPEID */      0,
3473   /* RID_USING */       0,
3474
3475   /* casts */
3476   /* RID_CONSTCAST */   0,
3477   /* RID_DYNCAST */     0,
3478   /* RID_REINTCAST */   0,
3479   /* RID_STATCAST */    0,
3480
3481   /* alternate spellings */
3482   /* RID_AND */         0,
3483   /* RID_AND_EQ */      0,
3484   /* RID_NOT */         0,
3485   /* RID_NOT_EQ */      0,
3486   /* RID_OR */          0,
3487   /* RID_OR_EQ */       0,
3488   /* RID_XOR */         0,
3489   /* RID_XOR_EQ */      0,
3490   /* RID_BITAND */      0,
3491   /* RID_BITOR */       0,
3492   /* RID_COMPL */       0,
3493
3494   /* Objective C */
3495   /* RID_ID */                  OBJECTNAME,
3496   /* RID_AT_ENCODE */           ENCODE,
3497   /* RID_AT_END */              END,
3498   /* RID_AT_CLASS */            CLASS,
3499   /* RID_AT_ALIAS */            ALIAS,
3500   /* RID_AT_DEFS */             DEFS,
3501   /* RID_AT_PRIVATE */          PRIVATE,
3502   /* RID_AT_PROTECTED */        PROTECTED,
3503   /* RID_AT_PUBLIC */           PUBLIC,
3504   /* RID_AT_PROTOCOL */         PROTOCOL,
3505   /* RID_AT_SELECTOR */         SELECTOR,
3506   /* RID_AT_INTERFACE */        INTERFACE,
3507   /* RID_AT_IMPLEMENTATION */   IMPLEMENTATION
3508 };
3509
3510 static void
3511 init_reswords ()
3512 {
3513   unsigned int i;
3514   tree id;
3515   int mask = (flag_isoc99 ? 0 : D_C89)
3516               | (flag_traditional ? D_TRAD : 0)
3517               | (flag_no_asm ? (flag_isoc99 ? D_EXT : D_EXT|D_EXT89) : 0);
3518
3519   if (c_language != clk_objective_c)
3520      mask |= D_OBJC;
3521
3522   /* It is not necessary to register ridpointers as a GC root, because
3523      all the trees it points to are permanently interned in the
3524      get_identifier hash anyway.  */
3525   ridpointers = (tree *) xcalloc ((int) RID_MAX, sizeof (tree));
3526   for (i = 0; i < N_reswords; i++)
3527     {
3528       /* If a keyword is disabled, do not enter it into the table
3529          and so create a canonical spelling that isn't a keyword.  */
3530       if (reswords[i].disable & mask)
3531         continue;
3532
3533       id = get_identifier (reswords[i].word);
3534       C_RID_CODE (id) = reswords[i].rid;
3535       C_IS_RESERVED_WORD (id) = 1;
3536       ridpointers [(int) reswords[i].rid] = id;
3537     }
3538 }
3539
3540 const char *
3541 init_parse (filename)
3542      const char *filename;
3543 {
3544   add_c_tree_codes ();
3545
3546   /* Make identifier nodes long enough for the language-specific slots.  */
3547   set_identifier_size (sizeof (struct lang_identifier));
3548
3549   init_reswords ();
3550   init_pragma ();
3551
3552   return init_c_lex (filename);
3553 }
3554
3555 void
3556 finish_parse ()
3557 {
3558   cpp_finish (parse_in);
3559   /* Call to cpp_destroy () omitted for performance reasons.  */
3560   errorcount += cpp_errors (parse_in);
3561 }
3562
3563 #define NAME(type) cpp_type2name (type)
3564
3565 static void
3566 yyerror (msgid)
3567      const char *msgid;
3568 {
3569   const char *string = _(msgid);
3570
3571   if (last_token == CPP_EOF)
3572     error ("%s at end of input", string);
3573   else if (last_token == CPP_CHAR || last_token == CPP_WCHAR)
3574     {
3575       unsigned int val = TREE_INT_CST_LOW (yylval.ttype);
3576       const char *const ell = (last_token == CPP_CHAR) ? "" : "L";
3577       if (val <= UCHAR_MAX && ISGRAPH (val))
3578         error ("%s before %s'%c'", string, ell, val);
3579       else
3580         error ("%s before %s'\\x%x'", string, ell, val);
3581     }
3582   else if (last_token == CPP_STRING
3583            || last_token == CPP_WSTRING)
3584     error ("%s before string constant", string);
3585   else if (last_token == CPP_NUMBER)
3586     error ("%s before numeric constant", string);
3587   else if (last_token == CPP_NAME)
3588     error ("%s before \"%s\"", string, IDENTIFIER_POINTER (yylval.ttype));
3589   else
3590     error ("%s before '%s' token", string, NAME(last_token));
3591 }
3592
3593 static int
3594 yylexname ()
3595 {
3596   tree decl;
3597
3598 ifobjc
3599   int objc_force_identifier = objc_need_raw_identifier;
3600   OBJC_NEED_RAW_IDENTIFIER (0);
3601 end ifobjc
3602
3603   if (C_IS_RESERVED_WORD (yylval.ttype))
3604     {
3605       enum rid rid_code = C_RID_CODE (yylval.ttype);
3606
3607 ifobjc
3608       /* Turn non-typedefed refs to "id" into plain identifiers; this
3609          allows constructs like "void foo(id id);" to work.  */
3610       if (rid_code == RID_ID)
3611       {
3612         decl = lookup_name (yylval.ttype);
3613         if (decl == NULL_TREE || TREE_CODE (decl) != TYPE_DECL)
3614           return IDENTIFIER;
3615       }
3616
3617       if (!OBJC_IS_AT_KEYWORD (rid_code)
3618           && (!OBJC_IS_PQ_KEYWORD (rid_code) || objc_pq_context))
3619 end ifobjc
3620       {
3621         int yycode = rid_to_yy[(int) rid_code];
3622         if (yycode == STRING_FUNC_NAME)
3623           {
3624             /* __FUNCTION__ and __PRETTY_FUNCTION__ get converted
3625                to string constants.  */
3626             const char *name = fname_string (rid_code);
3627
3628             yylval.ttype = build_string (strlen (name) + 1, name);
3629             last_token = CPP_STRING;  /* so yyerror won't choke */
3630             return STRING;
3631           }
3632
3633         /* Return the canonical spelling for this keyword.  */
3634         yylval.ttype = ridpointers[(int) rid_code];
3635         return yycode;
3636       }
3637     }
3638
3639   decl = lookup_name (yylval.ttype);
3640   if (decl)
3641     {
3642       if (TREE_CODE (decl) == TYPE_DECL)
3643         return TYPENAME;
3644     }
3645 ifobjc
3646   else
3647     {
3648       tree objc_interface_decl = is_class_name (yylval.ttype);
3649       /* ObjC class names are in the same namespace as variables and
3650          typedefs, and hence are shadowed by local declarations.  */
3651       if (objc_interface_decl
3652           && (global_bindings_p ()
3653               || (!objc_force_identifier && !decl)))
3654         {
3655           yylval.ttype = objc_interface_decl;
3656           return CLASSNAME;
3657         }
3658     }
3659 end ifobjc
3660
3661   return IDENTIFIER;
3662 }
3663
3664
3665 static inline int
3666 _yylex ()
3667 {
3668  get_next:
3669   last_token = c_lex (&yylval.ttype);
3670   switch (last_token)
3671     {
3672     case CPP_EQ:                                        return '=';
3673     case CPP_NOT:                                       return '!';
3674     case CPP_GREATER:   yylval.code = GT_EXPR;          return ARITHCOMPARE;
3675     case CPP_LESS:      yylval.code = LT_EXPR;          return ARITHCOMPARE;
3676     case CPP_PLUS:      yylval.code = PLUS_EXPR;        return '+';
3677     case CPP_MINUS:     yylval.code = MINUS_EXPR;       return '-';
3678     case CPP_MULT:      yylval.code = MULT_EXPR;        return '*';
3679     case CPP_DIV:       yylval.code = TRUNC_DIV_EXPR;   return '/';
3680     case CPP_MOD:       yylval.code = TRUNC_MOD_EXPR;   return '%';
3681     case CPP_AND:       yylval.code = BIT_AND_EXPR;     return '&';
3682     case CPP_OR:        yylval.code = BIT_IOR_EXPR;     return '|';
3683     case CPP_XOR:       yylval.code = BIT_XOR_EXPR;     return '^';
3684     case CPP_RSHIFT:    yylval.code = RSHIFT_EXPR;      return RSHIFT;
3685     case CPP_LSHIFT:    yylval.code = LSHIFT_EXPR;      return LSHIFT;
3686
3687     case CPP_COMPL:                                     return '~';
3688     case CPP_AND_AND:                                   return ANDAND;
3689     case CPP_OR_OR:                                     return OROR;
3690     case CPP_QUERY:                                     return '?';
3691     case CPP_OPEN_PAREN:                                return '(';
3692     case CPP_EQ_EQ:     yylval.code = EQ_EXPR;          return EQCOMPARE;
3693     case CPP_NOT_EQ:    yylval.code = NE_EXPR;          return EQCOMPARE;
3694     case CPP_GREATER_EQ:yylval.code = GE_EXPR;          return ARITHCOMPARE;
3695     case CPP_LESS_EQ:   yylval.code = LE_EXPR;          return ARITHCOMPARE;
3696
3697     case CPP_PLUS_EQ:   yylval.code = PLUS_EXPR;        return ASSIGN;
3698     case CPP_MINUS_EQ:  yylval.code = MINUS_EXPR;       return ASSIGN;
3699     case CPP_MULT_EQ:   yylval.code = MULT_EXPR;        return ASSIGN;
3700     case CPP_DIV_EQ:    yylval.code = TRUNC_DIV_EXPR;   return ASSIGN;
3701     case CPP_MOD_EQ:    yylval.code = TRUNC_MOD_EXPR;   return ASSIGN;
3702     case CPP_AND_EQ:    yylval.code = BIT_AND_EXPR;     return ASSIGN;
3703     case CPP_OR_EQ:     yylval.code = BIT_IOR_EXPR;     return ASSIGN;
3704     case CPP_XOR_EQ:    yylval.code = BIT_XOR_EXPR;     return ASSIGN;
3705     case CPP_RSHIFT_EQ: yylval.code = RSHIFT_EXPR;      return ASSIGN;
3706     case CPP_LSHIFT_EQ: yylval.code = LSHIFT_EXPR;      return ASSIGN;
3707
3708     case CPP_OPEN_SQUARE:                               return '[';
3709     case CPP_CLOSE_SQUARE:                              return ']';
3710     case CPP_OPEN_BRACE:                                return '{';
3711     case CPP_CLOSE_BRACE:                               return '}';
3712     case CPP_ELLIPSIS:                                  return ELLIPSIS;
3713
3714     case CPP_PLUS_PLUS:                                 return PLUSPLUS;
3715     case CPP_MINUS_MINUS:                               return MINUSMINUS;
3716     case CPP_DEREF:                                     return POINTSAT;
3717     case CPP_DOT:                                       return '.';
3718
3719       /* The following tokens may affect the interpretation of any
3720          identifiers following, if doing Objective-C.  */
3721     case CPP_COLON:             OBJC_NEED_RAW_IDENTIFIER (0);   return ':';
3722     case CPP_COMMA:             OBJC_NEED_RAW_IDENTIFIER (0);   return ',';
3723     case CPP_CLOSE_PAREN:       OBJC_NEED_RAW_IDENTIFIER (0);   return ')';
3724     case CPP_SEMICOLON:         OBJC_NEED_RAW_IDENTIFIER (0);   return ';';
3725
3726     case CPP_EOF:
3727       return 0;
3728
3729     case CPP_NAME:
3730       return yylexname ();
3731
3732     case CPP_NUMBER:
3733     case CPP_CHAR:
3734     case CPP_WCHAR:
3735       return CONSTANT;
3736
3737     case CPP_STRING:
3738     case CPP_WSTRING:
3739       return STRING;
3740
3741       /* This token is Objective-C specific.  It gives the next token
3742          special significance.  */
3743     case CPP_ATSIGN:
3744 ifobjc
3745       {
3746         tree after_at;
3747         enum cpp_ttype after_at_type;
3748
3749         after_at_type = c_lex (&after_at);
3750
3751         if (after_at_type == CPP_NAME
3752             && C_IS_RESERVED_WORD (after_at)
3753             && OBJC_IS_AT_KEYWORD (C_RID_CODE (after_at)))
3754           {
3755             yylval.ttype = after_at;
3756             last_token = after_at_type;
3757             return rid_to_yy [(int) C_RID_CODE (after_at)];
3758           }
3759         _cpp_backup_tokens (parse_in, 1);
3760         return '@';
3761       }
3762 end ifobjc
3763
3764       /* These tokens are C++ specific (and will not be generated
3765          in C mode, but let's be cautious).  */
3766     case CPP_SCOPE:
3767     case CPP_DEREF_STAR:
3768     case CPP_DOT_STAR:
3769     case CPP_MIN_EQ:
3770     case CPP_MAX_EQ:
3771     case CPP_MIN:
3772     case CPP_MAX:
3773       /* These tokens should not survive translation phase 4.  */
3774     case CPP_HASH:
3775     case CPP_PASTE:
3776       error ("syntax error at '%s' token", NAME(last_token));
3777       goto get_next;
3778
3779     default:
3780       abort ();
3781     }
3782   /* NOTREACHED */
3783 }
3784
3785 static int
3786 yylex()
3787 {
3788   int r;
3789   timevar_push (TV_LEX);
3790   r = _yylex();
3791   timevar_pop (TV_LEX);
3792   return r;
3793 }
3794
3795 /* Sets the value of the 'yydebug' variable to VALUE.
3796    This is a function so we don't have to have YYDEBUG defined
3797    in order to build the compiler.  */
3798
3799 void
3800 set_yydebug (value)
3801      int value;
3802 {
3803 #if YYDEBUG != 0
3804   yydebug = value;
3805 #else
3806   warning ("YYDEBUG not defined.");
3807 #endif
3808 }
3809
3810 /* Function used when yydebug is set, to print a token in more detail.  */
3811
3812 static void
3813 yyprint (file, yychar, yyl)
3814      FILE *file;
3815      int yychar;
3816      YYSTYPE yyl;
3817 {
3818   tree t = yyl.ttype;
3819
3820   fprintf (file, " [%s]", NAME(last_token));
3821
3822   switch (yychar)
3823     {
3824     case IDENTIFIER:
3825     case TYPENAME:
3826     case OBJECTNAME:
3827     case TYPESPEC:
3828     case TYPE_QUAL:
3829     case SCSPEC:
3830       if (IDENTIFIER_POINTER (t))
3831         fprintf (file, " `%s'", IDENTIFIER_POINTER (t));
3832       break;
3833
3834     case CONSTANT:
3835       fprintf (file, " %s", GET_MODE_NAME (TYPE_MODE (TREE_TYPE (t))));
3836       if (TREE_CODE (t) == INTEGER_CST)
3837         fprintf (file,
3838 #if HOST_BITS_PER_WIDE_INT == 64
3839 #if HOST_BITS_PER_WIDE_INT == HOST_BITS_PER_INT
3840                  " 0x%x%016x",
3841 #else
3842 #if HOST_BITS_PER_WIDE_INT == HOST_BITS_PER_LONG
3843                  " 0x%lx%016lx",
3844 #else
3845                  " 0x%llx%016llx",
3846 #endif
3847 #endif
3848 #else
3849 #if HOST_BITS_PER_WIDE_INT != HOST_BITS_PER_INT
3850                  " 0x%lx%08lx",
3851 #else
3852                  " 0x%x%08x",
3853 #endif
3854 #endif
3855                  TREE_INT_CST_HIGH (t), TREE_INT_CST_LOW (t));
3856       break;
3857     }
3858 }
3859 \f
3860 /* This is not the ideal place to put these, but we have to get them out
3861    of c-lex.c because cp/lex.c has its own versions.  */
3862
3863 /* Return something to represent absolute declarators containing a *.
3864    TARGET is the absolute declarator that the * contains.
3865    TYPE_QUALS_ATTRS is a list of modifiers such as const or volatile
3866    to apply to the pointer type, represented as identifiers, possible mixed
3867    with attributes.
3868
3869    We return an INDIRECT_REF whose "contents" are TARGET (inside a TREE_LIST,
3870    if attributes are present) and whose type is the modifier list.  */
3871
3872 tree
3873 make_pointer_declarator (type_quals_attrs, target)
3874      tree type_quals_attrs, target;
3875 {
3876   tree quals, attrs;
3877   tree itarget = target;
3878   split_specs_attrs (type_quals_attrs, &quals, &attrs);
3879   if (attrs != NULL_TREE)
3880     itarget = tree_cons (attrs, target, NULL_TREE);
3881   return build1 (INDIRECT_REF, quals, itarget);
3882 }