gcc/ada/sem_ch7.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M . C H 7                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This package contains the routines to process package specifications and
  28 --  bodies. The most important semantic aspects of package processing are the
  29 --  handling of private and full declarations, and the construction of
  30 --  dispatch tables for tagged types.
  31
  32 with Atree;    use Atree;
  33 with Debug;    use Debug;
  34 with Einfo;    use Einfo;
  35 with Elists;   use Elists;
  36 with Errout;   use Errout;
  37 with Exp_Disp; use Exp_Disp;
  38 with Exp_Dbug; use Exp_Dbug;
  39 with Lib;      use Lib;
  40 with Lib.Xref; use Lib.Xref;
  41 with Namet;    use Namet;
  42 with Nmake;    use Nmake;
  43 with Nlists;   use Nlists;
  44 with Opt;      use Opt;
  45 with Output;   use Output;
  46 with Sem;      use Sem;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch3;  use Sem_Ch3;
  49 with Sem_Ch6;  use Sem_Ch6;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch10; use Sem_Ch10;
  52 with Sem_Ch12; use Sem_Ch12;
  53 with Sem_Util; use Sem_Util;
  54 with Sem_Warn; use Sem_Warn;
  55 with Snames;   use Snames;
  56 with Stand;    use Stand;
  57 with Sinfo;    use Sinfo;
  58 with Sinput;   use Sinput;
  59 with Style;
  60
  61 package body Sem_Ch7 is
  62
  63    -----------------------------------
  64    -- Handling private declarations --
  65    -----------------------------------
  66
  67    --  The principle that each entity has a single defining occurrence clashes
  68    --  with the presence of two separate definitions for private types: the
  69    --  first is the private type declaration, and the second is the full type
  70    --  declaration. It is important that all references to the type point to
  71    --  the same defining occurrence, namely the first one. To enforce the two
  72    --  separate views of the entity, the corresponding information is swapped
  73    --  between the two declarations. Outside of the package, the defining
  74    --  occurrence only contains the private declaration information, while in
  75    --  the private part and the body of the package the defining occurrence
  76    --  contains the full declaration. To simplify the swap, the defining
  77    --  occurrence that currently holds the private declaration points to the
  78    --  full declaration. During semantic processing the defining occurrence
  79    --  also points to a list of private dependents, that is to say access types
  80    --  or composite types whose designated types or component types are
  81    --  subtypes or derived types of the private type in question. After the
  82    --  full declaration has been seen, the private dependents are updated to
  83    --  indicate that they have full definitions.
  84
  85    -----------------------
  86    -- Local Subprograms --
  87    -----------------------
  88
  89    procedure Install_Package_Entity (Id : Entity_Id);
  90    --  Basic procedure for the previous two. Places one entity on its
  91    --  visibility chain, and recurses on the visible part if the entity
  92    --  is an inner package.
  93
  94    function Is_Private_Base_Type (E : Entity_Id) return Boolean;
  95    --  True for a private type that is not a subtype
  96
  97    function Is_Visible_Dependent (Dep : Entity_Id) return Boolean;
  98    --  If the private dependent is a private type whose full view is
  99    --  derived from the parent type, its full properties are revealed
 100    --  only if we are in the immediate scope of the private dependent.
 101    --  Should this predicate be tightened further???
 102
 103    procedure Declare_Inherited_Private_Subprograms (Id : Entity_Id);
 104    --  Called upon entering the private part of a public child package
 105    --  and the body of a nested package, to potentially declare certain
 106    --  inherited subprograms that were inherited by types in the visible
 107    --  part, but whose declaration was deferred because the parent
 108    --  operation was private and not visible at that point. These
 109    --  subprograms are located by traversing the visible part declarations
 110    --  looking for non-private type extensions and then examining each of
 111    --  the primitive operations of such types to find those that were
 112    --  inherited but declared with a special internal name. Each such
 113    --  operation is now declared as an operation with a normal name (using
 114    --  the name of the parent operation) and replaces the previous implicit
 115    --  operation in the primitive operations list of the type. If the
 116    --  inherited private operation has been overridden, then it's
 117    --  replaced by the overriding operation.
 118
 119    --------------------------
 120    -- Analyze_Package_Body --
 121    --------------------------
 122
 123    procedure Analyze_Package_Body (N : Node_Id) is
 124       Loc              : constant Source_Ptr := Sloc (N);
 125       HSS              : Node_Id;
 126       Body_Id          : Entity_Id;
 127       Spec_Id          : Entity_Id;
 128       Last_Spec_Entity : Entity_Id;
 129       New_N            : Node_Id;
 130       Pack_Decl        : Node_Id;
 131
 132       procedure Install_Composite_Operations (P : Entity_Id);
 133       --  Composite types declared in the current scope may depend on
 134       --  types that were private at the point of declaration, and whose
 135       --  full view is now in  scope. Indicate that the corresponding
 136       --  operations on the composite type are available.
 137
 138       ----------------------------------
 139       -- Install_Composite_Operations --
 140       ----------------------------------
 141
 142       procedure Install_Composite_Operations (P : Entity_Id) is
 143          Id : Entity_Id;
 144
 145       begin
 146          Id := First_Entity (P);
 147
 148          while Present (Id) loop
 149
 150             if Is_Type (Id)
 151               and then (Is_Limited_Composite (Id)
 152                          or else Is_Private_Composite (Id))
 153               and then No (Private_Component (Id))
 154             then
 155                Set_Is_Limited_Composite (Id, False);
 156                Set_Is_Private_Composite (Id, False);
 157             end if;
 158
 159             Next_Entity (Id);
 160          end loop;
 161       end Install_Composite_Operations;
 162
 163    --  Start of processing for Analyze_Package_Body
 164
 165    begin
 166       --  Find corresponding package specification, and establish the
 167       --  current scope. The visible defining entity for the package is the
 168       --  defining occurrence in the spec. On exit from the package body, all
 169       --  body declarations are attached to the defining entity for the body,
 170       --  but the later is never used for name resolution. In this fashion
 171       --  there is only one visible entity that denotes the package.
 172
 173       if Debug_Flag_C then
 174          Write_Str ("====  Compiling package body ");
 175          Write_Name (Chars (Defining_Entity (N)));
 176          Write_Str (" from ");
 177          Write_Location (Loc);
 178          Write_Eol;
 179       end if;
 180
 181       --  Set Body_Id. Note that this Will be reset to point to the
 182       --  generic copy later on in the generic case.
 183
 184       Body_Id := Defining_Entity (N);
 185
 186       if Present (Corresponding_Spec (N)) then
 187
 188          --  Body is body of package instantiation. Corresponding spec
 189          --  has already been set.
 190
 191          Spec_Id := Corresponding_Spec (N);
 192          Pack_Decl := Unit_Declaration_Node (Spec_Id);
 193
 194       else
 195          Spec_Id := Current_Entity_In_Scope (Defining_Entity (N));
 196
 197          if Present (Spec_Id)
 198            and then Is_Package (Spec_Id)
 199          then
 200             Pack_Decl := Unit_Declaration_Node (Spec_Id);
 201
 202             if Nkind (Pack_Decl) = N_Package_Renaming_Declaration then
 203                Error_Msg_N ("cannot supply body for package renaming", N);
 204                return;
 205
 206             elsif Present (Corresponding_Body (Pack_Decl)) then
 207                Error_Msg_N ("redefinition of package body", N);
 208                return;
 209             end if;
 210
 211          else
 212             Error_Msg_N ("missing specification for package body", N);
 213             return;
 214          end if;
 215
 216          if Is_Package (Spec_Id)
 217            and then
 218              (Scope (Spec_Id) = Standard_Standard
 219                or else Is_Child_Unit (Spec_Id))
 220            and then not Unit_Requires_Body (Spec_Id)
 221          then
 222             if Ada_Version = Ada_83 then
 223                Error_Msg_N
 224                  ("optional package body (not allowed in Ada 95)?", N);
 225             else
 226                Error_Msg_N
 227                  ("spec of this package does not allow a body", N);
 228             end if;
 229          end if;
 230       end if;
 231
 232       Set_Is_Compilation_Unit (Body_Id, Is_Compilation_Unit (Spec_Id));
 233       Style.Check_Identifier (Body_Id, Spec_Id);
 234
 235       if Is_Child_Unit (Spec_Id) then
 236          if Nkind (Parent (N)) /= N_Compilation_Unit then
 237             Error_Msg_NE
 238               ("body of child unit& cannot be an inner package", N, Spec_Id);
 239          end if;
 240
 241          Set_Is_Child_Unit (Body_Id);
 242       end if;
 243
 244       --  Generic package case
 245
 246       if Ekind (Spec_Id) = E_Generic_Package then
 247
 248          --  Disable expansion and perform semantic analysis on copy.
 249          --  The unannotated body will be used in all instantiations.
 250
 251          Body_Id := Defining_Entity (N);
 252          Set_Ekind (Body_Id, E_Package_Body);
 253          Set_Scope (Body_Id, Scope (Spec_Id));
 254          Set_Body_Entity (Spec_Id, Body_Id);
 255          Set_Spec_Entity (Body_Id, Spec_Id);
 256
 257          New_N := Copy_Generic_Node (N, Empty, Instantiating => False);
 258          Rewrite (N, New_N);
 259
 260          --  Update Body_Id to point to the copied node for the remainder
 261          --  of the processing.
 262
 263          Body_Id := Defining_Entity (N);
 264          Start_Generic;
 265       end if;
 266
 267       --  The Body_Id is that of the copied node in the generic case, the
 268       --  current node otherwise. Note that N was rewritten above, so we
 269       --  must be sure to get the latest Body_Id value.
 270
 271       Set_Ekind (Body_Id, E_Package_Body);
 272       Set_Body_Entity (Spec_Id, Body_Id);
 273       Set_Spec_Entity (Body_Id, Spec_Id);
 274
 275       --  Defining name for the package body is not a visible entity: Only
 276       --  the defining name for the declaration is visible.
 277
 278       Set_Etype (Body_Id, Standard_Void_Type);
 279       Set_Scope (Body_Id, Scope (Spec_Id));
 280       Set_Corresponding_Spec (N, Spec_Id);
 281       Set_Corresponding_Body (Pack_Decl, Body_Id);
 282
 283       --  The body entity is not used for semantics or code generation, but
 284       --  it is attached to the entity list of the enclosing scope to simplify
 285       --  the listing of back-annotations for the types it main contain.
 286
 287       if Scope (Spec_Id) /= Standard_Standard then
 288          Append_Entity (Body_Id, Scope (Spec_Id));
 289       end if;
 290
 291       --  Indicate that we are currently compiling the body of the package
 292
 293       Set_In_Package_Body (Spec_Id);
 294       Set_Has_Completion (Spec_Id);
 295       Last_Spec_Entity := Last_Entity (Spec_Id);
 296
 297       New_Scope (Spec_Id);
 298
 299       Set_Categorization_From_Pragmas (N);
 300
 301       Install_Visible_Declarations (Spec_Id);
 302       Install_Private_Declarations (Spec_Id);
 303       Install_Private_With_Clauses (Spec_Id);
 304       Install_Composite_Operations (Spec_Id);
 305
 306       if Ekind (Spec_Id) = E_Generic_Package then
 307          Set_Use (Generic_Formal_Declarations (Pack_Decl));
 308       end if;
 309
 310       Set_Use (Visible_Declarations (Specification (Pack_Decl)));
 311       Set_Use (Private_Declarations (Specification (Pack_Decl)));
 312
 313       --  This is a nested package, so it may be necessary to declare
 314       --  certain inherited subprograms that are not yet visible because
 315       --  the parent type's subprograms are now visible.
 316
 317       if Ekind (Scope (Spec_Id)) = E_Package
 318         and then Scope (Spec_Id) /= Standard_Standard
 319       then
 320          Declare_Inherited_Private_Subprograms (Spec_Id);
 321       end if;
 322
 323       if Present (Declarations (N)) then
 324          Analyze_Declarations (Declarations (N));
 325       end if;
 326
 327       HSS := Handled_Statement_Sequence (N);
 328
 329       if Present (HSS) then
 330          Process_End_Label (HSS, 't', Spec_Id);
 331          Analyze (HSS);
 332
 333          --  Check that elaboration code in a preelaborable package body is
 334          --  empty other than null statements and labels (RM 10.2.1(6)).
 335
 336          Validate_Null_Statement_Sequence (N);
 337       end if;
 338
 339       Validate_Categorization_Dependency (N, Spec_Id);
 340       Check_Completion (Body_Id);
 341
 342       --  Generate start of body reference. Note that we do this fairly late,
 343       --  because the call will use In_Extended_Main_Source_Unit as a check,
 344       --  and we want to make sure that Corresponding_Stub links are set
 345
 346       Generate_Reference (Spec_Id, Body_Id, 'b', Set_Ref => False);
 347
 348       --  For a generic package, collect global references and mark
 349       --  them on the original body so that they are not resolved
 350       --  again at the point of instantiation.
 351
 352       if Ekind (Spec_Id) /= E_Package then
 353          Save_Global_References (Original_Node (N));
 354          End_Generic;
 355       end if;
 356
 357       --  The entities of the package body have so far been chained onto
 358       --  the declaration chain for the spec. That's been fine while we
 359       --  were in the body, since we wanted them to be visible, but now
 360       --  that we are leaving the package body, they are no longer visible,
 361       --  so we remove them from the entity chain of the package spec entity,
 362       --  and copy them to the entity chain of the package body entity, where
 363       --  they will never again be visible.
 364
 365       if Present (Last_Spec_Entity) then
 366          Set_First_Entity (Body_Id, Next_Entity (Last_Spec_Entity));
 367          Set_Next_Entity (Last_Spec_Entity, Empty);
 368          Set_Last_Entity (Body_Id, Last_Entity (Spec_Id));
 369          Set_Last_Entity (Spec_Id, Last_Spec_Entity);
 370
 371       else
 372          Set_First_Entity (Body_Id, First_Entity (Spec_Id));
 373          Set_Last_Entity  (Body_Id, Last_Entity  (Spec_Id));
 374          Set_First_Entity (Spec_Id, Empty);
 375          Set_Last_Entity  (Spec_Id, Empty);
 376       end if;
 377
 378       End_Package_Scope (Spec_Id);
 379
 380       --  All entities declared in body are not visible
 381
 382       declare
 383          E : Entity_Id;
 384
 385       begin
 386          E := First_Entity (Body_Id);
 387
 388          while Present (E) loop
 389             Set_Is_Immediately_Visible (E, False);
 390             Set_Is_Potentially_Use_Visible (E, False);
 391             Set_Is_Hidden (E);
 392
 393             --  Child units may appear on the entity list (for example if
 394             --  they appear in the context of a subunit) but they are not
 395             --  body entities.
 396
 397             if not Is_Child_Unit (E) then
 398                Set_Is_Package_Body_Entity (E);
 399             end if;
 400
 401             Next_Entity (E);
 402          end loop;
 403       end;
 404
 405       Check_References (Body_Id);
 406
 407       --  For a generic unit, check that the formal parameters are referenced,
 408       --  and that local variables are used, as for regular packages.
 409
 410       if Ekind (Spec_Id) = E_Generic_Package then
 411          Check_References (Spec_Id);
 412       end if;
 413
 414       --  The processing so far has made all entities of the package body
 415       --  public (i.e. externally visible to the linker). This is in general
 416       --  necessary, since inlined or generic bodies, for which code is
 417       --  generated in other units, may need to see these entities. The
 418       --  following loop runs backwards from the end of the entities of the
 419       --  package body making these entities invisible until we reach a
 420       --  referencer, i.e. a declaration that could reference a previous
 421       --  declaration, a generic body or an inlined body, or a stub (which
 422       --  may contain either of these). This is of course an approximation,
 423       --  but it is conservative and definitely correct.
 424
 425       --  We only do this at the outer (library) level non-generic packages.
 426       --  The reason is simply to cut down on the number of external symbols
 427       --  generated, so this is simply an optimization of the efficiency
 428       --  of the compilation process. It has no other effect.
 429
 430       if (Scope (Spec_Id) = Standard_Standard or else Is_Child_Unit (Spec_Id))
 431         and then not Is_Generic_Unit (Spec_Id)
 432         and then Present (Declarations (N))
 433       then
 434          Make_Non_Public_Where_Possible : declare
 435
 436             function Has_Referencer
 437               (L     : List_Id;
 438                Outer : Boolean)
 439                return  Boolean;
 440             --  Traverse the given list of declarations in reverse order.
 441             --  Return True as soon as a referencer is reached. Return
 442             --  False if none is found. The Outer parameter is True for
 443             --  the outer level call, and False for inner level calls for
 444             --  nested packages. If Outer is True, then any entities up
 445             --  to the point of hitting a referencer get their Is_Public
 446             --  flag cleared, so that the entities will be treated as
 447             --  static entities in the C sense, and need not have fully
 448             --  qualified names. For inner levels, we need all names to
 449             --  be fully qualified to deal with the same name appearing
 450             --  in parallel packages (right now this is tied to their
 451             --  being external).
 452
 453             --------------------
 454             -- Has_Referencer --
 455             --------------------
 456
 457             function Has_Referencer
 458               (L     : List_Id;
 459                Outer : Boolean)
 460                return  Boolean
 461             is
 462                D : Node_Id;
 463                E : Entity_Id;
 464                K : Node_Kind;
 465                S : Entity_Id;
 466
 467             begin
 468                if No (L) then
 469                   return False;
 470                end if;
 471
 472                D := Last (L);
 473
 474                while Present (D) loop
 475                   K := Nkind (D);
 476
 477                   if K in N_Body_Stub then
 478                      return True;
 479
 480                   elsif K = N_Subprogram_Body then
 481                      if Acts_As_Spec (D) then
 482                         E := Defining_Entity (D);
 483
 484                         --  An inlined body acts as a referencer. Note also
 485                         --  that we never reset Is_Public for an inlined
 486                         --  subprogram. Gigi requires Is_Public to be set.
 487
 488                         --  Note that we test Has_Pragma_Inline here rather
 489                         --  than Is_Inlined. We are compiling this for a
 490                         --  client, and it is the client who will decide
 491                         --  if actual inlining should occur, so we need to
 492                         --  assume that the procedure could be inlined for
 493                         --  the purpose of accessing global entities.
 494
 495                         if Has_Pragma_Inline (E) then
 496                            return True;
 497                         else
 498                            Set_Is_Public (E, False);
 499                         end if;
 500
 501                      else
 502                         E := Corresponding_Spec (D);
 503
 504                         if Present (E)
 505                           and then (Is_Generic_Unit (E)
 506                                      or else Has_Pragma_Inline (E)
 507                                      or else Is_Inlined (E))
 508                         then
 509                            return True;
 510                         end if;
 511                      end if;
 512
 513                   --  Processing for package bodies
 514
 515                   elsif K = N_Package_Body
 516                     and then Present (Corresponding_Spec (D))
 517                   then
 518                      E := Corresponding_Spec (D);
 519
 520                      --  Generic package body is a referencer. It would
 521                      --  seem that we only have to consider generics that
 522                      --  can be exported, i.e. where the corresponding spec
 523                      --  is the spec of the current package, but because of
 524                      --  nested instantiations, a fully private generic
 525                      --  body may export other private body entities.
 526
 527                      if Is_Generic_Unit (E) then
 528                         return True;
 529
 530                      --  For non-generic package body, recurse into body
 531                      --  unless this is an instance, we ignore instances
 532                      --  since they cannot have references that affect
 533                      --  outer entities.
 534
 535                      elsif not Is_Generic_Instance (E) then
 536                         if Has_Referencer
 537                              (Declarations (D), Outer => False)
 538                         then
 539                            return True;
 540                         end if;
 541                      end if;
 542
 543                   --  Processing for package specs, recurse into declarations.
 544                   --  Again we skip this for the case of generic instances.
 545
 546                   elsif K = N_Package_Declaration then
 547                      S := Specification (D);
 548
 549                      if not Is_Generic_Unit (Defining_Entity (S)) then
 550                         if Has_Referencer
 551                              (Private_Declarations (S), Outer => False)
 552                         then
 553                            return True;
 554                         elsif Has_Referencer
 555                                (Visible_Declarations (S), Outer => False)
 556                         then
 557                            return True;
 558                         end if;
 559                      end if;
 560
 561                   --  Objects and exceptions need not be public if we have
 562                   --  not encountered a referencer so far. We only reset
 563                   --  the flag for outer level entities that are not
 564                   --  imported/exported, and which have no interface name.
 565
 566                   elsif K = N_Object_Declaration
 567                     or else K = N_Exception_Declaration
 568                     or else K = N_Subprogram_Declaration
 569                   then
 570                      E := Defining_Entity (D);
 571
 572                      if Outer
 573                        and then not Is_Imported (E)
 574                        and then not Is_Exported (E)
 575                        and then No (Interface_Name (E))
 576                      then
 577                         Set_Is_Public (E, False);
 578                      end if;
 579                   end if;
 580
 581                   Prev (D);
 582                end loop;
 583
 584                return False;
 585             end Has_Referencer;
 586
 587          --  Start of processing for Make_Non_Public_Where_Possible
 588
 589          begin
 590             declare
 591                Discard : Boolean;
 592                pragma Warnings (Off, Discard);
 593
 594             begin
 595                Discard := Has_Referencer (Declarations (N), Outer => True);
 596             end;
 597          end Make_Non_Public_Where_Possible;
 598       end if;
 599
 600       --  If expander is not active, then here is where we turn off the
 601       --  In_Package_Body flag, otherwise it is turned off at the end of
 602       --  the corresponding expansion routine. If this is an instance body,
 603       --  we need to qualify names of local entities, because the body may
 604       --  have been compiled as a preliminary to another instantiation.
 605
 606       if not Expander_Active then
 607          Set_In_Package_Body (Spec_Id, False);
 608
 609          if Is_Generic_Instance (Spec_Id)
 610            and then Operating_Mode = Generate_Code
 611          then
 612             Qualify_Entity_Names (N);
 613          end if;
 614       end if;
 615    end Analyze_Package_Body;
 616
 617    ---------------------------------
 618    -- Analyze_Package_Declaration --
 619    ---------------------------------
 620
 621    procedure Analyze_Package_Declaration (N : Node_Id) is
 622       Id : constant Node_Id := Defining_Entity (N);
 623       PF : Boolean;
 624
 625    begin
 626       Generate_Definition (Id);
 627       Enter_Name (Id);
 628       Set_Ekind (Id, E_Package);
 629       Set_Etype (Id, Standard_Void_Type);
 630
 631       New_Scope (Id);
 632
 633       PF := Is_Pure (Enclosing_Lib_Unit_Entity);
 634       Set_Is_Pure (Id, PF);
 635
 636       Set_Categorization_From_Pragmas (N);
 637
 638       if Debug_Flag_C then
 639          Write_Str ("====  Compiling package spec ");
 640          Write_Name (Chars (Id));
 641          Write_Str (" from ");
 642          Write_Location (Sloc (N));
 643          Write_Eol;
 644       end if;
 645
 646       Analyze (Specification (N));
 647       Validate_Categorization_Dependency (N, Id);
 648       End_Package_Scope (Id);
 649
 650       --  For a compilation unit, indicate whether it needs a body, and
 651       --  whether elaboration warnings may be meaningful on it.
 652
 653       if Nkind (Parent (N)) = N_Compilation_Unit then
 654          Set_Body_Required (Parent (N), Unit_Requires_Body (Id));
 655
 656          if not Body_Required (Parent (N)) then
 657             Set_Suppress_Elaboration_Warnings (Id);
 658          end if;
 659
 660          Validate_RT_RAT_Component (N);
 661       end if;
 662    end Analyze_Package_Declaration;
 663
 664    -----------------------------------
 665    -- Analyze_Package_Specification --
 666    -----------------------------------
 667
 668    --  Note that this code is shared for the analysis of generic package
 669    --  specs (see Sem_Ch12.Analyze_Generic_Package_Declaration for details).
 670
 671    procedure Analyze_Package_Specification (N : Node_Id) is
 672       Id           : constant Entity_Id  := Defining_Entity (N);
 673       Orig_Decl    : constant Node_Id    := Original_Node (Parent (N));
 674       Vis_Decls    : constant List_Id    := Visible_Declarations (N);
 675       Priv_Decls   : constant List_Id    := Private_Declarations (N);
 676       E            : Entity_Id;
 677       L            : Entity_Id;
 678       Public_Child : Boolean;
 679
 680       procedure Clear_Constants (Id : Entity_Id; FE : Entity_Id);
 681       --  Clears constant indications (Never_Set_In_Source, Constant_Value,
 682       --  and Is_True_Constant) on all variables that are entities of Id,
 683       --  and on the chain whose first element is FE. A recursive call is
 684       --  made for all packages and generic packages.
 685
 686       procedure Generate_Parent_References;
 687       --  For a child unit, generate references to parent units, for
 688       --  GPS navigation purposes.
 689
 690       function Is_Public_Child (Child, Unit : Entity_Id) return Boolean;
 691       --  Child and Unit are entities of compilation units. True if Child
 692       --  is a public child of Parent as defined in 10.1.1
 693
 694       procedure Inspect_Deferred_Constant_Completion;
 695       --  Examines the deferred constants in the private part of the package
 696       --  specification. Emits the error message "constant declaration requires
 697       --  initialization expression " if not completed by an Import pragma.
 698
 699       procedure Inspect_Unchecked_Union_Completion (Decls : List_Id);
 700       --  Detects all incomplete or private type declarations having a known
 701       --  discriminant part that are completed by an Unchecked_Union. Emits
 702       --  the error message "Unchecked_Union may not complete discriminated
 703       --  partial view".
 704
 705       ---------------------
 706       -- Clear_Constants --
 707       ---------------------
 708
 709       procedure Clear_Constants (Id : Entity_Id; FE : Entity_Id) is
 710          E : Entity_Id;
 711
 712       begin
 713          --  Ignore package renamings, not interesting and they can
 714          --  cause self referential loops in the code below.
 715
 716          if Nkind (Parent (Id)) = N_Package_Renaming_Declaration then
 717             return;
 718          end if;
 719
 720          --  Note: in the loop below, the check for Next_Entity pointing
 721          --  back to the package entity seems very odd, but it is needed,
 722          --  because this kind of unexpected circularity does occur ???
 723
 724          E := FE;
 725          while Present (E) and then E /= Id loop
 726             if Ekind (E) = E_Variable then
 727                Set_Never_Set_In_Source (E, False);
 728                Set_Is_True_Constant    (E, False);
 729                Set_Current_Value       (E, Empty);
 730                Set_Is_Known_Non_Null   (E, False);
 731
 732             elsif Ekind (E) = E_Package
 733                     or else
 734                   Ekind (E) = E_Generic_Package
 735             then
 736                Clear_Constants (E, First_Entity (E));
 737                Clear_Constants (E, First_Private_Entity (E));
 738             end if;
 739
 740             Next_Entity (E);
 741          end loop;
 742       end Clear_Constants;
 743
 744       --------------------------------
 745       -- Generate_Parent_References --
 746       --------------------------------
 747
 748       procedure Generate_Parent_References is
 749          Decl : constant Node_Id := Parent (N);
 750
 751       begin
 752          if Id = Cunit_Entity (Main_Unit)
 753            or else Parent (Decl) = Library_Unit (Cunit (Main_Unit))
 754          then
 755             Generate_Reference (Id, Scope (Id), 'k', False);
 756
 757          elsif Nkind (Unit (Cunit (Main_Unit))) /= N_Subprogram_Body
 758            and then Nkind (Unit (Cunit (Main_Unit))) /= N_Subunit
 759          then
 760             --  If current unit is an ancestor of main unit, generate
 761             --  a reference to its own parent.
 762
 763             declare
 764                U         : Node_Id;
 765                Main_Spec : Node_Id := Unit (Cunit (Main_Unit));
 766
 767             begin
 768                if Nkind (Main_Spec) = N_Package_Body then
 769                   Main_Spec := Unit (Library_Unit (Cunit (Main_Unit)));
 770                end if;
 771
 772                U := Parent_Spec (Main_Spec);
 773                while Present (U) loop
 774                   if U = Parent (Decl) then
 775                      Generate_Reference (Id, Scope (Id), 'k',  False);
 776                      exit;
 777
 778                   elsif Nkind (Unit (U)) = N_Package_Body then
 779                      exit;
 780
 781                   else
 782                      U := Parent_Spec (Unit (U));
 783                   end if;
 784                end loop;
 785             end;
 786          end if;
 787       end Generate_Parent_References;
 788
 789       ---------------------
 790       -- Is_Public_Child --
 791       ---------------------
 792
 793       function Is_Public_Child (Child, Unit : Entity_Id) return Boolean is
 794       begin
 795          if not Is_Private_Descendant (Child) then
 796             return True;
 797          else
 798             if Child = Unit then
 799                return not Private_Present (
 800                  Parent (Unit_Declaration_Node (Child)));
 801             else
 802                return Is_Public_Child (Scope (Child), Unit);
 803             end if;
 804          end if;
 805       end Is_Public_Child;
 806
 807       ------------------------------------------
 808       -- Inspect_Deferred_Constant_Completion --
 809       ------------------------------------------
 810
 811       procedure Inspect_Deferred_Constant_Completion is
 812          Decl   : Node_Id;
 813
 814       begin
 815          Decl := First (Priv_Decls);
 816          while Present (Decl) loop
 817
 818             --  Deferred constant signature
 819
 820             if Nkind (Decl) = N_Object_Declaration
 821               and then Constant_Present (Decl)
 822               and then No (Expression (Decl))
 823
 824                --  No need to check internally generated constants
 825
 826               and then Comes_From_Source (Decl)
 827
 828                --  The constant is not completed. A full object declaration
 829                --  or a pragma Import complete a deferred constant.
 830
 831               and then not Has_Completion (Defining_Identifier (Decl))
 832             then
 833                Error_Msg_N
 834                  ("constant declaration requires initialization expression",
 835                  Defining_Identifier (Decl));
 836             end if;
 837
 838             Decl := Next (Decl);
 839          end loop;
 840       end Inspect_Deferred_Constant_Completion;
 841
 842       ----------------------------------------
 843       -- Inspect_Unchecked_Union_Completion --
 844       ----------------------------------------
 845
 846       procedure Inspect_Unchecked_Union_Completion (Decls : List_Id) is
 847          Decl : Node_Id := First (Decls);
 848
 849       begin
 850          while Present (Decl) loop
 851
 852             --  We are looking at an incomplete or private type declaration
 853             --  with a known_discriminant_part whose full view is an
 854             --  Unchecked_Union.
 855
 856             if (Nkind (Decl) = N_Incomplete_Type_Declaration
 857                   or else
 858                 Nkind (Decl) = N_Private_Type_Declaration)
 859               and then Has_Discriminants (Defining_Identifier (Decl))
 860               and then Present (Full_View (Defining_Identifier (Decl)))
 861               and then Is_Unchecked_Union
 862                 (Full_View (Defining_Identifier (Decl)))
 863             then
 864                Error_Msg_N ("completion of discriminated partial view" &
 865                  " cannot be an Unchecked_Union",
 866                  Full_View (Defining_Identifier (Decl)));
 867             end if;
 868
 869             Next (Decl);
 870          end loop;
 871       end Inspect_Unchecked_Union_Completion;
 872
 873    --  Start of processing for Analyze_Package_Specification
 874
 875    begin
 876       if Present (Vis_Decls) then
 877          Analyze_Declarations (Vis_Decls);
 878       end if;
 879
 880       --  Verify that incomplete types have received full declarations
 881
 882       E := First_Entity (Id);
 883       while Present (E) loop
 884          if Ekind (E) = E_Incomplete_Type
 885            and then No (Full_View (E))
 886          then
 887             Error_Msg_N ("no declaration in visible part for incomplete}", E);
 888          end if;
 889
 890          Next_Entity (E);
 891       end loop;
 892
 893       if Is_Remote_Call_Interface (Id)
 894          and then Nkind (Parent (Parent (N))) = N_Compilation_Unit
 895       then
 896          Validate_RCI_Declarations (Id);
 897       end if;
 898
 899       --  Save global references in the visible declarations, before
 900       --  installing private declarations of parent unit if there is one,
 901       --  because the privacy status of types defined in the parent will
 902       --  change. This is only relevant for generic child units, but is
 903       --  done in all cases for uniformity.
 904
 905       if Ekind (Id) = E_Generic_Package
 906         and then Nkind (Orig_Decl) = N_Generic_Package_Declaration
 907       then
 908          declare
 909             Orig_Spec : constant Node_Id    := Specification (Orig_Decl);
 910             Save_Priv : constant List_Id := Private_Declarations (Orig_Spec);
 911
 912          begin
 913             Set_Private_Declarations (Orig_Spec, Empty_List);
 914             Save_Global_References   (Orig_Decl);
 915             Set_Private_Declarations (Orig_Spec, Save_Priv);
 916          end;
 917       end if;
 918
 919       --  If package is a public child unit, then make the private
 920       --  declarations of the parent visible.
 921
 922       Public_Child := False;
 923
 924       declare
 925          Par       : Entity_Id;
 926          Pack_Decl : Node_Id;
 927          Par_Spec  : Node_Id;
 928
 929       begin
 930          Par := Id;
 931          Par_Spec := Parent_Spec (Parent (N));
 932
 933          --  If the package is formal package of an enclosing generic, is is
 934          --  transformed into a local generic declaration, and compiled to make
 935          --  its spec available. We need to retrieve the original generic to
 936          --  determine whether it is a child unit, and install its parents.
 937
 938          if No (Par_Spec)
 939            and then
 940              Nkind (Original_Node (Parent (N))) = N_Formal_Package_Declaration
 941          then
 942             Par := Entity (Name (Original_Node (Parent (N))));
 943             Par_Spec := Parent_Spec (Unit_Declaration_Node (Par));
 944          end if;
 945
 946          if Present (Par_Spec) then
 947             Generate_Parent_References;
 948
 949             while Scope (Par) /= Standard_Standard
 950               and then Is_Public_Child (Id, Par)
 951             loop
 952                Public_Child := True;
 953                Par := Scope (Par);
 954                Install_Private_Declarations (Par);
 955                Install_Private_With_Clauses (Par);
 956                Pack_Decl := Unit_Declaration_Node (Par);
 957                Set_Use (Private_Declarations (Specification (Pack_Decl)));
 958             end loop;
 959          end if;
 960       end;
 961
 962       if Is_Compilation_Unit (Id) then
 963          Install_Private_With_Clauses (Id);
 964       end if;
 965
 966       --  Analyze private part if present. The flag In_Private_Part is
 967       --  reset in End_Package_Scope.
 968
 969       L := Last_Entity (Id);
 970
 971       if Present (Priv_Decls) then
 972          Set_In_Private_Part (Id);
 973
 974          --  Upon entering a public child's private part, it may be
 975          --  necessary to declare subprograms that were derived in
 976          --  the package visible part but not yet made visible.
 977
 978          if Public_Child then
 979             Declare_Inherited_Private_Subprograms (Id);
 980          end if;
 981
 982          Analyze_Declarations (Priv_Decls);
 983
 984          --  Check the private declarations for incomplete deferred constants
 985
 986          Inspect_Deferred_Constant_Completion;
 987
 988          --  The first private entity is the immediate follower of the last
 989          --  visible entity, if there was one.
 990
 991          if Present (L) then
 992             Set_First_Private_Entity (Id, Next_Entity (L));
 993          else
 994             Set_First_Private_Entity (Id, First_Entity (Id));
 995          end if;
 996
 997       --  There may be inherited private subprograms that need to be
 998       --  declared, even in the absence of an explicit private part.
 999       --  If there are any public declarations in the package and
1000       --  the package is a public child unit, then an implicit private
1001       --  part is assumed.
1002
1003       elsif Present (L) and then Public_Child then
1004          Set_In_Private_Part (Id);
1005          Declare_Inherited_Private_Subprograms (Id);
1006          Set_First_Private_Entity (Id, Next_Entity (L));
1007       end if;
1008
1009       --  Check rule of 3.6(11), which in general requires
1010       --  waiting till all full types have been seen.
1011
1012       E := First_Entity (Id);
1013       while Present (E) loop
1014          if Ekind (E) = E_Record_Type or else Ekind (E) = E_Array_Type then
1015             Check_Aliased_Component_Types (E);
1016          end if;
1017
1018          Next_Entity (E);
1019       end loop;
1020
1021       --  Ada 2005 (AI-216): The completion of an incomplete or private type
1022       --  declaration having a known_discriminant_part shall not be an
1023       --  Unchecked_Union type.
1024
1025       if Present (Vis_Decls) then
1026          Inspect_Unchecked_Union_Completion (Vis_Decls);
1027       end if;
1028
1029       if Present (Priv_Decls) then
1030          Inspect_Unchecked_Union_Completion (Priv_Decls);
1031       end if;
1032
1033       if Ekind (Id) = E_Generic_Package
1034         and then Nkind (Orig_Decl) = N_Generic_Package_Declaration
1035         and then Present (Priv_Decls)
1036       then
1037          --  Save global references in private declarations, ignoring the
1038          --  visible declarations that were processed earlier.
1039
1040          declare
1041             Orig_Spec : constant Node_Id := Specification (Orig_Decl);
1042             Save_Vis  : constant List_Id := Visible_Declarations (Orig_Spec);
1043             Save_Form : constant List_Id :=
1044                           Generic_Formal_Declarations (Orig_Decl);
1045
1046          begin
1047             Set_Visible_Declarations        (Orig_Spec, Empty_List);
1048             Set_Generic_Formal_Declarations (Orig_Decl, Empty_List);
1049             Save_Global_References          (Orig_Decl);
1050             Set_Generic_Formal_Declarations (Orig_Decl, Save_Form);
1051             Set_Visible_Declarations        (Orig_Spec, Save_Vis);
1052          end;
1053       end if;
1054
1055       Process_End_Label (N, 'e', Id);
1056
1057       --  For the case of a library level package, we must go through all
1058       --  the entities clearing the indications that the value may be
1059       --  constant and not modified. Why? Because any client of this
1060       --  package may modify these values freely from anywhere. This
1061       --  also applies to any nested packages or generic packages.
1062
1063       --  For now we unconditionally clear constants for packages that
1064       --  are instances of generic packages. The reason is that we do not
1065       --  have the body yet, and we otherwise think things are unreferenced
1066       --  when they are not. This should be fixed sometime (the effect is
1067       --  not terrible, we just lose some warnings, and also some cases
1068       --  of value propagation) ???
1069
1070       if Is_Library_Level_Entity (Id)
1071         or else Is_Generic_Instance (Id)
1072       then
1073          Clear_Constants (Id, First_Entity (Id));
1074          Clear_Constants (Id, First_Private_Entity (Id));
1075       end if;
1076    end Analyze_Package_Specification;
1077
1078    --------------------------------------
1079    -- Analyze_Private_Type_Declaration --
1080    --------------------------------------
1081
1082    procedure Analyze_Private_Type_Declaration (N : Node_Id) is
1083       PF : constant Boolean   := Is_Pure (Enclosing_Lib_Unit_Entity);
1084       Id : constant Entity_Id := Defining_Identifier (N);
1085
1086    begin
1087       Generate_Definition (Id);
1088       Set_Is_Pure         (Id, PF);
1089       Init_Size_Align     (Id);
1090
1091       if (Ekind (Current_Scope) /= E_Package
1092           and then Ekind (Current_Scope) /= E_Generic_Package)
1093         or else In_Private_Part (Current_Scope)
1094       then
1095          Error_Msg_N ("invalid context for private declaration", N);
1096       end if;
1097
1098       New_Private_Type (N, Id, N);
1099       Set_Depends_On_Private (Id);
1100    end Analyze_Private_Type_Declaration;
1101
1102    -------------------------------------------
1103    -- Declare_Inherited_Private_Subprograms --
1104    -------------------------------------------
1105
1106    procedure Declare_Inherited_Private_Subprograms (Id : Entity_Id) is
1107       E              : Entity_Id;
1108       Op_List        : Elist_Id;
1109       Op_Elmt        : Elmt_Id;
1110       Op_Elmt_2      : Elmt_Id;
1111       Prim_Op        : Entity_Id;
1112       New_Op         : Entity_Id := Empty;
1113       Parent_Subp    : Entity_Id;
1114       Found_Explicit : Boolean;
1115       Decl_Privates  : Boolean;
1116
1117       function Has_Overriding_Pragma (Subp : Entity_Id) return Boolean;
1118       --  Check whether a pragma Overriding has been provided for a primitive
1119       --  operation that is found to be overriding in the private part.
1120
1121       function Is_Primitive_Of (T : Entity_Id; S : Entity_Id) return Boolean;
1122       --  Check whether an inherited subprogram is an operation of an
1123       --  untagged derived type.
1124
1125       ---------------------------
1126       -- Has_Overriding_Pragma --
1127       ---------------------------
1128
1129       function Has_Overriding_Pragma (Subp : Entity_Id) return Boolean is
1130          Decl : constant Node_Id := Unit_Declaration_Node (Subp);
1131          Prag : Node_Id;
1132
1133       begin
1134          if No (Decl)
1135            or else Nkind (Decl) /= N_Subprogram_Declaration
1136            or else No (Next (Decl))
1137          then
1138             return False;
1139
1140          else
1141             Prag := Next (Decl);
1142
1143             while Present (Prag)
1144               and then Nkind (Prag) = N_Pragma
1145             loop
1146                if Chars (Prag) = Name_Overriding
1147                  or else Chars (Prag) = Name_Optional_Overriding
1148                then
1149                   return True;
1150                else
1151                   Next (Prag);
1152                end if;
1153             end loop;
1154          end if;
1155
1156          return False;
1157       end Has_Overriding_Pragma;
1158
1159       ---------------------
1160       -- Is_Primitive_Of --
1161       ---------------------
1162
1163       function Is_Primitive_Of (T : Entity_Id; S : Entity_Id) return Boolean is
1164          Formal : Entity_Id;
1165
1166       begin
1167          if Etype (S) = T then
1168             return True;
1169
1170          else
1171             Formal := First_Formal (S);
1172
1173             while Present (Formal) loop
1174                if Etype (Formal) = T then
1175                   return True;
1176                end if;
1177
1178                Next_Formal (Formal);
1179             end loop;
1180
1181             return False;
1182          end if;
1183       end Is_Primitive_Of;
1184
1185    --  Start of processing for Declare_Inherited_Private_Subprograms
1186
1187    begin
1188       E := First_Entity (Id);
1189       while Present (E) loop
1190
1191          --  If the entity is a nonprivate type extension whose parent
1192          --  type is declared in an open scope, then the type may have
1193          --  inherited operations that now need to be made visible.
1194          --  Ditto if the entity is a formal derived type in a child unit.
1195
1196          if ((Is_Derived_Type (E) and then not Is_Private_Type (E))
1197                or else
1198                  (Nkind (Parent (E)) = N_Private_Extension_Declaration
1199                    and then Is_Generic_Type (E)))
1200            and then In_Open_Scopes (Scope (Etype (E)))
1201            and then E = Base_Type (E)
1202          then
1203             if Is_Tagged_Type (E) then
1204                Op_List       := Primitive_Operations (E);
1205                New_Op        := Empty;
1206                Decl_Privates := False;
1207
1208                Op_Elmt := First_Elmt (Op_List);
1209                while Present (Op_Elmt) loop
1210                   Prim_Op := Node (Op_Elmt);
1211
1212                   --  If the primitive operation is an implicit operation
1213                   --  with an internal name whose parent operation has
1214                   --  a normal name, then we now need to either declare the
1215                   --  operation (i.e., make it visible), or replace it
1216                   --  by an overriding operation if one exists.
1217
1218                   if Present (Alias (Prim_Op))
1219                     and then not Comes_From_Source (Prim_Op)
1220                     and then Is_Internal_Name (Chars (Prim_Op))
1221                     and then not Is_Internal_Name (Chars (Alias (Prim_Op)))
1222                   then
1223                      Parent_Subp := Alias (Prim_Op);
1224
1225                      Found_Explicit := False;
1226                      Op_Elmt_2 := Next_Elmt (Op_Elmt);
1227                      while Present (Op_Elmt_2) loop
1228                         if Chars (Node (Op_Elmt_2)) = Chars (Parent_Subp)
1229                           and then Type_Conformant (Prim_Op, Node (Op_Elmt_2))
1230                         then
1231                            --  The private inherited operation has been
1232                            --  overridden by an explicit subprogram, so
1233                            --  change the private op's list element to
1234                            --  designate the explicit so the explicit
1235                            --  one will get the right dispatching slot.
1236
1237                            New_Op := Node (Op_Elmt_2);
1238                            Replace_Elmt (Op_Elmt, New_Op);
1239                            Remove_Elmt (Op_List, Op_Elmt_2);
1240                            Found_Explicit := True;
1241                            Decl_Privates  := True;
1242
1243                            --  If explicit_overriding is in effect, check that
1244                            --  the overriding operation is properly labelled.
1245
1246                            if Explicit_Overriding
1247                              and then Comes_From_Source (New_Op)
1248                               and then not Has_Overriding_Pragma (New_Op)
1249                            then
1250                               Error_Msg_NE
1251                                 ("Missing overriding pragma for&",
1252                                   New_Op, New_Op);
1253                            end if;
1254
1255                            exit;
1256                         end if;
1257
1258                         Next_Elmt (Op_Elmt_2);
1259                      end loop;
1260
1261                      if not Found_Explicit then
1262                         Derive_Subprogram
1263                           (New_Op, Alias (Prim_Op), E, Etype (E));
1264
1265                         pragma Assert
1266                           (Is_Dispatching_Operation (New_Op)
1267                             and then Node (Last_Elmt (Op_List)) = New_Op);
1268
1269                         --  Substitute the new operation for the old one
1270                         --  in the type's primitive operations list. Since
1271                         --  the new operation was also just added to the end
1272                         --  of list, the last element must be removed.
1273
1274                         --  (Question: is there a simpler way of declaring
1275                         --  the operation, say by just replacing the name
1276                         --  of the earlier operation, reentering it in the
1277                         --  in the symbol table (how?), and marking it as
1278                         --  private???)
1279
1280                         Replace_Elmt (Op_Elmt, New_Op);
1281                         Remove_Last_Elmt (Op_List);
1282                         Decl_Privates := True;
1283                      end if;
1284                   end if;
1285
1286                   Next_Elmt (Op_Elmt);
1287                end loop;
1288
1289                --  The type's DT attributes need to be recalculated
1290                --  in the case where private dispatching operations
1291                --  have been added or overridden. Normally this action
1292                --  occurs during type freezing, but we force it here
1293                --  since the type may already have been frozen (e.g.,
1294                --  if the type's package has an empty private part).
1295                --  This can only be done if expansion is active, otherwise
1296                --  Tag may not be present.
1297
1298                if Decl_Privates
1299                  and then Expander_Active
1300                then
1301                   Set_All_DT_Position (E);
1302                end if;
1303
1304             else
1305                --   Non-tagged type, scan forward to locate
1306                --   inherited hidden operations.
1307
1308                Prim_Op := Next_Entity (E);
1309
1310                while Present (Prim_Op) loop
1311                   if Is_Subprogram (Prim_Op)
1312                     and then Present (Alias (Prim_Op))
1313                     and then not Comes_From_Source (Prim_Op)
1314                     and then Is_Internal_Name (Chars (Prim_Op))
1315                     and then not Is_Internal_Name (Chars (Alias (Prim_Op)))
1316                     and then Is_Primitive_Of (E, Prim_Op)
1317                   then
1318                      Derive_Subprogram (New_Op, Alias (Prim_Op), E, Etype (E));
1319                   end if;
1320
1321                   Next_Entity (Prim_Op);
1322                end loop;
1323             end if;
1324          end if;
1325
1326          Next_Entity (E);
1327       end loop;
1328    end Declare_Inherited_Private_Subprograms;
1329
1330    -----------------------
1331    -- End_Package_Scope --
1332    -----------------------
1333
1334    procedure End_Package_Scope (P : Entity_Id) is
1335    begin
1336       Uninstall_Declarations (P);
1337       Pop_Scope;
1338    end End_Package_Scope;
1339
1340    ---------------------------
1341    -- Exchange_Declarations --
1342    ---------------------------
1343
1344    procedure Exchange_Declarations (Id : Entity_Id) is
1345       Full_Id : constant Entity_Id := Full_View (Id);
1346       H1      : constant Entity_Id := Homonym (Id);
1347       Next1   : constant Entity_Id := Next_Entity (Id);
1348       H2      : Entity_Id;
1349       Next2   : Entity_Id;
1350
1351    begin
1352       --  If missing full declaration for type, nothing to exchange
1353
1354       if No (Full_Id) then
1355          return;
1356       end if;
1357
1358       --  Otherwise complete the exchange, and preserve semantic links
1359
1360       Next2 := Next_Entity (Full_Id);
1361       H2    := Homonym (Full_Id);
1362
1363       --  Reset full declaration pointer to reflect the switched entities
1364       --  and readjust the next entity chains.
1365
1366       Exchange_Entities (Id, Full_Id);
1367
1368       Set_Next_Entity (Id, Next1);
1369       Set_Homonym     (Id, H1);
1370
1371       Set_Full_View   (Full_Id, Id);
1372       Set_Next_Entity (Full_Id, Next2);
1373       Set_Homonym     (Full_Id, H2);
1374    end Exchange_Declarations;
1375
1376    ----------------------------
1377    -- Install_Package_Entity --
1378    ----------------------------
1379
1380    procedure Install_Package_Entity (Id : Entity_Id) is
1381    begin
1382       if not Is_Internal (Id) then
1383          if Debug_Flag_E then
1384             Write_Str ("Install: ");
1385             Write_Name (Chars (Id));
1386             Write_Eol;
1387          end if;
1388
1389          if not Is_Child_Unit (Id) then
1390             Set_Is_Immediately_Visible (Id);
1391          end if;
1392
1393       end if;
1394    end Install_Package_Entity;
1395
1396    ----------------------------------
1397    -- Install_Private_Declarations --
1398    ----------------------------------
1399
1400    procedure Install_Private_Declarations (P : Entity_Id) is
1401       Id        : Entity_Id;
1402       Priv_Elmt : Elmt_Id;
1403       Priv      : Entity_Id;
1404       Full      : Entity_Id;
1405
1406    begin
1407       --  First exchange declarations for private types, so that the
1408       --  full declaration is visible. For each private type, we check
1409       --  its Private_Dependents list and also exchange any subtypes of
1410       --  or derived types from it. Finally, if this is a Taft amendment
1411       --  type, the incomplete declaration is irrelevant, and we want to
1412       --  link the eventual full declaration with the original private
1413       --  one so we also skip the exchange.
1414
1415       Id := First_Entity (P);
1416       while Present (Id) and then Id /= First_Private_Entity (P) loop
1417
1418          if Is_Private_Base_Type (Id)
1419            and then Comes_From_Source (Full_View (Id))
1420            and then Present (Full_View (Id))
1421            and then Scope (Full_View (Id)) = Scope (Id)
1422            and then Ekind (Full_View (Id)) /= E_Incomplete_Type
1423          then
1424             --  If there is a use-type clause on the private type, set the
1425             --  full view accordingly.
1426
1427             Set_In_Use (Full_View (Id), In_Use (Id));
1428             Full := Full_View (Id);
1429
1430             if Is_Private_Base_Type (Full)
1431               and then Has_Private_Declaration (Full)
1432               and then Nkind (Parent (Full)) = N_Full_Type_Declaration
1433               and then In_Open_Scopes (Scope (Etype (Full)))
1434               and then In_Package_Body (Current_Scope)
1435               and then not Is_Private_Type (Etype (Full))
1436             then
1437                --  This is the completion of a private type by a derivation
1438                --  from another private type which is not private anymore. This
1439                --  can only happen in a package nested within a child package,
1440                --  when the parent type is defined in the parent unit. At this
1441                --  point the current type is not private either, and we have to
1442                --  install the underlying full view, which is now visible.
1443
1444                if No (Full_View (Full))
1445                  and then Present (Underlying_Full_View (Full))
1446                then
1447                   Set_Full_View (Id, Underlying_Full_View (Full));
1448                   Set_Underlying_Full_View (Full, Empty);
1449                   Set_Is_Frozen (Full_View (Id));
1450                end if;
1451             end if;
1452
1453             Priv_Elmt := First_Elmt (Private_Dependents (Id));
1454
1455             Exchange_Declarations (Id);
1456             Set_Is_Immediately_Visible (Id);
1457
1458             while Present (Priv_Elmt) loop
1459                Priv := Node (Priv_Elmt);
1460
1461                --  Before the exchange, verify that the presence of the
1462                --  Full_View field. It will be empty if the entity
1463                --  has already been installed due to a previous call.
1464
1465                if Present (Full_View (Priv))
1466                  and then Is_Visible_Dependent (Priv)
1467                then
1468
1469                   --  For each subtype that is swapped, we also swap the
1470                   --  reference to it in Private_Dependents, to allow access
1471                   --  to it when we swap them out in End_Package_Scope.
1472
1473                   Replace_Elmt (Priv_Elmt, Full_View (Priv));
1474                   Exchange_Declarations (Priv);
1475                   Set_Is_Immediately_Visible
1476                     (Priv, In_Open_Scopes (Scope (Priv)));
1477                   Set_Is_Potentially_Use_Visible
1478                     (Priv, Is_Potentially_Use_Visible (Node (Priv_Elmt)));
1479                end if;
1480
1481                Next_Elmt (Priv_Elmt);
1482             end loop;
1483          end if;
1484
1485          Next_Entity (Id);
1486       end loop;
1487
1488       --  Next make other declarations in the private part visible as well
1489
1490       Id := First_Private_Entity (P);
1491
1492       while Present (Id) loop
1493          Install_Package_Entity (Id);
1494          Set_Is_Hidden (Id, False);
1495          Next_Entity (Id);
1496       end loop;
1497
1498       --  Indicate that the private part is currently visible, so it can be
1499       --  properly reset on exit.
1500
1501       Set_In_Private_Part (P);
1502    end Install_Private_Declarations;
1503
1504    ----------------------------------
1505    -- Install_Visible_Declarations --
1506    ----------------------------------
1507
1508    procedure Install_Visible_Declarations (P : Entity_Id) is
1509       Id          : Entity_Id;
1510       Last_Entity : Entity_Id;
1511
1512    begin
1513       pragma Assert (Is_Package (P) or else Is_Record_Type (P));
1514
1515       if Is_Package (P) then
1516          Last_Entity := First_Private_Entity (P);
1517       else
1518          Last_Entity := Empty;
1519       end if;
1520
1521       Id := First_Entity (P);
1522
1523       while Present (Id) and then Id /= Last_Entity loop
1524          Install_Package_Entity (Id);
1525          Next_Entity (Id);
1526       end loop;
1527    end Install_Visible_Declarations;
1528
1529    --------------------------
1530    -- Is_Private_Base_Type --
1531    --------------------------
1532
1533    function Is_Private_Base_Type (E : Entity_Id) return Boolean is
1534    begin
1535       return Ekind (E) = E_Private_Type
1536         or else Ekind (E) = E_Limited_Private_Type
1537         or else Ekind (E) = E_Record_Type_With_Private;
1538    end Is_Private_Base_Type;
1539
1540    --------------------------
1541    -- Is_Visible_Dependent --
1542    --------------------------
1543
1544    function Is_Visible_Dependent (Dep : Entity_Id) return Boolean
1545    is
1546       S : constant Entity_Id := Scope (Dep);
1547
1548    begin
1549       --  Renamings created for actual types have the visibility of the
1550       --  actual.
1551
1552       if Ekind (S) = E_Package
1553         and then Is_Generic_Instance (S)
1554         and then (Is_Generic_Actual_Type (Dep)
1555                    or else Is_Generic_Actual_Type (Full_View (Dep)))
1556       then
1557          return True;
1558
1559       elsif not (Is_Derived_Type (Dep))
1560         and then Is_Derived_Type (Full_View (Dep))
1561       then
1562          --  When instantiating a package body, the scope stack is empty,
1563          --  so check instead whether the dependent type is defined in
1564          --  the same scope as the instance itself.
1565
1566          return In_Open_Scopes (S)
1567            or else (Is_Generic_Instance (Current_Scope)
1568               and then Scope (Dep) = Scope (Current_Scope));
1569       else
1570          return True;
1571       end if;
1572    end Is_Visible_Dependent;
1573
1574    ----------------------------
1575    -- May_Need_Implicit_Body --
1576    ----------------------------
1577
1578    procedure May_Need_Implicit_Body (E : Entity_Id) is
1579       P     : constant Node_Id := Unit_Declaration_Node (E);
1580       S     : constant Node_Id := Parent (P);
1581       B     : Node_Id;
1582       Decls : List_Id;
1583
1584    begin
1585       if not Has_Completion (E)
1586         and then Nkind (P) = N_Package_Declaration
1587         and then Present (Activation_Chain_Entity (P))
1588       then
1589          B :=
1590            Make_Package_Body (Sloc (E),
1591              Defining_Unit_Name => Make_Defining_Identifier (Sloc (E),
1592                Chars => Chars (E)),
1593              Declarations  => New_List);
1594
1595          if Nkind (S) = N_Package_Specification then
1596             if Present (Private_Declarations (S)) then
1597                Decls := Private_Declarations (S);
1598             else
1599                Decls := Visible_Declarations (S);
1600             end if;
1601          else
1602             Decls := Declarations (S);
1603          end if;
1604
1605          Append (B, Decls);
1606          Analyze (B);
1607       end if;
1608    end May_Need_Implicit_Body;
1609
1610    ----------------------
1611    -- New_Private_Type --
1612    ----------------------
1613
1614    procedure New_Private_Type (N : Node_Id; Id : Entity_Id; Def : Node_Id) is
1615    begin
1616       Enter_Name (Id);
1617
1618       if Limited_Present (Def) then
1619          Set_Ekind (Id, E_Limited_Private_Type);
1620       else
1621          Set_Ekind (Id, E_Private_Type);
1622       end if;
1623
1624       Set_Etype              (Id, Id);
1625       Set_Has_Delayed_Freeze (Id);
1626       Set_Is_First_Subtype   (Id);
1627       Init_Size_Align        (Id);
1628
1629       Set_Is_Constrained (Id,
1630         No (Discriminant_Specifications (N))
1631           and then not Unknown_Discriminants_Present (N));
1632
1633       --  Set tagged flag before processing discriminants, to catch
1634       --  illegal usage.
1635
1636       Set_Is_Tagged_Type (Id, Tagged_Present (Def));
1637
1638       Set_Discriminant_Constraint (Id, No_Elist);
1639       Set_Stored_Constraint (Id, No_Elist);
1640
1641       if Present (Discriminant_Specifications (N)) then
1642          New_Scope (Id);
1643          Process_Discriminants (N);
1644          End_Scope;
1645
1646       elsif Unknown_Discriminants_Present (N) then
1647          Set_Has_Unknown_Discriminants (Id);
1648       end if;
1649
1650       Set_Private_Dependents (Id, New_Elmt_List);
1651
1652       if Tagged_Present (Def) then
1653          Set_Ekind                (Id, E_Record_Type_With_Private);
1654          Make_Class_Wide_Type     (Id);
1655          Set_Primitive_Operations (Id, New_Elmt_List);
1656          Set_Is_Abstract          (Id, Abstract_Present (Def));
1657          Set_Is_Limited_Record    (Id, Limited_Present (Def));
1658          Set_Has_Delayed_Freeze   (Id, True);
1659
1660       elsif Abstract_Present (Def) then
1661          Error_Msg_N ("only a tagged type can be abstract", N);
1662       end if;
1663    end New_Private_Type;
1664
1665    ----------------------------
1666    -- Uninstall_Declarations --
1667    ----------------------------
1668
1669    procedure Uninstall_Declarations (P : Entity_Id) is
1670       Decl      : constant Node_Id := Unit_Declaration_Node (P);
1671       Id        : Entity_Id;
1672       Full      : Entity_Id;
1673       Priv_Elmt : Elmt_Id;
1674       Priv_Sub  : Entity_Id;
1675
1676       procedure Preserve_Full_Attributes (Priv, Full : Entity_Id);
1677       --  Copy to the private declaration the attributes of the full view
1678       --  that need to be available for the partial view also.
1679
1680       function Type_In_Use (T : Entity_Id) return Boolean;
1681       --  Check whether type or base type appear in an active use_type clause
1682
1683       ------------------------------
1684       -- Preserve_Full_Attributes --
1685       ------------------------------
1686
1687       procedure Preserve_Full_Attributes (Priv, Full : Entity_Id) is
1688          Priv_Is_Base_Type : constant Boolean := Priv = Base_Type (Priv);
1689
1690       begin
1691          Set_Size_Info (Priv, (Full));
1692          Set_RM_Size (Priv, RM_Size (Full));
1693          Set_Size_Known_At_Compile_Time (Priv, Size_Known_At_Compile_Time
1694                                                                       (Full));
1695          Set_Is_Volatile       (Priv, Is_Volatile       (Full));
1696          Set_Treat_As_Volatile (Priv, Treat_As_Volatile (Full));
1697          Set_Is_Ada_2005       (Priv, Is_Ada_2005       (Full));
1698          --  Why is atomic not copied here ???
1699
1700          if Referenced (Full) then
1701             Set_Referenced (Priv);
1702          end if;
1703
1704          if Priv_Is_Base_Type then
1705             Set_Is_Controlled (Priv, Is_Controlled (Base_Type (Full)));
1706             Set_Finalize_Storage_Only (Priv, Finalize_Storage_Only
1707                                                            (Base_Type (Full)));
1708             Set_Has_Task (Priv, Has_Task (Base_Type (Full)));
1709             Set_Has_Controlled_Component (Priv, Has_Controlled_Component
1710                                                            (Base_Type (Full)));
1711          end if;
1712
1713          Set_Freeze_Node (Priv, Freeze_Node (Full));
1714
1715          if Is_Tagged_Type (Priv)
1716            and then Is_Tagged_Type (Full)
1717            and then not Error_Posted (Full)
1718          then
1719             if Priv_Is_Base_Type then
1720                Set_Access_Disp_Table (Priv, Access_Disp_Table
1721                                                            (Base_Type (Full)));
1722             end if;
1723
1724             Set_First_Entity (Priv, First_Entity (Full));
1725             Set_Last_Entity  (Priv, Last_Entity (Full));
1726             Set_Has_Discriminants (Priv, Has_Discriminants (Full));
1727          end if;
1728       end Preserve_Full_Attributes;
1729
1730       -----------------
1731       -- Type_In_Use --
1732       -----------------
1733
1734       function Type_In_Use (T : Entity_Id) return Boolean is
1735       begin
1736          return Scope (Base_Type (T)) = P
1737            and then  (In_Use (T) or else In_Use (Base_Type (T)));
1738       end Type_In_Use;
1739
1740    --  Start of processing for Uninstall_Declarations
1741
1742    begin
1743       Id := First_Entity (P);
1744
1745       while Present (Id) and then Id /= First_Private_Entity (P) loop
1746          if Debug_Flag_E then
1747             Write_Str ("unlinking visible entity ");
1748             Write_Int (Int (Id));
1749             Write_Eol;
1750          end if;
1751
1752          --  On  exit from the package scope, we must preserve the visibility
1753          --  established by use clauses in the current scope. Two cases:
1754
1755          --  a) If the entity is an operator, it may be a primitive operator of
1756          --  a type for which there is a visible use-type clause.
1757
1758          --  b) for other entities, their use-visibility is determined by a
1759          --  visible use clause for the package itself. For a generic instance,
1760          --  the instantiation of the formals appears in the visible part,
1761          --  but the formals are private and remain so.
1762
1763          if Ekind (Id) = E_Function
1764            and then  Is_Operator_Symbol_Name (Chars (Id))
1765            and then not Is_Hidden (Id)
1766            and then not Error_Posted (Id)
1767          then
1768             Set_Is_Potentially_Use_Visible (Id,
1769               In_Use (P)
1770               or else Type_In_Use (Etype (Id))
1771               or else Type_In_Use (Etype (First_Formal (Id)))
1772               or else (Present (Next_Formal (First_Formal (Id)))
1773                          and then
1774                            Type_In_Use
1775                              (Etype (Next_Formal (First_Formal (Id))))));
1776          else
1777             Set_Is_Potentially_Use_Visible (Id,
1778               In_Use (P) and not Is_Hidden (Id));
1779          end if;
1780
1781          --  Local entities are not immediately visible outside of the package
1782
1783          Set_Is_Immediately_Visible (Id, False);
1784
1785          --  If this is a private type with a full view (for example a local
1786          --  subtype of a private type declared elsewhere), ensure that the
1787          --  full view is also removed from visibility: it may be exposed when
1788          --  swapping views in an instantiation.
1789
1790          if Is_Type (Id)
1791            and then Present (Full_View (Id))
1792          then
1793             Set_Is_Immediately_Visible (Full_View (Id), False);
1794          end if;
1795
1796          if Is_Tagged_Type (Id) and then Ekind (Id) = E_Record_Type then
1797             Check_Abstract_Overriding (Id);
1798          end if;
1799
1800          if (Ekind (Id) = E_Private_Type
1801                or else Ekind (Id) = E_Limited_Private_Type)
1802            and then No (Full_View (Id))
1803            and then not Is_Generic_Type (Id)
1804            and then not Is_Derived_Type (Id)
1805          then
1806             Error_Msg_N ("missing full declaration for private type&", Id);
1807
1808          elsif Ekind (Id) = E_Record_Type_With_Private
1809            and then not Is_Generic_Type (Id)
1810            and then No (Full_View (Id))
1811          then
1812             if Nkind (Parent (Id)) = N_Private_Type_Declaration then
1813                Error_Msg_N ("missing full declaration for private type&", Id);
1814             else
1815                Error_Msg_N
1816                  ("missing full declaration for private extension", Id);
1817             end if;
1818
1819          elsif Ekind (Id) = E_Constant
1820            and then No (Constant_Value (Id))
1821            and then No (Full_View (Id))
1822            and then not Is_Imported (Id)
1823            and then (Nkind (Parent (Id)) /= N_Object_Declaration
1824                       or else not No_Initialization (Parent (Id)))
1825          then
1826             if not Has_Private_Declaration (Etype (Id)) then
1827
1828                --  We assume that the user did not not intend a deferred
1829                --  constant declaration, and the expression is just missing.
1830
1831                Error_Msg_N
1832                  ("constant declaration requires initialization expression",
1833                    Parent (Id));
1834
1835                if Is_Limited_Type (Etype (Id)) then
1836                   Error_Msg_N
1837                     ("\else remove keyword CONSTANT from declaration",
1838                     Parent (Id));
1839                end if;
1840
1841             else
1842                Error_Msg_N
1843                   ("missing full declaration for deferred constant ('R'M 7.4)",
1844                      Id);
1845
1846                if Is_Limited_Type (Etype (Id)) then
1847                   Error_Msg_N
1848                     ("\else remove keyword CONSTANT from declaration",
1849                     Parent (Id));
1850                end if;
1851             end if;
1852          end if;
1853
1854          Next_Entity (Id);
1855       end loop;
1856
1857       --  If the specification was installed as the parent of a public child
1858       --  unit, the private declarations were not installed, and there is
1859       --  nothing to do.
1860
1861       if not In_Private_Part (P) then
1862          return;
1863       else
1864          Set_In_Private_Part (P, False);
1865       end if;
1866
1867       --  Make private entities invisible and exchange full and private
1868       --  declarations for private types.
1869
1870       while Present (Id) loop
1871          if Debug_Flag_E then
1872             Write_Str ("unlinking private entity ");
1873             Write_Int (Int (Id));
1874             Write_Eol;
1875          end if;
1876
1877          if Is_Tagged_Type (Id) and then Ekind (Id) = E_Record_Type then
1878             Check_Abstract_Overriding (Id);
1879          end if;
1880
1881          Set_Is_Immediately_Visible (Id, False);
1882
1883          if Is_Private_Base_Type (Id)
1884            and then Present (Full_View (Id))
1885          then
1886             Full := Full_View (Id);
1887
1888             --  If the partial view is not declared in the visible part
1889             --  of the package (as is the case when it is a type derived
1890             --  from some other private type in the private part of the
1891             --  current package), no exchange takes place.
1892
1893             if No (Parent (Id))
1894               or else List_Containing (Parent (Id))
1895                 /= Visible_Declarations (Specification (Decl))
1896             then
1897                goto Next_Id;
1898             end if;
1899
1900             --  The entry in the private part points to the full declaration,
1901             --  which is currently visible. Exchange them so only the private
1902             --  type declaration remains accessible, and link private and
1903             --  full declaration in the opposite direction. Before the actual
1904             --  exchange, we copy back attributes of the full view that
1905             --  must be available to the partial view too.
1906
1907             Preserve_Full_Attributes (Id, Full);
1908
1909             Set_Is_Potentially_Use_Visible (Id, In_Use (P));
1910
1911             if  Is_Indefinite_Subtype (Full)
1912               and then not Is_Indefinite_Subtype (Id)
1913             then
1914                Error_Msg_N
1915                  ("full view of type must be definite subtype", Full);
1916             end if;
1917
1918             Priv_Elmt := First_Elmt (Private_Dependents (Id));
1919
1920             --  Swap out the subtypes and derived types of Id that were
1921             --  compiled in this scope, or installed previously by
1922             --  Install_Private_Declarations.
1923             --  Before we do the swap, we verify the presence of the
1924             --  Full_View field which may be empty due to a swap by
1925             --  a previous call to End_Package_Scope (e.g. from the
1926             --  freezing mechanism).
1927
1928             while Present (Priv_Elmt) loop
1929                Priv_Sub := Node (Priv_Elmt);
1930
1931                if Present (Full_View (Priv_Sub)) then
1932
1933                   if Scope (Priv_Sub) = P
1934                      or else not In_Open_Scopes (Scope (Priv_Sub))
1935                   then
1936                      Set_Is_Immediately_Visible (Priv_Sub, False);
1937                   end if;
1938
1939                   if Is_Visible_Dependent (Priv_Sub) then
1940                      Preserve_Full_Attributes
1941                        (Priv_Sub, Full_View (Priv_Sub));
1942                      Replace_Elmt (Priv_Elmt, Full_View (Priv_Sub));
1943                      Exchange_Declarations (Priv_Sub);
1944                   end if;
1945                end if;
1946
1947                Next_Elmt (Priv_Elmt);
1948             end loop;
1949
1950             --  Now restore the type itself to its private view.
1951
1952             Exchange_Declarations (Id);
1953
1954          elsif Ekind (Id) = E_Incomplete_Type
1955            and then No (Full_View (Id))
1956          then
1957             --  Mark Taft amendment types
1958
1959             Set_Has_Completion_In_Body (Id);
1960
1961          elsif not Is_Child_Unit (Id)
1962            and then (not Is_Private_Type (Id)
1963                       or else No (Full_View (Id)))
1964          then
1965             Set_Is_Hidden (Id);
1966             Set_Is_Potentially_Use_Visible (Id, False);
1967          end if;
1968
1969          <<Next_Id>>
1970             Next_Entity (Id);
1971       end loop;
1972    end Uninstall_Declarations;
1973
1974    ------------------------
1975    -- Unit_Requires_Body --
1976    ------------------------
1977
1978    function Unit_Requires_Body (P : Entity_Id) return Boolean is
1979       E : Entity_Id;
1980
1981    begin
1982       --  Imported entity never requires body. Right now, only
1983       --  subprograms can be imported, but perhaps in the future
1984       --  we will allow import of packages.
1985
1986       if Is_Imported (P) then
1987          return False;
1988
1989       --  Body required if library package with pragma Elaborate_Body
1990
1991       elsif Has_Pragma_Elaborate_Body (P) then
1992          return True;
1993
1994       --  Body required if subprogram
1995
1996       elsif Is_Subprogram (P) or else Is_Generic_Subprogram (P) then
1997          return True;
1998
1999       --  Treat a block as requiring a body
2000
2001       elsif Ekind (P) = E_Block then
2002          return True;
2003
2004       elsif Ekind (P) = E_Package
2005         and then Nkind (Parent (P)) = N_Package_Specification
2006         and then Present (Generic_Parent (Parent (P)))
2007       then
2008          declare
2009             G_P : constant Entity_Id := Generic_Parent (Parent (P));
2010
2011          begin
2012             if Has_Pragma_Elaborate_Body (G_P) then
2013                return True;
2014             end if;
2015          end;
2016       end if;
2017
2018       --  Otherwise search entity chain for entity requiring completion
2019
2020       E := First_Entity (P);
2021       while Present (E) loop
2022
2023          --  Always ignore child units. Child units get added to the entity
2024          --  list of a parent unit, but are not original entities of the
2025          --  parent, and so do not affect whether the parent needs a body.
2026
2027          if Is_Child_Unit (E) then
2028             null;
2029
2030          --  Ignore formal packages and their renamings
2031
2032          elsif Ekind (E) = E_Package
2033            and then Nkind (Original_Node (Unit_Declaration_Node (E))) =
2034                                                 N_Formal_Package_Declaration
2035          then
2036             null;
2037
2038          --  Otherwise test to see if entity requires a completion
2039
2040          elsif (Is_Overloadable (E)
2041                and then Ekind (E) /= E_Enumeration_Literal
2042                and then Ekind (E) /= E_Operator
2043                and then not Is_Abstract (E)
2044                and then not Has_Completion (E))
2045
2046            or else
2047              (Ekind (E) = E_Package
2048                and then E /= P
2049                and then not Has_Completion (E)
2050                and then Unit_Requires_Body (E))
2051
2052            or else
2053              (Ekind (E) = E_Incomplete_Type and then No (Full_View (E)))
2054
2055            or else
2056             ((Ekind (E) = E_Task_Type or else
2057               Ekind (E) = E_Protected_Type)
2058                and then not Has_Completion (E))
2059
2060            or else
2061              (Ekind (E) = E_Generic_Package and then E /= P
2062                and then not Has_Completion (E)
2063                and then Unit_Requires_Body (E))
2064
2065            or else
2066              (Is_Generic_Subprogram (E)
2067                and then not Has_Completion (E))
2068
2069          then
2070             return True;
2071
2072          --  Entity that does not require completion
2073
2074          else
2075             null;
2076          end if;
2077
2078          Next_Entity (E);
2079       end loop;
2080
2081       return False;
2082    end Unit_Requires_Body;
2083
2084 end Sem_Ch7;