gcc/ada/sem_ch7.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M . C H 7                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This package contains the routines to process package specifications and
  28 --  bodies. The most important semantic aspects of package processing are the
  29 --  handling of private and full declarations, and the construction of
  30 --  dispatch tables for tagged types.
  31
  32 with Atree;    use Atree;
  33 with Debug;    use Debug;
  34 with Einfo;    use Einfo;
  35 with Elists;   use Elists;
  36 with Errout;   use Errout;
  37 with Exp_Disp; use Exp_Disp;
  38 with Exp_Dbug; use Exp_Dbug;
  39 with Lib;      use Lib;
  40 with Lib.Xref; use Lib.Xref;
  41 with Namet;    use Namet;
  42 with Nmake;    use Nmake;
  43 with Nlists;   use Nlists;
  44 with Opt;      use Opt;
  45 with Output;   use Output;
  46 with Sem;      use Sem;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch3;  use Sem_Ch3;
  49 with Sem_Ch6;  use Sem_Ch6;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch10; use Sem_Ch10;
  52 with Sem_Ch12; use Sem_Ch12;
  53 with Sem_Util; use Sem_Util;
  54 with Sem_Warn; use Sem_Warn;
  55 with Snames;   use Snames;
  56 with Stand;    use Stand;
  57 with Sinfo;    use Sinfo;
  58 with Sinput;   use Sinput;
  59 with Style;
  60
  61 package body Sem_Ch7 is
  62
  63    -----------------------------------
  64    -- Handling private declarations --
  65    -----------------------------------
  66
  67    --  The principle that each entity has a single defining occurrence clashes
  68    --  with the presence of two separate definitions for private types: the
  69    --  first is the private type declaration, and the second is the full type
  70    --  declaration. It is important that all references to the type point to
  71    --  the same defining occurrence, namely the first one. To enforce the two
  72    --  separate views of the entity, the corresponding information is swapped
  73    --  between the two declarations. Outside of the package, the defining
  74    --  occurrence only contains the private declaration information, while in
  75    --  the private part and the body of the package the defining occurrence
  76    --  contains the full declaration. To simplify the swap, the defining
  77    --  occurrence that currently holds the private declaration points to the
  78    --  full declaration. During semantic processing the defining occurrence
  79    --  also points to a list of private dependents, that is to say access types
  80    --  or composite types whose designated types or component types are
  81    --  subtypes or derived types of the private type in question. After the
  82    --  full declaration has been seen, the private dependents are updated to
  83    --  indicate that they have full definitions.
  84
  85    -----------------------
  86    -- Local Subprograms --
  87    -----------------------
  88
  89    procedure Install_Package_Entity (Id : Entity_Id);
  90    --  Basic procedure for the previous two. Places one entity on its
  91    --  visibility chain, and recurses on the visible part if the entity
  92    --  is an inner package.
  93
  94    function Is_Private_Base_Type (E : Entity_Id) return Boolean;
  95    --  True for a private type that is not a subtype
  96
  97    function Is_Visible_Dependent (Dep : Entity_Id) return Boolean;
  98    --  If the private dependent is a private type whose full view is
  99    --  derived from the parent type, its full properties are revealed
 100    --  only if we are in the immediate scope of the private dependent.
 101    --  Should this predicate be tightened further???
 102
 103    procedure Declare_Inherited_Private_Subprograms (Id : Entity_Id);
 104    --  Called upon entering the private part of a public child package
 105    --  and the body of a nested package, to potentially declare certain
 106    --  inherited subprograms that were inherited by types in the visible
 107    --  part, but whose declaration was deferred because the parent
 108    --  operation was private and not visible at that point. These
 109    --  subprograms are located by traversing the visible part declarations
 110    --  looking for non-private type extensions and then examining each of
 111    --  the primitive operations of such types to find those that were
 112    --  inherited but declared with a special internal name. Each such
 113    --  operation is now declared as an operation with a normal name (using
 114    --  the name of the parent operation) and replaces the previous implicit
 115    --  operation in the primitive operations list of the type. If the
 116    --  inherited private operation has been overridden, then it's
 117    --  replaced by the overriding operation.
 118
 119    --------------------------
 120    -- Analyze_Package_Body --
 121    --------------------------
 122
 123    procedure Analyze_Package_Body (N : Node_Id) is
 124       Loc              : constant Source_Ptr := Sloc (N);
 125       HSS              : Node_Id;
 126       Body_Id          : Entity_Id;
 127       Spec_Id          : Entity_Id;
 128       Last_Spec_Entity : Entity_Id;
 129       New_N            : Node_Id;
 130       Pack_Decl        : Node_Id;
 131
 132       procedure Install_Composite_Operations (P : Entity_Id);
 133       --  Composite types declared in the current scope may depend on
 134       --  types that were private at the point of declaration, and whose
 135       --  full view is now in  scope. Indicate that the corresponding
 136       --  operations on the composite type are available.
 137
 138       ----------------------------------
 139       -- Install_Composite_Operations --
 140       ----------------------------------
 141
 142       procedure Install_Composite_Operations (P : Entity_Id) is
 143          Id : Entity_Id;
 144
 145       begin
 146          Id := First_Entity (P);
 147
 148          while Present (Id) loop
 149
 150             if Is_Type (Id)
 151               and then (Is_Limited_Composite (Id)
 152                          or else Is_Private_Composite (Id))
 153               and then No (Private_Component (Id))
 154             then
 155                Set_Is_Limited_Composite (Id, False);
 156                Set_Is_Private_Composite (Id, False);
 157             end if;
 158
 159             Next_Entity (Id);
 160          end loop;
 161       end Install_Composite_Operations;
 162
 163    --  Start of processing for Analyze_Package_Body
 164
 165    begin
 166       --  Find corresponding package specification, and establish the
 167       --  current scope. The visible defining entity for the package is the
 168       --  defining occurrence in the spec. On exit from the package body, all
 169       --  body declarations are attached to the defining entity for the body,
 170       --  but the later is never used for name resolution. In this fashion
 171       --  there is only one visible entity that denotes the package.
 172
 173       if Debug_Flag_C then
 174          Write_Str ("====  Compiling package body ");
 175          Write_Name (Chars (Defining_Entity (N)));
 176          Write_Str (" from ");
 177          Write_Location (Loc);
 178          Write_Eol;
 179       end if;
 180
 181       --  Set Body_Id. Note that this Will be reset to point to the
 182       --  generic copy later on in the generic case.
 183
 184       Body_Id := Defining_Entity (N);
 185
 186       if Present (Corresponding_Spec (N)) then
 187
 188          --  Body is body of package instantiation. Corresponding spec
 189          --  has already been set.
 190
 191          Spec_Id := Corresponding_Spec (N);
 192          Pack_Decl := Unit_Declaration_Node (Spec_Id);
 193
 194       else
 195          Spec_Id := Current_Entity_In_Scope (Defining_Entity (N));
 196
 197          if Present (Spec_Id)
 198            and then Is_Package_Or_Generic_Package (Spec_Id)
 199          then
 200             Pack_Decl := Unit_Declaration_Node (Spec_Id);
 201
 202             if Nkind (Pack_Decl) = N_Package_Renaming_Declaration then
 203                Error_Msg_N ("cannot supply body for package renaming", N);
 204                return;
 205
 206             elsif Present (Corresponding_Body (Pack_Decl)) then
 207                Error_Msg_N ("redefinition of package body", N);
 208                return;
 209             end if;
 210
 211          else
 212             Error_Msg_N ("missing specification for package body", N);
 213             return;
 214          end if;
 215
 216          if Is_Package_Or_Generic_Package (Spec_Id)
 217            and then
 218              (Scope (Spec_Id) = Standard_Standard
 219                or else Is_Child_Unit (Spec_Id))
 220            and then not Unit_Requires_Body (Spec_Id)
 221          then
 222             if Ada_Version = Ada_83 then
 223                Error_Msg_N
 224                  ("optional package body (not allowed in Ada 95)?", N);
 225             else
 226                Error_Msg_N
 227                  ("spec of this package does not allow a body", N);
 228             end if;
 229          end if;
 230       end if;
 231
 232       Set_Is_Compilation_Unit (Body_Id, Is_Compilation_Unit (Spec_Id));
 233       Style.Check_Identifier (Body_Id, Spec_Id);
 234
 235       if Is_Child_Unit (Spec_Id) then
 236          if Nkind (Parent (N)) /= N_Compilation_Unit then
 237             Error_Msg_NE
 238               ("body of child unit& cannot be an inner package", N, Spec_Id);
 239          end if;
 240
 241          Set_Is_Child_Unit (Body_Id);
 242       end if;
 243
 244       --  Generic package case
 245
 246       if Ekind (Spec_Id) = E_Generic_Package then
 247
 248          --  Disable expansion and perform semantic analysis on copy.
 249          --  The unannotated body will be used in all instantiations.
 250
 251          Body_Id := Defining_Entity (N);
 252          Set_Ekind (Body_Id, E_Package_Body);
 253          Set_Scope (Body_Id, Scope (Spec_Id));
 254          Set_Body_Entity (Spec_Id, Body_Id);
 255          Set_Spec_Entity (Body_Id, Spec_Id);
 256
 257          New_N := Copy_Generic_Node (N, Empty, Instantiating => False);
 258          Rewrite (N, New_N);
 259
 260          --  Update Body_Id to point to the copied node for the remainder
 261          --  of the processing.
 262
 263          Body_Id := Defining_Entity (N);
 264          Start_Generic;
 265       end if;
 266
 267       --  The Body_Id is that of the copied node in the generic case, the
 268       --  current node otherwise. Note that N was rewritten above, so we
 269       --  must be sure to get the latest Body_Id value.
 270
 271       Set_Ekind (Body_Id, E_Package_Body);
 272       Set_Body_Entity (Spec_Id, Body_Id);
 273       Set_Spec_Entity (Body_Id, Spec_Id);
 274
 275       --  Defining name for the package body is not a visible entity: Only
 276       --  the defining name for the declaration is visible.
 277
 278       Set_Etype (Body_Id, Standard_Void_Type);
 279       Set_Scope (Body_Id, Scope (Spec_Id));
 280       Set_Corresponding_Spec (N, Spec_Id);
 281       Set_Corresponding_Body (Pack_Decl, Body_Id);
 282
 283       --  The body entity is not used for semantics or code generation, but
 284       --  it is attached to the entity list of the enclosing scope to simplify
 285       --  the listing of back-annotations for the types it main contain.
 286
 287       if Scope (Spec_Id) /= Standard_Standard then
 288          Append_Entity (Body_Id, Scope (Spec_Id));
 289       end if;
 290
 291       --  Indicate that we are currently compiling the body of the package
 292
 293       Set_In_Package_Body (Spec_Id);
 294       Set_Has_Completion (Spec_Id);
 295       Last_Spec_Entity := Last_Entity (Spec_Id);
 296
 297       New_Scope (Spec_Id);
 298
 299       Set_Categorization_From_Pragmas (N);
 300
 301       Install_Visible_Declarations (Spec_Id);
 302       Install_Private_Declarations (Spec_Id);
 303       Install_Private_With_Clauses (Spec_Id);
 304       Install_Composite_Operations (Spec_Id);
 305
 306       if Ekind (Spec_Id) = E_Generic_Package then
 307          Set_Use (Generic_Formal_Declarations (Pack_Decl));
 308       end if;
 309
 310       Set_Use (Visible_Declarations (Specification (Pack_Decl)));
 311       Set_Use (Private_Declarations (Specification (Pack_Decl)));
 312
 313       --  This is a nested package, so it may be necessary to declare
 314       --  certain inherited subprograms that are not yet visible because
 315       --  the parent type's subprograms are now visible.
 316
 317       if Ekind (Scope (Spec_Id)) = E_Package
 318         and then Scope (Spec_Id) /= Standard_Standard
 319       then
 320          Declare_Inherited_Private_Subprograms (Spec_Id);
 321       end if;
 322
 323       if Present (Declarations (N)) then
 324          Analyze_Declarations (Declarations (N));
 325       end if;
 326
 327       HSS := Handled_Statement_Sequence (N);
 328
 329       if Present (HSS) then
 330          Process_End_Label (HSS, 't', Spec_Id);
 331          Analyze (HSS);
 332
 333          --  Check that elaboration code in a preelaborable package body is
 334          --  empty other than null statements and labels (RM 10.2.1(6)).
 335
 336          Validate_Null_Statement_Sequence (N);
 337       end if;
 338
 339       Validate_Categorization_Dependency (N, Spec_Id);
 340       Check_Completion (Body_Id);
 341
 342       --  Generate start of body reference. Note that we do this fairly late,
 343       --  because the call will use In_Extended_Main_Source_Unit as a check,
 344       --  and we want to make sure that Corresponding_Stub links are set
 345
 346       Generate_Reference (Spec_Id, Body_Id, 'b', Set_Ref => False);
 347
 348       --  For a generic package, collect global references and mark
 349       --  them on the original body so that they are not resolved
 350       --  again at the point of instantiation.
 351
 352       if Ekind (Spec_Id) /= E_Package then
 353          Save_Global_References (Original_Node (N));
 354          End_Generic;
 355       end if;
 356
 357       --  The entities of the package body have so far been chained onto
 358       --  the declaration chain for the spec. That's been fine while we
 359       --  were in the body, since we wanted them to be visible, but now
 360       --  that we are leaving the package body, they are no longer visible,
 361       --  so we remove them from the entity chain of the package spec entity,
 362       --  and copy them to the entity chain of the package body entity, where
 363       --  they will never again be visible.
 364
 365       if Present (Last_Spec_Entity) then
 366          Set_First_Entity (Body_Id, Next_Entity (Last_Spec_Entity));
 367          Set_Next_Entity (Last_Spec_Entity, Empty);
 368          Set_Last_Entity (Body_Id, Last_Entity (Spec_Id));
 369          Set_Last_Entity (Spec_Id, Last_Spec_Entity);
 370
 371       else
 372          Set_First_Entity (Body_Id, First_Entity (Spec_Id));
 373          Set_Last_Entity  (Body_Id, Last_Entity  (Spec_Id));
 374          Set_First_Entity (Spec_Id, Empty);
 375          Set_Last_Entity  (Spec_Id, Empty);
 376       end if;
 377
 378       End_Package_Scope (Spec_Id);
 379
 380       --  All entities declared in body are not visible
 381
 382       declare
 383          E : Entity_Id;
 384
 385       begin
 386          E := First_Entity (Body_Id);
 387
 388          while Present (E) loop
 389             Set_Is_Immediately_Visible (E, False);
 390             Set_Is_Potentially_Use_Visible (E, False);
 391             Set_Is_Hidden (E);
 392
 393             --  Child units may appear on the entity list (for example if
 394             --  they appear in the context of a subunit) but they are not
 395             --  body entities.
 396
 397             if not Is_Child_Unit (E) then
 398                Set_Is_Package_Body_Entity (E);
 399             end if;
 400
 401             Next_Entity (E);
 402          end loop;
 403       end;
 404
 405       Check_References (Body_Id);
 406
 407       --  For a generic unit, check that the formal parameters are referenced,
 408       --  and that local variables are used, as for regular packages.
 409
 410       if Ekind (Spec_Id) = E_Generic_Package then
 411          Check_References (Spec_Id);
 412       end if;
 413
 414       --  The processing so far has made all entities of the package body
 415       --  public (i.e. externally visible to the linker). This is in general
 416       --  necessary, since inlined or generic bodies, for which code is
 417       --  generated in other units, may need to see these entities. The
 418       --  following loop runs backwards from the end of the entities of the
 419       --  package body making these entities invisible until we reach a
 420       --  referencer, i.e. a declaration that could reference a previous
 421       --  declaration, a generic body or an inlined body, or a stub (which
 422       --  may contain either of these). This is of course an approximation,
 423       --  but it is conservative and definitely correct.
 424
 425       --  We only do this at the outer (library) level non-generic packages.
 426       --  The reason is simply to cut down on the number of external symbols
 427       --  generated, so this is simply an optimization of the efficiency
 428       --  of the compilation process. It has no other effect.
 429
 430       if (Scope (Spec_Id) = Standard_Standard or else Is_Child_Unit (Spec_Id))
 431         and then not Is_Generic_Unit (Spec_Id)
 432         and then Present (Declarations (N))
 433       then
 434          Make_Non_Public_Where_Possible : declare
 435
 436             function Has_Referencer
 437               (L     : List_Id;
 438                Outer : Boolean)
 439                return  Boolean;
 440             --  Traverse the given list of declarations in reverse order.
 441             --  Return True as soon as a referencer is reached. Return
 442             --  False if none is found. The Outer parameter is True for
 443             --  the outer level call, and False for inner level calls for
 444             --  nested packages. If Outer is True, then any entities up
 445             --  to the point of hitting a referencer get their Is_Public
 446             --  flag cleared, so that the entities will be treated as
 447             --  static entities in the C sense, and need not have fully
 448             --  qualified names. For inner levels, we need all names to
 449             --  be fully qualified to deal with the same name appearing
 450             --  in parallel packages (right now this is tied to their
 451             --  being external).
 452
 453             --------------------
 454             -- Has_Referencer --
 455             --------------------
 456
 457             function Has_Referencer
 458               (L     : List_Id;
 459                Outer : Boolean)
 460                return  Boolean
 461             is
 462                D : Node_Id;
 463                E : Entity_Id;
 464                K : Node_Kind;
 465                S : Entity_Id;
 466
 467             begin
 468                if No (L) then
 469                   return False;
 470                end if;
 471
 472                D := Last (L);
 473
 474                while Present (D) loop
 475                   K := Nkind (D);
 476
 477                   if K in N_Body_Stub then
 478                      return True;
 479
 480                   elsif K = N_Subprogram_Body then
 481                      if Acts_As_Spec (D) then
 482                         E := Defining_Entity (D);
 483
 484                         --  An inlined body acts as a referencer. Note also
 485                         --  that we never reset Is_Public for an inlined
 486                         --  subprogram. Gigi requires Is_Public to be set.
 487
 488                         --  Note that we test Has_Pragma_Inline here rather
 489                         --  than Is_Inlined. We are compiling this for a
 490                         --  client, and it is the client who will decide
 491                         --  if actual inlining should occur, so we need to
 492                         --  assume that the procedure could be inlined for
 493                         --  the purpose of accessing global entities.
 494
 495                         if Has_Pragma_Inline (E) then
 496                            return True;
 497                         else
 498                            Set_Is_Public (E, False);
 499                         end if;
 500
 501                      else
 502                         E := Corresponding_Spec (D);
 503
 504                         if Present (E)
 505                           and then (Is_Generic_Unit (E)
 506                                      or else Has_Pragma_Inline (E)
 507                                      or else Is_Inlined (E))
 508                         then
 509                            return True;
 510                         end if;
 511                      end if;
 512
 513                   --  Processing for package bodies
 514
 515                   elsif K = N_Package_Body
 516                     and then Present (Corresponding_Spec (D))
 517                   then
 518                      E := Corresponding_Spec (D);
 519
 520                      --  Generic package body is a referencer. It would
 521                      --  seem that we only have to consider generics that
 522                      --  can be exported, i.e. where the corresponding spec
 523                      --  is the spec of the current package, but because of
 524                      --  nested instantiations, a fully private generic
 525                      --  body may export other private body entities.
 526
 527                      if Is_Generic_Unit (E) then
 528                         return True;
 529
 530                      --  For non-generic package body, recurse into body
 531                      --  unless this is an instance, we ignore instances
 532                      --  since they cannot have references that affect
 533                      --  outer entities.
 534
 535                      elsif not Is_Generic_Instance (E) then
 536                         if Has_Referencer
 537                              (Declarations (D), Outer => False)
 538                         then
 539                            return True;
 540                         end if;
 541                      end if;
 542
 543                   --  Processing for package specs, recurse into declarations.
 544                   --  Again we skip this for the case of generic instances.
 545
 546                   elsif K = N_Package_Declaration then
 547                      S := Specification (D);
 548
 549                      if not Is_Generic_Unit (Defining_Entity (S)) then
 550                         if Has_Referencer
 551                              (Private_Declarations (S), Outer => False)
 552                         then
 553                            return True;
 554                         elsif Has_Referencer
 555                                (Visible_Declarations (S), Outer => False)
 556                         then
 557                            return True;
 558                         end if;
 559                      end if;
 560
 561                   --  Objects and exceptions need not be public if we have
 562                   --  not encountered a referencer so far. We only reset
 563                   --  the flag for outer level entities that are not
 564                   --  imported/exported, and which have no interface name.
 565
 566                   elsif K = N_Object_Declaration
 567                     or else K = N_Exception_Declaration
 568                     or else K = N_Subprogram_Declaration
 569                   then
 570                      E := Defining_Entity (D);
 571
 572                      if Outer
 573                        and then not Is_Imported (E)
 574                        and then not Is_Exported (E)
 575                        and then No (Interface_Name (E))
 576                      then
 577                         Set_Is_Public (E, False);
 578                      end if;
 579                   end if;
 580
 581                   Prev (D);
 582                end loop;
 583
 584                return False;
 585             end Has_Referencer;
 586
 587          --  Start of processing for Make_Non_Public_Where_Possible
 588
 589          begin
 590             declare
 591                Discard : Boolean;
 592                pragma Warnings (Off, Discard);
 593
 594             begin
 595                Discard := Has_Referencer (Declarations (N), Outer => True);
 596             end;
 597          end Make_Non_Public_Where_Possible;
 598       end if;
 599
 600       --  If expander is not active, then here is where we turn off the
 601       --  In_Package_Body flag, otherwise it is turned off at the end of
 602       --  the corresponding expansion routine. If this is an instance body,
 603       --  we need to qualify names of local entities, because the body may
 604       --  have been compiled as a preliminary to another instantiation.
 605
 606       if not Expander_Active then
 607          Set_In_Package_Body (Spec_Id, False);
 608
 609          if Is_Generic_Instance (Spec_Id)
 610            and then Operating_Mode = Generate_Code
 611          then
 612             Qualify_Entity_Names (N);
 613          end if;
 614       end if;
 615    end Analyze_Package_Body;
 616
 617    ---------------------------------
 618    -- Analyze_Package_Declaration --
 619    ---------------------------------
 620
 621    procedure Analyze_Package_Declaration (N : Node_Id) is
 622       Id : constant Node_Id := Defining_Entity (N);
 623       PF : Boolean;
 624
 625    begin
 626       --  Ada 2005 (AI-217): Check if the package has been erroneously named
 627       --  in a limited-with clause of its own context. In this case the error
 628       --  has been previously notified by Analyze_Context.
 629
 630       --     limited with Pkg; -- ERROR
 631       --     package Pkg is ...
 632
 633       if From_With_Type (Id) then
 634          return;
 635       end if;
 636
 637       Generate_Definition (Id);
 638       Enter_Name (Id);
 639       Set_Ekind (Id, E_Package);
 640       Set_Etype (Id, Standard_Void_Type);
 641
 642       New_Scope (Id);
 643
 644       PF := Is_Pure (Enclosing_Lib_Unit_Entity);
 645       Set_Is_Pure (Id, PF);
 646
 647       Set_Categorization_From_Pragmas (N);
 648
 649       if Debug_Flag_C then
 650          Write_Str ("====  Compiling package spec ");
 651          Write_Name (Chars (Id));
 652          Write_Str (" from ");
 653          Write_Location (Sloc (N));
 654          Write_Eol;
 655       end if;
 656
 657       Analyze (Specification (N));
 658       Validate_Categorization_Dependency (N, Id);
 659       End_Package_Scope (Id);
 660
 661       --  For a compilation unit, indicate whether it needs a body, and
 662       --  whether elaboration warnings may be meaningful on it.
 663
 664       if Nkind (Parent (N)) = N_Compilation_Unit then
 665          Set_Body_Required (Parent (N), Unit_Requires_Body (Id));
 666
 667          if not Body_Required (Parent (N)) then
 668             Set_Suppress_Elaboration_Warnings (Id);
 669          end if;
 670
 671          Validate_RT_RAT_Component (N);
 672       end if;
 673    end Analyze_Package_Declaration;
 674
 675    -----------------------------------
 676    -- Analyze_Package_Specification --
 677    -----------------------------------
 678
 679    --  Note that this code is shared for the analysis of generic package
 680    --  specs (see Sem_Ch12.Analyze_Generic_Package_Declaration for details).
 681
 682    procedure Analyze_Package_Specification (N : Node_Id) is
 683       Id           : constant Entity_Id  := Defining_Entity (N);
 684       Orig_Decl    : constant Node_Id    := Original_Node (Parent (N));
 685       Vis_Decls    : constant List_Id    := Visible_Declarations (N);
 686       Priv_Decls   : constant List_Id    := Private_Declarations (N);
 687       E            : Entity_Id;
 688       L            : Entity_Id;
 689       Public_Child : Boolean;
 690
 691       procedure Clear_Constants (Id : Entity_Id; FE : Entity_Id);
 692       --  Clears constant indications (Never_Set_In_Source, Constant_Value,
 693       --  and Is_True_Constant) on all variables that are entities of Id,
 694       --  and on the chain whose first element is FE. A recursive call is
 695       --  made for all packages and generic packages.
 696
 697       procedure Generate_Parent_References;
 698       --  For a child unit, generate references to parent units, for
 699       --  GPS navigation purposes.
 700
 701       function Is_Public_Child (Child, Unit : Entity_Id) return Boolean;
 702       --  Child and Unit are entities of compilation units. True if Child
 703       --  is a public child of Parent as defined in 10.1.1
 704
 705       procedure Inspect_Deferred_Constant_Completion;
 706       --  Examines the deferred constants in the private part of the package
 707       --  specification. Emits the error message "constant declaration requires
 708       --  initialization expression " if not completed by an Import pragma.
 709
 710       procedure Inspect_Unchecked_Union_Completion (Decls : List_Id);
 711       --  Detects all incomplete or private type declarations having a known
 712       --  discriminant part that are completed by an Unchecked_Union. Emits
 713       --  the error message "Unchecked_Union may not complete discriminated
 714       --  partial view".
 715
 716       procedure Install_Parent_Private_Declarations (Inst_Id : Entity_Id);
 717       --  Given the package entity of a generic package instantiation or
 718       --  formal package whose corresponding generic is a child unit, installs
 719       --  the private declarations of each of the child unit's parents.
 720       --  This has to be done at the point of entering the instance package's
 721       --  private part rather than being done in Sem_Ch12.Install_Parent
 722       --  (which is where the parents' visible declarations are installed).
 723
 724       ---------------------
 725       -- Clear_Constants --
 726       ---------------------
 727
 728       procedure Clear_Constants (Id : Entity_Id; FE : Entity_Id) is
 729          E : Entity_Id;
 730
 731       begin
 732          --  Ignore package renamings, not interesting and they can
 733          --  cause self referential loops in the code below.
 734
 735          if Nkind (Parent (Id)) = N_Package_Renaming_Declaration then
 736             return;
 737          end if;
 738
 739          --  Note: in the loop below, the check for Next_Entity pointing
 740          --  back to the package entity seems very odd, but it is needed,
 741          --  because this kind of unexpected circularity does occur ???
 742
 743          E := FE;
 744          while Present (E) and then E /= Id loop
 745             if Ekind (E) = E_Variable then
 746                Set_Never_Set_In_Source (E, False);
 747                Set_Is_True_Constant    (E, False);
 748                Set_Current_Value       (E, Empty);
 749                Set_Is_Known_Null       (E, False);
 750
 751                if not Can_Never_Be_Null (E) then
 752                   Set_Is_Known_Non_Null (E, False);
 753                end if;
 754
 755             elsif Ekind (E) = E_Package
 756                     or else
 757                   Ekind (E) = E_Generic_Package
 758             then
 759                Clear_Constants (E, First_Entity (E));
 760                Clear_Constants (E, First_Private_Entity (E));
 761             end if;
 762
 763             Next_Entity (E);
 764          end loop;
 765       end Clear_Constants;
 766
 767       --------------------------------
 768       -- Generate_Parent_References --
 769       --------------------------------
 770
 771       procedure Generate_Parent_References is
 772          Decl : constant Node_Id := Parent (N);
 773
 774       begin
 775          if Id = Cunit_Entity (Main_Unit)
 776            or else Parent (Decl) = Library_Unit (Cunit (Main_Unit))
 777          then
 778             Generate_Reference (Id, Scope (Id), 'k', False);
 779
 780          elsif Nkind (Unit (Cunit (Main_Unit))) /= N_Subprogram_Body
 781            and then Nkind (Unit (Cunit (Main_Unit))) /= N_Subunit
 782          then
 783             --  If current unit is an ancestor of main unit, generate
 784             --  a reference to its own parent.
 785
 786             declare
 787                U         : Node_Id;
 788                Main_Spec : Node_Id := Unit (Cunit (Main_Unit));
 789
 790             begin
 791                if Nkind (Main_Spec) = N_Package_Body then
 792                   Main_Spec := Unit (Library_Unit (Cunit (Main_Unit)));
 793                end if;
 794
 795                U := Parent_Spec (Main_Spec);
 796                while Present (U) loop
 797                   if U = Parent (Decl) then
 798                      Generate_Reference (Id, Scope (Id), 'k',  False);
 799                      exit;
 800
 801                   elsif Nkind (Unit (U)) = N_Package_Body then
 802                      exit;
 803
 804                   else
 805                      U := Parent_Spec (Unit (U));
 806                   end if;
 807                end loop;
 808             end;
 809          end if;
 810       end Generate_Parent_References;
 811
 812       ---------------------
 813       -- Is_Public_Child --
 814       ---------------------
 815
 816       function Is_Public_Child (Child, Unit : Entity_Id) return Boolean is
 817       begin
 818          if not Is_Private_Descendant (Child) then
 819             return True;
 820          else
 821             if Child = Unit then
 822                return not Private_Present (
 823                  Parent (Unit_Declaration_Node (Child)));
 824             else
 825                return Is_Public_Child (Scope (Child), Unit);
 826             end if;
 827          end if;
 828       end Is_Public_Child;
 829
 830       ------------------------------------------
 831       -- Inspect_Deferred_Constant_Completion --
 832       ------------------------------------------
 833
 834       procedure Inspect_Deferred_Constant_Completion is
 835          Decl   : Node_Id;
 836
 837       begin
 838          Decl := First (Priv_Decls);
 839          while Present (Decl) loop
 840
 841             --  Deferred constant signature
 842
 843             if Nkind (Decl) = N_Object_Declaration
 844               and then Constant_Present (Decl)
 845               and then No (Expression (Decl))
 846
 847                --  No need to check internally generated constants
 848
 849               and then Comes_From_Source (Decl)
 850
 851                --  The constant is not completed. A full object declaration
 852                --  or a pragma Import complete a deferred constant.
 853
 854               and then not Has_Completion (Defining_Identifier (Decl))
 855             then
 856                Error_Msg_N
 857                  ("constant declaration requires initialization expression",
 858                  Defining_Identifier (Decl));
 859             end if;
 860
 861             Decl := Next (Decl);
 862          end loop;
 863       end Inspect_Deferred_Constant_Completion;
 864
 865       ----------------------------------------
 866       -- Inspect_Unchecked_Union_Completion --
 867       ----------------------------------------
 868
 869       procedure Inspect_Unchecked_Union_Completion (Decls : List_Id) is
 870          Decl : Node_Id := First (Decls);
 871
 872       begin
 873          while Present (Decl) loop
 874
 875             --  We are looking at an incomplete or private type declaration
 876             --  with a known_discriminant_part whose full view is an
 877             --  Unchecked_Union.
 878
 879             if (Nkind (Decl) = N_Incomplete_Type_Declaration
 880                   or else
 881                 Nkind (Decl) = N_Private_Type_Declaration)
 882               and then Has_Discriminants (Defining_Identifier (Decl))
 883               and then Present (Full_View (Defining_Identifier (Decl)))
 884               and then Is_Unchecked_Union
 885                 (Full_View (Defining_Identifier (Decl)))
 886             then
 887                Error_Msg_N ("completion of discriminated partial view" &
 888                  " cannot be an Unchecked_Union",
 889                  Full_View (Defining_Identifier (Decl)));
 890             end if;
 891
 892             Next (Decl);
 893          end loop;
 894       end Inspect_Unchecked_Union_Completion;
 895
 896       -----------------------------------------
 897       -- Install_Parent_Private_Declarations --
 898       -----------------------------------------
 899
 900       procedure Install_Parent_Private_Declarations (Inst_Id : Entity_Id) is
 901          Inst_Par  : Entity_Id := Inst_Id;
 902          Gen_Par   : Entity_Id;
 903          Inst_Node : Node_Id;
 904
 905       begin
 906          Gen_Par :=
 907            Generic_Parent (Specification (Unit_Declaration_Node (Inst_Par)));
 908          while Present (Gen_Par) and then Is_Child_Unit (Gen_Par) loop
 909             Inst_Node := Get_Package_Instantiation_Node (Inst_Par);
 910
 911             if (Nkind (Inst_Node) = N_Package_Instantiation
 912                   or else Nkind (Inst_Node) = N_Formal_Package_Declaration)
 913               and then Nkind (Name (Inst_Node)) = N_Expanded_Name
 914             then
 915                Inst_Par := Entity (Prefix (Name (Inst_Node)));
 916
 917                if Present (Renamed_Entity (Inst_Par)) then
 918                   Inst_Par := Renamed_Entity (Inst_Par);
 919                end if;
 920
 921                Gen_Par :=
 922                  Generic_Parent
 923                    (Specification (Unit_Declaration_Node (Inst_Par)));
 924
 925                --  Install the private declarations and private use clauses
 926                --  of a parent instance of the child instance.
 927
 928                if Present (Gen_Par) then
 929                   Install_Private_Declarations (Inst_Par);
 930                   Set_Use (Private_Declarations
 931                              (Specification
 932                                 (Unit_Declaration_Node (Inst_Par))));
 933
 934                --  If we've reached the end of the generic instance parents,
 935                --  then finish off by looping through the nongeneric parents
 936                --  and installing their private declarations.
 937
 938                else
 939                   while Present (Inst_Par)
 940                     and then Inst_Par /= Standard_Standard
 941                     and then (not In_Open_Scopes (Inst_Par)
 942                                 or else not In_Private_Part (Inst_Par))
 943                   loop
 944                      Install_Private_Declarations (Inst_Par);
 945                      Set_Use (Private_Declarations
 946                                 (Specification
 947                                    (Unit_Declaration_Node (Inst_Par))));
 948                      Inst_Par := Scope (Inst_Par);
 949                   end loop;
 950
 951                   exit;
 952                end if;
 953
 954             else
 955                exit;
 956             end if;
 957          end loop;
 958       end Install_Parent_Private_Declarations;
 959
 960    --  Start of processing for Analyze_Package_Specification
 961
 962    begin
 963       if Present (Vis_Decls) then
 964          Analyze_Declarations (Vis_Decls);
 965       end if;
 966
 967       --  Verify that incomplete types have received full declarations
 968
 969       E := First_Entity (Id);
 970       while Present (E) loop
 971          if Ekind (E) = E_Incomplete_Type
 972            and then No (Full_View (E))
 973          then
 974             Error_Msg_N ("no declaration in visible part for incomplete}", E);
 975          end if;
 976
 977          Next_Entity (E);
 978       end loop;
 979
 980       if Is_Remote_Call_Interface (Id)
 981          and then Nkind (Parent (Parent (N))) = N_Compilation_Unit
 982       then
 983          Validate_RCI_Declarations (Id);
 984       end if;
 985
 986       --  Save global references in the visible declarations, before
 987       --  installing private declarations of parent unit if there is one,
 988       --  because the privacy status of types defined in the parent will
 989       --  change. This is only relevant for generic child units, but is
 990       --  done in all cases for uniformity.
 991
 992       if Ekind (Id) = E_Generic_Package
 993         and then Nkind (Orig_Decl) = N_Generic_Package_Declaration
 994       then
 995          declare
 996             Orig_Spec : constant Node_Id    := Specification (Orig_Decl);
 997             Save_Priv : constant List_Id := Private_Declarations (Orig_Spec);
 998
 999          begin
1000             Set_Private_Declarations (Orig_Spec, Empty_List);
1001             Save_Global_References   (Orig_Decl);
1002             Set_Private_Declarations (Orig_Spec, Save_Priv);
1003          end;
1004       end if;
1005
1006       --  If package is a public child unit, then make the private
1007       --  declarations of the parent visible.
1008
1009       Public_Child := False;
1010
1011       declare
1012          Par       : Entity_Id;
1013          Pack_Decl : Node_Id;
1014          Par_Spec  : Node_Id;
1015
1016       begin
1017          Par := Id;
1018          Par_Spec := Parent_Spec (Parent (N));
1019
1020          --  If the package is formal package of an enclosing generic, is is
1021          --  transformed into a local generic declaration, and compiled to make
1022          --  its spec available. We need to retrieve the original generic to
1023          --  determine whether it is a child unit, and install its parents.
1024
1025          if No (Par_Spec)
1026            and then
1027              Nkind (Original_Node (Parent (N))) = N_Formal_Package_Declaration
1028          then
1029             Par := Entity (Name (Original_Node (Parent (N))));
1030             Par_Spec := Parent_Spec (Unit_Declaration_Node (Par));
1031          end if;
1032
1033          if Present (Par_Spec) then
1034             Generate_Parent_References;
1035
1036             while Scope (Par) /= Standard_Standard
1037               and then Is_Public_Child (Id, Par)
1038             loop
1039                Public_Child := True;
1040                Par := Scope (Par);
1041                Install_Private_Declarations (Par);
1042                Install_Private_With_Clauses (Par);
1043                Pack_Decl := Unit_Declaration_Node (Par);
1044                Set_Use (Private_Declarations (Specification (Pack_Decl)));
1045             end loop;
1046          end if;
1047       end;
1048
1049       if Is_Compilation_Unit (Id) then
1050          Install_Private_With_Clauses (Id);
1051       end if;
1052
1053       --  If this is a package associated with a generic instance or formal
1054       --  package, then the private declarations of each of the generic's
1055       --  parents must be installed at this point.
1056
1057       if Is_Generic_Instance (Id)
1058         or else
1059           (Nkind (Unit_Declaration_Node (Id)) = N_Generic_Package_Declaration
1060              and then
1061            Nkind (Original_Node (Unit_Declaration_Node (Id)))
1062              = N_Formal_Package_Declaration)
1063       then
1064          Install_Parent_Private_Declarations (Id);
1065       end if;
1066
1067       --  Analyze private part if present. The flag In_Private_Part is
1068       --  reset in End_Package_Scope.
1069
1070       L := Last_Entity (Id);
1071
1072       if Present (Priv_Decls) then
1073          Set_In_Private_Part (Id);
1074
1075          --  Upon entering a public child's private part, it may be
1076          --  necessary to declare subprograms that were derived in
1077          --  the package visible part but not yet made visible.
1078
1079          if Public_Child then
1080             Declare_Inherited_Private_Subprograms (Id);
1081          end if;
1082
1083          Analyze_Declarations (Priv_Decls);
1084
1085          --  Check the private declarations for incomplete deferred constants
1086
1087          Inspect_Deferred_Constant_Completion;
1088
1089          --  The first private entity is the immediate follower of the last
1090          --  visible entity, if there was one.
1091
1092          if Present (L) then
1093             Set_First_Private_Entity (Id, Next_Entity (L));
1094          else
1095             Set_First_Private_Entity (Id, First_Entity (Id));
1096          end if;
1097
1098       --  There may be inherited private subprograms that need to be
1099       --  declared, even in the absence of an explicit private part.
1100       --  If there are any public declarations in the package and
1101       --  the package is a public child unit, then an implicit private
1102       --  part is assumed.
1103
1104       elsif Present (L) and then Public_Child then
1105          Set_In_Private_Part (Id);
1106          Declare_Inherited_Private_Subprograms (Id);
1107          Set_First_Private_Entity (Id, Next_Entity (L));
1108       end if;
1109
1110       --  Check rule of 3.6(11), which in general requires
1111       --  waiting till all full types have been seen.
1112
1113       E := First_Entity (Id);
1114       while Present (E) loop
1115          if Ekind (E) = E_Record_Type or else Ekind (E) = E_Array_Type then
1116             Check_Aliased_Component_Types (E);
1117          end if;
1118
1119          Next_Entity (E);
1120       end loop;
1121
1122       --  Ada 2005 (AI-216): The completion of an incomplete or private type
1123       --  declaration having a known_discriminant_part shall not be an
1124       --  Unchecked_Union type.
1125
1126       if Present (Vis_Decls) then
1127          Inspect_Unchecked_Union_Completion (Vis_Decls);
1128       end if;
1129
1130       if Present (Priv_Decls) then
1131          Inspect_Unchecked_Union_Completion (Priv_Decls);
1132       end if;
1133
1134       if Ekind (Id) = E_Generic_Package
1135         and then Nkind (Orig_Decl) = N_Generic_Package_Declaration
1136         and then Present (Priv_Decls)
1137       then
1138          --  Save global references in private declarations, ignoring the
1139          --  visible declarations that were processed earlier.
1140
1141          declare
1142             Orig_Spec : constant Node_Id := Specification (Orig_Decl);
1143             Save_Vis  : constant List_Id := Visible_Declarations (Orig_Spec);
1144             Save_Form : constant List_Id :=
1145                           Generic_Formal_Declarations (Orig_Decl);
1146
1147          begin
1148             Set_Visible_Declarations        (Orig_Spec, Empty_List);
1149             Set_Generic_Formal_Declarations (Orig_Decl, Empty_List);
1150             Save_Global_References          (Orig_Decl);
1151             Set_Generic_Formal_Declarations (Orig_Decl, Save_Form);
1152             Set_Visible_Declarations        (Orig_Spec, Save_Vis);
1153          end;
1154       end if;
1155
1156       Process_End_Label (N, 'e', Id);
1157
1158       --  For the case of a library level package, we must go through all
1159       --  the entities clearing the indications that the value may be
1160       --  constant and not modified. Why? Because any client of this
1161       --  package may modify these values freely from anywhere. This
1162       --  also applies to any nested packages or generic packages.
1163
1164       --  For now we unconditionally clear constants for packages that
1165       --  are instances of generic packages. The reason is that we do not
1166       --  have the body yet, and we otherwise think things are unreferenced
1167       --  when they are not. This should be fixed sometime (the effect is
1168       --  not terrible, we just lose some warnings, and also some cases
1169       --  of value propagation) ???
1170
1171       if Is_Library_Level_Entity (Id)
1172         or else Is_Generic_Instance (Id)
1173       then
1174          Clear_Constants (Id, First_Entity (Id));
1175          Clear_Constants (Id, First_Private_Entity (Id));
1176       end if;
1177    end Analyze_Package_Specification;
1178
1179    --------------------------------------
1180    -- Analyze_Private_Type_Declaration --
1181    --------------------------------------
1182
1183    procedure Analyze_Private_Type_Declaration (N : Node_Id) is
1184       PF : constant Boolean   := Is_Pure (Enclosing_Lib_Unit_Entity);
1185       Id : constant Entity_Id := Defining_Identifier (N);
1186
1187    begin
1188       Generate_Definition (Id);
1189       Set_Is_Pure         (Id, PF);
1190       Init_Size_Align     (Id);
1191
1192       if (Ekind (Current_Scope) /= E_Package
1193           and then Ekind (Current_Scope) /= E_Generic_Package)
1194         or else In_Private_Part (Current_Scope)
1195       then
1196          Error_Msg_N ("invalid context for private declaration", N);
1197       end if;
1198
1199       New_Private_Type (N, Id, N);
1200       Set_Depends_On_Private (Id);
1201    end Analyze_Private_Type_Declaration;
1202
1203    -------------------------------------------
1204    -- Declare_Inherited_Private_Subprograms --
1205    -------------------------------------------
1206
1207    procedure Declare_Inherited_Private_Subprograms (Id : Entity_Id) is
1208       E              : Entity_Id;
1209       Op_List        : Elist_Id;
1210       Op_Elmt        : Elmt_Id;
1211       Op_Elmt_2      : Elmt_Id;
1212       Prim_Op        : Entity_Id;
1213       New_Op         : Entity_Id := Empty;
1214       Parent_Subp    : Entity_Id;
1215       Found_Explicit : Boolean;
1216       Decl_Privates  : Boolean;
1217
1218       function Is_Primitive_Of (T : Entity_Id; S : Entity_Id) return Boolean;
1219       --  Check whether an inherited subprogram is an operation of an
1220       --  untagged derived type.
1221
1222       ---------------------
1223       -- Is_Primitive_Of --
1224       ---------------------
1225
1226       function Is_Primitive_Of (T : Entity_Id; S : Entity_Id) return Boolean is
1227          Formal : Entity_Id;
1228
1229       begin
1230          if Etype (S) = T then
1231             return True;
1232
1233          else
1234             Formal := First_Formal (S);
1235
1236             while Present (Formal) loop
1237                if Etype (Formal) = T then
1238                   return True;
1239                end if;
1240
1241                Next_Formal (Formal);
1242             end loop;
1243
1244             return False;
1245          end if;
1246       end Is_Primitive_Of;
1247
1248    --  Start of processing for Declare_Inherited_Private_Subprograms
1249
1250    begin
1251       E := First_Entity (Id);
1252       while Present (E) loop
1253
1254          --  If the entity is a nonprivate type extension whose parent
1255          --  type is declared in an open scope, then the type may have
1256          --  inherited operations that now need to be made visible.
1257          --  Ditto if the entity is a formal derived type in a child unit.
1258
1259          if ((Is_Derived_Type (E) and then not Is_Private_Type (E))
1260                or else
1261                  (Nkind (Parent (E)) = N_Private_Extension_Declaration
1262                    and then Is_Generic_Type (E)))
1263            and then In_Open_Scopes (Scope (Etype (E)))
1264            and then E = Base_Type (E)
1265          then
1266             if Is_Tagged_Type (E) then
1267                Op_List       := Primitive_Operations (E);
1268                New_Op        := Empty;
1269                Decl_Privates := False;
1270
1271                Op_Elmt := First_Elmt (Op_List);
1272                while Present (Op_Elmt) loop
1273                   Prim_Op := Node (Op_Elmt);
1274
1275                   --  If the primitive operation is an implicit operation
1276                   --  with an internal name whose parent operation has
1277                   --  a normal name, then we now need to either declare the
1278                   --  operation (i.e., make it visible), or replace it
1279                   --  by an overriding operation if one exists.
1280
1281                   if Present (Alias (Prim_Op))
1282                     and then not Comes_From_Source (Prim_Op)
1283                     and then Is_Internal_Name (Chars (Prim_Op))
1284                     and then not Is_Internal_Name (Chars (Alias (Prim_Op)))
1285                   then
1286                      Parent_Subp := Alias (Prim_Op);
1287
1288                      Found_Explicit := False;
1289                      Op_Elmt_2 := Next_Elmt (Op_Elmt);
1290                      while Present (Op_Elmt_2) loop
1291                         if Chars (Node (Op_Elmt_2)) = Chars (Parent_Subp)
1292                           and then Type_Conformant (Prim_Op, Node (Op_Elmt_2))
1293                         then
1294                            --  The private inherited operation has been
1295                            --  overridden by an explicit subprogram, so
1296                            --  change the private op's list element to
1297                            --  designate the explicit so the explicit
1298                            --  one will get the right dispatching slot.
1299
1300                            New_Op := Node (Op_Elmt_2);
1301                            Replace_Elmt (Op_Elmt, New_Op);
1302                            Remove_Elmt (Op_List, Op_Elmt_2);
1303                            Found_Explicit := True;
1304                            Set_Is_Overriding_Operation (New_Op);
1305                            Decl_Privates  := True;
1306
1307                            exit;
1308                         end if;
1309
1310                         Next_Elmt (Op_Elmt_2);
1311                      end loop;
1312
1313                      if not Found_Explicit then
1314                         Derive_Subprogram
1315                           (New_Op, Alias (Prim_Op), E, Etype (E));
1316
1317                         pragma Assert
1318                           (Is_Dispatching_Operation (New_Op)
1319                             and then Node (Last_Elmt (Op_List)) = New_Op);
1320
1321                         --  Substitute the new operation for the old one
1322                         --  in the type's primitive operations list. Since
1323                         --  the new operation was also just added to the end
1324                         --  of list, the last element must be removed.
1325
1326                         --  (Question: is there a simpler way of declaring
1327                         --  the operation, say by just replacing the name
1328                         --  of the earlier operation, reentering it in the
1329                         --  in the symbol table (how?), and marking it as
1330                         --  private???)
1331
1332                         Replace_Elmt (Op_Elmt, New_Op);
1333                         Remove_Last_Elmt (Op_List);
1334                         Decl_Privates := True;
1335                      end if;
1336                   end if;
1337
1338                   Next_Elmt (Op_Elmt);
1339                end loop;
1340
1341                --  The type's DT attributes need to be recalculated
1342                --  in the case where private dispatching operations
1343                --  have been added or overridden. Normally this action
1344                --  occurs during type freezing, but we force it here
1345                --  since the type may already have been frozen (e.g.,
1346                --  if the type's package has an empty private part).
1347                --  This can only be done if expansion is active, otherwise
1348                --  Tag may not be present.
1349
1350                if Decl_Privates
1351                  and then Expander_Active
1352                then
1353                   Set_All_DT_Position (E);
1354                end if;
1355
1356             else
1357                --   Non-tagged type, scan forward to locate
1358                --   inherited hidden operations.
1359
1360                Prim_Op := Next_Entity (E);
1361
1362                while Present (Prim_Op) loop
1363                   if Is_Subprogram (Prim_Op)
1364                     and then Present (Alias (Prim_Op))
1365                     and then not Comes_From_Source (Prim_Op)
1366                     and then Is_Internal_Name (Chars (Prim_Op))
1367                     and then not Is_Internal_Name (Chars (Alias (Prim_Op)))
1368                     and then Is_Primitive_Of (E, Prim_Op)
1369                   then
1370                      Derive_Subprogram (New_Op, Alias (Prim_Op), E, Etype (E));
1371                   end if;
1372
1373                   Next_Entity (Prim_Op);
1374                end loop;
1375             end if;
1376          end if;
1377
1378          Next_Entity (E);
1379       end loop;
1380    end Declare_Inherited_Private_Subprograms;
1381
1382    -----------------------
1383    -- End_Package_Scope --
1384    -----------------------
1385
1386    procedure End_Package_Scope (P : Entity_Id) is
1387    begin
1388       Uninstall_Declarations (P);
1389       Pop_Scope;
1390    end End_Package_Scope;
1391
1392    ---------------------------
1393    -- Exchange_Declarations --
1394    ---------------------------
1395
1396    procedure Exchange_Declarations (Id : Entity_Id) is
1397       Full_Id : constant Entity_Id := Full_View (Id);
1398       H1      : constant Entity_Id := Homonym (Id);
1399       Next1   : constant Entity_Id := Next_Entity (Id);
1400       H2      : Entity_Id;
1401       Next2   : Entity_Id;
1402
1403    begin
1404       --  If missing full declaration for type, nothing to exchange
1405
1406       if No (Full_Id) then
1407          return;
1408       end if;
1409
1410       --  Otherwise complete the exchange, and preserve semantic links
1411
1412       Next2 := Next_Entity (Full_Id);
1413       H2    := Homonym (Full_Id);
1414
1415       --  Reset full declaration pointer to reflect the switched entities
1416       --  and readjust the next entity chains.
1417
1418       Exchange_Entities (Id, Full_Id);
1419
1420       Set_Next_Entity (Id, Next1);
1421       Set_Homonym     (Id, H1);
1422
1423       Set_Full_View   (Full_Id, Id);
1424       Set_Next_Entity (Full_Id, Next2);
1425       Set_Homonym     (Full_Id, H2);
1426    end Exchange_Declarations;
1427
1428    ----------------------------
1429    -- Install_Package_Entity --
1430    ----------------------------
1431
1432    procedure Install_Package_Entity (Id : Entity_Id) is
1433    begin
1434       if not Is_Internal (Id) then
1435          if Debug_Flag_E then
1436             Write_Str ("Install: ");
1437             Write_Name (Chars (Id));
1438             Write_Eol;
1439          end if;
1440
1441          if not Is_Child_Unit (Id) then
1442             Set_Is_Immediately_Visible (Id);
1443          end if;
1444
1445       end if;
1446    end Install_Package_Entity;
1447
1448    ----------------------------------
1449    -- Install_Private_Declarations --
1450    ----------------------------------
1451
1452    procedure Install_Private_Declarations (P : Entity_Id) is
1453       Id        : Entity_Id;
1454       Priv_Elmt : Elmt_Id;
1455       Priv      : Entity_Id;
1456       Full      : Entity_Id;
1457
1458    begin
1459       --  First exchange declarations for private types, so that the
1460       --  full declaration is visible. For each private type, we check
1461       --  its Private_Dependents list and also exchange any subtypes of
1462       --  or derived types from it. Finally, if this is a Taft amendment
1463       --  type, the incomplete declaration is irrelevant, and we want to
1464       --  link the eventual full declaration with the original private
1465       --  one so we also skip the exchange.
1466
1467       Id := First_Entity (P);
1468       while Present (Id) and then Id /= First_Private_Entity (P) loop
1469
1470          if Is_Private_Base_Type (Id)
1471            and then Comes_From_Source (Full_View (Id))
1472            and then Present (Full_View (Id))
1473            and then Scope (Full_View (Id)) = Scope (Id)
1474            and then Ekind (Full_View (Id)) /= E_Incomplete_Type
1475          then
1476             --  If there is a use-type clause on the private type, set the
1477             --  full view accordingly.
1478
1479             Set_In_Use (Full_View (Id), In_Use (Id));
1480             Full := Full_View (Id);
1481
1482             if Is_Private_Base_Type (Full)
1483               and then Has_Private_Declaration (Full)
1484               and then Nkind (Parent (Full)) = N_Full_Type_Declaration
1485               and then In_Open_Scopes (Scope (Etype (Full)))
1486               and then In_Package_Body (Current_Scope)
1487               and then not Is_Private_Type (Etype (Full))
1488             then
1489                --  This is the completion of a private type by a derivation
1490                --  from another private type which is not private anymore. This
1491                --  can only happen in a package nested within a child package,
1492                --  when the parent type is defined in the parent unit. At this
1493                --  point the current type is not private either, and we have to
1494                --  install the underlying full view, which is now visible.
1495
1496                if No (Full_View (Full))
1497                  and then Present (Underlying_Full_View (Full))
1498                then
1499                   Set_Full_View (Id, Underlying_Full_View (Full));
1500                   Set_Underlying_Full_View (Full, Empty);
1501                   Set_Is_Frozen (Full_View (Id));
1502                end if;
1503             end if;
1504
1505             Priv_Elmt := First_Elmt (Private_Dependents (Id));
1506
1507             Exchange_Declarations (Id);
1508             Set_Is_Immediately_Visible (Id);
1509
1510             while Present (Priv_Elmt) loop
1511                Priv := Node (Priv_Elmt);
1512
1513                --  Before the exchange, verify that the presence of the
1514                --  Full_View field. It will be empty if the entity
1515                --  has already been installed due to a previous call.
1516
1517                if Present (Full_View (Priv))
1518                  and then Is_Visible_Dependent (Priv)
1519                then
1520
1521                   --  For each subtype that is swapped, we also swap the
1522                   --  reference to it in Private_Dependents, to allow access
1523                   --  to it when we swap them out in End_Package_Scope.
1524
1525                   Replace_Elmt (Priv_Elmt, Full_View (Priv));
1526                   Exchange_Declarations (Priv);
1527                   Set_Is_Immediately_Visible
1528                     (Priv, In_Open_Scopes (Scope (Priv)));
1529                   Set_Is_Potentially_Use_Visible
1530                     (Priv, Is_Potentially_Use_Visible (Node (Priv_Elmt)));
1531                end if;
1532
1533                Next_Elmt (Priv_Elmt);
1534             end loop;
1535          end if;
1536
1537          Next_Entity (Id);
1538       end loop;
1539
1540       --  Next make other declarations in the private part visible as well
1541
1542       Id := First_Private_Entity (P);
1543
1544       while Present (Id) loop
1545          Install_Package_Entity (Id);
1546          Set_Is_Hidden (Id, False);
1547          Next_Entity (Id);
1548       end loop;
1549
1550       --  Indicate that the private part is currently visible, so it can be
1551       --  properly reset on exit.
1552
1553       Set_In_Private_Part (P);
1554    end Install_Private_Declarations;
1555
1556    ----------------------------------
1557    -- Install_Visible_Declarations --
1558    ----------------------------------
1559
1560    procedure Install_Visible_Declarations (P : Entity_Id) is
1561       Id          : Entity_Id;
1562       Last_Entity : Entity_Id;
1563
1564    begin
1565       pragma Assert
1566         (Is_Package_Or_Generic_Package (P) or else Is_Record_Type (P));
1567
1568       if Is_Package_Or_Generic_Package (P) then
1569          Last_Entity := First_Private_Entity (P);
1570       else
1571          Last_Entity := Empty;
1572       end if;
1573
1574       Id := First_Entity (P);
1575
1576       while Present (Id) and then Id /= Last_Entity loop
1577          Install_Package_Entity (Id);
1578          Next_Entity (Id);
1579       end loop;
1580    end Install_Visible_Declarations;
1581
1582    --------------------------
1583    -- Is_Private_Base_Type --
1584    --------------------------
1585
1586    function Is_Private_Base_Type (E : Entity_Id) return Boolean is
1587    begin
1588       return Ekind (E) = E_Private_Type
1589         or else Ekind (E) = E_Limited_Private_Type
1590         or else Ekind (E) = E_Record_Type_With_Private;
1591    end Is_Private_Base_Type;
1592
1593    --------------------------
1594    -- Is_Visible_Dependent --
1595    --------------------------
1596
1597    function Is_Visible_Dependent (Dep : Entity_Id) return Boolean
1598    is
1599       S : constant Entity_Id := Scope (Dep);
1600
1601    begin
1602       --  Renamings created for actual types have the visibility of the
1603       --  actual.
1604
1605       if Ekind (S) = E_Package
1606         and then Is_Generic_Instance (S)
1607         and then (Is_Generic_Actual_Type (Dep)
1608                    or else Is_Generic_Actual_Type (Full_View (Dep)))
1609       then
1610          return True;
1611
1612       elsif not (Is_Derived_Type (Dep))
1613         and then Is_Derived_Type (Full_View (Dep))
1614       then
1615          --  When instantiating a package body, the scope stack is empty,
1616          --  so check instead whether the dependent type is defined in
1617          --  the same scope as the instance itself.
1618
1619          return In_Open_Scopes (S)
1620            or else (Is_Generic_Instance (Current_Scope)
1621               and then Scope (Dep) = Scope (Current_Scope));
1622       else
1623          return True;
1624       end if;
1625    end Is_Visible_Dependent;
1626
1627    ----------------------------
1628    -- May_Need_Implicit_Body --
1629    ----------------------------
1630
1631    procedure May_Need_Implicit_Body (E : Entity_Id) is
1632       P     : constant Node_Id := Unit_Declaration_Node (E);
1633       S     : constant Node_Id := Parent (P);
1634       B     : Node_Id;
1635       Decls : List_Id;
1636
1637    begin
1638       if not Has_Completion (E)
1639         and then Nkind (P) = N_Package_Declaration
1640         and then Present (Activation_Chain_Entity (P))
1641       then
1642          B :=
1643            Make_Package_Body (Sloc (E),
1644              Defining_Unit_Name => Make_Defining_Identifier (Sloc (E),
1645                Chars => Chars (E)),
1646              Declarations  => New_List);
1647
1648          if Nkind (S) = N_Package_Specification then
1649             if Present (Private_Declarations (S)) then
1650                Decls := Private_Declarations (S);
1651             else
1652                Decls := Visible_Declarations (S);
1653             end if;
1654          else
1655             Decls := Declarations (S);
1656          end if;
1657
1658          Append (B, Decls);
1659          Analyze (B);
1660       end if;
1661    end May_Need_Implicit_Body;
1662
1663    ----------------------
1664    -- New_Private_Type --
1665    ----------------------
1666
1667    procedure New_Private_Type (N : Node_Id; Id : Entity_Id; Def : Node_Id) is
1668    begin
1669       Enter_Name (Id);
1670
1671       if Limited_Present (Def) then
1672          Set_Ekind (Id, E_Limited_Private_Type);
1673       else
1674          Set_Ekind (Id, E_Private_Type);
1675       end if;
1676
1677       Set_Etype              (Id, Id);
1678       Set_Has_Delayed_Freeze (Id);
1679       Set_Is_First_Subtype   (Id);
1680       Init_Size_Align        (Id);
1681
1682       Set_Is_Constrained (Id,
1683         No (Discriminant_Specifications (N))
1684           and then not Unknown_Discriminants_Present (N));
1685
1686       --  Set tagged flag before processing discriminants, to catch
1687       --  illegal usage.
1688
1689       Set_Is_Tagged_Type (Id, Tagged_Present (Def));
1690
1691       Set_Discriminant_Constraint (Id, No_Elist);
1692       Set_Stored_Constraint (Id, No_Elist);
1693
1694       if Present (Discriminant_Specifications (N)) then
1695          New_Scope (Id);
1696          Process_Discriminants (N);
1697          End_Scope;
1698
1699       elsif Unknown_Discriminants_Present (N) then
1700          Set_Has_Unknown_Discriminants (Id);
1701       end if;
1702
1703       Set_Private_Dependents (Id, New_Elmt_List);
1704
1705       if Tagged_Present (Def) then
1706          Set_Ekind                (Id, E_Record_Type_With_Private);
1707          Make_Class_Wide_Type     (Id);
1708          Set_Primitive_Operations (Id, New_Elmt_List);
1709          Set_Is_Abstract          (Id, Abstract_Present (Def));
1710          Set_Is_Limited_Record    (Id, Limited_Present (Def));
1711          Set_Has_Delayed_Freeze   (Id, True);
1712
1713       elsif Abstract_Present (Def) then
1714          Error_Msg_N ("only a tagged type can be abstract", N);
1715       end if;
1716    end New_Private_Type;
1717
1718    ----------------------------
1719    -- Uninstall_Declarations --
1720    ----------------------------
1721
1722    procedure Uninstall_Declarations (P : Entity_Id) is
1723       Decl      : constant Node_Id := Unit_Declaration_Node (P);
1724       Id        : Entity_Id;
1725       Full      : Entity_Id;
1726       Priv_Elmt : Elmt_Id;
1727       Priv_Sub  : Entity_Id;
1728
1729       procedure Preserve_Full_Attributes (Priv, Full : Entity_Id);
1730       --  Copy to the private declaration the attributes of the full view
1731       --  that need to be available for the partial view also.
1732
1733       function Type_In_Use (T : Entity_Id) return Boolean;
1734       --  Check whether type or base type appear in an active use_type clause
1735
1736       ------------------------------
1737       -- Preserve_Full_Attributes --
1738       ------------------------------
1739
1740       procedure Preserve_Full_Attributes (Priv, Full : Entity_Id) is
1741          Priv_Is_Base_Type : constant Boolean := Priv = Base_Type (Priv);
1742
1743       begin
1744          Set_Size_Info (Priv, (Full));
1745          Set_RM_Size (Priv, RM_Size (Full));
1746          Set_Size_Known_At_Compile_Time (Priv, Size_Known_At_Compile_Time
1747                                                                       (Full));
1748          Set_Is_Volatile        (Priv, Is_Volatile        (Full));
1749          Set_Treat_As_Volatile  (Priv, Treat_As_Volatile  (Full));
1750          Set_Is_Ada_2005        (Priv, Is_Ada_2005        (Full));
1751
1752          if Is_Unchecked_Union (Full) then
1753             Set_Is_Unchecked_Union (Base_Type (Priv));
1754          end if;
1755          --  Why is atomic not copied here ???
1756
1757          if Referenced (Full) then
1758             Set_Referenced (Priv);
1759          end if;
1760
1761          if Priv_Is_Base_Type then
1762             Set_Is_Controlled (Priv, Is_Controlled (Base_Type (Full)));
1763             Set_Finalize_Storage_Only (Priv, Finalize_Storage_Only
1764                                                            (Base_Type (Full)));
1765             Set_Has_Task (Priv, Has_Task (Base_Type (Full)));
1766             Set_Has_Controlled_Component (Priv, Has_Controlled_Component
1767                                                            (Base_Type (Full)));
1768          end if;
1769
1770          Set_Freeze_Node (Priv, Freeze_Node (Full));
1771
1772          if Is_Tagged_Type (Priv)
1773            and then Is_Tagged_Type (Full)
1774            and then not Error_Posted (Full)
1775          then
1776             if Priv_Is_Base_Type then
1777
1778                --  Ada 2005 (AI-345): The full view of a type implementing
1779                --  an interface can be a task type.
1780
1781                --    type T is new I with private;
1782                --  private
1783                --    task type T is new I with ...
1784
1785                if Is_Interface (Etype (Priv))
1786                  and then Is_Concurrent_Type (Base_Type (Full))
1787                then
1788                   --  Protect the frontend against previous errors
1789
1790                   if Present (Corresponding_Record_Type
1791                                (Base_Type (Full)))
1792                   then
1793                      Set_Access_Disp_Table
1794                        (Priv, Access_Disp_Table
1795                                (Corresponding_Record_Type (Base_Type (Full))));
1796
1797                   --  Generic context, or previous errors
1798
1799                   else
1800                      null;
1801                   end if;
1802
1803                else
1804                   Set_Access_Disp_Table
1805                     (Priv, Access_Disp_Table (Base_Type (Full)));
1806                end if;
1807             end if;
1808
1809             Set_First_Entity (Priv, First_Entity (Full));
1810             Set_Last_Entity  (Priv, Last_Entity (Full));
1811             Set_Has_Discriminants (Priv, Has_Discriminants (Full));
1812          end if;
1813       end Preserve_Full_Attributes;
1814
1815       -----------------
1816       -- Type_In_Use --
1817       -----------------
1818
1819       function Type_In_Use (T : Entity_Id) return Boolean is
1820       begin
1821          return Scope (Base_Type (T)) = P
1822            and then  (In_Use (T) or else In_Use (Base_Type (T)));
1823       end Type_In_Use;
1824
1825    --  Start of processing for Uninstall_Declarations
1826
1827    begin
1828       Id := First_Entity (P);
1829
1830       while Present (Id) and then Id /= First_Private_Entity (P) loop
1831          if Debug_Flag_E then
1832             Write_Str ("unlinking visible entity ");
1833             Write_Int (Int (Id));
1834             Write_Eol;
1835          end if;
1836
1837          --  On  exit from the package scope, we must preserve the visibility
1838          --  established by use clauses in the current scope. Two cases:
1839
1840          --  a) If the entity is an operator, it may be a primitive operator of
1841          --  a type for which there is a visible use-type clause.
1842
1843          --  b) for other entities, their use-visibility is determined by a
1844          --  visible use clause for the package itself. For a generic instance,
1845          --  the instantiation of the formals appears in the visible part,
1846          --  but the formals are private and remain so.
1847
1848          if Ekind (Id) = E_Function
1849            and then  Is_Operator_Symbol_Name (Chars (Id))
1850            and then not Is_Hidden (Id)
1851            and then not Error_Posted (Id)
1852          then
1853             Set_Is_Potentially_Use_Visible (Id,
1854               In_Use (P)
1855               or else Type_In_Use (Etype (Id))
1856               or else Type_In_Use (Etype (First_Formal (Id)))
1857               or else (Present (Next_Formal (First_Formal (Id)))
1858                          and then
1859                            Type_In_Use
1860                              (Etype (Next_Formal (First_Formal (Id))))));
1861          else
1862             Set_Is_Potentially_Use_Visible (Id,
1863               In_Use (P) and not Is_Hidden (Id));
1864          end if;
1865
1866          --  Local entities are not immediately visible outside of the package
1867
1868          Set_Is_Immediately_Visible (Id, False);
1869
1870          --  If this is a private type with a full view (for example a local
1871          --  subtype of a private type declared elsewhere), ensure that the
1872          --  full view is also removed from visibility: it may be exposed when
1873          --  swapping views in an instantiation.
1874
1875          if Is_Type (Id)
1876            and then Present (Full_View (Id))
1877          then
1878             Set_Is_Immediately_Visible (Full_View (Id), False);
1879          end if;
1880
1881          if Is_Tagged_Type (Id) and then Ekind (Id) = E_Record_Type then
1882             Check_Abstract_Overriding (Id);
1883          end if;
1884
1885          if (Ekind (Id) = E_Private_Type
1886                or else Ekind (Id) = E_Limited_Private_Type)
1887            and then No (Full_View (Id))
1888            and then not Is_Generic_Type (Id)
1889            and then not Is_Derived_Type (Id)
1890          then
1891             Error_Msg_N ("missing full declaration for private type&", Id);
1892
1893          elsif Ekind (Id) = E_Record_Type_With_Private
1894            and then not Is_Generic_Type (Id)
1895            and then No (Full_View (Id))
1896          then
1897             if Nkind (Parent (Id)) = N_Private_Type_Declaration then
1898                Error_Msg_N ("missing full declaration for private type&", Id);
1899             else
1900                Error_Msg_N
1901                  ("missing full declaration for private extension", Id);
1902             end if;
1903
1904          elsif Ekind (Id) = E_Constant
1905            and then No (Constant_Value (Id))
1906            and then No (Full_View (Id))
1907            and then not Is_Imported (Id)
1908            and then (Nkind (Parent (Id)) /= N_Object_Declaration
1909                       or else not No_Initialization (Parent (Id)))
1910          then
1911             if not Has_Private_Declaration (Etype (Id)) then
1912
1913                --  We assume that the user did not not intend a deferred
1914                --  constant declaration, and the expression is just missing.
1915
1916                Error_Msg_N
1917                  ("constant declaration requires initialization expression",
1918                    Parent (Id));
1919
1920                if Is_Limited_Type (Etype (Id)) then
1921                   Error_Msg_N
1922                     ("\else remove keyword CONSTANT from declaration",
1923                     Parent (Id));
1924                end if;
1925
1926             else
1927                Error_Msg_N
1928                   ("missing full declaration for deferred constant ('R'M 7.4)",
1929                      Id);
1930
1931                if Is_Limited_Type (Etype (Id)) then
1932                   Error_Msg_N
1933                     ("\else remove keyword CONSTANT from declaration",
1934                     Parent (Id));
1935                end if;
1936             end if;
1937          end if;
1938
1939          Next_Entity (Id);
1940       end loop;
1941
1942       --  If the specification was installed as the parent of a public child
1943       --  unit, the private declarations were not installed, and there is
1944       --  nothing to do.
1945
1946       if not In_Private_Part (P) then
1947          return;
1948       else
1949          Set_In_Private_Part (P, False);
1950       end if;
1951
1952       --  Make private entities invisible and exchange full and private
1953       --  declarations for private types.
1954
1955       while Present (Id) loop
1956          if Debug_Flag_E then
1957             Write_Str ("unlinking private entity ");
1958             Write_Int (Int (Id));
1959             Write_Eol;
1960          end if;
1961
1962          if Is_Tagged_Type (Id) and then Ekind (Id) = E_Record_Type then
1963             Check_Abstract_Overriding (Id);
1964          end if;
1965
1966          Set_Is_Immediately_Visible (Id, False);
1967
1968          if Is_Private_Base_Type (Id)
1969            and then Present (Full_View (Id))
1970          then
1971             Full := Full_View (Id);
1972
1973             --  If the partial view is not declared in the visible part
1974             --  of the package (as is the case when it is a type derived
1975             --  from some other private type in the private part of the
1976             --  current package), no exchange takes place.
1977
1978             if No (Parent (Id))
1979               or else List_Containing (Parent (Id))
1980                 /= Visible_Declarations (Specification (Decl))
1981             then
1982                goto Next_Id;
1983             end if;
1984
1985             --  The entry in the private part points to the full declaration,
1986             --  which is currently visible. Exchange them so only the private
1987             --  type declaration remains accessible, and link private and
1988             --  full declaration in the opposite direction. Before the actual
1989             --  exchange, we copy back attributes of the full view that
1990             --  must be available to the partial view too.
1991
1992             Preserve_Full_Attributes (Id, Full);
1993
1994             Set_Is_Potentially_Use_Visible (Id, In_Use (P));
1995
1996             if  Is_Indefinite_Subtype (Full)
1997               and then not Is_Indefinite_Subtype (Id)
1998             then
1999                Error_Msg_N
2000                  ("full view of type must be definite subtype", Full);
2001             end if;
2002
2003             Priv_Elmt := First_Elmt (Private_Dependents (Id));
2004
2005             --  Swap out the subtypes and derived types of Id that were
2006             --  compiled in this scope, or installed previously by
2007             --  Install_Private_Declarations.
2008             --  Before we do the swap, we verify the presence of the
2009             --  Full_View field which may be empty due to a swap by
2010             --  a previous call to End_Package_Scope (e.g. from the
2011             --  freezing mechanism).
2012
2013             while Present (Priv_Elmt) loop
2014                Priv_Sub := Node (Priv_Elmt);
2015
2016                if Present (Full_View (Priv_Sub)) then
2017
2018                   if Scope (Priv_Sub) = P
2019                      or else not In_Open_Scopes (Scope (Priv_Sub))
2020                   then
2021                      Set_Is_Immediately_Visible (Priv_Sub, False);
2022                   end if;
2023
2024                   if Is_Visible_Dependent (Priv_Sub) then
2025                      Preserve_Full_Attributes
2026                        (Priv_Sub, Full_View (Priv_Sub));
2027                      Replace_Elmt (Priv_Elmt, Full_View (Priv_Sub));
2028                      Exchange_Declarations (Priv_Sub);
2029                   end if;
2030                end if;
2031
2032                Next_Elmt (Priv_Elmt);
2033             end loop;
2034
2035             --  Now restore the type itself to its private view
2036
2037             Exchange_Declarations (Id);
2038
2039          elsif Ekind (Id) = E_Incomplete_Type
2040            and then No (Full_View (Id))
2041          then
2042             --  Mark Taft amendment types
2043
2044             Set_Has_Completion_In_Body (Id);
2045
2046          elsif not Is_Child_Unit (Id)
2047            and then (not Is_Private_Type (Id)
2048                       or else No (Full_View (Id)))
2049          then
2050             Set_Is_Hidden (Id);
2051             Set_Is_Potentially_Use_Visible (Id, False);
2052          end if;
2053
2054          <<Next_Id>>
2055             Next_Entity (Id);
2056       end loop;
2057    end Uninstall_Declarations;
2058
2059    ------------------------
2060    -- Unit_Requires_Body --
2061    ------------------------
2062
2063    function Unit_Requires_Body (P : Entity_Id) return Boolean is
2064       E : Entity_Id;
2065
2066    begin
2067       --  Imported entity never requires body. Right now, only
2068       --  subprograms can be imported, but perhaps in the future
2069       --  we will allow import of packages.
2070
2071       if Is_Imported (P) then
2072          return False;
2073
2074       --  Body required if library package with pragma Elaborate_Body
2075
2076       elsif Has_Pragma_Elaborate_Body (P) then
2077          return True;
2078
2079       --  Body required if subprogram
2080
2081       elsif Is_Subprogram (P) or else Is_Generic_Subprogram (P) then
2082          return True;
2083
2084       --  Treat a block as requiring a body
2085
2086       elsif Ekind (P) = E_Block then
2087          return True;
2088
2089       elsif Ekind (P) = E_Package
2090         and then Nkind (Parent (P)) = N_Package_Specification
2091         and then Present (Generic_Parent (Parent (P)))
2092       then
2093          declare
2094             G_P : constant Entity_Id := Generic_Parent (Parent (P));
2095
2096          begin
2097             if Has_Pragma_Elaborate_Body (G_P) then
2098                return True;
2099             end if;
2100          end;
2101       end if;
2102
2103       --  Otherwise search entity chain for entity requiring completion
2104
2105       E := First_Entity (P);
2106       while Present (E) loop
2107
2108          --  Always ignore child units. Child units get added to the entity
2109          --  list of a parent unit, but are not original entities of the
2110          --  parent, and so do not affect whether the parent needs a body.
2111
2112          if Is_Child_Unit (E) then
2113             null;
2114
2115          --  Ignore formal packages and their renamings
2116
2117          elsif Ekind (E) = E_Package
2118            and then Nkind (Original_Node (Unit_Declaration_Node (E))) =
2119                                                 N_Formal_Package_Declaration
2120          then
2121             null;
2122
2123          --  Otherwise test to see if entity requires a completion
2124
2125          elsif (Is_Overloadable (E)
2126                and then Ekind (E) /= E_Enumeration_Literal
2127                and then Ekind (E) /= E_Operator
2128                and then not Is_Abstract (E)
2129                and then not Has_Completion (E))
2130
2131            or else
2132              (Ekind (E) = E_Package
2133                and then E /= P
2134                and then not Has_Completion (E)
2135                and then Unit_Requires_Body (E))
2136
2137            or else
2138              (Ekind (E) = E_Incomplete_Type and then No (Full_View (E)))
2139
2140            or else
2141             ((Ekind (E) = E_Task_Type or else
2142               Ekind (E) = E_Protected_Type)
2143                and then not Has_Completion (E))
2144
2145            or else
2146              (Ekind (E) = E_Generic_Package and then E /= P
2147                and then not Has_Completion (E)
2148                and then Unit_Requires_Body (E))
2149
2150            or else
2151              (Is_Generic_Subprogram (E)
2152                and then not Has_Completion (E))
2153
2154          then
2155             return True;
2156
2157          --  Entity that does not require completion
2158
2159          else
2160             null;
2161          end if;
2162
2163          Next_Entity (E);
2164       end loop;
2165
2166       return False;
2167    end Unit_Requires_Body;
2168
2169 end Sem_Ch7;