gcc/ada/tbuild.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               T B U I L D                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Einfo;    use Einfo;
  28 with Elists;   use Elists;
  29 with Lib;      use Lib;
  30 with Nlists;   use Nlists;
  31 with Nmake;    use Nmake;
  32 with Opt;      use Opt;
  33 with Restrict; use Restrict;
  34 with Rident;   use Rident;
  35 with Sinfo;    use Sinfo;
  36 with Snames;   use Snames;
  37 with Stand;    use Stand;
  38 with Stringt;  use Stringt;
  39 with Uintp;    use Uintp;
  40
  41 package body Tbuild is
  42
  43    -----------------------
  44    -- Local Subprograms --
  45    -----------------------
  46
  47    procedure Add_Unique_Serial_Number;
  48    --  Add a unique serialization to the string in the Name_Buffer. This
  49    --  consists of a unit specific serial number, and b/s for body/spec.
  50
  51    ------------------------------
  52    -- Add_Unique_Serial_Number --
  53    ------------------------------
  54
  55    Config_Serial_Number : Nat := 0;
  56    --  Counter for use in config pragmas, see comment below
  57
  58    procedure Add_Unique_Serial_Number is
  59    begin
  60       --  If we are analyzing configuration pragmas, Cunit (Main_Unit) will
  61       --  not be set yet. This happens for example when analyzing static
  62       --  string expressions in configuration pragmas. For this case, we
  63       --  just maintain a local counter, defined above and we do not need
  64       --  to add a b or s indication in this case.
  65
  66       if No (Cunit (Current_Sem_Unit)) then
  67          Config_Serial_Number := Config_Serial_Number + 1;
  68          Add_Nat_To_Name_Buffer (Config_Serial_Number);
  69          return;
  70
  71       --  Normal case, within a unit
  72
  73       else
  74          declare
  75             Unit_Node : constant Node_Id := Unit (Cunit (Current_Sem_Unit));
  76
  77          begin
  78             Add_Nat_To_Name_Buffer (Increment_Serial_Number);
  79
  80             --  Add either b or s, depending on whether current unit is a spec
  81             --  or a body. This is needed because we may generate the same name
  82             --  in a spec and a body otherwise.
  83
  84             Name_Len := Name_Len + 1;
  85
  86             if Nkind (Unit_Node) = N_Package_Declaration
  87               or else Nkind (Unit_Node) = N_Subprogram_Declaration
  88               or else Nkind (Unit_Node) in N_Generic_Declaration
  89             then
  90                Name_Buffer (Name_Len) := 's';
  91             else
  92                Name_Buffer (Name_Len) := 'b';
  93             end if;
  94          end;
  95       end if;
  96    end Add_Unique_Serial_Number;
  97
  98    ----------------
  99    -- Checks_Off --
 100    ----------------
 101
 102    function Checks_Off (N : Node_Id) return Node_Id is
 103    begin
 104       return
 105         Make_Unchecked_Expression (Sloc (N),
 106           Expression => N);
 107    end Checks_Off;
 108
 109    ----------------
 110    -- Convert_To --
 111    ----------------
 112
 113    function Convert_To (Typ : Entity_Id; Expr : Node_Id) return Node_Id is
 114       Result : Node_Id;
 115
 116    begin
 117       if Present (Etype (Expr))
 118         and then (Etype (Expr)) = Typ
 119       then
 120          return Relocate_Node (Expr);
 121       else
 122          Result :=
 123            Make_Type_Conversion (Sloc (Expr),
 124              Subtype_Mark => New_Occurrence_Of (Typ, Sloc (Expr)),
 125              Expression => Relocate_Node (Expr));
 126
 127          Set_Etype (Result, Typ);
 128          return Result;
 129       end if;
 130    end Convert_To;
 131
 132    ------------------
 133    -- Discard_List --
 134    ------------------
 135
 136    procedure Discard_List (L : List_Id) is
 137       pragma Warnings (Off, L);
 138    begin
 139       null;
 140    end Discard_List;
 141
 142    ------------------
 143    -- Discard_Node --
 144    ------------------
 145
 146    procedure Discard_Node (N : Node_Or_Entity_Id) is
 147       pragma Warnings (Off, N);
 148    begin
 149       null;
 150    end Discard_Node;
 151
 152    -------------------------------------------
 153    -- Make_Byte_Aligned_Attribute_Reference --
 154    -------------------------------------------
 155
 156    function Make_Byte_Aligned_Attribute_Reference
 157      (Sloc           : Source_Ptr;
 158       Prefix         : Node_Id;
 159       Attribute_Name : Name_Id)
 160       return           Node_Id
 161    is
 162       N : constant Node_Id :=
 163             Make_Attribute_Reference (Sloc,
 164               Prefix        => Prefix,
 165               Attribute_Name => Attribute_Name);
 166
 167    begin
 168       pragma Assert (Attribute_Name = Name_Address
 169                        or else
 170                      Attribute_Name = Name_Unrestricted_Access);
 171       Set_Must_Be_Byte_Aligned (N, True);
 172       return N;
 173    end Make_Byte_Aligned_Attribute_Reference;
 174
 175    --------------------
 176    -- Make_DT_Access --
 177    --------------------
 178
 179    function Make_DT_Access
 180      (Loc : Source_Ptr;
 181       Rec : Node_Id;
 182       Typ : Entity_Id) return Node_Id
 183    is
 184       Full_Type : Entity_Id := Typ;
 185
 186    begin
 187       if Is_Private_Type (Typ) then
 188          Full_Type := Underlying_Type (Typ);
 189       end if;
 190
 191       return
 192         Unchecked_Convert_To (
 193           New_Occurrence_Of
 194             (Etype (Node (First_Elmt (Access_Disp_Table (Full_Type)))), Loc),
 195           Make_Selected_Component (Loc,
 196             Prefix => New_Copy (Rec),
 197             Selector_Name =>
 198               New_Reference_To (First_Tag_Component (Full_Type), Loc)));
 199    end Make_DT_Access;
 200
 201    -------------------------------------
 202    -- Make_Implicit_Exception_Handler --
 203    -------------------------------------
 204
 205    function Make_Implicit_Exception_Handler
 206      (Sloc              : Source_Ptr;
 207       Choice_Parameter  : Node_Id := Empty;
 208       Exception_Choices : List_Id;
 209       Statements        : List_Id) return Node_Id
 210    is
 211       Handler : Node_Id;
 212       Loc     : Source_Ptr;
 213
 214    begin
 215       --  Set the source location only when debugging the expanded code
 216
 217       --  When debugging the source code directly, we do not want the compiler
 218       --  to associate this implicit exception handler with any specific source
 219       --  line, because it can potentially confuse the debugger. The most
 220       --  damaging situation would arise when the debugger tries to insert a
 221       --  breakpoint at a certain line. If the code of the associated implicit
 222       --  exception handler is generated before the code of that line, then the
 223       --  debugger will end up inserting the breakpoint inside the exception
 224       --  handler, rather than the code the user intended to break on. As a
 225       --  result, it is likely that the program will not hit the breakpoint
 226       --  as expected.
 227
 228       if Debug_Generated_Code then
 229          Loc := Sloc;
 230       else
 231          Loc := No_Location;
 232       end if;
 233
 234       Handler :=
 235         Make_Exception_Handler
 236           (Loc, Choice_Parameter, Exception_Choices, Statements);
 237       Set_Local_Raise_Statements (Handler, No_Elist);
 238       return Handler;
 239    end Make_Implicit_Exception_Handler;
 240
 241    --------------------------------
 242    -- Make_Implicit_If_Statement --
 243    --------------------------------
 244
 245    function Make_Implicit_If_Statement
 246      (Node            : Node_Id;
 247       Condition       : Node_Id;
 248       Then_Statements : List_Id;
 249       Elsif_Parts     : List_Id := No_List;
 250       Else_Statements : List_Id := No_List) return Node_Id
 251    is
 252    begin
 253       Check_Restriction (No_Implicit_Conditionals, Node);
 254
 255       return Make_If_Statement (Sloc (Node),
 256         Condition,
 257         Then_Statements,
 258         Elsif_Parts,
 259         Else_Statements);
 260    end Make_Implicit_If_Statement;
 261
 262    -------------------------------------
 263    -- Make_Implicit_Label_Declaration --
 264    -------------------------------------
 265
 266    function Make_Implicit_Label_Declaration
 267      (Loc                 : Source_Ptr;
 268       Defining_Identifier : Node_Id;
 269       Label_Construct     : Node_Id) return Node_Id
 270    is
 271       N : constant Node_Id :=
 272             Make_Implicit_Label_Declaration (Loc, Defining_Identifier);
 273    begin
 274       Set_Label_Construct (N, Label_Construct);
 275       return N;
 276    end Make_Implicit_Label_Declaration;
 277
 278    ----------------------------------
 279    -- Make_Implicit_Loop_Statement --
 280    ----------------------------------
 281
 282    function Make_Implicit_Loop_Statement
 283      (Node                   : Node_Id;
 284       Statements             : List_Id;
 285       Identifier             : Node_Id := Empty;
 286       Iteration_Scheme       : Node_Id := Empty;
 287       Has_Created_Identifier : Boolean := False;
 288       End_Label              : Node_Id := Empty) return Node_Id
 289    is
 290    begin
 291       Check_Restriction (No_Implicit_Loops, Node);
 292
 293       if Present (Iteration_Scheme)
 294         and then Present (Condition (Iteration_Scheme))
 295       then
 296          Check_Restriction (No_Implicit_Conditionals, Node);
 297       end if;
 298
 299       return Make_Loop_Statement (Sloc (Node),
 300         Identifier             => Identifier,
 301         Iteration_Scheme       => Iteration_Scheme,
 302         Statements             => Statements,
 303         Has_Created_Identifier => Has_Created_Identifier,
 304         End_Label              => End_Label);
 305    end Make_Implicit_Loop_Statement;
 306
 307    --------------------------
 308    -- Make_Integer_Literal --
 309    ---------------------------
 310
 311    function Make_Integer_Literal
 312      (Loc    : Source_Ptr;
 313       Intval : Int) return Node_Id
 314    is
 315    begin
 316       return Make_Integer_Literal (Loc, UI_From_Int (Intval));
 317    end Make_Integer_Literal;
 318
 319    --------------------------------
 320    -- Make_Linker_Section_Pragma --
 321    --------------------------------
 322
 323    function Make_Linker_Section_Pragma
 324      (Ent : Entity_Id;
 325       Loc : Source_Ptr;
 326       Sec : String) return Node_Id
 327    is
 328       LS : Node_Id;
 329
 330    begin
 331       LS :=
 332         Make_Pragma
 333           (Loc,
 334            Name_Linker_Section,
 335            New_List
 336              (Make_Pragma_Argument_Association
 337                 (Sloc => Loc,
 338                  Expression => New_Occurrence_Of (Ent, Loc)),
 339               Make_Pragma_Argument_Association
 340                 (Sloc => Loc,
 341                  Expression =>
 342                    Make_String_Literal
 343                      (Sloc => Loc,
 344                       Strval => Sec))));
 345
 346       Set_Has_Gigi_Rep_Item (Ent);
 347       return LS;
 348    end Make_Linker_Section_Pragma;
 349
 350    -----------------
 351    -- Make_Pragma --
 352    -----------------
 353
 354    function Make_Pragma
 355      (Sloc                         : Source_Ptr;
 356       Chars                        : Name_Id;
 357       Pragma_Argument_Associations : List_Id := No_List;
 358       Debug_Statement              : Node_Id := Empty) return Node_Id
 359    is
 360    begin
 361       return
 362         Make_Pragma (Sloc,
 363           Pragma_Argument_Associations => Pragma_Argument_Associations,
 364           Debug_Statement              => Debug_Statement,
 365           Pragma_Identifier            => Make_Identifier (Sloc, Chars));
 366    end Make_Pragma;
 367
 368    ---------------------------------
 369    -- Make_Raise_Constraint_Error --
 370    ---------------------------------
 371
 372    function Make_Raise_Constraint_Error
 373      (Sloc      : Source_Ptr;
 374       Condition : Node_Id := Empty;
 375       Reason    : RT_Exception_Code) return Node_Id
 376    is
 377    begin
 378       pragma Assert (Reason in RT_CE_Exceptions);
 379       return
 380         Make_Raise_Constraint_Error (Sloc,
 381           Condition => Condition,
 382           Reason =>
 383             UI_From_Int (RT_Exception_Code'Pos (Reason)));
 384    end Make_Raise_Constraint_Error;
 385
 386    ------------------------------
 387    -- Make_Raise_Program_Error --
 388    ------------------------------
 389
 390    function Make_Raise_Program_Error
 391      (Sloc      : Source_Ptr;
 392       Condition : Node_Id := Empty;
 393       Reason    : RT_Exception_Code) return Node_Id
 394    is
 395    begin
 396       pragma Assert (Reason in RT_PE_Exceptions);
 397       return
 398         Make_Raise_Program_Error (Sloc,
 399           Condition => Condition,
 400           Reason =>
 401             UI_From_Int (RT_Exception_Code'Pos (Reason)));
 402    end Make_Raise_Program_Error;
 403
 404    ------------------------------
 405    -- Make_Raise_Storage_Error --
 406    ------------------------------
 407
 408    function Make_Raise_Storage_Error
 409      (Sloc      : Source_Ptr;
 410       Condition : Node_Id := Empty;
 411       Reason    : RT_Exception_Code) return Node_Id
 412    is
 413    begin
 414       pragma Assert (Reason in RT_SE_Exceptions);
 415       return
 416         Make_Raise_Storage_Error (Sloc,
 417           Condition => Condition,
 418           Reason =>
 419             UI_From_Int (RT_Exception_Code'Pos (Reason)));
 420    end Make_Raise_Storage_Error;
 421
 422    -------------------------
 423    -- Make_String_Literal --
 424    -------------------------
 425
 426    function Make_String_Literal
 427      (Sloc   : Source_Ptr;
 428       Strval : String) return Node_Id
 429    is
 430    begin
 431       Start_String;
 432       Store_String_Chars (Strval);
 433       return
 434         Make_String_Literal (Sloc,
 435           Strval => End_String);
 436    end Make_String_Literal;
 437
 438    ---------------------------
 439    -- Make_Unsuppress_Block --
 440    ---------------------------
 441
 442    --  Generates the following expansion:
 443
 444    --    declare
 445    --       pragma Suppress (<check>);
 446    --    begin
 447    --       <stmts>
 448    --    end;
 449
 450    function Make_Unsuppress_Block
 451      (Loc   : Source_Ptr;
 452       Check : Name_Id;
 453       Stmts : List_Id) return Node_Id
 454    is
 455    begin
 456       return
 457         Make_Block_Statement (Loc,
 458           Declarations => New_List (
 459             Make_Pragma (Loc,
 460               Chars => Name_Suppress,
 461               Pragma_Argument_Associations => New_List (
 462                 Make_Pragma_Argument_Association (Loc,
 463                   Expression => Make_Identifier (Loc, Check))))),
 464
 465           Handled_Statement_Sequence =>
 466             Make_Handled_Sequence_Of_Statements (Loc,
 467               Statements => Stmts));
 468    end Make_Unsuppress_Block;
 469
 470    --------------------------
 471    -- New_Constraint_Error --
 472    --------------------------
 473
 474    function New_Constraint_Error (Loc : Source_Ptr) return Node_Id is
 475       Ident_Node : Node_Id;
 476       Raise_Node : Node_Id;
 477
 478    begin
 479       Ident_Node := New_Node (N_Identifier, Loc);
 480       Set_Chars (Ident_Node, Chars (Standard_Entity (S_Constraint_Error)));
 481       Set_Entity (Ident_Node, Standard_Entity (S_Constraint_Error));
 482       Raise_Node := New_Node (N_Raise_Statement, Loc);
 483       Set_Name (Raise_Node, Ident_Node);
 484       return Raise_Node;
 485    end New_Constraint_Error;
 486
 487    -----------------------
 488    -- New_External_Name --
 489    -----------------------
 490
 491    function New_External_Name
 492      (Related_Id   : Name_Id;
 493       Suffix       : Character := ' ';
 494       Suffix_Index : Int       := 0;
 495       Prefix       : Character := ' ') return Name_Id
 496    is
 497    begin
 498       Get_Name_String (Related_Id);
 499
 500       if Prefix /= ' ' then
 501          pragma Assert (Is_OK_Internal_Letter (Prefix));
 502
 503          for J in reverse 1 .. Name_Len loop
 504             Name_Buffer (J + 1) := Name_Buffer (J);
 505          end loop;
 506
 507          Name_Len := Name_Len + 1;
 508          Name_Buffer (1) := Prefix;
 509       end if;
 510
 511       if Suffix /= ' ' then
 512          pragma Assert (Is_OK_Internal_Letter (Suffix));
 513          Name_Len := Name_Len + 1;
 514          Name_Buffer (Name_Len) := Suffix;
 515       end if;
 516
 517       if Suffix_Index /= 0 then
 518          if Suffix_Index < 0 then
 519             Add_Unique_Serial_Number;
 520          else
 521             Add_Nat_To_Name_Buffer (Suffix_Index);
 522          end if;
 523       end if;
 524
 525       return Name_Find;
 526    end New_External_Name;
 527
 528    function New_External_Name
 529      (Related_Id   : Name_Id;
 530       Suffix       : String;
 531       Suffix_Index : Int       := 0;
 532       Prefix       : Character := ' ') return Name_Id
 533    is
 534    begin
 535       Get_Name_String (Related_Id);
 536
 537       if Prefix /= ' ' then
 538          pragma Assert (Is_OK_Internal_Letter (Prefix));
 539
 540          for J in reverse 1 .. Name_Len loop
 541             Name_Buffer (J + 1) := Name_Buffer (J);
 542          end loop;
 543
 544          Name_Len := Name_Len + 1;
 545          Name_Buffer (1) := Prefix;
 546       end if;
 547
 548       if Suffix /= "" then
 549          Name_Buffer (Name_Len + 1 .. Name_Len + Suffix'Length) := Suffix;
 550          Name_Len := Name_Len + Suffix'Length;
 551       end if;
 552
 553       if Suffix_Index /= 0 then
 554          if Suffix_Index < 0 then
 555             Add_Unique_Serial_Number;
 556          else
 557             Add_Nat_To_Name_Buffer (Suffix_Index);
 558          end if;
 559       end if;
 560
 561       return Name_Find;
 562    end New_External_Name;
 563
 564    function New_External_Name
 565      (Suffix       : Character;
 566       Suffix_Index : Nat) return Name_Id
 567    is
 568    begin
 569       Name_Buffer (1) := Suffix;
 570       Name_Len := 1;
 571       Add_Nat_To_Name_Buffer (Suffix_Index);
 572       return Name_Find;
 573    end New_External_Name;
 574
 575    -----------------------
 576    -- New_Internal_Name --
 577    -----------------------
 578
 579    function New_Internal_Name (Id_Char : Character) return Name_Id is
 580    begin
 581       pragma Assert (Is_OK_Internal_Letter (Id_Char));
 582       Name_Buffer (1) := Id_Char;
 583       Name_Len := 1;
 584       Add_Unique_Serial_Number;
 585       return Name_Enter;
 586    end New_Internal_Name;
 587
 588    -----------------------
 589    -- New_Occurrence_Of --
 590    -----------------------
 591
 592    function New_Occurrence_Of
 593      (Def_Id : Entity_Id;
 594       Loc    : Source_Ptr) return Node_Id
 595    is
 596       Occurrence : Node_Id;
 597
 598    begin
 599       Occurrence := New_Node (N_Identifier, Loc);
 600       Set_Chars (Occurrence, Chars (Def_Id));
 601       Set_Entity (Occurrence, Def_Id);
 602
 603       if Is_Type (Def_Id) then
 604          Set_Etype (Occurrence, Def_Id);
 605       else
 606          Set_Etype (Occurrence, Etype (Def_Id));
 607       end if;
 608
 609       return Occurrence;
 610    end New_Occurrence_Of;
 611
 612    ----------------------
 613    -- New_Reference_To --
 614    ----------------------
 615
 616    function New_Reference_To
 617      (Def_Id : Entity_Id;
 618       Loc    : Source_Ptr) return Node_Id
 619    is
 620       Occurrence : Node_Id;
 621
 622    begin
 623       Occurrence := New_Node (N_Identifier, Loc);
 624       Set_Chars (Occurrence, Chars (Def_Id));
 625       Set_Entity (Occurrence, Def_Id);
 626       return Occurrence;
 627    end New_Reference_To;
 628
 629    -----------------------
 630    -- New_Suffixed_Name --
 631    -----------------------
 632
 633    function New_Suffixed_Name
 634      (Related_Id : Name_Id;
 635       Suffix     : String) return Name_Id
 636    is
 637    begin
 638       Get_Name_String (Related_Id);
 639       Name_Len := Name_Len + 1;
 640       Name_Buffer (Name_Len) := '_';
 641       Name_Buffer (Name_Len + 1 .. Name_Len + Suffix'Length) := Suffix;
 642       Name_Len := Name_Len + Suffix'Length;
 643       return Name_Find;
 644    end New_Suffixed_Name;
 645
 646    -------------------
 647    -- OK_Convert_To --
 648    -------------------
 649
 650    function OK_Convert_To (Typ : Entity_Id; Expr : Node_Id) return Node_Id is
 651       Result : Node_Id;
 652    begin
 653       Result :=
 654         Make_Type_Conversion (Sloc (Expr),
 655           Subtype_Mark => New_Occurrence_Of (Typ, Sloc (Expr)),
 656           Expression   => Relocate_Node (Expr));
 657       Set_Conversion_OK (Result, True);
 658       Set_Etype (Result, Typ);
 659       return Result;
 660    end OK_Convert_To;
 661
 662    --------------------------
 663    -- Unchecked_Convert_To --
 664    --------------------------
 665
 666    function Unchecked_Convert_To
 667      (Typ  : Entity_Id;
 668       Expr : Node_Id) return Node_Id
 669    is
 670       Loc    : constant Source_Ptr := Sloc (Expr);
 671       Result : Node_Id;
 672
 673    begin
 674       --  If the expression is already of the correct type, then nothing
 675       --  to do, except for relocating the node in case this is required.
 676
 677       if Present (Etype (Expr))
 678         and then (Base_Type (Etype (Expr)) = Typ
 679                    or else Etype (Expr) = Typ)
 680       then
 681          return Relocate_Node (Expr);
 682
 683       --  Cases where the inner expression is itself an unchecked conversion
 684       --  to the same type, and we can thus eliminate the outer conversion.
 685
 686       elsif Nkind (Expr) = N_Unchecked_Type_Conversion
 687         and then Entity (Subtype_Mark (Expr)) = Typ
 688       then
 689          Result := Relocate_Node (Expr);
 690
 691       elsif Nkind (Expr) = N_Null
 692         and then Is_Access_Type (Typ)
 693       then
 694          --  No need for a conversion
 695
 696          Result := Relocate_Node (Expr);
 697
 698       --  All other cases
 699
 700       else
 701          Result :=
 702            Make_Unchecked_Type_Conversion (Loc,
 703              Subtype_Mark => New_Occurrence_Of (Typ, Loc),
 704              Expression   => Relocate_Node (Expr));
 705       end if;
 706
 707       Set_Etype (Result, Typ);
 708       return Result;
 709    end Unchecked_Convert_To;
 710
 711 end Tbuild;