gcc/ada/switch-c.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S W I T C H - C                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Debug;    use Debug;
  27 with Lib;      use Lib;
  28 with Osint;    use Osint;
  29 with Opt;      use Opt;
  30 with Prepcomp; use Prepcomp;
  31 with Validsw;  use Validsw;
  32 with Sem_Warn; use Sem_Warn;
  33 with Stylesw;  use Stylesw;
  34
  35 with System.OS_Lib; use System.OS_Lib;
  36
  37 with System.WCh_Con; use System.WCh_Con;
  38
  39 package body Switch.C is
  40
  41    RTS_Specified : String_Access := null;
  42    --  Used to detect multiple use of --RTS= flag
  43
  44    -----------------------------
  45    -- Scan_Front_End_Switches --
  46    -----------------------------
  47
  48    procedure Scan_Front_End_Switches (Switch_Chars : String) is
  49       First_Switch : Boolean := True;
  50       --  False for all but first switch
  51
  52       Max : constant Natural := Switch_Chars'Last;
  53       Ptr : Natural;
  54       C   : Character := ' ';
  55       Dot : Boolean;
  56
  57       Store_Switch : Boolean;
  58       --  For -gnatxx switches, the normal processing, signalled by this flag
  59       --  being set to True, is to store the switch on exit from the case
  60       --  statement, the switch stored is -gnat followed by the characters
  61       --  from First_Char to Ptr-1. For cases like -gnaty, where the switch
  62       --  is stored in separate pieces, this flag is set to False, and the
  63       --  appropriate calls to Store_Compilation_Switch are made from within
  64       --  the case branch.
  65
  66       First_Char : Positive;
  67       --  Marks start of switch to be stored
  68
  69    begin
  70       Ptr := Switch_Chars'First;
  71
  72       --  Skip past the initial character (must be the switch character)
  73
  74       if Ptr = Max then
  75          Bad_Switch (C);
  76       else
  77          Ptr := Ptr + 1;
  78       end if;
  79
  80       --  Handle switches that do not start with -gnat
  81
  82       if Ptr + 3 > Max
  83         or else Switch_Chars (Ptr .. Ptr + 3) /= "gnat"
  84       then
  85          --  There are two front-end switches that do not start with -gnat:
  86          --  -I, --RTS
  87
  88          if Switch_Chars (Ptr) = 'I' then
  89
  90             --  Set flag Search_Directory_Present if switch is "-I" only:
  91             --  the directory will be the next argument.
  92
  93             if Ptr = Max then
  94                Search_Directory_Present := True;
  95                return;
  96             end if;
  97
  98             Ptr := Ptr + 1;
  99
 100             --  Find out whether this is a -I- or regular -Ixxx switch
 101
 102             --  Note: -I switches are not recorded in the ALI file, since the
 103             --  meaning of the program depends on the source files compiled,
 104             --  not where they came from.
 105
 106             if Ptr = Max and then Switch_Chars (Ptr) = '-' then
 107                Look_In_Primary_Dir := False;
 108             else
 109                Add_Src_Search_Dir (Switch_Chars (Ptr .. Max));
 110             end if;
 111
 112          --  Processing of the --RTS switch. --RTS may have been modified by
 113          --  gcc into -fRTS (for GCC targets).
 114
 115          elsif Ptr + 3 <= Max
 116            and then (Switch_Chars (Ptr .. Ptr + 3) = "fRTS"
 117                        or else
 118                      Switch_Chars (Ptr .. Ptr + 3) = "-RTS")
 119          then
 120             Ptr := Ptr + 1;
 121
 122             if Ptr + 4 > Max
 123               or else Switch_Chars (Ptr + 3) /= '='
 124             then
 125                Osint.Fail ("missing path for --RTS");
 126             else
 127                --  Check that this is the first time --RTS is specified or if
 128                --  it is not the first time, the same path has been specified.
 129
 130                if RTS_Specified = null then
 131                   RTS_Specified := new String'(Switch_Chars (Ptr + 4 .. Max));
 132
 133                elsif
 134                  RTS_Specified.all /= Switch_Chars (Ptr + 4 .. Max)
 135                then
 136                   Osint.Fail
 137                     ("--RTS cannot be specified multiple times");
 138                end if;
 139
 140                --  Valid --RTS switch
 141
 142                Opt.No_Stdinc := True;
 143                Opt.RTS_Switch := True;
 144
 145                RTS_Src_Path_Name :=
 146                  Get_RTS_Search_Dir
 147                    (Switch_Chars (Ptr + 4 .. Max), Include);
 148
 149                RTS_Lib_Path_Name :=
 150                  Get_RTS_Search_Dir
 151                    (Switch_Chars (Ptr + 4 .. Max), Objects);
 152
 153                if RTS_Src_Path_Name /= null
 154                  and then RTS_Lib_Path_Name /= null
 155                then
 156                   --  Store the -fRTS switch (Note: Store_Compilation_Switch
 157                   --  changes -fRTS back into --RTS for the actual output).
 158
 159                   Store_Compilation_Switch (Switch_Chars);
 160
 161                elsif RTS_Src_Path_Name = null
 162                  and then RTS_Lib_Path_Name = null
 163                then
 164                   Osint.Fail ("RTS path not valid: missing " &
 165                               "adainclude and adalib directories");
 166
 167                elsif RTS_Src_Path_Name = null then
 168                   Osint.Fail ("RTS path not valid: missing " &
 169                               "adainclude directory");
 170
 171                elsif RTS_Lib_Path_Name = null then
 172                   Osint.Fail ("RTS path not valid: missing " &
 173                               "adalib directory");
 174                end if;
 175             end if;
 176
 177             --  There are no other switches not starting with -gnat
 178
 179          else
 180             Bad_Switch (Switch_Chars);
 181          end if;
 182
 183       --  Case of switch starting with -gnat
 184
 185       else
 186          Ptr := Ptr + 4;
 187
 188          --  Loop to scan through switches given in switch string
 189
 190          while Ptr <= Max loop
 191             First_Char := Ptr;
 192             Store_Switch := True;
 193
 194             C := Switch_Chars (Ptr);
 195
 196             case C is
 197
 198             when 'a' =>
 199                Ptr := Ptr + 1;
 200                Assertions_Enabled := True;
 201                Debug_Pragmas_Enabled := True;
 202
 203             --  Processing for A switch
 204
 205             when 'A' =>
 206                Ptr := Ptr + 1;
 207                Config_File := False;
 208
 209             --  Processing for b switch
 210
 211             when 'b' =>
 212                Ptr := Ptr + 1;
 213                Brief_Output := True;
 214
 215             --  Processing for B switch
 216
 217             when 'B' =>
 218                Ptr := Ptr + 1;
 219                Assume_No_Invalid_Values := True;
 220
 221             --  Processing for c switch
 222
 223             when 'c' =>
 224                if not First_Switch then
 225                   Osint.Fail
 226                     ("-gnatc must be first if combined with other switches");
 227                end if;
 228
 229                Ptr := Ptr + 1;
 230                Operating_Mode := Check_Semantics;
 231
 232                if Tree_Output then
 233                   ASIS_Mode := True;
 234                end if;
 235
 236             --  Processing for d switch
 237
 238             when 'd' =>
 239                Store_Switch := False;
 240                Dot := False;
 241
 242                --  Note: for the debug switch, the remaining characters in this
 243                --  switch field must all be debug flags, since all valid switch
 244                --  characters are also valid debug characters.
 245
 246                --  Loop to scan out debug flags
 247
 248                while Ptr < Max loop
 249                   Ptr := Ptr + 1;
 250                   C := Switch_Chars (Ptr);
 251                   exit when C = ASCII.NUL or else C = '/' or else C = '-';
 252
 253                   if C in '1' .. '9' or else
 254                      C in 'a' .. 'z' or else
 255                      C in 'A' .. 'Z'
 256                   then
 257                      if Dot then
 258                         Set_Dotted_Debug_Flag (C);
 259                         Store_Compilation_Switch ("-gnatd." & C);
 260                      else
 261                         Set_Debug_Flag (C);
 262                         Store_Compilation_Switch ("-gnatd" & C);
 263                      end if;
 264
 265                   elsif C = '.' then
 266                      Dot := True;
 267
 268                   elsif Dot then
 269                      Bad_Switch ("-gnatd." & Switch_Chars (Ptr .. Max));
 270                   else
 271                      Bad_Switch ("-gnatd" & Switch_Chars (Ptr .. Max));
 272                   end if;
 273                end loop;
 274
 275                return;
 276
 277             --  Processing for D switch
 278
 279             when 'D' =>
 280                Ptr := Ptr + 1;
 281
 282                --  Note: -gnatD also sets -gnatx (to turn off cross-reference
 283                --  generation in the ali file) since otherwise this generation
 284                --  gets confused by the "wrong" Sloc values put in the tree.
 285
 286                Debug_Generated_Code := True;
 287                Xref_Active := False;
 288                Set_Debug_Flag ('g');
 289
 290             --  -gnate? (extended switches)
 291
 292             when 'e' =>
 293                Ptr := Ptr + 1;
 294
 295                --  The -gnate? switches are all double character switches
 296                --  so we must always have a character after the e.
 297
 298                if Ptr > Max then
 299                   Bad_Switch ("-gnate");
 300                end if;
 301
 302                case Switch_Chars (Ptr) is
 303
 304                   --  -gnatec (configuration pragmas)
 305
 306                   when 'c' =>
 307                      Store_Switch := False;
 308                      Ptr := Ptr + 1;
 309
 310                      --  There may be an equal sign between -gnatec and
 311                      --  the path name of the config file.
 312
 313                      if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 314                         Ptr := Ptr + 1;
 315                      end if;
 316
 317                      if Ptr > Max then
 318                         Bad_Switch ("-gnatec");
 319                      end if;
 320
 321                      declare
 322                         Config_File_Name : constant String_Access :=
 323                                              new String'
 324                                                   (Switch_Chars (Ptr .. Max));
 325
 326                      begin
 327                         if Config_File_Names = null then
 328                            Config_File_Names :=
 329                              new String_List'(1 => Config_File_Name);
 330
 331                         else
 332                            declare
 333                               New_Names : constant String_List_Access :=
 334                                             new String_List
 335                                               (1 ..
 336                                                Config_File_Names'Length + 1);
 337
 338                            begin
 339                               for Index in Config_File_Names'Range loop
 340                                  New_Names (Index) :=
 341                                    Config_File_Names (Index);
 342                                  Config_File_Names (Index) := null;
 343                               end loop;
 344
 345                               New_Names (New_Names'Last) := Config_File_Name;
 346                               Free (Config_File_Names);
 347                               Config_File_Names := New_Names;
 348                            end;
 349                         end if;
 350                      end;
 351
 352                      return;
 353
 354                   --  -gnateD switch (preprocessing symbol definition)
 355
 356                   when 'D' =>
 357                      Store_Switch := False;
 358                      Ptr := Ptr + 1;
 359
 360                      if Ptr > Max then
 361                         Bad_Switch ("-gnateD");
 362                      end if;
 363
 364                      Add_Symbol_Definition (Switch_Chars (Ptr .. Max));
 365
 366                      --  Store the switch
 367
 368                      Store_Compilation_Switch
 369                        ("-gnateD" & Switch_Chars (Ptr .. Max));
 370                      Ptr := Max + 1;
 371
 372                   --  -gnatef (full source path for brief error messages)
 373
 374                   when 'f' =>
 375                      Store_Switch := False;
 376                      Ptr := Ptr + 1;
 377                      Full_Path_Name_For_Brief_Errors := True;
 378                      return;
 379
 380                   --  -gnateG (save preprocessor output)
 381
 382                   when 'G' =>
 383                      if Ptr < Max then
 384                         Bad_Switch (Switch_Chars);
 385                      end if;
 386
 387                      Generate_Processed_File := True;
 388                      Ptr := Ptr + 1;
 389
 390                   --  -gnateI (index of unit in multi-unit source)
 391
 392                   when 'I' =>
 393                      Ptr := Ptr + 1;
 394                      Scan_Pos (Switch_Chars, Max, Ptr, Multiple_Unit_Index, C);
 395
 396                   --  -gnatem (mapping file)
 397
 398                   when 'm' =>
 399                      Store_Switch := False;
 400                      Ptr := Ptr + 1;
 401
 402                      --  There may be an equal sign between -gnatem and
 403                      --  the path name of the mapping file.
 404
 405                      if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 406                         Ptr := Ptr + 1;
 407                      end if;
 408
 409                      if Ptr > Max then
 410                         Bad_Switch ("-gnatem");
 411                      end if;
 412
 413                      Mapping_File_Name :=
 414                        new String'(Switch_Chars (Ptr .. Max));
 415                      return;
 416
 417                   --  -gnatep (preprocessing data file)
 418
 419                   when 'p' =>
 420                      Store_Switch := False;
 421                      Ptr := Ptr + 1;
 422
 423                      --  There may be an equal sign between -gnatep and
 424                      --  the path name of the mapping file.
 425
 426                      if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 427                         Ptr := Ptr + 1;
 428                      end if;
 429
 430                      if Ptr > Max then
 431                         Bad_Switch ("-gnatep");
 432                      end if;
 433
 434                      Preprocessing_Data_File :=
 435                        new String'(Switch_Chars (Ptr .. Max));
 436
 437                      --  Store the switch, normalizing to -gnatep=
 438
 439                      Store_Compilation_Switch
 440                        ("-gnatep=" & Preprocessing_Data_File.all);
 441
 442                      Ptr := Max + 1;
 443
 444                   when 'z' =>
 445                      Store_Switch := False;
 446                      Disable_Switch_Storing;
 447                      Ptr := Ptr + 1;
 448
 449                   --  All other -gnate? switches are unassigned
 450
 451                   when others =>
 452                      Bad_Switch ("-gnate" & Switch_Chars (Ptr .. Max));
 453                end case;
 454
 455             --  -gnatE (dynamic elaboration checks)
 456
 457             when 'E' =>
 458                Ptr := Ptr + 1;
 459                Dynamic_Elaboration_Checks := True;
 460
 461             --  -gnatf (full error messages)
 462
 463             when 'f' =>
 464                Ptr := Ptr + 1;
 465                All_Errors_Mode := True;
 466
 467             --  Processing for F switch
 468
 469             when 'F' =>
 470                Ptr := Ptr + 1;
 471                External_Name_Exp_Casing := Uppercase;
 472                External_Name_Imp_Casing := Uppercase;
 473
 474             --  Processing for g switch
 475
 476             when 'g' =>
 477                Ptr := Ptr + 1;
 478                GNAT_Mode := True;
 479                Identifier_Character_Set := 'n';
 480                System_Extend_Unit := Empty;
 481                Warning_Mode := Treat_As_Error;
 482
 483                --  Set Ada 2005 mode explicitly. We don't want to rely on the
 484                --  implicit setting here, since for example, we want
 485                --  Preelaborate_05 treated as Preelaborate
 486
 487                Ada_Version := Ada_05;
 488                Ada_Version_Explicit := Ada_Version;
 489
 490                --  Set default warnings for -gnatg
 491
 492                Check_Unreferenced              := True;
 493                Check_Unreferenced_Formals      := True;
 494                Check_Withs                     := True;
 495                Constant_Condition_Warnings     := True;
 496                Implementation_Unit_Warnings    := True;
 497                Ineffective_Inline_Warnings     := True;
 498                Warn_On_Assertion_Failure       := True;
 499                Warn_On_Assumed_Low_Bound       := True;
 500                Warn_On_Bad_Fixed_Value         := True;
 501                Warn_On_Constant                := True;
 502                Warn_On_Export_Import           := True;
 503                Warn_On_Modified_Unread         := True;
 504                Warn_On_No_Value_Assigned       := True;
 505                Warn_On_Non_Local_Exception     := False;
 506                Warn_On_Obsolescent_Feature     := True;
 507                Warn_On_Redundant_Constructs    := True;
 508                Warn_On_Object_Renames_Function := True;
 509                Warn_On_Unchecked_Conversion    := True;
 510                Warn_On_Unrecognized_Pragma     := True;
 511
 512                Set_GNAT_Style_Check_Options;
 513
 514             --  Processing for G switch
 515
 516             when 'G' =>
 517                Ptr := Ptr + 1;
 518                Print_Generated_Code := True;
 519
 520             --  Processing for h switch
 521
 522             when 'h' =>
 523                Ptr := Ptr + 1;
 524                Usage_Requested := True;
 525
 526             --  Processing for H switch
 527
 528             when 'H' =>
 529                Ptr := Ptr + 1;
 530                HLO_Active := True;
 531
 532             --  Processing for i switch
 533
 534             when 'i' =>
 535                if Ptr = Max then
 536                   Bad_Switch ("-gnati");
 537                end if;
 538
 539                Ptr := Ptr + 1;
 540                C := Switch_Chars (Ptr);
 541
 542                if C in '1' .. '5'
 543                  or else C = '8'
 544                  or else C = '9'
 545                  or else C = 'p'
 546                  or else C = 'f'
 547                  or else C = 'n'
 548                  or else C = 'w'
 549                then
 550                   Identifier_Character_Set := C;
 551                   Ptr := Ptr + 1;
 552
 553                else
 554                   Bad_Switch ("-gnati" & Switch_Chars (Ptr .. Max));
 555                end if;
 556
 557             --  Processing for I switch
 558
 559             when 'I' =>
 560                Ptr := Ptr + 1;
 561                Ignore_Rep_Clauses := True;
 562
 563             --  Processing for j switch
 564
 565             when 'j' =>
 566                Ptr := Ptr + 1;
 567
 568                --  There may be an equal sign between -gnatj and the value
 569
 570                if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 571                   Ptr := Ptr + 1;
 572                end if;
 573
 574                Scan_Nat (Switch_Chars, Max, Ptr, Error_Msg_Line_Length, C);
 575
 576             --  Processing for k switch
 577
 578             when 'k' =>
 579                Ptr := Ptr + 1;
 580                   Scan_Pos
 581                     (Switch_Chars, Max, Ptr, Maximum_File_Name_Length, C);
 582
 583             --  Processing for l switch
 584
 585             when 'l' =>
 586                Ptr := Ptr + 1;
 587                Full_List := True;
 588
 589                --  There may be an equal sign between -gnatl and a file name
 590
 591                if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 592                   if Ptr = Max then
 593                      Osint.Fail ("file name for -gnatl= is null");
 594                   else
 595                      Opt.Full_List_File_Name :=
 596                        new String'(Switch_Chars (Ptr + 1 .. Max));
 597                      Ptr := Max + 1;
 598                   end if;
 599                end if;
 600
 601             --  Processing for L switch
 602
 603             when 'L' =>
 604                Ptr := Ptr + 1;
 605                Dump_Source_Text := True;
 606
 607             --  Processing for m switch
 608
 609             when 'm' =>
 610                Ptr := Ptr + 1;
 611
 612                --  There may be an equal sign between -gnatm and the value
 613
 614                if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 615                   Ptr := Ptr + 1;
 616                end if;
 617
 618                Scan_Nat (Switch_Chars, Max, Ptr, Maximum_Errors, C);
 619
 620             --  Processing for n switch
 621
 622             when 'n' =>
 623                Ptr := Ptr + 1;
 624                Inline_Active := True;
 625
 626             --  Processing for N switch
 627
 628             when 'N' =>
 629                Ptr := Ptr + 1;
 630                Inline_Active := True;
 631                Front_End_Inlining := True;
 632
 633             --  Processing for o switch
 634
 635             when 'o' =>
 636                Ptr := Ptr + 1;
 637                Suppress_Options (Overflow_Check) := False;
 638                Opt.Enable_Overflow_Checks := True;
 639
 640             --  Processing for O switch
 641
 642             when 'O' =>
 643                Store_Switch := False;
 644                Ptr := Ptr + 1;
 645                Output_File_Name_Present := True;
 646
 647             --  Processing for p switch
 648
 649             when 'p' =>
 650                Ptr := Ptr + 1;
 651
 652                --  Set all specific options as well as All_Checks in the
 653                --  Suppress_Options array, excluding Elaboration_Check, since
 654                --  this is treated specially because we do not want -gnatp to
 655                --  disable static elaboration processing.
 656
 657                for J in Suppress_Options'Range loop
 658                   if J /= Elaboration_Check then
 659                      Suppress_Options (J) := True;
 660                   end if;
 661                end loop;
 662
 663                Validity_Checks_On         := False;
 664                Opt.Suppress_Checks        := True;
 665                Opt.Enable_Overflow_Checks := False;
 666
 667             --  Processing for P switch
 668
 669             when 'P' =>
 670                Ptr := Ptr + 1;
 671                Polling_Required := True;
 672
 673             --  Processing for q switch
 674
 675             when 'q' =>
 676                Ptr := Ptr + 1;
 677                Try_Semantics := True;
 678
 679             --  Processing for Q switch
 680
 681             when 'Q' =>
 682                Ptr := Ptr + 1;
 683                Force_ALI_Tree_File := True;
 684                Try_Semantics := True;
 685
 686                --  Processing for r switch
 687
 688             when 'r' =>
 689                Ptr := Ptr + 1;
 690                Treat_Restrictions_As_Warnings := True;
 691
 692             --  Processing for R switch
 693
 694             when 'R' =>
 695                Back_Annotate_Rep_Info := True;
 696                List_Representation_Info := 1;
 697
 698                Ptr := Ptr + 1;
 699                while Ptr <= Max loop
 700                   C := Switch_Chars (Ptr);
 701
 702                   if C in '1' .. '3' then
 703                      List_Representation_Info :=
 704                        Character'Pos (C) - Character'Pos ('0');
 705
 706                   elsif Switch_Chars (Ptr) = 's' then
 707                      List_Representation_Info_To_File := True;
 708
 709                   elsif Switch_Chars (Ptr) = 'm' then
 710                      List_Representation_Info_Mechanisms := True;
 711
 712                   else
 713                      Bad_Switch ("-gnatR" & Switch_Chars (Ptr .. Max));
 714                   end if;
 715
 716                   Ptr := Ptr + 1;
 717                end loop;
 718
 719             --  Processing for s switch
 720
 721             when 's' =>
 722                if not First_Switch then
 723                   Osint.Fail
 724                     ("-gnats must be first if combined with other switches");
 725                end if;
 726
 727                Ptr := Ptr + 1;
 728                Operating_Mode := Check_Syntax;
 729
 730             --  Processing for S switch
 731
 732             when 'S' =>
 733                Print_Standard := True;
 734                Ptr := Ptr + 1;
 735
 736             --  Processing for t switch
 737
 738             when 't' =>
 739                Ptr := Ptr + 1;
 740                Tree_Output := True;
 741
 742                if Operating_Mode = Check_Semantics then
 743                   ASIS_Mode := True;
 744                end if;
 745
 746                Back_Annotate_Rep_Info := True;
 747
 748             --  Processing for T switch
 749
 750             when 'T' =>
 751                Ptr := Ptr + 1;
 752                Scan_Pos (Switch_Chars, Max, Ptr, Table_Factor, C);
 753
 754             --  Processing for u switch
 755
 756             when 'u' =>
 757                Ptr := Ptr + 1;
 758                List_Units := True;
 759
 760             --  Processing for U switch
 761
 762             when 'U' =>
 763                Ptr := Ptr + 1;
 764                Unique_Error_Tag := True;
 765
 766             --  Processing for v switch
 767
 768             when 'v' =>
 769                Ptr := Ptr + 1;
 770                Verbose_Mode := True;
 771
 772             --  Processing for V switch
 773
 774             when 'V' =>
 775                Store_Switch := False;
 776                Ptr := Ptr + 1;
 777
 778                if Ptr > Max then
 779                   Bad_Switch ("-gnatV");
 780
 781                else
 782                   declare
 783                      OK  : Boolean;
 784
 785                   begin
 786                      Set_Validity_Check_Options
 787                        (Switch_Chars (Ptr .. Max), OK, Ptr);
 788
 789                      if not OK then
 790                         Bad_Switch ("-gnatV" & Switch_Chars (Ptr .. Max));
 791                      end if;
 792
 793                      for Index in First_Char + 1 .. Max loop
 794                         Store_Compilation_Switch
 795                           ("-gnatV" & Switch_Chars (Index));
 796                      end loop;
 797                   end;
 798                end if;
 799
 800                Ptr := Max + 1;
 801
 802             --  Processing for w switch
 803
 804             when 'w' =>
 805                Store_Switch := False;
 806                Ptr := Ptr + 1;
 807
 808                if Ptr > Max then
 809                   Bad_Switch ("-gnatw");
 810                end if;
 811
 812                while Ptr <= Max loop
 813                   C := Switch_Chars (Ptr);
 814
 815                   --  Case of dot switch
 816
 817                   if C = '.' and then Ptr < Max then
 818                      Ptr := Ptr + 1;
 819                      C := Switch_Chars (Ptr);
 820
 821                      if Set_Dot_Warning_Switch (C) then
 822                         Store_Compilation_Switch ("-gnatw." & C);
 823                      else
 824                         Bad_Switch ("-gnatw." & Switch_Chars (Ptr .. Max));
 825                      end if;
 826
 827                      --  Normal case, no dot
 828
 829                   else
 830                      if Set_Warning_Switch (C) then
 831                         Store_Compilation_Switch ("-gnatw" & C);
 832                      else
 833                         Bad_Switch ("-gnatw" & Switch_Chars (Ptr .. Max));
 834                      end if;
 835                   end if;
 836
 837                   Ptr := Ptr + 1;
 838                end loop;
 839
 840                return;
 841
 842             --  Processing for W switch
 843
 844             when 'W' =>
 845                Ptr := Ptr + 1;
 846
 847                if Ptr > Max then
 848                   Bad_Switch ("-gnatW");
 849                end if;
 850
 851                begin
 852                   Wide_Character_Encoding_Method :=
 853                     Get_WC_Encoding_Method (Switch_Chars (Ptr));
 854                exception
 855                   when Constraint_Error =>
 856                      Bad_Switch ("-gnatW" & Switch_Chars (Ptr .. Max));
 857                end;
 858
 859                Wide_Character_Encoding_Method_Specified := True;
 860
 861                Upper_Half_Encoding :=
 862                  Wide_Character_Encoding_Method in
 863                    WC_Upper_Half_Encoding_Method;
 864
 865                Ptr := Ptr + 1;
 866
 867             --  Processing for x switch
 868
 869             when 'x' =>
 870                Ptr := Ptr + 1;
 871                Xref_Active := False;
 872
 873             --  Processing for X switch
 874
 875             when 'X' =>
 876                Ptr := Ptr + 1;
 877                Extensions_Allowed := True;
 878
 879             --  Processing for y switch
 880
 881             when 'y' =>
 882                Ptr := Ptr + 1;
 883
 884                if Ptr > Max then
 885                   Set_Default_Style_Check_Options;
 886
 887                else
 888                   Store_Switch := False;
 889
 890                   declare
 891                      OK  : Boolean;
 892
 893                   begin
 894                      Set_Style_Check_Options
 895                        (Switch_Chars (Ptr .. Max), OK, Ptr);
 896
 897                      if not OK then
 898                         Osint.Fail
 899                           ("bad -gnaty switch (" &
 900                            Style_Msg_Buf (1 .. Style_Msg_Len) & ')');
 901                      end if;
 902
 903                      Ptr := First_Char + 1;
 904                      while Ptr <= Max loop
 905                         if Switch_Chars (Ptr) = 'M' then
 906                            First_Char := Ptr;
 907                            loop
 908                               Ptr := Ptr + 1;
 909                               exit when Ptr > Max
 910                                 or else Switch_Chars (Ptr) not in '0' .. '9';
 911                            end loop;
 912
 913                            Store_Compilation_Switch
 914                              ("-gnaty" & Switch_Chars (First_Char .. Ptr - 1));
 915
 916                         else
 917                            Store_Compilation_Switch
 918                              ("-gnaty" & Switch_Chars (Ptr));
 919                            Ptr := Ptr + 1;
 920                         end if;
 921                      end loop;
 922                   end;
 923                end if;
 924
 925             --  Processing for z switch
 926
 927             when 'z' =>
 928                Ptr := Ptr + 1;
 929
 930                --  Allowed for compiler only if this is the only
 931                --  -z switch, we do not allow multiple occurrences
 932
 933                if Distribution_Stub_Mode = No_Stubs then
 934                   case Switch_Chars (Ptr) is
 935                      when 'r' =>
 936                         Distribution_Stub_Mode := Generate_Receiver_Stub_Body;
 937
 938                      when 'c' =>
 939                         Distribution_Stub_Mode := Generate_Caller_Stub_Body;
 940
 941                      when others =>
 942                         Bad_Switch ("-gnatz" & Switch_Chars (Ptr .. Max));
 943                   end case;
 944
 945                   Ptr := Ptr + 1;
 946                end if;
 947
 948             --  Processing for Z switch
 949
 950             when 'Z' =>
 951                Ptr := Ptr + 1;
 952                Osint.Fail
 953                  ("-gnatZ is no longer supported: consider using --RTS=zcx");
 954
 955             --  Processing for 83 switch
 956
 957             when '8' =>
 958                if Ptr = Max then
 959                   Bad_Switch ("-gnat8");
 960                end if;
 961
 962                Ptr := Ptr + 1;
 963
 964                if Switch_Chars (Ptr) /= '3' then
 965                   Bad_Switch ("-gnat8" & Switch_Chars (Ptr .. Max));
 966                else
 967                   Ptr := Ptr + 1;
 968                   Ada_Version := Ada_83;
 969                   Ada_Version_Explicit := Ada_Version;
 970                end if;
 971
 972             --  Processing for 95 switch
 973
 974             when '9' =>
 975                if Ptr = Max then
 976                   Bad_Switch ("-gnat9");
 977                end if;
 978
 979                Ptr := Ptr + 1;
 980
 981                if Switch_Chars (Ptr) /= '5' then
 982                   Bad_Switch ("-gnat9" & Switch_Chars (Ptr .. Max));
 983                else
 984                   Ptr := Ptr + 1;
 985                   Ada_Version := Ada_95;
 986                   Ada_Version_Explicit := Ada_Version;
 987                end if;
 988
 989             --  Processing for 05 switch
 990
 991             when '0' =>
 992                if Ptr = Max then
 993                   Bad_Switch ("-gnat0");
 994                end if;
 995
 996                Ptr := Ptr + 1;
 997
 998                if Switch_Chars (Ptr) /= '5' then
 999                   Bad_Switch ("-gnat0" & Switch_Chars (Ptr .. Max));
1000                else
1001                   Ptr := Ptr + 1;
1002                   Ada_Version := Ada_05;
1003                   Ada_Version_Explicit := Ada_Version;
1004                end if;
1005
1006             --  Ignore extra switch character
1007
1008             when '/' | '-' =>
1009                Ptr := Ptr + 1;
1010
1011             --  Anything else is an error (illegal switch character)
1012
1013             when others =>
1014                Bad_Switch ("-gnat" & Switch_Chars (Ptr .. Max));
1015             end case;
1016
1017             if Store_Switch then
1018                Store_Compilation_Switch
1019                  ("-gnat" & Switch_Chars (First_Char .. Ptr - 1));
1020             end if;
1021
1022             First_Switch := False;
1023          end loop;
1024       end if;
1025    end Scan_Front_End_Switches;
1026
1027 end Switch.C;