gcc/ada/sem_ch7.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M . C H 7                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This package contains the routines to process package specifications and
  28 --  bodies. The most important semantic aspects of package processing are the
  29 --  handling of private and full declarations, and the construction of
  30 --  dispatch tables for tagged types.
  31
  32 with Atree;    use Atree;
  33 with Debug;    use Debug;
  34 with Einfo;    use Einfo;
  35 with Elists;   use Elists;
  36 with Errout;   use Errout;
  37 with Exp_Disp; use Exp_Disp;
  38 with Exp_Dbug; use Exp_Dbug;
  39 with Lib;      use Lib;
  40 with Lib.Xref; use Lib.Xref;
  41 with Namet;    use Namet;
  42 with Nmake;    use Nmake;
  43 with Nlists;   use Nlists;
  44 with Opt;      use Opt;
  45 with Output;   use Output;
  46 with Sem;      use Sem;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch3;  use Sem_Ch3;
  49 with Sem_Ch6;  use Sem_Ch6;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch10; use Sem_Ch10;
  52 with Sem_Ch12; use Sem_Ch12;
  53 with Sem_Util; use Sem_Util;
  54 with Sem_Warn; use Sem_Warn;
  55 with Snames;   use Snames;
  56 with Stand;    use Stand;
  57 with Sinfo;    use Sinfo;
  58 with Sinput;   use Sinput;
  59 with Style;
  60
  61 package body Sem_Ch7 is
  62
  63    -----------------------------------
  64    -- Handling private declarations --
  65    -----------------------------------
  66
  67    --  The principle that each entity has a single defining occurrence clashes
  68    --  with the presence of two separate definitions for private types: the
  69    --  first is the private type declaration, and the second is the full type
  70    --  declaration. It is important that all references to the type point to
  71    --  the same defining occurrence, namely the first one. To enforce the two
  72    --  separate views of the entity, the corresponding information is swapped
  73    --  between the two declarations. Outside of the package, the defining
  74    --  occurrence only contains the private declaration information, while in
  75    --  the private part and the body of the package the defining occurrence
  76    --  contains the full declaration. To simplify the swap, the defining
  77    --  occurrence that currently holds the private declaration points to the
  78    --  full declaration. During semantic processing the defining occurrence
  79    --  also points to a list of private dependents, that is to say access types
  80    --  or composite types whose designated types or component types are
  81    --  subtypes or derived types of the private type in question. After the
  82    --  full declaration has been seen, the private dependents are updated to
  83    --  indicate that they have full definitions.
  84
  85    -----------------------
  86    -- Local Subprograms --
  87    -----------------------
  88
  89    procedure Install_Package_Entity (Id : Entity_Id);
  90    --  Basic procedure for the previous two. Places one entity on its
  91    --  visibility chain, and recurses on the visible part if the entity
  92    --  is an inner package.
  93
  94    function Is_Private_Base_Type (E : Entity_Id) return Boolean;
  95    --  True for a private type that is not a subtype.
  96
  97    function Is_Visible_Dependent (Dep : Entity_Id) return Boolean;
  98    --  If the private dependent is a private type whose full view is
  99    --  derived from the parent type, its full properties are revealed
 100    --  only if we are in the immediate scope of the private dependent.
 101    --  Should this predicate be tightened further???
 102
 103    procedure Declare_Inherited_Private_Subprograms (Id : Entity_Id);
 104    --  Called upon entering the private part of a public child package
 105    --  and the body of a nested package, to potentially declare certain
 106    --  inherited subprograms that were inherited by types in the visible
 107    --  part, but whose declaration was deferred because the parent
 108    --  operation was private and not visible at that point. These
 109    --  subprograms are located by traversing the visible part declarations
 110    --  looking for non-private type extensions and then examining each of
 111    --  the primitive operations of such types to find those that were
 112    --  inherited but declared with a special internal name. Each such
 113    --  operation is now declared as an operation with a normal name (using
 114    --  the name of the parent operation) and replaces the previous implicit
 115    --  operation in the primitive operations list of the type. If the
 116    --  inherited private operation has been overridden, then it's
 117    --  replaced by the overriding operation.
 118
 119    --------------------------
 120    -- Analyze_Package_Body --
 121    --------------------------
 122
 123    procedure Analyze_Package_Body (N : Node_Id) is
 124       Loc              : constant Source_Ptr := Sloc (N);
 125       HSS              : Node_Id;
 126       Body_Id          : Entity_Id;
 127       Spec_Id          : Entity_Id;
 128       Last_Spec_Entity : Entity_Id;
 129       New_N            : Node_Id;
 130       Pack_Decl        : Node_Id;
 131
 132       procedure Install_Composite_Operations (P : Entity_Id);
 133       --  Composite types declared in the current scope may depend on
 134       --  types that were private at the point of declaration, and whose
 135       --  full view is now in  scope. Indicate that the corresponding
 136       --  operations on the composite type are available.
 137
 138       ----------------------------------
 139       -- Install_Composite_Operations --
 140       ----------------------------------
 141
 142       procedure Install_Composite_Operations (P : Entity_Id) is
 143          Id : Entity_Id;
 144
 145       begin
 146          Id := First_Entity (P);
 147
 148          while Present (Id) loop
 149
 150             if Is_Type (Id)
 151               and then (Is_Limited_Composite (Id)
 152                          or else Is_Private_Composite (Id))
 153               and then No (Private_Component (Id))
 154             then
 155                Set_Is_Limited_Composite (Id, False);
 156                Set_Is_Private_Composite (Id, False);
 157             end if;
 158
 159             Next_Entity (Id);
 160          end loop;
 161       end Install_Composite_Operations;
 162
 163    --  Start of processing for Analyze_Package_Body
 164
 165    begin
 166       --  Find corresponding package specification, and establish the
 167       --  current scope. The visible defining entity for the package is the
 168       --  defining occurrence in the spec. On exit from the package body, all
 169       --  body declarations are attached to the defining entity for the body,
 170       --  but the later is never used for name resolution. In this fashion
 171       --  there is only one visible entity that denotes the package.
 172
 173       if Debug_Flag_C then
 174          Write_Str ("====  Compiling package body ");
 175          Write_Name (Chars (Defining_Entity (N)));
 176          Write_Str (" from ");
 177          Write_Location (Loc);
 178          Write_Eol;
 179       end if;
 180
 181       --  Set Body_Id. Note that this Will be reset to point to the
 182       --  generic copy later on in the generic case.
 183
 184       Body_Id := Defining_Entity (N);
 185
 186       if Present (Corresponding_Spec (N)) then
 187
 188          --  Body is body of package instantiation. Corresponding spec
 189          --  has already been set.
 190
 191          Spec_Id := Corresponding_Spec (N);
 192          Pack_Decl := Unit_Declaration_Node (Spec_Id);
 193
 194       else
 195          Spec_Id := Current_Entity_In_Scope (Defining_Entity (N));
 196
 197          if Present (Spec_Id)
 198            and then Is_Package (Spec_Id)
 199          then
 200             Pack_Decl := Unit_Declaration_Node (Spec_Id);
 201
 202             if Nkind (Pack_Decl) = N_Package_Renaming_Declaration then
 203                Error_Msg_N ("cannot supply body for package renaming", N);
 204                return;
 205
 206             elsif Present (Corresponding_Body (Pack_Decl)) then
 207                Error_Msg_N ("redefinition of package body", N);
 208                return;
 209             end if;
 210
 211          else
 212             Error_Msg_N ("missing specification for package body", N);
 213             return;
 214          end if;
 215
 216          if Is_Package (Spec_Id)
 217            and then
 218              (Scope (Spec_Id) = Standard_Standard
 219                or else Is_Child_Unit (Spec_Id))
 220            and then not Unit_Requires_Body (Spec_Id)
 221          then
 222             if Ada_Version = Ada_83 then
 223                Error_Msg_N
 224                  ("optional package body (not allowed in Ada 95)?", N);
 225             else
 226                Error_Msg_N
 227                  ("spec of this package does not allow a body", N);
 228             end if;
 229          end if;
 230       end if;
 231
 232       Set_Is_Compilation_Unit (Body_Id, Is_Compilation_Unit (Spec_Id));
 233       Style.Check_Identifier (Body_Id, Spec_Id);
 234
 235       if Is_Child_Unit (Spec_Id) then
 236          if Nkind (Parent (N)) /= N_Compilation_Unit then
 237             Error_Msg_NE
 238               ("body of child unit& cannot be an inner package", N, Spec_Id);
 239          end if;
 240
 241          Set_Is_Child_Unit (Body_Id);
 242       end if;
 243
 244       --  Generic package case
 245
 246       if Ekind (Spec_Id) = E_Generic_Package then
 247
 248          --  Disable expansion and perform semantic analysis on copy.
 249          --  The unannotated body will be used in all instantiations.
 250
 251          Body_Id := Defining_Entity (N);
 252          Set_Ekind (Body_Id, E_Package_Body);
 253          Set_Scope (Body_Id, Scope (Spec_Id));
 254          Set_Body_Entity (Spec_Id, Body_Id);
 255          Set_Spec_Entity (Body_Id, Spec_Id);
 256
 257          New_N := Copy_Generic_Node (N, Empty, Instantiating => False);
 258          Rewrite (N, New_N);
 259
 260          --  Update Body_Id to point to the copied node for the remainder
 261          --  of the processing.
 262
 263          Body_Id := Defining_Entity (N);
 264          Start_Generic;
 265       end if;
 266
 267       --  The Body_Id is that of the copied node in the generic case, the
 268       --  current node otherwise. Note that N was rewritten above, so we
 269       --  must be sure to get the latest Body_Id value.
 270
 271       Set_Ekind (Body_Id, E_Package_Body);
 272       Set_Body_Entity (Spec_Id, Body_Id);
 273       Set_Spec_Entity (Body_Id, Spec_Id);
 274
 275       --  Defining name for the package body is not a visible entity: Only
 276       --  the defining name for the declaration is visible.
 277
 278       Set_Etype (Body_Id, Standard_Void_Type);
 279       Set_Scope (Body_Id, Scope (Spec_Id));
 280       Set_Corresponding_Spec (N, Spec_Id);
 281       Set_Corresponding_Body (Pack_Decl, Body_Id);
 282
 283       --  The body entity is not used for semantics or code generation, but
 284       --  it is attached to the entity list of the enclosing scope to simplify
 285       --  the listing of back-annotations for the types it main contain.
 286
 287       if Scope (Spec_Id) /= Standard_Standard then
 288          Append_Entity (Body_Id, Scope (Spec_Id));
 289       end if;
 290
 291       --  Indicate that we are currently compiling the body of the package.
 292
 293       Set_In_Package_Body (Spec_Id);
 294       Set_Has_Completion (Spec_Id);
 295       Last_Spec_Entity := Last_Entity (Spec_Id);
 296
 297       New_Scope (Spec_Id);
 298
 299       Set_Categorization_From_Pragmas (N);
 300
 301       Install_Visible_Declarations (Spec_Id);
 302       Install_Private_Declarations (Spec_Id);
 303       Install_Private_With_Clauses (Spec_Id);
 304       Install_Composite_Operations (Spec_Id);
 305
 306       if Ekind (Spec_Id) = E_Generic_Package then
 307          Set_Use (Generic_Formal_Declarations (Pack_Decl));
 308       end if;
 309
 310       Set_Use (Visible_Declarations (Specification (Pack_Decl)));
 311       Set_Use (Private_Declarations (Specification (Pack_Decl)));
 312
 313       --  This is a nested package, so it may be necessary to declare
 314       --  certain inherited subprograms that are not yet visible because
 315       --  the parent type's subprograms are now visible.
 316
 317       if Ekind (Scope (Spec_Id)) = E_Package
 318         and then Scope (Spec_Id) /= Standard_Standard
 319       then
 320          Declare_Inherited_Private_Subprograms (Spec_Id);
 321       end if;
 322
 323       if Present (Declarations (N)) then
 324          Analyze_Declarations (Declarations (N));
 325       end if;
 326
 327       HSS := Handled_Statement_Sequence (N);
 328
 329       if Present (HSS) then
 330          Process_End_Label (HSS, 't', Spec_Id);
 331          Analyze (HSS);
 332
 333          --  Check that elaboration code in a preelaborable package body is
 334          --  empty other than null statements and labels (RM 10.2.1(6)).
 335
 336          Validate_Null_Statement_Sequence (N);
 337       end if;
 338
 339       Validate_Categorization_Dependency (N, Spec_Id);
 340       Check_Completion (Body_Id);
 341
 342       --  Generate start of body reference. Note that we do this fairly late,
 343       --  because the call will use In_Extended_Main_Source_Unit as a check,
 344       --  and we want to make sure that Corresponding_Stub links are set
 345
 346       Generate_Reference (Spec_Id, Body_Id, 'b', Set_Ref => False);
 347
 348       --  For a generic package, collect global references and mark
 349       --  them on the original body so that they are not resolved
 350       --  again at the point of instantiation.
 351
 352       if Ekind (Spec_Id) /= E_Package then
 353          Save_Global_References (Original_Node (N));
 354          End_Generic;
 355       end if;
 356
 357       --  The entities of the package body have so far been chained onto
 358       --  the declaration chain for the spec. That's been fine while we
 359       --  were in the body, since we wanted them to be visible, but now
 360       --  that we are leaving the package body, they are no longer visible,
 361       --  so we remove them from the entity chain of the package spec entity,
 362       --  and copy them to the entity chain of the package body entity, where
 363       --  they will never again be visible.
 364
 365       if Present (Last_Spec_Entity) then
 366          Set_First_Entity (Body_Id, Next_Entity (Last_Spec_Entity));
 367          Set_Next_Entity (Last_Spec_Entity, Empty);
 368          Set_Last_Entity (Body_Id, Last_Entity (Spec_Id));
 369          Set_Last_Entity (Spec_Id, Last_Spec_Entity);
 370
 371       else
 372          Set_First_Entity (Body_Id, First_Entity (Spec_Id));
 373          Set_Last_Entity  (Body_Id, Last_Entity  (Spec_Id));
 374          Set_First_Entity (Spec_Id, Empty);
 375          Set_Last_Entity  (Spec_Id, Empty);
 376       end if;
 377
 378       End_Package_Scope (Spec_Id);
 379
 380       --  All entities declared in body are not visible.
 381
 382       declare
 383          E : Entity_Id;
 384
 385       begin
 386          E := First_Entity (Body_Id);
 387
 388          while Present (E) loop
 389             Set_Is_Immediately_Visible (E, False);
 390             Set_Is_Potentially_Use_Visible (E, False);
 391             Set_Is_Hidden (E);
 392
 393             --  Child units may appear on the entity list (for example if
 394             --  they appear in the context of a subunit) but they are not
 395             --  body entities.
 396
 397             if not Is_Child_Unit (E) then
 398                Set_Is_Package_Body_Entity (E);
 399             end if;
 400
 401             Next_Entity (E);
 402          end loop;
 403       end;
 404
 405       Check_References (Body_Id);
 406
 407       --  For a generic unit, check that the formal parameters are referenced,
 408       --  and that local variables are used, as for regular packages.
 409
 410       if Ekind (Spec_Id) = E_Generic_Package then
 411          Check_References (Spec_Id);
 412       end if;
 413
 414       --  The processing so far has made all entities of the package body
 415       --  public (i.e. externally visible to the linker). This is in general
 416       --  necessary, since inlined or generic bodies, for which code is
 417       --  generated in other units, may need to see these entities. The
 418       --  following loop runs backwards from the end of the entities of the
 419       --  package body making these entities invisible until we reach a
 420       --  referencer, i.e. a declaration that could reference a previous
 421       --  declaration, a generic body or an inlined body, or a stub (which
 422       --  may contain either of these). This is of course an approximation,
 423       --  but it is conservative and definitely correct.
 424
 425       --  We only do this at the outer (library) level non-generic packages.
 426       --  The reason is simply to cut down on the number of external symbols
 427       --  generated, so this is simply an optimization of the efficiency
 428       --  of the compilation process. It has no other effect.
 429
 430       if (Scope (Spec_Id) = Standard_Standard or else Is_Child_Unit (Spec_Id))
 431         and then not Is_Generic_Unit (Spec_Id)
 432         and then Present (Declarations (N))
 433       then
 434          Make_Non_Public_Where_Possible : declare
 435
 436             function Has_Referencer
 437               (L     : List_Id;
 438                Outer : Boolean)
 439                return  Boolean;
 440             --  Traverse the given list of declarations in reverse order.
 441             --  Return True as soon as a referencer is reached. Return
 442             --  False if none is found. The Outer parameter is True for
 443             --  the outer level call, and False for inner level calls for
 444             --  nested packages. If Outer is True, then any entities up
 445             --  to the point of hitting a referencer get their Is_Public
 446             --  flag cleared, so that the entities will be treated as
 447             --  static entities in the C sense, and need not have fully
 448             --  qualified names. For inner levels, we need all names to
 449             --  be fully qualified to deal with the same name appearing
 450             --  in parallel packages (right now this is tied to their
 451             --  being external).
 452
 453             --------------------
 454             -- Has_Referencer --
 455             --------------------
 456
 457             function Has_Referencer
 458               (L     : List_Id;
 459                Outer : Boolean)
 460                return  Boolean
 461             is
 462                D : Node_Id;
 463                E : Entity_Id;
 464                K : Node_Kind;
 465                S : Entity_Id;
 466
 467             begin
 468                if No (L) then
 469                   return False;
 470                end if;
 471
 472                D := Last (L);
 473
 474                while Present (D) loop
 475                   K := Nkind (D);
 476
 477                   if K in N_Body_Stub then
 478                      return True;
 479
 480                   elsif K = N_Subprogram_Body then
 481                      if Acts_As_Spec (D) then
 482                         E := Defining_Entity (D);
 483
 484                         --  An inlined body acts as a referencer. Note also
 485                         --  that we never reset Is_Public for an inlined
 486                         --  subprogram. Gigi requires Is_Public to be set.
 487
 488                         --  Note that we test Has_Pragma_Inline here rather
 489                         --  than Is_Inlined. We are compiling this for a
 490                         --  client, and it is the client who will decide
 491                         --  if actual inlining should occur, so we need to
 492                         --  assume that the procedure could be inlined for
 493                         --  the purpose of accessing global entities.
 494
 495                         if Has_Pragma_Inline (E) then
 496                            return True;
 497                         else
 498                            Set_Is_Public (E, False);
 499                         end if;
 500
 501                      else
 502                         E := Corresponding_Spec (D);
 503
 504                         if Present (E)
 505                           and then (Is_Generic_Unit (E)
 506                                      or else Has_Pragma_Inline (E)
 507                                      or else Is_Inlined (E))
 508                         then
 509                            return True;
 510                         end if;
 511                      end if;
 512
 513                   --  Processing for package bodies
 514
 515                   elsif K = N_Package_Body
 516                     and then Present (Corresponding_Spec (D))
 517                   then
 518                      E := Corresponding_Spec (D);
 519
 520                      --  Generic package body is a referencer. It would
 521                      --  seem that we only have to consider generics that
 522                      --  can be exported, i.e. where the corresponding spec
 523                      --  is the spec of the current package, but because of
 524                      --  nested instantiations, a fully private generic
 525                      --  body may export other private body entities.
 526
 527                      if Is_Generic_Unit (E) then
 528                         return True;
 529
 530                      --  For non-generic package body, recurse into body
 531                      --  unless this is an instance, we ignore instances
 532                      --  since they cannot have references that affect
 533                      --  outer entities.
 534
 535                      elsif not Is_Generic_Instance (E) then
 536                         if Has_Referencer
 537                              (Declarations (D), Outer => False)
 538                         then
 539                            return True;
 540                         end if;
 541                      end if;
 542
 543                   --  Processing for package specs, recurse into declarations.
 544                   --  Again we skip this for the case of generic instances.
 545
 546                   elsif K = N_Package_Declaration then
 547                      S := Specification (D);
 548
 549                      if not Is_Generic_Unit (Defining_Entity (S)) then
 550                         if Has_Referencer
 551                              (Private_Declarations (S), Outer => False)
 552                         then
 553                            return True;
 554                         elsif Has_Referencer
 555                                (Visible_Declarations (S), Outer => False)
 556                         then
 557                            return True;
 558                         end if;
 559                      end if;
 560
 561                   --  Objects and exceptions need not be public if we have
 562                   --  not encountered a referencer so far. We only reset
 563                   --  the flag for outer level entities that are not
 564                   --  imported/exported, and which have no interface name.
 565
 566                   elsif K = N_Object_Declaration
 567                     or else K = N_Exception_Declaration
 568                     or else K = N_Subprogram_Declaration
 569                   then
 570                      E := Defining_Entity (D);
 571
 572                      if Outer
 573                        and then not Is_Imported (E)
 574                        and then not Is_Exported (E)
 575                        and then No (Interface_Name (E))
 576                      then
 577                         Set_Is_Public (E, False);
 578                      end if;
 579                   end if;
 580
 581                   Prev (D);
 582                end loop;
 583
 584                return False;
 585             end Has_Referencer;
 586
 587          --  Start of processing for Make_Non_Public_Where_Possible
 588
 589          begin
 590             declare
 591                Discard : Boolean;
 592                pragma Warnings (Off, Discard);
 593
 594             begin
 595                Discard := Has_Referencer (Declarations (N), Outer => True);
 596             end;
 597          end Make_Non_Public_Where_Possible;
 598       end if;
 599
 600       --  If expander is not active, then here is where we turn off the
 601       --  In_Package_Body flag, otherwise it is turned off at the end of
 602       --  the corresponding expansion routine. If this is an instance body,
 603       --  we need to qualify names of local entities, because the body may
 604       --  have been compiled as a preliminary to another instantiation.
 605
 606       if not Expander_Active then
 607          Set_In_Package_Body (Spec_Id, False);
 608
 609          if Is_Generic_Instance (Spec_Id)
 610            and then Operating_Mode = Generate_Code
 611          then
 612             Qualify_Entity_Names (N);
 613          end if;
 614       end if;
 615    end Analyze_Package_Body;
 616
 617    ---------------------------------
 618    -- Analyze_Package_Declaration --
 619    ---------------------------------
 620
 621    procedure Analyze_Package_Declaration (N : Node_Id) is
 622       Id : constant Node_Id := Defining_Entity (N);
 623       PF : Boolean;
 624
 625    begin
 626       Generate_Definition (Id);
 627       Enter_Name (Id);
 628       Set_Ekind (Id, E_Package);
 629       Set_Etype (Id, Standard_Void_Type);
 630
 631       New_Scope (Id);
 632
 633       PF := Is_Pure (Enclosing_Lib_Unit_Entity);
 634       Set_Is_Pure (Id, PF);
 635
 636       Set_Categorization_From_Pragmas (N);
 637
 638       if Debug_Flag_C then
 639          Write_Str ("====  Compiling package spec ");
 640          Write_Name (Chars (Id));
 641          Write_Str (" from ");
 642          Write_Location (Sloc (N));
 643          Write_Eol;
 644       end if;
 645
 646       Analyze (Specification (N));
 647       Validate_Categorization_Dependency (N, Id);
 648       End_Package_Scope (Id);
 649
 650       --  For a compilation unit, indicate whether it needs a body, and
 651       --  whether elaboration warnings may be meaningful on it.
 652
 653       if Nkind (Parent (N)) = N_Compilation_Unit then
 654          Set_Body_Required (Parent (N), Unit_Requires_Body (Id));
 655
 656          if not Body_Required (Parent (N)) then
 657             Set_Suppress_Elaboration_Warnings (Id);
 658          end if;
 659
 660          Validate_RT_RAT_Component (N);
 661       end if;
 662    end Analyze_Package_Declaration;
 663
 664    -----------------------------------
 665    -- Analyze_Package_Specification --
 666    -----------------------------------
 667
 668    --  Note that this code is shared for the analysis of generic package
 669    --  specs (see Sem_Ch12.Analyze_Generic_Package_Declaration for details).
 670
 671    procedure Analyze_Package_Specification (N : Node_Id) is
 672       Id           : constant Entity_Id  := Defining_Entity (N);
 673       Orig_Decl    : constant Node_Id    := Original_Node (Parent (N));
 674       Vis_Decls    : constant List_Id    := Visible_Declarations (N);
 675       Priv_Decls   : constant List_Id    := Private_Declarations (N);
 676       E            : Entity_Id;
 677       L            : Entity_Id;
 678       Public_Child : Boolean;
 679
 680       procedure Clear_Constants (Id : Entity_Id; FE : Entity_Id);
 681       --  Clears constant indications (Never_Set_In_Source, Constant_Value,
 682       --  and Is_True_Constant) on all variables that are entities of Id,
 683       --  and on the chain whose first element is FE. A recursive call is
 684       --  made for all packages and generic packages.
 685
 686       procedure Generate_Parent_References;
 687       --  For a child unit, generate references to parent units, for
 688       --  GPS navigation purposes.
 689
 690       function Is_Public_Child (Child, Unit : Entity_Id) return Boolean;
 691       --  Child and Unit are entities of compilation units. True if Child
 692       --  is a public child of Parent as defined in 10.1.1
 693
 694       procedure Inspect_Deferred_Constant_Completion;
 695       --  Examines the deferred constants in the private part of the
 696       --  package specification. Emits the error "constant declaration
 697       --  requires initialization expression " if not completed by an
 698       --  import pragma.
 699
 700       ---------------------
 701       -- Clear_Constants --
 702       ---------------------
 703
 704       procedure Clear_Constants (Id : Entity_Id; FE : Entity_Id) is
 705          E : Entity_Id;
 706
 707       begin
 708          --  Ignore package renamings, not interesting and they can
 709          --  cause self referential loops in the code below.
 710
 711          if Nkind (Parent (Id)) = N_Package_Renaming_Declaration then
 712             return;
 713          end if;
 714
 715          --  Note: in the loop below, the check for Next_Entity pointing
 716          --  back to the package entity seems very odd, but it is needed,
 717          --  because this kind of unexpected circularity does occur ???
 718
 719          E := FE;
 720          while Present (E) and then E /= Id loop
 721             if Ekind (E) = E_Variable then
 722                Set_Never_Set_In_Source (E, False);
 723                Set_Is_True_Constant    (E, False);
 724                Set_Current_Value       (E, Empty);
 725                Set_Is_Known_Non_Null   (E, False);
 726
 727             elsif Ekind (E) = E_Package
 728                     or else
 729                   Ekind (E) = E_Generic_Package
 730             then
 731                Clear_Constants (E, First_Entity (E));
 732                Clear_Constants (E, First_Private_Entity (E));
 733             end if;
 734
 735             Next_Entity (E);
 736          end loop;
 737       end Clear_Constants;
 738
 739       --------------------------------
 740       -- Generate_Parent_References --
 741       --------------------------------
 742
 743       procedure Generate_Parent_References is
 744          Decl : constant Node_Id := Parent (N);
 745
 746       begin
 747          if Id = Cunit_Entity (Main_Unit)
 748            or else Parent (Decl) = Library_Unit (Cunit (Main_Unit))
 749          then
 750             Generate_Reference (Id, Scope (Id), 'k', False);
 751
 752          elsif Nkind (Unit (Cunit (Main_Unit))) /= N_Subprogram_Body
 753            and then Nkind (Unit (Cunit (Main_Unit))) /= N_Subunit
 754          then
 755             --  If current unit is an ancestor of main unit, generate
 756             --  a reference to its own parent.
 757
 758             declare
 759                U         : Node_Id;
 760                Main_Spec : Node_Id := Unit (Cunit (Main_Unit));
 761
 762             begin
 763                if Nkind (Main_Spec) = N_Package_Body then
 764                   Main_Spec := Unit (Library_Unit (Cunit (Main_Unit)));
 765                end if;
 766
 767                U := Parent_Spec (Main_Spec);
 768                while Present (U) loop
 769                   if U = Parent (Decl) then
 770                      Generate_Reference (Id, Scope (Id), 'k',  False);
 771                      exit;
 772
 773                   elsif Nkind (Unit (U)) = N_Package_Body then
 774                      exit;
 775
 776                   else
 777                      U := Parent_Spec (Unit (U));
 778                   end if;
 779                end loop;
 780             end;
 781          end if;
 782       end Generate_Parent_References;
 783
 784       ---------------------
 785       -- Is_Public_Child --
 786       ---------------------
 787
 788       function Is_Public_Child (Child, Unit : Entity_Id) return Boolean is
 789       begin
 790          if not Is_Private_Descendant (Child) then
 791             return True;
 792          else
 793             if Child = Unit then
 794                return not Private_Present (
 795                  Parent (Unit_Declaration_Node (Child)));
 796             else
 797                return Is_Public_Child (Scope (Child), Unit);
 798             end if;
 799          end if;
 800       end Is_Public_Child;
 801
 802       --------------------------------------------
 803       --  Inspect_Deferred_Constant_Completion  --
 804       --------------------------------------------
 805
 806       procedure Inspect_Deferred_Constant_Completion is
 807          Decl   : Node_Id;
 808       begin
 809
 810          Decl := First (Priv_Decls);
 811          while Present (Decl) loop
 812
 813             --  Deferred constant signature
 814
 815             if Nkind (Decl) = N_Object_Declaration
 816               and then Constant_Present (Decl)
 817               and then No (Expression (Decl))
 818
 819                --  No need to check internally generated constants
 820
 821               and then Comes_From_Source (Decl)
 822
 823                --  The constant is not completed. A full object declaration
 824                --  or a pragma Import complete a deferred constant.
 825
 826               and then not Has_Completion (Defining_Identifier (Decl))
 827             then
 828                Error_Msg_N
 829                  ("constant declaration requires initialization expression",
 830                  Defining_Identifier (Decl));
 831
 832             end if;
 833
 834             Decl := Next (Decl);
 835          end loop;
 836       end Inspect_Deferred_Constant_Completion;
 837
 838    --  Start of processing for Analyze_Package_Specification
 839
 840    begin
 841       if Present (Vis_Decls) then
 842          Analyze_Declarations (Vis_Decls);
 843       end if;
 844
 845       --  Verify that incomplete types have received full declarations.
 846
 847       E := First_Entity (Id);
 848       while Present (E) loop
 849          if Ekind (E) = E_Incomplete_Type
 850            and then No (Full_View (E))
 851          then
 852             Error_Msg_N ("no declaration in visible part for incomplete}", E);
 853          end if;
 854
 855          Next_Entity (E);
 856       end loop;
 857
 858       if Is_Remote_Call_Interface (Id)
 859          and then Nkind (Parent (Parent (N))) = N_Compilation_Unit
 860       then
 861          Validate_RCI_Declarations (Id);
 862       end if;
 863
 864       --  Save global references in the visible declarations, before
 865       --  installing private declarations of parent unit if there is one,
 866       --  because the privacy status of types defined in the parent will
 867       --  change. This is only relevant for generic child units, but is
 868       --  done in all cases for uniformity.
 869
 870       if Ekind (Id) = E_Generic_Package
 871         and then Nkind (Orig_Decl) = N_Generic_Package_Declaration
 872       then
 873          declare
 874             Orig_Spec : constant Node_Id    := Specification (Orig_Decl);
 875             Save_Priv : constant List_Id := Private_Declarations (Orig_Spec);
 876
 877          begin
 878             Set_Private_Declarations (Orig_Spec, Empty_List);
 879             Save_Global_References   (Orig_Decl);
 880             Set_Private_Declarations (Orig_Spec, Save_Priv);
 881          end;
 882       end if;
 883
 884       --  If package is a public child unit, then make the private
 885       --  declarations of the parent visible.
 886
 887       Public_Child := False;
 888
 889       if Present (Parent_Spec (Parent (N))) then
 890          Generate_Parent_References;
 891
 892          declare
 893             Par       : Entity_Id := Id;
 894             Pack_Decl : Node_Id;
 895
 896          begin
 897             while Scope (Par) /= Standard_Standard
 898               and then Is_Public_Child (Id, Par)
 899             loop
 900                Public_Child := True;
 901                Par := Scope (Par);
 902                Install_Private_Declarations (Par);
 903                Install_Private_With_Clauses (Par);
 904                Pack_Decl := Unit_Declaration_Node (Par);
 905                Set_Use (Private_Declarations (Specification (Pack_Decl)));
 906             end loop;
 907          end;
 908       end if;
 909
 910       if Is_Compilation_Unit (Id) then
 911          Install_Private_With_Clauses (Id);
 912       end if;
 913
 914       --  Analyze private part if present. The flag In_Private_Part is
 915       --  reset in End_Package_Scope.
 916
 917       L := Last_Entity (Id);
 918
 919       if Present (Priv_Decls) then
 920          Set_In_Private_Part (Id);
 921
 922          --  Upon entering a public child's private part, it may be
 923          --  necessary to declare subprograms that were derived in
 924          --  the package visible part but not yet made visible.
 925
 926          if Public_Child then
 927             Declare_Inherited_Private_Subprograms (Id);
 928          end if;
 929
 930          Analyze_Declarations (Priv_Decls);
 931
 932          --  Check the private declarations for incomplete deferred
 933          --  constants.
 934
 935          Inspect_Deferred_Constant_Completion;
 936
 937          --  The first private entity is the immediate follower of the last
 938          --  visible entity, if there was one.
 939
 940          if Present (L) then
 941             Set_First_Private_Entity (Id, Next_Entity (L));
 942          else
 943             Set_First_Private_Entity (Id, First_Entity (Id));
 944          end if;
 945
 946       --  There may be inherited private subprograms that need to be
 947       --  declared, even in the absence of an explicit private part.
 948       --  If there are any public declarations in the package and
 949       --  the package is a public child unit, then an implicit private
 950       --  part is assumed.
 951
 952       elsif Present (L) and then Public_Child then
 953          Set_In_Private_Part (Id);
 954          Declare_Inherited_Private_Subprograms (Id);
 955          Set_First_Private_Entity (Id, Next_Entity (L));
 956       end if;
 957
 958       --  Check rule of 3.6(11), which in general requires
 959       --  waiting till all full types have been seen.
 960
 961       E := First_Entity (Id);
 962       while Present (E) loop
 963          if Ekind (E) = E_Record_Type or else Ekind (E) = E_Array_Type then
 964             Check_Aliased_Component_Types (E);
 965          end if;
 966
 967          Next_Entity (E);
 968       end loop;
 969
 970       if Ekind (Id) = E_Generic_Package
 971         and then Nkind (Orig_Decl) = N_Generic_Package_Declaration
 972         and then Present (Priv_Decls)
 973       then
 974          --  Save global references in private declarations, ignoring the
 975          --  visible declarations that were processed earlier.
 976
 977          declare
 978             Orig_Spec : constant Node_Id := Specification (Orig_Decl);
 979             Save_Vis  : constant List_Id := Visible_Declarations (Orig_Spec);
 980             Save_Form : constant List_Id :=
 981                           Generic_Formal_Declarations (Orig_Decl);
 982
 983          begin
 984             Set_Visible_Declarations        (Orig_Spec, Empty_List);
 985             Set_Generic_Formal_Declarations (Orig_Decl, Empty_List);
 986             Save_Global_References          (Orig_Decl);
 987             Set_Generic_Formal_Declarations (Orig_Decl, Save_Form);
 988             Set_Visible_Declarations        (Orig_Spec, Save_Vis);
 989          end;
 990       end if;
 991
 992       Process_End_Label (N, 'e', Id);
 993
 994       --  For the case of a library level package, we must go through all
 995       --  the entities clearing the indications that the value may be
 996       --  constant and not modified. Why? Because any client of this
 997       --  package may modify these values freely from anywhere. This
 998       --  also applies to any nested packages or generic packages.
 999
1000       --  For now we unconditionally clear constants for packages that
1001       --  are instances of generic packages. The reason is that we do not
1002       --  have the body yet, and we otherwise think things are unreferenced
1003       --  when they are not. This should be fixed sometime (the effect is
1004       --  not terrible, we just lose some warnings, and also some cases
1005       --  of value propagation) ???
1006
1007       if Is_Library_Level_Entity (Id)
1008         or else Is_Generic_Instance (Id)
1009       then
1010          Clear_Constants (Id, First_Entity (Id));
1011          Clear_Constants (Id, First_Private_Entity (Id));
1012       end if;
1013    end Analyze_Package_Specification;
1014
1015    --------------------------------------
1016    -- Analyze_Private_Type_Declaration --
1017    --------------------------------------
1018
1019    procedure Analyze_Private_Type_Declaration (N : Node_Id) is
1020       PF : constant Boolean   := Is_Pure (Enclosing_Lib_Unit_Entity);
1021       Id : constant Entity_Id := Defining_Identifier (N);
1022
1023    begin
1024       Generate_Definition (Id);
1025       Set_Is_Pure         (Id, PF);
1026       Init_Size_Align     (Id);
1027
1028       if (Ekind (Current_Scope) /= E_Package
1029           and then Ekind (Current_Scope) /= E_Generic_Package)
1030         or else In_Private_Part (Current_Scope)
1031       then
1032          Error_Msg_N ("invalid context for private declaration", N);
1033       end if;
1034
1035       New_Private_Type (N, Id, N);
1036       Set_Depends_On_Private (Id);
1037    end Analyze_Private_Type_Declaration;
1038
1039    -------------------------------------------
1040    -- Declare_Inherited_Private_Subprograms --
1041    -------------------------------------------
1042
1043    procedure Declare_Inherited_Private_Subprograms (Id : Entity_Id) is
1044       E              : Entity_Id;
1045       Op_List        : Elist_Id;
1046       Op_Elmt        : Elmt_Id;
1047       Op_Elmt_2      : Elmt_Id;
1048       Prim_Op        : Entity_Id;
1049       New_Op         : Entity_Id := Empty;
1050       Parent_Subp    : Entity_Id;
1051       Found_Explicit : Boolean;
1052       Decl_Privates  : Boolean;
1053
1054       function Has_Overriding_Pragma (Subp : Entity_Id) return Boolean;
1055       --  Check whether a pragma Overriding has been provided for a primitive
1056       --  operation that is found to be overriding in the private part.
1057
1058       function Is_Primitive_Of (T : Entity_Id; S : Entity_Id) return Boolean;
1059       --  Check whether an inherited subprogram is an operation of an
1060       --  untagged derived type.
1061
1062       ---------------------------
1063       -- Has_Overriding_Pragma --
1064       ---------------------------
1065
1066       function Has_Overriding_Pragma (Subp : Entity_Id) return Boolean is
1067          Decl : constant Node_Id := Unit_Declaration_Node (Subp);
1068          Prag : Node_Id;
1069
1070       begin
1071          if No (Decl)
1072            or else Nkind (Decl) /= N_Subprogram_Declaration
1073            or else No (Next (Decl))
1074          then
1075             return False;
1076
1077          else
1078             Prag := Next (Decl);
1079
1080             while Present (Prag)
1081               and then Nkind (Prag) = N_Pragma
1082             loop
1083                if Chars (Prag) = Name_Overriding
1084                  or else Chars (Prag) = Name_Optional_Overriding
1085                then
1086                   return True;
1087                else
1088                   Next (Prag);
1089                end if;
1090             end loop;
1091          end if;
1092
1093          return False;
1094       end Has_Overriding_Pragma;
1095
1096       ---------------------
1097       -- Is_Primitive_Of --
1098       ---------------------
1099
1100       function Is_Primitive_Of (T : Entity_Id; S : Entity_Id) return Boolean is
1101          Formal : Entity_Id;
1102
1103       begin
1104          if Etype (S) = T then
1105             return True;
1106
1107          else
1108             Formal := First_Formal (S);
1109
1110             while Present (Formal) loop
1111                if Etype (Formal) = T then
1112                   return True;
1113                end if;
1114
1115                Next_Formal (Formal);
1116             end loop;
1117
1118             return False;
1119          end if;
1120       end Is_Primitive_Of;
1121
1122    --  Start of processing for Declare_Inherited_Private_Subprograms
1123
1124    begin
1125       E := First_Entity (Id);
1126       while Present (E) loop
1127
1128          --  If the entity is a nonprivate type extension whose parent
1129          --  type is declared in an open scope, then the type may have
1130          --  inherited operations that now need to be made visible.
1131          --  Ditto if the entity is a formal derived type in a child unit.
1132
1133          if ((Is_Derived_Type (E) and then not Is_Private_Type (E))
1134                or else
1135                  (Nkind (Parent (E)) = N_Private_Extension_Declaration
1136                    and then Is_Generic_Type (E)))
1137            and then In_Open_Scopes (Scope (Etype (E)))
1138            and then E = Base_Type (E)
1139          then
1140             if Is_Tagged_Type (E) then
1141                Op_List       := Primitive_Operations (E);
1142                New_Op        := Empty;
1143                Decl_Privates := False;
1144
1145                Op_Elmt := First_Elmt (Op_List);
1146                while Present (Op_Elmt) loop
1147                   Prim_Op := Node (Op_Elmt);
1148
1149                   --  If the primitive operation is an implicit operation
1150                   --  with an internal name whose parent operation has
1151                   --  a normal name, then we now need to either declare the
1152                   --  operation (i.e., make it visible), or replace it
1153                   --  by an overriding operation if one exists.
1154
1155                   if Present (Alias (Prim_Op))
1156                     and then not Comes_From_Source (Prim_Op)
1157                     and then Is_Internal_Name (Chars (Prim_Op))
1158                     and then not Is_Internal_Name (Chars (Alias (Prim_Op)))
1159                   then
1160                      Parent_Subp := Alias (Prim_Op);
1161
1162                      Found_Explicit := False;
1163                      Op_Elmt_2 := Next_Elmt (Op_Elmt);
1164                      while Present (Op_Elmt_2) loop
1165                         if Chars (Node (Op_Elmt_2)) = Chars (Parent_Subp)
1166                           and then Type_Conformant (Prim_Op, Node (Op_Elmt_2))
1167                         then
1168                            --  The private inherited operation has been
1169                            --  overridden by an explicit subprogram, so
1170                            --  change the private op's list element to
1171                            --  designate the explicit so the explicit
1172                            --  one will get the right dispatching slot.
1173
1174                            New_Op := Node (Op_Elmt_2);
1175                            Replace_Elmt (Op_Elmt, New_Op);
1176                            Remove_Elmt (Op_List, Op_Elmt_2);
1177                            Found_Explicit := True;
1178                            Decl_Privates  := True;
1179
1180                            --  If explicit_overriding is in effect, check that
1181                            --  the overriding operation is properly labelled.
1182
1183                            if Explicit_Overriding
1184                              and then Comes_From_Source (New_Op)
1185                               and then not Has_Overriding_Pragma (New_Op)
1186                            then
1187                               Error_Msg_NE
1188                                 ("Missing overriding pragma for&",
1189                                   New_Op, New_Op);
1190                            end if;
1191
1192                            exit;
1193                         end if;
1194
1195                         Next_Elmt (Op_Elmt_2);
1196                      end loop;
1197
1198                      if not Found_Explicit then
1199                         Derive_Subprogram
1200                           (New_Op, Alias (Prim_Op), E, Etype (E));
1201
1202                         pragma Assert
1203                           (Is_Dispatching_Operation (New_Op)
1204                             and then Node (Last_Elmt (Op_List)) = New_Op);
1205
1206                         --  Substitute the new operation for the old one
1207                         --  in the type's primitive operations list. Since
1208                         --  the new operation was also just added to the end
1209                         --  of list, the last element must be removed.
1210
1211                         --  (Question: is there a simpler way of declaring
1212                         --  the operation, say by just replacing the name
1213                         --  of the earlier operation, reentering it in the
1214                         --  in the symbol table (how?), and marking it as
1215                         --  private???)
1216
1217                         Replace_Elmt (Op_Elmt, New_Op);
1218                         Remove_Last_Elmt (Op_List);
1219                         Decl_Privates := True;
1220                      end if;
1221                   end if;
1222
1223                   Next_Elmt (Op_Elmt);
1224                end loop;
1225
1226                --  The type's DT attributes need to be recalculated
1227                --  in the case where private dispatching operations
1228                --  have been added or overridden. Normally this action
1229                --  occurs during type freezing, but we force it here
1230                --  since the type may already have been frozen (e.g.,
1231                --  if the type's package has an empty private part).
1232                --  This can only be done if expansion is active, otherwise
1233                --  Tag may not be present.
1234
1235                if Decl_Privates
1236                  and then Expander_Active
1237                then
1238                   Set_All_DT_Position (E);
1239                end if;
1240
1241             else
1242                --   Non-tagged type, scan forward to locate
1243                --   inherited hidden operations.
1244
1245                Prim_Op := Next_Entity (E);
1246
1247                while Present (Prim_Op) loop
1248                   if Is_Subprogram (Prim_Op)
1249                     and then Present (Alias (Prim_Op))
1250                     and then not Comes_From_Source (Prim_Op)
1251                     and then Is_Internal_Name (Chars (Prim_Op))
1252                     and then not Is_Internal_Name (Chars (Alias (Prim_Op)))
1253                     and then Is_Primitive_Of (E, Prim_Op)
1254                   then
1255                      Derive_Subprogram (New_Op, Alias (Prim_Op), E, Etype (E));
1256                   end if;
1257
1258                   Next_Entity (Prim_Op);
1259                end loop;
1260             end if;
1261          end if;
1262
1263          Next_Entity (E);
1264       end loop;
1265    end Declare_Inherited_Private_Subprograms;
1266
1267    -----------------------
1268    -- End_Package_Scope --
1269    -----------------------
1270
1271    procedure End_Package_Scope (P : Entity_Id) is
1272    begin
1273       Uninstall_Declarations (P);
1274       Pop_Scope;
1275    end End_Package_Scope;
1276
1277    ---------------------------
1278    -- Exchange_Declarations --
1279    ---------------------------
1280
1281    procedure Exchange_Declarations (Id : Entity_Id) is
1282       Full_Id : constant Entity_Id := Full_View (Id);
1283       H1      : constant Entity_Id := Homonym (Id);
1284       Next1   : constant Entity_Id := Next_Entity (Id);
1285       H2      : Entity_Id;
1286       Next2   : Entity_Id;
1287
1288    begin
1289       --  If missing full declaration for type, nothing to exchange
1290
1291       if No (Full_Id) then
1292          return;
1293       end if;
1294
1295       --  Otherwise complete the exchange, and preserve semantic links
1296
1297       Next2 := Next_Entity (Full_Id);
1298       H2    := Homonym (Full_Id);
1299
1300       --  Reset full declaration pointer to reflect the switched entities
1301       --  and readjust the next entity chains.
1302
1303       Exchange_Entities (Id, Full_Id);
1304
1305       Set_Next_Entity (Id, Next1);
1306       Set_Homonym     (Id, H1);
1307
1308       Set_Full_View   (Full_Id, Id);
1309       Set_Next_Entity (Full_Id, Next2);
1310       Set_Homonym     (Full_Id, H2);
1311    end Exchange_Declarations;
1312
1313    ----------------------------
1314    -- Install_Package_Entity --
1315    ----------------------------
1316
1317    procedure Install_Package_Entity (Id : Entity_Id) is
1318    begin
1319       if not Is_Internal (Id) then
1320          if Debug_Flag_E then
1321             Write_Str ("Install: ");
1322             Write_Name (Chars (Id));
1323             Write_Eol;
1324          end if;
1325
1326          if not Is_Child_Unit (Id) then
1327             Set_Is_Immediately_Visible (Id);
1328          end if;
1329
1330       end if;
1331    end Install_Package_Entity;
1332
1333    ----------------------------------
1334    -- Install_Private_Declarations --
1335    ----------------------------------
1336
1337    procedure Install_Private_Declarations (P : Entity_Id) is
1338       Id        : Entity_Id;
1339       Priv_Elmt : Elmt_Id;
1340       Priv      : Entity_Id;
1341       Full      : Entity_Id;
1342
1343    begin
1344       --  First exchange declarations for private types, so that the
1345       --  full declaration is visible. For each private type, we check
1346       --  its Private_Dependents list and also exchange any subtypes of
1347       --  or derived types from it. Finally, if this is a Taft amendment
1348       --  type, the incomplete declaration is irrelevant, and we want to
1349       --  link the eventual full declaration with the original private
1350       --  one so we also skip the exchange.
1351
1352       Id := First_Entity (P);
1353       while Present (Id) and then Id /= First_Private_Entity (P) loop
1354
1355          if Is_Private_Base_Type (Id)
1356            and then Comes_From_Source (Full_View (Id))
1357            and then Present (Full_View (Id))
1358            and then Scope (Full_View (Id)) = Scope (Id)
1359            and then Ekind (Full_View (Id)) /= E_Incomplete_Type
1360          then
1361             --  If there is a use-type clause on the private type, set the
1362             --  full view accordingly.
1363
1364             Set_In_Use (Full_View (Id), In_Use (Id));
1365             Full := Full_View (Id);
1366
1367             if Is_Private_Base_Type (Full)
1368               and then Has_Private_Declaration (Full)
1369               and then Nkind (Parent (Full)) = N_Full_Type_Declaration
1370               and then In_Open_Scopes (Scope (Etype (Full)))
1371               and then In_Package_Body (Current_Scope)
1372               and then not Is_Private_Type (Etype (Full))
1373             then
1374                --  This is the completion of a private type by a derivation
1375                --  from another private type which is not private anymore. This
1376                --  can only happen in a package nested within a child package,
1377                --  when the parent type is defined in the parent unit. At this
1378                --  point the current type is not private either, and we have to
1379                --  install the underlying full view, which is now visible.
1380
1381                if No (Full_View (Full))
1382                  and then Present (Underlying_Full_View (Full))
1383                then
1384                   Set_Full_View (Id, Underlying_Full_View (Full));
1385                   Set_Underlying_Full_View (Full, Empty);
1386                   Set_Is_Frozen (Full_View (Id));
1387                end if;
1388             end if;
1389
1390             Priv_Elmt := First_Elmt (Private_Dependents (Id));
1391
1392             Exchange_Declarations (Id);
1393             Set_Is_Immediately_Visible (Id);
1394
1395             while Present (Priv_Elmt) loop
1396                Priv := Node (Priv_Elmt);
1397
1398                --  Before the exchange, verify that the presence of the
1399                --  Full_View field. It will be empty if the entity
1400                --  has already been installed due to a previous call.
1401
1402                if Present (Full_View (Priv))
1403                  and then Is_Visible_Dependent (Priv)
1404                then
1405
1406                   --  For each subtype that is swapped, we also swap the
1407                   --  reference to it in Private_Dependents, to allow access
1408                   --  to it when we swap them out in End_Package_Scope.
1409
1410                   Replace_Elmt (Priv_Elmt, Full_View (Priv));
1411                   Exchange_Declarations (Priv);
1412                   Set_Is_Immediately_Visible
1413                     (Priv, In_Open_Scopes (Scope (Priv)));
1414                   Set_Is_Potentially_Use_Visible
1415                     (Priv, Is_Potentially_Use_Visible (Node (Priv_Elmt)));
1416                end if;
1417
1418                Next_Elmt (Priv_Elmt);
1419             end loop;
1420          end if;
1421
1422          Next_Entity (Id);
1423       end loop;
1424
1425       --  Next make other declarations in the private part visible as well.
1426
1427       Id := First_Private_Entity (P);
1428
1429       while Present (Id) loop
1430          Install_Package_Entity (Id);
1431          Next_Entity (Id);
1432       end loop;
1433
1434       --  Indicate that the private part is currently visible, so it can be
1435       --  properly reset on exit.
1436
1437       Set_In_Private_Part (P);
1438    end Install_Private_Declarations;
1439
1440    ----------------------------------
1441    -- Install_Visible_Declarations --
1442    ----------------------------------
1443
1444    procedure Install_Visible_Declarations (P : Entity_Id) is
1445       Id : Entity_Id;
1446
1447    begin
1448       Id := First_Entity (P);
1449
1450       while Present (Id) and then Id /= First_Private_Entity (P) loop
1451          Install_Package_Entity (Id);
1452          Next_Entity (Id);
1453       end loop;
1454    end Install_Visible_Declarations;
1455
1456    --------------------------
1457    -- Is_Private_Base_Type --
1458    --------------------------
1459
1460    function Is_Private_Base_Type (E : Entity_Id) return Boolean is
1461    begin
1462       return Ekind (E) = E_Private_Type
1463         or else Ekind (E) = E_Limited_Private_Type
1464         or else Ekind (E) = E_Record_Type_With_Private;
1465    end Is_Private_Base_Type;
1466
1467    --------------------------
1468    -- Is_Visible_Dependent --
1469    --------------------------
1470
1471    function Is_Visible_Dependent (Dep : Entity_Id) return Boolean
1472    is
1473       S : constant Entity_Id := Scope (Dep);
1474
1475    begin
1476       --  Renamings created for actual types have the visibility of the
1477       --  actual.
1478
1479       if Ekind (S) = E_Package
1480         and then Is_Generic_Instance (S)
1481         and then (Is_Generic_Actual_Type (Dep)
1482                    or else Is_Generic_Actual_Type (Full_View (Dep)))
1483       then
1484          return True;
1485
1486       elsif not (Is_Derived_Type (Dep))
1487         and then Is_Derived_Type (Full_View (Dep))
1488       then
1489          --  When instantiating a package body, the scope stack is empty,
1490          --  so check instead whether the dependent type is defined in
1491          --  the same scope as the instance itself.
1492
1493          return In_Open_Scopes (S)
1494            or else (Is_Generic_Instance (Current_Scope)
1495               and then Scope (Dep) = Scope (Current_Scope));
1496       else
1497          return True;
1498       end if;
1499    end Is_Visible_Dependent;
1500
1501    ----------------------------
1502    -- May_Need_Implicit_Body --
1503    ----------------------------
1504
1505    procedure May_Need_Implicit_Body (E : Entity_Id) is
1506       P     : constant Node_Id := Unit_Declaration_Node (E);
1507       S     : constant Node_Id := Parent (P);
1508       B     : Node_Id;
1509       Decls : List_Id;
1510
1511    begin
1512       if not Has_Completion (E)
1513         and then Nkind (P) = N_Package_Declaration
1514         and then Present (Activation_Chain_Entity (P))
1515       then
1516          B :=
1517            Make_Package_Body (Sloc (E),
1518              Defining_Unit_Name => Make_Defining_Identifier (Sloc (E),
1519                Chars => Chars (E)),
1520              Declarations  => New_List);
1521
1522          if Nkind (S) = N_Package_Specification then
1523             if Present (Private_Declarations (S)) then
1524                Decls := Private_Declarations (S);
1525             else
1526                Decls := Visible_Declarations (S);
1527             end if;
1528          else
1529             Decls := Declarations (S);
1530          end if;
1531
1532          Append (B, Decls);
1533          Analyze (B);
1534       end if;
1535    end May_Need_Implicit_Body;
1536
1537    ----------------------
1538    -- New_Private_Type --
1539    ----------------------
1540
1541    procedure New_Private_Type (N : Node_Id; Id : Entity_Id; Def : Node_Id) is
1542    begin
1543       Enter_Name (Id);
1544
1545       if Limited_Present (Def) then
1546          Set_Ekind (Id, E_Limited_Private_Type);
1547       else
1548          Set_Ekind (Id, E_Private_Type);
1549       end if;
1550
1551       Set_Etype              (Id, Id);
1552       Set_Has_Delayed_Freeze (Id);
1553       Set_Is_First_Subtype   (Id);
1554       Init_Size_Align        (Id);
1555
1556       Set_Is_Constrained (Id,
1557         No (Discriminant_Specifications (N))
1558           and then not Unknown_Discriminants_Present (N));
1559
1560       --  Set tagged flag before processing discriminants, to catch
1561       --  illegal usage.
1562
1563       Set_Is_Tagged_Type (Id, Tagged_Present (Def));
1564
1565       Set_Discriminant_Constraint (Id, No_Elist);
1566       Set_Stored_Constraint (Id, No_Elist);
1567
1568       if Present (Discriminant_Specifications (N)) then
1569          New_Scope (Id);
1570          Process_Discriminants (N);
1571          End_Scope;
1572
1573       elsif Unknown_Discriminants_Present (N) then
1574          Set_Has_Unknown_Discriminants (Id);
1575       end if;
1576
1577       Set_Private_Dependents (Id, New_Elmt_List);
1578
1579       if Tagged_Present (Def) then
1580          Set_Ekind                (Id, E_Record_Type_With_Private);
1581          Make_Class_Wide_Type     (Id);
1582          Set_Primitive_Operations (Id, New_Elmt_List);
1583          Set_Is_Abstract          (Id, Abstract_Present (Def));
1584          Set_Is_Limited_Record    (Id, Limited_Present (Def));
1585          Set_Has_Delayed_Freeze   (Id, True);
1586
1587       elsif Abstract_Present (Def) then
1588          Error_Msg_N ("only a tagged type can be abstract", N);
1589       end if;
1590    end New_Private_Type;
1591
1592    ----------------------------
1593    -- Uninstall_Declarations --
1594    ----------------------------
1595
1596    procedure Uninstall_Declarations (P : Entity_Id) is
1597       Decl      : constant Node_Id := Unit_Declaration_Node (P);
1598       Id        : Entity_Id;
1599       Full      : Entity_Id;
1600       Priv_Elmt : Elmt_Id;
1601       Priv_Sub  : Entity_Id;
1602
1603       procedure Preserve_Full_Attributes (Priv, Full : Entity_Id);
1604       --  Copy to the private declaration the attributes of the full view
1605       --  that need to be available for the partial view also.
1606
1607       function Type_In_Use (T : Entity_Id) return Boolean;
1608       --  Check whether type or base type appear in an active use_type clause.
1609
1610       ------------------------------
1611       -- Preserve_Full_Attributes --
1612       ------------------------------
1613
1614       procedure Preserve_Full_Attributes (Priv, Full : Entity_Id) is
1615          Priv_Is_Base_Type : constant Boolean := Priv = Base_Type (Priv);
1616
1617       begin
1618          Set_Size_Info (Priv, (Full));
1619          Set_RM_Size (Priv, RM_Size (Full));
1620          Set_Size_Known_At_Compile_Time (Priv, Size_Known_At_Compile_Time
1621                                                                       (Full));
1622          Set_Is_Volatile       (Priv, Is_Volatile       (Full));
1623          Set_Treat_As_Volatile (Priv, Treat_As_Volatile (Full));
1624
1625          if Referenced (Full) then
1626             Set_Referenced (Priv);
1627          end if;
1628
1629          if Priv_Is_Base_Type then
1630             Set_Is_Controlled (Priv, Is_Controlled (Base_Type (Full)));
1631             Set_Finalize_Storage_Only (Priv, Finalize_Storage_Only
1632                                                            (Base_Type (Full)));
1633             Set_Has_Task (Priv, Has_Task (Base_Type (Full)));
1634             Set_Has_Controlled_Component (Priv, Has_Controlled_Component
1635                                                            (Base_Type (Full)));
1636          end if;
1637
1638          Set_Freeze_Node (Priv, Freeze_Node (Full));
1639
1640          if Is_Tagged_Type (Priv)
1641            and then Is_Tagged_Type (Full)
1642            and then not Error_Posted (Full)
1643          then
1644             if Priv_Is_Base_Type then
1645                Set_Access_Disp_Table (Priv, Access_Disp_Table
1646                                                            (Base_Type (Full)));
1647             end if;
1648
1649             Set_First_Entity (Priv, First_Entity (Full));
1650             Set_Last_Entity  (Priv, Last_Entity (Full));
1651             Set_Has_Discriminants (Priv, Has_Discriminants (Full));
1652          end if;
1653       end Preserve_Full_Attributes;
1654
1655       -----------------
1656       -- Type_In_Use --
1657       -----------------
1658
1659       function Type_In_Use (T : Entity_Id) return Boolean is
1660       begin
1661          return Scope (Base_Type (T)) = P
1662            and then  (In_Use (T) or else In_Use (Base_Type (T)));
1663       end Type_In_Use;
1664
1665    --  Start of processing for Uninstall_Declarations
1666
1667    begin
1668       Id := First_Entity (P);
1669
1670       while Present (Id) and then Id /= First_Private_Entity (P) loop
1671          if Debug_Flag_E then
1672             Write_Str ("unlinking visible entity ");
1673             Write_Int (Int (Id));
1674             Write_Eol;
1675          end if;
1676
1677          --  On  exit from the package scope, we must preserve the visibility
1678          --  established by use clauses in the current scope. Two cases:
1679
1680          --  a) If the entity is an operator, it may be a primitive operator of
1681          --  a type for which there is a visible use-type clause.
1682
1683          --  b) for other entities, their use-visibility is determined by a
1684          --  visible use clause for the package itself. For a generic instance,
1685          --  the instantiation of the formals appears in the visible part,
1686          --  but the formals are private and remain so.
1687
1688          if Ekind (Id) = E_Function
1689            and then  Is_Operator_Symbol_Name (Chars (Id))
1690            and then not Is_Hidden (Id)
1691            and then not Error_Posted (Id)
1692          then
1693             Set_Is_Potentially_Use_Visible (Id,
1694               In_Use (P)
1695               or else Type_In_Use (Etype (Id))
1696               or else Type_In_Use (Etype (First_Formal (Id)))
1697               or else (Present (Next_Formal (First_Formal (Id)))
1698                          and then
1699                            Type_In_Use
1700                              (Etype (Next_Formal (First_Formal (Id))))));
1701          else
1702             Set_Is_Potentially_Use_Visible (Id,
1703               In_Use (P) and not Is_Hidden (Id));
1704          end if;
1705
1706          --  Local entities are not immediately visible outside of the package.
1707
1708          Set_Is_Immediately_Visible (Id, False);
1709
1710          --  If this is a private type with a full view (for example a local
1711          --  subtype of a private type declared elsewhere), ensure that the
1712          --  full view is also removed from visibility: it may be exposed when
1713          --  swapping views in an instantiation.
1714
1715          if Is_Type (Id)
1716            and then Present (Full_View (Id))
1717          then
1718             Set_Is_Immediately_Visible (Full_View (Id), False);
1719          end if;
1720
1721          if Is_Tagged_Type (Id) and then Ekind (Id) = E_Record_Type then
1722             Check_Abstract_Overriding (Id);
1723          end if;
1724
1725          if (Ekind (Id) = E_Private_Type
1726                or else Ekind (Id) = E_Limited_Private_Type)
1727            and then No (Full_View (Id))
1728            and then not Is_Generic_Type (Id)
1729            and then not Is_Derived_Type (Id)
1730          then
1731             Error_Msg_N ("missing full declaration for private type&", Id);
1732
1733          elsif Ekind (Id) = E_Record_Type_With_Private
1734            and then not Is_Generic_Type (Id)
1735            and then No (Full_View (Id))
1736          then
1737             if Nkind (Parent (Id)) = N_Private_Type_Declaration then
1738                Error_Msg_N ("missing full declaration for private type&", Id);
1739             else
1740                Error_Msg_N
1741                  ("missing full declaration for private extension", Id);
1742             end if;
1743
1744          elsif Ekind (Id) = E_Constant
1745            and then No (Constant_Value (Id))
1746            and then No (Full_View (Id))
1747            and then not Is_Imported (Id)
1748            and then (Nkind (Parent (Id)) /= N_Object_Declaration
1749                       or else not No_Initialization (Parent (Id)))
1750          then
1751             if not Has_Private_Declaration (Etype (Id)) then
1752
1753                --  We assume that the user did not not intend a deferred
1754                --  constant declaration, and the expression is just missing.
1755
1756                Error_Msg_N
1757                  ("constant declaration requires initialization expression",
1758                    Parent (Id));
1759
1760                if Is_Limited_Type (Etype (Id)) then
1761                   Error_Msg_N
1762                     ("\else remove keyword CONSTANT from declaration",
1763                     Parent (Id));
1764                end if;
1765
1766             else
1767                Error_Msg_N
1768                   ("missing full declaration for deferred constant ('R'M 7.4)",
1769                      Id);
1770
1771                if Is_Limited_Type (Etype (Id)) then
1772                   Error_Msg_N
1773                     ("\else remove keyword CONSTANT from declaration",
1774                     Parent (Id));
1775                end if;
1776             end if;
1777          end if;
1778
1779          Next_Entity (Id);
1780       end loop;
1781
1782       --  If the specification was installed as the parent of a public child
1783       --  unit, the private declarations were not installed, and there is
1784       --  nothing to do.
1785
1786       if not In_Private_Part (P) then
1787          return;
1788       else
1789          Set_In_Private_Part (P, False);
1790       end if;
1791
1792       --  Make private entities invisible and exchange full and private
1793       --  declarations for private types.
1794
1795       while Present (Id) loop
1796          if Debug_Flag_E then
1797             Write_Str ("unlinking private entity ");
1798             Write_Int (Int (Id));
1799             Write_Eol;
1800          end if;
1801
1802          if Is_Tagged_Type (Id) and then Ekind (Id) = E_Record_Type then
1803             Check_Abstract_Overriding (Id);
1804          end if;
1805
1806          Set_Is_Immediately_Visible (Id, False);
1807
1808          if Is_Private_Base_Type (Id)
1809            and then Present (Full_View (Id))
1810          then
1811             Full := Full_View (Id);
1812
1813             --  If the partial view is not declared in the visible part
1814             --  of the package (as is the case when it is a type derived
1815             --  from some other private type in the private part of the
1816             --  current package), no exchange takes place.
1817
1818             if No (Parent (Id))
1819               or else List_Containing (Parent (Id))
1820                 /= Visible_Declarations (Specification (Decl))
1821             then
1822                goto Next_Id;
1823             end if;
1824
1825             --  The entry in the private part points to the full declaration,
1826             --  which is currently visible. Exchange them so only the private
1827             --  type declaration remains accessible, and link private and
1828             --  full declaration in the opposite direction. Before the actual
1829             --  exchange, we copy back attributes of the full view that
1830             --  must be available to the partial view too.
1831
1832             Preserve_Full_Attributes (Id, Full);
1833
1834             Set_Is_Potentially_Use_Visible (Id, In_Use (P));
1835
1836             if  Is_Indefinite_Subtype (Full)
1837               and then not Is_Indefinite_Subtype (Id)
1838             then
1839                Error_Msg_N
1840                  ("full view of type must be definite subtype", Full);
1841             end if;
1842
1843             Priv_Elmt := First_Elmt (Private_Dependents (Id));
1844             Exchange_Declarations (Id);
1845
1846             --  Swap out the subtypes and derived types of Id that were
1847             --  compiled in this scope, or installed previously by
1848             --  Install_Private_Declarations.
1849             --  Before we do the swap, we verify the presence of the
1850             --  Full_View field which may be empty due to a swap by
1851             --  a previous call to End_Package_Scope (e.g. from the
1852             --  freezing mechanism).
1853
1854             while Present (Priv_Elmt) loop
1855                Priv_Sub := Node (Priv_Elmt);
1856
1857                if Present (Full_View (Priv_Sub)) then
1858
1859                   if Scope (Priv_Sub) = P
1860                      or else not In_Open_Scopes (Scope (Priv_Sub))
1861                   then
1862                      Set_Is_Immediately_Visible (Priv_Sub, False);
1863                   end if;
1864
1865                   if Is_Visible_Dependent (Priv_Sub) then
1866                      Preserve_Full_Attributes
1867                        (Priv_Sub, Full_View (Priv_Sub));
1868                      Replace_Elmt (Priv_Elmt, Full_View (Priv_Sub));
1869                      Exchange_Declarations (Priv_Sub);
1870                   end if;
1871                end if;
1872
1873                Next_Elmt (Priv_Elmt);
1874             end loop;
1875
1876          elsif Ekind (Id) = E_Incomplete_Type
1877            and then No (Full_View (Id))
1878          then
1879             --  Mark Taft amendment types
1880
1881             Set_Has_Completion_In_Body (Id);
1882
1883          elsif not Is_Child_Unit (Id)
1884            and then (not Is_Private_Type (Id)
1885                       or else No (Full_View (Id)))
1886          then
1887             Set_Is_Hidden (Id);
1888             Set_Is_Potentially_Use_Visible (Id, False);
1889          end if;
1890
1891          <<Next_Id>>
1892             Next_Entity (Id);
1893       end loop;
1894    end Uninstall_Declarations;
1895
1896    ------------------------
1897    -- Unit_Requires_Body --
1898    ------------------------
1899
1900    function Unit_Requires_Body (P : Entity_Id) return Boolean is
1901       E : Entity_Id;
1902
1903    begin
1904       --  Imported entity never requires body. Right now, only
1905       --  subprograms can be imported, but perhaps in the future
1906       --  we will allow import of packages.
1907
1908       if Is_Imported (P) then
1909          return False;
1910
1911       --  Body required if library package with pragma Elaborate_Body
1912
1913       elsif Has_Pragma_Elaborate_Body (P) then
1914          return True;
1915
1916       --  Body required if subprogram
1917
1918       elsif Is_Subprogram (P) or else Is_Generic_Subprogram (P) then
1919          return True;
1920
1921       --  Treat a block as requiring a body
1922
1923       elsif Ekind (P) = E_Block then
1924          return True;
1925
1926       elsif Ekind (P) = E_Package
1927         and then Nkind (Parent (P)) = N_Package_Specification
1928         and then Present (Generic_Parent (Parent (P)))
1929       then
1930          declare
1931             G_P : constant Entity_Id := Generic_Parent (Parent (P));
1932
1933          begin
1934             if Has_Pragma_Elaborate_Body (G_P) then
1935                return True;
1936             end if;
1937          end;
1938       end if;
1939
1940       --  Otherwise search entity chain for entity requiring completion.
1941
1942       E := First_Entity (P);
1943       while Present (E) loop
1944
1945          --  Always ignore child units. Child units get added to the entity
1946          --  list of a parent unit, but are not original entities of the
1947          --  parent, and so do not affect whether the parent needs a body.
1948
1949          if Is_Child_Unit (E) then
1950             null;
1951
1952          --  Otherwise test to see if entity requires a completion
1953
1954          elsif (Is_Overloadable (E)
1955                and then Ekind (E) /= E_Enumeration_Literal
1956                and then Ekind (E) /= E_Operator
1957                and then not Is_Abstract (E)
1958                and then not Has_Completion (E))
1959
1960            or else
1961              (Ekind (E) = E_Package
1962                and then E /= P
1963                and then not Has_Completion (E)
1964                and then Unit_Requires_Body (E))
1965
1966            or else
1967              (Ekind (E) = E_Incomplete_Type and then No (Full_View (E)))
1968
1969            or else
1970             ((Ekind (E) = E_Task_Type or else
1971               Ekind (E) = E_Protected_Type)
1972                and then not Has_Completion (E))
1973
1974            or else
1975              (Ekind (E) = E_Generic_Package and then E /= P
1976                and then not Has_Completion (E)
1977                and then Unit_Requires_Body (E))
1978
1979            or else
1980              (Is_Generic_Subprogram (E)
1981                and then not Has_Completion (E))
1982
1983          then
1984             return True;
1985
1986          --  Entity that does not require completion
1987
1988          else
1989             null;
1990          end if;
1991
1992          Next_Entity (E);
1993       end loop;
1994
1995       return False;
1996    end Unit_Requires_Body;
1997
1998 end Sem_Ch7;