gcc/ada/treepr.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               T R E E P R                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Debug;    use Debug;
  29 with Einfo;    use Einfo;
  30 with Elists;   use Elists;
  31 with Lib;      use Lib;
  32 with Namet;    use Namet;
  33 with Nlists;   use Nlists;
  34 with Output;   use Output;
  35 with Sem_Mech; use Sem_Mech;
  36 with Sinfo;    use Sinfo;
  37 with Snames;   use Snames;
  38 with Sinput;   use Sinput;
  39 with Stand;    use Stand;
  40 with Stringt;  use Stringt;
  41 with Treeprs;  use Treeprs;
  42 with Uintp;    use Uintp;
  43 with Urealp;   use Urealp;
  44 with Uname;    use Uname;
  45 with Unchecked_Deallocation;
  46
  47 package body Treepr is
  48
  49    use Atree.Unchecked_Access;
  50    --  This module uses the unchecked access functions in package Atree
  51    --  since it does an untyped traversal of the tree (we do not want to
  52    --  count on the structure of the tree being correct in this routine!)
  53
  54    ----------------------------------
  55    -- Approach Used for Tree Print --
  56    ----------------------------------
  57
  58    --  When a complete subtree is being printed, a trace phase first marks
  59    --  the nodes and lists to be printed. This trace phase allocates logical
  60    --  numbers corresponding to the order in which the nodes and lists will
  61    --  be printed. The Node_Id, List_Id and Elist_Id values are mapped to
  62    --  logical node numbers using a hash table. Output is done using a set
  63    --  of Print_xxx routines, which are similar to the Write_xxx routines
  64    --  with the same name, except that they do not generate any output in
  65    --  the marking phase. This allows identical logic to be used in the
  66    --  two phases.
  67
  68    --  Note that the hash table not only holds the serial numbers, but also
  69    --  acts as a record of which nodes have already been visited. In the
  70    --  marking phase, a node has been visited if it is already in the hash
  71    --  table, and in the printing phase, we can tell whether a node has
  72    --  already been printed by looking at the value of the serial number.
  73
  74    ----------------------
  75    -- Global Variables --
  76    ----------------------
  77
  78    type Hash_Record is record
  79       Serial : Nat;
  80       --  Serial number for hash table entry. A value of zero means that
  81       --  the entry is currently unused.
  82
  83       Id : Int;
  84       --  If serial number field is non-zero, contains corresponding Id value
  85    end record;
  86
  87    type Hash_Table_Type is array (Nat range <>) of Hash_Record;
  88    type Access_Hash_Table_Type is access Hash_Table_Type;
  89    Hash_Table : Access_Hash_Table_Type;
  90    --  The hash table itself, see Serial_Number function for details of use
  91
  92    Hash_Table_Len : Nat;
  93    --  Range of Hash_Table is from 0 .. Hash_Table_Len - 1 so that dividing
  94    --  by Hash_Table_Len gives a remainder that is in Hash_Table'Range.
  95
  96    Next_Serial_Number : Nat;
  97    --  Number of last visited node or list. Used during the marking phase to
  98    --  set proper node numbers in the hash table, and during the printing
  99    --  phase to make sure that a given node is not printed more than once.
 100    --  (nodes are printed in order during the printing phase, that's the
 101    --  point of numbering them in the first place!)
 102
 103    Printing_Descendants : Boolean;
 104    --  True if descendants are being printed, False if not. In the false case,
 105    --  only node Id's are printed. In the true case, node numbers as well as
 106    --  node Id's are printed, as described above.
 107
 108    type Phase_Type is (Marking, Printing);
 109    --  Type for Phase variable
 110
 111    Phase : Phase_Type;
 112    --  When an entire tree is being printed, the traversal operates in two
 113    --  phases. The first phase marks the nodes in use by installing node
 114    --  numbers in the node number table. The second phase prints the nodes.
 115    --  This variable indicates the current phase.
 116
 117    ----------------------
 118    -- Local Procedures --
 119    ----------------------
 120
 121    procedure Print_End_Span (N : Node_Id);
 122    --  Special routine to print contents of End_Span field of node N.
 123    --  The format includes the implicit source location as well as the
 124    --  value of the field.
 125
 126    procedure Print_Init;
 127    --  Initialize for printing of tree with descendents
 128
 129    procedure Print_Term;
 130    --  Clean up after printing of tree with descendents
 131
 132    procedure Print_Char (C : Character);
 133    --  Print character C if currently in print phase, noop if in marking phase
 134
 135    procedure Print_Name (N : Name_Id);
 136    --  Print name from names table if currently in print phase, noop if in
 137    --  marking phase. Note that the name is output in mixed case mode.
 138
 139    procedure Print_Node_Kind (N : Node_Id);
 140    --  Print node kind name in mixed case if in print phase, noop if in
 141    --  marking phase.
 142
 143    procedure Print_Str (S : String);
 144    --  Print string S if currently in print phase, noop if in marking phase
 145
 146    procedure Print_Str_Mixed_Case (S : String);
 147    --  Like Print_Str, except that the string is printed in mixed case mode
 148
 149    procedure Print_Int (I : Int);
 150    --  Print integer I if currently in print phase, noop if in marking phase
 151
 152    procedure Print_Eol;
 153    --  Print end of line if currently in print phase, noop if in marking phase
 154
 155    procedure Print_Node_Ref (N : Node_Id);
 156    --  Print "<empty>", "<error>" or "Node #nnn" with additional information
 157    --  in the latter case, including the Id and the Nkind of the node.
 158
 159    procedure Print_List_Ref (L : List_Id);
 160    --  Print "<no list>", or "<empty node list>" or "Node list #nnn"
 161
 162    procedure Print_Elist_Ref (E : Elist_Id);
 163    --  Print "<no elist>", or "<empty element list>" or "Element list #nnn"
 164
 165    procedure Print_Entity_Info (Ent : Entity_Id; Prefix : String);
 166    --  Called if the node being printed is an entity. Prints fields from the
 167    --  extension, using routines in Einfo to get the field names and flags.
 168
 169    procedure Print_Field (Val : Union_Id; Format : UI_Format := Auto);
 170    --  Print representation of Field value (name, tree, string, uint, charcode)
 171    --  The format parameter controls the format of printing in the case of an
 172    --  integer value (see UI_Write for details).
 173
 174    procedure Print_Flag (F : Boolean);
 175    --  Print True or False
 176
 177    procedure Print_Node
 178      (N           : Node_Id;
 179       Prefix_Str  : String;
 180       Prefix_Char : Character);
 181    --  This is the internal routine used to print a single node. Each line of
 182    --  output is preceded by Prefix_Str (which is used to set the indentation
 183    --  level and the bars used to link list elements). In addition, for lines
 184    --  other than the first, an additional character Prefix_Char is output.
 185
 186    function Serial_Number (Id : Int) return Nat;
 187    --  Given a Node_Id, List_Id or Elist_Id, returns the previously assigned
 188    --  serial number, or zero if no serial number has yet been assigned.
 189
 190    procedure Set_Serial_Number;
 191    --  Can be called only immediately following a call to Serial_Number that
 192    --  returned a value of zero. Causes the value of Next_Serial_Number to be
 193    --  placed in the hash table (corresponding to the Id argument used in the
 194    --  Serial_Number call), and increments Next_Serial_Number.
 195
 196    procedure Visit_Node
 197      (N           : Node_Id;
 198       Prefix_Str  : String;
 199       Prefix_Char : Character);
 200    --  Called to process a single node in the case where descendents are to
 201    --  be printed before every line, and Prefix_Char added to all lines
 202    --  except the header line for the node.
 203
 204    procedure Visit_List (L : List_Id; Prefix_Str : String);
 205    --  Visit_List is called to process a list in the case where descendents
 206    --  are to be printed. Prefix_Str is to be added to all printed lines.
 207
 208    procedure Visit_Elist (E : Elist_Id; Prefix_Str : String);
 209    --  Visit_Elist is called to process an element list in the case where
 210    --  descendents are to be printed. Prefix_Str is to be added to all
 211    --  printed lines.
 212
 213    --------
 214    -- pe --
 215    --------
 216
 217    procedure pe (E : Elist_Id) is
 218    begin
 219       Print_Tree_Elist (E);
 220    end pe;
 221
 222    --------
 223    -- pl --
 224    --------
 225
 226    procedure pl (L : Int) is
 227       Lid : Int;
 228
 229    begin
 230       if L < 0 then
 231          Lid := L;
 232
 233       --  This is the case where we transform e.g. +36 to -99999936
 234
 235       else
 236          if L <= 9 then
 237             Lid := -(99999990 + L);
 238          elsif L <= 99 then
 239             Lid := -(99999900 + L);
 240          elsif L <= 999 then
 241             Lid := -(99999000 + L);
 242          elsif L <= 9999 then
 243             Lid := -(99990000 + L);
 244          elsif L <= 99999 then
 245             Lid := -(99900000 + L);
 246          elsif L <= 999999 then
 247             Lid := -(99000000 + L);
 248          elsif L <= 9999999 then
 249             Lid := -(90000000 + L);
 250          else
 251             Lid := -L;
 252          end if;
 253       end if;
 254
 255       --  Now output the list
 256
 257       Print_Tree_List (List_Id (Lid));
 258    end pl;
 259
 260    --------
 261    -- pn --
 262    --------
 263
 264    procedure pn (N : Node_Id) is
 265    begin
 266       Print_Tree_Node (N);
 267    end pn;
 268
 269    ----------------
 270    -- Print_Char --
 271    ----------------
 272
 273    procedure Print_Char (C : Character) is
 274    begin
 275       if Phase = Printing then
 276          Write_Char (C);
 277       end if;
 278    end Print_Char;
 279
 280    ---------------------
 281    -- Print_Elist_Ref --
 282    ---------------------
 283
 284    procedure Print_Elist_Ref (E : Elist_Id) is
 285    begin
 286       if Phase /= Printing then
 287          return;
 288       end if;
 289
 290       if E = No_Elist then
 291          Write_Str ("<no elist>");
 292
 293       elsif Is_Empty_Elmt_List (E) then
 294          Write_Str ("Empty elist, (Elist_Id=");
 295          Write_Int (Int (E));
 296          Write_Char (')');
 297
 298       else
 299          Write_Str ("(Elist_Id=");
 300          Write_Int (Int (E));
 301          Write_Char (')');
 302
 303          if Printing_Descendants then
 304             Write_Str (" #");
 305             Write_Int (Serial_Number (Int (E)));
 306          end if;
 307       end if;
 308    end Print_Elist_Ref;
 309
 310    -------------------------
 311    -- Print_Elist_Subtree --
 312    -------------------------
 313
 314    procedure Print_Elist_Subtree (E : Elist_Id) is
 315    begin
 316       Print_Init;
 317
 318       Next_Serial_Number := 1;
 319       Phase := Marking;
 320       Visit_Elist (E, "");
 321
 322       Next_Serial_Number := 1;
 323       Phase := Printing;
 324       Visit_Elist (E, "");
 325
 326       Print_Term;
 327    end Print_Elist_Subtree;
 328
 329    --------------------
 330    -- Print_End_Span --
 331    --------------------
 332
 333    procedure Print_End_Span (N : Node_Id) is
 334       Val : constant Uint := End_Span (N);
 335
 336    begin
 337       UI_Write (Val);
 338       Write_Str (" (Uint = ");
 339       Write_Int (Int (Field5 (N)));
 340       Write_Str (")  ");
 341
 342       if Val /= No_Uint then
 343          Write_Location (End_Location (N));
 344       end if;
 345    end Print_End_Span;
 346
 347    -----------------------
 348    -- Print_Entity_Info --
 349    -----------------------
 350
 351    procedure Print_Entity_Info (Ent : Entity_Id; Prefix : String) is
 352       function Field_Present (U : Union_Id) return Boolean;
 353       --  Returns False unless the value U represents a missing value
 354       --  (Empty, No_Uint, No_Ureal or No_String)
 355
 356       function Field_Present (U : Union_Id) return Boolean is
 357       begin
 358          return
 359             U /= Union_Id (Empty)    and then
 360             U /= To_Union (No_Uint)  and then
 361             U /= To_Union (No_Ureal) and then
 362             U /= Union_Id (No_String);
 363       end Field_Present;
 364
 365    --  Start of processing for Print_Entity_Info
 366
 367    begin
 368       Print_Str (Prefix);
 369       Print_Str ("Ekind = ");
 370       Print_Str_Mixed_Case (Entity_Kind'Image (Ekind (Ent)));
 371       Print_Eol;
 372
 373       Print_Str (Prefix);
 374       Print_Str ("Etype = ");
 375       Print_Node_Ref (Etype (Ent));
 376       Print_Eol;
 377
 378       if Convention (Ent) /= Convention_Ada then
 379          Print_Str (Prefix);
 380          Print_Str ("Convention = ");
 381
 382          --  Print convention name skipping the Convention_ at the start
 383
 384          declare
 385             S : constant String := Convention_Id'Image (Convention (Ent));
 386
 387          begin
 388             Print_Str_Mixed_Case (S (12 .. S'Last));
 389             Print_Eol;
 390          end;
 391       end if;
 392
 393       if Field_Present (Field6 (Ent)) then
 394          Print_Str (Prefix);
 395          Write_Field6_Name (Ent);
 396          Write_Str (" = ");
 397          Print_Field (Field6 (Ent));
 398          Print_Eol;
 399       end if;
 400
 401       if Field_Present (Field7 (Ent)) then
 402          Print_Str (Prefix);
 403          Write_Field7_Name (Ent);
 404          Write_Str (" = ");
 405          Print_Field (Field7 (Ent));
 406          Print_Eol;
 407       end if;
 408
 409       if Field_Present (Field8 (Ent)) then
 410          Print_Str (Prefix);
 411          Write_Field8_Name (Ent);
 412          Write_Str (" = ");
 413          Print_Field (Field8 (Ent));
 414          Print_Eol;
 415       end if;
 416
 417       if Field_Present (Field9 (Ent)) then
 418          Print_Str (Prefix);
 419          Write_Field9_Name (Ent);
 420          Write_Str (" = ");
 421          Print_Field (Field9 (Ent));
 422          Print_Eol;
 423       end if;
 424
 425       if Field_Present (Field10 (Ent)) then
 426          Print_Str (Prefix);
 427          Write_Field10_Name (Ent);
 428          Write_Str (" = ");
 429          Print_Field (Field10 (Ent));
 430          Print_Eol;
 431       end if;
 432
 433       if Field_Present (Field11 (Ent)) then
 434          Print_Str (Prefix);
 435          Write_Field11_Name (Ent);
 436          Write_Str (" = ");
 437          Print_Field (Field11 (Ent));
 438          Print_Eol;
 439       end if;
 440
 441       if Field_Present (Field12 (Ent)) then
 442          Print_Str (Prefix);
 443          Write_Field12_Name (Ent);
 444          Write_Str (" = ");
 445          Print_Field (Field12 (Ent));
 446          Print_Eol;
 447       end if;
 448
 449       if Field_Present (Field13 (Ent)) then
 450          Print_Str (Prefix);
 451          Write_Field13_Name (Ent);
 452          Write_Str (" = ");
 453          Print_Field (Field13 (Ent));
 454          Print_Eol;
 455       end if;
 456
 457       if Field_Present (Field14 (Ent)) then
 458          Print_Str (Prefix);
 459          Write_Field14_Name (Ent);
 460          Write_Str (" = ");
 461          Print_Field (Field14 (Ent));
 462          Print_Eol;
 463       end if;
 464
 465       if Field_Present (Field15 (Ent)) then
 466          Print_Str (Prefix);
 467          Write_Field15_Name (Ent);
 468          Write_Str (" = ");
 469          Print_Field (Field15 (Ent));
 470          Print_Eol;
 471       end if;
 472
 473       if Field_Present (Field16 (Ent)) then
 474          Print_Str (Prefix);
 475          Write_Field16_Name (Ent);
 476          Write_Str (" = ");
 477          Print_Field (Field16 (Ent));
 478          Print_Eol;
 479       end if;
 480
 481       if Field_Present (Field17 (Ent)) then
 482          Print_Str (Prefix);
 483          Write_Field17_Name (Ent);
 484          Write_Str (" = ");
 485          Print_Field (Field17 (Ent));
 486          Print_Eol;
 487       end if;
 488
 489       if Field_Present (Field18 (Ent)) then
 490          Print_Str (Prefix);
 491          Write_Field18_Name (Ent);
 492          Write_Str (" = ");
 493          Print_Field (Field18 (Ent));
 494          Print_Eol;
 495       end if;
 496
 497       if Field_Present (Field19 (Ent)) then
 498          Print_Str (Prefix);
 499          Write_Field19_Name (Ent);
 500          Write_Str (" = ");
 501          Print_Field (Field19 (Ent));
 502          Print_Eol;
 503       end if;
 504
 505       if Field_Present (Field20 (Ent)) then
 506          Print_Str (Prefix);
 507          Write_Field20_Name (Ent);
 508          Write_Str (" = ");
 509          Print_Field (Field20 (Ent));
 510          Print_Eol;
 511       end if;
 512
 513       if Field_Present (Field21 (Ent)) then
 514          Print_Str (Prefix);
 515          Write_Field21_Name (Ent);
 516          Write_Str (" = ");
 517          Print_Field (Field21 (Ent));
 518          Print_Eol;
 519       end if;
 520
 521       if Field_Present (Field22 (Ent)) then
 522          Print_Str (Prefix);
 523          Write_Field22_Name (Ent);
 524          Write_Str (" = ");
 525
 526          --  Mechanism case has to be handled specially
 527
 528          if Ekind (Ent) = E_Function or else Is_Formal (Ent) then
 529             declare
 530                M : constant Mechanism_Type := Mechanism (Ent);
 531
 532             begin
 533                case M is
 534                   when Default_Mechanism  => Write_Str ("Default");
 535                   when By_Copy            => Write_Str ("By_Copy");
 536                   when By_Reference       => Write_Str ("By_Reference");
 537                   when By_Descriptor      => Write_Str ("By_Descriptor");
 538                   when By_Descriptor_UBS  => Write_Str ("By_Descriptor_UBS");
 539                   when By_Descriptor_UBSB => Write_Str ("By_Descriptor_UBSB");
 540                   when By_Descriptor_UBA  => Write_Str ("By_Descriptor_UBA");
 541                   when By_Descriptor_S    => Write_Str ("By_Descriptor_S");
 542                   when By_Descriptor_SB   => Write_Str ("By_Descriptor_SB");
 543                   when By_Descriptor_A    => Write_Str ("By_Descriptor_A");
 544                   when By_Descriptor_NCA  => Write_Str ("By_Descriptor_NCA");
 545
 546                   when 1 .. Mechanism_Type'Last =>
 547                      Write_Str ("By_Copy if size <= ");
 548                      Write_Int (Int (M));
 549
 550                end case;
 551             end;
 552
 553          --  Normal case (not Mechanism)
 554
 555          else
 556             Print_Field (Field22 (Ent));
 557          end if;
 558
 559          Print_Eol;
 560       end if;
 561
 562       if Field_Present (Field23 (Ent)) then
 563          Print_Str (Prefix);
 564          Write_Field23_Name (Ent);
 565          Write_Str (" = ");
 566          Print_Field (Field23 (Ent));
 567          Print_Eol;
 568       end if;
 569
 570       if Field_Present (Field24 (Ent)) then
 571          Print_Str (Prefix);
 572          Write_Field24_Name (Ent);
 573          Write_Str (" = ");
 574          Print_Field (Field24 (Ent));
 575          Print_Eol;
 576       end if;
 577
 578       if Field_Present (Field25 (Ent)) then
 579          Print_Str (Prefix);
 580          Write_Field25_Name (Ent);
 581          Write_Str (" = ");
 582          Print_Field (Field25 (Ent));
 583          Print_Eol;
 584       end if;
 585
 586       if Field_Present (Field26 (Ent)) then
 587          Print_Str (Prefix);
 588          Write_Field26_Name (Ent);
 589          Write_Str (" = ");
 590          Print_Field (Field26 (Ent));
 591          Print_Eol;
 592       end if;
 593
 594       if Field_Present (Field27 (Ent)) then
 595          Print_Str (Prefix);
 596          Write_Field27_Name (Ent);
 597          Write_Str (" = ");
 598          Print_Field (Field27 (Ent));
 599          Print_Eol;
 600       end if;
 601
 602       Write_Entity_Flags (Ent, Prefix);
 603    end Print_Entity_Info;
 604
 605    ---------------
 606    -- Print_Eol --
 607    ---------------
 608
 609    procedure Print_Eol is
 610    begin
 611       if Phase = Printing then
 612          Write_Eol;
 613       end if;
 614    end Print_Eol;
 615
 616    -----------------
 617    -- Print_Field --
 618    -----------------
 619
 620    procedure Print_Field (Val : Union_Id; Format : UI_Format := Auto) is
 621    begin
 622       if Phase /= Printing then
 623          return;
 624       end if;
 625
 626       if Val in Node_Range then
 627          Print_Node_Ref (Node_Id (Val));
 628
 629       elsif Val in List_Range then
 630          Print_List_Ref (List_Id (Val));
 631
 632       elsif Val in Elist_Range then
 633          Print_Elist_Ref (Elist_Id (Val));
 634
 635       elsif Val in Names_Range then
 636          Print_Name (Name_Id (Val));
 637          Write_Str (" (Name_Id=");
 638          Write_Int (Int (Val));
 639          Write_Char (')');
 640
 641       elsif Val in Strings_Range then
 642          Write_String_Table_Entry (String_Id (Val));
 643          Write_Str (" (String_Id=");
 644          Write_Int (Int (Val));
 645          Write_Char (')');
 646
 647       elsif Val in Uint_Range then
 648          UI_Write (From_Union (Val), Format);
 649          Write_Str (" (Uint = ");
 650          Write_Int (Int (Val));
 651          Write_Char (')');
 652
 653       elsif Val in Ureal_Range then
 654          UR_Write (From_Union (Val));
 655          Write_Str (" (Ureal = ");
 656          Write_Int (Int (Val));
 657          Write_Char (')');
 658
 659       else
 660          Print_Str ("****** Incorrect value = ");
 661          Print_Int (Int (Val));
 662       end if;
 663    end Print_Field;
 664
 665    ----------------
 666    -- Print_Flag --
 667    ----------------
 668
 669    procedure Print_Flag (F : Boolean) is
 670    begin
 671       if F then
 672          Print_Str ("True");
 673       else
 674          Print_Str ("False");
 675       end if;
 676    end Print_Flag;
 677
 678    ----------------
 679    -- Print_Init --
 680    ----------------
 681
 682    procedure Print_Init is
 683    begin
 684       Printing_Descendants := True;
 685       Write_Eol;
 686
 687       --  Allocate and clear serial number hash table. The size is 150% of
 688       --  the maximum possible number of entries, so that the hash table
 689       --  cannot get significantly overloaded.
 690
 691       Hash_Table_Len := (150 * (Num_Nodes + Num_Lists + Num_Elists)) / 100;
 692       Hash_Table := new Hash_Table_Type  (0 .. Hash_Table_Len - 1);
 693
 694       for J in Hash_Table'Range loop
 695          Hash_Table (J).Serial := 0;
 696       end loop;
 697
 698    end Print_Init;
 699
 700    ---------------
 701    -- Print_Int --
 702    ---------------
 703
 704    procedure Print_Int (I : Int) is
 705    begin
 706       if Phase = Printing then
 707          Write_Int (I);
 708       end if;
 709    end Print_Int;
 710
 711    --------------------
 712    -- Print_List_Ref --
 713    --------------------
 714
 715    procedure Print_List_Ref (L : List_Id) is
 716    begin
 717       if Phase /= Printing then
 718          return;
 719       end if;
 720
 721       if No (L) then
 722          Write_Str ("<no list>");
 723
 724       elsif Is_Empty_List (L) then
 725          Write_Str ("<empty list> (List_Id=");
 726          Write_Int (Int (L));
 727          Write_Char (')');
 728
 729       else
 730          Write_Str ("List");
 731
 732          if Printing_Descendants then
 733             Write_Str (" #");
 734             Write_Int (Serial_Number (Int (L)));
 735          end if;
 736
 737          Write_Str (" (List_Id=");
 738          Write_Int (Int (L));
 739          Write_Char (')');
 740       end if;
 741    end Print_List_Ref;
 742
 743    ------------------------
 744    -- Print_List_Subtree --
 745    ------------------------
 746
 747    procedure Print_List_Subtree (L : List_Id) is
 748    begin
 749       Print_Init;
 750
 751       Next_Serial_Number := 1;
 752       Phase := Marking;
 753       Visit_List (L, "");
 754
 755       Next_Serial_Number := 1;
 756       Phase := Printing;
 757       Visit_List (L, "");
 758
 759       Print_Term;
 760    end Print_List_Subtree;
 761
 762    ----------------
 763    -- Print_Name --
 764    ----------------
 765
 766    procedure Print_Name (N : Name_Id) is
 767    begin
 768       if Phase = Printing then
 769          if N = No_Name then
 770             Print_Str ("<No_Name>");
 771
 772          elsif N = Error_Name then
 773             Print_Str ("<Error_Name>");
 774
 775          elsif Is_Valid_Name (N) then
 776             Get_Name_String (N);
 777             Print_Char ('"');
 778             Write_Name (N);
 779             Print_Char ('"');
 780
 781          else
 782             Print_Str ("<invalid name ???>");
 783          end if;
 784       end if;
 785    end Print_Name;
 786
 787    ----------------
 788    -- Print_Node --
 789    ----------------
 790
 791    procedure Print_Node
 792      (N           : Node_Id;
 793       Prefix_Str  : String;
 794       Prefix_Char : Character)
 795    is
 796       F : Fchar;
 797       P : Natural := Pchar_Pos (Nkind (N));
 798
 799       Field_To_Be_Printed : Boolean;
 800       Prefix_Str_Char     : String (Prefix_Str'First .. Prefix_Str'Last + 1);
 801
 802       Sfile : Source_File_Index;
 803       Notes : Boolean;
 804       Fmt   : UI_Format;
 805
 806    begin
 807       if Phase /= Printing then
 808          return;
 809       end if;
 810
 811       if Nkind (N) = N_Integer_Literal and then Print_In_Hex (N) then
 812          Fmt := Hex;
 813       else
 814          Fmt := Auto;
 815       end if;
 816
 817       Prefix_Str_Char (Prefix_Str'Range)    := Prefix_Str;
 818       Prefix_Str_Char (Prefix_Str'Last + 1) := Prefix_Char;
 819
 820       --  Print header line
 821
 822       Print_Str (Prefix_Str);
 823       Print_Node_Ref (N);
 824
 825       Notes := False;
 826
 827       if N > Atree_Private_Part.Nodes.Last then
 828          Print_Str (" (no such node)");
 829          Print_Eol;
 830          return;
 831       end if;
 832
 833       if Comes_From_Source (N) then
 834          Notes := True;
 835          Print_Str (" (source");
 836       end if;
 837
 838       if Analyzed (N) then
 839          if not Notes then
 840             Notes := True;
 841             Print_Str (" (");
 842          else
 843             Print_Str (",");
 844          end if;
 845
 846          Print_Str ("analyzed");
 847       end if;
 848
 849       if Error_Posted (N) then
 850          if not Notes then
 851             Notes := True;
 852             Print_Str (" (");
 853          else
 854             Print_Str (",");
 855          end if;
 856
 857          Print_Str ("posted");
 858       end if;
 859
 860       if Notes then
 861          Print_Char (')');
 862       end if;
 863
 864       Print_Eol;
 865
 866       if Is_Rewrite_Substitution (N) then
 867          Print_Str (Prefix_Str);
 868          Print_Str (" Rewritten: original node = ");
 869          Print_Node_Ref (Original_Node (N));
 870          Print_Eol;
 871       end if;
 872
 873       if N = Empty then
 874          return;
 875       end if;
 876
 877       if not Is_List_Member (N) then
 878          Print_Str (Prefix_Str);
 879          Print_Str (" Parent = ");
 880          Print_Node_Ref (Parent (N));
 881          Print_Eol;
 882       end if;
 883
 884       --  Print Sloc field if it is set
 885
 886       if Sloc (N) /= No_Location then
 887          Print_Str (Prefix_Str_Char);
 888          Print_Str ("Sloc = ");
 889
 890          if Sloc (N) = Standard_Location then
 891             Print_Str ("Standard_Location");
 892
 893          elsif Sloc (N) = Standard_ASCII_Location then
 894             Print_Str ("Standard_ASCII_Location");
 895
 896          else
 897             Sfile := Get_Source_File_Index (Sloc (N));
 898             Print_Int (Int (Sloc (N)) - Int (Source_Text (Sfile)'First));
 899             Write_Str ("  ");
 900             Write_Location (Sloc (N));
 901          end if;
 902
 903          Print_Eol;
 904       end if;
 905
 906       --  Print Chars field if present
 907
 908       if Nkind (N) in N_Has_Chars and then Chars (N) /= No_Name then
 909          Print_Str (Prefix_Str_Char);
 910          Print_Str ("Chars = ");
 911          Print_Name (Chars (N));
 912          Write_Str (" (Name_Id=");
 913          Write_Int (Int (Chars (N)));
 914          Write_Char (')');
 915          Print_Eol;
 916       end if;
 917
 918       --  Special field print operations for non-entity nodes
 919
 920       if Nkind (N) not in N_Entity then
 921
 922          --  Deal with Left_Opnd and Right_Opnd fields
 923
 924          if Nkind (N) in N_Op
 925            or else Nkind (N) = N_And_Then
 926            or else Nkind (N) = N_Or_Else
 927            or else Nkind (N) in N_Membership_Test
 928          then
 929             --  Print Left_Opnd if present
 930
 931             if Nkind (N) not in N_Unary_Op then
 932                Print_Str (Prefix_Str_Char);
 933                Print_Str ("Left_Opnd = ");
 934                Print_Node_Ref (Left_Opnd (N));
 935                Print_Eol;
 936             end if;
 937
 938             --  Print Right_Opnd
 939
 940             Print_Str (Prefix_Str_Char);
 941             Print_Str ("Right_Opnd = ");
 942             Print_Node_Ref (Right_Opnd (N));
 943             Print_Eol;
 944          end if;
 945
 946          --  Print Entity field if operator (other cases of Entity
 947          --  are in the table, so are handled in the normal circuit)
 948
 949          if Nkind (N) in N_Op and then Present (Entity (N)) then
 950             Print_Str (Prefix_Str_Char);
 951             Print_Str ("Entity = ");
 952             Print_Node_Ref (Entity (N));
 953             Print_Eol;
 954          end if;
 955
 956          --  Print special fields if we have a subexpression
 957
 958          if Nkind (N) in N_Subexpr then
 959
 960             if Assignment_OK (N) then
 961                Print_Str (Prefix_Str_Char);
 962                Print_Str ("Assignment_OK = True");
 963                Print_Eol;
 964             end if;
 965
 966             if Do_Range_Check (N) then
 967                Print_Str (Prefix_Str_Char);
 968                Print_Str ("Do_Range_Check = True");
 969                Print_Eol;
 970             end if;
 971
 972             if Has_Dynamic_Length_Check (N) then
 973                Print_Str (Prefix_Str_Char);
 974                Print_Str ("Has_Dynamic_Length_Check = True");
 975                Print_Eol;
 976             end if;
 977
 978             if Has_Dynamic_Range_Check (N) then
 979                Print_Str (Prefix_Str_Char);
 980                Print_Str ("Has_Dynamic_Range_Check = True");
 981                Print_Eol;
 982             end if;
 983
 984             if Is_Controlling_Actual (N) then
 985                Print_Str (Prefix_Str_Char);
 986                Print_Str ("Is_Controlling_Actual = True");
 987                Print_Eol;
 988             end if;
 989
 990             if Is_Overloaded (N) then
 991                Print_Str (Prefix_Str_Char);
 992                Print_Str ("Is_Overloaded = True");
 993                Print_Eol;
 994             end if;
 995
 996             if Is_Static_Expression (N) then
 997                Print_Str (Prefix_Str_Char);
 998                Print_Str ("Is_Static_Expression = True");
 999                Print_Eol;
1000             end if;
1001
1002             if Must_Not_Freeze (N) then
1003                Print_Str (Prefix_Str_Char);
1004                Print_Str ("Must_Not_Freeze = True");
1005                Print_Eol;
1006             end if;
1007
1008             if Paren_Count (N) /= 0 then
1009                Print_Str (Prefix_Str_Char);
1010                Print_Str ("Paren_Count = ");
1011                Print_Int (Int (Paren_Count (N)));
1012                Print_Eol;
1013             end if;
1014
1015             if Raises_Constraint_Error (N) then
1016                Print_Str (Prefix_Str_Char);
1017                Print_Str ("Raise_Constraint_Error = True");
1018                Print_Eol;
1019             end if;
1020
1021          end if;
1022
1023          --  Print Do_Overflow_Check field if present
1024
1025          if Nkind (N) in N_Op and then Do_Overflow_Check (N) then
1026             Print_Str (Prefix_Str_Char);
1027             Print_Str ("Do_Overflow_Check = True");
1028             Print_Eol;
1029          end if;
1030
1031          --  Print Etype field if present (printing of this field for entities
1032          --  is handled by the Print_Entity_Info procedure).
1033
1034          if Nkind (N) in N_Has_Etype and then Present (Etype (N)) then
1035             Print_Str (Prefix_Str_Char);
1036             Print_Str ("Etype = ");
1037             Print_Node_Ref (Etype (N));
1038             Print_Eol;
1039          end if;
1040       end if;
1041
1042       --  Loop to print fields included in Pchars array
1043
1044       while P < Pchar_Pos (Node_Kind'Succ (Nkind (N))) loop
1045          F := Pchars (P);
1046          P := P + 1;
1047
1048          --  Check for case of False flag, which we never print, or
1049          --  an Empty field, which is also never printed
1050
1051          case F is
1052             when F_Field1 =>
1053                Field_To_Be_Printed := Field1 (N) /= Union_Id (Empty);
1054
1055             when F_Field2 =>
1056                Field_To_Be_Printed := Field2 (N) /= Union_Id (Empty);
1057
1058             when F_Field3 =>
1059                Field_To_Be_Printed := Field3 (N) /= Union_Id (Empty);
1060
1061             when F_Field4 =>
1062                Field_To_Be_Printed := Field4 (N) /= Union_Id (Empty);
1063
1064             when F_Field5 =>
1065                Field_To_Be_Printed := Field5 (N) /= Union_Id (Empty);
1066
1067             when F_Flag4  => Field_To_Be_Printed := Flag4  (N);
1068             when F_Flag5  => Field_To_Be_Printed := Flag5  (N);
1069             when F_Flag6  => Field_To_Be_Printed := Flag6  (N);
1070             when F_Flag7  => Field_To_Be_Printed := Flag7  (N);
1071             when F_Flag8  => Field_To_Be_Printed := Flag8  (N);
1072             when F_Flag9  => Field_To_Be_Printed := Flag9  (N);
1073             when F_Flag10 => Field_To_Be_Printed := Flag10 (N);
1074             when F_Flag11 => Field_To_Be_Printed := Flag11 (N);
1075             when F_Flag12 => Field_To_Be_Printed := Flag12 (N);
1076             when F_Flag13 => Field_To_Be_Printed := Flag13 (N);
1077             when F_Flag14 => Field_To_Be_Printed := Flag14 (N);
1078             when F_Flag15 => Field_To_Be_Printed := Flag15 (N);
1079             when F_Flag16 => Field_To_Be_Printed := Flag16 (N);
1080             when F_Flag17 => Field_To_Be_Printed := Flag17 (N);
1081             when F_Flag18 => Field_To_Be_Printed := Flag18 (N);
1082
1083             --  Flag1,2,3 are no longer used
1084
1085             when F_Flag1  => raise Program_Error;
1086             when F_Flag2  => raise Program_Error;
1087             when F_Flag3  => raise Program_Error;
1088
1089          end case;
1090
1091          --  Print field if it is to be printed
1092
1093          if Field_To_Be_Printed then
1094             Print_Str (Prefix_Str_Char);
1095
1096             while P < Pchar_Pos (Node_Kind'Succ (Nkind (N)))
1097               and then Pchars (P) not in Fchar
1098             loop
1099                Print_Char (Pchars (P));
1100                P := P + 1;
1101             end loop;
1102
1103             Print_Str (" = ");
1104
1105             case F is
1106                when F_Field1 => Print_Field (Field1 (N), Fmt);
1107                when F_Field2 => Print_Field (Field2 (N), Fmt);
1108                when F_Field3 => Print_Field (Field3 (N), Fmt);
1109                when F_Field4 => Print_Field (Field4 (N), Fmt);
1110
1111                --  Special case End_Span = Uint5
1112
1113                when F_Field5 =>
1114                   if Nkind (N) = N_Case_Statement
1115                     or else Nkind (N) = N_If_Statement
1116                   then
1117                      Print_End_Span (N);
1118                   else
1119                      Print_Field (Field5 (N), Fmt);
1120                   end if;
1121
1122                when F_Flag4  => Print_Flag  (Flag4 (N));
1123                when F_Flag5  => Print_Flag  (Flag5 (N));
1124                when F_Flag6  => Print_Flag  (Flag6 (N));
1125                when F_Flag7  => Print_Flag  (Flag7 (N));
1126                when F_Flag8  => Print_Flag  (Flag8 (N));
1127                when F_Flag9  => Print_Flag  (Flag9 (N));
1128                when F_Flag10 => Print_Flag  (Flag10 (N));
1129                when F_Flag11 => Print_Flag  (Flag11 (N));
1130                when F_Flag12 => Print_Flag  (Flag12 (N));
1131                when F_Flag13 => Print_Flag  (Flag13 (N));
1132                when F_Flag14 => Print_Flag  (Flag14 (N));
1133                when F_Flag15 => Print_Flag  (Flag15 (N));
1134                when F_Flag16 => Print_Flag  (Flag16 (N));
1135                when F_Flag17 => Print_Flag  (Flag17 (N));
1136                when F_Flag18 => Print_Flag  (Flag18 (N));
1137
1138                --  Flag1,2,3 are no longer used
1139
1140                when F_Flag1  => raise Program_Error;
1141                when F_Flag2  => raise Program_Error;
1142                when F_Flag3  => raise Program_Error;
1143             end case;
1144
1145             Print_Eol;
1146
1147          --  Field is not to be printed (False flag field)
1148
1149          else
1150             while P < Pchar_Pos (Node_Kind'Succ (Nkind (N)))
1151               and then Pchars (P) not in Fchar
1152             loop
1153                P := P + 1;
1154             end loop;
1155          end if;
1156
1157       end loop;
1158
1159       --  Print entity information for entities
1160
1161       if Nkind (N) in N_Entity then
1162          Print_Entity_Info (N, Prefix_Str_Char);
1163       end if;
1164
1165    end Print_Node;
1166
1167    ---------------------
1168    -- Print_Node_Kind --
1169    ---------------------
1170
1171    procedure Print_Node_Kind (N : Node_Id) is
1172       Ucase : Boolean;
1173       S     : constant String := Node_Kind'Image (Nkind (N));
1174
1175    begin
1176       if Phase = Printing then
1177          Ucase := True;
1178
1179          --  Note: the call to Fold_Upper in this loop is to get past the GNAT
1180          --  bug of 'Image returning lower case instead of upper case.
1181
1182          for J in S'Range loop
1183             if Ucase then
1184                Write_Char (Fold_Upper (S (J)));
1185             else
1186                Write_Char (Fold_Lower (S (J)));
1187             end if;
1188
1189             Ucase := (S (J) = '_');
1190          end loop;
1191       end if;
1192    end Print_Node_Kind;
1193
1194    --------------------
1195    -- Print_Node_Ref --
1196    --------------------
1197
1198    procedure Print_Node_Ref (N : Node_Id) is
1199       S : Nat;
1200
1201    begin
1202       if Phase /= Printing then
1203          return;
1204       end if;
1205
1206       if N = Empty then
1207          Write_Str ("<empty>");
1208
1209       elsif N = Error then
1210          Write_Str ("<error>");
1211
1212       else
1213          if Printing_Descendants then
1214             S := Serial_Number (Int (N));
1215
1216             if S /= 0 then
1217                Write_Str ("Node");
1218                Write_Str (" #");
1219                Write_Int (S);
1220                Write_Char (' ');
1221             end if;
1222          end if;
1223
1224          Print_Node_Kind (N);
1225
1226          if Nkind (N) in N_Has_Chars then
1227             Write_Char (' ');
1228             Print_Name (Chars (N));
1229          end if;
1230
1231          if Nkind (N) in N_Entity then
1232             Write_Str (" (Entity_Id=");
1233          else
1234             Write_Str (" (Node_Id=");
1235          end if;
1236
1237          Write_Int (Int (N));
1238
1239          if Sloc (N) <= Standard_Location then
1240             Write_Char ('s');
1241          end if;
1242
1243          Write_Char (')');
1244
1245       end if;
1246    end Print_Node_Ref;
1247
1248    ------------------------
1249    -- Print_Node_Subtree --
1250    ------------------------
1251
1252    procedure Print_Node_Subtree (N : Node_Id) is
1253    begin
1254       Print_Init;
1255
1256       Next_Serial_Number := 1;
1257       Phase := Marking;
1258       Visit_Node (N, "", ' ');
1259
1260       Next_Serial_Number := 1;
1261       Phase := Printing;
1262       Visit_Node (N, "", ' ');
1263
1264       Print_Term;
1265    end Print_Node_Subtree;
1266
1267    ---------------
1268    -- Print_Str --
1269    ---------------
1270
1271    procedure Print_Str (S : String) is
1272    begin
1273       if Phase = Printing then
1274          Write_Str (S);
1275       end if;
1276    end Print_Str;
1277
1278    --------------------------
1279    -- Print_Str_Mixed_Case --
1280    --------------------------
1281
1282    procedure Print_Str_Mixed_Case (S : String) is
1283       Ucase : Boolean;
1284
1285    begin
1286       if Phase = Printing then
1287          Ucase := True;
1288
1289          for J in S'Range loop
1290             if Ucase then
1291                Write_Char (S (J));
1292             else
1293                Write_Char (Fold_Lower (S (J)));
1294             end if;
1295
1296             Ucase := (S (J) = '_');
1297          end loop;
1298       end if;
1299    end Print_Str_Mixed_Case;
1300
1301    ----------------
1302    -- Print_Term --
1303    ----------------
1304
1305    procedure Print_Term is
1306       procedure Free is new Unchecked_Deallocation
1307         (Hash_Table_Type, Access_Hash_Table_Type);
1308
1309    begin
1310       Free (Hash_Table);
1311    end Print_Term;
1312
1313    ---------------------
1314    -- Print_Tree_Elist --
1315    ---------------------
1316
1317    procedure Print_Tree_Elist (E : Elist_Id) is
1318       M : Elmt_Id;
1319
1320    begin
1321       Printing_Descendants := False;
1322       Phase := Printing;
1323
1324       Print_Elist_Ref (E);
1325       Print_Eol;
1326
1327       M := First_Elmt (E);
1328
1329       if No (M) then
1330          Print_Str ("<empty element list>");
1331          Print_Eol;
1332
1333       else
1334          loop
1335             Print_Char ('|');
1336             Print_Eol;
1337             exit when No (Next_Elmt (M));
1338             Print_Node (Node (M), "", '|');
1339             Next_Elmt (M);
1340          end loop;
1341
1342          Print_Node (Node (M), "", ' ');
1343          Print_Eol;
1344       end if;
1345    end Print_Tree_Elist;
1346
1347    ---------------------
1348    -- Print_Tree_List --
1349    ---------------------
1350
1351    procedure Print_Tree_List (L : List_Id) is
1352       N : Node_Id;
1353
1354    begin
1355       Printing_Descendants := False;
1356       Phase := Printing;
1357
1358       Print_List_Ref (L);
1359       Print_Str (" List_Id=");
1360       Print_Int (Int (L));
1361       Print_Eol;
1362
1363       N := First (L);
1364
1365       if N = Empty then
1366          Print_Str ("<empty node list>");
1367          Print_Eol;
1368
1369       else
1370          loop
1371             Print_Char ('|');
1372             Print_Eol;
1373             exit when Next (N) = Empty;
1374             Print_Node (N, "", '|');
1375             Next (N);
1376          end loop;
1377
1378          Print_Node (N, "", ' ');
1379          Print_Eol;
1380       end if;
1381    end Print_Tree_List;
1382
1383    ---------------------
1384    -- Print_Tree_Node --
1385    ---------------------
1386
1387    procedure Print_Tree_Node (N : Node_Id; Label : String := "") is
1388    begin
1389       Printing_Descendants := False;
1390       Phase := Printing;
1391       Print_Node (N, Label, ' ');
1392    end Print_Tree_Node;
1393
1394    --------
1395    -- pt --
1396    --------
1397
1398    procedure pt (N : Node_Id) is
1399    begin
1400       Print_Node_Subtree (N);
1401    end pt;
1402
1403    -------------------
1404    -- Serial_Number --
1405    -------------------
1406
1407    --  The hashing algorithm is to use the remainder of the ID value divided
1408    --  by the hash table length as the starting point in the table, and then
1409    --  handle collisions by serial searching wrapping at the end of the table.
1410
1411    Hash_Slot : Nat;
1412    --  Set by an unsuccessful call to Serial_Number (one which returns zero)
1413    --  to save the slot that should be used if Set_Serial_Number is called.
1414
1415    function Serial_Number (Id : Int) return Nat is
1416       H : Int := Id mod Hash_Table_Len;
1417
1418    begin
1419       while Hash_Table (H).Serial /= 0 loop
1420
1421          if Id = Hash_Table (H).Id then
1422             return Hash_Table (H).Serial;
1423          end if;
1424
1425          H := H + 1;
1426
1427          if H > Hash_Table'Last then
1428             H := 0;
1429          end if;
1430       end loop;
1431
1432       --  Entry was not found, save slot number for possible subsequent call
1433       --  to Set_Serial_Number, and unconditionally save the Id in this slot
1434       --  in case of such a call (the Id field is never read if the serial
1435       --  number of the slot is zero, so this is harmless in the case where
1436       --  Set_Serial_Number is not subsequently called).
1437
1438       Hash_Slot := H;
1439       Hash_Table (H).Id := Id;
1440       return 0;
1441
1442    end Serial_Number;
1443
1444    -----------------------
1445    -- Set_Serial_Number --
1446    -----------------------
1447
1448    procedure Set_Serial_Number is
1449    begin
1450       Hash_Table (Hash_Slot).Serial := Next_Serial_Number;
1451       Next_Serial_Number := Next_Serial_Number + 1;
1452    end Set_Serial_Number;
1453
1454    ---------------
1455    -- Tree_Dump --
1456    ---------------
1457
1458    procedure Tree_Dump is
1459       procedure Underline;
1460       --  Put underline under string we just printed
1461
1462       procedure Underline is
1463          Col : constant Int := Column;
1464
1465       begin
1466          Write_Eol;
1467
1468          while Col > Column loop
1469             Write_Char ('-');
1470          end loop;
1471
1472          Write_Eol;
1473       end Underline;
1474
1475    --  Start of processing for Tree_Dump. Note that we turn off the tree dump
1476    --  flags immediately, before starting the dump. This avoids generating two
1477    --  copies of the dump if an abort occurs after printing the dump, and more
1478    --  importantly, avoids an infinite loop if an abort occurs during the dump.
1479
1480    --  Note: unlike in the source print case (in Sprint), we do not output
1481    --  separate trees for each unit. Instead the -df debug switch causes the
1482    --  tree that is output from the main unit to trace references into other
1483    --  units (normally such references are not traced). Since all other units
1484    --  are linked to the main unit by at least one reference, this causes all
1485    --  tree nodes to be included in the output tree.
1486
1487    begin
1488       if Debug_Flag_Y then
1489          Debug_Flag_Y := False;
1490          Write_Eol;
1491          Write_Str ("Tree created for Standard (spec) ");
1492          Underline;
1493          Print_Node_Subtree (Standard_Package_Node);
1494          Write_Eol;
1495       end if;
1496
1497       if Debug_Flag_T then
1498          Debug_Flag_T := False;
1499
1500          Write_Eol;
1501          Write_Str ("Tree created for ");
1502          Write_Unit_Name (Unit_Name (Main_Unit));
1503          Underline;
1504          Print_Node_Subtree (Cunit (Main_Unit));
1505          Write_Eol;
1506       end if;
1507
1508    end Tree_Dump;
1509
1510    -----------------
1511    -- Visit_Elist --
1512    -----------------
1513
1514    procedure Visit_Elist (E : Elist_Id; Prefix_Str : String) is
1515       M : Elmt_Id;
1516       N : Node_Id;
1517       S : constant Nat := Serial_Number (Int (E));
1518
1519    begin
1520       --  In marking phase, return if already marked, otherwise set next
1521       --  serial number in hash table for later reference.
1522
1523       if Phase = Marking then
1524          if S /= 0 then
1525             return; -- already visited
1526          else
1527             Set_Serial_Number;
1528          end if;
1529
1530       --  In printing phase, if already printed, then return, otherwise we
1531       --  are printing the next item, so increment the serial number.
1532
1533       else
1534          if S < Next_Serial_Number then
1535             return; -- already printed
1536          else
1537             Next_Serial_Number := Next_Serial_Number + 1;
1538          end if;
1539       end if;
1540
1541       --  Now process the list (Print calls have no effect in marking phase)
1542
1543       Print_Str (Prefix_Str);
1544       Print_Elist_Ref (E);
1545       Print_Eol;
1546
1547       if Is_Empty_Elmt_List (E) then
1548          Print_Str (Prefix_Str);
1549          Print_Str ("(Empty element list)");
1550          Print_Eol;
1551          Print_Eol;
1552
1553       else
1554          if Phase = Printing then
1555             M := First_Elmt (E);
1556             while Present (M) loop
1557                N := Node (M);
1558                Print_Str (Prefix_Str);
1559                Print_Str (" ");
1560                Print_Node_Ref (N);
1561                Print_Eol;
1562                Next_Elmt (M);
1563             end loop;
1564
1565             Print_Str (Prefix_Str);
1566             Print_Eol;
1567          end if;
1568
1569          M := First_Elmt (E);
1570          while Present (M) loop
1571             Visit_Node (Node (M), Prefix_Str, ' ');
1572             Next_Elmt (M);
1573          end loop;
1574       end if;
1575    end Visit_Elist;
1576
1577    ----------------
1578    -- Visit_List --
1579    ----------------
1580
1581    procedure Visit_List (L : List_Id; Prefix_Str : String) is
1582       N : Node_Id;
1583       S : constant Nat := Serial_Number (Int (L));
1584
1585    begin
1586       --  In marking phase, return if already marked, otherwise set next
1587       --  serial number in hash table for later reference.
1588
1589       if Phase = Marking then
1590          if S /= 0 then
1591             return;
1592          else
1593             Set_Serial_Number;
1594          end if;
1595
1596       --  In printing phase, if already printed, then return, otherwise we
1597       --  are printing the next item, so increment the serial number.
1598
1599       else
1600          if S < Next_Serial_Number then
1601             return; -- already printed
1602          else
1603             Next_Serial_Number := Next_Serial_Number + 1;
1604          end if;
1605       end if;
1606
1607       --  Now process the list (Print calls have no effect in marking phase)
1608
1609       Print_Str (Prefix_Str);
1610       Print_List_Ref (L);
1611       Print_Eol;
1612
1613       Print_Str (Prefix_Str);
1614       Print_Str ("|Parent = ");
1615       Print_Node_Ref (Parent (L));
1616       Print_Eol;
1617
1618       N := First (L);
1619
1620       if N = Empty then
1621          Print_Str (Prefix_Str);
1622          Print_Str ("(Empty list)");
1623          Print_Eol;
1624          Print_Eol;
1625
1626       else
1627          Print_Str (Prefix_Str);
1628          Print_Char ('|');
1629          Print_Eol;
1630
1631          while Next (N) /= Empty loop
1632             Visit_Node (N, Prefix_Str, '|');
1633             Next (N);
1634          end loop;
1635       end if;
1636
1637       Visit_Node (N, Prefix_Str, ' ');
1638    end Visit_List;
1639
1640    ----------------
1641    -- Visit_Node --
1642    ----------------
1643
1644    procedure Visit_Node
1645      (N           : Node_Id;
1646       Prefix_Str  : String;
1647       Prefix_Char : Character)
1648    is
1649       New_Prefix : String (Prefix_Str'First .. Prefix_Str'Last + 2);
1650       --  Prefix string for printing referenced fields
1651
1652       procedure Visit_Descendent
1653         (D         : Union_Id;
1654          No_Indent : Boolean := False);
1655       --  This procedure tests the given value of one of the Fields referenced
1656       --  by the current node to determine whether to visit it recursively.
1657       --  Normally No_Indent is false, which means tha the visited node will
1658       --  be indented using New_Prefix. If No_Indent is set to True, then
1659       --  this indentation is skipped, and Prefix_Str is used for the call
1660       --  to print the descendent. No_Indent is effective only if the
1661       --  referenced descendent is a node.
1662
1663       ----------------------
1664       -- Visit_Descendent --
1665       ----------------------
1666
1667       procedure Visit_Descendent
1668         (D         : Union_Id;
1669          No_Indent : Boolean := False)
1670       is
1671       begin
1672          --  Case of descendent is a node
1673
1674          if D in Node_Range then
1675
1676             --  Don't bother about Empty or Error descendents
1677
1678             if D <= Union_Id (Empty_Or_Error) then
1679                return;
1680             end if;
1681
1682             declare
1683                Nod : constant Node_Or_Entity_Id := Node_Or_Entity_Id (D);
1684
1685             begin
1686                --  Descendents in one of the standardly compiled internal
1687                --  packages are normally ignored, unless the parent is also
1688                --  in such a package (happens when Standard itself is output)
1689                --  or if the -df switch is set which causes all links to be
1690                --  followed, even into package standard.
1691
1692                if Sloc (Nod) <= Standard_Location then
1693                   if Sloc (N) > Standard_Location
1694                     and then not Debug_Flag_F
1695                   then
1696                      return;
1697                   end if;
1698
1699                --  Don't bother about a descendent in a different unit than
1700                --  the node we came from unless the -df switch is set. Note
1701                --  that we know at this point that Sloc (D) > Standard_Location
1702
1703                --  Note: the tests for No_Location here just make sure that we
1704                --  don't blow up on a node which is missing an Sloc value. This
1705                --  should not normally happen.
1706
1707                else
1708                   if (Sloc (N) <= Standard_Location
1709                         or else Sloc (N) = No_Location
1710                         or else Sloc (Nod) = No_Location
1711                         or else not In_Same_Source_Unit (Nod, N))
1712                     and then not Debug_Flag_F
1713                   then
1714                      return;
1715                   end if;
1716                end if;
1717
1718                --  Don't bother visiting a source node that has a parent which
1719                --  is not the node we came from. We prefer to trace such nodes
1720                --  from their real parents. This causes the tree to be printed
1721                --  in a more coherent order, e.g. a defining identifier listed
1722                --  next to its corresponding declaration, instead of next to
1723                --  some semantic reference.
1724
1725                --  This test is skipped for nodes in standard packages unless
1726                --  the -dy option is set (which outputs the tree for standard)
1727
1728                --  Also, always follow pointers to Is_Itype entities,
1729                --  since we want to list these when they are first referenced.
1730
1731                if Parent (Nod) /= Empty
1732                  and then Comes_From_Source (Nod)
1733                  and then Parent (Nod) /= N
1734                  and then (Sloc (N) > Standard_Location or else Debug_Flag_Y)
1735                then
1736                   return;
1737                end if;
1738
1739                --  If we successfully fall through all the above tests (which
1740                --  execute a return if the node is not to be visited), we can
1741                --  go ahead and visit the node!
1742
1743                if No_Indent then
1744                   Visit_Node (Nod, Prefix_Str, Prefix_Char);
1745                else
1746                   Visit_Node (Nod, New_Prefix, ' ');
1747                end if;
1748             end;
1749
1750          --  Case of descendent is a list
1751
1752          elsif D in List_Range then
1753
1754             --  Don't bother with a missing list, empty list or error list
1755
1756             if D = Union_Id (No_List)
1757               or else D = Union_Id (Error_List)
1758               or else Is_Empty_List (List_Id (D))
1759             then
1760                return;
1761
1762             --  Otherwise we can visit the list. Note that we don't bother
1763             --  to do the parent test that we did for the node case, because
1764             --  it just does not happen that lists are referenced more than
1765             --  one place in the tree. We aren't counting on this being the
1766             --  case to generate valid output, it is just that we don't need
1767             --  in practice to worry about listing the list at a place that
1768             --  is inconvenient.
1769
1770             else
1771                Visit_List (List_Id (D), New_Prefix);
1772             end if;
1773
1774          --  Case of descendent is an element list
1775
1776          elsif D in Elist_Range then
1777
1778             --  Don't bother with a missing list, or an empty list
1779
1780             if D = Union_Id (No_Elist)
1781               or else Is_Empty_Elmt_List (Elist_Id (D))
1782             then
1783                return;
1784
1785             --  Otherwise, visit the referenced element list
1786
1787             else
1788                Visit_Elist (Elist_Id (D), New_Prefix);
1789             end if;
1790
1791          --  For all other kinds of descendents (strings, names, uints etc),
1792          --  there is nothing to visit (the contents of the field will be
1793          --  printed when we print the containing node, but what concerns
1794          --  us now is looking for descendents in the tree.
1795
1796          else
1797             null;
1798          end if;
1799       end Visit_Descendent;
1800
1801    --  Start of processing for Visit_Node
1802
1803    begin
1804       if N = Empty then
1805          return;
1806       end if;
1807
1808       --  Set fatal error node in case we get a blow up during the trace
1809
1810       Current_Error_Node := N;
1811
1812       New_Prefix (Prefix_Str'Range)    := Prefix_Str;
1813       New_Prefix (Prefix_Str'Last + 1) := Prefix_Char;
1814       New_Prefix (Prefix_Str'Last + 2) := ' ';
1815
1816       --  In the marking phase, all we do is to set the serial number
1817
1818       if Phase = Marking then
1819          if Serial_Number (Int (N)) /= 0 then
1820             return; -- already visited
1821          else
1822             Set_Serial_Number;
1823          end if;
1824
1825       --  In the printing phase, we print the node
1826
1827       else
1828          if Serial_Number (Int (N)) < Next_Serial_Number then
1829
1830             --  Here we have already visited the node, but if it is in
1831             --  a list, we still want to print the reference, so that
1832             --  it is clear that it belongs to the list.
1833
1834             if Is_List_Member (N) then
1835                Print_Str (Prefix_Str);
1836                Print_Node_Ref (N);
1837                Print_Eol;
1838                Print_Str (Prefix_Str);
1839                Print_Char (Prefix_Char);
1840                Print_Str ("(already output)");
1841                Print_Eol;
1842                Print_Str (Prefix_Str);
1843                Print_Char (Prefix_Char);
1844                Print_Eol;
1845             end if;
1846
1847             return;
1848
1849          else
1850             Print_Node (N, Prefix_Str, Prefix_Char);
1851             Print_Str (Prefix_Str);
1852             Print_Char (Prefix_Char);
1853             Print_Eol;
1854             Next_Serial_Number := Next_Serial_Number + 1;
1855          end if;
1856       end if;
1857
1858       --  Visit all descendents of this node
1859
1860       if Nkind (N) not in N_Entity then
1861          Visit_Descendent (Field1 (N));
1862          Visit_Descendent (Field2 (N));
1863          Visit_Descendent (Field3 (N));
1864          Visit_Descendent (Field4 (N));
1865          Visit_Descendent (Field5 (N));
1866
1867       --  Entity case
1868
1869       else
1870          Visit_Descendent (Field1 (N));
1871          Visit_Descendent (Field3 (N));
1872          Visit_Descendent (Field4 (N));
1873          Visit_Descendent (Field5 (N));
1874          Visit_Descendent (Field6 (N));
1875          Visit_Descendent (Field7 (N));
1876          Visit_Descendent (Field8 (N));
1877          Visit_Descendent (Field9 (N));
1878          Visit_Descendent (Field10 (N));
1879          Visit_Descendent (Field11 (N));
1880          Visit_Descendent (Field12 (N));
1881          Visit_Descendent (Field13 (N));
1882          Visit_Descendent (Field14 (N));
1883          Visit_Descendent (Field15 (N));
1884          Visit_Descendent (Field16 (N));
1885          Visit_Descendent (Field17 (N));
1886          Visit_Descendent (Field18 (N));
1887          Visit_Descendent (Field19 (N));
1888          Visit_Descendent (Field20 (N));
1889          Visit_Descendent (Field21 (N));
1890          Visit_Descendent (Field22 (N));
1891          Visit_Descendent (Field23 (N));
1892
1893          --  Now an interesting kludge. Normally parents are always printed
1894          --  since we traverse the tree in a downwards direction. There is
1895          --  however an exception to this rule, which is the case where a
1896          --  parent is constructed by the compiler and is not referenced
1897          --  elsewhere in the tree. The following catches this case
1898
1899          if not Comes_From_Source (N) then
1900             Visit_Descendent (Union_Id (Parent (N)));
1901          end if;
1902
1903          --  You may be wondering why we omitted Field2 above. The answer
1904          --  is that this is the Next_Entity field, and we want to treat
1905          --  it rather specially. Why? Because a Next_Entity link does not
1906          --  correspond to a level deeper in the tree, and we do not want
1907          --  the tree to march off to the right of the page due to bogus
1908          --  indentations coming from this effect.
1909
1910          --  To prevent this, what we do is to control references via
1911          --  Next_Entity only from the first entity on a given scope
1912          --  chain, and we keep them all at the same level. Of course
1913          --  if an entity has already been referenced it is not printed.
1914
1915          if Present (Next_Entity (N))
1916            and then Present (Scope (N))
1917            and then First_Entity (Scope (N)) = N
1918          then
1919             declare
1920                Nod : Node_Id;
1921
1922             begin
1923                Nod := N;
1924                while Present (Nod) loop
1925                   Visit_Descendent (Union_Id (Next_Entity (Nod)));
1926                   Nod := Next_Entity (Nod);
1927                end loop;
1928             end;
1929          end if;
1930       end if;
1931    end Visit_Node;
1932
1933 end Treepr;