gcc/ada/sem_warn.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ W A R N                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1999-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Alloc;
  28 with Atree;    use Atree;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Fname;    use Fname;
  32 with Lib;      use Lib;
  33 with Nlists;   use Nlists;
  34 with Opt;      use Opt;
  35 with Sem;      use Sem;
  36 with Sem_Ch8;  use Sem_Ch8;
  37 with Sem_Util; use Sem_Util;
  38 with Sinfo;    use Sinfo;
  39 with Sinput;   use Sinput;
  40 with Snames;   use Snames;
  41 with Stand;    use Stand;
  42 with Table;
  43
  44 package body Sem_Warn is
  45
  46    --  The following table collects Id's of entities that are potentially
  47    --  unreferenced. See Check_Unset_Reference for further details.
  48
  49    package Unreferenced_Entities is new Table.Table (
  50      Table_Component_Type => Entity_Id,
  51      Table_Index_Type     => Nat,
  52      Table_Low_Bound      => 1,
  53      Table_Initial        => Alloc.Unreferenced_Entities_Initial,
  54      Table_Increment      => Alloc.Unreferenced_Entities_Increment,
  55      Table_Name           => "Unreferenced_Entities");
  56
  57    ------------------------------
  58    -- Handling of Conditionals --
  59    ------------------------------
  60
  61    --  Note: this is work in progress, the data structures and general
  62    --  approach are defined, but are not in use yet. ???
  63
  64    --  One entry is made in the following table for each branch of
  65    --  a conditional, e.g. an if-then-elsif-else-endif structure
  66    --  creates three entries in this table.
  67
  68    type Branch_Entry is record
  69       Sloc : Source_Ptr;
  70       --  Location for warnings associated with this branch
  71
  72       Defs : Elist_Id;
  73       --  List of entities defined for the first time in this branch. On
  74       --  exit from a conditional structure, any entity that is in the
  75       --  list of all branches is removed (and the entity flagged as
  76       --  defined by the conditional as a whole). Thus after processing
  77       --  a conditional, Defs contains a list of entities defined in this
  78       --  branch for the first time, but not defined at all in some other
  79       --  branch of the same conditional. A value of No_Elist is used to
  80       --  represent the initial empty list.
  81
  82       Next : Nat;
  83       --  Index of next branch for this conditional, zero = last branch
  84    end record;
  85
  86    package Branch_Table is new Table.Table (
  87      Table_Component_Type => Branch_Entry,
  88      Table_Index_Type     => Nat,
  89      Table_Low_Bound      => 1,
  90      Table_Initial        => Alloc.Branches_Initial,
  91      Table_Increment      => Alloc.Branches_Increment,
  92      Table_Name           => "Branches");
  93
  94    --  The following table is used to represent conditionals, there is
  95    --  one entry in this table for each conditional structure.
  96
  97    type Conditional_Entry is record
  98       If_Stmt : Boolean;
  99       --  True for IF statement, False for CASE statement
 100
 101       First_Branch : Nat;
 102       --  Index in Branch table of first branch, zero = none yet
 103
 104       Current_Branch : Nat;
 105       --  Index in Branch table of current branch, zero = none yet
 106    end record;
 107
 108    package Conditional_Table is new Table.Table (
 109      Table_Component_Type => Conditional_Entry,
 110      Table_Index_Type     => Nat,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Conditionals_Initial,
 113      Table_Increment      => Alloc.Conditionals_Increment,
 114      Table_Name           => "Conditionals");
 115
 116    --  The following table is a stack that keeps track of the current
 117    --  conditional. The Last entry is the top of the stack. An Empty
 118    --  entry represents the start of a compilation unit. Non-zero
 119    --  entries in the stack are indexes into the conditional table.
 120
 121    package Conditional_Stack is new Table.Table (
 122      Table_Component_Type => Nat,
 123      Table_Index_Type     => Nat,
 124      Table_Low_Bound      => 1,
 125      Table_Initial        => Alloc.Conditional_Stack_Initial,
 126      Table_Increment      => Alloc.Conditional_Stack_Increment,
 127      Table_Name           => "Conditional_Stack");
 128
 129    pragma Warnings (Off, Branch_Table);
 130    pragma Warnings (Off, Conditional_Table);
 131    pragma Warnings (Off, Conditional_Stack);
 132    --  Not yet referenced, see note above ???
 133
 134    -----------------------
 135    -- Local Subprograms --
 136    -----------------------
 137
 138    function Generic_Package_Spec_Entity (E : Entity_Id) return Boolean;
 139    --  This returns true if the entity E is declared within a generic package.
 140    --  The point of this is to detect variables which are not assigned within
 141    --  the generic, but might be assigned outside the package for any given
 142    --  instance. These are cases where we leave the warnings to be posted
 143    --  for the instance, when we will know more.
 144
 145    function Operand_Has_Warnings_Suppressed (N : Node_Id) return Boolean;
 146    --  This function traverses the expression tree represented by the node
 147    --  N and determines if any sub-operand is a reference to an entity for
 148    --  which the Warnings_Off flag is set. True is returned if such an
 149    --  entity is encountered, and False otherwise.
 150
 151    ----------------------
 152    -- Check_References --
 153    ----------------------
 154
 155    procedure Check_References (E : Entity_Id; Anod : Node_Id := Empty) is
 156       E1 : Entity_Id;
 157       UR : Node_Id;
 158
 159       function Missing_Subunits return Boolean;
 160       --  We suppress warnings when there are missing subunits, because this
 161       --  may generate too many false positives: entities in a parent may
 162       --  only be referenced in one of the subunits. We make an exception
 163       --  for subunits that contain no other stubs.
 164
 165       procedure Output_Reference_Error (M : String);
 166       --  Used to output an error message. Deals with posting the error on
 167       --  the body formal in the accept case.
 168
 169       function Publicly_Referenceable (Ent : Entity_Id) return Boolean;
 170       --  This is true if the entity in question is potentially referenceable
 171       --  from another unit. This is true for entities in packages that are
 172       --  at the library level.
 173
 174       -----------------------
 175       --  Missing_Subunits --
 176       -----------------------
 177
 178       function Missing_Subunits return Boolean is
 179          D : Node_Id;
 180
 181       begin
 182          if not Unloaded_Subunits then
 183
 184             --  Normal compilation, all subunits are present
 185
 186             return False;
 187
 188          elsif E /= Main_Unit_Entity then
 189
 190             --  No warnings on a stub that is not the main unit
 191
 192             return True;
 193
 194          elsif Nkind (Unit_Declaration_Node (E)) in N_Proper_Body then
 195             D := First (Declarations (Unit_Declaration_Node (E)));
 196
 197             while Present (D) loop
 198
 199                --  No warnings if the proper body contains nested stubs
 200
 201                if Nkind (D) in N_Body_Stub then
 202                   return True;
 203                end if;
 204
 205                Next (D);
 206             end loop;
 207
 208             return False;
 209
 210          else
 211             --   Missing stubs elsewhere
 212
 213             return True;
 214          end if;
 215       end Missing_Subunits;
 216
 217       ----------------------------
 218       -- Output_Reference_Error --
 219       ----------------------------
 220
 221       procedure Output_Reference_Error (M : String) is
 222       begin
 223          --  Other than accept case, post error on defining identifier
 224
 225          if No (Anod) then
 226             Error_Msg_N (M, E1);
 227
 228          --  Accept case, find body formal to post the message
 229
 230          else
 231             declare
 232                Parm  : Node_Id;
 233                Enod  : Node_Id;
 234                Defid : Entity_Id;
 235
 236             begin
 237                Enod := Anod;
 238
 239                if Present (Parameter_Specifications (Anod)) then
 240                   Parm := First (Parameter_Specifications (Anod));
 241
 242                   while Present (Parm) loop
 243                      Defid := Defining_Identifier (Parm);
 244
 245                      if Chars (E1) = Chars (Defid) then
 246                         Enod := Defid;
 247                         exit;
 248                      end if;
 249
 250                      Next (Parm);
 251                   end loop;
 252                end if;
 253
 254                Error_Msg_NE (M, Enod, E1);
 255             end;
 256          end if;
 257       end Output_Reference_Error;
 258
 259       ----------------------------
 260       -- Publicly_Referenceable --
 261       ----------------------------
 262
 263       function Publicly_Referenceable (Ent : Entity_Id) return Boolean is
 264          P    : Node_Id;
 265          Prev : Node_Id;
 266
 267       begin
 268          --  Examine parents to look for a library level package spec
 269          --  But if we find a body or block or other similar construct
 270          --  along the way, we cannot be referenced.
 271
 272          Prev := Ent;
 273          P    := Parent (Ent);
 274          loop
 275             case Nkind (P) is
 276
 277                --  If we get to top of tree, then publicly referenceable
 278
 279                when N_Empty =>
 280                   return True;
 281
 282                --  If we reach a generic package declaration, then always
 283                --  consider this referenceable, since any instantiation will
 284                --  have access to the entities in the generic package. Note
 285                --  that the package itself may not be instantiated, but then
 286                --  we will get a warning for the package entity
 287                --  Note that generic formal parameters are themselves not
 288                --  publicly referenceable in an instance, and warnings on
 289                --  them are useful.
 290
 291                when N_Generic_Package_Declaration =>
 292                   return
 293                     not Is_List_Member (Prev)
 294                       or else List_Containing (Prev)
 295                         /= Generic_Formal_Declarations (P);
 296
 297                --  if we reach a subprogram body, entity is not referenceable
 298                --  unless it is the defining entity of the body. This will
 299                --  happen, e.g. when a function is an attribute renaming that
 300                --  is rewritten as a body.
 301
 302                when N_Subprogram_Body  =>
 303                   if Ent /= Defining_Entity (P) then
 304                      return False;
 305                   else
 306                      P := Parent (P);
 307                   end if;
 308
 309                --  If we reach any other body, definitely not referenceable
 310
 311                when N_Package_Body    |
 312                     N_Task_Body       |
 313                     N_Entry_Body      |
 314                     N_Protected_Body  |
 315                     N_Block_Statement |
 316                     N_Subunit         =>
 317                   return False;
 318
 319                --  For all other cases, keep looking up tree
 320
 321                when others =>
 322                   Prev := P;
 323                   P    := Parent (P);
 324             end case;
 325          end loop;
 326       end Publicly_Referenceable;
 327
 328    --  Start of processing for Check_References
 329
 330    begin
 331       --  No messages if warnings are suppressed, or if we have detected
 332       --  any real errors so far (this last check avoids junk messages
 333       --  resulting from errors, e.g. a subunit that is not loaded).
 334
 335       if Warning_Mode = Suppress
 336         or else Serious_Errors_Detected /= 0
 337       then
 338          return;
 339       end if;
 340
 341       --  We also skip the messages if any subunits were not loaded (see
 342       --  comment in Sem_Ch10 to understand how this is set, and why it is
 343       --  necessary to suppress the warnings in this case).
 344
 345       if Missing_Subunits then
 346          return;
 347       end if;
 348
 349       --  Otherwise loop through entities, looking for suspicious stuff
 350
 351       E1 := First_Entity (E);
 352       while Present (E1) loop
 353
 354          --  We only look at source entities with warning flag on
 355
 356          if Comes_From_Source (E1) and then not Warnings_Off (E1) then
 357
 358             --  We are interested in variables and out parameters, but we
 359             --  exclude protected types, too complicated to worry about.
 360
 361             if Ekind (E1) = E_Variable
 362                  or else
 363                (Ekind (E1) = E_Out_Parameter
 364                   and then not Is_Protected_Type (Current_Scope))
 365             then
 366                --  Post warning if this object not assigned. Note that we
 367                --  do not consider the implicit initialization of an access
 368                --  type to be the assignment of a value for this purpose.
 369
 370                if Ekind (E1) = E_Out_Parameter
 371                  and then Present (Spec_Entity (E1))
 372                then
 373                   UR := Unset_Reference (Spec_Entity (E1));
 374                else
 375                   UR := Unset_Reference (E1);
 376                end if;
 377
 378                --  If the entity is an out parameter of the current subprogram
 379                --  body, check the warning status of the parameter in the spec.
 380
 381                if Ekind (E1) = E_Out_Parameter
 382                  and then Present (Spec_Entity (E1))
 383                  and then Warnings_Off (Spec_Entity (E1))
 384                then
 385                   null;
 386
 387                elsif Warn_On_No_Value_Assigned
 388                  and then Present (UR)
 389                  and then Is_Access_Type (Etype (E1))
 390                then
 391
 392                   --  For access types, the only time we made a UR
 393                   --  entry was for a dereference, and so we post
 394                   --  the appropriate warning here (note that the
 395                   --  dereference may not be explicit in the source,
 396                   --  for example in the case of a dispatching call
 397                   --  with an anonymous access controlling formal, or
 398                   --  of an assignment of a pointer involving a
 399                   --  discriminant check on the designated object).
 400
 401                   Error_Msg_NE ("& may be null?", UR, E1);
 402                   goto Continue;
 403
 404                elsif Never_Set_In_Source (E1)
 405                  and then not Generic_Package_Spec_Entity (E1)
 406                then
 407                   if Warn_On_No_Value_Assigned then
 408
 409                      --  Do not output complaint about never being assigned a
 410                      --  value if a pragma Unreferenced applies to the variable
 411                      --  or if it is a parameter, to the corresponding spec.
 412
 413                      if Has_Pragma_Unreferenced (E1)
 414                        or else (Is_Formal (E1)
 415                                   and then Present (Spec_Entity (E1))
 416                                   and then
 417                                     Has_Pragma_Unreferenced (Spec_Entity (E1)))
 418                      then
 419                         null;
 420
 421                      --  Pragma Unreferenced not set, so output message
 422
 423                      else
 424                         Output_Reference_Error
 425                           ("& is never assigned a value?");
 426
 427                         --  Deal with special case where this variable is
 428                         --  hidden by a loop variable
 429
 430                         if Ekind (E1) = E_Variable
 431                           and then Present (Hiding_Loop_Variable (E1))
 432                         then
 433                            Error_Msg_Sloc := Sloc (E1);
 434                            Error_Msg_N
 435                              ("declaration hides &#?",
 436                               Hiding_Loop_Variable (E1));
 437                            Error_Msg_N
 438                              ("for loop implicitly declares loop variable?",
 439                               Hiding_Loop_Variable (E1));
 440                         end if;
 441                      end if;
 442                   end if;
 443                   goto Continue;
 444
 445                --  Case of variable that could be a constant. Note that we
 446                --  never signal such messages for generic package entities,
 447                --  since a given instance could have modifications outside
 448                --  the package.
 449
 450                elsif Warn_On_Constant
 451                  and then Ekind (E1) = E_Variable
 452                  and then Is_True_Constant (E1)
 453                  and then not Generic_Package_Spec_Entity (E1)
 454                then
 455                   Error_Msg_N
 456                     ("& is not modified, could be declared constant?", E1);
 457                end if;
 458
 459                --  Check for unset reference, note that we exclude access
 460                --  types from this check, since access types do always have
 461                --  a null value, and that seems legitimate in this case.
 462
 463                if Warn_On_No_Value_Assigned and then Present (UR) then
 464
 465                   --  For other than access type, go back to original node
 466                   --  to deal with case where original unset reference
 467                   --  has been rewritten during expansion.
 468
 469                   UR := Original_Node (UR);
 470
 471                   --  In some cases, the original node may be a type
 472                   --  conversion or qualification, and in this case
 473                   --  we want the object entity inside.
 474
 475                   while Nkind (UR) = N_Type_Conversion
 476                     or else Nkind (UR) = N_Qualified_Expression
 477                   loop
 478                      UR := Expression (UR);
 479                   end loop;
 480
 481                   --  Here we issue the warning, all checks completed
 482                   --  If the unset reference is prefix of a selected
 483                   --  component that comes from source, mention the
 484                   --  component as well. If the selected component comes
 485                   --  from expansion, all we know is that the entity is
 486                   --  not fully initialized at the point of the reference.
 487                   --  Locate an unintialized component to get a better
 488                   --  error message.
 489
 490                   if Nkind (Parent (UR)) = N_Selected_Component then
 491                      Error_Msg_Node_2 := Selector_Name (Parent (UR));
 492
 493                      if not Comes_From_Source (Parent (UR)) then
 494                         declare
 495                            Comp : Entity_Id;
 496
 497                         begin
 498                            Comp := First_Entity (Etype (E1));
 499                            while Present (Comp) loop
 500                               if Ekind (Comp) = E_Component
 501                                 and then Nkind (Parent (Comp)) =
 502                                   N_Component_Declaration
 503                                 and then No (Expression (Parent (Comp)))
 504                               then
 505                                  Error_Msg_Node_2 := Comp;
 506                                  exit;
 507                               end if;
 508
 509                               Next_Entity (Comp);
 510                            end loop;
 511                         end;
 512                      end if;
 513
 514                      Error_Msg_N
 515                        ("`&.&` may be referenced before it has a value?",
 516                         UR);
 517                   else
 518                      Error_Msg_N
 519                        ("& may be referenced before it has a value?",
 520                         UR);
 521                   end if;
 522
 523                   goto Continue;
 524                end if;
 525             end if;
 526
 527             --  Then check for unreferenced entities. Note that we are only
 528             --  interested in entities which do not have the Referenced flag
 529             --  set. The Referenced_As_LHS flag is interesting only if the
 530             --  Referenced flag is not set.
 531
 532             if not Referenced (E1)
 533
 534                --  Check that warnings on unreferenced entities are enabled
 535
 536               and then ((Check_Unreferenced and then not Is_Formal (E1))
 537                            or else
 538                         (Check_Unreferenced_Formals and then Is_Formal (E1))
 539                            or else
 540                         (Warn_On_Modified_Unread
 541                           and then Referenced_As_LHS (E1)))
 542
 543                --  Labels, and enumeration literals, and exceptions. The
 544                --  warnings are also placed on local packages that cannot
 545                --  be referenced from elsewhere, including those declared
 546                --  within a package body.
 547
 548                and then (Is_Object (E1)
 549                            or else
 550                          Is_Type (E1)
 551                            or else
 552                          Ekind (E1) = E_Label
 553                            or else
 554                          Ekind (E1) = E_Exception
 555                            or else
 556                          Ekind (E1) = E_Named_Integer
 557                            or else
 558                          Ekind (E1) = E_Named_Real
 559                            or else
 560                          Is_Overloadable (E1)
 561                            or else
 562                              (Ekind (E1) = E_Package
 563                                and then
 564                                 (Ekind (E) = E_Function
 565                                   or else Ekind (E) = E_Package_Body
 566                                   or else Ekind (E) = E_Procedure
 567                                   or else Ekind (E) = E_Block)))
 568
 569                --  Exclude instantiations, since there is no reason why
 570                --  every entity in an instantiation should be referenced.
 571
 572                and then Instantiation_Location (Sloc (E1)) = No_Location
 573
 574                --  Exclude formal parameters from bodies if the corresponding
 575                --  spec entity has been referenced in the case where there is
 576                --  a separate spec.
 577
 578                and then not (Is_Formal (E1)
 579                                and then
 580                              Ekind (Scope (E1)) = E_Subprogram_Body
 581                                and then
 582                              Present (Spec_Entity (E1))
 583                                and then
 584                              Referenced (Spec_Entity (E1)))
 585
 586                --  Consider private type referenced if full view is referenced
 587                --  If there is not full view, this is a generic type on which
 588                --  warnings are also useful.
 589
 590                and then
 591                  not (Is_Private_Type (E1)
 592                    and then
 593                      Present (Full_View (E1))
 594                        and then Referenced (Full_View (E1)))
 595
 596                --  Don't worry about full view, only about private type
 597
 598                and then not Has_Private_Declaration (E1)
 599
 600                --  Eliminate dispatching operations from consideration, we
 601                --  cannot tell if these are referenced or not in any easy
 602                --  manner (note this also catches Adjust/Finalize/Initialize)
 603
 604                and then not Is_Dispatching_Operation (E1)
 605
 606                --  Check entity that can be publicly referenced (we do not
 607                --  give messages for such entities, since there could be
 608                --  other units, not involved in this compilation, that
 609                --  contain relevant references.
 610
 611                and then not Publicly_Referenceable (E1)
 612
 613                --  Class wide types are marked as source entities, but
 614                --  they are not really source entities, and are always
 615                --  created, so we do not care if they are not referenced.
 616
 617                and then Ekind (E1) /= E_Class_Wide_Type
 618
 619                --  Objects other than parameters of task types are allowed
 620                --  to be non-referenced, since they start up tasks!
 621
 622                and then ((Ekind (E1) /= E_Variable
 623                              and then Ekind (E1) /= E_Constant
 624                              and then Ekind (E1) /= E_Component)
 625                            or else not Is_Task_Type (Etype (E1)))
 626
 627                --  For subunits, only place warnings on the main unit
 628                --  itself, since parent units are not completely compiled
 629
 630                and then (Nkind (Unit (Cunit (Main_Unit))) /= N_Subunit
 631                            or else
 632                          Get_Source_Unit (E1) = Main_Unit)
 633             then
 634                --  Suppress warnings in internal units if not in -gnatg
 635                --  mode (these would be junk warnings for an applications
 636                --  program, since they refer to problems in internal units)
 637
 638                if GNAT_Mode
 639                  or else not
 640                    Is_Internal_File_Name
 641                      (Unit_File_Name (Get_Source_Unit (E1)))
 642                then
 643                   --  We do not immediately flag the error. This is because
 644                   --  we have not expanded generic bodies yet, and they may
 645                   --  have the missing reference. So instead we park the
 646                   --  entity on a list, for later processing. However, for
 647                   --  the accept case, post the error right here, since we
 648                   --  have the information now in this case.
 649
 650                   if Present (Anod) then
 651                      Output_Reference_Error ("& is not referenced?");
 652
 653                   else
 654                      Unreferenced_Entities.Increment_Last;
 655                      Unreferenced_Entities.Table
 656                        (Unreferenced_Entities.Last) := E1;
 657                   end if;
 658                end if;
 659
 660             --  Generic units are referenced in the generic body,
 661             --  but if they are not public and never instantiated
 662             --  we want to force a warning on them. We treat them
 663             --  as redundant constructs to minimize noise.
 664
 665             elsif Is_Generic_Subprogram (E1)
 666               and then not Is_Instantiated (E1)
 667               and then not Publicly_Referenceable (E1)
 668               and then Instantiation_Depth (Sloc (E1)) = 0
 669               and then Warn_On_Redundant_Constructs
 670             then
 671                Unreferenced_Entities.Increment_Last;
 672                Unreferenced_Entities.Table (Unreferenced_Entities.Last) := E1;
 673
 674                --  Force warning on entity.
 675
 676                Set_Referenced (E1, False);
 677             end if;
 678          end if;
 679
 680          --  Recurse into nested package or block. Do not recurse into a
 681          --  formal package, because the correponding body is not analyzed.
 682
 683          <<Continue>>
 684             if ((Ekind (E1) = E_Package or else Ekind (E1) = E_Generic_Package)
 685                   and then Nkind (Parent (E1)) = N_Package_Specification
 686                   and then
 687                     Nkind (Original_Node (Unit_Declaration_Node (E1)))
 688                       /= N_Formal_Package_Declaration)
 689
 690               or else Ekind (E1) = E_Block
 691             then
 692                Check_References (E1);
 693             end if;
 694
 695             Next_Entity (E1);
 696       end loop;
 697    end Check_References;
 698
 699    ---------------------------
 700    -- Check_Unset_Reference --
 701    ---------------------------
 702
 703    procedure Check_Unset_Reference (N : Node_Id) is
 704    begin
 705       --  Nothing to do if warnings suppressed
 706
 707       if Warning_Mode = Suppress then
 708          return;
 709       end if;
 710
 711       --  Ignore reference to non-scalar if not from source. Almost always
 712       --  such references are bogus (e.g. calls to init procs to set
 713       --  default discriminant values).
 714
 715       if not Comes_From_Source (N)
 716         and then not Is_Scalar_Type (Etype (N))
 717       then
 718          return;
 719       end if;
 720
 721       --  Otherwise see what kind of node we have. If the entity already
 722       --  has an unset reference, it is not necessarily the earliest in
 723       --  the text, because resolution of the prefix of selected components
 724       --  is completed before the resolution of the selected component itself.
 725       --  as a result, given  (R /= null and then R.X > 0), the occurrences
 726       --  of R are examined in right-to-left order. If there is already an
 727       --  unset reference, we check whether N is earlier before proceeding.
 728
 729       case Nkind (N) is
 730          when N_Identifier | N_Expanded_Name =>
 731             declare
 732                E : constant Entity_Id := Entity (N);
 733
 734             begin
 735                if (Ekind (E) = E_Variable
 736                     or else Ekind (E) = E_Out_Parameter)
 737                  and then Never_Set_In_Source (E)
 738                  and then (No (Unset_Reference (E))
 739                              or else Earlier_In_Extended_Unit
 740                                (Sloc (N),  Sloc (Unset_Reference (E))))
 741                  and then not Warnings_Off (E)
 742                then
 743                   --  We may have an unset reference. The first test is
 744                   --  whether we are accessing a discriminant of a record
 745                   --  or a component with default initialization. Both of
 746                   --  these cases can be ignored, since the actual object
 747                   --  that is referenced is definitely initialized. Note
 748                   --  that this covers the case of reading discriminants
 749                   --  of an out parameter, which is OK even in Ada 83.
 750
 751                   --  Note that we are only interested in a direct reference
 752                   --  to a record component here. If the reference is via an
 753                   --  access type, then the access object is being referenced,
 754                   --  not the record, and still deserves an unset reference.
 755
 756                   if Nkind (Parent (N)) = N_Selected_Component
 757                     and not Is_Access_Type (Etype (N))
 758                   then
 759                      declare
 760                         ES : constant Entity_Id :=
 761                                Entity (Selector_Name (Parent (N)));
 762
 763                      begin
 764                         if Ekind (ES) = E_Discriminant
 765                           or else Present (Expression (Declaration_Node (ES)))
 766                         then
 767                            return;
 768                         end if;
 769                      end;
 770                   end if;
 771
 772                   --  Here we have a potential unset reference. But before we
 773                   --  get worried about it, we have to make sure that the
 774                   --  entity declaration is in the same procedure as the
 775                   --  reference, since if they are in separate procedures,
 776                   --  then we have no idea about sequential execution.
 777
 778                   --  The tests in the loop below catch all such cases, but
 779                   --  do allow the reference to appear in a loop, block, or
 780                   --  package spec that is nested within the declaring scope.
 781                   --  As always, it is possible to construct cases where the
 782                   --  warning is wrong, that is why it is a warning!
 783
 784                   declare
 785                      SR : Entity_Id;
 786                      SE : constant Entity_Id := Scope (E);
 787
 788                   begin
 789                      SR := Current_Scope;
 790                      while SR /= SE loop
 791                         if SR = Standard_Standard
 792                           or else Is_Subprogram (SR)
 793                           or else Is_Concurrent_Body (SR)
 794                           or else Is_Concurrent_Type (SR)
 795                         then
 796                            return;
 797                         end if;
 798
 799                         SR := Scope (SR);
 800                      end loop;
 801
 802                      --  Case of reference has an access type. This is a
 803                      --  special case since access types are always set to
 804                      --  null so cannot be truly uninitialized, but we still
 805                      --  want to warn about cases of obvious null dereference.
 806
 807                      if Is_Access_Type (Etype (N)) then
 808                         declare
 809                            P : Node_Id;
 810
 811                            function Process
 812                              (N    : Node_Id)
 813                               return Traverse_Result;
 814                            --  Process function for instantation of Traverse
 815                            --  below. Checks if N contains reference to E
 816                            --  other than a dereference.
 817
 818                            function Ref_In (Nod : Node_Id) return Boolean;
 819                            --  Determines whether Nod contains a reference
 820                            --  to the entity E that is not a dereference.
 821
 822                            function Process
 823                              (N    : Node_Id)
 824                               return Traverse_Result
 825                            is
 826                            begin
 827                               if Is_Entity_Name (N)
 828                                 and then Entity (N) = E
 829                                 and then not Is_Dereferenced (N)
 830                               then
 831                                  return Abandon;
 832                               else
 833                                  return OK;
 834                               end if;
 835                            end Process;
 836
 837                            function Ref_In (Nod : Node_Id) return Boolean is
 838                               function Traverse is new Traverse_Func (Process);
 839
 840                            begin
 841                               return Traverse (Nod) = Abandon;
 842                            end Ref_In;
 843
 844                         begin
 845                            --  Don't bother if we are inside an instance,
 846                            --  since the compilation of the generic template
 847                            --  is where the warning should be issued.
 848
 849                            if In_Instance then
 850                               return;
 851                            end if;
 852
 853                            --  Don't bother if this is not the main unit.
 854                            --  If we try to give this warning for with'ed
 855                            --  units, we get some false positives, since
 856                            --  we do not record references in other units.
 857
 858                            if not In_Extended_Main_Source_Unit (E)
 859                                 or else
 860                               not In_Extended_Main_Source_Unit (N)
 861                            then
 862                               return;
 863                            end if;
 864
 865                            --  We are only interested in deferences
 866
 867                            if not Is_Dereferenced (N) then
 868                               return;
 869                            end if;
 870
 871                            --  One more check, don't bother with references
 872                            --  that are inside conditional statements or while
 873                            --  loops if the condition references the entity in
 874                            --  question. This avoids most false positives.
 875
 876                            P := Parent (N);
 877                            loop
 878                               P := Parent (P);
 879                               exit when No (P);
 880
 881                               if (Nkind (P) = N_If_Statement
 882                                      or else
 883                                    Nkind (P) = N_Elsif_Part)
 884                                  and then Ref_In (Condition (P))
 885                               then
 886                                  return;
 887
 888                               elsif Nkind (P) = N_Loop_Statement
 889                                 and then Present (Iteration_Scheme (P))
 890                                 and then
 891                                   Ref_In (Condition (Iteration_Scheme (P)))
 892                               then
 893                                  return;
 894                               end if;
 895                            end loop;
 896                         end;
 897                      end if;
 898
 899                      --  Here we definitely have a case for giving a warning
 900                      --  for a reference to an unset value. But we don't give
 901                      --  the warning now. Instead we set the Unset_Reference
 902                      --  field of the identifier involved. The reason for this
 903                      --  is that if we find the variable is never ever assigned
 904                      --  a value then that warning is more important and there
 905                      --  is no point in giving the reference warning.
 906
 907                      --  If this is an identifier, set the field directly
 908
 909                      if Nkind (N) = N_Identifier then
 910                         Set_Unset_Reference (E, N);
 911
 912                      --  Otherwise it is an expanded name, so set the field
 913                      --  of the actual identifier for the reference.
 914
 915                      else
 916                         Set_Unset_Reference (E, Selector_Name (N));
 917                      end if;
 918                   end;
 919                end if;
 920             end;
 921
 922          when N_Indexed_Component | N_Slice =>
 923             Check_Unset_Reference (Prefix (N));
 924
 925          when N_Selected_Component =>
 926
 927             if Present (Entity (Selector_Name (N)))
 928               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 929             then
 930                --   A discriminant is always initialized
 931
 932                null;
 933
 934             else
 935                Check_Unset_Reference (Prefix (N));
 936             end if;
 937
 938          when N_Type_Conversion | N_Qualified_Expression =>
 939             Check_Unset_Reference (Expression (N));
 940
 941          when others =>
 942             null;
 943
 944       end case;
 945    end Check_Unset_Reference;
 946
 947    ------------------------
 948    -- Check_Unused_Withs --
 949    ------------------------
 950
 951    procedure Check_Unused_Withs (Spec_Unit : Unit_Number_Type := No_Unit) is
 952       Cnode : Node_Id;
 953       Item  : Node_Id;
 954       Lunit : Node_Id;
 955       Ent   : Entity_Id;
 956
 957       Munite : constant Entity_Id := Cunit_Entity (Main_Unit);
 958       --  This is needed for checking the special renaming case
 959
 960       procedure Check_One_Unit (Unit : Unit_Number_Type);
 961       --  Subsidiary procedure, performs checks for specified unit
 962
 963       --------------------
 964       -- Check_One_Unit --
 965       --------------------
 966
 967       procedure Check_One_Unit (Unit : Unit_Number_Type) is
 968          Is_Visible_Renaming : Boolean := False;
 969          Pack                : Entity_Id;
 970
 971          procedure Check_Inner_Package (Pack : Entity_Id);
 972          --  Pack is a package local to a unit in a with_clause. Both the
 973          --  unit and Pack are referenced. If none of the entities in Pack
 974          --  are referenced, then the only occurrence of Pack is in a use
 975          --  clause or a pragma, and a warning is worthwhile as well.
 976
 977          function Check_System_Aux return Boolean;
 978          --  Before giving a warning on a with_clause for System, check
 979          --  whether a system extension is present.
 980
 981          function Find_Package_Renaming
 982            (P : Entity_Id;
 983             L : Entity_Id) return Entity_Id;
 984          --  The only reference to a context unit may be in a renaming
 985          --  declaration. If this renaming declares a visible entity, do
 986          --  not warn that the context clause could be moved to the body,
 987          --  because the renaming may be intented to re-export the unit.
 988
 989          -------------------------
 990          -- Check_Inner_Package --
 991          -------------------------
 992
 993          procedure Check_Inner_Package (Pack : Entity_Id) is
 994             E  : Entity_Id;
 995             Un : constant Node_Id := Sinfo.Unit (Cnode);
 996
 997             function Check_Use_Clause (N : Node_Id) return Traverse_Result;
 998             --  If N is a use_clause for Pack, emit warning.
 999
1000             procedure Check_Use_Clauses is new
1001               Traverse_Proc (Check_Use_Clause);
1002
1003             ----------------------
1004             -- Check_Use_Clause --
1005             ----------------------
1006
1007             function Check_Use_Clause (N : Node_Id) return Traverse_Result is
1008                Nam  : Node_Id;
1009
1010             begin
1011                if Nkind (N) = N_Use_Package_Clause then
1012                   Nam := First (Names (N));
1013
1014                   while Present (Nam) loop
1015                      if Entity (Nam) = Pack then
1016                         Error_Msg_Qual_Level := 1;
1017                         Error_Msg_NE
1018                           ("no entities of package& are referenced?",
1019                              Nam, Pack);
1020                         Error_Msg_Qual_Level := 0;
1021                      end if;
1022
1023                      Next (Nam);
1024                   end loop;
1025                end if;
1026
1027                return OK;
1028             end Check_Use_Clause;
1029
1030          --  Start of processing for Check_Inner_Package
1031
1032          begin
1033             E := First_Entity (Pack);
1034
1035             while Present (E) loop
1036                if Referenced (E) then
1037                   return;
1038                end if;
1039
1040                Next_Entity (E);
1041             end loop;
1042
1043             --  No entities of the package are referenced. Check whether
1044             --  the reference to the package itself is a use clause, and
1045             --  if so place a warning on it.
1046
1047             Check_Use_Clauses (Un);
1048          end Check_Inner_Package;
1049
1050          ----------------------
1051          -- Check_System_Aux --
1052          ----------------------
1053
1054          function Check_System_Aux return Boolean is
1055             Ent : Entity_Id;
1056
1057          begin
1058             if Chars (Lunit) = Name_System
1059                and then Scope (Lunit) = Standard_Standard
1060                and then Present_System_Aux
1061             then
1062                Ent := First_Entity (System_Aux_Id);
1063
1064                while Present (Ent) loop
1065                   if Referenced (Ent) then
1066                      return True;
1067                   end if;
1068
1069                   Next_Entity (Ent);
1070                end loop;
1071             end if;
1072
1073             return False;
1074          end Check_System_Aux;
1075
1076          ---------------------------
1077          -- Find_Package_Renaming --
1078          ---------------------------
1079
1080          function Find_Package_Renaming
1081            (P : Entity_Id;
1082             L : Entity_Id) return Entity_Id
1083          is
1084             E1 : Entity_Id;
1085             R  : Entity_Id;
1086
1087          begin
1088             Is_Visible_Renaming := False;
1089             E1 := First_Entity (P);
1090
1091             while Present (E1) loop
1092                if Ekind (E1) = E_Package
1093                   and then Renamed_Object (E1) = L
1094                then
1095                   Is_Visible_Renaming := not Is_Hidden (E1);
1096                   return E1;
1097
1098                elsif Ekind (E1) = E_Package
1099                  and then No (Renamed_Object (E1))
1100                  and then not Is_Generic_Instance (E1)
1101                then
1102                   R := Find_Package_Renaming (E1, L);
1103
1104                   if Present (R) then
1105                      Is_Visible_Renaming := not Is_Hidden (R);
1106                      return R;
1107                   end if;
1108                end if;
1109
1110                Next_Entity (E1);
1111             end loop;
1112
1113             return Empty;
1114          end Find_Package_Renaming;
1115
1116       --  Start of processing for Check_One_Unit
1117
1118       begin
1119          Cnode := Cunit (Unit);
1120
1121          --  Only do check in units that are part of the extended main
1122          --  unit. This is actually a necessary restriction, because in
1123          --  the case of subprogram acting as its own specification,
1124          --  there can be with's in subunits that we will not see.
1125
1126          if not In_Extended_Main_Source_Unit (Cnode) then
1127             return;
1128
1129          --  In configurable run time mode, we remove the bodies of
1130          --  non-inlined subprograms, which may lead to spurious warnings,
1131          --  which are clearly undesirable.
1132
1133          elsif Configurable_Run_Time_Mode
1134            and then Is_Predefined_File_Name (Unit_File_Name (Unit))
1135          then
1136             return;
1137          end if;
1138
1139          --  Loop through context items in this unit
1140
1141          Item := First (Context_Items (Cnode));
1142          while Present (Item) loop
1143             if Nkind (Item) = N_With_Clause
1144                and then not Implicit_With (Item)
1145                and then In_Extended_Main_Source_Unit (Item)
1146             then
1147                Lunit := Entity (Name (Item));
1148
1149                --  Check if this unit is referenced
1150
1151                if not Referenced (Lunit) then
1152
1153                   --  Suppress warnings in internal units if not in -gnatg
1154                   --  mode (these would be junk warnings for an applications
1155                   --  program, since they refer to problems in internal units)
1156
1157                   if GNAT_Mode
1158                     or else not Is_Internal_File_Name (Unit_File_Name (Unit))
1159                   then
1160                      --  Here we definitely have a non-referenced unit. If
1161                      --  it is the special call for a spec unit, then just
1162                      --  set the flag to be read later.
1163
1164                      if Unit = Spec_Unit then
1165                         Set_Unreferenced_In_Spec (Item);
1166
1167                      --  Otherwise simple unreferenced message
1168
1169                      else
1170                         Error_Msg_N
1171                           ("unit& is not referenced?", Name (Item));
1172                      end if;
1173                   end if;
1174
1175                --  If main unit is a renaming of this unit, then we consider
1176                --  the with to be OK (obviously it is needed in this case!)
1177
1178                elsif Present (Renamed_Entity (Munite))
1179                   and then Renamed_Entity (Munite) = Lunit
1180                then
1181                   null;
1182
1183                --  If this unit is referenced, and it is a package, we
1184                --  do another test, to see if any of the entities in the
1185                --  package are referenced. If none of the entities are
1186                --  referenced, we still post a warning. This occurs if
1187                --  the only use of the package is in a use clause, or
1188                --  in a package renaming declaration.
1189
1190                elsif Ekind (Lunit) = E_Package then
1191
1192                   --  If Is_Instantiated is set, it means that the package
1193                   --  is implicitly instantiated (this is the case of a
1194                   --  parent instance or an actual for a generic package
1195                   --  formal), and this counts as a reference.
1196
1197                   if Is_Instantiated (Lunit) then
1198                      null;
1199
1200                   --  If no entities in package, and there is a pragma
1201                   --  Elaborate_Body present, then assume that this with
1202                   --  is done for purposes of this elaboration.
1203
1204                   elsif No (First_Entity (Lunit))
1205                     and then Has_Pragma_Elaborate_Body (Lunit)
1206                   then
1207                      null;
1208
1209                   --  Otherwise see if any entities have been referenced
1210
1211                   else
1212                      Ent := First_Entity (Lunit);
1213                      loop
1214                         --  No more entities, and we did not find one
1215                         --  that was referenced. Means we have a definite
1216                         --  case of a with none of whose entities was
1217                         --  referenced.
1218
1219                         if No (Ent) then
1220
1221                            --  If in spec, just set the flag
1222
1223                            if Unit = Spec_Unit then
1224                               Set_No_Entities_Ref_In_Spec (Item);
1225
1226                            elsif Check_System_Aux then
1227                               null;
1228
1229                            --  Else give the warning
1230
1231                            else
1232                               Error_Msg_N
1233                                 ("no entities of & are referenced?",
1234                                  Name (Item));
1235
1236                               --  Look for renamings of this package, and
1237                               --  flag them as well. If the original package
1238                               --  has warnings off, we suppress the warning
1239                               --  on the renaming as well.
1240
1241                               Pack := Find_Package_Renaming (Munite, Lunit);
1242
1243                               if Present (Pack)
1244                                 and then not Warnings_Off (Lunit)
1245                               then
1246                                  Error_Msg_NE
1247                                    ("no entities of & are referenced?",
1248                                      Unit_Declaration_Node (Pack),
1249                                        Pack);
1250                               end if;
1251                            end if;
1252
1253                            exit;
1254
1255                         --  Case of next entity is referenced
1256
1257                         elsif Referenced (Ent)
1258                           or else Referenced_As_LHS (Ent)
1259                         then
1260                            --  This means that the with is indeed fine, in
1261                            --  that it is definitely needed somewhere, and
1262                            --  we can quite worrying about this one.
1263
1264                            --  Except for one little detail, if either of
1265                            --  the flags was set during spec processing,
1266                            --  this is where we complain that the with
1267                            --  could be moved from the spec. If the spec
1268                            --  contains a visible renaming of the package,
1269                            --  inhibit warning to move with_clause to body.
1270
1271                            if Ekind (Munite) = E_Package_Body then
1272                               Pack :=
1273                                 Find_Package_Renaming
1274                                   (Spec_Entity (Munite), Lunit);
1275                            end if;
1276
1277                            if Unreferenced_In_Spec (Item) then
1278                               Error_Msg_N
1279                                 ("unit& is not referenced in spec?",
1280                                  Name (Item));
1281
1282                            elsif No_Entities_Ref_In_Spec (Item) then
1283                               Error_Msg_N
1284                                 ("no entities of & are referenced in spec?",
1285                                  Name (Item));
1286
1287                            else
1288                               if Ekind (Ent) = E_Package then
1289                                  Check_Inner_Package (Ent);
1290                               end if;
1291
1292                               exit;
1293                            end if;
1294
1295                            if not Is_Visible_Renaming then
1296                               Error_Msg_N
1297                                 ("\with clause might be moved to body?",
1298                                  Name (Item));
1299                            end if;
1300
1301                            exit;
1302
1303                         --  Move to next entity to continue search
1304
1305                         else
1306                            Next_Entity (Ent);
1307                         end if;
1308                      end loop;
1309                   end if;
1310
1311                --  For a generic package, the only interesting kind of
1312                --  reference is an instantiation, since entities cannot
1313                --  be referenced directly.
1314
1315                elsif Is_Generic_Unit (Lunit) then
1316
1317                   --  Unit was never instantiated, set flag for case of spec
1318                   --  call, or give warning for normal call.
1319
1320                   if not Is_Instantiated (Lunit) then
1321                      if Unit = Spec_Unit then
1322                         Set_Unreferenced_In_Spec (Item);
1323                      else
1324                         Error_Msg_N
1325                           ("unit& is never instantiated?", Name (Item));
1326                      end if;
1327
1328                   --  If unit was indeed instantiated, make sure that
1329                   --  flag is not set showing it was uninstantiated in
1330                   --  the spec, and if so, give warning.
1331
1332                   elsif Unreferenced_In_Spec (Item) then
1333                      Error_Msg_N
1334                        ("unit& is not instantiated in spec?", Name (Item));
1335                      Error_Msg_N
1336                        ("\with clause can be moved to body?", Name (Item));
1337                   end if;
1338                end if;
1339             end if;
1340
1341             Next (Item);
1342          end loop;
1343
1344       end Check_One_Unit;
1345
1346    --  Start of processing for Check_Unused_Withs
1347
1348    begin
1349       if not Opt.Check_Withs
1350         or else Operating_Mode = Check_Syntax
1351       then
1352          return;
1353       end if;
1354
1355       --  Flag any unused with clauses, but skip this step if we are
1356       --  compiling a subunit on its own, since we do not have enough
1357       --  information to determine whether with's are used. We will get
1358       --  the relevant warnings when we compile the parent. This is the
1359       --  normal style of GNAT compilation in any case.
1360
1361       if Nkind (Unit (Cunit (Main_Unit))) = N_Subunit then
1362          return;
1363       end if;
1364
1365       --  Process specified units
1366
1367       if Spec_Unit = No_Unit then
1368
1369          --  For main call, check all units
1370
1371          for Unit in Main_Unit .. Last_Unit loop
1372             Check_One_Unit (Unit);
1373          end loop;
1374
1375       else
1376          --  For call for spec, check only the spec
1377
1378          Check_One_Unit (Spec_Unit);
1379       end if;
1380    end Check_Unused_Withs;
1381
1382    ---------------------------------
1383    -- Generic_Package_Spec_Entity --
1384    ---------------------------------
1385
1386    function Generic_Package_Spec_Entity (E : Entity_Id) return Boolean is
1387       S : Entity_Id;
1388
1389    begin
1390       if Is_Package_Body_Entity (E) then
1391          return False;
1392
1393       else
1394          S := Scope (E);
1395
1396          loop
1397             if S = Standard_Standard then
1398                return False;
1399
1400             elsif Ekind (S) = E_Generic_Package then
1401                return True;
1402
1403             elsif Ekind (S) = E_Package then
1404                S := Scope (S);
1405
1406             else
1407                return False;
1408             end if;
1409          end loop;
1410       end if;
1411    end Generic_Package_Spec_Entity;
1412
1413    -------------------------------------
1414    -- Operand_Has_Warnings_Suppressed --
1415    -------------------------------------
1416
1417    function Operand_Has_Warnings_Suppressed (N : Node_Id) return Boolean is
1418
1419       function Check_For_Warnings (N : Node_Id) return Traverse_Result;
1420       --  Function used to check one node to see if it is or was originally
1421       --  a reference to an entity for which Warnings are off. If so, Abandon
1422       --  is returned, otherwise OK_Orig is returned to continue the traversal
1423       --  of the original expression.
1424
1425       function Traverse is new Traverse_Func (Check_For_Warnings);
1426       --  Function used to traverse tree looking for warnings
1427
1428       ------------------------
1429       -- Check_For_Warnings --
1430       ------------------------
1431
1432       function Check_For_Warnings (N : Node_Id) return Traverse_Result is
1433          R : constant Node_Id := Original_Node (N);
1434
1435       begin
1436          if Nkind (R) in N_Has_Entity
1437            and then Present (Entity (R))
1438            and then Warnings_Off (Entity (R))
1439          then
1440             return Abandon;
1441          else
1442             return OK_Orig;
1443          end if;
1444       end Check_For_Warnings;
1445
1446    --  Start of processing for Operand_Has_Warnings_Suppressed
1447
1448    begin
1449       return Traverse (N) = Abandon;
1450
1451    --  If any exception occurs, then something has gone wrong, and this is
1452    --  only a minor aesthetic issue anyway, so just say we did not find what
1453    --  we are looking for, rather than blow up.
1454
1455    exception
1456       when others =>
1457          return False;
1458    end Operand_Has_Warnings_Suppressed;
1459
1460    ----------------------------------
1461    -- Output_Unreferenced_Messages --
1462    ----------------------------------
1463
1464    procedure Output_Unreferenced_Messages is
1465       E : Entity_Id;
1466
1467    begin
1468       for J in Unreferenced_Entities.First ..
1469                Unreferenced_Entities.Last
1470       loop
1471          E := Unreferenced_Entities.Table (J);
1472
1473          if not Referenced (E) and then not Warnings_Off (E) then
1474             case Ekind (E) is
1475                when E_Variable =>
1476
1477                   --  Case of variable that is assigned but not read. We
1478                   --  suppress the message if the variable is volatile,
1479                   --  has an address clause, or is imported.
1480
1481                   if Referenced_As_LHS (E)
1482                     and then No (Address_Clause (E))
1483                     and then not Is_Volatile (E)
1484                   then
1485                      if Warn_On_Modified_Unread
1486                        and then not Is_Imported (E)
1487                      then
1488                         Error_Msg_N
1489                           ("variable & is assigned but never read?", E);
1490                      end if;
1491
1492                   --  Normal case of neither assigned nor read
1493
1494                   else
1495                      if Present (Renamed_Object (E))
1496                        and then Comes_From_Source (Renamed_Object (E))
1497                      then
1498                         Error_Msg_N
1499                           ("renamed variable & is not referenced?", E);
1500                      else
1501                         Error_Msg_N
1502                           ("variable & is not referenced?", E);
1503                      end if;
1504                   end if;
1505
1506                when E_Constant =>
1507                   if Present (Renamed_Object (E))
1508                     and then Comes_From_Source (Renamed_Object (E))
1509                   then
1510                      Error_Msg_N ("renamed constant & is not referenced?", E);
1511                   else
1512                      Error_Msg_N ("constant & is not referenced?", E);
1513                   end if;
1514
1515                when E_In_Parameter     |
1516                     E_Out_Parameter    |
1517                     E_In_Out_Parameter =>
1518
1519                   --  Do not emit message for formals of a renaming, because
1520                   --  they are never referenced explicitly.
1521
1522                   if Nkind (Original_Node (Unit_Declaration_Node (Scope (E))))
1523                     /= N_Subprogram_Renaming_Declaration
1524                   then
1525                      Error_Msg_N ("formal parameter & is not referenced?", E);
1526                   end if;
1527
1528                when E_Named_Integer    |
1529                     E_Named_Real       =>
1530                   Error_Msg_N ("named number & is not referenced?", E);
1531
1532                when E_Enumeration_Literal =>
1533                   Error_Msg_N ("literal & is not referenced?", E);
1534
1535                when E_Function         =>
1536                   Error_Msg_N ("function & is not referenced?", E);
1537
1538                when E_Procedure         =>
1539                   Error_Msg_N ("procedure & is not referenced?", E);
1540
1541                when E_Generic_Procedure =>
1542                   Error_Msg_N
1543                     ("generic procedure & is never instantiated?", E);
1544
1545                when E_Generic_Function  =>
1546                   Error_Msg_N ("generic function & is never instantiated?", E);
1547
1548                when Type_Kind          =>
1549                   Error_Msg_N ("type & is not referenced?", E);
1550
1551                when others =>
1552                   Error_Msg_N ("& is not referenced?", E);
1553             end case;
1554
1555             Set_Warnings_Off (E);
1556          end if;
1557       end loop;
1558    end Output_Unreferenced_Messages;
1559
1560    -----------------------------
1561    -- Warn_On_Known_Condition --
1562    -----------------------------
1563
1564    procedure Warn_On_Known_Condition (C : Node_Id) is
1565       P : Node_Id;
1566
1567    begin
1568       --   Argument replacement in an inlined body can make conditions
1569       --   static. Do not emit warnings in this case.
1570
1571       if In_Inlined_Body then
1572          return;
1573       end if;
1574
1575       if Constant_Condition_Warnings
1576         and then Nkind (C) = N_Identifier
1577         and then
1578           (Entity (C) = Standard_False or else Entity (C) = Standard_True)
1579         and then Comes_From_Source (Original_Node (C))
1580         and then not In_Instance
1581       then
1582          --  See if this is in a statement or a declaration
1583
1584          P := Parent (C);
1585          loop
1586             --  If tree is not attached, do not issue warning (this is very
1587             --  peculiar, and probably arises from some other error condition)
1588
1589             if No (P) then
1590                return;
1591
1592             --  If we are in a declaration, then no warning, since in practice
1593             --  conditionals in declarations are used for intended tests which
1594             --  may be known at compile time, e.g. things like
1595
1596             --    x : constant Integer := 2 + (Word'Size = 32);
1597
1598             --  And a warning is annoying in such cases
1599
1600             elsif Nkind (P) in N_Declaration
1601                     or else
1602                   Nkind (P) in N_Later_Decl_Item
1603             then
1604                return;
1605
1606             --  Don't warn in assert pragma, since presumably tests in such
1607             --  a context are very definitely intended, and might well be
1608             --  known at compile time. Note that we have to test the original
1609             --  node, since assert pragmas get rewritten at analysis time.
1610
1611             elsif Nkind (Original_Node (P)) = N_Pragma
1612               and then Chars (Original_Node (P)) = Name_Assert
1613             then
1614                return;
1615             end if;
1616
1617             exit when Is_Statement (P);
1618             P := Parent (P);
1619          end loop;
1620
1621          --  Here we issue the warning unless some sub-operand has warnings
1622          --  set off, in which case we suppress the warning for the node.
1623
1624          if not Operand_Has_Warnings_Suppressed (C) then
1625             if Entity (C) = Standard_True then
1626                Error_Msg_N ("condition is always True?", C);
1627             else
1628                Error_Msg_N ("condition is always False?", C);
1629             end if;
1630          end if;
1631       end if;
1632    end Warn_On_Known_Condition;
1633
1634 end Sem_Warn;