gcc/ada/sem_warn.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ W A R N                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1999-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Alloc;
  27 with Atree;    use Atree;
  28 with Debug;    use Debug;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Exp_Code; use Exp_Code;
  32 with Fname;    use Fname;
  33 with Lib;      use Lib;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Opt;      use Opt;
  37 with Rtsfind;  use Rtsfind;
  38 with Sem;      use Sem;
  39 with Sem_Ch8;  use Sem_Ch8;
  40 with Sem_Eval; use Sem_Eval;
  41 with Sem_Util; use Sem_Util;
  42 with Sinfo;    use Sinfo;
  43 with Sinput;   use Sinput;
  44 with Snames;   use Snames;
  45 with Stand;    use Stand;
  46 with Stringt;  use Stringt;
  47 with Table;
  48 with Uintp;    use Uintp;
  49
  50 package body Sem_Warn is
  51
  52    --  The following table collects Id's of entities that are potentially
  53    --  unreferenced. See Check_Unset_Reference for further details.
  54    --  ??? Check_Unset_Reference has zero information about this table.
  55
  56    package Unreferenced_Entities is new Table.Table (
  57      Table_Component_Type => Entity_Id,
  58      Table_Index_Type     => Nat,
  59      Table_Low_Bound      => 1,
  60      Table_Initial        => Alloc.Unreferenced_Entities_Initial,
  61      Table_Increment      => Alloc.Unreferenced_Entities_Increment,
  62      Table_Name           => "Unreferenced_Entities");
  63
  64    package In_Out_Warnings is new Table.Table (
  65      Table_Component_Type => Entity_Id,
  66      Table_Index_Type     => Nat,
  67      Table_Low_Bound      => 1,
  68      Table_Initial        => Alloc.In_Out_Warnings_Initial,
  69      Table_Increment      => Alloc.In_Out_Warnings_Increment,
  70      Table_Name           => "In_Out_Warnings");
  71
  72    -----------------------
  73    -- Local Subprograms --
  74    -----------------------
  75
  76    function Generic_Package_Spec_Entity (E : Entity_Id) return Boolean;
  77    --  This returns true if the entity E is declared within a generic package.
  78    --  The point of this is to detect variables which are not assigned within
  79    --  the generic, but might be assigned outside the package for any given
  80    --  instance. These are cases where we leave the warnings to be posted for
  81    --  the instance, when we will know more.
  82
  83    function Goto_Spec_Entity (E : Entity_Id) return Entity_Id;
  84    --  If E is a parameter entity for a subprogram body, then this function
  85    --  returns the corresponding spec entity, if not, E is returned unchanged.
  86
  87    function Has_Pragma_Unreferenced_Check_Spec (E : Entity_Id) return Boolean;
  88    --  Tests Has_Pragma_Unreferenced flag for entity E. If E is not a formal,
  89    --  this is simply the setting of the flag Has_Pragma_Unreferenced. If E is
  90    --  a body formal, the setting of the flag in the corresponding spec is
  91    --  also checked (and True returned if either flag is True).
  92
  93    function Never_Set_In_Source_Check_Spec (E : Entity_Id) return Boolean;
  94    --  Tests Never_Set_In_Source status for entity E. If E is not a formal,
  95    --  this is simply the setting of the flag Never_Set_In_Source. If E is
  96    --  a body formal, the setting of the flag in the corresponding spec is
  97    --  also checked (and False returned if either flag is False).
  98
  99    function Operand_Has_Warnings_Suppressed (N : Node_Id) return Boolean;
 100    --  This function traverses the expression tree represented by the node N
 101    --  and determines if any sub-operand is a reference to an entity for which
 102    --  the Warnings_Off flag is set. True is returned if such an entity is
 103    --  encountered, and False otherwise.
 104
 105    function Referenced_Check_Spec (E : Entity_Id) return Boolean;
 106    --  Tests Referenced status for entity E. If E is not a formal, this is
 107    --  simply the setting of the flag Referenced. If E is a body formal, the
 108    --  setting of the flag in the corresponding spec is also checked (and True
 109    --  returned if either flag is True).
 110
 111    function Referenced_As_LHS_Check_Spec (E : Entity_Id) return Boolean;
 112    --  Tests Referenced_As_LHS status for entity E. If E is not a formal, this
 113    --  is simply the setting of the flag Referenced_As_LHS. If E is a body
 114    --  formal, the setting of the flag in the corresponding spec is also
 115    --  checked (and True returned if either flag is True).
 116
 117    procedure Warn_On_Unreferenced_Entity
 118      (Spec_E : Entity_Id;
 119       Body_E : Entity_Id := Empty);
 120    --  Output warnings for unreferenced entity E. For the case of an entry
 121    --  formal, Body_E is the corresponding body entity for a particular
 122    --  accept statement, and the message is posted on Body_E. In all other
 123    --  cases, Body_E is ignored and must be Empty.
 124
 125    --------------------------
 126    -- Check_Code_Statement --
 127    --------------------------
 128
 129    procedure Check_Code_Statement (N : Node_Id) is
 130    begin
 131       --  If volatile, nothing to worry about
 132
 133       if Is_Asm_Volatile (N) then
 134          return;
 135       end if;
 136
 137       --  Warn if no input or no output
 138
 139       Setup_Asm_Inputs (N);
 140
 141       if No (Asm_Input_Value) then
 142          Error_Msg_F
 143            ("?code statement with no inputs should usually be Volatile!", N);
 144          return;
 145       end if;
 146
 147       Setup_Asm_Outputs (N);
 148
 149       if No (Asm_Output_Variable) then
 150          Error_Msg_F
 151            ("?code statement with no outputs should usually be Volatile!", N);
 152          return;
 153       end if;
 154
 155       --  Check multiple code statements in a row
 156
 157       if Is_List_Member (N)
 158         and then Present (Prev (N))
 159         and then Nkind (Prev (N)) = N_Code_Statement
 160       then
 161          Error_Msg_F
 162            ("?code statements in sequence should usually be Volatile!", N);
 163          Error_Msg_F
 164            ("\?(suggest using template with multiple instructions)!", N);
 165       end if;
 166    end Check_Code_Statement;
 167
 168    ---------------------------------
 169    -- Check_Infinite_Loop_Warning --
 170    ---------------------------------
 171
 172    --  The case we look for is a while loop which tests a local variable, where
 173    --  there is no obvious direct or possible indirect update of the variable
 174    --  within the body of the loop.
 175
 176    procedure Check_Infinite_Loop_Warning (Loop_Statement : Node_Id) is
 177       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
 178
 179       Ref : Node_Id := Empty;
 180       --  Reference in iteration scheme to variable that may not be modified in
 181       --  loop, indicating a possible infinite loop.
 182
 183       Var : Entity_Id := Empty;
 184       --  Corresponding entity (entity of Ref)
 185
 186       procedure Find_Var (N : Node_Id);
 187       --  Inspect condition to see if it depends on a single entity reference.
 188       --  If so, Ref is set to point to the reference node, and Var is set to
 189       --  the referenced Entity.
 190
 191       function Has_Indirection (T : Entity_Id) return Boolean;
 192       --  If the controlling variable is an access type, or is a record type
 193       --  with access components, assume that it is changed indirectly and
 194       --  suppress the warning. As a concession to low-level programming, in
 195       --  particular within Declib, we also suppress warnings on a record
 196       --  type that contains components of type Address or Short_Address.
 197
 198       function Is_Suspicious_Function_Name (E : Entity_Id) return Boolean;
 199       --  Given an entity name, see if the name appears to have something to
 200       --  do with I/O or network stuff, and if so, return True. Used to kill
 201       --  some false positives on a heuristic basis that such functions will
 202       --  likely have some strange side effect dependencies. A rather funny
 203       --  kludge, but warning messages are in the heuristics business.
 204
 205       function Test_Ref (N : Node_Id) return Traverse_Result;
 206       --  Test for reference to variable in question. Returns Abandon if
 207       --  matching reference found.
 208
 209       function Find_Ref is new Traverse_Func (Test_Ref);
 210       --  Function to traverse body of procedure. Returns Abandon if matching
 211       --  reference found.
 212
 213       --------------
 214       -- Find_Var --
 215       --------------
 216
 217       procedure Find_Var (N : Node_Id) is
 218       begin
 219          --  Condition is a direct variable reference
 220
 221          if Is_Entity_Name (N) then
 222             Ref := N;
 223             Var := Entity (Ref);
 224
 225             --  Case of condition is a comparison with compile time known value
 226
 227          elsif Nkind (N) in N_Op_Compare then
 228             if Compile_Time_Known_Value (Right_Opnd (N)) then
 229                Find_Var (Left_Opnd (N));
 230
 231             elsif Compile_Time_Known_Value (Left_Opnd (N)) then
 232                Find_Var (Right_Opnd (N));
 233
 234             --  Ignore any other comparison
 235
 236             else
 237                return;
 238             end if;
 239
 240             --  If condition is a negation, check its operand
 241
 242          elsif Nkind (N) = N_Op_Not then
 243             Find_Var (Right_Opnd (N));
 244
 245             --  Case of condition is function call
 246
 247          elsif Nkind (N) = N_Function_Call then
 248
 249             --  Forget it if function name is not entity, who knows what
 250             --  we might be calling?
 251
 252             if not Is_Entity_Name (Name (N)) then
 253                return;
 254
 255                --  Forget it if warnings are suppressed on function entity
 256
 257             elsif Warnings_Off (Entity (Name (N))) then
 258                return;
 259
 260                --  Forget it if function name is suspicious. A strange test
 261                --  but warning generation is in the heuristics business!
 262
 263             elsif Is_Suspicious_Function_Name (Entity (Name (N))) then
 264                return;
 265             end if;
 266
 267             --  OK, see if we have one argument
 268
 269             declare
 270                PA : constant List_Id := Parameter_Associations (N);
 271
 272             begin
 273                --  One argument, so check the argument
 274
 275                if Present (PA)
 276                  and then List_Length (PA) = 1
 277                then
 278                   if Nkind (First (PA)) = N_Parameter_Association then
 279                      Find_Var (Explicit_Actual_Parameter (First (PA)));
 280                   else
 281                      Find_Var (First (PA));
 282                   end if;
 283
 284                   --  Not one argument
 285
 286                else
 287                   return;
 288                end if;
 289             end;
 290
 291             --  Any other kind of node is not something we warn for
 292
 293          else
 294             return;
 295          end if;
 296       end Find_Var;
 297
 298       ---------------------
 299       -- Has_Indirection --
 300       ---------------------
 301
 302       function Has_Indirection (T : Entity_Id) return Boolean is
 303          Comp : Entity_Id;
 304          Rec  : Entity_Id;
 305
 306       begin
 307          if Is_Access_Type (T) then
 308             return True;
 309
 310          elsif Is_Private_Type (T)
 311            and then Present (Full_View (T))
 312            and then Is_Access_Type (Full_View (T))
 313          then
 314             return True;
 315
 316          elsif Is_Record_Type (T) then
 317             Rec := T;
 318
 319          elsif Is_Private_Type (T)
 320            and then Present (Full_View (T))
 321            and then Is_Record_Type (Full_View (T))
 322          then
 323             Rec := Full_View (T);
 324          else
 325             return False;
 326          end if;
 327
 328          Comp := First_Component (Rec);
 329          while Present (Comp) loop
 330             if Is_Access_Type (Etype (Comp))
 331               or else Is_Descendent_Of_Address (Etype (Comp))
 332             then
 333                return True;
 334             end if;
 335
 336             Next_Component (Comp);
 337          end loop;
 338
 339          return False;
 340       end Has_Indirection;
 341
 342       ---------------------------------
 343       -- Is_Suspicious_Function_Name --
 344       ---------------------------------
 345
 346       function Is_Suspicious_Function_Name (E : Entity_Id) return Boolean is
 347          S : Entity_Id;
 348
 349          function Substring_Present (S : String) return Boolean;
 350          --  Returns True if name buffer has given string delimited by non-
 351          --  alphabetic characters or by end of string. S is lower case.
 352
 353          -----------------------
 354          -- Substring_Present --
 355          -----------------------
 356
 357          function Substring_Present (S : String) return Boolean is
 358             Len : constant Natural := S'Length;
 359
 360          begin
 361             for J in 1 .. Name_Len - (Len - 1) loop
 362                if Name_Buffer (J .. J + (Len - 1)) = S
 363                  and then
 364                    (J = 1
 365                      or else Name_Buffer (J - 1) not in 'a' .. 'z')
 366                  and then
 367                    (J + Len > Name_Len
 368                      or else Name_Buffer (J + Len) not in 'a' .. 'z')
 369                then
 370                   return True;
 371                end if;
 372             end loop;
 373
 374             return False;
 375          end Substring_Present;
 376
 377          --  Start of processing for Is_Suspicious_Function_Name
 378
 379       begin
 380          S := E;
 381          while Present (S) and then S /= Standard_Standard loop
 382             Get_Name_String (Chars (S));
 383
 384             if Substring_Present ("io")
 385               or else Substring_Present ("file")
 386               or else Substring_Present ("network")
 387             then
 388                return True;
 389             else
 390                S := Scope (S);
 391             end if;
 392          end loop;
 393
 394          return False;
 395       end Is_Suspicious_Function_Name;
 396
 397       --------------
 398       -- Test_Ref --
 399       --------------
 400
 401       function Test_Ref (N : Node_Id) return Traverse_Result is
 402       begin
 403          --  Waste of time to look at iteration scheme
 404
 405          if N = Iter then
 406             return Skip;
 407
 408             --  Direct reference to variable in question
 409
 410          elsif Is_Entity_Name (N)
 411            and then Present (Entity (N))
 412            and then Entity (N) = Var
 413          then
 414             --  If this is an Lvalue, then definitely abandon, since
 415             --  this could be a direct modification of the variable.
 416
 417             if May_Be_Lvalue (N) then
 418                return Abandon;
 419             end if;
 420
 421             --  If we appear in the context of a procedure call, then also
 422             --  abandon, since there may be issues of non-visible side
 423             --  effects going on in the call.
 424
 425             declare
 426                P : Node_Id;
 427             begin
 428                P := N;
 429                loop
 430                   P := Parent (P);
 431                   exit when P = Loop_Statement;
 432
 433                   if Nkind (P) = N_Procedure_Call_Statement then
 434                      return Abandon;
 435                   end if;
 436                end loop;
 437             end;
 438
 439             --  Reference to variable renaming variable in question
 440
 441          elsif Is_Entity_Name (N)
 442            and then Present (Entity (N))
 443            and then Ekind (Entity (N)) = E_Variable
 444            and then Present (Renamed_Object (Entity (N)))
 445            and then Is_Entity_Name (Renamed_Object (Entity (N)))
 446            and then Entity (Renamed_Object (Entity (N))) = Var
 447            and then May_Be_Lvalue (N)
 448          then
 449             return Abandon;
 450
 451             --  Call to subprogram
 452
 453          elsif Nkind (N) = N_Procedure_Call_Statement
 454            or else Nkind (N) = N_Function_Call
 455          then
 456             --  If subprogram is within the scope of the entity we are dealing
 457             --  with as the loop variable, then it could modify this parameter,
 458             --  so we abandon in this case. In the case of a subprogram that is
 459             --  not an entity we also abandon. The check for no entity being
 460             --  present is a defense against previous errors.
 461
 462             if not Is_Entity_Name (Name (N))
 463               or else No (Entity (Name (N)))
 464               or else Scope_Within (Entity (Name (N)), Scope (Var))
 465             then
 466                return Abandon;
 467             end if;
 468          end if;
 469
 470          --  All OK, continue scan
 471
 472          return OK;
 473       end Test_Ref;
 474
 475    --  Start of processing for Check_Infinite_Loop_Warning
 476
 477    begin
 478       --  We need a while iteration with no condition actions. Conditions
 479       --  actions just make things too complicated to get the warning right.
 480
 481       if No (Iter)
 482         or else No (Condition (Iter))
 483         or else Present (Condition_Actions (Iter))
 484         or else Debug_Flag_Dot_W
 485       then
 486          return;
 487       end if;
 488
 489       --  Initial conditions met, see if condition is of right form
 490
 491       Find_Var (Condition (Iter));
 492
 493       --  Nothing to do if local variable from source not found
 494
 495       if No (Var)
 496         or else Ekind (Var) /= E_Variable
 497         or else Is_Library_Level_Entity (Var)
 498         or else not Comes_From_Source (Var)
 499       then
 500          return;
 501
 502       --  Nothing to do if there is some indirection involved (assume that the
 503       --  designated variable might be modified in some way we don't see).
 504
 505       elsif Has_Indirection (Etype (Var)) then
 506          return;
 507
 508       --  Same sort of thing for volatile variable, might be modified by
 509       --  some other task or by the operating system in some way.
 510
 511       elsif Is_Volatile (Var) then
 512          return;
 513       end if;
 514
 515       --  Filter out case of original statement sequence starting with delay.
 516       --  We assume this is a multi-tasking program and that the condition
 517       --  is affected by other threads (some kind of busy wait).
 518
 519       declare
 520          Fstm : constant Node_Id :=
 521                   Original_Node (First (Statements (Loop_Statement)));
 522       begin
 523          if Nkind (Fstm) = N_Delay_Relative_Statement
 524            or else Nkind (Fstm) = N_Delay_Until_Statement
 525          then
 526             return;
 527          end if;
 528       end;
 529
 530       --  We have a variable reference of the right form, now we scan the loop
 531       --  body to see if it looks like it might not be modified
 532
 533       if Find_Ref (Loop_Statement) = OK then
 534          Error_Msg_NE
 535            ("?variable& is not modified in loop body!", Ref, Var);
 536          Error_Msg_N
 537            ("\?possible infinite loop!", Ref);
 538       end if;
 539    end Check_Infinite_Loop_Warning;
 540
 541    ----------------------
 542    -- Check_References --
 543    ----------------------
 544
 545    procedure Check_References (E : Entity_Id; Anod : Node_Id := Empty) is
 546       E1 : Entity_Id;
 547       UR : Node_Id;
 548
 549       function Body_Formal
 550         (E                : Entity_Id;
 551          Accept_Statement : Node_Id) return Entity_Id;
 552       --  For an entry formal entity from an entry declaration, find the
 553       --  corrsesponding body formal from the given accept statement.
 554
 555       function Missing_Subunits return Boolean;
 556       --  We suppress warnings when there are missing subunits, because this
 557       --  may generate too many false positives: entities in a parent may only
 558       --  be referenced in one of the subunits. We make an exception for
 559       --  subunits that contain no other stubs.
 560
 561       procedure Output_Reference_Error (M : String);
 562       --  Used to output an error message. Deals with posting the error on the
 563       --  body formal in the accept case.
 564
 565       function Publicly_Referenceable (Ent : Entity_Id) return Boolean;
 566       --  This is true if the entity in question is potentially referenceable
 567       --  from another unit. This is true for entities in packages that are at
 568       --  the library level.
 569
 570       ----------------------
 571       -- Missing_Subunits --
 572       ----------------------
 573
 574       function Missing_Subunits return Boolean is
 575          D : Node_Id;
 576
 577       begin
 578          if not Unloaded_Subunits then
 579
 580             --  Normal compilation, all subunits are present
 581
 582             return False;
 583
 584          elsif E /= Main_Unit_Entity then
 585
 586             --  No warnings on a stub that is not the main unit
 587
 588             return True;
 589
 590          elsif Nkind (Unit_Declaration_Node (E)) in N_Proper_Body then
 591             D := First (Declarations (Unit_Declaration_Node (E)));
 592             while Present (D) loop
 593
 594                --  No warnings if the proper body contains nested stubs
 595
 596                if Nkind (D) in N_Body_Stub then
 597                   return True;
 598                end if;
 599
 600                Next (D);
 601             end loop;
 602
 603             return False;
 604
 605          else
 606             --  Missing stubs elsewhere
 607
 608             return True;
 609          end if;
 610       end Missing_Subunits;
 611
 612       -----------------
 613       -- Body_Formal --
 614       -----------------
 615
 616       function Body_Formal
 617         (E                : Entity_Id;
 618          Accept_Statement : Node_Id) return Entity_Id
 619       is
 620          Body_Param : Node_Id;
 621          Body_E     : Entity_Id;
 622
 623       begin
 624          --  Loop to find matching parameter in accept statement
 625
 626          Body_Param := First (Parameter_Specifications (Accept_Statement));
 627          while Present (Body_Param) loop
 628             Body_E := Defining_Identifier (Body_Param);
 629
 630             if Chars (Body_E) = Chars (E) then
 631                return Body_E;
 632             end if;
 633
 634             Next (Body_Param);
 635          end loop;
 636
 637          --  Should never fall through, should always find a match
 638
 639          raise Program_Error;
 640       end Body_Formal;
 641
 642       ----------------------------
 643       -- Output_Reference_Error --
 644       ----------------------------
 645
 646       procedure Output_Reference_Error (M : String) is
 647       begin
 648          --  Don't output message for IN OUT formal unless we have the warning
 649          --  flag specifically set. It is a bit odd to distinguish IN OUT
 650          --  formals from other cases. This distinction is historical in
 651          --  nature. Warnings for IN OUT formals were added fairly late.
 652
 653          if Ekind (E1) = E_In_Out_Parameter
 654            and then not Check_Unreferenced_Formals
 655          then
 656             return;
 657          end if;
 658
 659          --  Other than accept case, post error on defining identifier
 660
 661          if No (Anod) then
 662             Error_Msg_N (M, E1);
 663
 664          --  Accept case, find body formal to post the message
 665
 666          else
 667             Error_Msg_NE (M, Body_Formal (E1, Accept_Statement => Anod), E1);
 668
 669          end if;
 670       end Output_Reference_Error;
 671
 672       ----------------------------
 673       -- Publicly_Referenceable --
 674       ----------------------------
 675
 676       function Publicly_Referenceable (Ent : Entity_Id) return Boolean is
 677          P    : Node_Id;
 678          Prev : Node_Id;
 679
 680       begin
 681          --  A formal parameter is never referenceable outside the body of its
 682          --  subprogram or entry.
 683
 684          if Is_Formal (Ent) then
 685             return False;
 686          end if;
 687
 688          --  Examine parents to look for a library level package spec. But if
 689          --  we find a body or block or other similar construct along the way,
 690          --  we cannot be referenced.
 691
 692          Prev := Ent;
 693          P    := Parent (Ent);
 694          loop
 695             case Nkind (P) is
 696
 697                --  If we get to top of tree, then publicly referenceable
 698
 699                when N_Empty =>
 700                   return True;
 701
 702                --  If we reach a generic package declaration, then always
 703                --  consider this referenceable, since any instantiation will
 704                --  have access to the entities in the generic package. Note
 705                --  that the package itself may not be instantiated, but then
 706                --  we will get a warning for the package entity.
 707
 708                --  Note that generic formal parameters are themselves not
 709                --  publicly referenceable in an instance, and warnings on them
 710                --  are useful.
 711
 712                when N_Generic_Package_Declaration =>
 713                   return
 714                     not Is_List_Member (Prev)
 715                       or else List_Containing (Prev)
 716                         /= Generic_Formal_Declarations (P);
 717
 718                --  Similarly, the generic formals of a generic subprogram are
 719                --  not accessible.
 720
 721                when N_Generic_Subprogram_Declaration  =>
 722                   if Is_List_Member (Prev)
 723                     and then List_Containing (Prev) =
 724                                Generic_Formal_Declarations (P)
 725                   then
 726                      return False;
 727                   else
 728                      P := Parent (P);
 729                   end if;
 730
 731                --  If we reach a subprogram body, entity is not referenceable
 732                --  unless it is the defining entity of the body. This will
 733                --  happen, e.g. when a function is an attribute renaming that
 734                --  is rewritten as a body.
 735
 736                when N_Subprogram_Body  =>
 737                   if Ent /= Defining_Entity (P) then
 738                      return False;
 739                   else
 740                      P := Parent (P);
 741                   end if;
 742
 743                --  If we reach any other body, definitely not referenceable
 744
 745                when N_Package_Body    |
 746                     N_Task_Body       |
 747                     N_Entry_Body      |
 748                     N_Protected_Body  |
 749                     N_Block_Statement |
 750                     N_Subunit         =>
 751                   return False;
 752
 753                --  For all other cases, keep looking up tree
 754
 755                when others =>
 756                   Prev := P;
 757                   P    := Parent (P);
 758             end case;
 759          end loop;
 760       end Publicly_Referenceable;
 761
 762    --  Start of processing for Check_References
 763
 764    begin
 765       --  No messages if warnings are suppressed, or if we have detected any
 766       --  real errors so far (this last check avoids junk messages resulting
 767       --  from errors, e.g. a subunit that is not loaded).
 768
 769       if Warning_Mode = Suppress
 770         or else Serious_Errors_Detected /= 0
 771       then
 772          return;
 773       end if;
 774
 775       --  We also skip the messages if any subunits were not loaded (see
 776       --  comment in Sem_Ch10 to understand how this is set, and why it is
 777       --  necessary to suppress the warnings in this case).
 778
 779       if Missing_Subunits then
 780          return;
 781       end if;
 782
 783       --  Otherwise loop through entities, looking for suspicious stuff
 784
 785       E1 := First_Entity (E);
 786       while Present (E1) loop
 787
 788          --  We only look at source entities with warning flag on. We also
 789          --  ignore objects whose type or base type has warnings suppressed.
 790
 791          if Comes_From_Source (E1)
 792            and then not Warnings_Off (E1)
 793            and then not Warnings_Off (Etype (E1))
 794            and then not Warnings_Off (Base_Type (Etype (E1)))
 795          then
 796             --  We are interested in variables and out/in-out parameters, but
 797             --  we exclude protected types, too complicated to worry about.
 798
 799             if Ekind (E1) = E_Variable
 800                  or else
 801                 ((Ekind (E1) = E_Out_Parameter
 802                     or else Ekind (E1) = E_In_Out_Parameter)
 803                   and then not Is_Protected_Type (Current_Scope))
 804             then
 805                --  Case of an unassigned variable
 806
 807                --  First gather any Unset_Reference indication for E1. In the
 808                --  case of a parameter, it is the Spec_Entity that is relevant.
 809
 810                if Ekind (E1) = E_Out_Parameter
 811                  and then Present (Spec_Entity (E1))
 812                then
 813                   UR := Unset_Reference (Spec_Entity (E1));
 814                else
 815                   UR := Unset_Reference (E1);
 816                end if;
 817
 818                --  If the entity is an out parameter of the current subprogram
 819                --  body, check the warning status of the parameter in the spec.
 820
 821                if Is_Formal (E1)
 822                  and then Present (Spec_Entity (E1))
 823                  and then Warnings_Off (Spec_Entity (E1))
 824                then
 825                   null;
 826
 827                elsif Present (UR)
 828                  and then Is_Access_Type (Etype (E1))
 829                then
 830                   --  For access types, the only time we made a UR entry was
 831                   --  for a dereference, and so we post the appropriate warning
 832                   --  here (note that the dereference may not be explicit in
 833                   --  the source, for example in the case of a dispatching call
 834                   --  with an anonymous access controlling formal, or of an
 835                   --  assignment of a pointer involving discriminant check
 836                   --  on the designated object).
 837
 838                   Error_Msg_NE ("?& may be null!", UR, E1);
 839                   goto Continue;
 840
 841                --  Case of variable that could be a constant. Note that we
 842                --  never signal such messages for generic package entities,
 843                --  since a given instance could have modifications outside
 844                --  the package.
 845
 846                elsif Warn_On_Constant
 847                  and then ((Ekind (E1) = E_Variable
 848                               and then Has_Initial_Value (E1))
 849                              or else
 850                             Ekind (E1) = E_In_Out_Parameter)
 851                  and then Never_Set_In_Source_Check_Spec (E1)
 852                  and then not Address_Taken (E1)
 853                  and then not Generic_Package_Spec_Entity (E1)
 854                then
 855                   --  A special case, if this variable is volatile and not
 856                   --  imported, it is not helpful to tell the programmer
 857                   --  to mark the variable as constant, since this would be
 858                   --  illegal by virtue of RM C.6(13).
 859
 860                   if (Is_Volatile (E1) or else Has_Volatile_Components (E1))
 861                     and then not Is_Imported (E1)
 862                   then
 863                      Error_Msg_N
 864                        ("?& is not modified, volatile has no effect!", E1);
 865
 866                   --  Another special case, Exception_Occurrence, this catches
 867                   --  the case of exception choice (and a bit more too, but not
 868                   --  worth doing more investigation here).
 869
 870                   elsif Is_RTE (Etype (E1), RE_Exception_Occurrence) then
 871                      null;
 872
 873                   --  Here we give the warning if referenced and no pragma
 874                   --  Unreferenced is present.
 875
 876                   else
 877                      if Ekind (E1) = E_Variable then
 878                         if Referenced_Check_Spec (E1)
 879                           and then not Has_Pragma_Unreferenced_Check_Spec (E1)
 880                         then
 881                            Error_Msg_N
 882                              ("?& is not modified, "
 883                               & "could be declared constant!",
 884                               E1);
 885                         end if;
 886
 887                      else pragma Assert (Ekind (E1) = E_In_Out_Parameter);
 888                         if Referenced_Check_Spec (E1)
 889                           and then
 890                             not Has_Pragma_Unreferenced_Check_Spec (E1)
 891                         then
 892                            --  Suppress warning if private type, since in this
 893                            --  case it may be quite reasonable for the logical
 894                            --  view to be in out, even if the implementation
 895                            --  ends up using access types.
 896
 897                            if Has_Private_Declaration (Etype (E1)) then
 898                               null;
 899
 900                            --  Suppress warning for any composite type, since
 901                            --  for composites it seems quite reasonable to pass
 902                            --  a value of the composite type and then modify
 903                            --  just a component.
 904
 905                            elsif Is_Composite_Type (Etype (E1)) then
 906                               null;
 907
 908                            --  Suppress warning for parameter of dispatching
 909                            --  operation, since it is quite reasonable to have
 910                            --  an operation that is overridden, and for some
 911                            --  subclasses needs to be IN OUT and for others
 912                            --  the parameter does not happen to be assigned.
 913
 914                            elsif Is_Dispatching_Operation
 915                              (Scope (Goto_Spec_Entity (E1)))
 916                            then
 917                               null;
 918
 919                            --  OK, looks like warning for an IN OUT parameter
 920                            --  that could be IN makes sense, but we delay the
 921                            --  output of the warning, pending possibly finding
 922                            --  out later on that the associated subprogram is
 923                            --  used as a generic actual, or its address/access
 924                            --  is taken. In these two cases, we suppress the
 925                            --  warning because the context may force use of IN
 926                            --  OUT, even if in this particular case the formal
 927                            --  is not modifed.
 928
 929                            else
 930                               In_Out_Warnings.Append (E1);
 931                            end if;
 932                         end if;
 933                      end if;
 934                   end if;
 935
 936                   --  Other cases of a variable never set in source
 937
 938                elsif Never_Set_In_Source_Check_Spec (E1)
 939
 940                   --  No warning if warning for this case turned off
 941
 942                   and then Warn_On_No_Value_Assigned
 943
 944                   --  No warning if address taken somewhere
 945
 946                   and then not Address_Taken (E1)
 947
 948                   --  No warning if explicit initial value
 949
 950                   and then not Has_Initial_Value (E1)
 951
 952                   --  No warning for generic package spec entities, since we
 953                   --  might set them in a child unit or something like that
 954
 955                   and then not Generic_Package_Spec_Entity (E1)
 956
 957                   --  No warning if fully initialized type, except that for
 958                   --  this purpose we do not consider access types to qualify
 959                   --  as fully initialized types (relying on an access type
 960                   --  variable being null when it is never set is a bit odd!)
 961
 962                   --  Also we generate warning for an out parameter that is
 963                   --  never referenced, since again it seems odd to rely on
 964                   --  default initialization to set an out parameter value.
 965
 966                  and then (Is_Access_Type (Etype (E1))
 967                             or else Ekind (E1) = E_Out_Parameter
 968                             or else not Is_Fully_Initialized_Type (Etype (E1)))
 969                then
 970                   --  Do not output complaint about never being assigned a
 971                   --  value if a pragma Unreferenced applies to the variable
 972                   --  we are examining, or if it is a parameter, if there is
 973                   --  a pragma Unreferenced for the corresponding spec.
 974
 975                   if Has_Pragma_Unreferenced_Check_Spec (E1)
 976                     or else Has_Pragma_Unreferenced_Objects (Etype (E1))
 977                   then
 978                      null;
 979
 980                   --  Case of unreferenced formal
 981
 982                   elsif Is_Formal (E1) then
 983                      if Referenced_Check_Spec (E1) then
 984                         Output_Reference_Error
 985                           ("?formal parameter& is read but never assigned!");
 986                      else
 987                         Output_Reference_Error
 988                           ("?formal parameter& is not referenced!");
 989                      end if;
 990
 991                   --  Case of variable
 992
 993                   else
 994                      if Referenced (E1) then
 995                         Output_Reference_Error
 996                           ("?variable& is read but never assigned!");
 997                      else
 998                         Output_Reference_Error
 999                           ("?variable& is never read and never assigned!");
1000                      end if;
1001
1002                      --  Deal with special case where this variable is
1003                      --  hidden by a loop variable
1004
1005                      if Ekind (E1) = E_Variable
1006                        and then Present (Hiding_Loop_Variable (E1))
1007                      then
1008                         Error_Msg_N
1009                           ("?for loop implicitly declares loop variable!",
1010                            Hiding_Loop_Variable (E1));
1011
1012                         Error_Msg_Sloc := Sloc (E1);
1013                         Error_Msg_N
1014                           ("\?declaration hides & declared#!",
1015                            Hiding_Loop_Variable (E1));
1016                      end if;
1017                   end if;
1018
1019                   goto Continue;
1020                end if;
1021
1022                --  Check for unset reference
1023
1024                if Warn_On_No_Value_Assigned and then Present (UR) then
1025
1026                   --  For other than access type, go back to original node to
1027                   --  deal with case where original unset reference has been
1028                   --  rewritten during expansion.
1029
1030                   --  In some cases, the original node may be a type conversion
1031                   --  or qualification, and in this case we want the object
1032                   --  entity inside.
1033
1034                   UR := Original_Node (UR);
1035                   while Nkind (UR) = N_Type_Conversion
1036                     or else Nkind (UR) = N_Qualified_Expression
1037                   loop
1038                      UR := Expression (UR);
1039                   end loop;
1040
1041                   --  Here we issue the warning, all checks completed
1042
1043                   --  If we have a return statement, this was a case of an OUT
1044                   --  parameter not being set at the time of the return. (Note:
1045                   --  it can't be N_Extended_Return_Statement, because those
1046                   --  are only for functions, and functions do not allow OUT
1047                   --  parameters.)
1048
1049                   if Nkind (UR) = N_Simple_Return_Statement then
1050                      Error_Msg_NE
1051                        ("?OUT parameter& not set before return", UR, E1);
1052
1053                   --  If the unset reference is prefix of a selected component
1054                   --  that comes from source, mention the component as well. If
1055                   --  the selected component comes from expansion, all we know
1056                   --  is that the entity is not fully initialized at the point
1057                   --  of the reference. Locate an unintialized component to get
1058                   --  a better error message.
1059
1060                   elsif Nkind (Parent (UR)) = N_Selected_Component then
1061                      Error_Msg_Node_2 := Selector_Name (Parent (UR));
1062
1063                      if not Comes_From_Source (Parent (UR)) then
1064                         declare
1065                            Comp : Entity_Id;
1066
1067                         begin
1068                            Comp := First_Entity (Etype (E1));
1069                            while Present (Comp) loop
1070                               if Ekind (Comp) = E_Component
1071                                 and then Nkind (Parent (Comp)) =
1072                                                       N_Component_Declaration
1073                                 and then No (Expression (Parent (Comp)))
1074                               then
1075                                  Error_Msg_Node_2 := Comp;
1076                                  exit;
1077                               end if;
1078
1079                               Next_Entity (Comp);
1080                            end loop;
1081                         end;
1082                      end if;
1083
1084                      --  Issue proper warning. This is a case of referencing
1085                      --  a variable before it has been explicitly assigned.
1086                      --  For access types, UR was only set for dereferences,
1087                      --  so the issue is that the value may be null.
1088
1089                      if Is_Access_Type (Etype (Parent (UR))) then
1090                         Error_Msg_N ("?`&.&` may be null!", UR);
1091                      else
1092                         Error_Msg_N
1093                           ("?`&.&` may be referenced before it has a value!",
1094                            UR);
1095                      end if;
1096
1097                   --  All other cases of unset reference active
1098
1099                   else
1100                      Error_Msg_N
1101                        ("?& may be referenced before it has a value!",
1102                         UR);
1103                   end if;
1104
1105                   goto Continue;
1106                end if;
1107             end if;
1108
1109             --  Then check for unreferenced entities. Note that we are only
1110             --  interested in entities which do not have the Referenced flag
1111             --  set. The Referenced_As_LHS flag is interesting only if the
1112             --  Referenced flag is not set.
1113
1114             if not Referenced_Check_Spec (E1)
1115
1116                --  Check that warnings on unreferenced entities are enabled
1117
1118               and then ((Check_Unreferenced and then not Is_Formal (E1))
1119                            or else
1120                         (Check_Unreferenced_Formals and then Is_Formal (E1))
1121                            or else
1122                         (Warn_On_Modified_Unread
1123                           and then Referenced_As_LHS_Check_Spec (E1)))
1124
1125                --  Labels, and enumeration literals, and exceptions. The
1126                --  warnings are also placed on local packages that cannot be
1127                --  referenced from elsewhere, including those declared within a
1128                --  package body.
1129
1130                and then (Is_Object (E1)
1131                            or else
1132                          Is_Type (E1)
1133                            or else
1134                          Ekind (E1) = E_Label
1135                            or else
1136                          Ekind (E1) = E_Exception
1137                            or else
1138                          Ekind (E1) = E_Named_Integer
1139                            or else
1140                          Ekind (E1) = E_Named_Real
1141                            or else
1142                          Is_Overloadable (E1)
1143
1144                            --  Package case, if the main unit is a package
1145                            --  spec or generic package spec, then there may
1146                            --  be a corresponding body that references this
1147                            --  package in some other file. Otherwise we can
1148                            --  be sure that there is no other reference.
1149
1150                            or else
1151                              (Ekind (E1) = E_Package
1152                                 and then
1153                                   Ekind (Cunit_Entity (Current_Sem_Unit)) /=
1154                                                           E_Package
1155                                 and then
1156                                   Ekind (Cunit_Entity (Current_Sem_Unit)) /=
1157                                                           E_Generic_Package))
1158
1159                --  Exclude instantiations, since there is no reason why every
1160                --  entity in an instantiation should be referenced.
1161
1162                and then Instantiation_Location (Sloc (E1)) = No_Location
1163
1164                --  Exclude formal parameters from bodies if the corresponding
1165                --  spec entity has been referenced in the case where there is
1166                --  a separate spec.
1167
1168                and then not (Is_Formal (E1)
1169                                and then
1170                              Ekind (Scope (E1)) = E_Subprogram_Body
1171                                and then
1172                              Present (Spec_Entity (E1))
1173                                and then
1174                              Referenced (Spec_Entity (E1)))
1175
1176                --  Consider private type referenced if full view is referenced
1177                --  If there is not full view, this is a generic type on which
1178                --  warnings are also useful.
1179
1180                and then
1181                  not (Is_Private_Type (E1)
1182                    and then
1183                      Present (Full_View (E1))
1184                        and then Referenced (Full_View (E1)))
1185
1186                --  Don't worry about full view, only about private type
1187
1188                and then not Has_Private_Declaration (E1)
1189
1190                --  Eliminate dispatching operations from consideration, we
1191                --  cannot tell if these are referenced or not in any easy
1192                --  manner (note this also catches Adjust/Finalize/Initialize)
1193
1194                and then not Is_Dispatching_Operation (E1)
1195
1196                --  Check entity that can be publicly referenced (we do not give
1197                --  messages for such entities, since there could be other
1198                --  units, not involved in this compilation, that contain
1199                --  relevant references.
1200
1201                and then not Publicly_Referenceable (E1)
1202
1203                --  Class wide types are marked as source entities, but they are
1204                --  not really source entities, and are always created, so we do
1205                --  not care if they are not referenced.
1206
1207                and then Ekind (E1) /= E_Class_Wide_Type
1208
1209                --  Objects other than parameters of task types are allowed to
1210                --  be non-referenced, since they start up tasks!
1211
1212                and then ((Ekind (E1) /= E_Variable
1213                              and then Ekind (E1) /= E_Constant
1214                              and then Ekind (E1) /= E_Component)
1215                            or else not Is_Task_Type (Etype (E1)))
1216
1217                --  For subunits, only place warnings on the main unit itself,
1218                --  since parent units are not completely compiled
1219
1220                and then (Nkind (Unit (Cunit (Main_Unit))) /= N_Subunit
1221                            or else
1222                          Get_Source_Unit (E1) = Main_Unit)
1223
1224                --  No warning on a return object, because these are often
1225                --  created with a single expression and an implicit return.
1226                --  If the object is a variable there will be a warning
1227                --  indicating that it could be declared constant.
1228
1229                and then not
1230                  (Ekind (E1) = E_Constant and then Is_Return_Object (E1))
1231             then
1232                --  Suppress warnings in internal units if not in -gnatg mode
1233                --  (these would be junk warnings for an applications program,
1234                --  since they refer to problems in internal units)
1235
1236                if GNAT_Mode
1237                  or else not
1238                    Is_Internal_File_Name
1239                      (Unit_File_Name (Get_Source_Unit (E1)))
1240                then
1241                   --  We do not immediately flag the error. This is because we
1242                   --  have not expanded generic bodies yet, and they may have
1243                   --  the missing reference. So instead we park the entity on a
1244                   --  list, for later processing. However for the case of an
1245                   --  accept statement we want to output messages now, since
1246                   --  we know we already have all information at hand, and we
1247                   --  also want to have separate warnings for each accept
1248                   --  statement for the same entry.
1249
1250                   if Present (Anod) then
1251                      pragma Assert (Is_Formal (E1));
1252
1253                      --  The unreferenced entity is E1, but post the warning
1254                      --  on the body entity for this accept statement.
1255
1256                      Warn_On_Unreferenced_Entity
1257                        (E1, Body_Formal (E1, Accept_Statement => Anod));
1258
1259                   else
1260                      Unreferenced_Entities.Append (E1);
1261                   end if;
1262                end if;
1263
1264             --  Generic units are referenced in the generic body, but if they
1265             --  are not public and never instantiated we want to force a
1266             --  warning on them. We treat them as redundant constructs to
1267             --  minimize noise.
1268
1269             elsif Is_Generic_Subprogram (E1)
1270               and then not Is_Instantiated (E1)
1271               and then not Publicly_Referenceable (E1)
1272               and then Instantiation_Depth (Sloc (E1)) = 0
1273               and then Warn_On_Redundant_Constructs
1274             then
1275                Unreferenced_Entities.Append (E1);
1276
1277                --  Force warning on entity
1278
1279                Set_Referenced (E1, False);
1280             end if;
1281          end if;
1282
1283          --  Recurse into nested package or block. Do not recurse into a
1284          --  formal package, because the correponding body is not analyzed.
1285
1286          <<Continue>>
1287             if ((Ekind (E1) = E_Package or else Ekind (E1) = E_Generic_Package)
1288                   and then Nkind (Parent (E1)) = N_Package_Specification
1289                   and then
1290                     Nkind (Original_Node (Unit_Declaration_Node (E1)))
1291                       /= N_Formal_Package_Declaration)
1292
1293               or else Ekind (E1) = E_Block
1294             then
1295                Check_References (E1);
1296             end if;
1297
1298             Next_Entity (E1);
1299       end loop;
1300    end Check_References;
1301
1302    ---------------------------
1303    -- Check_Unset_Reference --
1304    ---------------------------
1305
1306    procedure Check_Unset_Reference (N : Node_Id) is
1307       Typ : constant Entity_Id := Etype (N);
1308
1309       function Is_OK_Fully_Initialized return Boolean;
1310       --  This function returns true if the given node N is fully initialized
1311       --  so that the reference is safe as far as this routine is concerned.
1312       --  Safe generally means that the type of N is a fully initialized type.
1313       --  The one special case is that for access types, which are always fully
1314       --  initialized, we don't consider a dereference OK since it will surely
1315       --  be dereferencing a null value, which won't do.
1316
1317       function Prefix_Has_Dereference (Pref : Node_Id) return Boolean;
1318       --  Used to test indexed or selected component or slice to see if the
1319       --  evaluation of the prefix depends on a dereference, and if so, returns
1320       --  True, in which case we always check the prefix, even if we know that
1321       --  the referenced component is initialized. Pref is the prefix to test.
1322
1323       -----------------------------
1324       -- Is_OK_Fully_Initialized --
1325       -----------------------------
1326
1327       function Is_OK_Fully_Initialized return Boolean is
1328       begin
1329          if Is_Access_Type (Typ) and then Is_Dereferenced (N) then
1330             return False;
1331          else
1332             return Is_Fully_Initialized_Type (Typ);
1333          end if;
1334       end Is_OK_Fully_Initialized;
1335
1336       ----------------------------
1337       -- Prefix_Has_Dereference --
1338       ----------------------------
1339
1340       function Prefix_Has_Dereference (Pref : Node_Id) return Boolean is
1341       begin
1342          --  If prefix is of an access type, certainly need a dereference
1343
1344          if Is_Access_Type (Etype (Pref)) then
1345             return True;
1346
1347          --  If prefix is explicit dereference, that's a dereference for sure
1348
1349          elsif Nkind (Pref) = N_Explicit_Dereference then
1350             return True;
1351
1352             --  If prefix is itself a component reference or slice check prefix
1353
1354          elsif Nkind (Pref) = N_Slice
1355            or else Nkind (Pref) = N_Indexed_Component
1356            or else Nkind (Pref) = N_Selected_Component
1357          then
1358             return Prefix_Has_Dereference (Prefix (Pref));
1359
1360          --  All other cases do not involve a dereference
1361
1362          else
1363             return False;
1364          end if;
1365       end Prefix_Has_Dereference;
1366
1367    --  Start of processing for Check_Unset_Reference
1368
1369    begin
1370       --  Nothing to do if warnings suppressed
1371
1372       if Warning_Mode = Suppress then
1373          return;
1374       end if;
1375
1376       --  Ignore reference unless it comes from source. Almost always if we
1377       --  have a reference from generated code, it is bogus (e.g. calls to init
1378       --  procs to set default discriminant values).
1379
1380       if not Comes_From_Source (N) then
1381          return;
1382       end if;
1383
1384       --  Otherwise see what kind of node we have. If the entity already
1385       --  has an unset reference, it is not necessarily the earliest in
1386       --  the text, because resolution of the prefix of selected components
1387       --  is completed before the resolution of the selected component itself.
1388       --  as a result, given  (R /= null and then R.X > 0), the occurrences
1389       --  of R are examined in right-to-left order. If there is already an
1390       --  unset reference, we check whether N is earlier before proceeding.
1391
1392       case Nkind (N) is
1393
1394          --  For identifier or exanded name, examine the entity involved
1395
1396          when N_Identifier | N_Expanded_Name =>
1397             declare
1398                E : constant Entity_Id := Entity (N);
1399
1400             begin
1401                if (Ekind (E) = E_Variable
1402                      or else
1403                    Ekind (E) = E_Out_Parameter)
1404                  and then Never_Set_In_Source_Check_Spec (E)
1405                  and then not Has_Initial_Value (E)
1406                  and then (No (Unset_Reference (E))
1407                             or else
1408                               Earlier_In_Extended_Unit
1409                                 (Sloc (N),  Sloc (Unset_Reference (E))))
1410                  and then not Warnings_Off (E)
1411                then
1412                   --  We may have an unset reference. The first test is whether
1413                   --  this is an access to a discriminant of a record or a
1414                   --  component with default initialization. Both of these
1415                   --  cases can be ignored, since the actual object that is
1416                   --  referenced is definitely initialized. Note that this
1417                   --  covers the case of reading discriminants of an out
1418                   --  parameter, which is OK even in Ada 83.
1419
1420                   --  Note that we are only interested in a direct reference to
1421                   --  a record component here. If the reference is via an
1422                   --  access type, then the access object is being referenced,
1423                   --  not the record, and still deserves an unset reference.
1424
1425                   if Nkind (Parent (N)) = N_Selected_Component
1426                     and not Is_Access_Type (Typ)
1427                   then
1428                      declare
1429                         ES : constant Entity_Id :=
1430                                Entity (Selector_Name (Parent (N)));
1431                      begin
1432                         if Ekind (ES) = E_Discriminant
1433                           or else
1434                             (Present (Declaration_Node (ES))
1435                                and then
1436                              Present (Expression (Declaration_Node (ES))))
1437                         then
1438                            return;
1439                         end if;
1440                      end;
1441                   end if;
1442
1443                   --  Exclude fully initialized types
1444
1445                   if Is_OK_Fully_Initialized then
1446                      return;
1447                   end if;
1448
1449                   --  Here we have a potential unset reference. But before we
1450                   --  get worried about it, we have to make sure that the
1451                   --  entity declaration is in the same procedure as the
1452                   --  reference, since if they are in separate procedures, then
1453                   --  we have no idea about sequential execution.
1454
1455                   --  The tests in the loop below catch all such cases, but do
1456                   --  allow the reference to appear in a loop, block, or
1457                   --  package spec that is nested within the declaring scope.
1458                   --  As always, it is possible to construct cases where the
1459                   --  warning is wrong, that is why it is a warning!
1460
1461                   declare
1462                      SR : Entity_Id;
1463                      SE : constant Entity_Id := Scope (E);
1464
1465                   begin
1466                      SR := Current_Scope;
1467                      while SR /= SE loop
1468                         if SR = Standard_Standard
1469                           or else Is_Subprogram (SR)
1470                           or else Is_Concurrent_Body (SR)
1471                           or else Is_Concurrent_Type (SR)
1472                         then
1473                            return;
1474                         end if;
1475
1476                         SR := Scope (SR);
1477                      end loop;
1478
1479                      --  Case of reference has an access type. This is special
1480                      --  case since access types are always set to null so
1481                      --  cannot be truly uninitialized, but we still want to
1482                      --  warn about cases of obvious null dereference.
1483
1484                      if Is_Access_Type (Typ) then
1485                         Access_Type_Case : declare
1486                            P : Node_Id;
1487
1488                            function Process
1489                              (N : Node_Id) return Traverse_Result;
1490                            --  Process function for instantation of Traverse
1491                            --  below. Checks if N contains reference to other
1492                            --  than a dereference.
1493
1494                            function Ref_In (Nod : Node_Id) return Boolean;
1495                            --  Determines whether Nod contains a reference to
1496                            --  the entity E that is not a dereference.
1497
1498                            -------------
1499                            -- Process --
1500                            -------------
1501
1502                            function Process
1503                              (N : Node_Id) return Traverse_Result
1504                            is
1505                            begin
1506                               if Is_Entity_Name (N)
1507                                 and then Entity (N) = E
1508                                 and then not Is_Dereferenced (N)
1509                               then
1510                                  return Abandon;
1511                               else
1512                                  return OK;
1513                               end if;
1514                            end Process;
1515
1516                            ------------
1517                            -- Ref_In --
1518                            ------------
1519
1520                            function Ref_In (Nod : Node_Id) return Boolean is
1521                               function Traverse is new Traverse_Func (Process);
1522                            begin
1523                               return Traverse (Nod) = Abandon;
1524                            end Ref_In;
1525
1526                         --  Start of processing for Access_Type_Case
1527
1528                         begin
1529                            --  Don't bother if we are inside an instance, since
1530                            --  the compilation of the generic template is where
1531                            --  the warning should be issued.
1532
1533                            if In_Instance then
1534                               return;
1535                            end if;
1536
1537                            --  Don't bother if this is not the main unit. If we
1538                            --  try to give this warning for with'ed units, we
1539                            --  get some false positives, since we do not record
1540                            --  references in other units.
1541
1542                            if not In_Extended_Main_Source_Unit (E)
1543                                 or else
1544                               not In_Extended_Main_Source_Unit (N)
1545                            then
1546                               return;
1547                            end if;
1548
1549                            --  We are only interested in dereferences
1550
1551                            if not Is_Dereferenced (N) then
1552                               return;
1553                            end if;
1554
1555                            --  One more check, don't bother with references
1556                            --  that are inside conditional statements or while
1557                            --  loops if the condition references the entity in
1558                            --  question. This avoids most false positives.
1559
1560                            P := Parent (N);
1561                            loop
1562                               P := Parent (P);
1563                               exit when No (P);
1564
1565                               if (Nkind (P) = N_If_Statement
1566                                      or else
1567                                    Nkind (P) = N_Elsif_Part)
1568                                  and then Ref_In (Condition (P))
1569                               then
1570                                  return;
1571
1572                               elsif Nkind (P) = N_Loop_Statement
1573                                 and then Present (Iteration_Scheme (P))
1574                                 and then
1575                                   Ref_In (Condition (Iteration_Scheme (P)))
1576                               then
1577                                  return;
1578                               end if;
1579                            end loop;
1580                         end Access_Type_Case;
1581                      end if;
1582
1583                      --  Here we definitely have a case for giving a warning
1584                      --  for a reference to an unset value. But we don't give
1585                      --  the warning now. Instead we set the Unset_Reference
1586                      --  field of the identifier involved. The reason for this
1587                      --  is that if we find the variable is never ever assigned
1588                      --  a value then that warning is more important and there
1589                      --  is no point in giving the reference warning.
1590
1591                      --  If this is an identifier, set the field directly
1592
1593                      if Nkind (N) = N_Identifier then
1594                         Set_Unset_Reference (E, N);
1595
1596                      --  Otherwise it is an expanded name, so set the field of
1597                      --  the actual identifier for the reference.
1598
1599                      else
1600                         Set_Unset_Reference (E, Selector_Name (N));
1601                      end if;
1602                   end;
1603                end if;
1604             end;
1605
1606          --  Indexed component or slice
1607
1608          when N_Indexed_Component | N_Slice =>
1609
1610             --  If prefix does not involve dereferencing an access type, then
1611             --  we know we are OK if the component type is fully initialized,
1612             --  since the component will have been set as part of the default
1613             --  initialization.
1614
1615             if not Prefix_Has_Dereference (Prefix (N))
1616               and then Is_OK_Fully_Initialized
1617             then
1618                return;
1619
1620             --  Look at prefix in access type case, or if the component is not
1621             --  fully initialized.
1622
1623             else
1624                Check_Unset_Reference (Prefix (N));
1625             end if;
1626
1627          --  Record component
1628
1629          when N_Selected_Component =>
1630             declare
1631                Pref : constant Node_Id   := Prefix (N);
1632                Ent  : constant Entity_Id := Entity (Selector_Name (N));
1633
1634             begin
1635                --  If prefix involves dereferencing an access type, always
1636                --  check the prefix, since the issue then is whether this
1637                --  access value is null.
1638
1639                if Prefix_Has_Dereference (Pref) then
1640                   null;
1641
1642                --  Always go to prefix if no selector entity is set. Can this
1643                --  happen in the normal case? Not clear, but it definitely can
1644                --  happen in error cases.
1645
1646                elsif No (Ent) then
1647                   null;
1648
1649                --  For a record component, check some cases where we have
1650                --  reasonable cause to consider that the component is known to
1651                --  be or probably is initialized. In this case, we don't care
1652                --  if the prefix itself was explicitly initialized.
1653
1654                --  Discriminants are always considered initialized
1655
1656                elsif Ekind (Ent) = E_Discriminant then
1657                   return;
1658
1659                --  An explicitly initialized component is certainly initialized
1660
1661                elsif Nkind (Parent (Ent)) = N_Component_Declaration
1662                  and then Present (Expression (Parent (Ent)))
1663                then
1664                   return;
1665
1666                --  A fully initialized component is initialized
1667
1668                elsif Is_OK_Fully_Initialized then
1669                   return;
1670                end if;
1671
1672                --  If none of those cases apply, check the record type prefix
1673
1674                Check_Unset_Reference (Pref);
1675             end;
1676
1677          --  For type conversions or qualifications examine the expression
1678
1679          when N_Type_Conversion | N_Qualified_Expression =>
1680             Check_Unset_Reference (Expression (N));
1681
1682          --  For explicit dereference, always check prefix, which will generate
1683          --  an unset reference (since this is a case of dereferencing null).
1684
1685          when N_Explicit_Dereference =>
1686             Check_Unset_Reference (Prefix (N));
1687
1688          --  All other cases are not cases of an unset reference
1689
1690          when others =>
1691             null;
1692
1693       end case;
1694    end Check_Unset_Reference;
1695
1696    ------------------------
1697    -- Check_Unused_Withs --
1698    ------------------------
1699
1700    procedure Check_Unused_Withs (Spec_Unit : Unit_Number_Type := No_Unit) is
1701       Cnode : Node_Id;
1702       Item  : Node_Id;
1703       Lunit : Node_Id;
1704       Ent   : Entity_Id;
1705
1706       Munite : constant Entity_Id := Cunit_Entity (Main_Unit);
1707       --  This is needed for checking the special renaming case
1708
1709       procedure Check_One_Unit (Unit : Unit_Number_Type);
1710       --  Subsidiary procedure, performs checks for specified unit
1711
1712       --------------------
1713       -- Check_One_Unit --
1714       --------------------
1715
1716       procedure Check_One_Unit (Unit : Unit_Number_Type) is
1717          Is_Visible_Renaming : Boolean := False;
1718          Pack                : Entity_Id;
1719
1720          procedure Check_Inner_Package (Pack : Entity_Id);
1721          --  Pack is a package local to a unit in a with_clause. Both the
1722          --  unit and Pack are referenced. If none of the entities in Pack
1723          --  are referenced, then the only occurrence of Pack is in a use
1724          --  clause or a pragma, and a warning is worthwhile as well.
1725
1726          function Check_System_Aux return Boolean;
1727          --  Before giving a warning on a with_clause for System, check
1728          --  whether a system extension is present.
1729
1730          function Find_Package_Renaming
1731            (P : Entity_Id;
1732             L : Entity_Id) return Entity_Id;
1733          --  The only reference to a context unit may be in a renaming
1734          --  declaration. If this renaming declares a visible entity, do
1735          --  not warn that the context clause could be moved to the body,
1736          --  because the renaming may be intented to re-export the unit.
1737
1738          -------------------------
1739          -- Check_Inner_Package --
1740          -------------------------
1741
1742          procedure Check_Inner_Package (Pack : Entity_Id) is
1743             E  : Entity_Id;
1744             Un : constant Node_Id := Sinfo.Unit (Cnode);
1745
1746             function Check_Use_Clause (N : Node_Id) return Traverse_Result;
1747             --  If N is a use_clause for Pack, emit warning
1748
1749             procedure Check_Use_Clauses is new
1750               Traverse_Proc (Check_Use_Clause);
1751
1752             ----------------------
1753             -- Check_Use_Clause --
1754             ----------------------
1755
1756             function Check_Use_Clause (N : Node_Id) return Traverse_Result is
1757                Nam  : Node_Id;
1758
1759             begin
1760                if Nkind (N) = N_Use_Package_Clause then
1761                   Nam := First (Names (N));
1762                   while Present (Nam) loop
1763                      if Entity (Nam) = Pack then
1764                         Error_Msg_Qual_Level := 1;
1765                         Error_Msg_NE
1766                           ("?no entities of package& are referenced!",
1767                              Nam, Pack);
1768                         Error_Msg_Qual_Level := 0;
1769                      end if;
1770
1771                      Next (Nam);
1772                   end loop;
1773                end if;
1774
1775                return OK;
1776             end Check_Use_Clause;
1777
1778          --  Start of processing for Check_Inner_Package
1779
1780          begin
1781             E := First_Entity (Pack);
1782             while Present (E) loop
1783                if Referenced_Check_Spec (E) then
1784                   return;
1785                end if;
1786
1787                Next_Entity (E);
1788             end loop;
1789
1790             --  No entities of the package are referenced. Check whether the
1791             --  reference to the package itself is a use clause, and if so
1792             --  place a warning on it.
1793
1794             Check_Use_Clauses (Un);
1795          end Check_Inner_Package;
1796
1797          ----------------------
1798          -- Check_System_Aux --
1799          ----------------------
1800
1801          function Check_System_Aux return Boolean is
1802             Ent : Entity_Id;
1803
1804          begin
1805             if Chars (Lunit) = Name_System
1806                and then Scope (Lunit) = Standard_Standard
1807                and then Present_System_Aux
1808             then
1809                Ent := First_Entity (System_Aux_Id);
1810                while Present (Ent) loop
1811                   if Referenced_Check_Spec (Ent) then
1812                      return True;
1813                   end if;
1814
1815                   Next_Entity (Ent);
1816                end loop;
1817             end if;
1818
1819             return False;
1820          end Check_System_Aux;
1821
1822          ---------------------------
1823          -- Find_Package_Renaming --
1824          ---------------------------
1825
1826          function Find_Package_Renaming
1827            (P : Entity_Id;
1828             L : Entity_Id) return Entity_Id
1829          is
1830             E1 : Entity_Id;
1831             R  : Entity_Id;
1832
1833          begin
1834             Is_Visible_Renaming := False;
1835
1836             E1 := First_Entity (P);
1837             while Present (E1) loop
1838                if Ekind (E1) = E_Package
1839                   and then Renamed_Object (E1) = L
1840                then
1841                   Is_Visible_Renaming := not Is_Hidden (E1);
1842                   return E1;
1843
1844                elsif Ekind (E1) = E_Package
1845                  and then No (Renamed_Object (E1))
1846                  and then not Is_Generic_Instance (E1)
1847                then
1848                   R := Find_Package_Renaming (E1, L);
1849
1850                   if Present (R) then
1851                      Is_Visible_Renaming := not Is_Hidden (R);
1852                      return R;
1853                   end if;
1854                end if;
1855
1856                Next_Entity (E1);
1857             end loop;
1858
1859             return Empty;
1860          end Find_Package_Renaming;
1861
1862       --  Start of processing for Check_One_Unit
1863
1864       begin
1865          Cnode := Cunit (Unit);
1866
1867          --  Only do check in units that are part of the extended main unit.
1868          --  This is actually a necessary restriction, because in the case of
1869          --  subprogram acting as its own specification, there can be with's in
1870          --  subunits that we will not see.
1871
1872          if not In_Extended_Main_Source_Unit (Cnode) then
1873             return;
1874
1875          --  In configurable run time mode, we remove the bodies of non-inlined
1876          --  subprograms, which may lead to spurious warnings, which are
1877          --  clearly undesirable.
1878
1879          elsif Configurable_Run_Time_Mode
1880            and then Is_Predefined_File_Name (Unit_File_Name (Unit))
1881          then
1882             return;
1883          end if;
1884
1885          --  Loop through context items in this unit
1886
1887          Item := First (Context_Items (Cnode));
1888          while Present (Item) loop
1889             if Nkind (Item) = N_With_Clause
1890                and then not Implicit_With (Item)
1891                and then In_Extended_Main_Source_Unit (Item)
1892             then
1893                Lunit := Entity (Name (Item));
1894
1895                --  Check if this unit is referenced (skip the check if this
1896                --  is explicitly marked by a pragma Unreferenced).
1897
1898                if not Referenced (Lunit)
1899                  and then not Has_Pragma_Unreferenced (Lunit)
1900                then
1901                   --  Suppress warnings in internal units if not in -gnatg mode
1902                   --  (these would be junk warnings for an application program,
1903                   --  since they refer to problems in internal units).
1904
1905                   if GNAT_Mode
1906                     or else not Is_Internal_File_Name (Unit_File_Name (Unit))
1907                   then
1908                      --  Here we definitely have a non-referenced unit. If it
1909                      --  is the special call for a spec unit, then just set the
1910                      --  flag to be read later.
1911
1912                      if Unit = Spec_Unit then
1913                         Set_Unreferenced_In_Spec (Item);
1914
1915                      --  Otherwise simple unreferenced message
1916
1917                      else
1918                         Error_Msg_N
1919                           ("?unit& is not referenced!", Name (Item));
1920                      end if;
1921                   end if;
1922
1923                --  If main unit is a renaming of this unit, then we consider
1924                --  the with to be OK (obviously it is needed in this case!)
1925                --  This may be transitive: the unit in the with_clause may
1926                --  itself be a renaming, in which case both it and the main
1927                --  unit rename the same ultimate package.
1928
1929                elsif Present (Renamed_Entity (Munite))
1930                   and then
1931                     (Renamed_Entity (Munite) = Lunit
1932                       or else Renamed_Entity (Munite) = Renamed_Entity (Lunit))
1933                then
1934                   null;
1935
1936                --  If this unit is referenced, and it is a package, we do
1937                --  another test, to see if any of the entities in the package
1938                --  are referenced. If none of the entities are referenced, we
1939                --  still post a warning. This occurs if the only use of the
1940                --  package is in a use clause, or in a package renaming
1941                --  declaration.
1942
1943                elsif Ekind (Lunit) = E_Package then
1944
1945                   --  If Is_Instantiated is set, it means that the package is
1946                   --  implicitly instantiated (this is the case of parent
1947                   --  instance or an actual for a generic package formal), and
1948                   --  this counts as a reference.
1949
1950                   if Is_Instantiated (Lunit) then
1951                      null;
1952
1953                   --  If no entities in package, and there is a pragma
1954                   --  Elaborate_Body present, then assume that this with is
1955                   --  done for purposes of this elaboration.
1956
1957                   elsif No (First_Entity (Lunit))
1958                     and then Has_Pragma_Elaborate_Body (Lunit)
1959                   then
1960                      null;
1961
1962                   --  Otherwise see if any entities have been referenced
1963
1964                   else
1965                      if Limited_Present (Item) then
1966                         Ent := First_Entity (Limited_View (Lunit));
1967                      else
1968                         Ent := First_Entity (Lunit);
1969                      end if;
1970
1971                      loop
1972                         --  No more entities, and we did not find one that was
1973                         --  referenced. Means we have a definite case of a with
1974                         --  none of whose entities was referenced.
1975
1976                         if No (Ent) then
1977
1978                            --  If in spec, just set the flag
1979
1980                            if Unit = Spec_Unit then
1981                               Set_No_Entities_Ref_In_Spec (Item);
1982
1983                            elsif Check_System_Aux then
1984                               null;
1985
1986                            --  Else give the warning
1987
1988                            else
1989                               Error_Msg_N
1990                                 ("?no entities of & are referenced!",
1991                                  Name (Item));
1992
1993                               --  Look for renamings of this package, and flag
1994                               --  them as well. If the original package has
1995                               --  warnings off, we suppress the warning on the
1996                               --  renaming as well.
1997
1998                               Pack := Find_Package_Renaming (Munite, Lunit);
1999
2000                               if Present (Pack)
2001                                 and then not Warnings_Off (Lunit)
2002                               then
2003                                  Error_Msg_NE
2004                                    ("?no entities of & are referenced!",
2005                                      Unit_Declaration_Node (Pack),
2006                                        Pack);
2007                               end if;
2008                            end if;
2009
2010                            exit;
2011
2012                         --  Case of entity being referenced. The reference may
2013                         --  come from a limited_with_clause, in which case the
2014                         --  limited view of the entity carries the flag.
2015
2016                         elsif Referenced_Check_Spec (Ent)
2017                           or else Referenced_As_LHS_Check_Spec (Ent)
2018                           or else
2019                             (From_With_Type (Ent)
2020                               and then Is_Incomplete_Type (Ent)
2021                               and then Present (Non_Limited_View (Ent))
2022                               and then Referenced (Non_Limited_View (Ent)))
2023                         then
2024                            --  This means that the with is indeed fine, in that
2025                            --  it is definitely needed somewhere, and we can
2026                            --  quit worrying about this one...
2027
2028                            --  Except for one little detail: if either of the
2029                            --  flags was set during spec processing, this is
2030                            --  where we complain that the with could be moved
2031                            --  from the spec. If the spec contains a visible
2032                            --  renaming of the package, inhibit warning to move
2033                            --  with_clause to body.
2034
2035                            if Ekind (Munite) = E_Package_Body then
2036                               Pack :=
2037                                 Find_Package_Renaming
2038                                   (Spec_Entity (Munite), Lunit);
2039                            end if;
2040
2041                            if Unreferenced_In_Spec (Item) then
2042                               Error_Msg_N
2043                                 ("?unit& is not referenced in spec!",
2044                                  Name (Item));
2045
2046                            elsif No_Entities_Ref_In_Spec (Item) then
2047                               Error_Msg_N
2048                                 ("?no entities of & are referenced in spec!",
2049                                  Name (Item));
2050
2051                            else
2052                               if Ekind (Ent) = E_Package then
2053                                  Check_Inner_Package (Ent);
2054                               end if;
2055
2056                               exit;
2057                            end if;
2058
2059                            if not Is_Visible_Renaming then
2060                               Error_Msg_N
2061                                 ("\?with clause might be moved to body!",
2062                                  Name (Item));
2063                            end if;
2064
2065                            exit;
2066
2067                         --  Move to next entity to continue search
2068
2069                         else
2070                            Next_Entity (Ent);
2071                         end if;
2072                      end loop;
2073                   end if;
2074
2075                --  For a generic package, the only interesting kind of
2076                --  reference is an instantiation, since entities cannot be
2077                --  referenced directly.
2078
2079                elsif Is_Generic_Unit (Lunit) then
2080
2081                   --  Unit was never instantiated, set flag for case of spec
2082                   --  call, or give warning for normal call.
2083
2084                   if not Is_Instantiated (Lunit) then
2085                      if Unit = Spec_Unit then
2086                         Set_Unreferenced_In_Spec (Item);
2087                      else
2088                         Error_Msg_N
2089                           ("?unit& is never instantiated!", Name (Item));
2090                      end if;
2091
2092                   --  If unit was indeed instantiated, make sure that flag is
2093                   --  not set showing it was uninstantiated in the spec, and if
2094                   --  so, give warning.
2095
2096                   elsif Unreferenced_In_Spec (Item) then
2097                      Error_Msg_N
2098                        ("?unit& is not instantiated in spec!", Name (Item));
2099                      Error_Msg_N
2100                        ("\?with clause can be moved to body!", Name (Item));
2101                   end if;
2102                end if;
2103             end if;
2104
2105             Next (Item);
2106          end loop;
2107
2108       end Check_One_Unit;
2109
2110    --  Start of processing for Check_Unused_Withs
2111
2112    begin
2113       if not Opt.Check_Withs
2114         or else Operating_Mode = Check_Syntax
2115       then
2116          return;
2117       end if;
2118
2119       --  Flag any unused with clauses, but skip this step if we are compiling
2120       --  a subunit on its own, since we do not have enough information to
2121       --  determine whether with's are used. We will get the relevant warnings
2122       --  when we compile the parent. This is the normal style of GNAT
2123       --  compilation in any case.
2124
2125       if Nkind (Unit (Cunit (Main_Unit))) = N_Subunit then
2126          return;
2127       end if;
2128
2129       --  Process specified units
2130
2131       if Spec_Unit = No_Unit then
2132
2133          --  For main call, check all units
2134
2135          for Unit in Main_Unit .. Last_Unit loop
2136             Check_One_Unit (Unit);
2137          end loop;
2138
2139       else
2140          --  For call for spec, check only the spec
2141
2142          Check_One_Unit (Spec_Unit);
2143       end if;
2144    end Check_Unused_Withs;
2145
2146    ---------------------------------
2147    -- Generic_Package_Spec_Entity --
2148    ---------------------------------
2149
2150    function Generic_Package_Spec_Entity (E : Entity_Id) return Boolean is
2151       S : Entity_Id;
2152
2153    begin
2154       if Is_Package_Body_Entity (E) then
2155          return False;
2156
2157       else
2158          S := Scope (E);
2159          loop
2160             if S = Standard_Standard then
2161                return False;
2162
2163             elsif Ekind (S) = E_Generic_Package then
2164                return True;
2165
2166             elsif Ekind (S) = E_Package then
2167                S := Scope (S);
2168
2169             else
2170                return False;
2171             end if;
2172          end loop;
2173       end if;
2174    end Generic_Package_Spec_Entity;
2175
2176    ----------------------
2177    -- Goto_Spec_Entity --
2178    ----------------------
2179
2180    function Goto_Spec_Entity (E : Entity_Id) return Entity_Id is
2181    begin
2182       if Is_Formal (E)
2183         and then Present (Spec_Entity (E))
2184       then
2185          return Spec_Entity (E);
2186       else
2187          return E;
2188       end if;
2189    end Goto_Spec_Entity;
2190
2191    ----------------------------------------
2192    -- Has_Pragma_Unreferenced_Check_Spec --
2193    ----------------------------------------
2194
2195    function Has_Pragma_Unreferenced_Check_Spec
2196      (E : Entity_Id) return Boolean
2197    is
2198    begin
2199       if Is_Formal (E) and then Present (Spec_Entity (E)) then
2200          return Has_Pragma_Unreferenced (E)
2201                   or else
2202                 Has_Pragma_Unreferenced (Spec_Entity (E));
2203       else
2204          return Has_Pragma_Unreferenced (E);
2205       end if;
2206    end Has_Pragma_Unreferenced_Check_Spec;
2207
2208    ------------------------------------
2209    -- Never_Set_In_Source_Check_Spec --
2210    ------------------------------------
2211
2212    function Never_Set_In_Source_Check_Spec (E : Entity_Id) return Boolean is
2213    begin
2214       if Is_Formal (E) and then Present (Spec_Entity (E)) then
2215          return Never_Set_In_Source (E)
2216                   and then
2217                 Never_Set_In_Source (Spec_Entity (E));
2218       else
2219          return Never_Set_In_Source (E);
2220       end if;
2221    end Never_Set_In_Source_Check_Spec;
2222
2223    -------------------------------------
2224    -- Operand_Has_Warnings_Suppressed --
2225    -------------------------------------
2226
2227    function Operand_Has_Warnings_Suppressed (N : Node_Id) return Boolean is
2228
2229       function Check_For_Warnings (N : Node_Id) return Traverse_Result;
2230       --  Function used to check one node to see if it is or was originally
2231       --  a reference to an entity for which Warnings are off. If so, Abandon
2232       --  is returned, otherwise OK_Orig is returned to continue the traversal
2233       --  of the original expression.
2234
2235       function Traverse is new Traverse_Func (Check_For_Warnings);
2236       --  Function used to traverse tree looking for warnings
2237
2238       ------------------------
2239       -- Check_For_Warnings --
2240       ------------------------
2241
2242       function Check_For_Warnings (N : Node_Id) return Traverse_Result is
2243          R : constant Node_Id := Original_Node (N);
2244
2245       begin
2246          if Nkind (R) in N_Has_Entity
2247            and then Present (Entity (R))
2248            and then Warnings_Off (Entity (R))
2249          then
2250             return Abandon;
2251          else
2252             return OK_Orig;
2253          end if;
2254       end Check_For_Warnings;
2255
2256    --  Start of processing for Operand_Has_Warnings_Suppressed
2257
2258    begin
2259       return Traverse (N) = Abandon;
2260
2261    --  If any exception occurs, then something has gone wrong, and this is
2262    --  only a minor aesthetic issue anyway, so just say we did not find what
2263    --  we are looking for, rather than blow up.
2264
2265    exception
2266       when others =>
2267          return False;
2268    end Operand_Has_Warnings_Suppressed;
2269
2270    -----------------------------------------
2271    -- Output_Non_Modified_In_Out_Warnings --
2272    -----------------------------------------
2273
2274    procedure Output_Non_Modifed_In_Out_Warnings is
2275
2276       function No_Warn_On_In_Out (E : Entity_Id) return Boolean;
2277       --  Given a formal parameter entity E, determines if there is a reason to
2278       --  suppress IN OUT warnings (not modified, could be IN) for formals of
2279       --  the subprogram. We suppress these warnings if Warnings Off is set, or
2280       --  if we have seen the address of the subprogram being taken, or if the
2281       --  subprogram is used as a generic actual (in the latter cases the
2282       --  context may force use of IN OUT, even if the parameter is not
2283       --  modifies for this particular case.
2284
2285       -----------------------
2286       -- No_Warn_On_In_Out --
2287       -----------------------
2288
2289       function No_Warn_On_In_Out (E : Entity_Id) return Boolean is
2290          S : constant Entity_Id := Scope (E);
2291       begin
2292          if Warnings_Off (S) then
2293             return True;
2294          elsif Address_Taken (S) then
2295             return True;
2296          elsif Used_As_Generic_Actual (S) then
2297             return True;
2298          elsif Present (Spec_Entity (E)) then
2299             return No_Warn_On_In_Out (Spec_Entity (E));
2300          else
2301             return False;
2302          end if;
2303       end No_Warn_On_In_Out;
2304
2305    --  Start of processing for Output_Non_Modifed_In_Out_Warnings
2306
2307    begin
2308       --  Loop through entities for which a warning may be needed
2309
2310       for J in In_Out_Warnings.First .. In_Out_Warnings.Last loop
2311          declare
2312             E1 : constant Entity_Id := In_Out_Warnings.Table (J);
2313
2314          begin
2315             --  Suppress warning in specific cases (see details in comments for
2316             --  No_Warn_On_In_Out).
2317
2318             if No_Warn_On_In_Out (E1) then
2319                null;
2320
2321             --  Here we generate the warning
2322
2323             else
2324                Error_Msg_N ("?formal parameter & is not modified!", E1);
2325                Error_Msg_N ("\?mode could be IN instead of `IN OUT`!", E1);
2326
2327                --  Kill any other warnings on this entity, since this is the
2328                --  one that should dominate any other unreferenced warning.
2329
2330                Set_Warnings_Off (E1);
2331             end if;
2332          end;
2333       end loop;
2334    end Output_Non_Modifed_In_Out_Warnings;
2335
2336    ----------------------------------------
2337    -- Output_Obsolescent_Entity_Warnings --
2338    ----------------------------------------
2339
2340    procedure Output_Obsolescent_Entity_Warnings (N : Node_Id; E : Entity_Id) is
2341       P : constant Node_Id := Parent (N);
2342       S : Entity_Id;
2343
2344    begin
2345       S := Current_Scope;
2346
2347       --  Do not output message if we are the scope of standard. This means
2348       --  we have a reference from a context clause from when it is originally
2349       --  processed, and that's too early to tell whether it is an obsolescent
2350       --  unit doing the with'ing. In Sem_Ch10.Analyze_Compilation_Unit we make
2351       --  sure that we have a later call when the scope is available. This test
2352       --  also eliminates all messages for use clauses, which is fine (we do
2353       --  not want messages for use clauses, since they are always redundant
2354       --  with respect to the associated with clause).
2355
2356       if S = Standard_Standard then
2357          return;
2358       end if;
2359
2360       --  Do not output message if we are in scope of an obsolescent package
2361       --  or subprogram.
2362
2363       loop
2364          if Is_Obsolescent (S) then
2365             return;
2366          end if;
2367
2368          S := Scope (S);
2369          exit when S = Standard_Standard;
2370       end loop;
2371
2372       --  Here we will output the message
2373
2374       Error_Msg_Sloc := Sloc (E);
2375
2376       --  Case of with clause
2377
2378       if Nkind (P) = N_With_Clause then
2379          if Ekind (E) = E_Package then
2380             Error_Msg_NE
2381               ("?with of obsolescent package& declared#", N, E);
2382          elsif Ekind (E) = E_Procedure then
2383             Error_Msg_NE
2384               ("?with of obsolescent procedure& declared#", N, E);
2385          else
2386             Error_Msg_NE
2387               ("?with of obsolescent function& declared#", N, E);
2388          end if;
2389
2390       --  If we do not have a with clause, then ignore any reference to an
2391       --  obsolescent package name. We only want to give the one warning of
2392       --  withing the package, not one each time it is used to qualify.
2393
2394       elsif Ekind (E) = E_Package then
2395          return;
2396
2397       --  Procedure call statement
2398
2399       elsif Nkind (P) = N_Procedure_Call_Statement then
2400          Error_Msg_NE
2401            ("?call to obsolescent procedure& declared#", N, E);
2402
2403       --  Function call
2404
2405       elsif Nkind (P) = N_Function_Call then
2406          Error_Msg_NE
2407            ("?call to obsolescent function& declared#", N, E);
2408
2409       --  Reference to obsolescent type
2410
2411       elsif Is_Type (E) then
2412          Error_Msg_NE
2413            ("?reference to obsolescent type& declared#", N, E);
2414
2415       --  Reference to obsolescent component
2416
2417       elsif Ekind (E) = E_Component
2418         or else Ekind (E) = E_Discriminant
2419       then
2420          Error_Msg_NE
2421            ("?reference to obsolescent component& declared#", N, E);
2422
2423       --  Reference to obsolescent variable
2424
2425       elsif Ekind (E) = E_Variable then
2426          Error_Msg_NE
2427            ("?reference to obsolescent variable& declared#", N, E);
2428
2429       --  Reference to obsolescent constant
2430
2431       elsif Ekind (E) = E_Constant
2432         or else Ekind (E) in Named_Kind
2433       then
2434          Error_Msg_NE
2435            ("?reference to obsolescent constant& declared#", N, E);
2436
2437       --  Reference to obsolescent enumeration literal
2438
2439       elsif Ekind (E) = E_Enumeration_Literal then
2440          Error_Msg_NE
2441            ("?reference to obsolescent enumeration literal& declared#", N, E);
2442
2443       --  Generic message for any other case we missed
2444
2445       else
2446          Error_Msg_NE
2447            ("?reference to obsolescent entity& declared#", N, E);
2448       end if;
2449
2450       --  Output additional warning if present
2451
2452       declare
2453          W : constant Node_Id := Obsolescent_Warning (E);
2454
2455       begin
2456          if Present (W) then
2457
2458             --  This is a warning continuation to start on a new line
2459             Name_Buffer (1) := '\';
2460             Name_Buffer (2) := '\';
2461             Name_Buffer (3) := '?';
2462             Name_Len := 3;
2463
2464             --  Add characters to message, and output message. Note that
2465             --  we quote every character of the message since we don't
2466             --  want to process any insertions.
2467
2468             for J in 1 .. String_Length (Strval (W)) loop
2469                Add_Char_To_Name_Buffer (''');
2470                Add_Char_To_Name_Buffer
2471                  (Get_Character (Get_String_Char (Strval (W), J)));
2472             end loop;
2473
2474             Error_Msg_N (Name_Buffer (1 .. Name_Len), N);
2475          end if;
2476       end;
2477    end Output_Obsolescent_Entity_Warnings;
2478
2479    ----------------------------------
2480    -- Output_Unreferenced_Messages --
2481    ----------------------------------
2482
2483    procedure Output_Unreferenced_Messages is
2484    begin
2485       for J in Unreferenced_Entities.First ..
2486                Unreferenced_Entities.Last
2487       loop
2488          Warn_On_Unreferenced_Entity (Unreferenced_Entities.Table (J));
2489       end loop;
2490    end Output_Unreferenced_Messages;
2491
2492    ---------------------------
2493    -- Referenced_Check_Spec --
2494    ---------------------------
2495
2496    function Referenced_Check_Spec (E : Entity_Id) return Boolean is
2497    begin
2498       if Is_Formal (E) and then Present (Spec_Entity (E)) then
2499          return Referenced (E) or else Referenced (Spec_Entity (E));
2500       else
2501          return Referenced (E);
2502       end if;
2503    end Referenced_Check_Spec;
2504
2505    ----------------------------------
2506    -- Referenced_As_LHS_Check_Spec --
2507    ----------------------------------
2508
2509    function Referenced_As_LHS_Check_Spec (E : Entity_Id) return Boolean is
2510    begin
2511       if Is_Formal (E) and then Present (Spec_Entity (E)) then
2512          return Referenced_As_LHS (E)
2513            or else Referenced_As_LHS (Spec_Entity (E));
2514       else
2515          return Referenced_As_LHS (E);
2516       end if;
2517    end Referenced_As_LHS_Check_Spec;
2518
2519    ----------------------------
2520    -- Set_Dot_Warning_Switch --
2521    ----------------------------
2522
2523    function Set_Dot_Warning_Switch (C : Character) return Boolean is
2524    begin
2525       case C is
2526          when 'c' =>
2527             Warn_On_Unrepped_Components         := True;
2528
2529          when 'C' =>
2530             Warn_On_Unrepped_Components         := False;
2531
2532          when 'r' =>
2533             Warn_On_Object_Renames_Function     := True;
2534
2535          when 'R' =>
2536             Warn_On_Object_Renames_Function     := False;
2537
2538          when 'x' =>
2539             Warn_On_Non_Local_Exception         := True;
2540
2541          when 'X' =>
2542             Warn_On_Non_Local_Exception         := False;
2543
2544          when others =>
2545             return False;
2546       end case;
2547
2548       return True;
2549    end Set_Dot_Warning_Switch;
2550
2551    ------------------------
2552    -- Set_Warning_Switch --
2553    ------------------------
2554
2555    function Set_Warning_Switch (C : Character) return Boolean is
2556    begin
2557       case C is
2558          when 'a' =>
2559             Check_Unreferenced                  := True;
2560             Check_Unreferenced_Formals          := True;
2561             Check_Withs                         := True;
2562             Constant_Condition_Warnings         := True;
2563             Implementation_Unit_Warnings        := True;
2564             Ineffective_Inline_Warnings         := True;
2565             Warn_On_Ada_2005_Compatibility      := True;
2566             Warn_On_Assumed_Low_Bound           := True;
2567             Warn_On_Bad_Fixed_Value             := True;
2568             Warn_On_Constant                    := True;
2569             Warn_On_Export_Import               := True;
2570             Warn_On_Modified_Unread             := True;
2571             Warn_On_No_Value_Assigned           := True;
2572             Warn_On_Non_Local_Exception         := True;
2573             Warn_On_Obsolescent_Feature         := True;
2574             Warn_On_Questionable_Missing_Parens := True;
2575             Warn_On_Redundant_Constructs        := True;
2576             Warn_On_Object_Renames_Function     := True;
2577             Warn_On_Unchecked_Conversion        := True;
2578             Warn_On_Unrecognized_Pragma         := True;
2579             Warn_On_Unrepped_Components         := True;
2580
2581          when 'A' =>
2582             Check_Unreferenced                  := False;
2583             Check_Unreferenced_Formals          := False;
2584             Check_Withs                         := False;
2585             Constant_Condition_Warnings         := False;
2586             Elab_Warnings                       := False;
2587             Implementation_Unit_Warnings        := False;
2588             Ineffective_Inline_Warnings         := False;
2589             Warn_On_Ada_2005_Compatibility      := False;
2590             Warn_On_Bad_Fixed_Value             := False;
2591             Warn_On_Constant                    := False;
2592             Warn_On_Deleted_Code                := False;
2593             Warn_On_Dereference                 := False;
2594             Warn_On_Export_Import               := False;
2595             Warn_On_Hiding                      := False;
2596             Warn_On_Modified_Unread             := False;
2597             Warn_On_No_Value_Assigned           := False;
2598             Warn_On_Non_Local_Exception         := False;
2599             Warn_On_Obsolescent_Feature         := False;
2600             Warn_On_Questionable_Missing_Parens := False;
2601             Warn_On_Redundant_Constructs        := False;
2602             Warn_On_Object_Renames_Function     := False;
2603             Warn_On_Unchecked_Conversion        := False;
2604             Warn_On_Unrecognized_Pragma         := False;
2605             Warn_On_Unrepped_Components         := False;
2606
2607          when 'b' =>
2608             Warn_On_Bad_Fixed_Value             := True;
2609
2610          when 'B' =>
2611             Warn_On_Bad_Fixed_Value             := False;
2612
2613          when 'c' =>
2614             Constant_Condition_Warnings         := True;
2615
2616          when 'C' =>
2617             Constant_Condition_Warnings         := False;
2618
2619          when 'd' =>
2620             Warn_On_Dereference                 := True;
2621
2622          when 'D' =>
2623             Warn_On_Dereference                 := False;
2624
2625          when 'e' =>
2626             Warning_Mode                        := Treat_As_Error;
2627
2628          when 'f' =>
2629             Check_Unreferenced_Formals          := True;
2630
2631          when 'F' =>
2632             Check_Unreferenced_Formals          := False;
2633
2634          when 'g' =>
2635             Warn_On_Unrecognized_Pragma         := True;
2636
2637          when 'G' =>
2638             Warn_On_Unrecognized_Pragma         := False;
2639
2640          when 'h' =>
2641             Warn_On_Hiding                      := True;
2642
2643          when 'H' =>
2644             Warn_On_Hiding                      := False;
2645
2646          when 'i' =>
2647             Implementation_Unit_Warnings        := True;
2648
2649          when 'I' =>
2650             Implementation_Unit_Warnings        := False;
2651
2652          when 'j' =>
2653             Warn_On_Obsolescent_Feature         := True;
2654
2655          when 'J' =>
2656             Warn_On_Obsolescent_Feature         := False;
2657
2658          when 'k' =>
2659             Warn_On_Constant                    := True;
2660
2661          when 'K' =>
2662             Warn_On_Constant                    := False;
2663
2664          when 'l' =>
2665             Elab_Warnings                       := True;
2666
2667          when 'L' =>
2668             Elab_Warnings                       := False;
2669
2670          when 'm' =>
2671             Warn_On_Modified_Unread             := True;
2672
2673          when 'M' =>
2674             Warn_On_Modified_Unread             := False;
2675
2676          when 'n' =>
2677             Warning_Mode                        := Normal;
2678
2679          when 'o' =>
2680             Address_Clause_Overlay_Warnings     := True;
2681
2682          when 'O' =>
2683             Address_Clause_Overlay_Warnings     := False;
2684
2685          when 'p' =>
2686             Ineffective_Inline_Warnings         := True;
2687
2688          when 'P' =>
2689             Ineffective_Inline_Warnings         := False;
2690
2691          when 'q' =>
2692             Warn_On_Questionable_Missing_Parens := True;
2693
2694          when 'Q' =>
2695             Warn_On_Questionable_Missing_Parens := False;
2696
2697          when 'r' =>
2698             Warn_On_Redundant_Constructs        := True;
2699
2700          when 'R' =>
2701             Warn_On_Redundant_Constructs        := False;
2702
2703          when 's' =>
2704             Warning_Mode                        := Suppress;
2705
2706          when 't' =>
2707             Warn_On_Deleted_Code                := True;
2708
2709          when 'T' =>
2710             Warn_On_Deleted_Code                := False;
2711
2712          when 'u' =>
2713             Check_Unreferenced                  := True;
2714             Check_Withs                         := True;
2715             Check_Unreferenced_Formals          := True;
2716
2717          when 'U' =>
2718             Check_Unreferenced                  := False;
2719             Check_Withs                         := False;
2720             Check_Unreferenced_Formals          := False;
2721
2722          when 'v' =>
2723             Warn_On_No_Value_Assigned           := True;
2724
2725          when 'V' =>
2726             Warn_On_No_Value_Assigned           := False;
2727
2728          when 'w' =>
2729             Warn_On_Assumed_Low_Bound           := True;
2730
2731          when 'W' =>
2732             Warn_On_Assumed_Low_Bound           := False;
2733
2734          when 'x' =>
2735             Warn_On_Export_Import               := True;
2736
2737          when 'X' =>
2738             Warn_On_Export_Import               := False;
2739
2740          when 'y' =>
2741             Warn_On_Ada_2005_Compatibility      := True;
2742
2743          when 'Y' =>
2744             Warn_On_Ada_2005_Compatibility      := False;
2745
2746          when 'z' =>
2747             Warn_On_Unchecked_Conversion        := True;
2748
2749          when 'Z' =>
2750             Warn_On_Unchecked_Conversion        := False;
2751
2752          when others =>
2753             return False;
2754       end case;
2755
2756       return True;
2757    end Set_Warning_Switch;
2758
2759    -----------------------------
2760    -- Warn_On_Known_Condition --
2761    -----------------------------
2762
2763    procedure Warn_On_Known_Condition (C : Node_Id) is
2764       P : Node_Id;
2765
2766       procedure Track (N : Node_Id; Loc : Node_Id);
2767       --  Adds continuation warning(s) pointing to reason (assignment or test)
2768       --  for the operand of the conditional having a known value (or at least
2769       --  enough is known about the value to issue the warning). N is the node
2770       --  which is judged to have a known value. Loc is the warning location.
2771
2772       -----------
2773       -- Track --
2774       -----------
2775
2776       procedure Track (N : Node_Id; Loc : Node_Id) is
2777          Nod : constant Node_Id := Original_Node (N);
2778
2779       begin
2780          if Nkind (Nod) in N_Op_Compare then
2781             Track (Left_Opnd (Nod), Loc);
2782             Track (Right_Opnd (Nod), Loc);
2783
2784          elsif Is_Entity_Name (Nod)
2785            and then Is_Object (Entity (Nod))
2786          then
2787             declare
2788                CV : constant Node_Id := Current_Value (Entity (Nod));
2789
2790             begin
2791                if Present (CV) then
2792                   Error_Msg_Sloc := Sloc (CV);
2793
2794                   if Nkind (CV) not in N_Subexpr then
2795                      Error_Msg_N ("\\?(see test #)", Loc);
2796
2797                   elsif Nkind (Parent (CV)) =
2798                           N_Case_Statement_Alternative
2799                   then
2800                      Error_Msg_N ("\\?(see case alternative #)", Loc);
2801
2802                   else
2803                      Error_Msg_N ("\\?(see assignment #)", Loc);
2804                   end if;
2805                end if;
2806             end;
2807          end if;
2808       end Track;
2809
2810    --  Start of processing for Warn_On_Known_Condition
2811
2812    begin
2813       --   Argument replacement in an inlined body can make conditions static.
2814       --   Do not emit warnings in this case.
2815
2816       if In_Inlined_Body then
2817          return;
2818       end if;
2819
2820       if Constant_Condition_Warnings
2821         and then Nkind (C) = N_Identifier
2822         and then
2823           (Entity (C) = Standard_False or else Entity (C) = Standard_True)
2824         and then Comes_From_Source (Original_Node (C))
2825         and then not In_Instance
2826       then
2827          --  See if this is in a statement or a declaration
2828
2829          P := Parent (C);
2830          loop
2831             --  If tree is not attached, do not issue warning (this is very
2832             --  peculiar, and probably arises from some other error condition)
2833
2834             if No (P) then
2835                return;
2836
2837             --  If we are in a declaration, then no warning, since in practice
2838             --  conditionals in declarations are used for intended tests which
2839             --  may be known at compile time, e.g. things like
2840
2841             --    x : constant Integer := 2 + (Word'Size = 32);
2842
2843             --  And a warning is annoying in such cases
2844
2845             elsif Nkind (P) in N_Declaration
2846                     or else
2847                   Nkind (P) in N_Later_Decl_Item
2848             then
2849                return;
2850
2851             --  Don't warn in assert pragma, since presumably tests in such
2852             --  a context are very definitely intended, and might well be
2853             --  known at compile time. Note that we have to test the original
2854             --  node, since assert pragmas get rewritten at analysis time.
2855
2856             elsif Nkind (Original_Node (P)) = N_Pragma
2857               and then Chars (Original_Node (P)) = Name_Assert
2858             then
2859                return;
2860             end if;
2861
2862             exit when Is_Statement (P);
2863             P := Parent (P);
2864          end loop;
2865
2866          --  Here we issue the warning unless some sub-operand has warnings
2867          --  set off, in which case we suppress the warning for the node. If
2868          --  the original expression is an inequality, it has been expanded
2869          --  into a negation, and the value of the original expression is the
2870          --  negation of the equality. If the expression is an entity that
2871          --  appears within a negation, it is clearer to flag the negation
2872          --  itself, and report on its constant value.
2873
2874          if not Operand_Has_Warnings_Suppressed (C) then
2875             declare
2876                True_Branch : Boolean := Entity (C) = Standard_True;
2877                Cond        : Node_Id := C;
2878
2879             begin
2880                if Present (Parent (C))
2881                  and then Nkind (Parent (C)) = N_Op_Not
2882                then
2883                   True_Branch := not True_Branch;
2884                   Cond        := Parent (C);
2885                end if;
2886
2887                if True_Branch then
2888                   if Is_Entity_Name (Original_Node (C))
2889                     and then Nkind (Cond) /= N_Op_Not
2890                   then
2891                      Error_Msg_NE
2892                        ("object & is always True?", Cond, Original_Node (C));
2893                      Track (Original_Node (C), Cond);
2894
2895                   else
2896                      Error_Msg_N ("condition is always True?", Cond);
2897                      Track (Cond, Cond);
2898                   end if;
2899
2900                else
2901                   Error_Msg_N ("condition is always False?", Cond);
2902                   Track (Cond, Cond);
2903                end if;
2904             end;
2905          end if;
2906       end if;
2907    end Warn_On_Known_Condition;
2908
2909    ------------------------------
2910    -- Warn_On_Suspicious_Index --
2911    ------------------------------
2912
2913    procedure Warn_On_Suspicious_Index (Name : Entity_Id; X : Node_Id) is
2914
2915       Low_Bound : Uint;
2916       --  Set to lower bound for a suspicious type
2917
2918       Ent : Entity_Id;
2919       --  Entity for array reference
2920
2921       Typ : Entity_Id;
2922       --  Array type
2923
2924       function Is_Suspicious_Type (Typ : Entity_Id) return Boolean;
2925       --  Tests to see if Typ is a type for which we may have a suspicious
2926       --  index, namely an unconstrained array type, whose lower bound is
2927       --  either zero or one. If so, True is returned, and Low_Bound is set
2928       --  to this lower bound. If not, False is returned, and Low_Bound is
2929       --  undefined on return.
2930       --
2931       --  For now, we limite this to standard string types, so any other
2932       --  unconstrained types return False. We may change our minds on this
2933       --  later on, but strings seem the most important case.
2934
2935       procedure Test_Suspicious_Index;
2936       --  Test if index is of suspicious type and if so, generate warning
2937
2938       ------------------------
2939       -- Is_Suspicious_Type --
2940       ------------------------
2941
2942       function Is_Suspicious_Type (Typ : Entity_Id) return Boolean is
2943          LB : Node_Id;
2944
2945       begin
2946          if Is_Array_Type (Typ)
2947            and then not Is_Constrained (Typ)
2948            and then Number_Dimensions (Typ) = 1
2949            and then not Warnings_Off (Typ)
2950            and then (Root_Type (Typ) = Standard_String
2951                        or else
2952                      Root_Type (Typ) = Standard_Wide_String
2953                        or else
2954                      Root_Type (Typ) = Standard_Wide_Wide_String)
2955          then
2956             LB := Type_Low_Bound (Etype (First_Index (Typ)));
2957
2958             if Compile_Time_Known_Value (LB) then
2959                Low_Bound := Expr_Value (LB);
2960                return Low_Bound = Uint_0 or else Low_Bound = Uint_1;
2961             end if;
2962          end if;
2963
2964          return False;
2965       end Is_Suspicious_Type;
2966
2967       ---------------------------
2968       -- Test_Suspicious_Index --
2969       ---------------------------
2970
2971       procedure Test_Suspicious_Index is
2972
2973          function Length_Reference (N : Node_Id) return Boolean;
2974          --  Check if node N is of the form Name'Length
2975
2976          procedure Warn1;
2977          --  Generate first warning line
2978
2979          ----------------------
2980          -- Length_Reference --
2981          ----------------------
2982
2983          function Length_Reference (N : Node_Id) return Boolean is
2984             R : constant Node_Id := Original_Node (N);
2985          begin
2986             return
2987               Nkind (R) = N_Attribute_Reference
2988                and then Attribute_Name (R) = Name_Length
2989                and then Is_Entity_Name (Prefix (R))
2990                and then Entity (Prefix (R)) = Ent;
2991          end Length_Reference;
2992
2993          -----------
2994          -- Warn1 --
2995          -----------
2996
2997          procedure Warn1 is
2998          begin
2999             Error_Msg_Uint_1 := Low_Bound;
3000             Error_Msg_FE ("?index for& may assume lower bound of^", X, Ent);
3001          end Warn1;
3002
3003       --  Start of processing for Test_Suspicious_Index
3004
3005       begin
3006          --  Nothing to do if subscript does not come from source (we don't
3007          --  want to give garbage warnings on compiler expanded code, e.g. the
3008          --  loops generated for slice assignments. Sucb junk warnings would
3009          --  be placed on source constructs with no subscript in sight!)
3010
3011          if not Comes_From_Source (Original_Node (X)) then
3012             return;
3013          end if;
3014
3015          --  Case where subscript is a constant integer
3016
3017          if Nkind (X) = N_Integer_Literal then
3018             Warn1;
3019
3020             --  Case where original form of subscript is an integer literal
3021
3022             if Nkind (Original_Node (X)) = N_Integer_Literal then
3023                if Intval (X) = Low_Bound then
3024                   Error_Msg_FE
3025                     ("\suggested replacement: `&''First`", X, Ent);
3026                else
3027                   Error_Msg_Uint_1 := Intval (X) - Low_Bound;
3028                   Error_Msg_FE
3029                     ("\suggested replacement: `&''First + ^`", X, Ent);
3030
3031                end if;
3032
3033             --  Case where original form of subscript is more complex
3034
3035             else
3036                --  Build string X'First - 1 + expression where the expression
3037                --  is the original subscript. If the expression starts with "1
3038                --  + ", then the "- 1 + 1" is elided.
3039
3040                Error_Msg_String (1 .. 13) := "'First - 1 + ";
3041                Error_Msg_Strlen := 13;
3042
3043                declare
3044                   Sref : Source_Ptr := Sloc (First_Node (Original_Node (X)));
3045                   Tref : constant Source_Buffer_Ptr :=
3046                            Source_Text (Get_Source_File_Index (Sref));
3047                   --  Tref (Sref) is used to scan the subscript
3048
3049                   Pctr : Natural;
3050                   --  Paretheses counter when scanning subscript
3051
3052                begin
3053                   --  Tref (Sref) points to start of subscript
3054
3055                   --  Elide - 1 if subscript starts with 1 +
3056
3057                   if Tref (Sref .. Sref + 2) = "1 +" then
3058                      Error_Msg_Strlen := Error_Msg_Strlen - 6;
3059                      Sref := Sref + 2;
3060
3061                   elsif Tref (Sref .. Sref + 1) = "1+" then
3062                      Error_Msg_Strlen := Error_Msg_Strlen - 6;
3063                      Sref := Sref + 1;
3064                   end if;
3065
3066                   --  Now we will copy the subscript to the string buffer
3067
3068                   Pctr := 0;
3069                   loop
3070                      --  Count parens, exit if terminating right paren. Note
3071                      --  check to ignore paren appearing as character literal.
3072
3073                      if Tref (Sref + 1) = '''
3074                           and then
3075                         Tref (Sref - 1) = '''
3076                      then
3077                         null;
3078                      else
3079                         if Tref (Sref) = '(' then
3080                            Pctr := Pctr + 1;
3081                         elsif Tref (Sref) = ')' then
3082                            exit when Pctr = 0;
3083                            Pctr := Pctr - 1;
3084                         end if;
3085                      end if;
3086
3087                      --  Done if terminating double dot (slice case)
3088
3089                      exit when Pctr = 0
3090                        and then (Tref (Sref .. Sref + 1) = ".."
3091                                   or else
3092                                  Tref (Sref .. Sref + 2) = " ..");
3093
3094                      --  Quit if we have hit EOF character, something wrong
3095
3096                      if Tref (Sref) = EOF then
3097                         return;
3098                      end if;
3099
3100                      --  String literals are too much of a pain to handle
3101
3102                      if Tref (Sref) = '"' or else Tref (Sref) = '%' then
3103                         return;
3104                      end if;
3105
3106                      --  If we have a 'Range reference, then this is a case
3107                      --  where we cannot easily give a replacement. Don't try!
3108
3109                      if Tref (Sref .. Sref + 4) = "range"
3110                        and then Tref (Sref - 1) < 'A'
3111                        and then Tref (Sref + 5) < 'A'
3112                      then
3113                         return;
3114                      end if;
3115
3116                      --  Else store next character
3117
3118                      Error_Msg_Strlen := Error_Msg_Strlen + 1;
3119                      Error_Msg_String (Error_Msg_Strlen) := Tref (Sref);
3120                      Sref := Sref + 1;
3121
3122                      --  If we get more than 40 characters then the expression
3123                      --  is too long to copy, or something has gone wrong. In
3124                      --  either case, just skip the attempt at a suggested fix.
3125
3126                      if Error_Msg_Strlen > 40 then
3127                         return;
3128                      end if;
3129                   end loop;
3130                end;
3131
3132                --  Replacement subscript is now in string buffer
3133
3134                Error_Msg_FE
3135                  ("\suggested replacement: `&~`", Original_Node (X), Ent);
3136             end if;
3137
3138          --  Case where subscript is of the form X'Length
3139
3140          elsif Length_Reference (X) then
3141             Warn1;
3142             Error_Msg_Node_2 := Ent;
3143             Error_Msg_FE
3144               ("\suggest replacement of `&''Length` by `&''Last`",
3145                X, Ent);
3146
3147          --  Case where subscript is of the form X'Length - expression
3148
3149          elsif Nkind (X) = N_Op_Subtract
3150            and then Length_Reference (Left_Opnd (X))
3151          then
3152             Warn1;
3153             Error_Msg_Node_2 := Ent;
3154             Error_Msg_FE
3155               ("\suggest replacement of `&''Length` by `&''Last`",
3156                Left_Opnd (X), Ent);
3157          end if;
3158       end Test_Suspicious_Index;
3159
3160    --  Start of processing for Warn_On_Suspicious_Index
3161
3162    begin
3163       --  Only process if warnings activated
3164
3165       if Warn_On_Assumed_Low_Bound then
3166
3167          --  Test if array is simple entity name
3168
3169          if Is_Entity_Name (Name) then
3170
3171             --  Test if array is parameter of unconstrained string type
3172
3173             Ent := Entity (Name);
3174             Typ := Etype (Ent);
3175
3176             if Is_Formal (Ent)
3177               and then Is_Suspicious_Type (Typ)
3178               and then not Low_Bound_Known (Ent)
3179             then
3180                Test_Suspicious_Index;
3181             end if;
3182          end if;
3183       end if;
3184    end Warn_On_Suspicious_Index;
3185
3186    --------------------------------------
3187    -- Warn_On_Unassigned_Out_Parameter --
3188    --------------------------------------
3189
3190    procedure Warn_On_Unassigned_Out_Parameter
3191      (Return_Node : Node_Id;
3192       Scope_Id    : Entity_Id)
3193    is
3194       Form  : Entity_Id;
3195       Form2 : Entity_Id;
3196
3197    begin
3198       --  Ignore if procedure or return statement does not come from source
3199
3200       if not Comes_From_Source (Scope_Id)
3201         or else not Comes_From_Source (Return_Node)
3202       then
3203          return;
3204       end if;
3205
3206       --  Loop through formals
3207
3208       Form := First_Formal (Scope_Id);
3209       while Present (Form) loop
3210
3211          --  We are only interested in OUT parameters that come from source
3212          --  and are never set in the source, and furthermore only in scalars
3213          --  since non-scalars generate too many false positives.
3214
3215          if Ekind (Form) = E_Out_Parameter
3216            and then Never_Set_In_Source_Check_Spec (Form)
3217            and then Is_Scalar_Type (Etype (Form))
3218            and then not Present (Unset_Reference (Form))
3219          then
3220             --  Before we issue the warning, an add ad hoc defence against the
3221             --  most common case of false positives with this warning which is
3222             --  the case where there is a Boolean OUT parameter that has been
3223             --  set, and whose meaning is "ignore the values of the other
3224             --  parameters". We can't of course reliably tell this case at
3225             --  compile time, but the following test kills a lot of false
3226             --  positives, without generating a significant number of false
3227             --  negatives (missed real warnings).
3228
3229             Form2 := First_Formal (Scope_Id);
3230             while Present (Form2) loop
3231                if Ekind (Form2) = E_Out_Parameter
3232                  and then Root_Type (Etype (Form2)) = Standard_Boolean
3233                  and then not Never_Set_In_Source_Check_Spec (Form2)
3234                then
3235                   return;
3236                end if;
3237
3238                Next_Formal (Form2);
3239             end loop;
3240
3241             --  Here all conditionas are met, record possible unset reference
3242
3243             Set_Unset_Reference (Form, Return_Node);
3244          end if;
3245
3246          Next_Formal (Form);
3247       end loop;
3248    end Warn_On_Unassigned_Out_Parameter;
3249
3250    ---------------------------------
3251    -- Warn_On_Unreferenced_Entity --
3252    ---------------------------------
3253
3254    procedure Warn_On_Unreferenced_Entity
3255      (Spec_E : Entity_Id;
3256       Body_E : Entity_Id := Empty)
3257    is
3258       E : Entity_Id := Spec_E;
3259    begin
3260       if not Referenced_Check_Spec (E) and then not Warnings_Off (E) then
3261          case Ekind (E) is
3262             when E_Variable =>
3263
3264                --  Case of variable that is assigned but not read. We
3265                --  suppress the message if the variable is volatile, has an
3266                --  address clause, or is imported.
3267
3268                if Referenced_As_LHS_Check_Spec (E)
3269                  and then No (Address_Clause (E))
3270                  and then not Is_Volatile (E)
3271                then
3272                   if Warn_On_Modified_Unread
3273                     and then not Is_Imported (E)
3274                     and then not Is_Return_Object (E)
3275
3276                      --  Suppress message for aliased or renamed variables,
3277                      --  since there may be other entities that read the
3278                      --  same memory location.
3279
3280                     and then not Is_Aliased (E)
3281                     and then No (Renamed_Object (E))
3282
3283                   then
3284                      Error_Msg_N
3285                        ("?variable & is assigned but never read!", E);
3286                      Set_Last_Assignment (E, Empty);
3287                   end if;
3288
3289                --  Normal case of neither assigned nor read
3290
3291                else
3292                   --  We suppress the message for types for which a valid
3293                   --  pragma Unreferenced_Objects has been given, otherwise
3294                   --  we go ahead and give the message.
3295
3296                   if not Has_Pragma_Unreferenced_Objects (Etype (E)) then
3297
3298                      --  Distinguish renamed case in message
3299
3300                      if Present (Renamed_Object (E))
3301                        and then Comes_From_Source (Renamed_Object (E))
3302                      then
3303                         Error_Msg_N
3304                           ("?renamed variable & is not referenced!", E);
3305                      else
3306                         Error_Msg_N
3307                           ("?variable & is not referenced!", E);
3308                      end if;
3309                   end if;
3310                end if;
3311
3312             when E_Constant =>
3313                if Present (Renamed_Object (E))
3314                  and then Comes_From_Source (Renamed_Object (E))
3315                then
3316                   Error_Msg_N
3317                     ("?renamed constant & is not referenced!", E);
3318                else
3319                   Error_Msg_N ("?constant & is not referenced!", E);
3320                end if;
3321
3322             when E_In_Parameter     |
3323                  E_In_Out_Parameter =>
3324
3325                --  Do not emit message for formals of a renaming, because
3326                --  they are never referenced explicitly.
3327
3328                if Nkind (Original_Node (Unit_Declaration_Node (Scope (E))))
3329                  /= N_Subprogram_Renaming_Declaration
3330                then
3331                   --  Suppress this message for an IN OUT parameter of a
3332                   --  non-scalar type, since it is normal to have only an
3333                   --  assignment in such a case.
3334
3335                   if Ekind (E) = E_In_Parameter
3336                     or else not Referenced_As_LHS_Check_Spec (E)
3337                     or else Is_Scalar_Type (E)
3338                   then
3339                      if Present (Body_E) then
3340                         E := Body_E;
3341                      end if;
3342                      Error_Msg_NE
3343                        ("?formal parameter & is not referenced!", E, Spec_E);
3344                   end if;
3345                end if;
3346
3347             when E_Out_Parameter    =>
3348                null;
3349
3350             when E_Named_Integer    |
3351                  E_Named_Real       =>
3352                Error_Msg_N ("?named number & is not referenced!", E);
3353
3354             when E_Enumeration_Literal =>
3355                Error_Msg_N ("?literal & is not referenced!", E);
3356
3357             when E_Function         =>
3358                Error_Msg_N ("?function & is not referenced!", E);
3359
3360             when E_Procedure         =>
3361                Error_Msg_N ("?procedure & is not referenced!", E);
3362
3363             when E_Generic_Procedure =>
3364                Error_Msg_N
3365                  ("?generic procedure & is never instantiated!", E);
3366
3367             when E_Generic_Function  =>
3368                Error_Msg_N
3369                  ("?generic function & is never instantiated!", E);
3370
3371             when Type_Kind          =>
3372                Error_Msg_N ("?type & is not referenced!", E);
3373
3374             when others =>
3375                Error_Msg_N ("?& is not referenced!", E);
3376          end case;
3377
3378          --  Kill warnings on the entity on which the message has been posted
3379
3380          Set_Warnings_Off (E);
3381       end if;
3382    end Warn_On_Unreferenced_Entity;
3383
3384    --------------------------------
3385    -- Warn_On_Useless_Assignment --
3386    --------------------------------
3387
3388    procedure Warn_On_Useless_Assignment
3389      (Ent : Entity_Id;
3390       Loc : Source_Ptr := No_Location)
3391    is
3392       P : Node_Id;
3393       X : Node_Id;
3394
3395       function Check_Ref (N : Node_Id) return Traverse_Result;
3396       --  Used to instantiate Traverse_Func. Returns Abandon if
3397       --  a reference to the entity in question is found.
3398
3399       function Test_No_Refs is new Traverse_Func (Check_Ref);
3400
3401       ---------------
3402       -- Check_Ref --
3403       ---------------
3404
3405       function Check_Ref (N : Node_Id) return Traverse_Result is
3406       begin
3407          --  Check reference to our identifier. We use name equality here
3408          --  because the exception handlers have not yet been analyzed. This
3409          --  is not quite right, but it really does not matter that we fail
3410          --  to output the warning in some obscure cases of name clashes.
3411
3412          if Nkind (N) = N_Identifier
3413            and then Chars (N) = Chars (Ent)
3414          then
3415             return Abandon;
3416          else
3417             return OK;
3418          end if;
3419       end Check_Ref;
3420
3421    --  Start of processing for Warn_On_Useless_Assignment
3422
3423    begin
3424       --  Check if this is a case we want to warn on, a variable with the
3425       --  last assignment field set, with warnings enabled, and which is
3426       --  not imported or exported.
3427
3428       if Ekind (Ent) = E_Variable
3429         and then not Is_Return_Object (Ent)
3430         and then Present (Last_Assignment (Ent))
3431         and then not Warnings_Off (Ent)
3432         and then not Has_Pragma_Unreferenced_Check_Spec (Ent)
3433         and then not Is_Imported (Ent)
3434         and then not Is_Exported (Ent)
3435       then
3436          --  Before we issue the message, check covering exception handlers.
3437          --  Search up tree for enclosing statement sequences and handlers
3438
3439          P := Parent (Last_Assignment (Ent));
3440          while Present (P) loop
3441
3442             --  Something is really wrong if we don't find a handled
3443             --  statement sequence, so just suppress the warning.
3444
3445             if No (P) then
3446                Set_Last_Assignment (Ent, Empty);
3447                return;
3448
3449             --  When we hit a package/subprogram body, issue warning and exit
3450
3451             elsif Nkind (P) = N_Subprogram_Body
3452               or else Nkind (P) = N_Package_Body
3453             then
3454                if Loc = No_Location then
3455                   Error_Msg_NE
3456                     ("?useless assignment to&, value never referenced!",
3457                      Last_Assignment (Ent), Ent);
3458                else
3459                   Error_Msg_Sloc := Loc;
3460                   Error_Msg_NE
3461                     ("?useless assignment to&, value overwritten #!",
3462                      Last_Assignment (Ent), Ent);
3463                end if;
3464
3465                Set_Last_Assignment (Ent, Empty);
3466                return;
3467
3468             --  Enclosing handled sequence of statements
3469
3470             elsif Nkind (P) = N_Handled_Sequence_Of_Statements then
3471
3472                --  Check exception handlers present
3473
3474                if Present (Exception_Handlers (P)) then
3475
3476                   --  If we are not at the top level, we regard an inner
3477                   --  exception handler as a decisive indicator that we should
3478                   --  not generate the warning, since the variable in question
3479                   --  may be acceessed after an exception in the outer block.
3480
3481                   if Nkind (Parent (P)) /= N_Subprogram_Body
3482                     and then Nkind (Parent (P)) /= N_Package_Body
3483                   then
3484                      Set_Last_Assignment (Ent, Empty);
3485                      return;
3486
3487                      --  Otherwise we are at the outer level. An exception
3488                      --  handler is significant only if it references the
3489                      --  variable in question.
3490
3491                   else
3492                      X := First (Exception_Handlers (P));
3493                      while Present (X) loop
3494                         if Test_No_Refs (X) = Abandon then
3495                            Set_Last_Assignment (Ent, Empty);
3496                            return;
3497                         end if;
3498
3499                         X := Next (X);
3500                      end loop;
3501                   end if;
3502                end if;
3503             end if;
3504
3505             P := Parent (P);
3506          end loop;
3507       end if;
3508    end Warn_On_Useless_Assignment;
3509
3510    ---------------------------------
3511    -- Warn_On_Useless_Assignments --
3512    ---------------------------------
3513
3514    procedure Warn_On_Useless_Assignments (E : Entity_Id) is
3515       Ent : Entity_Id;
3516    begin
3517       if Warn_On_Modified_Unread
3518         and then In_Extended_Main_Source_Unit (E)
3519       then
3520          Ent := First_Entity (E);
3521          while Present (Ent) loop
3522             Warn_On_Useless_Assignment (Ent);
3523             Next_Entity (Ent);
3524          end loop;
3525       end if;
3526    end Warn_On_Useless_Assignments;
3527
3528 end Sem_Warn;