gcc/ada/switch-c.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S W I T C H - C                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with GNAT.OS_Lib; use GNAT.OS_Lib;
  28
  29 with Debug;    use Debug;
  30 with Lib;      use Lib;
  31 with Osint;    use Osint;
  32 with Opt;      use Opt;
  33 with Prepcomp; use Prepcomp;
  34 with Validsw;  use Validsw;
  35 with Sem_Warn; use Sem_Warn;
  36 with Stylesw;  use Stylesw;
  37
  38 with System.WCh_Con; use System.WCh_Con;
  39
  40 package body Switch.C is
  41
  42    RTS_Specified : String_Access := null;
  43    --  Used to detect multiple use of --RTS= flag
  44
  45    -----------------------------
  46    -- Scan_Front_End_Switches --
  47    -----------------------------
  48
  49    procedure Scan_Front_End_Switches (Switch_Chars : String) is
  50       Switch_Starts_With_Gnat : Boolean;
  51       --  True if first four switch characters are "gnat"
  52
  53       First_Switch : Boolean := True;
  54       --  False for all but first switch
  55
  56       Ptr : Integer := Switch_Chars'First;
  57       Max : constant Integer := Switch_Chars'Last;
  58       C   : Character := ' ';
  59       Dot : Boolean;
  60
  61       Store_Switch : Boolean  := True;
  62       First_Char   : Integer  := Ptr;
  63       Storing      : String   := Switch_Chars;
  64       First_Stored : Positive := Ptr + 1;
  65       --  The above need comments ???
  66
  67    begin
  68       --  Skip past the initial character (must be the switch character)
  69
  70       if Ptr = Max then
  71          Bad_Switch (C);
  72       else
  73          Ptr := Ptr + 1;
  74       end if;
  75
  76       --  Remove "gnat" from the switch, if present
  77
  78       Switch_Starts_With_Gnat :=
  79         Ptr + 3 <= Max and then Switch_Chars (Ptr .. Ptr + 3) = "gnat";
  80
  81       if Switch_Starts_With_Gnat then
  82          Ptr := Ptr + 4;
  83          First_Stored := Ptr;
  84       end if;
  85
  86       --  Loop to scan through switches given in switch string
  87
  88       while Ptr <= Max loop
  89          Store_Switch := True;
  90          First_Char := Ptr;
  91          C := Switch_Chars (Ptr);
  92
  93          --  Processing for a switch
  94
  95          case Switch_Starts_With_Gnat is
  96
  97             when False =>
  98
  99             --  There are few front-end switches that
 100             --  do not start with -gnat: -I, --RTS
 101
 102                if Switch_Chars (Ptr) = 'I' then
 103                   Store_Switch := False;
 104
 105                   --  Set flag Search_Directory_Present if switch is "-I" only:
 106                   --  the directory will be the next argument.
 107
 108                   if Ptr = Max then
 109                      Search_Directory_Present := True;
 110                      return;
 111                   end if;
 112
 113                   Ptr := Ptr + 1;
 114
 115                   --  Find out whether this is a -I- or regular -Ixxx switch
 116
 117                   if Ptr = Max and then Switch_Chars (Ptr) = '-' then
 118                      Look_In_Primary_Dir := False;
 119
 120                   else
 121                      Add_Src_Search_Dir (Switch_Chars (Ptr .. Max));
 122                   end if;
 123
 124                   Ptr := Max + 1;
 125
 126                --  Processing of the --RTS switch. --RTS has been modified by
 127                --  gcc and is now of the form -fRTS
 128
 129                elsif Ptr + 3 <= Max
 130                  and then Switch_Chars (Ptr .. Ptr + 3) = "fRTS"
 131                then
 132                   Ptr := Ptr + 1;
 133
 134                   if Ptr + 4 > Max
 135                     or else Switch_Chars (Ptr + 3) /= '='
 136                   then
 137                      Osint.Fail ("missing path for --RTS");
 138                   else
 139                      --  Check that this is the first time --RTS is specified
 140                      --  or if it is not the first time, the same path has
 141                      --  been specified.
 142
 143                      if RTS_Specified = null then
 144                         RTS_Specified :=
 145                           new String'(Switch_Chars (Ptr + 4 .. Max));
 146
 147                      elsif
 148                        RTS_Specified.all /= Switch_Chars (Ptr + 4 .. Max)
 149                      then
 150                         Osint.Fail
 151                           ("--RTS cannot be specified multiple times");
 152                      end if;
 153
 154                      --  Valid --RTS switch
 155
 156                      Opt.No_Stdinc := True;
 157                      Opt.RTS_Switch := True;
 158
 159                      RTS_Src_Path_Name := Get_RTS_Search_Dir
 160                                             (Switch_Chars (Ptr + 4 .. Max),
 161                                              Include);
 162                      RTS_Lib_Path_Name := Get_RTS_Search_Dir
 163                                             (Switch_Chars (Ptr + 4 .. Max),
 164                                              Objects);
 165
 166                      if RTS_Src_Path_Name /= null and then
 167                         RTS_Lib_Path_Name /= null
 168                      then
 169                         Ptr := Max + 1;
 170
 171                      elsif RTS_Src_Path_Name = null and then
 172                            RTS_Lib_Path_Name = null
 173                      then
 174                         Osint.Fail ("RTS path not valid: missing " &
 175                                     "adainclude and adalib directories");
 176
 177                      elsif RTS_Src_Path_Name = null then
 178                         Osint.Fail ("RTS path not valid: missing " &
 179                                     "adainclude directory");
 180
 181                      elsif RTS_Lib_Path_Name = null then
 182                         Osint.Fail ("RTS path not valid: missing " &
 183                                     "adalib directory");
 184                      end if;
 185                   end if;
 186                else
 187                   Bad_Switch (C);
 188                end if;
 189
 190          when True =>
 191
 192             --  Process -gnat* options
 193
 194             case C is
 195
 196             when 'a' =>
 197                Ptr := Ptr + 1;
 198                Assertions_Enabled := True;
 199                Debug_Pragmas_Enabled := True;
 200
 201             --  Processing for A switch
 202
 203             when 'A' =>
 204                Ptr := Ptr + 1;
 205                Config_File := False;
 206
 207             --  Processing for b switch
 208
 209             when 'b' =>
 210                Ptr := Ptr + 1;
 211                Brief_Output := True;
 212
 213             --  Processing for c switch
 214
 215             when 'c' =>
 216                if not First_Switch then
 217                   Osint.Fail
 218                     ("-gnatc must be first if combined with other switches");
 219                end if;
 220
 221                Ptr := Ptr + 1;
 222                Operating_Mode := Check_Semantics;
 223
 224                if Tree_Output then
 225                   ASIS_Mode := True;
 226                end if;
 227
 228             --  Processing for d switch
 229
 230             when 'd' =>
 231                Store_Switch := False;
 232                Storing (First_Stored) := 'd';
 233                Dot := False;
 234
 235                --  Note: for the debug switch, the remaining characters in this
 236                --  switch field must all be debug flags, since all valid switch
 237                --  characters are also valid debug characters.
 238
 239                --  Loop to scan out debug flags
 240
 241                while Ptr < Max loop
 242                   Ptr := Ptr + 1;
 243                   C := Switch_Chars (Ptr);
 244                   exit when C = ASCII.NUL or else C = '/' or else C = '-';
 245
 246                   if C in '1' .. '9' or else
 247                      C in 'a' .. 'z' or else
 248                      C in 'A' .. 'Z'
 249                   then
 250                      if Dot then
 251                         Set_Dotted_Debug_Flag (C);
 252                         Storing (First_Stored + 1) := '.';
 253                         Storing (First_Stored + 2) := C;
 254                         Store_Compilation_Switch
 255                           (Storing (Storing'First .. First_Stored + 2));
 256                         Dot := False;
 257
 258                      else
 259                         Set_Debug_Flag (C);
 260                         Storing (First_Stored + 1) := C;
 261                         Store_Compilation_Switch
 262                           (Storing (Storing'First .. First_Stored + 1));
 263                      end if;
 264
 265                   elsif C = '.' then
 266                      Dot := True;
 267
 268                   else
 269                      Bad_Switch (C);
 270                   end if;
 271                end loop;
 272
 273                return;
 274
 275             --  Processing for D switch
 276
 277             when 'D' =>
 278                Ptr := Ptr + 1;
 279
 280                --  Note: -gnatD also sets -gnatx (to turn off cross-reference
 281                --  generation in the ali file) since otherwise this generation
 282                --  gets confused by the "wrong" Sloc values put in the tree.
 283
 284                Debug_Generated_Code := True;
 285                Xref_Active := False;
 286                Set_Debug_Flag ('g');
 287
 288             --  -gnate? (extended switches)
 289
 290             when 'e' =>
 291                Ptr := Ptr + 1;
 292
 293                --  The -gnate? switches are all double character switches
 294                --  so we must always have a character after the e.
 295
 296                if Ptr > Max then
 297                   Bad_Switch (C);
 298                end if;
 299
 300                case Switch_Chars (Ptr) is
 301
 302                   --  -gnatec (configuration pragmas)
 303
 304                   when 'c' =>
 305                      Store_Switch := False;
 306                      Ptr := Ptr + 1;
 307
 308                      --  There may be an equal sign between -gnatec and
 309                      --  the path name of the config file.
 310
 311                      if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 312                         Ptr := Ptr + 1;
 313                      end if;
 314
 315                      if Ptr > Max then
 316                         Bad_Switch (C);
 317                      end if;
 318
 319                      declare
 320                         Config_File_Name : constant String_Access :=
 321                                              new String'
 322                                                   (Switch_Chars (Ptr .. Max));
 323
 324                      begin
 325                         if Config_File_Names = null then
 326                            Config_File_Names :=
 327                              new String_List'(1 => Config_File_Name);
 328
 329                         else
 330                            declare
 331                               New_Names : constant String_List_Access :=
 332                                             new String_List
 333                                               (1 ..
 334                                                Config_File_Names'Length + 1);
 335
 336                            begin
 337                               for Index in Config_File_Names'Range loop
 338                                  New_Names (Index) :=
 339                                    Config_File_Names (Index);
 340                                  Config_File_Names (Index) := null;
 341                               end loop;
 342
 343                               New_Names (New_Names'Last) := Config_File_Name;
 344                               Free (Config_File_Names);
 345                               Config_File_Names := New_Names;
 346                            end;
 347                         end if;
 348                      end;
 349
 350                      return;
 351
 352                   --  -gnateD switch (symbol definition)
 353
 354                   when 'D' =>
 355                      Store_Switch := False;
 356                      Ptr := Ptr + 1;
 357
 358                      if Ptr > Max then
 359                         Bad_Switch (C);
 360                      end if;
 361
 362                      Add_Symbol_Definition (Switch_Chars (Ptr .. Max));
 363
 364                      --  Store the switch
 365
 366                      Storing (First_Stored .. First_Stored + 1) := "eD";
 367                      Storing
 368                        (First_Stored + 2 .. First_Stored + Max - Ptr + 2) :=
 369                        Switch_Chars (Ptr .. Max);
 370                      Store_Compilation_Switch (Storing
 371                               (Storing'First .. First_Stored + Max - Ptr + 2));
 372                      return;
 373
 374                   --  -gnatef (full source path for brief error messages)
 375
 376                   when 'f' =>
 377                      Store_Switch := False;
 378                      Ptr := Ptr + 1;
 379                      Full_Path_Name_For_Brief_Errors := True;
 380                      return;
 381
 382                   --  -gnateI (index of unit in multi-unit source)
 383
 384                   when 'I' =>
 385                      Ptr := Ptr + 1;
 386                      Scan_Pos
 387                        (Switch_Chars, Max, Ptr, Multiple_Unit_Index, C);
 388
 389                   --  -gnatem (mapping file)
 390
 391                   when 'm' =>
 392                      Store_Switch := False;
 393                      Ptr := Ptr + 1;
 394
 395                      --  There may be an equal sign between -gnatem and
 396                      --  the path name of the mapping file.
 397
 398                      if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 399                         Ptr := Ptr + 1;
 400                      end if;
 401
 402                      if Ptr > Max then
 403                         Bad_Switch (C);
 404                      end if;
 405
 406                      Mapping_File_Name :=
 407                        new String'(Switch_Chars (Ptr .. Max));
 408                      return;
 409
 410                   --  -gnatep (preprocessing data file)
 411
 412                   when 'p' =>
 413                      Store_Switch := False;
 414                      Ptr := Ptr + 1;
 415
 416                      --  There may be an equal sign between -gnatep and
 417                      --  the path name of the mapping file.
 418
 419                      if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 420                         Ptr := Ptr + 1;
 421                      end if;
 422
 423                      if Ptr > Max then
 424                         Bad_Switch (C);
 425                      end if;
 426
 427                      Preprocessing_Data_File :=
 428                        new String'(Switch_Chars (Ptr .. Max));
 429
 430                      --  Store the switch.
 431                      --  Because we may store a longer switch (we normalize
 432                      --  to -gnatep=), use a local variable.
 433
 434                      declare
 435                         To_Store : String
 436                           (1 .. Preprocessing_Data_File'Length + 8);
 437
 438                      begin
 439                         To_Store (1 .. 8) := "-gnatep=";
 440                         To_Store (9 .. Preprocessing_Data_File'Length + 8) :=
 441                           Preprocessing_Data_File.all;
 442                         Store_Compilation_Switch (To_Store);
 443                      end;
 444
 445                   return;
 446
 447                   when 'z' =>
 448                      Store_Switch := False;
 449                      Disable_Switch_Storing;
 450                      Ptr := Ptr + 1;
 451
 452                   --  All other -gnate? switches are unassigned
 453
 454                   when others =>
 455                      Bad_Switch (C);
 456                end case;
 457
 458             --  -gnatE (dynamic elaboration checks)
 459
 460             when 'E' =>
 461                Ptr := Ptr + 1;
 462                Dynamic_Elaboration_Checks := True;
 463
 464             --  -gnatf (full error messages)
 465
 466             when 'f' =>
 467                Ptr := Ptr + 1;
 468                All_Errors_Mode := True;
 469
 470             --  Processing for F switch
 471
 472             when 'F' =>
 473                Ptr := Ptr + 1;
 474                External_Name_Exp_Casing := Uppercase;
 475                External_Name_Imp_Casing := Uppercase;
 476
 477             --  Processing for g switch
 478
 479             when 'g' =>
 480                Ptr := Ptr + 1;
 481                GNAT_Mode := True;
 482                Identifier_Character_Set := 'n';
 483                System_Extend_Unit := Empty;
 484                Warning_Mode := Treat_As_Error;
 485
 486                --  Set Ada 2005 mode explicitly. We don't want to rely on the
 487                --  implicit setting here, since for example, we want
 488                --  Preelaborate_05 treated as Preelaborate
 489
 490                Ada_Version := Ada_05;
 491                Ada_Version_Explicit := Ada_Version;
 492
 493                --  Set default warnings for -gnatg (same set as -gnatwa)
 494
 495                Check_Unreferenced           := True;
 496                Check_Unreferenced_Formals   := True;
 497                Check_Withs                  := True;
 498                Constant_Condition_Warnings  := True;
 499                Implementation_Unit_Warnings := True;
 500                Ineffective_Inline_Warnings  := True;
 501                Warn_On_Bad_Fixed_Value      := True;
 502                Warn_On_Constant             := True;
 503                Warn_On_Export_Import        := True;
 504                Warn_On_Modified_Unread      := True;
 505                Warn_On_No_Value_Assigned    := True;
 506                Warn_On_Obsolescent_Feature  := True;
 507                Warn_On_Redundant_Constructs := True;
 508                Warn_On_Unchecked_Conversion := True;
 509                Warn_On_Unrecognized_Pragma  := True;
 510
 511                Set_Style_Check_Options ("3abcdefhiklmnprstux");
 512
 513             --  Processing for G switch
 514
 515             when 'G' =>
 516                Ptr := Ptr + 1;
 517                Print_Generated_Code := True;
 518
 519             --  Processing for h switch
 520
 521             when 'h' =>
 522                Ptr := Ptr + 1;
 523                Usage_Requested := True;
 524
 525             --  Processing for H switch
 526
 527             when 'H' =>
 528                Ptr := Ptr + 1;
 529                HLO_Active := True;
 530
 531             --  Processing for i switch
 532
 533             when 'i' =>
 534                if Ptr = Max then
 535                   Bad_Switch (C);
 536                end if;
 537
 538                Ptr := Ptr + 1;
 539                C := Switch_Chars (Ptr);
 540
 541                if C in '1' .. '5'
 542                  or else C = '8'
 543                  or else C = '9'
 544                  or else C = 'p'
 545                  or else C = 'f'
 546                  or else C = 'n'
 547                  or else C = 'w'
 548                then
 549                   Identifier_Character_Set := C;
 550                   Ptr := Ptr + 1;
 551
 552                else
 553                   Bad_Switch (C);
 554                end if;
 555
 556             --  Processing for k switch
 557
 558             when 'k' =>
 559                Ptr := Ptr + 1;
 560                   Scan_Pos
 561                     (Switch_Chars, Max, Ptr, Maximum_File_Name_Length, C);
 562
 563             --  Processing for l switch
 564
 565             when 'l' =>
 566                Ptr := Ptr + 1;
 567                Full_List := True;
 568
 569             --  Processing for L switch
 570
 571             when 'L' =>
 572                Ptr := Ptr + 1;
 573                Osint.Fail
 574                  ("-gnatL is no longer supported: consider using --RTS=sjlj");
 575
 576             --  Processing for m switch
 577
 578             when 'm' =>
 579                Ptr := Ptr + 1;
 580
 581                --  There may be an equal sign between -gnatm and the value
 582
 583                if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 584                   Ptr := Ptr + 1;
 585                end if;
 586
 587                Scan_Pos (Switch_Chars, Max, Ptr, Maximum_Errors, C);
 588
 589             --  Processing for n switch
 590
 591             when 'n' =>
 592                Ptr := Ptr + 1;
 593                Inline_Active := True;
 594
 595             --  Processing for N switch
 596
 597             when 'N' =>
 598                Ptr := Ptr + 1;
 599                Inline_Active := True;
 600                Front_End_Inlining := True;
 601
 602             --  Processing for o switch
 603
 604             when 'o' =>
 605                Ptr := Ptr + 1;
 606                Suppress_Options (Overflow_Check) := False;
 607                Opt.Enable_Overflow_Checks := True;
 608
 609             --  Processing for O switch
 610
 611             when 'O' =>
 612                Store_Switch := False;
 613                Ptr := Ptr + 1;
 614                Output_File_Name_Present := True;
 615
 616             --  Processing for p switch
 617
 618             when 'p' =>
 619                Ptr := Ptr + 1;
 620
 621                --  Set all specific options as well as All_Checks in the
 622                --  Suppress_Options array, excluding Elaboration_Check, since
 623                --  this is treated specially because we do not want -gnatp to
 624                --  disable static elaboration processing.
 625
 626                for J in Suppress_Options'Range loop
 627                   if J /= Elaboration_Check then
 628                      Suppress_Options (J) := True;
 629                   end if;
 630                end loop;
 631
 632                Validity_Checks_On         := False;
 633                Opt.Suppress_Checks        := True;
 634                Opt.Enable_Overflow_Checks := False;
 635
 636             --  Processing for P switch
 637
 638             when 'P' =>
 639                Ptr := Ptr + 1;
 640                Polling_Required := True;
 641
 642             --  Processing for q switch
 643
 644             when 'q' =>
 645                Ptr := Ptr + 1;
 646                Try_Semantics := True;
 647
 648             --  Processing for q switch
 649
 650             when 'Q' =>
 651                Ptr := Ptr + 1;
 652                Force_ALI_Tree_File := True;
 653                Try_Semantics := True;
 654
 655             --  Processing for R switch
 656
 657             when 'R' =>
 658                Ptr := Ptr + 1;
 659                Back_Annotate_Rep_Info := True;
 660                List_Representation_Info := 1;
 661
 662                while Ptr <= Max loop
 663                   C := Switch_Chars (Ptr);
 664
 665                   if C in '1' .. '3' then
 666                      List_Representation_Info :=
 667                        Character'Pos (C) - Character'Pos ('0');
 668
 669                   elsif Switch_Chars (Ptr) = 's' then
 670                      List_Representation_Info_To_File := True;
 671
 672                   elsif Switch_Chars (Ptr) = 'm' then
 673                      List_Representation_Info_Mechanisms := True;
 674
 675                   else
 676                      Bad_Switch (C);
 677                   end if;
 678
 679                   Ptr := Ptr + 1;
 680                end loop;
 681
 682             --  Processing for s switch
 683
 684             when 's' =>
 685                if not First_Switch then
 686                   Osint.Fail
 687                     ("-gnats must be first if combined with other switches");
 688                end if;
 689
 690                Ptr := Ptr + 1;
 691                Operating_Mode := Check_Syntax;
 692
 693             --  Processing for S switch
 694
 695             when 'S' =>
 696                Print_Standard := True;
 697                Ptr := Ptr + 1;
 698
 699             --  Processing for t switch
 700
 701             when 't' =>
 702                Ptr := Ptr + 1;
 703                Tree_Output := True;
 704
 705                if Operating_Mode = Check_Semantics then
 706                   ASIS_Mode := True;
 707                end if;
 708
 709                Back_Annotate_Rep_Info := True;
 710
 711             --  Processing for T switch
 712
 713             when 'T' =>
 714                Ptr := Ptr + 1;
 715                Scan_Pos (Switch_Chars, Max, Ptr, Table_Factor, C);
 716
 717             --  Processing for u switch
 718
 719             when 'u' =>
 720                Ptr := Ptr + 1;
 721                List_Units := True;
 722
 723             --  Processing for U switch
 724
 725             when 'U' =>
 726                Ptr := Ptr + 1;
 727                Unique_Error_Tag := True;
 728
 729             --  Processing for v switch
 730
 731             when 'v' =>
 732                Ptr := Ptr + 1;
 733                Verbose_Mode := True;
 734
 735             --  Processing for V switch
 736
 737             when 'V' =>
 738                Store_Switch := False;
 739                Storing (First_Stored) := 'V';
 740                Ptr := Ptr + 1;
 741
 742                if Ptr > Max then
 743                   Bad_Switch (C);
 744
 745                else
 746                   declare
 747                      OK  : Boolean;
 748
 749                   begin
 750                      Set_Validity_Check_Options
 751                        (Switch_Chars (Ptr .. Max), OK, Ptr);
 752
 753                      if not OK then
 754                         Bad_Switch (C);
 755                      end if;
 756
 757                      for Index in First_Char + 1 .. Max loop
 758                         Storing (First_Stored + 1) :=
 759                           Switch_Chars (Index);
 760                         Store_Compilation_Switch
 761                           (Storing (Storing'First .. First_Stored + 1));
 762                      end loop;
 763                   end;
 764                end if;
 765
 766                Ptr := Max + 1;
 767
 768             --  Processing for w switch
 769
 770             when 'w' =>
 771                Store_Switch := False;
 772                Storing (First_Stored) := 'w';
 773                Ptr := Ptr + 1;
 774
 775                if Ptr > Max then
 776                   Bad_Switch (C);
 777                end if;
 778
 779                while Ptr <= Max loop
 780                   C := Switch_Chars (Ptr);
 781
 782                   if Set_Warning_Switch (C) then
 783                      null;
 784                   else
 785                      Bad_Switch (C);
 786                   end if;
 787
 788                   if C /= 'w' then
 789                      Storing (First_Stored + 1) := C;
 790                      Store_Compilation_Switch
 791                        (Storing (Storing'First .. First_Stored + 1));
 792                   end if;
 793
 794                   Ptr := Ptr + 1;
 795                end loop;
 796
 797                return;
 798
 799             --  Processing for W switch
 800
 801             when 'W' =>
 802                Ptr := Ptr + 1;
 803
 804                if Ptr > Max then
 805                   Bad_Switch (C);
 806                end if;
 807
 808                for J in WC_Encoding_Method loop
 809                   if Switch_Chars (Ptr) = WC_Encoding_Letters (J) then
 810                      Wide_Character_Encoding_Method := J;
 811                      exit;
 812
 813                   elsif J = WC_Encoding_Method'Last then
 814                      Bad_Switch (C);
 815                   end if;
 816                end loop;
 817
 818                Upper_Half_Encoding :=
 819                  Wide_Character_Encoding_Method in
 820                  WC_Upper_Half_Encoding_Method;
 821
 822                Ptr := Ptr + 1;
 823
 824             --  Processing for x switch
 825
 826             when 'x' =>
 827                Ptr := Ptr + 1;
 828                Xref_Active := False;
 829
 830             --  Processing for X switch
 831
 832             when 'X' =>
 833                Ptr := Ptr + 1;
 834                Extensions_Allowed := True;
 835                Ada_Version := Ada_Version_Type'Last;
 836                Ada_Version_Explicit := Ada_Version;
 837
 838             --  Processing for y switch
 839
 840             when 'y' =>
 841                Ptr := Ptr + 1;
 842
 843                if Ptr > Max then
 844                   Set_Default_Style_Check_Options;
 845
 846                else
 847                   Store_Switch := False;
 848                   Storing (First_Stored) := 'y';
 849
 850                   declare
 851                      OK  : Boolean;
 852                      Last_Stored : Integer;
 853
 854                   begin
 855                      Set_Style_Check_Options
 856                        (Switch_Chars (Ptr .. Max), OK, Ptr);
 857
 858                      if not OK then
 859                         declare
 860                            R : String (1 .. Style_Msg_Len + 20);
 861                         begin
 862                            R (1 .. 19) := "bad -gnaty switch (";
 863                            R (20 .. R'Last - 1) :=
 864                              Style_Msg_Buf (1 .. Style_Msg_Len);
 865                            R (R'Last) := ')';
 866                            Osint.Fail (R);
 867                         end;
 868                      end if;
 869
 870                      Ptr := First_Char + 1;
 871                      while Ptr <= Max loop
 872                         Last_Stored := First_Stored + 1;
 873                         Storing (Last_Stored) := Switch_Chars (Ptr);
 874
 875                         if Switch_Chars (Ptr) = 'M' then
 876                            loop
 877                               Ptr := Ptr + 1;
 878                               exit when Ptr > Max
 879                                 or else Switch_Chars (Ptr) not in '0' .. '9';
 880                               Last_Stored := Last_Stored + 1;
 881                               Storing (Last_Stored) := Switch_Chars (Ptr);
 882                            end loop;
 883
 884                         else
 885                            Ptr := Ptr + 1;
 886                         end if;
 887
 888                         Store_Compilation_Switch
 889                           (Storing (Storing'First .. Last_Stored));
 890                      end loop;
 891                   end;
 892                end if;
 893
 894             --  Processing for z switch
 895
 896             when 'z' =>
 897                Ptr := Ptr + 1;
 898
 899                --  Allowed for compiler only if this is the only
 900                --  -z switch, we do not allow multiple occurrences
 901
 902                if Distribution_Stub_Mode = No_Stubs then
 903                   case Switch_Chars (Ptr) is
 904                      when 'r' =>
 905                         Distribution_Stub_Mode := Generate_Receiver_Stub_Body;
 906
 907                      when 'c' =>
 908                         Distribution_Stub_Mode := Generate_Caller_Stub_Body;
 909
 910                      when others =>
 911                         Bad_Switch (C);
 912                   end case;
 913
 914                   Ptr := Ptr + 1;
 915
 916                end if;
 917
 918             --  Processing for Z switch
 919
 920             when 'Z' =>
 921                Ptr := Ptr + 1;
 922                Osint.Fail
 923                  ("-gnatZ is no longer supported: consider using --RTS=zcx");
 924
 925             --  Processing for 83 switch
 926
 927             when '8' =>
 928                if Ptr = Max then
 929                   Bad_Switch (C);
 930                end if;
 931
 932                Ptr := Ptr + 1;
 933
 934                if Switch_Chars (Ptr) /= '3' then
 935                   Bad_Switch (C);
 936                else
 937                   Ptr := Ptr + 1;
 938                   Ada_Version := Ada_83;
 939                   Ada_Version_Explicit := Ada_Version;
 940                end if;
 941
 942             --  Processing for 95 switch
 943
 944             when '9' =>
 945                if Ptr = Max then
 946                   Bad_Switch (C);
 947                end if;
 948
 949                Ptr := Ptr + 1;
 950
 951                if Switch_Chars (Ptr) /= '5' then
 952                   Bad_Switch (C);
 953                else
 954                   Ptr := Ptr + 1;
 955                   Ada_Version := Ada_95;
 956                   Ada_Version_Explicit := Ada_Version;
 957                end if;
 958
 959             --  Processing for 05 switch
 960
 961             when '0' =>
 962                if Ptr = Max then
 963                   Bad_Switch (C);
 964                end if;
 965
 966                Ptr := Ptr + 1;
 967
 968                if Switch_Chars (Ptr) /= '5' then
 969                   Bad_Switch (C);
 970                else
 971                   Ptr := Ptr + 1;
 972                   Ada_Version := Ada_05;
 973                   Ada_Version_Explicit := Ada_Version;
 974                end if;
 975
 976             --  Ignore extra switch character
 977
 978             when '/' | '-' =>
 979                Ptr := Ptr + 1;
 980
 981             --  Anything else is an error (illegal switch character)
 982
 983             when others =>
 984                Bad_Switch (C);
 985             end case;
 986          end case;
 987
 988          if Store_Switch then
 989             Storing (First_Stored .. First_Stored + Ptr - First_Char - 1) :=
 990               Switch_Chars (First_Char .. Ptr - 1);
 991             Store_Compilation_Switch
 992               (Storing (Storing'First .. First_Stored + Ptr - First_Char - 1));
 993          end if;
 994
 995          First_Switch := False;
 996       end loop;
 997    end Scan_Front_End_Switches;
 998
 999 end Switch.C;