gcc/c-parse.in

   1 /* YACC parser for C syntax and for Objective C.  -*-c-*-
   2    Copyright (C) 1987, 1988, 1989, 1992, 1993, 1994, 1995, 1996,
   3    1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 This file is part of GCC.
   6
   7 GCC is free software; you can redistribute it and/or modify it under
   8 the terms of the GNU General Public License as published by the Free
   9 Software Foundation; either version 2, or (at your option) any later
  10 version.
  11
  12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GCC; see the file COPYING.  If not, write to the Free
  19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 02111-1307, USA.  */
  21
  22 /* This file defines the grammar of C and that of Objective C.
  23    ifobjc ... end ifobjc  conditionals contain code for Objective C only.
  24    ifc ... end ifc  conditionals contain code for C only.
  25    Sed commands in Makefile.in are used to convert this file into
  26    c-parse.y and into objc-parse.y.  */
  27
  28 /* To whomever it may concern: I have heard that such a thing was once
  29    written by AT&T, but I have never seen it.  */
  30
  31 ifobjc
  32 %expect 31 /* shift/reduce conflicts, and 1 reduce/reduce conflict.  */
  33 end ifobjc
  34 ifc
  35 %expect 10 /* shift/reduce conflicts, and no reduce/reduce conflicts.  */
  36 end ifc
  37
  38 %{
  39 #include "config.h"
  40 #include "system.h"
  41 #include "tree.h"
  42 #include "input.h"
  43 #include "cpplib.h"
  44 #include "intl.h"
  45 #include "timevar.h"
  46 #include "c-lex.h"
  47 #include "c-tree.h"
  48 #include "c-pragma.h"
  49 #include "flags.h"
  50 #include "output.h"
  51 #include "toplev.h"
  52 #include "ggc.h"
  53
  54 #ifdef MULTIBYTE_CHARS
  55 #include <locale.h>
  56 #endif
  57
  58 ifobjc
  59 #include "objc-act.h"
  60 end ifobjc
  61
  62 /* Like YYERROR but do call yyerror.  */
  63 #define YYERROR1 { yyerror ("syntax error"); YYERROR; }
  64
  65 /* Cause the "yydebug" variable to be defined.  */
  66 #define YYDEBUG 1
  67
  68 /* Rename the "yyparse" function so that we can override it elsewhere.  */
  69 #define yyparse yyparse_1
  70 %}
  71
  72 %start program
  73
  74 %union {long itype; tree ttype; enum tree_code code;
  75         const char *filename; int lineno; }
  76
  77 /* All identifiers that are not reserved words
  78    and are not declared typedefs in the current block */
  79 %token IDENTIFIER
  80
  81 /* All identifiers that are declared typedefs in the current block.
  82    In some contexts, they are treated just like IDENTIFIER,
  83    but they can also serve as typespecs in declarations.  */
  84 %token TYPENAME
  85
  86 /* Reserved words that specify storage class.
  87    yylval contains an IDENTIFIER_NODE which indicates which one.  */
  88 %token SCSPEC
  89
  90 /* Reserved words that specify type.
  91    yylval contains an IDENTIFIER_NODE which indicates which one.  */
  92 %token TYPESPEC
  93
  94 /* Reserved words that qualify type: "const", "volatile", or "restrict".
  95    yylval contains an IDENTIFIER_NODE which indicates which one.  */
  96 %token TYPE_QUAL
  97
  98 /* Character or numeric constants.
  99    yylval is the node for the constant.  */
 100 %token CONSTANT
 101
 102 /* String constants in raw form.
 103    yylval is a STRING_CST node.  */
 104 %token STRING
 105
 106 /* "...", used for functions with variable arglists.  */
 107 %token ELLIPSIS
 108
 109 /* the reserved words */
 110 /* SCO include files test "ASM", so use something else. */
 111 %token SIZEOF ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
 112 %token BREAK CONTINUE RETURN GOTO ASM_KEYWORD TYPEOF ALIGNOF
 113 %token ATTRIBUTE EXTENSION LABEL
 114 %token REALPART IMAGPART VA_ARG CHOOSE_EXPR TYPES_COMPATIBLE_P
 115 %token PTR_VALUE PTR_BASE PTR_EXTENT
 116
 117 /* function name can be a string const or a var decl. */
 118 %token STRING_FUNC_NAME VAR_FUNC_NAME
 119
 120 /* Add precedence rules to solve dangling else s/r conflict */
 121 %nonassoc IF
 122 %nonassoc ELSE
 123
 124 /* Define the operator tokens and their precedences.
 125    The value is an integer because, if used, it is the tree code
 126    to use in the expression made from the operator.  */
 127
 128 %right <code> ASSIGN '='
 129 %right <code> '?' ':'
 130 %left <code> OROR
 131 %left <code> ANDAND
 132 %left <code> '|'
 133 %left <code> '^'
 134 %left <code> '&'
 135 %left <code> EQCOMPARE
 136 %left <code> ARITHCOMPARE
 137 %left <code> LSHIFT RSHIFT
 138 %left <code> '+' '-'
 139 %left <code> '*' '/' '%'
 140 %right <code> UNARY PLUSPLUS MINUSMINUS
 141 %left HYPERUNARY
 142 %left <code> POINTSAT '.' '(' '['
 143
 144 /* The Objective-C keywords.  These are included in C and in
 145    Objective C, so that the token codes are the same in both.  */
 146 %token INTERFACE IMPLEMENTATION END SELECTOR DEFS ENCODE
 147 %token CLASSNAME PUBLIC PRIVATE PROTECTED PROTOCOL OBJECTNAME CLASS ALIAS
 148
 149 %type <code> unop
 150 %type <ttype> ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
 151 %type <ttype> BREAK CONTINUE RETURN GOTO ASM_KEYWORD SIZEOF TYPEOF ALIGNOF
 152
 153 %type <ttype> identifier IDENTIFIER TYPENAME CONSTANT expr nonnull_exprlist exprlist
 154 %type <ttype> expr_no_commas cast_expr unary_expr primary string STRING
 155 %type <ttype> declspecs_nosc_nots_nosa_noea declspecs_nosc_nots_nosa_ea
 156 %type <ttype> declspecs_nosc_nots_sa_noea declspecs_nosc_nots_sa_ea
 157 %type <ttype> declspecs_nosc_ts_nosa_noea declspecs_nosc_ts_nosa_ea
 158 %type <ttype> declspecs_nosc_ts_sa_noea declspecs_nosc_ts_sa_ea
 159 %type <ttype> declspecs_sc_nots_nosa_noea declspecs_sc_nots_nosa_ea
 160 %type <ttype> declspecs_sc_nots_sa_noea declspecs_sc_nots_sa_ea
 161 %type <ttype> declspecs_sc_ts_nosa_noea declspecs_sc_ts_nosa_ea
 162 %type <ttype> declspecs_sc_ts_sa_noea declspecs_sc_ts_sa_ea
 163 %type <ttype> declspecs_ts declspecs_nots
 164 %type <ttype> declspecs_ts_nosa declspecs_nots_nosa
 165 %type <ttype> declspecs_nosc_ts declspecs_nosc_nots declspecs_nosc declspecs
 166 %type <ttype> maybe_type_quals_attrs typespec_nonattr typespec_attr
 167 %type <ttype> typespec_reserved_nonattr typespec_reserved_attr
 168 %type <ttype> typespec_nonreserved_nonattr
 169
 170 %type <ttype> SCSPEC TYPESPEC TYPE_QUAL maybe_type_qual
 171 %type <ttype> initdecls notype_initdecls initdcl notype_initdcl
 172 %type <ttype> init maybeasm
 173 %type <ttype> asm_operands nonnull_asm_operands asm_operand asm_clobbers
 174 %type <ttype> maybe_attribute attributes attribute attribute_list attrib
 175 %type <ttype> any_word extension
 176
 177 %type <ttype> compstmt compstmt_start compstmt_nostart compstmt_primary_start
 178 %type <ttype> do_stmt_start poplevel stmt label
 179
 180 %type <ttype> c99_block_start c99_block_end
 181 %type <ttype> declarator
 182 %type <ttype> notype_declarator after_type_declarator
 183 %type <ttype> parm_declarator
 184 %type <ttype> parm_declarator_starttypename parm_declarator_nostarttypename
 185 %type <ttype> array_declarator
 186
 187 %type <ttype> structsp_attr structsp_nonattr
 188 %type <ttype> component_decl_list component_decl_list2
 189 %type <ttype> component_decl components components_notype component_declarator
 190 %type <ttype> component_notype_declarator
 191 %type <ttype> enumlist enumerator
 192 %type <ttype> struct_head union_head enum_head
 193 %type <ttype> typename absdcl absdcl1 absdcl1_ea absdcl1_noea
 194 %type <ttype> direct_absdcl1 absdcl_maybe_attribute
 195 %type <ttype> xexpr parms parm firstparm identifiers
 196
 197 %type <ttype> parmlist parmlist_1 parmlist_2
 198 %type <ttype> parmlist_or_identifiers parmlist_or_identifiers_1
 199 %type <ttype> identifiers_or_typenames
 200
 201 %type <itype> setspecs setspecs_fp
 202
 203 %type <filename> save_filename
 204 %type <lineno> save_lineno
 205 \f
 206 ifobjc
 207 /* the Objective-C nonterminals */
 208
 209 %type <ttype> ivar_decl_list ivar_decls ivar_decl ivars ivar_declarator
 210 %type <ttype> methoddecl unaryselector keywordselector selector
 211 %type <ttype> keyworddecl receiver objcmessageexpr messageargs
 212 %type <ttype> keywordexpr keywordarglist keywordarg
 213 %type <ttype> myparms myparm optparmlist reservedwords objcselectorexpr
 214 %type <ttype> selectorarg keywordnamelist keywordname objcencodeexpr
 215 %type <ttype> objc_string non_empty_protocolrefs protocolrefs identifier_list objcprotocolexpr
 216
 217 %type <ttype> CLASSNAME OBJECTNAME
 218 end ifobjc
 219 \f
 220 %{
 221 /* Number of statements (loosely speaking) and compound statements
 222    seen so far.  */
 223 static int stmt_count;
 224 static int compstmt_count;
 225
 226 /* Input file and line number of the end of the body of last simple_if;
 227    used by the stmt-rule immediately after simple_if returns.  */
 228 static const char *if_stmt_file;
 229 static int if_stmt_line;
 230
 231 /* List of types and structure classes of the current declaration.  */
 232 static tree current_declspecs = NULL_TREE;
 233 static tree prefix_attributes = NULL_TREE;
 234
 235 /* List of all the attributes applying to the identifier currently being
 236    declared; includes prefix_attributes and possibly some more attributes
 237    just after a comma.  */
 238 static tree all_prefix_attributes = NULL_TREE;
 239
 240 /* Stack of saved values of current_declspecs, prefix_attributes and
 241    all_prefix_attributes.  */
 242 static tree declspec_stack;
 243
 244 /* PUSH_DECLSPEC_STACK is called from setspecs; POP_DECLSPEC_STACK
 245    should be called from the productions making use of setspecs.  */
 246 #define PUSH_DECLSPEC_STACK                                              \
 247   do {                                                                   \
 248     declspec_stack = tree_cons (build_tree_list (prefix_attributes,      \
 249                                                  all_prefix_attributes), \
 250                                 current_declspecs,                       \
 251                                 declspec_stack);                         \
 252   } while (0)
 253
 254 #define POP_DECLSPEC_STACK                                              \
 255   do {                                                                  \
 256     current_declspecs = TREE_VALUE (declspec_stack);                    \
 257     prefix_attributes = TREE_PURPOSE (TREE_PURPOSE (declspec_stack));   \
 258     all_prefix_attributes = TREE_VALUE (TREE_PURPOSE (declspec_stack)); \
 259     declspec_stack = TREE_CHAIN (declspec_stack);                       \
 260   } while (0)
 261
 262 /* For __extension__, save/restore the warning flags which are
 263    controlled by __extension__.  */
 264 #define SAVE_WARN_FLAGS()                       \
 265         size_int (pedantic                      \
 266                   | (warn_pointer_arith << 1)   \
 267                   | (warn_traditional << 2))
 268
 269 #define RESTORE_WARN_FLAGS(tval)                \
 270   do {                                          \
 271     int val = tree_low_cst (tval, 0);           \
 272     pedantic = val & 1;                         \
 273     warn_pointer_arith = (val >> 1) & 1;        \
 274     warn_traditional = (val >> 2) & 1;          \
 275   } while (0)
 276
 277 ifobjc
 278 /* Objective-C specific parser/lexer information */
 279
 280 static enum tree_code objc_inherit_code;
 281 static int objc_pq_context = 0, objc_public_flag = 0;
 282
 283 /* The following flag is needed to contextualize ObjC lexical analysis.
 284    In some cases (e.g., 'int NSObject;'), it is undesirable to bind
 285    an identifier to an ObjC class, even if a class with that name
 286    exists.  */
 287 static int objc_need_raw_identifier;
 288 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   objc_need_raw_identifier = VAL
 289 end ifobjc
 290
 291 ifc
 292 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   /* nothing */
 293 end ifc
 294
 295 /* Tell yyparse how to print a token's value, if yydebug is set.  */
 296
 297 #define YYPRINT(FILE,YYCHAR,YYLVAL) yyprint(FILE,YYCHAR,YYLVAL)
 298
 299 static void yyprint       PARAMS ((FILE *, int, YYSTYPE));
 300 static void yyerror       PARAMS ((const char *));
 301 static int yylexname      PARAMS ((void));
 302 static inline int _yylex  PARAMS ((void));
 303 static int  yylex         PARAMS ((void));
 304 static void init_reswords PARAMS ((void));
 305
 306 /* Add GC roots for variables local to this file.  */
 307 void
 308 c_parse_init ()
 309 {
 310   init_reswords ();
 311
 312   ggc_add_tree_root (&declspec_stack, 1);
 313   ggc_add_tree_root (&current_declspecs, 1);
 314   ggc_add_tree_root (&prefix_attributes, 1);
 315   ggc_add_tree_root (&all_prefix_attributes, 1);
 316 }
 317
 318 %}
 319 \f
 320 %%
 321 program: /* empty */
 322                 { if (pedantic)
 323                     pedwarn ("ISO C forbids an empty source file");
 324                   finish_file ();
 325                 }
 326         | extdefs
 327                 {
 328                   /* In case there were missing closebraces,
 329                      get us back to the global binding level.  */
 330                   while (! global_bindings_p ())
 331                     poplevel (0, 0, 0);
 332 ifc
 333                   finish_fname_decls ();
 334 end ifc
 335                   finish_file ();
 336                 }
 337         ;
 338
 339 /* the reason for the strange actions in this rule
 340  is so that notype_initdecls when reached via datadef
 341  can find a valid list of type and sc specs in $0. */
 342
 343 extdefs:
 344         {$<ttype>$ = NULL_TREE; } extdef
 345         | extdefs {$<ttype>$ = NULL_TREE; ggc_collect(); } extdef
 346         ;
 347
 348 extdef:
 349         fndef
 350         | datadef
 351 ifobjc
 352         | objcdef
 353 end ifobjc
 354         | ASM_KEYWORD '(' expr ')' ';'
 355                 { STRIP_NOPS ($3);
 356                   if ((TREE_CODE ($3) == ADDR_EXPR
 357                        && TREE_CODE (TREE_OPERAND ($3, 0)) == STRING_CST)
 358                       || TREE_CODE ($3) == STRING_CST)
 359                     assemble_asm ($3);
 360                   else
 361                     error ("argument of `asm' is not a constant string"); }
 362         | extension extdef
 363                 { RESTORE_WARN_FLAGS ($1); }
 364         ;
 365
 366 datadef:
 367           setspecs notype_initdecls ';'
 368                 { if (pedantic)
 369                     error ("ISO C forbids data definition with no type or storage class");
 370                   else if (!flag_traditional)
 371                     warning ("data definition has no type or storage class");
 372
 373                   POP_DECLSPEC_STACK; }
 374         | declspecs_nots setspecs notype_initdecls ';'
 375                 { POP_DECLSPEC_STACK; }
 376         | declspecs_ts setspecs initdecls ';'
 377                 { POP_DECLSPEC_STACK; }
 378         | declspecs ';'
 379           { shadow_tag ($1); }
 380         | error ';'
 381         | error '}'
 382         | ';'
 383                 { if (pedantic)
 384                     pedwarn ("ISO C does not allow extra `;' outside of a function"); }
 385         ;
 386 \f
 387 fndef:
 388           declspecs_ts setspecs declarator
 389                 { if (! start_function (current_declspecs, $3,
 390                                         all_prefix_attributes))
 391                     YYERROR1;
 392                 }
 393           old_style_parm_decls
 394                 { store_parm_decls (); }
 395           save_filename save_lineno compstmt_or_error
 396                 { DECL_SOURCE_FILE (current_function_decl) = $7;
 397                   DECL_SOURCE_LINE (current_function_decl) = $8;
 398                   finish_function (0);
 399                   POP_DECLSPEC_STACK; }
 400         | declspecs_ts setspecs declarator error
 401                 { POP_DECLSPEC_STACK; }
 402         | declspecs_nots setspecs notype_declarator
 403                 { if (! start_function (current_declspecs, $3,
 404                                         all_prefix_attributes))
 405                     YYERROR1;
 406                 }
 407           old_style_parm_decls
 408                 { store_parm_decls (); }
 409           save_filename save_lineno compstmt_or_error
 410                 { DECL_SOURCE_FILE (current_function_decl) = $7;
 411                   DECL_SOURCE_LINE (current_function_decl) = $8;
 412                   finish_function (0);
 413                   POP_DECLSPEC_STACK; }
 414         | declspecs_nots setspecs notype_declarator error
 415                 { POP_DECLSPEC_STACK; }
 416         | setspecs notype_declarator
 417                 { if (! start_function (NULL_TREE, $2,
 418                                         all_prefix_attributes))
 419                     YYERROR1;
 420                 }
 421           old_style_parm_decls
 422                 { store_parm_decls (); }
 423           save_filename save_lineno compstmt_or_error
 424                 { DECL_SOURCE_FILE (current_function_decl) = $6;
 425                   DECL_SOURCE_LINE (current_function_decl) = $7;
 426                   finish_function (0);
 427                   POP_DECLSPEC_STACK; }
 428         | setspecs notype_declarator error
 429                 { POP_DECLSPEC_STACK; }
 430         ;
 431
 432 identifier:
 433         IDENTIFIER
 434         | TYPENAME
 435 ifobjc
 436         | OBJECTNAME
 437         | CLASSNAME
 438 end ifobjc
 439         ;
 440
 441 unop:     '&'
 442                 { $$ = ADDR_EXPR; }
 443         | '-'
 444                 { $$ = NEGATE_EXPR; }
 445         | '+'
 446                 { $$ = CONVERT_EXPR;
 447 ifc
 448   if (warn_traditional && !in_system_header)
 449     warning ("traditional C rejects the unary plus operator");
 450 end ifc
 451                 }
 452         | PLUSPLUS
 453                 { $$ = PREINCREMENT_EXPR; }
 454         | MINUSMINUS
 455                 { $$ = PREDECREMENT_EXPR; }
 456         | '~'
 457                 { $$ = BIT_NOT_EXPR; }
 458         | '!'
 459                 { $$ = TRUTH_NOT_EXPR; }
 460         ;
 461
 462 expr:   nonnull_exprlist
 463                 { $$ = build_compound_expr ($1); }
 464         ;
 465
 466 exprlist:
 467           /* empty */
 468                 { $$ = NULL_TREE; }
 469         | nonnull_exprlist
 470         ;
 471
 472 nonnull_exprlist:
 473         expr_no_commas
 474                 { $$ = build_tree_list (NULL_TREE, $1); }
 475         | nonnull_exprlist ',' expr_no_commas
 476                 { chainon ($1, build_tree_list (NULL_TREE, $3)); }
 477         ;
 478
 479 unary_expr:
 480         primary
 481         | '*' cast_expr   %prec UNARY
 482                 { $$ = build_indirect_ref ($2, "unary *"); }
 483         /* __extension__ turns off -pedantic for following primary.  */
 484         | extension cast_expr     %prec UNARY
 485                 { $$ = $2;
 486                   RESTORE_WARN_FLAGS ($1); }
 487         | unop cast_expr  %prec UNARY
 488                 { $$ = build_unary_op ($1, $2, 0);
 489                   overflow_warning ($$); }
 490         /* Refer to the address of a label as a pointer.  */
 491         | ANDAND identifier
 492                 { $$ = finish_label_address_expr ($2); }
 493 /* This seems to be impossible on some machines, so let's turn it off.
 494    You can use __builtin_next_arg to find the anonymous stack args.
 495         | '&' ELLIPSIS
 496                 { tree types = TYPE_ARG_TYPES (TREE_TYPE (current_function_decl));
 497                   $$ = error_mark_node;
 498                   if (TREE_VALUE (tree_last (types)) == void_type_node)
 499                     error ("`&...' used in function with fixed number of arguments");
 500                   else
 501                     {
 502                       if (pedantic)
 503                         pedwarn ("ISO C forbids `&...'");
 504                       $$ = tree_last (DECL_ARGUMENTS (current_function_decl));
 505                       $$ = build_unary_op (ADDR_EXPR, $$, 0);
 506                     } }
 507 */
 508         | sizeof unary_expr  %prec UNARY
 509                 { skip_evaluation--;
 510                   if (TREE_CODE ($2) == COMPONENT_REF
 511                       && DECL_C_BIT_FIELD (TREE_OPERAND ($2, 1)))
 512                     error ("`sizeof' applied to a bit-field");
 513                   $$ = c_sizeof (TREE_TYPE ($2)); }
 514         | sizeof '(' typename ')'  %prec HYPERUNARY
 515                 { skip_evaluation--;
 516                   $$ = c_sizeof (groktypename ($3)); }
 517         | alignof unary_expr  %prec UNARY
 518                 { skip_evaluation--;
 519                   $$ = c_alignof_expr ($2); }
 520         | alignof '(' typename ')'  %prec HYPERUNARY
 521                 { skip_evaluation--;
 522                   $$ = c_alignof (groktypename ($3)); }
 523         | REALPART cast_expr %prec UNARY
 524                 { $$ = build_unary_op (REALPART_EXPR, $2, 0); }
 525         | IMAGPART cast_expr %prec UNARY
 526                 { $$ = build_unary_op (IMAGPART_EXPR, $2, 0); }
 527         ;
 528
 529 sizeof:
 530         SIZEOF { skip_evaluation++; }
 531         ;
 532
 533 alignof:
 534         ALIGNOF { skip_evaluation++; }
 535         ;
 536
 537 cast_expr:
 538         unary_expr
 539         | '(' typename ')' cast_expr  %prec UNARY
 540                 { $$ = c_cast_expr ($2, $4); }
 541         ;
 542
 543 expr_no_commas:
 544           cast_expr
 545         | expr_no_commas '+' expr_no_commas
 546                 { $$ = parser_build_binary_op ($2, $1, $3); }
 547         | expr_no_commas '-' expr_no_commas
 548                 { $$ = parser_build_binary_op ($2, $1, $3); }
 549         | expr_no_commas '*' expr_no_commas
 550                 { $$ = parser_build_binary_op ($2, $1, $3); }
 551         | expr_no_commas '/' expr_no_commas
 552                 { $$ = parser_build_binary_op ($2, $1, $3); }
 553         | expr_no_commas '%' expr_no_commas
 554                 { $$ = parser_build_binary_op ($2, $1, $3); }
 555         | expr_no_commas LSHIFT expr_no_commas
 556                 { $$ = parser_build_binary_op ($2, $1, $3); }
 557         | expr_no_commas RSHIFT expr_no_commas
 558                 { $$ = parser_build_binary_op ($2, $1, $3); }
 559         | expr_no_commas ARITHCOMPARE expr_no_commas
 560                 { $$ = parser_build_binary_op ($2, $1, $3); }
 561         | expr_no_commas EQCOMPARE expr_no_commas
 562                 { $$ = parser_build_binary_op ($2, $1, $3); }
 563         | expr_no_commas '&' expr_no_commas
 564                 { $$ = parser_build_binary_op ($2, $1, $3); }
 565         | expr_no_commas '|' expr_no_commas
 566                 { $$ = parser_build_binary_op ($2, $1, $3); }
 567         | expr_no_commas '^' expr_no_commas
 568                 { $$ = parser_build_binary_op ($2, $1, $3); }
 569         | expr_no_commas ANDAND
 570                 { $1 = truthvalue_conversion (default_conversion ($1));
 571                   skip_evaluation += $1 == boolean_false_node; }
 572           expr_no_commas
 573                 { skip_evaluation -= $1 == boolean_false_node;
 574                   $$ = parser_build_binary_op (TRUTH_ANDIF_EXPR, $1, $4); }
 575         | expr_no_commas OROR
 576                 { $1 = truthvalue_conversion (default_conversion ($1));
 577                   skip_evaluation += $1 == boolean_true_node; }
 578           expr_no_commas
 579                 { skip_evaluation -= $1 == boolean_true_node;
 580                   $$ = parser_build_binary_op (TRUTH_ORIF_EXPR, $1, $4); }
 581         | expr_no_commas '?'
 582                 { $1 = truthvalue_conversion (default_conversion ($1));
 583                   skip_evaluation += $1 == boolean_false_node; }
 584           expr ':'
 585                 { skip_evaluation += (($1 == boolean_true_node)
 586                                       - ($1 == boolean_false_node)); }
 587           expr_no_commas
 588                 { skip_evaluation -= $1 == boolean_true_node;
 589                   $$ = build_conditional_expr ($1, $4, $7); }
 590         | expr_no_commas '?'
 591                 { if (pedantic)
 592                     pedwarn ("ISO C forbids omitting the middle term of a ?: expression");
 593                   /* Make sure first operand is calculated only once.  */
 594                   $<ttype>2 = save_expr ($1);
 595                   $1 = truthvalue_conversion (default_conversion ($<ttype>2));
 596                   skip_evaluation += $1 == boolean_true_node; }
 597           ':' expr_no_commas
 598                 { skip_evaluation -= $1 == boolean_true_node;
 599                   $$ = build_conditional_expr ($1, $<ttype>2, $5); }
 600         | expr_no_commas '=' expr_no_commas
 601                 { char class;
 602                   $$ = build_modify_expr ($1, NOP_EXPR, $3);
 603                   class = TREE_CODE_CLASS (TREE_CODE ($$));
 604                   if (IS_EXPR_CODE_CLASS (class))
 605                     C_SET_EXP_ORIGINAL_CODE ($$, MODIFY_EXPR);
 606                 }
 607         | expr_no_commas ASSIGN expr_no_commas
 608                 { char class;
 609                   $$ = build_modify_expr ($1, $2, $3);
 610                   /* This inhibits warnings in truthvalue_conversion.  */
 611                   class = TREE_CODE_CLASS (TREE_CODE ($$));
 612                   if (IS_EXPR_CODE_CLASS (class))
 613                     C_SET_EXP_ORIGINAL_CODE ($$, ERROR_MARK);
 614                 }
 615         ;
 616
 617 primary:
 618         IDENTIFIER
 619                 {
 620                   if (yychar == YYEMPTY)
 621                     yychar = YYLEX;
 622                   $$ = build_external_ref ($1, yychar == '(');
 623                 }
 624         | CONSTANT
 625         | string
 626                 { $$ = combine_strings ($1); }
 627         | VAR_FUNC_NAME
 628                 { $$ = fname_decl (C_RID_CODE ($$), $$); }
 629         | '(' typename ')' '{'
 630                 { start_init (NULL_TREE, NULL, 0);
 631                   $2 = groktypename ($2);
 632                   really_start_incremental_init ($2); }
 633           initlist_maybe_comma '}'  %prec UNARY
 634                 { tree constructor = pop_init_level (0);
 635                   tree type = $2;
 636                   finish_init ();
 637
 638                   if (pedantic && ! flag_isoc99)
 639                     pedwarn ("ISO C89 forbids compound literals");
 640                   $$ = build_compound_literal (type, constructor);
 641                 }
 642         | '(' expr ')'
 643                 { char class = TREE_CODE_CLASS (TREE_CODE ($2));
 644                   if (IS_EXPR_CODE_CLASS (class))
 645                     C_SET_EXP_ORIGINAL_CODE ($2, ERROR_MARK);
 646                   $$ = $2; }
 647         | '(' error ')'
 648                 { $$ = error_mark_node; }
 649         | compstmt_primary_start compstmt_nostart ')'
 650                  { tree saved_last_tree;
 651
 652                    if (pedantic)
 653                      pedwarn ("ISO C forbids braced-groups within expressions");
 654                   pop_label_level ();
 655
 656                   saved_last_tree = COMPOUND_BODY ($1);
 657                   RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
 658                   last_tree = saved_last_tree;
 659                   TREE_CHAIN (last_tree) = NULL_TREE;
 660                   if (!last_expr_type)
 661                     last_expr_type = void_type_node;
 662                   $$ = build1 (STMT_EXPR, last_expr_type, $1);
 663                   TREE_SIDE_EFFECTS ($$) = 1;
 664                 }
 665         | compstmt_primary_start error ')'
 666                 {
 667                   pop_label_level ();
 668                   last_tree = COMPOUND_BODY ($1);
 669                   TREE_CHAIN (last_tree) = NULL_TREE;
 670                   $$ = error_mark_node;
 671                 }
 672         | primary '(' exprlist ')'   %prec '.'
 673                 { $$ = build_function_call ($1, $3); }
 674         | VA_ARG '(' expr_no_commas ',' typename ')'
 675                 { $$ = build_va_arg ($3, groktypename ($5)); }
 676
 677       | CHOOSE_EXPR '(' expr_no_commas ',' expr_no_commas ',' expr_no_commas ')'
 678                 {
 679                   tree c;
 680
 681                   c = fold ($3);
 682                   STRIP_NOPS (c);
 683                   if (TREE_CODE (c) != INTEGER_CST)
 684                     error ("first argument to __builtin_choose_expr not a constant");
 685                   $$ = integer_zerop (c) ? $7 : $5;
 686                 }
 687       | TYPES_COMPATIBLE_P '(' typename ',' typename ')'
 688                 {
 689                   tree e1, e2;
 690
 691                   e1 = TYPE_MAIN_VARIANT (groktypename ($3));
 692                   e2 = TYPE_MAIN_VARIANT (groktypename ($5));
 693
 694                   $$ = comptypes (e1, e2)
 695                     ? build_int_2 (1, 0) : build_int_2 (0, 0);
 696                 }
 697         | primary '[' expr ']'   %prec '.'
 698                 { $$ = build_array_ref ($1, $3); }
 699         | primary '.' identifier
 700                 {
 701 ifobjc
 702                     if (!is_public ($1, $3))
 703                       $$ = error_mark_node;
 704                     else
 705 end ifobjc
 706                       $$ = build_component_ref ($1, $3);
 707                 }
 708         | primary POINTSAT identifier
 709                 {
 710                   tree expr = build_indirect_ref ($1, "->");
 711
 712 ifobjc
 713                       if (!is_public (expr, $3))
 714                         $$ = error_mark_node;
 715                       else
 716 end ifobjc
 717                         $$ = build_component_ref (expr, $3);
 718                 }
 719         | primary PLUSPLUS
 720                 { $$ = build_unary_op (POSTINCREMENT_EXPR, $1, 0); }
 721         | primary MINUSMINUS
 722                 { $$ = build_unary_op (POSTDECREMENT_EXPR, $1, 0); }
 723 ifobjc
 724         | objcmessageexpr
 725                 { $$ = build_message_expr ($1); }
 726         | objcselectorexpr
 727                 { $$ = build_selector_expr ($1); }
 728         | objcprotocolexpr
 729                 { $$ = build_protocol_expr ($1); }
 730         | objcencodeexpr
 731                 { $$ = build_encode_expr ($1); }
 732         | objc_string
 733                 { $$ = build_objc_string_object ($1); }
 734 end ifobjc
 735         ;
 736
 737 /* Produces a STRING_CST with perhaps more STRING_CSTs chained onto it.  */
 738 string:
 739           STRING
 740         | string STRING
 741                 {
 742 ifc
 743                   static int last_lineno = 0;
 744                   static const char *last_input_filename = 0;
 745 end ifc
 746                   $$ = chainon ($1, $2);
 747 ifc
 748                   if (warn_traditional && !in_system_header
 749                       && (lineno != last_lineno || !last_input_filename ||
 750                           strcmp (last_input_filename, input_filename)))
 751                     {
 752                       warning ("traditional C rejects string concatenation");
 753                       last_lineno = lineno;
 754                       last_input_filename = input_filename;
 755                     }
 756 end ifc
 757                 }
 758         ;
 759
 760 ifobjc
 761 /* Produces an STRING_CST with perhaps more STRING_CSTs chained
 762    onto it, which is to be read as an ObjC string object.  */
 763 objc_string:
 764           '@' STRING
 765                 { $$ = $2; }
 766         | objc_string '@' STRING
 767                 { $$ = chainon ($1, $3); }
 768         ;
 769 end ifobjc
 770
 771 old_style_parm_decls:
 772         /* empty */
 773         | datadecls
 774         | datadecls ELLIPSIS
 775                 /* ... is used here to indicate a varargs function.  */
 776                 { c_mark_varargs ();
 777                   if (pedantic)
 778                     pedwarn ("ISO C does not permit use of `varargs.h'"); }
 779         ;
 780
 781 /* The following are analogous to lineno_decl, decls and decl
 782    except that they do not allow nested functions.
 783    They are used for old-style parm decls.  */
 784 lineno_datadecl:
 785           save_filename save_lineno datadecl
 786                 { }
 787         ;
 788
 789 datadecls:
 790         lineno_datadecl
 791         | errstmt
 792         | datadecls lineno_datadecl
 793         | lineno_datadecl errstmt
 794         ;
 795
 796 /* We don't allow prefix attributes here because they cause reduce/reduce
 797    conflicts: we can't know whether we're parsing a function decl with
 798    attribute suffix, or function defn with attribute prefix on first old
 799    style parm.  */
 800 datadecl:
 801         declspecs_ts_nosa setspecs initdecls ';'
 802                 { POP_DECLSPEC_STACK; }
 803         | declspecs_nots_nosa setspecs notype_initdecls ';'
 804                 { POP_DECLSPEC_STACK; }
 805         | declspecs_ts_nosa ';'
 806                 { shadow_tag_warned ($1, 1);
 807                   pedwarn ("empty declaration"); }
 808         | declspecs_nots_nosa ';'
 809                 { pedwarn ("empty declaration"); }
 810         ;
 811
 812 /* This combination which saves a lineno before a decl
 813    is the normal thing to use, rather than decl itself.
 814    This is to avoid shift/reduce conflicts in contexts
 815    where statement labels are allowed.  */
 816 lineno_decl:
 817           save_filename save_lineno decl
 818                 { }
 819         ;
 820
 821 /* records the type and storage class specs to use for processing
 822    the declarators that follow.
 823    Maintains a stack of outer-level values of current_declspecs,
 824    for the sake of parm declarations nested in function declarators.  */
 825 setspecs: /* empty */
 826                 { pending_xref_error ();
 827                   PUSH_DECLSPEC_STACK;
 828                   split_specs_attrs ($<ttype>0,
 829                                      &current_declspecs, &prefix_attributes);
 830                   all_prefix_attributes = prefix_attributes; }
 831         ;
 832
 833 /* Possibly attributes after a comma, which should reset all_prefix_attributes
 834    to prefix_attributes with these ones chained on the front.  */
 835 maybe_resetattrs:
 836           maybe_attribute
 837                 { all_prefix_attributes = chainon ($1, prefix_attributes); }
 838         ;
 839
 840 decl:
 841         declspecs_ts setspecs initdecls ';'
 842                 { POP_DECLSPEC_STACK; }
 843         | declspecs_nots setspecs notype_initdecls ';'
 844                 { POP_DECLSPEC_STACK; }
 845         | declspecs_ts setspecs nested_function
 846                 { POP_DECLSPEC_STACK; }
 847         | declspecs_nots setspecs notype_nested_function
 848                 { POP_DECLSPEC_STACK; }
 849         | declspecs ';'
 850                 { shadow_tag ($1); }
 851         | extension decl
 852                 { RESTORE_WARN_FLAGS ($1); }
 853         ;
 854
 855 /* A list of declaration specifiers.  These are:
 856
 857    - Storage class specifiers (SCSPEC), which for GCC currently include
 858    function specifiers ("inline").
 859
 860    - Type specifiers (typespec_*).
 861
 862    - Type qualifiers (TYPE_QUAL).
 863
 864    - Attribute specifier lists (attributes).
 865
 866    These are stored as a TREE_LIST; the head of the list is the last
 867    item in the specifier list.  Each entry in the list has either a
 868    TREE_PURPOSE that is an attribute specifier list, or a TREE_VALUE that
 869    is a single other specifier or qualifier; and a TREE_CHAIN that is the
 870    rest of the list.  TREE_STATIC is set on the list if something other
 871    than a storage class specifier or attribute has been seen; this is used
 872    to warn for the obsolescent usage of storage class specifiers other than
 873    at the start of the list.  (Doing this properly would require function
 874    specifiers to be handled separately from storage class specifiers.)
 875
 876    The various cases below are classified according to:
 877
 878    (a) Whether a storage class specifier is included or not; some
 879    places in the grammar disallow storage class specifiers (_sc or _nosc).
 880
 881    (b) Whether a type specifier has been seen; after a type specifier,
 882    a typedef name is an identifier to redeclare (_ts or _nots).
 883
 884    (c) Whether the list starts with an attribute; in certain places,
 885    the grammar requires specifiers that don't start with an attribute
 886    (_sa or _nosa).
 887
 888    (d) Whether the list ends with an attribute (or a specifier such that
 889    any following attribute would have been parsed as part of that specifier);
 890    this avoids shift-reduce conflicts in the parsing of attributes
 891    (_ea or _noea).
 892
 893    TODO:
 894
 895    (i) Distinguish between function specifiers and storage class specifiers,
 896    at least for the purpose of warnings about obsolescent usage.
 897
 898    (ii) Halve the number of productions here by eliminating the _sc/_nosc
 899    distinction and instead checking where required that storage class
 900    specifiers aren't present.  */
 901
 902 /* Declspecs which contain at least one type specifier or typedef name.
 903    (Just `const' or `volatile' is not enough.)
 904    A typedef'd name following these is taken as a name to be declared.
 905    Declspecs have a non-NULL TREE_VALUE, attributes do not.  */
 906
 907 declspecs_nosc_nots_nosa_noea:
 908           TYPE_QUAL
 909                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 910                   TREE_STATIC ($$) = 1; }
 911         | declspecs_nosc_nots_nosa_noea TYPE_QUAL
 912                 { $$ = tree_cons (NULL_TREE, $2, $1);
 913                   TREE_STATIC ($$) = 1; }
 914         | declspecs_nosc_nots_nosa_ea TYPE_QUAL
 915                 { $$ = tree_cons (NULL_TREE, $2, $1);
 916                   TREE_STATIC ($$) = 1; }
 917         ;
 918
 919 declspecs_nosc_nots_nosa_ea:
 920           declspecs_nosc_nots_nosa_noea attributes
 921                 { $$ = tree_cons ($2, NULL_TREE, $1);
 922                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 923         ;
 924
 925 declspecs_nosc_nots_sa_noea:
 926           declspecs_nosc_nots_sa_noea TYPE_QUAL
 927                 { $$ = tree_cons (NULL_TREE, $2, $1);
 928                   TREE_STATIC ($$) = 1; }
 929         | declspecs_nosc_nots_sa_ea TYPE_QUAL
 930                 { $$ = tree_cons (NULL_TREE, $2, $1);
 931                   TREE_STATIC ($$) = 1; }
 932         ;
 933
 934 declspecs_nosc_nots_sa_ea:
 935           attributes
 936                 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE);
 937                   TREE_STATIC ($$) = 0; }
 938         | declspecs_nosc_nots_sa_noea attributes
 939                 { $$ = tree_cons ($2, NULL_TREE, $1);
 940                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 941         ;
 942
 943 declspecs_nosc_ts_nosa_noea:
 944           typespec_nonattr
 945                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 946                   TREE_STATIC ($$) = 1; }
 947         | declspecs_nosc_ts_nosa_noea TYPE_QUAL
 948                 { $$ = tree_cons (NULL_TREE, $2, $1);
 949                   TREE_STATIC ($$) = 1; }
 950         | declspecs_nosc_ts_nosa_ea TYPE_QUAL
 951                 { $$ = tree_cons (NULL_TREE, $2, $1);
 952                   TREE_STATIC ($$) = 1; }
 953         | declspecs_nosc_ts_nosa_noea typespec_reserved_nonattr
 954                 { $$ = tree_cons (NULL_TREE, $2, $1);
 955                   TREE_STATIC ($$) = 1; }
 956         | declspecs_nosc_ts_nosa_ea typespec_reserved_nonattr
 957                 { $$ = tree_cons (NULL_TREE, $2, $1);
 958                   TREE_STATIC ($$) = 1; }
 959         | declspecs_nosc_nots_nosa_noea typespec_nonattr
 960                 { $$ = tree_cons (NULL_TREE, $2, $1);
 961                   TREE_STATIC ($$) = 1; }
 962         | declspecs_nosc_nots_nosa_ea typespec_nonattr
 963                 { $$ = tree_cons (NULL_TREE, $2, $1);
 964                   TREE_STATIC ($$) = 1; }
 965         ;
 966
 967 declspecs_nosc_ts_nosa_ea:
 968           typespec_attr
 969                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 970                   TREE_STATIC ($$) = 1; }
 971         | declspecs_nosc_ts_nosa_noea attributes
 972                 { $$ = tree_cons ($2, NULL_TREE, $1);
 973                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 974         | declspecs_nosc_ts_nosa_noea typespec_reserved_attr
 975                 { $$ = tree_cons (NULL_TREE, $2, $1);
 976                   TREE_STATIC ($$) = 1; }
 977         | declspecs_nosc_ts_nosa_ea typespec_reserved_attr
 978                 { $$ = tree_cons (NULL_TREE, $2, $1);
 979                   TREE_STATIC ($$) = 1; }
 980         | declspecs_nosc_nots_nosa_noea typespec_attr
 981                 { $$ = tree_cons (NULL_TREE, $2, $1);
 982                   TREE_STATIC ($$) = 1; }
 983         | declspecs_nosc_nots_nosa_ea typespec_attr
 984                 { $$ = tree_cons (NULL_TREE, $2, $1);
 985                   TREE_STATIC ($$) = 1; }
 986         ;
 987
 988 declspecs_nosc_ts_sa_noea:
 989           declspecs_nosc_ts_sa_noea TYPE_QUAL
 990                 { $$ = tree_cons (NULL_TREE, $2, $1);
 991                   TREE_STATIC ($$) = 1; }
 992         | declspecs_nosc_ts_sa_ea TYPE_QUAL
 993                 { $$ = tree_cons (NULL_TREE, $2, $1);
 994                   TREE_STATIC ($$) = 1; }
 995         | declspecs_nosc_ts_sa_noea typespec_reserved_nonattr
 996                 { $$ = tree_cons (NULL_TREE, $2, $1);
 997                   TREE_STATIC ($$) = 1; }
 998         | declspecs_nosc_ts_sa_ea typespec_reserved_nonattr
 999                 { $$ = tree_cons (NULL_TREE, $2, $1);
1000                   TREE_STATIC ($$) = 1; }
1001         | declspecs_nosc_nots_sa_noea typespec_nonattr
1002                 { $$ = tree_cons (NULL_TREE, $2, $1);
1003                   TREE_STATIC ($$) = 1; }
1004         | declspecs_nosc_nots_sa_ea typespec_nonattr
1005                 { $$ = tree_cons (NULL_TREE, $2, $1);
1006                   TREE_STATIC ($$) = 1; }
1007         ;
1008
1009 declspecs_nosc_ts_sa_ea:
1010           declspecs_nosc_ts_sa_noea attributes
1011                 { $$ = tree_cons ($2, NULL_TREE, $1);
1012                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1013         | declspecs_nosc_ts_sa_noea typespec_reserved_attr
1014                 { $$ = tree_cons (NULL_TREE, $2, $1);
1015                   TREE_STATIC ($$) = 1; }
1016         | declspecs_nosc_ts_sa_ea typespec_reserved_attr
1017                 { $$ = tree_cons (NULL_TREE, $2, $1);
1018                   TREE_STATIC ($$) = 1; }
1019         | declspecs_nosc_nots_sa_noea typespec_attr
1020                 { $$ = tree_cons (NULL_TREE, $2, $1);
1021                   TREE_STATIC ($$) = 1; }
1022         | declspecs_nosc_nots_sa_ea typespec_attr
1023                 { $$ = tree_cons (NULL_TREE, $2, $1);
1024                   TREE_STATIC ($$) = 1; }
1025         ;
1026
1027 declspecs_sc_nots_nosa_noea:
1028           SCSPEC
1029                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
1030                   TREE_STATIC ($$) = 0; }
1031         | declspecs_sc_nots_nosa_noea TYPE_QUAL
1032                 { $$ = tree_cons (NULL_TREE, $2, $1);
1033                   TREE_STATIC ($$) = 1; }
1034         | declspecs_sc_nots_nosa_ea TYPE_QUAL
1035                 { $$ = tree_cons (NULL_TREE, $2, $1);
1036                   TREE_STATIC ($$) = 1; }
1037         | declspecs_nosc_nots_nosa_noea SCSPEC
1038                 { if (extra_warnings && TREE_STATIC ($1))
1039                     warning ("`%s' is not at beginning of declaration",
1040                              IDENTIFIER_POINTER ($2));
1041                   $$ = tree_cons (NULL_TREE, $2, $1);
1042                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1043         | declspecs_nosc_nots_nosa_ea SCSPEC
1044                 { if (extra_warnings && TREE_STATIC ($1))
1045                     warning ("`%s' is not at beginning of declaration",
1046                              IDENTIFIER_POINTER ($2));
1047                   $$ = tree_cons (NULL_TREE, $2, $1);
1048                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1049         | declspecs_sc_nots_nosa_noea SCSPEC
1050                 { if (extra_warnings && TREE_STATIC ($1))
1051                     warning ("`%s' is not at beginning of declaration",
1052                              IDENTIFIER_POINTER ($2));
1053                   $$ = tree_cons (NULL_TREE, $2, $1);
1054                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1055         | declspecs_sc_nots_nosa_ea SCSPEC
1056                 { if (extra_warnings && TREE_STATIC ($1))
1057                     warning ("`%s' is not at beginning of declaration",
1058                              IDENTIFIER_POINTER ($2));
1059                   $$ = tree_cons (NULL_TREE, $2, $1);
1060                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1061         ;
1062
1063 declspecs_sc_nots_nosa_ea:
1064           declspecs_sc_nots_nosa_noea attributes
1065                 { $$ = tree_cons ($2, NULL_TREE, $1);
1066                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1067         ;
1068
1069 declspecs_sc_nots_sa_noea:
1070           declspecs_sc_nots_sa_noea TYPE_QUAL
1071                 { $$ = tree_cons (NULL_TREE, $2, $1);
1072                   TREE_STATIC ($$) = 1; }
1073         | declspecs_sc_nots_sa_ea TYPE_QUAL
1074                 { $$ = tree_cons (NULL_TREE, $2, $1);
1075                   TREE_STATIC ($$) = 1; }
1076         | declspecs_nosc_nots_sa_noea SCSPEC
1077                 { if (extra_warnings && TREE_STATIC ($1))
1078                     warning ("`%s' is not at beginning of declaration",
1079                              IDENTIFIER_POINTER ($2));
1080                   $$ = tree_cons (NULL_TREE, $2, $1);
1081                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1082         | declspecs_nosc_nots_sa_ea SCSPEC
1083                 { if (extra_warnings && TREE_STATIC ($1))
1084                     warning ("`%s' is not at beginning of declaration",
1085                              IDENTIFIER_POINTER ($2));
1086                   $$ = tree_cons (NULL_TREE, $2, $1);
1087                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1088         | declspecs_sc_nots_sa_noea SCSPEC
1089                 { if (extra_warnings && TREE_STATIC ($1))
1090                     warning ("`%s' is not at beginning of declaration",
1091                              IDENTIFIER_POINTER ($2));
1092                   $$ = tree_cons (NULL_TREE, $2, $1);
1093                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1094         | declspecs_sc_nots_sa_ea SCSPEC
1095                 { if (extra_warnings && TREE_STATIC ($1))
1096                     warning ("`%s' is not at beginning of declaration",
1097                              IDENTIFIER_POINTER ($2));
1098                   $$ = tree_cons (NULL_TREE, $2, $1);
1099                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1100         ;
1101
1102 declspecs_sc_nots_sa_ea:
1103           declspecs_sc_nots_sa_noea attributes
1104                 { $$ = tree_cons ($2, NULL_TREE, $1);
1105                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1106         ;
1107
1108 declspecs_sc_ts_nosa_noea:
1109           declspecs_sc_ts_nosa_noea TYPE_QUAL
1110                 { $$ = tree_cons (NULL_TREE, $2, $1);
1111                   TREE_STATIC ($$) = 1; }
1112         | declspecs_sc_ts_nosa_ea TYPE_QUAL
1113                 { $$ = tree_cons (NULL_TREE, $2, $1);
1114                   TREE_STATIC ($$) = 1; }
1115         | declspecs_sc_ts_nosa_noea typespec_reserved_nonattr
1116                 { $$ = tree_cons (NULL_TREE, $2, $1);
1117                   TREE_STATIC ($$) = 1; }
1118         | declspecs_sc_ts_nosa_ea typespec_reserved_nonattr
1119                 { $$ = tree_cons (NULL_TREE, $2, $1);
1120                   TREE_STATIC ($$) = 1; }
1121         | declspecs_sc_nots_nosa_noea typespec_nonattr
1122                 { $$ = tree_cons (NULL_TREE, $2, $1);
1123                   TREE_STATIC ($$) = 1; }
1124         | declspecs_sc_nots_nosa_ea typespec_nonattr
1125                 { $$ = tree_cons (NULL_TREE, $2, $1);
1126                   TREE_STATIC ($$) = 1; }
1127         | declspecs_nosc_ts_nosa_noea SCSPEC
1128                 { if (extra_warnings && TREE_STATIC ($1))
1129                     warning ("`%s' is not at beginning of declaration",
1130                              IDENTIFIER_POINTER ($2));
1131                   $$ = tree_cons (NULL_TREE, $2, $1);
1132                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1133         | declspecs_nosc_ts_nosa_ea SCSPEC
1134                 { if (extra_warnings && TREE_STATIC ($1))
1135                     warning ("`%s' is not at beginning of declaration",
1136                              IDENTIFIER_POINTER ($2));
1137                   $$ = tree_cons (NULL_TREE, $2, $1);
1138                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1139         | declspecs_sc_ts_nosa_noea SCSPEC
1140                 { if (extra_warnings && TREE_STATIC ($1))
1141                     warning ("`%s' is not at beginning of declaration",
1142                              IDENTIFIER_POINTER ($2));
1143                   $$ = tree_cons (NULL_TREE, $2, $1);
1144                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1145         | declspecs_sc_ts_nosa_ea SCSPEC
1146                 { if (extra_warnings && TREE_STATIC ($1))
1147                     warning ("`%s' is not at beginning of declaration",
1148                              IDENTIFIER_POINTER ($2));
1149                   $$ = tree_cons (NULL_TREE, $2, $1);
1150                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1151         ;
1152
1153 declspecs_sc_ts_nosa_ea:
1154           declspecs_sc_ts_nosa_noea attributes
1155                 { $$ = tree_cons ($2, NULL_TREE, $1);
1156                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1157         | declspecs_sc_ts_nosa_noea typespec_reserved_attr
1158                 { $$ = tree_cons (NULL_TREE, $2, $1);
1159                   TREE_STATIC ($$) = 1; }
1160         | declspecs_sc_ts_nosa_ea typespec_reserved_attr
1161                 { $$ = tree_cons (NULL_TREE, $2, $1);
1162                   TREE_STATIC ($$) = 1; }
1163         | declspecs_sc_nots_nosa_noea typespec_attr
1164                 { $$ = tree_cons (NULL_TREE, $2, $1);
1165                   TREE_STATIC ($$) = 1; }
1166         | declspecs_sc_nots_nosa_ea typespec_attr
1167                 { $$ = tree_cons (NULL_TREE, $2, $1);
1168                   TREE_STATIC ($$) = 1; }
1169         ;
1170
1171 declspecs_sc_ts_sa_noea:
1172           declspecs_sc_ts_sa_noea TYPE_QUAL
1173                 { $$ = tree_cons (NULL_TREE, $2, $1);
1174                   TREE_STATIC ($$) = 1; }
1175         | declspecs_sc_ts_sa_ea TYPE_QUAL
1176                 { $$ = tree_cons (NULL_TREE, $2, $1);
1177                   TREE_STATIC ($$) = 1; }
1178         | declspecs_sc_ts_sa_noea typespec_reserved_nonattr
1179                 { $$ = tree_cons (NULL_TREE, $2, $1);
1180                   TREE_STATIC ($$) = 1; }
1181         | declspecs_sc_ts_sa_ea typespec_reserved_nonattr
1182                 { $$ = tree_cons (NULL_TREE, $2, $1);
1183                   TREE_STATIC ($$) = 1; }
1184         | declspecs_sc_nots_sa_noea typespec_nonattr
1185                 { $$ = tree_cons (NULL_TREE, $2, $1);
1186                   TREE_STATIC ($$) = 1; }
1187         | declspecs_sc_nots_sa_ea typespec_nonattr
1188                 { $$ = tree_cons (NULL_TREE, $2, $1);
1189                   TREE_STATIC ($$) = 1; }
1190         | declspecs_nosc_ts_sa_noea SCSPEC
1191                 { if (extra_warnings && TREE_STATIC ($1))
1192                     warning ("`%s' is not at beginning of declaration",
1193                              IDENTIFIER_POINTER ($2));
1194                   $$ = tree_cons (NULL_TREE, $2, $1);
1195                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1196         | declspecs_nosc_ts_sa_ea SCSPEC
1197                 { if (extra_warnings && TREE_STATIC ($1))
1198                     warning ("`%s' is not at beginning of declaration",
1199                              IDENTIFIER_POINTER ($2));
1200                   $$ = tree_cons (NULL_TREE, $2, $1);
1201                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1202         | declspecs_sc_ts_sa_noea SCSPEC
1203                 { if (extra_warnings && TREE_STATIC ($1))
1204                     warning ("`%s' is not at beginning of declaration",
1205                              IDENTIFIER_POINTER ($2));
1206                   $$ = tree_cons (NULL_TREE, $2, $1);
1207                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1208         | declspecs_sc_ts_sa_ea SCSPEC
1209                 { if (extra_warnings && TREE_STATIC ($1))
1210                     warning ("`%s' is not at beginning of declaration",
1211                              IDENTIFIER_POINTER ($2));
1212                   $$ = tree_cons (NULL_TREE, $2, $1);
1213                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1214         ;
1215
1216 declspecs_sc_ts_sa_ea:
1217           declspecs_sc_ts_sa_noea attributes
1218                 { $$ = tree_cons ($2, NULL_TREE, $1);
1219                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1220         | declspecs_sc_ts_sa_noea typespec_reserved_attr
1221                 { $$ = tree_cons (NULL_TREE, $2, $1);
1222                   TREE_STATIC ($$) = 1; }
1223         | declspecs_sc_ts_sa_ea typespec_reserved_attr
1224                 { $$ = tree_cons (NULL_TREE, $2, $1);
1225                   TREE_STATIC ($$) = 1; }
1226         | declspecs_sc_nots_sa_noea typespec_attr
1227                 { $$ = tree_cons (NULL_TREE, $2, $1);
1228                   TREE_STATIC ($$) = 1; }
1229         | declspecs_sc_nots_sa_ea typespec_attr
1230                 { $$ = tree_cons (NULL_TREE, $2, $1);
1231                   TREE_STATIC ($$) = 1; }
1232         ;
1233
1234 /* Particular useful classes of declspecs.  */
1235 declspecs_ts:
1236           declspecs_nosc_ts_nosa_noea
1237         | declspecs_nosc_ts_nosa_ea
1238         | declspecs_nosc_ts_sa_noea
1239         | declspecs_nosc_ts_sa_ea
1240         | declspecs_sc_ts_nosa_noea
1241         | declspecs_sc_ts_nosa_ea
1242         | declspecs_sc_ts_sa_noea
1243         | declspecs_sc_ts_sa_ea
1244         ;
1245
1246 declspecs_nots:
1247           declspecs_nosc_nots_nosa_noea
1248         | declspecs_nosc_nots_nosa_ea
1249         | declspecs_nosc_nots_sa_noea
1250         | declspecs_nosc_nots_sa_ea
1251         | declspecs_sc_nots_nosa_noea
1252         | declspecs_sc_nots_nosa_ea
1253         | declspecs_sc_nots_sa_noea
1254         | declspecs_sc_nots_sa_ea
1255         ;
1256
1257 declspecs_ts_nosa:
1258           declspecs_nosc_ts_nosa_noea
1259         | declspecs_nosc_ts_nosa_ea
1260         | declspecs_sc_ts_nosa_noea
1261         | declspecs_sc_ts_nosa_ea
1262         ;
1263
1264 declspecs_nots_nosa:
1265           declspecs_nosc_nots_nosa_noea
1266         | declspecs_nosc_nots_nosa_ea
1267         | declspecs_sc_nots_nosa_noea
1268         | declspecs_sc_nots_nosa_ea
1269         ;
1270
1271 declspecs_nosc_ts:
1272           declspecs_nosc_ts_nosa_noea
1273         | declspecs_nosc_ts_nosa_ea
1274         | declspecs_nosc_ts_sa_noea
1275         | declspecs_nosc_ts_sa_ea
1276         ;
1277
1278 declspecs_nosc_nots:
1279           declspecs_nosc_nots_nosa_noea
1280         | declspecs_nosc_nots_nosa_ea
1281         | declspecs_nosc_nots_sa_noea
1282         | declspecs_nosc_nots_sa_ea
1283         ;
1284
1285 declspecs_nosc:
1286           declspecs_nosc_ts_nosa_noea
1287         | declspecs_nosc_ts_nosa_ea
1288         | declspecs_nosc_ts_sa_noea
1289         | declspecs_nosc_ts_sa_ea
1290         | declspecs_nosc_nots_nosa_noea
1291         | declspecs_nosc_nots_nosa_ea
1292         | declspecs_nosc_nots_sa_noea
1293         | declspecs_nosc_nots_sa_ea
1294         ;
1295
1296 declspecs:
1297           declspecs_nosc_nots_nosa_noea
1298         | declspecs_nosc_nots_nosa_ea
1299         | declspecs_nosc_nots_sa_noea
1300         | declspecs_nosc_nots_sa_ea
1301         | declspecs_nosc_ts_nosa_noea
1302         | declspecs_nosc_ts_nosa_ea
1303         | declspecs_nosc_ts_sa_noea
1304         | declspecs_nosc_ts_sa_ea
1305         | declspecs_sc_nots_nosa_noea
1306         | declspecs_sc_nots_nosa_ea
1307         | declspecs_sc_nots_sa_noea
1308         | declspecs_sc_nots_sa_ea
1309         | declspecs_sc_ts_nosa_noea
1310         | declspecs_sc_ts_nosa_ea
1311         | declspecs_sc_ts_sa_noea
1312         | declspecs_sc_ts_sa_ea
1313         ;
1314
1315 /* A (possibly empty) sequence of type qualifiers and attributes.  */
1316 maybe_type_quals_attrs:
1317           /* empty */
1318                 { $$ = NULL_TREE; }
1319         | declspecs_nosc_nots
1320                 { $$ = $1; }
1321         ;
1322
1323 /* A type specifier (but not a type qualifier).
1324    Once we have seen one of these in a declaration,
1325    if a typedef name appears then it is being redeclared.
1326
1327    The _reserved versions start with a reserved word and may appear anywhere
1328    in the declaration specifiers; the _nonreserved versions may only
1329    appear before any other type specifiers, and after that are (if names)
1330    being redeclared.
1331
1332    FIXME: should the _nonreserved version be restricted to names being
1333    redeclared only?  The other entries there relate only the GNU extensions
1334    and Objective C, and are historically parsed thus, and don't make sense
1335    after other type specifiers, but it might be cleaner to count them as
1336    _reserved.
1337
1338    _attr means: specifiers that either end with attributes,
1339    or are such that any following attributes would
1340    be parsed as part of the specifier.
1341
1342    _nonattr: specifiers.  */
1343
1344 typespec_nonattr:
1345           typespec_reserved_nonattr
1346         | typespec_nonreserved_nonattr
1347         ;
1348
1349 typespec_attr:
1350           typespec_reserved_attr
1351         ;
1352
1353 typespec_reserved_nonattr:
1354           TYPESPEC
1355                 { OBJC_NEED_RAW_IDENTIFIER (1); }
1356         | structsp_nonattr
1357         ;
1358
1359 typespec_reserved_attr:
1360           structsp_attr
1361         ;
1362
1363 typespec_nonreserved_nonattr:
1364           TYPENAME
1365                 { /* For a typedef name, record the meaning, not the name.
1366                      In case of `foo foo, bar;'.  */
1367                   $$ = lookup_name ($1); }
1368 ifobjc
1369         | CLASSNAME protocolrefs
1370                 { $$ = get_static_reference ($1, $2); }
1371         | OBJECTNAME protocolrefs
1372                 { $$ = get_object_reference ($2); }
1373
1374 /* Make "<SomeProtocol>" equivalent to "id <SomeProtocol>"
1375    - nisse@lysator.liu.se */
1376         | non_empty_protocolrefs
1377                 { $$ = get_object_reference ($1); }
1378 end ifobjc
1379         | TYPEOF '(' expr ')'
1380                 { $$ = TREE_TYPE ($3); }
1381         | TYPEOF '(' typename ')'
1382                 { $$ = groktypename ($3); }
1383         ;
1384
1385 /* typespec_nonreserved_attr does not exist.  */
1386
1387 initdecls:
1388         initdcl
1389         | initdecls ',' maybe_resetattrs initdcl
1390         ;
1391
1392 notype_initdecls:
1393         notype_initdcl
1394         | notype_initdecls ',' maybe_resetattrs notype_initdcl
1395         ;
1396
1397 maybeasm:
1398           /* empty */
1399                 { $$ = NULL_TREE; }
1400         | ASM_KEYWORD '(' string ')'
1401                 { if (TREE_CHAIN ($3)) $3 = combine_strings ($3);
1402                   $$ = $3;
1403                 }
1404         ;
1405
1406 initdcl:
1407           declarator maybeasm maybe_attribute '='
1408                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1409                                           chainon ($3, all_prefix_attributes));
1410                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1411           init
1412 /* Note how the declaration of the variable is in effect while its init is parsed! */
1413                 { finish_init ();
1414                   finish_decl ($<ttype>5, $6, $2); }
1415         | declarator maybeasm maybe_attribute
1416                 { tree d = start_decl ($1, current_declspecs, 0,
1417                                        chainon ($3, all_prefix_attributes));
1418                   finish_decl (d, NULL_TREE, $2);
1419                 }
1420         ;
1421
1422 notype_initdcl:
1423           notype_declarator maybeasm maybe_attribute '='
1424                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1425                                           chainon ($3, all_prefix_attributes));
1426                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1427           init
1428 /* Note how the declaration of the variable is in effect while its init is parsed! */
1429                 { finish_init ();
1430                   finish_decl ($<ttype>5, $6, $2); }
1431         | notype_declarator maybeasm maybe_attribute
1432                 { tree d = start_decl ($1, current_declspecs, 0,
1433                                        chainon ($3, all_prefix_attributes));
1434                   finish_decl (d, NULL_TREE, $2); }
1435         ;
1436 /* the * rules are dummies to accept the Apollo extended syntax
1437    so that the header files compile. */
1438 maybe_attribute:
1439       /* empty */
1440                 { $$ = NULL_TREE; }
1441         | attributes
1442                 { $$ = $1; }
1443         ;
1444
1445 attributes:
1446       attribute
1447                 { $$ = $1; }
1448         | attributes attribute
1449                 { $$ = chainon ($1, $2); }
1450         ;
1451
1452 attribute:
1453       ATTRIBUTE '(' '(' attribute_list ')' ')'
1454                 { $$ = $4; }
1455         ;
1456
1457 attribute_list:
1458       attrib
1459                 { $$ = $1; }
1460         | attribute_list ',' attrib
1461                 { $$ = chainon ($1, $3); }
1462         ;
1463
1464 attrib:
1465     /* empty */
1466                 { $$ = NULL_TREE; }
1467         | any_word
1468                 { $$ = build_tree_list ($1, NULL_TREE); }
1469         | any_word '(' IDENTIFIER ')'
1470                 { $$ = build_tree_list ($1, build_tree_list (NULL_TREE, $3)); }
1471         | any_word '(' IDENTIFIER ',' nonnull_exprlist ')'
1472                 { $$ = build_tree_list ($1, tree_cons (NULL_TREE, $3, $5)); }
1473         | any_word '(' exprlist ')'
1474                 { $$ = build_tree_list ($1, $3); }
1475         ;
1476
1477 /* This still leaves out most reserved keywords,
1478    shouldn't we include them?  */
1479
1480 any_word:
1481           identifier
1482         | SCSPEC
1483         | TYPESPEC
1484         | TYPE_QUAL
1485         ;
1486 \f
1487 /* Initializers.  `init' is the entry point.  */
1488
1489 init:
1490         expr_no_commas
1491         | '{'
1492                 { really_start_incremental_init (NULL_TREE); }
1493           initlist_maybe_comma '}'
1494                 { $$ = pop_init_level (0); }
1495         | error
1496                 { $$ = error_mark_node; }
1497         ;
1498
1499 /* `initlist_maybe_comma' is the guts of an initializer in braces.  */
1500 initlist_maybe_comma:
1501           /* empty */
1502                 { if (pedantic)
1503                     pedwarn ("ISO C forbids empty initializer braces"); }
1504         | initlist1 maybecomma
1505         ;
1506
1507 initlist1:
1508           initelt
1509         | initlist1 ',' initelt
1510         ;
1511
1512 /* `initelt' is a single element of an initializer.
1513    It may use braces.  */
1514 initelt:
1515           designator_list '=' initval
1516                 { if (pedantic && ! flag_isoc99)
1517                     pedwarn ("ISO C89 forbids specifying subobject to initialize"); }
1518         | designator initval
1519                 { if (pedantic)
1520                     pedwarn ("obsolete use of designated initializer without `='"); }
1521         | identifier ':'
1522                 { set_init_label ($1);
1523                   if (pedantic)
1524                     pedwarn ("obsolete use of designated initializer with `:'"); }
1525           initval
1526         | initval
1527         ;
1528
1529 initval:
1530           '{'
1531                 { push_init_level (0); }
1532           initlist_maybe_comma '}'
1533                 { process_init_element (pop_init_level (0)); }
1534         | expr_no_commas
1535                 { process_init_element ($1); }
1536         | error
1537         ;
1538
1539 designator_list:
1540           designator
1541         | designator_list designator
1542         ;
1543
1544 designator:
1545           '.' identifier
1546                 { set_init_label ($2); }
1547         /* These are for labeled elements.  The syntax for an array element
1548            initializer conflicts with the syntax for an Objective-C message,
1549            so don't include these productions in the Objective-C grammar.  */
1550 ifc
1551         | '[' expr_no_commas ELLIPSIS expr_no_commas ']'
1552                 { set_init_index ($2, $4);
1553                   if (pedantic)
1554                     pedwarn ("ISO C forbids specifying range of elements to initialize"); }
1555         | '[' expr_no_commas ']'
1556                 { set_init_index ($2, NULL_TREE); }
1557 end ifc
1558         ;
1559 \f
1560 nested_function:
1561           declarator
1562                 { if (pedantic)
1563                     pedwarn ("ISO C forbids nested functions");
1564
1565                   push_function_context ();
1566                   if (! start_function (current_declspecs, $1,
1567                                         all_prefix_attributes))
1568                     {
1569                       pop_function_context ();
1570                       YYERROR1;
1571                     }
1572                 }
1573            old_style_parm_decls
1574                 { store_parm_decls (); }
1575 /* This used to use compstmt_or_error.
1576    That caused a bug with input `f(g) int g {}',
1577    where the use of YYERROR1 above caused an error
1578    which then was handled by compstmt_or_error.
1579    There followed a repeated execution of that same rule,
1580    which called YYERROR1 again, and so on.  */
1581           save_filename save_lineno compstmt
1582                 { tree decl = current_function_decl;
1583                   DECL_SOURCE_FILE (decl) = $5;
1584                   DECL_SOURCE_LINE (decl) = $6;
1585                   finish_function (1);
1586                   pop_function_context ();
1587                   add_decl_stmt (decl); }
1588         ;
1589
1590 notype_nested_function:
1591           notype_declarator
1592                 { if (pedantic)
1593                     pedwarn ("ISO C forbids nested functions");
1594
1595                   push_function_context ();
1596                   if (! start_function (current_declspecs, $1,
1597                                         all_prefix_attributes))
1598                     {
1599                       pop_function_context ();
1600                       YYERROR1;
1601                     }
1602                 }
1603           old_style_parm_decls
1604                 { store_parm_decls (); }
1605 /* This used to use compstmt_or_error.
1606    That caused a bug with input `f(g) int g {}',
1607    where the use of YYERROR1 above caused an error
1608    which then was handled by compstmt_or_error.
1609    There followed a repeated execution of that same rule,
1610    which called YYERROR1 again, and so on.  */
1611           save_filename save_lineno compstmt
1612                 { tree decl = current_function_decl;
1613                   DECL_SOURCE_FILE (decl) = $5;
1614                   DECL_SOURCE_LINE (decl) = $6;
1615                   finish_function (1);
1616                   pop_function_context ();
1617                   add_decl_stmt (decl); }
1618         ;
1619
1620 /* Any kind of declarator (thus, all declarators allowed
1621    after an explicit typespec).  */
1622
1623 declarator:
1624           after_type_declarator
1625         | notype_declarator
1626         ;
1627
1628 /* A declarator that is allowed only after an explicit typespec.  */
1629
1630 after_type_declarator:
1631           '(' maybe_attribute after_type_declarator ')'
1632                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1633         | after_type_declarator '(' parmlist_or_identifiers  %prec '.'
1634                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1635 /*      | after_type_declarator '(' error ')'  %prec '.'
1636                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1637                   poplevel (0, 0, 0); }  */
1638         | after_type_declarator array_declarator  %prec '.'
1639                 { $$ = set_array_declarator_type ($2, $1, 0); }
1640         | '*' maybe_type_quals_attrs after_type_declarator  %prec UNARY
1641                 { $$ = make_pointer_declarator ($2, $3); }
1642         | TYPENAME
1643 ifobjc
1644         | OBJECTNAME
1645 end ifobjc
1646         ;
1647
1648 /* Kinds of declarator that can appear in a parameter list
1649    in addition to notype_declarator.  This is like after_type_declarator
1650    but does not allow a typedef name in parentheses as an identifier
1651    (because it would conflict with a function with that typedef as arg).  */
1652 parm_declarator:
1653           parm_declarator_starttypename
1654         | parm_declarator_nostarttypename
1655         ;
1656
1657 parm_declarator_starttypename:
1658           parm_declarator_starttypename '(' parmlist_or_identifiers  %prec '.'
1659                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1660 /*      | parm_declarator_starttypename '(' error ')'  %prec '.'
1661                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1662                   poplevel (0, 0, 0); }  */
1663         | parm_declarator_starttypename array_declarator  %prec '.'
1664                 { $$ = set_array_declarator_type ($2, $1, 0); }
1665         | TYPENAME
1666 ifobjc
1667         | OBJECTNAME
1668 end ifobjc
1669         ;
1670
1671 parm_declarator_nostarttypename:
1672           parm_declarator_nostarttypename '(' parmlist_or_identifiers  %prec '.'
1673                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1674 /*      | parm_declarator_nostarttypename '(' error ')'  %prec '.'
1675                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1676                   poplevel (0, 0, 0); }  */
1677         | parm_declarator_nostarttypename array_declarator  %prec '.'
1678                 { $$ = set_array_declarator_type ($2, $1, 0); }
1679         | '*' maybe_type_quals_attrs parm_declarator_starttypename  %prec UNARY
1680                 { $$ = make_pointer_declarator ($2, $3); }
1681         | '*' maybe_type_quals_attrs parm_declarator_nostarttypename  %prec UNARY
1682                 { $$ = make_pointer_declarator ($2, $3); }
1683         | '(' maybe_attribute parm_declarator_nostarttypename ')'
1684                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1685         ;
1686
1687 /* A declarator allowed whether or not there has been
1688    an explicit typespec.  These cannot redeclare a typedef-name.  */
1689
1690 notype_declarator:
1691           notype_declarator '(' parmlist_or_identifiers  %prec '.'
1692                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1693 /*      | notype_declarator '(' error ')'  %prec '.'
1694                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1695                   poplevel (0, 0, 0); }  */
1696         | '(' maybe_attribute notype_declarator ')'
1697                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1698         | '*' maybe_type_quals_attrs notype_declarator  %prec UNARY
1699                 { $$ = make_pointer_declarator ($2, $3); }
1700         | notype_declarator array_declarator  %prec '.'
1701                 { $$ = set_array_declarator_type ($2, $1, 0); }
1702         | IDENTIFIER
1703         ;
1704
1705 struct_head:
1706           STRUCT
1707                 { $$ = NULL_TREE; }
1708         | STRUCT attributes
1709                 { $$ = $2; }
1710         ;
1711
1712 union_head:
1713           UNION
1714                 { $$ = NULL_TREE; }
1715         | UNION attributes
1716                 { $$ = $2; }
1717         ;
1718
1719 enum_head:
1720           ENUM
1721                 { $$ = NULL_TREE; }
1722         | ENUM attributes
1723                 { $$ = $2; }
1724         ;
1725
1726 /* structsp_attr: struct/union/enum specifiers that either
1727    end with attributes, or are such that any following attributes would
1728    be parsed as part of the struct/union/enum specifier.
1729
1730    structsp_nonattr: other struct/union/enum specifiers.  */
1731
1732 structsp_attr:
1733           struct_head identifier '{'
1734                 { $$ = start_struct (RECORD_TYPE, $2);
1735                   /* Start scope of tag before parsing components.  */
1736                 }
1737           component_decl_list '}' maybe_attribute
1738                 { $$ = finish_struct ($<ttype>4, $5, chainon ($1, $7)); }
1739         | struct_head '{' component_decl_list '}' maybe_attribute
1740                 { $$ = finish_struct (start_struct (RECORD_TYPE, NULL_TREE),
1741                                       $3, chainon ($1, $5));
1742                 }
1743         | union_head identifier '{'
1744                 { $$ = start_struct (UNION_TYPE, $2); }
1745           component_decl_list '}' maybe_attribute
1746                 { $$ = finish_struct ($<ttype>4, $5, chainon ($1, $7)); }
1747         | union_head '{' component_decl_list '}' maybe_attribute
1748                 { $$ = finish_struct (start_struct (UNION_TYPE, NULL_TREE),
1749                                       $3, chainon ($1, $5));
1750                 }
1751         | enum_head identifier '{'
1752                 { $$ = start_enum ($2); }
1753           enumlist maybecomma_warn '}' maybe_attribute
1754                 { $$ = finish_enum ($<ttype>4, nreverse ($5),
1755                                     chainon ($1, $8)); }
1756         | enum_head '{'
1757                 { $$ = start_enum (NULL_TREE); }
1758           enumlist maybecomma_warn '}' maybe_attribute
1759                 { $$ = finish_enum ($<ttype>3, nreverse ($4),
1760                                     chainon ($1, $7)); }
1761         ;
1762
1763 structsp_nonattr:
1764           struct_head identifier
1765                 { $$ = xref_tag (RECORD_TYPE, $2); }
1766         | union_head identifier
1767                 { $$ = xref_tag (UNION_TYPE, $2); }
1768         | enum_head identifier
1769                 { $$ = xref_tag (ENUMERAL_TYPE, $2);
1770                   /* In ISO C, enumerated types can be referred to
1771                      only if already defined.  */
1772                   if (pedantic && !COMPLETE_TYPE_P ($$))
1773                     pedwarn ("ISO C forbids forward references to `enum' types"); }
1774         ;
1775
1776 maybecomma:
1777           /* empty */
1778         | ','
1779         ;
1780
1781 maybecomma_warn:
1782           /* empty */
1783         | ','
1784                 { if (pedantic && ! flag_isoc99)
1785                     pedwarn ("comma at end of enumerator list"); }
1786         ;
1787
1788 component_decl_list:
1789           component_decl_list2
1790                 { $$ = $1; }
1791         | component_decl_list2 component_decl
1792                 { $$ = chainon ($1, $2);
1793                   pedwarn ("no semicolon at end of struct or union"); }
1794         ;
1795
1796 component_decl_list2:   /* empty */
1797                 { $$ = NULL_TREE; }
1798         | component_decl_list2 component_decl ';'
1799                 { $$ = chainon ($1, $2); }
1800         | component_decl_list2 ';'
1801                 { if (pedantic)
1802                     pedwarn ("extra semicolon in struct or union specified"); }
1803 ifobjc
1804         /* foo(sizeof(struct{ @defs(ClassName)})); */
1805         | DEFS '(' CLASSNAME ')'
1806                 {
1807                   tree interface = lookup_interface ($3);
1808
1809                   if (interface)
1810                     $$ = get_class_ivars (interface);
1811                   else
1812                     {
1813                       error ("cannot find interface declaration for `%s'",
1814                              IDENTIFIER_POINTER ($3));
1815                       $$ = NULL_TREE;
1816                     }
1817                 }
1818 end ifobjc
1819         ;
1820
1821 component_decl:
1822           declspecs_nosc_ts setspecs components
1823                 { $$ = $3;
1824                   POP_DECLSPEC_STACK; }
1825         | declspecs_nosc_ts setspecs save_filename save_lineno
1826                 {
1827                   /* Support for unnamed structs or unions as members of
1828                      structs or unions (which is [a] useful and [b] supports
1829                      MS P-SDK).  */
1830                   if (pedantic)
1831                     pedwarn ("ISO C doesn't support unnamed structs/unions");
1832
1833                   $$ = grokfield($3, $4, NULL, current_declspecs, NULL_TREE);
1834                   POP_DECLSPEC_STACK; }
1835         | declspecs_nosc_nots setspecs components_notype
1836                 { $$ = $3;
1837                   POP_DECLSPEC_STACK; }
1838         | declspecs_nosc_nots
1839                 { if (pedantic)
1840                     pedwarn ("ISO C forbids member declarations with no members");
1841                   shadow_tag($1);
1842                   $$ = NULL_TREE; }
1843         | error
1844                 { $$ = NULL_TREE; }
1845         | extension component_decl
1846                 { $$ = $2;
1847                   RESTORE_WARN_FLAGS ($1); }
1848         ;
1849
1850 components:
1851           component_declarator
1852         | components ',' maybe_resetattrs component_declarator
1853                 { $$ = chainon ($1, $4); }
1854         ;
1855
1856 components_notype:
1857           component_notype_declarator
1858         | components_notype ',' maybe_resetattrs component_notype_declarator
1859                 { $$ = chainon ($1, $4); }
1860         ;
1861
1862 component_declarator:
1863           save_filename save_lineno declarator maybe_attribute
1864                 { $$ = grokfield ($1, $2, $3, current_declspecs, NULL_TREE);
1865                   decl_attributes (&$$, chainon ($4, all_prefix_attributes), 0); }
1866         | save_filename save_lineno
1867           declarator ':' expr_no_commas maybe_attribute
1868                 { $$ = grokfield ($1, $2, $3, current_declspecs, $5);
1869                   decl_attributes (&$$, chainon ($6, all_prefix_attributes), 0); }
1870         | save_filename save_lineno ':' expr_no_commas maybe_attribute
1871                 { $$ = grokfield ($1, $2, NULL_TREE, current_declspecs, $4);
1872                   decl_attributes (&$$, chainon ($5, all_prefix_attributes), 0); }
1873         ;
1874
1875 component_notype_declarator:
1876           save_filename save_lineno notype_declarator maybe_attribute
1877                 { $$ = grokfield ($1, $2, $3, current_declspecs, NULL_TREE);
1878                   decl_attributes (&$$, chainon ($4, all_prefix_attributes), 0); }
1879         | save_filename save_lineno
1880           notype_declarator ':' expr_no_commas maybe_attribute
1881                 { $$ = grokfield ($1, $2, $3, current_declspecs, $5);
1882                   decl_attributes (&$$, chainon ($6, all_prefix_attributes), 0); }
1883         | save_filename save_lineno ':' expr_no_commas maybe_attribute
1884                 { $$ = grokfield ($1, $2, NULL_TREE, current_declspecs, $4);
1885                   decl_attributes (&$$, chainon ($5, all_prefix_attributes), 0); }
1886         ;
1887
1888 /* We chain the enumerators in reverse order.
1889    They are put in forward order where enumlist is used.
1890    (The order used to be significant, but no longer is so.
1891    However, we still maintain the order, just to be clean.)  */
1892
1893 enumlist:
1894           enumerator
1895         | enumlist ',' enumerator
1896                 { if ($1 == error_mark_node)
1897                     $$ = $1;
1898                   else
1899                     $$ = chainon ($3, $1); }
1900         | error
1901                 { $$ = error_mark_node; }
1902         ;
1903
1904
1905 enumerator:
1906           identifier
1907                 { $$ = build_enumerator ($1, NULL_TREE); }
1908         | identifier '=' expr_no_commas
1909                 { $$ = build_enumerator ($1, $3); }
1910         ;
1911
1912 typename:
1913           declspecs_nosc
1914                 { pending_xref_error ();
1915                   $<ttype>$ = $1; }
1916           absdcl
1917                 { $$ = build_tree_list ($<ttype>2, $3); }
1918         ;
1919
1920 absdcl:   /* an absolute declarator */
1921         /* empty */
1922                 { $$ = NULL_TREE; }
1923         | absdcl1
1924         ;
1925
1926 absdcl_maybe_attribute:   /* absdcl maybe_attribute, but not just attributes */
1927         /* empty */
1928                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1929                                                          NULL_TREE),
1930                                         all_prefix_attributes); }
1931         | absdcl1
1932                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1933                                                          $1),
1934                                         all_prefix_attributes); }
1935         | absdcl1_noea attributes
1936                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1937                                                          $1),
1938                                         chainon ($2, all_prefix_attributes)); }
1939         ;
1940
1941 absdcl1:  /* a nonempty absolute declarator */
1942           absdcl1_ea
1943         | absdcl1_noea
1944         ;
1945
1946 absdcl1_noea:
1947           direct_absdcl1
1948         | '*' maybe_type_quals_attrs absdcl1_noea
1949                 { $$ = make_pointer_declarator ($2, $3); }
1950         ;
1951
1952 absdcl1_ea:
1953           '*' maybe_type_quals_attrs
1954                 { $$ = make_pointer_declarator ($2, NULL_TREE); }
1955         | '*' maybe_type_quals_attrs absdcl1_ea
1956                 { $$ = make_pointer_declarator ($2, $3); }
1957         ;
1958
1959 direct_absdcl1:
1960           '(' maybe_attribute absdcl1 ')'
1961                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1962         | direct_absdcl1 '(' parmlist
1963                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1964         | direct_absdcl1 array_declarator
1965                 { $$ = set_array_declarator_type ($2, $1, 1); }
1966         | '(' parmlist
1967                 { $$ = build_nt (CALL_EXPR, NULL_TREE, $2, NULL_TREE); }
1968         | array_declarator
1969                 { $$ = set_array_declarator_type ($1, NULL_TREE, 1); }
1970         ;
1971
1972 /* The [...] part of a declarator for an array type.  */
1973
1974 array_declarator:
1975           '[' expr ']'
1976                 { $$ = build_array_declarator ($2, NULL_TREE, 0, 0); }
1977         | '[' declspecs_nosc expr ']'
1978                 { $$ = build_array_declarator ($3, $2, 0, 0); }
1979         | '[' ']'
1980                 { $$ = build_array_declarator (NULL_TREE, NULL_TREE, 0, 0); }
1981         | '[' declspecs_nosc ']'
1982                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 0); }
1983         | '[' '*' ']'
1984                 { $$ = build_array_declarator (NULL_TREE, NULL_TREE, 0, 1); }
1985         | '[' declspecs_nosc '*' ']'
1986                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 1); }
1987         | '[' SCSPEC expr ']'
1988                 { if (C_RID_CODE ($2) != RID_STATIC)
1989                     error ("storage class specifier in array declarator");
1990                   $$ = build_array_declarator ($3, NULL_TREE, 1, 0); }
1991         | '[' SCSPEC declspecs_nosc expr ']'
1992                 { if (C_RID_CODE ($2) != RID_STATIC)
1993                     error ("storage class specifier in array declarator");
1994                   $$ = build_array_declarator ($4, $3, 1, 0); }
1995         | '[' declspecs_nosc SCSPEC expr ']'
1996                 { if (C_RID_CODE ($3) != RID_STATIC)
1997                     error ("storage class specifier in array declarator");
1998                   $$ = build_array_declarator ($4, $2, 1, 0); }
1999         ;
2000
2001 /* A nonempty series of declarations and statements (possibly followed by
2002    some labels) that can form the body of a compound statement.
2003    NOTE: we don't allow labels on declarations; this might seem like a
2004    natural extension, but there would be a conflict between attributes
2005    on the label and prefix attributes on the declaration.  */
2006
2007 stmts_and_decls:
2008           lineno_stmt_decl_or_labels_ending_stmt
2009         | lineno_stmt_decl_or_labels_ending_decl
2010         | lineno_stmt_decl_or_labels_ending_label
2011                 {
2012                   pedwarn ("deprecated use of label at end of compound statement");
2013                 }
2014         | lineno_stmt_decl_or_labels_ending_error
2015         ;
2016
2017 lineno_stmt_decl_or_labels_ending_stmt:
2018           lineno_stmt
2019         | lineno_stmt_decl_or_labels_ending_stmt lineno_stmt
2020         | lineno_stmt_decl_or_labels_ending_decl lineno_stmt
2021         | lineno_stmt_decl_or_labels_ending_label lineno_stmt
2022         | lineno_stmt_decl_or_labels_ending_error lineno_stmt
2023         ;
2024
2025 lineno_stmt_decl_or_labels_ending_decl:
2026           lineno_decl
2027         | lineno_stmt_decl_or_labels_ending_stmt lineno_decl
2028                 { if (pedantic && !flag_isoc99)
2029                     pedwarn ("ISO C89 forbids mixed declarations and code"); }
2030         | lineno_stmt_decl_or_labels_ending_decl lineno_decl
2031         | lineno_stmt_decl_or_labels_ending_error lineno_decl
2032         ;
2033
2034 lineno_stmt_decl_or_labels_ending_label:
2035           lineno_label
2036         | lineno_stmt_decl_or_labels_ending_stmt lineno_label
2037         | lineno_stmt_decl_or_labels_ending_decl lineno_label
2038         | lineno_stmt_decl_or_labels_ending_label lineno_label
2039         | lineno_stmt_decl_or_labels_ending_error lineno_label
2040         ;
2041
2042 lineno_stmt_decl_or_labels_ending_error:
2043         errstmt
2044         | lineno_stmt_decl_or_labels errstmt
2045         ;
2046
2047 lineno_stmt_decl_or_labels:
2048           lineno_stmt_decl_or_labels_ending_stmt
2049         | lineno_stmt_decl_or_labels_ending_decl
2050         | lineno_stmt_decl_or_labels_ending_label
2051         | lineno_stmt_decl_or_labels_ending_error
2052         ;
2053
2054 errstmt:  error ';'
2055         ;
2056
2057 pushlevel:  /* empty */
2058                 { pushlevel (0);
2059                   clear_last_expr ();
2060                   add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2061 ifobjc
2062                   if (objc_method_context)
2063                     add_objc_decls ();
2064 end ifobjc
2065                 }
2066         ;
2067
2068 poplevel:  /* empty */
2069                 { $$ = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0); }
2070
2071 /* Start and end blocks created for the new scopes of C99.  */
2072 c99_block_start: /* empty */
2073                 { if (flag_isoc99)
2074                     {
2075                       $$ = c_begin_compound_stmt ();
2076                       pushlevel (0);
2077                       clear_last_expr ();
2078                       add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2079 ifobjc
2080                       if (objc_method_context)
2081                         add_objc_decls ();
2082 end ifobjc
2083                     }
2084                   else
2085                     $$ = NULL_TREE;
2086                 }
2087         ;
2088
2089 /* Productions using c99_block_start and c99_block_end will need to do what's
2090    in compstmt: RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); $$ = $2; where
2091    $1 is the value of c99_block_start and $2 of c99_block_end.  */
2092 c99_block_end: /* empty */
2093                 { if (flag_isoc99)
2094                     {
2095                       tree scope_stmt = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0);
2096                       $$ = poplevel (kept_level_p (), 0, 0);
2097                       SCOPE_STMT_BLOCK (TREE_PURPOSE (scope_stmt))
2098                         = SCOPE_STMT_BLOCK (TREE_VALUE (scope_stmt))
2099                         = $$;
2100                     }
2101                   else
2102                     $$ = NULL_TREE; }
2103         ;
2104
2105 /* Read zero or more forward-declarations for labels
2106    that nested functions can jump to.  */
2107 maybe_label_decls:
2108           /* empty */
2109         | label_decls
2110                 { if (pedantic)
2111                     pedwarn ("ISO C forbids label declarations"); }
2112         ;
2113
2114 label_decls:
2115           label_decl
2116         | label_decls label_decl
2117         ;
2118
2119 label_decl:
2120           LABEL identifiers_or_typenames ';'
2121                 { tree link;
2122                   for (link = $2; link; link = TREE_CHAIN (link))
2123                     {
2124                       tree label = shadow_label (TREE_VALUE (link));
2125                       C_DECLARED_LABEL_FLAG (label) = 1;
2126                       add_decl_stmt (label);
2127                     }
2128                 }
2129         ;
2130
2131 /* This is the body of a function definition.
2132    It causes syntax errors to ignore to the next openbrace.  */
2133 compstmt_or_error:
2134           compstmt
2135                 {}
2136         | error compstmt
2137         ;
2138
2139 compstmt_start: '{' { compstmt_count++;
2140                       $$ = c_begin_compound_stmt (); }
2141
2142 compstmt_nostart: '}'
2143                 { $$ = convert (void_type_node, integer_zero_node); }
2144         | pushlevel maybe_label_decls compstmt_contents_nonempty '}' poplevel
2145                 { $$ = poplevel (kept_level_p (), 1, 0);
2146                   SCOPE_STMT_BLOCK (TREE_PURPOSE ($5))
2147                     = SCOPE_STMT_BLOCK (TREE_VALUE ($5))
2148                     = $$; }
2149         ;
2150
2151 compstmt_contents_nonempty:
2152           stmts_and_decls
2153         | error
2154         ;
2155
2156 compstmt_primary_start:
2157         '(' '{'
2158                 { if (current_function_decl == 0)
2159                     {
2160                       error ("braced-group within expression allowed only inside a function");
2161                       YYERROR;
2162                     }
2163                   /* We must force a BLOCK for this level
2164                      so that, if it is not expanded later,
2165                      there is a way to turn off the entire subtree of blocks
2166                      that are contained in it.  */
2167                   keep_next_level ();
2168                   push_label_level ();
2169                   compstmt_count++;
2170                   $$ = add_stmt (build_stmt (COMPOUND_STMT, last_tree));
2171                 }
2172
2173 compstmt: compstmt_start compstmt_nostart
2174                 { RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2175                   $$ = $1; }
2176         ;
2177
2178 /* Value is number of statements counted as of the closeparen.  */
2179 simple_if:
2180           if_prefix c99_block_lineno_labeled_stmt
2181                 { c_finish_then (); }
2182 /* Make sure c_expand_end_cond is run once
2183    for each call to c_expand_start_cond.
2184    Otherwise a crash is likely.  */
2185         | if_prefix error
2186         ;
2187
2188 if_prefix:
2189           /* We must build the IF_STMT node before parsing its
2190              condition so that STMT_LINENO refers to the line
2191              containing the "if", and not the line containing
2192              the close-parenthesis.
2193
2194              c_begin_if_stmt returns the IF_STMT node, which
2195              we later pass to c_expand_start_cond to fill
2196              in the condition and other tidbits.  */
2197           IF
2198                 { $<ttype>$ = c_begin_if_stmt (); }
2199             '(' expr ')'
2200                 { c_expand_start_cond (truthvalue_conversion ($4),
2201                                        compstmt_count,$<ttype>2);
2202                   $<itype>$ = stmt_count;
2203                   if_stmt_file = $<filename>-2;
2204                   if_stmt_line = $<lineno>-1; }
2205         ;
2206
2207 /* This is a subroutine of stmt.
2208    It is used twice, once for valid DO statements
2209    and once for catching errors in parsing the end test.  */
2210 do_stmt_start:
2211           DO
2212                 { stmt_count++;
2213                   compstmt_count++;
2214                   $<ttype>$
2215                     = add_stmt (build_stmt (DO_STMT, NULL_TREE,
2216                                             NULL_TREE));
2217                   /* In the event that a parse error prevents
2218                      parsing the complete do-statement, set the
2219                      condition now.  Otherwise, we can get crashes at
2220                      RTL-generation time.  */
2221                   DO_COND ($<ttype>$) = error_mark_node; }
2222           c99_block_lineno_labeled_stmt WHILE
2223                 { $$ = $<ttype>2;
2224                   RECHAIN_STMTS ($$, DO_BODY ($$)); }
2225         ;
2226
2227 /* The forced readahead in here is because we might be at the end of a
2228    line, and the line and file won't be bumped until yylex absorbs the
2229    first token on the next line.  */
2230 save_filename:
2231                 { if (yychar == YYEMPTY)
2232                     yychar = YYLEX;
2233                   $$ = input_filename; }
2234         ;
2235
2236 save_lineno:
2237                 { if (yychar == YYEMPTY)
2238                     yychar = YYLEX;
2239                   $$ = lineno; }
2240         ;
2241
2242 lineno_labeled_stmt:
2243           lineno_stmt
2244         | lineno_label lineno_labeled_stmt
2245         ;
2246
2247 /* Like lineno_labeled_stmt, but a block in C99.  */
2248 c99_block_lineno_labeled_stmt:
2249           c99_block_start lineno_labeled_stmt c99_block_end
2250                 { if (flag_isoc99)
2251                     RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); }
2252         ;
2253
2254 lineno_stmt:
2255           save_filename save_lineno stmt
2256                 { if ($3)
2257                     {
2258                       STMT_LINENO ($3) = $2;
2259                       /* ??? We currently have no way of recording
2260                          the filename for a statement.  This probably
2261                          matters little in practice at the moment,
2262                          but I suspect that problems will occur when
2263                          doing inlining at the tree level.  */
2264                     }
2265                 }
2266         ;
2267
2268 lineno_label:
2269           save_filename save_lineno label
2270                 { if ($3)
2271                     {
2272                       STMT_LINENO ($3) = $2;
2273                     }
2274                 }
2275         ;
2276
2277 select_or_iter_stmt:
2278           simple_if ELSE
2279                 { c_expand_start_else ();
2280                   $<itype>1 = stmt_count; }
2281           c99_block_lineno_labeled_stmt
2282                 { c_finish_else ();
2283                   c_expand_end_cond ();
2284                   if (extra_warnings && stmt_count == $<itype>1)
2285                     warning ("empty body in an else-statement"); }
2286         | simple_if %prec IF
2287                 { c_expand_end_cond ();
2288                   /* This warning is here instead of in simple_if, because we
2289                      do not want a warning if an empty if is followed by an
2290                      else statement.  Increment stmt_count so we don't
2291                      give a second error if this is a nested `if'.  */
2292                   if (extra_warnings && stmt_count++ == $<itype>1)
2293                     warning_with_file_and_line (if_stmt_file, if_stmt_line,
2294                                                 "empty body in an if-statement"); }
2295 /* Make sure c_expand_end_cond is run once
2296    for each call to c_expand_start_cond.
2297    Otherwise a crash is likely.  */
2298         | simple_if ELSE error
2299                 { c_expand_end_cond (); }
2300        /* We must build the WHILE_STMT node before parsing its
2301           condition so that STMT_LINENO refers to the line
2302           containing the "while", and not the line containing
2303           the close-parenthesis.
2304
2305           c_begin_while_stmt returns the WHILE_STMT node, which
2306           we later pass to c_finish_while_stmt_cond to fill
2307           in the condition and other tidbits.  */
2308         | WHILE
2309                 { stmt_count++;
2310                   $<ttype>$ = c_begin_while_stmt (); }
2311           '(' expr ')'
2312                 { $4 = truthvalue_conversion ($4);
2313                   c_finish_while_stmt_cond (truthvalue_conversion ($4),
2314                                             $<ttype>2);
2315                   $<ttype>$ = add_stmt ($<ttype>2); }
2316           c99_block_lineno_labeled_stmt
2317                 { RECHAIN_STMTS ($<ttype>6, WHILE_BODY ($<ttype>6)); }
2318         | do_stmt_start
2319           '(' expr ')' ';'
2320                 { DO_COND ($1) = truthvalue_conversion ($3); }
2321         | do_stmt_start error
2322                 { }
2323         | FOR
2324                 { $<ttype>$ = build_stmt (FOR_STMT, NULL_TREE, NULL_TREE,
2325                                           NULL_TREE, NULL_TREE);
2326                   add_stmt ($<ttype>$); }
2327           '(' for_init_stmt
2328                 { stmt_count++;
2329                   RECHAIN_STMTS ($<ttype>2, FOR_INIT_STMT ($<ttype>2)); }
2330           xexpr ';'
2331                 { if ($6)
2332                     FOR_COND ($<ttype>2) = truthvalue_conversion ($6); }
2333           xexpr ')'
2334                 { FOR_EXPR ($<ttype>2) = $9; }
2335           c99_block_lineno_labeled_stmt
2336                 { RECHAIN_STMTS ($<ttype>2, FOR_BODY ($<ttype>2)); }
2337         | SWITCH '(' expr ')'
2338                 { stmt_count++;
2339                   $<ttype>$ = c_start_case ($3); }
2340           c99_block_lineno_labeled_stmt
2341                 { c_finish_case (); }
2342         ;
2343
2344 for_init_stmt:
2345           xexpr ';'
2346                 { add_stmt (build_stmt (EXPR_STMT, $1)); }
2347         | decl
2348                 { check_for_loop_decls (); }
2349         ;
2350
2351 /* Parse a single real statement, not including any labels.  */
2352 stmt:
2353           compstmt
2354                 { stmt_count++; $$ = $1; }
2355         | expr ';'
2356                 { stmt_count++;
2357                   $$ = c_expand_expr_stmt ($1); }
2358         | c99_block_start select_or_iter_stmt c99_block_end
2359                 { if (flag_isoc99)
2360                     RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2361                   $$ = NULL_TREE; }
2362         | BREAK ';'
2363                 { stmt_count++;
2364                   $$ = add_stmt (build_break_stmt ()); }
2365         | CONTINUE ';'
2366                 { stmt_count++;
2367                   $$ = add_stmt (build_continue_stmt ()); }
2368         | RETURN ';'
2369                 { stmt_count++;
2370                   $$ = c_expand_return (NULL_TREE); }
2371         | RETURN expr ';'
2372                 { stmt_count++;
2373                   $$ = c_expand_return ($2); }
2374         | ASM_KEYWORD maybe_type_qual '(' expr ')' ';'
2375                 { stmt_count++;
2376                   $$ = simple_asm_stmt ($4); }
2377         /* This is the case with just output operands.  */
2378         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ')' ';'
2379                 { stmt_count++;
2380                   $$ = build_asm_stmt ($2, $4, $6, NULL_TREE, NULL_TREE); }
2381         /* This is the case with input operands as well.  */
2382         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2383           asm_operands ')' ';'
2384                 { stmt_count++;
2385                   $$ = build_asm_stmt ($2, $4, $6, $8, NULL_TREE); }
2386         /* This is the case with clobbered registers as well.  */
2387         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2388           asm_operands ':' asm_clobbers ')' ';'
2389                 { stmt_count++;
2390                   $$ = build_asm_stmt ($2, $4, $6, $8, $10); }
2391         | GOTO identifier ';'
2392                 { tree decl;
2393                   stmt_count++;
2394                   decl = lookup_label ($2);
2395                   if (decl != 0)
2396                     {
2397                       TREE_USED (decl) = 1;
2398                       $$ = add_stmt (build_stmt (GOTO_STMT, decl));
2399                     }
2400                   else
2401                     $$ = NULL_TREE;
2402                 }
2403         | GOTO '*' expr ';'
2404                 { if (pedantic)
2405                     pedwarn ("ISO C forbids `goto *expr;'");
2406                   stmt_count++;
2407                   $3 = convert (ptr_type_node, $3);
2408                   $$ = add_stmt (build_stmt (GOTO_STMT, $3)); }
2409         | ';'
2410                 { $$ = NULL_TREE; }
2411         ;
2412
2413 /* Any kind of label, including jump labels and case labels.
2414    ANSI C accepts labels only before statements, but we allow them
2415    also at the end of a compound statement.  */
2416
2417 label:    CASE expr_no_commas ':'
2418                 { stmt_count++;
2419                   $$ = do_case ($2, NULL_TREE); }
2420         | CASE expr_no_commas ELLIPSIS expr_no_commas ':'
2421                 { stmt_count++;
2422                   $$ = do_case ($2, $4); }
2423         | DEFAULT ':'
2424                 { stmt_count++;
2425                   $$ = do_case (NULL_TREE, NULL_TREE); }
2426         | identifier save_filename save_lineno ':' maybe_attribute
2427                 { tree label = define_label ($2, $3, $1);
2428                   stmt_count++;
2429                   if (label)
2430                     {
2431                       decl_attributes (&label, $5, 0);
2432                       $$ = add_stmt (build_stmt (LABEL_STMT, label));
2433                     }
2434                   else
2435                     $$ = NULL_TREE;
2436                 }
2437         ;
2438
2439 /* Either a type-qualifier or nothing.  First thing in an `asm' statement.  */
2440
2441 maybe_type_qual:
2442         /* empty */
2443                 { emit_line_note (input_filename, lineno);
2444                   $$ = NULL_TREE; }
2445         | TYPE_QUAL
2446                 { emit_line_note (input_filename, lineno); }
2447         ;
2448
2449 xexpr:
2450         /* empty */
2451                 { $$ = NULL_TREE; }
2452         | expr
2453         ;
2454
2455 /* These are the operands other than the first string and colon
2456    in  asm ("addextend %2,%1": "=dm" (x), "0" (y), "g" (*x))  */
2457 asm_operands: /* empty */
2458                 { $$ = NULL_TREE; }
2459         | nonnull_asm_operands
2460         ;
2461
2462 nonnull_asm_operands:
2463           asm_operand
2464         | nonnull_asm_operands ',' asm_operand
2465                 { $$ = chainon ($1, $3); }
2466         ;
2467
2468 asm_operand:
2469           STRING '(' expr ')'
2470                 { $$ = build_tree_list (build_tree_list (NULL_TREE, $1), $3); }
2471         | '[' identifier ']' STRING '(' expr ')'
2472                 { $$ = build_tree_list (build_tree_list ($2, $4), $6); }
2473         ;
2474
2475 asm_clobbers:
2476           string
2477                 { $$ = tree_cons (NULL_TREE, combine_strings ($1), NULL_TREE); }
2478         | asm_clobbers ',' string
2479                 { $$ = tree_cons (NULL_TREE, combine_strings ($3), $1); }
2480         ;
2481 \f
2482 /* This is what appears inside the parens in a function declarator.
2483    Its value is a list of ..._TYPE nodes.  Attributes must appear here
2484    to avoid a conflict with their appearance after an open parenthesis
2485    in an abstract declarator, as in
2486    "void bar (int (__attribute__((__mode__(SI))) int foo));".  */
2487 parmlist:
2488           maybe_attribute
2489                 { pushlevel (0);
2490                   clear_parm_order ();
2491                   declare_parm_level (0); }
2492           parmlist_1
2493                 { $$ = $3;
2494                   parmlist_tags_warning ();
2495                   poplevel (0, 0, 0); }
2496         ;
2497
2498 parmlist_1:
2499           parmlist_2 ')'
2500         | parms ';'
2501                 { tree parm;
2502                   if (pedantic)
2503                     pedwarn ("ISO C forbids forward parameter declarations");
2504                   /* Mark the forward decls as such.  */
2505                   for (parm = getdecls (); parm; parm = TREE_CHAIN (parm))
2506                     TREE_ASM_WRITTEN (parm) = 1;
2507                   clear_parm_order (); }
2508           maybe_attribute
2509                 { /* Dummy action so attributes are in known place
2510                      on parser stack.  */ }
2511           parmlist_1
2512                 { $$ = $6; }
2513         | error ')'
2514                 { $$ = tree_cons (NULL_TREE, NULL_TREE, NULL_TREE); }
2515         ;
2516
2517 /* This is what appears inside the parens in a function declarator.
2518    Is value is represented in the format that grokdeclarator expects.  */
2519 parmlist_2:  /* empty */
2520                 { $$ = get_parm_info (0); }
2521         | ELLIPSIS
2522                 { $$ = get_parm_info (0);
2523                   /* Gcc used to allow this as an extension.  However, it does
2524                      not work for all targets, and thus has been disabled.
2525                      Also, since func (...) and func () are indistinguishable,
2526                      it caused problems with the code in expand_builtin which
2527                      tries to verify that BUILT_IN_NEXT_ARG is being used
2528                      correctly.  */
2529                   error ("ISO C requires a named argument before `...'");
2530                 }
2531         | parms
2532                 { $$ = get_parm_info (1); }
2533         | parms ',' ELLIPSIS
2534                 { $$ = get_parm_info (0); }
2535         ;
2536
2537 parms:
2538         firstparm
2539                 { push_parm_decl ($1); }
2540         | parms ',' parm
2541                 { push_parm_decl ($3); }
2542         ;
2543
2544 /* A single parameter declaration or parameter type name,
2545    as found in a parmlist.  */
2546 parm:
2547           declspecs_ts setspecs parm_declarator maybe_attribute
2548                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2549                                                          $3),
2550                                         chainon ($4, all_prefix_attributes));
2551                   POP_DECLSPEC_STACK; }
2552         | declspecs_ts setspecs notype_declarator maybe_attribute
2553                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2554                                                          $3),
2555                                         chainon ($4, all_prefix_attributes));
2556                   POP_DECLSPEC_STACK; }
2557         | declspecs_ts setspecs absdcl_maybe_attribute
2558                 { $$ = $3;
2559                   POP_DECLSPEC_STACK; }
2560         | declspecs_nots setspecs notype_declarator maybe_attribute
2561                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2562                                                          $3),
2563                                         chainon ($4, all_prefix_attributes));
2564                   POP_DECLSPEC_STACK; }
2565
2566         | declspecs_nots setspecs absdcl_maybe_attribute
2567                 { $$ = $3;
2568                   POP_DECLSPEC_STACK; }
2569         ;
2570
2571 /* The first parm, which must suck attributes from off the top of the parser
2572    stack.  */
2573 firstparm:
2574           declspecs_ts_nosa setspecs_fp parm_declarator maybe_attribute
2575                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2576                                                          $3),
2577                                         chainon ($4, all_prefix_attributes));
2578                   POP_DECLSPEC_STACK; }
2579         | declspecs_ts_nosa setspecs_fp notype_declarator maybe_attribute
2580                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2581                                                          $3),
2582                                         chainon ($4, all_prefix_attributes));
2583                   POP_DECLSPEC_STACK; }
2584         | declspecs_ts_nosa setspecs_fp absdcl_maybe_attribute
2585                 { $$ = $3;
2586                   POP_DECLSPEC_STACK; }
2587         | declspecs_nots_nosa setspecs_fp notype_declarator maybe_attribute
2588                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2589                                                          $3),
2590                                         chainon ($4, all_prefix_attributes));
2591                   POP_DECLSPEC_STACK; }
2592
2593         | declspecs_nots_nosa setspecs_fp absdcl_maybe_attribute
2594                 { $$ = $3;
2595                   POP_DECLSPEC_STACK; }
2596         ;
2597
2598 setspecs_fp:
2599           setspecs
2600                 { prefix_attributes = chainon (prefix_attributes, $<ttype>-2);
2601                   all_prefix_attributes = prefix_attributes; }
2602         ;
2603
2604 /* This is used in a function definition
2605    where either a parmlist or an identifier list is ok.
2606    Its value is a list of ..._TYPE nodes or a list of identifiers.  */
2607 parmlist_or_identifiers:
2608                 { pushlevel (0);
2609                   clear_parm_order ();
2610                   declare_parm_level (1); }
2611           parmlist_or_identifiers_1
2612                 { $$ = $2;
2613                   parmlist_tags_warning ();
2614                   poplevel (0, 0, 0); }
2615         ;
2616
2617 parmlist_or_identifiers_1:
2618           parmlist_1
2619         | identifiers ')'
2620                 { tree t;
2621                   for (t = $1; t; t = TREE_CHAIN (t))
2622                     if (TREE_VALUE (t) == NULL_TREE)
2623                       error ("`...' in old-style identifier list");
2624                   $$ = tree_cons (NULL_TREE, NULL_TREE, $1); }
2625         ;
2626
2627 /* A nonempty list of identifiers.  */
2628 identifiers:
2629         IDENTIFIER
2630                 { $$ = build_tree_list (NULL_TREE, $1); }
2631         | identifiers ',' IDENTIFIER
2632                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2633         ;
2634
2635 /* A nonempty list of identifiers, including typenames.  */
2636 identifiers_or_typenames:
2637         identifier
2638                 { $$ = build_tree_list (NULL_TREE, $1); }
2639         | identifiers_or_typenames ',' identifier
2640                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2641         ;
2642
2643 extension:
2644         EXTENSION
2645                 { $$ = SAVE_WARN_FLAGS();
2646                   pedantic = 0;
2647                   warn_pointer_arith = 0;
2648                   warn_traditional = 0; }
2649         ;
2650 \f
2651 ifobjc
2652 /* Objective-C productions.  */
2653
2654 objcdef:
2655           classdef
2656         | classdecl
2657         | aliasdecl
2658         | protocoldef
2659         | methoddef
2660         | END
2661                 {
2662                   if (objc_implementation_context)
2663                     {
2664                       finish_class (objc_implementation_context);
2665                       objc_ivar_chain = NULL_TREE;
2666                       objc_implementation_context = NULL_TREE;
2667                     }
2668                   else
2669                     warning ("`@end' must appear in an implementation context");
2670                 }
2671         ;
2672
2673 /* A nonempty list of identifiers.  */
2674 identifier_list:
2675         identifier
2676                 { $$ = build_tree_list (NULL_TREE, $1); }
2677         | identifier_list ',' identifier
2678                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2679         ;
2680
2681 classdecl:
2682           CLASS identifier_list ';'
2683                 {
2684                   objc_declare_class ($2);
2685                 }
2686
2687 aliasdecl:
2688           ALIAS identifier identifier ';'
2689                 {
2690                   objc_declare_alias ($2, $3);
2691                 }
2692
2693 classdef:
2694           INTERFACE identifier protocolrefs '{'
2695                 {
2696                   objc_interface_context = objc_ivar_context
2697                     = start_class (CLASS_INTERFACE_TYPE, $2, NULL_TREE, $3);
2698                   objc_public_flag = 0;
2699                 }
2700           ivar_decl_list '}'
2701                 {
2702                   continue_class (objc_interface_context);
2703                 }
2704           methodprotolist
2705           END
2706                 {
2707                   finish_class (objc_interface_context);
2708                   objc_interface_context = NULL_TREE;
2709                 }
2710
2711         | INTERFACE identifier protocolrefs
2712                 {
2713                   objc_interface_context
2714                     = start_class (CLASS_INTERFACE_TYPE, $2, NULL_TREE, $3);
2715                   continue_class (objc_interface_context);
2716                 }
2717           methodprotolist
2718           END
2719                 {
2720                   finish_class (objc_interface_context);
2721                   objc_interface_context = NULL_TREE;
2722                 }
2723
2724         | INTERFACE identifier ':' identifier protocolrefs '{'
2725                 {
2726                   objc_interface_context = objc_ivar_context
2727                     = start_class (CLASS_INTERFACE_TYPE, $2, $4, $5);
2728                   objc_public_flag = 0;
2729                 }
2730           ivar_decl_list '}'
2731                 {
2732                   continue_class (objc_interface_context);
2733                 }
2734           methodprotolist
2735           END
2736                 {
2737                   finish_class (objc_interface_context);
2738                   objc_interface_context = NULL_TREE;
2739                 }
2740
2741         | INTERFACE identifier ':' identifier protocolrefs
2742                 {
2743                   objc_interface_context
2744                     = start_class (CLASS_INTERFACE_TYPE, $2, $4, $5);
2745                   continue_class (objc_interface_context);
2746                 }
2747           methodprotolist
2748           END
2749                 {
2750                   finish_class (objc_interface_context);
2751                   objc_interface_context = NULL_TREE;
2752                 }
2753
2754         | IMPLEMENTATION identifier '{'
2755                 {
2756                   objc_implementation_context = objc_ivar_context
2757                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, NULL_TREE, NULL_TREE);
2758                   objc_public_flag = 0;
2759                 }
2760           ivar_decl_list '}'
2761                 {
2762                   objc_ivar_chain
2763                     = continue_class (objc_implementation_context);
2764                 }
2765
2766         | IMPLEMENTATION identifier
2767                 {
2768                   objc_implementation_context
2769                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, NULL_TREE, NULL_TREE);
2770                   objc_ivar_chain
2771                     = continue_class (objc_implementation_context);
2772                 }
2773
2774         | IMPLEMENTATION identifier ':' identifier '{'
2775                 {
2776                   objc_implementation_context = objc_ivar_context
2777                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2778                   objc_public_flag = 0;
2779                 }
2780           ivar_decl_list '}'
2781                 {
2782                   objc_ivar_chain
2783                     = continue_class (objc_implementation_context);
2784                 }
2785
2786         | IMPLEMENTATION identifier ':' identifier
2787                 {
2788                   objc_implementation_context
2789                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2790                   objc_ivar_chain
2791                     = continue_class (objc_implementation_context);
2792                 }
2793
2794         | INTERFACE identifier '(' identifier ')' protocolrefs
2795                 {
2796                   objc_interface_context
2797                     = start_class (CATEGORY_INTERFACE_TYPE, $2, $4, $6);
2798                   continue_class (objc_interface_context);
2799                 }
2800           methodprotolist
2801           END
2802                 {
2803                   finish_class (objc_interface_context);
2804                   objc_interface_context = NULL_TREE;
2805                 }
2806
2807         | IMPLEMENTATION identifier '(' identifier ')'
2808                 {
2809                   objc_implementation_context
2810                     = start_class (CATEGORY_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2811                   objc_ivar_chain
2812                     = continue_class (objc_implementation_context);
2813                 }
2814         ;
2815
2816 protocoldef:
2817           PROTOCOL identifier protocolrefs
2818                 {
2819                   objc_pq_context = 1;
2820                   objc_interface_context
2821                     = start_protocol(PROTOCOL_INTERFACE_TYPE, $2, $3);
2822                 }
2823           methodprotolist END
2824                 {
2825                   objc_pq_context = 0;
2826                   finish_protocol(objc_interface_context);
2827                   objc_interface_context = NULL_TREE;
2828                 }
2829         /* The @protocol forward-declaration production introduces a
2830            reduce/reduce conflict on ';', which should be resolved in
2831            favor of the production 'identifier_list -> identifier'.  */
2832         | PROTOCOL identifier_list ';'
2833                 {
2834                   objc_declare_protocols ($2);
2835                 }
2836         ;
2837
2838 protocolrefs:
2839           /* empty */
2840                 {
2841                   $$ = NULL_TREE;
2842                 }
2843         | non_empty_protocolrefs
2844         ;
2845
2846 non_empty_protocolrefs:
2847           ARITHCOMPARE identifier_list ARITHCOMPARE
2848                 {
2849                   if ($1 == LT_EXPR && $3 == GT_EXPR)
2850                     $$ = $2;
2851                   else
2852                     YYERROR1;
2853                 }
2854         ;
2855
2856 ivar_decl_list:
2857           ivar_decl_list visibility_spec ivar_decls
2858         | ivar_decls
2859         ;
2860
2861 visibility_spec:
2862           PRIVATE { objc_public_flag = 2; }
2863         | PROTECTED { objc_public_flag = 0; }
2864         | PUBLIC { objc_public_flag = 1; }
2865         ;
2866
2867 ivar_decls:
2868           /* empty */
2869                 {
2870                   $$ = NULL_TREE;
2871                 }
2872         | ivar_decls ivar_decl ';'
2873         | ivar_decls ';'
2874                 {
2875                   if (pedantic)
2876                     pedwarn ("extra semicolon in struct or union specified");
2877                 }
2878         ;
2879
2880
2881 /* There is a shift-reduce conflict here, because `components' may
2882    start with a `typename'.  It happens that shifting (the default resolution)
2883    does the right thing, because it treats the `typename' as part of
2884    a `typed_typespecs'.
2885
2886    It is possible that this same technique would allow the distinction
2887    between `notype_initdecls' and `initdecls' to be eliminated.
2888    But I am being cautious and not trying it.  */
2889
2890 ivar_decl:
2891         declspecs_nosc_ts setspecs ivars
2892                 { $$ = $3;
2893                   POP_DECLSPEC_STACK; }
2894         | declspecs_nosc_nots setspecs ivars
2895                 { $$ = $3;
2896                   POP_DECLSPEC_STACK; }
2897         | error
2898                 { $$ = NULL_TREE; }
2899         ;
2900
2901 ivars:
2902           /* empty */
2903                 { $$ = NULL_TREE; }
2904         | ivar_declarator
2905         | ivars ',' maybe_resetattrs ivar_declarator
2906         ;
2907
2908 ivar_declarator:
2909           declarator
2910                 {
2911                   $$ = add_instance_variable (objc_ivar_context,
2912                                               objc_public_flag,
2913                                               $1, current_declspecs,
2914                                               NULL_TREE);
2915                 }
2916         | declarator ':' expr_no_commas
2917                 {
2918                   $$ = add_instance_variable (objc_ivar_context,
2919                                               objc_public_flag,
2920                                               $1, current_declspecs, $3);
2921                 }
2922         | ':' expr_no_commas
2923                 {
2924                   $$ = add_instance_variable (objc_ivar_context,
2925                                               objc_public_flag,
2926                                               NULL_TREE,
2927                                               current_declspecs, $2);
2928                 }
2929         ;
2930
2931 methodtype:
2932           '+'
2933                 { objc_inherit_code = CLASS_METHOD_DECL; }
2934         | '-'
2935                 { objc_inherit_code = INSTANCE_METHOD_DECL; }
2936         ;
2937
2938 methoddef:
2939           methodtype
2940                 {
2941                   objc_pq_context = 1;
2942                   if (!objc_implementation_context)
2943                     fatal_error ("method definition not in class context");
2944                 }
2945           methoddecl
2946                 {
2947                   objc_pq_context = 0;
2948                   if (objc_inherit_code == CLASS_METHOD_DECL)
2949                     add_class_method (objc_implementation_context, $3);
2950                   else
2951                     add_instance_method (objc_implementation_context, $3);
2952                   start_method_def ($3);
2953                 }
2954           optarglist
2955                 {
2956                   continue_method_def ();
2957                 }
2958           compstmt_or_error
2959                 {
2960                   finish_method_def ();
2961                 }
2962         ;
2963
2964 /* the reason for the strange actions in this rule
2965  is so that notype_initdecls when reached via datadef
2966  can find a valid list of type and sc specs in $0. */
2967
2968 methodprotolist:
2969           /* empty  */
2970         | {$<ttype>$ = NULL_TREE; } methodprotolist2
2971         ;
2972
2973 methodprotolist2:                /* eliminates a shift/reduce conflict */
2974            methodproto
2975         |  datadef
2976         | methodprotolist2 methodproto
2977         | methodprotolist2 {$<ttype>$ = NULL_TREE; } datadef
2978         ;
2979
2980 semi_or_error:
2981           ';'
2982         | error
2983         ;
2984
2985 methodproto:
2986           methodtype
2987                 {
2988                   /* Remember protocol qualifiers in prototypes.  */
2989                   objc_pq_context = 1;
2990                 }
2991           methoddecl
2992                 {
2993                   /* Forget protocol qualifiers here.  */
2994                   objc_pq_context = 0;
2995                   if (objc_inherit_code == CLASS_METHOD_DECL)
2996                     add_class_method (objc_interface_context, $3);
2997                   else
2998                     add_instance_method (objc_interface_context, $3);
2999                 }
3000           semi_or_error
3001         ;
3002
3003 methoddecl:
3004           '(' typename ')' unaryselector
3005                 {
3006                   $$ = build_method_decl (objc_inherit_code, $2, $4, NULL_TREE);
3007                 }
3008
3009         | unaryselector
3010                 {
3011                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, NULL_TREE);
3012                 }
3013
3014         | '(' typename ')' keywordselector optparmlist
3015                 {
3016                   $$ = build_method_decl (objc_inherit_code, $2, $4, $5);
3017                 }
3018
3019         | keywordselector optparmlist
3020                 {
3021                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, $2);
3022                 }
3023         ;
3024
3025 /* "optarglist" assumes that start_method_def has already been called...
3026    if it is not, the "xdecls" will not be placed in the proper scope */
3027
3028 optarglist:
3029           /* empty */
3030         | ';' myxdecls
3031         ;
3032
3033 /* to get around the following situation: "int foo (int a) int b; {}" that
3034    is synthesized when parsing "- a:a b:b; id c; id d; { ... }" */
3035
3036 myxdecls:
3037           /* empty */
3038         | mydecls
3039         ;
3040
3041 mydecls:
3042         mydecl
3043         | errstmt
3044         | mydecls mydecl
3045         | mydecl errstmt
3046         ;
3047
3048 mydecl:
3049         declspecs_ts setspecs myparms ';'
3050                 { POP_DECLSPEC_STACK; }
3051         | declspecs_ts ';'
3052                 { shadow_tag ($1); }
3053         | declspecs_nots ';'
3054                 { pedwarn ("empty declaration"); }
3055         ;
3056
3057 myparms:
3058         myparm
3059                 { push_parm_decl ($1); }
3060         | myparms ',' myparm
3061                 { push_parm_decl ($3); }
3062         ;
3063
3064 /* A single parameter declaration or parameter type name,
3065    as found in a parmlist. DOES NOT ALLOW AN INITIALIZER OR ASMSPEC */
3066
3067 myparm:
3068           parm_declarator maybe_attribute
3069                 { $$ = build_tree_list (build_tree_list (current_declspecs,
3070                                                          $1),
3071                                         chainon ($2, all_prefix_attributes)); }
3072         | notype_declarator maybe_attribute
3073                 { $$ = build_tree_list (build_tree_list (current_declspecs,
3074                                                          $1),
3075                                         chainon ($2, all_prefix_attributes)); }
3076         | absdcl_maybe_attribute
3077                 { $$ = $1; }
3078         ;
3079
3080 optparmlist:
3081           /* empty */
3082                 {
3083                   $$ = NULL_TREE;
3084                 }
3085         | ',' ELLIPSIS
3086                 {
3087                   /* oh what a kludge! */
3088                   $$ = objc_ellipsis_node;
3089                 }
3090         | ','
3091                 {
3092                   pushlevel (0);
3093                 }
3094           parmlist_2
3095                 {
3096                   /* returns a tree list node generated by get_parm_info */
3097                   $$ = $3;
3098                   poplevel (0, 0, 0);
3099                 }
3100         ;
3101
3102 unaryselector:
3103           selector
3104         ;
3105
3106 keywordselector:
3107           keyworddecl
3108
3109         | keywordselector keyworddecl
3110                 {
3111                   $$ = chainon ($1, $2);
3112                 }
3113         ;
3114
3115 selector:
3116           IDENTIFIER
3117         | TYPENAME
3118         | CLASSNAME
3119         | OBJECTNAME
3120         | reservedwords
3121         ;
3122
3123 reservedwords:
3124           ENUM | STRUCT | UNION | IF | ELSE | WHILE | DO | FOR
3125         | SWITCH | CASE | DEFAULT | BREAK | CONTINUE | RETURN
3126         | GOTO | ASM_KEYWORD | SIZEOF | TYPEOF | ALIGNOF
3127         | TYPESPEC | TYPE_QUAL
3128         ;
3129
3130 keyworddecl:
3131           selector ':' '(' typename ')' identifier
3132                 {
3133                   $$ = build_keyword_decl ($1, $4, $6);
3134                 }
3135
3136         | selector ':' identifier
3137                 {
3138                   $$ = build_keyword_decl ($1, NULL_TREE, $3);
3139                 }
3140
3141         | ':' '(' typename ')' identifier
3142                 {
3143                   $$ = build_keyword_decl (NULL_TREE, $3, $5);
3144                 }
3145
3146         | ':' identifier
3147                 {
3148                   $$ = build_keyword_decl (NULL_TREE, NULL_TREE, $2);
3149                 }
3150         ;
3151
3152 messageargs:
3153           selector
3154         | keywordarglist
3155         ;
3156
3157 keywordarglist:
3158           keywordarg
3159         | keywordarglist keywordarg
3160                 {
3161                   $$ = chainon ($1, $2);
3162                 }
3163         ;
3164
3165
3166 keywordexpr:
3167           nonnull_exprlist
3168                 {
3169                   if (TREE_CHAIN ($1) == NULL_TREE)
3170                     /* just return the expr., remove a level of indirection */
3171                     $$ = TREE_VALUE ($1);
3172                   else
3173                     /* we have a comma expr., we will collapse later */
3174                     $$ = $1;
3175                 }
3176         ;
3177
3178 keywordarg:
3179           selector ':' keywordexpr
3180                 {
3181                   $$ = build_tree_list ($1, $3);
3182                 }
3183         | ':' keywordexpr
3184                 {
3185                   $$ = build_tree_list (NULL_TREE, $2);
3186                 }
3187         ;
3188
3189 receiver:
3190           expr
3191         | CLASSNAME
3192                 {
3193                   $$ = get_class_reference ($1);
3194                 }
3195         ;
3196
3197 objcmessageexpr:
3198           '['
3199                 { objc_receiver_context = 1; }
3200           receiver
3201                 { objc_receiver_context = 0; }
3202           messageargs ']'
3203                 {
3204                   $$ = build_tree_list ($3, $5);
3205                 }
3206         ;
3207
3208 selectorarg:
3209           selector
3210         | keywordnamelist
3211         ;
3212
3213 keywordnamelist:
3214           keywordname
3215         | keywordnamelist keywordname
3216                 {
3217                   $$ = chainon ($1, $2);
3218                 }
3219         ;
3220
3221 keywordname:
3222           selector ':'
3223                 {
3224                   $$ = build_tree_list ($1, NULL_TREE);
3225                 }
3226         | ':'
3227                 {
3228                   $$ = build_tree_list (NULL_TREE, NULL_TREE);
3229                 }
3230         ;
3231
3232 objcselectorexpr:
3233           SELECTOR '(' selectorarg ')'
3234                 {
3235                   $$ = $3;
3236                 }
3237         ;
3238
3239 objcprotocolexpr:
3240           PROTOCOL '(' identifier ')'
3241                 {
3242                   $$ = $3;
3243                 }
3244         ;
3245
3246 /* extension to support C-structures in the archiver */
3247
3248 objcencodeexpr:
3249           ENCODE '(' typename ')'
3250                 {
3251                   $$ = groktypename ($3);
3252                 }
3253         ;
3254
3255 end ifobjc
3256 %%
3257
3258 /* yylex() is a thin wrapper around c_lex(), all it does is translate
3259    cpplib.h's token codes into yacc's token codes.  */
3260
3261 static enum cpp_ttype last_token;
3262
3263 /* The reserved keyword table.  */
3264 struct resword
3265 {
3266   const char *word;
3267   ENUM_BITFIELD(rid) rid : 16;
3268   unsigned int disable   : 16;
3269 };
3270
3271 /* Disable mask.  Keywords are disabled if (reswords[i].disable & mask) is
3272    _true_.  */
3273 #define D_TRAD  0x01    /* not in traditional C */
3274 #define D_C89   0x02    /* not in C89 */
3275 #define D_EXT   0x04    /* GCC extension */
3276 #define D_EXT89 0x08    /* GCC extension incorporated in C99 */
3277 #define D_OBJC  0x10    /* Objective C only */
3278
3279 static const struct resword reswords[] =
3280 {
3281   { "_Bool",            RID_BOOL,       0 },
3282   { "_Complex",         RID_COMPLEX,    0 },
3283   { "__FUNCTION__",     RID_FUNCTION_NAME, 0 },
3284   { "__PRETTY_FUNCTION__", RID_PRETTY_FUNCTION_NAME, 0 },
3285   { "__alignof",        RID_ALIGNOF,    0 },
3286   { "__alignof__",      RID_ALIGNOF,    0 },
3287   { "__asm",            RID_ASM,        0 },
3288   { "__asm__",          RID_ASM,        0 },
3289   { "__attribute",      RID_ATTRIBUTE,  0 },
3290   { "__attribute__",    RID_ATTRIBUTE,  0 },
3291   { "__bounded",        RID_BOUNDED,    0 },
3292   { "__bounded__",      RID_BOUNDED,    0 },
3293   { "__builtin_choose_expr", RID_CHOOSE_EXPR, 0 },
3294   { "__builtin_types_compatible_p", RID_TYPES_COMPATIBLE_P, 0 },
3295   { "__builtin_va_arg", RID_VA_ARG,     0 },
3296   { "__complex",        RID_COMPLEX,    0 },
3297   { "__complex__",      RID_COMPLEX,    0 },
3298   { "__const",          RID_CONST,      0 },
3299   { "__const__",        RID_CONST,      0 },
3300   { "__extension__",    RID_EXTENSION,  0 },
3301   { "__func__",         RID_C99_FUNCTION_NAME, 0 },
3302   { "__imag",           RID_IMAGPART,   0 },
3303   { "__imag__",         RID_IMAGPART,   0 },
3304   { "__inline",         RID_INLINE,     0 },
3305   { "__inline__",       RID_INLINE,     0 },
3306   { "__label__",        RID_LABEL,      0 },
3307   { "__ptrbase",        RID_PTRBASE,    0 },
3308   { "__ptrbase__",      RID_PTRBASE,    0 },
3309   { "__ptrextent",      RID_PTREXTENT,  0 },
3310   { "__ptrextent__",    RID_PTREXTENT,  0 },
3311   { "__ptrvalue",       RID_PTRVALUE,   0 },
3312   { "__ptrvalue__",     RID_PTRVALUE,   0 },
3313   { "__real",           RID_REALPART,   0 },
3314   { "__real__",         RID_REALPART,   0 },
3315   { "__restrict",       RID_RESTRICT,   0 },
3316   { "__restrict__",     RID_RESTRICT,   0 },
3317   { "__signed",         RID_SIGNED,     0 },
3318   { "__signed__",       RID_SIGNED,     0 },
3319   { "__typeof",         RID_TYPEOF,     0 },
3320   { "__typeof__",       RID_TYPEOF,     0 },
3321   { "__unbounded",      RID_UNBOUNDED,  0 },
3322   { "__unbounded__",    RID_UNBOUNDED,  0 },
3323   { "__volatile",       RID_VOLATILE,   0 },
3324   { "__volatile__",     RID_VOLATILE,   0 },
3325   { "asm",              RID_ASM,        D_EXT },
3326   { "auto",             RID_AUTO,       0 },
3327   { "break",            RID_BREAK,      0 },
3328   { "case",             RID_CASE,       0 },
3329   { "char",             RID_CHAR,       0 },
3330   { "const",            RID_CONST,      D_TRAD },
3331   { "continue",         RID_CONTINUE,   0 },
3332   { "default",          RID_DEFAULT,    0 },
3333   { "do",               RID_DO,         0 },
3334   { "double",           RID_DOUBLE,     0 },
3335   { "else",             RID_ELSE,       0 },
3336   { "enum",             RID_ENUM,       0 },
3337   { "extern",           RID_EXTERN,     0 },
3338   { "float",            RID_FLOAT,      0 },
3339   { "for",              RID_FOR,        0 },
3340   { "goto",             RID_GOTO,       0 },
3341   { "if",               RID_IF,         0 },
3342   { "inline",           RID_INLINE,     D_TRAD|D_EXT89 },
3343   { "int",              RID_INT,        0 },
3344   { "long",             RID_LONG,       0 },
3345   { "register",         RID_REGISTER,   0 },
3346   { "restrict",         RID_RESTRICT,   D_TRAD|D_C89 },
3347   { "return",           RID_RETURN,     0 },
3348   { "short",            RID_SHORT,      0 },
3349   { "signed",           RID_SIGNED,     D_TRAD },
3350   { "sizeof",           RID_SIZEOF,     0 },
3351   { "static",           RID_STATIC,     0 },
3352   { "struct",           RID_STRUCT,     0 },
3353   { "switch",           RID_SWITCH,     0 },
3354   { "typedef",          RID_TYPEDEF,    0 },
3355   { "typeof",           RID_TYPEOF,     D_TRAD|D_EXT },
3356   { "union",            RID_UNION,      0 },
3357   { "unsigned",         RID_UNSIGNED,   0 },
3358   { "void",             RID_VOID,       0 },
3359   { "volatile",         RID_VOLATILE,   D_TRAD },
3360   { "while",            RID_WHILE,      0 },
3361 ifobjc
3362   { "id",               RID_ID,                 D_OBJC },
3363
3364   /* These objc keywords are recognized only immediately after
3365      an '@'.  */
3366   { "class",            RID_AT_CLASS,           D_OBJC },
3367   { "compatibility_alias", RID_AT_ALIAS,        D_OBJC },
3368   { "defs",             RID_AT_DEFS,            D_OBJC },
3369   { "encode",           RID_AT_ENCODE,          D_OBJC },
3370   { "end",              RID_AT_END,             D_OBJC },
3371   { "implementation",   RID_AT_IMPLEMENTATION,  D_OBJC },
3372   { "interface",        RID_AT_INTERFACE,       D_OBJC },
3373   { "private",          RID_AT_PRIVATE,         D_OBJC },
3374   { "protected",        RID_AT_PROTECTED,       D_OBJC },
3375   { "protocol",         RID_AT_PROTOCOL,        D_OBJC },
3376   { "public",           RID_AT_PUBLIC,          D_OBJC },
3377   { "selector",         RID_AT_SELECTOR,        D_OBJC },
3378
3379   /* These are recognized only in protocol-qualifier context
3380      (see above) */
3381   { "bycopy",           RID_BYCOPY,             D_OBJC },
3382   { "byref",            RID_BYREF,              D_OBJC },
3383   { "in",               RID_IN,                 D_OBJC },
3384   { "inout",            RID_INOUT,              D_OBJC },
3385   { "oneway",           RID_ONEWAY,             D_OBJC },
3386   { "out",              RID_OUT,                D_OBJC },
3387 end ifobjc
3388 };
3389 #define N_reswords (sizeof reswords / sizeof (struct resword))
3390
3391 /* Table mapping from RID_* constants to yacc token numbers.
3392    Unfortunately we have to have entries for all the keywords in all
3393    three languages.  */
3394 static const short rid_to_yy[RID_MAX] =
3395 {
3396   /* RID_STATIC */      SCSPEC,
3397   /* RID_UNSIGNED */    TYPESPEC,
3398   /* RID_LONG */        TYPESPEC,
3399   /* RID_CONST */       TYPE_QUAL,
3400   /* RID_EXTERN */      SCSPEC,
3401   /* RID_REGISTER */    SCSPEC,
3402   /* RID_TYPEDEF */     SCSPEC,
3403   /* RID_SHORT */       TYPESPEC,
3404   /* RID_INLINE */      SCSPEC,
3405   /* RID_VOLATILE */    TYPE_QUAL,
3406   /* RID_SIGNED */      TYPESPEC,
3407   /* RID_AUTO */        SCSPEC,
3408   /* RID_RESTRICT */    TYPE_QUAL,
3409
3410   /* C extensions */
3411   /* RID_BOUNDED */     TYPE_QUAL,
3412   /* RID_UNBOUNDED */   TYPE_QUAL,
3413   /* RID_COMPLEX */     TYPESPEC,
3414
3415   /* C++ */
3416   /* RID_FRIEND */      0,
3417   /* RID_VIRTUAL */     0,
3418   /* RID_EXPLICIT */    0,
3419   /* RID_EXPORT */      0,
3420   /* RID_MUTABLE */     0,
3421
3422   /* ObjC */
3423   /* RID_IN */          TYPE_QUAL,
3424   /* RID_OUT */         TYPE_QUAL,
3425   /* RID_INOUT */       TYPE_QUAL,
3426   /* RID_BYCOPY */      TYPE_QUAL,
3427   /* RID_BYREF */       TYPE_QUAL,
3428   /* RID_ONEWAY */      TYPE_QUAL,
3429
3430   /* C */
3431   /* RID_INT */         TYPESPEC,
3432   /* RID_CHAR */        TYPESPEC,
3433   /* RID_FLOAT */       TYPESPEC,
3434   /* RID_DOUBLE */      TYPESPEC,
3435   /* RID_VOID */        TYPESPEC,
3436   /* RID_ENUM */        ENUM,
3437   /* RID_STRUCT */      STRUCT,
3438   /* RID_UNION */       UNION,
3439   /* RID_IF */          IF,
3440   /* RID_ELSE */        ELSE,
3441   /* RID_WHILE */       WHILE,
3442   /* RID_DO */          DO,
3443   /* RID_FOR */         FOR,
3444   /* RID_SWITCH */      SWITCH,
3445   /* RID_CASE */        CASE,
3446   /* RID_DEFAULT */     DEFAULT,
3447   /* RID_BREAK */       BREAK,
3448   /* RID_CONTINUE */    CONTINUE,
3449   /* RID_RETURN */      RETURN,
3450   /* RID_GOTO */        GOTO,
3451   /* RID_SIZEOF */      SIZEOF,
3452
3453   /* C extensions */
3454   /* RID_ASM */         ASM_KEYWORD,
3455   /* RID_TYPEOF */      TYPEOF,
3456   /* RID_ALIGNOF */     ALIGNOF,
3457   /* RID_ATTRIBUTE */   ATTRIBUTE,
3458   /* RID_VA_ARG */      VA_ARG,
3459   /* RID_EXTENSION */   EXTENSION,
3460   /* RID_IMAGPART */    IMAGPART,
3461   /* RID_REALPART */    REALPART,
3462   /* RID_LABEL */       LABEL,
3463   /* RID_PTRBASE */     PTR_BASE,
3464   /* RID_PTREXTENT */   PTR_EXTENT,
3465   /* RID_PTRVALUE */    PTR_VALUE,
3466
3467   /* RID_CHOOSE_EXPR */                 CHOOSE_EXPR,
3468   /* RID_TYPES_COMPATIBLE_P */          TYPES_COMPATIBLE_P,
3469
3470   /* RID_FUNCTION_NAME */               STRING_FUNC_NAME,
3471   /* RID_PRETTY_FUNCTION_NAME */        STRING_FUNC_NAME,
3472   /* RID_C99_FUNCTION_NAME */           VAR_FUNC_NAME,
3473
3474   /* C++ */
3475   /* RID_BOOL */        TYPESPEC,
3476   /* RID_WCHAR */       0,
3477   /* RID_CLASS */       0,
3478   /* RID_PUBLIC */      0,
3479   /* RID_PRIVATE */     0,
3480   /* RID_PROTECTED */   0,
3481   /* RID_TEMPLATE */    0,
3482   /* RID_NULL */        0,
3483   /* RID_CATCH */       0,
3484   /* RID_DELETE */      0,
3485   /* RID_FALSE */       0,
3486   /* RID_NAMESPACE */   0,
3487   /* RID_NEW */         0,
3488   /* RID_OPERATOR */    0,
3489   /* RID_THIS */        0,
3490   /* RID_THROW */       0,
3491   /* RID_TRUE */        0,
3492   /* RID_TRY */         0,
3493   /* RID_TYPENAME */    0,
3494   /* RID_TYPEID */      0,
3495   /* RID_USING */       0,
3496
3497   /* casts */
3498   /* RID_CONSTCAST */   0,
3499   /* RID_DYNCAST */     0,
3500   /* RID_REINTCAST */   0,
3501   /* RID_STATCAST */    0,
3502
3503   /* alternate spellings */
3504   /* RID_AND */         0,
3505   /* RID_AND_EQ */      0,
3506   /* RID_NOT */         0,
3507   /* RID_NOT_EQ */      0,
3508   /* RID_OR */          0,
3509   /* RID_OR_EQ */       0,
3510   /* RID_XOR */         0,
3511   /* RID_XOR_EQ */      0,
3512   /* RID_BITAND */      0,
3513   /* RID_BITOR */       0,
3514   /* RID_COMPL */       0,
3515
3516   /* Objective C */
3517   /* RID_ID */                  OBJECTNAME,
3518   /* RID_AT_ENCODE */           ENCODE,
3519   /* RID_AT_END */              END,
3520   /* RID_AT_CLASS */            CLASS,
3521   /* RID_AT_ALIAS */            ALIAS,
3522   /* RID_AT_DEFS */             DEFS,
3523   /* RID_AT_PRIVATE */          PRIVATE,
3524   /* RID_AT_PROTECTED */        PROTECTED,
3525   /* RID_AT_PUBLIC */           PUBLIC,
3526   /* RID_AT_PROTOCOL */         PROTOCOL,
3527   /* RID_AT_SELECTOR */         SELECTOR,
3528   /* RID_AT_INTERFACE */        INTERFACE,
3529   /* RID_AT_IMPLEMENTATION */   IMPLEMENTATION
3530 };
3531
3532 static void
3533 init_reswords ()
3534 {
3535   unsigned int i;
3536   tree id;
3537   int mask = (flag_isoc99 ? 0 : D_C89)
3538               | (flag_traditional ? D_TRAD : 0)
3539               | (flag_no_asm ? (flag_isoc99 ? D_EXT : D_EXT|D_EXT89) : 0);
3540
3541   if (c_language != clk_objective_c)
3542      mask |= D_OBJC;
3543
3544   /* It is not necessary to register ridpointers as a GC root, because
3545      all the trees it points to are permanently interned in the
3546      get_identifier hash anyway.  */
3547   ridpointers = (tree *) xcalloc ((int) RID_MAX, sizeof (tree));
3548   for (i = 0; i < N_reswords; i++)
3549     {
3550       /* If a keyword is disabled, do not enter it into the table
3551          and so create a canonical spelling that isn't a keyword.  */
3552       if (reswords[i].disable & mask)
3553         continue;
3554
3555       id = get_identifier (reswords[i].word);
3556       C_RID_CODE (id) = reswords[i].rid;
3557       C_IS_RESERVED_WORD (id) = 1;
3558       ridpointers [(int) reswords[i].rid] = id;
3559     }
3560 }
3561
3562 #define NAME(type) cpp_type2name (type)
3563
3564 static void
3565 yyerror (msgid)
3566      const char *msgid;
3567 {
3568   const char *string = _(msgid);
3569
3570   if (last_token == CPP_EOF)
3571     error ("%s at end of input", string);
3572   else if (last_token == CPP_CHAR || last_token == CPP_WCHAR)
3573     {
3574       unsigned int val = TREE_INT_CST_LOW (yylval.ttype);
3575       const char *const ell = (last_token == CPP_CHAR) ? "" : "L";
3576       if (val <= UCHAR_MAX && ISGRAPH (val))
3577         error ("%s before %s'%c'", string, ell, val);
3578       else
3579         error ("%s before %s'\\x%x'", string, ell, val);
3580     }
3581   else if (last_token == CPP_STRING
3582            || last_token == CPP_WSTRING)
3583     error ("%s before string constant", string);
3584   else if (last_token == CPP_NUMBER)
3585     error ("%s before numeric constant", string);
3586   else if (last_token == CPP_NAME)
3587     error ("%s before \"%s\"", string, IDENTIFIER_POINTER (yylval.ttype));
3588   else
3589     error ("%s before '%s' token", string, NAME(last_token));
3590 }
3591
3592 static int
3593 yylexname ()
3594 {
3595   tree decl;
3596
3597 ifobjc
3598   int objc_force_identifier = objc_need_raw_identifier;
3599   OBJC_NEED_RAW_IDENTIFIER (0);
3600 end ifobjc
3601
3602   if (C_IS_RESERVED_WORD (yylval.ttype))
3603     {
3604       enum rid rid_code = C_RID_CODE (yylval.ttype);
3605
3606 ifobjc
3607       /* Turn non-typedefed refs to "id" into plain identifiers; this
3608          allows constructs like "void foo(id id);" to work.  */
3609       if (rid_code == RID_ID)
3610       {
3611         decl = lookup_name (yylval.ttype);
3612         if (decl == NULL_TREE || TREE_CODE (decl) != TYPE_DECL)
3613           return IDENTIFIER;
3614       }
3615
3616       if (!OBJC_IS_AT_KEYWORD (rid_code)
3617           && (!OBJC_IS_PQ_KEYWORD (rid_code) || objc_pq_context))
3618 end ifobjc
3619       {
3620         int yycode = rid_to_yy[(int) rid_code];
3621         if (yycode == STRING_FUNC_NAME)
3622           {
3623             /* __FUNCTION__ and __PRETTY_FUNCTION__ get converted
3624                to string constants.  */
3625             const char *name = fname_string (rid_code);
3626
3627             yylval.ttype = build_string (strlen (name) + 1, name);
3628             C_ARTIFICIAL_STRING_P (yylval.ttype) = 1;
3629             last_token = CPP_STRING;  /* so yyerror won't choke */
3630             return STRING;
3631           }
3632
3633         /* Return the canonical spelling for this keyword.  */
3634         yylval.ttype = ridpointers[(int) rid_code];
3635         return yycode;
3636       }
3637     }
3638
3639   decl = lookup_name (yylval.ttype);
3640   if (decl)
3641     {
3642       if (TREE_CODE (decl) == TYPE_DECL)
3643         return TYPENAME;
3644     }
3645 ifobjc
3646   else
3647     {
3648       tree objc_interface_decl = is_class_name (yylval.ttype);
3649       /* ObjC class names are in the same namespace as variables and
3650          typedefs, and hence are shadowed by local declarations.  */
3651       if (objc_interface_decl
3652           && (global_bindings_p ()
3653               || (!objc_force_identifier && !decl)))
3654         {
3655           yylval.ttype = objc_interface_decl;
3656           return CLASSNAME;
3657         }
3658     }
3659 end ifobjc
3660
3661   return IDENTIFIER;
3662 }
3663
3664
3665 static inline int
3666 _yylex ()
3667 {
3668  get_next:
3669   last_token = c_lex (&yylval.ttype);
3670   switch (last_token)
3671     {
3672     case CPP_EQ:                                        return '=';
3673     case CPP_NOT:                                       return '!';
3674     case CPP_GREATER:   yylval.code = GT_EXPR;          return ARITHCOMPARE;
3675     case CPP_LESS:      yylval.code = LT_EXPR;          return ARITHCOMPARE;
3676     case CPP_PLUS:      yylval.code = PLUS_EXPR;        return '+';
3677     case CPP_MINUS:     yylval.code = MINUS_EXPR;       return '-';
3678     case CPP_MULT:      yylval.code = MULT_EXPR;        return '*';
3679     case CPP_DIV:       yylval.code = TRUNC_DIV_EXPR;   return '/';
3680     case CPP_MOD:       yylval.code = TRUNC_MOD_EXPR;   return '%';
3681     case CPP_AND:       yylval.code = BIT_AND_EXPR;     return '&';
3682     case CPP_OR:        yylval.code = BIT_IOR_EXPR;     return '|';
3683     case CPP_XOR:       yylval.code = BIT_XOR_EXPR;     return '^';
3684     case CPP_RSHIFT:    yylval.code = RSHIFT_EXPR;      return RSHIFT;
3685     case CPP_LSHIFT:    yylval.code = LSHIFT_EXPR;      return LSHIFT;
3686
3687     case CPP_COMPL:                                     return '~';
3688     case CPP_AND_AND:                                   return ANDAND;
3689     case CPP_OR_OR:                                     return OROR;
3690     case CPP_QUERY:                                     return '?';
3691     case CPP_OPEN_PAREN:                                return '(';
3692     case CPP_EQ_EQ:     yylval.code = EQ_EXPR;          return EQCOMPARE;
3693     case CPP_NOT_EQ:    yylval.code = NE_EXPR;          return EQCOMPARE;
3694     case CPP_GREATER_EQ:yylval.code = GE_EXPR;          return ARITHCOMPARE;
3695     case CPP_LESS_EQ:   yylval.code = LE_EXPR;          return ARITHCOMPARE;
3696
3697     case CPP_PLUS_EQ:   yylval.code = PLUS_EXPR;        return ASSIGN;
3698     case CPP_MINUS_EQ:  yylval.code = MINUS_EXPR;       return ASSIGN;
3699     case CPP_MULT_EQ:   yylval.code = MULT_EXPR;        return ASSIGN;
3700     case CPP_DIV_EQ:    yylval.code = TRUNC_DIV_EXPR;   return ASSIGN;
3701     case CPP_MOD_EQ:    yylval.code = TRUNC_MOD_EXPR;   return ASSIGN;
3702     case CPP_AND_EQ:    yylval.code = BIT_AND_EXPR;     return ASSIGN;
3703     case CPP_OR_EQ:     yylval.code = BIT_IOR_EXPR;     return ASSIGN;
3704     case CPP_XOR_EQ:    yylval.code = BIT_XOR_EXPR;     return ASSIGN;
3705     case CPP_RSHIFT_EQ: yylval.code = RSHIFT_EXPR;      return ASSIGN;
3706     case CPP_LSHIFT_EQ: yylval.code = LSHIFT_EXPR;      return ASSIGN;
3707
3708     case CPP_OPEN_SQUARE:                               return '[';
3709     case CPP_CLOSE_SQUARE:                              return ']';
3710     case CPP_OPEN_BRACE:                                return '{';
3711     case CPP_CLOSE_BRACE:                               return '}';
3712     case CPP_ELLIPSIS:                                  return ELLIPSIS;
3713
3714     case CPP_PLUS_PLUS:                                 return PLUSPLUS;
3715     case CPP_MINUS_MINUS:                               return MINUSMINUS;
3716     case CPP_DEREF:                                     return POINTSAT;
3717     case CPP_DOT:                                       return '.';
3718
3719       /* The following tokens may affect the interpretation of any
3720          identifiers following, if doing Objective-C.  */
3721     case CPP_COLON:             OBJC_NEED_RAW_IDENTIFIER (0);   return ':';
3722     case CPP_COMMA:             OBJC_NEED_RAW_IDENTIFIER (0);   return ',';
3723     case CPP_CLOSE_PAREN:       OBJC_NEED_RAW_IDENTIFIER (0);   return ')';
3724     case CPP_SEMICOLON:         OBJC_NEED_RAW_IDENTIFIER (0);   return ';';
3725
3726     case CPP_EOF:
3727       return 0;
3728
3729     case CPP_NAME:
3730       return yylexname ();
3731
3732     case CPP_NUMBER:
3733     case CPP_CHAR:
3734     case CPP_WCHAR:
3735       return CONSTANT;
3736
3737     case CPP_STRING:
3738     case CPP_WSTRING:
3739       return STRING;
3740
3741       /* This token is Objective-C specific.  It gives the next token
3742          special significance.  */
3743     case CPP_ATSIGN:
3744 ifobjc
3745       {
3746         tree after_at;
3747         enum cpp_ttype after_at_type;
3748
3749         after_at_type = c_lex (&after_at);
3750
3751         if (after_at_type == CPP_NAME
3752             && C_IS_RESERVED_WORD (after_at)
3753             && OBJC_IS_AT_KEYWORD (C_RID_CODE (after_at)))
3754           {
3755             yylval.ttype = after_at;
3756             last_token = after_at_type;
3757             return rid_to_yy [(int) C_RID_CODE (after_at)];
3758           }
3759         _cpp_backup_tokens (parse_in, 1);
3760         return '@';
3761       }
3762 end ifobjc
3763
3764       /* These tokens are C++ specific (and will not be generated
3765          in C mode, but let's be cautious).  */
3766     case CPP_SCOPE:
3767     case CPP_DEREF_STAR:
3768     case CPP_DOT_STAR:
3769     case CPP_MIN_EQ:
3770     case CPP_MAX_EQ:
3771     case CPP_MIN:
3772     case CPP_MAX:
3773       /* These tokens should not survive translation phase 4.  */
3774     case CPP_HASH:
3775     case CPP_PASTE:
3776       error ("syntax error at '%s' token", NAME(last_token));
3777       goto get_next;
3778
3779     default:
3780       abort ();
3781     }
3782   /* NOTREACHED */
3783 }
3784
3785 static int
3786 yylex()
3787 {
3788   int r;
3789   timevar_push (TV_LEX);
3790   r = _yylex();
3791   timevar_pop (TV_LEX);
3792   return r;
3793 }
3794
3795 /* Sets the value of the 'yydebug' variable to VALUE.
3796    This is a function so we don't have to have YYDEBUG defined
3797    in order to build the compiler.  */
3798
3799 void
3800 c_set_yydebug (value)
3801      int value;
3802 {
3803 #if YYDEBUG != 0
3804   yydebug = value;
3805 #else
3806   warning ("YYDEBUG not defined");
3807 #endif
3808 }
3809
3810 /* Function used when yydebug is set, to print a token in more detail.  */
3811
3812 static void
3813 yyprint (file, yychar, yyl)
3814      FILE *file;
3815      int yychar;
3816      YYSTYPE yyl;
3817 {
3818   tree t = yyl.ttype;
3819
3820   fprintf (file, " [%s]", NAME(last_token));
3821
3822   switch (yychar)
3823     {
3824     case IDENTIFIER:
3825     case TYPENAME:
3826     case OBJECTNAME:
3827     case TYPESPEC:
3828     case TYPE_QUAL:
3829     case SCSPEC:
3830       if (IDENTIFIER_POINTER (t))
3831         fprintf (file, " `%s'", IDENTIFIER_POINTER (t));
3832       break;
3833
3834     case CONSTANT:
3835       fprintf (file, " %s", GET_MODE_NAME (TYPE_MODE (TREE_TYPE (t))));
3836       if (TREE_CODE (t) == INTEGER_CST)
3837         fprintf (file,
3838 #if HOST_BITS_PER_WIDE_INT == 64
3839 #if HOST_BITS_PER_WIDE_INT == HOST_BITS_PER_INT
3840                  " 0x%x%016x",
3841 #else
3842 #if HOST_BITS_PER_WIDE_INT == HOST_BITS_PER_LONG
3843                  " 0x%lx%016lx",
3844 #else
3845                  " 0x%llx%016llx",
3846 #endif
3847 #endif
3848 #else
3849 #if HOST_BITS_PER_WIDE_INT != HOST_BITS_PER_INT
3850                  " 0x%lx%08lx",
3851 #else
3852                  " 0x%x%08x",
3853 #endif
3854 #endif
3855                  TREE_INT_CST_HIGH (t), TREE_INT_CST_LOW (t));
3856       break;
3857     }
3858 }
3859 \f
3860 /* This is not the ideal place to put these, but we have to get them out
3861    of c-lex.c because cp/lex.c has its own versions.  */
3862
3863 /* Return something to represent absolute declarators containing a *.
3864    TARGET is the absolute declarator that the * contains.
3865    TYPE_QUALS_ATTRS is a list of modifiers such as const or volatile
3866    to apply to the pointer type, represented as identifiers, possible mixed
3867    with attributes.
3868
3869    We return an INDIRECT_REF whose "contents" are TARGET (inside a TREE_LIST,
3870    if attributes are present) and whose type is the modifier list.  */
3871
3872 tree
3873 make_pointer_declarator (type_quals_attrs, target)
3874      tree type_quals_attrs, target;
3875 {
3876   tree quals, attrs;
3877   tree itarget = target;
3878   split_specs_attrs (type_quals_attrs, &quals, &attrs);
3879   if (attrs != NULL_TREE)
3880     itarget = tree_cons (attrs, target, NULL_TREE);
3881   return build1 (INDIRECT_REF, quals, itarget);
3882 }