gcc/ada/sem_ch6.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 6                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Checks;   use Checks;
  29 with Debug;    use Debug;
  30 with Einfo;    use Einfo;
  31 with Elists;   use Elists;
  32 with Errout;   use Errout;
  33 with Expander; use Expander;
  34 with Exp_Ch7;  use Exp_Ch7;
  35 with Fname;    use Fname;
  36 with Freeze;   use Freeze;
  37 with Lib.Xref; use Lib.Xref;
  38 with Namet;    use Namet;
  39 with Lib;      use Lib;
  40 with Nlists;   use Nlists;
  41 with Nmake;    use Nmake;
  42 with Opt;      use Opt;
  43 with Output;   use Output;
  44 with Rtsfind;  use Rtsfind;
  45 with Sem;      use Sem;
  46 with Sem_Cat;  use Sem_Cat;
  47 with Sem_Ch3;  use Sem_Ch3;
  48 with Sem_Ch4;  use Sem_Ch4;
  49 with Sem_Ch5;  use Sem_Ch5;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch10; use Sem_Ch10;
  52 with Sem_Ch12; use Sem_Ch12;
  53 with Sem_Disp; use Sem_Disp;
  54 with Sem_Dist; use Sem_Dist;
  55 with Sem_Elim; use Sem_Elim;
  56 with Sem_Eval; use Sem_Eval;
  57 with Sem_Mech; use Sem_Mech;
  58 with Sem_Prag; use Sem_Prag;
  59 with Sem_Res;  use Sem_Res;
  60 with Sem_Util; use Sem_Util;
  61 with Sem_Type; use Sem_Type;
  62 with Sem_Warn; use Sem_Warn;
  63 with Sinput;   use Sinput;
  64 with Stand;    use Stand;
  65 with Sinfo;    use Sinfo;
  66 with Sinfo.CN; use Sinfo.CN;
  67 with Snames;   use Snames;
  68 with Stringt;  use Stringt;
  69 with Style;
  70 with Stylesw;  use Stylesw;
  71 with Tbuild;   use Tbuild;
  72 with Uintp;    use Uintp;
  73 with Urealp;   use Urealp;
  74 with Validsw;  use Validsw;
  75
  76 package body Sem_Ch6 is
  77
  78    -----------------------
  79    -- Local Subprograms --
  80    -----------------------
  81
  82    procedure Analyze_Generic_Subprogram_Body (N : Node_Id; Gen_Id : Entity_Id);
  83    --  Analyze a generic subprogram body. N is the body to be analyzed,
  84    --  and Gen_Id is the defining entity Id for the corresponding spec.
  85
  86    procedure Build_Body_To_Inline (N : Node_Id; Subp : Entity_Id);
  87    --  If a subprogram has pragma Inline and inlining is active, use generic
  88    --  machinery to build an unexpanded body for the subprogram. This body is
  89    --  subsequenty used for inline expansions at call sites. If subprogram can
  90    --  be inlined (depending on size and nature of local declarations) this
  91    --  function returns true. Otherwise subprogram body is treated normally.
  92    --  If proper warnings are enabled and the subprogram contains a construct
  93    --  that cannot be inlined, the offending construct is flagged accordingly.
  94
  95    type Conformance_Type is
  96      (Type_Conformant, Mode_Conformant, Subtype_Conformant, Fully_Conformant);
  97    --  Conformance type used for following call, meaning matches the
  98    --  RM definitions of the corresponding terms.
  99
 100    procedure Check_Conformance
 101      (New_Id   : Entity_Id;
 102       Old_Id   : Entity_Id;
 103       Ctype    : Conformance_Type;
 104       Errmsg   : Boolean;
 105       Conforms : out Boolean;
 106       Err_Loc  : Node_Id := Empty;
 107       Get_Inst : Boolean := False);
 108    --  Given two entities, this procedure checks that the profiles associated
 109    --  with these entities meet the conformance criterion given by the third
 110    --  parameter. If they conform, Conforms is set True and control returns
 111    --  to the caller. If they do not conform, Conforms is set to False, and
 112    --  in addition, if Errmsg is True on the call, proper messages are output
 113    --  to complain about the conformance failure. If Err_Loc is non_Empty
 114    --  the error messages are placed on Err_Loc, if Err_Loc is empty, then
 115    --  error messages are placed on the appropriate part of the construct
 116    --  denoted by New_Id. If Get_Inst is true, then this is a mode conformance
 117    --  against a formal access-to-subprogram type so Get_Instance_Of must
 118    --  be called.
 119
 120    procedure Check_Overriding_Operation
 121      (N    : Node_Id;
 122       Subp : Entity_Id);
 123    --  Check that a subprogram with a pragma Overriding or Optional_Overriding
 124    --  is legal. This check is performed here rather than in Sem_Prag because
 125    --  the pragma must follow immediately the declaration, and can be treated
 126    --  as part of the declaration itself, as described in AI-218.
 127
 128    procedure Check_Subprogram_Order (N : Node_Id);
 129    --  N is the N_Subprogram_Body node for a subprogram. This routine applies
 130    --  the alpha ordering rule for N if this ordering requirement applicable.
 131
 132    function Is_Non_Overriding_Operation
 133      (Prev_E : Entity_Id;
 134       New_E  : Entity_Id) return Boolean;
 135    --  Enforce the rule given in 12.3(18): a private operation in an instance
 136    --  overrides an inherited operation only if the corresponding operation
 137    --  was overriding in the generic. This can happen for primitive operations
 138    --  of types derived (in the generic unit) from formal private or formal
 139    --  derived types.
 140
 141    procedure Check_Returns
 142      (HSS  : Node_Id;
 143       Mode : Character;
 144       Err  : out Boolean);
 145    --  Called to check for missing return statements in a function body,
 146    --  or for returns present in a procedure body which has No_Return set.
 147    --  L is the handled statement sequence for the subprogram body. This
 148    --  procedure checks all flow paths to make sure they either have a
 149    --  return (Mode = 'F') or do not have a return (Mode = 'P'). The flag
 150    --  Err is set if there are any control paths not explicitly terminated
 151    --  by a return in the function case, and is True otherwise.
 152
 153    function Conforming_Types
 154      (T1       : Entity_Id;
 155       T2       : Entity_Id;
 156       Ctype    : Conformance_Type;
 157       Get_Inst : Boolean := False) return Boolean;
 158    --  Check that two formal parameter types conform, checking both
 159    --  for equality of base types, and where required statically
 160    --  matching subtypes, depending on the setting of Ctype.
 161
 162    procedure Enter_Overloaded_Entity (S : Entity_Id);
 163    --  This procedure makes S, a new overloaded entity, into the first
 164    --  visible entity with that name.
 165
 166    procedure Install_Entity (E : Entity_Id);
 167    --  Make single entity visible. Used for generic formals as well.
 168
 169    procedure Install_Formals (Id : Entity_Id);
 170    --  On entry to a subprogram body, make the formals visible. Note
 171    --  that simply placing the subprogram on the scope stack is not
 172    --  sufficient: the formals must become the current entities for
 173    --  their names.
 174
 175    procedure Make_Inequality_Operator (S : Entity_Id);
 176    --  Create the declaration for an inequality operator that is implicitly
 177    --  created by a user-defined equality operator that yields a boolean.
 178
 179    procedure May_Need_Actuals (Fun : Entity_Id);
 180    --  Flag functions that can be called without parameters, i.e. those that
 181    --  have no parameters, or those for which defaults exist for all parameters
 182
 183    procedure Reference_Body_Formals (Spec : Entity_Id; Bod : Entity_Id);
 184    --  If there is a separate spec for a subprogram or generic subprogram,
 185    --  the formals of the body are treated as references to the corresponding
 186    --  formals of the spec. This reference does not count as an actual use of
 187    --  the formal, in order to diagnose formals that are unused in the body.
 188
 189    procedure Set_Formal_Validity (Formal_Id : Entity_Id);
 190    --  Formal_Id is an formal parameter entity. This procedure deals with
 191    --  setting the proper validity status for this entity, which depends
 192    --  on the kind of parameter and the validity checking mode.
 193
 194    ---------------------------------------------
 195    -- Analyze_Abstract_Subprogram_Declaration --
 196    ---------------------------------------------
 197
 198    procedure Analyze_Abstract_Subprogram_Declaration (N : Node_Id) is
 199       Designator : constant Entity_Id :=
 200                      Analyze_Subprogram_Specification (Specification (N));
 201       Scop       : constant Entity_Id := Current_Scope;
 202
 203    begin
 204       Generate_Definition (Designator);
 205       Set_Is_Abstract (Designator);
 206       New_Overloaded_Entity (Designator);
 207       Check_Delayed_Subprogram (Designator);
 208
 209       Set_Categorization_From_Scope (Designator, Scop);
 210
 211       if Ekind (Scope (Designator)) = E_Protected_Type then
 212          Error_Msg_N
 213            ("abstract subprogram not allowed in protected type", N);
 214       end if;
 215
 216       Generate_Reference_To_Formals (Designator);
 217    end Analyze_Abstract_Subprogram_Declaration;
 218
 219    ----------------------------
 220    -- Analyze_Function_Call  --
 221    ----------------------------
 222
 223    procedure Analyze_Function_Call (N : Node_Id) is
 224       P      : constant Node_Id := Name (N);
 225       L      : constant List_Id := Parameter_Associations (N);
 226       Actual : Node_Id;
 227
 228    begin
 229       Analyze (P);
 230
 231       --  If error analyzing name, then set Any_Type as result type and return
 232
 233       if Etype (P) = Any_Type then
 234          Set_Etype (N, Any_Type);
 235          return;
 236       end if;
 237
 238       --  Otherwise analyze the parameters
 239
 240       if Present (L) then
 241          Actual := First (L);
 242
 243          while Present (Actual) loop
 244             Analyze (Actual);
 245             Check_Parameterless_Call (Actual);
 246             Next (Actual);
 247          end loop;
 248       end if;
 249
 250       Analyze_Call (N);
 251    end Analyze_Function_Call;
 252
 253    -------------------------------------
 254    -- Analyze_Generic_Subprogram_Body --
 255    -------------------------------------
 256
 257    procedure Analyze_Generic_Subprogram_Body
 258      (N      : Node_Id;
 259       Gen_Id : Entity_Id)
 260    is
 261       Gen_Decl : constant Node_Id     := Unit_Declaration_Node (Gen_Id);
 262       Kind     : constant Entity_Kind := Ekind (Gen_Id);
 263       Body_Id  : Entity_Id;
 264       New_N    : Node_Id;
 265       Spec     : Node_Id;
 266
 267    begin
 268       --  Copy body and disable expansion while analyzing the generic
 269       --  For a stub, do not copy the stub (which would load the proper body),
 270       --  this will be done when the proper body is analyzed.
 271
 272       if Nkind (N) /= N_Subprogram_Body_Stub then
 273          New_N := Copy_Generic_Node (N, Empty, Instantiating => False);
 274          Rewrite (N, New_N);
 275          Start_Generic;
 276       end if;
 277
 278       Spec := Specification (N);
 279
 280       --  Within the body of the generic, the subprogram is callable, and
 281       --  behaves like the corresponding non-generic unit.
 282
 283       Body_Id := Defining_Entity (Spec);
 284
 285       if Kind = E_Generic_Procedure
 286         and then Nkind (Spec) /= N_Procedure_Specification
 287       then
 288          Error_Msg_N ("invalid body for generic procedure ", Body_Id);
 289          return;
 290
 291       elsif Kind = E_Generic_Function
 292         and then Nkind (Spec) /= N_Function_Specification
 293       then
 294          Error_Msg_N ("invalid body for generic function ", Body_Id);
 295          return;
 296       end if;
 297
 298       Set_Corresponding_Body (Gen_Decl, Body_Id);
 299
 300       if Has_Completion (Gen_Id)
 301         and then Nkind (Parent (N)) /= N_Subunit
 302       then
 303          Error_Msg_N ("duplicate generic body", N);
 304          return;
 305       else
 306          Set_Has_Completion (Gen_Id);
 307       end if;
 308
 309       if Nkind (N) = N_Subprogram_Body_Stub then
 310          Set_Ekind (Defining_Entity (Specification (N)), Kind);
 311       else
 312          Set_Corresponding_Spec (N, Gen_Id);
 313       end if;
 314
 315       if Nkind (Parent (N)) = N_Compilation_Unit then
 316          Set_Cunit_Entity (Current_Sem_Unit, Defining_Entity (N));
 317       end if;
 318
 319       --  Make generic parameters immediately visible in the body. They are
 320       --  needed to process the formals declarations. Then make the formals
 321       --  visible in a separate step.
 322
 323       New_Scope (Gen_Id);
 324
 325       declare
 326          E         : Entity_Id;
 327          First_Ent : Entity_Id;
 328
 329       begin
 330          First_Ent := First_Entity (Gen_Id);
 331
 332          E := First_Ent;
 333          while Present (E) and then not Is_Formal (E) loop
 334             Install_Entity (E);
 335             Next_Entity (E);
 336          end loop;
 337
 338          Set_Use (Generic_Formal_Declarations (Gen_Decl));
 339
 340          --  Now generic formals are visible, and the specification can be
 341          --  analyzed, for subsequent conformance check.
 342
 343          Body_Id := Analyze_Subprogram_Specification (Spec);
 344
 345          --  Make formal parameters visible
 346
 347          if Present (E) then
 348
 349             --  E is the first formal parameter, we loop through the formals
 350             --  installing them so that they will be visible.
 351
 352             Set_First_Entity (Gen_Id, E);
 353             while Present (E) loop
 354                Install_Entity (E);
 355                Next_Formal (E);
 356             end loop;
 357          end if;
 358
 359          --  Visible generic entity is callable within its own body.
 360
 361          Set_Ekind (Gen_Id, Ekind (Body_Id));
 362          Set_Ekind (Body_Id, E_Subprogram_Body);
 363          Set_Convention (Body_Id, Convention (Gen_Id));
 364          Set_Scope (Body_Id, Scope (Gen_Id));
 365          Check_Fully_Conformant (Body_Id, Gen_Id, Body_Id);
 366
 367          if Nkind (N) = N_Subprogram_Body_Stub then
 368
 369             --  No body to analyze, so restore state of generic unit.
 370
 371             Set_Ekind (Gen_Id, Kind);
 372             Set_Ekind (Body_Id, Kind);
 373
 374             if Present (First_Ent) then
 375                Set_First_Entity (Gen_Id, First_Ent);
 376             end if;
 377
 378             End_Scope;
 379             return;
 380          end if;
 381
 382          --  If this is a compilation unit, it must be made visible
 383          --  explicitly, because the compilation of the declaration,
 384          --  unlike other library unit declarations, does not. If it
 385          --  is not a unit, the following is redundant but harmless.
 386
 387          Set_Is_Immediately_Visible (Gen_Id);
 388          Reference_Body_Formals (Gen_Id, Body_Id);
 389
 390          Set_Actual_Subtypes (N, Current_Scope);
 391          Analyze_Declarations (Declarations (N));
 392          Check_Completion;
 393          Analyze (Handled_Statement_Sequence (N));
 394
 395          Save_Global_References (Original_Node (N));
 396
 397          --  Prior to exiting the scope, include generic formals again
 398          --  (if any are present) in the set of local entities.
 399
 400          if Present (First_Ent) then
 401             Set_First_Entity (Gen_Id, First_Ent);
 402          end if;
 403
 404          Check_References (Gen_Id);
 405       end;
 406
 407       Process_End_Label (Handled_Statement_Sequence (N), 't', Current_Scope);
 408       End_Scope;
 409       Check_Subprogram_Order (N);
 410
 411       --  Outside of its body, unit is generic again.
 412
 413       Set_Ekind (Gen_Id, Kind);
 414       Generate_Reference (Gen_Id, Body_Id, 'b', Set_Ref => False);
 415       Style.Check_Identifier (Body_Id, Gen_Id);
 416       End_Generic;
 417    end Analyze_Generic_Subprogram_Body;
 418
 419    -----------------------------
 420    -- Analyze_Operator_Symbol --
 421    -----------------------------
 422
 423    --  An operator symbol such as "+" or "and" may appear in context where
 424    --  the literal denotes an entity name, such as  "+"(x, y) or in a
 425    --  context when it is just a string, as in  (conjunction = "or"). In
 426    --  these cases the parser generates this node, and the semantics does
 427    --  the disambiguation. Other such case are actuals in an instantiation,
 428    --  the generic unit in an instantiation, and pragma arguments.
 429
 430    procedure Analyze_Operator_Symbol (N : Node_Id) is
 431       Par : constant Node_Id := Parent (N);
 432
 433    begin
 434       if        (Nkind (Par) = N_Function_Call and then N = Name (Par))
 435         or else  Nkind (Par) = N_Function_Instantiation
 436         or else (Nkind (Par) = N_Indexed_Component and then N = Prefix (Par))
 437         or else (Nkind (Par) = N_Pragma_Argument_Association
 438                    and then not Is_Pragma_String_Literal (Par))
 439         or else  Nkind (Par) = N_Subprogram_Renaming_Declaration
 440         or else  (Nkind (Par) = N_Attribute_Reference
 441                    and then Attribute_Name (Par) /= Name_Value)
 442       then
 443          Find_Direct_Name (N);
 444
 445       else
 446          Change_Operator_Symbol_To_String_Literal (N);
 447          Analyze (N);
 448       end if;
 449    end Analyze_Operator_Symbol;
 450
 451    -----------------------------------
 452    -- Analyze_Parameter_Association --
 453    -----------------------------------
 454
 455    procedure Analyze_Parameter_Association (N : Node_Id) is
 456    begin
 457       Analyze (Explicit_Actual_Parameter (N));
 458    end Analyze_Parameter_Association;
 459
 460    ----------------------------
 461    -- Analyze_Procedure_Call --
 462    ----------------------------
 463
 464    procedure Analyze_Procedure_Call (N : Node_Id) is
 465       Loc     : constant Source_Ptr := Sloc (N);
 466       P       : constant Node_Id    := Name (N);
 467       Actuals : constant List_Id    := Parameter_Associations (N);
 468       Actual  : Node_Id;
 469       New_N   : Node_Id;
 470
 471       procedure Analyze_Call_And_Resolve;
 472       --  Do Analyze and Resolve calls for procedure call
 473
 474       ------------------------------
 475       -- Analyze_Call_And_Resolve --
 476       ------------------------------
 477
 478       procedure Analyze_Call_And_Resolve is
 479       begin
 480          if Nkind (N) = N_Procedure_Call_Statement then
 481             Analyze_Call (N);
 482             Resolve (N, Standard_Void_Type);
 483          else
 484             Analyze (N);
 485          end if;
 486       end Analyze_Call_And_Resolve;
 487
 488    --  Start of processing for Analyze_Procedure_Call
 489
 490    begin
 491       --  The syntactic construct: PREFIX ACTUAL_PARAMETER_PART can denote
 492       --  a procedure call or an entry call. The prefix may denote an access
 493       --  to subprogram type, in which case an implicit dereference applies.
 494       --  If the prefix is an indexed component (without implicit defererence)
 495       --  then the construct denotes a call to a member of an entire family.
 496       --  If the prefix is a simple name, it may still denote a call to a
 497       --  parameterless member of an entry family. Resolution of these various
 498       --  interpretations is delicate.
 499
 500       Analyze (P);
 501
 502       --  If error analyzing prefix, then set Any_Type as result and return
 503
 504       if Etype (P) = Any_Type then
 505          Set_Etype (N, Any_Type);
 506          return;
 507       end if;
 508
 509       --  Otherwise analyze the parameters
 510
 511       if Present (Actuals) then
 512          Actual := First (Actuals);
 513
 514          while Present (Actual) loop
 515             Analyze (Actual);
 516             Check_Parameterless_Call (Actual);
 517             Next (Actual);
 518          end loop;
 519       end if;
 520
 521       --  Special processing for Elab_Spec and Elab_Body calls
 522
 523       if Nkind (P) = N_Attribute_Reference
 524         and then (Attribute_Name (P) = Name_Elab_Spec
 525                    or else Attribute_Name (P) = Name_Elab_Body)
 526       then
 527          if Present (Actuals) then
 528             Error_Msg_N
 529               ("no parameters allowed for this call", First (Actuals));
 530             return;
 531          end if;
 532
 533          Set_Etype (N, Standard_Void_Type);
 534          Set_Analyzed (N);
 535
 536       elsif Is_Entity_Name (P)
 537         and then Is_Record_Type (Etype (Entity (P)))
 538         and then Remote_AST_I_Dereference (P)
 539       then
 540          return;
 541
 542       elsif Is_Entity_Name (P)
 543         and then Ekind (Entity (P)) /= E_Entry_Family
 544       then
 545          if Is_Access_Type (Etype (P))
 546            and then Ekind (Designated_Type (Etype (P))) = E_Subprogram_Type
 547            and then No (Actuals)
 548            and then Comes_From_Source (N)
 549          then
 550             Error_Msg_N ("missing explicit dereference in call", N);
 551          end if;
 552
 553          Analyze_Call_And_Resolve;
 554
 555       --  If the prefix is the simple name of an entry family, this is
 556       --  a parameterless call from within the task body itself.
 557
 558       elsif Is_Entity_Name (P)
 559         and then Nkind (P) = N_Identifier
 560         and then Ekind (Entity (P)) = E_Entry_Family
 561         and then Present (Actuals)
 562         and then No (Next (First (Actuals)))
 563       then
 564          --  Can be call to parameterless entry family. What appears to be
 565          --  the sole argument is in fact the entry index. Rewrite prefix
 566          --  of node accordingly. Source representation is unchanged by this
 567          --  transformation.
 568
 569          New_N :=
 570            Make_Indexed_Component (Loc,
 571              Prefix =>
 572                Make_Selected_Component (Loc,
 573                  Prefix => New_Occurrence_Of (Scope (Entity (P)), Loc),
 574                  Selector_Name => New_Occurrence_Of (Entity (P), Loc)),
 575              Expressions => Actuals);
 576          Set_Name (N, New_N);
 577          Set_Etype (New_N, Standard_Void_Type);
 578          Set_Parameter_Associations (N, No_List);
 579          Analyze_Call_And_Resolve;
 580
 581       elsif Nkind (P) = N_Explicit_Dereference then
 582          if Ekind (Etype (P)) = E_Subprogram_Type then
 583             Analyze_Call_And_Resolve;
 584          else
 585             Error_Msg_N ("expect access to procedure in call", P);
 586          end if;
 587
 588       --  The name can be a selected component or an indexed component
 589       --  that yields an access to subprogram. Such a prefix is legal if
 590       --  the call has parameter associations.
 591
 592       elsif Is_Access_Type (Etype (P))
 593         and then Ekind (Designated_Type (Etype (P))) = E_Subprogram_Type
 594       then
 595          if Present (Actuals) then
 596             Analyze_Call_And_Resolve;
 597          else
 598             Error_Msg_N ("missing explicit dereference in call ", N);
 599          end if;
 600
 601       --  If not an access to subprogram, then the prefix must resolve to
 602       --  the name of an entry, entry family, or protected operation.
 603
 604       --  For the case of a simple entry call, P is a selected component
 605       --  where the prefix is the task and the selector name is the entry.
 606       --  A call to a protected procedure will have the same syntax. If
 607       --  the protected object contains overloaded operations, the entity
 608       --  may appear as a function, the context will select the operation
 609       --  whose type is Void.
 610
 611       elsif Nkind (P) = N_Selected_Component
 612         and then (Ekind (Entity (Selector_Name (P))) = E_Entry
 613                     or else
 614                   Ekind (Entity (Selector_Name (P))) = E_Procedure
 615                     or else
 616                   Ekind (Entity (Selector_Name (P))) = E_Function)
 617       then
 618          Analyze_Call_And_Resolve;
 619
 620       elsif Nkind (P) = N_Selected_Component
 621         and then Ekind (Entity (Selector_Name (P))) = E_Entry_Family
 622         and then Present (Actuals)
 623         and then No (Next (First (Actuals)))
 624       then
 625          --  Can be call to parameterless entry family. What appears to be
 626          --  the sole argument is in fact the entry index. Rewrite prefix
 627          --  of node accordingly. Source representation is unchanged by this
 628          --  transformation.
 629
 630          New_N :=
 631            Make_Indexed_Component (Loc,
 632              Prefix => New_Copy (P),
 633              Expressions => Actuals);
 634          Set_Name (N, New_N);
 635          Set_Etype (New_N, Standard_Void_Type);
 636          Set_Parameter_Associations (N, No_List);
 637          Analyze_Call_And_Resolve;
 638
 639       --  For the case of a reference to an element of an entry family, P is
 640       --  an indexed component whose prefix is a selected component (task and
 641       --  entry family), and whose index is the entry family index.
 642
 643       elsif Nkind (P) = N_Indexed_Component
 644         and then Nkind (Prefix (P)) = N_Selected_Component
 645         and then Ekind (Entity (Selector_Name (Prefix (P)))) = E_Entry_Family
 646       then
 647          Analyze_Call_And_Resolve;
 648
 649       --  If the prefix is the name of an entry family, it is a call from
 650       --  within the task body itself.
 651
 652       elsif Nkind (P) = N_Indexed_Component
 653         and then Nkind (Prefix (P)) = N_Identifier
 654         and then Ekind (Entity (Prefix (P))) = E_Entry_Family
 655       then
 656          New_N :=
 657            Make_Selected_Component (Loc,
 658              Prefix => New_Occurrence_Of (Scope (Entity (Prefix (P))), Loc),
 659              Selector_Name => New_Occurrence_Of (Entity (Prefix (P)), Loc));
 660          Rewrite (Prefix (P), New_N);
 661          Analyze (P);
 662          Analyze_Call_And_Resolve;
 663
 664       --  Anything else is an error.
 665
 666       else
 667          Error_Msg_N ("Invalid procedure or entry call", N);
 668       end if;
 669    end Analyze_Procedure_Call;
 670
 671    ------------------------------
 672    -- Analyze_Return_Statement --
 673    ------------------------------
 674
 675    procedure Analyze_Return_Statement (N : Node_Id) is
 676       Loc      : constant Source_Ptr := Sloc (N);
 677       Expr     : Node_Id;
 678       Scope_Id : Entity_Id;
 679       Kind     : Entity_Kind;
 680       R_Type   : Entity_Id;
 681
 682    begin
 683       --  Find subprogram or accept statement enclosing the return statement
 684
 685       Scope_Id := Empty;
 686       for J in reverse 0 .. Scope_Stack.Last loop
 687          Scope_Id := Scope_Stack.Table (J).Entity;
 688          exit when Ekind (Scope_Id) /= E_Block and then
 689                    Ekind (Scope_Id) /= E_Loop;
 690       end loop;
 691
 692       pragma Assert (Present (Scope_Id));
 693
 694       Kind := Ekind (Scope_Id);
 695       Expr := Expression (N);
 696
 697       if Kind /= E_Function
 698         and then Kind /= E_Generic_Function
 699         and then Kind /= E_Procedure
 700         and then Kind /= E_Generic_Procedure
 701         and then Kind /= E_Entry
 702         and then Kind /= E_Entry_Family
 703       then
 704          Error_Msg_N ("illegal context for return statement", N);
 705
 706       elsif Present (Expr) then
 707          if Kind = E_Function or else Kind = E_Generic_Function then
 708             Set_Return_Present (Scope_Id);
 709             R_Type := Etype (Scope_Id);
 710             Set_Return_Type (N, R_Type);
 711             Analyze_And_Resolve (Expr, R_Type);
 712
 713             if (Is_Class_Wide_Type (Etype (Expr))
 714                  or else Is_Dynamically_Tagged (Expr))
 715               and then not Is_Class_Wide_Type (R_Type)
 716             then
 717                Error_Msg_N
 718                  ("dynamically tagged expression not allowed!", Expr);
 719             end if;
 720
 721             Apply_Constraint_Check (Expr, R_Type);
 722
 723             --  ??? A real run-time accessibility check is needed
 724             --  in cases involving dereferences of access parameters.
 725             --  For now we just check the static cases.
 726
 727             if Is_Return_By_Reference_Type (Etype (Scope_Id))
 728               and then Object_Access_Level (Expr)
 729                 > Subprogram_Access_Level (Scope_Id)
 730             then
 731                Rewrite (N,
 732                  Make_Raise_Program_Error (Loc,
 733                    Reason => PE_Accessibility_Check_Failed));
 734                Analyze (N);
 735
 736                Error_Msg_N
 737                  ("cannot return a local value by reference?", N);
 738                Error_Msg_NE
 739                  ("& will be raised at run time?!",
 740                   N, Standard_Program_Error);
 741             end if;
 742
 743          elsif Kind = E_Procedure or else Kind = E_Generic_Procedure then
 744             Error_Msg_N ("procedure cannot return value (use function)", N);
 745
 746          else
 747             Error_Msg_N ("accept statement cannot return value", N);
 748          end if;
 749
 750       --  No expression present
 751
 752       else
 753          if Kind = E_Function or Kind = E_Generic_Function then
 754             Error_Msg_N ("missing expression in return from function", N);
 755          end if;
 756
 757          if (Ekind (Scope_Id) = E_Procedure
 758               or else Ekind (Scope_Id) = E_Generic_Procedure)
 759            and then No_Return (Scope_Id)
 760          then
 761             Error_Msg_N
 762               ("RETURN statement not allowed (No_Return)", N);
 763          end if;
 764       end if;
 765
 766       Check_Unreachable_Code (N);
 767    end Analyze_Return_Statement;
 768
 769    -----------------------------
 770    -- Analyze_Subprogram_Body --
 771    -----------------------------
 772
 773    --  This procedure is called for regular subprogram bodies, generic bodies,
 774    --  and for subprogram stubs of both kinds. In the case of stubs, only the
 775    --  specification matters, and is used to create a proper declaration for
 776    --  the subprogram, or to perform conformance checks.
 777
 778    procedure Analyze_Subprogram_Body (N : Node_Id) is
 779       Loc          : constant Source_Ptr := Sloc (N);
 780       Body_Spec    : constant Node_Id    := Specification (N);
 781       Body_Id      : Entity_Id           := Defining_Entity (Body_Spec);
 782       Prev_Id      : constant Entity_Id  := Current_Entity_In_Scope (Body_Id);
 783       Body_Deleted : constant Boolean    := False;
 784
 785       HSS          : Node_Id;
 786       Spec_Id      : Entity_Id;
 787       Spec_Decl    : Node_Id   := Empty;
 788       Last_Formal  : Entity_Id := Empty;
 789       Conformant   : Boolean;
 790       Missing_Ret  : Boolean;
 791       P_Ent        : Entity_Id;
 792
 793       procedure Check_Following_Pragma;
 794       --  If front-end inlining is enabled, look ahead to recognize a pragma
 795       --  that may appear after the body.
 796
 797       procedure Check_Following_Pragma is
 798          Prag : Node_Id;
 799
 800       begin
 801          if Front_End_Inlining
 802            and then Is_List_Member (N)
 803            and then Present (Spec_Decl)
 804            and then List_Containing (N) = List_Containing (Spec_Decl)
 805          then
 806             Prag := Next (N);
 807
 808             if Present (Prag)
 809               and then Nkind (Prag) = N_Pragma
 810               and then Get_Pragma_Id (Chars (Prag)) = Pragma_Inline
 811               and then
 812               Chars
 813                 (Expression (First (Pragma_Argument_Associations (Prag))))
 814                    = Chars (Body_Id)
 815             then
 816                Analyze (Prag);
 817             end if;
 818          end if;
 819       end Check_Following_Pragma;
 820
 821    --  Start of processing for Analyze_Subprogram_Body
 822
 823    begin
 824       if Debug_Flag_C then
 825          Write_Str ("====  Compiling subprogram body ");
 826          Write_Name (Chars (Body_Id));
 827          Write_Str (" from ");
 828          Write_Location (Loc);
 829          Write_Eol;
 830       end if;
 831
 832       Trace_Scope (N, Body_Id, " Analyze subprogram");
 833
 834       --  Generic subprograms are handled separately. They always have
 835       --  a generic specification. Determine whether current scope has
 836       --  a previous declaration.
 837
 838       --  If the subprogram body is defined within an instance of the
 839       --  same name, the instance appears as a package renaming, and
 840       --  will be hidden within the subprogram.
 841
 842       if Present (Prev_Id)
 843         and then not Is_Overloadable (Prev_Id)
 844         and then (Nkind (Parent (Prev_Id)) /= N_Package_Renaming_Declaration
 845                    or else Comes_From_Source (Prev_Id))
 846       then
 847          if Is_Generic_Subprogram (Prev_Id) then
 848             Spec_Id := Prev_Id;
 849             Set_Is_Compilation_Unit (Body_Id, Is_Compilation_Unit (Spec_Id));
 850             Set_Is_Child_Unit       (Body_Id, Is_Child_Unit       (Spec_Id));
 851
 852             Analyze_Generic_Subprogram_Body (N, Spec_Id);
 853             return;
 854
 855          else
 856             --  Previous entity conflicts with subprogram name.
 857             --  Attempting to enter name will post error.
 858
 859             Enter_Name (Body_Id);
 860             return;
 861          end if;
 862
 863       --  Non-generic case, find the subprogram declaration, if one was
 864       --  seen, or enter new overloaded entity in the current scope.
 865       --  If the current_entity is the body_id itself, the unit is being
 866       --  analyzed as part of the context of one of its subunits. No need
 867       --  to redo the analysis.
 868
 869       elsif Prev_Id = Body_Id
 870         and then Has_Completion (Body_Id)
 871       then
 872          return;
 873
 874       else
 875          Body_Id := Analyze_Subprogram_Specification (Body_Spec);
 876
 877          if Nkind (N) = N_Subprogram_Body_Stub
 878            or else No (Corresponding_Spec (N))
 879          then
 880             Spec_Id := Find_Corresponding_Spec (N);
 881
 882             --  If this is a duplicate body, no point in analyzing it
 883
 884             if Error_Posted (N) then
 885                return;
 886             end if;
 887
 888             --  A subprogram body should cause freezing of its own
 889             --  declaration, but if there was no previous explicit
 890             --  declaration, then the subprogram will get frozen too
 891             --  late (there may be code within the body that depends
 892             --  on the subprogram having been frozen, such as uses of
 893             --  extra formals), so we force it to be frozen here.
 894             --  Same holds if the body and the spec are compilation units.
 895
 896             if No (Spec_Id) then
 897                Freeze_Before (N, Body_Id);
 898
 899             elsif Nkind (Parent (N)) = N_Compilation_Unit then
 900                Freeze_Before (N, Spec_Id);
 901             end if;
 902          else
 903             Spec_Id := Corresponding_Spec (N);
 904          end if;
 905       end if;
 906
 907       --  Do not inline any subprogram that contains nested subprograms,
 908       --  since the backend inlining circuit seems to generate uninitialized
 909       --  references in this case. We know this happens in the case of front
 910       --  end ZCX support, but it also appears it can happen in other cases
 911       --  as well. The backend often rejects attempts to inline in the case
 912       --  of nested procedures anyway, so little if anything is lost by this.
 913
 914       --  Do not do this test if errors have been detected, because in some
 915       --  error cases, this code blows up, and we don't need it anyway if
 916       --  there have been errors, since we won't get to the linker anyway.
 917
 918       if Serious_Errors_Detected = 0 then
 919          P_Ent := Body_Id;
 920          loop
 921             P_Ent := Scope (P_Ent);
 922             exit when No (P_Ent) or else P_Ent = Standard_Standard;
 923
 924             if Is_Subprogram (P_Ent) then
 925                Set_Is_Inlined (P_Ent, False);
 926
 927                if Comes_From_Source (P_Ent)
 928                  and then Has_Pragma_Inline (P_Ent)
 929                then
 930                   Cannot_Inline
 931                     ("cannot inline& (nested subprogram)?",
 932                      N, P_Ent);
 933                end if;
 934             end if;
 935          end loop;
 936       end if;
 937
 938       --  Case of fully private operation in the body of the protected type.
 939       --  We must create a declaration for the subprogram, in order to attach
 940       --  the protected subprogram that will be used in internal calls.
 941
 942       if No (Spec_Id)
 943         and then Comes_From_Source (N)
 944         and then Is_Protected_Type (Current_Scope)
 945       then
 946          declare
 947             Decl     : Node_Id;
 948             Plist    : List_Id;
 949             Formal   : Entity_Id;
 950             New_Spec : Node_Id;
 951
 952          begin
 953             Formal := First_Formal (Body_Id);
 954
 955             --  The protected operation always has at least one formal,
 956             --  namely the object itself, but it is only placed in the
 957             --  parameter list if expansion is enabled.
 958
 959             if Present (Formal)
 960               or else Expander_Active
 961             then
 962                Plist := New_List;
 963
 964             else
 965                Plist := No_List;
 966             end if;
 967
 968             while Present (Formal) loop
 969                Append
 970                  (Make_Parameter_Specification (Loc,
 971                    Defining_Identifier =>
 972                      Make_Defining_Identifier (Sloc (Formal),
 973                        Chars => Chars (Formal)),
 974                    In_Present  => In_Present (Parent (Formal)),
 975                    Out_Present => Out_Present (Parent (Formal)),
 976                    Parameter_Type =>
 977                      New_Reference_To (Etype (Formal), Loc),
 978                    Expression =>
 979                      New_Copy_Tree (Expression (Parent (Formal)))),
 980                  Plist);
 981
 982                Next_Formal (Formal);
 983             end loop;
 984
 985             if Nkind (Body_Spec) = N_Procedure_Specification then
 986                New_Spec :=
 987                  Make_Procedure_Specification (Loc,
 988                     Defining_Unit_Name =>
 989                       Make_Defining_Identifier (Sloc (Body_Id),
 990                         Chars => Chars (Body_Id)),
 991                     Parameter_Specifications => Plist);
 992             else
 993                New_Spec :=
 994                  Make_Function_Specification (Loc,
 995                     Defining_Unit_Name =>
 996                       Make_Defining_Identifier (Sloc (Body_Id),
 997                         Chars => Chars (Body_Id)),
 998                     Parameter_Specifications => Plist,
 999                     Subtype_Mark => New_Occurrence_Of (Etype (Body_Id), Loc));
1000             end if;
1001
1002             Decl :=
1003               Make_Subprogram_Declaration (Loc,
1004                 Specification => New_Spec);
1005             Insert_Before (N, Decl);
1006             Spec_Id := Defining_Unit_Name (New_Spec);
1007
1008             --  Indicate that the entity comes from source, to ensure that
1009             --  cross-reference information is properly generated.
1010             --  The body itself is rewritten during expansion, and the
1011             --  body entity will not appear in calls to the operation.
1012
1013             Set_Comes_From_Source (Spec_Id, True);
1014             Analyze (Decl);
1015             Set_Has_Completion (Spec_Id);
1016             Set_Convention (Spec_Id, Convention_Protected);
1017          end;
1018
1019       elsif Present (Spec_Id) then
1020          Spec_Decl := Unit_Declaration_Node (Spec_Id);
1021       end if;
1022
1023       --  Place subprogram on scope stack, and make formals visible. If there
1024       --  is a spec, the visible entity remains that of the spec.
1025
1026       if Present (Spec_Id) then
1027          Generate_Reference (Spec_Id, Body_Id, 'b', Set_Ref => False);
1028          if Style_Check then
1029             Style.Check_Identifier (Body_Id, Spec_Id);
1030          end if;
1031
1032          Set_Is_Compilation_Unit (Body_Id, Is_Compilation_Unit (Spec_Id));
1033          Set_Is_Child_Unit       (Body_Id, Is_Child_Unit       (Spec_Id));
1034
1035          if Is_Abstract (Spec_Id) then
1036             Error_Msg_N ("an abstract subprogram cannot have a body", N);
1037             return;
1038          else
1039             Set_Convention (Body_Id, Convention (Spec_Id));
1040             Set_Has_Completion (Spec_Id);
1041
1042             if Is_Protected_Type (Scope (Spec_Id)) then
1043                Set_Privals_Chain (Spec_Id, New_Elmt_List);
1044             end if;
1045
1046             --  If this is a body generated for a renaming, do not check for
1047             --  full conformance. The check is redundant, because the spec of
1048             --  the body is a copy of the spec in the renaming declaration,
1049             --  and the test can lead to spurious errors on nested defaults.
1050
1051             if Present (Spec_Decl)
1052               and then not Comes_From_Source (N)
1053               and then
1054                 (Nkind (Original_Node (Spec_Decl)) =
1055                                         N_Subprogram_Renaming_Declaration
1056                    or else (Present (Corresponding_Body (Spec_Decl))
1057                               and then
1058                                 Nkind (Unit_Declaration_Node
1059                                         (Corresponding_Body (Spec_Decl))) =
1060                                            N_Subprogram_Renaming_Declaration))
1061             then
1062                Conformant := True;
1063             else
1064                Check_Conformance
1065                  (Body_Id, Spec_Id,
1066                    Fully_Conformant, True, Conformant, Body_Id);
1067             end if;
1068
1069             --  If the body is not fully conformant, we have to decide if we
1070             --  should analyze it or not. If it has a really messed up profile
1071             --  then we probably should not analyze it, since we will get too
1072             --  many bogus messages.
1073
1074             --  Our decision is to go ahead in the non-fully conformant case
1075             --  only if it is at least mode conformant with the spec. Note
1076             --  that the call to Check_Fully_Conformant has issued the proper
1077             --  error messages to complain about the lack of conformance.
1078
1079             if not Conformant
1080               and then not Mode_Conformant (Body_Id, Spec_Id)
1081             then
1082                return;
1083             end if;
1084          end if;
1085
1086          if Spec_Id /= Body_Id then
1087             Reference_Body_Formals (Spec_Id, Body_Id);
1088          end if;
1089
1090          if Nkind (N) /= N_Subprogram_Body_Stub then
1091             Set_Corresponding_Spec (N, Spec_Id);
1092             Install_Formals (Spec_Id);
1093             Last_Formal := Last_Entity (Spec_Id);
1094             New_Scope (Spec_Id);
1095
1096             --  Make sure that the subprogram is immediately visible. For
1097             --  child units that have no separate spec this is indispensable.
1098             --  Otherwise it is safe albeit redundant.
1099
1100             Set_Is_Immediately_Visible (Spec_Id);
1101          end if;
1102
1103          Set_Corresponding_Body (Unit_Declaration_Node (Spec_Id), Body_Id);
1104          Set_Ekind (Body_Id, E_Subprogram_Body);
1105          Set_Scope (Body_Id, Scope (Spec_Id));
1106
1107       --  Case of subprogram body with no previous spec
1108
1109       else
1110          if Style_Check
1111            and then Comes_From_Source (Body_Id)
1112            and then not Suppress_Style_Checks (Body_Id)
1113            and then not In_Instance
1114          then
1115             Style.Body_With_No_Spec (N);
1116          end if;
1117
1118          New_Overloaded_Entity (Body_Id);
1119
1120          if Nkind (N) /= N_Subprogram_Body_Stub then
1121             Set_Acts_As_Spec (N);
1122             Generate_Definition (Body_Id);
1123             Generate_Reference
1124               (Body_Id, Body_Id, 'b', Set_Ref => False, Force => True);
1125             Generate_Reference_To_Formals (Body_Id);
1126             Install_Formals (Body_Id);
1127             New_Scope (Body_Id);
1128          end if;
1129       end if;
1130
1131       --  If this is the proper body of a stub, we must verify that the stub
1132       --  conforms to the body, and to the previous spec if one was present.
1133       --  we know already that the body conforms to that spec. This test is
1134       --  only required for subprograms that come from source.
1135
1136       if Nkind (Parent (N)) = N_Subunit
1137         and then Comes_From_Source (N)
1138         and then not Error_Posted (Body_Id)
1139       then
1140          declare
1141             Old_Id : constant Entity_Id :=
1142                        Defining_Entity
1143                          (Specification (Corresponding_Stub (Parent (N))));
1144
1145             Conformant : Boolean := False;
1146
1147          begin
1148             if No (Spec_Id) then
1149                Check_Fully_Conformant (Body_Id, Old_Id);
1150
1151             else
1152                Check_Conformance
1153                  (Body_Id, Old_Id, Fully_Conformant, False, Conformant);
1154
1155                if not Conformant then
1156
1157                   --  The stub was taken to be a new declaration. Indicate
1158                   --  that it lacks a body.
1159
1160                   Set_Has_Completion (Old_Id, False);
1161                end if;
1162             end if;
1163          end;
1164       end if;
1165
1166       Set_Has_Completion (Body_Id);
1167       Check_Eliminated (Body_Id);
1168
1169       if Nkind (N) = N_Subprogram_Body_Stub then
1170          return;
1171
1172       elsif  Present (Spec_Id)
1173         and then Expander_Active
1174       then
1175          Check_Following_Pragma;
1176
1177          if Is_Always_Inlined (Spec_Id)
1178            or else (Has_Pragma_Inline (Spec_Id)
1179              and then (Front_End_Inlining or else Configurable_Run_Time_Mode))
1180          then
1181             Build_Body_To_Inline (N, Spec_Id);
1182          end if;
1183       end if;
1184
1185       --  Ada 2005 (AI-262): In library subprogram bodies, after the analysis
1186       --  if its specification we have to install the private withed units.
1187
1188       if Is_Compilation_Unit (Body_Id)
1189         and then Scope (Body_Id) = Standard_Standard
1190       then
1191          Install_Private_With_Clauses (Body_Id);
1192       end if;
1193
1194       --  Now we can go on to analyze the body
1195
1196       HSS := Handled_Statement_Sequence (N);
1197       Set_Actual_Subtypes (N, Current_Scope);
1198       Analyze_Declarations (Declarations (N));
1199       Check_Completion;
1200       Analyze (HSS);
1201       Process_End_Label (HSS, 't', Current_Scope);
1202       End_Scope;
1203       Check_Subprogram_Order (N);
1204       Set_Analyzed (Body_Id);
1205
1206       --  If we have a separate spec, then the analysis of the declarations
1207       --  caused the entities in the body to be chained to the spec id, but
1208       --  we want them chained to the body id. Only the formal parameters
1209       --  end up chained to the spec id in this case.
1210
1211       if Present (Spec_Id) then
1212
1213          --  If a parent unit is categorized, the context of a subunit
1214          --  must conform to the categorization. Conversely, if a child
1215          --  unit is categorized, the parents themselves must conform.
1216
1217          if Nkind (Parent (N)) = N_Subunit then
1218             Validate_Categorization_Dependency (N, Spec_Id);
1219
1220          elsif Is_Child_Unit (Spec_Id) then
1221             Validate_Categorization_Dependency
1222               (Unit_Declaration_Node (Spec_Id), Spec_Id);
1223          end if;
1224
1225          if Present (Last_Formal) then
1226             Set_Next_Entity
1227               (Last_Entity (Body_Id), Next_Entity (Last_Formal));
1228             Set_Next_Entity (Last_Formal, Empty);
1229             Set_Last_Entity (Body_Id, Last_Entity (Spec_Id));
1230             Set_Last_Entity (Spec_Id, Last_Formal);
1231
1232          else
1233             Set_First_Entity (Body_Id, First_Entity (Spec_Id));
1234             Set_Last_Entity  (Body_Id, Last_Entity (Spec_Id));
1235             Set_First_Entity (Spec_Id, Empty);
1236             Set_Last_Entity  (Spec_Id, Empty);
1237          end if;
1238       end if;
1239
1240       --  If function, check return statements
1241
1242       if Nkind (Body_Spec) = N_Function_Specification then
1243          declare
1244             Id : Entity_Id;
1245
1246          begin
1247             if Present (Spec_Id) then
1248                Id := Spec_Id;
1249             else
1250                Id := Body_Id;
1251             end if;
1252
1253             if Return_Present (Id) then
1254                Check_Returns (HSS, 'F', Missing_Ret);
1255
1256                if Missing_Ret then
1257                   Set_Has_Missing_Return (Id);
1258                end if;
1259
1260             elsif not Is_Machine_Code_Subprogram (Id)
1261               and then not Body_Deleted
1262             then
1263                Error_Msg_N ("missing RETURN statement in function body", N);
1264             end if;
1265          end;
1266
1267       --  If procedure with No_Return, check returns
1268
1269       elsif Nkind (Body_Spec) = N_Procedure_Specification
1270         and then Present (Spec_Id)
1271         and then No_Return (Spec_Id)
1272       then
1273          Check_Returns (HSS, 'P', Missing_Ret);
1274       end if;
1275
1276       --  Now we are going to check for variables that are never modified
1277       --  in the body of the procedure. We omit these checks if the first
1278       --  statement of the procedure raises an exception. In particular
1279       --  this deals with the common idiom of a stubbed function, which
1280       --  might appear as something like
1281
1282       --     function F (A : Integer) return Some_Type;
1283       --        X : Some_Type;
1284       --     begin
1285       --        raise Program_Error;
1286       --        return X;
1287       --     end F;
1288
1289       --  Here the purpose of X is simply to satisfy the (annoying)
1290       --  requirement in Ada that there be at least one return, and
1291       --  we certainly do not want to go posting warnings on X that
1292       --  it is not initialized!
1293
1294       declare
1295          Stm : Node_Id := First (Statements (HSS));
1296
1297       begin
1298          --  Skip an initial label (for one thing this occurs when we
1299          --  are in front end ZCX mode, but in any case it is irrelevant).
1300
1301          if Nkind (Stm) = N_Label then
1302             Next (Stm);
1303          end if;
1304
1305          --  Do the test on the original statement before expansion
1306
1307          declare
1308             Ostm : constant Node_Id := Original_Node (Stm);
1309
1310          begin
1311             --  If explicit raise statement, return with no checks
1312
1313             if Nkind (Ostm) = N_Raise_Statement then
1314                return;
1315
1316             --  Check for explicit call cases which likely raise an exception
1317
1318             elsif Nkind (Ostm) = N_Procedure_Call_Statement then
1319                if Is_Entity_Name (Name (Ostm)) then
1320                   declare
1321                      Ent : constant Entity_Id := Entity (Name (Ostm));
1322
1323                   begin
1324                      --  If the procedure is marked No_Return, then likely it
1325                      --  raises an exception, but in any case it is not coming
1326                      --  back here, so no need to check beyond the call.
1327
1328                      if Ekind (Ent) = E_Procedure
1329                        and then No_Return (Ent)
1330                      then
1331                         return;
1332
1333                      --  If the procedure name is Raise_Exception, then also
1334                      --  assume that it raises an exception. The main target
1335                      --  here is Ada.Exceptions.Raise_Exception, but this name
1336                      --  is pretty evocative in any context! Note that the
1337                      --  procedure in Ada.Exceptions is not marked No_Return
1338                      --  because of the annoying case of the null exception Id.
1339
1340                      elsif Chars (Ent) = Name_Raise_Exception then
1341                         return;
1342                      end if;
1343                   end;
1344                end if;
1345             end if;
1346          end;
1347       end;
1348
1349       --  Check for variables that are never modified
1350
1351       declare
1352          E1, E2 : Entity_Id;
1353
1354       begin
1355          --  If there is a separate spec, then transfer Never_Set_In_Source
1356          --  flags from out parameters to the corresponding entities in the
1357          --  body. The reason we do that is we want to post error flags on
1358          --  the body entities, not the spec entities.
1359
1360          if Present (Spec_Id) then
1361             E1 := First_Entity (Spec_Id);
1362
1363             while Present (E1) loop
1364                if Ekind (E1) = E_Out_Parameter then
1365                   E2 := First_Entity (Body_Id);
1366                   while Present (E2) loop
1367                      exit when Chars (E1) = Chars (E2);
1368                      Next_Entity (E2);
1369                   end loop;
1370
1371                   if Present (E2) then
1372                      Set_Never_Set_In_Source (E2, Never_Set_In_Source (E1));
1373                   end if;
1374                end if;
1375
1376                Next_Entity (E1);
1377             end loop;
1378          end if;
1379
1380          --  Check references in body unless it was deleted. Note that the
1381          --  check of Body_Deleted here is not just for efficiency, it is
1382          --  necessary to avoid junk warnings on formal parameters.
1383
1384          if not Body_Deleted then
1385             Check_References (Body_Id);
1386          end if;
1387       end;
1388    end Analyze_Subprogram_Body;
1389
1390    ------------------------------------
1391    -- Analyze_Subprogram_Declaration --
1392    ------------------------------------
1393
1394    procedure Analyze_Subprogram_Declaration (N : Node_Id) is
1395       Designator : constant Entity_Id :=
1396                      Analyze_Subprogram_Specification (Specification (N));
1397       Scop       : constant Entity_Id := Current_Scope;
1398
1399    --  Start of processing for Analyze_Subprogram_Declaration
1400
1401    begin
1402       Generate_Definition (Designator);
1403
1404       --  Check for RCI unit subprogram declarations against in-lined
1405       --  subprograms and subprograms having access parameter or limited
1406       --  parameter without Read and Write (RM E.2.3(12-13)).
1407
1408       Validate_RCI_Subprogram_Declaration (N);
1409
1410       Trace_Scope
1411         (N,
1412          Defining_Entity (N),
1413          " Analyze subprogram spec. ");
1414
1415       if Debug_Flag_C then
1416          Write_Str ("====  Compiling subprogram spec ");
1417          Write_Name (Chars (Designator));
1418          Write_Str (" from ");
1419          Write_Location (Sloc (N));
1420          Write_Eol;
1421       end if;
1422
1423       New_Overloaded_Entity (Designator);
1424       Check_Delayed_Subprogram (Designator);
1425
1426       --  What is the following code for, it used to be
1427
1428       --  ???   Set_Suppress_Elaboration_Checks
1429       --  ???     (Designator, Elaboration_Checks_Suppressed (Designator));
1430
1431       --  The following seems equivalent, but a bit dubious
1432
1433       if Elaboration_Checks_Suppressed (Designator) then
1434          Set_Kill_Elaboration_Checks (Designator);
1435       end if;
1436
1437       if Scop /= Standard_Standard
1438         and then not Is_Child_Unit (Designator)
1439       then
1440          Set_Categorization_From_Scope (Designator, Scop);
1441       else
1442          --  For a compilation unit, check for library-unit pragmas.
1443
1444          New_Scope (Designator);
1445          Set_Categorization_From_Pragmas (N);
1446          Validate_Categorization_Dependency (N, Designator);
1447          Pop_Scope;
1448       end if;
1449
1450       --  For a compilation unit, set body required. This flag will only be
1451       --  reset if a valid Import or Interface pragma is processed later on.
1452
1453       if Nkind (Parent (N)) = N_Compilation_Unit then
1454          Set_Body_Required (Parent (N), True);
1455       end if;
1456
1457       Generate_Reference_To_Formals (Designator);
1458       Check_Eliminated (Designator);
1459
1460       if Comes_From_Source (N)
1461         and then Is_List_Member (N)
1462       then
1463          Check_Overriding_Operation (N, Designator);
1464       end if;
1465
1466    end Analyze_Subprogram_Declaration;
1467
1468    --------------------------------------
1469    -- Analyze_Subprogram_Specification --
1470    --------------------------------------
1471
1472    --  Reminder: N here really is a subprogram specification (not a subprogram
1473    --  declaration). This procedure is called to analyze the specification in
1474    --  both subprogram bodies and subprogram declarations (specs).
1475
1476    function Analyze_Subprogram_Specification (N : Node_Id) return Entity_Id is
1477       Designator : constant Entity_Id := Defining_Entity (N);
1478       Formals    : constant List_Id   := Parameter_Specifications (N);
1479       Typ        : Entity_Id;
1480
1481    begin
1482       Generate_Definition (Designator);
1483
1484       if Nkind (N) = N_Function_Specification then
1485          Set_Ekind (Designator, E_Function);
1486          Set_Mechanism (Designator, Default_Mechanism);
1487
1488          if Subtype_Mark (N) /= Error then
1489             Find_Type (Subtype_Mark (N));
1490             Typ := Entity (Subtype_Mark (N));
1491             Set_Etype (Designator, Typ);
1492
1493             if Ekind (Typ) = E_Incomplete_Type
1494               or else (Is_Class_Wide_Type (Typ)
1495                          and then
1496                            Ekind (Root_Type (Typ)) = E_Incomplete_Type)
1497             then
1498                Error_Msg_N
1499                  ("invalid use of incomplete type", Subtype_Mark (N));
1500             end if;
1501
1502          else
1503             Set_Etype (Designator, Any_Type);
1504          end if;
1505
1506       else
1507          Set_Ekind (Designator, E_Procedure);
1508          Set_Etype (Designator, Standard_Void_Type);
1509       end if;
1510
1511       if Present (Formals) then
1512          Set_Scope (Designator, Current_Scope);
1513          New_Scope (Designator);
1514          Process_Formals (Formals, N);
1515          End_Scope;
1516       end if;
1517
1518       if Nkind (N) = N_Function_Specification then
1519          if Nkind (Designator) = N_Defining_Operator_Symbol then
1520             Valid_Operator_Definition (Designator);
1521          end if;
1522
1523          May_Need_Actuals (Designator);
1524
1525          if Is_Abstract (Etype (Designator))
1526            and then Nkind (Parent (N)) /= N_Abstract_Subprogram_Declaration
1527          then
1528             Error_Msg_N
1529               ("function that returns abstract type must be abstract", N);
1530          end if;
1531       end if;
1532
1533       return Designator;
1534    end Analyze_Subprogram_Specification;
1535
1536    --------------------------
1537    -- Build_Body_To_Inline --
1538    --------------------------
1539
1540    procedure Build_Body_To_Inline (N : Node_Id; Subp : Entity_Id) is
1541       Decl : constant Node_Id := Unit_Declaration_Node (Subp);
1542       Original_Body   : Node_Id;
1543       Body_To_Analyze : Node_Id;
1544       Max_Size        : constant := 10;
1545       Stat_Count      : Integer := 0;
1546
1547       function Has_Excluded_Declaration (Decls : List_Id) return Boolean;
1548       --  Check for declarations that make inlining not worthwhile.
1549
1550       function Has_Excluded_Statement   (Stats : List_Id) return Boolean;
1551       --  Check for statements that make inlining not worthwhile: any
1552       --  tasking statement, nested at any level. Keep track of total
1553       --  number of elementary statements, as a measure of acceptable size.
1554
1555       function Has_Pending_Instantiation return Boolean;
1556       --  If some enclosing body contains instantiations that appear before
1557       --  the corresponding generic body, the enclosing body has a freeze node
1558       --  so that it can be elaborated after the generic itself. This might
1559       --  conflict with subsequent inlinings, so that it is unsafe to try to
1560       --  inline in such a case.
1561
1562       procedure Remove_Pragmas;
1563       --  A pragma Unreferenced that mentions a formal parameter has no
1564       --  meaning when the body is inlined and the formals are rewritten.
1565       --  Remove it from body to inline. The analysis of the non-inlined
1566       --  body will handle the pragma properly.
1567
1568       ------------------------------
1569       -- Has_Excluded_Declaration --
1570       ------------------------------
1571
1572       function Has_Excluded_Declaration (Decls : List_Id) return Boolean is
1573          D : Node_Id;
1574
1575          function Is_Unchecked_Conversion (D : Node_Id) return Boolean;
1576          --  Nested subprograms make a given body ineligible for inlining,
1577          --  but we make an exception for instantiations of unchecked
1578          --  conversion. The body has not been analyzed yet, so we check
1579          --  the name, and verify that the visible entity with that name is
1580          --  the predefined unit.
1581
1582          function Is_Unchecked_Conversion (D : Node_Id) return Boolean is
1583             Id : constant Node_Id := Name (D);
1584             Conv : Entity_Id;
1585
1586          begin
1587             if Nkind (Id) = N_Identifier
1588               and then Chars (Id) = Name_Unchecked_Conversion
1589             then
1590                Conv := Current_Entity (Id);
1591
1592             elsif Nkind (Id) = N_Selected_Component
1593               and then Chars (Selector_Name (Id)) = Name_Unchecked_Conversion
1594             then
1595                Conv := Current_Entity (Selector_Name (Id));
1596
1597             else
1598                return False;
1599             end if;
1600
1601             return
1602               Present (Conv)
1603               and then Scope (Conv) = Standard_Standard
1604               and then Is_Intrinsic_Subprogram (Conv);
1605          end Is_Unchecked_Conversion;
1606
1607       --  Start of processing for Has_Excluded_Declaration
1608
1609       begin
1610          D := First (Decls);
1611
1612          while Present (D) loop
1613             if       (Nkind (D) = N_Function_Instantiation
1614                         and then not Is_Unchecked_Conversion (D))
1615               or else Nkind (D) = N_Protected_Type_Declaration
1616               or else Nkind (D) = N_Package_Declaration
1617               or else Nkind (D) = N_Package_Instantiation
1618               or else Nkind (D) = N_Subprogram_Body
1619               or else Nkind (D) = N_Procedure_Instantiation
1620               or else Nkind (D) = N_Task_Type_Declaration
1621             then
1622                Cannot_Inline
1623                  ("cannot inline & (non-allowed declaration)?", D, Subp);
1624                return True;
1625             end if;
1626
1627             Next (D);
1628          end loop;
1629
1630          return False;
1631       end Has_Excluded_Declaration;
1632
1633       ----------------------------
1634       -- Has_Excluded_Statement --
1635       ----------------------------
1636
1637       function Has_Excluded_Statement (Stats : List_Id) return Boolean is
1638          S : Node_Id;
1639          E : Node_Id;
1640
1641       begin
1642          S := First (Stats);
1643
1644          while Present (S) loop
1645             Stat_Count := Stat_Count + 1;
1646
1647             if Nkind (S) = N_Abort_Statement
1648               or else Nkind (S) = N_Asynchronous_Select
1649               or else Nkind (S) = N_Conditional_Entry_Call
1650               or else Nkind (S) = N_Delay_Relative_Statement
1651               or else Nkind (S) = N_Delay_Until_Statement
1652               or else Nkind (S) = N_Selective_Accept
1653               or else Nkind (S) = N_Timed_Entry_Call
1654             then
1655                Cannot_Inline
1656                  ("cannot inline & (non-allowed statement)?", S, Subp);
1657                return True;
1658
1659             elsif Nkind (S) = N_Block_Statement then
1660                if Present (Declarations (S))
1661                  and then Has_Excluded_Declaration (Declarations (S))
1662                then
1663                   return True;
1664
1665                elsif Present (Handled_Statement_Sequence (S))
1666                   and then
1667                     (Present
1668                       (Exception_Handlers (Handled_Statement_Sequence (S)))
1669                      or else
1670                        Has_Excluded_Statement
1671                          (Statements (Handled_Statement_Sequence (S))))
1672                then
1673                   return True;
1674                end if;
1675
1676             elsif Nkind (S) = N_Case_Statement then
1677                E := First (Alternatives (S));
1678
1679                while Present (E) loop
1680                   if Has_Excluded_Statement (Statements (E)) then
1681                      return True;
1682                   end if;
1683
1684                   Next (E);
1685                end loop;
1686
1687             elsif Nkind (S) = N_If_Statement then
1688                if Has_Excluded_Statement (Then_Statements (S)) then
1689                   return True;
1690                end if;
1691
1692                if Present (Elsif_Parts (S)) then
1693                   E := First (Elsif_Parts (S));
1694
1695                   while Present (E) loop
1696                      if Has_Excluded_Statement (Then_Statements (E)) then
1697                         return True;
1698                      end if;
1699                      Next (E);
1700                   end loop;
1701                end if;
1702
1703                if Present (Else_Statements (S))
1704                  and then Has_Excluded_Statement (Else_Statements (S))
1705                then
1706                   return True;
1707                end if;
1708
1709             elsif Nkind (S) = N_Loop_Statement
1710               and then Has_Excluded_Statement (Statements (S))
1711             then
1712                return True;
1713             end if;
1714
1715             Next (S);
1716          end loop;
1717
1718          return False;
1719       end Has_Excluded_Statement;
1720
1721       -------------------------------
1722       -- Has_Pending_Instantiation --
1723       -------------------------------
1724
1725       function Has_Pending_Instantiation return Boolean is
1726          S : Entity_Id := Current_Scope;
1727
1728       begin
1729          while Present (S) loop
1730             if Is_Compilation_Unit (S)
1731               or else Is_Child_Unit (S)
1732             then
1733                return False;
1734             elsif Ekind (S) = E_Package
1735               and then Has_Forward_Instantiation (S)
1736             then
1737                return True;
1738             end if;
1739
1740             S := Scope (S);
1741          end loop;
1742
1743          return False;
1744       end Has_Pending_Instantiation;
1745
1746       --------------------
1747       -- Remove_Pragmas --
1748       --------------------
1749
1750       procedure Remove_Pragmas is
1751          Decl : Node_Id;
1752          Nxt  : Node_Id;
1753
1754       begin
1755          Decl := First (Declarations (Body_To_Analyze));
1756          while Present (Decl) loop
1757             Nxt := Next (Decl);
1758
1759             if Nkind (Decl) = N_Pragma
1760               and then Chars (Decl) = Name_Unreferenced
1761             then
1762                Remove (Decl);
1763             end if;
1764
1765             Decl := Nxt;
1766          end loop;
1767       end Remove_Pragmas;
1768
1769    --  Start of processing for Build_Body_To_Inline
1770
1771    begin
1772       if Nkind (Decl) = N_Subprogram_Declaration
1773         and then Present (Body_To_Inline (Decl))
1774       then
1775          return;    --  Done already.
1776
1777       --  Functions that return unconstrained composite types will require
1778       --  secondary stack handling, and cannot currently be inlined.
1779       --  Ditto for functions that return controlled types, where controlled
1780       --  actions interfere in complex ways with inlining.
1781
1782       elsif Ekind (Subp) = E_Function
1783         and then not Is_Scalar_Type (Etype (Subp))
1784         and then not Is_Access_Type (Etype (Subp))
1785         and then not Is_Constrained (Etype (Subp))
1786       then
1787          Cannot_Inline
1788            ("cannot inline & (unconstrained return type)?", N, Subp);
1789          return;
1790
1791       elsif Ekind (Subp) = E_Function
1792         and then Controlled_Type (Etype (Subp))
1793       then
1794          Cannot_Inline
1795            ("cannot inline & (controlled return type)?", N, Subp);
1796          return;
1797       end if;
1798
1799       if Present (Declarations (N))
1800         and then Has_Excluded_Declaration (Declarations (N))
1801       then
1802          return;
1803       end if;
1804
1805       if Present (Handled_Statement_Sequence (N)) then
1806          if Present (Exception_Handlers (Handled_Statement_Sequence (N))) then
1807             Cannot_Inline
1808               ("cannot inline& (exception handler)?",
1809                First (Exception_Handlers (Handled_Statement_Sequence (N))),
1810                Subp);
1811             return;
1812          elsif
1813            Has_Excluded_Statement
1814              (Statements (Handled_Statement_Sequence (N)))
1815          then
1816             return;
1817          end if;
1818       end if;
1819
1820       --  We do not inline a subprogram  that is too large, unless it is
1821       --  marked Inline_Always. This pragma does not suppress the other
1822       --  checks on inlining (forbidden declarations, handlers, etc).
1823
1824       if Stat_Count > Max_Size
1825         and then not Is_Always_Inlined (Subp)
1826       then
1827          Cannot_Inline ("cannot inline& (body too large)?", N, Subp);
1828          return;
1829       end if;
1830
1831       if Has_Pending_Instantiation then
1832          Cannot_Inline
1833            ("cannot inline& (forward instance within enclosing body)?",
1834              N, Subp);
1835          return;
1836       end if;
1837
1838       --  Within an instance, the body to inline must be treated as a nested
1839       --  generic, so that the proper global references are preserved.
1840
1841       if In_Instance then
1842          Save_Env (Scope (Current_Scope), Scope (Current_Scope));
1843          Original_Body := Copy_Generic_Node (N, Empty, True);
1844       else
1845          Original_Body := Copy_Separate_Tree (N);
1846       end if;
1847
1848       --  We need to capture references to the formals in order to substitute
1849       --  the actuals at the point of inlining, i.e. instantiation. To treat
1850       --  the formals as globals to the body to inline, we nest it within
1851       --  a dummy parameterless subprogram, declared within the real one.
1852       --  To avoid generating an internal name (which is never public, and
1853       --  which affects serial numbers of other generated names), we use
1854       --  an internal symbol that cannot conflict with user declarations.
1855
1856       Set_Parameter_Specifications (Specification (Original_Body), No_List);
1857       Set_Defining_Unit_Name
1858         (Specification (Original_Body),
1859           Make_Defining_Identifier (Sloc (N), Name_uParent));
1860       Set_Corresponding_Spec (Original_Body, Empty);
1861
1862       Body_To_Analyze := Copy_Generic_Node (Original_Body, Empty, False);
1863
1864       --  Set return type of function, which is also global and does not need
1865       --  to be resolved.
1866
1867       if Ekind (Subp) = E_Function then
1868          Set_Subtype_Mark (Specification (Body_To_Analyze),
1869            New_Occurrence_Of (Etype (Subp), Sloc (N)));
1870       end if;
1871
1872       if No (Declarations (N)) then
1873          Set_Declarations (N, New_List (Body_To_Analyze));
1874       else
1875          Append (Body_To_Analyze, Declarations (N));
1876       end if;
1877
1878       Expander_Mode_Save_And_Set (False);
1879       Remove_Pragmas;
1880
1881       Analyze (Body_To_Analyze);
1882       New_Scope (Defining_Entity (Body_To_Analyze));
1883       Save_Global_References (Original_Body);
1884       End_Scope;
1885       Remove (Body_To_Analyze);
1886
1887       Expander_Mode_Restore;
1888       Set_Body_To_Inline (Decl, Original_Body);
1889       Set_Ekind (Defining_Entity (Original_Body), Ekind (Subp));
1890       Set_Is_Inlined (Subp);
1891
1892       if In_Instance then
1893          Restore_Env;
1894       end if;
1895    end Build_Body_To_Inline;
1896
1897    -------------------
1898    -- Cannot_Inline --
1899    -------------------
1900
1901    procedure Cannot_Inline (Msg : String; N : Node_Id; Subp : Entity_Id) is
1902    begin
1903       --  Do not emit warning if this is a predefined unit which is not
1904       --  the main unit. With validity checks enabled, some predefined
1905       --  subprograms may contain nested subprograms and become ineligible
1906       --  for inlining.
1907
1908       if Is_Predefined_File_Name (Unit_File_Name (Get_Source_Unit (Subp)))
1909         and then not In_Extended_Main_Source_Unit (Subp)
1910       then
1911          null;
1912
1913       elsif Is_Always_Inlined (Subp) then
1914          Error_Msg_NE (Msg (1 .. Msg'Length - 1), N, Subp);
1915
1916       elsif Ineffective_Inline_Warnings then
1917          Error_Msg_NE (Msg, N, Subp);
1918       end if;
1919    end Cannot_Inline;
1920
1921    -----------------------
1922    -- Check_Conformance --
1923    -----------------------
1924
1925    procedure Check_Conformance
1926      (New_Id   : Entity_Id;
1927       Old_Id   : Entity_Id;
1928       Ctype    : Conformance_Type;
1929       Errmsg   : Boolean;
1930       Conforms : out Boolean;
1931       Err_Loc  : Node_Id := Empty;
1932       Get_Inst : Boolean := False)
1933    is
1934       Old_Type   : constant Entity_Id := Etype (Old_Id);
1935       New_Type   : constant Entity_Id := Etype (New_Id);
1936       Old_Formal : Entity_Id;
1937       New_Formal : Entity_Id;
1938
1939       procedure Conformance_Error (Msg : String; N : Node_Id := New_Id);
1940       --  Post error message for conformance error on given node.
1941       --  Two messages are output. The first points to the previous
1942       --  declaration with a general "no conformance" message.
1943       --  The second is the detailed reason, supplied as Msg. The
1944       --  parameter N provide information for a possible & insertion
1945       --  in the message, and also provides the location for posting
1946       --  the message in the absence of a specified Err_Loc location.
1947
1948       -----------------------
1949       -- Conformance_Error --
1950       -----------------------
1951
1952       procedure Conformance_Error (Msg : String; N : Node_Id := New_Id) is
1953          Enode : Node_Id;
1954
1955       begin
1956          Conforms := False;
1957
1958          if Errmsg then
1959             if No (Err_Loc) then
1960                Enode := N;
1961             else
1962                Enode := Err_Loc;
1963             end if;
1964
1965             Error_Msg_Sloc := Sloc (Old_Id);
1966
1967             case Ctype is
1968                when Type_Conformant =>
1969                   Error_Msg_N
1970                     ("not type conformant with declaration#!", Enode);
1971
1972                when Mode_Conformant =>
1973                   Error_Msg_N
1974                     ("not mode conformant with declaration#!", Enode);
1975
1976                when Subtype_Conformant =>
1977                   Error_Msg_N
1978                     ("not subtype conformant with declaration#!", Enode);
1979
1980                when Fully_Conformant =>
1981                   Error_Msg_N
1982                     ("not fully conformant with declaration#!", Enode);
1983             end case;
1984
1985             Error_Msg_NE (Msg, Enode, N);
1986          end if;
1987       end Conformance_Error;
1988
1989    --  Start of processing for Check_Conformance
1990
1991    begin
1992       Conforms := True;
1993
1994       --  We need a special case for operators, since they don't
1995       --  appear explicitly.
1996
1997       if Ctype = Type_Conformant then
1998          if Ekind (New_Id) = E_Operator
1999            and then Operator_Matches_Spec (New_Id, Old_Id)
2000          then
2001             return;
2002          end if;
2003       end if;
2004
2005       --  If both are functions/operators, check return types conform
2006
2007       if Old_Type /= Standard_Void_Type
2008         and then New_Type /= Standard_Void_Type
2009       then
2010          if not Conforming_Types (Old_Type, New_Type, Ctype, Get_Inst) then
2011             Conformance_Error ("return type does not match!", New_Id);
2012             return;
2013          end if;
2014
2015       --  If either is a function/operator and the other isn't, error
2016
2017       elsif Old_Type /= Standard_Void_Type
2018         or else New_Type /= Standard_Void_Type
2019       then
2020          Conformance_Error ("functions can only match functions!", New_Id);
2021          return;
2022       end if;
2023
2024       --  In subtype conformant case, conventions must match (RM 6.3.1(16))
2025       --  If this is a renaming as body, refine error message to indicate that
2026       --  the conflict is with the original declaration. If the entity is not
2027       --  frozen, the conventions don't have to match, the one of the renamed
2028       --  entity is inherited.
2029
2030       if Ctype >= Subtype_Conformant then
2031          if Convention (Old_Id) /= Convention (New_Id) then
2032
2033             if not Is_Frozen (New_Id) then
2034                null;
2035
2036             elsif Present (Err_Loc)
2037               and then Nkind (Err_Loc) = N_Subprogram_Renaming_Declaration
2038               and then Present (Corresponding_Spec (Err_Loc))
2039             then
2040                Error_Msg_Name_1 := Chars (New_Id);
2041                Error_Msg_Name_2 :=
2042                  Name_Ada + Convention_Id'Pos (Convention (New_Id));
2043
2044                Conformance_Error ("prior declaration for% has convention %!");
2045
2046             else
2047                Conformance_Error ("calling conventions do not match!");
2048             end if;
2049
2050             return;
2051
2052          elsif Is_Formal_Subprogram (Old_Id)
2053            or else Is_Formal_Subprogram (New_Id)
2054          then
2055             Conformance_Error ("formal subprograms not allowed!");
2056             return;
2057          end if;
2058       end if;
2059
2060       --  Deal with parameters
2061
2062       --  Note: we use the entity information, rather than going directly
2063       --  to the specification in the tree. This is not only simpler, but
2064       --  absolutely necessary for some cases of conformance tests between
2065       --  operators, where the declaration tree simply does not exist!
2066
2067       Old_Formal := First_Formal (Old_Id);
2068       New_Formal := First_Formal (New_Id);
2069
2070       while Present (Old_Formal) and then Present (New_Formal) loop
2071          if Ctype = Fully_Conformant then
2072
2073             --  Names must match. Error message is more accurate if we do
2074             --  this before checking that the types of the formals match.
2075
2076             if Chars (Old_Formal) /= Chars (New_Formal) then
2077                Conformance_Error ("name & does not match!", New_Formal);
2078
2079                --  Set error posted flag on new formal as well to stop
2080                --  junk cascaded messages in some cases.
2081
2082                Set_Error_Posted (New_Formal);
2083                return;
2084             end if;
2085          end if;
2086
2087          --  Types must always match. In the visible part of an instance,
2088          --  usual overloading rules for dispatching operations apply, and
2089          --  we check base types (not the actual subtypes).
2090
2091          if In_Instance_Visible_Part
2092            and then Is_Dispatching_Operation (New_Id)
2093          then
2094             if not Conforming_Types
2095               (Base_Type (Etype (Old_Formal)),
2096                  Base_Type (Etype (New_Formal)), Ctype, Get_Inst)
2097             then
2098                Conformance_Error ("type of & does not match!", New_Formal);
2099                return;
2100             end if;
2101
2102          elsif not Conforming_Types
2103            (Etype (Old_Formal), Etype (New_Formal), Ctype, Get_Inst)
2104          then
2105             Conformance_Error ("type of & does not match!", New_Formal);
2106             return;
2107          end if;
2108
2109          --  For mode conformance, mode must match
2110
2111          if Ctype >= Mode_Conformant
2112            and then Parameter_Mode (Old_Formal) /= Parameter_Mode (New_Formal)
2113          then
2114             Conformance_Error ("mode of & does not match!", New_Formal);
2115             return;
2116          end if;
2117
2118          --  Full conformance checks
2119
2120          if Ctype = Fully_Conformant then
2121
2122             --  We have checked already that names match.
2123             --  Check default expressions for in parameters
2124
2125             if Parameter_Mode (Old_Formal) = E_In_Parameter then
2126                declare
2127                   NewD : constant Boolean :=
2128                            Present (Default_Value (New_Formal));
2129                   OldD : constant Boolean :=
2130                            Present (Default_Value (Old_Formal));
2131                begin
2132                   if NewD or OldD then
2133
2134                      --  The old default value has been analyzed because
2135                      --  the current full declaration will have frozen
2136                      --  everything before. The new default values have not
2137                      --  been analyzed, so analyze them now before we check
2138                      --  for conformance.
2139
2140                      if NewD then
2141                         New_Scope (New_Id);
2142                         Analyze_Per_Use_Expression
2143                           (Default_Value (New_Formal), Etype (New_Formal));
2144                         End_Scope;
2145                      end if;
2146
2147                      if not (NewD and OldD)
2148                        or else not Fully_Conformant_Expressions
2149                                     (Default_Value (Old_Formal),
2150                                      Default_Value (New_Formal))
2151                      then
2152                         Conformance_Error
2153                           ("default expression for & does not match!",
2154                            New_Formal);
2155                         return;
2156                      end if;
2157                   end if;
2158                end;
2159             end if;
2160          end if;
2161
2162          --  A couple of special checks for Ada 83 mode. These checks are
2163          --  skipped if either entity is an operator in package Standard.
2164          --  or if either old or new instance is not from the source program.
2165
2166          if Ada_Version = Ada_83
2167            and then Sloc (Old_Id) > Standard_Location
2168            and then Sloc (New_Id) > Standard_Location
2169            and then Comes_From_Source (Old_Id)
2170            and then Comes_From_Source (New_Id)
2171          then
2172             declare
2173                Old_Param : constant Node_Id := Declaration_Node (Old_Formal);
2174                New_Param : constant Node_Id := Declaration_Node (New_Formal);
2175
2176             begin
2177                --  Explicit IN must be present or absent in both cases. This
2178                --  test is required only in the full conformance case.
2179
2180                if In_Present (Old_Param) /= In_Present (New_Param)
2181                  and then Ctype = Fully_Conformant
2182                then
2183                   Conformance_Error
2184                     ("(Ada 83) IN must appear in both declarations",
2185                      New_Formal);
2186                   return;
2187                end if;
2188
2189                --  Grouping (use of comma in param lists) must be the same
2190                --  This is where we catch a misconformance like:
2191
2192                --    A,B : Integer
2193                --    A : Integer; B : Integer
2194
2195                --  which are represented identically in the tree except
2196                --  for the setting of the flags More_Ids and Prev_Ids.
2197
2198                if More_Ids (Old_Param) /= More_Ids (New_Param)
2199                  or else Prev_Ids (Old_Param) /= Prev_Ids (New_Param)
2200                then
2201                   Conformance_Error
2202                     ("grouping of & does not match!", New_Formal);
2203                   return;
2204                end if;
2205             end;
2206          end if;
2207
2208          Next_Formal (Old_Formal);
2209          Next_Formal (New_Formal);
2210       end loop;
2211
2212       if Present (Old_Formal) then
2213          Conformance_Error ("too few parameters!");
2214          return;
2215
2216       elsif Present (New_Formal) then
2217          Conformance_Error ("too many parameters!", New_Formal);
2218          return;
2219       end if;
2220
2221    end Check_Conformance;
2222
2223    ------------------------------
2224    -- Check_Delayed_Subprogram --
2225    ------------------------------
2226
2227    procedure Check_Delayed_Subprogram (Designator : Entity_Id) is
2228       F : Entity_Id;
2229
2230       procedure Possible_Freeze (T : Entity_Id);
2231       --  T is the type of either a formal parameter or of the return type.
2232       --  If T is not yet frozen and needs a delayed freeze, then the
2233       --  subprogram itself must be delayed.
2234
2235       procedure Possible_Freeze (T : Entity_Id) is
2236       begin
2237          if Has_Delayed_Freeze (T)
2238            and then not Is_Frozen (T)
2239          then
2240             Set_Has_Delayed_Freeze (Designator);
2241
2242          elsif Is_Access_Type (T)
2243            and then Has_Delayed_Freeze (Designated_Type (T))
2244            and then not Is_Frozen (Designated_Type (T))
2245          then
2246             Set_Has_Delayed_Freeze (Designator);
2247          end if;
2248       end Possible_Freeze;
2249
2250    --  Start of processing for Check_Delayed_Subprogram
2251
2252    begin
2253       --  Never need to freeze abstract subprogram
2254
2255       if Is_Abstract (Designator) then
2256          null;
2257       else
2258          --  Need delayed freeze if return type itself needs a delayed
2259          --  freeze and is not yet frozen.
2260
2261          Possible_Freeze (Etype (Designator));
2262          Possible_Freeze (Base_Type (Etype (Designator))); -- needed ???
2263
2264          --  Need delayed freeze if any of the formal types themselves need
2265          --  a delayed freeze and are not yet frozen.
2266
2267          F := First_Formal (Designator);
2268          while Present (F) loop
2269             Possible_Freeze (Etype (F));
2270             Possible_Freeze (Base_Type (Etype (F))); -- needed ???
2271             Next_Formal (F);
2272          end loop;
2273       end if;
2274
2275       --  Mark functions that return by reference. Note that it cannot be
2276       --  done for delayed_freeze subprograms because the underlying
2277       --  returned type may not be known yet (for private types)
2278
2279       if not Has_Delayed_Freeze (Designator)
2280         and then Expander_Active
2281       then
2282          declare
2283             Typ  : constant Entity_Id := Etype (Designator);
2284             Utyp : constant Entity_Id := Underlying_Type (Typ);
2285
2286          begin
2287             if Is_Return_By_Reference_Type (Typ) then
2288                Set_Returns_By_Ref (Designator);
2289
2290             elsif Present (Utyp) and then Controlled_Type (Utyp) then
2291                Set_Returns_By_Ref (Designator);
2292             end if;
2293          end;
2294       end if;
2295    end Check_Delayed_Subprogram;
2296
2297    ------------------------------------
2298    -- Check_Discriminant_Conformance --
2299    ------------------------------------
2300
2301    procedure Check_Discriminant_Conformance
2302      (N        : Node_Id;
2303       Prev     : Entity_Id;
2304       Prev_Loc : Node_Id)
2305    is
2306       Old_Discr      : Entity_Id := First_Discriminant (Prev);
2307       New_Discr      : Node_Id   := First (Discriminant_Specifications (N));
2308       New_Discr_Id   : Entity_Id;
2309       New_Discr_Type : Entity_Id;
2310
2311       procedure Conformance_Error (Msg : String; N : Node_Id);
2312       --  Post error message for conformance error on given node.
2313       --  Two messages are output. The first points to the previous
2314       --  declaration with a general "no conformance" message.
2315       --  The second is the detailed reason, supplied as Msg. The
2316       --  parameter N provide information for a possible & insertion
2317       --  in the message.
2318
2319       -----------------------
2320       -- Conformance_Error --
2321       -----------------------
2322
2323       procedure Conformance_Error (Msg : String; N : Node_Id) is
2324       begin
2325          Error_Msg_Sloc := Sloc (Prev_Loc);
2326          Error_Msg_N ("not fully conformant with declaration#!", N);
2327          Error_Msg_NE (Msg, N, N);
2328       end Conformance_Error;
2329
2330    --  Start of processing for Check_Discriminant_Conformance
2331
2332    begin
2333       while Present (Old_Discr) and then Present (New_Discr) loop
2334
2335          New_Discr_Id := Defining_Identifier (New_Discr);
2336
2337          --  The subtype mark of the discriminant on the full type
2338          --  has not been analyzed so we do it here. For an access
2339          --  discriminant a new type is created.
2340
2341          if Nkind (Discriminant_Type (New_Discr)) = N_Access_Definition then
2342             New_Discr_Type :=
2343               Access_Definition (N, Discriminant_Type (New_Discr));
2344
2345          else
2346             Analyze (Discriminant_Type (New_Discr));
2347             New_Discr_Type := Etype (Discriminant_Type (New_Discr));
2348          end if;
2349
2350          if not Conforming_Types
2351                   (Etype (Old_Discr), New_Discr_Type, Fully_Conformant)
2352          then
2353             Conformance_Error ("type of & does not match!", New_Discr_Id);
2354             return;
2355          else
2356             --  Treat the new discriminant as an occurrence of the old
2357             --  one, for navigation purposes, and fill in some semantic
2358             --  information, for completeness.
2359
2360             Generate_Reference (Old_Discr, New_Discr_Id, 'r');
2361             Set_Etype (New_Discr_Id, Etype (Old_Discr));
2362             Set_Scope (New_Discr_Id, Scope (Old_Discr));
2363          end if;
2364
2365          --  Names must match
2366
2367          if Chars (Old_Discr) /= Chars (Defining_Identifier (New_Discr)) then
2368             Conformance_Error ("name & does not match!", New_Discr_Id);
2369             return;
2370          end if;
2371
2372          --  Default expressions must match
2373
2374          declare
2375             NewD : constant Boolean :=
2376                      Present (Expression (New_Discr));
2377             OldD : constant Boolean :=
2378                      Present (Expression (Parent (Old_Discr)));
2379
2380          begin
2381             if NewD or OldD then
2382
2383                --  The old default value has been analyzed and expanded,
2384                --  because the current full declaration will have frozen
2385                --  everything before. The new default values have not
2386                --  been expanded, so expand now to check conformance.
2387
2388                if NewD then
2389                   Analyze_Per_Use_Expression
2390                     (Expression (New_Discr), New_Discr_Type);
2391                end if;
2392
2393                if not (NewD and OldD)
2394                  or else not Fully_Conformant_Expressions
2395                               (Expression (Parent (Old_Discr)),
2396                                Expression (New_Discr))
2397
2398                then
2399                   Conformance_Error
2400                     ("default expression for & does not match!",
2401                      New_Discr_Id);
2402                   return;
2403                end if;
2404             end if;
2405          end;
2406
2407          --  In Ada 83 case, grouping must match: (A,B : X) /= (A : X; B : X)
2408
2409          if Ada_Version = Ada_83 then
2410             declare
2411                Old_Disc : constant Node_Id := Declaration_Node (Old_Discr);
2412
2413             begin
2414                --  Grouping (use of comma in param lists) must be the same
2415                --  This is where we catch a misconformance like:
2416
2417                --    A,B : Integer
2418                --    A : Integer; B : Integer
2419
2420                --  which are represented identically in the tree except
2421                --  for the setting of the flags More_Ids and Prev_Ids.
2422
2423                if More_Ids (Old_Disc) /= More_Ids (New_Discr)
2424                  or else Prev_Ids (Old_Disc) /= Prev_Ids (New_Discr)
2425                then
2426                   Conformance_Error
2427                     ("grouping of & does not match!", New_Discr_Id);
2428                   return;
2429                end if;
2430             end;
2431          end if;
2432
2433          Next_Discriminant (Old_Discr);
2434          Next (New_Discr);
2435       end loop;
2436
2437       if Present (Old_Discr) then
2438          Conformance_Error ("too few discriminants!", Defining_Identifier (N));
2439          return;
2440
2441       elsif Present (New_Discr) then
2442          Conformance_Error
2443            ("too many discriminants!", Defining_Identifier (New_Discr));
2444          return;
2445       end if;
2446    end Check_Discriminant_Conformance;
2447
2448    ----------------------------
2449    -- Check_Fully_Conformant --
2450    ----------------------------
2451
2452    procedure Check_Fully_Conformant
2453      (New_Id  : Entity_Id;
2454       Old_Id  : Entity_Id;
2455       Err_Loc : Node_Id := Empty)
2456    is
2457       Result : Boolean;
2458
2459    begin
2460       Check_Conformance
2461         (New_Id, Old_Id, Fully_Conformant, True, Result, Err_Loc);
2462    end Check_Fully_Conformant;
2463
2464    ---------------------------
2465    -- Check_Mode_Conformant --
2466    ---------------------------
2467
2468    procedure Check_Mode_Conformant
2469      (New_Id   : Entity_Id;
2470       Old_Id   : Entity_Id;
2471       Err_Loc  : Node_Id := Empty;
2472       Get_Inst : Boolean := False)
2473    is
2474       Result : Boolean;
2475
2476    begin
2477       Check_Conformance
2478         (New_Id, Old_Id, Mode_Conformant, True, Result, Err_Loc, Get_Inst);
2479    end Check_Mode_Conformant;
2480
2481    --------------------------------
2482    -- Check_Overriding_Operation --
2483    --------------------------------
2484
2485    procedure Check_Overriding_Operation
2486      (N    : Node_Id;
2487       Subp : Entity_Id)
2488    is
2489       Arg1       : Node_Id;
2490       Decl       : Node_Id;
2491       Has_Pragma : Boolean := False;
2492
2493    begin
2494       --  See whether there is an overriding pragma immediately following
2495       --  the declaration. Intervening pragmas, such as Inline, are allowed.
2496
2497       Decl := Next (N);
2498       while Present (Decl)
2499         and then Nkind (Decl) = N_Pragma
2500       loop
2501          if Chars (Decl) = Name_Overriding
2502            or else Chars (Decl) = Name_Optional_Overriding
2503          then
2504             --  For now disable the use of these pragmas, until the ARG
2505             --  finalizes the design of this feature.
2506
2507             Error_Msg_N ("?unrecognized pragma", Decl);
2508
2509             if not Is_Overriding_Operation (Subp) then
2510
2511                --  Before emitting an error message, check whether this
2512                --  may override an operation that is not yet visible, as
2513                --  in the case of a derivation of a private operation in
2514                --  a child unit. Such an operation is introduced with a
2515                --  different name, but its alias is the parent operation.
2516
2517                declare
2518                   E : Entity_Id;
2519
2520                begin
2521                   E := First_Entity (Current_Scope);
2522
2523                   while Present (E) loop
2524                      if Ekind (E) = Ekind (Subp)
2525                        and then not Comes_From_Source (E)
2526                        and then Present (Alias (E))
2527                        and then Chars (Alias (E)) = Chars (Subp)
2528                        and then In_Open_Scopes (Scope (Alias (E)))
2529                      then
2530                         exit;
2531                      else
2532                         Next_Entity (E);
2533                      end if;
2534                   end loop;
2535
2536                   if No (E) then
2537                      Error_Msg_NE
2538                        ("& must override an inherited operation",
2539                          Decl, Subp);
2540                   end if;
2541                end;
2542             end if;
2543
2544             --  Verify syntax of pragma
2545
2546             Arg1 := First (Pragma_Argument_Associations (Decl));
2547
2548             if Present (Arg1) then
2549                if not Is_Entity_Name (Expression (Arg1)) then
2550                   Error_Msg_N ("pragma applies to local subprogram", Decl);
2551
2552                elsif Chars (Expression (Arg1)) /= Chars (Subp) then
2553                   Error_Msg_N
2554                     ("pragma must apply to preceding subprogram", Decl);
2555
2556                elsif Present (Next (Arg1)) then
2557                   Error_Msg_N ("illegal pragma format", Decl);
2558                end if;
2559             end if;
2560
2561             Set_Analyzed (Decl);
2562             Has_Pragma := True;
2563             exit;
2564          end if;
2565
2566          Next (Decl);
2567       end loop;
2568
2569       if not Has_Pragma
2570         and then Explicit_Overriding
2571         and then Is_Overriding_Operation (Subp)
2572       then
2573          Error_Msg_NE ("Missing overriding pragma for&", Subp, Subp);
2574       end if;
2575    end Check_Overriding_Operation;
2576
2577    -------------------
2578    -- Check_Returns --
2579    -------------------
2580
2581    procedure Check_Returns
2582      (HSS  : Node_Id;
2583       Mode : Character;
2584       Err  : out Boolean)
2585    is
2586       Handler : Node_Id;
2587
2588       procedure Check_Statement_Sequence (L : List_Id);
2589       --  Internal recursive procedure to check a list of statements for proper
2590       --  termination by a return statement (or a transfer of control or a
2591       --  compound statement that is itself internally properly terminated).
2592
2593       ------------------------------
2594       -- Check_Statement_Sequence --
2595       ------------------------------
2596
2597       procedure Check_Statement_Sequence (L : List_Id) is
2598          Last_Stm : Node_Id;
2599          Kind     : Node_Kind;
2600
2601          Raise_Exception_Call : Boolean;
2602          --  Set True if statement sequence terminated by Raise_Exception call
2603          --  or a Reraise_Occurrence call.
2604
2605       begin
2606          Raise_Exception_Call := False;
2607
2608          --  Get last real statement
2609
2610          Last_Stm := Last (L);
2611
2612          --  Don't count pragmas
2613
2614          while Nkind (Last_Stm) = N_Pragma
2615
2616          --  Don't count call to SS_Release (can happen after Raise_Exception)
2617
2618            or else
2619              (Nkind (Last_Stm) = N_Procedure_Call_Statement
2620                 and then
2621               Nkind (Name (Last_Stm)) = N_Identifier
2622                 and then
2623               Is_RTE (Entity (Name (Last_Stm)), RE_SS_Release))
2624
2625          --  Don't count exception junk
2626
2627            or else
2628              ((Nkind (Last_Stm) = N_Goto_Statement
2629                  or else Nkind (Last_Stm) = N_Label
2630                  or else Nkind (Last_Stm) = N_Object_Declaration)
2631                and then Exception_Junk (Last_Stm))
2632          loop
2633             Prev (Last_Stm);
2634          end loop;
2635
2636          --  Here we have the "real" last statement
2637
2638          Kind := Nkind (Last_Stm);
2639
2640          --  Transfer of control, OK. Note that in the No_Return procedure
2641          --  case, we already diagnosed any explicit return statements, so
2642          --  we can treat them as OK in this context.
2643
2644          if Is_Transfer (Last_Stm) then
2645             return;
2646
2647          --  Check cases of explicit non-indirect procedure calls
2648
2649          elsif Kind = N_Procedure_Call_Statement
2650            and then Is_Entity_Name (Name (Last_Stm))
2651          then
2652             --  Check call to Raise_Exception procedure which is treated
2653             --  specially, as is a call to Reraise_Occurrence.
2654
2655             --  We suppress the warning in these cases since it is likely that
2656             --  the programmer really does not expect to deal with the case
2657             --  of Null_Occurrence, and thus would find a warning about a
2658             --  missing return curious, and raising Program_Error does not
2659             --  seem such a bad behavior if this does occur.
2660
2661             if Is_RTE (Entity (Name (Last_Stm)), RE_Raise_Exception)
2662                  or else
2663                Is_RTE (Entity (Name (Last_Stm)), RE_Reraise_Occurrence)
2664             then
2665                Raise_Exception_Call := True;
2666
2667                --  For Raise_Exception call, test first argument, if it is
2668                --  an attribute reference for a 'Identity call, then we know
2669                --  that the call cannot possibly return.
2670
2671                declare
2672                   Arg : constant Node_Id :=
2673                           Original_Node (First_Actual (Last_Stm));
2674
2675                begin
2676                   if Nkind (Arg) = N_Attribute_Reference
2677                     and then Attribute_Name (Arg) = Name_Identity
2678                   then
2679                      return;
2680                   end if;
2681                end;
2682             end if;
2683
2684          --  If statement, need to look inside if there is an else and check
2685          --  each constituent statement sequence for proper termination.
2686
2687          elsif Kind = N_If_Statement
2688            and then Present (Else_Statements (Last_Stm))
2689          then
2690             Check_Statement_Sequence (Then_Statements (Last_Stm));
2691             Check_Statement_Sequence (Else_Statements (Last_Stm));
2692
2693             if Present (Elsif_Parts (Last_Stm)) then
2694                declare
2695                   Elsif_Part : Node_Id := First (Elsif_Parts (Last_Stm));
2696
2697                begin
2698                   while Present (Elsif_Part) loop
2699                      Check_Statement_Sequence (Then_Statements (Elsif_Part));
2700                      Next (Elsif_Part);
2701                   end loop;
2702                end;
2703             end if;
2704
2705             return;
2706
2707          --  Case statement, check each case for proper termination
2708
2709          elsif Kind = N_Case_Statement then
2710             declare
2711                Case_Alt : Node_Id;
2712
2713             begin
2714                Case_Alt := First_Non_Pragma (Alternatives (Last_Stm));
2715                while Present (Case_Alt) loop
2716                   Check_Statement_Sequence (Statements (Case_Alt));
2717                   Next_Non_Pragma (Case_Alt);
2718                end loop;
2719             end;
2720
2721             return;
2722
2723          --  Block statement, check its handled sequence of statements
2724
2725          elsif Kind = N_Block_Statement then
2726             declare
2727                Err1 : Boolean;
2728
2729             begin
2730                Check_Returns
2731                  (Handled_Statement_Sequence (Last_Stm), Mode, Err1);
2732
2733                if Err1 then
2734                   Err := True;
2735                end if;
2736
2737                return;
2738             end;
2739
2740          --  Loop statement. If there is an iteration scheme, we can definitely
2741          --  fall out of the loop. Similarly if there is an exit statement, we
2742          --  can fall out. In either case we need a following return.
2743
2744          elsif Kind = N_Loop_Statement then
2745             if Present (Iteration_Scheme (Last_Stm))
2746               or else Has_Exit (Entity (Identifier (Last_Stm)))
2747             then
2748                null;
2749
2750             --  A loop with no exit statement or iteration scheme if either
2751             --  an inifite loop, or it has some other exit (raise/return).
2752             --  In either case, no warning is required.
2753
2754             else
2755                return;
2756             end if;
2757
2758          --  Timed entry call, check entry call and delay alternatives
2759
2760          --  Note: in expanded code, the timed entry call has been converted
2761          --  to a set of expanded statements on which the check will work
2762          --  correctly in any case.
2763
2764          elsif Kind = N_Timed_Entry_Call then
2765             declare
2766                ECA : constant Node_Id := Entry_Call_Alternative (Last_Stm);
2767                DCA : constant Node_Id := Delay_Alternative      (Last_Stm);
2768
2769             begin
2770                --  If statement sequence of entry call alternative is missing,
2771                --  then we can definitely fall through, and we post the error
2772                --  message on the entry call alternative itself.
2773
2774                if No (Statements (ECA)) then
2775                   Last_Stm := ECA;
2776
2777                --  If statement sequence of delay alternative is missing, then
2778                --  we can definitely fall through, and we post the error
2779                --  message on the delay alternative itself.
2780
2781                --  Note: if both ECA and DCA are missing the return, then we
2782                --  post only one message, should be enough to fix the bugs.
2783                --  If not we will get a message next time on the DCA when the
2784                --  ECA is fixed!
2785
2786                elsif No (Statements (DCA)) then
2787                   Last_Stm := DCA;
2788
2789                --  Else check both statement sequences
2790
2791                else
2792                   Check_Statement_Sequence (Statements (ECA));
2793                   Check_Statement_Sequence (Statements (DCA));
2794                   return;
2795                end if;
2796             end;
2797
2798          --  Conditional entry call, check entry call and else part
2799
2800          --  Note: in expanded code, the conditional entry call has been
2801          --  converted to a set of expanded statements on which the check
2802          --  will work correctly in any case.
2803
2804          elsif Kind = N_Conditional_Entry_Call then
2805             declare
2806                ECA : constant Node_Id := Entry_Call_Alternative (Last_Stm);
2807
2808             begin
2809                --  If statement sequence of entry call alternative is missing,
2810                --  then we can definitely fall through, and we post the error
2811                --  message on the entry call alternative itself.
2812
2813                if No (Statements (ECA)) then
2814                   Last_Stm := ECA;
2815
2816                --  Else check statement sequence and else part
2817
2818                else
2819                   Check_Statement_Sequence (Statements (ECA));
2820                   Check_Statement_Sequence (Else_Statements (Last_Stm));
2821                   return;
2822                end if;
2823             end;
2824          end if;
2825
2826          --  If we fall through, issue appropriate message
2827
2828          if Mode = 'F' then
2829
2830             if not Raise_Exception_Call then
2831                Error_Msg_N
2832                  ("?RETURN statement missing following this statement!",
2833                   Last_Stm);
2834                Error_Msg_N
2835                  ("\?Program_Error may be raised at run time",
2836                   Last_Stm);
2837             end if;
2838
2839             --  Note: we set Err even though we have not issued a warning
2840             --  because we still have a case of a missing return. This is
2841             --  an extremely marginal case, probably will never be noticed
2842             --  but we might as well get it right.
2843
2844             Err := True;
2845
2846          else
2847             Error_Msg_N
2848               ("implied return after this statement not allowed (No_Return)",
2849                Last_Stm);
2850          end if;
2851       end Check_Statement_Sequence;
2852
2853    --  Start of processing for Check_Returns
2854
2855    begin
2856       Err := False;
2857       Check_Statement_Sequence (Statements (HSS));
2858
2859       if Present (Exception_Handlers (HSS)) then
2860          Handler := First_Non_Pragma (Exception_Handlers (HSS));
2861          while Present (Handler) loop
2862             Check_Statement_Sequence (Statements (Handler));
2863             Next_Non_Pragma (Handler);
2864          end loop;
2865       end if;
2866    end Check_Returns;
2867
2868    ----------------------------
2869    -- Check_Subprogram_Order --
2870    ----------------------------
2871
2872    procedure Check_Subprogram_Order (N : Node_Id) is
2873
2874       function Subprogram_Name_Greater (S1, S2 : String) return Boolean;
2875       --  This is used to check if S1 > S2 in the sense required by this
2876       --  test, for example nameab < namec, but name2 < name10.
2877
2878       function Subprogram_Name_Greater (S1, S2 : String) return Boolean is
2879          L1, L2 : Positive;
2880          N1, N2 : Natural;
2881
2882       begin
2883          --  Remove trailing numeric parts
2884
2885          L1 := S1'Last;
2886          while S1 (L1) in '0' .. '9' loop
2887             L1 := L1 - 1;
2888          end loop;
2889
2890          L2 := S2'Last;
2891          while S2 (L2) in '0' .. '9' loop
2892             L2 := L2 - 1;
2893          end loop;
2894
2895          --  If non-numeric parts non-equal, that's decisive
2896
2897          if S1 (S1'First .. L1) < S2 (S2'First .. L2) then
2898             return False;
2899
2900          elsif S1 (S1'First .. L1) > S2 (S2'First .. L2) then
2901             return True;
2902
2903          --  If non-numeric parts equal, compare suffixed numeric parts. Note
2904          --  that a missing suffix is treated as numeric zero in this test.
2905
2906          else
2907             N1 := 0;
2908             while L1 < S1'Last loop
2909                L1 := L1 + 1;
2910                N1 := N1 * 10 + Character'Pos (S1 (L1)) - Character'Pos ('0');
2911             end loop;
2912
2913             N2 := 0;
2914             while L2 < S2'Last loop
2915                L2 := L2 + 1;
2916                N2 := N2 * 10 + Character'Pos (S2 (L2)) - Character'Pos ('0');
2917             end loop;
2918
2919             return N1 > N2;
2920          end if;
2921       end Subprogram_Name_Greater;
2922
2923    --  Start of processing for Check_Subprogram_Order
2924
2925    begin
2926       --  Check body in alpha order if this is option
2927
2928       if Style_Check
2929         and then Style_Check_Subprogram_Order
2930         and then Nkind (N) = N_Subprogram_Body
2931         and then Comes_From_Source (N)
2932         and then In_Extended_Main_Source_Unit (N)
2933       then
2934          declare
2935             LSN : String_Ptr
2936                     renames Scope_Stack.Table
2937                               (Scope_Stack.Last).Last_Subprogram_Name;
2938
2939             Body_Id : constant Entity_Id :=
2940                         Defining_Entity (Specification (N));
2941
2942          begin
2943             Get_Decoded_Name_String (Chars (Body_Id));
2944
2945             if LSN /= null then
2946                if Subprogram_Name_Greater
2947                     (LSN.all, Name_Buffer (1 .. Name_Len))
2948                then
2949                   Style.Subprogram_Not_In_Alpha_Order (Body_Id);
2950                end if;
2951
2952                Free (LSN);
2953             end if;
2954
2955             LSN := new String'(Name_Buffer (1 .. Name_Len));
2956          end;
2957       end if;
2958    end Check_Subprogram_Order;
2959
2960    ------------------------------
2961    -- Check_Subtype_Conformant --
2962    ------------------------------
2963
2964    procedure Check_Subtype_Conformant
2965      (New_Id  : Entity_Id;
2966       Old_Id  : Entity_Id;
2967       Err_Loc : Node_Id := Empty)
2968    is
2969       Result : Boolean;
2970
2971    begin
2972       Check_Conformance
2973         (New_Id, Old_Id, Subtype_Conformant, True, Result, Err_Loc);
2974    end Check_Subtype_Conformant;
2975
2976    ---------------------------
2977    -- Check_Type_Conformant --
2978    ---------------------------
2979
2980    procedure Check_Type_Conformant
2981      (New_Id  : Entity_Id;
2982       Old_Id  : Entity_Id;
2983       Err_Loc : Node_Id := Empty)
2984    is
2985       Result : Boolean;
2986
2987    begin
2988       Check_Conformance
2989         (New_Id, Old_Id, Type_Conformant, True, Result, Err_Loc);
2990    end Check_Type_Conformant;
2991
2992    ----------------------
2993    -- Conforming_Types --
2994    ----------------------
2995
2996    function Conforming_Types
2997      (T1       : Entity_Id;
2998       T2       : Entity_Id;
2999       Ctype    : Conformance_Type;
3000       Get_Inst : Boolean := False) return Boolean
3001    is
3002       Type_1 : Entity_Id := T1;
3003       Type_2 : Entity_Id := T2;
3004       Are_Anonymous_Access_To_Subprogram_Types : Boolean := False;
3005
3006       function Base_Types_Match (T1, T2 : Entity_Id) return Boolean;
3007       --  If neither T1 nor T2 are generic actual types, or if they are
3008       --  in different scopes (e.g. parent and child instances), then verify
3009       --  that the base types are equal. Otherwise T1 and T2 must be
3010       --  on the same subtype chain. The whole purpose of this procedure
3011       --  is to prevent spurious ambiguities in an instantiation that may
3012       --  arise if two distinct generic types are instantiated with the
3013       --  same actual.
3014
3015       ----------------------
3016       -- Base_Types_Match --
3017       ----------------------
3018
3019       function Base_Types_Match (T1, T2 : Entity_Id) return Boolean is
3020       begin
3021          if T1 = T2 then
3022             return True;
3023
3024          elsif Base_Type (T1) = Base_Type (T2) then
3025
3026             --  The following is too permissive. A more precise test must
3027             --  check that the generic actual is an ancestor subtype of the
3028             --  other ???.
3029
3030             return not Is_Generic_Actual_Type (T1)
3031               or else not Is_Generic_Actual_Type (T2)
3032               or else Scope (T1) /= Scope (T2);
3033
3034          --  In some cases a type imported through a limited_with clause,
3035          --  and its non-limited view are both visible, for example in an
3036          --  anonymous access_to_classwide type in a formal. Both entities
3037          --  designate the same type.
3038
3039          elsif From_With_Type (T1)
3040            and then Ekind (T1) = E_Incomplete_Type
3041            and then T2 = Non_Limited_View (T1)
3042          then
3043             return True;
3044
3045          else
3046             return False;
3047          end if;
3048       end Base_Types_Match;
3049
3050    begin
3051       --  The context is an instance association for a formal
3052       --  access-to-subprogram type; the formal parameter types
3053       --  require mapping because they may denote other formal
3054       --  parameters of the generic unit.
3055
3056       if Get_Inst then
3057          Type_1 := Get_Instance_Of (T1);
3058          Type_2 := Get_Instance_Of (T2);
3059       end if;
3060
3061       --  First see if base types match
3062
3063       if Base_Types_Match (Type_1, Type_2) then
3064          return Ctype <= Mode_Conformant
3065            or else Subtypes_Statically_Match (Type_1, Type_2);
3066
3067       elsif Is_Incomplete_Or_Private_Type (Type_1)
3068         and then Present (Full_View (Type_1))
3069         and then Base_Types_Match (Full_View (Type_1), Type_2)
3070       then
3071          return Ctype <= Mode_Conformant
3072            or else Subtypes_Statically_Match (Full_View (Type_1), Type_2);
3073
3074       elsif Ekind (Type_2) = E_Incomplete_Type
3075         and then Present (Full_View (Type_2))
3076         and then Base_Types_Match (Type_1, Full_View (Type_2))
3077       then
3078          return Ctype <= Mode_Conformant
3079            or else Subtypes_Statically_Match (Type_1, Full_View (Type_2));
3080
3081       elsif Is_Private_Type (Type_2)
3082         and then In_Instance
3083         and then Present (Full_View (Type_2))
3084         and then Base_Types_Match (Type_1, Full_View (Type_2))
3085       then
3086          return Ctype <= Mode_Conformant
3087            or else Subtypes_Statically_Match (Type_1, Full_View (Type_2));
3088       end if;
3089
3090       --  Ada 2005 (AI-254): Detect anonymous access to subprogram types
3091
3092       Are_Anonymous_Access_To_Subprogram_Types :=
3093
3094          --  Case 1: Anonymous access to subprogram types
3095
3096         (Ekind (Type_1) = E_Anonymous_Access_Subprogram_Type
3097            and then Ekind (Type_2) = E_Anonymous_Access_Subprogram_Type)
3098
3099          --  Case 2: Anonymous access to PROTECTED subprogram types. In this
3100          --  case the anonymous type_declaration has been replaced by an
3101          --  occurrence of an internal access to subprogram type declaration
3102          --  available through the Original_Access_Type attribute
3103
3104         or else
3105           (Ekind (Type_1) = E_Access_Protected_Subprogram_Type
3106             and then Ekind (Type_2) = E_Access_Protected_Subprogram_Type
3107             and then not Comes_From_Source (Type_1)
3108             and then not Comes_From_Source (Type_2)
3109             and then Present (Original_Access_Type (Type_1))
3110             and then Present (Original_Access_Type (Type_2))
3111             and then Ekind (Original_Access_Type (Type_1)) =
3112                        E_Anonymous_Access_Protected_Subprogram_Type
3113             and then Ekind (Original_Access_Type (Type_2)) =
3114                        E_Anonymous_Access_Protected_Subprogram_Type);
3115
3116       --  Test anonymous access type case. For this case, static subtype
3117       --  matching is required for mode conformance (RM 6.3.1(15))
3118
3119       if (Ekind (Type_1) = E_Anonymous_Access_Type
3120             and then Ekind (Type_2) = E_Anonymous_Access_Type)
3121         or else Are_Anonymous_Access_To_Subprogram_Types -- Ada 2005 (AI-254)
3122       then
3123          declare
3124             Desig_1 : Entity_Id;
3125             Desig_2 : Entity_Id;
3126
3127          begin
3128             Desig_1 := Directly_Designated_Type (Type_1);
3129
3130             --  An access parameter can designate an incomplete type
3131
3132             if Ekind (Desig_1) = E_Incomplete_Type
3133               and then Present (Full_View (Desig_1))
3134             then
3135                Desig_1 := Full_View (Desig_1);
3136             end if;
3137
3138             Desig_2 := Directly_Designated_Type (Type_2);
3139
3140             if Ekind (Desig_2) = E_Incomplete_Type
3141               and then Present (Full_View (Desig_2))
3142             then
3143                Desig_2 := Full_View (Desig_2);
3144             end if;
3145
3146             --  The context is an instance association for a formal
3147             --  access-to-subprogram type; formal access parameter
3148             --  designated types require mapping because they may
3149             --  denote other formal parameters of the generic unit.
3150
3151             if Get_Inst then
3152                Desig_1 := Get_Instance_Of (Desig_1);
3153                Desig_2 := Get_Instance_Of (Desig_2);
3154             end if;
3155
3156             --  It is possible for a Class_Wide_Type to be introduced for
3157             --  an incomplete type, in which case there is a separate class_
3158             --  wide type for the full view. The types conform if their
3159             --  Etypes conform, i.e. one may be the full view of the other.
3160             --  This can only happen in the context of an access parameter,
3161             --  other uses of an incomplete Class_Wide_Type are illegal.
3162
3163             if Is_Class_Wide_Type (Desig_1)
3164               and then Is_Class_Wide_Type (Desig_2)
3165             then
3166                return
3167                  Conforming_Types
3168                    (Etype (Base_Type (Desig_1)),
3169                     Etype (Base_Type (Desig_2)), Ctype);
3170
3171             elsif Are_Anonymous_Access_To_Subprogram_Types then
3172                return Ctype = Type_Conformant
3173                         or else
3174                       Subtypes_Statically_Match (Desig_1, Desig_2);
3175
3176             else
3177                return Base_Type (Desig_1) = Base_Type (Desig_2)
3178                 and then (Ctype = Type_Conformant
3179                             or else
3180                           Subtypes_Statically_Match (Desig_1, Desig_2));
3181             end if;
3182          end;
3183
3184       --  Otherwise definitely no match
3185
3186       else
3187          return False;
3188       end if;
3189
3190    end Conforming_Types;
3191
3192    --------------------------
3193    -- Create_Extra_Formals --
3194    --------------------------
3195
3196    procedure Create_Extra_Formals (E : Entity_Id) is
3197       Formal      : Entity_Id;
3198       Last_Extra  : Entity_Id;
3199       Formal_Type : Entity_Id;
3200       P_Formal    : Entity_Id := Empty;
3201
3202       function Add_Extra_Formal (Typ : Entity_Id) return Entity_Id;
3203       --  Add an extra formal, associated with the current Formal. The
3204       --  extra formal is added to the list of extra formals, and also
3205       --  returned as the result. These formals are always of mode IN.
3206
3207       ----------------------
3208       -- Add_Extra_Formal --
3209       ----------------------
3210
3211       function Add_Extra_Formal (Typ : Entity_Id) return Entity_Id is
3212          EF : constant Entity_Id :=
3213                 Make_Defining_Identifier (Sloc (Formal),
3214                   Chars => New_External_Name (Chars (Formal), 'F'));
3215
3216       begin
3217          --  We never generate extra formals if expansion is not active
3218          --  because we don't need them unless we are generating code.
3219
3220          if not Expander_Active then
3221             return Empty;
3222          end if;
3223
3224          --  A little optimization. Never generate an extra formal for
3225          --  the _init operand of an initialization procedure, since it
3226          --  could never be used.
3227
3228          if Chars (Formal) = Name_uInit then
3229             return Empty;
3230          end if;
3231
3232          Set_Ekind           (EF, E_In_Parameter);
3233          Set_Actual_Subtype  (EF, Typ);
3234          Set_Etype           (EF, Typ);
3235          Set_Scope           (EF, Scope (Formal));
3236          Set_Mechanism       (EF, Default_Mechanism);
3237          Set_Formal_Validity (EF);
3238
3239          Set_Extra_Formal (Last_Extra, EF);
3240          Last_Extra := EF;
3241          return EF;
3242       end Add_Extra_Formal;
3243
3244    --  Start of processing for Create_Extra_Formals
3245
3246    begin
3247       --  If this is a derived subprogram then the subtypes of the
3248       --  parent subprogram's formal parameters will be used to
3249       --  to determine the need for extra formals.
3250
3251       if Is_Overloadable (E) and then Present (Alias (E)) then
3252          P_Formal := First_Formal (Alias (E));
3253       end if;
3254
3255       Last_Extra := Empty;
3256       Formal := First_Formal (E);
3257       while Present (Formal) loop
3258          Last_Extra := Formal;
3259          Next_Formal (Formal);
3260       end loop;
3261
3262       --  If Extra_formals where already created, don't do it again
3263       --  This situation may arise for subprogram types created as part
3264       --  of dispatching calls (see Expand_Dispatch_Call)
3265
3266       if Present (Last_Extra) and then
3267         Present (Extra_Formal (Last_Extra))
3268       then
3269          return;
3270       end if;
3271
3272       Formal := First_Formal (E);
3273
3274       while Present (Formal) loop
3275
3276          --  Create extra formal for supporting the attribute 'Constrained.
3277          --  The case of a private type view without discriminants also
3278          --  requires the extra formal if the underlying type has defaulted
3279          --  discriminants.
3280
3281          if Ekind (Formal) /= E_In_Parameter then
3282             if Present (P_Formal) then
3283                Formal_Type := Etype (P_Formal);
3284             else
3285                Formal_Type := Etype (Formal);
3286             end if;
3287
3288             if not Has_Discriminants (Formal_Type)
3289               and then Ekind (Formal_Type) in Private_Kind
3290               and then Present (Underlying_Type (Formal_Type))
3291             then
3292                Formal_Type := Underlying_Type (Formal_Type);
3293             end if;
3294
3295             if Has_Discriminants (Formal_Type)
3296               and then
3297                 ((not Is_Constrained (Formal_Type)
3298                     and then not Is_Indefinite_Subtype (Formal_Type))
3299                   or else Present (Extra_Formal (Formal)))
3300             then
3301                Set_Extra_Constrained
3302                  (Formal, Add_Extra_Formal (Standard_Boolean));
3303             end if;
3304          end if;
3305
3306          --  Create extra formal for supporting accessibility checking
3307
3308          --  This is suppressed if we specifically suppress accessibility
3309          --  checks at the pacage level for either the subprogram, or the
3310          --  package in which it resides. However, we do not suppress it
3311          --  simply if the scope has accessibility checks suppressed, since
3312          --  this could cause trouble when clients are compiled with a
3313          --  different suppression setting. The explicit checks at the
3314          --  package level are safe from this point of view.
3315
3316          if Ekind (Etype (Formal)) = E_Anonymous_Access_Type
3317            and then not
3318              (Explicit_Suppress (E, Accessibility_Check)
3319                or else
3320               Explicit_Suppress (Scope (E), Accessibility_Check))
3321            and then
3322              (not Present (P_Formal)
3323                or else Present (Extra_Accessibility (P_Formal)))
3324          then
3325             --  Temporary kludge: for now we avoid creating the extra
3326             --  formal for access parameters of protected operations
3327             --  because of problem with the case of internal protected
3328             --  calls. ???
3329
3330             if Nkind (Parent (Parent (Parent (E)))) /= N_Protected_Definition
3331               and then Nkind (Parent (Parent (Parent (E)))) /= N_Protected_Body
3332             then
3333                Set_Extra_Accessibility
3334                  (Formal, Add_Extra_Formal (Standard_Natural));
3335             end if;
3336          end if;
3337
3338          if Present (P_Formal) then
3339             Next_Formal (P_Formal);
3340          end if;
3341
3342          Next_Formal (Formal);
3343       end loop;
3344    end Create_Extra_Formals;
3345
3346    -----------------------------
3347    -- Enter_Overloaded_Entity --
3348    -----------------------------
3349
3350    procedure Enter_Overloaded_Entity (S : Entity_Id) is
3351       E   : Entity_Id := Current_Entity_In_Scope (S);
3352       C_E : Entity_Id := Current_Entity (S);
3353
3354    begin
3355       if Present (E) then
3356          Set_Has_Homonym (E);
3357          Set_Has_Homonym (S);
3358       end if;
3359
3360       Set_Is_Immediately_Visible (S);
3361       Set_Scope (S, Current_Scope);
3362
3363       --  Chain new entity if front of homonym in current scope, so that
3364       --  homonyms are contiguous.
3365
3366       if Present (E)
3367         and then E /= C_E
3368       then
3369          while Homonym (C_E) /= E loop
3370             C_E := Homonym (C_E);
3371          end loop;
3372
3373          Set_Homonym (C_E, S);
3374
3375       else
3376          E := C_E;
3377          Set_Current_Entity (S);
3378       end if;
3379
3380       Set_Homonym (S, E);
3381
3382       Append_Entity (S, Current_Scope);
3383       Set_Public_Status (S);
3384
3385       if Debug_Flag_E then
3386          Write_Str ("New overloaded entity chain: ");
3387          Write_Name (Chars (S));
3388          E := S;
3389
3390          while Present (E) loop
3391             Write_Str (" "); Write_Int (Int (E));
3392             E := Homonym (E);
3393          end loop;
3394
3395          Write_Eol;
3396       end if;
3397
3398       --  Generate warning for hiding
3399
3400       if Warn_On_Hiding
3401         and then Comes_From_Source (S)
3402         and then In_Extended_Main_Source_Unit (S)
3403       then
3404          E := S;
3405          loop
3406             E := Homonym (E);
3407             exit when No (E);
3408
3409             --  Warn unless genuine overloading
3410
3411             if (not Is_Overloadable (E))
3412               or else Subtype_Conformant (E, S)
3413             then
3414                Error_Msg_Sloc := Sloc (E);
3415                Error_Msg_N ("declaration of & hides one#?", S);
3416             end if;
3417          end loop;
3418       end if;
3419    end Enter_Overloaded_Entity;
3420
3421    -----------------------------
3422    -- Find_Corresponding_Spec --
3423    -----------------------------
3424
3425    function Find_Corresponding_Spec (N : Node_Id) return Entity_Id is
3426       Spec       : constant Node_Id   := Specification (N);
3427       Designator : constant Entity_Id := Defining_Entity (Spec);
3428
3429       E : Entity_Id;
3430
3431    begin
3432       E := Current_Entity (Designator);
3433
3434       while Present (E) loop
3435
3436          --  We are looking for a matching spec. It must have the same scope,
3437          --  and the same name, and either be type conformant, or be the case
3438          --  of a library procedure spec and its body (which belong to one
3439          --  another regardless of whether they are type conformant or not).
3440
3441          if Scope (E) = Current_Scope then
3442             if Current_Scope = Standard_Standard
3443               or else (Ekind (E) = Ekind (Designator)
3444                          and then Type_Conformant (E, Designator))
3445             then
3446                --  Within an instantiation, we know that spec and body are
3447                --  subtype conformant, because they were subtype conformant
3448                --  in the generic. We choose the subtype-conformant entity
3449                --  here as well, to resolve spurious ambiguities in the
3450                --  instance that were not present in the generic (i.e. when
3451                --  two different types are given the same actual). If we are
3452                --  looking for a spec to match a body, full conformance is
3453                --  expected.
3454
3455                if In_Instance then
3456                   Set_Convention (Designator, Convention (E));
3457
3458                   if Nkind (N) = N_Subprogram_Body
3459                     and then Present (Homonym (E))
3460                     and then not Fully_Conformant (E, Designator)
3461                   then
3462                      goto Next_Entity;
3463
3464                   elsif not Subtype_Conformant (E, Designator) then
3465                      goto Next_Entity;
3466                   end if;
3467                end if;
3468
3469                if not Has_Completion (E) then
3470
3471                   if Nkind (N) /= N_Subprogram_Body_Stub then
3472                      Set_Corresponding_Spec (N, E);
3473                   end if;
3474
3475                   Set_Has_Completion (E);
3476                   return E;
3477
3478                elsif Nkind (Parent (N)) = N_Subunit then
3479
3480                   --  If this is the proper body of a subunit, the completion
3481                   --  flag is set when analyzing the stub.
3482
3483                   return E;
3484
3485                --  If body already exists, this is an error unless the
3486                --  previous declaration is the implicit declaration of
3487                --  a derived subprogram, or this is a spurious overloading
3488                --  in an instance.
3489
3490                elsif No (Alias (E))
3491                  and then not Is_Intrinsic_Subprogram (E)
3492                  and then not In_Instance
3493                then
3494                   Error_Msg_Sloc := Sloc (E);
3495                   if Is_Imported (E) then
3496                      Error_Msg_NE
3497                       ("body not allowed for imported subprogram & declared#",
3498                         N, E);
3499                   else
3500                      Error_Msg_NE ("duplicate body for & declared#", N, E);
3501                   end if;
3502                end if;
3503
3504             elsif Is_Child_Unit (E)
3505               and then
3506                 Nkind (Unit_Declaration_Node (Designator)) = N_Subprogram_Body
3507               and then
3508                 Nkind (Parent (Unit_Declaration_Node (Designator)))
3509                   = N_Compilation_Unit
3510             then
3511
3512                --  Child units cannot be overloaded, so a conformance mismatch
3513                --  between body and a previous spec is an error.
3514
3515                Error_Msg_N
3516                  ("body of child unit does not match previous declaration", N);
3517             end if;
3518          end if;
3519
3520          <<Next_Entity>>
3521             E := Homonym (E);
3522       end loop;
3523
3524       --  On exit, we know that no previous declaration of subprogram exists
3525
3526       return Empty;
3527    end Find_Corresponding_Spec;
3528
3529    ----------------------
3530    -- Fully_Conformant --
3531    ----------------------
3532
3533    function Fully_Conformant (New_Id, Old_Id : Entity_Id) return Boolean is
3534       Result : Boolean;
3535
3536    begin
3537       Check_Conformance (New_Id, Old_Id, Fully_Conformant, False, Result);
3538       return Result;
3539    end Fully_Conformant;
3540
3541    ----------------------------------
3542    -- Fully_Conformant_Expressions --
3543    ----------------------------------
3544
3545    function Fully_Conformant_Expressions
3546      (Given_E1 : Node_Id;
3547       Given_E2 : Node_Id) return Boolean
3548    is
3549       E1 : constant Node_Id := Original_Node (Given_E1);
3550       E2 : constant Node_Id := Original_Node (Given_E2);
3551       --  We always test conformance on original nodes, since it is possible
3552       --  for analysis and/or expansion to make things look as though they
3553       --  conform when they do not, e.g. by converting 1+2 into 3.
3554
3555       function FCE (Given_E1, Given_E2 : Node_Id) return Boolean
3556         renames Fully_Conformant_Expressions;
3557
3558       function FCL (L1, L2 : List_Id) return Boolean;
3559       --  Compare elements of two lists for conformance. Elements have to
3560       --  be conformant, and actuals inserted as default parameters do not
3561       --  match explicit actuals with the same value.
3562
3563       function FCO (Op_Node, Call_Node : Node_Id) return Boolean;
3564       --  Compare an operator node with a function call.
3565
3566       ---------
3567       -- FCL --
3568       ---------
3569
3570       function FCL (L1, L2 : List_Id) return Boolean is
3571          N1, N2 : Node_Id;
3572
3573       begin
3574          if L1 = No_List then
3575             N1 := Empty;
3576          else
3577             N1 := First (L1);
3578          end if;
3579
3580          if L2 = No_List then
3581             N2 := Empty;
3582          else
3583             N2 := First (L2);
3584          end if;
3585
3586          --  Compare two lists, skipping rewrite insertions (we want to
3587          --  compare the original trees, not the expanded versions!)
3588
3589          loop
3590             if Is_Rewrite_Insertion (N1) then
3591                Next (N1);
3592             elsif Is_Rewrite_Insertion (N2) then
3593                Next (N2);
3594             elsif No (N1) then
3595                return No (N2);
3596             elsif No (N2) then
3597                return False;
3598             elsif not FCE (N1, N2) then
3599                return False;
3600             else
3601                Next (N1);
3602                Next (N2);
3603             end if;
3604          end loop;
3605       end FCL;
3606
3607       ---------
3608       -- FCO --
3609       ---------
3610
3611       function FCO (Op_Node, Call_Node : Node_Id) return Boolean is
3612          Actuals : constant List_Id := Parameter_Associations (Call_Node);
3613          Act     : Node_Id;
3614
3615       begin
3616          if No (Actuals)
3617             or else Entity (Op_Node) /= Entity (Name (Call_Node))
3618          then
3619             return False;
3620
3621          else
3622             Act := First (Actuals);
3623
3624             if Nkind (Op_Node) in N_Binary_Op then
3625
3626                if not FCE (Left_Opnd (Op_Node), Act) then
3627                   return False;
3628                end if;
3629
3630                Next (Act);
3631             end if;
3632
3633             return Present (Act)
3634               and then FCE (Right_Opnd (Op_Node), Act)
3635               and then No (Next (Act));
3636          end if;
3637       end FCO;
3638
3639    --  Start of processing for Fully_Conformant_Expressions
3640
3641    begin
3642       --  Non-conformant if paren count does not match. Note: if some idiot
3643       --  complains that we don't do this right for more than 3 levels of
3644       --  parentheses, they will be treated with the respect they deserve :-)
3645
3646       if Paren_Count (E1) /= Paren_Count (E2) then
3647          return False;
3648
3649       --  If same entities are referenced, then they are conformant
3650       --  even if they have different forms (RM 8.3.1(19-20)).
3651
3652       elsif Is_Entity_Name (E1) and then Is_Entity_Name (E2) then
3653          if Present (Entity (E1)) then
3654             return Entity (E1) = Entity (E2)
3655               or else (Chars (Entity (E1)) = Chars (Entity (E2))
3656                         and then Ekind (Entity (E1)) = E_Discriminant
3657                         and then Ekind (Entity (E2)) = E_In_Parameter);
3658
3659          elsif Nkind (E1) = N_Expanded_Name
3660            and then Nkind (E2) = N_Expanded_Name
3661            and then Nkind (Selector_Name (E1)) = N_Character_Literal
3662            and then Nkind (Selector_Name (E2)) = N_Character_Literal
3663          then
3664             return Chars (Selector_Name (E1)) = Chars (Selector_Name (E2));
3665
3666          else
3667             --  Identifiers in component associations don't always have
3668             --  entities, but their names must conform.
3669
3670             return Nkind  (E1) = N_Identifier
3671               and then Nkind (E2) = N_Identifier
3672               and then Chars (E1) = Chars (E2);
3673          end if;
3674
3675       elsif Nkind (E1) = N_Character_Literal
3676         and then Nkind (E2) = N_Expanded_Name
3677       then
3678          return Nkind (Selector_Name (E2)) = N_Character_Literal
3679            and then Chars (E1) = Chars (Selector_Name (E2));
3680
3681       elsif Nkind (E2) = N_Character_Literal
3682         and then Nkind (E1) = N_Expanded_Name
3683       then
3684          return Nkind (Selector_Name (E1)) = N_Character_Literal
3685            and then Chars (E2) = Chars (Selector_Name (E1));
3686
3687       elsif Nkind (E1) in N_Op
3688         and then Nkind (E2) = N_Function_Call
3689       then
3690          return FCO (E1, E2);
3691
3692       elsif Nkind (E2) in N_Op
3693         and then Nkind (E1) = N_Function_Call
3694       then
3695          return FCO (E2, E1);
3696
3697       --  Otherwise we must have the same syntactic entity
3698
3699       elsif Nkind (E1) /= Nkind (E2) then
3700          return False;
3701
3702       --  At this point, we specialize by node type
3703
3704       else
3705          case Nkind (E1) is
3706
3707             when N_Aggregate =>
3708                return
3709                  FCL (Expressions (E1), Expressions (E2))
3710                    and then FCL (Component_Associations (E1),
3711                                  Component_Associations (E2));
3712
3713             when N_Allocator =>
3714                if Nkind (Expression (E1)) = N_Qualified_Expression
3715                     or else
3716                   Nkind (Expression (E2)) = N_Qualified_Expression
3717                then
3718                   return FCE (Expression (E1), Expression (E2));
3719
3720                --  Check that the subtype marks and any constraints
3721                --  are conformant
3722
3723                else
3724                   declare
3725                      Indic1 : constant Node_Id := Expression (E1);
3726                      Indic2 : constant Node_Id := Expression (E2);
3727                      Elt1   : Node_Id;
3728                      Elt2   : Node_Id;
3729
3730                   begin
3731                      if Nkind (Indic1) /= N_Subtype_Indication then
3732                         return
3733                           Nkind (Indic2) /= N_Subtype_Indication
3734                             and then Entity (Indic1) = Entity (Indic2);
3735
3736                      elsif Nkind (Indic2) /= N_Subtype_Indication then
3737                         return
3738                           Nkind (Indic1) /= N_Subtype_Indication
3739                             and then Entity (Indic1) = Entity (Indic2);
3740
3741                      else
3742                         if Entity (Subtype_Mark (Indic1)) /=
3743                           Entity (Subtype_Mark (Indic2))
3744                         then
3745                            return False;
3746                         end if;
3747
3748                         Elt1 := First (Constraints (Constraint (Indic1)));
3749                         Elt2 := First (Constraints (Constraint (Indic2)));
3750
3751                         while Present (Elt1) and then Present (Elt2) loop
3752                            if not FCE (Elt1, Elt2) then
3753                               return False;
3754                            end if;
3755
3756                            Next (Elt1);
3757                            Next (Elt2);
3758                         end loop;
3759
3760                         return True;
3761                      end if;
3762                   end;
3763                end if;
3764
3765             when N_Attribute_Reference =>
3766                return
3767                  Attribute_Name (E1) = Attribute_Name (E2)
3768                    and then FCL (Expressions (E1), Expressions (E2));
3769
3770             when N_Binary_Op =>
3771                return
3772                  Entity (E1) = Entity (E2)
3773                    and then FCE (Left_Opnd  (E1), Left_Opnd  (E2))
3774                    and then FCE (Right_Opnd (E1), Right_Opnd (E2));
3775
3776             when N_And_Then | N_Or_Else | N_In | N_Not_In =>
3777                return
3778                  FCE (Left_Opnd  (E1), Left_Opnd  (E2))
3779                    and then
3780                  FCE (Right_Opnd (E1), Right_Opnd (E2));
3781
3782             when N_Character_Literal =>
3783                return
3784                  Char_Literal_Value (E1) = Char_Literal_Value (E2);
3785
3786             when N_Component_Association =>
3787                return
3788                  FCL (Choices (E1), Choices (E2))
3789                    and then FCE (Expression (E1), Expression (E2));
3790
3791             when N_Conditional_Expression =>
3792                return
3793                  FCL (Expressions (E1), Expressions (E2));
3794
3795             when N_Explicit_Dereference =>
3796                return
3797                  FCE (Prefix (E1), Prefix (E2));
3798
3799             when N_Extension_Aggregate =>
3800                return
3801                  FCL (Expressions (E1), Expressions (E2))
3802                    and then Null_Record_Present (E1) =
3803                             Null_Record_Present (E2)
3804                    and then FCL (Component_Associations (E1),
3805                                Component_Associations (E2));
3806
3807             when N_Function_Call =>
3808                return
3809                  FCE (Name (E1), Name (E2))
3810                    and then FCL (Parameter_Associations (E1),
3811                                  Parameter_Associations (E2));
3812
3813             when N_Indexed_Component =>
3814                return
3815                  FCE (Prefix (E1), Prefix (E2))
3816                    and then FCL (Expressions (E1), Expressions (E2));
3817
3818             when N_Integer_Literal =>
3819                return (Intval (E1) = Intval (E2));
3820
3821             when N_Null =>
3822                return True;
3823
3824             when N_Operator_Symbol =>
3825                return
3826                  Chars (E1) = Chars (E2);
3827
3828             when N_Others_Choice =>
3829                return True;
3830
3831             when N_Parameter_Association =>
3832                return
3833                  Chars (Selector_Name (E1))  = Chars (Selector_Name (E2))
3834                    and then FCE (Explicit_Actual_Parameter (E1),
3835                                  Explicit_Actual_Parameter (E2));
3836
3837             when N_Qualified_Expression =>
3838                return
3839                  FCE (Subtype_Mark (E1), Subtype_Mark (E2))
3840                    and then FCE (Expression (E1), Expression (E2));
3841
3842             when N_Range =>
3843                return
3844                  FCE (Low_Bound (E1), Low_Bound (E2))
3845                    and then FCE (High_Bound (E1), High_Bound (E2));
3846
3847             when N_Real_Literal =>
3848                return (Realval (E1) = Realval (E2));
3849
3850             when N_Selected_Component =>
3851                return
3852                  FCE (Prefix (E1), Prefix (E2))
3853                    and then FCE (Selector_Name (E1), Selector_Name (E2));
3854
3855             when N_Slice =>
3856                return
3857                  FCE (Prefix (E1), Prefix (E2))
3858                    and then FCE (Discrete_Range (E1), Discrete_Range (E2));
3859
3860             when N_String_Literal =>
3861                declare
3862                   S1 : constant String_Id := Strval (E1);
3863                   S2 : constant String_Id := Strval (E2);
3864                   L1 : constant Nat       := String_Length (S1);
3865                   L2 : constant Nat       := String_Length (S2);
3866
3867                begin
3868                   if L1 /= L2 then
3869                      return False;
3870
3871                   else
3872                      for J in 1 .. L1 loop
3873                         if Get_String_Char (S1, J) /=
3874                            Get_String_Char (S2, J)
3875                         then
3876                            return False;
3877                         end if;
3878                      end loop;
3879
3880                      return True;
3881                   end if;
3882                end;
3883
3884             when N_Type_Conversion =>
3885                return
3886                  FCE (Subtype_Mark (E1), Subtype_Mark (E2))
3887                    and then FCE (Expression (E1), Expression (E2));
3888
3889             when N_Unary_Op =>
3890                return
3891                  Entity (E1) = Entity (E2)
3892                    and then FCE (Right_Opnd (E1), Right_Opnd (E2));
3893
3894             when N_Unchecked_Type_Conversion =>
3895                return
3896                  FCE (Subtype_Mark (E1), Subtype_Mark (E2))
3897                    and then FCE (Expression (E1), Expression (E2));
3898
3899             --  All other node types cannot appear in this context. Strictly
3900             --  we should raise a fatal internal error. Instead we just ignore
3901             --  the nodes. This means that if anyone makes a mistake in the
3902             --  expander and mucks an expression tree irretrievably, the
3903             --  result will be a failure to detect a (probably very obscure)
3904             --  case of non-conformance, which is better than bombing on some
3905             --  case where two expressions do in fact conform.
3906
3907             when others =>
3908                return True;
3909
3910          end case;
3911       end if;
3912    end Fully_Conformant_Expressions;
3913
3914    ----------------------------------------
3915    -- Fully_Conformant_Discrete_Subtypes --
3916    ----------------------------------------
3917
3918    function Fully_Conformant_Discrete_Subtypes
3919      (Given_S1 : Node_Id;
3920       Given_S2 : Node_Id) return Boolean
3921    is
3922       S1 : constant Node_Id := Original_Node (Given_S1);
3923       S2 : constant Node_Id := Original_Node (Given_S2);
3924
3925       function Conforming_Bounds (B1, B2 : Node_Id) return Boolean;
3926       --  Special-case for a bound given by a discriminant, which in the
3927       --  body is replaced with the discriminal of the enclosing type.
3928
3929       function Conforming_Ranges (R1, R2 : Node_Id) return Boolean;
3930       --  Check both bounds.
3931
3932       function Conforming_Bounds (B1, B2 : Node_Id) return Boolean is
3933       begin
3934          if Is_Entity_Name (B1)
3935            and then Is_Entity_Name (B2)
3936            and then Ekind (Entity (B1)) = E_Discriminant
3937          then
3938             return Chars (B1) = Chars (B2);
3939
3940          else
3941             return Fully_Conformant_Expressions (B1, B2);
3942          end if;
3943       end Conforming_Bounds;
3944
3945       function Conforming_Ranges (R1, R2 : Node_Id) return Boolean is
3946       begin
3947          return
3948            Conforming_Bounds (Low_Bound (R1), Low_Bound (R2))
3949              and then
3950            Conforming_Bounds (High_Bound (R1), High_Bound (R2));
3951       end Conforming_Ranges;
3952
3953    --  Start of processing for Fully_Conformant_Discrete_Subtypes
3954
3955    begin
3956       if Nkind (S1) /= Nkind (S2) then
3957          return False;
3958
3959       elsif Is_Entity_Name (S1) then
3960          return Entity (S1) = Entity (S2);
3961
3962       elsif Nkind (S1) = N_Range then
3963          return Conforming_Ranges (S1, S2);
3964
3965       elsif Nkind (S1) = N_Subtype_Indication then
3966          return
3967             Entity (Subtype_Mark (S1)) = Entity (Subtype_Mark (S2))
3968               and then
3969             Conforming_Ranges
3970               (Range_Expression (Constraint (S1)),
3971                Range_Expression (Constraint (S2)));
3972       else
3973          return True;
3974       end if;
3975    end Fully_Conformant_Discrete_Subtypes;
3976
3977    --------------------
3978    -- Install_Entity --
3979    --------------------
3980
3981    procedure Install_Entity (E : Entity_Id) is
3982       Prev : constant Entity_Id := Current_Entity (E);
3983
3984    begin
3985       Set_Is_Immediately_Visible (E);
3986       Set_Current_Entity (E);
3987       Set_Homonym (E, Prev);
3988    end Install_Entity;
3989
3990    ---------------------
3991    -- Install_Formals --
3992    ---------------------
3993
3994    procedure Install_Formals (Id : Entity_Id) is
3995       F : Entity_Id;
3996
3997    begin
3998       F := First_Formal (Id);
3999
4000       while Present (F) loop
4001          Install_Entity (F);
4002          Next_Formal (F);
4003       end loop;
4004    end Install_Formals;
4005
4006    ---------------------------------
4007    -- Is_Non_Overriding_Operation --
4008    ---------------------------------
4009
4010    function Is_Non_Overriding_Operation
4011      (Prev_E : Entity_Id;
4012       New_E  : Entity_Id) return Boolean
4013    is
4014       Formal : Entity_Id;
4015       F_Typ  : Entity_Id;
4016       G_Typ  : Entity_Id := Empty;
4017
4018       function Get_Generic_Parent_Type (F_Typ : Entity_Id) return Entity_Id;
4019       --  If F_Type is a derived type associated with a generic actual
4020       --  subtype, then return its Generic_Parent_Type attribute, else
4021       --  return Empty.
4022
4023       function Types_Correspond
4024         (P_Type : Entity_Id;
4025          N_Type : Entity_Id) return Boolean;
4026       --  Returns true if and only if the types (or designated types
4027       --  in the case of anonymous access types) are the same or N_Type
4028       --  is derived directly or indirectly from P_Type.
4029
4030       -----------------------------
4031       -- Get_Generic_Parent_Type --
4032       -----------------------------
4033
4034       function Get_Generic_Parent_Type (F_Typ : Entity_Id) return Entity_Id is
4035          G_Typ : Entity_Id;
4036          Indic : Node_Id;
4037
4038       begin
4039          if Is_Derived_Type (F_Typ)
4040            and then Nkind (Parent (F_Typ)) = N_Full_Type_Declaration
4041          then
4042             --  The tree must be traversed to determine the parent
4043             --  subtype in the generic unit, which unfortunately isn't
4044             --  always available via semantic attributes. ???
4045             --  (Note: The use of Original_Node is needed for cases
4046             --  where a full derived type has been rewritten.)
4047
4048             Indic := Subtype_Indication
4049                        (Type_Definition (Original_Node (Parent (F_Typ))));
4050
4051             if Nkind (Indic) = N_Subtype_Indication then
4052                G_Typ := Entity (Subtype_Mark (Indic));
4053             else
4054                G_Typ := Entity (Indic);
4055             end if;
4056
4057             if Nkind (Parent (G_Typ)) = N_Subtype_Declaration
4058               and then Present (Generic_Parent_Type (Parent (G_Typ)))
4059             then
4060                return Generic_Parent_Type (Parent (G_Typ));
4061             end if;
4062          end if;
4063
4064          return Empty;
4065       end Get_Generic_Parent_Type;
4066
4067       ----------------------
4068       -- Types_Correspond --
4069       ----------------------
4070
4071       function Types_Correspond
4072         (P_Type : Entity_Id;
4073          N_Type : Entity_Id) return Boolean
4074       is
4075          Prev_Type : Entity_Id := Base_Type (P_Type);
4076          New_Type  : Entity_Id := Base_Type (N_Type);
4077
4078       begin
4079          if Ekind (Prev_Type) = E_Anonymous_Access_Type then
4080             Prev_Type := Designated_Type (Prev_Type);
4081          end if;
4082
4083          if Ekind (New_Type) = E_Anonymous_Access_Type then
4084             New_Type := Designated_Type (New_Type);
4085          end if;
4086
4087          if Prev_Type = New_Type then
4088             return True;
4089
4090          elsif not Is_Class_Wide_Type (New_Type) then
4091             while Etype (New_Type) /= New_Type loop
4092                New_Type := Etype (New_Type);
4093                if New_Type = Prev_Type then
4094                   return True;
4095                end if;
4096             end loop;
4097          end if;
4098          return False;
4099       end Types_Correspond;
4100
4101    --  Start of processing for Is_Non_Overriding_Operation
4102
4103    begin
4104       --  In the case where both operations are implicit derived
4105       --  subprograms then neither overrides the other. This can
4106       --  only occur in certain obscure cases (e.g., derivation
4107       --  from homographs created in a generic instantiation).
4108
4109       if Present (Alias (Prev_E)) and then Present (Alias (New_E)) then
4110          return True;
4111
4112       elsif Ekind (Current_Scope) = E_Package
4113         and then Is_Generic_Instance (Current_Scope)
4114         and then In_Private_Part (Current_Scope)
4115         and then Comes_From_Source (New_E)
4116       then
4117          --  We examine the formals and result subtype of the inherited
4118          --  operation, to determine whether their type is derived from
4119          --  (the instance of) a generic type.
4120
4121          Formal := First_Formal (Prev_E);
4122
4123          while Present (Formal) loop
4124             F_Typ := Base_Type (Etype (Formal));
4125
4126             if Ekind (F_Typ) = E_Anonymous_Access_Type then
4127                F_Typ := Designated_Type (F_Typ);
4128             end if;
4129
4130             G_Typ := Get_Generic_Parent_Type (F_Typ);
4131
4132             Next_Formal (Formal);
4133          end loop;
4134
4135          if not Present (G_Typ) and then Ekind (Prev_E) = E_Function then
4136             G_Typ := Get_Generic_Parent_Type (Base_Type (Etype (Prev_E)));
4137          end if;
4138
4139          if No (G_Typ) then
4140             return False;
4141          end if;
4142
4143          --  If the generic type is a private type, then the original
4144          --  operation was not overriding in the generic, because there was
4145          --  no primitive operation to override.
4146
4147          if Nkind (Parent (G_Typ)) = N_Formal_Type_Declaration
4148            and then Nkind (Formal_Type_Definition (Parent (G_Typ))) =
4149              N_Formal_Private_Type_Definition
4150          then
4151             return True;
4152
4153          --  The generic parent type is the ancestor of a formal derived
4154          --  type declaration. We need to check whether it has a primitive
4155          --  operation that should be overridden by New_E in the generic.
4156
4157          else
4158             declare
4159                P_Formal : Entity_Id;
4160                N_Formal : Entity_Id;
4161                P_Typ    : Entity_Id;
4162                N_Typ    : Entity_Id;
4163                P_Prim   : Entity_Id;
4164                Prim_Elt : Elmt_Id := First_Elmt (Primitive_Operations (G_Typ));
4165
4166             begin
4167                while Present (Prim_Elt) loop
4168                   P_Prim := Node (Prim_Elt);
4169
4170                   if Chars (P_Prim) = Chars (New_E)
4171                     and then Ekind (P_Prim) = Ekind (New_E)
4172                   then
4173                      P_Formal := First_Formal (P_Prim);
4174                      N_Formal := First_Formal (New_E);
4175                      while Present (P_Formal) and then Present (N_Formal) loop
4176                         P_Typ := Etype (P_Formal);
4177                         N_Typ := Etype (N_Formal);
4178
4179                         if not Types_Correspond (P_Typ, N_Typ) then
4180                            exit;
4181                         end if;
4182
4183                         Next_Entity (P_Formal);
4184                         Next_Entity (N_Formal);
4185                      end loop;
4186
4187                      --  Found a matching primitive operation belonging to
4188                      --  the formal ancestor type, so the new subprogram
4189                      --  is overriding.
4190
4191                      if not Present (P_Formal)
4192                        and then not Present (N_Formal)
4193                        and then (Ekind (New_E) /= E_Function
4194                                   or else
4195                                  Types_Correspond
4196                                    (Etype (P_Prim), Etype (New_E)))
4197                      then
4198                         return False;
4199                      end if;
4200                   end if;
4201
4202                   Next_Elmt (Prim_Elt);
4203                end loop;
4204
4205                --  If no match found, then the new subprogram does
4206                --  not override in the generic (nor in the instance).
4207
4208                return True;
4209             end;
4210          end if;
4211       else
4212          return False;
4213       end if;
4214    end Is_Non_Overriding_Operation;
4215
4216    ------------------------------
4217    -- Make_Inequality_Operator --
4218    ------------------------------
4219
4220    --  S is the defining identifier of an equality operator. We build a
4221    --  subprogram declaration with the right signature. This operation is
4222    --  intrinsic, because it is always expanded as the negation of the
4223    --  call to the equality function.
4224
4225    procedure Make_Inequality_Operator (S : Entity_Id) is
4226       Loc     : constant Source_Ptr := Sloc (S);
4227       Decl    : Node_Id;
4228       Formals : List_Id;
4229       Op_Name : Entity_Id;
4230
4231       A : Entity_Id;
4232       B : Entity_Id;
4233
4234    begin
4235       --  Check that equality was properly defined.
4236
4237       if  No (Next_Formal (First_Formal (S))) then
4238          return;
4239       end if;
4240
4241       A := Make_Defining_Identifier (Loc, Chars (First_Formal (S)));
4242       B := Make_Defining_Identifier (Loc,
4243              Chars (Next_Formal (First_Formal (S))));
4244
4245       Op_Name := Make_Defining_Operator_Symbol (Loc, Name_Op_Ne);
4246
4247       Formals := New_List (
4248         Make_Parameter_Specification (Loc,
4249           Defining_Identifier => A,
4250           Parameter_Type =>
4251             New_Reference_To (Etype (First_Formal (S)), Loc)),
4252
4253         Make_Parameter_Specification (Loc,
4254           Defining_Identifier => B,
4255           Parameter_Type =>
4256             New_Reference_To (Etype (Next_Formal (First_Formal (S))), Loc)));
4257
4258       Decl :=
4259         Make_Subprogram_Declaration (Loc,
4260           Specification =>
4261             Make_Function_Specification (Loc,
4262               Defining_Unit_Name => Op_Name,
4263               Parameter_Specifications => Formals,
4264               Subtype_Mark => New_Reference_To (Standard_Boolean, Loc)));
4265
4266       --  Insert inequality right after equality if it is explicit or after
4267       --  the derived type when implicit. These entities are created only
4268       --  for visibility purposes, and eventually replaced in the course of
4269       --  expansion, so they do not need to be attached to the tree and seen
4270       --  by the back-end. Keeping them internal also avoids spurious freezing
4271       --  problems. The parent field is set simply to make analysis safe.
4272
4273       if No (Alias (S)) then
4274          Set_Parent (Decl, Parent (Unit_Declaration_Node (S)));
4275       else
4276          Set_Parent (Decl, Parent (Parent (Etype (First_Formal (S)))));
4277       end if;
4278
4279       Mark_Rewrite_Insertion (Decl);
4280       Set_Is_Intrinsic_Subprogram (Op_Name);
4281       Analyze (Decl);
4282       Set_Has_Completion (Op_Name);
4283       Set_Corresponding_Equality (Op_Name, S);
4284       Set_Is_Abstract (Op_Name, Is_Abstract (S));
4285
4286    end Make_Inequality_Operator;
4287
4288    ----------------------
4289    -- May_Need_Actuals --
4290    ----------------------
4291
4292    procedure May_Need_Actuals (Fun : Entity_Id) is
4293       F : Entity_Id;
4294       B : Boolean;
4295
4296    begin
4297       F := First_Formal (Fun);
4298       B := True;
4299
4300       while Present (F) loop
4301          if No (Default_Value (F)) then
4302             B := False;
4303             exit;
4304          end if;
4305
4306          Next_Formal (F);
4307       end loop;
4308
4309       Set_Needs_No_Actuals (Fun, B);
4310    end May_Need_Actuals;
4311
4312    ---------------------
4313    -- Mode_Conformant --
4314    ---------------------
4315
4316    function Mode_Conformant (New_Id, Old_Id : Entity_Id) return Boolean is
4317       Result : Boolean;
4318
4319    begin
4320       Check_Conformance (New_Id, Old_Id, Mode_Conformant, False, Result);
4321       return Result;
4322    end Mode_Conformant;
4323
4324    ---------------------------
4325    -- New_Overloaded_Entity --
4326    ---------------------------
4327
4328    procedure New_Overloaded_Entity
4329      (S            : Entity_Id;
4330       Derived_Type : Entity_Id := Empty)
4331    is
4332       E : Entity_Id;
4333       --  Entity that S overrides
4334
4335       Prev_Vis : Entity_Id := Empty;
4336       --  Needs comment ???
4337
4338       function Is_Private_Declaration (E : Entity_Id) return Boolean;
4339       --  Check that E is declared in the private part of the current package,
4340       --  or in the package body, where it may hide a previous declaration.
4341       --  We can't use In_Private_Part by itself because this flag is also
4342       --  set when freezing entities, so we must examine the place of the
4343       --  declaration in the tree, and recognize wrapper packages as well.
4344
4345       procedure Maybe_Primitive_Operation (Overriding : Boolean := False);
4346       --  If the subprogram being analyzed is a primitive operation of
4347       --  the type of one of its formals, set the corresponding flag.
4348
4349       ----------------------------
4350       -- Is_Private_Declaration --
4351       ----------------------------
4352
4353       function Is_Private_Declaration (E : Entity_Id) return Boolean is
4354          Priv_Decls : List_Id;
4355          Decl       : constant Node_Id := Unit_Declaration_Node (E);
4356
4357       begin
4358          if Is_Package (Current_Scope)
4359            and then In_Private_Part (Current_Scope)
4360          then
4361             Priv_Decls :=
4362               Private_Declarations (
4363                 Specification (Unit_Declaration_Node (Current_Scope)));
4364
4365             return In_Package_Body (Current_Scope)
4366               or else List_Containing (Decl) = Priv_Decls
4367               or else (Nkind (Parent (Decl)) = N_Package_Specification
4368                          and then not Is_Compilation_Unit (
4369                            Defining_Entity (Parent (Decl)))
4370                          and then List_Containing (Parent (Parent (Decl)))
4371                            = Priv_Decls);
4372          else
4373             return False;
4374          end if;
4375       end Is_Private_Declaration;
4376
4377       -------------------------------
4378       -- Maybe_Primitive_Operation --
4379       -------------------------------
4380
4381       procedure Maybe_Primitive_Operation (Overriding : Boolean := False) is
4382          Formal : Entity_Id;
4383          F_Typ  : Entity_Id;
4384          B_Typ  : Entity_Id;
4385
4386          function Visible_Part_Type (T : Entity_Id) return Boolean;
4387          --  Returns true if T is declared in the visible part of
4388          --  the current package scope; otherwise returns false.
4389          --  Assumes that T is declared in a package.
4390
4391          procedure Check_Private_Overriding (T : Entity_Id);
4392          --  Checks that if a primitive abstract subprogram of a visible
4393          --  abstract type is declared in a private part, then it must
4394          --  override an abstract subprogram declared in the visible part.
4395          --  Also checks that if a primitive function with a controlling
4396          --  result is declared in a private part, then it must override
4397          --  a function declared in the visible part.
4398
4399          ------------------------------
4400          -- Check_Private_Overriding --
4401          ------------------------------
4402
4403          procedure Check_Private_Overriding (T : Entity_Id) is
4404          begin
4405             if Ekind (Current_Scope) = E_Package
4406               and then In_Private_Part (Current_Scope)
4407               and then Visible_Part_Type (T)
4408               and then not In_Instance
4409             then
4410                if Is_Abstract (T)
4411                  and then Is_Abstract (S)
4412                  and then (not Overriding or else not Is_Abstract (E))
4413                then
4414                   Error_Msg_N ("abstract subprograms must be visible "
4415                                 & "('R'M 3.9.3(10))!", S);
4416
4417                elsif Ekind (S) = E_Function
4418                  and then Is_Tagged_Type (T)
4419                  and then T = Base_Type (Etype (S))
4420                  and then not Overriding
4421                then
4422                   Error_Msg_N
4423                     ("private function with tagged result must"
4424                      & " override visible-part function", S);
4425                   Error_Msg_N
4426                     ("\move subprogram to the visible part"
4427                      & " ('R'M 3.9.3(10))", S);
4428                end if;
4429             end if;
4430          end Check_Private_Overriding;
4431
4432          -----------------------
4433          -- Visible_Part_Type --
4434          -----------------------
4435
4436          function Visible_Part_Type (T : Entity_Id) return Boolean is
4437             P : constant Node_Id := Unit_Declaration_Node (Scope (T));
4438             N : Node_Id;
4439
4440          begin
4441             --  If the entity is a private type, then it must be
4442             --  declared in a visible part.
4443
4444             if Ekind (T) in Private_Kind then
4445                return True;
4446             end if;
4447
4448             --  Otherwise, we traverse the visible part looking for its
4449             --  corresponding declaration. We cannot use the declaration
4450             --  node directly because in the private part the entity of a
4451             --  private type is the one in the full view, which does not
4452             --  indicate that it is the completion of something visible.
4453
4454             N := First (Visible_Declarations (Specification (P)));
4455             while Present (N) loop
4456                if Nkind (N) = N_Full_Type_Declaration
4457                  and then Present (Defining_Identifier (N))
4458                  and then T = Defining_Identifier (N)
4459                then
4460                   return True;
4461
4462                elsif (Nkind (N) = N_Private_Type_Declaration
4463                        or else
4464                       Nkind (N) = N_Private_Extension_Declaration)
4465                  and then Present (Defining_Identifier (N))
4466                  and then T = Full_View (Defining_Identifier (N))
4467                then
4468                   return True;
4469                end if;
4470
4471                Next (N);
4472             end loop;
4473
4474             return False;
4475          end Visible_Part_Type;
4476
4477       --  Start of processing for Maybe_Primitive_Operation
4478
4479       begin
4480          if not Comes_From_Source (S) then
4481             null;
4482
4483          --  If the subprogram is at library level, it is not a
4484          --  primitive operation.
4485
4486          elsif Current_Scope = Standard_Standard then
4487             null;
4488
4489          elsif (Ekind (Current_Scope) = E_Package
4490                  and then not In_Package_Body (Current_Scope))
4491            or else Overriding
4492          then
4493             --  For function, check return type
4494
4495             if Ekind (S) = E_Function then
4496                B_Typ := Base_Type (Etype (S));
4497
4498                if Scope (B_Typ) = Current_Scope then
4499                   Set_Has_Primitive_Operations (B_Typ);
4500                   Check_Private_Overriding (B_Typ);
4501                end if;
4502             end if;
4503
4504             --  For all subprograms, check formals
4505
4506             Formal := First_Formal (S);
4507             while Present (Formal) loop
4508                if Ekind (Etype (Formal)) = E_Anonymous_Access_Type then
4509                   F_Typ := Designated_Type (Etype (Formal));
4510                else
4511                   F_Typ := Etype (Formal);
4512                end if;
4513
4514                B_Typ := Base_Type (F_Typ);
4515
4516                if Scope (B_Typ) = Current_Scope then
4517                   Set_Has_Primitive_Operations (B_Typ);
4518                   Check_Private_Overriding (B_Typ);
4519                end if;
4520
4521                Next_Formal (Formal);
4522             end loop;
4523          end if;
4524       end Maybe_Primitive_Operation;
4525
4526    --  Start of processing for New_Overloaded_Entity
4527
4528    begin
4529       --  We need to look for an entity that S may override. This must be a
4530       --  homonym in the current scope, so we look for the first homonym of
4531       --  S in the current scope as the starting point for the search.
4532
4533       E := Current_Entity_In_Scope (S);
4534
4535       --  If there is no homonym then this is definitely not overriding
4536
4537       if No (E) then
4538          Enter_Overloaded_Entity (S);
4539          Check_Dispatching_Operation (S, Empty);
4540          Maybe_Primitive_Operation;
4541
4542       --  If there is a homonym that is not overloadable, then we have an
4543       --  error, except for the special cases checked explicitly below.
4544
4545       elsif not Is_Overloadable (E) then
4546
4547          --  Check for spurious conflict produced by a subprogram that has the
4548          --  same name as that of the enclosing generic package. The conflict
4549          --  occurs within an instance, between the subprogram and the renaming
4550          --  declaration for the package. After the subprogram, the package
4551          --  renaming declaration becomes hidden.
4552
4553          if Ekind (E) = E_Package
4554            and then Present (Renamed_Object (E))
4555            and then Renamed_Object (E) = Current_Scope
4556            and then Nkind (Parent (Renamed_Object (E))) =
4557                                                      N_Package_Specification
4558            and then Present (Generic_Parent (Parent (Renamed_Object (E))))
4559          then
4560             Set_Is_Hidden (E);
4561             Set_Is_Immediately_Visible (E, False);
4562             Enter_Overloaded_Entity (S);
4563             Set_Homonym (S, Homonym (E));
4564             Check_Dispatching_Operation (S, Empty);
4565
4566          --  If the subprogram is implicit it is hidden by the previous
4567          --  declaration. However if it is dispatching, it must appear in
4568          --  the dispatch table anyway, because it can be dispatched to
4569          --  even if it cannot be called directly.
4570
4571          elsif Present (Alias (S))
4572            and then not Comes_From_Source (S)
4573          then
4574             Set_Scope (S, Current_Scope);
4575
4576             if Is_Dispatching_Operation (Alias (S)) then
4577                Check_Dispatching_Operation (S, Empty);
4578             end if;
4579
4580             return;
4581
4582          else
4583             Error_Msg_Sloc := Sloc (E);
4584             Error_Msg_N ("& conflicts with declaration#", S);
4585
4586             --  Useful additional warning
4587
4588             if Is_Generic_Unit (E) then
4589                Error_Msg_N ("\previous generic unit cannot be overloaded", S);
4590             end if;
4591
4592             return;
4593          end if;
4594
4595       --  E exists and is overloadable
4596
4597       else
4598          --  Loop through E and its homonyms to determine if any of them
4599          --  is the candidate for overriding by S.
4600
4601          while Present (E) loop
4602
4603             --  Definitely not interesting if not in the current scope
4604
4605             if Scope (E) /= Current_Scope then
4606                null;
4607
4608             --  Check if we have type conformance
4609
4610             elsif Type_Conformant (E, S) then
4611
4612                --  If the old and new entities have the same profile and
4613                --  one is not the body of the other, then this is an error,
4614                --  unless one of them is implicitly declared.
4615
4616                --  There are some cases when both can be implicit, for example
4617                --  when both a literal and a function that overrides it are
4618                --  inherited in a derivation, or when an inhertited operation
4619                --  of a tagged full type overrides the ineherited operation of
4620                --  a private extension. Ada 83 had a special rule for the
4621                --  the literal case. In Ada95, the later implicit operation
4622                --  hides the former, and the literal is always the former.
4623                --  In the odd case where both are derived operations declared
4624                --  at the same point, both operations should be declared,
4625                --  and in that case we bypass the following test and proceed
4626                --  to the next part (this can only occur for certain obscure
4627                --  cases involving homographs in instances and can't occur for
4628                --  dispatching operations ???). Note that the following
4629                --  condition is less than clear. For example, it's not at
4630                --  all clear why there's a test for E_Entry here. ???
4631
4632                if Present (Alias (S))
4633                  and then (No (Alias (E))
4634                             or else Comes_From_Source (E)
4635                             or else Is_Dispatching_Operation (E))
4636                  and then
4637                    (Ekind (E) = E_Entry
4638                      or else Ekind (E) /= E_Enumeration_Literal)
4639                then
4640                   --  When an derived operation is overloaded it may be due
4641                   --  to the fact that the full view of a private extension
4642                   --  re-inherits. It has to be dealt with.
4643
4644                   if Is_Package (Current_Scope)
4645                     and then In_Private_Part (Current_Scope)
4646                   then
4647                      Check_Operation_From_Private_View (S, E);
4648                   end if;
4649
4650                   --  In any case the implicit operation remains hidden by
4651                   --  the existing declaration, which is overriding.
4652
4653                   Set_Is_Overriding_Operation (E);
4654                   return;
4655
4656                   --  Within an instance, the renaming declarations for
4657                   --  actual subprograms may become ambiguous, but they do
4658                   --  not hide each other.
4659
4660                elsif Ekind (E) /= E_Entry
4661                  and then not Comes_From_Source (E)
4662                  and then not Is_Generic_Instance (E)
4663                  and then (Present (Alias (E))
4664                             or else Is_Intrinsic_Subprogram (E))
4665                  and then (not In_Instance
4666                             or else No (Parent (E))
4667                             or else Nkind (Unit_Declaration_Node (E)) /=
4668                                N_Subprogram_Renaming_Declaration)
4669                then
4670                   --  A subprogram child unit is not allowed to override
4671                   --  an inherited subprogram (10.1.1(20)).
4672
4673                   if Is_Child_Unit (S) then
4674                      Error_Msg_N
4675                        ("child unit overrides inherited subprogram in parent",
4676                         S);
4677                      return;
4678                   end if;
4679
4680                   if Is_Non_Overriding_Operation (E, S) then
4681                      Enter_Overloaded_Entity (S);
4682                      if not Present (Derived_Type)
4683                        or else Is_Tagged_Type (Derived_Type)
4684                      then
4685                         Check_Dispatching_Operation (S, Empty);
4686                      end if;
4687
4688                      return;
4689                   end if;
4690
4691                   --  E is a derived operation or an internal operator which
4692                   --  is being overridden. Remove E from further visibility.
4693                   --  Furthermore, if E is a dispatching operation, it must be
4694                   --  replaced in the list of primitive operations of its type
4695                   --  (see Override_Dispatching_Operation).
4696
4697                   declare
4698                      Prev : Entity_Id;
4699
4700                   begin
4701                      Prev := First_Entity (Current_Scope);
4702
4703                      while Present (Prev)
4704                        and then Next_Entity (Prev) /= E
4705                      loop
4706                         Next_Entity (Prev);
4707                      end loop;
4708
4709                      --  It is possible for E to be in the current scope and
4710                      --  yet not in the entity chain. This can only occur in a
4711                      --  generic context where E is an implicit concatenation
4712                      --  in the formal part, because in a generic body the
4713                      --  entity chain starts with the formals.
4714
4715                      pragma Assert
4716                        (Present (Prev) or else Chars (E) = Name_Op_Concat);
4717
4718                      --  E must be removed both from the entity_list of the
4719                      --  current scope, and from the visibility chain
4720
4721                      if Debug_Flag_E then
4722                         Write_Str ("Override implicit operation ");
4723                         Write_Int (Int (E));
4724                         Write_Eol;
4725                      end if;
4726
4727                      --  If E is a predefined concatenation, it stands for four
4728                      --  different operations. As a result, a single explicit
4729                      --  declaration does not hide it. In a possible ambiguous
4730                      --  situation, Disambiguate chooses the user-defined op,
4731                      --  so it is correct to retain the previous internal one.
4732
4733                      if Chars (E) /= Name_Op_Concat
4734                        or else Ekind (E) /= E_Operator
4735                      then
4736                         --  For nondispatching derived operations that are
4737                         --  overridden by a subprogram declared in the private
4738                         --  part of a package, we retain the derived subprogram
4739                         --  but mark it as not immediately visible. If the
4740                         --  derived operation was declared in the visible part
4741                         --  then this ensures that it will still be visible
4742                         --  outside the package with the proper signature
4743                         --  (calls from outside must also be directed to this
4744                         --  version rather than the overriding one, unlike the
4745                         --  dispatching case). Calls from inside the package
4746                         --  will still resolve to the overriding subprogram
4747                         --  since the derived one is marked as not visible
4748                         --  within the package.
4749
4750                         --  If the private operation is dispatching, we achieve
4751                         --  the overriding by keeping the implicit operation
4752                         --  but setting its alias to be the overring one. In
4753                         --  this fashion the proper body is executed in all
4754                         --  cases, but the original signature is used outside
4755                         --  of the package.
4756
4757                         --  If the overriding is not in the private part, we
4758                         --  remove the implicit operation altogether.
4759
4760                         if Is_Private_Declaration (S) then
4761
4762                            if not Is_Dispatching_Operation (E) then
4763                               Set_Is_Immediately_Visible (E, False);
4764                            else
4765
4766                               --  work done in Override_Dispatching_Operation.
4767
4768                               null;
4769                            end if;
4770
4771                         else
4772                            --  Find predecessor of E in Homonym chain
4773
4774                            if E = Current_Entity (E) then
4775                               Prev_Vis := Empty;
4776                            else
4777                               Prev_Vis := Current_Entity (E);
4778                               while Homonym (Prev_Vis) /= E loop
4779                                  Prev_Vis := Homonym (Prev_Vis);
4780                               end loop;
4781                            end if;
4782
4783                            if Prev_Vis /= Empty then
4784
4785                               --  Skip E in the visibility chain
4786
4787                               Set_Homonym (Prev_Vis, Homonym (E));
4788
4789                            else
4790                               Set_Name_Entity_Id (Chars (E), Homonym (E));
4791                            end if;
4792
4793                            Set_Next_Entity (Prev, Next_Entity (E));
4794
4795                            if No (Next_Entity (Prev)) then
4796                               Set_Last_Entity (Current_Scope, Prev);
4797                            end if;
4798
4799                         end if;
4800                      end if;
4801
4802                      Enter_Overloaded_Entity (S);
4803                      Set_Is_Overriding_Operation (S);
4804
4805                      if Is_Dispatching_Operation (E) then
4806
4807                         --  An overriding dispatching subprogram inherits
4808                         --  the convention of the overridden subprogram
4809                         --  (by AI-117).
4810
4811                         Set_Convention (S, Convention (E));
4812
4813                         Check_Dispatching_Operation (S, E);
4814                      else
4815                         Check_Dispatching_Operation (S, Empty);
4816                      end if;
4817
4818                      Maybe_Primitive_Operation (Overriding => True);
4819                      goto Check_Inequality;
4820                   end;
4821
4822                --  Apparent redeclarations in instances can occur when two
4823                --  formal types get the same actual type. The subprograms in
4824                --  in the instance are legal,  even if not callable from the
4825                --  outside. Calls from within are disambiguated elsewhere.
4826                --  For dispatching operations in the visible part, the usual
4827                --  rules apply, and operations with the same profile are not
4828                --  legal (B830001).
4829
4830                elsif (In_Instance_Visible_Part
4831                        and then not Is_Dispatching_Operation (E))
4832                  or else In_Instance_Not_Visible
4833                then
4834                   null;
4835
4836                --  Here we have a real error (identical profile)
4837
4838                else
4839                   Error_Msg_Sloc := Sloc (E);
4840
4841                   --  Avoid cascaded errors if the entity appears in
4842                   --  subsequent calls.
4843
4844                   Set_Scope (S, Current_Scope);
4845
4846                   Error_Msg_N ("& conflicts with declaration#", S);
4847
4848                   if Is_Generic_Instance (S)
4849                     and then not Has_Completion (E)
4850                   then
4851                      Error_Msg_N
4852                        ("\instantiation cannot provide body for it", S);
4853                   end if;
4854
4855                   return;
4856                end if;
4857
4858             else
4859                null;
4860             end if;
4861
4862             Prev_Vis := E;
4863             E := Homonym (E);
4864          end loop;
4865
4866          --  On exit, we know that S is a new entity
4867
4868          Enter_Overloaded_Entity (S);
4869          Maybe_Primitive_Operation;
4870
4871          --  If S is a derived operation for an untagged type then
4872          --  by definition it's not a dispatching operation (even
4873          --  if the parent operation was dispatching), so we don't
4874          --  call Check_Dispatching_Operation in that case.
4875
4876          if not Present (Derived_Type)
4877            or else Is_Tagged_Type (Derived_Type)
4878          then
4879             Check_Dispatching_Operation (S, Empty);
4880          end if;
4881       end if;
4882
4883       --  If this is a  user-defined equality operator that is not
4884       --  a derived subprogram, create the corresponding inequality.
4885       --  If the operation is dispatching, the expansion is done
4886       --  elsewhere, and we do not create an explicit inequality
4887       --  operation.
4888
4889       <<Check_Inequality>>
4890          if Chars (S) = Name_Op_Eq
4891            and then Etype (S) = Standard_Boolean
4892            and then Present (Parent (S))
4893            and then not Is_Dispatching_Operation (S)
4894          then
4895             Make_Inequality_Operator (S);
4896          end if;
4897    end New_Overloaded_Entity;
4898
4899    ---------------------
4900    -- Process_Formals --
4901    ---------------------
4902
4903    procedure Process_Formals
4904      (T           : List_Id;
4905       Related_Nod : Node_Id)
4906    is
4907       Param_Spec  : Node_Id;
4908       Formal      : Entity_Id;
4909       Formal_Type : Entity_Id;
4910       Default     : Node_Id;
4911       Ptype       : Entity_Id;
4912
4913       function Is_Class_Wide_Default (D : Node_Id) return Boolean;
4914       --  Check whether the default has a class-wide type. After analysis
4915       --  the default has the type of the formal, so we must also check
4916       --  explicitly for an access attribute.
4917
4918       ---------------------------
4919       -- Is_Class_Wide_Default --
4920       ---------------------------
4921
4922       function Is_Class_Wide_Default (D : Node_Id) return Boolean is
4923       begin
4924          return Is_Class_Wide_Type (Designated_Type (Etype (D)))
4925            or else (Nkind (D) =  N_Attribute_Reference
4926                       and then Attribute_Name (D) = Name_Access
4927                       and then Is_Class_Wide_Type (Etype (Prefix (D))));
4928       end Is_Class_Wide_Default;
4929
4930    --  Start of processing for Process_Formals
4931
4932    begin
4933       --  In order to prevent premature use of the formals in the same formal
4934       --  part, the Ekind is left undefined until all default expressions are
4935       --  analyzed. The Ekind is established in a separate loop at the end.
4936
4937       Param_Spec := First (T);
4938
4939       while Present (Param_Spec) loop
4940
4941          Formal := Defining_Identifier (Param_Spec);
4942          Enter_Name (Formal);
4943
4944          --  Case of ordinary parameters
4945
4946          if Nkind (Parameter_Type (Param_Spec)) /= N_Access_Definition then
4947             Find_Type (Parameter_Type (Param_Spec));
4948             Ptype := Parameter_Type (Param_Spec);
4949
4950             if Ptype = Error then
4951                goto Continue;
4952             end if;
4953
4954             Formal_Type := Entity (Ptype);
4955
4956             if Ekind (Formal_Type) = E_Incomplete_Type
4957               or else (Is_Class_Wide_Type (Formal_Type)
4958                         and then Ekind (Root_Type (Formal_Type)) =
4959                                                          E_Incomplete_Type)
4960             then
4961                --  Ada 2005 (AI-50217): Incomplete tagged types that are made
4962                --  visible by a limited with_clause are valid formal types.
4963
4964                if From_With_Type (Formal_Type)
4965                  and then Is_Tagged_Type (Formal_Type)
4966                then
4967                   null;
4968
4969                elsif Nkind (Parent (T)) /= N_Access_Function_Definition
4970                  and then Nkind (Parent (T)) /= N_Access_Procedure_Definition
4971                then
4972                   Error_Msg_N ("invalid use of incomplete type", Param_Spec);
4973                end if;
4974
4975             elsif Ekind (Formal_Type) = E_Void then
4976                Error_Msg_NE ("premature use of&",
4977                  Parameter_Type (Param_Spec), Formal_Type);
4978             end if;
4979
4980             --  Ada 2005 (AI-231): Create and decorate an internal subtype
4981             --  declaration corresponding to the null-excluding type of the
4982             --  formal in the enclosing scope. In addition, replace the
4983             --  parameter type of the formal to this internal subtype.
4984
4985             if Null_Exclusion_Present (Param_Spec) then
4986                declare
4987                   Loc   : constant Source_Ptr := Sloc (Param_Spec);
4988
4989                   Anon  : constant Entity_Id :=
4990                             Make_Defining_Identifier (Loc,
4991                               Chars => New_Internal_Name ('S'));
4992
4993                   Curr_Scope : constant Scope_Stack_Entry :=
4994                                  Scope_Stack.Table (Scope_Stack.Last);
4995
4996                   Ptype : constant Node_Id := Parameter_Type (Param_Spec);
4997                   Decl  : Node_Id;
4998                   P     : Node_Id := Parent (Parent (Related_Nod));
4999
5000                begin
5001                   Set_Is_Internal (Anon);
5002
5003                   Decl :=
5004                     Make_Subtype_Declaration (Loc,
5005                       Defining_Identifier      => Anon,
5006                         Null_Exclusion_Present => True,
5007                         Subtype_Indication     =>
5008                           New_Occurrence_Of (Etype (Ptype), Loc));
5009
5010                   --  Propagate the null-excluding attribute to the new entity
5011
5012                   if Null_Exclusion_Present (Param_Spec) then
5013                      Set_Null_Exclusion_Present (Param_Spec, False);
5014                      Set_Can_Never_Be_Null (Anon);
5015                   end if;
5016
5017                   Mark_Rewrite_Insertion (Decl);
5018
5019                   --  Insert the new declaration in the nearest enclosing scope
5020
5021                   while not Has_Declarations (P) loop
5022                      P := Parent (P);
5023                   end loop;
5024
5025                   Prepend (Decl, Declarations (P));
5026
5027                   Rewrite (Ptype, New_Occurrence_Of (Anon, Loc));
5028                   Mark_Rewrite_Insertion (Ptype);
5029
5030                   --  Analyze the new declaration in the context of the
5031                   --  enclosing scope
5032
5033                   Scope_Stack.Decrement_Last;
5034                   Analyze (Decl);
5035                   Scope_Stack.Append (Curr_Scope);
5036
5037                   Formal_Type := Anon;
5038                end;
5039             end if;
5040
5041             --  Ada 2005 (AI-231): Static checks
5042
5043             if Null_Exclusion_Present (Param_Spec)
5044               or else Can_Never_Be_Null (Entity (Ptype))
5045             then
5046                Null_Exclusion_Static_Checks (Param_Spec);
5047             end if;
5048
5049          --  An access formal type
5050
5051          else
5052             Formal_Type :=
5053               Access_Definition (Related_Nod, Parameter_Type (Param_Spec));
5054
5055             --  Ada 2005 (AI-254)
5056
5057             declare
5058                AD : constant Node_Id :=
5059                       Access_To_Subprogram_Definition
5060                         (Parameter_Type (Param_Spec));
5061             begin
5062                if Present (AD) and then Protected_Present (AD) then
5063                   Formal_Type :=
5064                     Replace_Anonymous_Access_To_Protected_Subprogram
5065                       (Param_Spec, Formal_Type);
5066                end if;
5067             end;
5068          end if;
5069
5070          Set_Etype (Formal, Formal_Type);
5071          Default := Expression (Param_Spec);
5072
5073          if Present (Default) then
5074             if Out_Present (Param_Spec) then
5075                Error_Msg_N
5076                  ("default initialization only allowed for IN parameters",
5077                   Param_Spec);
5078             end if;
5079
5080             --  Do the special preanalysis of the expression (see section on
5081             --  "Handling of Default Expressions" in the spec of package Sem).
5082
5083             Analyze_Per_Use_Expression (Default, Formal_Type);
5084
5085             --  Check that the designated type of an access parameter's
5086             --  default is not a class-wide type unless the parameter's
5087             --  designated type is also class-wide.
5088
5089             if Ekind (Formal_Type) = E_Anonymous_Access_Type
5090               and then Is_Class_Wide_Default (Default)
5091               and then not Is_Class_Wide_Type (Designated_Type (Formal_Type))
5092             then
5093                Error_Msg_N
5094                  ("access to class-wide expression not allowed here", Default);
5095             end if;
5096          end if;
5097
5098       <<Continue>>
5099          Next (Param_Spec);
5100       end loop;
5101
5102       --  Now set the kind (mode) of each formal
5103
5104       Param_Spec := First (T);
5105
5106       while Present (Param_Spec) loop
5107          Formal := Defining_Identifier (Param_Spec);
5108          Set_Formal_Mode (Formal);
5109
5110          if Ekind (Formal) = E_In_Parameter then
5111             Set_Default_Value (Formal, Expression (Param_Spec));
5112
5113             if Present (Expression (Param_Spec)) then
5114                Default :=  Expression (Param_Spec);
5115
5116                if Is_Scalar_Type (Etype (Default)) then
5117                   if Nkind
5118                        (Parameter_Type (Param_Spec)) /= N_Access_Definition
5119                   then
5120                      Formal_Type := Entity (Parameter_Type (Param_Spec));
5121
5122                   else
5123                      Formal_Type := Access_Definition
5124                        (Related_Nod, Parameter_Type (Param_Spec));
5125                   end if;
5126
5127                   Apply_Scalar_Range_Check (Default, Formal_Type);
5128                end if;
5129             end if;
5130          end if;
5131
5132          Next (Param_Spec);
5133       end loop;
5134
5135    end Process_Formals;
5136
5137    ----------------------------
5138    -- Reference_Body_Formals --
5139    ----------------------------
5140
5141    procedure Reference_Body_Formals (Spec : Entity_Id; Bod : Entity_Id) is
5142       Fs : Entity_Id;
5143       Fb : Entity_Id;
5144
5145    begin
5146       if Error_Posted (Spec) then
5147          return;
5148       end if;
5149
5150       Fs := First_Formal (Spec);
5151       Fb := First_Formal (Bod);
5152
5153       while Present (Fs) loop
5154          Generate_Reference (Fs, Fb, 'b');
5155
5156          if Style_Check then
5157             Style.Check_Identifier (Fb, Fs);
5158          end if;
5159
5160          Set_Spec_Entity (Fb, Fs);
5161          Set_Referenced (Fs, False);
5162          Next_Formal (Fs);
5163          Next_Formal (Fb);
5164       end loop;
5165    end Reference_Body_Formals;
5166
5167    -------------------------
5168    -- Set_Actual_Subtypes --
5169    -------------------------
5170
5171    procedure Set_Actual_Subtypes (N : Node_Id; Subp : Entity_Id) is
5172       Loc            : constant Source_Ptr := Sloc (N);
5173       Decl           : Node_Id;
5174       Formal         : Entity_Id;
5175       T              : Entity_Id;
5176       First_Stmt     : Node_Id := Empty;
5177       AS_Needed      : Boolean;
5178
5179    begin
5180       --  If this is an emtpy initialization procedure, no need to create
5181       --  actual subtypes (small optimization).
5182
5183       if Ekind (Subp) = E_Procedure
5184         and then Is_Null_Init_Proc (Subp)
5185       then
5186          return;
5187       end if;
5188
5189       Formal := First_Formal (Subp);
5190       while Present (Formal) loop
5191          T := Etype (Formal);
5192
5193          --  We never need an actual subtype for a constrained formal.
5194
5195          if Is_Constrained (T) then
5196             AS_Needed := False;
5197
5198          --  If we have unknown discriminants, then we do not need an
5199          --  actual subtype, or more accurately we cannot figure it out!
5200          --  Note that all class-wide types have unknown discriminants.
5201
5202          elsif Has_Unknown_Discriminants (T) then
5203             AS_Needed := False;
5204
5205          --  At this stage we have an unconstrained type that may need
5206          --  an actual subtype. For sure the actual subtype is needed
5207          --  if we have an unconstrained array type.
5208
5209          elsif Is_Array_Type (T) then
5210             AS_Needed := True;
5211
5212          --  The only other case which needs an actual subtype is an
5213          --  unconstrained record type which is an IN parameter (we
5214          --  cannot generate actual subtypes for the OUT or IN OUT case,
5215          --  since an assignment can change the discriminant values.
5216          --  However we exclude the case of initialization procedures,
5217          --  since discriminants are handled very specially in this context,
5218          --  see the section entitled "Handling of Discriminants" in Einfo.
5219          --  We also exclude the case of Discrim_SO_Functions (functions
5220          --  used in front end layout mode for size/offset values), since
5221          --  in such functions only discriminants are referenced, and not
5222          --  only are such subtypes not needed, but they cannot always
5223          --  be generated, because of order of elaboration issues.
5224
5225          elsif Is_Record_Type (T)
5226            and then Ekind (Formal) = E_In_Parameter
5227            and then Chars (Formal) /= Name_uInit
5228            and then not Is_Discrim_SO_Function (Subp)
5229          then
5230             AS_Needed := True;
5231
5232          --  All other cases do not need an actual subtype
5233
5234          else
5235             AS_Needed := False;
5236          end if;
5237
5238          --  Generate actual subtypes for unconstrained arrays and
5239          --  unconstrained discriminated records.
5240
5241          if AS_Needed then
5242             if Nkind (N) = N_Accept_Statement then
5243
5244                --  If expansion is active, The formal is replaced by a local
5245                --  variable that renames the corresponding entry of the
5246                --  parameter block, and it is this local variable that may
5247                --  require an actual subtype.
5248
5249                if Expander_Active then
5250                   Decl := Build_Actual_Subtype (T, Renamed_Object (Formal));
5251                else
5252                   Decl := Build_Actual_Subtype (T, Formal);
5253                end if;
5254
5255                if Present (Handled_Statement_Sequence (N)) then
5256                   First_Stmt :=
5257                     First (Statements (Handled_Statement_Sequence (N)));
5258                   Prepend (Decl, Statements (Handled_Statement_Sequence (N)));
5259                   Mark_Rewrite_Insertion (Decl);
5260                else
5261                   --  If the accept statement has no body, there will be
5262                   --  no reference to the actuals, so no need to compute
5263                   --  actual subtypes.
5264
5265                   return;
5266                end if;
5267
5268             else
5269                Decl := Build_Actual_Subtype (T, Formal);
5270                Prepend (Decl, Declarations (N));
5271                Mark_Rewrite_Insertion (Decl);
5272             end if;
5273
5274             --  The declaration uses the bounds of an existing object,
5275             --  and therefore needs no constraint checks.
5276
5277             Analyze (Decl, Suppress => All_Checks);
5278
5279             --  We need to freeze manually the generated type when it is
5280             --  inserted anywhere else than in a declarative part.
5281
5282             if Present (First_Stmt) then
5283                Insert_List_Before_And_Analyze (First_Stmt,
5284                  Freeze_Entity (Defining_Identifier (Decl), Loc));
5285             end if;
5286
5287             if Nkind (N) = N_Accept_Statement
5288               and then Expander_Active
5289             then
5290                Set_Actual_Subtype (Renamed_Object (Formal),
5291                  Defining_Identifier (Decl));
5292             else
5293                Set_Actual_Subtype (Formal, Defining_Identifier (Decl));
5294             end if;
5295          end if;
5296
5297          Next_Formal (Formal);
5298       end loop;
5299    end Set_Actual_Subtypes;
5300
5301    ---------------------
5302    -- Set_Formal_Mode --
5303    ---------------------
5304
5305    procedure Set_Formal_Mode (Formal_Id : Entity_Id) is
5306       Spec : constant Node_Id := Parent (Formal_Id);
5307
5308    begin
5309       --  Note: we set Is_Known_Valid for IN parameters and IN OUT parameters
5310       --  since we ensure that corresponding actuals are always valid at the
5311       --  point of the call.
5312
5313       if Out_Present (Spec) then
5314          if Ekind (Scope (Formal_Id)) = E_Function
5315            or else Ekind (Scope (Formal_Id)) = E_Generic_Function
5316          then
5317             Error_Msg_N ("functions can only have IN parameters", Spec);
5318             Set_Ekind (Formal_Id, E_In_Parameter);
5319
5320          elsif In_Present (Spec) then
5321             Set_Ekind (Formal_Id, E_In_Out_Parameter);
5322
5323          else
5324             Set_Ekind               (Formal_Id, E_Out_Parameter);
5325             Set_Never_Set_In_Source (Formal_Id, True);
5326             Set_Is_True_Constant    (Formal_Id, False);
5327             Set_Current_Value       (Formal_Id, Empty);
5328          end if;
5329
5330       else
5331          Set_Ekind (Formal_Id, E_In_Parameter);
5332       end if;
5333
5334       --  Set Is_Known_Non_Null for access parameters since the language
5335       --  guarantees that access parameters are always non-null. We also
5336       --  set Can_Never_Be_Null, since there is no way to change the value.
5337
5338       if Nkind (Parameter_Type (Spec)) = N_Access_Definition then
5339
5340          --  Ada 2005 (AI-231): This behaviour has been modified in Ada 2005.
5341          --  It is only forced if the null_exclusion appears.
5342
5343          if Ada_Version < Ada_05
5344            or else Null_Exclusion_Present (Spec)
5345          then
5346             Set_Is_Known_Non_Null (Formal_Id);
5347             Set_Can_Never_Be_Null (Formal_Id);
5348          end if;
5349       end if;
5350
5351       Set_Mechanism (Formal_Id, Default_Mechanism);
5352       Set_Formal_Validity (Formal_Id);
5353    end Set_Formal_Mode;
5354
5355    -------------------------
5356    -- Set_Formal_Validity --
5357    -------------------------
5358
5359    procedure Set_Formal_Validity (Formal_Id : Entity_Id) is
5360    begin
5361       --  If no validity checking, then we cannot assume anything about
5362       --  the validity of parameters, since we do not know there is any
5363       --  checking of the validity on the call side.
5364
5365       if not Validity_Checks_On then
5366          return;
5367
5368       --  If validity checking for parameters is enabled, this means we are
5369       --  not supposed to make any assumptions about argument values.
5370
5371       elsif Validity_Check_Parameters then
5372          return;
5373
5374       --  If we are checking in parameters, we will assume that the caller is
5375       --  also checking parameters, so we can assume the parameter is valid.
5376
5377       elsif Ekind (Formal_Id) = E_In_Parameter
5378         and then Validity_Check_In_Params
5379       then
5380          Set_Is_Known_Valid (Formal_Id, True);
5381
5382       --  Similar treatment for IN OUT parameters
5383
5384       elsif Ekind (Formal_Id) = E_In_Out_Parameter
5385         and then Validity_Check_In_Out_Params
5386       then
5387          Set_Is_Known_Valid (Formal_Id, True);
5388       end if;
5389    end Set_Formal_Validity;
5390
5391    ------------------------
5392    -- Subtype_Conformant --
5393    ------------------------
5394
5395    function Subtype_Conformant (New_Id, Old_Id : Entity_Id) return Boolean is
5396       Result : Boolean;
5397
5398    begin
5399       Check_Conformance (New_Id, Old_Id, Subtype_Conformant, False, Result);
5400       return Result;
5401    end Subtype_Conformant;
5402
5403    ---------------------
5404    -- Type_Conformant --
5405    ---------------------
5406
5407    function Type_Conformant (New_Id, Old_Id : Entity_Id) return Boolean is
5408       Result : Boolean;
5409    begin
5410       Check_Conformance (New_Id, Old_Id, Type_Conformant, False, Result);
5411       return Result;
5412    end Type_Conformant;
5413
5414    -------------------------------
5415    -- Valid_Operator_Definition --
5416    -------------------------------
5417
5418    procedure Valid_Operator_Definition (Designator : Entity_Id) is
5419       N    : Integer := 0;
5420       F    : Entity_Id;
5421       Id   : constant Name_Id := Chars (Designator);
5422       N_OK : Boolean;
5423
5424    begin
5425       F := First_Formal (Designator);
5426
5427       while Present (F) loop
5428          N := N + 1;
5429
5430          if Present (Default_Value (F)) then
5431             Error_Msg_N
5432               ("default values not allowed for operator parameters",
5433                Parent (F));
5434          end if;
5435
5436          Next_Formal (F);
5437       end loop;
5438
5439       --  Verify that user-defined operators have proper number of arguments
5440       --  First case of operators which can only be unary
5441
5442       if Id = Name_Op_Not
5443         or else Id = Name_Op_Abs
5444       then
5445          N_OK := (N = 1);
5446
5447       --  Case of operators which can be unary or binary
5448
5449       elsif Id = Name_Op_Add
5450         or Id = Name_Op_Subtract
5451       then
5452          N_OK := (N in 1 .. 2);
5453
5454       --  All other operators can only be binary
5455
5456       else
5457          N_OK := (N = 2);
5458       end if;
5459
5460       if not N_OK then
5461          Error_Msg_N
5462            ("incorrect number of arguments for operator", Designator);
5463       end if;
5464
5465       if Id = Name_Op_Ne
5466         and then Base_Type (Etype (Designator)) = Standard_Boolean
5467         and then not Is_Intrinsic_Subprogram (Designator)
5468       then
5469          Error_Msg_N
5470             ("explicit definition of inequality not allowed", Designator);
5471       end if;
5472    end Valid_Operator_Definition;
5473
5474 end Sem_Ch6;