gcc/ada/uintp.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                U I N T P                                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Output;  use Output;
  35 with Tree_IO; use Tree_IO;
  36
  37 with GNAT.HTable; use GNAT.HTable;
  38
  39 package body Uintp is
  40
  41    ------------------------
  42    -- Local Declarations --
  43    ------------------------
  44
  45    Uint_Int_First : Uint := Uint_0;
  46    --  Uint value containing Int'First value, set by Initialize. The initial
  47    --  value of Uint_0 is used for an assertion check that ensures that this
  48    --  value is not used before it is initialized. This value is used in the
  49    --  UI_Is_In_Int_Range predicate, and it is right that this is a host value,
  50    --  since the issue is host representation of integer values.
  51
  52    Uint_Int_Last : Uint;
  53    --  Uint value containing Int'Last value set by Initialize
  54
  55    UI_Power_2 : array (Int range 0 .. 64) of Uint;
  56    --  This table is used to memoize exponentiations by powers of 2. The Nth
  57    --  entry, if set, contains the Uint value 2 ** N. Initially UI_Power_2_Set
  58    --  is zero and only the 0'th entry is set, the invariant being that all
  59    --  entries in the range 0 .. UI_Power_2_Set are initialized.
  60
  61    UI_Power_2_Set : Nat;
  62    --  Number of entries set in UI_Power_2;
  63
  64    UI_Power_10 : array (Int range 0 .. 64) of Uint;
  65    --  This table is used to memoize exponentiations by powers of 10 in the
  66    --  same manner as described above for UI_Power_2.
  67
  68    UI_Power_10_Set : Nat;
  69    --  Number of entries set in UI_Power_10;
  70
  71    Uints_Min   : Uint;
  72    Udigits_Min : Int;
  73    --  These values are used to make sure that the mark/release mechanism does
  74    --  not destroy values saved in the U_Power tables or in the hash table used
  75    --  by UI_From_Int. Whenever an entry is made in either of these tabls,
  76    --  Uints_Min and Udigits_Min are updated to protect the entry, and Release
  77    --  never cuts back beyond these minimum values.
  78
  79    Int_0 : constant Int := 0;
  80    Int_1 : constant Int := 1;
  81    Int_2 : constant Int := 2;
  82    --  These values are used in some cases where the use of numeric literals
  83    --  would cause ambiguities (integer vs Uint).
  84
  85    ----------------------------
  86    -- UI_From_Int Hash Table --
  87    ----------------------------
  88
  89    --  UI_From_Int uses a hash table to avoid duplicating entries and wasting
  90    --  storage. This is particularly important for complex cases of back
  91    --  annotation.
  92
  93    subtype Hnum is Nat range 0 .. 1022;
  94
  95    function Hash_Num (F : Int) return Hnum;
  96    --  Hashing function
  97
  98    package UI_Ints is new Simple_HTable (
  99      Header_Num => Hnum,
 100      Element    => Uint,
 101      No_Element => No_Uint,
 102      Key        => Int,
 103      Hash       => Hash_Num,
 104      Equal      => "=");
 105
 106    -----------------------
 107    -- Local Subprograms --
 108    -----------------------
 109
 110    function Direct (U : Uint) return Boolean;
 111    pragma Inline (Direct);
 112    --  Returns True if U is represented directly
 113
 114    function Direct_Val (U : Uint) return Int;
 115    --  U is a Uint for is represented directly. The returned result is the
 116    --  value represented.
 117
 118    function GCD (Jin, Kin : Int) return Int;
 119    --  Compute GCD of two integers. Assumes that Jin >= Kin >= 0
 120
 121    procedure Image_Out
 122      (Input     : Uint;
 123       To_Buffer : Boolean;
 124       Format    : UI_Format);
 125    --  Common processing for UI_Image and UI_Write, To_Buffer is set True for
 126    --  UI_Image, and false for UI_Write, and Format is copied from the Format
 127    --  parameter to UI_Image or UI_Write.
 128
 129    procedure Init_Operand (UI : Uint; Vec : out UI_Vector);
 130    pragma Inline (Init_Operand);
 131    --  This procedure puts the value of UI into the vector in canonical
 132    --  multiple precision format. The parameter should be of the correct size
 133    --  as determined by a previous call to N_Digits (UI). The first digit of
 134    --  Vec contains the sign, all other digits are always non- negative. Note
 135    --  that the input may be directly represented, and in this case Vec will
 136    --  contain the corresponding one or two digit value. The low bound of Vec
 137    --  is always 1.
 138
 139    function Least_Sig_Digit (Arg : Uint) return Int;
 140    pragma Inline (Least_Sig_Digit);
 141    --  Returns the Least Significant Digit of Arg quickly. When the given Uint
 142    --  is less than 2**15, the value returned is the input value, in this case
 143    --  the result may be negative. It is expected that any use will mask off
 144    --  unnecessary bits. This is used for finding Arg mod B where B is a power
 145    --  of two. Hence the actual base is irrelevent as long as it is a power of
 146    --  two.
 147
 148    procedure Most_Sig_2_Digits
 149      (Left      : Uint;
 150       Right     : Uint;
 151       Left_Hat  : out Int;
 152       Right_Hat : out Int);
 153    --  Returns leading two significant digits from the given pair of Uint's.
 154    --  Mathematically: returns Left / (Base ** K) and Right / (Base ** K) where
 155    --  K is as small as possible S.T. Right_Hat < Base * Base. It is required
 156    --  that Left > Right for the algorithm to work.
 157
 158    function N_Digits (Input : Uint) return Int;
 159    pragma Inline (N_Digits);
 160    --  Returns number of "digits" in a Uint
 161
 162    function Sum_Digits (Left : Uint; Sign : Int) return Int;
 163    --  If Sign = 1 return the sum of the "digits" of Abs (Left). If the total
 164    --  has more then one digit then return Sum_Digits of total.
 165
 166    function Sum_Double_Digits (Left : Uint; Sign : Int) return Int;
 167    --  Same as above but work in New_Base = Base * Base
 168
 169    procedure UI_Div_Rem
 170      (Left, Right       : Uint;
 171       Quotient          : out Uint;
 172       Remainder         : out Uint;
 173       Discard_Quotient  : Boolean;
 174       Discard_Remainder : Boolean);
 175    --  Compute euclidian division of Left by Right, and return Quotient and
 176    --  signed Remainder (Left rem Right).
 177    --
 178    --    If Discard_Quotient is True, Quotient is left unchanged.
 179    --    If Discard_Remainder is True, Remainder is left unchanged.
 180
 181    function Vector_To_Uint
 182      (In_Vec   : UI_Vector;
 183       Negative : Boolean) return Uint;
 184    --  Functions that calculate values in UI_Vectors, call this function to
 185    --  create and return the Uint value. In_Vec contains the multiple precision
 186    --  (Base) representation of a non-negative value. Leading zeroes are
 187    --  permitted. Negative is set if the desired result is the negative of the
 188    --  given value. The result will be either the appropriate directly
 189    --  represented value, or a table entry in the proper canonical format is
 190    --  created and returned.
 191    --
 192    --  Note that Init_Operand puts a signed value in the result vector, but
 193    --  Vector_To_Uint is always presented with a non-negative value. The
 194    --  processing of signs is something that is done by the caller before
 195    --  calling Vector_To_Uint.
 196
 197    ------------
 198    -- Direct --
 199    ------------
 200
 201    function Direct (U : Uint) return Boolean is
 202    begin
 203       return Int (U) <= Int (Uint_Direct_Last);
 204    end Direct;
 205
 206    ----------------
 207    -- Direct_Val --
 208    ----------------
 209
 210    function Direct_Val (U : Uint) return Int is
 211    begin
 212       pragma Assert (Direct (U));
 213       return Int (U) - Int (Uint_Direct_Bias);
 214    end Direct_Val;
 215
 216    ---------
 217    -- GCD --
 218    ---------
 219
 220    function GCD (Jin, Kin : Int) return Int is
 221       J, K, Tmp : Int;
 222
 223    begin
 224       pragma Assert (Jin >= Kin);
 225       pragma Assert (Kin >= Int_0);
 226
 227       J := Jin;
 228       K := Kin;
 229       while K /= Uint_0 loop
 230          Tmp := J mod K;
 231          J := K;
 232          K := Tmp;
 233       end loop;
 234
 235       return J;
 236    end GCD;
 237
 238    --------------
 239    -- Hash_Num --
 240    --------------
 241
 242    function Hash_Num (F : Int) return Hnum is
 243    begin
 244       return Standard."mod" (F, Hnum'Range_Length);
 245    end Hash_Num;
 246
 247    ---------------
 248    -- Image_Out --
 249    ---------------
 250
 251    procedure Image_Out
 252      (Input     : Uint;
 253       To_Buffer : Boolean;
 254       Format    : UI_Format)
 255    is
 256       Marks  : constant Uintp.Save_Mark := Uintp.Mark;
 257       Base   : Uint;
 258       Ainput : Uint;
 259
 260       Digs_Output : Natural := 0;
 261       --  Counts digits output. In hex mode, but not in decimal mode, we
 262       --  put an underline after every four hex digits that are output.
 263
 264       Exponent : Natural := 0;
 265       --  If the number is too long to fit in the buffer, we switch to an
 266       --  approximate output format with an exponent. This variable records
 267       --  the exponent value.
 268
 269       function Better_In_Hex return Boolean;
 270       --  Determines if it is better to generate digits in base 16 (result
 271       --  is true) or base 10 (result is false). The choice is purely a
 272       --  matter of convenience and aesthetics, so it does not matter which
 273       --  value is returned from a correctness point of view.
 274
 275       procedure Image_Char (C : Character);
 276       --  Internal procedure to output one character
 277
 278       procedure Image_Exponent (N : Natural);
 279       --  Output non-zero exponent. Note that we only use the exponent form in
 280       --  the buffer case, so we know that To_Buffer is true.
 281
 282       procedure Image_Uint (U : Uint);
 283       --  Internal procedure to output characters of non-negative Uint
 284
 285       -------------------
 286       -- Better_In_Hex --
 287       -------------------
 288
 289       function Better_In_Hex return Boolean is
 290          T16 : constant Uint := Uint_2 ** Int'(16);
 291          A   : Uint;
 292
 293       begin
 294          A := UI_Abs (Input);
 295
 296          --  Small values up to 2**16 can always be in decimal
 297
 298          if A < T16 then
 299             return False;
 300          end if;
 301
 302          --  Otherwise, see if we are a power of 2 or one less than a power
 303          --  of 2. For the moment these are the only cases printed in hex.
 304
 305          if A mod Uint_2 = Uint_1 then
 306             A := A + Uint_1;
 307          end if;
 308
 309          loop
 310             if A mod T16 /= Uint_0 then
 311                return False;
 312
 313             else
 314                A := A / T16;
 315             end if;
 316
 317             exit when A < T16;
 318          end loop;
 319
 320          while A > Uint_2 loop
 321             if A mod Uint_2 /= Uint_0 then
 322                return False;
 323
 324             else
 325                A := A / Uint_2;
 326             end if;
 327          end loop;
 328
 329          return True;
 330       end Better_In_Hex;
 331
 332       ----------------
 333       -- Image_Char --
 334       ----------------
 335
 336       procedure Image_Char (C : Character) is
 337       begin
 338          if To_Buffer then
 339             if UI_Image_Length + 6 > UI_Image_Max then
 340                Exponent := Exponent + 1;
 341             else
 342                UI_Image_Length := UI_Image_Length + 1;
 343                UI_Image_Buffer (UI_Image_Length) := C;
 344             end if;
 345          else
 346             Write_Char (C);
 347          end if;
 348       end Image_Char;
 349
 350       --------------------
 351       -- Image_Exponent --
 352       --------------------
 353
 354       procedure Image_Exponent (N : Natural) is
 355       begin
 356          if N >= 10 then
 357             Image_Exponent (N / 10);
 358          end if;
 359
 360          UI_Image_Length := UI_Image_Length + 1;
 361          UI_Image_Buffer (UI_Image_Length) :=
 362            Character'Val (Character'Pos ('0') + N mod 10);
 363       end Image_Exponent;
 364
 365       ----------------
 366       -- Image_Uint --
 367       ----------------
 368
 369       procedure Image_Uint (U : Uint) is
 370          H : constant array (Int range 0 .. 15) of Character :=
 371                "0123456789ABCDEF";
 372
 373       begin
 374          if U >= Base then
 375             Image_Uint (U / Base);
 376          end if;
 377
 378          if Digs_Output = 4 and then Base = Uint_16 then
 379             Image_Char ('_');
 380             Digs_Output := 0;
 381          end if;
 382
 383          Image_Char (H (UI_To_Int (U rem Base)));
 384
 385          Digs_Output := Digs_Output + 1;
 386       end Image_Uint;
 387
 388    --  Start of processing for Image_Out
 389
 390    begin
 391       if Input = No_Uint then
 392          Image_Char ('?');
 393          return;
 394       end if;
 395
 396       UI_Image_Length := 0;
 397
 398       if Input < Uint_0 then
 399          Image_Char ('-');
 400          Ainput := -Input;
 401       else
 402          Ainput := Input;
 403       end if;
 404
 405       if Format = Hex
 406         or else (Format = Auto and then Better_In_Hex)
 407       then
 408          Base := Uint_16;
 409          Image_Char ('1');
 410          Image_Char ('6');
 411          Image_Char ('#');
 412          Image_Uint (Ainput);
 413          Image_Char ('#');
 414
 415       else
 416          Base := Uint_10;
 417          Image_Uint (Ainput);
 418       end if;
 419
 420       if Exponent /= 0 then
 421          UI_Image_Length := UI_Image_Length + 1;
 422          UI_Image_Buffer (UI_Image_Length) := 'E';
 423          Image_Exponent (Exponent);
 424       end if;
 425
 426       Uintp.Release (Marks);
 427    end Image_Out;
 428
 429    -------------------
 430    -- Init_Operand --
 431    -------------------
 432
 433    procedure Init_Operand (UI : Uint; Vec : out UI_Vector) is
 434       Loc : Int;
 435
 436       pragma Assert (Vec'First = Int'(1));
 437
 438    begin
 439       if Direct (UI) then
 440          Vec (1) := Direct_Val (UI);
 441
 442          if Vec (1) >= Base then
 443             Vec (2) := Vec (1) rem Base;
 444             Vec (1) := Vec (1) / Base;
 445          end if;
 446
 447       else
 448          Loc := Uints.Table (UI).Loc;
 449
 450          for J in 1 .. Uints.Table (UI).Length loop
 451             Vec (J) := Udigits.Table (Loc + J - 1);
 452          end loop;
 453       end if;
 454    end Init_Operand;
 455
 456    ----------------
 457    -- Initialize --
 458    ----------------
 459
 460    procedure Initialize is
 461    begin
 462       Uints.Init;
 463       Udigits.Init;
 464
 465       Uint_Int_First := UI_From_Int (Int'First);
 466       Uint_Int_Last  := UI_From_Int (Int'Last);
 467
 468       UI_Power_2 (0) := Uint_1;
 469       UI_Power_2_Set := 0;
 470
 471       UI_Power_10 (0) := Uint_1;
 472       UI_Power_10_Set := 0;
 473
 474       Uints_Min := Uints.Last;
 475       Udigits_Min := Udigits.Last;
 476
 477       UI_Ints.Reset;
 478    end Initialize;
 479
 480    ---------------------
 481    -- Least_Sig_Digit --
 482    ---------------------
 483
 484    function Least_Sig_Digit (Arg : Uint) return Int is
 485       V : Int;
 486
 487    begin
 488       if Direct (Arg) then
 489          V := Direct_Val (Arg);
 490
 491          if V >= Base then
 492             V := V mod Base;
 493          end if;
 494
 495          --  Note that this result may be negative
 496
 497          return V;
 498
 499       else
 500          return
 501            Udigits.Table
 502             (Uints.Table (Arg).Loc + Uints.Table (Arg).Length - 1);
 503       end if;
 504    end Least_Sig_Digit;
 505
 506    ----------
 507    -- Mark --
 508    ----------
 509
 510    function Mark return Save_Mark is
 511    begin
 512       return (Save_Uint => Uints.Last, Save_Udigit => Udigits.Last);
 513    end Mark;
 514
 515    -----------------------
 516    -- Most_Sig_2_Digits --
 517    -----------------------
 518
 519    procedure Most_Sig_2_Digits
 520      (Left      : Uint;
 521       Right     : Uint;
 522       Left_Hat  : out Int;
 523       Right_Hat : out Int)
 524    is
 525    begin
 526       pragma Assert (Left >= Right);
 527
 528       if Direct (Left) then
 529          Left_Hat  := Direct_Val (Left);
 530          Right_Hat := Direct_Val (Right);
 531          return;
 532
 533       else
 534          declare
 535             L1 : constant Int :=
 536                    Udigits.Table (Uints.Table (Left).Loc);
 537             L2 : constant Int :=
 538                    Udigits.Table (Uints.Table (Left).Loc + 1);
 539
 540          begin
 541             --  It is not so clear what to return when Arg is negative???
 542
 543             Left_Hat := abs (L1) * Base + L2;
 544          end;
 545       end if;
 546
 547       declare
 548          Length_L : constant Int := Uints.Table (Left).Length;
 549          Length_R : Int;
 550          R1 : Int;
 551          R2 : Int;
 552          T  : Int;
 553
 554       begin
 555          if Direct (Right) then
 556             T := Direct_Val (Left);
 557             R1 := abs (T / Base);
 558             R2 := T rem Base;
 559             Length_R := 2;
 560
 561          else
 562             R1 := abs (Udigits.Table (Uints.Table (Right).Loc));
 563             R2 := Udigits.Table (Uints.Table (Right).Loc + 1);
 564             Length_R := Uints.Table (Right).Length;
 565          end if;
 566
 567          if Length_L = Length_R then
 568             Right_Hat := R1 * Base + R2;
 569          elsif Length_L = Length_R + Int_1 then
 570             Right_Hat := R1;
 571          else
 572             Right_Hat := 0;
 573          end if;
 574       end;
 575    end Most_Sig_2_Digits;
 576
 577    ---------------
 578    -- N_Digits --
 579    ---------------
 580
 581    --  Note: N_Digits returns 1 for No_Uint
 582
 583    function N_Digits (Input : Uint) return Int is
 584    begin
 585       if Direct (Input) then
 586          if Direct_Val (Input) >= Base then
 587             return 2;
 588          else
 589             return 1;
 590          end if;
 591
 592       else
 593          return Uints.Table (Input).Length;
 594       end if;
 595    end N_Digits;
 596
 597    --------------
 598    -- Num_Bits --
 599    --------------
 600
 601    function Num_Bits (Input : Uint) return Nat is
 602       Bits : Nat;
 603       Num  : Nat;
 604
 605    begin
 606       --  Largest negative number has to be handled specially, since it is in
 607       --  Int_Range, but we cannot take the absolute value.
 608
 609       if Input = Uint_Int_First then
 610          return Int'Size;
 611
 612       --  For any other number in Int_Range, get absolute value of number
 613
 614       elsif UI_Is_In_Int_Range (Input) then
 615          Num := abs (UI_To_Int (Input));
 616          Bits := 0;
 617
 618       --  If not in Int_Range then initialize bit count for all low order
 619       --  words, and set number to high order digit.
 620
 621       else
 622          Bits := Base_Bits * (Uints.Table (Input).Length - 1);
 623          Num  := abs (Udigits.Table (Uints.Table (Input).Loc));
 624       end if;
 625
 626       --  Increase bit count for remaining value in Num
 627
 628       while Types.">" (Num, 0) loop
 629          Num := Num / 2;
 630          Bits := Bits + 1;
 631       end loop;
 632
 633       return Bits;
 634    end Num_Bits;
 635
 636    ---------
 637    -- pid --
 638    ---------
 639
 640    procedure pid (Input : Uint) is
 641    begin
 642       UI_Write (Input, Decimal);
 643       Write_Eol;
 644    end pid;
 645
 646    ---------
 647    -- pih --
 648    ---------
 649
 650    procedure pih (Input : Uint) is
 651    begin
 652       UI_Write (Input, Hex);
 653       Write_Eol;
 654    end pih;
 655
 656    -------------
 657    -- Release --
 658    -------------
 659
 660    procedure Release (M : Save_Mark) is
 661    begin
 662       Uints.Set_Last   (Uint'Max (M.Save_Uint,   Uints_Min));
 663       Udigits.Set_Last (Int'Max  (M.Save_Udigit, Udigits_Min));
 664    end Release;
 665
 666    ----------------------
 667    -- Release_And_Save --
 668    ----------------------
 669
 670    procedure Release_And_Save (M : Save_Mark; UI : in out Uint) is
 671    begin
 672       if Direct (UI) then
 673          Release (M);
 674
 675       else
 676          declare
 677             UE_Len : constant Pos := Uints.Table (UI).Length;
 678             UE_Loc : constant Int := Uints.Table (UI).Loc;
 679
 680             UD : constant Udigits.Table_Type (1 .. UE_Len) :=
 681                    Udigits.Table (UE_Loc .. UE_Loc + UE_Len - 1);
 682
 683          begin
 684             Release (M);
 685
 686             Uints.Increment_Last;
 687             UI := Uints.Last;
 688
 689             Uints.Table (UI) := (UE_Len, Udigits.Last + 1);
 690
 691             for J in 1 .. UE_Len loop
 692                Udigits.Increment_Last;
 693                Udigits.Table (Udigits.Last) := UD (J);
 694             end loop;
 695          end;
 696       end if;
 697    end Release_And_Save;
 698
 699    procedure Release_And_Save (M : Save_Mark; UI1, UI2 : in out Uint) is
 700    begin
 701       if Direct (UI1) then
 702          Release_And_Save (M, UI2);
 703
 704       elsif Direct (UI2) then
 705          Release_And_Save (M, UI1);
 706
 707       else
 708          declare
 709             UE1_Len : constant Pos := Uints.Table (UI1).Length;
 710             UE1_Loc : constant Int := Uints.Table (UI1).Loc;
 711
 712             UD1 : constant Udigits.Table_Type (1 .. UE1_Len) :=
 713                     Udigits.Table (UE1_Loc .. UE1_Loc + UE1_Len - 1);
 714
 715             UE2_Len : constant Pos := Uints.Table (UI2).Length;
 716             UE2_Loc : constant Int := Uints.Table (UI2).Loc;
 717
 718             UD2 : constant Udigits.Table_Type (1 .. UE2_Len) :=
 719                     Udigits.Table (UE2_Loc .. UE2_Loc + UE2_Len - 1);
 720
 721          begin
 722             Release (M);
 723
 724             Uints.Increment_Last;
 725             UI1 := Uints.Last;
 726
 727             Uints.Table (UI1) := (UE1_Len, Udigits.Last + 1);
 728
 729             for J in 1 .. UE1_Len loop
 730                Udigits.Increment_Last;
 731                Udigits.Table (Udigits.Last) := UD1 (J);
 732             end loop;
 733
 734             Uints.Increment_Last;
 735             UI2 := Uints.Last;
 736
 737             Uints.Table (UI2) := (UE2_Len, Udigits.Last + 1);
 738
 739             for J in 1 .. UE2_Len loop
 740                Udigits.Increment_Last;
 741                Udigits.Table (Udigits.Last) := UD2 (J);
 742             end loop;
 743          end;
 744       end if;
 745    end Release_And_Save;
 746
 747    ----------------
 748    -- Sum_Digits --
 749    ----------------
 750
 751    --  This is done in one pass
 752
 753    --  Mathematically: assume base congruent to 1 and compute an equivelent
 754    --  integer to Left.
 755
 756    --  If Sign = -1 return the alternating sum of the "digits"
 757
 758    --     D1 - D2 + D3 - D4 + D5 ...
 759
 760    --  (where D1 is Least Significant Digit)
 761
 762    --  Mathematically: assume base congruent to -1 and compute an equivelent
 763    --  integer to Left.
 764
 765    --  This is used in Rem and Base is assumed to be 2 ** 15
 766
 767    --  Note: The next two functions are very similar, any style changes made
 768    --  to one should be reflected in both.  These would be simpler if we
 769    --  worked base 2 ** 32.
 770
 771    function Sum_Digits (Left : Uint; Sign : Int) return Int is
 772    begin
 773       pragma Assert (Sign = Int_1 or Sign = Int (-1));
 774
 775       --  First try simple case;
 776
 777       if Direct (Left) then
 778          declare
 779             Tmp_Int : Int := Direct_Val (Left);
 780
 781          begin
 782             if Tmp_Int >= Base then
 783                Tmp_Int := (Tmp_Int / Base) +
 784                   Sign * (Tmp_Int rem Base);
 785
 786                   --  Now Tmp_Int is in [-(Base - 1) .. 2 * (Base - 1)]
 787
 788                if Tmp_Int >= Base then
 789
 790                   --  Sign must be 1
 791
 792                   Tmp_Int := (Tmp_Int / Base) + 1;
 793
 794                end if;
 795
 796                --  Now Tmp_Int is in [-(Base - 1) .. (Base - 1)]
 797
 798             end if;
 799
 800             return Tmp_Int;
 801          end;
 802
 803       --  Otherwise full circuit is needed
 804
 805       else
 806          declare
 807             L_Length : constant Int := N_Digits (Left);
 808             L_Vec    : UI_Vector (1 .. L_Length);
 809             Tmp_Int  : Int;
 810             Carry    : Int;
 811             Alt      : Int;
 812
 813          begin
 814             Init_Operand (Left, L_Vec);
 815             L_Vec (1) := abs L_Vec (1);
 816             Tmp_Int := 0;
 817             Carry := 0;
 818             Alt := 1;
 819
 820             for J in reverse 1 .. L_Length loop
 821                Tmp_Int := Tmp_Int + Alt * (L_Vec (J) + Carry);
 822
 823                --  Tmp_Int is now between [-2 * Base + 1 .. 2 * Base - 1],
 824                --  since old Tmp_Int is between [-(Base - 1) .. Base - 1]
 825                --  and L_Vec is in [0 .. Base - 1] and Carry in [-1 .. 1]
 826
 827                if Tmp_Int >= Base then
 828                   Tmp_Int := Tmp_Int - Base;
 829                   Carry := 1;
 830
 831                elsif Tmp_Int <= -Base then
 832                   Tmp_Int := Tmp_Int + Base;
 833                   Carry := -1;
 834
 835                else
 836                   Carry := 0;
 837                end if;
 838
 839                --  Tmp_Int is now between [-Base + 1 .. Base - 1]
 840
 841                Alt := Alt * Sign;
 842             end loop;
 843
 844             Tmp_Int := Tmp_Int + Alt * Carry;
 845
 846             --  Tmp_Int is now between [-Base .. Base]
 847
 848             if Tmp_Int >= Base then
 849                Tmp_Int := Tmp_Int - Base + Alt * Sign * 1;
 850
 851             elsif Tmp_Int <= -Base then
 852                Tmp_Int := Tmp_Int + Base + Alt * Sign * (-1);
 853             end if;
 854
 855             --  Now Tmp_Int is in [-(Base - 1) .. (Base - 1)]
 856
 857             return Tmp_Int;
 858          end;
 859       end if;
 860    end Sum_Digits;
 861
 862    -----------------------
 863    -- Sum_Double_Digits --
 864    -----------------------
 865
 866    --  Note: This is used in Rem, Base is assumed to be 2 ** 15
 867
 868    function Sum_Double_Digits (Left : Uint; Sign : Int) return Int is
 869    begin
 870       --  First try simple case;
 871
 872       pragma Assert (Sign = Int_1 or Sign = Int (-1));
 873
 874       if Direct (Left) then
 875          return Direct_Val (Left);
 876
 877       --  Otherwise full circuit is needed
 878
 879       else
 880          declare
 881             L_Length      : constant Int := N_Digits (Left);
 882             L_Vec         : UI_Vector (1 .. L_Length);
 883             Most_Sig_Int  : Int;
 884             Least_Sig_Int : Int;
 885             Carry         : Int;
 886             J             : Int;
 887             Alt           : Int;
 888
 889          begin
 890             Init_Operand (Left, L_Vec);
 891             L_Vec (1) := abs L_Vec (1);
 892             Most_Sig_Int := 0;
 893             Least_Sig_Int := 0;
 894             Carry := 0;
 895             Alt := 1;
 896             J := L_Length;
 897
 898             while J > Int_1 loop
 899                Least_Sig_Int := Least_Sig_Int + Alt * (L_Vec (J) + Carry);
 900
 901                --  Least is in [-2 Base + 1 .. 2 * Base - 1]
 902                --  Since L_Vec in [0 .. Base - 1] and Carry in [-1 .. 1]
 903                --  and old Least in [-Base + 1 .. Base - 1]
 904
 905                if Least_Sig_Int >= Base then
 906                   Least_Sig_Int := Least_Sig_Int - Base;
 907                   Carry := 1;
 908
 909                elsif Least_Sig_Int <= -Base then
 910                   Least_Sig_Int := Least_Sig_Int + Base;
 911                   Carry := -1;
 912
 913                else
 914                   Carry := 0;
 915                end if;
 916
 917                --  Least is now in [-Base + 1 .. Base - 1]
 918
 919                Most_Sig_Int := Most_Sig_Int + Alt * (L_Vec (J - 1) + Carry);
 920
 921                --  Most is in [-2 Base + 1 .. 2 * Base - 1]
 922                --  Since L_Vec in [0 ..  Base - 1] and Carry in  [-1 .. 1]
 923                --  and old Most in [-Base + 1 .. Base - 1]
 924
 925                if Most_Sig_Int >= Base then
 926                   Most_Sig_Int := Most_Sig_Int - Base;
 927                   Carry := 1;
 928
 929                elsif Most_Sig_Int <= -Base then
 930                   Most_Sig_Int := Most_Sig_Int + Base;
 931                   Carry := -1;
 932                else
 933                   Carry := 0;
 934                end if;
 935
 936                --  Most is now in [-Base + 1 .. Base - 1]
 937
 938                J := J - 2;
 939                Alt := Alt * Sign;
 940             end loop;
 941
 942             if J = Int_1 then
 943                Least_Sig_Int := Least_Sig_Int + Alt * (L_Vec (J) + Carry);
 944             else
 945                Least_Sig_Int := Least_Sig_Int + Alt * Carry;
 946             end if;
 947
 948             if Least_Sig_Int >= Base then
 949                Least_Sig_Int := Least_Sig_Int - Base;
 950                Most_Sig_Int := Most_Sig_Int + Alt * 1;
 951
 952             elsif Least_Sig_Int <= -Base then
 953                Least_Sig_Int := Least_Sig_Int + Base;
 954                Most_Sig_Int := Most_Sig_Int + Alt * (-1);
 955             end if;
 956
 957             if Most_Sig_Int >= Base then
 958                Most_Sig_Int := Most_Sig_Int - Base;
 959                Alt := Alt * Sign;
 960                Least_Sig_Int :=
 961                  Least_Sig_Int + Alt * 1; -- cannot overflow again
 962
 963             elsif Most_Sig_Int <= -Base then
 964                Most_Sig_Int := Most_Sig_Int + Base;
 965                Alt := Alt * Sign;
 966                Least_Sig_Int :=
 967                  Least_Sig_Int + Alt * (-1); --  cannot overflow again.
 968             end if;
 969
 970             return Most_Sig_Int * Base + Least_Sig_Int;
 971          end;
 972       end if;
 973    end Sum_Double_Digits;
 974
 975    ---------------
 976    -- Tree_Read --
 977    ---------------
 978
 979    procedure Tree_Read is
 980    begin
 981       Uints.Tree_Read;
 982       Udigits.Tree_Read;
 983
 984       Tree_Read_Int (Int (Uint_Int_First));
 985       Tree_Read_Int (Int (Uint_Int_Last));
 986       Tree_Read_Int (UI_Power_2_Set);
 987       Tree_Read_Int (UI_Power_10_Set);
 988       Tree_Read_Int (Int (Uints_Min));
 989       Tree_Read_Int (Udigits_Min);
 990
 991       for J in 0 .. UI_Power_2_Set loop
 992          Tree_Read_Int (Int (UI_Power_2 (J)));
 993       end loop;
 994
 995       for J in 0 .. UI_Power_10_Set loop
 996          Tree_Read_Int (Int (UI_Power_10 (J)));
 997       end loop;
 998
 999    end Tree_Read;
1000
1001    ----------------
1002    -- Tree_Write --
1003    ----------------
1004
1005    procedure Tree_Write is
1006    begin
1007       Uints.Tree_Write;
1008       Udigits.Tree_Write;
1009
1010       Tree_Write_Int (Int (Uint_Int_First));
1011       Tree_Write_Int (Int (Uint_Int_Last));
1012       Tree_Write_Int (UI_Power_2_Set);
1013       Tree_Write_Int (UI_Power_10_Set);
1014       Tree_Write_Int (Int (Uints_Min));
1015       Tree_Write_Int (Udigits_Min);
1016
1017       for J in 0 .. UI_Power_2_Set loop
1018          Tree_Write_Int (Int (UI_Power_2 (J)));
1019       end loop;
1020
1021       for J in 0 .. UI_Power_10_Set loop
1022          Tree_Write_Int (Int (UI_Power_10 (J)));
1023       end loop;
1024
1025    end Tree_Write;
1026
1027    -------------
1028    -- UI_Abs --
1029    -------------
1030
1031    function UI_Abs (Right : Uint) return Uint is
1032    begin
1033       if Right < Uint_0 then
1034          return -Right;
1035       else
1036          return Right;
1037       end if;
1038    end UI_Abs;
1039
1040    -------------
1041    -- UI_Add --
1042    -------------
1043
1044    function UI_Add (Left : Int; Right : Uint) return Uint is
1045    begin
1046       return UI_Add (UI_From_Int (Left), Right);
1047    end UI_Add;
1048
1049    function UI_Add (Left : Uint; Right : Int) return Uint is
1050    begin
1051       return UI_Add (Left, UI_From_Int (Right));
1052    end UI_Add;
1053
1054    function UI_Add (Left : Uint; Right : Uint) return Uint is
1055    begin
1056       --  Simple cases of direct operands and addition of zero
1057
1058       if Direct (Left) then
1059          if Direct (Right) then
1060             return UI_From_Int (Direct_Val (Left) + Direct_Val (Right));
1061
1062          elsif Int (Left) = Int (Uint_0) then
1063             return Right;
1064          end if;
1065
1066       elsif Direct (Right) and then Int (Right) = Int (Uint_0) then
1067          return Left;
1068       end if;
1069
1070       --  Otherwise full circuit is needed
1071
1072       declare
1073          L_Length   : constant Int := N_Digits (Left);
1074          R_Length   : constant Int := N_Digits (Right);
1075          L_Vec      : UI_Vector (1 .. L_Length);
1076          R_Vec      : UI_Vector (1 .. R_Length);
1077          Sum_Length : Int;
1078          Tmp_Int    : Int;
1079          Carry      : Int;
1080          Borrow     : Int;
1081          X_Bigger   : Boolean := False;
1082          Y_Bigger   : Boolean := False;
1083          Result_Neg : Boolean := False;
1084
1085       begin
1086          Init_Operand (Left, L_Vec);
1087          Init_Operand (Right, R_Vec);
1088
1089          --  At least one of the two operands is in multi-digit form.
1090          --  Calculate the number of digits sufficient to hold result.
1091
1092          if L_Length > R_Length then
1093             Sum_Length := L_Length + 1;
1094             X_Bigger := True;
1095          else
1096             Sum_Length := R_Length + 1;
1097
1098             if R_Length > L_Length then
1099                Y_Bigger := True;
1100             end if;
1101          end if;
1102
1103          --  Make copies of the absolute values of L_Vec and R_Vec into X and Y
1104          --  both with lengths equal to the maximum possibly needed. This makes
1105          --  looping over the digits much simpler.
1106
1107          declare
1108             X      : UI_Vector (1 .. Sum_Length);
1109             Y      : UI_Vector (1 .. Sum_Length);
1110             Tmp_UI : UI_Vector (1 .. Sum_Length);
1111
1112          begin
1113             for J in 1 .. Sum_Length - L_Length loop
1114                X (J) := 0;
1115             end loop;
1116
1117             X (Sum_Length - L_Length + 1) := abs L_Vec (1);
1118
1119             for J in 2 .. L_Length loop
1120                X (J + (Sum_Length - L_Length)) := L_Vec (J);
1121             end loop;
1122
1123             for J in 1 .. Sum_Length - R_Length loop
1124                Y (J) := 0;
1125             end loop;
1126
1127             Y (Sum_Length - R_Length + 1) := abs R_Vec (1);
1128
1129             for J in 2 .. R_Length loop
1130                Y (J + (Sum_Length - R_Length)) := R_Vec (J);
1131             end loop;
1132
1133             if (L_Vec (1) < Int_0) = (R_Vec (1) < Int_0) then
1134
1135                --  Same sign so just add
1136
1137                Carry := 0;
1138                for J in reverse 1 .. Sum_Length loop
1139                   Tmp_Int := X (J) + Y (J) + Carry;
1140
1141                   if Tmp_Int >= Base then
1142                      Tmp_Int := Tmp_Int - Base;
1143                      Carry := 1;
1144                   else
1145                      Carry := 0;
1146                   end if;
1147
1148                   X (J) := Tmp_Int;
1149                end loop;
1150
1151                return Vector_To_Uint (X, L_Vec (1) < Int_0);
1152
1153             else
1154                --  Find which one has bigger magnitude
1155
1156                if not (X_Bigger or Y_Bigger) then
1157                   for J in L_Vec'Range loop
1158                      if abs L_Vec (J) > abs R_Vec (J) then
1159                         X_Bigger := True;
1160                         exit;
1161                      elsif abs R_Vec (J) > abs L_Vec (J) then
1162                         Y_Bigger := True;
1163                         exit;
1164                      end if;
1165                   end loop;
1166                end if;
1167
1168                --  If they have identical magnitude, just return 0, else swap
1169                --  if necessary so that X had the bigger magnitude. Determine
1170                --  if result is negative at this time.
1171
1172                Result_Neg := False;
1173
1174                if not (X_Bigger or Y_Bigger) then
1175                   return Uint_0;
1176
1177                elsif Y_Bigger then
1178                   if R_Vec (1) < Int_0 then
1179                      Result_Neg := True;
1180                   end if;
1181
1182                   Tmp_UI := X;
1183                   X := Y;
1184                   Y := Tmp_UI;
1185
1186                else
1187                   if L_Vec (1) < Int_0 then
1188                      Result_Neg := True;
1189                   end if;
1190                end if;
1191
1192                --  Subtract Y from the bigger X
1193
1194                Borrow := 0;
1195
1196                for J in reverse 1 .. Sum_Length loop
1197                   Tmp_Int := X (J) - Y (J) + Borrow;
1198
1199                   if Tmp_Int < Int_0 then
1200                      Tmp_Int := Tmp_Int + Base;
1201                      Borrow := -1;
1202                   else
1203                      Borrow := 0;
1204                   end if;
1205
1206                   X (J) := Tmp_Int;
1207                end loop;
1208
1209                return Vector_To_Uint (X, Result_Neg);
1210
1211             end if;
1212          end;
1213       end;
1214    end UI_Add;
1215
1216    --------------------------
1217    -- UI_Decimal_Digits_Hi --
1218    --------------------------
1219
1220    function UI_Decimal_Digits_Hi (U : Uint) return Nat is
1221    begin
1222       --  The maximum value of a "digit" is 32767, which is 5 decimal digits,
1223       --  so an N_Digit number could take up to 5 times this number of digits.
1224       --  This is certainly too high for large numbers but it is not worth
1225       --  worrying about.
1226
1227       return 5 * N_Digits (U);
1228    end UI_Decimal_Digits_Hi;
1229
1230    --------------------------
1231    -- UI_Decimal_Digits_Lo --
1232    --------------------------
1233
1234    function UI_Decimal_Digits_Lo (U : Uint) return Nat is
1235    begin
1236       --  The maximum value of a "digit" is 32767, which is more than four
1237       --  decimal digits, but not a full five digits. The easily computed
1238       --  minimum number of decimal digits is thus 1 + 4 * the number of
1239       --  digits. This is certainly too low for large numbers but it is not
1240       --  worth worrying about.
1241
1242       return 1 + 4 * (N_Digits (U) - 1);
1243    end UI_Decimal_Digits_Lo;
1244
1245    ------------
1246    -- UI_Div --
1247    ------------
1248
1249    function UI_Div (Left : Int; Right : Uint) return Uint is
1250    begin
1251       return UI_Div (UI_From_Int (Left), Right);
1252    end UI_Div;
1253
1254    function UI_Div (Left : Uint; Right : Int) return Uint is
1255    begin
1256       return UI_Div (Left, UI_From_Int (Right));
1257    end UI_Div;
1258
1259    function UI_Div (Left, Right : Uint) return Uint is
1260       Quotient  : Uint;
1261       Remainder : Uint;
1262       pragma Warnings (Off, Remainder);
1263    begin
1264       UI_Div_Rem
1265         (Left, Right,
1266          Quotient, Remainder,
1267          Discard_Quotient  => False,
1268          Discard_Remainder => True);
1269       return Quotient;
1270    end UI_Div;
1271
1272    ----------------
1273    -- UI_Div_Rem --
1274    ----------------
1275
1276    procedure UI_Div_Rem
1277      (Left, Right       : Uint;
1278       Quotient          : out Uint;
1279       Remainder         : out Uint;
1280       Discard_Quotient  : Boolean;
1281       Discard_Remainder : Boolean)
1282    is
1283    begin
1284       pragma Assert (Right /= Uint_0);
1285
1286       --  Cases where both operands are represented directly
1287
1288       if Direct (Left) and then Direct (Right) then
1289          declare
1290             DV_Left  : constant Int := Direct_Val (Left);
1291             DV_Right : constant Int := Direct_Val (Right);
1292
1293          begin
1294             if not Discard_Quotient then
1295                Quotient := UI_From_Int (DV_Left / DV_Right);
1296             end if;
1297
1298             if not Discard_Remainder then
1299                Remainder := UI_From_Int (DV_Left rem DV_Right);
1300             end if;
1301
1302             return;
1303          end;
1304       end if;
1305
1306       declare
1307          L_Length    : constant Int := N_Digits (Left);
1308          R_Length    : constant Int := N_Digits (Right);
1309          Q_Length    : constant Int := L_Length - R_Length + 1;
1310          L_Vec       : UI_Vector (1 .. L_Length);
1311          R_Vec       : UI_Vector (1 .. R_Length);
1312          D           : Int;
1313          Remainder_I : Int;
1314          Tmp_Divisor : Int;
1315          Carry       : Int;
1316          Tmp_Int     : Int;
1317          Tmp_Dig     : Int;
1318
1319          procedure UI_Div_Vector
1320            (L_Vec     : UI_Vector;
1321             R_Int     : Int;
1322             Quotient  : out UI_Vector;
1323             Remainder : out Int);
1324          pragma Inline (UI_Div_Vector);
1325          --  Specialised variant for case where the divisor is a single digit
1326
1327          procedure UI_Div_Vector
1328            (L_Vec     : UI_Vector;
1329             R_Int     : Int;
1330             Quotient  : out UI_Vector;
1331             Remainder : out Int)
1332          is
1333             Tmp_Int : Int;
1334
1335          begin
1336             Remainder := 0;
1337             for J in L_Vec'Range loop
1338                Tmp_Int := Remainder * Base + abs L_Vec (J);
1339                Quotient (Quotient'First + J - L_Vec'First) := Tmp_Int / R_Int;
1340                Remainder := Tmp_Int rem R_Int;
1341             end loop;
1342
1343             if L_Vec (L_Vec'First) < Int_0 then
1344                Remainder := -Remainder;
1345             end if;
1346          end UI_Div_Vector;
1347
1348       --  Start of processing for UI_Div_Rem
1349
1350       begin
1351          --  Result is zero if left operand is shorter than right
1352
1353          if L_Length < R_Length then
1354             if not Discard_Quotient then
1355                Quotient := Uint_0;
1356             end if;
1357             if not Discard_Remainder then
1358                Remainder := Left;
1359             end if;
1360             return;
1361          end if;
1362
1363          Init_Operand (Left, L_Vec);
1364          Init_Operand (Right, R_Vec);
1365
1366          --  Case of right operand is single digit. Here we can simply divide
1367          --  each digit of the left operand by the divisor, from most to least
1368          --  significant, carrying the remainder to the next digit (just like
1369          --  ordinary long division by hand).
1370
1371          if R_Length = Int_1 then
1372             Tmp_Divisor := abs R_Vec (1);
1373
1374             declare
1375                Quotient_V : UI_Vector (1 .. L_Length);
1376
1377             begin
1378                UI_Div_Vector (L_Vec, Tmp_Divisor, Quotient_V, Remainder_I);
1379
1380                if not Discard_Quotient then
1381                   Quotient :=
1382                     Vector_To_Uint
1383                       (Quotient_V, (L_Vec (1) < Int_0 xor R_Vec (1) < Int_0));
1384                end if;
1385
1386                if not Discard_Remainder then
1387                   Remainder := UI_From_Int (Remainder_I);
1388                end if;
1389                return;
1390             end;
1391          end if;
1392
1393          --  The possible simple cases have been exhausted. Now turn to the
1394          --  algorithm D from the section of Knuth mentioned at the top of
1395          --  this package.
1396
1397          Algorithm_D : declare
1398             Dividend     : UI_Vector (1 .. L_Length + 1);
1399             Divisor      : UI_Vector (1 .. R_Length);
1400             Quotient_V   : UI_Vector (1 .. Q_Length);
1401             Divisor_Dig1 : Int;
1402             Divisor_Dig2 : Int;
1403             Q_Guess      : Int;
1404
1405          begin
1406             --  [ NORMALIZE ] (step D1 in the algorithm). First calculate the
1407             --  scale d, and then multiply Left and Right (u and v in the book)
1408             --  by d to get the dividend and divisor to work with.
1409
1410             D := Base / (abs R_Vec (1) + 1);
1411
1412             Dividend (1) := 0;
1413             Dividend (2) := abs L_Vec (1);
1414
1415             for J in 3 .. L_Length + Int_1 loop
1416                Dividend (J) := L_Vec (J - 1);
1417             end loop;
1418
1419             Divisor (1) := abs R_Vec (1);
1420
1421             for J in Int_2 .. R_Length loop
1422                Divisor (J) := R_Vec (J);
1423             end loop;
1424
1425             if D > Int_1 then
1426
1427                --  Multiply Dividend by D
1428
1429                Carry := 0;
1430                for J in reverse Dividend'Range loop
1431                   Tmp_Int      := Dividend (J) * D + Carry;
1432                   Dividend (J) := Tmp_Int rem Base;
1433                   Carry        := Tmp_Int / Base;
1434                end loop;
1435
1436                --  Multiply Divisor by d
1437
1438                Carry := 0;
1439                for J in reverse Divisor'Range loop
1440                   Tmp_Int      := Divisor (J) * D + Carry;
1441                   Divisor (J)  := Tmp_Int rem Base;
1442                   Carry        := Tmp_Int / Base;
1443                end loop;
1444             end if;
1445
1446             --  Main loop of long division algorithm
1447
1448             Divisor_Dig1 := Divisor (1);
1449             Divisor_Dig2 := Divisor (2);
1450
1451             for J in Quotient_V'Range loop
1452
1453                --  [ CALCULATE Q (hat) ] (step D3 in the algorithm)
1454
1455                Tmp_Int := Dividend (J) * Base + Dividend (J + 1);
1456
1457                --  Initial guess
1458
1459                if Dividend (J) = Divisor_Dig1 then
1460                   Q_Guess := Base - 1;
1461                else
1462                   Q_Guess := Tmp_Int / Divisor_Dig1;
1463                end if;
1464
1465                --  Refine the guess
1466
1467                while Divisor_Dig2 * Q_Guess >
1468                      (Tmp_Int - Q_Guess * Divisor_Dig1) * Base +
1469                                                           Dividend (J + 2)
1470                loop
1471                   Q_Guess := Q_Guess - 1;
1472                end loop;
1473
1474                --  [ MULTIPLY & SUBTRACT ] (step D4). Q_Guess * Divisor is
1475                --  subtracted from the remaining dividend.
1476
1477                Carry := 0;
1478                for K in reverse Divisor'Range loop
1479                   Tmp_Int := Dividend (J + K) - Q_Guess * Divisor (K) + Carry;
1480                   Tmp_Dig := Tmp_Int rem Base;
1481                   Carry   := Tmp_Int / Base;
1482
1483                   if Tmp_Dig < Int_0 then
1484                      Tmp_Dig := Tmp_Dig + Base;
1485                      Carry   := Carry - 1;
1486                   end if;
1487
1488                   Dividend (J + K) := Tmp_Dig;
1489                end loop;
1490
1491                Dividend (J) := Dividend (J) + Carry;
1492
1493                --  [ TEST REMAINDER ] & [ ADD BACK ] (steps D5 and D6)
1494
1495                --  Here there is a slight difference from the book: the last
1496                --  carry is always added in above and below (cancelling each
1497                --  other). In fact the dividend going negative is used as
1498                --  the test.
1499
1500                --  If the Dividend went negative, then Q_Guess was off by
1501                --  one, so it is decremented, and the divisor is added back
1502                --  into the relevant portion of the dividend.
1503
1504                if Dividend (J) < Int_0 then
1505                   Q_Guess := Q_Guess - 1;
1506
1507                   Carry := 0;
1508                   for K in reverse Divisor'Range loop
1509                      Tmp_Int := Dividend (J + K) + Divisor (K) + Carry;
1510
1511                      if Tmp_Int >= Base then
1512                         Tmp_Int := Tmp_Int - Base;
1513                         Carry := 1;
1514                      else
1515                         Carry := 0;
1516                      end if;
1517
1518                      Dividend (J + K) := Tmp_Int;
1519                   end loop;
1520
1521                   Dividend (J) := Dividend (J) + Carry;
1522                end if;
1523
1524                --  Finally we can get the next quotient digit
1525
1526                Quotient_V (J) := Q_Guess;
1527             end loop;
1528
1529             --  [ UNNORMALIZE ] (step D8)
1530
1531             if not Discard_Quotient then
1532                Quotient := Vector_To_Uint
1533                  (Quotient_V, (L_Vec (1) < Int_0 xor R_Vec (1) < Int_0));
1534             end if;
1535
1536             if not Discard_Remainder then
1537                declare
1538                   Remainder_V : UI_Vector (1 .. R_Length);
1539                   Discard_Int : Int;
1540                   pragma Warnings (Off, Discard_Int);
1541                begin
1542                   UI_Div_Vector
1543                     (Dividend (Dividend'Last - R_Length + 1 .. Dividend'Last),
1544                      D,
1545                      Remainder_V, Discard_Int);
1546                   Remainder := Vector_To_Uint (Remainder_V, L_Vec (1) < Int_0);
1547                end;
1548             end if;
1549          end Algorithm_D;
1550       end;
1551    end UI_Div_Rem;
1552
1553    ------------
1554    -- UI_Eq --
1555    ------------
1556
1557    function UI_Eq (Left : Int; Right : Uint) return Boolean is
1558    begin
1559       return not UI_Ne (UI_From_Int (Left), Right);
1560    end UI_Eq;
1561
1562    function UI_Eq (Left : Uint; Right : Int) return Boolean is
1563    begin
1564       return not UI_Ne (Left, UI_From_Int (Right));
1565    end UI_Eq;
1566
1567    function UI_Eq (Left : Uint; Right : Uint) return Boolean is
1568    begin
1569       return not UI_Ne (Left, Right);
1570    end UI_Eq;
1571
1572    --------------
1573    -- UI_Expon --
1574    --------------
1575
1576    function UI_Expon (Left : Int; Right : Uint) return Uint is
1577    begin
1578       return UI_Expon (UI_From_Int (Left), Right);
1579    end UI_Expon;
1580
1581    function UI_Expon (Left : Uint; Right : Int) return Uint is
1582    begin
1583       return UI_Expon (Left, UI_From_Int (Right));
1584    end UI_Expon;
1585
1586    function UI_Expon (Left : Int; Right : Int) return Uint is
1587    begin
1588       return UI_Expon (UI_From_Int (Left), UI_From_Int (Right));
1589    end UI_Expon;
1590
1591    function UI_Expon (Left : Uint; Right : Uint) return Uint is
1592    begin
1593       pragma Assert (Right >= Uint_0);
1594
1595       --  Any value raised to power of 0 is 1
1596
1597       if Right = Uint_0 then
1598          return Uint_1;
1599
1600       --  0 to any positive power is 0
1601
1602       elsif Left = Uint_0 then
1603          return Uint_0;
1604
1605       --  1 to any power is 1
1606
1607       elsif Left = Uint_1 then
1608          return Uint_1;
1609
1610       --  Any value raised to power of 1 is that value
1611
1612       elsif Right = Uint_1 then
1613          return Left;
1614
1615       --  Cases which can be done by table lookup
1616
1617       elsif Right <= Uint_64 then
1618
1619          --  2 ** N for N in 2 .. 64
1620
1621          if Left = Uint_2 then
1622             declare
1623                Right_Int : constant Int := Direct_Val (Right);
1624
1625             begin
1626                if Right_Int > UI_Power_2_Set then
1627                   for J in UI_Power_2_Set + Int_1 .. Right_Int loop
1628                      UI_Power_2 (J) := UI_Power_2 (J - Int_1) * Int_2;
1629                      Uints_Min := Uints.Last;
1630                      Udigits_Min := Udigits.Last;
1631                   end loop;
1632
1633                   UI_Power_2_Set := Right_Int;
1634                end if;
1635
1636                return UI_Power_2 (Right_Int);
1637             end;
1638
1639          --  10 ** N for N in 2 .. 64
1640
1641          elsif Left = Uint_10 then
1642             declare
1643                Right_Int : constant Int := Direct_Val (Right);
1644
1645             begin
1646                if Right_Int > UI_Power_10_Set then
1647                   for J in UI_Power_10_Set + Int_1 .. Right_Int loop
1648                      UI_Power_10 (J) := UI_Power_10 (J - Int_1) * Int (10);
1649                      Uints_Min := Uints.Last;
1650                      Udigits_Min := Udigits.Last;
1651                   end loop;
1652
1653                   UI_Power_10_Set := Right_Int;
1654                end if;
1655
1656                return UI_Power_10 (Right_Int);
1657             end;
1658          end if;
1659       end if;
1660
1661       --  If we fall through, then we have the general case (see Knuth 4.6.3)
1662
1663       declare
1664          N       : Uint := Right;
1665          Squares : Uint := Left;
1666          Result  : Uint := Uint_1;
1667          M       : constant Uintp.Save_Mark := Uintp.Mark;
1668
1669       begin
1670          loop
1671             if (Least_Sig_Digit (N) mod Int_2) = Int_1 then
1672                Result := Result * Squares;
1673             end if;
1674
1675             N := N / Uint_2;
1676             exit when N = Uint_0;
1677             Squares := Squares *  Squares;
1678          end loop;
1679
1680          Uintp.Release_And_Save (M, Result);
1681          return Result;
1682       end;
1683    end UI_Expon;
1684
1685    ----------------
1686    -- UI_From_CC --
1687    ----------------
1688
1689    function UI_From_CC (Input : Char_Code) return Uint is
1690    begin
1691       return UI_From_Dint (Dint (Input));
1692    end UI_From_CC;
1693
1694    ------------------
1695    -- UI_From_Dint --
1696    ------------------
1697
1698    function UI_From_Dint (Input : Dint) return Uint is
1699    begin
1700
1701       if Dint (Min_Direct) <= Input and then Input <= Dint (Max_Direct) then
1702          return Uint (Dint (Uint_Direct_Bias) + Input);
1703
1704       --  For values of larger magnitude, compute digits into a vector and call
1705       --  Vector_To_Uint.
1706
1707       else
1708          declare
1709             Max_For_Dint : constant := 5;
1710             --  Base is defined so that 5 Uint digits is sufficient to hold the
1711             --  largest possible Dint value.
1712
1713             V : UI_Vector (1 .. Max_For_Dint);
1714
1715             Temp_Integer : Dint;
1716
1717          begin
1718             for J in V'Range loop
1719                V (J) := 0;
1720             end loop;
1721
1722             Temp_Integer := Input;
1723
1724             for J in reverse V'Range loop
1725                V (J) := Int (abs (Temp_Integer rem Dint (Base)));
1726                Temp_Integer := Temp_Integer / Dint (Base);
1727             end loop;
1728
1729             return Vector_To_Uint (V, Input < Dint'(0));
1730          end;
1731       end if;
1732    end UI_From_Dint;
1733
1734    -----------------
1735    -- UI_From_Int --
1736    -----------------
1737
1738    function UI_From_Int (Input : Int) return Uint is
1739       U : Uint;
1740
1741    begin
1742       if Min_Direct <= Input and then Input <= Max_Direct then
1743          return Uint (Int (Uint_Direct_Bias) + Input);
1744       end if;
1745
1746       --  If already in the hash table, return entry
1747
1748       U := UI_Ints.Get (Input);
1749
1750       if U /= No_Uint then
1751          return U;
1752       end if;
1753
1754       --  For values of larger magnitude, compute digits into a vector and call
1755       --  Vector_To_Uint.
1756
1757       declare
1758          Max_For_Int : constant := 3;
1759          --  Base is defined so that 3 Uint digits is sufficient to hold the
1760          --  largest possible Int value.
1761
1762          V : UI_Vector (1 .. Max_For_Int);
1763
1764          Temp_Integer : Int;
1765
1766       begin
1767          for J in V'Range loop
1768             V (J) := 0;
1769          end loop;
1770
1771          Temp_Integer := Input;
1772
1773          for J in reverse V'Range loop
1774             V (J) := abs (Temp_Integer rem Base);
1775             Temp_Integer := Temp_Integer / Base;
1776          end loop;
1777
1778          U := Vector_To_Uint (V, Input < Int_0);
1779          UI_Ints.Set (Input, U);
1780          Uints_Min := Uints.Last;
1781          Udigits_Min := Udigits.Last;
1782          return U;
1783       end;
1784    end UI_From_Int;
1785
1786    ------------
1787    -- UI_GCD --
1788    ------------
1789
1790    --  Lehmer's algorithm for GCD
1791
1792    --  The idea is to avoid using multiple precision arithmetic wherever
1793    --  possible, substituting Int arithmetic instead. See Knuth volume II,
1794    --  Algorithm L (page 329).
1795
1796    --  We use the same notation as Knuth (U_Hat standing for the obvious!)
1797
1798    function UI_GCD (Uin, Vin : Uint) return Uint is
1799       U, V : Uint;
1800       --  Copies of Uin and Vin
1801
1802       U_Hat, V_Hat : Int;
1803       --  The most Significant digits of U,V
1804
1805       A, B, C, D, T, Q, Den1, Den2 : Int;
1806
1807       Tmp_UI : Uint;
1808       Marks  : constant Uintp.Save_Mark := Uintp.Mark;
1809       Iterations : Integer := 0;
1810
1811    begin
1812       pragma Assert (Uin >= Vin);
1813       pragma Assert (Vin >= Uint_0);
1814
1815       U := Uin;
1816       V := Vin;
1817
1818       loop
1819          Iterations := Iterations + 1;
1820
1821          if Direct (V) then
1822             if V = Uint_0 then
1823                return U;
1824             else
1825                return
1826                  UI_From_Int (GCD (Direct_Val (V), UI_To_Int (U rem V)));
1827             end if;
1828          end if;
1829
1830          Most_Sig_2_Digits (U, V, U_Hat, V_Hat);
1831          A := 1;
1832          B := 0;
1833          C := 0;
1834          D := 1;
1835
1836          loop
1837             --  We might overflow and get division by zero here. This just
1838             --  means we cannot take the single precision step
1839
1840             Den1 := V_Hat + C;
1841             Den2 := V_Hat + D;
1842             exit when (Den1 * Den2) = Int_0;
1843
1844             --  Compute Q, the trial quotient
1845
1846             Q := (U_Hat + A) / Den1;
1847
1848             exit when Q /= ((U_Hat + B) / Den2);
1849
1850             --  A single precision step Euclid step will give same answer as a
1851             --  multiprecision one.
1852
1853             T := A - (Q * C);
1854             A := C;
1855             C := T;
1856
1857             T := B - (Q * D);
1858             B := D;
1859             D := T;
1860
1861             T := U_Hat - (Q * V_Hat);
1862             U_Hat := V_Hat;
1863             V_Hat := T;
1864
1865          end loop;
1866
1867          --  Take a multiprecision Euclid step
1868
1869          if B = Int_0 then
1870
1871             --  No single precision steps take a regular Euclid step
1872
1873             Tmp_UI := U rem V;
1874             U := V;
1875             V := Tmp_UI;
1876
1877          else
1878             --  Use prior single precision steps to compute this Euclid step
1879
1880             --  For constructs such as:
1881             --  sqrt_2: constant :=  1.41421_35623_73095_04880_16887_24209_698;
1882             --  sqrt_eps: constant long_float := long_float( 1.0 / sqrt_2)
1883             --    ** long_float'machine_mantissa;
1884             --
1885             --  we spend 80% of our time working on this step. Perhaps we need
1886             --  a special case Int / Uint dot product to speed things up. ???
1887
1888             --  Alternatively we could increase the single precision iterations
1889             --  to handle Uint's of some small size ( <5 digits?). Then we
1890             --  would have more iterations on small Uint. On the code above, we
1891             --  only get 5 (on average) single precision iterations per large
1892             --  iteration. ???
1893
1894             Tmp_UI := (UI_From_Int (A) * U) + (UI_From_Int (B) * V);
1895             V := (UI_From_Int (C) * U) + (UI_From_Int (D) * V);
1896             U := Tmp_UI;
1897          end if;
1898
1899          --  If the operands are very different in magnitude, the loop will
1900          --  generate large amounts of short-lived data, which it is worth
1901          --  removing periodically.
1902
1903          if Iterations > 100 then
1904             Release_And_Save (Marks, U, V);
1905             Iterations := 0;
1906          end if;
1907       end loop;
1908    end UI_GCD;
1909
1910    ------------
1911    -- UI_Ge --
1912    ------------
1913
1914    function UI_Ge (Left : Int; Right : Uint) return Boolean is
1915    begin
1916       return not UI_Lt (UI_From_Int (Left), Right);
1917    end UI_Ge;
1918
1919    function UI_Ge (Left : Uint; Right : Int) return Boolean is
1920    begin
1921       return not UI_Lt (Left, UI_From_Int (Right));
1922    end UI_Ge;
1923
1924    function UI_Ge (Left : Uint; Right : Uint) return Boolean is
1925    begin
1926       return not UI_Lt (Left, Right);
1927    end UI_Ge;
1928
1929    ------------
1930    -- UI_Gt --
1931    ------------
1932
1933    function UI_Gt (Left : Int; Right : Uint) return Boolean is
1934    begin
1935       return UI_Lt (Right, UI_From_Int (Left));
1936    end UI_Gt;
1937
1938    function UI_Gt (Left : Uint; Right : Int) return Boolean is
1939    begin
1940       return UI_Lt (UI_From_Int (Right), Left);
1941    end UI_Gt;
1942
1943    function UI_Gt (Left : Uint; Right : Uint) return Boolean is
1944    begin
1945       return UI_Lt (Right, Left);
1946    end UI_Gt;
1947
1948    ---------------
1949    -- UI_Image --
1950    ---------------
1951
1952    procedure UI_Image (Input : Uint; Format : UI_Format := Auto) is
1953    begin
1954       Image_Out (Input, True, Format);
1955    end UI_Image;
1956
1957    -------------------------
1958    -- UI_Is_In_Int_Range --
1959    -------------------------
1960
1961    function UI_Is_In_Int_Range (Input : Uint) return Boolean is
1962    begin
1963       --  Make sure we don't get called before Initialize
1964
1965       pragma Assert (Uint_Int_First /= Uint_0);
1966
1967       if Direct (Input) then
1968          return True;
1969       else
1970          return Input >= Uint_Int_First
1971            and then Input <= Uint_Int_Last;
1972       end if;
1973    end UI_Is_In_Int_Range;
1974
1975    ------------
1976    -- UI_Le --
1977    ------------
1978
1979    function UI_Le (Left : Int; Right : Uint) return Boolean is
1980    begin
1981       return not UI_Lt (Right, UI_From_Int (Left));
1982    end UI_Le;
1983
1984    function UI_Le (Left : Uint; Right : Int) return Boolean is
1985    begin
1986       return not UI_Lt (UI_From_Int (Right), Left);
1987    end UI_Le;
1988
1989    function UI_Le (Left : Uint; Right : Uint) return Boolean is
1990    begin
1991       return not UI_Lt (Right, Left);
1992    end UI_Le;
1993
1994    ------------
1995    -- UI_Lt --
1996    ------------
1997
1998    function UI_Lt (Left : Int; Right : Uint) return Boolean is
1999    begin
2000       return UI_Lt (UI_From_Int (Left), Right);
2001    end UI_Lt;
2002
2003    function UI_Lt (Left : Uint; Right : Int) return Boolean is
2004    begin
2005       return UI_Lt (Left, UI_From_Int (Right));
2006    end UI_Lt;
2007
2008    function UI_Lt (Left : Uint; Right : Uint) return Boolean is
2009    begin
2010       --  Quick processing for identical arguments
2011
2012       if Int (Left) = Int (Right) then
2013          return False;
2014
2015       --  Quick processing for both arguments directly represented
2016
2017       elsif Direct (Left) and then Direct (Right) then
2018          return Int (Left) < Int (Right);
2019
2020       --  At least one argument is more than one digit long
2021
2022       else
2023          declare
2024             L_Length : constant Int := N_Digits (Left);
2025             R_Length : constant Int := N_Digits (Right);
2026
2027             L_Vec : UI_Vector (1 .. L_Length);
2028             R_Vec : UI_Vector (1 .. R_Length);
2029
2030          begin
2031             Init_Operand (Left, L_Vec);
2032             Init_Operand (Right, R_Vec);
2033
2034             if L_Vec (1) < Int_0 then
2035
2036                --  First argument negative, second argument non-negative
2037
2038                if R_Vec (1) >= Int_0 then
2039                   return True;
2040
2041                --  Both arguments negative
2042
2043                else
2044                   if L_Length /= R_Length then
2045                      return L_Length > R_Length;
2046
2047                   elsif L_Vec (1) /= R_Vec (1) then
2048                      return L_Vec (1) < R_Vec (1);
2049
2050                   else
2051                      for J in 2 .. L_Vec'Last loop
2052                         if L_Vec (J) /= R_Vec (J) then
2053                            return L_Vec (J) > R_Vec (J);
2054                         end if;
2055                      end loop;
2056
2057                      return False;
2058                   end if;
2059                end if;
2060
2061             else
2062                --  First argument non-negative, second argument negative
2063
2064                if R_Vec (1) < Int_0 then
2065                   return False;
2066
2067                --  Both arguments non-negative
2068
2069                else
2070                   if L_Length /= R_Length then
2071                      return L_Length < R_Length;
2072                   else
2073                      for J in L_Vec'Range loop
2074                         if L_Vec (J) /= R_Vec (J) then
2075                            return L_Vec (J) < R_Vec (J);
2076                         end if;
2077                      end loop;
2078
2079                      return False;
2080                   end if;
2081                end if;
2082             end if;
2083          end;
2084       end if;
2085    end UI_Lt;
2086
2087    ------------
2088    -- UI_Max --
2089    ------------
2090
2091    function UI_Max (Left : Int; Right : Uint) return Uint is
2092    begin
2093       return UI_Max (UI_From_Int (Left), Right);
2094    end UI_Max;
2095
2096    function UI_Max (Left : Uint; Right : Int) return Uint is
2097    begin
2098       return UI_Max (Left, UI_From_Int (Right));
2099    end UI_Max;
2100
2101    function UI_Max (Left : Uint; Right : Uint) return Uint is
2102    begin
2103       if Left >= Right then
2104          return Left;
2105       else
2106          return Right;
2107       end if;
2108    end UI_Max;
2109
2110    ------------
2111    -- UI_Min --
2112    ------------
2113
2114    function UI_Min (Left : Int; Right : Uint) return Uint is
2115    begin
2116       return UI_Min (UI_From_Int (Left), Right);
2117    end UI_Min;
2118
2119    function UI_Min (Left : Uint; Right : Int) return Uint is
2120    begin
2121       return UI_Min (Left, UI_From_Int (Right));
2122    end UI_Min;
2123
2124    function UI_Min (Left : Uint; Right : Uint) return Uint is
2125    begin
2126       if Left <= Right then
2127          return Left;
2128       else
2129          return Right;
2130       end if;
2131    end UI_Min;
2132
2133    -------------
2134    -- UI_Mod --
2135    -------------
2136
2137    function UI_Mod (Left : Int; Right : Uint) return Uint is
2138    begin
2139       return UI_Mod (UI_From_Int (Left), Right);
2140    end UI_Mod;
2141
2142    function UI_Mod (Left : Uint; Right : Int) return Uint is
2143    begin
2144       return UI_Mod (Left, UI_From_Int (Right));
2145    end UI_Mod;
2146
2147    function UI_Mod (Left : Uint; Right : Uint) return Uint is
2148       Urem : constant Uint := Left rem Right;
2149
2150    begin
2151       if (Left < Uint_0) = (Right < Uint_0)
2152         or else Urem = Uint_0
2153       then
2154          return Urem;
2155       else
2156          return Right + Urem;
2157       end if;
2158    end UI_Mod;
2159
2160    -------------------------------
2161    -- UI_Modular_Exponentiation --
2162    -------------------------------
2163
2164    function UI_Modular_Exponentiation
2165      (B      : Uint;
2166       E      : Uint;
2167       Modulo : Uint) return Uint
2168    is
2169       M : constant Save_Mark := Mark;
2170
2171       Result   : Uint := Uint_1;
2172       Base     : Uint := B;
2173       Exponent : Uint := E;
2174
2175    begin
2176       while Exponent /= Uint_0 loop
2177          if Least_Sig_Digit (Exponent) rem Int'(2) = Int'(1) then
2178             Result := (Result * Base) rem Modulo;
2179          end if;
2180
2181          Exponent := Exponent / Uint_2;
2182          Base := (Base * Base) rem Modulo;
2183       end loop;
2184
2185       Release_And_Save (M, Result);
2186       return Result;
2187    end UI_Modular_Exponentiation;
2188
2189    ------------------------
2190    -- UI_Modular_Inverse --
2191    ------------------------
2192
2193    function UI_Modular_Inverse (N : Uint; Modulo : Uint) return Uint is
2194       M : constant Save_Mark := Mark;
2195       U : Uint;
2196       V : Uint;
2197       Q : Uint;
2198       R : Uint;
2199       X : Uint;
2200       Y : Uint;
2201       T : Uint;
2202       S : Int := 1;
2203
2204    begin
2205       U := Modulo;
2206       V := N;
2207
2208       X := Uint_1;
2209       Y := Uint_0;
2210
2211       loop
2212          UI_Div_Rem
2213            (U, V,
2214             Quotient => Q, Remainder => R,
2215             Discard_Quotient  => False,
2216             Discard_Remainder => False);
2217
2218          U := V;
2219          V := R;
2220
2221          T := X;
2222          X := Y + Q * X;
2223          Y := T;
2224          S := -S;
2225
2226          exit when R = Uint_1;
2227       end loop;
2228
2229       if S = Int'(-1) then
2230          X := Modulo - X;
2231       end if;
2232
2233       Release_And_Save (M, X);
2234       return X;
2235    end UI_Modular_Inverse;
2236
2237    ------------
2238    -- UI_Mul --
2239    ------------
2240
2241    function UI_Mul (Left : Int; Right : Uint) return Uint is
2242    begin
2243       return UI_Mul (UI_From_Int (Left), Right);
2244    end UI_Mul;
2245
2246    function UI_Mul (Left : Uint; Right : Int) return Uint is
2247    begin
2248       return UI_Mul (Left, UI_From_Int (Right));
2249    end UI_Mul;
2250
2251    function UI_Mul (Left : Uint; Right : Uint) return Uint is
2252    begin
2253       --  Simple case of single length operands
2254
2255       if Direct (Left) and then Direct (Right) then
2256          return
2257            UI_From_Dint
2258              (Dint (Direct_Val (Left)) * Dint (Direct_Val (Right)));
2259       end if;
2260
2261       --  Otherwise we have the general case (Algorithm M in Knuth)
2262
2263       declare
2264          L_Length : constant Int := N_Digits (Left);
2265          R_Length : constant Int := N_Digits (Right);
2266          L_Vec    : UI_Vector (1 .. L_Length);
2267          R_Vec    : UI_Vector (1 .. R_Length);
2268          Neg      : Boolean;
2269
2270       begin
2271          Init_Operand (Left, L_Vec);
2272          Init_Operand (Right, R_Vec);
2273          Neg := (L_Vec (1) < Int_0) xor (R_Vec (1) < Int_0);
2274          L_Vec (1) := abs (L_Vec (1));
2275          R_Vec (1) := abs (R_Vec (1));
2276
2277          Algorithm_M : declare
2278             Product : UI_Vector (1 .. L_Length + R_Length);
2279             Tmp_Sum : Int;
2280             Carry   : Int;
2281
2282          begin
2283             for J in Product'Range loop
2284                Product (J) := 0;
2285             end loop;
2286
2287             for J in reverse R_Vec'Range loop
2288                Carry := 0;
2289                for K in reverse L_Vec'Range loop
2290                   Tmp_Sum :=
2291                     L_Vec (K) * R_Vec (J) + Product (J + K) + Carry;
2292                   Product (J + K) := Tmp_Sum rem Base;
2293                   Carry := Tmp_Sum / Base;
2294                end loop;
2295
2296                Product (J) := Carry;
2297             end loop;
2298
2299             return Vector_To_Uint (Product, Neg);
2300          end Algorithm_M;
2301       end;
2302    end UI_Mul;
2303
2304    ------------
2305    -- UI_Ne --
2306    ------------
2307
2308    function UI_Ne (Left : Int; Right : Uint) return Boolean is
2309    begin
2310       return UI_Ne (UI_From_Int (Left), Right);
2311    end UI_Ne;
2312
2313    function UI_Ne (Left : Uint; Right : Int) return Boolean is
2314    begin
2315       return UI_Ne (Left, UI_From_Int (Right));
2316    end UI_Ne;
2317
2318    function UI_Ne (Left : Uint; Right : Uint) return Boolean is
2319    begin
2320       --  Quick processing for identical arguments. Note that this takes
2321       --  care of the case of two No_Uint arguments.
2322
2323       if Int (Left) = Int (Right) then
2324          return False;
2325       end if;
2326
2327       --  See if left operand directly represented
2328
2329       if Direct (Left) then
2330
2331          --  If right operand directly represented then compare
2332
2333          if Direct (Right) then
2334             return Int (Left) /= Int (Right);
2335
2336          --  Left operand directly represented, right not, must be unequal
2337
2338          else
2339             return True;
2340          end if;
2341
2342       --  Right operand directly represented, left not, must be unequal
2343
2344       elsif Direct (Right) then
2345          return True;
2346       end if;
2347
2348       --  Otherwise both multi-word, do comparison
2349
2350       declare
2351          Size      : constant Int := N_Digits (Left);
2352          Left_Loc  : Int;
2353          Right_Loc : Int;
2354
2355       begin
2356          if Size /= N_Digits (Right) then
2357             return True;
2358          end if;
2359
2360          Left_Loc  := Uints.Table (Left).Loc;
2361          Right_Loc := Uints.Table (Right).Loc;
2362
2363          for J in Int_0 .. Size - Int_1 loop
2364             if Udigits.Table (Left_Loc + J) /=
2365                Udigits.Table (Right_Loc + J)
2366             then
2367                return True;
2368             end if;
2369          end loop;
2370
2371          return False;
2372       end;
2373    end UI_Ne;
2374
2375    ----------------
2376    -- UI_Negate --
2377    ----------------
2378
2379    function UI_Negate (Right : Uint) return Uint is
2380    begin
2381       --  Case where input is directly represented. Note that since the range
2382       --  of Direct values is non-symmetrical, the result may not be directly
2383       --  represented, this is taken care of in UI_From_Int.
2384
2385       if Direct (Right) then
2386          return UI_From_Int (-Direct_Val (Right));
2387
2388       --  Full processing for multi-digit case. Note that we cannot just copy
2389       --  the value to the end of the table negating the first digit, since the
2390       --  range of Direct values is non-symmetrical, so we can have a negative
2391       --  value that is not Direct whose negation can be represented directly.
2392
2393       else
2394          declare
2395             R_Length : constant Int := N_Digits (Right);
2396             R_Vec    : UI_Vector (1 .. R_Length);
2397             Neg      : Boolean;
2398
2399          begin
2400             Init_Operand (Right, R_Vec);
2401             Neg := R_Vec (1) > Int_0;
2402             R_Vec (1) := abs R_Vec (1);
2403             return Vector_To_Uint (R_Vec, Neg);
2404          end;
2405       end if;
2406    end UI_Negate;
2407
2408    -------------
2409    -- UI_Rem --
2410    -------------
2411
2412    function UI_Rem (Left : Int; Right : Uint) return Uint is
2413    begin
2414       return UI_Rem (UI_From_Int (Left), Right);
2415    end UI_Rem;
2416
2417    function UI_Rem (Left : Uint; Right : Int) return Uint is
2418    begin
2419       return UI_Rem (Left, UI_From_Int (Right));
2420    end UI_Rem;
2421
2422    function UI_Rem (Left, Right : Uint) return Uint is
2423       Sign : Int;
2424       Tmp  : Int;
2425
2426       subtype Int1_12 is Integer range 1 .. 12;
2427
2428    begin
2429       pragma Assert (Right /= Uint_0);
2430
2431       if Direct (Right) then
2432          if Direct (Left) then
2433             return UI_From_Int (Direct_Val (Left) rem Direct_Val (Right));
2434
2435          else
2436
2437             --  Special cases when Right is less than 13 and Left is larger
2438             --  larger than one digit. All of these algorithms depend on the
2439             --  base being 2 ** 15 We work with Abs (Left) and Abs(Right)
2440             --  then multiply result by Sign (Left)
2441
2442             if (Right <= Uint_12) and then (Right >= Uint_Minus_12) then
2443
2444                if Left < Uint_0 then
2445                   Sign := -1;
2446                else
2447                   Sign := 1;
2448                end if;
2449
2450                --  All cases are listed, grouped by mathematical method It is
2451                --  not inefficient to do have this case list out of order since
2452                --  GCC sorts the cases we list.
2453
2454                case Int1_12 (abs (Direct_Val (Right))) is
2455
2456                   when 1 =>
2457                      return Uint_0;
2458
2459                   --  Powers of two are simple AND's with LS Left Digit GCC
2460                   --  will recognise these constants as powers of 2 and replace
2461                   --  the rem with simpler operations where possible.
2462
2463                   --  Least_Sig_Digit might return Negative numbers
2464
2465                   when 2 =>
2466                      return UI_From_Int (
2467                         Sign * (Least_Sig_Digit (Left) mod 2));
2468
2469                   when 4 =>
2470                      return UI_From_Int (
2471                         Sign * (Least_Sig_Digit (Left) mod 4));
2472
2473                   when 8 =>
2474                      return UI_From_Int (
2475                         Sign * (Least_Sig_Digit (Left) mod 8));
2476
2477                   --  Some number theoretical tricks:
2478
2479                   --    If B Rem Right = 1 then
2480                   --    Left Rem Right = Sum_Of_Digits_Base_B (Left) Rem Right
2481
2482                   --  Note: 2^32 mod 3 = 1
2483
2484                   when 3 =>
2485                      return UI_From_Int (
2486                         Sign * (Sum_Double_Digits (Left, 1) rem Int (3)));
2487
2488                   --  Note: 2^15 mod 7 = 1
2489
2490                   when 7 =>
2491                      return UI_From_Int (
2492                         Sign * (Sum_Digits (Left, 1) rem Int (7)));
2493
2494                   --  Note: 2^32 mod 5 = -1
2495
2496                   --  Alternating sums might be negative, but rem is always
2497                   --  positive hence we must use mod here.
2498
2499                   when 5 =>
2500                      Tmp := Sum_Double_Digits (Left, -1) mod Int (5);
2501                      return UI_From_Int (Sign * Tmp);
2502
2503                   --  Note: 2^15 mod 9 = -1
2504
2505                   --  Alternating sums might be negative, but rem is always
2506                   --  positive hence we must use mod here.
2507
2508                   when 9  =>
2509                      Tmp := Sum_Digits (Left, -1) mod Int (9);
2510                      return UI_From_Int (Sign * Tmp);
2511
2512                   --  Note: 2^15 mod 11 = -1
2513
2514                   --  Alternating sums might be negative, but rem is always
2515                   --  positive hence we must use mod here.
2516
2517                   when 11 =>
2518                      Tmp := Sum_Digits (Left, -1) mod Int (11);
2519                      return UI_From_Int (Sign * Tmp);
2520
2521                   --  Now resort to Chinese Remainder theorem to reduce 6, 10,
2522                   --  12 to previous special cases
2523
2524                   --  There is no reason we could not add more cases like these
2525                   --  if it proves useful.
2526
2527                   --  Perhaps we should go up to 16, however we have no "trick"
2528                   --  for 13.
2529
2530                   --  To find u mod m we:
2531
2532                   --  Pick m1, m2 S.T.
2533                   --     GCD(m1, m2) = 1 AND m = (m1 * m2).
2534
2535                   --  Next we pick (Basis) M1, M2 small S.T.
2536                   --     (M1 mod m1) = (M2 mod m2) = 1 AND
2537                   --     (M1 mod m2) = (M2 mod m1) = 0
2538
2539                   --  So u mod m = (u1 * M1 + u2 * M2) mod m Where u1 = (u mod
2540                   --  m1) AND u2 = (u mod m2); Under typical circumstances the
2541                   --  last mod m can be done with a (possible) single
2542                   --  subtraction.
2543
2544                   --  m1 = 2; m2 = 3; M1 = 3; M2 = 4;
2545
2546                   when 6  =>
2547                      Tmp := 3 * (Least_Sig_Digit (Left) rem 2) +
2548                               4 * (Sum_Double_Digits (Left, 1) rem 3);
2549                      return UI_From_Int (Sign * (Tmp rem 6));
2550
2551                   --  m1 = 2; m2 = 5; M1 = 5; M2 = 6;
2552
2553                   when 10 =>
2554                      Tmp := 5 * (Least_Sig_Digit (Left) rem 2) +
2555                               6 * (Sum_Double_Digits (Left, -1) mod 5);
2556                      return UI_From_Int (Sign * (Tmp rem 10));
2557
2558                   --  m1 = 3; m2 = 4; M1 = 4; M2 = 9;
2559
2560                   when 12 =>
2561                      Tmp := 4 * (Sum_Double_Digits (Left, 1) rem 3) +
2562                               9 * (Least_Sig_Digit (Left) rem 4);
2563                      return UI_From_Int (Sign * (Tmp rem 12));
2564                end case;
2565
2566             end if;
2567
2568             --  Else fall through to general case
2569
2570             --  The special case Length (Left) = Length (Right) = 1 in Div
2571             --  looks slow. It uses UI_To_Int when Int should suffice. ???
2572          end if;
2573       end if;
2574
2575       declare
2576          Remainder : Uint;
2577          Quotient  : Uint;
2578          pragma Warnings (Off, Quotient);
2579       begin
2580          UI_Div_Rem
2581            (Left, Right, Quotient, Remainder,
2582             Discard_Quotient  => True,
2583             Discard_Remainder => False);
2584          return Remainder;
2585       end;
2586    end UI_Rem;
2587
2588    ------------
2589    -- UI_Sub --
2590    ------------
2591
2592    function UI_Sub (Left : Int; Right : Uint) return Uint is
2593    begin
2594       return UI_Add (Left, -Right);
2595    end UI_Sub;
2596
2597    function UI_Sub (Left : Uint; Right : Int) return Uint is
2598    begin
2599       return UI_Add (Left, -Right);
2600    end UI_Sub;
2601
2602    function UI_Sub (Left : Uint; Right : Uint) return Uint is
2603    begin
2604       if Direct (Left) and then Direct (Right) then
2605          return UI_From_Int (Direct_Val (Left) - Direct_Val (Right));
2606       else
2607          return UI_Add (Left, -Right);
2608       end if;
2609    end UI_Sub;
2610
2611    --------------
2612    -- UI_To_CC --
2613    --------------
2614
2615    function UI_To_CC (Input : Uint) return Char_Code is
2616    begin
2617       if Direct (Input) then
2618          return Char_Code (Direct_Val (Input));
2619
2620       --  Case of input is more than one digit
2621
2622       else
2623          declare
2624             In_Length : constant Int := N_Digits (Input);
2625             In_Vec    : UI_Vector (1 .. In_Length);
2626             Ret_CC    : Char_Code;
2627
2628          begin
2629             Init_Operand (Input, In_Vec);
2630
2631             --  We assume value is positive
2632
2633             Ret_CC := 0;
2634             for Idx in In_Vec'Range loop
2635                Ret_CC := Ret_CC * Char_Code (Base) +
2636                                   Char_Code (abs In_Vec (Idx));
2637             end loop;
2638
2639             return Ret_CC;
2640          end;
2641       end if;
2642    end UI_To_CC;
2643
2644    ----------------
2645    -- UI_To_Int --
2646    ----------------
2647
2648    function UI_To_Int (Input : Uint) return Int is
2649    begin
2650       if Direct (Input) then
2651          return Direct_Val (Input);
2652
2653       --  Case of input is more than one digit
2654
2655       else
2656          declare
2657             In_Length : constant Int := N_Digits (Input);
2658             In_Vec    : UI_Vector (1 .. In_Length);
2659             Ret_Int   : Int;
2660
2661          begin
2662             --  Uints of more than one digit could be outside the range for
2663             --  Ints. Caller should have checked for this if not certain.
2664             --  Fatal error to attempt to convert from value outside Int'Range.
2665
2666             pragma Assert (UI_Is_In_Int_Range (Input));
2667
2668             --  Otherwise, proceed ahead, we are OK
2669
2670             Init_Operand (Input, In_Vec);
2671             Ret_Int := 0;
2672
2673             --  Calculate -|Input| and then negates if value is positive. This
2674             --  handles our current definition of Int (based on 2s complement).
2675             --  Is it secure enough???
2676
2677             for Idx in In_Vec'Range loop
2678                Ret_Int := Ret_Int * Base - abs In_Vec (Idx);
2679             end loop;
2680
2681             if In_Vec (1) < Int_0 then
2682                return Ret_Int;
2683             else
2684                return -Ret_Int;
2685             end if;
2686          end;
2687       end if;
2688    end UI_To_Int;
2689
2690    --------------
2691    -- UI_Write --
2692    --------------
2693
2694    procedure UI_Write (Input : Uint; Format : UI_Format := Auto) is
2695    begin
2696       Image_Out (Input, False, Format);
2697    end UI_Write;
2698
2699    ---------------------
2700    -- Vector_To_Uint --
2701    ---------------------
2702
2703    function Vector_To_Uint
2704      (In_Vec   : UI_Vector;
2705       Negative : Boolean)
2706       return     Uint
2707    is
2708       Size : Int;
2709       Val  : Int;
2710
2711    begin
2712       --  The vector can contain leading zeros. These are not stored in the
2713       --  table, so loop through the vector looking for first non-zero digit
2714
2715       for J in In_Vec'Range loop
2716          if In_Vec (J) /= Int_0 then
2717
2718             --  The length of the value is the length of the rest of the vector
2719
2720             Size := In_Vec'Last - J + 1;
2721
2722             --  One digit value can always be represented directly
2723
2724             if Size = Int_1 then
2725                if Negative then
2726                   return Uint (Int (Uint_Direct_Bias) - In_Vec (J));
2727                else
2728                   return Uint (Int (Uint_Direct_Bias) + In_Vec (J));
2729                end if;
2730
2731             --  Positive two digit values may be in direct representation range
2732
2733             elsif Size = Int_2 and then not Negative then
2734                Val := In_Vec (J) * Base + In_Vec (J + 1);
2735
2736                if Val <= Max_Direct then
2737                   return Uint (Int (Uint_Direct_Bias) + Val);
2738                end if;
2739             end if;
2740
2741             --  The value is outside the direct representation range and must
2742             --  therefore be stored in the table. Expand the table to contain
2743             --  the count and tigis. The index of the new table entry will be
2744             --  returned as the result.
2745
2746             Uints.Increment_Last;
2747             Uints.Table (Uints.Last).Length := Size;
2748             Uints.Table (Uints.Last).Loc    := Udigits.Last + 1;
2749
2750             Udigits.Increment_Last;
2751
2752             if Negative then
2753                Udigits.Table (Udigits.Last) := -In_Vec (J);
2754             else
2755                Udigits.Table (Udigits.Last) := +In_Vec (J);
2756             end if;
2757
2758             for K in 2 .. Size loop
2759                Udigits.Increment_Last;
2760                Udigits.Table (Udigits.Last) := In_Vec (J + K - 1);
2761             end loop;
2762
2763             return Uints.Last;
2764          end if;
2765       end loop;
2766
2767       --  Dropped through loop only if vector contained all zeros
2768
2769       return Uint_0;
2770    end Vector_To_Uint;
2771
2772 end Uintp;