gcc/ada/sinput-d.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S I N P U T . D                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Osint;   use Osint;
  27 with Osint.C; use Osint.C;
  28
  29 package body Sinput.D is
  30
  31    Dfile : Source_File_Index;
  32    --  Index of currently active debug source file
  33
  34    ------------------------
  35    -- Close_Debug_Source --
  36    ------------------------
  37
  38    procedure Close_Debug_Source is
  39       S    : Source_File_Record renames Source_File.Table (Dfile);
  40       Src  : Source_Buffer_Ptr;
  41
  42    begin
  43       Trim_Lines_Table (Dfile);
  44       Close_Debug_File;
  45
  46       --  Now we need to read the file that we wrote and store it in memory for
  47       --  subsequent access.
  48
  49       Read_Source_File
  50         (S.Full_Debug_Name, S.Source_First, S.Source_Last, Src);
  51       S.Source_Text := Src;
  52    end Close_Debug_Source;
  53
  54    -------------------------
  55    -- Create_Debug_Source --
  56    -------------------------
  57
  58    procedure Create_Debug_Source
  59      (Source : Source_File_Index;
  60       Loc    : out Source_Ptr)
  61    is
  62    begin
  63       Loc := Source_File.Table (Source_File.Last).Source_Last + 1;
  64       Source_File.Append (Source_File.Table (Source));
  65       Dfile := Source_File.Last;
  66
  67       declare
  68          S : Source_File_Record renames Source_File.Table (Dfile);
  69
  70       begin
  71          S.Full_Debug_Name   := Create_Debug_File (S.File_Name);
  72          S.Debug_Source_Name := Strip_Directory (S.Full_Debug_Name);
  73          S.Source_First      := Loc;
  74          S.Source_Last       := Loc;
  75          S.Lines_Table       := null;
  76          S.Last_Source_Line  := 1;
  77
  78          --  Allocate lines table, guess that it needs to be three times bigger
  79          --  than the original source (in number of lines).
  80
  81          Alloc_Line_Tables
  82            (S, Int (Source_File.Table (Source).Last_Source_Line * 3));
  83          S.Lines_Table (1) := Loc;
  84       end;
  85    end Create_Debug_Source;
  86
  87    ----------------------
  88    -- Write_Debug_Line --
  89    ----------------------
  90
  91    procedure Write_Debug_Line (Str : String; Loc : in out Source_Ptr) is
  92       S : Source_File_Record renames Source_File.Table (Dfile);
  93
  94    begin
  95       --  Ignore write request if null line at start of file
  96
  97       if Str'Length = 0 and then Loc = S.Source_First then
  98          return;
  99
 100       --  Here we write the line, compute the source location for the following
 101       --  line, allocate its table entry, and update the source record entry.
 102
 103       else
 104          Write_Debug_Info (Str (Str'First .. Str'Last - 1));
 105          Loc := Loc - 1 + Source_Ptr (Str'Length + Debug_File_Eol_Length);
 106          Add_Line_Tables_Entry (S, Loc);
 107          S.Source_Last := Loc;
 108          Set_Source_File_Index_Table (Dfile);
 109       end if;
 110    end Write_Debug_Line;
 111
 112 end Sinput.D;